gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009, 2010
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # GDB does not use automake, but gnulib does.  This line lets us
  91 # generate its Makefile.in.
  92 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  93
  94 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  95     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  96     [${libdir}/debug])
  97
  98 # GDB's datadir relocation
  99
 100 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 101     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 102     [${datadir}/gdb])
 103
 104 AC_ARG_WITH(relocated-sources,
 105 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 106 [reloc_srcdir="${withval}"
 107  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 108               [Relocated directory for source files. ])
 109 ])
 110
 111 AC_CONFIG_SUBDIRS(doc testsuite)
 112
 113 # Check whether to support alternative target configurations
 114 AC_ARG_ENABLE(targets,
 115 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 116 [case "${enableval}" in
 117   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 118             ;;
 119   no)       enable_targets= ;;
 120   *)        enable_targets=$enableval ;;
 121 esac])
 122
 123 # Check whether to enable 64-bit support on 32-bit hosts
 124 AC_ARG_ENABLE(64-bit-bfd,
 125 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 126 [case "${enableval}" in
 127   yes)  want64=true  ;;
 128   no)   want64=false ;;
 129   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 130 esac],[want64=false])dnl
 131
 132 # Provide defaults for some variables set by the per-host and per-target
 133 # configuration.
 134 gdb_host_obs=posix-hdep.o
 135
 136 if test "${target}" = "${host}"; then
 137   gdb_native=yes
 138 else
 139   gdb_native=no
 140 fi
 141
 142 . $srcdir/configure.host
 143
 144 # Accumulate some settings from configure.tgt over all enabled targets
 145
 146 TARGET_OBS=
 147 all_targets=
 148
 149 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 150 do
 151   if test "$targ_alias" = "all"; then
 152     all_targets=true
 153   else
 154     # Canonicalize the secondary target names.
 155     result=`$ac_config_sub $targ_alias 2>/dev/null`
 156     if test -n "$result"; then
 157         targ=$result
 158     else
 159         targ=$targ_alias
 160     fi
 161
 162     . ${srcdir}/configure.tgt
 163
 164     AS_IF([test -z "${gdb_target_obs}"],
 165       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 166
 167     # Target-specific object files
 168     for i in ${gdb_target_obs}; do
 169         case " $TARGET_OBS " in
 170         *" ${i} "*) ;;
 171         *)
 172           TARGET_OBS="$TARGET_OBS ${i}"
 173           ;;
 174         esac
 175     done
 176
 177     # Check whether this target needs 64-bit CORE_ADDR
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181   fi
 182 done
 183
 184 if test x${all_targets} = xtrue; then
 185
 186   # We want all 64-bit targets if we either:
 187   #  - run on a 64-bit host  or
 188   #  - already require 64-bit support for some other target  or
 189   #  - the --enable-64-bit-bfd option was supplied
 190   # Otherwise we only support all 32-bit targets.
 191   #
 192   # NOTE: This test must be in sync with the corresponding
 193   #       tests in BFD!
 194
 195   if test x${want64} = xfalse; then
 196     AC_CHECK_SIZEOF(long)
 197     if test "x${ac_cv_sizeof_long}" = "x8"; then
 198       want64=true
 199     fi
 200   fi
 201   if test x${want64} = xtrue; then
 202     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 203   else
 204     TARGET_OBS='$(ALL_TARGET_OBS)'
 205   fi
 206 fi
 207
 208 AC_SUBST(TARGET_OBS)
 209
 210 # For other settings, only the main target counts.
 211 gdb_sim=
 212 gdb_osabi=
 213 build_gdbserver=
 214 targ=$target; . ${srcdir}/configure.tgt
 215
 216 # Fetch the default architecture and default target vector from BFD.
 217 targ=$target; . $srcdir/../bfd/config.bfd
 218
 219 # We only want the first architecture, so strip off the others if
 220 # there is more than one.
 221 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 222
 223 if test "x$targ_archs" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 225     [Define to BFD's default architecture. ])
 226 fi
 227 if test "x$targ_defvec" != x; then
 228   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 229     [Define to BFD's default target vector. ])
 230 fi
 231
 232 # The CLI cannot be disabled yet, but may be in the future.
 233
 234 # Enable CLI.
 235 AC_ARG_ENABLE(gdbcli,
 236 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 237   [case $enableval in
 238     yes)
 239       ;;
 240     no)
 241       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 242     *)
 243       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 244   esac],
 245   [enable_gdbcli=yes])
 246 if test x"$enable_gdbcli" = xyes; then
 247   if test -d $srcdir/cli; then
 248     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 249     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 250     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 251     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 252   fi
 253 fi
 254
 255 # Enable MI.
 256 AC_ARG_ENABLE(gdbmi,
 257 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 258   [case $enableval in
 259     yes | no)
 260       ;;
 261     *)
 262       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 263   esac],
 264   [enable_gdbmi=yes])
 265 if test x"$enable_gdbmi" = xyes; then
 266   if test -d $srcdir/mi; then
 267     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 268     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 269     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 270     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 271   fi
 272 fi
 273
 274 # Enable TUI.
 275 AC_ARG_ENABLE(tui,
 276 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 277   [case $enableval in
 278     yes | no | auto)
 279       ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 282   esac],enable_tui=auto)
 283
 284 # Enable gdbtk.
 285 AC_ARG_ENABLE(gdbtk,
 286 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 292   esac],
 293   [if test -d $srcdir/gdbtk; then
 294     enable_gdbtk=yes
 295   else
 296     enable_gdbtk=no
 297   fi])
 298 # We unconditionally disable gdbtk tests on selected platforms.
 299 case $host_os in
 300   go32* | windows*)
 301     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 302     enable_gdbtk=no ;;
 303 esac
 304
 305 # Libunwind support.
 306 AC_ARG_WITH(libunwind,
 307 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 308 [case "${withval}" in
 309   yes)  enable_libunwind=yes ;;
 310   no)   enable_libunwind=no ;;
 311   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 312 esac],[
 313   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 314   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 315     enable_libunwind=yes;
 316   fi
 317 ])
 318
 319 if test x"$enable_libunwind" = xyes; then
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 322   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 323   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 324   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 325 fi
 326
 327 opt_curses=no
 328 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 329
 330 prefer_curses=no
 331 if test "$opt_curses" = "yes"; then
 332   prefer_curses=yes
 333 fi
 334
 335 # Profiling support.
 336 AC_ARG_ENABLE(profiling,
 337 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 338   [case $enableval in
 339     yes | no)
 340       ;;
 341     *)
 342       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 343   esac],
 344  [enable_profiling=no])
 345
 346 AC_CHECK_FUNCS(monstartup _mcleanup)
 347 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 348 [AC_TRY_LINK(
 349 [#include <stdlib.h>
 350 extern char _etext;
 351 ],
 352 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 353 if test $ac_cv_var__etext = yes; then
 354   AC_DEFINE(HAVE__ETEXT, 1,
 355             [Define to 1 if your system has the _etext variable. ])
 356 fi
 357 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 358 [AC_TRY_LINK(
 359 [#include <stdlib.h>
 360 extern char etext;
 361 ],
 362 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 363 if test $ac_cv_var_etext = yes; then
 364   AC_DEFINE(HAVE_ETEXT, 1,
 365             [Define to 1 if your system has the etext variable. ])
 366 fi
 367 if test "$enable_profiling" = yes ; then
 368   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 369     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 370   fi
 371   PROFILE_CFLAGS=-pg
 372   OLD_CFLAGS="$CFLAGS"
 373   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 374
 375   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 376     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 377      ac_cv_cc_supports_pg=no)])
 378
 379   if test $ac_cv_cc_supports_pg = no; then
 380     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 381   fi
 382
 383   CFLAGS="$OLD_CFLAGS"
 384 fi
 385
 386 ACX_PKGVERSION([GDB])
 387 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 388 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 389 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 390
 391 # --------------------- #
 392 # Checks for programs.  #
 393 # --------------------- #
 394
 395 AC_PROG_AWK
 396 AC_PROG_INSTALL
 397 AC_PROG_LN_S
 398 AC_PROG_RANLIB
 399 AC_PROG_YACC
 400
 401 AC_CHECK_TOOL(AR, ar)
 402 AC_CHECK_TOOL(DLLTOOL, dlltool)
 403 AC_CHECK_TOOL(WINDRES, windres)
 404
 405 # Needed for GNU/Hurd.
 406 AC_CHECK_TOOL(MIG, mig)
 407
 408 # ---------------------- #
 409 # Checks for libraries.  #
 410 # ---------------------- #
 411
 412 # We might need to link with -lm; most simulators need it.
 413 AC_CHECK_LIB(m, main)
 414
 415 # We need to link with -lw to get `wctype' on Solaris before Solaris
 416 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 417 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 418 # is known to have this problem).  Therefore we avoid libw if we can.
 419 AC_CHECK_FUNC(wctype, [],
 420   [AC_CHECK_LIB(w, wctype)])
 421
 422 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 423 AC_SEARCH_LIBS(gethostbyname, nsl)
 424
 425 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 426 AC_SEARCH_LIBS(socketpair, socket)
 427
 428 # Link in zlib if we can.  This allows us to read compressed debug sections.
 429 AM_ZLIB
 430
 431 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 432 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 433
 434 AM_ICONV
 435
 436 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 437 # There is a very specific comment in /usr/include/curses.h explaining that
 438 # termcap routines built into libcurses must not be used.
 439 #
 440 # The symptoms we observed so far is GDB unexpectedly changing
 441 # the terminal settings when tgetent is called - this is particularly
 442 # visible as the output is missing carriage returns, and so rapidly
 443 # becomes very hard to read.
 444 #
 445 # The readline configure script has already decided that libtermcap
 446 # was enough for its purposes, and so decided to build readline using
 447 # libtermcap.  Since the TUI mode requires curses, building GDB with
 448 # TUI enabled results in both libraries to be used at the same time,
 449 # which is not allowed.  This basically means that GDB with TUI is
 450 # broken on alpha-osf.
 451
 452 case $host_os in
 453   osf* )
 454     if test x"$enable_tui" = xyes; then
 455       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 456     fi
 457     if test x"$enable_tui" = xauto; then
 458       enable_tui=no
 459     fi
 460     ;;
 461 esac
 462
 463 # For the TUI, we need enhanced curses functionality.
 464 if test x"$enable_tui" != xno; then
 465   prefer_curses=yes
 466 fi
 467
 468 curses_found=no
 469 if test x"$prefer_curses" = xyes; then
 470   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 471   # curses library because the latter might not provide all the
 472   # functionality we need.  However, this leads to problems on systems
 473   # where the linker searches /usr/local/lib, but the compiler doesn't
 474   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 475   # default installation of ncurses on alpha*-dec-osf* will lead to such
 476   # a situation.
 477   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 478
 479   if test "$ac_cv_search_waddstr" != no; then
 480     curses_found=yes
 481   fi
 482 fi
 483
 484 # Check whether we should enable the TUI, but only do so if we really
 485 # can.
 486 if test x"$enable_tui" != xno; then
 487   if test -d $srcdir/tui; then
 488     if test "$curses_found" != no; then
 489       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 490       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 491       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 492       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 493       CONFIG_ALL="${CONFIG_ALL} all-tui"
 494       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 495       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 496       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 497     else
 498       if test x"$enable_tui" = xyes; then
 499         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 500       else
 501         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 502       fi
 503     fi
 504   fi
 505 fi
 506
 507 # Since GDB uses Readline, we need termcap functionality.  In many
 508 # cases this will be provided by the curses library, but some systems
 509 # have a seperate termcap library, or no curses library at all.
 510
 511 case $host_os in
 512   cygwin*)
 513     if test -d $srcdir/libtermcap; then
 514       LIBS="../libtermcap/libtermcap.a $LIBS"
 515       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 516     fi ;;
 517   go32* | *djgpp*)
 518     ac_cv_search_tgetent="none required"
 519     ;;
 520   *mingw32*)
 521     ac_cv_search_tgetent="none required"
 522     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 523     ;;
 524 esac
 525
 526 # These are the libraries checked by Readline.
 527 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 528
 529 if test "$ac_cv_search_tgetent" = no; then
 530   AC_MSG_ERROR([no termcap library found])
 531 fi
 532
 533 AC_ARG_WITH([system-readline],
 534   [AS_HELP_STRING([--with-system-readline],
 535                   [use installed readline library])])
 536
 537 if test "$with_system_readline" = yes; then
 538   READLINE=-lreadline
 539   READLINE_DEPS=
 540   READLINE_CFLAGS=
 541
 542   # readline-6.0 started to use the name `_rl_echoing_p'.
 543   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 544
 545   AC_MSG_CHECKING([for readline_echoing_p])
 546   save_LIBS=$LIBS
 547   LIBS="$LIBS $READLINE"
 548   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 549                                     return readline_echoing_p;]]),
 550                  [READLINE_ECHOING_P=yes],
 551                  [READLINE_ECHOING_P=no
 552                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 553                             [readline-6.0 started to use different name.])])
 554   LIBS="$save_LIBS"
 555   AC_MSG_RESULT([$READLINE_ECHOING_P])
 556 else
 557   READLINE='$(READLINE_DIR)/libreadline.a'
 558   READLINE_DEPS='$(READLINE)'
 559   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 560 fi
 561 AC_SUBST(READLINE)
 562 AC_SUBST(READLINE_DEPS)
 563 AC_SUBST(READLINE_CFLAGS)
 564
 565 AC_ARG_WITH(expat,
 566   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 567   [], [with_expat=auto])
 568 AC_MSG_CHECKING([whether to use expat])
 569 AC_MSG_RESULT([$with_expat])
 570
 571 if test "${with_expat}" = no; then
 572   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 573   HAVE_LIBEXPAT=no
 574 else
 575   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 576                         [XML_Parser p = XML_ParserCreate (0);])
 577   if test "$HAVE_LIBEXPAT" != yes; then
 578     if test "$with_expat" = yes; then
 579       AC_MSG_ERROR([expat is missing or unusable])
 580     else
 581       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 582     fi
 583   else
 584     save_LIBS=$LIBS
 585     LIBS="$LIBS $LIBEXPAT"
 586     AC_CHECK_FUNCS(XML_StopParser)
 587     LIBS=$save_LIBS
 588   fi
 589 fi
 590
 591 dnl Utility to simplify finding libpython.
 592 dnl $1 = pythonX.Y
 593 dnl $2 = the shell variable to assign the result to
 594 dnl      If libpython is found we store $version here.
 595 dnl $3 = additional flags to add to CPPFLAGS
 596 dnl $4 = additional flags to add to LIBS
 597
 598 AC_DEFUN([AC_TRY_LIBPYTHON],
 599 [
 600   version=$1
 601   define([have_libpython_var],$2)
 602   new_CPPFLAGS=$3
 603   new_LIBS=$4
 604   AC_MSG_CHECKING([for ${version}])
 605   save_CPPFLAGS=$CPPFLAGS
 606   save_LIBS=$LIBS
 607   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 608   LIBS="$LIBS $new_LIBS"
 609   found_usable_python=no
 610   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 611                                  [[Py_Initialize ();]]),
 612                  [have_libpython_var=${version}
 613                   found_usable_python=yes],
 614                  [CPPFLAGS=$save_CPPFLAGS
 615                   LIBS=$save_LIBS])
 616   AC_MSG_RESULT([${found_usable_python}])
 617 ])
 618
 619 dnl There are several different values for --with-python:
 620 dnl
 621 dnl no -   Don't include python support.
 622 dnl yes -  Include python support, error if it's missing.
 623 dnl        If we find python in $PATH, use it to fetch configure options,
 624 dnl        otherwise assume the compiler can find it with no help from us.
 625 dnl        Python 2.6, 2.5, and then 2.4 are tried in turn.
 626 dnl auto - Same as "yes", but if python is missing from the system,
 627 dnl        fall back to "no".
 628 dnl /path/to/python/exec-prefix -
 629 dnl        Use the python located in this directory.
 630 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 631 dnl        the compilation parameters.  Otherwise use
 632 dnl        -I/path/to/python/exec-prefix/include,
 633 dnl        -L/path/to/python/exec-prefix/lib.
 634 dnl        Python 2.6, 2.5, and then 2.4 are tried in turn.
 635 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 636 dnl        but is deprecated.
 637 dnl /path/to/python/executable -
 638 dnl        Run python-config.py with this version of python to fetch the
 639 dnl        compilation parameters.
 640 dnl        NOTE: This needn't be the real python executable.
 641 dnl        In a cross-compilation scenario (build != host), this could be
 642 dnl        a shell script that provides what python-config.py provides for
 643 dnl        --ldflags, --includes, --exec-prefix.
 644 dnl python-executable -
 645 dnl        Find python-executable in $PATH, and then handle the same as
 646 dnl        /path/to/python/executable.
 647 dnl
 648 dnl If a python program is specified, it is used to run python-config.py and
 649 dnl is passed --ldflags, --includes, --exec-prefix.
 650
 651 AC_ARG_WITH(python,
 652   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 653   [], [with_python=auto])
 654 AC_MSG_CHECKING([whether to use python])
 655 AC_MSG_RESULT([$with_python])
 656
 657 if test "${with_python}" = no; then
 658   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 659   have_libpython=no
 660 else
 661   case "${with_python}" in
 662   /*)
 663     if test -d ${with_python}; then
 664       # Assume the python binary is ${with_python}/bin/python.
 665       python_prog="${with_python}/bin/python"
 666       python_prefix=
 667       if test ! -x ${python_prog}; then
 668         # Fall back to gdb 7.0/7.1 behaviour.
 669         python_prog=missing
 670         python_prefix=${with_python}
 671       fi
 672     elif test -x ${with_python}; then
 673       # While we can't run python compiled for $host (unless host == build),
 674       # the user could write a script that provides the needed information,
 675       # so we support that.
 676       python_prog=${with_python}
 677       python_prefix=
 678     else
 679       AC_ERROR(invalid value for --with-python)
 680     fi
 681     ;;
 682   */*)
 683     # Disallow --with-python=foo/bar.
 684     AC_ERROR(invalid value for --with-python)
 685     ;;
 686   *)
 687     # The user has either specified auto, yes, or the name of the python
 688     # program assumed to be in $PATH.
 689     python_prefix=
 690     case "${with_python}" in
 691     yes | auto)
 692       if test ${build} = ${host}; then
 693         AC_PATH_PROG(python_prog_path, python, missing)
 694         if test "${python_prog_path}" = missing; then
 695           python_prog=missing
 696         else
 697           python_prog=${python_prog_path}
 698         fi
 699       else
 700         # Not much we can do except assume the cross-compiler will find the
 701         # right files.
 702         python_prog=missing
 703       fi
 704       ;;
 705     *)
 706       # While we can't run python compiled for $host (unless host == build),
 707       # the user could write a script that provides the needed information,
 708       # so we support that.
 709       python_prog="${with_python}"
 710       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 711       if test "${python_prog_path}" = missing; then
 712         AC_ERROR(unable to find python program ${python_prog})
 713       fi
 714       ;;
 715     esac
 716   esac
 717
 718   if test "${python_prog}" != missing; then
 719     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 720     if test $? != 0; then
 721       AC_ERROR(failure running python-config --includes)
 722     fi
 723     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 724     if test $? != 0; then
 725       AC_ERROR(failure running python-config --ldflags)
 726     fi
 727     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 728     if test $? != 0; then
 729       AC_ERROR(failure running python-config --exec-prefix)
 730     fi
 731     have_python_config=yes
 732   else
 733     # Fall back to gdb 7.0/7.1 behaviour.
 734     if test -z ${python_prefix}; then
 735       python_includes=
 736       python_libs=
 737     else
 738       python_includes="-I${python_prefix}/include"
 739       python_libs="-L${python_prefix}/lib"
 740     fi
 741     have_python_config=no
 742   fi
 743
 744   # Having "/pythonX.Y" in the include path is awkward.
 745   # All those python headers get bubbled up to the top inviting lots
 746   # of random collisions.  GDB originally didn't use python-config to
 747   # find the compilation parameters and includes "pythonX.Y/" in the
 748   # path of the, umm, include file.  So strip away this part of the
 749   # output of python-config --includes.
 750   python_includes=`echo "${python_includes} " \
 751                         | sed -e 's,/python[[0-9]]*[[.]][[0-9]]* , ,g'`
 752
 753   # If we have python-config, only try the configuration it provides.
 754   # Otherwise fallback on the old way of trying different versions of
 755   # python in turn.
 756
 757   have_libpython=no
 758   if test "${have_python_config}" = yes; then
 759     python_version=`echo " ${python_libs} " \
 760                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]][[0-9]]*\) .*$,\1,'`
 761     case "${python_version}" in
 762     python*)
 763       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 764                        ${python_includes}, ${python_libs})
 765       ;;
 766     *)
 767       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 768       ;;
 769     esac
 770   else
 771     if test "${have_libpython}" = no; then
 772       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 773                        ${python_includes}, "${python_libs} -lpython2.6")
 774     fi
 775     if test ${have_libpython} = no; then
 776       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 777                        ${python_includes}, "${python_libs} -lpython2.5")
 778     fi
 779     if test ${have_libpython} = no; then
 780       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 781                        ${python_includes}, "${python_libs} -lpython2.4")
 782     fi
 783   fi
 784   if test "${have_libpython}" = python2.6; then
 785     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 786   elif test "${have_libpython}" = python2.5; then
 787     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 788   elif test "${have_libpython}" = python2.4; then
 789     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 790   fi
 791
 792   if test "${have_libpython}" = no; then
 793     case "${with_python}" in
 794     yes)
 795       AC_MSG_ERROR([python is missing or unusable])
 796       ;;
 797     auto)
 798       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 799       ;;
 800     *)
 801       AC_MSG_ERROR([no usable python found at ${with_python}])
 802       ;;
 803     esac
 804   else
 805     if test -n "${python_prefix}"; then
 806       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 807                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 808       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 809     fi
 810   fi
 811 fi
 812
 813 if test "${have_libpython}" != no; then
 814   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 815   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 816   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 817   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 818   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 819
 820   # Flags needed to compile Python code (taken from python-config --cflags).
 821   # We cannot call python-config directly because it will output whatever was
 822   # used when compiling the Python interpreter itself, including flags which
 823   # would make the python-related objects be compiled differently from the
 824   # rest of GDB (e.g., -O2 and -fPIC).
 825   if test "${GCC}" = yes; then
 826     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 827   fi
 828
 829   if test "x${tentative_python_cflags}" != x; then
 830     AC_MSG_CHECKING(compiler flags for python code)
 831     for flag in ${tentative_python_cflags}; do
 832       # Check that the compiler accepts it
 833       saved_CFLAGS="$CFLAGS"
 834       CFLAGS="$CFLAGS $flag"
 835       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 836       CFLAGS="$saved_CFLAGS"
 837     done
 838     AC_MSG_RESULT(${PYTHON_CFLAGS})
 839   fi
 840 else
 841   # Even if Python support is not compiled in, we need to have these files
 842   # included.
 843   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 844   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 845         python/py-prettyprint.c python/py-auto-load.c"
 846 fi
 847 AC_SUBST(PYTHON_CFLAGS)
 848
 849 # ------------------------- #
 850 # Checks for header files.  #
 851 # ------------------------- #
 852
 853 AC_HEADER_DIRENT
 854 AC_HEADER_STAT
 855 AC_HEADER_STDC
 856 # elf_hp.h is for HP/UX 64-bit shared library support.
 857 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 858 # unconditionally, so what's the point in checking these?
 859 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 860                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 861                   stdlib.h string.h memory.h strings.h sys/fault.h \
 862                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 863                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 864                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 865                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 866                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 867 AC_CHECK_HEADERS(link.h, [], [],
 868 [#if HAVE_SYS_TYPES_H
 869 # include <sys/types.h>
 870 #endif
 871 #if HAVE_NLIST_H
 872 # include <nlist.h>
 873 #endif
 874 ])
 875 AC_CHECK_HEADERS(sys/proc.h, [], [],
 876 [#if HAVE_SYS_PARAM_H
 877 # include <sys/param.h>
 878 #endif
 879 ])
 880 AC_CHECK_HEADERS(sys/user.h, [], [],
 881 [#if HAVE_SYS_PARAM_H
 882 # include <sys/param.h>
 883 #endif
 884 ])
 885
 886 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 887 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 888 # think that we don't have <curses.h> if we're using GCC.
 889 case $host_os in
 890   solaris2.[[789]])
 891     if test "$GCC" = yes; then
 892       AC_DEFINE(_MSE_INT_H, 1,
 893         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 894    Solaris 2.[789] when using GCC. ])
 895     fi ;;
 896 esac
 897 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 898 AC_CHECK_HEADERS(term.h, [], [],
 899 [#if HAVE_CURSES_H
 900 # include <curses.h>
 901 #endif
 902 ])
 903
 904 # ------------------------- #
 905 # Checks for declarations.  #
 906 # ------------------------- #
 907
 908 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 909                 snprintf, vsnprintf])
 910 AM_LC_MESSAGES
 911
 912 # ----------------------- #
 913 # Checks for structures.  #
 914 # ----------------------- #
 915
 916 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 917
 918 # ------------------ #
 919 # Checks for types.  #
 920 # ------------------ #
 921
 922 AC_TYPE_SIGNAL
 923 AC_CHECK_TYPES(socklen_t, [], [],
 924 [#include <sys/types.h>
 925 #include <sys/socket.h>
 926 ])
 927
 928 # ------------------------------------- #
 929 # Checks for compiler characteristics.  #
 930 # ------------------------------------- #
 931
 932 AC_C_CONST
 933 AC_C_INLINE
 934 AC_C_BIGENDIAN
 935
 936 # ------------------------------ #
 937 # Checks for library functions.  #
 938 # ------------------------------ #
 939
 940 AC_FUNC_ALLOCA
 941 AC_FUNC_MMAP
 942 AC_FUNC_VFORK
 943 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 944                 getgid pipe poll pread64 sbrk setpgid setpgrp setsid \
 945                 sigaction sigprocmask sigsetmask socketpair syscall \
 946                 ttrace wborder setlocale iconvlist libiconvlist btowc \
 947                 setrlimit getrlimit posix_madvise])
 948 AM_LANGINFO_CODESET
 949
 950 # Check the return and argument types of ptrace.  No canned test for
 951 # this, so roll our own.
 952 gdb_ptrace_headers='
 953 #if HAVE_SYS_TYPES_H
 954 # include <sys/types.h>
 955 #endif
 956 #if HAVE_SYS_PTRACE_H
 957 # include <sys/ptrace.h>
 958 #endif
 959 #if HAVE_UNISTD_H
 960 # include <unistd.h>
 961 #endif
 962 '
 963 # There is no point in checking if we don't have a prototype.
 964 AC_CHECK_DECLS(ptrace, [], [
 965   : ${gdb_cv_func_ptrace_ret='int'}
 966   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 967 ], $gdb_ptrace_headers)
 968 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 969 # empty argument list, so check for that explicitly.
 970 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 971   AC_TRY_COMPILE($gdb_ptrace_headers,
 972     [extern long ptrace (enum __ptrace_request, ...);],
 973     gdb_cv_func_ptrace_ret='long',
 974     AC_TRY_COMPILE($gdb_ptrace_headers,
 975       [extern int ptrace ();],
 976       gdb_cv_func_ptrace_ret='int',
 977       gdb_cv_func_ptrace_ret='long')))
 978 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 979   [Define as the return type of ptrace.])
 980 # Check argument types.
 981 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 982   AC_TRY_COMPILE($gdb_ptrace_headers,
 983     [extern long ptrace (enum __ptrace_request, ...);],
 984     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 985 for gdb_arg1 in 'int' 'long'; do
 986  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 987   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 988    for gdb_arg4 in 'int' 'long'; do
 989      AC_TRY_COMPILE($gdb_ptrace_headers, [
 990 extern $gdb_cv_func_ptrace_ret
 991   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 992 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 993     break 4;])
 994     for gdb_arg5 in 'int *' 'int' 'long'; do
 995      AC_TRY_COMPILE($gdb_ptrace_headers, [
 996 extern $gdb_cv_func_ptrace_ret
 997   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 998 ], [
 999 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1000     break 5;])
1001     done
1002    done
1003   done
1004  done
1005 done
1006 # Provide a safe default value.
1007 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1008 ])])
1009 ac_save_IFS=$IFS; IFS=','
1010 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1011 IFS=$ac_save_IFS
1012 shift
1013 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1014   [Define to the type of arg 3 for ptrace.])
1015 if test -n "$[5]"; then
1016   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1017     [Define to the type of arg 5 for ptrace.])
1018 fi
1019
1020 dnl AC_FUNC_SETPGRP does not work when cross compiling
1021 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1022 if test "$cross_compiling" = no; then
1023   AC_FUNC_SETPGRP
1024 else
1025   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1026     [AC_TRY_COMPILE([
1027 #include <unistd.h>
1028 ], [
1029   if (setpgrp(1,1) == -1)
1030     exit (0);
1031   else
1032     exit (1);
1033 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1034 if test $ac_cv_func_setpgrp_void = yes; then
1035   AC_DEFINE(SETPGRP_VOID, 1)
1036 fi
1037 fi
1038
1039 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1040 # since sigsetjmp might only be defined as a macro.
1041 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1042 [AC_TRY_COMPILE([
1043 #include <setjmp.h>
1044 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1045 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1046 if test $gdb_cv_func_sigsetjmp = yes; then
1047   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1048 fi
1049
1050 # Assume we'll default to using the included libiberty regex.
1051 gdb_use_included_regex=yes
1052
1053 # However, if the system regex is GNU regex, then default to *not*
1054 # using the included regex.
1055 AC_CACHE_CHECK(
1056   [for GNU regex],
1057   [gdb_cv_have_gnu_regex],
1058   [AC_TRY_COMPILE(
1059     [#include <gnu-versions.h>],
1060     [#define REGEX_INTERFACE_VERSION 1
1061 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1062 # error "Version mismatch"
1063 #endif],
1064     gdb_cv_have_gnu_regex=yes,
1065     gdb_cv_have_gnu_regex=no)])
1066 if test $gdb_cv_have_gnu_regex = yes; then
1067   gdb_use_included_regex=no
1068 fi
1069
1070 AC_ARG_WITH(included-regex,
1071   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1072   gdb_with_regex=$withval,
1073   gdb_with_regex=$gdb_use_included_regex)
1074 if test "$gdb_with_regex" = yes; then
1075   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1076     [Define to 1 if the regex included in libiberty should be used.])
1077 fi
1078
1079 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1080 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1081 [#include <sys/param.h>
1082 #include <sys/proc.h>
1083 ])
1084
1085 # See if <sys/lwp.h> defines `struct lwp`.
1086 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1087 [AC_TRY_COMPILE([#include <sys/param.h>
1088 #include <sys/lwp.h>], [struct lwp l;],
1089 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1090 if test $gdb_cv_struct_lwp = yes; then
1091   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1092             [Define to 1 if your system has struct lwp.])
1093 fi
1094
1095 # See if <machine/reg.h> degines `struct reg'.
1096 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1097 [AC_TRY_COMPILE([#include <sys/types.h>
1098 #include <machine/reg.h>], [struct reg r;],
1099 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1100 if test $gdb_cv_struct_reg = yes; then
1101   AC_DEFINE(HAVE_STRUCT_REG, 1,
1102             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1103 fi
1104
1105 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1106 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1107 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1108                  [#include <machine/reg.h>])
1109
1110 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1111 AC_MSG_CHECKING(for PTRACE_GETREGS)
1112 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1113 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1114                 [PTRACE_GETREGS;],
1115                 [gdb_cv_have_ptrace_getregs=yes],
1116                 [gdb_cv_have_ptrace_getregs=no])])
1117 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1118 if test $gdb_cv_have_ptrace_getregs = yes; then
1119   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1120   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1121 fi
1122
1123 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1124 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1125 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1126 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1127                 [PTRACE_GETFPXREGS;],
1128                 [gdb_cv_have_ptrace_getfpxregs=yes],
1129                 [gdb_cv_have_ptrace_getfpxregs=no])])
1130 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1131 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1132   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1133   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1134 fi
1135
1136 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1137 AC_MSG_CHECKING(for PT_GETDBREGS)
1138 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1139 [AC_TRY_COMPILE([#include <sys/types.h>
1140 #include <sys/ptrace.h>],
1141                 [PT_GETDBREGS;],
1142                 [gdb_cv_have_pt_getdbregs=yes],
1143                 [gdb_cv_have_pt_getdbregs=no])])
1144 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1145 if test $gdb_cv_have_pt_getdbregs = yes; then
1146   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1147   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1148 fi
1149
1150 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1151 AC_MSG_CHECKING(for PT_GETXMMREGS)
1152 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1153 [AC_TRY_COMPILE([#include <sys/types.h>
1154 #include <sys/ptrace.h>],
1155                 [PT_GETXMMREGS;],
1156                 [gdb_cv_have_pt_getxmmregs=yes],
1157                 [gdb_cv_have_pt_getxmmregs=no])])
1158 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1159 if test $gdb_cv_have_pt_getxmmregs = yes; then
1160   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1161   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1162 fi
1163
1164 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1165
1166 if test "${target}" = "${host}"; then
1167   case "${host}" in
1168   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1169       AC_DEFINE(NEW_PROC_API, 1,
1170       [Define if you want to use new multi-fd /proc interface
1171        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1172       ;;
1173   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1174       AC_DEFINE(NEW_PROC_API, 1,
1175       [Define if you want to use new multi-fd /proc interface
1176        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1177       ;;
1178   mips-sgi-irix5*)
1179       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1180       AC_DEFINE([_KMEMUSER], 1,
1181       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1182        around a <sys/proc.h> problem on IRIX 5.])
1183       ;;
1184   esac
1185 fi
1186
1187 if test "$ac_cv_header_sys_procfs_h" = yes; then
1188   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1189   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1190   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1191   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1192   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1193   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1194   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1195   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1196   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1197   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1198   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1199   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1200   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1201   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1202
1203
1204   dnl Check for broken prfpregset_t type
1205
1206   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1207   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1208   dnl instead of the struct itself).  We detect this here, and work
1209   dnl around it in gdb_proc_service.h.
1210
1211   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1212     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1213     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1214       [AC_TRY_RUN([#include <sys/procfs.h>
1215        int main ()
1216        {
1217          if (sizeof (prfpregset_t) == sizeof (void *))
1218            return 1;
1219          return 0;
1220        }],
1221        gdb_cv_prfpregset_t_broken=no,
1222        gdb_cv_prfpregset_t_broken=yes,
1223        gdb_cv_prfpregset_t_broken=yes)])
1224     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1225     if test $gdb_cv_prfpregset_t_broken = yes; then
1226       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1227       [Define if the prfpregset_t type is broken.])
1228     fi
1229   fi
1230
1231   dnl Check for PIOCSET ioctl entry
1232
1233   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1234   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1235   [AC_TRY_COMPILE([#include <unistd.h>
1236 #include <sys/types.h>
1237 #include <sys/procfs.h>
1238 ], [
1239     int dummy;;
1240     dummy = ioctl(0, PIOCSET, &dummy);
1241   ],
1242   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1243   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1244   if test $gdb_cv_have_procfs_piocset = yes; then
1245     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1246     [Define if ioctl argument PIOCSET is available.])
1247   fi
1248 fi
1249
1250 dnl For native ports (host == target), check to see what kind of
1251 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1252 if test ${host} = ${target} ; then
1253   dnl Check for struct link_map with l_ members which are indicative
1254   dnl of SVR4-like shared libraries
1255
1256   AC_MSG_CHECKING(for member l_addr in struct link_map)
1257   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1258     [AC_TRY_COMPILE([#include <link.h>],
1259                     [struct link_map lm; (void) lm.l_addr;],
1260                     gdb_cv_have_struct_link_map_with_l_members=yes,
1261                     gdb_cv_have_struct_link_map_with_l_members=no)])
1262   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1263   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1264     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1265     [Define if <link.h> exists and defines struct link_map which has
1266      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1267      SVR4-like systems.)])
1268   fi
1269
1270   dnl Check for struct link_map with lm_ members which are indicative
1271   dnl of SunOS-like shared libraries
1272
1273   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1274   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1275     [AC_TRY_COMPILE([#include <sys/types.h>
1276 #include <link.h>],
1277                     [struct link_map lm; (void) lm.lm_addr;],
1278                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1279                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1280   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1281   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1282     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1283     [Define if <link.h> exists and defines struct link_map which has
1284      members with an ``lm_'' prefix.  (For SunOS.)])
1285   fi
1286
1287   dnl Check for struct so_map with som_ members which are found on
1288   dnl some *BSD systems.
1289
1290   AC_MSG_CHECKING(for member som_addr in struct so_map)
1291   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1292     [AC_TRY_COMPILE([#include <sys/types.h>
1293 #ifdef HAVE_NLIST_H
1294 #include <nlist.h>
1295 #endif
1296 #include <link.h>],
1297                     [struct so_map lm; (void) lm.som_addr;],
1298                     gdb_cv_have_struct_so_map_with_som_members=yes,
1299                     gdb_cv_have_struct_so_map_with_som_members=no)])
1300   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1301   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1302     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1303     [Define if <link.h> exists and defines a struct so_map which has
1304      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1305   fi
1306
1307   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1308   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1309
1310   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1311   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1312     [AC_TRY_COMPILE([#define _SYSCALL32
1313 #include <sys/link.h>], [struct link_map32 l;],
1314      gdb_cv_have_struct_link_map32=yes,
1315      gdb_cv_have_struct_link_map32=no)])
1316   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1317   if test $gdb_cv_have_struct_link_map32 = yes; then
1318     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1319     [Define if <sys/link.h> has struct link_map32])
1320     AC_DEFINE(_SYSCALL32, 1,
1321     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1322   fi
1323 fi
1324
1325 # Check if the compiler supports the `long long' type.
1326
1327 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1328                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1329 [[extern long long foo;]],
1330 [[switch (foo & 2) { case 0: return 1; }]])],
1331                                   gdb_cv_c_long_long=yes,
1332                                   gdb_cv_c_long_long=no)])
1333 if test $gdb_cv_c_long_long = yes; then
1334   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1335             [Define to 1 if the compiler supports long long.])
1336 fi
1337
1338 # Check if the compiler and runtime support printing long longs.
1339
1340 AC_CACHE_CHECK([for long long support in printf],
1341                gdb_cv_printf_has_long_long,
1342                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1343 [[char buf[32];
1344   long long l = 0;
1345   l = (l << 16) + 0x0123;
1346   l = (l << 16) + 0x4567;
1347   l = (l << 16) + 0x89ab;
1348   l = (l << 16) + 0xcdef;
1349   sprintf (buf, "0x%016llx", l);
1350   return (strcmp ("0x0123456789abcdef", buf));]])],
1351                               gdb_cv_printf_has_long_long=yes,
1352                               gdb_cv_printf_has_long_long=no,
1353                               gdb_cv_printf_has_long_long=no)])
1354 if test $gdb_cv_printf_has_long_long = yes; then
1355   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1356             [Define to 1 if the "%ll" format works to print long longs.])
1357 fi
1358
1359 # Check if the compiler and runtime support printing decfloats.
1360
1361 AC_CACHE_CHECK([for decfloat support in printf],
1362                gdb_cv_printf_has_decfloat,
1363                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1364 [[char buf[64];
1365   _Decimal32 d32 = 1.2345df;
1366   _Decimal64 d64 = 1.2345dd;
1367   _Decimal128 d128 = 1.2345dl;
1368   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1369   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1370                               gdb_cv_printf_has_decfloat=yes,
1371                               gdb_cv_printf_has_decfloat=no,
1372                               gdb_cv_printf_has_decfloat=no)])
1373 if test $gdb_cv_printf_has_decfloat = yes; then
1374   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1375             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1376 fi
1377
1378 # Check if the compiler supports the `long double' type.  We can't use
1379 # AC_C_LONG_DOUBLE because that one does additional checks on the
1380 # constants defined in <float.h> that fail on some systems,
1381 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1382
1383 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1384                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1385                                   gdb_cv_c_long_double=yes,
1386                                   gdb_cv_c_long_double=no)])
1387 if test $gdb_cv_c_long_double = yes; then
1388   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1389            [Define to 1 if the compiler supports long double.])
1390 fi
1391
1392 # Check if the compiler and runtime support printing long doubles.
1393
1394 AC_CACHE_CHECK([for long double support in printf],
1395                gdb_cv_printf_has_long_double,
1396                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1397 [[char buf[16];
1398   long double f = 3.141592653;
1399   sprintf (buf, "%Lg", f);
1400   return (strncmp ("3.14159", buf, 7));]])],
1401                               gdb_cv_printf_has_long_double=yes,
1402                               gdb_cv_printf_has_long_double=no,
1403                               gdb_cv_printf_has_long_double=no)])
1404 if test $gdb_cv_printf_has_long_double = yes; then
1405   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1406             [Define to 1 if the "%Lg" format works to print long doubles.])
1407 fi
1408
1409 # Check if the compiler and runtime support scanning long doubles.
1410
1411 AC_CACHE_CHECK([for long double support in scanf],
1412                gdb_cv_scanf_has_long_double,
1413                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1414 [[#include <stdio.h>]],
1415 [[char *buf = "3.141592653";
1416   long double f = 0;
1417   sscanf (buf, "%Lg", &f);
1418   return !(f > 3.14159 && f < 3.14160);]])],
1419                               gdb_cv_scanf_has_long_double=yes,
1420                               gdb_cv_scanf_has_long_double=no,
1421                               gdb_cv_scanf_has_long_double=no)])
1422 if test $gdb_cv_scanf_has_long_double = yes; then
1423   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1424             [Define to 1 if the "%Lg" format works to scan long doubles.])
1425 fi
1426
1427 case ${host_os} in
1428 aix*)
1429   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1430     SAVE_LDFLAGS=$LDFLAGS
1431
1432     case $GCC in
1433     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1434     *) gdb_cv_bigtoc=-bbigtoc ;;
1435     esac
1436
1437     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1438     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1439     LDFLAGS="${SAVE_LDFLAGS}"
1440   ])
1441   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1442   ;;
1443 esac
1444
1445
1446 dnl For certain native configurations, we need to check whether thread
1447 dnl support can be built in or not.
1448 dnl
1449 dnl Note that we only want this if we are both native (host == target),
1450 dnl and not doing a canadian cross build (build == host).
1451
1452 if test ${build} = ${host} -a ${host} = ${target} ; then
1453    if test "$GCC" = "yes" ; then
1454       # The dynamically loaded libthread_db needs access to symbols in the gdb
1455       # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1456       # may not be supported there.
1457       AC_MSG_CHECKING(for the dynamic export flag)
1458       old_LDFLAGS="$LDFLAGS"
1459       # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1460       RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1461       LDFLAGS="$LDFLAGS $RDYNAMIC"
1462       AC_TRY_LINK([], [],
1463                   [found="-Wl,--dynamic-list"
1464                    RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
1465                   [RDYNAMIC="-rdynamic"
1466                    LDFLAGS="$old_LDFLAGS $RDYNAMIC"
1467                    AC_TRY_LINK([], [],
1468                                [found="-rdynamic"],
1469                                [found="no"
1470                                 # Error on its usage by .mh file.
1471                                 RDYNAMIC="no-rdynamic-available"])])
1472       AC_SUBST(RDYNAMIC)
1473       LDFLAGS="$old_LDFLAGS"
1474       AC_MSG_RESULT($found)
1475    fi
1476
1477    case ${host_os} in
1478    hpux*)
1479       AC_MSG_CHECKING(for HPUX/OSF thread support)
1480       if test -f /usr/include/dce/cma_config.h ; then
1481          if test "$GCC" = "yes" ; then
1482             AC_MSG_RESULT(yes)
1483             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1484             [Define if you have HPUX threads])
1485             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1486             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1487          else
1488             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1489          fi
1490       else
1491          AC_MSG_RESULT(no)
1492       fi
1493       ;;
1494    solaris*)
1495       # See if thread_db library is around for Solaris thread debugging.
1496       # Note that we must explicitly test for version 1 of the library
1497       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1498       # the same API.
1499       AC_MSG_CHECKING(for Solaris thread debugging library)
1500       if test -f /usr/lib/libthread_db.so.1 ; then
1501          AC_MSG_RESULT(yes)
1502          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1503          [Define if using Solaris thread debugging.])
1504          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1505          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1506          AC_CHECK_LIB(dl, dlopen)
1507          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1508          # Sun randomly tweaked the prototypes in <proc_service.h>
1509          # at one point.
1510          AC_MSG_CHECKING(if <proc_service.h> is old)
1511          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1512             AC_TRY_COMPILE([
1513                 #include <proc_service.h>
1514                 ps_err_e ps_pdwrite
1515                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1516             ],, gdb_cv_proc_service_is_old=no,
1517                 gdb_cv_proc_service_is_old=yes)
1518          ])
1519          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1520          if test $gdb_cv_proc_service_is_old = yes; then
1521             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1522             [Define if <proc_service.h> on solaris uses int instead of
1523              size_t, and assorted other type changes.])
1524          fi
1525       else
1526          AC_MSG_RESULT(no)
1527       fi
1528       ;;
1529    aix*)
1530       AC_MSG_CHECKING(for AiX thread debugging library)
1531       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1532                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1533                                    [#ifndef PTHDB_VERSION_3
1534                                     #error
1535                                     #endif],
1536                                    gdb_cv_have_aix_thread_debug=yes,
1537                                    gdb_cv_have_aix_thread_debug=no)])
1538       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1539       if test $gdb_cv_have_aix_thread_debug = yes; then
1540          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1541          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1542          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1543       fi
1544       ;;
1545    esac
1546    AC_SUBST(CONFIG_LDFLAGS)
1547 fi
1548
1549 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1550 dnl other error codes.
1551 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1552    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1553                   gdb_cv_thread_db_h_has_td_notalloc,
1554      AC_TRY_COMPILE(
1555        [#include <thread_db.h>],
1556        [int i = TD_NOTALLOC;],
1557        gdb_cv_thread_db_h_has_td_notalloc=yes,
1558        gdb_cv_thread_db_h_has_td_notalloc=no
1559      )
1560    )
1561    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1562                   gdb_cv_thread_db_h_has_td_version,
1563      AC_TRY_COMPILE(
1564        [#include <thread_db.h>],
1565        [int i = TD_VERSION;],
1566        gdb_cv_thread_db_h_has_td_version=yes,
1567        gdb_cv_thread_db_h_has_td_version=no
1568      )
1569    )
1570    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1571                   gdb_cv_thread_db_h_has_td_notls,
1572      AC_TRY_COMPILE(
1573        [#include <thread_db.h>],
1574        [int i = TD_NOTLS;],
1575        gdb_cv_thread_db_h_has_td_notls=yes,
1576        gdb_cv_thread_db_h_has_td_notls=no
1577      )
1578    )
1579 fi
1580 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1581   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1582             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1583 fi
1584 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1585   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1586             [Define if <thread_db.h> has the TD_VERSION error code.])
1587 fi
1588 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1589   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1590             [Define if <thread_db.h> has the TD_NOTLS error code.])
1591 fi
1592
1593 dnl See if we have a sys/syscall header file that has __NR_tkill.
1594 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1595    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1596                   gdb_cv_sys_syscall_h_has_tkill,
1597      AC_TRY_COMPILE(
1598        [#include <sys/syscall.h>],
1599        [int i = __NR_tkill;],
1600        gdb_cv_sys_syscall_h_has_tkill=yes,
1601        gdb_cv_sys_syscall_h_has_tkill=no
1602      )
1603    )
1604 fi
1605 dnl See if we can issue tkill syscall.
1606 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1607   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1608 fi
1609
1610 dnl Check if we can disable the virtual address space randomization.
1611 dnl The functionality of setarch -R.
1612 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1613 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1614 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1615 #       define ADDR_NO_RANDOMIZE 0x0040000
1616 #      endif
1617        /* Test the flag could be set and stays set.  */
1618        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1619        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1620            return 1])])
1621 AC_RUN_IFELSE([PERSONALITY_TEST],
1622               [have_personality=true],
1623               [have_personality=false],
1624               [AC_LINK_IFELSE([PERSONALITY_TEST],
1625                               [have_personality=true],
1626                               [have_personality=false])])
1627 if $have_personality
1628 then
1629     AC_DEFINE([HAVE_PERSONALITY], 1,
1630               [Define if you support the personality syscall.])
1631 fi
1632
1633 dnl Handle optional features that can be enabled.
1634
1635 target_sysroot_reloc=0
1636 AC_ARG_WITH(sysroot,
1637 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1638 [
1639  case ${with_sysroot} in
1640  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1641  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1642  esac
1643
1644  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1645
1646  if test "x$prefix" = xNONE; then
1647   test_prefix=/usr/local
1648  else
1649   test_prefix=$prefix
1650  fi
1651  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1652   test_exec_prefix=$test_prefix
1653  else
1654   test_exec_prefix=$exec_prefix
1655  fi
1656  case ${TARGET_SYSTEM_ROOT} in
1657  "${test_prefix}"|"${test_prefix}/"*|\
1658  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1659  '${prefix}'|'${prefix}/'*|\
1660  '${exec_prefix}'|'${exec_prefix}/'*)
1661    target_sysroot_reloc=1
1662    ;;
1663  esac
1664 ], [
1665  TARGET_SYSTEM_ROOT=
1666  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1667 ])
1668 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1669 AC_SUBST(TARGET_SYSTEM_ROOT)
1670 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1671
1672 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1673     [automatically load a system-wide gdbinit file],
1674     [])
1675
1676 AC_ARG_ENABLE(werror,
1677   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1678   [case "${enableval}" in
1679      yes | y) ERROR_ON_WARNING="yes" ;;
1680      no | n)  ERROR_ON_WARNING="no" ;;
1681      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1682    esac])
1683
1684 # Enable -Werror by default when using gcc
1685 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1686     ERROR_ON_WARNING=yes
1687 fi
1688
1689 WERROR_CFLAGS=""
1690 if test "${ERROR_ON_WARNING}" = yes ; then
1691     WERROR_CFLAGS="-Werror"
1692 fi
1693
1694 # The entries after -Wno-pointer-sign are disabled warnings which may
1695 # be enabled in the future, which can not currently be used to build
1696 # GDB.
1697 # NOTE: If you change this list, remember to update
1698 # gdb/doc/gdbint.texinfo.
1699 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1700 -Wformat-nonliteral -Wno-pointer-sign \
1701 -Wno-unused -Wunused-value -Wunused-function \
1702 -Wno-switch -Wno-char-subscripts"
1703
1704 # Enable -Wno-format by default when using gcc on mingw since many
1705 # GCC versions complain about %I64.
1706 case "${host}" in
1707   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1708 esac
1709
1710 AC_ARG_ENABLE(build-warnings,
1711 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1712 [case "${enableval}" in
1713   yes)  ;;
1714   no)   build_warnings="-w";;
1715   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1716         build_warnings="${build_warnings} ${t}";;
1717   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1718         build_warnings="${t} ${build_warnings}";;
1719   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1720 esac
1721 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1722   echo "Setting compiler warning flags = $build_warnings" 6>&1
1723 fi])dnl
1724 AC_ARG_ENABLE(gdb-build-warnings,
1725 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1726 [case "${enableval}" in
1727   yes)  ;;
1728   no)   build_warnings="-w";;
1729   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1730         build_warnings="${build_warnings} ${t}";;
1731   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1732         build_warnings="${t} ${build_warnings}";;
1733   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1734 esac
1735 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1736   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1737 fi])dnl
1738 WARN_CFLAGS=""
1739 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1740 then
1741     AC_MSG_CHECKING(compiler warning flags)
1742     # Separate out the -Werror flag as some files just cannot be
1743     # compiled with it enabled.
1744     for w in ${build_warnings}; do
1745         case $w in
1746         -Werr*) WERROR_CFLAGS=-Werror ;;
1747         *) # Check that GCC accepts it
1748             saved_CFLAGS="$CFLAGS"
1749             CFLAGS="$CFLAGS $w"
1750             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1751             CFLAGS="$saved_CFLAGS"
1752         esac
1753     done
1754     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1755 fi
1756 AC_SUBST(WARN_CFLAGS)
1757 AC_SUBST(WERROR_CFLAGS)
1758
1759 # In the Cygwin environment, we need some additional flags.
1760 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1761 [AC_EGREP_CPP(lose, [
1762 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1763 lose
1764 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1765
1766
1767 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1768 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1769 case ${host} in
1770   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1771   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1772   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1773 esac
1774 AC_SUBST(SER_HARDWIRE)
1775
1776 # libreadline needs libuser32.a in a cygwin environment
1777 WIN32LIBS=
1778 if test x$gdb_cv_os_cygwin = xyes; then
1779     WIN32LIBS="-luser32"
1780     case "${target}" in
1781         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1782         ;;
1783     esac
1784 fi
1785
1786 # The ser-tcp.c module requires sockets.
1787 case ${host} in
1788   *mingw32*)
1789     AC_DEFINE(USE_WIN32API, 1,
1790               [Define if we should use the Windows API, instead of the
1791                POSIX API.  On Windows, we use the Windows API when
1792                building for MinGW, but the POSIX API when building
1793                for Cygwin.])
1794     WIN32LIBS="$WIN32LIBS -lws2_32"
1795     ;;
1796 esac
1797 AC_SUBST(WIN32LIBS)
1798
1799 # Add ELF support to GDB, but only if BFD includes ELF support.
1800 OLD_CFLAGS=$CFLAGS
1801 OLD_LDFLAGS=$LDFLAGS
1802 OLD_LIBS=$LIBS
1803 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1804 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1805 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1806 LIBS="-lbfd -liberty $intl $LIBS"
1807 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1808 [AC_TRY_LINK(
1809 [#include <stdlib.h>
1810 #include "bfd.h"
1811 #include "elf-bfd.h"
1812 ],
1813 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1814 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1815 if test $gdb_cv_var_elf = yes; then
1816   CONFIG_OBS="$CONFIG_OBS elfread.o"
1817   AC_DEFINE(HAVE_ELF, 1,
1818             [Define if ELF support should be included.])
1819 fi
1820 CFLAGS=$OLD_CFLAGS
1821 LDFLAGS=$OLD_LDFLAGS
1822 LIBS=$OLD_LIBS
1823
1824 # Add any host-specific objects to GDB.
1825 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1826
1827 LIBGUI="../libgui/src/libgui.a"
1828 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1829 AC_SUBST(LIBGUI)
1830 AC_SUBST(GUI_CFLAGS_X)
1831
1832 WIN32LDAPP=
1833 AC_SUBST(WIN32LIBS)
1834 AC_SUBST(WIN32LDAPP)
1835
1836 case "${host}" in
1837 *-*-cygwin* | *-*-mingw* )
1838     configdir="win"
1839     ;;
1840 *)
1841     configdir="unix"
1842     ;;
1843 esac
1844
1845 GDBTKLIBS=
1846 if test "${enable_gdbtk}" = "yes"; then
1847
1848     # Gdbtk must have an absolute path to srcdir in order to run
1849     # properly when not installed.
1850     here=`pwd`
1851     cd ${srcdir}
1852     GDBTK_SRC_DIR=`pwd`
1853     cd $here
1854
1855     SC_PATH_TCLCONFIG
1856
1857     # If $no_tk is nonempty, then we can't do Tk, and there is no
1858     # point to doing Tcl.
1859     SC_PATH_TKCONFIG
1860
1861     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1862         SC_LOAD_TCLCONFIG
1863
1864         # Check for in-tree tcl
1865         here=`pwd`
1866         cd ${srcdir}/..
1867         topdir=`pwd`
1868         cd ${here}
1869
1870         intree="no"
1871         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1872           intree="yes"
1873         fi
1874
1875         # Find Tcl private headers
1876         if test x"${intree}" = xno; then
1877           CY_AC_TCL_PRIVATE_HEADERS
1878           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1879           TCL_LIBRARY="${TCL_LIB_SPEC}"
1880           TCL_DEPS=""
1881         else
1882           # If building tcl in the same src tree, private headers
1883           # are not needed, but we need to be sure to use the right
1884           # headers library
1885           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1886           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1887           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1888         fi
1889         AC_SUBST(TCL_INCLUDE)
1890         AC_SUBST(TCL_LIBRARY)
1891         AC_SUBST(TCL_DEPS)
1892
1893         SC_LOAD_TKCONFIG
1894
1895         # Check for in-tree Tk
1896         intree="no"
1897         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1898           intree="yes"
1899         fi
1900
1901         # Find Tk private headers
1902         if test x"${intree}" = xno; then
1903           CY_AC_TK_PRIVATE_HEADERS
1904           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1905           TK_LIBRARY=${TK_LIB_SPEC}
1906           TK_DEPS=""
1907         else
1908           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1909           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1910           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1911         fi
1912         AC_SUBST(TK_INCLUDE)
1913         AC_SUBST(TK_LIBRARY)
1914         AC_SUBST(TK_DEPS)
1915         AC_SUBST(TK_XINCLUDES)
1916
1917         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1918
1919         # Include some libraries that Tcl and Tk want.
1920         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1921         # Yes, the ordering seems wrong here.  But it isn't.
1922         # TK_LIBS is the list of libraries that need to be linked
1923         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1924         # were in LIBS then any link tests after this point would
1925         # try to include things like `$(LIBGUI)', which wouldn't work.
1926         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1927
1928         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1929         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1930         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1931         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1932         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1933         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1934         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1935
1936         if test x$gdb_cv_os_cygwin = xyes; then
1937           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1938           WIN32LDAPP="-Wl,--subsystem,console"
1939           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1940         fi
1941
1942         AC_CONFIG_SUBDIRS(gdbtk)
1943     fi
1944 fi
1945
1946 AC_SUBST(X_CFLAGS)
1947 AC_SUBST(X_LDFLAGS)
1948 AC_SUBST(X_LIBS)
1949 AC_SUBST(GDBTKLIBS)
1950 AC_SUBST(GDBTK_CFLAGS)
1951 AC_SUBST(GDBTK_SRC_DIR)
1952
1953 AC_PATH_X
1954
1955 # Unlike the sim directory, whether a simulator is linked is controlled by
1956 # presence of a gdb_sim definition in the target configure.tgt entry.
1957 # This code just checks for a few cases where we'd like to ignore those
1958 # definitions, even when they're present in the '.mt' file.  These cases
1959 # are when --disable-sim is specified, or if the simulator directory is
1960 # not part of the source tree.
1961 #
1962 AC_ARG_ENABLE(sim,
1963 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1964 [echo "enable_sim = $enable_sim";
1965  echo "enableval = ${enableval}";
1966  case "${enableval}" in
1967   yes) ignore_sim=false ;;
1968   no)  ignore_sim=true ;;
1969   *)   ignore_sim=false ;;
1970  esac],
1971 [ignore_sim=false])
1972
1973 if test ! -d "${srcdir}/../sim"; then
1974   ignore_sim=true
1975 fi
1976
1977 SIM=
1978 SIM_OBS=
1979 if test "${ignore_sim}" = "false"; then
1980   if test x"${gdb_sim}" != x ; then
1981     SIM="${gdb_sim}"
1982     SIM_OBS="remote-sim.o"
1983     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1984   fi
1985 fi
1986 AC_SUBST(SIM)
1987 AC_SUBST(SIM_OBS)
1988
1989 AC_SUBST(ENABLE_CFLAGS)
1990 AC_SUBST(PROFILE_CFLAGS)
1991
1992 AC_SUBST(CONFIG_OBS)
1993 AC_SUBST(CONFIG_DEPS)
1994 AC_SUBST(CONFIG_SRCS)
1995 AC_SUBST(CONFIG_ALL)
1996 AC_SUBST(CONFIG_CLEAN)
1997 AC_SUBST(CONFIG_INSTALL)
1998 AC_SUBST(CONFIG_UNINSTALL)
1999
2000 # List of host floatformats.
2001 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2002 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2003 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2004
2005 # target_subdir is used by the testsuite to find the target libraries.
2006 target_subdir=
2007 if test "${host}" != "${target}"; then
2008     target_subdir="${target_alias}/"
2009 fi
2010 AC_SUBST(target_subdir)
2011
2012 frags=
2013 if test "${gdb_native}" = "yes"; then
2014   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2015   if test ! -f ${host_makefile_frag}; then
2016     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2017   fi
2018   frags="$frags $host_makefile_frag"
2019 else
2020   host_makefile_frag=/dev/null
2021 fi
2022
2023 AC_SUBST_FILE(host_makefile_frag)
2024 AC_SUBST(frags)
2025
2026 changequote(,)dnl
2027 if test "${gdb_native}" = "yes"; then
2028 # We pick this up from the host configuration file (.mh) because we
2029 # do not have a native configuration Makefile fragment.
2030 nativefile=`sed -n '
2031 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2032 ' ${host_makefile_frag}`
2033 fi
2034 changequote([,])
2035
2036 if test x"${gdb_osabi}" != x ; then
2037     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2038                        [Define to the default OS ABI for this configuration.])
2039 fi
2040
2041 # Enable multi-ice-gdb-server.
2042 AC_ARG_ENABLE(multi-ice,
2043 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2044   [case $enableval in
2045     yes | no)
2046       ;;
2047     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2048   esac])
2049 if test "x$enable_multi_ice" = xyes; then
2050    AC_CONFIG_SUBDIRS(multi-ice)
2051 fi
2052
2053 # We only build gdbserver automatically in a native configuration.
2054 if test "$gdb_native" = "yes"; then
2055   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2056   if test "x$build_gdbserver" = xyes; then
2057     AC_MSG_RESULT(yes)
2058     AC_CONFIG_SUBDIRS(gdbserver)
2059   else
2060     AC_MSG_RESULT(no)
2061   fi
2062 fi
2063
2064 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2065 # to an empty version.
2066
2067 files=
2068 links=
2069
2070 rm -f nm.h
2071 if test "${nativefile}" != ""; then
2072     case "${nativefile}" in
2073       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2074       * ) GDB_NM_FILE="${nativefile}"
2075     esac
2076     files="${files} ${GDB_NM_FILE}"
2077     links="${links} nm.h"
2078     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2079 fi
2080 AC_SUBST(GDB_NM_FILE)
2081
2082 AC_LINK_FILES($files, $links)
2083
2084 dnl Check for exe extension set on certain hosts (e.g. Win32)
2085 AC_EXEEXT
2086
2087 dnl  Detect the character set used by this host.
2088 dnl  At the moment, we just assume it's UTF-8.
2089 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2090           [Define to be a string naming the default host character set.])
2091
2092 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
2093 [
2094 case x$CONFIG_HEADERS in
2095 xconfig.h:config.in)
2096 echo > stamp-h ;;
2097 esac
2098 ])
2099
2100 exit 0