gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # check for architecture variants
 122     arch=
 123     endian=
 124     case ${cpu} in
 125       am33_2.0)         cpu_type=mn10300 endian=little ;;
 126       alpha*)           cpu_type=alpha ;;
 127       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 128       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 129       c4x*)             cpu_type=tic4x ;;
 130       hppa*)            cpu_type=hppa ;;
 131 changequote(,)dnl
 132       i[3-7]86)         cpu_type=i386 arch=i386;;
 133       x86_64)           cpu_type=i386 arch=x86_64;;
 134       ia64)             cpu_type=ia64 ;;
 135       ip2k)             cpu_type=ip2k endian=big ;;
 136       iq2000)           cpu_type=iq2000 endian=big ;;
 137       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 138       m680[012346]0)    cpu_type=m68k ;;
 139 changequote([,])dnl
 140       m68008)           cpu_type=m68k ;;
 141       m683??)           cpu_type=m68k ;;
 142       m5200)            cpu_type=m68k ;;
 143       m8*)              cpu_type=m88k ;;
 144       mips*el)          cpu_type=mips endian=little ;;
 145       mips*)            cpu_type=mips endian=big ;;
 146       or32*)            cpu_type=or32 endian=big ;;
 147       pjl*)             cpu_type=pj endian=little ;;
 148       pj*)              cpu_type=pj endian=big ;;
 149       powerpc*le*)      cpu_type=ppc endian=little ;;
 150       powerpc*)         cpu_type=ppc endian=big ;;
 151       rs6000*)          cpu_type=ppc ;;
 152       s390x*)           cpu_type=s390 arch=s390x ;;
 153       s390*)            cpu_type=s390 arch=s390 ;;
 154       sh5*)             cpu_type=sh64 endian=big ;;
 155       sh5le*)           cpu_type=sh64 endian=little ;;
 156       sh64*)            cpu_type=sh64 endian=big ;;
 157       sh64le*)          cpu_type=sh64 endian=little ;;
 158       sh*le)            cpu_type=sh endian=little ;;
 159       sh*)              cpu_type=sh endian=big ;;
 160       sparclite*)       cpu_type=sparc arch=sparclite ;;
 161       sparclet*)        cpu_type=sparc arch=sparclet ;;
 162       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 163       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 164       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 165       v850*)            cpu_type=v850 ;;
 166       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 167       *)                cpu_type=${cpu} ;;
 168     esac
 169
 170     if test ${this_target} = $target ; then
 171       target_cpu_type=${cpu_type}
 172     elif test ${target_cpu_type} != ${cpu_type} ; then
 173       continue
 174     fi
 175
 176     generic_target=${cpu_type}-$vendor-$os
 177     dev=no
 178     bfd_gas=no
 179     em=generic
 180
 181     # assign object format
 182     case ${generic_target} in
 183       a29k-*-coff)                      fmt=coff ;;
 184       a29k-amd-udi)                     fmt=coff ;;
 185       a29k-amd-ebmon)                   fmt=coff ;;
 186       a29k-nyu-sym1)                    fmt=coff ;;
 187       a29k-*-rtems*)                    fmt=coff ;;
 188       a29k-*-vxworks*)                  fmt=coff ;;
 189
 190       alpha*-*-*vms*)                   fmt=evax ;;
 191       alpha*-*-netware*)                fmt=ecoff ;;
 192       alpha*-*-osf*)                    fmt=ecoff ;;
 193       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 194       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 195       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 196       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 197
 198       # cpu_type for am33_2.0 is set to mn10300
 199       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 200
 201       arc-*-elf*)                       fmt=elf ;;
 202
 203       arm-*-aout)                       fmt=aout ;;
 204       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 205       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 206       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 207       arm-*-kaos*)                      fmt=elf ;;
 208       arm*-*-conix*)                    fmt=elf ;;
 209       arm-*-linux*aout*)                fmt=aout em=linux ;;
 210       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 211       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 212       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 213       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 214       arm-**-nto*)                      fmt=elf ;;
 215       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 216       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 217       arm-*-wince)                      fmt=coff em=wince-pe ;;
 218       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 219       arm-*-riscix*)                    fmt=aout em=riscix ;;
 220       arm-*-vxworks)                    fmt=coff ;;
 221
 222       avr-*-*)                          fmt=elf ;;
 223
 224       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 225       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 226
 227       d10v-*-*)                         fmt=elf ;;
 228       d30v-*-*)                         fmt=elf ;;
 229       dlx-*-*)                          fmt=elf ;;
 230
 231       fr30-*-*)                         fmt=elf ;;
 232       frv-*-*)                          fmt=elf ;;
 233
 234       hppa-*-linux*)    case ${cpu} in
 235                             hppa*64*)   fmt=elf em=hppalinux64;;
 236                             hppa*)      fmt=elf em=linux;;
 237                         esac ;;
 238       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 239       hppa-*-lites*)                    fmt=elf em=hppa ;;
 240       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 241       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 242       hppa-*-osf*)                      fmt=som em=hppa ;;
 243       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 244       hppa-*-hpux11*)   case ${cpu} in
 245                             hppa*64*)   fmt=elf em=hppa64 ;;
 246                             hppa*)      fmt=som em=hppa ;;
 247                         esac ;;
 248       hppa-*-hpux*)                     fmt=som em=hppa ;;
 249       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 250       hppa-*-bsd*)                      fmt=som em=hppa ;;
 251       hppa-*-hiux*)                     fmt=som em=hppa ;;
 252
 253       h8300-*-rtems*)                   fmt=coff ;;
 254       h8300-*-coff)                     fmt=coff ;;
 255       h8300-*-elf)                      fmt=elf ;;
 256       h8500-*-rtems*)                   fmt=coff ;;
 257       h8500-*-coff)                     fmt=coff ;;
 258
 259       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 260       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 261       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 262       i386-*-beospe*)                   fmt=coff em=pe ;;
 263       i386-*-beos*)                     fmt=elf ;;
 264       i386-*-coff)                      fmt=coff ;;
 265       i386-*-elf)                       fmt=elf ;;
 266       i386-*-kaos*)                     fmt=elf ;;
 267       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 268       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 269       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 270       i386-*-netbsd*-gnu* | \
 271       i386-*-knetbsd*-gnu | \
 272       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 273       i386-*-*n*bsd*)   case ${cpu} in
 274                             x86_64)     fmt=elf em=nbsd ;;
 275                             *)          fmt=aout em=nbsd ;;
 276                         esac ;;
 277       i386-*-linux*aout*)               fmt=aout em=linux ;;
 278       i386-*-linux*oldld)               fmt=aout em=linux ;;
 279       i386-*-linux*coff*)               fmt=coff em=linux ;;
 280       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 281       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 282       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 283 changequote(,)dnl
 284       i386-*-sysv[45]*)                 fmt=elf ;;
 285       i386-*-solaris*)                  fmt=elf ;;
 286       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 287       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 288       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 289 changequote([,])dnl
 290       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 291                                         fmt=elf em=freebsd ;;
 292       i386-*-sysv*)                     fmt=coff ;;
 293       i386-*-sco3.2v5*coff)             fmt=coff ;;
 294       i386-*-isc*)                      fmt=coff ;;
 295       i386-*-sco3.2v5*)                 fmt=elf
 296           if test ${this_target} = $target; then
 297             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 298           fi ;;
 299       i386-*-sco3.2*)                   fmt=coff ;;
 300       i386-*-vsta)                      fmt=aout ;;
 301       i386-*-msdosdjgpp* \
 302       | i386-*-go32* \
 303       | i386-go32-rtems*)               fmt=coff em=go32
 304             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 305       i386-*-rtemself*)                 fmt=elf ;;
 306       i386-*-rtemscoff*)                fmt=coff ;;
 307       i386-*-rtems*)                    fmt=elf ;;
 308       i386-*-gnu*)                      fmt=elf ;;
 309       i386-*-mach*)                     fmt=aout em=mach ;;
 310       i386-*-msdos*)                    fmt=aout ;;
 311       i386-*-moss*)                     fmt=elf ;;
 312       i386-*-pe)                        fmt=coff em=pe ;;
 313       i386-*-cygwin*)                   fmt=coff em=pe ;;
 314       i386-*-interix*)                  fmt=coff em=interix ;;
 315       i386-*-mingw32*)                  fmt=coff em=pe ;;
 316       i386-*-nto-qnx*)                  fmt=elf ;;
 317       i386-*-*nt*)                      fmt=coff em=pe ;;
 318       i386-*-vxworks*)                  fmt=aout ;;
 319       i386-*-chaos)                     fmt=elf ;;
 320
 321       i860-*-*)                         fmt=elf endian=little
 322                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 323       i960-*-bout)                      fmt=bout ;;
 324       i960-*-coff)                      fmt=coff em=ic960 ;;
 325       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 326       i960-*-nindy*)                    fmt=bout ;;
 327       i960-*-vxworks5.0)                fmt=bout ;;
 328       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 329       i960-*-vxworks*)                  fmt=bout ;;
 330       i960-*-elf*)                      fmt=elf ;;
 331
 332       ia64-*-elf*)                      fmt=elf ;;
 333       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 334       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 335       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 336       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 337
 338       ip2k-*-*)                         fmt=elf ;;
 339
 340       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 341
 342       m32r-*-*)                         fmt=elf ;;
 343
 344       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 345       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 346
 347       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 348       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 349       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 350       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 351       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 352       m68k-apollo-*)                    fmt=coff em=apollo ;;
 353       m68k-*-elf*)                      fmt=elf ;;
 354       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 355       m68k-*-sysv*)                     fmt=coff ;;
 356       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 357       m68k-*-rtems*)                    fmt=elf ;;
 358       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 359       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 360       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 361       m68k-*-gnu*)                      fmt=elf ;;
 362       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 363       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 364       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 365       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 366       m68k-apple-aux*)                  fmt=coff em=aux ;;
 367       m68k-*-psos*)                     fmt=elf em=psos;;
 368
 369       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 370       m88k-*-coff*)                     fmt=coff ;;
 371
 372       mcore-*-elf)                      fmt=elf ;;
 373       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 374
 375       # don't change em like *-*-bsd does
 376       mips-dec-openbsd*)                fmt=elf endian=little ;;
 377       mips-dec-bsd*)                    fmt=aout endian=little ;;
 378       mips-sony-bsd*)                   fmt=ecoff ;;
 379       mips-*-bsd*)
 380             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 381       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 382       mips-*-osf*)                      fmt=ecoff endian=little ;;
 383       mips-*-ecoff*)                    fmt=ecoff ;;
 384       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 385       mips-*-irix6*)                    fmt=elf em=irix ;;
 386       mips-*-irix5*)                    fmt=elf em=irix ;;
 387       mips-*-irix*)                     fmt=ecoff em=irix ;;
 388       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 389       mips-*-riscos*)                   fmt=ecoff ;;
 390       mips*-*-linux*)                   fmt=elf em=tmips ;;
 391       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 392       mips-*-sysv*)                     fmt=ecoff ;;
 393       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 394       mips-*-netbsd*)                   fmt=elf ;;
 395       mips-*-openbsd*)                  fmt=elf ;;
 396       mips-*-vxworks*)                  fmt=elf ;;
 397
 398       mmix-*-*)                         fmt=elf ;;
 399       mn10200-*-*)                      fmt=elf ;;
 400       mn10300-*-*)                      fmt=elf ;;
 401       msp430-*-*)                       fmt=elf ;;
 402       openrisc-*-*)                     fmt=elf ;;
 403       or32-*-rtems*)                    fmt=coff ;;
 404       or32-*-coff)                      fmt=coff ;;
 405       or32-*-elf)                       fmt=elf ;;
 406       pj*)                              fmt=elf ;;
 407
 408       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 409       ppc-*-winnt*)                     fmt=coff em=pe ;;
 410       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 411       ppc-*-aix*)                       fmt=coff ;;
 412       ppc-*-beos*)                      fmt=coff ;;
 413       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 414       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 415       ppc-*-linux-gnu*)                 fmt=elf em=linux
 416             case "$endian" in
 417                 big)  ;;
 418                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 419             esac ;;
 420       ppc-*-solaris*)                   fmt=elf
 421             if test ${this_target} = $target; then
 422                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 423                           [Define if default target is PowerPC Solaris.])
 424             fi
 425             if test x${endian} = xbig; then
 426                 AC_MSG_ERROR(Solaris must be configured little endian)
 427             fi ;;
 428       ppc-*-rtems*)                     fmt=elf ;;
 429       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 430       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 431       ppc-**-nto*)                      fmt=elf ;;
 432       ppc-*-vxworks*)                   fmt=elf ;;
 433       ppc-*-windiss*)                   fmt=elf ;;
 434       ppc-*-kaos*)                      fmt=elf ;;
 435
 436       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 437       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 438
 439       sh*-*-linux*)                     fmt=elf em=linux
 440             case ${cpu} in
 441                 sh*eb)  endian=big ;;
 442                 *)      endian=little ;;
 443             esac ;;
 444       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 445       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 446       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 447       sh-*-elf*)                        fmt=elf ;;
 448       sh-*-coff*)                       fmt=coff ;;
 449       sh-*-nto*)                        fmt=elf ;;
 450       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 451       sh-*-rtemself*)                   fmt=elf ;;
 452       sh-*-rtems*)                      fmt=coff ;;
 453       sh-*-kaos*)                       fmt=elf ;;
 454       shle*-*-kaos*)                    fmt=elf ;;
 455       sh64-*-elf*)                      fmt=elf ;;
 456
 457       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 458       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 459       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 460       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 461
 462       sparc-*-rtemsaout*)               fmt=aout ;;
 463       sparc-*-rtemself*)                fmt=elf ;;
 464       sparc-*-rtems*)                   fmt=elf ;;
 465       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 466       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 467       sparc-*-coff)                     fmt=coff ;;
 468       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 469       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 470       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 471       sparc-fujitsu-none)               fmt=aout ;;
 472       sparc-*-elf)                      fmt=elf ;;
 473       sparc-*-sysv4*)                   fmt=elf ;;
 474       sparc-*-solaris*)                 fmt=elf ;;
 475       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 476       sparc-*-*n*bsd*)  case ${cpu} in
 477                             sparc64)    fmt=elf em=nbsd ;;
 478                             *)          fmt=aout em=nbsd ;;
 479                         esac ;;
 480       strongarm-*-coff)                 fmt=coff ;;
 481       strongarm-*-elf)                  fmt=elf ;;
 482       strongarm-*-kaos*)                fmt=elf ;;
 483       xscale-*-coff)                    fmt=coff ;;
 484       xscale-*-elf)                     fmt=elf ;;
 485
 486       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 487       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 488       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 489       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 490       tic80-*-*)                        fmt=coff ;;
 491
 492       v850-*-*)                         fmt=elf ;;
 493       v850e-*-*)                        fmt=elf ;;
 494       v850ea-*-*)                       fmt=elf ;;
 495
 496       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 497       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 498       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 499       vax-*-vms)                        fmt=vms ;;
 500
 501       w65-*-*)                          fmt=coff ;;
 502
 503       xstormy16-*-*)                    fmt=elf ;;
 504
 505       xtensa-*-*)                       fmt=elf ;;
 506
 507       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 508
 509       *-*-aout | *-*-scout)             fmt=aout ;;
 510       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 511       *-*-nindy*)                       fmt=bout ;;
 512       *-*-bsd*)                         fmt=aout em=sun3 ;;
 513       *-*-generic)                      fmt=generic ;;
 514       *-*-xray | *-*-hms)               fmt=coff ;;
 515       *-*-sim)                          fmt=coff ;;
 516       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 517       *-*-aros*)                                fmt=elf em=linux bfd_gas=yes ;;
 518       *-*-vxworks)                      fmt=aout ;;
 519       *-*-netware)                      fmt=elf ;;
 520     esac
 521
 522     if test ${this_target} = $target ; then
 523       endian_def=
 524       if test x${endian} = xbig; then
 525         endian_def=1
 526       elif test x${endian} = xlittle; then
 527         endian_def=0
 528       fi
 529       if test x${endian_def} != x; then
 530         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 531                            [Define as 1 if big endian.])
 532       fi
 533     fi
 534
 535     case ${cpu_type}-${fmt} in
 536         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 537                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 538                 | *-elf | *-ecoff | *-som)
 539             bfd_gas=yes ;;
 540     esac
 541
 542 # Other random stuff.
 543
 544     case ${cpu_type} in
 545       mips)
 546         # Set mips_cpu to the name of the default CPU.
 547         case ${target_cpu} in
 548           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 549             mips_cpu=from-abi
 550             ;;
 551           mipsisa32 | mipsisa32el)
 552             mips_cpu=mips32
 553             ;;
 554           mipsisa32r2 | mipsisa32r2el)
 555             mips_cpu=mips32r2
 556             ;;
 557           mipsisa64 | mipsisa64el)
 558             mips_cpu=mips64
 559             ;;
 560           mipsisa64r2 | mipsisa64r2el)
 561             mips_cpu=mips64r2
 562             ;;
 563           mipstx39 | mipstx39el)
 564             mips_cpu=r3900
 565             ;;
 566           mips64vr | mips64vrel)
 567             mips_cpu=vr4100
 568             ;;
 569           mipsisa32r2* | mipsisa64r2*)
 570 changequote(,)dnl
 571             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 572 changequote([,])dnl
 573             ;;
 574           mips64* | mipsisa64* | mipsisa32*)
 575 changequote(,)dnl
 576             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 577 changequote([,])dnl
 578             ;;
 579           *)
 580             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 581             ;;
 582         esac
 583         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 584         # binaries.  It's a GNU extension that some OSes don't understand.
 585         # The value only matters on ELF targets.
 586         case ${target} in
 587           *-*-irix*)
 588             use_e_mips_abi_o32=0
 589             ;;
 590           *)
 591             use_e_mips_abi_o32=1
 592             ;;
 593         esac
 594         # Decide whether to generate 32-bit or 64-bit code by default.
 595         # Used to resolve -march=from-abi when an embedded ABI is selected.
 596         case ${target} in
 597           mips64*-*-* | mipsisa64*-*-*)
 598             mips_default_64bit=1
 599             ;;
 600           *)
 601             mips_default_64bit=0
 602             ;;
 603         esac
 604         # Decide which ABI to target by default.
 605         case ${target} in
 606           mips64*-linux* | mips-sgi-irix6*)
 607             mips_default_abi=N32_ABI
 608             ;;
 609           mips*-linux*)
 610             mips_default_abi=O32_ABI
 611             ;;
 612           *)
 613             mips_default_abi=NO_ABI
 614             ;;
 615         esac
 616         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 617                            [Default CPU for MIPS targets. ])
 618         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 619                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 620         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 621                            [Generate 64-bit code by default on MIPS targets. ])
 622         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 623                            [Choose a default ABI for MIPS targets. ])
 624         ;;
 625     esac
 626
 627     # Do we need the opcodes library?
 628     case ${cpu_type} in
 629       vax | i386 | tic30)
 630         ;;
 631
 632       *)
 633         need_opcodes=yes
 634
 635         case "${enable_shared}" in
 636         yes) shared_opcodes=true ;;
 637         *opcodes*) shared_opcodes=true ;;
 638         *) shared_opcodes=false ;;
 639         esac
 640         if test "${shared_opcodes}" = "true"; then
 641           # A shared libopcodes must be linked against libbfd.
 642           need_bfd=yes
 643         fi
 644         ;;
 645     esac
 646
 647     # Any other special object files needed ?
 648     case ${cpu_type} in
 649       fr30 | ip2k | iq2000 | m32r | openrisc)
 650         using_cgen=yes
 651         ;;
 652
 653       frv)
 654         using_cgen=yes
 655         ;;
 656       m68k)
 657         case ${extra_objects} in
 658         *m68k-parse.o*) ;;
 659         *) extra_objects="$extra_objects m68k-parse.o" ;;
 660         esac
 661         ;;
 662
 663       mips)
 664         echo ${extra_objects} | grep -s "itbl-parse.o"
 665         if test $? -ne 0 ; then
 666           extra_objects="$extra_objects itbl-parse.o"
 667         fi
 668
 669         echo ${extra_objects} | grep -s "itbl-lex.o"
 670         if test $? -ne 0 ; then
 671           extra_objects="$extra_objects itbl-lex.o"
 672         fi
 673
 674         echo ${extra_objects} | grep -s "itbl-ops.o"
 675         if test $? -ne 0 ; then
 676           extra_objects="$extra_objects itbl-ops.o"
 677         fi
 678         ;;
 679
 680       i386 | s390 | sparc)
 681         if test $this_target = $target ; then
 682           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 683         fi
 684         ;;
 685
 686       xstormy16)
 687         using_cgen=yes
 688         ;;
 689
 690       xtensa)
 691         echo ${extra_objects} | grep -s "xtensa-relax.o"
 692         if test $? -ne 0 ; then
 693           extra_objects="$extra_objects xtensa-relax.o"
 694         fi
 695         ;;
 696
 697       *)
 698         ;;
 699     esac
 700
 701     if test $using_cgen = yes ; then
 702         case "x${extra_objects}" in
 703         *cgen.o*) ;;
 704         *) extra_objects="$extra_objects cgen.o" ;;
 705         esac
 706     fi
 707
 708 # See if we really can support this configuration with the emulation code.
 709
 710     if test $this_target = $target ; then
 711       primary_bfd_gas=$bfd_gas
 712       obj_format=$fmt
 713       te_file=$em
 714
 715       if test $bfd_gas = no ; then
 716         # Can't support other configurations this way.
 717         break
 718       fi
 719     elif test $bfd_gas = no ; then
 720       # Can't support this configuration.
 721       break
 722     fi
 723
 724 # From target name and format, produce a list of supported emulations.
 725
 726     case ${generic_target}-${fmt} in
 727       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 728       mips*-*-linux*-*) case "$endian" in
 729                         big)    emulation="mipsbelf mipslelf mipself" ;;
 730                         *)      emulation="mipslelf mipsbelf mipself" ;;
 731                         esac ;;
 732       mips-*-lnews*-ecoff) ;;
 733       mips-*-*-ecoff)   case "$endian" in
 734                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 735                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 736                         esac ;;
 737       mips-*-*-elf)     case "$endian" in
 738                         big)    emulation="mipsbelf mipslelf mipself" ;;
 739                         *)      emulation="mipslelf mipsbelf mipself" ;;
 740                         esac ;;
 741       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 742       # i386-pc-pe-coff != i386-pc-coff.
 743       i386-*-pe-coff)   ;;
 744       # Uncommenting the next line will turn on support for i386 AOUT
 745       # for the default linux configuration
 746       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 747       #
 748       i386-*-aout)      emulation="i386aout" ;;
 749       i386-*-coff)      emulation="i386coff" ;;
 750       i386-*-elf)       emulation="i386elf" ;;
 751
 752       # Always all formats.  The first stated emulation becomes the default.
 753       cris-*-*aout*)    emulation="crisaout criself" ;;
 754       cris-*-*)         emulation="criself crisaout" ;;
 755     esac
 756
 757     emulations="$emulations $emulation"
 758
 759 done
 760
 761 # Turn on all targets if possible
 762 if test ${all_targets} = "yes"; then
 763   case ${target_cpu_type} in
 764   i386)
 765     case ${obj_format} in
 766     aout)
 767       emulations="$emulations i386coff i386elf"
 768       ;;
 769     coff)
 770       emulations="$emulations i386aout i386elf"
 771     ;;
 772     elf)
 773       emulations="$emulations i386aout i386coff"
 774       ;;
 775     esac
 776   ;;
 777   esac
 778 fi
 779
 780 # Assign floating point type.  Most processors with FP support
 781 # IEEE FP.  On those that don't support FP at all, usually IEEE
 782 # is emulated.
 783 case ${target_cpu} in
 784   vax | tahoe ) atof=${target_cpu} ;;
 785   pdp11)        atof=vax ;;
 786   *)            atof=ieee ;;
 787 esac
 788
 789 case "${obj_format}" in
 790   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 791 esac
 792
 793 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 794 cgen_cpu_prefix=""
 795 if test $using_cgen = yes ; then
 796   case ${target_cpu} in
 797     *) cgen_cpu_prefix=${target_cpu} ;;
 798   esac
 799   AC_SUBST(cgen_cpu_prefix)
 800   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 801 fi
 802
 803 dnl
 804 dnl Make sure the desired support files exist.
 805 dnl
 806
 807 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 808   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 809 fi
 810
 811 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 812   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 813 fi
 814
 815 case ${user_bfd_gas}-${primary_bfd_gas} in
 816   yes-yes | no-no)
 817     # We didn't override user's choice.
 818     ;;
 819   no-yes)
 820     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 821     ;;
 822   no-preferred)
 823     primary_bfd_gas=no
 824     ;;
 825   *-preferred)
 826     primary_bfd_gas=yes
 827     ;;
 828   yes-*)
 829     primary_bfd_gas=yes
 830     ;;
 831   -*)
 832     # User specified nothing.
 833     ;;
 834 esac
 835
 836 # Some COFF configurations want these random other flags set.
 837 case ${obj_format} in
 838   coff)
 839     case ${target_cpu_type} in
 840       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 841       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 842       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 843     esac
 844     ;;
 845 esac
 846
 847 # Getting this done right is going to be a bitch.  Each configuration specified
 848 # with --enable-targets=... should be checked for environment, format, cpu, and
 849 # bfd_gas setting.
 850 #
 851 # For each configuration, the necessary object file support code must be linked
 852 # in.  This might be only one, it might be up to four.  The necessary emulation
 853 # code needs to be provided, too.
 854 #
 855 # And then there's "--enable-targets=all"....
 856 #
 857 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 858
 859 formats="${obj_format}"
 860 emfiles=""
 861 EMULATIONS=""
 862 GAS_UNIQ(emulations)
 863 for em in . $emulations ; do
 864   case $em in
 865     .)  continue ;;
 866     mipsbelf | mipslelf | mipself)
 867         fmt=elf   file=mipself ;;
 868     mipsbecoff | mipslecoff | mipsecoff)
 869         fmt=ecoff file=mipsecoff ;;
 870     *coff)
 871         fmt=coff  file=$em ;;
 872     *aout)
 873         fmt=aout file=$em ;;
 874     *elf)
 875         fmt=elf file=$em ;;
 876   esac
 877   formats="$formats $fmt"
 878   emfiles="$emfiles e-$file.o"
 879   EMULATIONS="$EMULATIONS &$em,"
 880 done
 881 GAS_UNIQ(formats)
 882 GAS_UNIQ(emfiles)
 883 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 884   for fmt in $formats ; do
 885     case $fmt in
 886       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 887       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 888       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 889       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 890       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 891       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 892       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 893       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 894       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 895       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 896     esac
 897     extra_objects="$extra_objects obj-$fmt.o"
 898   done
 899   obj_format=multi
 900 fi
 901 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 902   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 903   # e-mips* has more than one emulation per file, e-i386* has just one at the
 904   # moment.  If only one emulation is specified, then don't define
 905   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 906   case "${obj_format}${emfiles}" in
 907     multi* | *mips*)
 908       extra_objects="$extra_objects $emfiles"
 909       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 910   esac
 911 fi
 912 AC_SUBST(extra_objects)
 913 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 914 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 915                    [Default emulation.])
 916
 917 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 918   yes-*-coff)   need_bfd=yes ;;
 919   no-*-coff)    need_bfd=yes
 920                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 921 esac
 922
 923 reject_dev_configs=yes
 924
 925 case ${reject_dev_configs}-${dev} in
 926   yes-yes) # Oops.
 927     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 928     ;;
 929 esac
 930
 931 AC_SUBST(target_cpu_type)
 932 AC_SUBST(obj_format)
 933 AC_SUBST(te_file)
 934 AC_SUBST(install_tooldir)
 935 AC_SUBST(atof)
 936 dnl AC_SUBST(emulation)
 937
 938 case "${primary_bfd_gas}" in
 939   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 940         need_bfd=yes ;;
 941 esac
 942
 943 # do we need the opcodes library?
 944 case "${need_opcodes}" in
 945 yes)
 946   OPCODES_LIB=../opcodes/libopcodes.la
 947   ;;
 948 esac
 949
 950 case "${need_bfd}" in
 951 yes)
 952   BFDLIB=../bfd/libbfd.la
 953   BFDVER_H=../bfd/bfdver.h
 954   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 955   ;;
 956 esac
 957
 958 AC_SUBST(BFDLIB)
 959 AC_SUBST(OPCODES_LIB)
 960
 961 AC_SUBST(BFDVER_H)
 962 AC_SUBST(ALL_OBJ_DEPS)
 963
 964 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 965 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 966 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 967 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 968 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 969
 970 AC_PROG_CC
 971
 972 AC_PROG_YACC
 973 AM_PROG_LEX
 974
 975 ALL_LINGUAS="fr tr es"
 976 CY_GNU_GETTEXT
 977
 978 AM_MAINTAINER_MODE
 979 AC_EXEEXT
 980
 981 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 982
 983 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 984 # people who are not cross-compiling but are compiling cross-assemblers.
 985 AC_MSG_CHECKING(whether compiling a cross-assembler)
 986 if test "${host}" = "${target}"; then
 987   cross_gas=no
 988 else
 989   cross_gas=yes
 990   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 991 fi
 992 AC_MSG_RESULT($cross_gas)
 993
 994 dnl ansidecl.h will deal with const
 995 dnl AC_CONST
 996 AC_FUNC_ALLOCA
 997 AC_C_INLINE
 998
 999 # VMS doesn't have unlink.
1000 AC_CHECK_FUNCS(unlink remove, break)
1001
1002 # Some systems don't have sbrk().
1003 AC_CHECK_FUNCS(sbrk)
1004
1005 # do we need the math library?
1006 case "${need_libm}" in
1007 yes)
1008   AC_CHECK_LIBM
1009   AC_SUBST(LIBM)
1010   ;;
1011 esac
1012
1013 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1014 # enough, but on some of those systems, the assert macro relies on requoting
1015 # working properly!
1016 GAS_WORKING_ASSERT
1017
1018 # On some systems, the system header files may not declare malloc, realloc,
1019 # and free.  There are places where gas needs these functions to have been
1020 # declared -- such as when taking their addresses.
1021 gas_test_headers="
1022 #ifdef HAVE_MEMORY_H
1023 #include <memory.h>
1024 #endif
1025 #ifdef HAVE_STRING_H
1026 #include <string.h>
1027 #else
1028 #ifdef HAVE_STRINGS_H
1029 #include <strings.h>
1030 #endif
1031 #endif
1032 #ifdef HAVE_STDLIB_H
1033 #include <stdlib.h>
1034 #endif
1035 #ifdef HAVE_UNISTD_H
1036 #include <unistd.h>
1037 #endif
1038 "
1039 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1040 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1041 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1042 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1043 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1044
1045 # Does errno.h declare errno, or do we have to add a separate declaration
1046 # for it?
1047 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1048 #ifdef HAVE_ERRNO_H
1049 #include <errno.h>
1050 #endif
1051 ])
1052
1053 dnl This must come last.
1054
1055 dnl We used to make symlinks to files in the source directory, but now
1056 dnl we just use the right name for .c files, and create .h files in
1057 dnl the build directory which include the right .h file.  Make sure
1058 dnl the old symlinks don't exist, so that a reconfigure in an existing
1059 dnl directory behaves reasonably.
1060
1061 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1062 AC_CONFIG_COMMANDS([default],
1063 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1064  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1065  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1066  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1067  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1068  if test "x$cgen_cpu_prefix" != x ; then
1069    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1070  fi
1071
1072  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1073 [target_cpu_type=${target_cpu_type}
1074  cgen_cpu_prefix=${cgen_cpu_prefix}
1075  obj_format=${obj_format}
1076  te_file=${te_file}])
1077
1078 AC_OUTPUT