gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66 changequote(,)dnl
  67     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  68 changequote([,])dnl
  69
  70     # check for architecture variants
  71     case ${cpu} in
  72       armeb)            cpu_type=arm endian=big ;;
  73       arm*)             cpu_type=arm endian=little ;;
  74       hppa*)            cpu_type=hppa ;;
  75 changequote(,)dnl
  76       i[456]86)         cpu_type=i386 ;;
  77       m680[012346]0)    cpu_type=m68k ;;
  78       m68008)           cpu_type=m68k ;;
  79       m683??)           cpu_type=m68k ;;
  80 changequote([,])dnl
  81       m8*)              cpu_type=m88k ;;
  82       mips*el)          cpu_type=mips endian=little;;
  83       mips*)            cpu_type=mips endian=big ;;
  84       powerpcle*)       cpu_type=ppc endian=little ;;
  85       powerpc*)         cpu_type=ppc endian=big ;;
  86       rs6000*)          cpu_type=ppc ;;
  87       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  88       sparc*)           cpu_type=sparc ;;
  89       *)                cpu_type=${cpu} ;;
  90     esac
  91
  92     if test ${this_target} = $target ; then
  93       target_cpu_type=${cpu_type}
  94     elif test ${target_cpu_type} != ${cpu_type} ; then
  95       continue
  96     fi
  97
  98     targ=${cpu_type}
  99     generic_target=${cpu_type}-$vendor-$os
 100     dev=no
 101     bfd_gas=no
 102     em=generic
 103
 104     # assign object format
 105     case ${generic_target} in
 106       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 107       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 108       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 109       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 110       a29k-*-vxworks*)      fmt=coff ;;
 111
 112       alpha-*-*vms*)        fmt=evax ;;
 113       alpha-*-netware*)     fmt=ecoff ;;
 114       alpha-*-osf*)         fmt=ecoff ;;
 115       alpha-*-linuxecoff*)  fmt=ecoff ;;
 116       alpha-*-linux*)       fmt=elf em=linux ;;
 117
 118 # start-sanitize-arc
 119       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 120 # end-sanitize-arc
 121
 122       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 123       arm-*-aout)           fmt=aout
 124                             case "$endian" in
 125                               big)      targ=arm-big ;;
 126                               *)        targ=arm-lit ;;
 127                             esac
 128                             ;;
 129       arm-*-coff)           fmt=coff ;;
 130       arm-*-riscix*)        fmt=aout ;;
 131       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 132
 133 # start-sanitize-d10v
 134       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 135 # end-sanitize-d10v
 136
 137       hppa-*-*elf*)         fmt=elf em=hppa ;;
 138       hppa-*-lites*)        fmt=elf em=hppa ;;
 139       hppa-*-osf*)          fmt=som em=hppa ;;
 140       hppa-*-hpux*)         fmt=som em=hppa ;;
 141       hppa-*-bsd*)          fmt=som em=hppa ;;
 142       hppa-*-hiux*)         fmt=som em=hppa ;;
 143
 144       h8300-*-coff)         fmt=coff ;;
 145
 146       i386-ibm-aix*)        fmt=coff targ=i386coff
 147                              em=i386aix ;;
 148       i386-*-bsd*)          fmt=aout em=386bsd ;;
 149       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 150       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 151       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 152       i386-*-linux*coff*)   fmt=coff em=linux
 153                              targ=i386coff ;;
 154       i386-*-linux*)        fmt=elf em=linux ;;
 155       i386-*-lynxos*)       fmt=coff targ=i386coff
 156                              em=lynx ;;
 157       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 158                             fmt=elf ;;
 159       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 160       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 161                             fmt=coff targ=i386coff ;;
 162       i386-*-vsta)          fmt=aout ;;
 163       i386-*-go32)          fmt=coff targ=i386coff ;;
 164       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 165       i386-*-gnu*)          fmt=elf ;;
 166       i386-*-mach*)
 167                             fmt=aout em=mach bfd_gas=yes ;;
 168       i386-*-msdos*)        fmt=aout ;;
 169       i386-*-moss*)         fmt=elf ;;
 170       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 171       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 172       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 173       i960-*-bout)          fmt=bout ;;
 174       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 175       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 176       i960-*-nindy*)        fmt=bout ;;
 177       i960-*-vxworks4*)     fmt=bout ;;
 178       i960-*-vxworks5.0)    fmt=bout ;;
 179       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 180       i960-*-vxworks*)      fmt=bout ;;
 181
 182       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 183                             fmt=aout em=sun3 ;;
 184       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 185       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 186       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 187       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 188                             fmt=elf ;;
 189       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 190                             fmt=coff targ=m68kcoff ;;
 191       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 192       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 193       m68k-*-linux*)        fmt=elf em=linux ;;
 194       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 195                              em=lynx ;;
 196       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 197       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 198       m68k-*-psos*)         fmt=elf em=psos;;
 199
 200       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 201       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 202
 203       # don't change em like *-*-bsd does
 204       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 205       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 206       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 207       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 208       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 209       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 210       mips-*-ecoff*)        fmt=ecoff
 211                             case "$endian" in
 212                             big) targ=mips-big ;;
 213                             *)   targ=mips-lit ;;
 214                             esac
 215                             ;;
 216       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 217       mips-*-gnu*)          fmt=aout
 218                             case "$endian" in
 219                             big) targ=mips-big ;;
 220                             *)   targ=mips-lit ;;
 221                             esac
 222                             ;;
 223       mips-*-irix6*)        fmt=elf targ=mips-big ;;
 224       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 225       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 226       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 227       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 228       mips-*-elf* | mips-*-rtems*)
 229                             fmt=elf
 230                             case "$endian" in
 231                             big) targ=mips-big ;;
 232                             *)   targ=mips-lit ;;
 233                             esac
 234                             ;;
 235       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 236       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 237       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 238                             fmt=coff em=pe
 239                             case "$endian" in
 240                             big) targ=ppc-big ;;
 241                             *)   targ=ppc-lit ;;
 242                             esac
 243                             ;;
 244       ppc-*-aix*)           fmt=coff ;;
 245       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 246                             fmt=elf
 247                             case "$endian" in
 248                             big)  targ=ppc-big ;;
 249                             *)    targ=ppc-lit ;;
 250                             esac
 251                             ;;
 252       ppc-*-linux*)         fmt=elf
 253                             case "$endian" in
 254                             big)  targ=ppc-big ;;
 255                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 256                             esac
 257                             ;;
 258       ppc-*-solaris*)       fmt=elf
 259                             case "$endian" in
 260                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 261                             *)    targ=ppc-sol ;;
 262                             esac
 263                             ;;
 264       ppc-*-rtems*)
 265                             fmt=elf
 266                             case "$endian" in
 267                             big)  targ=ppc-big ;;
 268                             *)    targ=ppc-lit ;;
 269                             esac
 270                             ;;
 271       ppc-*-macos* | ppc-*-mpw*)
 272                             fmt=coff em=macos ;;
 273       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 274
 275       sh-*-elf*)            fmt=elf ;;
 276       sh-*-coff*)           fmt=coff ;;
 277
 278       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 279       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 280
 281       sparc-*-rtems*)       fmt=aout ;;
 282       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 283       sparc-*-aout | sparc*-*-vxworks*)
 284                             fmt=aout em=sparcaout ;;
 285       sparc-*-coff)         fmt=coff ;;
 286       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 287       sparc-fujitsu-none)   fmt=aout ;;
 288       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 289                             fmt=elf ;;
 290       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 291
 292 # start-sanitize-tic80
 293       tic80-*-coff)         fmt=coff targ=tic80coff;;
 294 # end-sanitize-tic80
 295       v850-*-*)             fmt=elf bfd_gas=yes ;;
 296
 297       vax-*-bsd* | vax-*-ultrix*)
 298                             fmt=aout ;;
 299       vax-*-vms)            fmt=vms ;;
 300
 301       z8k-*-coff | z8k-*-sim)
 302                             fmt=coff ;;
 303
 304       w65-*-*)              fmt=coff ;;
 305
 306       *-*-aout | *-*-scout)
 307                             fmt=aout ;;
 308       *-*-nindy*)
 309                             fmt=bout ;;
 310       *-*-bsd*)
 311                             fmt=aout em=sun3 ;;
 312       *-*-generic)          fmt=generic ;;
 313       *-*-xray | *-*-hms)   fmt=coff ;;
 314       *-*-sim)              fmt=coff ;;
 315       *-*-elf | *-*-sysv4* | *-*-solaris*)
 316                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 317                             fmt=elf dev=yes ;;
 318       *-*-vxworks)          fmt=aout ;;
 319       *-*-netware)          fmt=elf ;;
 320     esac
 321
 322     case ${cpu_type}-${fmt} in
 323       alpha-*)  bfd_gas=yes ;;
 324       arm-*)    bfd_gas=yes ;;
 325     # not yet
 326     # i386-aout)        bfd_gas=preferred ;;
 327       mips-*)   bfd_gas=yes ;;
 328       ns32k-*)  bfd_gas=yes ;;
 329       ppc-*)    bfd_gas=yes ;;
 330       sparc-*)  bfd_gas=yes ;;
 331       *-elf)    bfd_gas=yes ;;
 332       *-ecoff)  bfd_gas=yes ;;
 333       *-som)    bfd_gas=yes ;;
 334       *)                ;;
 335     esac
 336
 337 # Other random stuff.
 338
 339     # do we need the opcodes library?
 340     case ${cpu_type} in
 341       vax | i386)
 342         ;;
 343       *)
 344         need_opcodes=yes
 345         if test "${shared_opcodes}" = "true"; then
 346           # A shared libopcodes must be linked against libbfd.
 347           need_bfd=yes
 348         fi
 349         ;;
 350     esac
 351
 352     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 353
 354     case ${cpu}-${vendor}-${os} in
 355       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 356     esac
 357
 358     case ${cpu_type} in
 359       m68k)
 360         case ${extra_objects} in
 361         *m68k-parse.o*) ;;
 362         *) extra_objects="$extra_objects m68k-parse.o" ;;
 363         esac
 364         ;;
 365     esac
 366
 367 # See if we really can support this configuration with the emulation code.
 368
 369     if test $this_target = $target ; then
 370       primary_bfd_gas=$bfd_gas
 371       obj_format=$fmt
 372       gas_target=$targ
 373       te_file=$em
 374
 375       if test $bfd_gas = no ; then
 376         # Can't support other configurations this way.
 377         break
 378       fi
 379     elif test $bfd_gas = no ; then
 380       # Can't support this configuration.
 381       break
 382     fi
 383
 384 # From target name and format, produce a list of supported emulations.
 385
 386     case ${generic_target}-${fmt} in
 387       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 388       mips-*-*-ecoff)   case "$endian" in
 389                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 390                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 391                         esac ;;
 392       mips-*-*-elf)     case "$endian" in
 393                         big)    emulation="mipsbelf mipslelf mipself" ;;
 394                         *)      emulation="mipslelf mipsbelf mipself" ;;
 395                         esac ;;
 396     esac
 397
 398     emulations="$emulations $emulation"
 399
 400 done
 401
 402 # Assign floating point type.  Most processors with FP support
 403 # IEEE FP.  On those that don't support FP at all, usually IEEE
 404 # is emulated.
 405 case ${target_cpu} in
 406   vax | tahoe ) atof=${target_cpu} ;;
 407   *)            atof=ieee ;;
 408 esac
 409
 410 case "${obj_format}" in
 411   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 412 esac
 413
 414 dnl
 415 dnl Make sure the desired support files exist.
 416 dnl
 417
 418 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 419   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 420 fi
 421
 422 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 423   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 424 fi
 425
 426 # and target makefile frag
 427
 428 target_frag=${srcdir}/config/${gas_target}.mt
 429 if test ! -r ${target_frag}; then
 430   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 431 fi
 432 AC_SUBST_FILE(target_frag)
 433
 434 case ${user_bfd_gas}-${primary_bfd_gas} in
 435   yes-yes | no-no)
 436     # We didn't override user's choice.
 437     ;;
 438   no-yes)
 439     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 440     ;;
 441   no-preferred)
 442     primary_bfd_gas=no
 443     ;;
 444   *-preferred)
 445     primary_bfd_gas=yes
 446     ;;
 447   yes-*)
 448     primary_bfd_gas=yes
 449     ;;
 450   -*)
 451     # User specified nothing.
 452     ;;
 453 esac
 454
 455 # Some COFF configurations want these random other flags set.
 456 case ${obj_format} in
 457   coff)
 458     case ${target_cpu_type} in
 459       i386) AC_DEFINE(I386COFF) ;;
 460       m68k) AC_DEFINE(M68KCOFF) ;;
 461       m88k) AC_DEFINE(M88KCOFF) ;;
 462     esac
 463     ;;
 464 esac
 465
 466 # Getting this done right is going to be a bitch.  Each configuration specified
 467 # with --enable-targets=... should be checked for environment, format, cpu, and
 468 # bfd_gas setting.
 469 #
 470 # For each configuration, the necessary object file support code must be linked
 471 # in.  This might be only one, it might be up to four.  The necessary emulation
 472 # code needs to be provided, too.
 473 #
 474 # And then there's "--enable-targets=all"....
 475 #
 476 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 477
 478 formats="${obj_format}"
 479 emfiles=""
 480 EMULATIONS=""
 481 GAS_UNIQ(emulations)
 482 for em in . $emulations ; do
 483   case $em in
 484     .)  continue ;;
 485     mipsbelf | mipslelf)
 486         fmt=elf   file=mipself ;;
 487     mipsbecoff | mipslecoff)
 488         fmt=ecoff file=mipsecoff ;;
 489   esac
 490   formats="$formats $fmt"
 491   emfiles="$emfiles e-$file.o"
 492   EMULATIONS="$EMULATIONS &$em,"
 493 done
 494 GAS_UNIQ(formats)
 495 GAS_UNIQ(emfiles)
 496 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 497   for fmt in $formats ; do
 498     case $fmt in
 499       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 500       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 501       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 502       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 503       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 504       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 505       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 506       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 507       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 508       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 509     esac
 510     extra_objects="$extra_objects obj-$fmt.o"
 511   done
 512   obj_format=multi
 513 fi
 514 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 515   te_file=multi
 516   extra_objects="$extra_objects $emfiles"
 517   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 518   AC_DEFINE(USE_EMULATIONS)
 519 fi
 520 AC_SUBST(extra_objects)
 521 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 522 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 523
 524 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 525         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 526         config/te-${te_file}.h config/atof-${atof}.c \
 527         $extra_files"
 528 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 529         $extra_links"
 530
 531 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 532   yes-*-coff)   need_bfd=yes ;;
 533   no-*-coff)    need_bfd=yes
 534                 AC_DEFINE(MANY_SEGMENTS) ;;
 535 esac
 536
 537 reject_dev_configs=yes
 538
 539 case ${reject_dev_configs}-${dev} in
 540   yes-yes) # Oops.
 541     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 542     ;;
 543 esac
 544
 545 AC_SUBST(target_cpu_type)
 546 AC_SUBST(obj_format)
 547 AC_SUBST(atof)
 548 dnl AC_SUBST(emulation)
 549
 550 AC_LINK_FILES($files, $links)
 551
 552 case "${primary_bfd_gas}" in
 553   yes)  AC_DEFINE(BFD_ASSEMBLER)
 554         need_bfd=yes ;;
 555 esac
 556
 557 # do we need the opcodes library?
 558 case "${need_opcodes}" in
 559 yes)
 560   OPCODES_DEP=../opcodes/libopcodes.a
 561   OPCODES_LIB='-L../opcodes -lopcodes'
 562
 563   # We need to handle some special cases for shared libraries.
 564   case "${host}" in
 565   *-*-sunos*)
 566     # On SunOS, we must link against the name we are going to install,
 567     # not -lbfd, since SunOS does not support SONAME.
 568     if test "${shared_opcodes}" = "true"; then
 569       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 570     fi
 571     ;;
 572   alpha*-*-osf*)
 573     # On Alpha OSF/1, the native linker searches all the -L
 574     # directories for any LIB.so files, and only then searches for any
 575     # LIB.a files.  That means that if there is an installed
 576     # libbfd.so, but this build is not done with --enable-shared, the
 577     # link will wind up being against the install libbfd.so rather
 578     # than the newly built libbfd.  To avoid this, we must explicitly
 579     # link against libbfd.a when --enable-shared is not used.
 580     if test "${shared_opcodes}" != "true"; then
 581       OPCODES_LIB='../opcodes/libopcodes.a'
 582     fi
 583     ;;
 584   esac
 585   ;;
 586 esac
 587 AC_SUBST(OPCODES_DEP)
 588 AC_SUBST(OPCODES_LIB)
 589
 590 case "${need_bfd}" in
 591 yes)
 592   BFDDEP=../bfd/libbfd.a
 593   BFDLIB='-L../bfd -lbfd'
 594   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 595
 596   # We need to handle some special cases for shared libraries
 597   case "${host}" in
 598   *-*-sunos*)
 599     # On SunOS, we must link against the name we are going to install,
 600     # not -lbfd, since SunOS does not support SONAME.
 601     if test "${shared_bfd}" = "true"; then
 602       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 603     fi
 604     ;;
 605   alpha*-*-osf*)
 606     # On Alpha OSF/1, the native linker searches all the -L
 607     # directories for any LIB.so files, and only then searches for any
 608     # LIB.a files.  That means that if there is an installed
 609     # libbfd.so, but this build is not done with --enable-shared, the
 610     # link will wind up being against the install libbfd.so rather
 611     # than the newly built libbfd.  To avoid this, we must explicitly
 612     # link against libbfd.a when --enable-shared is not used.
 613     if test "${shared_bfd}" != "true"; then
 614       BFDLIB='../bfd/libbfd.a'
 615     fi
 616     ;;
 617   esac
 618   ;;
 619 esac
 620 AC_SUBST(BFDDEP)
 621 AC_SUBST(BFDLIB)
 622 AC_SUBST(ALL_OBJ_DEPS)
 623
 624 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 625 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 626 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 627 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 628 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 629
 630 AC_PROG_CC
 631 AC_PROG_INSTALL
 632
 633 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 634
 635 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 636 # people who are not cross-compiling but are compiling cross-assemblers.
 637 AC_MSG_CHECKING(whether compiling a cross-assembler)
 638 if test "${host}" = "${target}"; then
 639   cross_gas=no
 640 else
 641   cross_gas=yes
 642   AC_DEFINE(CROSS_COMPILE)
 643 fi
 644 AC_MSG_RESULT($cross_gas)
 645
 646 dnl ansidecl.h will deal with const
 647 dnl AC_CONST
 648 AC_FUNC_ALLOCA
 649 AC_C_INLINE
 650
 651 # VMS doesn't have unlink.
 652 AC_CHECK_FUNCS(unlink remove, break)
 653
 654 # Some systems don't have sbrk().
 655 AC_CHECK_FUNCS(sbrk)
 656
 657 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 658 # enough, but on some of those systems, the assert macro relies on requoting
 659 # working properly!
 660 GAS_WORKING_ASSERT
 661
 662 # On some systems, the system header files may not declare malloc, realloc,
 663 # and free.  There are places where gas needs these functions to have been
 664 # declared -- such as when taking their addresses.
 665 gas_test_headers="
 666 #ifdef HAVE_MEMORY_H
 667 #include <memory.h>
 668 #endif
 669 #ifdef HAVE_STRING_H
 670 #include <string.h>
 671 #else
 672 #ifdef HAVE_STRINGS_H
 673 #include <strings.h>
 674 #endif
 675 #endif
 676 #ifdef HAVE_STDLIB_H
 677 #include <stdlib.h>
 678 #endif
 679 #ifdef HAVE_UNISTD_H
 680 #include <unistd.h>
 681 #endif
 682 "
 683 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 684 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 685 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 686 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 687
 688 # Does errno.h declare errno, or do we have to add a separate declaration
 689 # for it?
 690 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 691 #ifdef HAVE_ERRNO_H
 692 #include <errno.h>
 693 #endif
 694 ])
 695
 696 HLDFLAGS=
 697 HLDENV=
 698 RPATH_ENVVAR=LD_LIBRARY_PATH
 699 # If we have shared libraries, try to set rpath reasonably.
 700 if test "${shared}" = "true"; then
 701   case "${host}" in
 702   *-*-hpux*)
 703     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 704     RPATH_ENVVAR=SHLIB_PATH
 705     ;;
 706   *-*-irix5* | *-*-irix6*)
 707     HLDFLAGS='-Wl,-rpath,$(libdir)'
 708     ;;
 709   *-*-linux*aout*)
 710     ;;
 711   *-*-linux*)
 712     HLDFLAGS='-Wl,-rpath,$(libdir)'
 713     ;;
 714   *-*-solaris*)
 715     HLDFLAGS='-R $(libdir)'
 716     ;;
 717   *-*-sysv4*)
 718     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 719     ;;
 720   esac
 721 fi
 722
 723 # On SunOS, if the linker supports the -rpath option, use it to
 724 # prevent ../bfd and ../opcodes from being included in the run time
 725 # search path.
 726 case "${host}" in
 727   *-*-sunos*)
 728     echo 'main () { }' > conftest.c
 729     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 730     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 731       :
 732     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 733       :
 734     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 735       :
 736     elif test "${shared}" = "true"; then
 737       HLDFLAGS='-Wl,-rpath=$(libdir)'
 738     else
 739       HLDFLAGS='-Wl,-rpath='
 740     fi
 741     rm -f conftest.t conftest.c conftest
 742     ;;
 743 esac
 744 AC_SUBST(HLDFLAGS)
 745 AC_SUBST(HLDENV)
 746 AC_SUBST(RPATH_ENVVAR)
 747
 748 dnl This must come last.
 749 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)