gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.3)dnl We only need 2.0, but pre-2.3 loses on some AIX version.
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true ;;
  30   no)  shared=false ;;
  31   *)   AC_MSG_ERROR([bad value ${enableval} for BFD shared option]) ;;
  32 esac])dnl
  33
  34 # Generate a header file -- gets more post-processing by Makefile later.
  35 AC_CONFIG_HEADER(conf)
  36
  37 dnl For recursion to work right, this must be an absolute pathname.
  38 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  39 AC_CANONICAL_SYSTEM
  40 AC_ARG_PROGRAM
  41
  42 te_file=generic
  43
  44 canon_targets=""
  45 if test -n "$enable_targets" ; then
  46   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  47     result=`$ac_config_sub $t 2>/dev/null`
  48     if test -n "$result" ; then
  49       canon_targets="$canon_targets $result"
  50 #    else
  51 #      # Permit "all", etc.  We don't support it yet though.
  52 #      canon_targets="$canon_targets $t"
  53     fi
  54   done
  55   GAS_UNIQ(canon_targets)
  56 fi
  57
  58 emulations=""
  59
  60 for this_target in $target $canon_targets ; do
  61
  62     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  63
  64     # check for architecture variants
  65     case ${cpu} in
  66       armeb)            cpu_type=arm endian=big ;;
  67       arm*)             cpu_type=arm endian=little ;;
  68       hppa*)            cpu_type=hppa ;;
  69 changequote(,)dnl
  70       i[456]86)         cpu_type=i386 ;;
  71       m680[012346]0)    cpu_type=m68k ;;
  72       m68008)           cpu_type=m68k ;;
  73       m683??)           cpu_type=m68k ;;
  74 changequote([,])dnl
  75       m8*)              cpu_type=m88k ;;
  76       mips*el)          cpu_type=mips endian=little;;
  77       mips*)            cpu_type=mips endian=big ;;
  78       powerpcle*)       cpu_type=ppc endian=little ;;
  79       powerpc*)         cpu_type=ppc endian=big ;;
  80       rs6000*)          cpu_type=ppc ;;
  81       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  82       sparc*)           cpu_type=sparc ;;
  83       *)                cpu_type=${cpu} ;;
  84     esac
  85
  86     if test ${this_target} = $target ; then
  87       target_cpu_type=${cpu_type}
  88     elif test ${target_cpu_type} != ${cpu_type} ; then
  89       continue
  90     fi
  91
  92     targ=${cpu_type}
  93     generic_target=${cpu_type}-$vendor-$os
  94     dev=no
  95     bfd_gas=no
  96     em=generic
  97
  98     # assign object format
  99     case ${generic_target} in
 100       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 101       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 102       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 103       a29k-*-vxworks*)      fmt=coff ;;
 104
 105       alpha-*-netware*)     fmt=ecoff ;;
 106       alpha-*-osf*)         fmt=ecoff ;;
 107       alpha-*-linux*)       fmt=ecoff ;;
 108
 109 # start-sanitize-arc
 110       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 111 # end-sanitize-arc
 112
 113       arm-*-riscix*)        fmt=aout targ=arm-lit ;;
 114       arm-*-aout)           fmt=aout
 115                             case "$endian" in
 116                               big)      targ=arm-big ;;
 117                               *)        targ=arm-lit ;;
 118                             esac
 119                             ;;
 120       arm-*-coff)           fmt=coff ;;
 121       arm-*-riscix*)        fmt=aout ;;
 122       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 123
 124       hppa-*-*elf*)         fmt=elf em=hppa ;;
 125       hppa-*-lites*)        fmt=elf em=hppa ;;
 126       hppa-*-osf*)          fmt=som em=hppa ;;
 127       hppa-*-hpux*)         fmt=som em=hppa ;;
 128       hppa-*-bsd*)          fmt=som em=hppa ;;
 129       hppa-*-hiux*)         fmt=som em=hppa ;;
 130
 131       h8300-*-coff)         fmt=coff ;;
 132
 133       i386-ibm-aix*)        fmt=coff targ=i386coff
 134                              em=i386aix ;;
 135       i386-*-bsd*)          fmt=aout em=386bsd ;;
 136       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 137       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 138       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 139       i386-*-linux*coff*)   fmt=coff em=linux
 140                              targ=i386coff ;;
 141       i386-*-linux*)        fmt=elf em=linux ;;
 142       i386-*-lynxos*)       fmt=coff targ=i386coff
 143                              em=lynx ;;
 144       i386-*-sysv4* | i386-*-solaris* | i386-*-elf)
 145                             fmt=elf ;;
 146       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 147       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 148                             fmt=coff targ=i386coff ;;
 149       i386-*-vsta)          fmt=aout ;;
 150       i386-*-go32)          fmt=coff targ=i386coff ;;
 151       i386-*-gnu*)          fmt=elf ;;
 152       i386-*-mach*)
 153                             fmt=aout em=mach bfd_gas=yes ;;
 154       i386-*-msdos*)        fmt=aout ;;
 155       i386-*-moss*)         fmt=elf ;;
 156       i386-*-pe)            fmt=coff targ=i386coff em=pe bfd_gas=yes;;
 157       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe bfd_gas=yes;;
 158       i386-*-*nt)           fmt=coff targ=i386coff em=pe bfd_gas=yes;;
 159       i960-*-bout)          fmt=bout ;;
 160       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 161       i960-*-nindy*)        fmt=bout ;;
 162       i960-*-vxworks4*)     fmt=bout ;;
 163       i960-*-vxworks5.0)    fmt=bout ;;
 164       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 165       i960-*-vxworks*)      fmt=bout ;;
 166
 167       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 168                             fmt=aout em=sun3 ;;
 169       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 170       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 171       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 172       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 173                             fmt=elf ;;
 174       m68k-*-coff | m68k-*-sysv*)
 175                             fmt=coff targ=m68kcoff ;;
 176       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 177       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 178                              em=lynx ;;
 179       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 180       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 181       m68k-*-psos*)         fmt=elf em=psos;;
 182
 183       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 184       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 185
 186       # don't change em like *-*-bsd does
 187       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 188       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 189       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 190       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 191       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 192       mips-*-ecoff*)        fmt=ecoff
 193                             case "$endian" in
 194                             big) targ=mips-big ;;
 195                             *)   targ=mips-lit ;;
 196                             esac
 197                             ;;
 198       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 199       mips-*-gnu*)          fmt=aout
 200                             case "$endian" in
 201                             big) targ=mips-big ;;
 202                             *)   targ=mips-lit ;;
 203                             esac
 204                             ;;
 205       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 206       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 207       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 208       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 209       mips-*-elf*)          fmt=elf
 210                             case "$endian" in
 211                             big) targ=mips-big ;;
 212                             *)   targ=mips-lit ;;
 213                             esac
 214                             ;;
 215       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 216                             fmt=coff em=pe
 217                             case "$endian" in
 218                             big) targ=ppc-big ;;
 219                             *)   targ=ppc-lit ;;
 220                             esac
 221                             ;;
 222       ppc-*-aix*)           fmt=coff ;;
 223       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 224                             fmt=elf
 225                             case "$endian" in
 226                             big)  targ=ppc-big ;;
 227                             *)    targ=ppc-lit ;;
 228                             esac
 229                             ;;
 230       ppc-*-macos* | ppc-*-mpw*)
 231                             fmt=coff em=macos ;;
 232       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 233
 234       sh-*-coff)            fmt=coff ;;
 235
 236 # start-sanitize-rce
 237       rce-*-aout)           fmt=aout ;;
 238 # end-sanitize-rce
 239
 240       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 241       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 242
 243       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 244       sparc-*-aout | sparc*-*-vxworks)
 245                             fmt=aout ;;
 246       sparc-*-coff)         fmt=coff ;;
 247       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 248       sparc-fujitsu-none)   fmt=aout ;;
 249       sparc-*-elf | sparc*-*-solaris*)
 250                             fmt=elf ;;
 251       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 252
 253       vax-*-bsd* | vax-*-ultrix*)
 254                             fmt=aout ;;
 255       vax-*-vms)            fmt=vms ;;
 256
 257       z8k-*-coff | z8k-*-sim)
 258                             fmt=coff ;;
 259
 260       w65-*-*)              fmt=coff ;;
 261
 262       *-*-aout | *-*-scout)
 263                             fmt=aout ;;
 264       *-*-nindy*)
 265                             fmt=bout ;;
 266       *-*-bsd*)
 267                             fmt=aout em=sun3 ;;
 268       *-*-generic)          fmt=generic ;;
 269       *-*-xray | *-*-hms)   fmt=coff ;;
 270       *-*-sim)              fmt=coff ;;
 271       *-*-elf | *-*-sysv4* | *-*-solaris*)
 272                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 273                             fmt=elf dev=yes ;;
 274       *-*-vxworks)          fmt=aout ;;
 275       *-*-netware)          fmt=elf ;;
 276     esac
 277
 278     case ${cpu_type}-${fmt} in
 279       arm-*)    bfd_gas=yes ;;
 280     # not yet
 281     # i386-aout)        bfd_gas=preferred ;;
 282       mips-*)   bfd_gas=yes ;;
 283       ns32k-*)  bfd_gas=yes ;;
 284       ppc-*)    bfd_gas=yes ;;
 285       sparc-*)  bfd_gas=yes ;;
 286       *-elf)    bfd_gas=yes ;;
 287       *-ecoff)  bfd_gas=yes ;;
 288       *-som)    bfd_gas=yes ;;
 289       *)                ;;
 290     esac
 291
 292 # Other random stuff.
 293
 294     # do we need the opcodes library?
 295     case ${cpu_type} in
 296       alpha | vax | i386)
 297         ;;
 298       *)
 299         need_opcodes=yes
 300         if test "${shared}" = "true"; then
 301           # A shared libopcodes must be linked against libbfd.
 302           need_bfd=yes
 303         fi
 304         ;;
 305     esac
 306
 307     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 308
 309     case ${cpu}-${vendor}-${os} in
 310       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 311     esac
 312
 313     case ${cpu_type} in
 314       m68k)
 315         case ${extra_objects} in
 316         *m68k-parse.o*) ;;
 317         *) extra_objects="$extra_objects m68k-parse.o" ;;
 318         esac
 319         ;;
 320     esac
 321
 322 # See if we really can support this configuration with the emulation code.
 323
 324     if test $this_target = $target ; then
 325       primary_bfd_gas=$bfd_gas
 326       obj_format=$fmt
 327       gas_target=$targ
 328       te_file=$em
 329
 330       if test $bfd_gas = no ; then
 331         # Can't support other configurations this way.
 332         break
 333       fi
 334     elif test $bfd_gas = no ; then
 335       # Can't support this configuration.
 336       break
 337     fi
 338
 339 # From target name and format, produce a list of supported emulations.
 340
 341     case ${generic_target}-${fmt} in
 342       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 343       mips-*-*-ecoff)   case "$endian" in
 344                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 345                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 346                         esac ;;
 347       mips-*-*-elf)     case "$endian" in
 348                         big)    emulation="mipsbelf mipslelf mipself" ;;
 349                         *)      emulation="mipslelf mipsbelf mipself" ;;
 350                         esac ;;
 351     esac
 352
 353     emulations="$emulations $emulation"
 354
 355 done
 356
 357 # Assign floating point type.  Most processors with FP support
 358 # IEEE FP.  On those that don't support FP at all, usually IEEE
 359 # is emulated.
 360 case ${target_cpu} in
 361   vax | tahoe ) atof=${target_cpu} ;;
 362   *)            atof=ieee ;;
 363 esac
 364
 365 case "${obj_format}" in
 366   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 367 esac
 368
 369 dnl
 370 dnl Make sure the desired support files exist.
 371 dnl
 372
 373 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 374   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 375 fi
 376
 377 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 378   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 379 fi
 380
 381 # and target makefile frag
 382
 383 target_frag=${srcdir}/config/${gas_target}.mt
 384 if test ! -r ${target_frag}; then
 385   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 386 fi
 387 AC_SUBST_FILE(target_frag)
 388
 389 case ${user_bfd_gas}-${primary_bfd_gas} in
 390   yes-yes | no-no)
 391     # We didn't override user's choice.
 392     ;;
 393   no-yes)
 394     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 395     ;;
 396   no-preferred)
 397     primary_bfd_gas=no
 398     ;;
 399   *-preferred)
 400     primary_bfd_gas=yes
 401     ;;
 402   yes-*)
 403     primary_bfd_gas=yes
 404     ;;
 405   -*)
 406     # User specified nothing.
 407     ;;
 408 esac
 409
 410 # Some COFF configurations want these random other flags set.
 411 case ${obj_format} in
 412   coff)
 413     case ${target_cpu_type} in
 414       i386) AC_DEFINE(I386COFF) ;;
 415       m68k) AC_DEFINE(M68KCOFF) ;;
 416       m88k) AC_DEFINE(M88KCOFF) ;;
 417     esac
 418     ;;
 419 esac
 420
 421 # Getting this done right is going to be a bitch.  Each configuration specified
 422 # with --enable-targets=... should be checked for environment, format, cpu, and
 423 # bfd_gas setting.
 424 #
 425 # For each configuration, the necessary object file support code must be linked
 426 # in.  This might be only one, it might be up to four.  The necessary emulation
 427 # code needs to be provided, too.
 428 #
 429 # And then there's "--enable-targets=all"....
 430 #
 431 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 432
 433 formats="${obj_format}"
 434 emfiles=""
 435 EMULATIONS=""
 436 GAS_UNIQ(emulations)
 437 for em in . $emulations ; do
 438   case $em in
 439     .)  continue ;;
 440     mipsbelf | mipslelf)
 441         fmt=elf   file=mipself ;;
 442     mipsbecoff | mipslecoff)
 443         fmt=ecoff file=mipsecoff ;;
 444   esac
 445   formats="$formats $fmt"
 446   emfiles="$emfiles e-$file.o"
 447   EMULATIONS="$EMULATIONS &$em,"
 448 done
 449 GAS_UNIQ(formats)
 450 GAS_UNIQ(emfiles)
 451 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 452   for fmt in $formats ; do
 453     case $fmt in
 454       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 455       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 456       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 457       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 458       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 459       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 460       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 461       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 462       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 463       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 464     esac
 465     extra_objects="$extra_objects obj-$fmt.o"
 466   done
 467   obj_format=multi
 468 fi
 469 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 470   te_file=multi
 471   extra_objects="$extra_objects $emfiles"
 472   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 473   AC_DEFINE(USE_EMULATIONS)
 474 fi
 475 AC_SUBST(extra_objects)
 476 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 477 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 478
 479 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 480         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 481         config/te-${te_file}.h config/atof-${atof}.c \
 482         $extra_files"
 483 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 484         $extra_links"
 485
 486 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 487   yes-*-coff)   need_bfd=yes ;;
 488   no-*-coff)    need_bfd=yes
 489                 AC_DEFINE(MANY_SEGMENTS) ;;
 490 esac
 491
 492 reject_dev_configs=yes
 493
 494 case ${reject_dev_configs}-${dev} in
 495   yes-yes) # Oops.
 496     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 497     ;;
 498 esac
 499
 500 AC_SUBST(target_cpu_type)
 501 AC_SUBST(obj_format)
 502 AC_SUBST(atof)
 503 dnl AC_SUBST(emulation)
 504
 505 AC_LINK_FILES($files, $links)
 506
 507 case "${primary_bfd_gas}" in
 508   yes)  AC_DEFINE(BFD_ASSEMBLER)
 509         need_bfd=yes ;;
 510 esac
 511
 512 # do we need the opcodes library?
 513 case "${need_opcodes}" in
 514   yes)
 515     OPCODES_DEP=../opcodes/libopcodes.a
 516     OPCODES_LIB='-L../opcodes -lopcodes'
 517
 518     # We need to handle some special cases if opcodes was built shared.
 519     if test "${shared}" = "true"; then
 520       case "${host}" in
 521       *-*-sunos*)
 522       # On SunOS, we must link against the name we are going to install,
 523       # not -lbfd, since SunOS does not support SONAME.
 524       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 525       ;;
 526       esac
 527     fi
 528     ;;
 529 esac
 530 AC_SUBST(OPCODES_DEP)
 531 AC_SUBST(OPCODES_LIB)
 532
 533 case "${need_bfd}" in
 534   yes)
 535     BFDDEP=../bfd/libbfd.a
 536     BFDLIB='-L../bfd -lbfd'
 537     ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 538
 539     # We need to handle some special cases if BFD was built shared.
 540     if test "${shared}" = "true"; then
 541       case "${host}" in
 542         *-*-sunos*)
 543         # On SunOS, we must link against the name we are going to install,
 544         # not -lbfd, since SunOS does not support SONAME.
 545         BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 546         ;;
 547       esac
 548     fi
 549     ;;
 550 esac
 551 AC_SUBST(BFDDEP)
 552 AC_SUBST(BFDLIB)
 553 AC_SUBST(ALL_OBJ_DEPS)
 554
 555 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 556 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 557 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 558 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 559 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 560
 561 AC_PROG_CC
 562 AC_PROG_INSTALL
 563
 564 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 565
 566 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 567 # people who are not cross-compiling but are compiling cross-assemblers.
 568 AC_MSG_CHECKING(whether compiling a cross-assembler)
 569 if test "${host}" = "${target}"; then
 570   cross_gas=no
 571 else
 572   cross_gas=yes
 573   AC_DEFINE(CROSS_COMPILE)
 574 fi
 575 AC_MSG_RESULT($cross_gas)
 576
 577 dnl ansidecl.h will deal with const
 578 dnl AC_CONST
 579 AC_FUNC_ALLOCA
 580 AC_C_INLINE
 581
 582 # VMS doesn't have unlink.
 583 AC_CHECK_FUNCS(unlink remove, break)
 584
 585 # Some systems don't have sbrk().
 586 AC_CHECK_FUNCS(sbrk)
 587
 588 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 589 # enough, but on some of those systems, the assert macro relies on requoting
 590 # working properly!
 591 GAS_WORKING_ASSERT
 592
 593 # On some systems, the system header files may not declare malloc, realloc,
 594 # and free.  There are places where gas needs these functions to have been
 595 # declared -- such as when taking their addresses.
 596 gas_test_headers="
 597 #ifdef HAVE_MEMORY_H
 598 #include <memory.h>
 599 #endif
 600 #ifdef HAVE_STRING_H
 601 #include <string.h>
 602 #endif
 603 #ifdef HAVE_STDLIB_H
 604 #include <stdlib.h>
 605 #endif
 606 #ifdef HAVE_UNISTD_H
 607 #include <unistd.h>
 608 #endif
 609 "
 610 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 611 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 612
 613 # Does errno.h declare errno, or do we have to add a separate declaration
 614 # for it?
 615 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 616 #ifdef HAVE_ERRNO_H
 617 #include <errno.h>
 618 #endif
 619 ])
 620
 621 HLDFLAGS=
 622 RPATH_ENVVAR=LD_LIBRARY_PATH
 623 # If we have shared libraries, try to set rpath reasonably.
 624 if test "${shared}" = "true"; then
 625   case "${host}" in
 626   *-*-hpux*)
 627     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 628     RPATH_ENVVAR=SHLIB_PATH
 629     ;;
 630   *-*-irix5*)
 631     HLDFLAGS='-Wl,-rpath,$(libdir)'
 632     ;;
 633   *-*-linux*aout*)
 634     ;;
 635   *-*-linux*)
 636     HLDFLAGS='-Wl,-rpath,$(libdir)'
 637     ;;
 638   *-*-sysv4* | *-*-solaris*)
 639     HLDFLAGS='-R $(libdir)'
 640     ;;
 641   esac
 642 fi
 643
 644 # On SunOS, if the linker supports the -rpath option, use it to
 645 # prevent ../bfd and ../opcodes from being included in the run time
 646 # search path.
 647 case "${host}" in
 648   *-*-sunos*)
 649     echo 'main () { }' > conftest.c
 650     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 651     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 652       :
 653     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 654       :
 655     elif test "${shared}" = "true"; then
 656       HLDFLAGS='-Wl,-rpath=$(libdir)'
 657     else
 658       HLDFLAGS='-Wl,-rpath='
 659     fi
 660     rm -f conftest.t conftest.c conftest
 661     ;;
 662 esac
 663 AC_SUBST(HLDFLAGS)
 664 AC_SUBST(RPATH_ENVVAR)
 665
 666 dnl This must come last.
 667 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)