gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 dnl List of object files and targets accumulated by configure.
  49
  50 CONFIG_OBS=
  51 CONFIG_DEPS=
  52 CONFIG_SRCS=
  53 ENABLE_CFLAGS=
  54
  55 CONFIG_ALL=
  56 CONFIG_CLEAN=
  57 CONFIG_INSTALL=
  58 CONFIG_UNINSTALL=
  59
  60 dnl Set up for gettext.
  61 ZW_GNU_GETTEXT_SISTER_DIR
  62
  63 localedir='${datadir}/locale'
  64 AC_SUBST(localedir)
  65
  66 if test x"$USE_NLS" = xyes; then
  67    CONFIG_ALL="$CONFIG_ALL all-po"
  68    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  69    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  70    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  71 fi
  72
  73 PACKAGE=gdb
  74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  75 AC_SUBST(PACKAGE)
  76
  77 # We never need to detect it in this sub-configure.
  78 # But preserve it for config.status --recheck.
  79 AC_ARG_VAR(MAKEINFO,
  80   [Parent configure detects if it is of sufficient version.])
  81 AC_ARG_VAR(MAKEINFOFLAGS,
  82   [Parameters for MAKEINFO.])
  83
  84 MAKEINFO_EXTRA_FLAGS=""
  85 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  86   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  87   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  88     gdb_cv_have_makeinfo_click=yes
  89   else
  90     gdb_cv_have_makeinfo_click=no
  91   fi])
  92 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
  93   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
  94 fi
  95 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
  96
  97 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  98     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  99     [${libdir}/debug])
 100
 101 # We can't pass paths as command line arguments.
 102 # Mingw32 tries to be clever and will convert the paths for us.
 103 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 104 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 105 # This breaks GDB's relocatable path conversions since paths passed in
 106 # config.h would not get so translated, the path prefixes no longer match.
 107 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 108
 109 # GDB's datadir relocation
 110
 111 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 112     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 113     [${datadir}/gdb])
 114
 115 AC_ARG_WITH(relocated-sources,
 116 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 117 [reloc_srcdir="${withval}"
 118  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 119               [Relocated directory for source files. ])
 120 ])
 121
 122 AC_MSG_CHECKING([for default auto-load directory])
 123 AC_ARG_WITH(auto-load-dir,
 124 AS_HELP_STRING([--with-auto-load-dir=PATH],
 125   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 126   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 127 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 128 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 129               [Directories from which to load auto-loaded scripts.])
 130 AC_MSG_RESULT([$with_auto_load_dir])
 131
 132 AC_MSG_CHECKING([for default auto-load safe-path])
 133 AC_ARG_WITH(auto-load-safe-path,
 134 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 135   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 136 AS_HELP_STRING([--without-auto-load-safe-path],
 137                [do not restrict auto-loaded files locations]),
 138     [if test "$with_auto_load_safe_path" = "no"; then
 139      with_auto_load_safe_path="/"
 140      fi],
 141 [with_auto_load_safe_path="$with_auto_load_dir"])
 142 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 143 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 144               [Directories safe to hold auto-loaded files.])
 145 AC_MSG_RESULT([$with_auto_load_safe_path])
 146
 147 AC_CONFIG_SUBDIRS(testsuite)
 148
 149 # Check whether to support alternative target configurations
 150 AC_ARG_ENABLE(targets,
 151 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 152 [case "${enableval}" in
 153   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 154             ;;
 155   no)       enable_targets= ;;
 156   *)        enable_targets=$enableval ;;
 157 esac])
 158
 159 # Check whether to enable 64-bit support on 32-bit hosts
 160 AC_ARG_ENABLE(64-bit-bfd,
 161 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 162 [case "${enableval}" in
 163   yes)  want64=true  ;;
 164   no)   want64=false ;;
 165   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 166 esac],[want64=false])dnl
 167
 168 # Provide defaults for some variables set by the per-host and per-target
 169 # configuration.
 170 gdb_host_obs=posix-hdep.o
 171
 172 if test "${target}" = "${host}"; then
 173   gdb_native=yes
 174 else
 175   gdb_native=no
 176 fi
 177
 178 . $srcdir/configure.host
 179
 180 # Accumulate some settings from configure.tgt over all enabled targets
 181
 182 TARGET_OBS=
 183 all_targets=
 184 HAVE_NATIVE_GCORE_TARGET=
 185
 186 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 187 do
 188   if test "$targ_alias" = "all"; then
 189     all_targets=true
 190   else
 191     # Canonicalize the secondary target names.
 192     result=`$ac_config_sub $targ_alias 2>/dev/null`
 193     if test -n "$result"; then
 194         targ=$result
 195     else
 196         targ=$targ_alias
 197     fi
 198
 199     . ${srcdir}/configure.tgt
 200
 201     AS_IF([test -z "${gdb_target_obs}"],
 202       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 203
 204     # Target-specific object files
 205     for i in ${gdb_target_obs}; do
 206         case " $TARGET_OBS " in
 207         *" ${i} "*) ;;
 208         *)
 209           TARGET_OBS="$TARGET_OBS ${i}"
 210           ;;
 211         esac
 212     done
 213
 214     # Check whether this target needs 64-bit CORE_ADDR
 215     if test x${want64} = xfalse; then
 216       . ${srcdir}/../bfd/config.bfd
 217     fi
 218
 219     # Check whether this target is native and supports gcore.
 220     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 221        && $gdb_have_gcore; then
 222       HAVE_NATIVE_GCORE_TARGET=1
 223     fi
 224   fi
 225 done
 226
 227 if test x${all_targets} = xtrue; then
 228
 229   # We want all 64-bit targets if we either:
 230   #  - run on a 64-bit host  or
 231   #  - already require 64-bit support for some other target  or
 232   #  - the --enable-64-bit-bfd option was supplied
 233   # Otherwise we only support all 32-bit targets.
 234   #
 235   # NOTE: This test must be in sync with the corresponding
 236   #       tests in BFD!
 237
 238   if test x${want64} = xfalse; then
 239     AC_CHECK_SIZEOF(long)
 240     if test "x${ac_cv_sizeof_long}" = "x8"; then
 241       want64=true
 242     fi
 243   fi
 244   if test x${want64} = xtrue; then
 245     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 246   else
 247     TARGET_OBS='$(ALL_TARGET_OBS)'
 248   fi
 249 fi
 250
 251 AC_SUBST(TARGET_OBS)
 252 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 253
 254 # For other settings, only the main target counts.
 255 gdb_sim=
 256 gdb_osabi=
 257 build_gdbserver=
 258 targ=$target; . ${srcdir}/configure.tgt
 259
 260 # Fetch the default architecture and default target vector from BFD.
 261 targ=$target; . $srcdir/../bfd/config.bfd
 262
 263 # We only want the first architecture, so strip off the others if
 264 # there is more than one.
 265 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 266
 267 if test "x$targ_archs" != x; then
 268   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 269     [Define to BFD's default architecture. ])
 270 fi
 271 if test "x$targ_defvec" != x; then
 272   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 273     [Define to BFD's default target vector. ])
 274 fi
 275
 276 # Enable MI.
 277 AC_ARG_ENABLE(gdbmi,
 278 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 279   [case $enableval in
 280     yes | no)
 281       ;;
 282     *)
 283       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 284   esac],
 285   [enable_gdbmi=yes])
 286 if test x"$enable_gdbmi" = xyes; then
 287   if test -d "$srcdir/mi"; then
 288     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 289     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 290     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 291     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 292   fi
 293 fi
 294
 295 # Enable TUI.
 296 AC_ARG_ENABLE(tui,
 297 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 298   [case $enableval in
 299     yes | no | auto)
 300       ;;
 301     *)
 302       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 303   esac],enable_tui=auto)
 304
 305 # Enable gdbtk.
 306 AC_ARG_ENABLE(gdbtk,
 307 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 308   [case $enableval in
 309     yes | no)
 310       ;;
 311     *)
 312       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 313   esac],
 314   [if test -d "$srcdir/gdbtk"; then
 315     enable_gdbtk=yes
 316   else
 317     enable_gdbtk=no
 318   fi])
 319 # We unconditionally disable gdbtk tests on selected platforms.
 320 case $host_os in
 321   go32* | windows*)
 322     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 323     enable_gdbtk=no ;;
 324 esac
 325
 326 # Libunwind support for ia64.
 327
 328 AC_ARG_WITH(libunwind-ia64,
 329 AS_HELP_STRING([--with-libunwind-ia64],
 330                [use libunwind frame unwinding for ia64 targets]),,
 331             [with_libunwind_ia64=auto])
 332
 333 # Backward compatibility option.
 334 if test "${with_libunwind+set}" = set; then
 335   if test x"$with_libunwind_ia64" != xauto; then
 336     AC_MSG_ERROR(
 337       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 338   fi
 339   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 340   with_libunwind_ia64="$with_libunwind"
 341 fi
 342
 343 case "$with_libunwind_ia64" in
 344   yes | no)
 345     ;;
 346   auto)
 347     AC_CHECK_HEADERS(libunwind-ia64.h)
 348     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 349     ;;
 350   *)
 351     AC_MSG_ERROR(
 352       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 353     ;;
 354 esac
 355
 356 if test x"$with_libunwind_ia64" = xyes; then
 357   AC_CHECK_HEADERS(libunwind-ia64.h)
 358   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 359     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 360   fi
 361   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 362   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 363   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 364 fi
 365
 366 opt_curses=no
 367 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 368
 369 prefer_curses=no
 370 if test "$opt_curses" = "yes"; then
 371   prefer_curses=yes
 372 fi
 373
 374 # Profiling support.
 375 AC_ARG_ENABLE(profiling,
 376 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 377   [case $enableval in
 378     yes | no)
 379       ;;
 380     *)
 381       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 382   esac],
 383  [enable_profiling=no])
 384
 385 AC_CHECK_FUNCS(monstartup _mcleanup)
 386 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 387 [AC_TRY_LINK(
 388 [#include <stdlib.h>
 389 extern char _etext;
 390 ],
 391 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 392 if test "$ac_cv_var__etext" = yes; then
 393   AC_DEFINE(HAVE__ETEXT, 1,
 394             [Define to 1 if your system has the _etext variable. ])
 395 fi
 396 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 397 [AC_TRY_LINK(
 398 [#include <stdlib.h>
 399 extern char etext;
 400 ],
 401 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 402 if test "$ac_cv_var_etext" = yes; then
 403   AC_DEFINE(HAVE_ETEXT, 1,
 404             [Define to 1 if your system has the etext variable. ])
 405 fi
 406 if test "$enable_profiling" = yes ; then
 407   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 408     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 409   fi
 410   PROFILE_CFLAGS=-pg
 411   OLD_CFLAGS="$CFLAGS"
 412   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 413
 414   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 415     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 416      ac_cv_cc_supports_pg=no)])
 417
 418   if test "$ac_cv_cc_supports_pg" = no; then
 419     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 420   fi
 421
 422   CFLAGS="$OLD_CFLAGS"
 423 fi
 424
 425 CODESIGN_CERT=
 426 AC_ARG_ENABLE([codesign],
 427   AS_HELP_STRING([--enable-codesign=CERT],
 428                  [sign gdb with 'codesign -s CERT']),
 429   [CODESIGN_CERT=$enableval])
 430 AC_SUBST([CODESIGN_CERT])
 431
 432 ACX_PKGVERSION([GDB])
 433 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 434 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 435 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 436
 437 # --------------------- #
 438 # Checks for programs.  #
 439 # --------------------- #
 440
 441 AC_PROG_AWK
 442 AC_PROG_INSTALL
 443 AC_PROG_LN_S
 444 AC_PROG_RANLIB
 445 AC_PROG_YACC
 446
 447 AC_CHECK_TOOL(AR, ar)
 448 AC_CHECK_TOOL(DLLTOOL, dlltool)
 449 AC_CHECK_TOOL(WINDRES, windres)
 450
 451 case $host_os in
 452   gnu*)
 453     # Needed for GNU Hurd hosts.
 454     AC_CHECK_TOOL(MIG, mig)
 455     if test x"$MIG" = x; then
 456       AC_MSG_ERROR([MIG not found but required for $host hosts])
 457     fi
 458     ;;
 459 esac
 460
 461 # ---------------------- #
 462 # Checks for libraries.  #
 463 # ---------------------- #
 464
 465 # We might need to link with -lm; most simulators need it.
 466 AC_CHECK_LIB(m, main)
 467
 468 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 469 AC_SEARCH_LIBS(gethostbyname, nsl)
 470
 471 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 472 AC_SEARCH_LIBS(socketpair, socket)
 473
 474 # Link in zlib if we can.  This allows us to read compressed debug sections.
 475 AM_ZLIB
 476
 477 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 478 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 479 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 480   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 481             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 482
 483 AM_ICONV
 484
 485 # GDB may fork/exec the iconv program to get the list of supported character
 486 # sets.  Allow the user to specify where to find it.
 487 # There are several factors affecting the choice of option name:
 488 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 489 #   the build-time location of libiconv files.
 490 # - The program we need to find is iconv, which comes with glibc.  The user
 491 #   doesn't necessarily have libiconv installed.  Therefore naming this
 492 #   --with-libiconv-foo feels wrong.
 493 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 494 #   defined to work on directories not files (though it really doesn't know
 495 #   the difference).
 496 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 497 #   with --with-libiconv-prefix.
 498 # Putting these together is why the option name is --with-iconv-bin.
 499
 500 AC_ARG_WITH(iconv-bin,
 501 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 502 [iconv_bin="${withval}"
 503  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 504                     [Path of directory of iconv program.])
 505  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 506 ])
 507
 508 # For the TUI, we need enhanced curses functionality.
 509 if test x"$enable_tui" != xno; then
 510   prefer_curses=yes
 511 fi
 512
 513 curses_found=no
 514 if test x"$prefer_curses" = xyes; then
 515   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 516   # curses library because the latter might not provide all the
 517   # functionality we need.  However, this leads to problems on systems
 518   # where the linker searches /usr/local/lib, but the compiler doesn't
 519   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 520   # default installation of ncurses on alpha*-dec-osf* will lead to such
 521   # a situation.
 522   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 523
 524   if test "$ac_cv_search_waddstr" != no; then
 525     curses_found=yes
 526   fi
 527 fi
 528
 529 # Check whether we should enable the TUI, but only do so if we really
 530 # can.
 531 if test x"$enable_tui" != xno; then
 532   if test -d "$srcdir/tui"; then
 533     if test "$curses_found" != no; then
 534       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 535       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 536       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 537       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 538     else
 539       if test x"$enable_tui" = xyes; then
 540         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 541       else
 542         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 543       fi
 544     fi
 545   fi
 546 fi
 547
 548 # Since GDB uses Readline, we need termcap functionality.  In many
 549 # cases this will be provided by the curses library, but some systems
 550 # have a separate termcap library, or no curses library at all.
 551
 552 case $host_os in
 553   cygwin*)
 554     if test -d "$srcdir/libtermcap"; then
 555       LIBS="../libtermcap/libtermcap.a $LIBS"
 556       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 557     fi ;;
 558   go32* | *djgpp*)
 559     ac_cv_search_tgetent="none required"
 560     ;;
 561 esac
 562
 563 # These are the libraries checked by Readline.
 564 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 565
 566 if test "$ac_cv_search_tgetent" = no; then
 567   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 568 fi
 569
 570 AC_ARG_WITH([system-readline],
 571   [AS_HELP_STRING([--with-system-readline],
 572                   [use installed readline library])])
 573
 574 if test "$with_system_readline" = yes; then
 575    AC_CACHE_CHECK([whether system readline is new enough],
 576      [gdb_cv_readline_ok],
 577      [AC_TRY_COMPILE(
 578        [#include <stdio.h>
 579 #include <readline/readline.h>],
 580        [#if RL_VERSION_MAJOR < 7
 581 # error "readline version 7 required"
 582 #endif],
 583     gdb_cv_readline_ok=yes,
 584     gdb_cv_readline_ok=no)])
 585   if test "$gdb_cv_readline_ok" != yes; then
 586     AC_MSG_ERROR([system readline is not new enough])
 587   fi
 588
 589   READLINE=-lreadline
 590   READLINE_DEPS=
 591   READLINE_CFLAGS=
 592   READLINE_TEXI_INCFLAG=
 593 else
 594   READLINE='$(READLINE_DIR)/libreadline.a'
 595   READLINE_DEPS='$(READLINE)'
 596   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 597   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 598 fi
 599 AC_SUBST(READLINE)
 600 AC_SUBST(READLINE_DEPS)
 601 AC_SUBST(READLINE_CFLAGS)
 602 AC_SUBST(READLINE_TEXI_INCFLAG)
 603
 604 # Generate jit-reader.h
 605
 606 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 607 TARGET_PTR=
 608
 609 AC_CHECK_SIZEOF(unsigned long long)
 610 AC_CHECK_SIZEOF(unsigned long)
 611 AC_CHECK_SIZEOF(unsigned __int128)
 612
 613 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 614   TARGET_PTR="unsigned long"
 615 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 616   TARGET_PTR="unsigned long long"
 617 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 618   TARGET_PTR="unsigned __int128"
 619 else
 620   TARGET_PTR="unsigned long"
 621 fi
 622
 623 AC_SUBST(TARGET_PTR)
 624 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 625
 626 AC_SEARCH_LIBS(dlopen, dl)
 627
 628 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 629                 [directory to load the JIT readers from],
 630                 [${libdir}/gdb])
 631
 632 AC_ARG_WITH(expat,
 633   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 634   [], [with_expat=auto])
 635 AC_MSG_CHECKING([whether to use expat])
 636 AC_MSG_RESULT([$with_expat])
 637
 638 if test "${with_expat}" = no; then
 639   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 640   HAVE_LIBEXPAT=no
 641 else
 642   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 643                         [XML_Parser p = XML_ParserCreate (0);])
 644   if test "$HAVE_LIBEXPAT" != yes; then
 645     if test "$with_expat" = yes; then
 646       AC_MSG_ERROR([expat is missing or unusable])
 647     else
 648       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 649     fi
 650   else
 651     save_LIBS=$LIBS
 652     LIBS="$LIBS $LIBEXPAT"
 653     AC_CHECK_FUNCS(XML_StopParser)
 654     LIBS=$save_LIBS
 655   fi
 656 fi
 657
 658 AC_ARG_WITH(mpfr,
 659   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 660   [], [with_mpfr=auto])
 661 AC_MSG_CHECKING([whether to use MPFR])
 662 AC_MSG_RESULT([$with_mpfr])
 663
 664 if test "${with_mpfr}" = no; then
 665   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 666   HAVE_LIBMPFR=no
 667 else
 668   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 669                         [mpfr_exp_t exp; mpfr_t x;
 670                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 671   if test "$HAVE_LIBMPFR" != yes; then
 672     if test "$with_mpfr" = yes; then
 673       AC_MSG_ERROR([MPFR is missing or unusable])
 674     else
 675       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 676     fi
 677   fi
 678 fi
 679
 680 # --------------------- #
 681 # Check for libpython.  #
 682 # --------------------- #
 683
 684 dnl Utility to simplify finding libpython.
 685 dnl $1 = the shell variable to assign the result to
 686 dnl      If libpython is found we store $version here.
 687 dnl $2 = additional flags to add to CPPFLAGS
 688 dnl $3 = additional flags to add to LIBS
 689
 690 AC_DEFUN([AC_TRY_LIBPYTHON],
 691 [
 692   define([have_libpython_var],$1)
 693   new_CPPFLAGS=$2
 694   new_LIBS=$3
 695   AC_MSG_CHECKING([for python])
 696   save_CPPFLAGS=$CPPFLAGS
 697   save_LIBS=$LIBS
 698   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 699   LIBS="$new_LIBS $LIBS"
 700   found_usable_python=no
 701   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 702                                  [[Py_Initialize ();]])],
 703                  [have_libpython_var=yes
 704                   found_usable_python=yes
 705                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 706                   PYTHON_LIBS=$new_LIBS])
 707   CPPFLAGS=$save_CPPFLAGS
 708   LIBS=$save_LIBS
 709   AC_MSG_RESULT([${found_usable_python}])
 710 ])
 711
 712 dnl There are several different values for --with-python:
 713 dnl
 714 dnl no -   Don't include python support.
 715 dnl yes -  Include python support, error if it's missing.
 716 dnl        If we find python in $PATH, use it to fetch configure options,
 717 dnl        otherwise assume the compiler can find it with no help from us.
 718 dnl        Python 2.7 and 2.6 are tried in turn.
 719 dnl auto - Same as "yes", but if python is missing from the system,
 720 dnl        fall back to "no".
 721 dnl /path/to/python/exec-prefix -
 722 dnl        Use the python located in this directory.
 723 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 724 dnl        the compilation parameters.  Otherwise use
 725 dnl        -I/path/to/python/exec-prefix/include,
 726 dnl        -L/path/to/python/exec-prefix/lib.
 727 dnl        Python 2.7 and 2.6 are tried in turn.
 728 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 729 dnl        but is deprecated.
 730 dnl /path/to/python/executable -
 731 dnl        Run python-config.py with this version of python to fetch the
 732 dnl        compilation parameters.
 733 dnl        NOTE: This needn't be the real python executable.
 734 dnl        In a cross-compilation scenario (build != host), this could be
 735 dnl        a shell script that provides what python-config.py provides for
 736 dnl        --ldflags, --includes, --exec-prefix.
 737 dnl python-executable -
 738 dnl        Find python-executable in $PATH, and then handle the same as
 739 dnl        /path/to/python/executable.
 740 dnl
 741 dnl If a python program is specified, it is used to run python-config.py and
 742 dnl is passed --ldflags, --includes, --exec-prefix.
 743
 744 AC_ARG_WITH(python,
 745   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 746   [], [with_python=auto])
 747 AC_MSG_CHECKING([whether to use python])
 748 AC_MSG_RESULT([$with_python])
 749
 750 if test "${with_python}" = no; then
 751   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 752   have_libpython=no
 753 else
 754   case "${with_python}" in
 755   [[\\/]]* | ?:[[\\/]]*)
 756     if test -d "${with_python}"; then
 757       # Assume the python binary is ${with_python}/bin/python.
 758       python_prog="${with_python}/bin/python"
 759       python_prefix=
 760       # If python does not exit ${with_python}/bin, then try in
 761       # ${with_python}.  On Windows/MinGW, this is where the Python
 762       # executable is.
 763       if test ! -x "${python_prog}"; then
 764         python_prog="${with_python}/python"
 765         python_prefix=
 766       fi
 767       if test ! -x "${python_prog}"; then
 768         # Fall back to gdb 7.0/7.1 behaviour.
 769         python_prog=missing
 770         python_prefix=${with_python}
 771       fi
 772     elif test -x "${with_python}"; then
 773       # While we can't run python compiled for $host (unless host == build),
 774       # the user could write a script that provides the needed information,
 775       # so we support that.
 776       python_prog=${with_python}
 777       python_prefix=
 778     else
 779       AC_ERROR(invalid value for --with-python)
 780     fi
 781     ;;
 782   */*)
 783     # Disallow --with-python=foo/bar.
 784     AC_ERROR(invalid value for --with-python)
 785     ;;
 786   *)
 787     # The user has either specified auto, yes, or the name of the python
 788     # program assumed to be in $PATH.
 789     python_prefix=
 790     case "${with_python}" in
 791     yes | auto)
 792       if test "${build}" = "${host}"; then
 793         AC_PATH_PROG(python_prog_path, python, missing)
 794         if test "${python_prog_path}" = missing; then
 795           python_prog=missing
 796         else
 797           python_prog=${python_prog_path}
 798         fi
 799       else
 800         # Not much we can do except assume the cross-compiler will find the
 801         # right files.
 802         python_prog=missing
 803       fi
 804       ;;
 805     *)
 806       # While we can't run python compiled for $host (unless host == build),
 807       # the user could write a script that provides the needed information,
 808       # so we support that.
 809       python_prog="${with_python}"
 810       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 811       if test "${python_prog_path}" = missing; then
 812         AC_ERROR(unable to find python program ${python_prog})
 813       fi
 814       ;;
 815     esac
 816   esac
 817
 818   if test "${python_prog}" != missing; then
 819     # We have a python program to use, but it may be too old.
 820     # Don't flag an error for --with-python=auto (the default).
 821     have_python_config=yes
 822     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 823     if test $? != 0; then
 824       have_python_config=failed
 825       if test "${with_python}" != auto; then
 826         AC_ERROR(failure running python-config --includes)
 827       fi
 828     fi
 829     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 830     if test $? != 0; then
 831       have_python_config=failed
 832       if test "${with_python}" != auto; then
 833         AC_ERROR(failure running python-config --ldflags)
 834       fi
 835     fi
 836     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 837     if test $? != 0; then
 838       have_python_config=failed
 839       if test "${with_python}" != auto; then
 840         AC_ERROR(failure running python-config --exec-prefix)
 841       fi
 842     fi
 843   else
 844     # We do not have a python executable we can use to determine where
 845     # to find the Python headers and libs.  We cannot guess the include
 846     # path from the python_prefix either, because that include path
 847     # depends on the Python version.  So, there is nothing much we can
 848     # do except assume that the compiler will be able to find those files.
 849     python_includes=
 850     python_libs=
 851     have_python_config=no
 852   fi
 853
 854   # If we have python-config, only try the configuration it provides.
 855   # Otherwise fallback on the old way of trying different versions of
 856   # python in turn.
 857
 858   have_libpython=no
 859   if test "${have_python_config}" = yes; then
 860     AC_TRY_LIBPYTHON(have_libpython,
 861                      ${python_includes}, ${python_libs})
 862   elif test "${have_python_config}" != failed; then
 863     if test "${have_libpython}" = no; then
 864       AC_TRY_LIBPYTHON(have_libpython,
 865                        ${python_includes}, "-lpython2.7 ${python_libs}")
 866     fi
 867     if test "${have_libpython}" = no; then
 868       AC_TRY_LIBPYTHON(have_libpython,
 869                        ${python_includes}, "-lpython2.6 ${python_libs}")
 870     fi
 871   fi
 872
 873   if test "${have_libpython}" = no; then
 874     case "${with_python}" in
 875     yes)
 876       AC_MSG_ERROR([python is missing or unusable])
 877       ;;
 878     auto)
 879       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 880       ;;
 881     *)
 882       AC_MSG_ERROR([no usable python found at ${with_python}])
 883       ;;
 884     esac
 885   else
 886     if test -n "${python_prefix}"; then
 887       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 888                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 889       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 890     fi
 891   fi
 892 fi
 893
 894 if test "${have_libpython}" != no; then
 895   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 896   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 897   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 898   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 899   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 900   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 901
 902   # Flags needed to compile Python code (taken from python-config --cflags).
 903   # We cannot call python-config directly because it will output whatever was
 904   # used when compiling the Python interpreter itself, including flags which
 905   # would make the python-related objects be compiled differently from the
 906   # rest of GDB (e.g., -O2 and -fPIC).
 907   if test "${GCC}" = yes; then
 908     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 909     # Python headers recommend -DNDEBUG, but it's unclear if that just
 910     # refers to building Python itself.  In release mode, though, it
 911     # doesn't hurt for the Python code in gdb to follow.
 912     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 913   fi
 914
 915   if test "x${tentative_python_cflags}" != x; then
 916     AC_MSG_CHECKING(compiler flags for python code)
 917     for flag in ${tentative_python_cflags}; do
 918       # Check that the compiler accepts it
 919       saved_CFLAGS="$CFLAGS"
 920       CFLAGS="$CFLAGS $flag"
 921       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 922       CFLAGS="$saved_CFLAGS"
 923     done
 924     AC_MSG_RESULT(${PYTHON_CFLAGS})
 925   fi
 926
 927   # On x64 Windows, Python's include headers, and pyconfig.h in
 928   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 929   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 930   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 931   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 932   # The issue was reported to the Python community, but still isn't
 933   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 934
 935   case "$gdb_host" in
 936     mingw64)
 937            if test "${GCC}" = yes; then
 938              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 939            fi
 940            ;;
 941   esac
 942 else
 943   # Even if Python support is not compiled in, we need to have this file
 944   # included so that the "python" command, et.al., still exists.
 945   CONFIG_OBS="$CONFIG_OBS python/python.o"
 946   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
 947 fi
 948
 949 # Work around Python http://bugs.python.org/issue10112.  See also
 950 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
 951 # no effect.  Note that the only test after this that uses Python is
 952 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
 953 # run without -export-dynamic too.
 954 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
 955
 956 AC_SUBST(PYTHON_CFLAGS)
 957 AC_SUBST(PYTHON_CPPFLAGS)
 958 AC_SUBST(PYTHON_LIBS)
 959 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
 960
 961 # -------------------- #
 962 # Check for libguile.  #
 963 # -------------------- #
 964
 965 dnl Utility to simplify finding libguile.
 966 dnl $1 = pkg-config-program
 967 dnl $2 = space-separate list of guile versions to try
 968 dnl $3 = yes|no, indicating whether to flag errors or ignore them
 969 dnl $4 = the shell variable to assign the result to
 970 dnl      If libguile is found we store "yes" here.
 971
 972 AC_DEFUN([AC_TRY_LIBGUILE],
 973 [
 974   pkg_config=$1
 975   guile_version_list=$2
 976   flag_errors=$3
 977   define([have_libguile_var],$4)
 978   found_usable_guile=checking
 979   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
 980   for guile_version in ${guile_version_list}; do
 981     ${pkg_config} --exists ${guile_version} 2>/dev/null
 982     if test $? != 0; then
 983       continue
 984     fi
 985     dnl pkg-config says the package exists, so if we get an error now,
 986     dnl that's bad.
 987     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
 988     if test $? != 0; then
 989       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
 990     fi
 991     new_LIBS=`${pkg_config} --libs ${guile_version}`
 992     if test $? != 0; then
 993       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
 994     fi
 995     dnl If we get this far, great.
 996     found_usable_guile=${guile_version}
 997     break
 998   done
 999   if test "${found_usable_guile}" = "checking"; then
1000     if test "${flag_errors}" = "yes"; then
1001       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1002     else
1003       found_usable_guile=no
1004     fi
1005   fi
1006   dnl One final sanity check.
1007   dnl The user could have said --with-guile=python-2.7.
1008   if test "${found_usable_guile}" != no; then
1009     save_CPPFLAGS=$CPPFLAGS
1010     save_LIBS=$LIBS
1011     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1012     LIBS="$LIBS $new_LIBS"
1013     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1014                                    [[scm_init_guile ();]])],
1015                    [have_libguile_var=yes
1016                     GUILE_CPPFLAGS=$new_CPPFLAGS
1017                     GUILE_LIBS=$new_LIBS],
1018                    [found_usable_guile=no])
1019     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1020     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1021       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1022                 [Define if Guile supports manual finalization.])
1023     )
1024     CPPFLAGS=$save_CPPFLAGS
1025     LIBS=$save_LIBS
1026     if test "${found_usable_guile}" = no; then
1027       if test "${flag_errors}" = yes; then
1028         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1029       fi
1030     fi
1031   fi
1032   AC_MSG_RESULT([${found_usable_guile}])
1033 ])
1034
1035 dnl There are several different values for --with-guile:
1036 dnl
1037 dnl no -   Don't include guile support.
1038 dnl yes -  Include guile support, error if it's missing.
1039 dnl        The pkg-config program must be in $PATH.
1040 dnl auto - Same as "yes", but if guile is missing from the system,
1041 dnl        fall back to "no".
1042 dnl guile-version [guile-version-choice-2 ...] -
1043 dnl        A space-separated list of guile package versions to try.
1044 dnl        These are passed to pkg-config as-is.
1045 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1046 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1047 dnl /path/to/pkg-config -
1048 dnl        Use this pkg-config program.
1049 dnl        NOTE: This needn't be the "real" pkg-config program.
1050 dnl        It could be a shell script.  It is invoked as:
1051 dnl        pkg-config --exists $version
1052 dnl        pkg-config --cflags $version
1053 dnl        pkg-config --libs $version
1054 dnl        pkg-config --variable guild $version
1055 dnl        The script will be called with $version having each value in
1056 dnl        $try_guile_versions until --exists indicates success.
1057
1058 AC_ARG_WITH(guile,
1059   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1060   [], [with_guile=auto])
1061 AC_MSG_CHECKING([whether to use guile])
1062 AC_MSG_RESULT([$with_guile])
1063
1064 dnl We check guile with pkg-config.
1065 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1066
1067 try_guile_versions="guile-2.0"
1068 have_libguile=no
1069 case "${with_guile}" in
1070 no)
1071   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1072   ;;
1073 auto)
1074   if test "${pkg_config_prog_path}" = "missing"; then
1075     AC_MSG_WARN([pkg-config not found, guile support disabled])
1076   else
1077     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1078   fi
1079   ;;
1080 yes)
1081   if test "${pkg_config_prog_path}" = "missing"; then
1082     AC_MSG_ERROR([pkg-config not found])
1083   fi
1084   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1085   ;;
1086 [[\\/]]* | ?:[[\\/]]*)
1087   if test -x "${with_guile}"; then
1088     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1089   else
1090     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1091   fi
1092   ;;
1093 "" | */*)
1094   # Disallow --with=guile="" and --with-guile=foo/bar.
1095   AC_MSG_ERROR([invalid value for --with-guile])
1096   ;;
1097 *)
1098   # A space separate list of guile versions to try, in order.
1099   if test "${pkg_config_prog_path}" = "missing"; then
1100     AC_MSG_ERROR([pkg-config not found])
1101   fi
1102   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1103   ;;
1104 esac
1105
1106 if test "${have_libguile}" != no; then
1107   dnl Get the name of the 'guild' program.
1108   case "${with_guile}" in
1109   [[\\/]]* | ?:[[\\/]]*)
1110     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1111     ;;
1112   *)
1113     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1114     ;;
1115   esac
1116
1117   dnl Make sure guild can handle this host.
1118   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1119   dnl If not, disable guile support.
1120   if test "$ac_cv_guild_ok" = no; then
1121     have_libguile=no
1122     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1123   fi
1124 fi
1125
1126 if test "${have_libguile}" != no; then
1127   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1128   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1129   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1130   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1131   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1132   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1133
1134   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1135   save_LIBS="$LIBS"
1136   save_CPPFLAGS="$CPPFLAGS"
1137   LIBS="$GUILE_LIBS"
1138   CPPFLAGS="$GUILE_CPPFLAGS"
1139   AC_CHECK_FUNCS([scm_new_smob])
1140   LIBS="$save_LIBS"
1141   CPPFLAGS="$save_CPPFLAGS"
1142 else
1143   # Even if Guile support is not compiled in, we need to have these files
1144   # included.
1145   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1146   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1147 fi
1148 AC_SUBST(GUILE_CPPFLAGS)
1149 AC_SUBST(GUILE_LIBS)
1150 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1151
1152 # ---------------------------- #
1153 # Check for source highlight.  #
1154 # ---------------------------- #
1155
1156 SRCHIGH_LIBS=
1157 SRCHIGH_CFLAGS=
1158
1159 AC_ARG_ENABLE(source-highlight,
1160   AS_HELP_STRING([--enable-source-highlight],
1161     [enable source-highlight for source listings]),
1162   [case "${enableval}" in
1163   yes)  enable_source_highlight=yes ;;
1164   no)   enable_source_highlight=no  ;;
1165   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1166 esac],
1167 [enable_source_highlight=auto])
1168
1169 if test "${enable_source_highlight}" != "no"; then
1170   AC_MSG_CHECKING([for the source-highlight library])
1171   if test "${pkg_config_prog_path}" = "missing"; then
1172     AC_MSG_RESULT([no - pkg-config not found])
1173     if test "${enable_source_highlight}" = "yes"; then
1174       AC_MSG_ERROR([pkg-config was not found in your system])
1175     fi
1176   else
1177     case "$LDFLAGS" in
1178       *static-libstdc*)
1179         AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1180 either use --disable-source-highlight or dnl
1181 --without-static-standard-libraries])
1182         ;;
1183     esac
1184
1185     if ${pkg_config_prog_path} --exists source-highlight; then
1186       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1187       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1188       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1189                 [Define to 1 if the source-highlight library is available])
1190       AC_MSG_RESULT([yes])
1191     else
1192       AC_MSG_RESULT([no])
1193       if test "${enable_source_highlight}" = "yes"; then
1194         AC_MSG_ERROR([source-highlight was not found in your system])
1195       fi
1196     fi
1197   fi
1198 fi
1199 AC_SUBST(SRCHIGH_LIBS)
1200 AC_SUBST(SRCHIGH_CFLAGS)
1201
1202 # ------------------------- #
1203 # Checks for header files.  #
1204 # ------------------------- #
1205
1206 AC_HEADER_STDC
1207 # elf_hp.h is for HP/UX 64-bit shared library support.
1208 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h \
1209                   thread_db.h \
1210                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1211                   sys/resource.h sys/ptrace.h ptrace.h \
1212                   sys/reg.h sys/debugreg.h sys/select.h \
1213                   termios.h elf_hp.h])
1214 AC_CHECK_HEADERS(sys/user.h, [], [],
1215 [#if HAVE_SYS_PARAM_H
1216 # include <sys/param.h>
1217 #endif
1218 ])
1219
1220 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1221 AC_CHECK_HEADERS(term.h, [], [],
1222 [#if HAVE_CURSES_H
1223 # include <curses.h>
1224 #endif
1225 ])
1226
1227 # ------------------------- #
1228 # Checks for declarations.  #
1229 # ------------------------- #
1230
1231 libiberty_INIT
1232
1233 AC_CHECK_DECLS([snprintf])
1234 AM_LC_MESSAGES
1235
1236 # ------------------ #
1237 # Checks for types.  #
1238 # ------------------ #
1239
1240 AC_CHECK_TYPES(socklen_t, [], [],
1241 [#include <sys/types.h>
1242 #include <sys/socket.h>
1243 ])
1244
1245 # ------------------------------------- #
1246 # Checks for compiler characteristics.  #
1247 # ------------------------------------- #
1248
1249 AC_C_CONST
1250 AC_C_INLINE
1251 AC_C_BIGENDIAN
1252
1253 # ------------------------------ #
1254 # Checks for library functions.  #
1255 # ------------------------------ #
1256
1257 AC_CHECK_FUNCS([getuid getgid \
1258                 pipe poll pread pread64 pwrite resize_term \
1259                 getpgid setsid \
1260                 sigaction sigsetmask socketpair \
1261                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1262                 setrlimit getrlimit posix_madvise waitpid \
1263                 use_default_colors])
1264 AM_LANGINFO_CODESET
1265 GDB_AC_COMMON
1266
1267 # Check the return and argument types of ptrace.
1268 GDB_AC_PTRACE
1269
1270 dnl AC_FUNC_SETPGRP does not work when cross compiling
1271 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1272 if test "$cross_compiling" = no; then
1273   AC_FUNC_SETPGRP
1274 else
1275   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1276     [AC_TRY_COMPILE([
1277 #include <unistd.h>
1278 ], [
1279   if (setpgrp(1,1) == -1)
1280     exit (0);
1281   else
1282     exit (1);
1283 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1284 if test "$ac_cv_func_setpgrp_void" = yes; then
1285   AC_DEFINE(SETPGRP_VOID, 1)
1286 fi
1287 fi
1288
1289 # Assume we'll default to using the included libiberty regex.
1290 gdb_use_included_regex=yes
1291
1292 # However, if the system regex is GNU regex, then default to *not*
1293 # using the included regex.
1294 AC_CACHE_CHECK(
1295   [for GNU regex],
1296   [gdb_cv_have_gnu_regex],
1297   [AC_TRY_COMPILE(
1298     [#include <gnu-versions.h>],
1299     [#define REGEX_INTERFACE_VERSION 1
1300 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1301 # error "Version mismatch"
1302 #endif],
1303     gdb_cv_have_gnu_regex=yes,
1304     gdb_cv_have_gnu_regex=no)])
1305 if test "$gdb_cv_have_gnu_regex" = yes; then
1306   gdb_use_included_regex=no
1307 fi
1308
1309 AC_ARG_WITH(included-regex,
1310   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1311   gdb_with_regex=$withval,
1312   gdb_with_regex=$gdb_use_included_regex)
1313 if test "$gdb_with_regex" = yes; then
1314   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1315     [Define to 1 if the regex included in libiberty should be used.])
1316 fi
1317
1318 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1319 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1320 [#include <sys/param.h>
1321 #include <sys/proc.h>
1322 ])
1323
1324 # See if <sys/lwp.h> defines `struct lwp`.
1325 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1326 [AC_TRY_COMPILE([#include <sys/param.h>
1327 #define _KMEMUSER
1328 #include <sys/lwp.h>], [struct lwp l;],
1329 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1330 if test "$gdb_cv_struct_lwp" = yes; then
1331   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1332             [Define to 1 if your system has struct lwp.])
1333 fi
1334
1335 # See if <machine/reg.h> degines `struct reg'.
1336 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1337 [AC_TRY_COMPILE([#include <sys/types.h>
1338 #include <machine/reg.h>], [struct reg r;],
1339 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1340 if test "$gdb_cv_struct_reg" = yes; then
1341   AC_DEFINE(HAVE_STRUCT_REG, 1,
1342             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1343 fi
1344
1345 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1346 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1347 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1348                  [#include <sys/types.h>
1349 #include <machine/reg.h>])
1350
1351 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1352 # Older amd64 Linux's don't have the fs_base and gs_base members of
1353 # `struct user_regs_struct'.
1354 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1355      [], [], [#include <sys/types.h>
1356 #include <sys/user.h>])
1357
1358 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1359 AC_MSG_CHECKING(for PTRACE_GETREGS)
1360 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1361 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1362                 [PTRACE_GETREGS;],
1363                 [gdb_cv_have_ptrace_getregs=yes],
1364                 [gdb_cv_have_ptrace_getregs=no])])
1365 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1366 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1367   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1368   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1369 fi
1370
1371 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1372 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1373 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1374 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1375                 [PTRACE_GETFPXREGS;],
1376                 [gdb_cv_have_ptrace_getfpxregs=yes],
1377                 [gdb_cv_have_ptrace_getfpxregs=no])])
1378 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1379 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1380   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1381   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1382 fi
1383
1384 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1385 AC_MSG_CHECKING(for PT_GETDBREGS)
1386 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1387 [AC_TRY_COMPILE([#include <sys/types.h>
1388 #include <sys/ptrace.h>],
1389                 [PT_GETDBREGS;],
1390                 [gdb_cv_have_pt_getdbregs=yes],
1391                 [gdb_cv_have_pt_getdbregs=no])])
1392 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1393 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1394   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1395   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1396 fi
1397
1398 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1399 AC_MSG_CHECKING(for PT_GETXMMREGS)
1400 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1401 [AC_TRY_COMPILE([#include <sys/types.h>
1402 #include <sys/ptrace.h>],
1403                 [PT_GETXMMREGS;],
1404                 [gdb_cv_have_pt_getxmmregs=yes],
1405                 [gdb_cv_have_pt_getxmmregs=no])])
1406 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1407 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1408   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1409   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1410 fi
1411
1412 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1413 # Older FreeBSD versions don't have the pl_tdname member of
1414 # `struct ptrace_lwpinfo'.
1415 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1416                  [#include <sys/ptrace.h>])
1417
1418 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1419 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1420 # FreeBSD 10.3.
1421 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1422                  [#include <sys/ptrace.h>])
1423
1424 # Check if the compiler supports the `long long' type.
1425
1426 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1427                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1428 [[extern long long foo;]],
1429 [[switch (foo & 2) { case 0: return 1; }]])],
1430                                   gdb_cv_c_long_long=yes,
1431                                   gdb_cv_c_long_long=no)])
1432 if test "$gdb_cv_c_long_long" != yes; then
1433   # libdecnumber requires long long.
1434   AC_MSG_ERROR([Compiler must support long long for GDB.])
1435 fi
1436
1437 # Check if the compiler and runtime support printing long longs.
1438
1439 AC_CACHE_CHECK([for long long support in printf],
1440                gdb_cv_printf_has_long_long,
1441                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1442 [[char buf[32];
1443   long long l = 0;
1444   l = (l << 16) + 0x0123;
1445   l = (l << 16) + 0x4567;
1446   l = (l << 16) + 0x89ab;
1447   l = (l << 16) + 0xcdef;
1448   sprintf (buf, "0x%016llx", l);
1449   return (strcmp ("0x0123456789abcdef", buf));]])],
1450                               gdb_cv_printf_has_long_long=yes,
1451                               gdb_cv_printf_has_long_long=no,
1452                               gdb_cv_printf_has_long_long=no)])
1453 if test "$gdb_cv_printf_has_long_long" = yes; then
1454   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1455             [Define to 1 if the "%ll" format works to print long longs.])
1456 fi
1457
1458 # Check if the compiler and runtime support printing decfloats.
1459
1460 AC_CACHE_CHECK([for decfloat support in printf],
1461                gdb_cv_printf_has_decfloat,
1462                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1463 [[char buf[64];
1464   _Decimal32 d32 = 1.2345df;
1465   _Decimal64 d64 = 1.2345dd;
1466   _Decimal128 d128 = 1.2345dl;
1467   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1468   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1469                               gdb_cv_printf_has_decfloat=yes,
1470                               gdb_cv_printf_has_decfloat=no,
1471                               gdb_cv_printf_has_decfloat=no)])
1472 if test "$gdb_cv_printf_has_decfloat" = yes; then
1473   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1474             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1475 fi
1476
1477 # Check if the compiler supports the `long double' type.  We can't use
1478 # AC_C_LONG_DOUBLE because that one does additional checks on the
1479 # constants defined in <float.h> that fail on some systems,
1480 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1481
1482 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1483                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1484                                   gdb_cv_c_long_double=yes,
1485                                   gdb_cv_c_long_double=no)])
1486 if test "$gdb_cv_c_long_double" = yes; then
1487   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1488            [Define to 1 if the compiler supports long double.])
1489 fi
1490
1491 # Check if the compiler and runtime support printing long doubles.
1492
1493 AC_CACHE_CHECK([for long double support in printf],
1494                gdb_cv_printf_has_long_double,
1495                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1496 [[char buf[16];
1497   long double f = 3.141592653;
1498   sprintf (buf, "%Lg", f);
1499   return (strncmp ("3.14159", buf, 7));]])],
1500                               gdb_cv_printf_has_long_double=yes,
1501                               gdb_cv_printf_has_long_double=no,
1502                               gdb_cv_printf_has_long_double=no)])
1503 if test "$gdb_cv_printf_has_long_double" = yes; then
1504   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1505             [Define to 1 if the "%Lg" format works to print long doubles.])
1506 fi
1507
1508 # Check if the compiler and runtime support scanning long doubles.
1509
1510 AC_CACHE_CHECK([for long double support in scanf],
1511                gdb_cv_scanf_has_long_double,
1512                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1513 [[#include <stdio.h>]],
1514 [[char *buf = "3.141592653";
1515   long double f = 0;
1516   sscanf (buf, "%Lg", &f);
1517   return !(f > 3.14159 && f < 3.14160);]])],
1518                               gdb_cv_scanf_has_long_double=yes,
1519                               gdb_cv_scanf_has_long_double=no,
1520                               gdb_cv_scanf_has_long_double=no)])
1521 if test "$gdb_cv_scanf_has_long_double" = yes; then
1522   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1523             [Define to 1 if the "%Lg" format works to scan long doubles.])
1524 fi
1525
1526 case ${host_os} in
1527 aix*)
1528   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1529     SAVE_LDFLAGS=$LDFLAGS
1530
1531     case $GCC in
1532     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1533     *) gdb_cv_bigtoc=-bbigtoc ;;
1534     esac
1535
1536     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1537     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1538     LDFLAGS="${SAVE_LDFLAGS}"
1539   ])
1540   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1541   ;;
1542 esac
1543
1544 AC_MSG_CHECKING(for the dynamic export flag)
1545 dynamic_list=false
1546 if test "${gdb_native}" = yes; then
1547    # The dynamically loaded libthread_db needs access to symbols in the gdb
1548    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1549    # may not be supported there.
1550    old_LDFLAGS="$LDFLAGS"
1551    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1552    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1553    LDFLAGS="$LDFLAGS $RDYNAMIC"
1554    if test "${have_libpython}" = no; then
1555      AC_TRY_LINK([], [], [dynamic_list=true])
1556    else
1557      # Workaround http://bugs.python.org/issue4434 where static
1558      # libpythonX.Y.a would get its symbols required for
1559      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1560      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1561
1562      # Note the workaround for Python
1563      # http://bugs.python.org/issue10112 earlier has removed
1564      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1565      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1566      # always pass.
1567      old_CFLAGS="$CFLAGS"
1568      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1569      old_LIBS="$LIBS"
1570      LIBS="$LIBS $PYTHON_LIBS"
1571      old_CPPFLAGS="$CPPFLAGS"
1572      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1573      AC_RUN_IFELSE(
1574        [AC_LANG_PROGRAM(
1575          [#include "Python.h"],
1576          [int err;
1577           Py_Initialize ();
1578           err = PyRun_SimpleString ("import itertools\n");
1579           Py_Finalize ();
1580           return err == 0 ? 0 : 1;])],
1581        [dynamic_list=true], [], [true])
1582      LIBS="$old_LIBS"
1583      CFLAGS="$old_CFLAGS"
1584      CPPFLAGS="$old_CPPFLAGS"
1585    fi
1586    LDFLAGS="$old_LDFLAGS"
1587 fi
1588 if $dynamic_list; then
1589   found="-Wl,--dynamic-list"
1590   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1591 else
1592   found="-rdynamic"
1593   RDYNAMIC="-rdynamic"
1594 fi
1595 AC_SUBST(RDYNAMIC)
1596 AC_MSG_RESULT($found)
1597
1598 dnl For certain native configurations, we need to check whether thread
1599 dnl support can be built in or not.
1600 dnl
1601 dnl Note that we only want this if we are both native (host == target),
1602 dnl and not doing a canadian cross build (build == host).
1603
1604 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1605    case ${host_os} in
1606    aix*)
1607       AC_MSG_CHECKING(for AiX thread debugging library)
1608       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1609                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1610                                    [#ifndef PTHDB_VERSION_3
1611                                     #error
1612                                     #endif],
1613                                    gdb_cv_have_aix_thread_debug=yes,
1614                                    gdb_cv_have_aix_thread_debug=no)])
1615       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1616       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1617          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1618          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1619          LIBS="$LIBS -lpthdebug"
1620
1621          # Older versions of AIX do not provide the declaration for
1622          # the getthrds function (it appears that it was introduced
1623          # with AIX 6.x).
1624          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1625       fi
1626       ;;
1627    esac
1628    AC_SUBST(CONFIG_LDFLAGS)
1629 fi
1630
1631 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1632 dnl other error codes.
1633 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1634    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1635                   gdb_cv_thread_db_h_has_td_notalloc,
1636      AC_TRY_COMPILE(
1637        [#include <thread_db.h>],
1638        [int i = TD_NOTALLOC;],
1639        gdb_cv_thread_db_h_has_td_notalloc=yes,
1640        gdb_cv_thread_db_h_has_td_notalloc=no
1641      )
1642    )
1643    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1644                   gdb_cv_thread_db_h_has_td_version,
1645      AC_TRY_COMPILE(
1646        [#include <thread_db.h>],
1647        [int i = TD_VERSION;],
1648        gdb_cv_thread_db_h_has_td_version=yes,
1649        gdb_cv_thread_db_h_has_td_version=no
1650      )
1651    )
1652    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1653                   gdb_cv_thread_db_h_has_td_notls,
1654      AC_TRY_COMPILE(
1655        [#include <thread_db.h>],
1656        [int i = TD_NOTLS;],
1657        gdb_cv_thread_db_h_has_td_notls=yes,
1658        gdb_cv_thread_db_h_has_td_notls=no
1659      )
1660    )
1661 fi
1662 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1663   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1664             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1665 fi
1666 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1667   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1668             [Define if <thread_db.h> has the TD_VERSION error code.])
1669 fi
1670 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1671   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1672             [Define if <thread_db.h> has the TD_NOTLS error code.])
1673 fi
1674
1675 dnl Set the host's .gdbinit filename.
1676 case $host_os in
1677   go32* | *djgpp*)
1678     gdbinit=gdb.ini
1679     ;;
1680   *)
1681     gdbinit=.gdbinit
1682     ;;
1683 esac
1684 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1685
1686 dnl Handle optional features that can be enabled.
1687
1688 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1689 # except that the argument to --with-sysroot is optional.
1690 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1691 if test "x$with_sysroot" = xyes; then
1692   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1693 fi
1694 AC_ARG_WITH(sysroot,
1695   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1696                  [search for usr/lib et al within DIR]),
1697   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1698 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1699               [search for usr/lib et al within DIR])
1700 AC_SUBST(TARGET_SYSTEM_ROOT)
1701 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1702
1703 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1704     [automatically load a system-wide gdbinit file],
1705     [])
1706 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1707     [automatically load system-wide gdbinit files from this directory],
1708     [])
1709
1710 AM_GDB_WARNINGS
1711 AM_GDB_UBSAN
1712
1713 # In the Cygwin environment, we need some additional flags.
1714 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1715 [AC_EGREP_CPP(^lose$, [
1716 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1717 lose
1718 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1719
1720
1721 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1722 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1723 case ${host} in
1724   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1725   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1726   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1727   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1728 esac
1729 AC_SUBST(SER_HARDWIRE)
1730
1731 # libreadline needs libuser32.a in a cygwin environment
1732 WIN32LIBS=
1733 if test x"$gdb_cv_os_cygwin" = xyes; then
1734     WIN32LIBS="-luser32"
1735     case "${target}" in
1736         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1737         ;;
1738     esac
1739 fi
1740
1741 # The ser-tcp.c module requires sockets.
1742 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1743 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1744
1745 # Add ELF support to GDB, but only if BFD includes ELF support.
1746 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1747                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1748 if test "$gdb_cv_var_elf" = yes; then
1749   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1750   AC_DEFINE(HAVE_ELF, 1,
1751             [Define if ELF support should be included.])
1752   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1753   if test "$plugins" = "yes"; then
1754     AC_SEARCH_LIBS(dlopen, dl)
1755   fi
1756 fi
1757
1758 # Add macho support to GDB, but only if BFD includes it.
1759 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1760                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1761 if test "$gdb_cv_var_macho" = yes; then
1762   CONFIG_OBS="$CONFIG_OBS machoread.o"
1763 fi
1764
1765 # Add any host-specific objects to GDB.
1766 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1767
1768 # If building on ELF, look for lzma support for embedded compressed debug info.
1769 if test "$gdb_cv_var_elf" = yes; then
1770   AC_ARG_WITH(lzma,
1771     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1772     [], [with_lzma=auto])
1773   AC_MSG_CHECKING([whether to use lzma])
1774   AC_MSG_RESULT([$with_lzma])
1775
1776   if test "${with_lzma}" != no; then
1777     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1778                           [lzma_index_iter iter;
1779                            lzma_index_iter_init (&iter, 0);
1780                            lzma_mf_is_supported (LZMA_MF_HC3);])
1781     if test "$HAVE_LIBLZMA" != yes; then
1782       if test "$with_lzma" = yes; then
1783         AC_MSG_ERROR([missing liblzma for --with-lzma])
1784       fi
1785     fi
1786   fi
1787 fi
1788
1789 LIBGUI="../libgui/src/libgui.a"
1790 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1791 AC_SUBST(LIBGUI)
1792 AC_SUBST(GUI_CFLAGS_X)
1793
1794 WIN32LDAPP=
1795 AC_SUBST(WIN32LIBS)
1796 AC_SUBST(WIN32LDAPP)
1797
1798 case "${host}" in
1799 *-*-cygwin* | *-*-mingw* )
1800     configdir="win"
1801     ;;
1802 *)
1803     configdir="unix"
1804     ;;
1805 esac
1806
1807 GDBTKLIBS=
1808 if test "${enable_gdbtk}" = "yes"; then
1809
1810     # Gdbtk must have an absolute path to srcdir in order to run
1811     # properly when not installed.
1812     here=`pwd`
1813     cd ${srcdir}
1814     GDBTK_SRC_DIR=`pwd`
1815     cd $here
1816
1817     SC_PATH_TCLCONFIG
1818
1819     # If $no_tk is nonempty, then we can't do Tk, and there is no
1820     # point to doing Tcl.
1821     SC_PATH_TKCONFIG
1822
1823     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1824         SC_LOAD_TCLCONFIG
1825
1826         # Check for in-tree tcl
1827         here=`pwd`
1828         cd ${srcdir}/..
1829         topdir=`pwd`
1830         cd ${here}
1831
1832         intree="no"
1833         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1834           intree="yes"
1835         fi
1836
1837         # Find Tcl private headers
1838         if test x"${intree}" = xno; then
1839           CY_AC_TCL_PRIVATE_HEADERS
1840           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1841           TCL_LIBRARY="${TCL_LIB_SPEC}"
1842           TCL_DEPS=""
1843         else
1844           # If building tcl in the same src tree, private headers
1845           # are not needed, but we need to be sure to use the right
1846           # headers library
1847           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1848           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1849           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1850         fi
1851         AC_SUBST(TCL_INCLUDE)
1852         AC_SUBST(TCL_LIBRARY)
1853         AC_SUBST(TCL_DEPS)
1854
1855         SC_LOAD_TKCONFIG
1856
1857         # Check for in-tree Tk
1858         intree="no"
1859         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1860           intree="yes"
1861         fi
1862
1863         # Find Tk private headers
1864         if test x"${intree}" = xno; then
1865           CY_AC_TK_PRIVATE_HEADERS
1866           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1867           TK_LIBRARY=${TK_LIB_SPEC}
1868           TK_DEPS=""
1869         else
1870           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1871           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1872           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1873         fi
1874         AC_SUBST(TK_INCLUDE)
1875         AC_SUBST(TK_LIBRARY)
1876         AC_SUBST(TK_DEPS)
1877         AC_SUBST(TK_XINCLUDES)
1878
1879         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1880
1881         # Include some libraries that Tcl and Tk want.
1882         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1883         # Yes, the ordering seems wrong here.  But it isn't.
1884         # TK_LIBS is the list of libraries that need to be linked
1885         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1886         # were in LIBS then any link tests after this point would
1887         # try to include things like `$(LIBGUI)', which wouldn't work.
1888         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1889
1890         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1891         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1892         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1893         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1894         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1895         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1896         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1897
1898         if test x"$gdb_cv_os_cygwin" = xyes; then
1899           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1900           WIN32LDAPP="-Wl,--subsystem,console"
1901           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1902         fi
1903
1904         AC_CONFIG_SUBDIRS(gdbtk)
1905     fi
1906 fi
1907
1908 AC_SUBST(X_CFLAGS)
1909 AC_SUBST(X_LDFLAGS)
1910 AC_SUBST(X_LIBS)
1911 AC_SUBST(GDBTKLIBS)
1912 AC_SUBST(GDBTK_CFLAGS)
1913 AC_SUBST(GDBTK_SRC_DIR)
1914
1915 AC_PATH_X
1916
1917 # Unlike the sim directory, whether a simulator is linked is controlled by
1918 # presence of a gdb_sim definition in the target configure.tgt entry.
1919 # This code just checks for a few cases where we'd like to ignore those
1920 # definitions, even when they're present in the '.mt' file.  These cases
1921 # are when --disable-sim is specified, or if the simulator directory is
1922 # not part of the source tree.
1923 #
1924 AC_ARG_ENABLE(sim,
1925 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1926 [echo "enable_sim = $enable_sim";
1927  echo "enableval = ${enableval}";
1928  case "${enableval}" in
1929   yes) ignore_sim=false ;;
1930   no)  ignore_sim=true ;;
1931   *)   ignore_sim=false ;;
1932  esac],
1933 [ignore_sim=false])
1934
1935 if test ! -d "${srcdir}/../sim"; then
1936   ignore_sim=true
1937 fi
1938
1939 SIM=
1940 SIM_OBS=
1941 if test "${ignore_sim}" = "false"; then
1942   if test x"${gdb_sim}" != x ; then
1943     SIM="${gdb_sim}"
1944     SIM_OBS="remote-sim.o"
1945     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1946
1947     # Some tdep code should only be compiled in when the ppc sim is
1948     # built.  PR sim/13418.
1949     case $target in
1950       powerpc*-*-*)
1951         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
1952         ;;
1953     esac
1954   fi
1955 fi
1956 AC_SUBST(SIM)
1957 AC_SUBST(SIM_OBS)
1958
1959 AC_SUBST(ENABLE_CFLAGS)
1960 AC_SUBST(PROFILE_CFLAGS)
1961
1962 AC_SUBST(CONFIG_OBS)
1963 AC_SUBST(CONFIG_DEPS)
1964 AC_SUBST(CONFIG_SRCS)
1965 AC_SUBST(CONFIG_ALL)
1966 AC_SUBST(CONFIG_CLEAN)
1967 AC_SUBST(CONFIG_INSTALL)
1968 AC_SUBST(CONFIG_UNINSTALL)
1969
1970 # List of host floatformats.
1971 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1972 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1973 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1974
1975 # target_subdir is used by the testsuite to find the target libraries.
1976 target_subdir=
1977 if test "${host}" != "${target}"; then
1978     target_subdir="${target_alias}/"
1979 fi
1980 AC_SUBST(target_subdir)
1981
1982 # Import nat definitions.
1983 nat_makefile_frag=/dev/null
1984 if test "${gdb_native}" = "yes"; then
1985   . ${srcdir}/configure.nat
1986   nativefile=$NAT_FILE
1987 fi
1988
1989 AC_SUBST(NAT_FILE)
1990 AC_SUBST(NATDEPFILES)
1991 AC_SUBST(NAT_CDEPS)
1992 AC_SUBST(LOADLIBES)
1993 AC_SUBST(MH_CFLAGS)
1994 AC_SUBST(XM_CLIBS)
1995 AC_SUBST(NAT_GENERATED_FILES)
1996 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
1997 AC_SUBST_FILE(nat_makefile_frag)
1998
1999 if test x"${gdb_osabi}" != x ; then
2000     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2001                        [Define to the default OS ABI for this configuration.])
2002 fi
2003
2004 AC_ARG_ENABLE(gdbserver,
2005 AS_HELP_STRING([--enable-gdbserver],
2006                [automatically build gdbserver (yes/no/auto, default is auto)]),
2007 [case "${enableval}" in
2008   yes| no|auto) ;;
2009   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2010 esac],[enable_gdbserver=auto])
2011
2012 # We only build gdbserver automatically in a native configuration, and
2013 # only if the user did not explicitly disable its build.
2014 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2015   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2016   if test "x$build_gdbserver" = xyes; then
2017     AC_MSG_RESULT(yes)
2018     AC_CONFIG_SUBDIRS(gdbserver)
2019     gdbserver_build_enabled=yes
2020   else
2021     AC_MSG_RESULT(no)
2022   fi
2023 fi
2024
2025 # If the user explicitly request the gdbserver to be built, verify that
2026 # we were in fact able to enable it.
2027 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2028   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2029 fi
2030
2031 # Check for babeltrace and babeltrace-ctf
2032 AC_ARG_WITH(babeltrace,
2033   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2034   [], [with_babeltrace=auto])
2035 AC_MSG_CHECKING([whether to use babeltrace])
2036 AC_MSG_RESULT([$with_babeltrace])
2037
2038 if test "x$with_babeltrace" = "xno"; then
2039   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2040 else
2041   # Append -Werror to CFLAGS so that configure can catch the warning
2042   # "assignment from incompatible pointer type", which is related to
2043   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2044   # in GDB, while babeltrace 1.0.3 is broken.
2045   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2046   # safe to save and restore CFLAGS here.
2047   saved_CFLAGS=$CFLAGS
2048   CFLAGS="$CFLAGS -Werror"
2049   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2050                         [#include <babeltrace/babeltrace.h>
2051                          #include <babeltrace/ctf/events.h>
2052                          #include <babeltrace/ctf/iterator.h>],
2053                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2054                         struct bt_ctf_event *event = NULL;
2055                         const struct bt_definition *scope;
2056
2057                         pos->type = BT_SEEK_BEGIN;
2058                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2059                         scope = bt_ctf_get_top_level_scope (event,
2060                                                            BT_STREAM_EVENT_HEADER);
2061                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2062                         ])
2063   CFLAGS=$saved_CFLAGS
2064
2065   if test "$HAVE_LIBBABELTRACE" != yes; then
2066      if test "$with_babeltrace" = yes; then
2067        AC_MSG_ERROR([babeltrace is missing or unusable])
2068      else
2069        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2070      fi
2071   fi
2072 fi
2073
2074 # Check for xxhash
2075 AC_ARG_WITH(xxhash,
2076   AC_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2077   [], [with_xxhash=auto])
2078
2079 if test "x$with_xxhash" != "xno"; then
2080   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2081                         [#include <xxhash.h>],
2082                         [XXH32("foo", 3, 0);
2083                         ])
2084   if test "$HAVE_LIBXXHASH" != yes; then
2085     if test "$with_xxhash" = yes; then
2086       AC_MSG_ERROR([xxhash is missing or unusable])
2087     fi
2088   fi
2089   if test "x$with_xxhash" = "xauto"; then
2090     with_xxhash="$HAVE_LIBXXHASH"
2091   fi
2092 fi
2093
2094 AC_MSG_CHECKING([whether to use xxhash])
2095 AC_MSG_RESULT([$with_xxhash])
2096
2097 NM_H=
2098 rm -f nm.h
2099 if test "${nativefile}" != ""; then
2100     case "${nativefile}" in
2101       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2102       * ) GDB_NM_FILE="${nativefile}"
2103     esac
2104     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2105                     [GDB_NM_FILE=$GDB_NM_FILE])
2106     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2107     NM_H=nm.h
2108 fi
2109 AC_SUBST(GDB_NM_FILE)
2110 AC_SUBST(NM_H)
2111
2112 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2113 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2114 if test "x$USE_MAINTAINER_MODE" = xyes; then
2115   if test "${XSLTPROC}" = missing; then
2116     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2117   fi
2118 fi
2119 AC_SUBST(XSLTPROC)
2120
2121 dnl Check for exe extension set on certain hosts (e.g. Win32)
2122 AC_EXEEXT
2123
2124 dnl  Detect the character set used by this host.
2125 dnl  At the moment, we just assume it's UTF-8.
2126 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2127           [Define to be a string naming the default host character set.])
2128
2129 GDB_AC_SELFTEST([
2130   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) selftest-arch.o"
2131   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) selftest-arch.c"
2132 ])
2133
2134 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2135 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2136 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2137 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2138
2139 AC_OUTPUT