gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # check for architecture variants
 122     arch=
 123     endian=
 124     case ${cpu} in
 125       am33_2.0)         cpu_type=mn10300 endian=little ;;
 126       alpha*)           cpu_type=alpha ;;
 127       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 128       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 129       c4x*)             cpu_type=tic4x ;;
 130       hppa*)            cpu_type=hppa ;;
 131 changequote(,)dnl
 132       i[3-7]86)         cpu_type=i386 arch=i386;;
 133       x86_64)           cpu_type=i386 arch=x86_64;;
 134       ia64)             cpu_type=ia64 ;;
 135       ip2k)             cpu_type=ip2k endian=big ;;
 136       iq2000)           cpu_type=iq2000 endian=big ;;
 137       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 138       m680[012346]0)    cpu_type=m68k ;;
 139 changequote([,])dnl
 140       m68008)           cpu_type=m68k ;;
 141       m683??)           cpu_type=m68k ;;
 142       m5200)            cpu_type=m68k ;;
 143       m8*)              cpu_type=m88k ;;
 144       mips*el)          cpu_type=mips endian=little ;;
 145       mips*)            cpu_type=mips endian=big ;;
 146       or32*)            cpu_type=or32 endian=big ;;
 147       pjl*)             cpu_type=pj endian=little ;;
 148       pj*)              cpu_type=pj endian=big ;;
 149       powerpc*le*)      cpu_type=ppc endian=little ;;
 150       powerpc*)         cpu_type=ppc endian=big ;;
 151       rs6000*)          cpu_type=ppc ;;
 152       s390x*)           cpu_type=s390 arch=s390x ;;
 153       s390*)            cpu_type=s390 arch=s390 ;;
 154       sh5*)             cpu_type=sh64 endian=big ;;
 155       sh5le*)           cpu_type=sh64 endian=little ;;
 156       sh64*)            cpu_type=sh64 endian=big ;;
 157       sh64le*)          cpu_type=sh64 endian=little ;;
 158       sh*le)            cpu_type=sh endian=little ;;
 159       sh*)              cpu_type=sh endian=big ;;
 160       sparclite*)       cpu_type=sparc arch=sparclite ;;
 161       sparclet*)        cpu_type=sparc arch=sparclet ;;
 162       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 163       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 164       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 165       v850*)            cpu_type=v850 ;;
 166       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 167       *)                cpu_type=${cpu} ;;
 168     esac
 169
 170     if test ${this_target} = $target ; then
 171       target_cpu_type=${cpu_type}
 172     elif test ${target_cpu_type} != ${cpu_type} ; then
 173       continue
 174     fi
 175
 176     generic_target=${cpu_type}-$vendor-$os
 177     dev=no
 178     bfd_gas=no
 179     em=generic
 180
 181     # assign object format
 182     case ${generic_target} in
 183       a29k-*-coff)                      fmt=coff ;;
 184       a29k-amd-udi)                     fmt=coff ;;
 185       a29k-amd-ebmon)                   fmt=coff ;;
 186       a29k-nyu-sym1)                    fmt=coff ;;
 187       a29k-*-rtems*)                    fmt=coff ;;
 188       a29k-*-vxworks*)                  fmt=coff ;;
 189
 190       alpha*-*-*vms*)                   fmt=evax ;;
 191       alpha*-*-netware*)                fmt=ecoff ;;
 192       alpha*-*-osf*)                    fmt=ecoff ;;
 193       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 194       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 195       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 196       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 197
 198       # cpu_type for am33_2.0 is set to mn10300
 199       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 200
 201       arc-*-elf*)                       fmt=elf ;;
 202
 203       arm-*-aout)                       fmt=aout ;;
 204       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 205       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 206       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 207       arm-*-kaos*)                      fmt=elf ;;
 208       arm*-*-conix*)                    fmt=elf ;;
 209       arm-*-linux*aout*)                fmt=aout em=linux ;;
 210       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 211       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 212       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 213       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 214       arm-**-nto*)                      fmt=elf ;;
 215       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 216       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 217       arm-wince-pe | arm-*-wince)       fmt=coff em=wince-pe ;;
 218       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 219       arm-*-riscix*)                    fmt=aout em=riscix ;;
 220
 221       avr-*-*)                          fmt=elf ;;
 222
 223       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 224       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 225
 226       d10v-*-*)                         fmt=elf ;;
 227       d30v-*-*)                         fmt=elf ;;
 228       dlx-*-*)                          fmt=elf ;;
 229
 230       fr30-*-*)                         fmt=elf ;;
 231       frv-*-*)                          fmt=elf ;;
 232
 233       hppa-*-linux*)    case ${cpu} in
 234                             hppa*64*)   fmt=elf em=hppalinux64;;
 235                             hppa*)      fmt=elf em=linux;;
 236                         esac ;;
 237       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 238       hppa-*-lites*)                    fmt=elf em=hppa ;;
 239       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 240       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 241       hppa-*-osf*)                      fmt=som em=hppa ;;
 242       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 243       hppa-*-hpux11*)   case ${cpu} in
 244                             hppa*64*)   fmt=elf em=hppa64 ;;
 245                             hppa*)      fmt=som em=hppa ;;
 246                         esac ;;
 247       hppa-*-hpux*)                     fmt=som em=hppa ;;
 248       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 249       hppa-*-bsd*)                      fmt=som em=hppa ;;
 250       hppa-*-hiux*)                     fmt=som em=hppa ;;
 251
 252       h8300-*-rtems*)                   fmt=coff ;;
 253       h8300-*-coff)                     fmt=coff ;;
 254       h8300-*-elf)                      fmt=elf ;;
 255       h8500-*-rtems*)                   fmt=coff ;;
 256       h8500-*-coff)                     fmt=coff ;;
 257
 258       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 259       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 260       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 261       i386-*-beospe*)                   fmt=coff em=pe ;;
 262       i386-*-beos*)                     fmt=elf ;;
 263       i386-*-coff)                      fmt=coff ;;
 264       i386-*-elf)                       fmt=elf ;;
 265       i386-*-kaos*)                     fmt=elf ;;
 266       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 267       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 268       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 269       i386-*-netbsd*-gnu* | \
 270       i386-*-knetbsd*-gnu | \
 271       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 272       i386-*-*n*bsd*)   case ${cpu} in
 273                             x86_64)     fmt=elf em=nbsd ;;
 274                             *)          fmt=aout em=nbsd ;;
 275                         esac ;;
 276       i386-*-linux*aout*)               fmt=aout em=linux ;;
 277       i386-*-linux*oldld)               fmt=aout em=linux ;;
 278       i386-*-linux*coff*)               fmt=coff em=linux ;;
 279       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 280       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 281       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 282 changequote(,)dnl
 283       i386-*-sysv[45]*)                 fmt=elf ;;
 284       i386-*-solaris*)                  fmt=elf ;;
 285       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 286       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 287       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 288 changequote([,])dnl
 289       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 290                                         fmt=elf em=freebsd ;;
 291       i386-*-sysv*)                     fmt=coff ;;
 292       i386-*-sco3.2v5*coff)             fmt=coff ;;
 293       i386-*-isc*)                      fmt=coff ;;
 294       i386-*-sco3.2v5*)                 fmt=elf
 295           if test ${this_target} = $target; then
 296             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 297           fi ;;
 298       i386-*-sco3.2*)                   fmt=coff ;;
 299       i386-*-vsta)                      fmt=aout ;;
 300       i386-*-msdosdjgpp* \
 301       | i386-*-go32* \
 302       | i386-go32-rtems*)               fmt=coff em=go32
 303             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 304       i386-*-rtemself*)                 fmt=elf ;;
 305       i386-*-rtemscoff*)                fmt=coff ;;
 306       i386-*-rtems*)                    fmt=elf ;;
 307       i386-*-gnu*)                      fmt=elf ;;
 308       i386-*-mach*)                     fmt=aout em=mach ;;
 309       i386-*-msdos*)                    fmt=aout ;;
 310       i386-*-moss*)                     fmt=elf ;;
 311       i386-*-pe)                        fmt=coff em=pe ;;
 312       i386-*-cygwin*)                   fmt=coff em=pe ;;
 313       i386-*-interix*)                  fmt=coff em=interix ;;
 314       i386-*-mingw32*)                  fmt=coff em=pe ;;
 315       i386-*-nto-qnx*)                  fmt=elf ;;
 316       i386-*-*nt*)                      fmt=coff em=pe ;;
 317       i386-*-chaos)                     fmt=elf ;;
 318
 319       i860-*-*)                         fmt=elf endian=little
 320                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 321       i960-*-bout)                      fmt=bout ;;
 322       i960-*-coff)                      fmt=coff em=ic960 ;;
 323       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 324       i960-*-nindy*)                    fmt=bout ;;
 325       i960-*-vxworks5.0)                fmt=bout ;;
 326       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 327       i960-*-vxworks*)                  fmt=bout ;;
 328       i960-*-elf*)                      fmt=elf ;;
 329
 330       ia64-*-elf*)                      fmt=elf ;;
 331       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 332       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 333       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 334       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 335
 336       ip2k-*-*)                         fmt=elf ;;
 337
 338       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 339
 340       m32r-*-*)                         fmt=elf ;;
 341
 342       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 343       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 344
 345       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 346       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 347       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 348       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 349       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 350       m68k-apollo-*)                    fmt=coff em=apollo ;;
 351       m68k-*-elf*)                      fmt=elf ;;
 352       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 353       m68k-*-sysv*)                     fmt=coff ;;
 354       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 355       m68k-*-rtems*)                    fmt=elf ;;
 356       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 357       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 358       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 359       m68k-*-gnu*)                      fmt=elf ;;
 360       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 361       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 362       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 363       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 364       m68k-apple-aux*)                  fmt=coff em=aux ;;
 365       m68k-*-psos*)                     fmt=elf em=psos;;
 366
 367       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 368       m88k-*-coff*)                     fmt=coff ;;
 369
 370       mcore-*-elf)                      fmt=elf ;;
 371       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 372
 373       # don't change em like *-*-bsd does
 374       mips-dec-openbsd*)                fmt=elf endian=little ;;
 375       mips-dec-bsd*)                    fmt=aout endian=little ;;
 376       mips-sony-bsd*)                   fmt=ecoff ;;
 377       mips-*-bsd*)
 378             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 379       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 380       mips-*-osf*)                      fmt=ecoff endian=little ;;
 381       mips-*-ecoff*)                    fmt=ecoff ;;
 382       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 383       mips-*-irix6*)                    fmt=elf em=irix ;;
 384       mips-*-irix5*)                    fmt=elf em=irix ;;
 385       mips-*-irix*)                     fmt=ecoff em=irix ;;
 386       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 387       mips-*-riscos*)                   fmt=ecoff ;;
 388       mips*-*-linux*)                   fmt=elf em=tmips ;;
 389       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 390       mips-*-sysv*)                     fmt=ecoff ;;
 391       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 392       mips-*-netbsd*)                   fmt=elf ;;
 393       mips-*-openbsd*)                  fmt=elf ;;
 394
 395       mmix-*-*)                         fmt=elf ;;
 396       mn10200-*-*)                      fmt=elf ;;
 397       mn10300-*-*)                      fmt=elf ;;
 398       msp430-*-*)                       fmt=elf ;;
 399       openrisc-*-*)                     fmt=elf ;;
 400       or32-*-rtems*)                    fmt=coff ;;
 401       or32-*-coff)                      fmt=coff ;;
 402       or32-*-elf)                       fmt=elf ;;
 403       pj*)                              fmt=elf ;;
 404
 405       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 406       ppc-*-winnt*)                     fmt=coff em=pe ;;
 407 changequote(,)dnl
 408       ppc-*-aix5.[01])                  fmt=coff em=aix5 ;;
 409 changequote([,])dnl
 410       ppc-*-aix5.*)                     fmt=coff em=aix5
 411         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 412                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 413       ;;
 414       ppc-*-aix*)                       fmt=coff ;;
 415       ppc-*-beos*)                      fmt=coff ;;
 416       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 417       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 418       ppc-*-linux-gnu*)                 fmt=elf em=linux
 419             case "$endian" in
 420                 big)  ;;
 421                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 422             esac ;;
 423       ppc-*-solaris*)                   fmt=elf
 424             if test ${this_target} = $target; then
 425                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 426                           [Define if default target is PowerPC Solaris.])
 427             fi
 428             if test x${endian} = xbig; then
 429                 AC_MSG_ERROR(Solaris must be configured little endian)
 430             fi ;;
 431       ppc-*-rtems*)                     fmt=elf ;;
 432       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 433       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 434       ppc-**-nto*)                      fmt=elf ;;
 435       ppc-*-kaos*)                      fmt=elf ;;
 436
 437       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 438       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 439
 440       sh*-*-linux*)                     fmt=elf em=linux
 441             case ${cpu} in
 442                 sh*eb)  endian=big ;;
 443                 *)      endian=little ;;
 444             esac ;;
 445       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 446       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 447       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 448       sh-*-elf*)                        fmt=elf ;;
 449       sh-*-coff*)                       fmt=coff ;;
 450       sh-*-nto*)                        fmt=elf ;;
 451       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 452       sh-*-rtemself*)                   fmt=elf ;;
 453       sh-*-rtems*)                      fmt=coff ;;
 454       sh-*-kaos*)                       fmt=elf ;;
 455       shle*-*-kaos*)                    fmt=elf ;;
 456       sh64-*-elf*)                      fmt=elf ;;
 457
 458       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 459       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 460       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 461       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 462
 463       sparc-*-rtemsaout*)               fmt=aout ;;
 464       sparc-*-rtemself*)                fmt=elf ;;
 465       sparc-*-rtems*)                   fmt=elf ;;
 466       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 467       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 468       sparc-*-coff)                     fmt=coff ;;
 469       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 470       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 471       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 472       sparc-fujitsu-none)               fmt=aout ;;
 473       sparc-*-elf)                      fmt=elf ;;
 474       sparc-*-sysv4*)                   fmt=elf ;;
 475       sparc-*-solaris*)                 fmt=elf ;;
 476       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 477       sparc-*-*n*bsd*)  case ${cpu} in
 478                             sparc64)    fmt=elf em=nbsd ;;
 479                             *)          fmt=aout em=nbsd ;;
 480                         esac ;;
 481       strongarm-*-coff)                 fmt=coff ;;
 482       strongarm-*-elf)                  fmt=elf ;;
 483       strongarm-*-kaos*)                fmt=elf ;;
 484       xscale-*-coff)                    fmt=coff ;;
 485       xscale-*-elf)                     fmt=elf ;;
 486
 487       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 488       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 489       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 490       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 491       tic80-*-*)                        fmt=coff ;;
 492
 493       v850-*-*)                         fmt=elf ;;
 494       v850e-*-*)                        fmt=elf ;;
 495       v850ea-*-*)                       fmt=elf ;;
 496
 497       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 498       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 499       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 500       vax-*-linux-gnu*)                 fmt=elf em=linux bfd_gas=yes ;;
 501       vax-*-vms)                        fmt=vms ;;
 502
 503       w65-*-*)                          fmt=coff ;;
 504
 505       xstormy16-*-*)                    fmt=elf ;;
 506
 507       xtensa-*-*)                       fmt=elf ;;
 508
 509       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 510
 511       *-*-aout | *-*-scout)             fmt=aout ;;
 512       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 513       *-*-nindy*)                       fmt=bout ;;
 514       *-*-bsd*)                         fmt=aout em=sun3 ;;
 515       *-*-generic)                      fmt=generic ;;
 516       *-*-xray | *-*-hms)               fmt=coff ;;
 517       *-*-sim)                          fmt=coff ;;
 518       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 519       *-*-aros*)                        fmt=elf em=linux bfd_gas=yes ;;
 520       *-*-vxworks | *-*-windiss)        fmt=elf ;;
 521       *-*-netware)                      fmt=elf ;;
 522     esac
 523
 524     if test ${this_target} = $target ; then
 525       endian_def=
 526       if test x${endian} = xbig; then
 527         endian_def=1
 528       elif test x${endian} = xlittle; then
 529         endian_def=0
 530       fi
 531       if test x${endian_def} != x; then
 532         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 533                            [Define as 1 if big endian.])
 534       fi
 535     fi
 536
 537     case ${cpu_type}-${fmt} in
 538         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 539                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 540                 | *-elf | *-ecoff | *-som)
 541             bfd_gas=yes ;;
 542     esac
 543
 544 # Other random stuff.
 545
 546     case ${cpu_type} in
 547       mips)
 548         # Set mips_cpu to the name of the default CPU.
 549         case ${target_cpu} in
 550           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 551             mips_cpu=from-abi
 552             ;;
 553           mipsisa32 | mipsisa32el)
 554             mips_cpu=mips32
 555             ;;
 556           mipsisa32r2 | mipsisa32r2el)
 557             mips_cpu=mips32r2
 558             ;;
 559           mipsisa64 | mipsisa64el)
 560             mips_cpu=mips64
 561             ;;
 562           mipsisa64r2 | mipsisa64r2el)
 563             mips_cpu=mips64r2
 564             ;;
 565           mipstx39 | mipstx39el)
 566             mips_cpu=r3900
 567             ;;
 568           mips64vr | mips64vrel)
 569             mips_cpu=vr4100
 570             ;;
 571           mipsisa32r2* | mipsisa64r2*)
 572 changequote(,)dnl
 573             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 574 changequote([,])dnl
 575             ;;
 576           mips64* | mipsisa64* | mipsisa32*)
 577 changequote(,)dnl
 578             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 579 changequote([,])dnl
 580             ;;
 581           *)
 582             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 583             ;;
 584         esac
 585         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 586         # binaries.  It's a GNU extension that some OSes don't understand.
 587         # The value only matters on ELF targets.
 588         case ${target} in
 589           *-*-irix*)
 590             use_e_mips_abi_o32=0
 591             ;;
 592           *)
 593             use_e_mips_abi_o32=1
 594             ;;
 595         esac
 596         # Decide whether to generate 32-bit or 64-bit code by default.
 597         # Used to resolve -march=from-abi when an embedded ABI is selected.
 598         case ${target} in
 599           mips64*-*-* | mipsisa64*-*-*)
 600             mips_default_64bit=1
 601             ;;
 602           *)
 603             mips_default_64bit=0
 604             ;;
 605         esac
 606         # Decide which ABI to target by default.
 607         case ${target} in
 608           mips64*-linux* | mips-sgi-irix6*)
 609             mips_default_abi=N32_ABI
 610             ;;
 611           mips*-linux*)
 612             mips_default_abi=O32_ABI
 613             ;;
 614           *)
 615             mips_default_abi=NO_ABI
 616             ;;
 617         esac
 618         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 619                            [Default CPU for MIPS targets. ])
 620         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 621                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 622         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 623                            [Generate 64-bit code by default on MIPS targets. ])
 624         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 625                            [Choose a default ABI for MIPS targets. ])
 626         ;;
 627     esac
 628
 629     # Do we need the opcodes library?
 630     case ${cpu_type} in
 631       vax | i386 | tic30)
 632         ;;
 633
 634       *)
 635         need_opcodes=yes
 636
 637         case "${enable_shared}" in
 638         yes) shared_opcodes=true ;;
 639         *opcodes*) shared_opcodes=true ;;
 640         *) shared_opcodes=false ;;
 641         esac
 642         if test "${shared_opcodes}" = "true"; then
 643           # A shared libopcodes must be linked against libbfd.
 644           need_bfd=yes
 645         fi
 646         ;;
 647     esac
 648
 649     # Any other special object files needed ?
 650     case ${cpu_type} in
 651       fr30 | ip2k | iq2000 | m32r | openrisc)
 652         using_cgen=yes
 653         ;;
 654
 655       frv)
 656         using_cgen=yes
 657         ;;
 658       m68k)
 659         case ${extra_objects} in
 660         *m68k-parse.o*) ;;
 661         *) extra_objects="$extra_objects m68k-parse.o" ;;
 662         esac
 663         ;;
 664
 665       mips)
 666         echo ${extra_objects} | grep -s "itbl-parse.o"
 667         if test $? -ne 0 ; then
 668           extra_objects="$extra_objects itbl-parse.o"
 669         fi
 670
 671         echo ${extra_objects} | grep -s "itbl-lex.o"
 672         if test $? -ne 0 ; then
 673           extra_objects="$extra_objects itbl-lex.o"
 674         fi
 675
 676         echo ${extra_objects} | grep -s "itbl-ops.o"
 677         if test $? -ne 0 ; then
 678           extra_objects="$extra_objects itbl-ops.o"
 679         fi
 680         ;;
 681
 682       i386 | s390 | sparc)
 683         if test $this_target = $target ; then
 684           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 685         fi
 686         ;;
 687
 688       xstormy16)
 689         using_cgen=yes
 690         ;;
 691
 692       xtensa)
 693         echo ${extra_objects} | grep -s "xtensa-relax.o"
 694         if test $? -ne 0 ; then
 695           extra_objects="$extra_objects xtensa-relax.o"
 696         fi
 697         ;;
 698
 699       *)
 700         ;;
 701     esac
 702
 703     if test $using_cgen = yes ; then
 704         case "x${extra_objects}" in
 705         *cgen.o*) ;;
 706         *) extra_objects="$extra_objects cgen.o" ;;
 707         esac
 708     fi
 709
 710 # See if we really can support this configuration with the emulation code.
 711
 712     if test $this_target = $target ; then
 713       primary_bfd_gas=$bfd_gas
 714       obj_format=$fmt
 715       te_file=$em
 716
 717       if test $bfd_gas = no ; then
 718         # Can't support other configurations this way.
 719         break
 720       fi
 721     elif test $bfd_gas = no ; then
 722       # Can't support this configuration.
 723       break
 724     fi
 725
 726 # From target name and format, produce a list of supported emulations.
 727
 728     case ${generic_target}-${fmt} in
 729       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 730       mips*-*-linux*-*) case "$endian" in
 731                         big)    emulation="mipsbelf mipslelf mipself" ;;
 732                         *)      emulation="mipslelf mipsbelf mipself" ;;
 733                         esac ;;
 734       mips-*-lnews*-ecoff) ;;
 735       mips-*-*-ecoff)   case "$endian" in
 736                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 737                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 738                         esac ;;
 739       mips-*-*-elf)     case "$endian" in
 740                         big)    emulation="mipsbelf mipslelf mipself" ;;
 741                         *)      emulation="mipslelf mipsbelf mipself" ;;
 742                         esac ;;
 743       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 744       # i386-pc-pe-coff != i386-pc-coff.
 745       i386-*-pe-coff)   ;;
 746       # Uncommenting the next line will turn on support for i386 AOUT
 747       # for the default linux configuration
 748       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 749       #
 750       i386-*-aout)      emulation="i386aout" ;;
 751       i386-*-coff)      emulation="i386coff" ;;
 752       i386-*-elf)       emulation="i386elf" ;;
 753
 754       # Always all formats.  The first stated emulation becomes the default.
 755       cris-*-*aout*)    emulation="crisaout criself" ;;
 756       cris-*-*)         emulation="criself crisaout" ;;
 757     esac
 758
 759     emulations="$emulations $emulation"
 760
 761 done
 762
 763 # Turn on all targets if possible
 764 if test ${all_targets} = "yes"; then
 765   case ${target_cpu_type} in
 766   i386)
 767     case ${obj_format} in
 768     aout)
 769       emulations="$emulations i386coff i386elf"
 770       ;;
 771     coff)
 772       emulations="$emulations i386aout i386elf"
 773     ;;
 774     elf)
 775       emulations="$emulations i386aout i386coff"
 776       ;;
 777     esac
 778   ;;
 779   esac
 780 fi
 781
 782 # Assign floating point type.  Most processors with FP support
 783 # IEEE FP.  On those that don't support FP at all, usually IEEE
 784 # is emulated.
 785 case ${target_cpu} in
 786   vax | tahoe ) atof=${target_cpu} ;;
 787   pdp11)        atof=vax ;;
 788   *)            atof=ieee ;;
 789 esac
 790
 791 case "${obj_format}" in
 792   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 793 esac
 794
 795 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 796 cgen_cpu_prefix=""
 797 if test $using_cgen = yes ; then
 798   case ${target_cpu} in
 799     *) cgen_cpu_prefix=${target_cpu} ;;
 800   esac
 801   AC_SUBST(cgen_cpu_prefix)
 802   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 803 fi
 804
 805 dnl
 806 dnl Make sure the desired support files exist.
 807 dnl
 808
 809 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 810   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 811 fi
 812
 813 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 814   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 815 fi
 816
 817 case ${user_bfd_gas}-${primary_bfd_gas} in
 818   yes-yes | no-no)
 819     # We didn't override user's choice.
 820     ;;
 821   no-yes)
 822     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 823     ;;
 824   no-preferred)
 825     primary_bfd_gas=no
 826     ;;
 827   *-preferred)
 828     primary_bfd_gas=yes
 829     ;;
 830   yes-*)
 831     primary_bfd_gas=yes
 832     ;;
 833   -*)
 834     # User specified nothing.
 835     ;;
 836 esac
 837
 838 # Some COFF configurations want these random other flags set.
 839 case ${obj_format} in
 840   coff)
 841     case ${target_cpu_type} in
 842       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 843       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 844       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 845     esac
 846     ;;
 847 esac
 848
 849 # Getting this done right is going to be a bitch.  Each configuration specified
 850 # with --enable-targets=... should be checked for environment, format, cpu, and
 851 # bfd_gas setting.
 852 #
 853 # For each configuration, the necessary object file support code must be linked
 854 # in.  This might be only one, it might be up to four.  The necessary emulation
 855 # code needs to be provided, too.
 856 #
 857 # And then there's "--enable-targets=all"....
 858 #
 859 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 860
 861 formats="${obj_format}"
 862 emfiles=""
 863 EMULATIONS=""
 864 GAS_UNIQ(emulations)
 865 for em in . $emulations ; do
 866   case $em in
 867     .)  continue ;;
 868     mipsbelf | mipslelf | mipself)
 869         fmt=elf   file=mipself ;;
 870     mipsbecoff | mipslecoff | mipsecoff)
 871         fmt=ecoff file=mipsecoff ;;
 872     *coff)
 873         fmt=coff  file=$em ;;
 874     *aout)
 875         fmt=aout file=$em ;;
 876     *elf)
 877         fmt=elf file=$em ;;
 878   esac
 879   formats="$formats $fmt"
 880   emfiles="$emfiles e-$file.o"
 881   EMULATIONS="$EMULATIONS &$em,"
 882 done
 883 GAS_UNIQ(formats)
 884 GAS_UNIQ(emfiles)
 885 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 886   for fmt in $formats ; do
 887     case $fmt in
 888       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 889       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 890       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 891       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 892       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 893       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 894       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 895       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 896       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 897       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 898     esac
 899     extra_objects="$extra_objects obj-$fmt.o"
 900   done
 901   obj_format=multi
 902 fi
 903 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 904   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 905   # e-mips* has more than one emulation per file, e-i386* has just one at the
 906   # moment.  If only one emulation is specified, then don't define
 907   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 908   case "${obj_format}${emfiles}" in
 909     multi* | *mips*)
 910       extra_objects="$extra_objects $emfiles"
 911       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 912   esac
 913 fi
 914 AC_SUBST(extra_objects)
 915 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 916 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 917                    [Default emulation.])
 918
 919 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 920   yes-*-coff)   need_bfd=yes ;;
 921   no-*-coff)    need_bfd=yes
 922                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 923 esac
 924
 925 reject_dev_configs=yes
 926
 927 case ${reject_dev_configs}-${dev} in
 928   yes-yes) # Oops.
 929     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 930     ;;
 931 esac
 932
 933 AC_SUBST(target_cpu_type)
 934 AC_SUBST(obj_format)
 935 AC_SUBST(te_file)
 936 AC_SUBST(install_tooldir)
 937 AC_SUBST(atof)
 938 dnl AC_SUBST(emulation)
 939
 940 case "${primary_bfd_gas}" in
 941   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 942         need_bfd=yes ;;
 943 esac
 944
 945 # do we need the opcodes library?
 946 case "${need_opcodes}" in
 947 yes)
 948   OPCODES_LIB=../opcodes/libopcodes.la
 949   ;;
 950 esac
 951
 952 case "${need_bfd}" in
 953 yes)
 954   BFDLIB=../bfd/libbfd.la
 955   BFDVER_H=../bfd/bfdver.h
 956   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 957   ;;
 958 esac
 959
 960 AC_SUBST(BFDLIB)
 961 AC_SUBST(OPCODES_LIB)
 962
 963 AC_SUBST(BFDVER_H)
 964 AC_SUBST(ALL_OBJ_DEPS)
 965
 966 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 967 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 968 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 969 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 970 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 971
 972 AC_PROG_CC
 973
 974 AC_PROG_YACC
 975 AM_PROG_LEX
 976
 977 ALL_LINGUAS="fr tr es"
 978 CY_GNU_GETTEXT
 979
 980 AM_MAINTAINER_MODE
 981 AC_EXEEXT
 982
 983 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 984
 985 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 986 # people who are not cross-compiling but are compiling cross-assemblers.
 987 AC_MSG_CHECKING(whether compiling a cross-assembler)
 988 if test "${host}" = "${target}"; then
 989   cross_gas=no
 990 else
 991   cross_gas=yes
 992   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 993 fi
 994 AC_MSG_RESULT($cross_gas)
 995
 996 dnl ansidecl.h will deal with const
 997 dnl AC_CONST
 998 AC_FUNC_ALLOCA
 999 AC_C_INLINE
1000
1001 # VMS doesn't have unlink.
1002 AC_CHECK_FUNCS(unlink remove, break)
1003
1004 # Some systems don't have sbrk().
1005 AC_CHECK_FUNCS(sbrk)
1006
1007 # do we need the math library?
1008 case "${need_libm}" in
1009 yes)
1010   AC_CHECK_LIBM
1011   AC_SUBST(LIBM)
1012   ;;
1013 esac
1014
1015 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1016 # enough, but on some of those systems, the assert macro relies on requoting
1017 # working properly!
1018 GAS_WORKING_ASSERT
1019
1020 # On some systems, the system header files may not declare malloc, realloc,
1021 # and free.  There are places where gas needs these functions to have been
1022 # declared -- such as when taking their addresses.
1023 gas_test_headers="
1024 #ifdef HAVE_MEMORY_H
1025 #include <memory.h>
1026 #endif
1027 #ifdef HAVE_STRING_H
1028 #include <string.h>
1029 #else
1030 #ifdef HAVE_STRINGS_H
1031 #include <strings.h>
1032 #endif
1033 #endif
1034 #ifdef HAVE_STDLIB_H
1035 #include <stdlib.h>
1036 #endif
1037 #ifdef HAVE_UNISTD_H
1038 #include <unistd.h>
1039 #endif
1040 "
1041 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1042 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1043 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1044 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1045 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1046
1047 # Does errno.h declare errno, or do we have to add a separate declaration
1048 # for it?
1049 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1050 #ifdef HAVE_ERRNO_H
1051 #include <errno.h>
1052 #endif
1053 ])
1054
1055 dnl This must come last.
1056
1057 dnl We used to make symlinks to files in the source directory, but now
1058 dnl we just use the right name for .c files, and create .h files in
1059 dnl the build directory which include the right .h file.  Make sure
1060 dnl the old symlinks don't exist, so that a reconfigure in an existing
1061 dnl directory behaves reasonably.
1062
1063 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1064 AC_CONFIG_COMMANDS([default],
1065 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1066  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1067  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1068  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1069  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1070  if test "x$cgen_cpu_prefix" != x ; then
1071    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1072  fi
1073
1074  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1075 [target_cpu_type=${target_cpu_type}
1076  cgen_cpu_prefix=${cgen_cpu_prefix}
1077  obj_format=${obj_format}
1078  te_file=${te_file}])
1079
1080 AC_OUTPUT