gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright 2012, 2013 Free Software Foundation
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 AC_PREREQ(2.59)
  24 AC_INIT
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 changequote(,)dnl
  35 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  36 changequote([,])dnl
  37 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  38
  39 AC_PROG_CC
  40 AC_GNU_SOURCE
  41 AC_USE_SYSTEM_EXTENSIONS
  42 ACX_LARGEFILE
  43
  44 LT_INIT
  45
  46 AC_ARG_ENABLE(targets,
  47 [  --enable-targets        alternative target configurations besides the primary],
  48 [case "${enableval}" in
  49   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  50             ;;
  51   no)       enable_targets= ;;
  52   *)        enable_targets=$enableval ;;
  53 esac])dnl
  54
  55 ac_checking=yes
  56 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  57   ac_checking=
  58 fi
  59 AC_ARG_ENABLE(checking,
  60 [  --enable-checking       enable run-time checks],
  61 [case "${enableval}" in
  62   no|none)  ac_checking= ;;
  63   *)        ac_checking=yes ;;
  64 esac])dnl
  65 if test x$ac_checking != x ; then
  66   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  67 fi
  68
  69 using_cgen=no
  70
  71 AM_BINUTILS_WARNINGS
  72
  73 # Generate a header file
  74 AC_CONFIG_HEADERS(config.h:config.in)
  75
  76 # PR 14072
  77 AH_VERBATIM([00_CONFIG_H_CHECK],
  78 [/* Check that config.h is #included before system headers
  79    (this works only for glibc, but that should be enough).  */
  80 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  81 #  error config.h must be #included before system headers
  82 #endif
  83 #define __CONFIG_H__ 1])
  84
  85 # If we are on a DOS filesystem, we must use gdb.ini rather than
  86 # .gdbinit.
  87 case "${host}" in
  88   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  89     GDBINIT="gdb.ini"
  90     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  91     ;;
  92   *)
  93     GDBINIT=".gdbinit"
  94     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  95     ;;
  96 esac
  97 AC_SUBST(GDBINIT)
  98
  99 #We need this for the host.  BOUT header is in host order.
 100 AC_C_BIGENDIAN
 101
 102 te_file=generic
 103
 104 # Makefile target for installing gas in $(tooldir)/bin.
 105 install_tooldir=install-exec-tooldir
 106
 107 canon_targets=""
 108 all_targets=no
 109 if test -n "$enable_targets" ; then
 110   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 111     if test $t = "all"; then
 112       all_targets=yes
 113       continue
 114     fi
 115     result=`$ac_config_sub $t 2>/dev/null`
 116     if test -n "$result" ; then
 117       canon_targets="$canon_targets $result"
 118 #    else
 119 #      # Permit "all", etc.  We don't support it yet though.
 120 #      canon_targets="$canon_targets $t"
 121     fi
 122   done
 123   GAS_UNIQ(canon_targets)
 124 fi
 125
 126 emulations=""
 127
 128 for this_target in $target $canon_targets ; do
 129
 130     targ=${this_target}
 131     . ${srcdir}/configure.tgt
 132
 133     case ${target_cpu} in
 134       crisv32)
 135         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 136                            [Default CRIS architecture.])
 137         ;;
 138     esac
 139
 140     if test ${this_target} = $target ; then
 141       target_cpu_type=${cpu_type}
 142     elif test ${target_cpu_type} != ${cpu_type} ; then
 143       continue
 144     fi
 145
 146     generic_target=${cpu_type}-${target_vendor}-${target_os}
 147     case ${generic_target} in
 148       i386-*-sco3.2v5*)
 149         if test ${this_target} = $target; then
 150           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 151         fi
 152         ;;
 153
 154       i386-*-msdosdjgpp* \
 155       | i386-*-go32* \
 156       | i386-go32-rtems*)
 157         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 158         ;;
 159
 160       i860-*-*)
 161         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 162         ;;
 163
 164       microblaze*)
 165         ;;
 166
 167       mips-sony-bsd*)
 168         ;;
 169       mips-*-bsd*)
 170         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 171         ;;
 172
 173 changequote(,)dnl
 174       ppc-*-aix[5-9].*)
 175 changequote([,])dnl
 176         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 177                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 178         ;;
 179       ppc-*-linux-*)
 180         case "$endian" in
 181           big)  ;;
 182           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 183         esac
 184         ;;
 185       ppc-*-solaris*)
 186         if test ${this_target} = $target; then
 187           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 188                     [Define if default target is PowerPC Solaris.])
 189         fi
 190         if test x${endian} = xbig; then
 191           AC_MSG_ERROR(Solaris must be configured little endian)
 192         fi
 193         ;;
 194
 195       sh*-*-symbianelf*)
 196         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 197         ;;
 198     esac
 199
 200     if test ${this_target} = $target ; then
 201       endian_def=
 202       if test x${endian} = xbig; then
 203         endian_def=1
 204       elif test x${endian} = xlittle; then
 205         endian_def=0
 206       fi
 207       if test x${endian_def} != x; then
 208         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 209                            [Define as 1 if big endian.])
 210       fi
 211     fi
 212
 213 # Other random stuff.
 214
 215     case ${cpu_type} in
 216       mips)
 217         # Set mips_cpu to the name of the default CPU.
 218         case ${target_cpu} in
 219           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 220             mips_cpu=from-abi
 221             ;;
 222           mipsisa32 | mipsisa32el)
 223             mips_cpu=mips32
 224             ;;
 225           mipsisa32r2 | mipsisa32r2el)
 226             mips_cpu=mips32r2
 227             ;;
 228           mipsisa64 | mipsisa64el)
 229             mips_cpu=mips64
 230             ;;
 231           mipsisa64r2 | mipsisa64r2el)
 232             mips_cpu=mips64r2
 233             ;;
 234           mipstx39 | mipstx39el)
 235             mips_cpu=r3900
 236             ;;
 237           mips64vr | mips64vrel)
 238             mips_cpu=vr4100
 239             ;;
 240           mipsisa32r2* | mipsisa64r2*)
 241 changequote(,)dnl
 242             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 243 changequote([,])dnl
 244             ;;
 245           mips64* | mipsisa64* | mipsisa32*)
 246 changequote(,)dnl
 247             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 248 changequote([,])dnl
 249             ;;
 250           mips*)
 251 changequote(,)dnl
 252             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 253 changequote([,])dnl
 254             ;;
 255           *)
 256             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 257             ;;
 258         esac
 259         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 260         # binaries.  It's a GNU extension that some OSes don't understand.
 261         # The value only matters on ELF targets.
 262         case ${target} in
 263           *-*-irix*)
 264             use_e_mips_abi_o32=0
 265             ;;
 266           *)
 267             use_e_mips_abi_o32=1
 268             ;;
 269         esac
 270         # Decide whether to generate 32-bit or 64-bit code by default.
 271         # Used to resolve -march=from-abi when an embedded ABI is selected.
 272         case ${target} in
 273           mips64*-*-* | mipsisa64*-*-*)
 274             mips_default_64bit=1
 275             ;;
 276           *)
 277             mips_default_64bit=0
 278             ;;
 279         esac
 280         # Decide which ABI to target by default.
 281         case ${target} in
 282           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* | mips64*-kfreebsd*-gnu)
 283             mips_default_abi=N32_ABI
 284             ;;
 285           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 286             mips_default_abi=O32_ABI
 287             ;;
 288           mips64*-openbsd*)
 289             mips_default_abi=N64_ABI
 290             ;;
 291           *)
 292             mips_default_abi=NO_ABI
 293             ;;
 294         esac
 295         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 296                            [Default CPU for MIPS targets. ])
 297         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 298                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 299         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 300                            [Generate 64-bit code by default on MIPS targets. ])
 301         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 302                            [Choose a default ABI for MIPS targets. ])
 303         ;;
 304     esac
 305
 306     # Do we need the opcodes library?
 307     case ${cpu_type} in
 308       vax | tic30)
 309         ;;
 310
 311       *)
 312         need_opcodes=yes
 313
 314         case "${enable_shared}" in
 315         yes) shared_opcodes=true ;;
 316         *opcodes*) shared_opcodes=true ;;
 317         *) shared_opcodes=false ;;
 318         esac
 319         ;;
 320     esac
 321
 322     # Any other special object files needed ?
 323     case ${cpu_type} in
 324
 325       bfin)
 326         echo ${extra_objects} | grep -s "bfin-parse.o"
 327         if test $? -ne 0 ; then
 328           extra_objects="$extra_objects bfin-parse.o"
 329         fi
 330
 331         echo ${extra_objects} | grep -s "bfin-lex-wrapper.o"
 332         if test $? -ne 0 ; then
 333           extra_objects="$extra_objects bfin-lex-wrapper.o"
 334         fi
 335         ;;
 336
 337       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | openrisc)
 338         using_cgen=yes
 339         ;;
 340
 341       m32c)
 342         using_cgen=yes
 343         ;;
 344       frv)
 345         using_cgen=yes
 346         ;;
 347       m68k)
 348         case ${extra_objects} in
 349         *m68k-parse.o*) ;;
 350         *) extra_objects="$extra_objects m68k-parse.o" ;;
 351         esac
 352         ;;
 353
 354       mep)
 355         using_cgen=yes
 356         ;;
 357
 358       mips)
 359         echo ${extra_objects} | grep -s "itbl-parse.o"
 360         if test $? -ne 0 ; then
 361           extra_objects="$extra_objects itbl-parse.o"
 362         fi
 363
 364         echo ${extra_objects} | grep -s "itbl-lex-wrapper.o"
 365         if test $? -ne 0 ; then
 366           extra_objects="$extra_objects itbl-lex-wrapper.o"
 367         fi
 368
 369         echo ${extra_objects} | grep -s "itbl-ops.o"
 370         if test $? -ne 0 ; then
 371           extra_objects="$extra_objects itbl-ops.o"
 372         fi
 373         ;;
 374
 375       mt)
 376         using_cgen=yes
 377         ;;
 378
 379       i386 | s390 | sparc)
 380         if test $this_target = $target ; then
 381           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 382         fi
 383         ;;
 384
 385       rl78)
 386         echo ${extra_objects} | grep -s "rl78-parse.o"
 387         if test $? -ne 0 ; then
 388           extra_objects="$extra_objects rl78-parse.o"
 389         fi
 390         ;;
 391
 392       rx)
 393         echo ${extra_objects} | grep -s "rx-parse.o"
 394         if test $? -ne 0 ; then
 395           extra_objects="$extra_objects rx-parse.o"
 396         fi
 397         ;;
 398
 399       xstormy16)
 400         using_cgen=yes
 401         ;;
 402
 403       xc16x)
 404         using_cgen=yes
 405         ;;
 406
 407       xtensa)
 408         echo ${extra_objects} | grep -s "xtensa-relax.o"
 409         if test $? -ne 0 ; then
 410           extra_objects="$extra_objects xtensa-relax.o"
 411         fi
 412         ;;
 413
 414       *)
 415         ;;
 416     esac
 417
 418     if test $using_cgen = yes ; then
 419         case "x${extra_objects}" in
 420         *cgen.o*) ;;
 421         *) extra_objects="$extra_objects cgen.o" ;;
 422         esac
 423     fi
 424
 425 # See if we really can support this configuration with the emulation code.
 426
 427     if test $this_target = $target ; then
 428       obj_format=$fmt
 429       te_file=$em
 430     fi
 431
 432    case ${te_file} in
 433       vms) extra_objects="$extra_objects te-vms.o" ;;
 434    esac
 435
 436 # From target name and format, produce a list of supported emulations.
 437
 438     case ${generic_target}-${fmt} in
 439       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 440       mips*-*-linux*-* | mips*-*-freebsd* | mips*-*-kfreebsd*-gnu)
 441                         case "$endian" in
 442                         big)    emulation="mipsbelf mipslelf mipself" ;;
 443                         *)      emulation="mipslelf mipsbelf mipself" ;;
 444                         esac ;;
 445       mips-*-lnews*-ecoff) ;;
 446       mips-*-*-ecoff)   case "$endian" in
 447                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 448                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 449                         esac ;;
 450       mips-*-*-elf)     case "$endian" in
 451                         big)    emulation="mipsbelf mipslelf mipself" ;;
 452                         *)      emulation="mipslelf mipsbelf mipself" ;;
 453                         esac ;;
 454       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 455       # i386-pc-pe-coff != i386-pc-coff.
 456       i386-*-pe-coff)   ;;
 457       # Uncommenting the next line will turn on support for i386 AOUT
 458       # for the default linux configuration
 459       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 460       #
 461       i386-*-aout)      emulation="i386aout" ;;
 462       i386-*-coff)      emulation="i386coff" ;;
 463       i386-*-elf)       emulation="i386elf" ;;
 464
 465       # Always all formats.  The first stated emulation becomes the default.
 466       cris-*-*aout*)    emulation="crisaout criself" ;;
 467       cris-*-*)         emulation="criself crisaout" ;;
 468     esac
 469
 470     emulations="$emulations $emulation"
 471
 472 done
 473
 474 # Turn on all targets if possible
 475 if test ${all_targets} = "yes"; then
 476   case ${target_cpu_type} in
 477   i386)
 478     case ${obj_format} in
 479     aout)
 480       emulations="$emulations i386coff i386elf"
 481       ;;
 482     coff)
 483       emulations="$emulations i386aout i386elf"
 484     ;;
 485     elf)
 486       emulations="$emulations i386aout i386coff"
 487       ;;
 488     esac
 489   ;;
 490   x86_64)
 491     case ${obj_format} in
 492     aout)
 493       emulations="$emulations i386coff i386elf"
 494       ;;
 495     coff)
 496       emulations="$emulations i386aout i386elf"
 497     ;;
 498     elf)
 499       emulations="$emulations i386aout i386coff"
 500       ;;
 501     esac
 502   ;;
 503   esac
 504 fi
 505
 506 # PE code has way too many macros tweaking behaviour
 507 case ${te_file} in
 508   pe*) emulations="" ;;
 509 esac
 510
 511 # Assign floating point type.  Most processors with FP support
 512 # IEEE FP.  On those that don't support FP at all, usually IEEE
 513 # is emulated.
 514 case ${target_cpu} in
 515   vax | pdp11 ) atof=vax ;;
 516   *)            atof=ieee ;;
 517 esac
 518
 519 case "${obj_format}" in
 520   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 521 esac
 522
 523 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 524 cgen_cpu_prefix=""
 525 if test $using_cgen = yes ; then
 526   case ${target_cpu} in
 527     *) cgen_cpu_prefix=${target_cpu} ;;
 528   esac
 529   AC_SUBST(cgen_cpu_prefix)
 530   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 531 fi
 532
 533 dnl
 534 dnl Make sure the desired support files exist.
 535 dnl
 536
 537 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 538   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 539 fi
 540
 541 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 542   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 543 fi
 544
 545 # Some COFF configurations want these random other flags set.
 546 case ${obj_format} in
 547   coff)
 548     case ${target_cpu_type} in
 549       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 550       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 551       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 552       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 553     esac
 554     ;;
 555 esac
 556
 557 # Getting this done right is going to be a bitch.  Each configuration specified
 558 # with --enable-targets=... should be checked for environment, format, cpu
 559 # setting.
 560 #
 561 # For each configuration, the necessary object file support code must be linked
 562 # in.  This might be only one, it might be up to four.  The necessary emulation
 563 # code needs to be provided, too.
 564 #
 565 # And then there's "--enable-targets=all"....
 566 #
 567 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 568
 569 formats="${obj_format}"
 570 emfiles=""
 571 EMULATIONS=""
 572 GAS_UNIQ(emulations)
 573 for em in . $emulations ; do
 574   case $em in
 575     .)  continue ;;
 576     mipsbelf | mipslelf | mipself)
 577         fmt=elf   file=mipself ;;
 578     mipsbecoff | mipslecoff | mipsecoff)
 579         fmt=ecoff file=mipsecoff ;;
 580     *coff)
 581         fmt=coff  file=$em ;;
 582     *aout)
 583         fmt=aout file=$em ;;
 584     *elf)
 585         fmt=elf file=$em ;;
 586   esac
 587   formats="$formats $fmt"
 588   emfiles="$emfiles e-$file.o"
 589   EMULATIONS="$EMULATIONS &$em,"
 590 done
 591 GAS_UNIQ(formats)
 592 GAS_UNIQ(emfiles)
 593 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 594   for fmt in $formats ; do
 595     case $fmt in
 596       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 597       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 598       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 599       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 600       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 601       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 602       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 603     esac
 604     extra_objects="$extra_objects obj-$fmt.o"
 605   done
 606   obj_format=multi
 607 fi
 608 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 609   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 610   # e-mips* has more than one emulation per file, e-i386* has just one at the
 611   # moment.  If only one emulation is specified, then don't define
 612   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 613   case "${obj_format}${emfiles}" in
 614     multi* | *mips*)
 615       extra_objects="$extra_objects $emfiles"
 616       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 617   esac
 618 fi
 619 AC_SUBST(extra_objects)
 620 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 621 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 622                    [Default emulation.])
 623
 624 reject_dev_configs=yes
 625
 626 case ${reject_dev_configs}-${dev} in
 627   yes-yes) # Oops.
 628     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 629     ;;
 630 esac
 631
 632 AC_SUBST(target_cpu_type)
 633 AC_SUBST(obj_format)
 634 AC_SUBST(te_file)
 635 AC_SUBST(install_tooldir)
 636 AC_SUBST(atof)
 637 dnl AC_SUBST(emulation)
 638
 639 # do we need the opcodes library?
 640 case "${need_opcodes}" in
 641 yes)
 642   OPCODES_LIB=../opcodes/libopcodes.la
 643   ;;
 644 esac
 645
 646 AC_SUBST(OPCODES_LIB)
 647
 648 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 649 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 650 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 651 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 652 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 653
 654 AC_PROG_YACC
 655 AM_PROG_LEX
 656
 657 ALL_LINGUAS="fr tr es rw id ru fi ja"
 658 ZW_GNU_GETTEXT_SISTER_DIR
 659 AM_PO_SUBDIRS
 660
 661 AM_MAINTAINER_MODE
 662 AM_CONDITIONAL(GENINSRC_NEVER, false)
 663 AC_EXEEXT
 664
 665 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 666 ACX_HEADER_STRING
 667
 668 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 669 # people who are not cross-compiling but are compiling cross-assemblers.
 670 AC_MSG_CHECKING(whether compiling a cross-assembler)
 671 if test "${host}" = "${target}"; then
 672   cross_gas=no
 673 else
 674   cross_gas=yes
 675   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 676 fi
 677 AC_MSG_RESULT($cross_gas)
 678
 679 dnl ansidecl.h will deal with const
 680 dnl AC_C_CONST
 681 AC_FUNC_ALLOCA
 682 AC_C_INLINE
 683
 684 # VMS doesn't have unlink.
 685 AC_CHECK_FUNCS(unlink remove, break)
 686 AC_CHECK_FUNCS(sbrk setlocale)
 687
 688 AM_LC_MESSAGES
 689
 690 # do we need the math library?
 691 case "${need_libm}" in
 692 yes)
 693   LT_LIB_M
 694   AC_SUBST(LIBM)
 695   ;;
 696 esac
 697
 698 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 699 # enough, but on some of those systems, the assert macro relies on requoting
 700 # working properly!
 701 GAS_WORKING_ASSERT
 702
 703 # On some systems, the system header files may not declare malloc, realloc,
 704 # and free.  There are places where gas needs these functions to have been
 705 # declared -- such as when taking their addresses.
 706 gas_test_headers="
 707 #ifdef HAVE_MEMORY_H
 708 #include <memory.h>
 709 #endif
 710 #ifdef HAVE_STRING_H
 711 #include <string.h>
 712 #else
 713 #ifdef HAVE_STRINGS_H
 714 #include <strings.h>
 715 #endif
 716 #endif
 717 #ifdef HAVE_STDLIB_H
 718 #include <stdlib.h>
 719 #endif
 720 #ifdef HAVE_UNISTD_H
 721 #include <unistd.h>
 722 #endif
 723 "
 724
 725 # Does errno.h declare errno, or do we have to add a separate declaration
 726 # for it?
 727 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 728 #ifdef HAVE_ERRNO_H
 729 #include <errno.h>
 730 #endif
 731 ])
 732
 733 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 734 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 735 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 736 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 737 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 738 if test $gas_cv_decl_getopt_unistd_h = yes; then
 739   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 740             [Is the prototype for getopt in <unistd.h> in the expected format?])
 741 fi
 742
 743 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 744 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 745 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 746 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 747 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 748 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 749
 750 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf])
 751
 752 BFD_BINARY_FOPEN
 753
 754 # Link in zlib if we can.  This allows us to write compressed debug sections.
 755 AM_ZLIB
 756
 757 # Support for VMS timestamps via cross compile
 758
 759 if test "$ac_cv_header_time_h" = yes; then
 760   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 761 fi
 762
 763 if test "$ac_cv_header_sys_stat_h" = yes; then
 764     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 765     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 766 fi
 767
 768
 769 dnl Required for html, pdf, install-pdf and install-html targets.
 770 AC_SUBST(datarootdir)
 771 AC_SUBST(docdir)
 772 AC_SUBST(htmldir)
 773 AC_SUBST(pdfdir)
 774
 775 dnl This must come last.
 776
 777 dnl We used to make symlinks to files in the source directory, but now
 778 dnl we just use the right name for .c files, and create .h files in
 779 dnl the build directory which include the right .h file.  Make sure
 780 dnl the old symlinks don't exist, so that a reconfigure in an existing
 781 dnl directory behaves reasonably.
 782
 783 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 784 AC_CONFIG_COMMANDS([default],
 785 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 786  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 787  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 788  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 789  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 790  if test "x$cgen_cpu_prefix" != x ; then
 791    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 792  fi],
 793 [target_cpu_type=${target_cpu_type}
 794  cgen_cpu_prefix=${cgen_cpu_prefix}
 795  obj_format=${obj_format}
 796  te_file=${te_file}])
 797
 798 AC_OUTPUT