gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright 2012 Free Software Foundation
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 AC_PREREQ(2.59)
  24 AC_INIT
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 changequote(,)dnl
  35 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  36 changequote([,])dnl
  37 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  38
  39 AC_PROG_CC
  40 AC_GNU_SOURCE
  41 AC_USE_SYSTEM_EXTENSIONS
  42 ACX_LARGEFILE
  43
  44 LT_INIT
  45
  46 AC_ARG_ENABLE(targets,
  47 [  --enable-targets        alternative target configurations besides the primary],
  48 [case "${enableval}" in
  49   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  50             ;;
  51   no)       enable_targets= ;;
  52   *)        enable_targets=$enableval ;;
  53 esac])dnl
  54
  55 ac_checking=yes
  56 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  57   ac_checking=
  58 fi
  59 AC_ARG_ENABLE(checking,
  60 [  --enable-checking       enable run-time checks],
  61 [case "${enableval}" in
  62   no|none)  ac_checking= ;;
  63   *)        ac_checking=yes ;;
  64 esac])dnl
  65 if test x$ac_checking != x ; then
  66   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  67 fi
  68
  69 using_cgen=no
  70
  71 AM_BINUTILS_WARNINGS
  72
  73 # Generate a header file
  74 AC_CONFIG_HEADERS(config.h:config.in)
  75
  76 # PR 14072
  77 AH_VERBATIM([00_CONFIG_H_CHECK],
  78 [/* Check that config.h is #included before system headers
  79    (this works only for glibc, but that should be enough).  */
  80 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  81 #  error config.h must be #included before system headers
  82 #endif
  83 #define __CONFIG_H__ 1])
  84
  85 # If we are on a DOS filesystem, we must use gdb.ini rather than
  86 # .gdbinit.
  87 case "${host}" in
  88   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  89     GDBINIT="gdb.ini"
  90     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  91     ;;
  92   *)
  93     GDBINIT=".gdbinit"
  94     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  95     ;;
  96 esac
  97 AC_SUBST(GDBINIT)
  98
  99 #We need this for the host.  BOUT header is in host order.
 100 AC_C_BIGENDIAN
 101
 102 te_file=generic
 103
 104 # Makefile target for installing gas in $(tooldir)/bin.
 105 install_tooldir=install-exec-tooldir
 106
 107 canon_targets=""
 108 all_targets=no
 109 if test -n "$enable_targets" ; then
 110   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 111     if test $t = "all"; then
 112       all_targets=yes
 113       continue
 114     fi
 115     result=`$ac_config_sub $t 2>/dev/null`
 116     if test -n "$result" ; then
 117       canon_targets="$canon_targets $result"
 118 #    else
 119 #      # Permit "all", etc.  We don't support it yet though.
 120 #      canon_targets="$canon_targets $t"
 121     fi
 122   done
 123   GAS_UNIQ(canon_targets)
 124 fi
 125
 126 emulations=""
 127
 128 for this_target in $target $canon_targets ; do
 129
 130     targ=${this_target}
 131     . ${srcdir}/configure.tgt
 132
 133     case ${target_cpu} in
 134       crisv32)
 135         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 136                            [Default CRIS architecture.])
 137         ;;
 138     esac
 139
 140     if test ${this_target} = $target ; then
 141       target_cpu_type=${cpu_type}
 142     elif test ${target_cpu_type} != ${cpu_type} ; then
 143       continue
 144     fi
 145
 146     generic_target=${cpu_type}-${target_vendor}-${target_os}
 147     case ${generic_target} in
 148       i386-*-sco3.2v5*)
 149         if test ${this_target} = $target; then
 150           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 151         fi
 152         ;;
 153
 154       i386-*-msdosdjgpp* \
 155       | i386-*-go32* \
 156       | i386-go32-rtems*)
 157         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 158         ;;
 159
 160       i860-*-*)
 161         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 162         ;;
 163
 164       microblaze*)
 165         ;;
 166
 167       mips-sony-bsd*)
 168         ;;
 169       mips-*-bsd*)
 170         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 171         ;;
 172
 173 changequote(,)dnl
 174       ppc-*-aix[5-9].*)
 175 changequote([,])dnl
 176         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 177                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 178         ;;
 179       ppc-*-linux-*)
 180         case "$endian" in
 181           big)  ;;
 182           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 183         esac
 184         ;;
 185       ppc-*-solaris*)
 186         if test ${this_target} = $target; then
 187           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 188                     [Define if default target is PowerPC Solaris.])
 189         fi
 190         if test x${endian} = xbig; then
 191           AC_MSG_ERROR(Solaris must be configured little endian)
 192         fi
 193         ;;
 194
 195       sh*-*-symbianelf*)
 196         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 197         ;;
 198     esac
 199
 200     if test ${this_target} = $target ; then
 201       endian_def=
 202       if test x${endian} = xbig; then
 203         endian_def=1
 204       elif test x${endian} = xlittle; then
 205         endian_def=0
 206       fi
 207       if test x${endian_def} != x; then
 208         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 209                            [Define as 1 if big endian.])
 210       fi
 211     fi
 212
 213 # Other random stuff.
 214
 215     case ${cpu_type} in
 216       mips)
 217         # Set mips_cpu to the name of the default CPU.
 218         case ${target_cpu} in
 219           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 220             mips_cpu=from-abi
 221             ;;
 222           mipsisa32 | mipsisa32el)
 223             mips_cpu=mips32
 224             ;;
 225           mipsisa32r2 | mipsisa32r2el)
 226             mips_cpu=mips32r2
 227             ;;
 228           mipsisa64 | mipsisa64el)
 229             mips_cpu=mips64
 230             ;;
 231           mipsisa64r2 | mipsisa64r2el)
 232             mips_cpu=mips64r2
 233             ;;
 234           mipstx39 | mipstx39el)
 235             mips_cpu=r3900
 236             ;;
 237           mips64vr | mips64vrel)
 238             mips_cpu=vr4100
 239             ;;
 240           mipsisa32r2* | mipsisa64r2*)
 241 changequote(,)dnl
 242             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 243 changequote([,])dnl
 244             ;;
 245           mips64* | mipsisa64* | mipsisa32*)
 246 changequote(,)dnl
 247             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 248 changequote([,])dnl
 249             ;;
 250           *)
 251             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 252             ;;
 253         esac
 254         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 255         # binaries.  It's a GNU extension that some OSes don't understand.
 256         # The value only matters on ELF targets.
 257         case ${target} in
 258           *-*-irix*)
 259             use_e_mips_abi_o32=0
 260             ;;
 261           *)
 262             use_e_mips_abi_o32=1
 263             ;;
 264         esac
 265         # Decide whether to generate 32-bit or 64-bit code by default.
 266         # Used to resolve -march=from-abi when an embedded ABI is selected.
 267         case ${target} in
 268           mips64*-*-* | mipsisa64*-*-*)
 269             mips_default_64bit=1
 270             ;;
 271           *)
 272             mips_default_64bit=0
 273             ;;
 274         esac
 275         # Decide which ABI to target by default.
 276         case ${target} in
 277           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* | mips64*-kfreebsd*-gnu)
 278             mips_default_abi=N32_ABI
 279             ;;
 280           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 281             mips_default_abi=O32_ABI
 282             ;;
 283           mips64*-openbsd*)
 284             mips_default_abi=N64_ABI
 285             ;;
 286           *)
 287             mips_default_abi=NO_ABI
 288             ;;
 289         esac
 290         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 291                            [Default CPU for MIPS targets. ])
 292         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 293                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 294         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 295                            [Generate 64-bit code by default on MIPS targets. ])
 296         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 297                            [Choose a default ABI for MIPS targets. ])
 298         ;;
 299     esac
 300
 301     # Do we need the opcodes library?
 302     case ${cpu_type} in
 303       vax | tic30)
 304         ;;
 305
 306       *)
 307         need_opcodes=yes
 308
 309         case "${enable_shared}" in
 310         yes) shared_opcodes=true ;;
 311         *opcodes*) shared_opcodes=true ;;
 312         *) shared_opcodes=false ;;
 313         esac
 314         ;;
 315     esac
 316
 317     # Any other special object files needed ?
 318     case ${cpu_type} in
 319
 320       bfin)
 321         echo ${extra_objects} | grep -s "bfin-parse.o"
 322         if test $? -ne 0 ; then
 323           extra_objects="$extra_objects bfin-parse.o"
 324         fi
 325
 326         echo ${extra_objects} | grep -s "bfin-lex-wrapper.o"
 327         if test $? -ne 0 ; then
 328           extra_objects="$extra_objects bfin-lex-wrapper.o"
 329         fi
 330         ;;
 331
 332       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | openrisc)
 333         using_cgen=yes
 334         ;;
 335
 336       m32c)
 337         using_cgen=yes
 338         ;;
 339       frv)
 340         using_cgen=yes
 341         ;;
 342       m68k)
 343         case ${extra_objects} in
 344         *m68k-parse.o*) ;;
 345         *) extra_objects="$extra_objects m68k-parse.o" ;;
 346         esac
 347         ;;
 348
 349       mep)
 350         using_cgen=yes
 351         ;;
 352
 353       mips)
 354         echo ${extra_objects} | grep -s "itbl-parse.o"
 355         if test $? -ne 0 ; then
 356           extra_objects="$extra_objects itbl-parse.o"
 357         fi
 358
 359         echo ${extra_objects} | grep -s "itbl-lex-wrapper.o"
 360         if test $? -ne 0 ; then
 361           extra_objects="$extra_objects itbl-lex-wrapper.o"
 362         fi
 363
 364         echo ${extra_objects} | grep -s "itbl-ops.o"
 365         if test $? -ne 0 ; then
 366           extra_objects="$extra_objects itbl-ops.o"
 367         fi
 368         ;;
 369
 370       mt)
 371         using_cgen=yes
 372         ;;
 373
 374       i386 | s390 | sparc)
 375         if test $this_target = $target ; then
 376           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 377         fi
 378         ;;
 379
 380       rl78)
 381         echo ${extra_objects} | grep -s "rl78-parse.o"
 382         if test $? -ne 0 ; then
 383           extra_objects="$extra_objects rl78-parse.o"
 384         fi
 385         ;;
 386
 387       rx)
 388         echo ${extra_objects} | grep -s "rx-parse.o"
 389         if test $? -ne 0 ; then
 390           extra_objects="$extra_objects rx-parse.o"
 391         fi
 392         ;;
 393
 394       xstormy16)
 395         using_cgen=yes
 396         ;;
 397
 398       xc16x)
 399         using_cgen=yes
 400         ;;
 401
 402       xtensa)
 403         echo ${extra_objects} | grep -s "xtensa-relax.o"
 404         if test $? -ne 0 ; then
 405           extra_objects="$extra_objects xtensa-relax.o"
 406         fi
 407         ;;
 408
 409       *)
 410         ;;
 411     esac
 412
 413     if test $using_cgen = yes ; then
 414         case "x${extra_objects}" in
 415         *cgen.o*) ;;
 416         *) extra_objects="$extra_objects cgen.o" ;;
 417         esac
 418     fi
 419
 420 # See if we really can support this configuration with the emulation code.
 421
 422     if test $this_target = $target ; then
 423       obj_format=$fmt
 424       te_file=$em
 425     fi
 426
 427    case ${te_file} in
 428       vms) extra_objects="$extra_objects te-vms.o" ;;
 429    esac
 430
 431 # From target name and format, produce a list of supported emulations.
 432
 433     case ${generic_target}-${fmt} in
 434       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 435       mips*-*-linux*-* | mips*-*-freebsd* | mips*-*-kfreebsd*-gnu)
 436                         case "$endian" in
 437                         big)    emulation="mipsbelf mipslelf mipself" ;;
 438                         *)      emulation="mipslelf mipsbelf mipself" ;;
 439                         esac ;;
 440       mips-*-lnews*-ecoff) ;;
 441       mips-*-*-ecoff)   case "$endian" in
 442                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 443                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 444                         esac ;;
 445       mips-*-*-elf)     case "$endian" in
 446                         big)    emulation="mipsbelf mipslelf mipself" ;;
 447                         *)      emulation="mipslelf mipsbelf mipself" ;;
 448                         esac ;;
 449       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 450       # i386-pc-pe-coff != i386-pc-coff.
 451       i386-*-pe-coff)   ;;
 452       # Uncommenting the next line will turn on support for i386 AOUT
 453       # for the default linux configuration
 454       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 455       #
 456       i386-*-aout)      emulation="i386aout" ;;
 457       i386-*-coff)      emulation="i386coff" ;;
 458       i386-*-elf)       emulation="i386elf" ;;
 459
 460       # Always all formats.  The first stated emulation becomes the default.
 461       cris-*-*aout*)    emulation="crisaout criself" ;;
 462       cris-*-*)         emulation="criself crisaout" ;;
 463     esac
 464
 465     emulations="$emulations $emulation"
 466
 467 done
 468
 469 # Turn on all targets if possible
 470 if test ${all_targets} = "yes"; then
 471   case ${target_cpu_type} in
 472   i386)
 473     case ${obj_format} in
 474     aout)
 475       emulations="$emulations i386coff i386elf"
 476       ;;
 477     coff)
 478       emulations="$emulations i386aout i386elf"
 479     ;;
 480     elf)
 481       emulations="$emulations i386aout i386coff"
 482       ;;
 483     esac
 484   ;;
 485   x86_64)
 486     case ${obj_format} in
 487     aout)
 488       emulations="$emulations i386coff i386elf"
 489       ;;
 490     coff)
 491       emulations="$emulations i386aout i386elf"
 492     ;;
 493     elf)
 494       emulations="$emulations i386aout i386coff"
 495       ;;
 496     esac
 497   ;;
 498   esac
 499 fi
 500
 501 # PE code has way too many macros tweaking behaviour
 502 case ${te_file} in
 503   pe*) emulations="" ;;
 504 esac
 505
 506 # Assign floating point type.  Most processors with FP support
 507 # IEEE FP.  On those that don't support FP at all, usually IEEE
 508 # is emulated.
 509 case ${target_cpu} in
 510   vax | pdp11 ) atof=vax ;;
 511   *)            atof=ieee ;;
 512 esac
 513
 514 case "${obj_format}" in
 515   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 516 esac
 517
 518 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 519 cgen_cpu_prefix=""
 520 if test $using_cgen = yes ; then
 521   case ${target_cpu} in
 522     *) cgen_cpu_prefix=${target_cpu} ;;
 523   esac
 524   AC_SUBST(cgen_cpu_prefix)
 525   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 526 fi
 527
 528 dnl
 529 dnl Make sure the desired support files exist.
 530 dnl
 531
 532 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 533   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 534 fi
 535
 536 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 537   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 538 fi
 539
 540 # Some COFF configurations want these random other flags set.
 541 case ${obj_format} in
 542   coff)
 543     case ${target_cpu_type} in
 544       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 545       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 546       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 547       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 548     esac
 549     ;;
 550 esac
 551
 552 # Getting this done right is going to be a bitch.  Each configuration specified
 553 # with --enable-targets=... should be checked for environment, format, cpu
 554 # setting.
 555 #
 556 # For each configuration, the necessary object file support code must be linked
 557 # in.  This might be only one, it might be up to four.  The necessary emulation
 558 # code needs to be provided, too.
 559 #
 560 # And then there's "--enable-targets=all"....
 561 #
 562 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 563
 564 formats="${obj_format}"
 565 emfiles=""
 566 EMULATIONS=""
 567 GAS_UNIQ(emulations)
 568 for em in . $emulations ; do
 569   case $em in
 570     .)  continue ;;
 571     mipsbelf | mipslelf | mipself)
 572         fmt=elf   file=mipself ;;
 573     mipsbecoff | mipslecoff | mipsecoff)
 574         fmt=ecoff file=mipsecoff ;;
 575     *coff)
 576         fmt=coff  file=$em ;;
 577     *aout)
 578         fmt=aout file=$em ;;
 579     *elf)
 580         fmt=elf file=$em ;;
 581   esac
 582   formats="$formats $fmt"
 583   emfiles="$emfiles e-$file.o"
 584   EMULATIONS="$EMULATIONS &$em,"
 585 done
 586 GAS_UNIQ(formats)
 587 GAS_UNIQ(emfiles)
 588 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 589   for fmt in $formats ; do
 590     case $fmt in
 591       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 592       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 593       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 594       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 595       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 596       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 597       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 598     esac
 599     extra_objects="$extra_objects obj-$fmt.o"
 600   done
 601   obj_format=multi
 602 fi
 603 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 604   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 605   # e-mips* has more than one emulation per file, e-i386* has just one at the
 606   # moment.  If only one emulation is specified, then don't define
 607   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 608   case "${obj_format}${emfiles}" in
 609     multi* | *mips*)
 610       extra_objects="$extra_objects $emfiles"
 611       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 612   esac
 613 fi
 614 AC_SUBST(extra_objects)
 615 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 616 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 617                    [Default emulation.])
 618
 619 reject_dev_configs=yes
 620
 621 case ${reject_dev_configs}-${dev} in
 622   yes-yes) # Oops.
 623     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 624     ;;
 625 esac
 626
 627 AC_SUBST(target_cpu_type)
 628 AC_SUBST(obj_format)
 629 AC_SUBST(te_file)
 630 AC_SUBST(install_tooldir)
 631 AC_SUBST(atof)
 632 dnl AC_SUBST(emulation)
 633
 634 # do we need the opcodes library?
 635 case "${need_opcodes}" in
 636 yes)
 637   OPCODES_LIB=../opcodes/libopcodes.la
 638   ;;
 639 esac
 640
 641 AC_SUBST(OPCODES_LIB)
 642
 643 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 644 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 645 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 646 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 647 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 648
 649 AC_PROG_YACC
 650 AM_PROG_LEX
 651
 652 ALL_LINGUAS="fr tr es rw id ru fi ja"
 653 ZW_GNU_GETTEXT_SISTER_DIR
 654 AM_PO_SUBDIRS
 655
 656 AM_MAINTAINER_MODE
 657 AM_CONDITIONAL(GENINSRC_NEVER, false)
 658 AC_EXEEXT
 659
 660 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 661 ACX_HEADER_STRING
 662
 663 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 664 # people who are not cross-compiling but are compiling cross-assemblers.
 665 AC_MSG_CHECKING(whether compiling a cross-assembler)
 666 if test "${host}" = "${target}"; then
 667   cross_gas=no
 668 else
 669   cross_gas=yes
 670   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 671 fi
 672 AC_MSG_RESULT($cross_gas)
 673
 674 dnl ansidecl.h will deal with const
 675 dnl AC_C_CONST
 676 AC_FUNC_ALLOCA
 677 AC_C_INLINE
 678
 679 # VMS doesn't have unlink.
 680 AC_CHECK_FUNCS(unlink remove, break)
 681 AC_CHECK_FUNCS(sbrk setlocale)
 682
 683 AM_LC_MESSAGES
 684
 685 # do we need the math library?
 686 case "${need_libm}" in
 687 yes)
 688   LT_LIB_M
 689   AC_SUBST(LIBM)
 690   ;;
 691 esac
 692
 693 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 694 # enough, but on some of those systems, the assert macro relies on requoting
 695 # working properly!
 696 GAS_WORKING_ASSERT
 697
 698 # On some systems, the system header files may not declare malloc, realloc,
 699 # and free.  There are places where gas needs these functions to have been
 700 # declared -- such as when taking their addresses.
 701 gas_test_headers="
 702 #ifdef HAVE_MEMORY_H
 703 #include <memory.h>
 704 #endif
 705 #ifdef HAVE_STRING_H
 706 #include <string.h>
 707 #else
 708 #ifdef HAVE_STRINGS_H
 709 #include <strings.h>
 710 #endif
 711 #endif
 712 #ifdef HAVE_STDLIB_H
 713 #include <stdlib.h>
 714 #endif
 715 #ifdef HAVE_UNISTD_H
 716 #include <unistd.h>
 717 #endif
 718 "
 719
 720 # Does errno.h declare errno, or do we have to add a separate declaration
 721 # for it?
 722 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 723 #ifdef HAVE_ERRNO_H
 724 #include <errno.h>
 725 #endif
 726 ])
 727
 728 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 729 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 730 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 731 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 732 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 733 if test $gas_cv_decl_getopt_unistd_h = yes; then
 734   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 735             [Is the prototype for getopt in <unistd.h> in the expected format?])
 736 fi
 737
 738 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 739 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 740 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 741 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 742 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 743 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 744
 745 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf])
 746
 747 BFD_BINARY_FOPEN
 748
 749 # Link in zlib if we can.  This allows us to write compressed debug sections.
 750 AM_ZLIB
 751
 752 # Support for VMS timestamps via cross compile
 753
 754 if test "$ac_cv_header_time_h" = yes; then
 755   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 756 fi
 757
 758 if test "$ac_cv_header_sys_stat_h" = yes; then
 759     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 760     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 761 fi
 762
 763
 764 dnl Required for html, pdf, install-pdf and install-html targets.
 765 AC_SUBST(datarootdir)
 766 AC_SUBST(docdir)
 767 AC_SUBST(htmldir)
 768 AC_SUBST(pdfdir)
 769
 770 dnl This must come last.
 771
 772 dnl We used to make symlinks to files in the source directory, but now
 773 dnl we just use the right name for .c files, and create .h files in
 774 dnl the build directory which include the right .h file.  Make sure
 775 dnl the old symlinks don't exist, so that a reconfigure in an existing
 776 dnl directory behaves reasonably.
 777
 778 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 779 AC_CONFIG_COMMANDS([default],
 780 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 781  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 782  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 783  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 784  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 785  if test "x$cgen_cpu_prefix" != x ; then
 786    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 787  fi],
 788 [target_cpu_type=${target_cpu_type}
 789  cgen_cpu_prefix=${cgen_cpu_prefix}
 790  obj_format=${obj_format}
 791  te_file=${te_file}])
 792
 793 AC_OUTPUT