gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2018 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], BFD_VERSION)
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 AM_INIT_AUTOMAKE
  35
  36 AC_PROG_CC
  37 AC_GNU_SOURCE
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 LT_INIT
  41 ACX_LARGEFILE
  42 ACX_PROG_CMP_IGNORE_INITIAL
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations besides the primary],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 ac_checking=yes
  54 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  55   ac_checking=
  56 fi
  57 AC_ARG_ENABLE(checking,
  58 [  --enable-checking       enable run-time checks],
  59 [case "${enableval}" in
  60   no|none)  ac_checking= ;;
  61   *)        ac_checking=yes ;;
  62 esac])dnl
  63 if test x$ac_checking != x ; then
  64   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  65 fi
  66
  67 # PR gas/19109
  68 # Decide the default method for compressing debug sections.
  69 ac_default_compressed_debug_sections=unset
  70 # Provide a configure time option to override our default.
  71 AC_ARG_ENABLE(compressed_debug_sections,
  72               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  73               [compress debug sections by default]),
  74 [case ,"${enableval}", in
  75   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  76   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  77   *)   ac_default_compressed_debug_sections=unset ;;
  78 esac])dnl
  79
  80 # PR gas/19520
  81 # Decide if x86 assembler should generate relax relocations.
  82 ac_default_x86_relax_relocations=unset
  83 # Provide a configure time option to override our default.
  84 AC_ARG_ENABLE(x86_relax_relocations,
  85               AS_HELP_STRING([--enable-x86-relax-relocations],
  86               [generate x86 relax relocations by default]),
  87 [case "${enableval}" in
  88   no)  ac_default_x86_relax_relocations=0 ;;
  89 esac])dnl
  90
  91 # Decide if ELF assembler should generate common symbols with the
  92 # STT_COMMON type.
  93 ac_default_elf_stt_common=unset
  94 # Provide a configure time option to override our default.
  95 AC_ARG_ENABLE(elf_stt_common,
  96               AS_HELP_STRING([--enable-elf-stt-common],
  97               [generate ELF common symbols with STT_COMMON type by default]),
  98 [case "${enableval}" in
  99   yes)  ac_default_elf_stt_common=1 ;;
 100 esac])dnl
 101
 102
 103 # Decide if the ELF assembler should default to generating
 104 # GNU Build notes if none are provided by the input.
 105 ac_default_generate_build_notes=0
 106 # Provide a configuration option to override the default.
 107 AC_ARG_ENABLE(generate_build_notes,
 108               AS_HELP_STRING([--enable-generate-build-notes],
 109               [generate GNU Build notes if none are provided by the input]),
 110 [case "${enableval}" in
 111   yes)  ac_default_generate_build_notes=1 ;;
 112   no)   ac_default_generate_build_notes=0 ;;
 113 esac])dnl
 114
 115
 116 using_cgen=no
 117
 118 AM_BINUTILS_WARNINGS
 119
 120 # Generate a header file
 121 AC_CONFIG_HEADERS(config.h:config.in)
 122
 123 dnl Option --with-cpu=TYPE allows configure type control of the default
 124 dnl cpu type within the assembler.  Currently only the ARC target
 125 dnl supports this feature, but others may be added in the future.
 126 AC_ARG_WITH(cpu,
 127             AS_HELP_STRING([--with-cpu=CPU],
 128             [default cpu variant is CPU (currently only supported on ARC)]),
 129             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 130                                 "${with_cpu}",
 131                                 [Target specific CPU.])],
 132             [])
 133
 134 # PR 14072
 135 AH_VERBATIM([00_CONFIG_H_CHECK],
 136 [/* Check that config.h is #included before system headers
 137    (this works only for glibc, but that should be enough).  */
 138 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 139 #  error config.h must be #included before system headers
 140 #endif
 141 #define __CONFIG_H__ 1])
 142
 143 # If we are on a DOS filesystem, we must use gdb.ini rather than
 144 # .gdbinit.
 145 case "${host}" in
 146   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 147     GDBINIT="gdb.ini"
 148     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 149     ;;
 150   *)
 151     GDBINIT=".gdbinit"
 152     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 153     ;;
 154 esac
 155 AC_SUBST(GDBINIT)
 156
 157 #We need this for the host.
 158 AC_C_BIGENDIAN
 159
 160 te_file=generic
 161
 162 # Makefile target for installing gas in $(tooldir)/bin.
 163 install_tooldir=install-exec-tooldir
 164
 165 canon_targets=""
 166 all_targets=no
 167 if test -n "$enable_targets" ; then
 168   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 169     if test $t = "all"; then
 170       all_targets=yes
 171       continue
 172     fi
 173     result=`$ac_config_sub $t 2>/dev/null`
 174     if test -n "$result" ; then
 175       canon_targets="$canon_targets $result"
 176 #    else
 177 #      # Permit "all", etc.  We don't support it yet though.
 178 #      canon_targets="$canon_targets $t"
 179     fi
 180   done
 181   GAS_UNIQ(canon_targets)
 182 fi
 183
 184 emulations=""
 185
 186 for this_target in $target $canon_targets ; do
 187
 188     targ=${this_target}
 189     . ${srcdir}/configure.tgt
 190
 191     case ${target_cpu} in
 192       crisv32)
 193         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 194                            [Default CRIS architecture.])
 195         ;;
 196     esac
 197
 198     if test ${this_target} = $target ; then
 199       target_cpu_type=${cpu_type}
 200     elif test ${target_cpu_type} != ${cpu_type} ; then
 201       continue
 202     fi
 203
 204     generic_target=${cpu_type}-${target_vendor}-${target_os}
 205     case ${generic_target} in
 206       i386-*-msdosdjgpp* \
 207       | i386-*-go32* \
 208       | i386-go32-rtems*)
 209         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 210         ;;
 211
 212       i386-*-solaris2 \
 213       | x86_64-*-solaris2 \
 214       | i386-*-solaris2.[[0-9]] \
 215       | i386-*-solaris2.1[[01]] \
 216       | x86_64-*-solaris2.1[[01]])
 217         if test ${this_target} = $target \
 218            && test ${ac_default_x86_relax_relocations} = unset; then
 219           ac_default_x86_relax_relocations=0
 220         fi
 221         ;;
 222
 223       microblaze*)
 224         ;;
 225
 226 changequote(,)dnl
 227       ppc-*-aix[5-9].*)
 228 changequote([,])dnl
 229         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 230                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 231         ;;
 232       ppc-*-solaris*)
 233         if test ${this_target} = $target; then
 234           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 235                     [Define if default target is PowerPC Solaris.])
 236         fi
 237         if test x${endian} = xbig; then
 238           AC_MSG_ERROR(Solaris must be configured little endian)
 239         fi
 240         ;;
 241     esac
 242
 243     if test ${this_target} = $target ; then
 244       endian_def=
 245       if test x${endian} = xbig; then
 246         endian_def=1
 247       elif test x${endian} = xlittle; then
 248         endian_def=0
 249       fi
 250       if test x${endian_def} != x; then
 251         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 252                            [Define as 1 if big endian.])
 253       fi
 254     fi
 255
 256 # Other random stuff.
 257
 258     case ${cpu_type} in
 259       mips)
 260         # Set mips_cpu to the name of the default CPU.
 261         case ${target_cpu} in
 262           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 263             mips_cpu=from-abi
 264             ;;
 265           mipsisa32 | mipsisa32el)
 266             mips_cpu=mips32
 267             ;;
 268           mipsisa32r2 | mipsisa32r2el)
 269             mips_cpu=mips32r2
 270             ;;
 271           mipsisa32r3 | mipsisa32r3el)
 272             mips_cpu=mips32r3
 273             ;;
 274           mipsisa32r5 | mipsisa32r5el)
 275             mips_cpu=mips32r5
 276             ;;
 277           mipsisa32r6 | mipsisa32r6el)
 278             mips_cpu=mips32r6
 279             ;;
 280           mipsisa64 | mipsisa64el)
 281             mips_cpu=mips64
 282             ;;
 283           mipsisa64r2 | mipsisa64r2el)
 284             mips_cpu=mips64r2
 285             ;;
 286           mipsisa64r3 | mipsisa64r3el)
 287             mips_cpu=mips64r3
 288             ;;
 289           mipsisa64r5 | mipsisa64r5el)
 290             mips_cpu=mips64r5
 291             ;;
 292           mipsisa64r6 | mipsisa64r6el)
 293             mips_cpu=mips64r6
 294             ;;
 295           mipstx39 | mipstx39el)
 296             mips_cpu=r3900
 297             ;;
 298           mips64vr | mips64vrel)
 299             mips_cpu=vr4100
 300             ;;
 301           mipsisa32r2* | mipsisa64r2*)
 302 changequote(,)dnl
 303             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 304 changequote([,])dnl
 305             ;;
 306           mipsisa32r6* | mipsisa64r6*)
 307 changequote(,)dnl
 308             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 309 changequote([,])dnl
 310             ;;
 311           mips64* | mipsisa64* | mipsisa32*)
 312 changequote(,)dnl
 313             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 314 changequote([,])dnl
 315             ;;
 316           mips*)
 317 changequote(,)dnl
 318             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 319 changequote([,])dnl
 320             ;;
 321           *)
 322             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 323             ;;
 324         esac
 325         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 326         # binaries.  It's a GNU extension that some OSes don't understand.
 327         case ${target} in
 328           *-*-irix*)
 329             use_e_mips_abi_o32=0
 330             ;;
 331           *)
 332             use_e_mips_abi_o32=1
 333             ;;
 334         esac
 335         # Decide whether to generate 32-bit or 64-bit code by default.
 336         # Used to resolve -march=from-abi when an embedded ABI is selected.
 337         case ${target} in
 338           mips64*-*-* | mipsisa64*-*-*)
 339             mips_default_64bit=1
 340             ;;
 341           *)
 342             mips_default_64bit=0
 343             ;;
 344         esac
 345         # Decide which ABI to target by default.
 346         case ${target} in
 347           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 348           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 349             mips_default_abi=N32_ABI
 350             ;;
 351           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 352             mips_default_abi=O32_ABI
 353             ;;
 354           mips64*-openbsd*)
 355             mips_default_abi=N64_ABI
 356             ;;
 357           *)
 358             mips_default_abi=NO_ABI
 359             ;;
 360         esac
 361         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 362                            [Default CPU for MIPS targets. ])
 363         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 364                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 365         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 366                            [Generate 64-bit code by default on MIPS targets. ])
 367         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 368                            [Choose a default ABI for MIPS targets. ])
 369         ;;
 370     esac
 371
 372     # Do we need the opcodes library?
 373     case ${cpu_type} in
 374       vax | tic30)
 375         ;;
 376
 377       *)
 378         need_opcodes=yes
 379
 380         case "${enable_shared}" in
 381         yes) shared_opcodes=true ;;
 382         *opcodes*) shared_opcodes=true ;;
 383         *) shared_opcodes=false ;;
 384         esac
 385         ;;
 386     esac
 387
 388     # Any other special object files needed ?
 389     case ${cpu_type} in
 390
 391       bfin)
 392         for f in bfin-parse.o bfin-lex-wrapper.o; do
 393           case " $extra_objects " in
 394             *" $f "*) ;;
 395             *) extra_objects="$extra_objects $f" ;;
 396           esac
 397         done
 398         ;;
 399
 400       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 401         using_cgen=yes
 402         ;;
 403
 404       m32c)
 405         using_cgen=yes
 406         ;;
 407       frv)
 408         using_cgen=yes
 409         ;;
 410       m68k)
 411         f=m68k-parse.o
 412         case " $extra_objects " in
 413           *" $f "*) ;;
 414           *) extra_objects="$extra_objects $f" ;;
 415         esac
 416         ;;
 417
 418       mep)
 419         using_cgen=yes
 420         ;;
 421
 422       mips)
 423         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 424           case " $extra_objects " in
 425             *" $f "*) ;;
 426             *) extra_objects="$extra_objects $f" ;;
 427           esac
 428         done
 429         ;;
 430
 431       mt)
 432         using_cgen=yes
 433         ;;
 434
 435       nds32)
 436         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 437         # based on arch_name.
 438         AC_MSG_CHECKING(for default configuration of --with-arch)
 439         if test "x${with_arch}" != x; then
 440           case ${with_arch} in
 441             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 442               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 443                                  [Define value for nds32_arch_name])
 444               ;;
 445             *)
 446               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 447               ;;
 448           esac
 449         fi
 450         AC_MSG_RESULT($with_arch)
 451
 452         # Decide features one by one.
 453         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 454         if test "x${enable_dx_regs}" = xyes; then
 455           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 456                     [Define value for nds32_dx_regs])
 457         else
 458           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 459                     [Define default value for nds32_dx_regs])
 460         fi
 461         AC_MSG_RESULT($enable_dx_regs)
 462
 463         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 464         if test "x${enable_perf_ext}" = xno; then
 465           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 466                     [Define value for nds32_perf_ext])
 467         else
 468           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 469                     [Define default value for nds32_perf_ext])
 470         fi
 471         AC_MSG_RESULT($enable_perf_ext)
 472
 473         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 474         if test "x${enable_perf_ext2}" = xno; then
 475           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 476                     [Define value for nds32_perf_ext2])
 477         else
 478           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 479                     [Define default value for nds32_perf_ext2])
 480         fi
 481         AC_MSG_RESULT($enable_perf_ext2)
 482
 483         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 484         if test "x${enable_string_ext}" = xno; then
 485           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 486                     [Define value for nds32_string_ext])
 487         else
 488           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 489                     [Define default value for nds32_string_ext])
 490         fi
 491         AC_MSG_RESULT($enable_string_ext)
 492
 493         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 494         if test "x${enable_audio_ext}" = xno; then
 495           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 496                     [Define value for nds32_audio_ext])
 497         else
 498           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 499                     [Define default value for nds32_audio_ext])
 500         fi
 501         AC_MSG_RESULT($enable_audio_ext)
 502         ;;
 503
 504       aarch64 | i386 | riscv | s390 | sparc)
 505         if test $this_target = $target ; then
 506           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 507         fi
 508         ;;
 509
 510       rl78)
 511         f=rl78-parse.o
 512         case " $extra_objects " in
 513           *" $f "*) ;;
 514           *) extra_objects="$extra_objects $f" ;;
 515         esac
 516         ;;
 517
 518       rx)
 519         f=rx-parse.o
 520         case " $extra_objects " in
 521           *" $f "*) ;;
 522           *) extra_objects="$extra_objects $f" ;;
 523         esac
 524         ;;
 525
 526       xstormy16)
 527         using_cgen=yes
 528         ;;
 529
 530       xc16x)
 531         using_cgen=yes
 532         ;;
 533
 534       xtensa)
 535         f=config/xtensa-relax.o
 536         case " $extra_objects " in
 537           *" $f "*) ;;
 538           *) extra_objects="$extra_objects $f" ;;
 539         esac
 540         ;;
 541
 542       *)
 543         ;;
 544     esac
 545
 546     if test $using_cgen = yes ; then
 547         f=cgen.o
 548         case " $extra_objects " in
 549           *" $f "*) ;;
 550           *) extra_objects="$extra_objects $f" ;;
 551         esac
 552     fi
 553
 554 # See if we really can support this configuration with the emulation code.
 555
 556     if test $this_target = $target ; then
 557       obj_format=$fmt
 558       te_file=$em
 559     fi
 560
 561     case ${te_file} in
 562       vms)
 563         f=config/te-vms.o
 564         case " $extra_objects " in
 565           *" $f "*) ;;
 566           *) extra_objects="$extra_objects $f" ;;
 567         esac ;;
 568     esac
 569
 570 # From target name and format, produce a list of supported emulations.
 571
 572     case ${generic_target}-${fmt} in
 573       mips-*-*-*)       case "$endian" in
 574                         big)    emulation="mipsbelf mipslelf mipself" ;;
 575                         *)      emulation="mipslelf mipsbelf mipself" ;;
 576                         esac ;;
 577       # i386-pc-pe-coff != i386-pc-coff.
 578       i386-*-pe-coff)   ;;
 579       # Uncommenting the next line will turn on support for i386 AOUT
 580       # for the default linux configuration
 581       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 582       #
 583       i386-*-aout)      emulation="i386aout" ;;
 584       i386-*-coff)      emulation="i386coff" ;;
 585       i386-*-elf)       emulation="i386elf" ;;
 586
 587       # Always all formats.  The first stated emulation becomes the default.
 588       cris-*-*aout*)    emulation="crisaout criself" ;;
 589       cris-*-*)         emulation="criself crisaout" ;;
 590     esac
 591
 592     emulations="$emulations $emulation"
 593
 594 done
 595
 596 if test ${ac_default_x86_relax_relocations} = unset; then
 597   ac_default_x86_relax_relocations=1
 598 fi
 599 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 600   $ac_default_x86_relax_relocations,
 601   [Define to 1 if you want to generate x86 relax relocations by default.])
 602
 603 if test ${ac_default_elf_stt_common} = unset; then
 604   ac_default_elf_stt_common=0
 605 fi
 606 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 607   $ac_default_elf_stt_common,
 608   [Define to 1 if you want to generate ELF common symbols with the
 609    STT_COMMON type by default.])
 610
 611 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 612   $ac_default_generate_build_notes,
 613   [Define to 1 if you want to generate GNU Build attribute notes
 614    by default, if none are contained in the input.])
 615
 616 if test x$ac_default_compressed_debug_sections = xyes ; then
 617   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 618 fi
 619
 620 # Turn on all targets if possible
 621 if test ${all_targets} = "yes"; then
 622   case ${target_cpu_type} in
 623   i386)
 624     case ${obj_format} in
 625     aout)
 626       emulations="$emulations i386coff i386elf"
 627       ;;
 628     coff)
 629       emulations="$emulations i386aout i386elf"
 630     ;;
 631     elf)
 632       emulations="$emulations i386aout i386coff"
 633       ;;
 634     esac
 635   ;;
 636   x86_64)
 637     case ${obj_format} in
 638     aout)
 639       emulations="$emulations i386coff i386elf"
 640       ;;
 641     coff)
 642       emulations="$emulations i386aout i386elf"
 643     ;;
 644     elf)
 645       emulations="$emulations i386aout i386coff"
 646       ;;
 647     esac
 648   ;;
 649   esac
 650 fi
 651
 652 # PE code has way too many macros tweaking behaviour
 653 case ${te_file} in
 654   pe*) emulations="" ;;
 655 esac
 656
 657 # Assign floating point type.  Most processors with FP support
 658 # IEEE FP.  On those that don't support FP at all, usually IEEE
 659 # is emulated.
 660 case ${target_cpu} in
 661   vax | pdp11 ) atof=vax ;;
 662   *)            atof=ieee ;;
 663 esac
 664
 665 case "${obj_format}" in
 666   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 667 esac
 668
 669 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 670 cgen_cpu_prefix=""
 671 if test $using_cgen = yes ; then
 672   case ${target_cpu} in
 673     or1knd)
 674        cgen_cpu_prefix=or1k ;;
 675     *) cgen_cpu_prefix=${target_cpu} ;;
 676   esac
 677   AC_SUBST(cgen_cpu_prefix)
 678   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 679 fi
 680
 681 dnl
 682 dnl Make sure the desired support files exist.
 683 dnl
 684
 685 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 686   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 687 fi
 688
 689 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 690   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 691 fi
 692
 693 # Some COFF configurations want these random other flags set.
 694 case ${obj_format} in
 695   coff)
 696     case ${target_cpu_type} in
 697       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 698       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 699     esac
 700     ;;
 701 esac
 702
 703 # Getting this done right is going to be a bitch.  Each configuration specified
 704 # with --enable-targets=... should be checked for environment, format, cpu
 705 # setting.
 706 #
 707 # For each configuration, the necessary object file support code must be linked
 708 # in.  This might be only one, it might be up to four.  The necessary emulation
 709 # code needs to be provided, too.
 710 #
 711 # And then there's "--enable-targets=all"....
 712 #
 713 # For now, just always do it for MIPS ELF configurations.  Sigh.
 714
 715 formats="${obj_format}"
 716 emfiles=""
 717 EMULATIONS=""
 718 GAS_UNIQ(emulations)
 719 for em in . $emulations ; do
 720   case $em in
 721     .)  continue ;;
 722     mipsbelf | mipslelf | mipself)
 723         fmt=elf   file=mipself ;;
 724     *coff)
 725         fmt=coff  file=$em ;;
 726     *aout)
 727         fmt=aout file=$em ;;
 728     *elf)
 729         fmt=elf file=$em ;;
 730   esac
 731   formats="$formats $fmt"
 732   emfiles="$emfiles config/e-$file.o"
 733   EMULATIONS="$EMULATIONS &$em,"
 734 done
 735 GAS_UNIQ(formats)
 736 GAS_UNIQ(emfiles)
 737 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 738   for fmt in $formats ; do
 739     case $fmt in
 740       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 741       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 742       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 743       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 744       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 745       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 746     esac
 747     extra_objects="$extra_objects config/obj-$fmt.o"
 748   done
 749   obj_format=multi
 750 fi
 751 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 752   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 753   # e-mipself has more than one emulation per file, e-i386* has just one at the
 754   # moment.  If only one emulation is specified, then don't define
 755   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 756   case "${obj_format}${emfiles}" in
 757     multi* | *mipself*)
 758       extra_objects="$extra_objects $emfiles"
 759       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 760   esac
 761 fi
 762 AC_SUBST(extra_objects)
 763 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 764 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 765                    [Default emulation.])
 766
 767 reject_dev_configs=yes
 768
 769 case ${reject_dev_configs}-${dev} in
 770   yes-yes) # Oops.
 771     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 772     ;;
 773 esac
 774
 775 AC_SUBST(target_cpu_type)
 776 AC_SUBST(obj_format)
 777 AC_SUBST(te_file)
 778 AC_SUBST(install_tooldir)
 779 AC_SUBST(atof)
 780 dnl AC_SUBST(emulation)
 781
 782 # do we need the opcodes library?
 783 case "${need_opcodes}" in
 784 yes)
 785   OPCODES_LIB=../opcodes/libopcodes.la
 786   ;;
 787 esac
 788
 789 AC_SUBST(OPCODES_LIB)
 790
 791 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 792 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 793 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 794 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 795 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 796
 797 AC_PROG_YACC
 798 AM_PROG_LEX
 799
 800 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 801 ZW_GNU_GETTEXT_SISTER_DIR
 802 AM_PO_SUBDIRS
 803
 804 AM_MAINTAINER_MODE
 805 AM_CONDITIONAL(GENINSRC_NEVER, false)
 806 AC_EXEEXT
 807
 808 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 809 ACX_HEADER_STRING
 810
 811 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 812 # people who are not cross-compiling but are compiling cross-assemblers.
 813 AC_MSG_CHECKING(whether compiling a cross-assembler)
 814 if test "${host}" = "${target}"; then
 815   cross_gas=no
 816 else
 817   cross_gas=yes
 818   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 819 fi
 820 AC_MSG_RESULT($cross_gas)
 821
 822 dnl ansidecl.h will deal with const
 823 dnl AC_C_CONST
 824 AC_FUNC_ALLOCA
 825 AC_C_INLINE
 826
 827 # VMS doesn't have unlink.
 828 AC_CHECK_FUNCS(unlink remove, break)
 829 AC_CHECK_FUNCS(sbrk setlocale)
 830 AC_CHECK_FUNCS(strsignal)
 831
 832 AM_LC_MESSAGES
 833
 834 # do we need the math library?
 835 case "${need_libm}" in
 836 yes)
 837   LT_LIB_M
 838   AC_SUBST(LIBM)
 839   ;;
 840 esac
 841
 842 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 843 # enough, but on some of those systems, the assert macro relies on requoting
 844 # working properly!
 845 GAS_WORKING_ASSERT
 846
 847 # On some systems, the system header files may not declare malloc, realloc,
 848 # and free.  There are places where gas needs these functions to have been
 849 # declared -- such as when taking their addresses.
 850 gas_test_headers="
 851 #ifdef HAVE_MEMORY_H
 852 #include <memory.h>
 853 #endif
 854 #ifdef HAVE_STRING_H
 855 #include <string.h>
 856 #else
 857 #ifdef HAVE_STRINGS_H
 858 #include <strings.h>
 859 #endif
 860 #endif
 861 #ifdef HAVE_STDLIB_H
 862 #include <stdlib.h>
 863 #endif
 864 #ifdef HAVE_UNISTD_H
 865 #include <unistd.h>
 866 #endif
 867 "
 868
 869 # Does errno.h declare errno, or do we have to add a separate declaration
 870 # for it?
 871 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 872 #ifdef HAVE_ERRNO_H
 873 #include <errno.h>
 874 #endif
 875 ])
 876
 877 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 878 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 879 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 880 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 881 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 882 if test $gas_cv_decl_getopt_unistd_h = yes; then
 883   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 884             [Is the prototype for getopt in <unistd.h> in the expected format?])
 885 fi
 886
 887 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 888 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 889 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 890 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 891 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 892 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 893
 894 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf, asprintf])
 895
 896 BFD_BINARY_FOPEN
 897
 898 # Link in zlib if we can.  This allows us to write compressed debug sections.
 899 AM_ZLIB
 900
 901 # Support for VMS timestamps via cross compile
 902
 903 if test "$ac_cv_header_time_h" = yes; then
 904   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 905 fi
 906
 907 if test "$ac_cv_header_sys_stat_h" = yes; then
 908     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 909     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 910 fi
 911
 912
 913 dnl Required for html, pdf, install-pdf and install-html targets.
 914 AC_SUBST(datarootdir)
 915 AC_SUBST(docdir)
 916 AC_SUBST(htmldir)
 917 AC_SUBST(pdfdir)
 918
 919 dnl This must come last.
 920
 921 dnl We used to make symlinks to files in the source directory, but now
 922 dnl we just use the right name for .c files, and create .h files in
 923 dnl the build directory which include the right .h file.  Make sure
 924 dnl the old symlinks don't exist, so that a reconfigure in an existing
 925 dnl directory behaves reasonably.
 926
 927 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 928 AC_CONFIG_COMMANDS([default],
 929 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 930  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 931  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 932  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 933  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 934  if test "x$cgen_cpu_prefix" != x ; then
 935    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 936  fi],
 937 [target_cpu_type=${target_cpu_type}
 938  cgen_cpu_prefix=${cgen_cpu_prefix}
 939  obj_format=${obj_format}
 940  te_file=${te_file}])
 941
 942 AC_OUTPUT