gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52
  53 AC_ARG_ENABLE(werror,
  54   [  --enable-werror    treat compile warnings as errors],
  55   [case "${enableval}" in
  56      yes | y) ERROR_ON_WARNING="yes" ;;
  57      no | n)  ERROR_ON_WARNING="no" ;;
  58      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  59    esac])
  60
  61 # Enable -Werror by default, suppressing it only for --disable-werror
  62 # or --disable-build-warnings.
  63 if test "${ERROR_ON_WARNING}" != no
  64 then
  65   build_warnings="$build_warnings -Werror"
  66 fi
  67
  68 AC_ARG_ENABLE(build-warnings,
  69 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  70 [case "${enableval}" in
  71   yes)  ;;
  72   no)   build_warnings="-w";;
  73   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  74         build_warnings="${build_warnings} ${t}";;
  75   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  76         build_warnings="${t} ${build_warnings}";;
  77   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  78 esac
  79 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  80   echo "Setting warning flags = $build_warnings" 6>&1
  81 fi])dnl
  82 WARN_CFLAGS=""
  83 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  84     WARN_CFLAGS="${build_warnings}"
  85 fi
  86 AC_SUBST(WARN_CFLAGS)
  87
  88 # Generate a header file
  89 AM_CONFIG_HEADER(config.h:config.in)
  90
  91 # If we are on a DOS filesystem, we must use gdb.ini rather than
  92 # .gdbinit.
  93 case "${host}" in
  94   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  95     GDBINIT="gdb.ini"
  96     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  97     ;;
  98   *)
  99     GDBINIT=".gdbinit"
 100     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 101     ;;
 102 esac
 103 AC_SUBST(GDBINIT)
 104
 105 #We need this for the host.  BOUT header is in host order.
 106 AC_C_BIGENDIAN
 107
 108 te_file=generic
 109
 110 # Makefile target for installing gas in $(tooldir)/bin.
 111 install_tooldir=install-exec-tooldir
 112
 113 canon_targets=""
 114 all_targets=no
 115 if test -n "$enable_targets" ; then
 116   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 117     if test $t = "all"; then
 118       all_targets=yes
 119       continue
 120     fi
 121     result=`$ac_config_sub $t 2>/dev/null`
 122     if test -n "$result" ; then
 123       canon_targets="$canon_targets $result"
 124 #    else
 125 #      # Permit "all", etc.  We don't support it yet though.
 126 #      canon_targets="$canon_targets $t"
 127     fi
 128   done
 129   GAS_UNIQ(canon_targets)
 130 fi
 131
 132 emulations=""
 133
 134 for this_target in $target $canon_targets ; do
 135
 136     targ=${this_target}
 137     . ${srcdir}/configure.tgt
 138
 139     case ${target_cpu} in
 140       crisv32)
 141         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 142                            [Default CRIS architecture.])
 143         ;;
 144     esac
 145
 146     if test ${this_target} = $target ; then
 147       target_cpu_type=${cpu_type}
 148     elif test ${target_cpu_type} != ${cpu_type} ; then
 149       continue
 150     fi
 151
 152     generic_target=${cpu_type}-${target_vendor}-${target_os}
 153     case ${generic_target} in
 154       i386-*-sco3.2v5*)
 155         if test ${this_target} = $target; then
 156           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 157         fi
 158         ;;
 159
 160       i386-*-msdosdjgpp* \
 161       | i386-*-go32* \
 162       | i386-go32-rtems*)
 163         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 164         ;;
 165
 166       i860-*-*)
 167         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 168         ;;
 169
 170       mips-sony-bsd*)
 171         ;;
 172       mips-*-bsd*)
 173         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 174         ;;
 175
 176       ppc-*-aix5.*)
 177         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 178                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 179         ;;
 180       ppc-*-linux-*)
 181         case "$endian" in
 182           big)  ;;
 183           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 184         esac
 185         ;;
 186       ppc-*-solaris*)
 187         if test ${this_target} = $target; then
 188           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 189                     [Define if default target is PowerPC Solaris.])
 190         fi
 191         if test x${endian} = xbig; then
 192           AC_MSG_ERROR(Solaris must be configured little endian)
 193         fi
 194         ;;
 195
 196       sh*-*-symbianelf*)
 197         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 198         ;;
 199     esac
 200
 201     if test ${this_target} = $target ; then
 202       endian_def=
 203       if test x${endian} = xbig; then
 204         endian_def=1
 205       elif test x${endian} = xlittle; then
 206         endian_def=0
 207       fi
 208       if test x${endian_def} != x; then
 209         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 210                            [Define as 1 if big endian.])
 211       fi
 212     fi
 213
 214 # Other random stuff.
 215
 216     case ${cpu_type} in
 217       mips)
 218         # Set mips_cpu to the name of the default CPU.
 219         case ${target_cpu} in
 220           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 221             mips_cpu=from-abi
 222             ;;
 223           mipsisa32 | mipsisa32el)
 224             mips_cpu=mips32
 225             ;;
 226           mipsisa32r2 | mipsisa32r2el)
 227             mips_cpu=mips32r2
 228             ;;
 229           mipsisa64 | mipsisa64el)
 230             mips_cpu=mips64
 231             ;;
 232           mipsisa64r2 | mipsisa64r2el)
 233             mips_cpu=mips64r2
 234             ;;
 235           mipstx39 | mipstx39el)
 236             mips_cpu=r3900
 237             ;;
 238           mips64vr | mips64vrel)
 239             mips_cpu=vr4100
 240             ;;
 241           mipsisa32r2* | mipsisa64r2*)
 242 changequote(,)dnl
 243             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 244 changequote([,])dnl
 245             ;;
 246           mips64* | mipsisa64* | mipsisa32*)
 247 changequote(,)dnl
 248             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 249 changequote([,])dnl
 250             ;;
 251           *)
 252             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 253             ;;
 254         esac
 255         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 256         # binaries.  It's a GNU extension that some OSes don't understand.
 257         # The value only matters on ELF targets.
 258         case ${target} in
 259           *-*-irix*)
 260             use_e_mips_abi_o32=0
 261             ;;
 262           *)
 263             use_e_mips_abi_o32=1
 264             ;;
 265         esac
 266         # Decide whether to generate 32-bit or 64-bit code by default.
 267         # Used to resolve -march=from-abi when an embedded ABI is selected.
 268         case ${target} in
 269           mips64*-*-* | mipsisa64*-*-*)
 270             mips_default_64bit=1
 271             ;;
 272           *)
 273             mips_default_64bit=0
 274             ;;
 275         esac
 276         # Decide which ABI to target by default.
 277         case ${target} in
 278           mips64*-linux* | mips-sgi-irix6*)
 279             mips_default_abi=N32_ABI
 280             ;;
 281           mips*-linux*)
 282             mips_default_abi=O32_ABI
 283             ;;
 284           *)
 285             mips_default_abi=NO_ABI
 286             ;;
 287         esac
 288         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 289                            [Default CPU for MIPS targets. ])
 290         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 291                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 292         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 293                            [Generate 64-bit code by default on MIPS targets. ])
 294         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 295                            [Choose a default ABI for MIPS targets. ])
 296         ;;
 297     esac
 298
 299     # Do we need the opcodes library?
 300     case ${cpu_type} in
 301       vax | i386 | tic30)
 302         ;;
 303
 304       *)
 305         need_opcodes=yes
 306
 307         case "${enable_shared}" in
 308         yes) shared_opcodes=true ;;
 309         *opcodes*) shared_opcodes=true ;;
 310         *) shared_opcodes=false ;;
 311         esac
 312         if test "${shared_opcodes}" = "true"; then
 313           # A shared libopcodes must be linked against libbfd.
 314           need_bfd=yes
 315         fi
 316         ;;
 317     esac
 318
 319     # Any other special object files needed ?
 320     case ${cpu_type} in
 321       fr30 | ip2k | iq2000 | m32r | openrisc)
 322         using_cgen=yes
 323         ;;
 324
 325       frv)
 326         using_cgen=yes
 327         ;;
 328       m68k)
 329         case ${extra_objects} in
 330         *m68k-parse.o*) ;;
 331         *) extra_objects="$extra_objects m68k-parse.o" ;;
 332         esac
 333         ;;
 334
 335       mips)
 336         echo ${extra_objects} | grep -s "itbl-parse.o"
 337         if test $? -ne 0 ; then
 338           extra_objects="$extra_objects itbl-parse.o"
 339         fi
 340
 341         echo ${extra_objects} | grep -s "itbl-lex.o"
 342         if test $? -ne 0 ; then
 343           extra_objects="$extra_objects itbl-lex.o"
 344         fi
 345
 346         echo ${extra_objects} | grep -s "itbl-ops.o"
 347         if test $? -ne 0 ; then
 348           extra_objects="$extra_objects itbl-ops.o"
 349         fi
 350         ;;
 351
 352       i386 | s390 | sparc)
 353         if test $this_target = $target ; then
 354           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 355         fi
 356         ;;
 357
 358       xstormy16)
 359         using_cgen=yes
 360         ;;
 361
 362       xtensa)
 363         echo ${extra_objects} | grep -s "xtensa-relax.o"
 364         if test $? -ne 0 ; then
 365           extra_objects="$extra_objects xtensa-relax.o"
 366         fi
 367         ;;
 368
 369       *)
 370         ;;
 371     esac
 372
 373     if test $using_cgen = yes ; then
 374         case "x${extra_objects}" in
 375         *cgen.o*) ;;
 376         *) extra_objects="$extra_objects cgen.o" ;;
 377         esac
 378     fi
 379
 380 # See if we really can support this configuration with the emulation code.
 381
 382     if test $this_target = $target ; then
 383       primary_bfd_gas=$bfd_gas
 384       obj_format=$fmt
 385       te_file=$em
 386
 387       if test $bfd_gas = no ; then
 388         # Can't support other configurations this way.
 389         break
 390       fi
 391     elif test $bfd_gas = no ; then
 392       # Can't support this configuration.
 393       break
 394     fi
 395
 396 # From target name and format, produce a list of supported emulations.
 397
 398     case ${generic_target}-${fmt} in
 399       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 400       mips*-*-linux*-*) case "$endian" in
 401                         big)    emulation="mipsbelf mipslelf mipself" ;;
 402                         *)      emulation="mipslelf mipsbelf mipself" ;;
 403                         esac ;;
 404       mips-*-lnews*-ecoff) ;;
 405       mips-*-*-ecoff)   case "$endian" in
 406                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 407                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 408                         esac ;;
 409       mips-*-*-elf)     case "$endian" in
 410                         big)    emulation="mipsbelf mipslelf mipself" ;;
 411                         *)      emulation="mipslelf mipsbelf mipself" ;;
 412                         esac ;;
 413       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 414       # i386-pc-pe-coff != i386-pc-coff.
 415       i386-*-pe-coff)   ;;
 416       # Uncommenting the next line will turn on support for i386 AOUT
 417       # for the default linux configuration
 418       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 419       #
 420       i386-*-aout)      emulation="i386aout" ;;
 421       i386-*-coff)      emulation="i386coff" ;;
 422       i386-*-elf)       emulation="i386elf" ;;
 423
 424       # Always all formats.  The first stated emulation becomes the default.
 425       cris-*-*aout*)    emulation="crisaout criself" ;;
 426       cris-*-*)         emulation="criself crisaout" ;;
 427     esac
 428
 429     emulations="$emulations $emulation"
 430
 431 done
 432
 433 # Turn on all targets if possible
 434 if test ${all_targets} = "yes"; then
 435   case ${target_cpu_type} in
 436   i386)
 437     case ${obj_format} in
 438     aout)
 439       emulations="$emulations i386coff i386elf"
 440       ;;
 441     coff)
 442       emulations="$emulations i386aout i386elf"
 443     ;;
 444     elf)
 445       emulations="$emulations i386aout i386coff"
 446       ;;
 447     esac
 448   ;;
 449   esac
 450 fi
 451
 452 # Assign floating point type.  Most processors with FP support
 453 # IEEE FP.  On those that don't support FP at all, usually IEEE
 454 # is emulated.
 455 case ${target_cpu} in
 456   vax | tahoe ) atof=${target_cpu} ;;
 457   pdp11)        atof=vax ;;
 458   *)            atof=ieee ;;
 459 esac
 460
 461 case "${obj_format}" in
 462   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 463 esac
 464
 465 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 466 cgen_cpu_prefix=""
 467 if test $using_cgen = yes ; then
 468   case ${target_cpu} in
 469     *) cgen_cpu_prefix=${target_cpu} ;;
 470   esac
 471   AC_SUBST(cgen_cpu_prefix)
 472   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 473 fi
 474
 475 dnl
 476 dnl Make sure the desired support files exist.
 477 dnl
 478
 479 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 480   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 481 fi
 482
 483 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 484   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 485 fi
 486
 487 case ${user_bfd_gas}-${primary_bfd_gas} in
 488   yes-yes | no-no)
 489     # We didn't override user's choice.
 490     ;;
 491   no-yes)
 492     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 493     ;;
 494   no-preferred)
 495     primary_bfd_gas=no
 496     ;;
 497   *-preferred)
 498     primary_bfd_gas=yes
 499     ;;
 500   yes-*)
 501     primary_bfd_gas=yes
 502     ;;
 503   -*)
 504     # User specified nothing.
 505     ;;
 506 esac
 507
 508 # Some COFF configurations want these random other flags set.
 509 case ${obj_format} in
 510   coff)
 511     case ${target_cpu_type} in
 512       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 513       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 514       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 515     esac
 516     ;;
 517 esac
 518
 519 # Getting this done right is going to be a bitch.  Each configuration specified
 520 # with --enable-targets=... should be checked for environment, format, cpu, and
 521 # bfd_gas setting.
 522 #
 523 # For each configuration, the necessary object file support code must be linked
 524 # in.  This might be only one, it might be up to four.  The necessary emulation
 525 # code needs to be provided, too.
 526 #
 527 # And then there's "--enable-targets=all"....
 528 #
 529 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 530
 531 formats="${obj_format}"
 532 emfiles=""
 533 EMULATIONS=""
 534 GAS_UNIQ(emulations)
 535 for em in . $emulations ; do
 536   case $em in
 537     .)  continue ;;
 538     mipsbelf | mipslelf | mipself)
 539         fmt=elf   file=mipself ;;
 540     mipsbecoff | mipslecoff | mipsecoff)
 541         fmt=ecoff file=mipsecoff ;;
 542     *coff)
 543         fmt=coff  file=$em ;;
 544     *aout)
 545         fmt=aout file=$em ;;
 546     *elf)
 547         fmt=elf file=$em ;;
 548   esac
 549   formats="$formats $fmt"
 550   emfiles="$emfiles e-$file.o"
 551   EMULATIONS="$EMULATIONS &$em,"
 552 done
 553 GAS_UNIQ(formats)
 554 GAS_UNIQ(emfiles)
 555 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 556   for fmt in $formats ; do
 557     case $fmt in
 558       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 559       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 560       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 561       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 562       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 563       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 564       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 565       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 566       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 567     esac
 568     extra_objects="$extra_objects obj-$fmt.o"
 569   done
 570   obj_format=multi
 571 fi
 572 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 573   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 574   # e-mips* has more than one emulation per file, e-i386* has just one at the
 575   # moment.  If only one emulation is specified, then don't define
 576   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 577   case "${obj_format}${emfiles}" in
 578     multi* | *mips*)
 579       extra_objects="$extra_objects $emfiles"
 580       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 581   esac
 582 fi
 583 AC_SUBST(extra_objects)
 584 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 585 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 586                    [Default emulation.])
 587
 588 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 589   yes-*-coff)   need_bfd=yes ;;
 590   no-*-coff)    need_bfd=yes
 591                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 592 esac
 593
 594 reject_dev_configs=yes
 595
 596 case ${reject_dev_configs}-${dev} in
 597   yes-yes) # Oops.
 598     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 599     ;;
 600 esac
 601
 602 AC_SUBST(target_cpu_type)
 603 AC_SUBST(obj_format)
 604 AC_SUBST(te_file)
 605 AC_SUBST(install_tooldir)
 606 AC_SUBST(atof)
 607 dnl AC_SUBST(emulation)
 608
 609 case "${primary_bfd_gas}" in
 610   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 611         need_bfd=yes ;;
 612 esac
 613
 614 # do we need the opcodes library?
 615 case "${need_opcodes}" in
 616 yes)
 617   OPCODES_LIB=../opcodes/libopcodes.la
 618   ;;
 619 esac
 620
 621 case "${need_bfd}" in
 622 yes)
 623   BFDLIB=../bfd/libbfd.la
 624   BFDVER_H=../bfd/bfdver.h
 625   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 626   ;;
 627 esac
 628
 629 AC_SUBST(BFDLIB)
 630 AC_SUBST(OPCODES_LIB)
 631
 632 AC_SUBST(BFDVER_H)
 633 AC_SUBST(ALL_OBJ_DEPS)
 634
 635 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 636 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 637 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 638 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 639 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 640
 641 AC_PROG_CC
 642
 643 AC_PROG_YACC
 644 AM_PROG_LEX
 645
 646 ALL_LINGUAS="fr tr es"
 647 CY_GNU_GETTEXT
 648
 649 AM_MAINTAINER_MODE
 650 AC_EXEEXT
 651
 652 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 653
 654 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 655 # people who are not cross-compiling but are compiling cross-assemblers.
 656 AC_MSG_CHECKING(whether compiling a cross-assembler)
 657 if test "${host}" = "${target}"; then
 658   cross_gas=no
 659 else
 660   cross_gas=yes
 661   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 662 fi
 663 AC_MSG_RESULT($cross_gas)
 664
 665 dnl ansidecl.h will deal with const
 666 dnl AC_CONST
 667 AC_FUNC_ALLOCA
 668 AC_C_INLINE
 669
 670 # VMS doesn't have unlink.
 671 AC_CHECK_FUNCS(unlink remove, break)
 672
 673 # Some systems don't have sbrk().
 674 AC_CHECK_FUNCS(sbrk)
 675
 676 # do we need the math library?
 677 case "${need_libm}" in
 678 yes)
 679   AC_CHECK_LIBM
 680   AC_SUBST(LIBM)
 681   ;;
 682 esac
 683
 684 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 685 # enough, but on some of those systems, the assert macro relies on requoting
 686 # working properly!
 687 GAS_WORKING_ASSERT
 688
 689 # On some systems, the system header files may not declare malloc, realloc,
 690 # and free.  There are places where gas needs these functions to have been
 691 # declared -- such as when taking their addresses.
 692 gas_test_headers="
 693 #ifdef HAVE_MEMORY_H
 694 #include <memory.h>
 695 #endif
 696 #ifdef HAVE_STRING_H
 697 #include <string.h>
 698 #else
 699 #ifdef HAVE_STRINGS_H
 700 #include <strings.h>
 701 #endif
 702 #endif
 703 #ifdef HAVE_STDLIB_H
 704 #include <stdlib.h>
 705 #endif
 706 #ifdef HAVE_UNISTD_H
 707 #include <unistd.h>
 708 #endif
 709 "
 710
 711 # Does errno.h declare errno, or do we have to add a separate declaration
 712 # for it?
 713 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 714 #ifdef HAVE_ERRNO_H
 715 #include <errno.h>
 716 #endif
 717 ])
 718
 719 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 720 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 721 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 722 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 723 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 724 if test $gas_cv_decl_getopt_unistd_h = yes; then
 725   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 726             [Is the prototype for getopt in <unistd.h> in the expected format?])
 727 fi
 728
 729 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 730 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 731 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 732 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 733 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 734 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 735
 736 dnl This must come last.
 737
 738 dnl We used to make symlinks to files in the source directory, but now
 739 dnl we just use the right name for .c files, and create .h files in
 740 dnl the build directory which include the right .h file.  Make sure
 741 dnl the old symlinks don't exist, so that a reconfigure in an existing
 742 dnl directory behaves reasonably.
 743
 744 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 745 AC_CONFIG_COMMANDS([default],
 746 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 747  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 748  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 749  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 750  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 751  if test "x$cgen_cpu_prefix" != x ; then
 752    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 753  fi
 754
 755  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 756 [target_cpu_type=${target_cpu_type}
 757  cgen_cpu_prefix=${cgen_cpu_prefix}
 758  obj_format=${obj_format}
 759  te_file=${te_file}])
 760
 761 AC_OUTPUT