gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # check for architecture variants
 122     arch=
 123     endian=
 124     case ${cpu} in
 125       am33_2.0)         cpu_type=mn10300 endian=little ;;
 126       alpha*)           cpu_type=alpha ;;
 127       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 128       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 129       c4x*)             cpu_type=tic4x ;;
 130       hppa*)            cpu_type=hppa ;;
 131 changequote(,)dnl
 132       i[3-7]86)         cpu_type=i386 arch=i386;;
 133       x86_64)           cpu_type=i386 arch=x86_64;;
 134       ia64)             cpu_type=ia64 ;;
 135       ip2k)             cpu_type=ip2k endian=big ;;
 136       iq2000)           cpu_type=iq2000 endian=big ;;
 137       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 138       m680[012346]0)    cpu_type=m68k ;;
 139 changequote([,])dnl
 140       m68008)           cpu_type=m68k ;;
 141       m683??)           cpu_type=m68k ;;
 142       m5200)            cpu_type=m68k ;;
 143       m8*)              cpu_type=m88k ;;
 144       mips*el)          cpu_type=mips endian=little ;;
 145       mips*)            cpu_type=mips endian=big ;;
 146       or32*)            cpu_type=or32 endian=big ;;
 147       pjl*)             cpu_type=pj endian=little ;;
 148       pj*)              cpu_type=pj endian=big ;;
 149       powerpc*le*)      cpu_type=ppc endian=little ;;
 150       powerpc*)         cpu_type=ppc endian=big ;;
 151       rs6000*)          cpu_type=ppc ;;
 152       s390x*)           cpu_type=s390 arch=s390x ;;
 153       s390*)            cpu_type=s390 arch=s390 ;;
 154       sh5*)             cpu_type=sh64 endian=big ;;
 155       sh5le*)           cpu_type=sh64 endian=little ;;
 156       sh64*)            cpu_type=sh64 endian=big ;;
 157       sh64le*)          cpu_type=sh64 endian=little ;;
 158       sh*le)            cpu_type=sh endian=little ;;
 159       sh*)              cpu_type=sh endian=big ;;
 160       sparclite*)       cpu_type=sparc arch=sparclite ;;
 161       sparclet*)        cpu_type=sparc arch=sparclet ;;
 162       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 163       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 164       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 165       v850*)            cpu_type=v850 ;;
 166       crx*)             cpu_type=crx endian=little ;;
 167       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 168       m32r)             cpu_type=m32r target_cpu=m32r endian=big ;;
 169       m32rle)           cpu_type=m32r target_cpu=m32r endian=little ;;
 170       *)                cpu_type=${cpu} ;;
 171     esac
 172
 173     if test ${this_target} = $target ; then
 174       target_cpu_type=${cpu_type}
 175     elif test ${target_cpu_type} != ${cpu_type} ; then
 176       continue
 177     fi
 178
 179     generic_target=${cpu_type}-$vendor-$os
 180     dev=no
 181     bfd_gas=no
 182     em=generic
 183
 184     # assign object format
 185     case ${generic_target} in
 186       a29k-*-coff)                      fmt=coff ;;
 187       a29k-amd-udi)                     fmt=coff ;;
 188       a29k-amd-ebmon)                   fmt=coff ;;
 189       a29k-nyu-sym1)                    fmt=coff ;;
 190       a29k-*-rtems*)                    fmt=coff ;;
 191       a29k-*-vxworks*)                  fmt=coff ;;
 192
 193       alpha*-*-*vms*)                   fmt=evax ;;
 194       alpha*-*-osf*)                    fmt=ecoff ;;
 195       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 196       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 197       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 198       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 199
 200       # cpu_type for am33_2.0 is set to mn10300
 201       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 202
 203       arc-*-elf*)                       fmt=elf ;;
 204
 205       arm-*-aout)                       fmt=aout ;;
 206       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 207       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 208       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 209       arm-*-kaos*)                      fmt=elf ;;
 210       arm*-*-conix*)                    fmt=elf ;;
 211       arm-*-linux*aout*)                fmt=aout em=linux ;;
 212       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 213       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 214       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 215       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 216       arm-**-nto*)                      fmt=elf ;;
 217       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 218       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 219       arm-wince-pe | arm-*-wince)       fmt=coff em=wince-pe ;;
 220       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 221       arm-*-riscix*)                    fmt=aout em=riscix ;;
 222
 223       avr-*-*)                          fmt=elf ;;
 224
 225       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 226       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 227
 228       crx-*-elf*)                       fmt=elf ;;
 229
 230       d10v-*-*)                         fmt=elf ;;
 231       d30v-*-*)                         fmt=elf ;;
 232       dlx-*-*)                          fmt=elf ;;
 233
 234       fr30-*-*)                         fmt=elf ;;
 235       frv-*-*linux*)                    fmt=elf em=linux;;
 236       frv-*-*)                          fmt=elf ;;
 237
 238       hppa-*-linux*)    case ${cpu} in
 239                             hppa*64*)   fmt=elf em=hppalinux64;;
 240                             hppa*)      fmt=elf em=linux;;
 241                         esac ;;
 242       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 243       hppa-*-lites*)                    fmt=elf em=hppa ;;
 244       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 245       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 246       hppa-*-osf*)                      fmt=som em=hppa ;;
 247       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 248       hppa-*-hpux11*)   case ${cpu} in
 249                             hppa*64*)   fmt=elf em=hppa64 ;;
 250                             hppa*)      fmt=som em=hppa ;;
 251                         esac ;;
 252       hppa-*-hpux*)                     fmt=som em=hppa ;;
 253       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 254       hppa-*-bsd*)                      fmt=som em=hppa ;;
 255       hppa-*-hiux*)                     fmt=som em=hppa ;;
 256
 257       h8300-*-rtems*)                   fmt=coff ;;
 258       h8300-*-coff)                     fmt=coff ;;
 259       h8300-*-elf)                      fmt=elf ;;
 260       h8500-*-rtems*)                   fmt=coff ;;
 261       h8500-*-coff)                     fmt=coff ;;
 262
 263       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 264       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 265       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 266       i386-*-beospe*)                   fmt=coff em=pe ;;
 267       i386-*-beos*)                     fmt=elf ;;
 268       i386-*-coff)                      fmt=coff ;;
 269       i386-*-elf)                       fmt=elf ;;
 270       i386-*-kaos*)                     fmt=elf ;;
 271       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 272       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 273       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 274       i386-*-netbsd*-gnu* | \
 275       i386-*-knetbsd*-gnu | \
 276       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 277       i386-*-*n*bsd*)   case ${cpu} in
 278                             x86_64)     fmt=elf em=nbsd ;;
 279                             *)          fmt=aout em=nbsd ;;
 280                         esac ;;
 281       i386-*-linux*aout*)               fmt=aout em=linux ;;
 282       i386-*-linux*oldld)               fmt=aout em=linux ;;
 283       i386-*-linux*coff*)               fmt=coff em=linux ;;
 284       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 285       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 286       i386-*-lynxos*)                   fmt=elf em=lynx bfd_gas=yes ;;
 287 changequote(,)dnl
 288       i386-*-sysv[45]*)                 fmt=elf ;;
 289       i386-*-solaris*)                  fmt=elf ;;
 290       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 291       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 292       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 293 changequote([,])dnl
 294       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 295                                         fmt=elf em=freebsd ;;
 296       i386-*-sysv*)                     fmt=coff ;;
 297       i386-*-sco3.2v5*coff)             fmt=coff ;;
 298       i386-*-isc*)                      fmt=coff ;;
 299       i386-*-sco3.2v5*)                 fmt=elf
 300           if test ${this_target} = $target; then
 301             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 302           fi ;;
 303       i386-*-sco3.2*)                   fmt=coff ;;
 304       i386-*-vsta)                      fmt=aout ;;
 305       i386-*-msdosdjgpp* \
 306       | i386-*-go32* \
 307       | i386-go32-rtems*)               fmt=coff em=go32
 308             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 309       i386-*-rtemself*)                 fmt=elf ;;
 310       i386-*-rtemscoff*)                fmt=coff ;;
 311       i386-*-rtems*)                    fmt=elf ;;
 312       i386-*-gnu*)                      fmt=elf ;;
 313       i386-*-mach*)                     fmt=aout em=mach ;;
 314       i386-*-msdos*)                    fmt=aout ;;
 315       i386-*-moss*)                     fmt=elf ;;
 316       i386-*-pe)                        fmt=coff em=pe ;;
 317       i386-*-cygwin*)                   fmt=coff em=pe ;;
 318       i386-*-interix*)                  fmt=coff em=interix ;;
 319       i386-*-mingw32*)                  fmt=coff em=pe ;;
 320       i386-*-nto-qnx*)                  fmt=elf ;;
 321       i386-*-*nt*)                      fmt=coff em=pe ;;
 322       i386-*-chaos)                     fmt=elf ;;
 323
 324       i860-*-*)                         fmt=elf endian=little
 325                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 326       i960-*-bout)                      fmt=bout ;;
 327       i960-*-coff)                      fmt=coff em=ic960 ;;
 328       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 329       i960-*-nindy*)                    fmt=bout ;;
 330       i960-*-vxworks5.0)                fmt=bout ;;
 331       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 332       i960-*-vxworks*)                  fmt=bout ;;
 333       i960-*-elf*)                      fmt=elf ;;
 334
 335       ia64-*-elf*)                      fmt=elf ;;
 336       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 337       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 338       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 339       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 340
 341       ip2k-*-*)                         fmt=elf ;;
 342
 343       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 344
 345       m32r-*-elf*)                      fmt=elf ;;
 346       m32r-*-linux*)                    fmt=elf em=linux;;
 347
 348       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 349       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 350
 351       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 352       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 353       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 354       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 355       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 356       m68k-apollo-*)                    fmt=coff em=apollo ;;
 357       m68k-*-elf*)                      fmt=elf ;;
 358       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 359       m68k-*-sysv*)                     fmt=coff ;;
 360       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 361       m68k-*-rtems*)                    fmt=elf ;;
 362       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 363       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 364       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 365       m68k-*-uclinux*)                  fmt=elf ;;
 366       m68k-*-gnu*)                      fmt=elf ;;
 367       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 368       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 369       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 370       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 371       m68k-apple-aux*)                  fmt=coff em=aux ;;
 372       m68k-*-psos*)                     fmt=elf em=psos;;
 373
 374       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 375       m88k-*-coff*)                     fmt=coff ;;
 376
 377       mcore-*-elf)                      fmt=elf ;;
 378       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 379
 380       # don't change em like *-*-bsd does
 381       mips-dec-openbsd*)                fmt=elf endian=little ;;
 382       mips-sony-bsd*)                   fmt=ecoff ;;
 383       mips-*-bsd*)
 384             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 385       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 386       mips-*-osf*)                      fmt=ecoff endian=little ;;
 387       mips-*-ecoff*)                    fmt=ecoff ;;
 388       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 389       mips-*-irix6*)                    fmt=elf em=irix ;;
 390       mips-*-irix5*)                    fmt=elf em=irix ;;
 391       mips-*-irix*)                     fmt=ecoff em=irix ;;
 392       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 393       mips-*-riscos*)                   fmt=ecoff ;;
 394       mips*-*-linux*)                   fmt=elf em=tmips ;;
 395       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 396       mips-*-sysv*)                     fmt=ecoff ;;
 397       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 398       mips-*-netbsd*)                   fmt=elf ;;
 399       mips-*-openbsd*)                  fmt=elf ;;
 400
 401       mmix-*-*)                         fmt=elf ;;
 402       mn10200-*-*)                      fmt=elf ;;
 403       mn10300-*-*)                      fmt=elf ;;
 404       msp430-*-*)                       fmt=elf ;;
 405       openrisc-*-*)                     fmt=elf ;;
 406       or32-*-rtems*)                    fmt=elf ;;
 407       or32-*-coff)                      fmt=coff ;;
 408       or32-*-elf)                       fmt=elf ;;
 409       pj*)                              fmt=elf ;;
 410
 411       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 412       ppc-*-winnt*)                     fmt=coff em=pe ;;
 413 changequote(,)dnl
 414       ppc-*-aix5.[01])                  fmt=coff em=aix5 ;;
 415 changequote([,])dnl
 416       ppc-*-aix5.*)                     fmt=coff em=aix5
 417         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 418                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 419       ;;
 420       ppc-*-aix*)                       fmt=coff ;;
 421       ppc-*-beos*)                      fmt=coff ;;
 422       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 423       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 424       ppc-*-linux-gnu*)                 fmt=elf em=linux
 425             case "$endian" in
 426                 big)  ;;
 427                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 428             esac ;;
 429       ppc-*-solaris*)                   fmt=elf
 430             if test ${this_target} = $target; then
 431                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 432                           [Define if default target is PowerPC Solaris.])
 433             fi
 434             if test x${endian} = xbig; then
 435                 AC_MSG_ERROR(Solaris must be configured little endian)
 436             fi ;;
 437       ppc-*-rtems*)                     fmt=elf ;;
 438       ppc-*-macos*)                     fmt=coff em=macos ;;
 439       ppc-*-nto*)                       fmt=elf ;;
 440       ppc-*-kaos*)                      fmt=elf ;;
 441       ppc-*-lynxos*)                    fmt=elf em=lynx bfd_gas=yes ;;
 442
 443       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 444       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 445
 446       sh*-*-linux*)                     fmt=elf em=linux
 447             case ${cpu} in
 448                 sh*eb)  endian=big ;;
 449                 *)      endian=little ;;
 450             esac ;;
 451       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 452       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 453       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 454       sh*-*-symbianelf*)                fmt=elf endian=little
 455                 AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 456                 ;;
 457       sh-*-elf*)                        fmt=elf ;;
 458       sh-*-coff*)                       fmt=coff ;;
 459       sh-*-nto*)                        fmt=elf ;;
 460       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 461       sh-*-rtemscoff*)                  fmt=coff ;;
 462       sh-*-rtems*)                      fmt=elf ;;
 463       sh-*-kaos*)                       fmt=elf ;;
 464       shle*-*-kaos*)                    fmt=elf ;;
 465       sh64-*-elf*)                      fmt=elf ;;
 466
 467       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 468       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 469       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 470       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 471
 472       sparc-*-rtemsaout*)               fmt=aout ;;
 473       sparc-*-rtemself*)                fmt=elf ;;
 474       sparc-*-rtems*)                   fmt=elf ;;
 475       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 476       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 477       sparc-*-coff)                     fmt=coff ;;
 478       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 479       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 480       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 481       sparc-fujitsu-none)               fmt=aout ;;
 482       sparc-*-elf)                      fmt=elf ;;
 483       sparc-*-sysv4*)                   fmt=elf ;;
 484       sparc-*-solaris*)                 fmt=elf ;;
 485       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 486       sparc-*-*n*bsd*)  case ${cpu} in
 487                             sparc64)    fmt=elf em=nbsd ;;
 488                             *)          fmt=aout em=nbsd ;;
 489                         esac ;;
 490       strongarm-*-coff)                 fmt=coff ;;
 491       strongarm-*-elf)                  fmt=elf ;;
 492       strongarm-*-kaos*)                fmt=elf ;;
 493       xscale-*-coff)                    fmt=coff ;;
 494       xscale-*-elf)                     fmt=elf ;;
 495
 496       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 497       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 498       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 499       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 500       tic80-*-*)                        fmt=coff ;;
 501
 502       v850-*-*)                         fmt=elf ;;
 503       v850e-*-*)                        fmt=elf ;;
 504       v850ea-*-*)                       fmt=elf ;;
 505
 506       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 507       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 508       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 509       vax-*-linux-gnu*)                 fmt=elf em=linux bfd_gas=yes ;;
 510       vax-*-vms)                        fmt=vms ;;
 511
 512       w65-*-*)                          fmt=coff ;;
 513
 514       xstormy16-*-*)                    fmt=elf ;;
 515
 516       xtensa-*-*)                       fmt=elf ;;
 517
 518       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 519
 520       *-*-aout | *-*-scout)             fmt=aout ;;
 521       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 522       *-*-nindy*)                       fmt=bout ;;
 523       *-*-bsd*)                         fmt=aout em=sun3 ;;
 524       *-*-generic)                      fmt=generic ;;
 525       *-*-xray | *-*-hms)               fmt=coff ;;
 526       *-*-sim)                          fmt=coff ;;
 527       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 528       *-*-aros*)                        fmt=elf em=linux bfd_gas=yes ;;
 529       *-*-vxworks | *-*-windiss)        fmt=elf ;;
 530       *-*-netware)                      fmt=elf em=netware ;;
 531     esac
 532
 533     if test ${this_target} = $target ; then
 534       endian_def=
 535       if test x${endian} = xbig; then
 536         endian_def=1
 537       elif test x${endian} = xlittle; then
 538         endian_def=0
 539       fi
 540       if test x${endian_def} != x; then
 541         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 542                            [Define as 1 if big endian.])
 543       fi
 544     fi
 545
 546     case ${cpu_type}-${fmt} in
 547         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 548                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 549                 | *-elf | *-ecoff | *-som)
 550             bfd_gas=yes ;;
 551     esac
 552
 553 # Other random stuff.
 554
 555     case ${cpu_type} in
 556       mips)
 557         # Set mips_cpu to the name of the default CPU.
 558         case ${target_cpu} in
 559           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 560             mips_cpu=from-abi
 561             ;;
 562           mipsisa32 | mipsisa32el)
 563             mips_cpu=mips32
 564             ;;
 565           mipsisa32r2 | mipsisa32r2el)
 566             mips_cpu=mips32r2
 567             ;;
 568           mipsisa64 | mipsisa64el)
 569             mips_cpu=mips64
 570             ;;
 571           mipsisa64r2 | mipsisa64r2el)
 572             mips_cpu=mips64r2
 573             ;;
 574           mipstx39 | mipstx39el)
 575             mips_cpu=r3900
 576             ;;
 577           mips64vr | mips64vrel)
 578             mips_cpu=vr4100
 579             ;;
 580           mipsisa32r2* | mipsisa64r2*)
 581 changequote(,)dnl
 582             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 583 changequote([,])dnl
 584             ;;
 585           mips64* | mipsisa64* | mipsisa32*)
 586 changequote(,)dnl
 587             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 588 changequote([,])dnl
 589             ;;
 590           *)
 591             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 592             ;;
 593         esac
 594         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 595         # binaries.  It's a GNU extension that some OSes don't understand.
 596         # The value only matters on ELF targets.
 597         case ${target} in
 598           *-*-irix*)
 599             use_e_mips_abi_o32=0
 600             ;;
 601           *)
 602             use_e_mips_abi_o32=1
 603             ;;
 604         esac
 605         # Decide whether to generate 32-bit or 64-bit code by default.
 606         # Used to resolve -march=from-abi when an embedded ABI is selected.
 607         case ${target} in
 608           mips64*-*-* | mipsisa64*-*-*)
 609             mips_default_64bit=1
 610             ;;
 611           *)
 612             mips_default_64bit=0
 613             ;;
 614         esac
 615         # Decide which ABI to target by default.
 616         case ${target} in
 617           mips64*-linux* | mips-sgi-irix6*)
 618             mips_default_abi=N32_ABI
 619             ;;
 620           mips*-linux*)
 621             mips_default_abi=O32_ABI
 622             ;;
 623           *)
 624             mips_default_abi=NO_ABI
 625             ;;
 626         esac
 627         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 628                            [Default CPU for MIPS targets. ])
 629         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 630                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 631         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 632                            [Generate 64-bit code by default on MIPS targets. ])
 633         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 634                            [Choose a default ABI for MIPS targets. ])
 635         ;;
 636     esac
 637
 638     # Do we need the opcodes library?
 639     case ${cpu_type} in
 640       vax | i386 | tic30)
 641         ;;
 642
 643       *)
 644         need_opcodes=yes
 645
 646         case "${enable_shared}" in
 647         yes) shared_opcodes=true ;;
 648         *opcodes*) shared_opcodes=true ;;
 649         *) shared_opcodes=false ;;
 650         esac
 651         if test "${shared_opcodes}" = "true"; then
 652           # A shared libopcodes must be linked against libbfd.
 653           need_bfd=yes
 654         fi
 655         ;;
 656     esac
 657
 658     # Any other special object files needed ?
 659     case ${cpu_type} in
 660       fr30 | ip2k | iq2000 | m32r | openrisc)
 661         using_cgen=yes
 662         ;;
 663
 664       frv)
 665         using_cgen=yes
 666         ;;
 667       m68k)
 668         case ${extra_objects} in
 669         *m68k-parse.o*) ;;
 670         *) extra_objects="$extra_objects m68k-parse.o" ;;
 671         esac
 672         ;;
 673
 674       mips)
 675         echo ${extra_objects} | grep -s "itbl-parse.o"
 676         if test $? -ne 0 ; then
 677           extra_objects="$extra_objects itbl-parse.o"
 678         fi
 679
 680         echo ${extra_objects} | grep -s "itbl-lex.o"
 681         if test $? -ne 0 ; then
 682           extra_objects="$extra_objects itbl-lex.o"
 683         fi
 684
 685         echo ${extra_objects} | grep -s "itbl-ops.o"
 686         if test $? -ne 0 ; then
 687           extra_objects="$extra_objects itbl-ops.o"
 688         fi
 689         ;;
 690
 691       i386 | s390 | sparc)
 692         if test $this_target = $target ; then
 693           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 694         fi
 695         ;;
 696
 697       xstormy16)
 698         using_cgen=yes
 699         ;;
 700
 701       xtensa)
 702         echo ${extra_objects} | grep -s "xtensa-relax.o"
 703         if test $? -ne 0 ; then
 704           extra_objects="$extra_objects xtensa-relax.o"
 705         fi
 706         ;;
 707
 708       *)
 709         ;;
 710     esac
 711
 712     if test $using_cgen = yes ; then
 713         case "x${extra_objects}" in
 714         *cgen.o*) ;;
 715         *) extra_objects="$extra_objects cgen.o" ;;
 716         esac
 717     fi
 718
 719 # See if we really can support this configuration with the emulation code.
 720
 721     if test $this_target = $target ; then
 722       primary_bfd_gas=$bfd_gas
 723       obj_format=$fmt
 724       te_file=$em
 725
 726       if test $bfd_gas = no ; then
 727         # Can't support other configurations this way.
 728         break
 729       fi
 730     elif test $bfd_gas = no ; then
 731       # Can't support this configuration.
 732       break
 733     fi
 734
 735 # From target name and format, produce a list of supported emulations.
 736
 737     case ${generic_target}-${fmt} in
 738       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 739       mips*-*-linux*-*) case "$endian" in
 740                         big)    emulation="mipsbelf mipslelf mipself" ;;
 741                         *)      emulation="mipslelf mipsbelf mipself" ;;
 742                         esac ;;
 743       mips-*-lnews*-ecoff) ;;
 744       mips-*-*-ecoff)   case "$endian" in
 745                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 746                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 747                         esac ;;
 748       mips-*-*-elf)     case "$endian" in
 749                         big)    emulation="mipsbelf mipslelf mipself" ;;
 750                         *)      emulation="mipslelf mipsbelf mipself" ;;
 751                         esac ;;
 752       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 753       # i386-pc-pe-coff != i386-pc-coff.
 754       i386-*-pe-coff)   ;;
 755       # Uncommenting the next line will turn on support for i386 AOUT
 756       # for the default linux configuration
 757       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 758       #
 759       i386-*-aout)      emulation="i386aout" ;;
 760       i386-*-coff)      emulation="i386coff" ;;
 761       i386-*-elf)       emulation="i386elf" ;;
 762
 763       # Always all formats.  The first stated emulation becomes the default.
 764       cris-*-*aout*)    emulation="crisaout criself" ;;
 765       cris-*-*)         emulation="criself crisaout" ;;
 766     esac
 767
 768     emulations="$emulations $emulation"
 769
 770 done
 771
 772 # Turn on all targets if possible
 773 if test ${all_targets} = "yes"; then
 774   case ${target_cpu_type} in
 775   i386)
 776     case ${obj_format} in
 777     aout)
 778       emulations="$emulations i386coff i386elf"
 779       ;;
 780     coff)
 781       emulations="$emulations i386aout i386elf"
 782     ;;
 783     elf)
 784       emulations="$emulations i386aout i386coff"
 785       ;;
 786     esac
 787   ;;
 788   esac
 789 fi
 790
 791 # Assign floating point type.  Most processors with FP support
 792 # IEEE FP.  On those that don't support FP at all, usually IEEE
 793 # is emulated.
 794 case ${target_cpu} in
 795   vax | tahoe ) atof=${target_cpu} ;;
 796   pdp11)        atof=vax ;;
 797   *)            atof=ieee ;;
 798 esac
 799
 800 case "${obj_format}" in
 801   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 802 esac
 803
 804 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 805 cgen_cpu_prefix=""
 806 if test $using_cgen = yes ; then
 807   case ${target_cpu} in
 808     *) cgen_cpu_prefix=${target_cpu} ;;
 809   esac
 810   AC_SUBST(cgen_cpu_prefix)
 811   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 812 fi
 813
 814 dnl
 815 dnl Make sure the desired support files exist.
 816 dnl
 817
 818 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 819   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 820 fi
 821
 822 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 823   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 824 fi
 825
 826 case ${user_bfd_gas}-${primary_bfd_gas} in
 827   yes-yes | no-no)
 828     # We didn't override user's choice.
 829     ;;
 830   no-yes)
 831     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 832     ;;
 833   no-preferred)
 834     primary_bfd_gas=no
 835     ;;
 836   *-preferred)
 837     primary_bfd_gas=yes
 838     ;;
 839   yes-*)
 840     primary_bfd_gas=yes
 841     ;;
 842   -*)
 843     # User specified nothing.
 844     ;;
 845 esac
 846
 847 # Some COFF configurations want these random other flags set.
 848 case ${obj_format} in
 849   coff)
 850     case ${target_cpu_type} in
 851       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 852       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 853       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 854     esac
 855     ;;
 856 esac
 857
 858 # Getting this done right is going to be a bitch.  Each configuration specified
 859 # with --enable-targets=... should be checked for environment, format, cpu, and
 860 # bfd_gas setting.
 861 #
 862 # For each configuration, the necessary object file support code must be linked
 863 # in.  This might be only one, it might be up to four.  The necessary emulation
 864 # code needs to be provided, too.
 865 #
 866 # And then there's "--enable-targets=all"....
 867 #
 868 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 869
 870 formats="${obj_format}"
 871 emfiles=""
 872 EMULATIONS=""
 873 GAS_UNIQ(emulations)
 874 for em in . $emulations ; do
 875   case $em in
 876     .)  continue ;;
 877     mipsbelf | mipslelf | mipself)
 878         fmt=elf   file=mipself ;;
 879     mipsbecoff | mipslecoff | mipsecoff)
 880         fmt=ecoff file=mipsecoff ;;
 881     *coff)
 882         fmt=coff  file=$em ;;
 883     *aout)
 884         fmt=aout file=$em ;;
 885     *elf)
 886         fmt=elf file=$em ;;
 887   esac
 888   formats="$formats $fmt"
 889   emfiles="$emfiles e-$file.o"
 890   EMULATIONS="$EMULATIONS &$em,"
 891 done
 892 GAS_UNIQ(formats)
 893 GAS_UNIQ(emfiles)
 894 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 895   for fmt in $formats ; do
 896     case $fmt in
 897       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 898       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 899       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 900       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 901       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 902       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 903       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 904       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 905       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 906       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 907     esac
 908     extra_objects="$extra_objects obj-$fmt.o"
 909   done
 910   obj_format=multi
 911 fi
 912 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 913   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 914   # e-mips* has more than one emulation per file, e-i386* has just one at the
 915   # moment.  If only one emulation is specified, then don't define
 916   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 917   case "${obj_format}${emfiles}" in
 918     multi* | *mips*)
 919       extra_objects="$extra_objects $emfiles"
 920       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 921   esac
 922 fi
 923 AC_SUBST(extra_objects)
 924 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 925 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 926                    [Default emulation.])
 927
 928 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 929   yes-*-coff)   need_bfd=yes ;;
 930   no-*-coff)    need_bfd=yes
 931                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 932 esac
 933
 934 reject_dev_configs=yes
 935
 936 case ${reject_dev_configs}-${dev} in
 937   yes-yes) # Oops.
 938     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 939     ;;
 940 esac
 941
 942 AC_SUBST(target_cpu_type)
 943 AC_SUBST(obj_format)
 944 AC_SUBST(te_file)
 945 AC_SUBST(install_tooldir)
 946 AC_SUBST(atof)
 947 dnl AC_SUBST(emulation)
 948
 949 case "${primary_bfd_gas}" in
 950   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 951         need_bfd=yes ;;
 952 esac
 953
 954 # do we need the opcodes library?
 955 case "${need_opcodes}" in
 956 yes)
 957   OPCODES_LIB=../opcodes/libopcodes.la
 958   ;;
 959 esac
 960
 961 case "${need_bfd}" in
 962 yes)
 963   BFDLIB=../bfd/libbfd.la
 964   BFDVER_H=../bfd/bfdver.h
 965   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 966   ;;
 967 esac
 968
 969 AC_SUBST(BFDLIB)
 970 AC_SUBST(OPCODES_LIB)
 971
 972 AC_SUBST(BFDVER_H)
 973 AC_SUBST(ALL_OBJ_DEPS)
 974
 975 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 976 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 977 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 978 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 979 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 980
 981 AC_PROG_CC
 982
 983 AC_PROG_YACC
 984 AM_PROG_LEX
 985
 986 ALL_LINGUAS="fr tr es"
 987 CY_GNU_GETTEXT
 988
 989 AM_MAINTAINER_MODE
 990 AC_EXEEXT
 991
 992 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 993
 994 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 995 # people who are not cross-compiling but are compiling cross-assemblers.
 996 AC_MSG_CHECKING(whether compiling a cross-assembler)
 997 if test "${host}" = "${target}"; then
 998   cross_gas=no
 999 else
1000   cross_gas=yes
1001   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
1002 fi
1003 AC_MSG_RESULT($cross_gas)
1004
1005 dnl ansidecl.h will deal with const
1006 dnl AC_CONST
1007 AC_FUNC_ALLOCA
1008 AC_C_INLINE
1009
1010 # VMS doesn't have unlink.
1011 AC_CHECK_FUNCS(unlink remove, break)
1012
1013 # Some systems don't have sbrk().
1014 AC_CHECK_FUNCS(sbrk)
1015
1016 # do we need the math library?
1017 case "${need_libm}" in
1018 yes)
1019   AC_CHECK_LIBM
1020   AC_SUBST(LIBM)
1021   ;;
1022 esac
1023
1024 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1025 # enough, but on some of those systems, the assert macro relies on requoting
1026 # working properly!
1027 GAS_WORKING_ASSERT
1028
1029 # On some systems, the system header files may not declare malloc, realloc,
1030 # and free.  There are places where gas needs these functions to have been
1031 # declared -- such as when taking their addresses.
1032 gas_test_headers="
1033 #ifdef HAVE_MEMORY_H
1034 #include <memory.h>
1035 #endif
1036 #ifdef HAVE_STRING_H
1037 #include <string.h>
1038 #else
1039 #ifdef HAVE_STRINGS_H
1040 #include <strings.h>
1041 #endif
1042 #endif
1043 #ifdef HAVE_STDLIB_H
1044 #include <stdlib.h>
1045 #endif
1046 #ifdef HAVE_UNISTD_H
1047 #include <unistd.h>
1048 #endif
1049 "
1050 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1051 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1052 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1053 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1054 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1055
1056 # Does errno.h declare errno, or do we have to add a separate declaration
1057 # for it?
1058 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1059 #ifdef HAVE_ERRNO_H
1060 #include <errno.h>
1061 #endif
1062 ])
1063
1064 dnl This must come last.
1065
1066 dnl We used to make symlinks to files in the source directory, but now
1067 dnl we just use the right name for .c files, and create .h files in
1068 dnl the build directory which include the right .h file.  Make sure
1069 dnl the old symlinks don't exist, so that a reconfigure in an existing
1070 dnl directory behaves reasonably.
1071
1072 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1073 AC_CONFIG_COMMANDS([default],
1074 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1075  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1076  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1077  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1078  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1079  if test "x$cgen_cpu_prefix" != x ; then
1080    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1081  fi
1082
1083  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1084 [target_cpu_type=${target_cpu_type}
1085  cgen_cpu_prefix=${cgen_cpu_prefix}
1086  obj_format=${obj_format}
1087  te_file=${te_file}])
1088
1089 AC_OUTPUT