gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 119       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 120       hppa*)            cpu_type=hppa ;;
 121 changequote(,)dnl
 122       i[3-7]86)         cpu_type=i386 arch=i386;;
 123       x86_64)           cpu_type=i386 arch=x86_64;;
 124       ia64)             cpu_type=ia64 ;;
 125       ip2k)             cpu_type=ip2k endian=big ;;
 126       iq2000)           cpu_type=iq2000 endian=big ;;
 127       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 128       m680[012346]0)    cpu_type=m68k ;;
 129 changequote([,])dnl
 130       m68008)           cpu_type=m68k ;;
 131       m683??)           cpu_type=m68k ;;
 132       m5200)            cpu_type=m68k ;;
 133       m8*)              cpu_type=m88k ;;
 134       mips*el)          cpu_type=mips endian=little ;;
 135       mips*)            cpu_type=mips endian=big ;;
 136       or32*)            cpu_type=or32 endian=big ;;
 137       pjl*)             cpu_type=pj endian=little ;;
 138       pj*)              cpu_type=pj endian=big ;;
 139       powerpc*le*)      cpu_type=ppc endian=little ;;
 140       powerpc*)         cpu_type=ppc endian=big ;;
 141       rs6000*)          cpu_type=ppc ;;
 142       s390x*)           cpu_type=s390 arch=s390x ;;
 143       s390*)            cpu_type=s390 arch=s390 ;;
 144       sh5*)             cpu_type=sh64 endian=big ;;
 145       sh5le*)           cpu_type=sh64 endian=little ;;
 146       sh64*)            cpu_type=sh64 endian=big ;;
 147       sh64le*)          cpu_type=sh64 endian=little ;;
 148       sh*le)            cpu_type=sh endian=little ;;
 149       sh*)              cpu_type=sh endian=big ;;
 150       sparclite*)       cpu_type=sparc arch=sparclite ;;
 151       sparclet*)        cpu_type=sparc arch=sparclet ;;
 152       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 153       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 154       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 155       v850*)            cpu_type=v850 ;;
 156       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 157       *)                cpu_type=${cpu} ;;
 158     esac
 159
 160     if test ${this_target} = $target ; then
 161       target_cpu_type=${cpu_type}
 162     elif test ${target_cpu_type} != ${cpu_type} ; then
 163       continue
 164     fi
 165
 166     generic_target=${cpu_type}-$vendor-$os
 167     dev=no
 168     bfd_gas=no
 169     em=generic
 170
 171     # assign object format
 172     case ${generic_target} in
 173       a29k-*-coff)                      fmt=coff ;;
 174       a29k-amd-udi)                     fmt=coff ;;
 175       a29k-amd-ebmon)                   fmt=coff ;;
 176       a29k-nyu-sym1)                    fmt=coff ;;
 177       a29k-*-rtems*)                    fmt=coff ;;
 178       a29k-*-vxworks*)                  fmt=coff ;;
 179
 180       alpha*-*-*vms*)                   fmt=evax ;;
 181       alpha*-*-netware*)                fmt=ecoff ;;
 182       alpha*-*-osf*)                    fmt=ecoff ;;
 183       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 184       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 185       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 186       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 187
 188       arc-*-elf*)                       fmt=elf ;;
 189
 190       arm-*-aout)                       fmt=aout ;;
 191       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 192       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 193       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 194       arm-*-kaos*)                      fmt=elf ;;
 195       arm*-*-conix*)                    fmt=elf ;;
 196       arm-*-linux*aout*)                fmt=aout em=linux ;;
 197       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 198       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 199       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 200       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 201       arm-**-nto*)                      fmt=elf ;;
 202       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 203       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 204       arm-*-wince)                      fmt=coff em=wince-pe ;;
 205       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 206       arm-*-riscix*)                    fmt=aout em=riscix ;;
 207       arm-*-vxworks)                    fmt=coff ;;
 208
 209       avr-*-*)                          fmt=elf ;;
 210
 211       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 212       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 213
 214       d10v-*-*)                         fmt=elf ;;
 215       d30v-*-*)                         fmt=elf ;;
 216       dlx-*-*)                          fmt=elf ;;
 217
 218       fr30-*-*)                         fmt=elf ;;
 219       frv-*-*)                          fmt=elf ;;
 220
 221       hppa-*-linux*)    case ${cpu} in
 222                             hppa*64*)   fmt=elf em=hppalinux64;;
 223                             hppa*)      fmt=elf em=linux;;
 224                         esac ;;
 225       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 226       hppa-*-lites*)                    fmt=elf em=hppa ;;
 227       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 228       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 229       hppa-*-osf*)                      fmt=som em=hppa ;;
 230       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 231       hppa-*-hpux11*)   case ${cpu} in
 232                             hppa*64*)   fmt=elf em=hppa64 ;;
 233                             hppa*)      fmt=som em=hppa ;;
 234                         esac ;;
 235       hppa-*-hpux*)                     fmt=som em=hppa ;;
 236       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 237       hppa-*-bsd*)                      fmt=som em=hppa ;;
 238       hppa-*-hiux*)                     fmt=som em=hppa ;;
 239
 240       h8300-*-rtems*)                   fmt=coff ;;
 241       h8300-*-coff)                     fmt=coff ;;
 242       h8300-*-elf)                      fmt=elf ;;
 243       h8500-*-rtems*)                   fmt=coff ;;
 244       h8500-*-coff)                     fmt=coff ;;
 245
 246       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 247       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 248       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 249       i386-*-beospe*)                   fmt=coff em=pe ;;
 250       i386-*-beos*)                     fmt=elf ;;
 251       i386-*-coff)                      fmt=coff ;;
 252       i386-*-elf)                       fmt=elf ;;
 253       i386-*-kaos*)                     fmt=elf ;;
 254       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 255       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 256       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 257       i386-*-netbsd*-gnu*)              fmt=elf em=nbsd ;;
 258       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 259       i386-*-*n*bsd*)   case ${cpu} in
 260                             x86_64)     fmt=elf em=nbsd ;;
 261                             *)          fmt=aout em=nbsd ;;
 262                         esac ;;
 263       i386-*-linux*aout*)               fmt=aout em=linux ;;
 264       i386-*-linux*oldld)               fmt=aout em=linux ;;
 265       i386-*-linux*coff*)               fmt=coff em=linux ;;
 266       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 267       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 268       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 269 changequote(,)dnl
 270       i386-*-sysv[45]*)                 fmt=elf ;;
 271       i386-*-solaris*)                  fmt=elf ;;
 272       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 273       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 274       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 275 changequote([,])dnl
 276       i386-*-freebsd*)                  fmt=elf em=freebsd ;;
 277       i386-*-sysv*)                     fmt=coff ;;
 278       i386-*-sco3.2v5*coff)             fmt=coff ;;
 279       i386-*-isc*)                      fmt=coff ;;
 280       i386-*-sco3.2v5*)                 fmt=elf
 281           if test ${this_target} = $target; then
 282             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 283           fi ;;
 284       i386-*-sco3.2*)                   fmt=coff ;;
 285       i386-*-vsta)                      fmt=aout ;;
 286       i386-*-msdosdjgpp* \
 287       | i386-*-go32* \
 288       | i386-go32-rtems*)               fmt=coff em=go32
 289             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 290       i386-*-rtemself*)                 fmt=elf ;;
 291       i386-*-rtemscoff*)                fmt=coff ;;
 292       i386-*-rtems*)                    fmt=elf ;;
 293       i386-*-gnu*)                      fmt=elf ;;
 294       i386-*-mach*)                     fmt=aout em=mach ;;
 295       i386-*-msdos*)                    fmt=aout ;;
 296       i386-*-moss*)                     fmt=elf ;;
 297       i386-*-pe)                        fmt=coff em=pe ;;
 298       i386-*-cygwin*)                   fmt=coff em=pe ;;
 299       i386-*-interix*)                  fmt=coff em=interix ;;
 300       i386-*-mingw32*)                  fmt=coff em=pe ;;
 301       i386-*-nto-qnx*)                  fmt=elf ;;
 302       i386-*-*nt*)                      fmt=coff em=pe ;;
 303       i386-*-vxworks*)                  fmt=aout ;;
 304       i386-*-chaos)                     fmt=elf ;;
 305
 306       i860-*-*)                         fmt=elf endian=little
 307                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 308       i960-*-bout)                      fmt=bout ;;
 309       i960-*-coff)                      fmt=coff em=ic960 ;;
 310       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 311       i960-*-nindy*)                    fmt=bout ;;
 312       i960-*-vxworks5.0)                fmt=bout ;;
 313       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 314       i960-*-vxworks*)                  fmt=bout ;;
 315       i960-*-elf*)                      fmt=elf ;;
 316
 317       ia64-*-elf*)                      fmt=elf ;;
 318       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 319       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 320       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 321       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 322
 323       ip2k-*-*)                         fmt=elf ;;
 324
 325       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 326
 327       m32r-*-*)                         fmt=elf ;;
 328
 329       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 330       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 331
 332       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 333       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 334       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 335       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 336       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 337       m68k-apollo-*)                    fmt=coff em=apollo ;;
 338       m68k-*-elf*)                      fmt=elf ;;
 339       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 340       m68k-*-sysv*)                     fmt=coff ;;
 341       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 342       m68k-*-rtems*)                    fmt=elf ;;
 343       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 344       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 345       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 346       m68k-*-gnu*)                      fmt=elf ;;
 347       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 348       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 349       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 350       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 351       m68k-apple-aux*)                  fmt=coff em=aux ;;
 352       m68k-*-psos*)                     fmt=elf em=psos;;
 353
 354       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 355       m88k-*-coff*)                     fmt=coff ;;
 356
 357       mcore-*-elf)                      fmt=elf ;;
 358       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 359
 360       # don't change em like *-*-bsd does
 361       mips-dec-openbsd*)                fmt=elf endian=little ;;
 362       mips-dec-bsd*)                    fmt=aout endian=little ;;
 363       mips-sony-bsd*)                   fmt=ecoff ;;
 364       mips-*-bsd*)
 365             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 366       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 367       mips-*-osf*)                      fmt=ecoff endian=little ;;
 368       mips-*-ecoff*)                    fmt=ecoff ;;
 369       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 370       mips-*-irix6*)                    fmt=elf em=irix ;;
 371       mips-*-irix5*)                    fmt=elf em=irix ;;
 372       mips-*-irix*)                     fmt=ecoff em=irix ;;
 373       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 374       mips-*-riscos*)                   fmt=ecoff ;;
 375       mips*-*-linux*)                   fmt=elf em=tmips ;;
 376       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 377       mips-*-sysv*)                     fmt=ecoff ;;
 378       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 379       mips-*-netbsd*)                   fmt=elf ;;
 380       mips-*-openbsd*)                  fmt=elf ;;
 381       mips-*-vxworks*)                  fmt=elf ;;
 382
 383       mmix-*-*)                         fmt=elf ;;
 384       mn10200-*-*)                      fmt=elf ;;
 385       mn10300-*-*)                      fmt=elf ;;
 386       msp430-*-*)                       fmt=elf ;;
 387       openrisc-*-*)                     fmt=elf ;;
 388       or32-*-rtems*)                    fmt=coff ;;
 389       or32-*-coff)                      fmt=coff ;;
 390       or32-*-elf)                       fmt=elf ;;
 391       pj*)                              fmt=elf ;;
 392
 393       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 394       ppc-*-winnt*)                     fmt=coff em=pe ;;
 395       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 396       ppc-*-aix*)                       fmt=coff ;;
 397       ppc-*-beos*)                      fmt=coff ;;
 398       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 399       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 400       ppc-*-linux-gnu*)                 fmt=elf
 401             case "$endian" in
 402                 big)  ;;
 403                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 404             esac ;;
 405       ppc-*-solaris*)                   fmt=elf
 406             if test ${this_target} = $target; then
 407                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 408                           [Define if default target is PowerPC Solaris.])
 409             fi
 410             if test x${endian} = xbig; then
 411                 AC_MSG_ERROR(Solaris must be configured little endian)
 412             fi ;;
 413       ppc-*-rtems*)                     fmt=elf ;;
 414       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 415       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 416       ppc-**-nto*)                      fmt=elf ;;
 417       ppc-*-vxworks*)                   fmt=elf ;;
 418       ppc-*-windiss*)                   fmt=elf ;;
 419       ppc-*-kaos*)                      fmt=elf ;;
 420
 421       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 422       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 423
 424       sh*-*-linux*)                     fmt=elf em=linux
 425             case ${cpu} in
 426                 sh*eb)  endian=big ;;
 427                 *)      endian=little ;;
 428             esac ;;
 429       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 430       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 431       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 432       sh-*-elf*)                        fmt=elf ;;
 433       sh-*-coff*)                       fmt=coff ;;
 434       sh-*-nto*)                        fmt=elf ;;
 435       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 436       sh-*-rtemself*)                   fmt=elf ;;
 437       sh-*-rtems*)                      fmt=coff ;;
 438       sh-*-kaos*)                       fmt=elf ;;
 439       shle*-*-kaos*)                    fmt=elf ;;
 440       sh64-*-elf*)                      fmt=elf ;;
 441
 442       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 443       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 444       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 445       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 446
 447       sparc-*-rtemsaout*)               fmt=aout ;;
 448       sparc-*-rtemself*)                fmt=elf ;;
 449       sparc-*-rtems*)                   fmt=elf ;;
 450       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 451       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 452       sparc-*-coff)                     fmt=coff ;;
 453       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 454       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 455       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 456       sparc-fujitsu-none)               fmt=aout ;;
 457       sparc-*-elf)                      fmt=elf ;;
 458       sparc-*-sysv4*)                   fmt=elf ;;
 459       sparc-*-solaris*)                 fmt=elf ;;
 460       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 461       sparc-*-*n*bsd*)  case ${cpu} in
 462                             sparc64)    fmt=elf em=nbsd ;;
 463                             *)          fmt=aout em=nbsd ;;
 464                         esac ;;
 465       strongarm-*-coff)                 fmt=coff ;;
 466       strongarm-*-elf)                  fmt=elf ;;
 467       strongarm-*-kaos*)                fmt=elf ;;
 468       xscale-*-coff)                    fmt=coff ;;
 469       xscale-*-elf)                     fmt=elf ;;
 470
 471       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 472       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 473       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 474       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 475       tic80-*-*)                        fmt=coff ;;
 476
 477       v850-*-*)                         fmt=elf ;;
 478       v850e-*-*)                        fmt=elf ;;
 479       v850ea-*-*)                       fmt=elf ;;
 480
 481       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 482       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 483       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 484       vax-*-vms)                        fmt=vms ;;
 485
 486       w65-*-*)                          fmt=coff ;;
 487
 488       xstormy16-*-*)                    fmt=elf ;;
 489
 490       xtensa-*-*)                       fmt=elf ;;
 491
 492       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 493
 494       *-*-aout | *-*-scout)             fmt=aout ;;
 495       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 496       *-*-nindy*)                       fmt=bout ;;
 497       *-*-bsd*)                         fmt=aout em=sun3 ;;
 498       *-*-generic)                      fmt=generic ;;
 499       *-*-xray | *-*-hms)               fmt=coff ;;
 500       *-*-sim)                          fmt=coff ;;
 501       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 502       *-*-aros*)                                fmt=elf em=linux bfd_gas=yes ;;
 503       *-*-vxworks)                      fmt=aout ;;
 504       *-*-netware)                      fmt=elf ;;
 505     esac
 506
 507     if test ${this_target} = $target ; then
 508       endian_def=
 509       if test x${endian} = xbig; then
 510         endian_def=1
 511       elif test x${endian} = xlittle; then
 512         endian_def=0
 513       fi
 514       if test x${endian_def} != x; then
 515         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 516                            [Define as 1 if big endian.])
 517       fi
 518     fi
 519
 520     case ${cpu_type}-${fmt} in
 521         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 522                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 523                 | *-elf | *-ecoff | *-som)
 524             bfd_gas=yes ;;
 525     esac
 526
 527 # Other random stuff.
 528
 529     case ${cpu_type} in
 530       mips)
 531         # Set mips_cpu to the name of the default CPU.
 532         case ${target_cpu} in
 533           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 534             mips_cpu=from-abi
 535             ;;
 536           mipsisa32 | mipsisa32el)
 537             mips_cpu=mips32
 538             ;;
 539           mipsisa32r2 | mipsisa32r2el)
 540             mips_cpu=mips32r2
 541             ;;
 542           mipsisa64 | mipsisa64el)
 543             mips_cpu=mips64
 544             ;;
 545           mipstx39 | mipstx39el)
 546             mips_cpu=r3900
 547             ;;
 548           mips64vr | mips64vrel)
 549             mips_cpu=vr4100
 550             ;;
 551           mipsisa32r2*)
 552 changequote(,)dnl
 553             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 554 changequote([,])dnl
 555             ;;
 556           mips64* | mipsisa64* | mipsisa32*)
 557 changequote(,)dnl
 558             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 559 changequote([,])dnl
 560             ;;
 561           *)
 562             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 563             ;;
 564         esac
 565         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 566         # binaries.  It's a GNU extension that some OSes don't understand.
 567         # The value only matters on ELF targets.
 568         case ${target} in
 569           *-*-irix*)
 570             use_e_mips_abi_o32=0
 571             ;;
 572           *)
 573             use_e_mips_abi_o32=1
 574             ;;
 575         esac
 576         # Decide whether to generate 32-bit or 64-bit code by default.
 577         # Used to resolve -march=from-abi when an embedded ABI is selected.
 578         case ${target} in
 579           mips64*-*-* | mipsisa64*-*-*)
 580             mips_default_64bit=1
 581             ;;
 582           *)
 583             mips_default_64bit=0
 584             ;;
 585         esac
 586         # Decide which ABI to target by default.
 587         case ${target} in
 588           mips64*-linux* | mips-sgi-irix6*)
 589             mips_default_abi=N32_ABI
 590             ;;
 591           mips*-linux*)
 592             mips_default_abi=O32_ABI
 593             ;;
 594           *)
 595             mips_default_abi=NO_ABI
 596             ;;
 597         esac
 598         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 599                            [Default CPU for MIPS targets. ])
 600         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 601                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 602         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 603                            [Generate 64-bit code by default on MIPS targets. ])
 604         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 605                            [Choose a default ABI for MIPS targets. ])
 606         ;;
 607     esac
 608
 609     # Do we need the opcodes library?
 610     case ${cpu_type} in
 611       vax | i386 | tic30)
 612         ;;
 613
 614       *)
 615         need_opcodes=yes
 616
 617         case "${enable_shared}" in
 618         yes) shared_opcodes=true ;;
 619         *opcodes*) shared_opcodes=true ;;
 620         *) shared_opcodes=false ;;
 621         esac
 622         if test "${shared_opcodes}" = "true"; then
 623           # A shared libopcodes must be linked against libbfd.
 624           need_bfd=yes
 625         fi
 626         ;;
 627     esac
 628
 629     # Any other special object files needed ?
 630     case ${cpu_type} in
 631       fr30 | ip2k | iq2000 | m32r | openrisc)
 632         using_cgen=yes
 633         ;;
 634
 635       frv)
 636         using_cgen=yes
 637         ;;
 638       m68k)
 639         case ${extra_objects} in
 640         *m68k-parse.o*) ;;
 641         *) extra_objects="$extra_objects m68k-parse.o" ;;
 642         esac
 643         ;;
 644
 645       mips)
 646         echo ${extra_objects} | grep -s "itbl-parse.o"
 647         if test $? -ne 0 ; then
 648           extra_objects="$extra_objects itbl-parse.o"
 649         fi
 650
 651         echo ${extra_objects} | grep -s "itbl-lex.o"
 652         if test $? -ne 0 ; then
 653           extra_objects="$extra_objects itbl-lex.o"
 654         fi
 655
 656         echo ${extra_objects} | grep -s "itbl-ops.o"
 657         if test $? -ne 0 ; then
 658           extra_objects="$extra_objects itbl-ops.o"
 659         fi
 660         ;;
 661
 662       i386 | s390 | sparc)
 663         if test $this_target = $target ; then
 664           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 665         fi
 666         ;;
 667
 668       xstormy16)
 669         using_cgen=yes
 670         ;;
 671
 672       xtensa)
 673         echo ${extra_objects} | grep -s "xtensa-relax.o"
 674         if test $? -ne 0 ; then
 675           extra_objects="$extra_objects xtensa-relax.o"
 676         fi
 677         ;;
 678
 679       *)
 680         ;;
 681     esac
 682
 683     if test $using_cgen = yes ; then
 684         case "x${extra_objects}" in
 685         *cgen.o*) ;;
 686         *) extra_objects="$extra_objects cgen.o" ;;
 687         esac
 688     fi
 689
 690 # See if we really can support this configuration with the emulation code.
 691
 692     if test $this_target = $target ; then
 693       primary_bfd_gas=$bfd_gas
 694       obj_format=$fmt
 695       te_file=$em
 696
 697       if test $bfd_gas = no ; then
 698         # Can't support other configurations this way.
 699         break
 700       fi
 701     elif test $bfd_gas = no ; then
 702       # Can't support this configuration.
 703       break
 704     fi
 705
 706 # From target name and format, produce a list of supported emulations.
 707
 708     case ${generic_target}-${fmt} in
 709       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 710       mips*-*-linux*-*) case "$endian" in
 711                         big)    emulation="mipsbelf mipslelf mipself" ;;
 712                         *)      emulation="mipslelf mipsbelf mipself" ;;
 713                         esac ;;
 714       mips-*-lnews*-ecoff) ;;
 715       mips-*-*-ecoff)   case "$endian" in
 716                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 717                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 718                         esac ;;
 719       mips-*-*-elf)     case "$endian" in
 720                         big)    emulation="mipsbelf mipslelf mipself" ;;
 721                         *)      emulation="mipslelf mipsbelf mipself" ;;
 722                         esac ;;
 723       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 724       # i386-pc-pe-coff != i386-pc-coff.
 725       i386-*-pe-coff)   ;;
 726       # Uncommenting the next line will turn on support for i386 AOUT
 727       # for the default linux configuration
 728       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 729       #
 730       i386-*-aout)      emulation="i386aout" ;;
 731       i386-*-coff)      emulation="i386coff" ;;
 732       i386-*-elf)       emulation="i386elf" ;;
 733
 734       # Always all formats.  The first stated emulation becomes the default.
 735       cris-*-*aout*)    emulation="crisaout criself" ;;
 736       cris-*-*)         emulation="criself crisaout" ;;
 737     esac
 738
 739     emulations="$emulations $emulation"
 740
 741 done
 742
 743 # Turn on all targets if possible
 744 if test ${all_targets} = "yes"; then
 745   case ${target_cpu_type} in
 746   i386)
 747     case ${obj_format} in
 748     aout)
 749       emulations="$emulations i386coff i386elf"
 750       ;;
 751     coff)
 752       emulations="$emulations i386aout i386elf"
 753     ;;
 754     elf)
 755       emulations="$emulations i386aout i386coff"
 756       ;;
 757     esac
 758   ;;
 759   esac
 760 fi
 761
 762 # Assign floating point type.  Most processors with FP support
 763 # IEEE FP.  On those that don't support FP at all, usually IEEE
 764 # is emulated.
 765 case ${target_cpu} in
 766   vax | tahoe ) atof=${target_cpu} ;;
 767   pdp11)        atof=vax ;;
 768   *)            atof=ieee ;;
 769 esac
 770
 771 case "${obj_format}" in
 772   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 773 esac
 774
 775 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 776 cgen_cpu_prefix=""
 777 if test $using_cgen = yes ; then
 778   case ${target_cpu} in
 779     *) cgen_cpu_prefix=${target_cpu} ;;
 780   esac
 781   AC_SUBST(cgen_cpu_prefix)
 782   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 783 fi
 784
 785 dnl
 786 dnl Make sure the desired support files exist.
 787 dnl
 788
 789 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 790   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 791 fi
 792
 793 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 794   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 795 fi
 796
 797 case ${user_bfd_gas}-${primary_bfd_gas} in
 798   yes-yes | no-no)
 799     # We didn't override user's choice.
 800     ;;
 801   no-yes)
 802     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 803     ;;
 804   no-preferred)
 805     primary_bfd_gas=no
 806     ;;
 807   *-preferred)
 808     primary_bfd_gas=yes
 809     ;;
 810   yes-*)
 811     primary_bfd_gas=yes
 812     ;;
 813   -*)
 814     # User specified nothing.
 815     ;;
 816 esac
 817
 818 # Some COFF configurations want these random other flags set.
 819 case ${obj_format} in
 820   coff)
 821     case ${target_cpu_type} in
 822       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 823       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 824       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 825     esac
 826     ;;
 827 esac
 828
 829 # Getting this done right is going to be a bitch.  Each configuration specified
 830 # with --enable-targets=... should be checked for environment, format, cpu, and
 831 # bfd_gas setting.
 832 #
 833 # For each configuration, the necessary object file support code must be linked
 834 # in.  This might be only one, it might be up to four.  The necessary emulation
 835 # code needs to be provided, too.
 836 #
 837 # And then there's "--enable-targets=all"....
 838 #
 839 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 840
 841 formats="${obj_format}"
 842 emfiles=""
 843 EMULATIONS=""
 844 GAS_UNIQ(emulations)
 845 for em in . $emulations ; do
 846   case $em in
 847     .)  continue ;;
 848     mipsbelf | mipslelf | mipself)
 849         fmt=elf   file=mipself ;;
 850     mipsbecoff | mipslecoff | mipsecoff)
 851         fmt=ecoff file=mipsecoff ;;
 852     *coff)
 853         fmt=coff  file=$em ;;
 854     *aout)
 855         fmt=aout file=$em ;;
 856     *elf)
 857         fmt=elf file=$em ;;
 858   esac
 859   formats="$formats $fmt"
 860   emfiles="$emfiles e-$file.o"
 861   EMULATIONS="$EMULATIONS &$em,"
 862 done
 863 GAS_UNIQ(formats)
 864 GAS_UNIQ(emfiles)
 865 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 866   for fmt in $formats ; do
 867     case $fmt in
 868       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 869       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 870       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 871       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 872       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 873       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 874       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 875       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 876       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 877       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 878     esac
 879     extra_objects="$extra_objects obj-$fmt.o"
 880   done
 881   obj_format=multi
 882 fi
 883 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 884   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 885   # e-mips* has more than one emulation per file, e-i386* has just one at the
 886   # moment.  If only one emulation is specified, then don't define
 887   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 888   case "${obj_format}${emfiles}" in
 889     multi* | *mips*)
 890       extra_objects="$extra_objects $emfiles"
 891       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 892   esac
 893 fi
 894 AC_SUBST(extra_objects)
 895 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 896 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 897                    [Default emulation.])
 898
 899 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 900   yes-*-coff)   need_bfd=yes ;;
 901   no-*-coff)    need_bfd=yes
 902                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 903 esac
 904
 905 reject_dev_configs=yes
 906
 907 case ${reject_dev_configs}-${dev} in
 908   yes-yes) # Oops.
 909     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 910     ;;
 911 esac
 912
 913 AC_SUBST(target_cpu_type)
 914 AC_SUBST(obj_format)
 915 AC_SUBST(te_file)
 916 AC_SUBST(install_tooldir)
 917 AC_SUBST(atof)
 918 dnl AC_SUBST(emulation)
 919
 920 case "${primary_bfd_gas}" in
 921   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 922         need_bfd=yes ;;
 923 esac
 924
 925 # do we need the opcodes library?
 926 case "${need_opcodes}" in
 927 yes)
 928   OPCODES_LIB=../opcodes/libopcodes.la
 929   ;;
 930 esac
 931
 932 case "${need_bfd}" in
 933 yes)
 934   BFDLIB=../bfd/libbfd.la
 935   BFDVER_H=../bfd/bfdver.h
 936   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 937   ;;
 938 esac
 939
 940 AC_SUBST(BFDLIB)
 941 AC_SUBST(OPCODES_LIB)
 942
 943 AC_SUBST(BFDVER_H)
 944 AC_SUBST(ALL_OBJ_DEPS)
 945
 946 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 947 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 948 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 949 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 950 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 951
 952 AC_PROG_CC
 953
 954 AC_PROG_YACC
 955 AM_PROG_LEX
 956
 957 ALL_LINGUAS="fr tr es"
 958 CY_GNU_GETTEXT
 959
 960 AM_MAINTAINER_MODE
 961 AC_EXEEXT
 962
 963 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 964
 965 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 966 # people who are not cross-compiling but are compiling cross-assemblers.
 967 AC_MSG_CHECKING(whether compiling a cross-assembler)
 968 if test "${host}" = "${target}"; then
 969   cross_gas=no
 970 else
 971   cross_gas=yes
 972   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 973 fi
 974 AC_MSG_RESULT($cross_gas)
 975
 976 dnl ansidecl.h will deal with const
 977 dnl AC_CONST
 978 AC_FUNC_ALLOCA
 979 AC_C_INLINE
 980
 981 # VMS doesn't have unlink.
 982 AC_CHECK_FUNCS(unlink remove, break)
 983
 984 # Some systems don't have sbrk().
 985 AC_CHECK_FUNCS(sbrk)
 986
 987 # do we need the math library?
 988 case "${need_libm}" in
 989 yes)
 990   AC_CHECK_LIBM
 991   AC_SUBST(LIBM)
 992   ;;
 993 esac
 994
 995 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 996 # enough, but on some of those systems, the assert macro relies on requoting
 997 # working properly!
 998 GAS_WORKING_ASSERT
 999
1000 # On some systems, the system header files may not declare malloc, realloc,
1001 # and free.  There are places where gas needs these functions to have been
1002 # declared -- such as when taking their addresses.
1003 gas_test_headers="
1004 #ifdef HAVE_MEMORY_H
1005 #include <memory.h>
1006 #endif
1007 #ifdef HAVE_STRING_H
1008 #include <string.h>
1009 #else
1010 #ifdef HAVE_STRINGS_H
1011 #include <strings.h>
1012 #endif
1013 #endif
1014 #ifdef HAVE_STDLIB_H
1015 #include <stdlib.h>
1016 #endif
1017 #ifdef HAVE_UNISTD_H
1018 #include <unistd.h>
1019 #endif
1020 "
1021 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1022 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1023 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1024 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1025 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1026
1027 # Does errno.h declare errno, or do we have to add a separate declaration
1028 # for it?
1029 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1030 #ifdef HAVE_ERRNO_H
1031 #include <errno.h>
1032 #endif
1033 ])
1034
1035 dnl This must come last.
1036
1037 dnl We used to make symlinks to files in the source directory, but now
1038 dnl we just use the right name for .c files, and create .h files in
1039 dnl the build directory which include the right .h file.  Make sure
1040 dnl the old symlinks don't exist, so that a reconfigure in an existing
1041 dnl directory behaves reasonably.
1042
1043 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1044 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1045  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1046  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1047  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1048  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1049  if test "x$cgen_cpu_prefix" != x ; then
1050    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1051  fi
1052
1053  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1054 [target_cpu_type=${target_cpu_type}
1055  cgen_cpu_prefix=${cgen_cpu_prefix}
1056  obj_format=${obj_format}
1057  te_file=${te_file}])