gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 132       m680[012346]0)    cpu_type=m68k ;;
 133 changequote([,])dnl
 134       m68008)           cpu_type=m68k ;;
 135       m683??)           cpu_type=m68k ;;
 136       m5200)            cpu_type=m68k ;;
 137       m8*)              cpu_type=m88k ;;
 138       mips*el)          cpu_type=mips endian=little ;;
 139       mips*)            cpu_type=mips endian=big ;;
 140       pjl*)             cpu_type=pj endian=little ;;
 141       pj*)              cpu_type=pj endian=big ;;
 142       powerpcle*)       cpu_type=ppc endian=little ;;
 143       powerpc*)         cpu_type=ppc endian=big ;;
 144       rs6000*)          cpu_type=ppc ;;
 145       s390x*)           cpu_type=s390 arch=s390x ;;
 146       s390*)            cpu_type=s390 arch=s390 ;;
 147       sparclite*)       cpu_type=sparc arch=sparclite ;;
 148       sparclet*)        cpu_type=sparc arch=sparclet ;;
 149       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 150       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 151       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 152       v850*)            cpu_type=v850 ;;
 153       *)                cpu_type=${cpu} ;;
 154     esac
 155
 156     if test ${this_target} = $target ; then
 157       target_cpu_type=${cpu_type}
 158     elif test ${target_cpu_type} != ${cpu_type} ; then
 159       continue
 160     fi
 161
 162     generic_target=${cpu_type}-$vendor-$os
 163     dev=no
 164     bfd_gas=no
 165     em=generic
 166
 167     # assign object format
 168     case ${generic_target} in
 169       a29k-*-coff)          fmt=coff ;;
 170       a29k-amd-udi)         fmt=coff ;;
 171       a29k-amd-ebmon)       fmt=coff ;;
 172       a29k-nyu-sym1)        fmt=coff ;;
 173       a29k-*-rtems*)        fmt=coff ;;
 174       a29k-*-vxworks*)      fmt=coff ;;
 175
 176       alpha*-*-*vms*)       fmt=evax ;;
 177       alpha*-*-netware*)    fmt=ecoff ;;
 178       alpha*-*-openbsd*)    fmt=ecoff ;;
 179       alpha*-*-osf*)        fmt=ecoff ;;
 180       alpha*-*-linuxecoff*) fmt=ecoff ;;
 181       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 182       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 183
 184       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 185
 186       arm-*-aout)                       fmt=aout ;;
 187       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 188       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 189       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 190       arm*-*-conix*)                    fmt=elf ;;
 191       arm-*-linux*aout*)                fmt=aout em=linux ;;
 192       arm*-*-linux-gnu* | arm*-*-uclinux*)
 193                                         fmt=elf  em=linux ;;
 194       arm-*-netbsd*)                    fmt=aout em=nbsd ;;
 195       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 196       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 197       arm-*-wince)                      fmt=coff em=wince-pe ;;
 198       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 199       arm-*-riscix*)                    fmt=aout em=riscix ;;
 200
 201       avr-*-*)              fmt=elf bfd_gas=yes ;;
 202
 203       cris-*-*)             fmt=multi bfd_gas=yes ;;
 204
 205       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 206       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 207
 208
 209       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 210
 211       hppa-*-linux-gnu*)    case ${cpu} in
 212                                 hppa*64*)
 213                                         fmt=elf em=hppalinux64;;
 214                                 hppa*)
 215                                         fmt=elf em=linux;;
 216                             esac ;;
 217       hppa-*-*elf*)         fmt=elf em=hppa ;;
 218       hppa-*-lites*)        fmt=elf em=hppa ;;
 219       hppa-*-osf*)          fmt=som em=hppa ;;
 220       hppa-*-rtems*)        fmt=elf em=hppa ;;
 221       hppa-*-hpux11*)       case ${cpu} in
 222                                 hppa*64*)
 223                                         fmt=elf em=hppa64 ;;
 224                                 hppa*)
 225                                         fmt=som em=hppa ;;
 226                             esac ;;
 227       hppa-*-hpux*)         fmt=som em=hppa ;;
 228       hppa-*-mpeix*)        fmt=som em=hppa ;;
 229       hppa-*-bsd*)          fmt=som em=hppa ;;
 230       hppa-*-hiux*)         fmt=som em=hppa ;;
 231
 232       h8300-*-rtems*)       fmt=coff ;;
 233       h8300-*-coff)         fmt=coff ;;
 234       h8500-*-rtems*)       fmt=coff ;;
 235       h8500-*-coff)         fmt=coff ;;
 236
 237       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 238       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 239       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 240       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 241       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 242       i386-*-bsd*)          fmt=aout em=386bsd ;;
 243       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 244       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 245       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 246       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 247       i386-*-linux*coff*)   fmt=coff em=linux ;;
 248       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 249       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 250       i386-*-lynxos*)       fmt=coff em=lynx ;;
 251 changequote(,)dnl
 252       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 253                             fmt=elf bfd_gas=yes ;;
 254       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 255                             fmt=aout em=386bsd ;;
 256 changequote([,])dnl
 257       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 258                           fmt=coff ;;
 259       i386-*-sco3.2v5*)      fmt=elf
 260                             if test ${this_target} = $target; then
 261                                 AC_DEFINE(SCO_ELF, 1,
 262                                     [Define if defaulting to ELF on SCO 5.])
 263                             fi
 264                             ;;
 265       i386-*-sco3.2*)       fmt=coff ;;
 266       i386-*-vsta)          fmt=aout ;;
 267       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 268                             fmt=coff em=go32 bfd_gas=yes
 269                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 270                             ;;
 271       i386-*-rtemself*)     fmt=elf ;;
 272       i386-*-rtems*)        fmt=coff ;;
 273       i386-*-gnu*)          fmt=elf ;;
 274       i386-*-mach*)
 275                             fmt=aout em=mach bfd_gas=yes ;;
 276       i386-*-msdos*)        fmt=aout ;;
 277       i386-*-moss*)         fmt=elf ;;
 278       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 279       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 280       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 281       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 282       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 283       i386-*-vxworks*)      fmt=aout ;;
 284       i386-*-chaos)         fmt=elf ;;
 285       i860-stardent-sysv4* | i860-stardent-elf*)
 286                             fmt=elf bfd_gas=yes endian=little
 287                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 288       i960-*-bout)          fmt=bout ;;
 289       i960-*-coff)          fmt=coff em=ic960 ;;
 290       i960-*-rtems*)        fmt=coff em=ic960 ;;
 291       i960-*-nindy*)        fmt=bout ;;
 292       i960-*-vxworks4*)     fmt=bout ;;
 293       i960-*-vxworks5.0)    fmt=bout ;;
 294       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 295       i960-*-vxworks*)      fmt=bout ;;
 296       i960-*-elf*)          fmt=elf ;;
 297
 298       ia64-*-elf*)          fmt=elf ;;
 299       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 300       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 301       ia64-*-hpux*)         fmt=elf em=hpux ;;
 302
 303       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 304
 305       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 306
 307       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 308                             fmt=aout em=sun3 ;;
 309       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 310       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 311       m68k-apollo-*)        fmt=coff em=apollo ;;
 312       m68k-*-sysv4*) # must be before -sysv*
 313                             fmt=elf em=svr4 ;;
 314       m68k-*-elf*)          fmt=elf ;;
 315       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 316                             fmt=coff ;;
 317       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 318       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 319       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 320       m68k-*-gnu*)          fmt=elf ;;
 321       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 322       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 323       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 324       m68k-apple-aux*)      fmt=coff em=aux ;;
 325       m68k-*-psos*)         fmt=elf em=psos;;
 326
 327       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 328       m88k-*-coff*)         fmt=coff ;;
 329
 330       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 331       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 332
 333       # don't change em like *-*-bsd does
 334       mips-dec-netbsd*)     fmt=elf endian=little ;;
 335       mips-dec-openbsd*)    fmt=elf endian=little ;;
 336       mips-dec-bsd*)        fmt=aout endian=little ;;
 337       mips-sony-bsd*)       fmt=ecoff ;;
 338       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 339       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 340       mips-*-osf*)          fmt=ecoff endian=little ;;
 341       mips-*-ecoff*)        fmt=ecoff ;;
 342       mips-*-ecoff*)        fmt=ecoff ;;
 343       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 344       mips-*-irix6*)        fmt=elf ;;
 345       mips-*-irix5*)        fmt=elf ;;
 346       mips-*-irix*)         fmt=ecoff ;;
 347       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 348       mips-*-riscos*)       fmt=ecoff ;;
 349       mips-*-sysv4*MP*)     fmt=elf em=tmips ;;
 350       mips-*-sysv*)         fmt=ecoff ;;
 351       mips-*-elf* | mips-*-rtems* | mips-*-linux-gnu* | mips-*-gnu* | mips-*-openbsd*)
 352                             fmt=elf ;;
 353       mips-*-vxworks*)      fmt=elf
 354                             AC_DEFINE(MIPS_STABS_ELF, 1,
 355                                 [Use ELF stabs for MIPS, not ECOFF stabs])
 356                             ;;
 357       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 358       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 359       pj*)                  fmt=elf ;;
 360       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 361                             fmt=coff em=pe ;;
 362       ppc-*-aix*)           fmt=coff ;;
 363       ppc-*-beos*)          fmt=coff ;;
 364       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 365                             fmt=elf ;;
 366       ppc-*-linux-gnu*)     fmt=elf
 367                             case "$endian" in
 368                             big)  ;;
 369                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 370                             esac
 371                             ;;
 372       ppc-*-solaris*)       fmt=elf
 373                             if test ${this_target} = $target; then
 374                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 375                                 [Define if default target is PowerPC Solaris.])
 376                             fi
 377                             if test x${endian} = xbig; then
 378                                 AC_MSG_ERROR(Solaris must be configured little endian)
 379                             fi
 380                             ;;
 381       ppc-*-rtems*)         fmt=elf ;;
 382       ppc-*-macos* | ppc-*-mpw*)
 383                             fmt=coff em=macos ;;
 384       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 385       ppc-*-vxworks*)       fmt=elf ;;
 386
 387       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 388       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 389
 390       sh-*-linux*)          fmt=elf em=linux ;;
 391       sh-*-elf*)            fmt=elf ;;
 392       sh-*-coff*)           fmt=coff bfd_gas=yes;;
 393       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes;;
 394       sh-*-rtemself*)       fmt=elf ;;
 395       sh-*-rtems*)          fmt=coff bfd_gas=yes;;
 396
 397       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 398       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 399       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 400
 401       sparc-*-rtemsaout*)   fmt=aout ;;
 402       sparc-*-rtemself*)    fmt=elf ;;
 403       sparc-*-rtems*)       fmt=elf ;;
 404       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 405       sparc-*-aout | sparc*-*-vxworks*)
 406                             fmt=aout em=sparcaout ;;
 407       sparc-*-coff)         fmt=coff ;;
 408       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 409       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 410       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 411       sparc-fujitsu-none)   fmt=aout ;;
 412       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 413                             fmt=elf ;;
 414       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 415                             case ${cpu} in
 416                                 sparc) case ${os} in
 417                                            *elf*) fmt=elf ;;
 418                                            *)     fmt=aout ;;
 419                                        esac ;;
 420                                 sparc64) fmt=elf ;;
 421                             esac
 422                             ;;
 423       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 424
 425       strongarm-*-coff)     fmt=coff ;;
 426       strongarm-*-elf)      fmt=elf ;;
 427       xscale-*-coff)     fmt=coff ;;
 428       xscale-*-elf)      fmt=elf ;;
 429
 430       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 431       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 432       tic54x-*-* | c54x*-*-*)
 433                             fmt=coff bfd_gas=yes need_libm=yes;;
 434       tic80-*-*)            fmt=coff ;;
 435
 436       v850-*-*)             fmt=elf bfd_gas=yes ;;
 437       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 438       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 439
 440       vax-*-bsd* | vax-*-ultrix*)
 441                             fmt=aout ;;
 442       vax-*-vms)            fmt=vms ;;
 443
 444
 445       z8k-*-coff | z8k-*-sim)
 446                             fmt=coff ;;
 447
 448       w65-*-*)              fmt=coff ;;
 449
 450       *-*-aout | *-*-scout)
 451                             fmt=aout ;;
 452       *-*-freebsd*)         fmt=elf bfd_gas=yes ;;
 453       *-*-nindy*)
 454                             fmt=bout ;;
 455       *-*-bsd*)
 456                             fmt=aout em=sun3 ;;
 457       *-*-generic)          fmt=generic ;;
 458       *-*-xray | *-*-hms)   fmt=coff ;;
 459       *-*-sim)              fmt=coff ;;
 460       *-*-elf | *-*-sysv4* | *-*-solaris*)
 461                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 462                             fmt=elf dev=yes ;;
 463       *-*-vxworks)          fmt=aout ;;
 464       *-*-netware)          fmt=elf ;;
 465     esac
 466
 467     if test ${this_target} = $target ; then
 468       endian_def=
 469       if test x${endian} = xbig; then
 470         endian_def=1
 471       elif test x${endian} = xlittle; then
 472         endian_def=0
 473       fi
 474       if test x${endian_def} != x; then
 475         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 476                            [Define as 1 if big endian.])
 477       fi
 478     fi
 479
 480     case ${cpu_type}-${fmt} in
 481       alpha*-*) bfd_gas=yes ;;
 482       arm-*)    bfd_gas=yes ;;
 483     # not yet
 484     # i386-aout)        bfd_gas=preferred ;;
 485       ia64*-*)  bfd_gas=yes ;;
 486       mips-*)   bfd_gas=yes ;;
 487       ns32k-*)  bfd_gas=yes ;;
 488       pdp11-*)  bfd_gas=yes ;;
 489       ppc-*)    bfd_gas=yes ;;
 490       sparc-*)  bfd_gas=yes ;;
 491       strongarm-*)      bfd_gas=yes ;;
 492       xscale-*) bfd_gas=yes ;;
 493       *-elf)    bfd_gas=yes ;;
 494       *-ecoff)  bfd_gas=yes ;;
 495       *-som)    bfd_gas=yes ;;
 496     #enable bfd for coff and aout to allow testing if a bfd target is
 497     #the primary target, but not for coff or aout as the primary target
 498       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 499       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 500       *)                ;;
 501     esac
 502
 503 # Other random stuff.
 504
 505     # Do we need the opcodes library?
 506     case ${cpu_type} in
 507       vax | i386 | tic30)
 508         ;;
 509
 510       *)
 511         need_opcodes=yes
 512
 513         case "${enable_shared}" in
 514         yes) shared_opcodes=true ;;
 515         *opcodes*) shared_opcodes=true ;;
 516         *) shared_opcodes=false ;;
 517         esac
 518         if test "${shared_opcodes}" = "true"; then
 519           # A shared libopcodes must be linked against libbfd.
 520           need_bfd=yes
 521         fi
 522         ;;
 523     esac
 524
 525     # Any other special object files needed ?
 526     case ${cpu_type} in
 527       fr30 | m32r)
 528         using_cgen=yes
 529         ;;
 530
 531       m68k)
 532         case ${extra_objects} in
 533         *m68k-parse.o*) ;;
 534         *) extra_objects="$extra_objects m68k-parse.o" ;;
 535         esac
 536         ;;
 537
 538       s390)
 539        if test $this_target = $target ; then
 540           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 541        fi
 542        ;;
 543
 544       mips)
 545         echo ${extra_objects} | grep -s "itbl-parse.o"
 546         if test $? -ne 0 ; then
 547           extra_objects="$extra_objects itbl-parse.o"
 548         fi
 549
 550         echo ${extra_objects} | grep -s "itbl-lex.o"
 551         if test $? -ne 0 ; then
 552           extra_objects="$extra_objects itbl-lex.o"
 553         fi
 554
 555         echo ${extra_objects} | grep -s "itbl-ops.o"
 556         if test $? -ne 0 ; then
 557           extra_objects="$extra_objects itbl-ops.o"
 558         fi
 559         ;;
 560
 561       i386)
 562         if test $this_target = $target ; then
 563           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 564         fi
 565         ;;
 566       sparc)
 567         if test $this_target = $target ; then
 568           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 569         fi
 570         ;;
 571       *)
 572         ;;
 573     esac
 574
 575     if test $using_cgen = yes ; then
 576         case "x${extra_objects}" in
 577         *cgen.o*) ;;
 578         *) extra_objects="$extra_objects cgen.o" ;;
 579         esac
 580     fi
 581
 582 # See if we really can support this configuration with the emulation code.
 583
 584     if test $this_target = $target ; then
 585       primary_bfd_gas=$bfd_gas
 586       obj_format=$fmt
 587       te_file=$em
 588
 589       if test $bfd_gas = no ; then
 590         # Can't support other configurations this way.
 591         break
 592       fi
 593     elif test $bfd_gas = no ; then
 594       # Can't support this configuration.
 595       break
 596     fi
 597
 598 # From target name and format, produce a list of supported emulations.
 599
 600     case ${generic_target}-${fmt} in
 601       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 602       mips-*-linux-gnu*-*) case "$endian" in
 603                         big)    emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 604                         *)      emulation="mipslelf mipsbelf mipself mipslecoff mipsbecoff mipsecoff" ;;
 605                         esac ;;
 606       mips-*-lnews*-ecoff) ;;
 607       mips-*-*-ecoff)   case "$endian" in
 608                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 609                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 610                         esac ;;
 611       mips-*-*-elf)     case "$endian" in
 612                         big)    emulation="mipsbelf mipslelf mipself" ;;
 613                         *)      emulation="mipslelf mipsbelf mipself" ;;
 614                         esac ;;
 615       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 616       # i386-pc-pe-coff != i386-pc-coff.
 617       i386-*-pe-coff)   ;;
 618       # Uncommenting the next line will turn on support for i386 AOUT
 619       # for the default linux configuration
 620       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 621       #
 622       i386-*-aout)      emulation="i386aout" ;;
 623       i386-*-coff)      emulation="i386coff" ;;
 624       i386-*-elf)       emulation="i386elf" ;;
 625
 626       # Always all formats.  The first stated emulation becomes the default.
 627       cris-*-*aout*)    emulation="crisaout criself" ;;
 628       cris-*-*)         emulation="criself crisaout" ;;
 629     esac
 630
 631     emulations="$emulations $emulation"
 632
 633 done
 634
 635 # Turn on all targets if possible
 636 if test ${all_targets} = "yes"; then
 637   case ${target_cpu_type} in
 638   i386)
 639     case ${obj_format} in
 640     aout)
 641       emulations="$emulations i386coff i386elf"
 642       ;;
 643     coff)
 644       emulations="$emulations i386aout i386elf"
 645     ;;
 646     elf)
 647       emulations="$emulations i386aout i386coff"
 648       ;;
 649     esac
 650   ;;
 651   esac
 652 fi
 653
 654 # Assign floating point type.  Most processors with FP support
 655 # IEEE FP.  On those that don't support FP at all, usually IEEE
 656 # is emulated.
 657 case ${target_cpu} in
 658   vax | tahoe ) atof=${target_cpu} ;;
 659   pdp11)        atof=vax ;;
 660   *)            atof=ieee ;;
 661 esac
 662
 663 case "${obj_format}" in
 664   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 665 esac
 666
 667 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 668 cgen_cpu_prefix=""
 669 if test $using_cgen = yes ; then
 670   case ${target_cpu} in
 671     *) cgen_cpu_prefix=${target_cpu} ;;
 672   esac
 673   AC_SUBST(cgen_cpu_prefix)
 674   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 675 fi
 676
 677 dnl
 678 dnl Make sure the desired support files exist.
 679 dnl
 680
 681 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 682   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 683 fi
 684
 685 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 686   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 687 fi
 688
 689 case ${user_bfd_gas}-${primary_bfd_gas} in
 690   yes-yes | no-no)
 691     # We didn't override user's choice.
 692     ;;
 693   no-yes)
 694     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 695     ;;
 696   no-preferred)
 697     primary_bfd_gas=no
 698     ;;
 699   *-preferred)
 700     primary_bfd_gas=yes
 701     ;;
 702   yes-*)
 703     primary_bfd_gas=yes
 704     ;;
 705   -*)
 706     # User specified nothing.
 707     ;;
 708 esac
 709
 710 # Some COFF configurations want these random other flags set.
 711 case ${obj_format} in
 712   coff)
 713     case ${target_cpu_type} in
 714       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 715       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 716       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 717     esac
 718     ;;
 719 esac
 720
 721 # Getting this done right is going to be a bitch.  Each configuration specified
 722 # with --enable-targets=... should be checked for environment, format, cpu, and
 723 # bfd_gas setting.
 724 #
 725 # For each configuration, the necessary object file support code must be linked
 726 # in.  This might be only one, it might be up to four.  The necessary emulation
 727 # code needs to be provided, too.
 728 #
 729 # And then there's "--enable-targets=all"....
 730 #
 731 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 732
 733 formats="${obj_format}"
 734 emfiles=""
 735 EMULATIONS=""
 736 GAS_UNIQ(emulations)
 737 for em in . $emulations ; do
 738   case $em in
 739     .)  continue ;;
 740     mipsbelf | mipslelf | mipself)
 741         fmt=elf   file=mipself ;;
 742     mipsbecoff | mipslecoff | mipsecoff)
 743         fmt=ecoff file=mipsecoff ;;
 744     *coff)
 745         fmt=coff  file=$em ;;
 746     *aout)
 747         fmt=aout file=$em ;;
 748     *elf)
 749         fmt=elf file=$em ;;
 750   esac
 751   formats="$formats $fmt"
 752   emfiles="$emfiles e-$file.o"
 753   EMULATIONS="$EMULATIONS &$em,"
 754 done
 755 GAS_UNIQ(formats)
 756 GAS_UNIQ(emfiles)
 757 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 758   for fmt in $formats ; do
 759     case $fmt in
 760       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 761       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 762       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 763       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 764       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 765       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 766       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 767       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 768       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 769       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 770     esac
 771     extra_objects="$extra_objects obj-$fmt.o"
 772   done
 773   obj_format=multi
 774 fi
 775 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 776   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 777   # e-mips* has more than one emulation per file, e-i386* has just one at the
 778   # moment.  If only one emulation is specified, then don't define
 779   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 780   case "${obj_format}${emfiles}" in
 781     multi* | *mips*)
 782       extra_objects="$extra_objects $emfiles"
 783       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 784   esac
 785 fi
 786 AC_SUBST(extra_objects)
 787 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 788 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 789                    [Default emulation.])
 790
 791 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 792   yes-*-coff)   need_bfd=yes ;;
 793   no-*-coff)    need_bfd=yes
 794                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 795 esac
 796
 797 reject_dev_configs=yes
 798
 799 case ${reject_dev_configs}-${dev} in
 800   yes-yes) # Oops.
 801     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 802     ;;
 803 esac
 804
 805 AC_SUBST(target_cpu_type)
 806 AC_SUBST(obj_format)
 807 AC_SUBST(te_file)
 808 AC_SUBST(install_tooldir)
 809 AC_SUBST(atof)
 810 dnl AC_SUBST(emulation)
 811
 812 case "${primary_bfd_gas}" in
 813   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 814         need_bfd=yes ;;
 815 esac
 816
 817 # do we need the opcodes library?
 818 case "${need_opcodes}" in
 819 yes)
 820   OPCODES_LIB=../opcodes/libopcodes.la
 821   ;;
 822 esac
 823
 824 case "${need_bfd}" in
 825 yes)
 826   BFDLIB=../bfd/libbfd.la
 827   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 828   ;;
 829 esac
 830
 831 AC_SUBST(BFDLIB)
 832 AC_SUBST(OPCODES_LIB)
 833
 834 AC_SUBST(ALL_OBJ_DEPS)
 835
 836 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 837 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 838 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 839 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 840 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 841
 842 AC_PROG_CC
 843
 844 AC_PROG_YACC
 845 AM_PROG_LEX
 846
 847 ALL_LINGUAS=
 848 CY_GNU_GETTEXT
 849
 850 AM_MAINTAINER_MODE
 851 AC_EXEEXT
 852
 853 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 854
 855 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 856 # people who are not cross-compiling but are compiling cross-assemblers.
 857 AC_MSG_CHECKING(whether compiling a cross-assembler)
 858 if test "${host}" = "${target}"; then
 859   cross_gas=no
 860 else
 861   cross_gas=yes
 862   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 863 fi
 864 AC_MSG_RESULT($cross_gas)
 865
 866 dnl ansidecl.h will deal with const
 867 dnl AC_CONST
 868 AC_FUNC_ALLOCA
 869 AC_C_INLINE
 870
 871 # VMS doesn't have unlink.
 872 AC_CHECK_FUNCS(unlink remove, break)
 873
 874 # Some systems don't have sbrk().
 875 AC_CHECK_FUNCS(sbrk)
 876
 877 # do we need the math library?
 878 case "${need_libm}" in
 879 yes)
 880   AC_CHECK_LIBM
 881   AC_SUBST(LIBM)
 882   ;;
 883 esac
 884
 885 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 886 # enough, but on some of those systems, the assert macro relies on requoting
 887 # working properly!
 888 GAS_WORKING_ASSERT
 889
 890 # On some systems, the system header files may not declare malloc, realloc,
 891 # and free.  There are places where gas needs these functions to have been
 892 # declared -- such as when taking their addresses.
 893 gas_test_headers="
 894 #ifdef HAVE_MEMORY_H
 895 #include <memory.h>
 896 #endif
 897 #ifdef HAVE_STRING_H
 898 #include <string.h>
 899 #else
 900 #ifdef HAVE_STRINGS_H
 901 #include <strings.h>
 902 #endif
 903 #endif
 904 #ifdef HAVE_STDLIB_H
 905 #include <stdlib.h>
 906 #endif
 907 #ifdef HAVE_UNISTD_H
 908 #include <unistd.h>
 909 #endif
 910 "
 911 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 912 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 913 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 914 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 915 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 916
 917 # Does errno.h declare errno, or do we have to add a separate declaration
 918 # for it?
 919 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 920 #ifdef HAVE_ERRNO_H
 921 #include <errno.h>
 922 #endif
 923 ])
 924
 925 dnl This must come last.
 926
 927 dnl We used to make symlinks to files in the source directory, but now
 928 dnl we just use the right name for .c files, and create .h files in
 929 dnl the build directory which include the right .h file.  Make sure
 930 dnl the old symlinks don't exist, so that a reconfigure in an existing
 931 dnl directory behaves reasonably.
 932
 933 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 934 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 935  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 936  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 937  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 938  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 939  if test "x$cgen_cpu_prefix" != x ; then
 940    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 941  fi
 942
 943  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 944 [target_cpu_type=${target_cpu_type}
 945  cgen_cpu_prefix=${cgen_cpu_prefix}
 946  obj_format=${obj_format}
 947  te_file=${te_file}])