gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       ip2k)             cpu_type=ip2k endian=big ;;
 132       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 133       m680[012346]0)    cpu_type=m68k ;;
 134 changequote([,])dnl
 135       m68008)           cpu_type=m68k ;;
 136       m683??)           cpu_type=m68k ;;
 137       m5200)            cpu_type=m68k ;;
 138       m8*)              cpu_type=m88k ;;
 139       mips*el)          cpu_type=mips endian=little ;;
 140       mips*)            cpu_type=mips endian=big ;;
 141       or32*)            cpu_type=or32 endian=big ;;
 142       pjl*)             cpu_type=pj endian=little ;;
 143       pj*)              cpu_type=pj endian=big ;;
 144       powerpc*le*)      cpu_type=ppc endian=little ;;
 145       powerpc*)         cpu_type=ppc endian=big ;;
 146       rs6000*)          cpu_type=ppc ;;
 147       s390x*)           cpu_type=s390 arch=s390x ;;
 148       s390*)            cpu_type=s390 arch=s390 ;;
 149       sh5*)             cpu_type=sh64 endian=big ;;
 150       sh5le*)           cpu_type=sh64 endian=little ;;
 151       sh64*)            cpu_type=sh64 endian=big ;;
 152       sh64le*)          cpu_type=sh64 endian=little ;;
 153       sh*le)            cpu_type=sh endian=little ;;
 154       sh*)              cpu_type=sh endian=big ;;
 155       sparclite*)       cpu_type=sparc arch=sparclite ;;
 156       sparclet*)        cpu_type=sparc arch=sparclet ;;
 157       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 158       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 159       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 160       v850*)            cpu_type=v850 ;;
 161       *)                cpu_type=${cpu} ;;
 162     esac
 163
 164     if test ${this_target} = $target ; then
 165       target_cpu_type=${cpu_type}
 166     elif test ${target_cpu_type} != ${cpu_type} ; then
 167       continue
 168     fi
 169
 170     generic_target=${cpu_type}-$vendor-$os
 171     dev=no
 172     bfd_gas=no
 173     em=generic
 174
 175     # assign object format
 176     case ${generic_target} in
 177       a29k-*-coff)          fmt=coff ;;
 178       a29k-amd-udi)         fmt=coff ;;
 179       a29k-amd-ebmon)       fmt=coff ;;
 180       a29k-nyu-sym1)        fmt=coff ;;
 181       a29k-*-rtems*)        fmt=coff ;;
 182       a29k-*-vxworks*)      fmt=coff ;;
 183
 184       alpha*-*-*vms*)       fmt=evax ;;
 185       alpha*-*-netware*)    fmt=ecoff ;;
 186       alpha*-*-osf*)        fmt=ecoff ;;
 187       alpha*-*-linuxecoff*) fmt=ecoff ;;
 188       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 189       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 190       alpha*-*-openbsd*)    fmt=elf em=obsd ;;
 191
 192       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 193
 194       arm-*-aout)                       fmt=aout ;;
 195       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 196       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 197       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 198       arm*-*-conix*)                    fmt=elf ;;
 199       arm-*-linux*aout*)                fmt=aout em=linux ;;
 200       arm*-*-linux-gnu* | arm*-*-uclinux*)
 201                                         fmt=elf  em=linux ;;
 202       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 203       arm-*-netbsd* | arm-*-openbsd*)   fmt=aout em=nbsd ;;
 204       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 205       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 206       arm-*-wince)                      fmt=coff em=wince-pe ;;
 207       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 208       arm-*-riscix*)                    fmt=aout em=riscix ;;
 209       arm-*-vxworks)                    fmt=coff ;;
 210
 211       avr-*-*)              fmt=elf bfd_gas=yes ;;
 212
 213       cris-*-*)             fmt=multi bfd_gas=yes ;;
 214
 215       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 216       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 217       dlx-*-*)              fmt=elf ;;
 218
 219
 220       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 221       frv-*-*)              fmt=elf bfd_gas=yes ;;
 222
 223       hppa-*-linux-gnu*)    case ${cpu} in
 224                                 hppa*64*)
 225                                         fmt=elf em=hppalinux64;;
 226                                 hppa*)
 227                                         fmt=elf em=linux;;
 228                             esac ;;
 229       hppa-*-*elf*)         fmt=elf em=hppa ;;
 230       hppa-*-lites*)        fmt=elf em=hppa ;;
 231       hppa-*-netbsd*)       fmt=elf em=nbsd ;;
 232       hppa-*-openbsd*)      fmt=elf em=hppa ;;
 233       hppa-*-osf*)          fmt=som em=hppa ;;
 234       hppa-*-rtems*)        fmt=elf em=hppa ;;
 235       hppa-*-hpux11*)       case ${cpu} in
 236                                 hppa*64*)
 237                                         fmt=elf em=hppa64 ;;
 238                                 hppa*)
 239                                         fmt=som em=hppa ;;
 240                             esac ;;
 241       hppa-*-hpux*)         fmt=som em=hppa ;;
 242       hppa-*-mpeix*)        fmt=som em=hppa ;;
 243       hppa-*-bsd*)          fmt=som em=hppa ;;
 244       hppa-*-hiux*)         fmt=som em=hppa ;;
 245
 246       h8300-*-rtems*)       fmt=coff ;;
 247       h8300-*-coff)         fmt=coff ;;
 248       h8300-*-elf)          fmt=elf ;;
 249       h8500-*-rtems*)       fmt=coff ;;
 250       h8500-*-coff)         fmt=coff ;;
 251
 252       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 253       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 254       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 255       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 256       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 257       i386-*-bsd*)          fmt=aout em=386bsd ;;
 258       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 259       i386-*-netbsdpe*)       fmt=coff em=pe bfd_gas=yes ;;
 260       i386-*-netbsd*)       em=nbsd bfd_gas=yes
 261                             case ${cpu} in
 262                               x86_64)   fmt=elf ;;
 263                               *)        case ${os} in
 264                                           *elf*) fmt=elf ;;
 265                                           *)     fmt=aout ;;
 266                                         esac
 267                                         ;;
 268                             esac
 269                             ;;
 270       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 271       i386-*-linux*aout* | i386-*-linux*oldld)   fmt=aout em=linux ;;
 272       i386-*-linux*coff*)   fmt=coff em=linux ;;
 273       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 274       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 275       i386-*-lynxos*)       fmt=coff em=lynx ;;
 276 changequote(,)dnl
 277       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 278                             fmt=elf bfd_gas=yes ;;
 279       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 280                             fmt=aout em=386bsd ;;
 281 changequote([,])dnl
 282       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 283                           fmt=coff ;;
 284       i386-*-sco3.2v5*)      fmt=elf
 285                             if test ${this_target} = $target; then
 286                                 AC_DEFINE(SCO_ELF, 1,
 287                                     [Define if defaulting to ELF on SCO 5.])
 288                             fi
 289                             ;;
 290       i386-*-sco3.2*)       fmt=coff ;;
 291       i386-*-vsta)          fmt=aout ;;
 292       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 293                             fmt=coff em=go32 bfd_gas=yes
 294                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 295                             ;;
 296       i386-*-rtemself*)     fmt=elf ;;
 297       i386-*-rtemscoff*)    fmt=coff ;;
 298       i386-*-rtems*)        fmt=elf ;;
 299       i386-*-gnu*)          fmt=elf ;;
 300       i386-*-mach*)
 301                             fmt=aout em=mach bfd_gas=yes ;;
 302       i386-*-msdos*)        fmt=aout ;;
 303       i386-*-moss*)         fmt=elf ;;
 304       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 305       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 306       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 307       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 308       i386-*-nto-qnx*)      fmt=elf ;;
 309       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 310       i386-*-vxworks*)      fmt=aout ;;
 311       i386-*-chaos)         fmt=elf ;;
 312       i860-stardent-sysv4* | i860-stardent-elf*)
 313                             fmt=elf bfd_gas=yes endian=little
 314                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 315       i960-*-bout)          fmt=bout ;;
 316       i960-*-coff)          fmt=coff em=ic960 ;;
 317       i960-*-rtems*)        fmt=coff em=ic960 ;;
 318       i960-*-nindy*)        fmt=bout ;;
 319       i960-*-vxworks4*)     fmt=bout ;;
 320       i960-*-vxworks5.0)    fmt=bout ;;
 321       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 322       i960-*-vxworks*)      fmt=bout ;;
 323       i960-*-elf*)          fmt=elf ;;
 324
 325       ia64-*-elf*)          fmt=elf ;;
 326       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 327       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 328       ia64-*-hpux*)         fmt=elf em=hpux ;;
 329       ia64-*-netbsd*)       fmt=elf em=nbsd ;;
 330
 331       ip2k-*-*)             fmt=elf bfd_gas=yes ;;
 332
 333       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 334
 335       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 336
 337       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 338                             fmt=aout em=sun3 ;;
 339       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 340       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 341       m68k-apollo-*)        fmt=coff em=apollo ;;
 342       m68k-*-sysv4*) # must be before -sysv*
 343                             fmt=elf em=svr4 ;;
 344       m68k-*-elf*)          fmt=elf ;;
 345       m68k-*-coff | m68k-*-sysv* | m68k-*-rtemscoff*)
 346                             fmt=coff ;;
 347       m68k-*-rtems*)        fmt=elf ;;
 348       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 349       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 350       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 351       m68k-*-gnu*)          fmt=elf ;;
 352       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 353       m68k-*-netbsdelf*)    fmt=elf em=nbsd bfd_gas=yes ;;
 354       m68k-*-netbsdaout* | m68k-*-netbsd*)
 355                             fmt=aout em=nbsd bfd_gas=yes ;;
 356       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 357       m68k-apple-aux*)      fmt=coff em=aux ;;
 358       m68k-*-psos*)         fmt=elf em=psos;;
 359
 360       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 361       m88k-*-coff*)         fmt=coff ;;
 362
 363       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 364       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 365
 366       # don't change em like *-*-bsd does
 367       mips-dec-openbsd*)    fmt=elf endian=little ;;
 368       mips-dec-bsd*)        fmt=aout endian=little ;;
 369       mips-sony-bsd*)       fmt=ecoff ;;
 370       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 371       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 372       mips-*-osf*)          fmt=ecoff endian=little ;;
 373       mips-*-ecoff*)        fmt=ecoff ;;
 374       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 375       mips-*-irix6*)        fmt=elf ;;
 376       mips-*-irix5*)        fmt=elf ;;
 377       mips-*-irix*)         fmt=ecoff ;;
 378       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 379       mips-*-riscos*)       fmt=ecoff ;;
 380       mips*-*-linux*)       fmt=elf em=tmips ;;
 381       mips-*-sysv4*MP* | mips-*-gnu*)
 382                             fmt=elf em=tmips ;;
 383       mips-*-sysv*)         fmt=ecoff ;;
 384       mips-*-elf* | mips-*-rtems* | mips-*-netbsd* | mips-*-openbsd*)
 385                             fmt=elf ;;
 386       mips-*-vxworks*)      fmt=elf ;;
 387       mmix-*-*)             fmt=elf bfd_gas=yes ;;
 388       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 389       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 390       openrisc-*-*)         fmt=elf bfd_gas=yes ;;
 391       or32-*-rtems*)        fmt=coff ;;
 392       or32-*-coff)          fmt=coff ;;
 393       or32-*-elf)           fmt=elf ;;
 394       pj*)                  fmt=elf ;;
 395       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 396                             fmt=coff em=pe ;;
 397       ppc-*-aix5*)          fmt=coff em=aix5 ;;
 398       ppc-*-aix*)           fmt=coff ;;
 399       ppc-*-beos*)          fmt=coff ;;
 400       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 401                             fmt=elf ;;
 402       ppc-*-linux-gnu*)     fmt=elf
 403                             case "$endian" in
 404                             big)  ;;
 405                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 406                             esac
 407                             ;;
 408       ppc-*-solaris*)       fmt=elf
 409                             if test ${this_target} = $target; then
 410                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 411                                 [Define if default target is PowerPC Solaris.])
 412                             fi
 413                             if test x${endian} = xbig; then
 414                                 AC_MSG_ERROR(Solaris must be configured little endian)
 415                             fi
 416                             ;;
 417       ppc-*-rtems*)         fmt=elf ;;
 418       ppc-*-macos* | ppc-*-mpw*)
 419                             fmt=coff em=macos ;;
 420       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 421       ppc-*-vxworks*)       fmt=elf ;;
 422       ppc-*-windiss*)       fmt=elf ;;
 423
 424       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 425       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 426
 427       sh*-*-linux*)         fmt=elf em=linux
 428                             case ${cpu} in
 429                                 sh*eb)
 430                                         endian=big ;;
 431                                 sh*)
 432                                         endian=little ;;
 433                             esac ;;
 434       sh5*-*-netbsd*)       fmt=elf em=nbsd ;;
 435       sh64*-*-netbsd*)      fmt=elf em=nbsd ;;
 436       sh*-*-netbsdelf*)     fmt=elf em=nbsd ;;
 437       sh-*-elf*)            fmt=elf ;;
 438       sh-*-coff*)           fmt=coff ;;
 439       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes endian=little ;;
 440       sh-*-rtemself*)       fmt=elf ;;
 441       sh-*-rtems*)          fmt=coff ;;
 442
 443       sh64-*-elf*)          fmt=elf ;;
 444       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 445       ns32k-*-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 446       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 447
 448       sparc-*-rtemsaout*)   fmt=aout ;;
 449       sparc-*-rtemself*)    fmt=elf ;;
 450       sparc-*-rtems*)       fmt=elf ;;
 451       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 452       sparc-*-aout | sparc*-*-vxworks*)
 453                             fmt=aout em=sparcaout ;;
 454       sparc-*-coff)         fmt=coff ;;
 455       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 456       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 457       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 458       sparc-fujitsu-none)   fmt=aout ;;
 459       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 460                             fmt=elf ;;
 461       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 462                             case ${cpu} in
 463                                 sparc) case ${os} in
 464                                            *elf*) fmt=elf ;;
 465                                            *)     fmt=aout ;;
 466                                        esac ;;
 467                                 sparc64) fmt=elf ;;
 468                             esac
 469                             ;;
 470       sparc-*-openbsd*)     em=nbsd
 471                             case ${cpu} in
 472                                sparc) fmt=aout ;;
 473                                sparc64) fmt=elf ;;
 474                             esac
 475                             ;;
 476
 477       strongarm-*-coff)     fmt=coff ;;
 478       strongarm-*-elf)      fmt=elf ;;
 479       xscale-*-coff)     fmt=coff ;;
 480       xscale-*-elf)      fmt=elf ;;
 481
 482       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 483       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 484       tic54x-*-* | c54x*-*-*)
 485                             fmt=coff bfd_gas=yes need_libm=yes;;
 486       tic80-*-*)            fmt=coff ;;
 487
 488       v850-*-*)             fmt=elf bfd_gas=yes ;;
 489       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 490       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 491
 492       vax-*-netbsdelf*)     fmt=elf em=nbsd bfd_gas=yes ;;
 493       vax-*-netbsdaout* | vax-*-netbsd*)
 494                             fmt=aout em=nbsd ;;
 495       vax-*-bsd* | vax-*-ultrix*)
 496                             fmt=aout ;;
 497       vax-*-vms)            fmt=vms ;;
 498
 499       w65-*-*)              fmt=coff ;;
 500
 501       xstormy16-*-*)        fmt=elf bfd_gas=yes ;;
 502
 503       z8k-*-coff | z8k-*-sim)
 504                             fmt=coff ;;
 505
 506       *-*-aout | *-*-scout)
 507                             fmt=aout ;;
 508       *-*-freebsd*)         fmt=elf em=freebsd bfd_gas=yes ;;
 509       *-*-nindy*)
 510                             fmt=bout ;;
 511       *-*-bsd*)
 512                             fmt=aout em=sun3 ;;
 513       *-*-generic)          fmt=generic ;;
 514       *-*-xray | *-*-hms)   fmt=coff ;;
 515       *-*-sim)              fmt=coff ;;
 516       *-*-elf | *-*-sysv4* | *-*-solaris*)
 517                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 518                             fmt=elf dev=yes ;;
 519       *-*-vxworks)          fmt=aout ;;
 520       *-*-netware)          fmt=elf ;;
 521     esac
 522
 523     if test ${this_target} = $target ; then
 524       endian_def=
 525       if test x${endian} = xbig; then
 526         endian_def=1
 527       elif test x${endian} = xlittle; then
 528         endian_def=0
 529       fi
 530       if test x${endian_def} != x; then
 531         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 532                            [Define as 1 if big endian.])
 533       fi
 534     fi
 535
 536     case ${cpu_type}-${fmt} in
 537       alpha*-*) bfd_gas=yes ;;
 538       arm-*)    bfd_gas=yes ;;
 539     # not yet
 540     # i386-aout)        bfd_gas=preferred ;;
 541       ia64*-*)  bfd_gas=yes ;;
 542       mips-*)   bfd_gas=yes ;;
 543       ns32k-*)  bfd_gas=yes ;;
 544       pdp11-*)  bfd_gas=yes ;;
 545       ppc-*)    bfd_gas=yes ;;
 546       sparc-*)  bfd_gas=yes ;;
 547       strongarm-*)      bfd_gas=yes ;;
 548       xscale-*) bfd_gas=yes ;;
 549       *-elf)    bfd_gas=yes ;;
 550       *-ecoff)  bfd_gas=yes ;;
 551       *-som)    bfd_gas=yes ;;
 552     #enable bfd for coff and aout to allow testing if a bfd target is
 553     #the primary target, but not for coff or aout as the primary target
 554       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 555       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 556       *)                ;;
 557     esac
 558
 559 # Other random stuff.
 560
 561     # Do we need the opcodes library?
 562     case ${cpu_type} in
 563       vax | i386 | tic30)
 564         ;;
 565
 566       *)
 567         need_opcodes=yes
 568
 569         case "${enable_shared}" in
 570         yes) shared_opcodes=true ;;
 571         *opcodes*) shared_opcodes=true ;;
 572         *) shared_opcodes=false ;;
 573         esac
 574         if test "${shared_opcodes}" = "true"; then
 575           # A shared libopcodes must be linked against libbfd.
 576           need_bfd=yes
 577         fi
 578         ;;
 579     esac
 580
 581     # Any other special object files needed ?
 582     case ${cpu_type} in
 583       fr30 | ip2k | m32r | openrisc)
 584         using_cgen=yes
 585         ;;
 586
 587       frv)
 588         using_cgen=yes
 589         ;;
 590       m68k)
 591         case ${extra_objects} in
 592         *m68k-parse.o*) ;;
 593         *) extra_objects="$extra_objects m68k-parse.o" ;;
 594         esac
 595         ;;
 596
 597       mips)
 598         echo ${extra_objects} | grep -s "itbl-parse.o"
 599         if test $? -ne 0 ; then
 600           extra_objects="$extra_objects itbl-parse.o"
 601         fi
 602
 603         echo ${extra_objects} | grep -s "itbl-lex.o"
 604         if test $? -ne 0 ; then
 605           extra_objects="$extra_objects itbl-lex.o"
 606         fi
 607
 608         echo ${extra_objects} | grep -s "itbl-ops.o"
 609         if test $? -ne 0 ; then
 610           extra_objects="$extra_objects itbl-ops.o"
 611         fi
 612         ;;
 613
 614       i386 | s390 | sparc)
 615         if test $this_target = $target ; then
 616           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 617         fi
 618         ;;
 619
 620       xstormy16)
 621         using_cgen=yes
 622         ;;
 623
 624       *)
 625         ;;
 626     esac
 627
 628     if test $using_cgen = yes ; then
 629         case "x${extra_objects}" in
 630         *cgen.o*) ;;
 631         *) extra_objects="$extra_objects cgen.o" ;;
 632         esac
 633     fi
 634
 635 # See if we really can support this configuration with the emulation code.
 636
 637     if test $this_target = $target ; then
 638       primary_bfd_gas=$bfd_gas
 639       obj_format=$fmt
 640       te_file=$em
 641
 642       if test $bfd_gas = no ; then
 643         # Can't support other configurations this way.
 644         break
 645       fi
 646     elif test $bfd_gas = no ; then
 647       # Can't support this configuration.
 648       break
 649     fi
 650
 651 # From target name and format, produce a list of supported emulations.
 652
 653     case ${generic_target}-${fmt} in
 654       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 655       mips*-*-linux*-*) case "$endian" in
 656                         big)    emulation="mipsbelf mipslelf mipself" ;;
 657                         *)      emulation="mipslelf mipsbelf mipself" ;;
 658                         esac ;;
 659       mips-*-lnews*-ecoff) ;;
 660       mips-*-*-ecoff)   case "$endian" in
 661                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 662                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 663                         esac ;;
 664       mips-*-*-elf)     case "$endian" in
 665                         big)    emulation="mipsbelf mipslelf mipself" ;;
 666                         *)      emulation="mipslelf mipsbelf mipself" ;;
 667                         esac ;;
 668       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 669       # i386-pc-pe-coff != i386-pc-coff.
 670       i386-*-pe-coff)   ;;
 671       # Uncommenting the next line will turn on support for i386 AOUT
 672       # for the default linux configuration
 673       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 674       #
 675       i386-*-aout)      emulation="i386aout" ;;
 676       i386-*-coff)      emulation="i386coff" ;;
 677       i386-*-elf)       emulation="i386elf" ;;
 678
 679       # Always all formats.  The first stated emulation becomes the default.
 680       cris-*-*aout*)    emulation="crisaout criself" ;;
 681       cris-*-*)         emulation="criself crisaout" ;;
 682     esac
 683
 684     emulations="$emulations $emulation"
 685
 686 done
 687
 688 # Turn on all targets if possible
 689 if test ${all_targets} = "yes"; then
 690   case ${target_cpu_type} in
 691   i386)
 692     case ${obj_format} in
 693     aout)
 694       emulations="$emulations i386coff i386elf"
 695       ;;
 696     coff)
 697       emulations="$emulations i386aout i386elf"
 698     ;;
 699     elf)
 700       emulations="$emulations i386aout i386coff"
 701       ;;
 702     esac
 703   ;;
 704   esac
 705 fi
 706
 707 # Assign floating point type.  Most processors with FP support
 708 # IEEE FP.  On those that don't support FP at all, usually IEEE
 709 # is emulated.
 710 case ${target_cpu} in
 711   vax | tahoe ) atof=${target_cpu} ;;
 712   pdp11)        atof=vax ;;
 713   *)            atof=ieee ;;
 714 esac
 715
 716 case "${obj_format}" in
 717   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 718 esac
 719
 720 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 721 cgen_cpu_prefix=""
 722 if test $using_cgen = yes ; then
 723   case ${target_cpu} in
 724     *) cgen_cpu_prefix=${target_cpu} ;;
 725   esac
 726   AC_SUBST(cgen_cpu_prefix)
 727   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 728 fi
 729
 730 dnl
 731 dnl Make sure the desired support files exist.
 732 dnl
 733
 734 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 735   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 736 fi
 737
 738 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 739   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 740 fi
 741
 742 case ${user_bfd_gas}-${primary_bfd_gas} in
 743   yes-yes | no-no)
 744     # We didn't override user's choice.
 745     ;;
 746   no-yes)
 747     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 748     ;;
 749   no-preferred)
 750     primary_bfd_gas=no
 751     ;;
 752   *-preferred)
 753     primary_bfd_gas=yes
 754     ;;
 755   yes-*)
 756     primary_bfd_gas=yes
 757     ;;
 758   -*)
 759     # User specified nothing.
 760     ;;
 761 esac
 762
 763 # Some COFF configurations want these random other flags set.
 764 case ${obj_format} in
 765   coff)
 766     case ${target_cpu_type} in
 767       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 768       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 769       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 770     esac
 771     ;;
 772 esac
 773
 774 # Getting this done right is going to be a bitch.  Each configuration specified
 775 # with --enable-targets=... should be checked for environment, format, cpu, and
 776 # bfd_gas setting.
 777 #
 778 # For each configuration, the necessary object file support code must be linked
 779 # in.  This might be only one, it might be up to four.  The necessary emulation
 780 # code needs to be provided, too.
 781 #
 782 # And then there's "--enable-targets=all"....
 783 #
 784 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 785
 786 formats="${obj_format}"
 787 emfiles=""
 788 EMULATIONS=""
 789 GAS_UNIQ(emulations)
 790 for em in . $emulations ; do
 791   case $em in
 792     .)  continue ;;
 793     mipsbelf | mipslelf | mipself)
 794         fmt=elf   file=mipself ;;
 795     mipsbecoff | mipslecoff | mipsecoff)
 796         fmt=ecoff file=mipsecoff ;;
 797     *coff)
 798         fmt=coff  file=$em ;;
 799     *aout)
 800         fmt=aout file=$em ;;
 801     *elf)
 802         fmt=elf file=$em ;;
 803   esac
 804   formats="$formats $fmt"
 805   emfiles="$emfiles e-$file.o"
 806   EMULATIONS="$EMULATIONS &$em,"
 807 done
 808 GAS_UNIQ(formats)
 809 GAS_UNIQ(emfiles)
 810 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 811   for fmt in $formats ; do
 812     case $fmt in
 813       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 814       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 815       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 816       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 817       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 818       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 819       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 820       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 821       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 822       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 823     esac
 824     extra_objects="$extra_objects obj-$fmt.o"
 825   done
 826   obj_format=multi
 827 fi
 828 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 829   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 830   # e-mips* has more than one emulation per file, e-i386* has just one at the
 831   # moment.  If only one emulation is specified, then don't define
 832   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 833   case "${obj_format}${emfiles}" in
 834     multi* | *mips*)
 835       extra_objects="$extra_objects $emfiles"
 836       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 837   esac
 838 fi
 839 AC_SUBST(extra_objects)
 840 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 841 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 842                    [Default emulation.])
 843
 844 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 845   yes-*-coff)   need_bfd=yes ;;
 846   no-*-coff)    need_bfd=yes
 847                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 848 esac
 849
 850 reject_dev_configs=yes
 851
 852 case ${reject_dev_configs}-${dev} in
 853   yes-yes) # Oops.
 854     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 855     ;;
 856 esac
 857
 858 AC_SUBST(target_cpu_type)
 859 AC_SUBST(obj_format)
 860 AC_SUBST(te_file)
 861 AC_SUBST(install_tooldir)
 862 AC_SUBST(atof)
 863 dnl AC_SUBST(emulation)
 864
 865 case "${primary_bfd_gas}" in
 866   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 867         need_bfd=yes ;;
 868 esac
 869
 870 # do we need the opcodes library?
 871 case "${need_opcodes}" in
 872 yes)
 873   OPCODES_LIB=../opcodes/libopcodes.la
 874   ;;
 875 esac
 876
 877 case "${need_bfd}" in
 878 yes)
 879   BFDLIB=../bfd/libbfd.la
 880   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 881   ;;
 882 esac
 883
 884 AC_SUBST(BFDLIB)
 885 AC_SUBST(OPCODES_LIB)
 886
 887 AC_SUBST(ALL_OBJ_DEPS)
 888
 889 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 890 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 891 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 892 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 893 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 894
 895 AC_PROG_CC
 896
 897 AC_PROG_YACC
 898 AM_PROG_LEX
 899
 900 ALL_LINGUAS="fr tr es"
 901 CY_GNU_GETTEXT
 902
 903 AM_MAINTAINER_MODE
 904 AC_EXEEXT
 905
 906 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 907
 908 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 909 # people who are not cross-compiling but are compiling cross-assemblers.
 910 AC_MSG_CHECKING(whether compiling a cross-assembler)
 911 if test "${host}" = "${target}"; then
 912   cross_gas=no
 913 else
 914   cross_gas=yes
 915   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 916 fi
 917 AC_MSG_RESULT($cross_gas)
 918
 919 dnl ansidecl.h will deal with const
 920 dnl AC_CONST
 921 AC_FUNC_ALLOCA
 922 AC_C_INLINE
 923
 924 # VMS doesn't have unlink.
 925 AC_CHECK_FUNCS(unlink remove, break)
 926
 927 # Some systems don't have sbrk().
 928 AC_CHECK_FUNCS(sbrk)
 929
 930 # do we need the math library?
 931 case "${need_libm}" in
 932 yes)
 933   AC_CHECK_LIBM
 934   AC_SUBST(LIBM)
 935   ;;
 936 esac
 937
 938 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 939 # enough, but on some of those systems, the assert macro relies on requoting
 940 # working properly!
 941 GAS_WORKING_ASSERT
 942
 943 # On some systems, the system header files may not declare malloc, realloc,
 944 # and free.  There are places where gas needs these functions to have been
 945 # declared -- such as when taking their addresses.
 946 gas_test_headers="
 947 #ifdef HAVE_MEMORY_H
 948 #include <memory.h>
 949 #endif
 950 #ifdef HAVE_STRING_H
 951 #include <string.h>
 952 #else
 953 #ifdef HAVE_STRINGS_H
 954 #include <strings.h>
 955 #endif
 956 #endif
 957 #ifdef HAVE_STDLIB_H
 958 #include <stdlib.h>
 959 #endif
 960 #ifdef HAVE_UNISTD_H
 961 #include <unistd.h>
 962 #endif
 963 "
 964 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 965 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 966 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 967 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 968 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 969
 970 # Does errno.h declare errno, or do we have to add a separate declaration
 971 # for it?
 972 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 973 #ifdef HAVE_ERRNO_H
 974 #include <errno.h>
 975 #endif
 976 ])
 977
 978 dnl This must come last.
 979
 980 dnl We used to make symlinks to files in the source directory, but now
 981 dnl we just use the right name for .c files, and create .h files in
 982 dnl the build directory which include the right .h file.  Make sure
 983 dnl the old symlinks don't exist, so that a reconfigure in an existing
 984 dnl directory behaves reasonably.
 985
 986 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 987 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 988  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 989  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 990  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 991  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 992  if test "x$cgen_cpu_prefix" != x ; then
 993    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 994  fi
 995
 996  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 997 [target_cpu_type=${target_cpu_type}
 998  cgen_cpu_prefix=${cgen_cpu_prefix}
 999  obj_format=${obj_format}
1000  te_file=${te_file}])