gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # check for architecture variants
 122     arch=
 123     endian=
 124     case ${cpu} in
 125       am33_2.0)         cpu_type=mn10300 endian=little ;;
 126       alpha*)           cpu_type=alpha ;;
 127       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 128       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 129       c4x*)             cpu_type=tic4x ;;
 130       hppa*)            cpu_type=hppa ;;
 131 changequote(,)dnl
 132       i[3-7]86)         cpu_type=i386 arch=i386;;
 133       x86_64)           cpu_type=i386 arch=x86_64;;
 134       ia64)             cpu_type=ia64 ;;
 135       ip2k)             cpu_type=ip2k endian=big ;;
 136       iq2000)           cpu_type=iq2000 endian=big ;;
 137       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 138       m680[012346]0)    cpu_type=m68k ;;
 139 changequote([,])dnl
 140       m68008)           cpu_type=m68k ;;
 141       m683??)           cpu_type=m68k ;;
 142       m5200)            cpu_type=m68k ;;
 143       m8*)              cpu_type=m88k ;;
 144       mips*el)          cpu_type=mips endian=little ;;
 145       mips*)            cpu_type=mips endian=big ;;
 146       or32*)            cpu_type=or32 endian=big ;;
 147       pjl*)             cpu_type=pj endian=little ;;
 148       pj*)              cpu_type=pj endian=big ;;
 149       powerpc*le*)      cpu_type=ppc endian=little ;;
 150       powerpc*)         cpu_type=ppc endian=big ;;
 151       rs6000*)          cpu_type=ppc ;;
 152       s390x*)           cpu_type=s390 arch=s390x ;;
 153       s390*)            cpu_type=s390 arch=s390 ;;
 154       sh5*)             cpu_type=sh64 endian=big ;;
 155       sh5le*)           cpu_type=sh64 endian=little ;;
 156       sh64*)            cpu_type=sh64 endian=big ;;
 157       sh64le*)          cpu_type=sh64 endian=little ;;
 158       sh*le)            cpu_type=sh endian=little ;;
 159       sh*)              cpu_type=sh endian=big ;;
 160       sparclite*)       cpu_type=sparc arch=sparclite ;;
 161       sparclet*)        cpu_type=sparc arch=sparclet ;;
 162       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 163       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 164       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 165       v850*)            cpu_type=v850 ;;
 166       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 167       *)                cpu_type=${cpu} ;;
 168     esac
 169
 170     if test ${this_target} = $target ; then
 171       target_cpu_type=${cpu_type}
 172     elif test ${target_cpu_type} != ${cpu_type} ; then
 173       continue
 174     fi
 175
 176     generic_target=${cpu_type}-$vendor-$os
 177     dev=no
 178     bfd_gas=no
 179     em=generic
 180
 181     # assign object format
 182     case ${generic_target} in
 183       a29k-*-coff)                      fmt=coff ;;
 184       a29k-amd-udi)                     fmt=coff ;;
 185       a29k-amd-ebmon)                   fmt=coff ;;
 186       a29k-nyu-sym1)                    fmt=coff ;;
 187       a29k-*-rtems*)                    fmt=coff ;;
 188       a29k-*-vxworks*)                  fmt=coff ;;
 189
 190       alpha*-*-*vms*)                   fmt=evax ;;
 191       alpha*-*-netware*)                fmt=ecoff ;;
 192       alpha*-*-osf*)                    fmt=ecoff ;;
 193       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 194       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 195       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 196       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 197
 198       # cpu_type for am33_2.0 is set to mn10300
 199       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 200
 201       arc-*-elf*)                       fmt=elf ;;
 202
 203       arm-*-aout)                       fmt=aout ;;
 204       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 205       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 206       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 207       arm-*-kaos*)                      fmt=elf ;;
 208       arm*-*-conix*)                    fmt=elf ;;
 209       arm-*-linux*aout*)                fmt=aout em=linux ;;
 210       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 211       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 212       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 213       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 214       arm-**-nto*)                      fmt=elf ;;
 215       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 216       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 217       arm-*-wince)                      fmt=coff em=wince-pe ;;
 218       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 219       arm-*-riscix*)                    fmt=aout em=riscix ;;
 220       arm-*-vxworks)                    fmt=coff ;;
 221
 222       avr-*-*)                          fmt=elf ;;
 223
 224       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 225       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 226
 227       d10v-*-*)                         fmt=elf ;;
 228       d30v-*-*)                         fmt=elf ;;
 229       dlx-*-*)                          fmt=elf ;;
 230
 231       fr30-*-*)                         fmt=elf ;;
 232       frv-*-*)                          fmt=elf ;;
 233
 234       hppa-*-linux*)    case ${cpu} in
 235                             hppa*64*)   fmt=elf em=hppalinux64;;
 236                             hppa*)      fmt=elf em=linux;;
 237                         esac ;;
 238       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 239       hppa-*-lites*)                    fmt=elf em=hppa ;;
 240       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 241       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 242       hppa-*-osf*)                      fmt=som em=hppa ;;
 243       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 244       hppa-*-hpux11*)   case ${cpu} in
 245                             hppa*64*)   fmt=elf em=hppa64 ;;
 246                             hppa*)      fmt=som em=hppa ;;
 247                         esac ;;
 248       hppa-*-hpux*)                     fmt=som em=hppa ;;
 249       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 250       hppa-*-bsd*)                      fmt=som em=hppa ;;
 251       hppa-*-hiux*)                     fmt=som em=hppa ;;
 252
 253       h8300-*-rtems*)                   fmt=coff ;;
 254       h8300-*-coff)                     fmt=coff ;;
 255       h8300-*-elf)                      fmt=elf ;;
 256       h8500-*-rtems*)                   fmt=coff ;;
 257       h8500-*-coff)                     fmt=coff ;;
 258
 259       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 260       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 261       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 262       i386-*-beospe*)                   fmt=coff em=pe ;;
 263       i386-*-beos*)                     fmt=elf ;;
 264       i386-*-coff)                      fmt=coff ;;
 265       i386-*-elf)                       fmt=elf ;;
 266       i386-*-kaos*)                     fmt=elf ;;
 267       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 268       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 269       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 270       i386-*-netbsd*-gnu*)              fmt=elf em=nbsd ;;
 271       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 272       i386-*-*n*bsd*)   case ${cpu} in
 273                             x86_64)     fmt=elf em=nbsd ;;
 274                             *)          fmt=aout em=nbsd ;;
 275                         esac ;;
 276       i386-*-linux*aout*)               fmt=aout em=linux ;;
 277       i386-*-linux*oldld)               fmt=aout em=linux ;;
 278       i386-*-linux*coff*)               fmt=coff em=linux ;;
 279       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 280       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 281       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 282 changequote(,)dnl
 283       i386-*-sysv[45]*)                 fmt=elf ;;
 284       i386-*-solaris*)                  fmt=elf ;;
 285       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 286       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 287       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 288 changequote([,])dnl
 289       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 290                                         fmt=elf em=freebsd ;;
 291       i386-*-sysv*)                     fmt=coff ;;
 292       i386-*-sco3.2v5*coff)             fmt=coff ;;
 293       i386-*-isc*)                      fmt=coff ;;
 294       i386-*-sco3.2v5*)                 fmt=elf
 295           if test ${this_target} = $target; then
 296             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 297           fi ;;
 298       i386-*-sco3.2*)                   fmt=coff ;;
 299       i386-*-vsta)                      fmt=aout ;;
 300       i386-*-msdosdjgpp* \
 301       | i386-*-go32* \
 302       | i386-go32-rtems*)               fmt=coff em=go32
 303             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 304       i386-*-rtemself*)                 fmt=elf ;;
 305       i386-*-rtemscoff*)                fmt=coff ;;
 306       i386-*-rtems*)                    fmt=elf ;;
 307       i386-*-gnu*)                      fmt=elf ;;
 308       i386-*-mach*)                     fmt=aout em=mach ;;
 309       i386-*-msdos*)                    fmt=aout ;;
 310       i386-*-moss*)                     fmt=elf ;;
 311       i386-*-pe)                        fmt=coff em=pe ;;
 312       i386-*-cygwin*)                   fmt=coff em=pe ;;
 313       i386-*-interix*)                  fmt=coff em=interix ;;
 314       i386-*-mingw32*)                  fmt=coff em=pe ;;
 315       i386-*-nto-qnx*)                  fmt=elf ;;
 316       i386-*-*nt*)                      fmt=coff em=pe ;;
 317       i386-*-vxworks*)                  fmt=aout ;;
 318       i386-*-chaos)                     fmt=elf ;;
 319
 320       i860-*-*)                         fmt=elf endian=little
 321                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 322       i960-*-bout)                      fmt=bout ;;
 323       i960-*-coff)                      fmt=coff em=ic960 ;;
 324       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 325       i960-*-nindy*)                    fmt=bout ;;
 326       i960-*-vxworks5.0)                fmt=bout ;;
 327       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 328       i960-*-vxworks*)                  fmt=bout ;;
 329       i960-*-elf*)                      fmt=elf ;;
 330
 331       ia64-*-elf*)                      fmt=elf ;;
 332       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 333       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 334       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 335       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 336
 337       ip2k-*-*)                         fmt=elf ;;
 338
 339       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 340
 341       m32r-*-*)                         fmt=elf ;;
 342
 343       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 344       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 345
 346       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 347       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 348       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 349       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 350       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 351       m68k-apollo-*)                    fmt=coff em=apollo ;;
 352       m68k-*-elf*)                      fmt=elf ;;
 353       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 354       m68k-*-sysv*)                     fmt=coff ;;
 355       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 356       m68k-*-rtems*)                    fmt=elf ;;
 357       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 358       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 359       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 360       m68k-*-gnu*)                      fmt=elf ;;
 361       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 362       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 363       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 364       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 365       m68k-apple-aux*)                  fmt=coff em=aux ;;
 366       m68k-*-psos*)                     fmt=elf em=psos;;
 367
 368       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 369       m88k-*-coff*)                     fmt=coff ;;
 370
 371       mcore-*-elf)                      fmt=elf ;;
 372       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 373
 374       # don't change em like *-*-bsd does
 375       mips-dec-openbsd*)                fmt=elf endian=little ;;
 376       mips-dec-bsd*)                    fmt=aout endian=little ;;
 377       mips-sony-bsd*)                   fmt=ecoff ;;
 378       mips-*-bsd*)
 379             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 380       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 381       mips-*-osf*)                      fmt=ecoff endian=little ;;
 382       mips-*-ecoff*)                    fmt=ecoff ;;
 383       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 384       mips-*-irix6*)                    fmt=elf em=irix ;;
 385       mips-*-irix5*)                    fmt=elf em=irix ;;
 386       mips-*-irix*)                     fmt=ecoff em=irix ;;
 387       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 388       mips-*-riscos*)                   fmt=ecoff ;;
 389       mips*-*-linux*)                   fmt=elf em=tmips ;;
 390       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 391       mips-*-sysv*)                     fmt=ecoff ;;
 392       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 393       mips-*-netbsd*)                   fmt=elf ;;
 394       mips-*-openbsd*)                  fmt=elf ;;
 395       mips-*-vxworks*)                  fmt=elf ;;
 396
 397       mmix-*-*)                         fmt=elf ;;
 398       mn10200-*-*)                      fmt=elf ;;
 399       mn10300-*-*)                      fmt=elf ;;
 400       msp430-*-*)                       fmt=elf ;;
 401       openrisc-*-*)                     fmt=elf ;;
 402       or32-*-rtems*)                    fmt=coff ;;
 403       or32-*-coff)                      fmt=coff ;;
 404       or32-*-elf)                       fmt=elf ;;
 405       pj*)                              fmt=elf ;;
 406
 407       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 408       ppc-*-winnt*)                     fmt=coff em=pe ;;
 409       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 410       ppc-*-aix*)                       fmt=coff ;;
 411       ppc-*-beos*)                      fmt=coff ;;
 412       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 413       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 414       ppc-*-linux-gnu*)                 fmt=elf
 415             case "$endian" in
 416                 big)  ;;
 417                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 418             esac ;;
 419       ppc-*-solaris*)                   fmt=elf
 420             if test ${this_target} = $target; then
 421                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 422                           [Define if default target is PowerPC Solaris.])
 423             fi
 424             if test x${endian} = xbig; then
 425                 AC_MSG_ERROR(Solaris must be configured little endian)
 426             fi ;;
 427       ppc-*-rtems*)                     fmt=elf ;;
 428       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 429       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 430       ppc-**-nto*)                      fmt=elf ;;
 431       ppc-*-vxworks*)                   fmt=elf ;;
 432       ppc-*-windiss*)                   fmt=elf ;;
 433       ppc-*-kaos*)                      fmt=elf ;;
 434
 435       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 436       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 437
 438       sh*-*-linux*)                     fmt=elf em=linux
 439             case ${cpu} in
 440                 sh*eb)  endian=big ;;
 441                 *)      endian=little ;;
 442             esac ;;
 443       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 444       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 445       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 446       sh-*-elf*)                        fmt=elf ;;
 447       sh-*-coff*)                       fmt=coff ;;
 448       sh-*-nto*)                        fmt=elf ;;
 449       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 450       sh-*-rtemself*)                   fmt=elf ;;
 451       sh-*-rtems*)                      fmt=coff ;;
 452       sh-*-kaos*)                       fmt=elf ;;
 453       shle*-*-kaos*)                    fmt=elf ;;
 454       sh64-*-elf*)                      fmt=elf ;;
 455
 456       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 457       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 458       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 459       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 460
 461       sparc-*-rtemsaout*)               fmt=aout ;;
 462       sparc-*-rtemself*)                fmt=elf ;;
 463       sparc-*-rtems*)                   fmt=elf ;;
 464       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 465       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 466       sparc-*-coff)                     fmt=coff ;;
 467       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 468       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 469       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 470       sparc-fujitsu-none)               fmt=aout ;;
 471       sparc-*-elf)                      fmt=elf ;;
 472       sparc-*-sysv4*)                   fmt=elf ;;
 473       sparc-*-solaris*)                 fmt=elf ;;
 474       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 475       sparc-*-*n*bsd*)  case ${cpu} in
 476                             sparc64)    fmt=elf em=nbsd ;;
 477                             *)          fmt=aout em=nbsd ;;
 478                         esac ;;
 479       strongarm-*-coff)                 fmt=coff ;;
 480       strongarm-*-elf)                  fmt=elf ;;
 481       strongarm-*-kaos*)                fmt=elf ;;
 482       xscale-*-coff)                    fmt=coff ;;
 483       xscale-*-elf)                     fmt=elf ;;
 484
 485       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 486       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 487       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 488       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 489       tic80-*-*)                        fmt=coff ;;
 490
 491       v850-*-*)                         fmt=elf ;;
 492       v850e-*-*)                        fmt=elf ;;
 493       v850ea-*-*)                       fmt=elf ;;
 494
 495       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 496       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 497       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 498       vax-*-vms)                        fmt=vms ;;
 499
 500       w65-*-*)                          fmt=coff ;;
 501
 502       xstormy16-*-*)                    fmt=elf ;;
 503
 504       xtensa-*-*)                       fmt=elf ;;
 505
 506       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 507
 508       *-*-aout | *-*-scout)             fmt=aout ;;
 509       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 510       *-*-nindy*)                       fmt=bout ;;
 511       *-*-bsd*)                         fmt=aout em=sun3 ;;
 512       *-*-generic)                      fmt=generic ;;
 513       *-*-xray | *-*-hms)               fmt=coff ;;
 514       *-*-sim)                          fmt=coff ;;
 515       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 516       *-*-aros*)                                fmt=elf em=linux bfd_gas=yes ;;
 517       *-*-vxworks)                      fmt=aout ;;
 518       *-*-netware)                      fmt=elf ;;
 519     esac
 520
 521     if test ${this_target} = $target ; then
 522       endian_def=
 523       if test x${endian} = xbig; then
 524         endian_def=1
 525       elif test x${endian} = xlittle; then
 526         endian_def=0
 527       fi
 528       if test x${endian_def} != x; then
 529         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 530                            [Define as 1 if big endian.])
 531       fi
 532     fi
 533
 534     case ${cpu_type}-${fmt} in
 535         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 536                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 537                 | *-elf | *-ecoff | *-som)
 538             bfd_gas=yes ;;
 539     esac
 540
 541 # Other random stuff.
 542
 543     case ${cpu_type} in
 544       mips)
 545         # Set mips_cpu to the name of the default CPU.
 546         case ${target_cpu} in
 547           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 548             mips_cpu=from-abi
 549             ;;
 550           mipsisa32 | mipsisa32el)
 551             mips_cpu=mips32
 552             ;;
 553           mipsisa32r2 | mipsisa32r2el)
 554             mips_cpu=mips32r2
 555             ;;
 556           mipsisa64 | mipsisa64el)
 557             mips_cpu=mips64
 558             ;;
 559           mipsisa64r2 | mipsisa64r2el)
 560             mips_cpu=mips64r2
 561             ;;
 562           mipstx39 | mipstx39el)
 563             mips_cpu=r3900
 564             ;;
 565           mips64vr | mips64vrel)
 566             mips_cpu=vr4100
 567             ;;
 568           mipsisa32r2* | mipsisa64r2*)
 569 changequote(,)dnl
 570             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 571 changequote([,])dnl
 572             ;;
 573           mips64* | mipsisa64* | mipsisa32*)
 574 changequote(,)dnl
 575             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 576 changequote([,])dnl
 577             ;;
 578           *)
 579             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 580             ;;
 581         esac
 582         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 583         # binaries.  It's a GNU extension that some OSes don't understand.
 584         # The value only matters on ELF targets.
 585         case ${target} in
 586           *-*-irix*)
 587             use_e_mips_abi_o32=0
 588             ;;
 589           *)
 590             use_e_mips_abi_o32=1
 591             ;;
 592         esac
 593         # Decide whether to generate 32-bit or 64-bit code by default.
 594         # Used to resolve -march=from-abi when an embedded ABI is selected.
 595         case ${target} in
 596           mips64*-*-* | mipsisa64*-*-*)
 597             mips_default_64bit=1
 598             ;;
 599           *)
 600             mips_default_64bit=0
 601             ;;
 602         esac
 603         # Decide which ABI to target by default.
 604         case ${target} in
 605           mips64*-linux* | mips-sgi-irix6*)
 606             mips_default_abi=N32_ABI
 607             ;;
 608           mips*-linux*)
 609             mips_default_abi=O32_ABI
 610             ;;
 611           *)
 612             mips_default_abi=NO_ABI
 613             ;;
 614         esac
 615         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 616                            [Default CPU for MIPS targets. ])
 617         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 618                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 619         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 620                            [Generate 64-bit code by default on MIPS targets. ])
 621         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 622                            [Choose a default ABI for MIPS targets. ])
 623         ;;
 624     esac
 625
 626     # Do we need the opcodes library?
 627     case ${cpu_type} in
 628       vax | i386 | tic30)
 629         ;;
 630
 631       *)
 632         need_opcodes=yes
 633
 634         case "${enable_shared}" in
 635         yes) shared_opcodes=true ;;
 636         *opcodes*) shared_opcodes=true ;;
 637         *) shared_opcodes=false ;;
 638         esac
 639         if test "${shared_opcodes}" = "true"; then
 640           # A shared libopcodes must be linked against libbfd.
 641           need_bfd=yes
 642         fi
 643         ;;
 644     esac
 645
 646     # Any other special object files needed ?
 647     case ${cpu_type} in
 648       fr30 | ip2k | iq2000 | m32r | openrisc)
 649         using_cgen=yes
 650         ;;
 651
 652       frv)
 653         using_cgen=yes
 654         ;;
 655       m68k)
 656         case ${extra_objects} in
 657         *m68k-parse.o*) ;;
 658         *) extra_objects="$extra_objects m68k-parse.o" ;;
 659         esac
 660         ;;
 661
 662       mips)
 663         echo ${extra_objects} | grep -s "itbl-parse.o"
 664         if test $? -ne 0 ; then
 665           extra_objects="$extra_objects itbl-parse.o"
 666         fi
 667
 668         echo ${extra_objects} | grep -s "itbl-lex.o"
 669         if test $? -ne 0 ; then
 670           extra_objects="$extra_objects itbl-lex.o"
 671         fi
 672
 673         echo ${extra_objects} | grep -s "itbl-ops.o"
 674         if test $? -ne 0 ; then
 675           extra_objects="$extra_objects itbl-ops.o"
 676         fi
 677         ;;
 678
 679       i386 | s390 | sparc)
 680         if test $this_target = $target ; then
 681           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 682         fi
 683         ;;
 684
 685       xstormy16)
 686         using_cgen=yes
 687         ;;
 688
 689       xtensa)
 690         echo ${extra_objects} | grep -s "xtensa-relax.o"
 691         if test $? -ne 0 ; then
 692           extra_objects="$extra_objects xtensa-relax.o"
 693         fi
 694         ;;
 695
 696       *)
 697         ;;
 698     esac
 699
 700     if test $using_cgen = yes ; then
 701         case "x${extra_objects}" in
 702         *cgen.o*) ;;
 703         *) extra_objects="$extra_objects cgen.o" ;;
 704         esac
 705     fi
 706
 707 # See if we really can support this configuration with the emulation code.
 708
 709     if test $this_target = $target ; then
 710       primary_bfd_gas=$bfd_gas
 711       obj_format=$fmt
 712       te_file=$em
 713
 714       if test $bfd_gas = no ; then
 715         # Can't support other configurations this way.
 716         break
 717       fi
 718     elif test $bfd_gas = no ; then
 719       # Can't support this configuration.
 720       break
 721     fi
 722
 723 # From target name and format, produce a list of supported emulations.
 724
 725     case ${generic_target}-${fmt} in
 726       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 727       mips*-*-linux*-*) case "$endian" in
 728                         big)    emulation="mipsbelf mipslelf mipself" ;;
 729                         *)      emulation="mipslelf mipsbelf mipself" ;;
 730                         esac ;;
 731       mips-*-lnews*-ecoff) ;;
 732       mips-*-*-ecoff)   case "$endian" in
 733                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 734                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 735                         esac ;;
 736       mips-*-*-elf)     case "$endian" in
 737                         big)    emulation="mipsbelf mipslelf mipself" ;;
 738                         *)      emulation="mipslelf mipsbelf mipself" ;;
 739                         esac ;;
 740       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 741       # i386-pc-pe-coff != i386-pc-coff.
 742       i386-*-pe-coff)   ;;
 743       # Uncommenting the next line will turn on support for i386 AOUT
 744       # for the default linux configuration
 745       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 746       #
 747       i386-*-aout)      emulation="i386aout" ;;
 748       i386-*-coff)      emulation="i386coff" ;;
 749       i386-*-elf)       emulation="i386elf" ;;
 750
 751       # Always all formats.  The first stated emulation becomes the default.
 752       cris-*-*aout*)    emulation="crisaout criself" ;;
 753       cris-*-*)         emulation="criself crisaout" ;;
 754     esac
 755
 756     emulations="$emulations $emulation"
 757
 758 done
 759
 760 # Turn on all targets if possible
 761 if test ${all_targets} = "yes"; then
 762   case ${target_cpu_type} in
 763   i386)
 764     case ${obj_format} in
 765     aout)
 766       emulations="$emulations i386coff i386elf"
 767       ;;
 768     coff)
 769       emulations="$emulations i386aout i386elf"
 770     ;;
 771     elf)
 772       emulations="$emulations i386aout i386coff"
 773       ;;
 774     esac
 775   ;;
 776   esac
 777 fi
 778
 779 # Assign floating point type.  Most processors with FP support
 780 # IEEE FP.  On those that don't support FP at all, usually IEEE
 781 # is emulated.
 782 case ${target_cpu} in
 783   vax | tahoe ) atof=${target_cpu} ;;
 784   pdp11)        atof=vax ;;
 785   *)            atof=ieee ;;
 786 esac
 787
 788 case "${obj_format}" in
 789   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 790 esac
 791
 792 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 793 cgen_cpu_prefix=""
 794 if test $using_cgen = yes ; then
 795   case ${target_cpu} in
 796     *) cgen_cpu_prefix=${target_cpu} ;;
 797   esac
 798   AC_SUBST(cgen_cpu_prefix)
 799   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 800 fi
 801
 802 dnl
 803 dnl Make sure the desired support files exist.
 804 dnl
 805
 806 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 807   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 808 fi
 809
 810 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 811   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 812 fi
 813
 814 case ${user_bfd_gas}-${primary_bfd_gas} in
 815   yes-yes | no-no)
 816     # We didn't override user's choice.
 817     ;;
 818   no-yes)
 819     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 820     ;;
 821   no-preferred)
 822     primary_bfd_gas=no
 823     ;;
 824   *-preferred)
 825     primary_bfd_gas=yes
 826     ;;
 827   yes-*)
 828     primary_bfd_gas=yes
 829     ;;
 830   -*)
 831     # User specified nothing.
 832     ;;
 833 esac
 834
 835 # Some COFF configurations want these random other flags set.
 836 case ${obj_format} in
 837   coff)
 838     case ${target_cpu_type} in
 839       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 840       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 841       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 842     esac
 843     ;;
 844 esac
 845
 846 # Getting this done right is going to be a bitch.  Each configuration specified
 847 # with --enable-targets=... should be checked for environment, format, cpu, and
 848 # bfd_gas setting.
 849 #
 850 # For each configuration, the necessary object file support code must be linked
 851 # in.  This might be only one, it might be up to four.  The necessary emulation
 852 # code needs to be provided, too.
 853 #
 854 # And then there's "--enable-targets=all"....
 855 #
 856 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 857
 858 formats="${obj_format}"
 859 emfiles=""
 860 EMULATIONS=""
 861 GAS_UNIQ(emulations)
 862 for em in . $emulations ; do
 863   case $em in
 864     .)  continue ;;
 865     mipsbelf | mipslelf | mipself)
 866         fmt=elf   file=mipself ;;
 867     mipsbecoff | mipslecoff | mipsecoff)
 868         fmt=ecoff file=mipsecoff ;;
 869     *coff)
 870         fmt=coff  file=$em ;;
 871     *aout)
 872         fmt=aout file=$em ;;
 873     *elf)
 874         fmt=elf file=$em ;;
 875   esac
 876   formats="$formats $fmt"
 877   emfiles="$emfiles e-$file.o"
 878   EMULATIONS="$EMULATIONS &$em,"
 879 done
 880 GAS_UNIQ(formats)
 881 GAS_UNIQ(emfiles)
 882 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 883   for fmt in $formats ; do
 884     case $fmt in
 885       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 886       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 887       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 888       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 889       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 890       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 891       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 892       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 893       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 894       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 895     esac
 896     extra_objects="$extra_objects obj-$fmt.o"
 897   done
 898   obj_format=multi
 899 fi
 900 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 901   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 902   # e-mips* has more than one emulation per file, e-i386* has just one at the
 903   # moment.  If only one emulation is specified, then don't define
 904   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 905   case "${obj_format}${emfiles}" in
 906     multi* | *mips*)
 907       extra_objects="$extra_objects $emfiles"
 908       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 909   esac
 910 fi
 911 AC_SUBST(extra_objects)
 912 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 913 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 914                    [Default emulation.])
 915
 916 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 917   yes-*-coff)   need_bfd=yes ;;
 918   no-*-coff)    need_bfd=yes
 919                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 920 esac
 921
 922 reject_dev_configs=yes
 923
 924 case ${reject_dev_configs}-${dev} in
 925   yes-yes) # Oops.
 926     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 927     ;;
 928 esac
 929
 930 AC_SUBST(target_cpu_type)
 931 AC_SUBST(obj_format)
 932 AC_SUBST(te_file)
 933 AC_SUBST(install_tooldir)
 934 AC_SUBST(atof)
 935 dnl AC_SUBST(emulation)
 936
 937 case "${primary_bfd_gas}" in
 938   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 939         need_bfd=yes ;;
 940 esac
 941
 942 # do we need the opcodes library?
 943 case "${need_opcodes}" in
 944 yes)
 945   OPCODES_LIB=../opcodes/libopcodes.la
 946   ;;
 947 esac
 948
 949 case "${need_bfd}" in
 950 yes)
 951   BFDLIB=../bfd/libbfd.la
 952   BFDVER_H=../bfd/bfdver.h
 953   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 954   ;;
 955 esac
 956
 957 AC_SUBST(BFDLIB)
 958 AC_SUBST(OPCODES_LIB)
 959
 960 AC_SUBST(BFDVER_H)
 961 AC_SUBST(ALL_OBJ_DEPS)
 962
 963 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 964 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 965 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 966 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 967 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 968
 969 AC_PROG_CC
 970
 971 AC_PROG_YACC
 972 AM_PROG_LEX
 973
 974 ALL_LINGUAS="fr tr es"
 975 CY_GNU_GETTEXT
 976
 977 AM_MAINTAINER_MODE
 978 AC_EXEEXT
 979
 980 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 981
 982 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 983 # people who are not cross-compiling but are compiling cross-assemblers.
 984 AC_MSG_CHECKING(whether compiling a cross-assembler)
 985 if test "${host}" = "${target}"; then
 986   cross_gas=no
 987 else
 988   cross_gas=yes
 989   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 990 fi
 991 AC_MSG_RESULT($cross_gas)
 992
 993 dnl ansidecl.h will deal with const
 994 dnl AC_CONST
 995 AC_FUNC_ALLOCA
 996 AC_C_INLINE
 997
 998 # VMS doesn't have unlink.
 999 AC_CHECK_FUNCS(unlink remove, break)
1000
1001 # Some systems don't have sbrk().
1002 AC_CHECK_FUNCS(sbrk)
1003
1004 # do we need the math library?
1005 case "${need_libm}" in
1006 yes)
1007   AC_CHECK_LIBM
1008   AC_SUBST(LIBM)
1009   ;;
1010 esac
1011
1012 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1013 # enough, but on some of those systems, the assert macro relies on requoting
1014 # working properly!
1015 GAS_WORKING_ASSERT
1016
1017 # On some systems, the system header files may not declare malloc, realloc,
1018 # and free.  There are places where gas needs these functions to have been
1019 # declared -- such as when taking their addresses.
1020 gas_test_headers="
1021 #ifdef HAVE_MEMORY_H
1022 #include <memory.h>
1023 #endif
1024 #ifdef HAVE_STRING_H
1025 #include <string.h>
1026 #else
1027 #ifdef HAVE_STRINGS_H
1028 #include <strings.h>
1029 #endif
1030 #endif
1031 #ifdef HAVE_STDLIB_H
1032 #include <stdlib.h>
1033 #endif
1034 #ifdef HAVE_UNISTD_H
1035 #include <unistd.h>
1036 #endif
1037 "
1038 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1039 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1040 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1041 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1042 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1043
1044 # Does errno.h declare errno, or do we have to add a separate declaration
1045 # for it?
1046 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1047 #ifdef HAVE_ERRNO_H
1048 #include <errno.h>
1049 #endif
1050 ])
1051
1052 dnl This must come last.
1053
1054 dnl We used to make symlinks to files in the source directory, but now
1055 dnl we just use the right name for .c files, and create .h files in
1056 dnl the build directory which include the right .h file.  Make sure
1057 dnl the old symlinks don't exist, so that a reconfigure in an existing
1058 dnl directory behaves reasonably.
1059
1060 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1061 AC_CONFIG_COMMANDS([default],
1062 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1063  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1064  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1065  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1066  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1067  if test "x$cgen_cpu_prefix" != x ; then
1068    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1069  fi
1070
1071  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1072 [target_cpu_type=${target_cpu_type}
1073  cgen_cpu_prefix=${cgen_cpu_prefix}
1074  obj_format=${obj_format}
1075  te_file=${te_file}])
1076
1077 AC_OUTPUT