gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 132       m680[012346]0)    cpu_type=m68k ;;
 133 changequote([,])dnl
 134       m68008)           cpu_type=m68k ;;
 135       m683??)           cpu_type=m68k ;;
 136       m5200)            cpu_type=m68k ;;
 137       m8*)              cpu_type=m88k ;;
 138       mips*el)          cpu_type=mips endian=little ;;
 139       mips*)            cpu_type=mips endian=big ;;
 140       pjl*)             cpu_type=pj endian=little ;;
 141       pj*)              cpu_type=pj endian=big ;;
 142       powerpcle*)       cpu_type=ppc endian=little ;;
 143       powerpc*)         cpu_type=ppc endian=big ;;
 144       rs6000*)          cpu_type=ppc ;;
 145       s390x*)           cpu_type=s390 arch=s390x ;;
 146       s390*)            cpu_type=s390 arch=s390 ;;
 147       sparclite*)       cpu_type=sparc arch=sparclite ;;
 148       sparclet*)        cpu_type=sparc arch=sparclet ;;
 149       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 150       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 151       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 152       v850*)            cpu_type=v850 ;;
 153       *)                cpu_type=${cpu} ;;
 154     esac
 155
 156     if test ${this_target} = $target ; then
 157       target_cpu_type=${cpu_type}
 158     elif test ${target_cpu_type} != ${cpu_type} ; then
 159       continue
 160     fi
 161
 162     generic_target=${cpu_type}-$vendor-$os
 163     dev=no
 164     bfd_gas=no
 165     em=generic
 166
 167     # assign object format
 168     case ${generic_target} in
 169       a29k-*-coff)          fmt=coff ;;
 170       a29k-amd-udi)         fmt=coff ;;
 171       a29k-amd-ebmon)       fmt=coff ;;
 172       a29k-nyu-sym1)        fmt=coff ;;
 173       a29k-*-rtems*)        fmt=coff ;;
 174       a29k-*-vxworks*)      fmt=coff ;;
 175
 176       alpha*-*-*vms*)       fmt=evax ;;
 177       alpha*-*-netware*)    fmt=ecoff ;;
 178       alpha*-*-openbsd*)    fmt=ecoff ;;
 179       alpha*-*-osf*)        fmt=ecoff ;;
 180       alpha*-*-linuxecoff*) fmt=ecoff ;;
 181       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 182       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 183
 184       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 185
 186       arm-*-aout)                       fmt=aout ;;
 187       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 188       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 189       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 190       arm*-*-conix*)                    fmt=elf ;;
 191       arm-*-linux*aout*)                fmt=aout em=linux ;;
 192       arm*-*-linux-gnu* | arm*-*-uclinux*)
 193                                         fmt=elf  em=linux ;;
 194       arm-*-netbsd*)                    fmt=aout em=nbsd ;;
 195       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 196       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 197       arm-*-wince)                      fmt=coff em=wince-pe ;;
 198       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 199       arm-*-riscix*)                    fmt=aout em=riscix ;;
 200
 201       avr-*-*)              fmt=elf bfd_gas=yes ;;
 202
 203       cris-*-*)             fmt=multi bfd_gas=yes ;;
 204
 205       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 206       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 207
 208
 209       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 210
 211       hppa-*-linux-gnu*)    case ${cpu} in
 212                                 hppa*64*)
 213                                         fmt=elf em=hppalinux64;;
 214                                 hppa*)
 215                                         fmt=elf em=linux;;
 216                             esac ;;
 217       hppa-*-*elf*)         fmt=elf em=hppa ;;
 218       hppa-*-lites*)        fmt=elf em=hppa ;;
 219       hppa-*-osf*)          fmt=som em=hppa ;;
 220       hppa-*-rtems*)        fmt=elf em=hppa ;;
 221       hppa-*-hpux11*)       case ${cpu} in
 222                                 hppa*64*)
 223                                         fmt=elf em=hppa64 ;;
 224                                 hppa*)
 225                                         fmt=som em=hppa ;;
 226                             esac ;;
 227       hppa-*-hpux*)         fmt=som em=hppa ;;
 228       hppa-*-mpeix*)        fmt=som em=hppa ;;
 229       hppa-*-bsd*)          fmt=som em=hppa ;;
 230       hppa-*-hiux*)         fmt=som em=hppa ;;
 231
 232       h8300-*-rtems*)       fmt=coff ;;
 233       h8300-*-coff)         fmt=coff ;;
 234       h8500-*-rtems*)       fmt=coff ;;
 235       h8500-*-coff)         fmt=coff ;;
 236
 237       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 238       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 239       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 240       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 241       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 242       i386-*-bsd*)          fmt=aout em=386bsd ;;
 243       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 244       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 245       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 246       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 247       i386-*-linux*coff*)   fmt=coff em=linux ;;
 248       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 249       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 250       i386-*-lynxos*)       fmt=coff em=lynx ;;
 251 changequote(,)dnl
 252       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 253                             fmt=elf bfd_gas=yes ;;
 254       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 255                             fmt=aout em=386bsd ;;
 256 changequote([,])dnl
 257       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 258                           fmt=coff ;;
 259       i386-*-sco3.2v5*)      fmt=elf
 260                             if test ${this_target} = $target; then
 261                                 AC_DEFINE(SCO_ELF, 1,
 262                                     [Define if defaulting to ELF on SCO 5.])
 263                             fi
 264                             ;;
 265       i386-*-sco3.2*)       fmt=coff ;;
 266       i386-*-vsta)          fmt=aout ;;
 267       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 268                             fmt=coff em=go32 bfd_gas=yes
 269                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 270                             ;;
 271       i386-*-rtemself*)     fmt=elf ;;
 272       i386-*-rtems*)        fmt=coff ;;
 273       i386-*-gnu*)          fmt=elf ;;
 274       i386-*-mach*)
 275                             fmt=aout em=mach bfd_gas=yes ;;
 276       i386-*-msdos*)        fmt=aout ;;
 277       i386-*-moss*)         fmt=elf ;;
 278       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 279       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 280       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 281       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 282       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 283       i386-*-vxworks*)      fmt=aout ;;
 284       i386-*-chaos)         fmt=elf ;;
 285       i860-stardent-sysv4* | i860-stardent-elf*)
 286                             fmt=elf bfd_gas=yes endian=little
 287                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 288       i960-*-bout)          fmt=bout ;;
 289       i960-*-coff)          fmt=coff em=ic960 ;;
 290       i960-*-rtems*)        fmt=coff em=ic960 ;;
 291       i960-*-nindy*)        fmt=bout ;;
 292       i960-*-vxworks4*)     fmt=bout ;;
 293       i960-*-vxworks5.0)    fmt=bout ;;
 294       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 295       i960-*-vxworks*)      fmt=bout ;;
 296       i960-*-elf*)          fmt=elf ;;
 297
 298       ia64-*-elf*)          fmt=elf ;;
 299       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 300       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 301       ia64-*-hpux*)         fmt=elf em=hpux ;;
 302
 303       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 304
 305       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 306
 307       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 308                             fmt=aout em=sun3 ;;
 309       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 310       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 311       m68k-apollo-*)        fmt=coff em=apollo ;;
 312       m68k-*-sysv4*) # must be before -sysv*
 313                             fmt=elf em=svr4 ;;
 314       m68k-*-elf*)          fmt=elf ;;
 315       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 316                             fmt=coff ;;
 317       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 318       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 319       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 320       m68k-*-gnu*)          fmt=elf ;;
 321       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 322       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 323       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 324       m68k-apple-aux*)      fmt=coff em=aux ;;
 325       m68k-*-psos*)         fmt=elf em=psos;;
 326
 327       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 328       m88k-*-coff*)         fmt=coff ;;
 329
 330       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 331       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 332
 333       # don't change em like *-*-bsd does
 334       mips-dec-netbsd*)     fmt=elf endian=little ;;
 335       mips-dec-openbsd*)    fmt=elf endian=little ;;
 336       mips-dec-bsd*)        fmt=aout endian=little ;;
 337       mips-sony-bsd*)       fmt=ecoff ;;
 338       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 339       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 340       mips-*-osf*)          fmt=ecoff endian=little ;;
 341       mips-*-ecoff*)        fmt=ecoff ;;
 342       mips-*-ecoff*)        fmt=ecoff ;;
 343       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 344       mips-*-irix6*)        fmt=elf ;;
 345       mips-*-irix5*)        fmt=elf ;;
 346       mips-*-irix*)         fmt=ecoff ;;
 347       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 348       mips-*-riscos*)       fmt=ecoff ;;
 349       mips-*-sysv4*MP* | mips-*-linux-gnu* | mips-*-gnu*)
 350                             fmt=elf em=tmips ;;
 351       mips-*-sysv*)         fmt=ecoff ;;
 352       mips-*-elf* | mips-*-rtems* | mips-*-openbsd*)
 353                             fmt=elf ;;
 354       mips-*-vxworks*)      fmt=elf
 355                             AC_DEFINE(MIPS_STABS_ELF, 1,
 356                                 [Use ELF stabs for MIPS, not ECOFF stabs])
 357                             ;;
 358       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 359       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 360       pj*)                  fmt=elf ;;
 361       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 362                             fmt=coff em=pe ;;
 363       ppc-*-aix*)           fmt=coff ;;
 364       ppc-*-beos*)          fmt=coff ;;
 365       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 366                             fmt=elf ;;
 367       ppc-*-linux-gnu*)     fmt=elf
 368                             case "$endian" in
 369                             big)  ;;
 370                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 371                             esac
 372                             ;;
 373       ppc-*-solaris*)       fmt=elf
 374                             if test ${this_target} = $target; then
 375                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 376                                 [Define if default target is PowerPC Solaris.])
 377                             fi
 378                             if test x${endian} = xbig; then
 379                                 AC_MSG_ERROR(Solaris must be configured little endian)
 380                             fi
 381                             ;;
 382       ppc-*-rtems*)         fmt=elf ;;
 383       ppc-*-macos* | ppc-*-mpw*)
 384                             fmt=coff em=macos ;;
 385       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 386       ppc-*-vxworks*)       fmt=elf ;;
 387
 388       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 389       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 390
 391       sh-*-linux*)          fmt=elf em=linux ;;
 392       sh-*-elf*)            fmt=elf ;;
 393       sh-*-coff*)           fmt=coff bfd_gas=yes;;
 394       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes;;
 395       sh-*-rtemself*)       fmt=elf ;;
 396       sh-*-rtems*)          fmt=coff bfd_gas=yes;;
 397
 398       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 399       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 400       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 401
 402       sparc-*-rtemsaout*)   fmt=aout ;;
 403       sparc-*-rtemself*)    fmt=elf ;;
 404       sparc-*-rtems*)       fmt=elf ;;
 405       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 406       sparc-*-aout | sparc*-*-vxworks*)
 407                             fmt=aout em=sparcaout ;;
 408       sparc-*-coff)         fmt=coff ;;
 409       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 410       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 411       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 412       sparc-fujitsu-none)   fmt=aout ;;
 413       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 414                             fmt=elf ;;
 415       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 416                             case ${cpu} in
 417                                 sparc) case ${os} in
 418                                            *elf*) fmt=elf ;;
 419                                            *)     fmt=aout ;;
 420                                        esac ;;
 421                                 sparc64) fmt=elf ;;
 422                             esac
 423                             ;;
 424       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 425
 426       strongarm-*-coff)     fmt=coff ;;
 427       strongarm-*-elf)      fmt=elf ;;
 428       xscale-*-coff)     fmt=coff ;;
 429       xscale-*-elf)      fmt=elf ;;
 430
 431       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 432       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 433       tic54x-*-* | c54x*-*-*)
 434                             fmt=coff bfd_gas=yes need_libm=yes;;
 435       tic80-*-*)            fmt=coff ;;
 436
 437       v850-*-*)             fmt=elf bfd_gas=yes ;;
 438       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 439       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 440
 441       vax-*-bsd* | vax-*-ultrix*)
 442                             fmt=aout ;;
 443       vax-*-vms)            fmt=vms ;;
 444
 445
 446       z8k-*-coff | z8k-*-sim)
 447                             fmt=coff ;;
 448
 449       w65-*-*)              fmt=coff ;;
 450
 451       *-*-aout | *-*-scout)
 452                             fmt=aout ;;
 453       *-*-freebsd*)         fmt=elf bfd_gas=yes ;;
 454       *-*-nindy*)
 455                             fmt=bout ;;
 456       *-*-bsd*)
 457                             fmt=aout em=sun3 ;;
 458       *-*-generic)          fmt=generic ;;
 459       *-*-xray | *-*-hms)   fmt=coff ;;
 460       *-*-sim)              fmt=coff ;;
 461       *-*-elf | *-*-sysv4* | *-*-solaris*)
 462                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 463                             fmt=elf dev=yes ;;
 464       *-*-vxworks)          fmt=aout ;;
 465       *-*-netware)          fmt=elf ;;
 466     esac
 467
 468     if test ${this_target} = $target ; then
 469       endian_def=
 470       if test x${endian} = xbig; then
 471         endian_def=1
 472       elif test x${endian} = xlittle; then
 473         endian_def=0
 474       fi
 475       if test x${endian_def} != x; then
 476         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 477                            [Define as 1 if big endian.])
 478       fi
 479     fi
 480
 481     case ${cpu_type}-${fmt} in
 482       alpha*-*) bfd_gas=yes ;;
 483       arm-*)    bfd_gas=yes ;;
 484     # not yet
 485     # i386-aout)        bfd_gas=preferred ;;
 486       ia64*-*)  bfd_gas=yes ;;
 487       mips-*)   bfd_gas=yes ;;
 488       ns32k-*)  bfd_gas=yes ;;
 489       pdp11-*)  bfd_gas=yes ;;
 490       ppc-*)    bfd_gas=yes ;;
 491       sparc-*)  bfd_gas=yes ;;
 492       strongarm-*)      bfd_gas=yes ;;
 493       xscale-*) bfd_gas=yes ;;
 494       *-elf)    bfd_gas=yes ;;
 495       *-ecoff)  bfd_gas=yes ;;
 496       *-som)    bfd_gas=yes ;;
 497     #enable bfd for coff and aout to allow testing if a bfd target is
 498     #the primary target, but not for coff or aout as the primary target
 499       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 500       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 501       *)                ;;
 502     esac
 503
 504 # Other random stuff.
 505
 506     # Do we need the opcodes library?
 507     case ${cpu_type} in
 508       vax | i386 | tic30)
 509         ;;
 510
 511       *)
 512         need_opcodes=yes
 513
 514         case "${enable_shared}" in
 515         yes) shared_opcodes=true ;;
 516         *opcodes*) shared_opcodes=true ;;
 517         *) shared_opcodes=false ;;
 518         esac
 519         if test "${shared_opcodes}" = "true"; then
 520           # A shared libopcodes must be linked against libbfd.
 521           need_bfd=yes
 522         fi
 523         ;;
 524     esac
 525
 526     # Any other special object files needed ?
 527     case ${cpu_type} in
 528       fr30 | m32r)
 529         using_cgen=yes
 530         ;;
 531
 532       m68k)
 533         case ${extra_objects} in
 534         *m68k-parse.o*) ;;
 535         *) extra_objects="$extra_objects m68k-parse.o" ;;
 536         esac
 537         ;;
 538
 539       s390)
 540        if test $this_target = $target ; then
 541           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 542        fi
 543        ;;
 544
 545       mips)
 546         echo ${extra_objects} | grep -s "itbl-parse.o"
 547         if test $? -ne 0 ; then
 548           extra_objects="$extra_objects itbl-parse.o"
 549         fi
 550
 551         echo ${extra_objects} | grep -s "itbl-lex.o"
 552         if test $? -ne 0 ; then
 553           extra_objects="$extra_objects itbl-lex.o"
 554         fi
 555
 556         echo ${extra_objects} | grep -s "itbl-ops.o"
 557         if test $? -ne 0 ; then
 558           extra_objects="$extra_objects itbl-ops.o"
 559         fi
 560         ;;
 561
 562       i386)
 563         if test $this_target = $target ; then
 564           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 565         fi
 566         ;;
 567       sparc)
 568         if test $this_target = $target ; then
 569           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 570         fi
 571         ;;
 572       *)
 573         ;;
 574     esac
 575
 576     if test $using_cgen = yes ; then
 577         case "x${extra_objects}" in
 578         *cgen.o*) ;;
 579         *) extra_objects="$extra_objects cgen.o" ;;
 580         esac
 581     fi
 582
 583 # See if we really can support this configuration with the emulation code.
 584
 585     if test $this_target = $target ; then
 586       primary_bfd_gas=$bfd_gas
 587       obj_format=$fmt
 588       te_file=$em
 589
 590       if test $bfd_gas = no ; then
 591         # Can't support other configurations this way.
 592         break
 593       fi
 594     elif test $bfd_gas = no ; then
 595       # Can't support this configuration.
 596       break
 597     fi
 598
 599 # From target name and format, produce a list of supported emulations.
 600
 601     case ${generic_target}-${fmt} in
 602       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 603       mips-*-linux-gnu*-*) case "$endian" in
 604                         big)    emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 605                         *)      emulation="mipslelf mipsbelf mipself mipslecoff mipsbecoff mipsecoff" ;;
 606                         esac ;;
 607       mips-*-lnews*-ecoff) ;;
 608       mips-*-*-ecoff)   case "$endian" in
 609                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 610                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 611                         esac ;;
 612       mips-*-*-elf)     case "$endian" in
 613                         big)    emulation="mipsbelf mipslelf mipself" ;;
 614                         *)      emulation="mipslelf mipsbelf mipself" ;;
 615                         esac ;;
 616       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 617       # i386-pc-pe-coff != i386-pc-coff.
 618       i386-*-pe-coff)   ;;
 619       # Uncommenting the next line will turn on support for i386 AOUT
 620       # for the default linux configuration
 621       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 622       #
 623       i386-*-aout)      emulation="i386aout" ;;
 624       i386-*-coff)      emulation="i386coff" ;;
 625       i386-*-elf)       emulation="i386elf" ;;
 626
 627       # Always all formats.  The first stated emulation becomes the default.
 628       cris-*-*aout*)    emulation="crisaout criself" ;;
 629       cris-*-*)         emulation="criself crisaout" ;;
 630     esac
 631
 632     emulations="$emulations $emulation"
 633
 634 done
 635
 636 # Turn on all targets if possible
 637 if test ${all_targets} = "yes"; then
 638   case ${target_cpu_type} in
 639   i386)
 640     case ${obj_format} in
 641     aout)
 642       emulations="$emulations i386coff i386elf"
 643       ;;
 644     coff)
 645       emulations="$emulations i386aout i386elf"
 646     ;;
 647     elf)
 648       emulations="$emulations i386aout i386coff"
 649       ;;
 650     esac
 651   ;;
 652   esac
 653 fi
 654
 655 # Assign floating point type.  Most processors with FP support
 656 # IEEE FP.  On those that don't support FP at all, usually IEEE
 657 # is emulated.
 658 case ${target_cpu} in
 659   vax | tahoe ) atof=${target_cpu} ;;
 660   pdp11)        atof=vax ;;
 661   *)            atof=ieee ;;
 662 esac
 663
 664 case "${obj_format}" in
 665   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 666 esac
 667
 668 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 669 cgen_cpu_prefix=""
 670 if test $using_cgen = yes ; then
 671   case ${target_cpu} in
 672     *) cgen_cpu_prefix=${target_cpu} ;;
 673   esac
 674   AC_SUBST(cgen_cpu_prefix)
 675   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 676 fi
 677
 678 dnl
 679 dnl Make sure the desired support files exist.
 680 dnl
 681
 682 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 683   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 684 fi
 685
 686 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 687   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 688 fi
 689
 690 case ${user_bfd_gas}-${primary_bfd_gas} in
 691   yes-yes | no-no)
 692     # We didn't override user's choice.
 693     ;;
 694   no-yes)
 695     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 696     ;;
 697   no-preferred)
 698     primary_bfd_gas=no
 699     ;;
 700   *-preferred)
 701     primary_bfd_gas=yes
 702     ;;
 703   yes-*)
 704     primary_bfd_gas=yes
 705     ;;
 706   -*)
 707     # User specified nothing.
 708     ;;
 709 esac
 710
 711 # Some COFF configurations want these random other flags set.
 712 case ${obj_format} in
 713   coff)
 714     case ${target_cpu_type} in
 715       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 716       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 717       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 718     esac
 719     ;;
 720 esac
 721
 722 # Getting this done right is going to be a bitch.  Each configuration specified
 723 # with --enable-targets=... should be checked for environment, format, cpu, and
 724 # bfd_gas setting.
 725 #
 726 # For each configuration, the necessary object file support code must be linked
 727 # in.  This might be only one, it might be up to four.  The necessary emulation
 728 # code needs to be provided, too.
 729 #
 730 # And then there's "--enable-targets=all"....
 731 #
 732 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 733
 734 formats="${obj_format}"
 735 emfiles=""
 736 EMULATIONS=""
 737 GAS_UNIQ(emulations)
 738 for em in . $emulations ; do
 739   case $em in
 740     .)  continue ;;
 741     mipsbelf | mipslelf | mipself)
 742         fmt=elf   file=mipself ;;
 743     mipsbecoff | mipslecoff | mipsecoff)
 744         fmt=ecoff file=mipsecoff ;;
 745     *coff)
 746         fmt=coff  file=$em ;;
 747     *aout)
 748         fmt=aout file=$em ;;
 749     *elf)
 750         fmt=elf file=$em ;;
 751   esac
 752   formats="$formats $fmt"
 753   emfiles="$emfiles e-$file.o"
 754   EMULATIONS="$EMULATIONS &$em,"
 755 done
 756 GAS_UNIQ(formats)
 757 GAS_UNIQ(emfiles)
 758 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 759   for fmt in $formats ; do
 760     case $fmt in
 761       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 762       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 763       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 764       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 765       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 766       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 767       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 768       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 769       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 770       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 771     esac
 772     extra_objects="$extra_objects obj-$fmt.o"
 773   done
 774   obj_format=multi
 775 fi
 776 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 777   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 778   # e-mips* has more than one emulation per file, e-i386* has just one at the
 779   # moment.  If only one emulation is specified, then don't define
 780   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 781   case "${obj_format}${emfiles}" in
 782     multi* | *mips*)
 783       extra_objects="$extra_objects $emfiles"
 784       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 785   esac
 786 fi
 787 AC_SUBST(extra_objects)
 788 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 789 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 790                    [Default emulation.])
 791
 792 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 793   yes-*-coff)   need_bfd=yes ;;
 794   no-*-coff)    need_bfd=yes
 795                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 796 esac
 797
 798 reject_dev_configs=yes
 799
 800 case ${reject_dev_configs}-${dev} in
 801   yes-yes) # Oops.
 802     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 803     ;;
 804 esac
 805
 806 AC_SUBST(target_cpu_type)
 807 AC_SUBST(obj_format)
 808 AC_SUBST(te_file)
 809 AC_SUBST(install_tooldir)
 810 AC_SUBST(atof)
 811 dnl AC_SUBST(emulation)
 812
 813 case "${primary_bfd_gas}" in
 814   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 815         need_bfd=yes ;;
 816 esac
 817
 818 # do we need the opcodes library?
 819 case "${need_opcodes}" in
 820 yes)
 821   OPCODES_LIB=../opcodes/libopcodes.la
 822   ;;
 823 esac
 824
 825 case "${need_bfd}" in
 826 yes)
 827   BFDLIB=../bfd/libbfd.la
 828   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 829   ;;
 830 esac
 831
 832 AC_SUBST(BFDLIB)
 833 AC_SUBST(OPCODES_LIB)
 834
 835 AC_SUBST(ALL_OBJ_DEPS)
 836
 837 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 838 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 839 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 840 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 841 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 842
 843 AC_PROG_CC
 844
 845 AC_PROG_YACC
 846 AM_PROG_LEX
 847
 848 ALL_LINGUAS=
 849 CY_GNU_GETTEXT
 850
 851 AM_MAINTAINER_MODE
 852 AC_EXEEXT
 853
 854 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 855
 856 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 857 # people who are not cross-compiling but are compiling cross-assemblers.
 858 AC_MSG_CHECKING(whether compiling a cross-assembler)
 859 if test "${host}" = "${target}"; then
 860   cross_gas=no
 861 else
 862   cross_gas=yes
 863   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 864 fi
 865 AC_MSG_RESULT($cross_gas)
 866
 867 dnl ansidecl.h will deal with const
 868 dnl AC_CONST
 869 AC_FUNC_ALLOCA
 870 AC_C_INLINE
 871
 872 # VMS doesn't have unlink.
 873 AC_CHECK_FUNCS(unlink remove, break)
 874
 875 # Some systems don't have sbrk().
 876 AC_CHECK_FUNCS(sbrk)
 877
 878 # do we need the math library?
 879 case "${need_libm}" in
 880 yes)
 881   AC_CHECK_LIBM
 882   AC_SUBST(LIBM)
 883   ;;
 884 esac
 885
 886 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 887 # enough, but on some of those systems, the assert macro relies on requoting
 888 # working properly!
 889 GAS_WORKING_ASSERT
 890
 891 # On some systems, the system header files may not declare malloc, realloc,
 892 # and free.  There are places where gas needs these functions to have been
 893 # declared -- such as when taking their addresses.
 894 gas_test_headers="
 895 #ifdef HAVE_MEMORY_H
 896 #include <memory.h>
 897 #endif
 898 #ifdef HAVE_STRING_H
 899 #include <string.h>
 900 #else
 901 #ifdef HAVE_STRINGS_H
 902 #include <strings.h>
 903 #endif
 904 #endif
 905 #ifdef HAVE_STDLIB_H
 906 #include <stdlib.h>
 907 #endif
 908 #ifdef HAVE_UNISTD_H
 909 #include <unistd.h>
 910 #endif
 911 "
 912 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 913 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 914 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 915 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 916 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 917
 918 # Does errno.h declare errno, or do we have to add a separate declaration
 919 # for it?
 920 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 921 #ifdef HAVE_ERRNO_H
 922 #include <errno.h>
 923 #endif
 924 ])
 925
 926 dnl This must come last.
 927
 928 dnl We used to make symlinks to files in the source directory, but now
 929 dnl we just use the right name for .c files, and create .h files in
 930 dnl the build directory which include the right .h file.  Make sure
 931 dnl the old symlinks don't exist, so that a reconfigure in an existing
 932 dnl directory behaves reasonably.
 933
 934 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 935 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 936  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 937  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 938  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 939  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 940  if test "x$cgen_cpu_prefix" != x ; then
 941    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 942  fi
 943
 944  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 945 [target_cpu_type=${target_cpu_type}
 946  cgen_cpu_prefix=${cgen_cpu_prefix}
 947  obj_format=${obj_format}
 948  te_file=${te_file}])