gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 AM_BINUTILS_WARNINGS
  52
  53 # Generate a header file
  54 AM_CONFIG_HEADER(config.h:config.in)
  55
  56 # If we are on a DOS filesystem, we must use gdb.ini rather than
  57 # .gdbinit.
  58 case "${host}" in
  59   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  60     GDBINIT="gdb.ini"
  61     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  62     ;;
  63   *)
  64     GDBINIT=".gdbinit"
  65     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  66     ;;
  67 esac
  68 AC_SUBST(GDBINIT)
  69
  70 #We need this for the host.  BOUT header is in host order.
  71 AC_C_BIGENDIAN
  72
  73 te_file=generic
  74
  75 # Makefile target for installing gas in $(tooldir)/bin.
  76 install_tooldir=install-exec-tooldir
  77
  78 canon_targets=""
  79 all_targets=no
  80 if test -n "$enable_targets" ; then
  81   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  82     if test $t = "all"; then
  83       all_targets=yes
  84       continue
  85     fi
  86     result=`$ac_config_sub $t 2>/dev/null`
  87     if test -n "$result" ; then
  88       canon_targets="$canon_targets $result"
  89 #    else
  90 #      # Permit "all", etc.  We don't support it yet though.
  91 #      canon_targets="$canon_targets $t"
  92     fi
  93   done
  94   GAS_UNIQ(canon_targets)
  95 fi
  96
  97 emulations=""
  98
  99 for this_target in $target $canon_targets ; do
 100
 101     targ=${this_target}
 102     . ${srcdir}/configure.tgt
 103
 104     case ${target_cpu} in
 105       crisv32)
 106         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 107                            [Default CRIS architecture.])
 108         ;;
 109     esac
 110
 111     if test ${this_target} = $target ; then
 112       target_cpu_type=${cpu_type}
 113     elif test ${target_cpu_type} != ${cpu_type} ; then
 114       continue
 115     fi
 116
 117     generic_target=${cpu_type}-${target_vendor}-${target_os}
 118     case ${generic_target} in
 119       i386-*-sco3.2v5*)
 120         if test ${this_target} = $target; then
 121           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 122         fi
 123         ;;
 124
 125       i386-*-msdosdjgpp* \
 126       | i386-*-go32* \
 127       | i386-go32-rtems*)
 128         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 129         ;;
 130
 131       i860-*-*)
 132         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 133         ;;
 134
 135       mips-sony-bsd*)
 136         ;;
 137       mips-*-bsd*)
 138         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 139         ;;
 140
 141       ppc-*-aix5.*)
 142         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 143                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 144         ;;
 145       ppc-*-linux-*)
 146         case "$endian" in
 147           big)  ;;
 148           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 149         esac
 150         ;;
 151       ppc-*-solaris*)
 152         if test ${this_target} = $target; then
 153           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 154                     [Define if default target is PowerPC Solaris.])
 155         fi
 156         if test x${endian} = xbig; then
 157           AC_MSG_ERROR(Solaris must be configured little endian)
 158         fi
 159         ;;
 160
 161       sh*-*-symbianelf*)
 162         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 163         ;;
 164     esac
 165
 166     if test ${this_target} = $target ; then
 167       endian_def=
 168       if test x${endian} = xbig; then
 169         endian_def=1
 170       elif test x${endian} = xlittle; then
 171         endian_def=0
 172       fi
 173       if test x${endian_def} != x; then
 174         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 175                            [Define as 1 if big endian.])
 176       fi
 177     fi
 178
 179 # Other random stuff.
 180
 181     case ${cpu_type} in
 182       mips)
 183         # Set mips_cpu to the name of the default CPU.
 184         case ${target_cpu} in
 185           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 186             mips_cpu=from-abi
 187             ;;
 188           mipsisa32 | mipsisa32el)
 189             mips_cpu=mips32
 190             ;;
 191           mipsisa32r2 | mipsisa32r2el)
 192             mips_cpu=mips32r2
 193             ;;
 194           mipsisa64 | mipsisa64el)
 195             mips_cpu=mips64
 196             ;;
 197           mipsisa64r2 | mipsisa64r2el)
 198             mips_cpu=mips64r2
 199             ;;
 200           mipstx39 | mipstx39el)
 201             mips_cpu=r3900
 202             ;;
 203           mips64vr | mips64vrel)
 204             mips_cpu=vr4100
 205             ;;
 206           mipsisa32r2* | mipsisa64r2*)
 207 changequote(,)dnl
 208             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 209 changequote([,])dnl
 210             ;;
 211           mips64* | mipsisa64* | mipsisa32*)
 212 changequote(,)dnl
 213             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 214 changequote([,])dnl
 215             ;;
 216           *)
 217             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 218             ;;
 219         esac
 220         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 221         # binaries.  It's a GNU extension that some OSes don't understand.
 222         # The value only matters on ELF targets.
 223         case ${target} in
 224           *-*-irix*)
 225             use_e_mips_abi_o32=0
 226             ;;
 227           *)
 228             use_e_mips_abi_o32=1
 229             ;;
 230         esac
 231         # Decide whether to generate 32-bit or 64-bit code by default.
 232         # Used to resolve -march=from-abi when an embedded ABI is selected.
 233         case ${target} in
 234           mips64*-*-* | mipsisa64*-*-*)
 235             mips_default_64bit=1
 236             ;;
 237           *)
 238             mips_default_64bit=0
 239             ;;
 240         esac
 241         # Decide which ABI to target by default.
 242         case ${target} in
 243           mips64*-linux* | mips-sgi-irix6*)
 244             mips_default_abi=N32_ABI
 245             ;;
 246           mips*-linux*)
 247             mips_default_abi=O32_ABI
 248             ;;
 249           mips64*-openbsd*)
 250             mips_default_abi=N64_ABI
 251             ;;
 252           *)
 253             mips_default_abi=NO_ABI
 254             ;;
 255         esac
 256         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 257                            [Default CPU for MIPS targets. ])
 258         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 259                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 260         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 261                            [Generate 64-bit code by default on MIPS targets. ])
 262         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 263                            [Choose a default ABI for MIPS targets. ])
 264         ;;
 265     esac
 266
 267     # Do we need the opcodes library?
 268     case ${cpu_type} in
 269       vax | i386 | tic30)
 270         ;;
 271
 272       *)
 273         need_opcodes=yes
 274
 275         case "${enable_shared}" in
 276         yes) shared_opcodes=true ;;
 277         *opcodes*) shared_opcodes=true ;;
 278         *) shared_opcodes=false ;;
 279         esac
 280         if test "${shared_opcodes}" = "true"; then
 281           # A shared libopcodes must be linked against libbfd.
 282           need_bfd=yes
 283         fi
 284         ;;
 285     esac
 286
 287     # Any other special object files needed ?
 288     case ${cpu_type} in
 289       fr30 | ip2k | iq2000 | m32r | openrisc)
 290         using_cgen=yes
 291         ;;
 292
 293       frv)
 294         using_cgen=yes
 295         ;;
 296       m68k)
 297         case ${extra_objects} in
 298         *m68k-parse.o*) ;;
 299         *) extra_objects="$extra_objects m68k-parse.o" ;;
 300         esac
 301         ;;
 302
 303       mips)
 304         echo ${extra_objects} | grep -s "itbl-parse.o"
 305         if test $? -ne 0 ; then
 306           extra_objects="$extra_objects itbl-parse.o"
 307         fi
 308
 309         echo ${extra_objects} | grep -s "itbl-lex.o"
 310         if test $? -ne 0 ; then
 311           extra_objects="$extra_objects itbl-lex.o"
 312         fi
 313
 314         echo ${extra_objects} | grep -s "itbl-ops.o"
 315         if test $? -ne 0 ; then
 316           extra_objects="$extra_objects itbl-ops.o"
 317         fi
 318         ;;
 319
 320       i386 | s390 | sparc)
 321         if test $this_target = $target ; then
 322           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 323         fi
 324         ;;
 325
 326       xstormy16)
 327         using_cgen=yes
 328         ;;
 329
 330       xtensa)
 331         echo ${extra_objects} | grep -s "xtensa-relax.o"
 332         if test $? -ne 0 ; then
 333           extra_objects="$extra_objects xtensa-relax.o"
 334         fi
 335         ;;
 336
 337       *)
 338         ;;
 339     esac
 340
 341     if test $using_cgen = yes ; then
 342         case "x${extra_objects}" in
 343         *cgen.o*) ;;
 344         *) extra_objects="$extra_objects cgen.o" ;;
 345         esac
 346     fi
 347
 348 # See if we really can support this configuration with the emulation code.
 349
 350     if test $this_target = $target ; then
 351       primary_bfd_gas=$bfd_gas
 352       obj_format=$fmt
 353       te_file=$em
 354
 355       if test $bfd_gas = no ; then
 356         # Can't support other configurations this way.
 357         break
 358       fi
 359     elif test $bfd_gas = no ; then
 360       # Can't support this configuration.
 361       break
 362     fi
 363
 364 # From target name and format, produce a list of supported emulations.
 365
 366     case ${generic_target}-${fmt} in
 367       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 368       mips*-*-linux*-*) case "$endian" in
 369                         big)    emulation="mipsbelf mipslelf mipself" ;;
 370                         *)      emulation="mipslelf mipsbelf mipself" ;;
 371                         esac ;;
 372       mips-*-lnews*-ecoff) ;;
 373       mips-*-*-ecoff)   case "$endian" in
 374                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 375                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 376                         esac ;;
 377       mips-*-*-elf)     case "$endian" in
 378                         big)    emulation="mipsbelf mipslelf mipself" ;;
 379                         *)      emulation="mipslelf mipsbelf mipself" ;;
 380                         esac ;;
 381       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 382       # i386-pc-pe-coff != i386-pc-coff.
 383       i386-*-pe-coff)   ;;
 384       # Uncommenting the next line will turn on support for i386 AOUT
 385       # for the default linux configuration
 386       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 387       #
 388       i386-*-aout)      emulation="i386aout" ;;
 389       i386-*-coff)      emulation="i386coff" ;;
 390       i386-*-elf)       emulation="i386elf" ;;
 391
 392       # Always all formats.  The first stated emulation becomes the default.
 393       cris-*-*aout*)    emulation="crisaout criself" ;;
 394       cris-*-*)         emulation="criself crisaout" ;;
 395     esac
 396
 397     emulations="$emulations $emulation"
 398
 399 done
 400
 401 # Turn on all targets if possible
 402 if test ${all_targets} = "yes"; then
 403   case ${target_cpu_type} in
 404   i386)
 405     case ${obj_format} in
 406     aout)
 407       emulations="$emulations i386coff i386elf"
 408       ;;
 409     coff)
 410       emulations="$emulations i386aout i386elf"
 411     ;;
 412     elf)
 413       emulations="$emulations i386aout i386coff"
 414       ;;
 415     esac
 416   ;;
 417   esac
 418 fi
 419
 420 # Assign floating point type.  Most processors with FP support
 421 # IEEE FP.  On those that don't support FP at all, usually IEEE
 422 # is emulated.
 423 case ${target_cpu} in
 424   vax | tahoe ) atof=${target_cpu} ;;
 425   pdp11)        atof=vax ;;
 426   *)            atof=ieee ;;
 427 esac
 428
 429 case "${obj_format}" in
 430   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 431 esac
 432
 433 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 434 cgen_cpu_prefix=""
 435 if test $using_cgen = yes ; then
 436   case ${target_cpu} in
 437     *) cgen_cpu_prefix=${target_cpu} ;;
 438   esac
 439   AC_SUBST(cgen_cpu_prefix)
 440   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 441 fi
 442
 443 dnl
 444 dnl Make sure the desired support files exist.
 445 dnl
 446
 447 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 448   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 449 fi
 450
 451 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 452   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 453 fi
 454
 455 case ${user_bfd_gas}-${primary_bfd_gas} in
 456   yes-yes | no-no)
 457     # We didn't override user's choice.
 458     ;;
 459   no-yes)
 460     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 461     ;;
 462   no-preferred)
 463     primary_bfd_gas=no
 464     ;;
 465   *-preferred)
 466     primary_bfd_gas=yes
 467     ;;
 468   yes-*)
 469     primary_bfd_gas=yes
 470     ;;
 471   -*)
 472     # User specified nothing.
 473     ;;
 474 esac
 475
 476 # Some COFF configurations want these random other flags set.
 477 case ${obj_format} in
 478   coff)
 479     case ${target_cpu_type} in
 480       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 481       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 482       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 483     esac
 484     ;;
 485 esac
 486
 487 # Getting this done right is going to be a bitch.  Each configuration specified
 488 # with --enable-targets=... should be checked for environment, format, cpu, and
 489 # bfd_gas setting.
 490 #
 491 # For each configuration, the necessary object file support code must be linked
 492 # in.  This might be only one, it might be up to four.  The necessary emulation
 493 # code needs to be provided, too.
 494 #
 495 # And then there's "--enable-targets=all"....
 496 #
 497 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 498
 499 formats="${obj_format}"
 500 emfiles=""
 501 EMULATIONS=""
 502 GAS_UNIQ(emulations)
 503 for em in . $emulations ; do
 504   case $em in
 505     .)  continue ;;
 506     mipsbelf | mipslelf | mipself)
 507         fmt=elf   file=mipself ;;
 508     mipsbecoff | mipslecoff | mipsecoff)
 509         fmt=ecoff file=mipsecoff ;;
 510     *coff)
 511         fmt=coff  file=$em ;;
 512     *aout)
 513         fmt=aout file=$em ;;
 514     *elf)
 515         fmt=elf file=$em ;;
 516   esac
 517   formats="$formats $fmt"
 518   emfiles="$emfiles e-$file.o"
 519   EMULATIONS="$EMULATIONS &$em,"
 520 done
 521 GAS_UNIQ(formats)
 522 GAS_UNIQ(emfiles)
 523 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 524   for fmt in $formats ; do
 525     case $fmt in
 526       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 527       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 528       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 529       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 530       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 531       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 532       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 533       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 534       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 535     esac
 536     extra_objects="$extra_objects obj-$fmt.o"
 537   done
 538   obj_format=multi
 539 fi
 540 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 541   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 542   # e-mips* has more than one emulation per file, e-i386* has just one at the
 543   # moment.  If only one emulation is specified, then don't define
 544   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 545   case "${obj_format}${emfiles}" in
 546     multi* | *mips*)
 547       extra_objects="$extra_objects $emfiles"
 548       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 549   esac
 550 fi
 551 AC_SUBST(extra_objects)
 552 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 553 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 554                    [Default emulation.])
 555
 556 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 557   yes-*-coff)   need_bfd=yes ;;
 558   no-*-coff)    need_bfd=yes
 559                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 560 esac
 561
 562 reject_dev_configs=yes
 563
 564 case ${reject_dev_configs}-${dev} in
 565   yes-yes) # Oops.
 566     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 567     ;;
 568 esac
 569
 570 AC_SUBST(target_cpu_type)
 571 AC_SUBST(obj_format)
 572 AC_SUBST(te_file)
 573 AC_SUBST(install_tooldir)
 574 AC_SUBST(atof)
 575 dnl AC_SUBST(emulation)
 576
 577 case "${primary_bfd_gas}" in
 578   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 579         need_bfd=yes ;;
 580 esac
 581
 582 # do we need the opcodes library?
 583 case "${need_opcodes}" in
 584 yes)
 585   OPCODES_LIB=../opcodes/libopcodes.la
 586   ;;
 587 esac
 588
 589 case "${need_bfd}" in
 590 yes)
 591   BFDLIB=../bfd/libbfd.la
 592   BFDVER_H=../bfd/bfdver.h
 593   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 594   ;;
 595 esac
 596
 597 AC_SUBST(BFDLIB)
 598 AC_SUBST(OPCODES_LIB)
 599
 600 AC_SUBST(BFDVER_H)
 601 AC_SUBST(ALL_OBJ_DEPS)
 602
 603 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 604 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 605 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 606 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 607 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 608
 609 AC_PROG_CC
 610
 611 AC_PROG_YACC
 612 AM_PROG_LEX
 613
 614 ALL_LINGUAS="fr tr es rw"
 615 CY_GNU_GETTEXT
 616
 617 AM_MAINTAINER_MODE
 618 AC_EXEEXT
 619
 620 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 621
 622 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 623 # people who are not cross-compiling but are compiling cross-assemblers.
 624 AC_MSG_CHECKING(whether compiling a cross-assembler)
 625 if test "${host}" = "${target}"; then
 626   cross_gas=no
 627 else
 628   cross_gas=yes
 629   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 630 fi
 631 AC_MSG_RESULT($cross_gas)
 632
 633 dnl ansidecl.h will deal with const
 634 dnl AC_CONST
 635 AC_FUNC_ALLOCA
 636 AC_C_INLINE
 637
 638 # VMS doesn't have unlink.
 639 AC_CHECK_FUNCS(unlink remove, break)
 640
 641 # Some systems don't have sbrk().
 642 AC_CHECK_FUNCS(sbrk)
 643
 644 # do we need the math library?
 645 case "${need_libm}" in
 646 yes)
 647   AC_CHECK_LIBM
 648   AC_SUBST(LIBM)
 649   ;;
 650 esac
 651
 652 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 653 # enough, but on some of those systems, the assert macro relies on requoting
 654 # working properly!
 655 GAS_WORKING_ASSERT
 656
 657 # On some systems, the system header files may not declare malloc, realloc,
 658 # and free.  There are places where gas needs these functions to have been
 659 # declared -- such as when taking their addresses.
 660 gas_test_headers="
 661 #ifdef HAVE_MEMORY_H
 662 #include <memory.h>
 663 #endif
 664 #ifdef HAVE_STRING_H
 665 #include <string.h>
 666 #else
 667 #ifdef HAVE_STRINGS_H
 668 #include <strings.h>
 669 #endif
 670 #endif
 671 #ifdef HAVE_STDLIB_H
 672 #include <stdlib.h>
 673 #endif
 674 #ifdef HAVE_UNISTD_H
 675 #include <unistd.h>
 676 #endif
 677 "
 678
 679 # Does errno.h declare errno, or do we have to add a separate declaration
 680 # for it?
 681 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 682 #ifdef HAVE_ERRNO_H
 683 #include <errno.h>
 684 #endif
 685 ])
 686
 687 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 688 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 689 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 690 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 691 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 692 if test $gas_cv_decl_getopt_unistd_h = yes; then
 693   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 694             [Is the prototype for getopt in <unistd.h> in the expected format?])
 695 fi
 696
 697 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 698 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 699 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 700 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 701 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 702 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 703
 704 dnl This must come last.
 705
 706 dnl We used to make symlinks to files in the source directory, but now
 707 dnl we just use the right name for .c files, and create .h files in
 708 dnl the build directory which include the right .h file.  Make sure
 709 dnl the old symlinks don't exist, so that a reconfigure in an existing
 710 dnl directory behaves reasonably.
 711
 712 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 713 AC_CONFIG_COMMANDS([default],
 714 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 715  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 716  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 717  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 718  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 719  if test "x$cgen_cpu_prefix" != x ; then
 720    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 721  fi
 722
 723  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 724 [target_cpu_type=${target_cpu_type}
 725  cgen_cpu_prefix=${cgen_cpu_prefix}
 726  obj_format=${obj_format}
 727  te_file=${te_file}])
 728
 729 AC_OUTPUT