gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 dnl List of object files and targets accumulated by configure.
  49
  50 CONFIG_OBS=
  51 CONFIG_DEPS=
  52 CONFIG_SRCS=
  53 ENABLE_CFLAGS=
  54
  55 CONFIG_ALL=
  56 CONFIG_CLEAN=
  57 CONFIG_INSTALL=
  58 CONFIG_UNINSTALL=
  59
  60 dnl Set up for gettext.
  61 ZW_GNU_GETTEXT_SISTER_DIR
  62
  63 localedir='${datadir}/locale'
  64 AC_SUBST(localedir)
  65
  66 if test x"$USE_NLS" = xyes; then
  67    CONFIG_ALL="$CONFIG_ALL all-po"
  68    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  69    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  70    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  71 fi
  72
  73 PACKAGE=gdb
  74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  75 AC_SUBST(PACKAGE)
  76
  77 # We never need to detect it in this sub-configure.
  78 # But preserve it for config.status --recheck.
  79 AC_ARG_VAR(MAKEINFO,
  80   [Parent configure detects if it is of sufficient version.])
  81 AC_ARG_VAR(MAKEINFOFLAGS,
  82   [Parameters for MAKEINFO.])
  83
  84 MAKEINFO_EXTRA_FLAGS=""
  85 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  86   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  87   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  88     gdb_cv_have_makeinfo_click=yes
  89   else
  90     gdb_cv_have_makeinfo_click=no
  91   fi])
  92 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
  93   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
  94 fi
  95 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
  96
  97 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  98     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  99     [${libdir}/debug])
 100
 101 # We can't pass paths as command line arguments.
 102 # Mingw32 tries to be clever and will convert the paths for us.
 103 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 104 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 105 # This breaks GDB's relocatable path conversions since paths passed in
 106 # config.h would not get so translated, the path prefixes no longer match.
 107 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 108
 109 # GDB's datadir relocation
 110
 111 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 112     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 113     [${datadir}/gdb])
 114
 115 AC_ARG_WITH(relocated-sources,
 116 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 117 [reloc_srcdir="${withval}"
 118  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 119               [Relocated directory for source files. ])
 120 ])
 121
 122 AC_MSG_CHECKING([for default auto-load directory])
 123 AC_ARG_WITH(auto-load-dir,
 124 AS_HELP_STRING([--with-auto-load-dir=PATH],
 125   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 126   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 127 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 128 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 129               [Directories from which to load auto-loaded scripts.])
 130 AC_MSG_RESULT([$with_auto_load_dir])
 131
 132 AC_MSG_CHECKING([for default auto-load safe-path])
 133 AC_ARG_WITH(auto-load-safe-path,
 134 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 135   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 136 AS_HELP_STRING([--without-auto-load-safe-path],
 137                [do not restrict auto-loaded files locations]),
 138     [if test "$with_auto_load_safe_path" = "no"; then
 139      with_auto_load_safe_path="/"
 140      fi],
 141 [with_auto_load_safe_path="$with_auto_load_dir"])
 142 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 143 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 144               [Directories safe to hold auto-loaded files.])
 145 AC_MSG_RESULT([$with_auto_load_safe_path])
 146
 147 AC_CONFIG_SUBDIRS(testsuite)
 148
 149 # Check whether to support alternative target configurations
 150 AC_ARG_ENABLE(targets,
 151 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 152 [case "${enableval}" in
 153   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 154             ;;
 155   no)       enable_targets= ;;
 156   *)        enable_targets=$enableval ;;
 157 esac])
 158
 159 # Check whether to enable 64-bit support on 32-bit hosts
 160 AC_ARG_ENABLE(64-bit-bfd,
 161 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 162 [case "${enableval}" in
 163   yes)  want64=true  ;;
 164   no)   want64=false ;;
 165   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 166 esac],[want64=false])dnl
 167
 168 # Provide defaults for some variables set by the per-host and per-target
 169 # configuration.
 170 gdb_host_obs=posix-hdep.o
 171
 172 if test "${target}" = "${host}"; then
 173   gdb_native=yes
 174 else
 175   gdb_native=no
 176 fi
 177
 178 . $srcdir/configure.host
 179
 180 # Accumulate some settings from configure.tgt over all enabled targets
 181
 182 TARGET_OBS=
 183 all_targets=
 184 HAVE_NATIVE_GCORE_TARGET=
 185
 186 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 187 do
 188   if test "$targ_alias" = "all"; then
 189     all_targets=true
 190   else
 191     # Canonicalize the secondary target names.
 192     result=`$ac_config_sub $targ_alias 2>/dev/null`
 193     if test -n "$result"; then
 194         targ=$result
 195     else
 196         targ=$targ_alias
 197     fi
 198
 199     . ${srcdir}/configure.tgt
 200
 201     AS_IF([test -z "${gdb_target_obs}"],
 202       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 203
 204     # Target-specific object files
 205     for i in ${gdb_target_obs}; do
 206         case " $TARGET_OBS " in
 207         *" ${i} "*) ;;
 208         *)
 209           TARGET_OBS="$TARGET_OBS ${i}"
 210           ;;
 211         esac
 212     done
 213
 214     # Check whether this target needs 64-bit CORE_ADDR
 215     if test x${want64} = xfalse; then
 216       . ${srcdir}/../bfd/config.bfd
 217     fi
 218
 219     # Check whether this target is native and supports gcore.
 220     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 221        && $gdb_have_gcore; then
 222       HAVE_NATIVE_GCORE_TARGET=1
 223     fi
 224   fi
 225 done
 226
 227 if test x${all_targets} = xtrue; then
 228
 229   # We want all 64-bit targets if we either:
 230   #  - run on a 64-bit host  or
 231   #  - already require 64-bit support for some other target  or
 232   #  - the --enable-64-bit-bfd option was supplied
 233   # Otherwise we only support all 32-bit targets.
 234   #
 235   # NOTE: This test must be in sync with the corresponding
 236   #       tests in BFD!
 237
 238   if test x${want64} = xfalse; then
 239     AC_CHECK_SIZEOF(long)
 240     if test "x${ac_cv_sizeof_long}" = "x8"; then
 241       want64=true
 242     fi
 243   fi
 244   if test x${want64} = xtrue; then
 245     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 246   else
 247     TARGET_OBS='$(ALL_TARGET_OBS)'
 248   fi
 249 fi
 250
 251 AC_SUBST(TARGET_OBS)
 252 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 253
 254 # For other settings, only the main target counts.
 255 gdb_sim=
 256 gdb_osabi=
 257 targ=$target; . ${srcdir}/configure.tgt
 258
 259 # Fetch the default architecture and default target vector from BFD.
 260 targ=$target; . $srcdir/../bfd/config.bfd
 261
 262 # We only want the first architecture, so strip off the others if
 263 # there is more than one.
 264 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 265
 266 if test "x$targ_archs" != x; then
 267   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 268     [Define to BFD's default architecture. ])
 269 fi
 270 if test "x$targ_defvec" != x; then
 271   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 272     [Define to BFD's default target vector. ])
 273 fi
 274
 275 # Enable MI.
 276 AC_ARG_ENABLE(gdbmi,
 277 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 278   [case $enableval in
 279     yes | no)
 280       ;;
 281     *)
 282       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 283   esac],
 284   [enable_gdbmi=yes])
 285 if test x"$enable_gdbmi" = xyes; then
 286   if test -d "$srcdir/mi"; then
 287     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 288     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 289     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 290     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 291   fi
 292 fi
 293
 294 # Enable TUI.
 295 AC_ARG_ENABLE(tui,
 296 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 297   [case $enableval in
 298     yes | no | auto)
 299       ;;
 300     *)
 301       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 302   esac],enable_tui=auto)
 303
 304 # Enable gdbtk.
 305 AC_ARG_ENABLE(gdbtk,
 306 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 307   [case $enableval in
 308     yes | no)
 309       ;;
 310     *)
 311       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 312   esac],
 313   [if test -d "$srcdir/gdbtk"; then
 314     enable_gdbtk=yes
 315   else
 316     enable_gdbtk=no
 317   fi])
 318 # We unconditionally disable gdbtk tests on selected platforms.
 319 case $host_os in
 320   go32* | windows*)
 321     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 322     enable_gdbtk=no ;;
 323 esac
 324
 325 # Libunwind support for ia64.
 326
 327 AC_ARG_WITH(libunwind-ia64,
 328 AS_HELP_STRING([--with-libunwind-ia64],
 329                [use libunwind frame unwinding for ia64 targets]),,
 330             [with_libunwind_ia64=auto])
 331
 332 # Backward compatibility option.
 333 if test "${with_libunwind+set}" = set; then
 334   if test x"$with_libunwind_ia64" != xauto; then
 335     AC_MSG_ERROR(
 336       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 337   fi
 338   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 339   with_libunwind_ia64="$with_libunwind"
 340 fi
 341
 342 case "$with_libunwind_ia64" in
 343   yes | no)
 344     ;;
 345   auto)
 346     AC_CHECK_HEADERS(libunwind-ia64.h)
 347     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 348     ;;
 349   *)
 350     AC_MSG_ERROR(
 351       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 352     ;;
 353 esac
 354
 355 if test x"$with_libunwind_ia64" = xyes; then
 356   AC_CHECK_HEADERS(libunwind-ia64.h)
 357   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 358     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 359   fi
 360   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 361   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 362   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 363 fi
 364
 365 opt_curses=no
 366 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 367
 368 prefer_curses=no
 369 if test "$opt_curses" = "yes"; then
 370   prefer_curses=yes
 371 fi
 372
 373 # Profiling support.
 374 AC_ARG_ENABLE(profiling,
 375 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 376   [case $enableval in
 377     yes | no)
 378       ;;
 379     *)
 380       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 381   esac],
 382  [enable_profiling=no])
 383
 384 AC_CHECK_FUNCS(monstartup _mcleanup)
 385 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 386 [AC_TRY_LINK(
 387 [#include <stdlib.h>
 388 extern char _etext;
 389 ],
 390 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 391 if test "$ac_cv_var__etext" = yes; then
 392   AC_DEFINE(HAVE__ETEXT, 1,
 393             [Define to 1 if your system has the _etext variable. ])
 394 fi
 395 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 396 [AC_TRY_LINK(
 397 [#include <stdlib.h>
 398 extern char etext;
 399 ],
 400 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 401 if test "$ac_cv_var_etext" = yes; then
 402   AC_DEFINE(HAVE_ETEXT, 1,
 403             [Define to 1 if your system has the etext variable. ])
 404 fi
 405 if test "$enable_profiling" = yes ; then
 406   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 407     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 408   fi
 409   PROFILE_CFLAGS=-pg
 410   OLD_CFLAGS="$CFLAGS"
 411   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 412
 413   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 414     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 415      ac_cv_cc_supports_pg=no)])
 416
 417   if test "$ac_cv_cc_supports_pg" = no; then
 418     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 419   fi
 420
 421   CFLAGS="$OLD_CFLAGS"
 422 fi
 423
 424 CODESIGN_CERT=
 425 AC_ARG_ENABLE([codesign],
 426   AS_HELP_STRING([--enable-codesign=CERT],
 427                  [sign gdb with 'codesign -s CERT']),
 428   [CODESIGN_CERT=$enableval])
 429 AC_SUBST([CODESIGN_CERT])
 430
 431 ACX_PKGVERSION([GDB])
 432 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 433 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 434 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 435
 436 # --------------------- #
 437 # Checks for programs.  #
 438 # --------------------- #
 439
 440 AC_PROG_AWK
 441 AC_PROG_INSTALL
 442 AC_PROG_LN_S
 443 AC_PROG_RANLIB
 444 AC_PROG_YACC
 445
 446 AC_CHECK_TOOL(AR, ar)
 447 AC_CHECK_TOOL(DLLTOOL, dlltool)
 448 AC_CHECK_TOOL(WINDRES, windres)
 449
 450 case $host_os in
 451   gnu*)
 452     # Needed for GNU Hurd hosts.
 453     AC_CHECK_TOOL(MIG, mig)
 454     if test x"$MIG" = x; then
 455       AC_MSG_ERROR([MIG not found but required for $host hosts])
 456     fi
 457     ;;
 458 esac
 459
 460 # ---------------------- #
 461 # Checks for libraries.  #
 462 # ---------------------- #
 463
 464 # We might need to link with -lm; most simulators need it.
 465 AC_CHECK_LIB(m, main)
 466
 467 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 468 AC_SEARCH_LIBS(gethostbyname, nsl)
 469
 470 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 471 AC_SEARCH_LIBS(socketpair, socket)
 472
 473 # Link in zlib if we can.  This allows us to read compressed debug sections.
 474 AM_ZLIB
 475
 476 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 477 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 478 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 479   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 480             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 481
 482 AM_ICONV
 483
 484 # GDB may fork/exec the iconv program to get the list of supported character
 485 # sets.  Allow the user to specify where to find it.
 486 # There are several factors affecting the choice of option name:
 487 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 488 #   the build-time location of libiconv files.
 489 # - The program we need to find is iconv, which comes with glibc.  The user
 490 #   doesn't necessarily have libiconv installed.  Therefore naming this
 491 #   --with-libiconv-foo feels wrong.
 492 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 493 #   defined to work on directories not files (though it really doesn't know
 494 #   the difference).
 495 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 496 #   with --with-libiconv-prefix.
 497 # Putting these together is why the option name is --with-iconv-bin.
 498
 499 AC_ARG_WITH(iconv-bin,
 500 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 501 [iconv_bin="${withval}"
 502  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 503                     [Path of directory of iconv program.])
 504  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 505 ])
 506
 507 # For the TUI, we need enhanced curses functionality.
 508 if test x"$enable_tui" != xno; then
 509   prefer_curses=yes
 510 fi
 511
 512 curses_found=no
 513 if test x"$prefer_curses" = xyes; then
 514   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 515   # curses library because the latter might not provide all the
 516   # functionality we need.  However, this leads to problems on systems
 517   # where the linker searches /usr/local/lib, but the compiler doesn't
 518   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 519   # default installation of ncurses on alpha*-dec-osf* will lead to such
 520   # a situation.
 521   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 522
 523   if test "$ac_cv_search_waddstr" != no; then
 524     curses_found=yes
 525   fi
 526 fi
 527
 528 # Check whether we should enable the TUI, but only do so if we really
 529 # can.
 530 if test x"$enable_tui" != xno; then
 531   if test -d "$srcdir/tui"; then
 532     if test "$curses_found" != no; then
 533       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 534       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 535       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 536       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 537     else
 538       if test x"$enable_tui" = xyes; then
 539         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 540       else
 541         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 542       fi
 543     fi
 544   fi
 545 fi
 546
 547 # Since GDB uses Readline, we need termcap functionality.  In many
 548 # cases this will be provided by the curses library, but some systems
 549 # have a separate termcap library, or no curses library at all.
 550
 551 case $host_os in
 552   cygwin*)
 553     if test -d "$srcdir/libtermcap"; then
 554       LIBS="../libtermcap/libtermcap.a $LIBS"
 555       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 556     fi ;;
 557   go32* | *djgpp*)
 558     ac_cv_search_tgetent="none required"
 559     ;;
 560 esac
 561
 562 # These are the libraries checked by Readline.
 563 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 564
 565 if test "$ac_cv_search_tgetent" = no; then
 566   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 567 fi
 568
 569 AC_ARG_WITH([system-readline],
 570   [AS_HELP_STRING([--with-system-readline],
 571                   [use installed readline library])])
 572
 573 if test "$with_system_readline" = yes; then
 574    AC_CACHE_CHECK([whether system readline is new enough],
 575      [gdb_cv_readline_ok],
 576      [AC_TRY_COMPILE(
 577        [#include <stdio.h>
 578 #include <readline/readline.h>],
 579        [#if RL_VERSION_MAJOR < 7
 580 # error "readline version 7 required"
 581 #endif],
 582     gdb_cv_readline_ok=yes,
 583     gdb_cv_readline_ok=no)])
 584   if test "$gdb_cv_readline_ok" != yes; then
 585     AC_MSG_ERROR([system readline is not new enough])
 586   fi
 587
 588   READLINE=-lreadline
 589   READLINE_DEPS=
 590   READLINE_CFLAGS=
 591   READLINE_TEXI_INCFLAG=
 592 else
 593   READLINE='$(READLINE_DIR)/libreadline.a'
 594   READLINE_DEPS='$(READLINE)'
 595   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 596   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 597 fi
 598 AC_SUBST(READLINE)
 599 AC_SUBST(READLINE_DEPS)
 600 AC_SUBST(READLINE_CFLAGS)
 601 AC_SUBST(READLINE_TEXI_INCFLAG)
 602
 603 # Generate jit-reader.h
 604
 605 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 606 TARGET_PTR=
 607
 608 AC_CHECK_SIZEOF(unsigned long long)
 609 AC_CHECK_SIZEOF(unsigned long)
 610 AC_CHECK_SIZEOF(unsigned __int128)
 611
 612 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 613   TARGET_PTR="unsigned long"
 614 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 615   TARGET_PTR="unsigned long long"
 616 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 617   TARGET_PTR="unsigned __int128"
 618 else
 619   TARGET_PTR="unsigned long"
 620 fi
 621
 622 AC_SUBST(TARGET_PTR)
 623 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 624
 625 AC_SEARCH_LIBS(dlopen, dl)
 626
 627 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 628                 [directory to load the JIT readers from],
 629                 [${libdir}/gdb])
 630
 631 AC_ARG_WITH(expat,
 632   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 633   [], [with_expat=auto])
 634 AC_MSG_CHECKING([whether to use expat])
 635 AC_MSG_RESULT([$with_expat])
 636
 637 if test "${with_expat}" = no; then
 638   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 639   HAVE_LIBEXPAT=no
 640 else
 641   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 642                         [XML_Parser p = XML_ParserCreate (0);])
 643   if test "$HAVE_LIBEXPAT" != yes; then
 644     if test "$with_expat" = yes; then
 645       AC_MSG_ERROR([expat is missing or unusable])
 646     else
 647       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 648     fi
 649   else
 650     save_LIBS=$LIBS
 651     LIBS="$LIBS $LIBEXPAT"
 652     AC_CHECK_FUNCS(XML_StopParser)
 653     LIBS=$save_LIBS
 654   fi
 655 fi
 656
 657 AC_ARG_WITH(mpfr,
 658   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 659   [], [with_mpfr=auto])
 660 AC_MSG_CHECKING([whether to use MPFR])
 661 AC_MSG_RESULT([$with_mpfr])
 662
 663 if test "${with_mpfr}" = no; then
 664   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 665   HAVE_LIBMPFR=no
 666 else
 667   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 668                         [mpfr_exp_t exp; mpfr_t x;
 669                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 670   if test "$HAVE_LIBMPFR" != yes; then
 671     if test "$with_mpfr" = yes; then
 672       AC_MSG_ERROR([MPFR is missing or unusable])
 673     else
 674       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 675     fi
 676   fi
 677 fi
 678
 679 # --------------------- #
 680 # Check for libpython.  #
 681 # --------------------- #
 682
 683 dnl Utility to simplify finding libpython.
 684 dnl $1 = the shell variable to assign the result to
 685 dnl      If libpython is found we store $version here.
 686 dnl $2 = additional flags to add to CPPFLAGS
 687 dnl $3 = additional flags to add to LIBS
 688
 689 AC_DEFUN([AC_TRY_LIBPYTHON],
 690 [
 691   define([have_libpython_var],$1)
 692   new_CPPFLAGS=$2
 693   new_LIBS=$3
 694   AC_MSG_CHECKING([for python])
 695   save_CPPFLAGS=$CPPFLAGS
 696   save_LIBS=$LIBS
 697   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 698   LIBS="$new_LIBS $LIBS"
 699   found_usable_python=no
 700   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 701                                  [[Py_Initialize ();]])],
 702                  [have_libpython_var=yes
 703                   found_usable_python=yes
 704                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 705                   PYTHON_LIBS=$new_LIBS])
 706   CPPFLAGS=$save_CPPFLAGS
 707   LIBS=$save_LIBS
 708   AC_MSG_RESULT([${found_usable_python}])
 709 ])
 710
 711 dnl There are several different values for --with-python:
 712 dnl
 713 dnl no -   Don't include python support.
 714 dnl yes -  Include python support, error if it's missing.
 715 dnl        If we find python in $PATH, use it to fetch configure options,
 716 dnl        otherwise assume the compiler can find it with no help from us.
 717 dnl        Python 2.7 and 2.6 are tried in turn.
 718 dnl auto - Same as "yes", but if python is missing from the system,
 719 dnl        fall back to "no".
 720 dnl /path/to/python/exec-prefix -
 721 dnl        Use the python located in this directory.
 722 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 723 dnl        the compilation parameters.  Otherwise use
 724 dnl        -I/path/to/python/exec-prefix/include,
 725 dnl        -L/path/to/python/exec-prefix/lib.
 726 dnl        Python 2.7 and 2.6 are tried in turn.
 727 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 728 dnl        but is deprecated.
 729 dnl /path/to/python/executable -
 730 dnl        Run python-config.py with this version of python to fetch the
 731 dnl        compilation parameters.
 732 dnl        NOTE: This needn't be the real python executable.
 733 dnl        In a cross-compilation scenario (build != host), this could be
 734 dnl        a shell script that provides what python-config.py provides for
 735 dnl        --ldflags, --includes, --exec-prefix.
 736 dnl python-executable -
 737 dnl        Find python-executable in $PATH, and then handle the same as
 738 dnl        /path/to/python/executable.
 739 dnl
 740 dnl If a python program is specified, it is used to run python-config.py and
 741 dnl is passed --ldflags, --includes, --exec-prefix.
 742
 743 AC_ARG_WITH(python,
 744   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 745   [], [with_python=auto])
 746 AC_MSG_CHECKING([whether to use python])
 747 AC_MSG_RESULT([$with_python])
 748
 749 if test "${with_python}" = no; then
 750   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 751   have_libpython=no
 752 else
 753   case "${with_python}" in
 754   [[\\/]]* | ?:[[\\/]]*)
 755     if test -d "${with_python}"; then
 756       # Assume the python binary is ${with_python}/bin/python.
 757       python_prog="${with_python}/bin/python"
 758       python_prefix=
 759       # If python does not exit ${with_python}/bin, then try in
 760       # ${with_python}.  On Windows/MinGW, this is where the Python
 761       # executable is.
 762       if test ! -x "${python_prog}"; then
 763         python_prog="${with_python}/python"
 764         python_prefix=
 765       fi
 766       if test ! -x "${python_prog}"; then
 767         # Fall back to gdb 7.0/7.1 behaviour.
 768         python_prog=missing
 769         python_prefix=${with_python}
 770       fi
 771     elif test -x "${with_python}"; then
 772       # While we can't run python compiled for $host (unless host == build),
 773       # the user could write a script that provides the needed information,
 774       # so we support that.
 775       python_prog=${with_python}
 776       python_prefix=
 777     else
 778       AC_ERROR(invalid value for --with-python)
 779     fi
 780     ;;
 781   */*)
 782     # Disallow --with-python=foo/bar.
 783     AC_ERROR(invalid value for --with-python)
 784     ;;
 785   *)
 786     # The user has either specified auto, yes, or the name of the python
 787     # program assumed to be in $PATH.
 788     python_prefix=
 789     case "${with_python}" in
 790     yes | auto)
 791       if test "${build}" = "${host}"; then
 792         AC_PATH_PROG(python_prog_path, python, missing)
 793         if test "${python_prog_path}" = missing; then
 794           python_prog=missing
 795         else
 796           python_prog=${python_prog_path}
 797         fi
 798       else
 799         # Not much we can do except assume the cross-compiler will find the
 800         # right files.
 801         python_prog=missing
 802       fi
 803       ;;
 804     *)
 805       # While we can't run python compiled for $host (unless host == build),
 806       # the user could write a script that provides the needed information,
 807       # so we support that.
 808       python_prog="${with_python}"
 809       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 810       if test "${python_prog_path}" = missing; then
 811         AC_ERROR(unable to find python program ${python_prog})
 812       fi
 813       ;;
 814     esac
 815   esac
 816
 817   if test "${python_prog}" != missing; then
 818     # We have a python program to use, but it may be too old.
 819     # Don't flag an error for --with-python=auto (the default).
 820     have_python_config=yes
 821     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 822     if test $? != 0; then
 823       have_python_config=failed
 824       if test "${with_python}" != auto; then
 825         AC_ERROR(failure running python-config --includes)
 826       fi
 827     fi
 828     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 829     if test $? != 0; then
 830       have_python_config=failed
 831       if test "${with_python}" != auto; then
 832         AC_ERROR(failure running python-config --ldflags)
 833       fi
 834     fi
 835     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 836     if test $? != 0; then
 837       have_python_config=failed
 838       if test "${with_python}" != auto; then
 839         AC_ERROR(failure running python-config --exec-prefix)
 840       fi
 841     fi
 842   else
 843     # We do not have a python executable we can use to determine where
 844     # to find the Python headers and libs.  We cannot guess the include
 845     # path from the python_prefix either, because that include path
 846     # depends on the Python version.  So, there is nothing much we can
 847     # do except assume that the compiler will be able to find those files.
 848     python_includes=
 849     python_libs=
 850     have_python_config=no
 851   fi
 852
 853   # If we have python-config, only try the configuration it provides.
 854   # Otherwise fallback on the old way of trying different versions of
 855   # python in turn.
 856
 857   have_libpython=no
 858   if test "${have_python_config}" = yes; then
 859     AC_TRY_LIBPYTHON(have_libpython,
 860                      ${python_includes}, ${python_libs})
 861   elif test "${have_python_config}" != failed; then
 862     if test "${have_libpython}" = no; then
 863       AC_TRY_LIBPYTHON(have_libpython,
 864                        ${python_includes}, "-lpython2.7 ${python_libs}")
 865     fi
 866     if test "${have_libpython}" = no; then
 867       AC_TRY_LIBPYTHON(have_libpython,
 868                        ${python_includes}, "-lpython2.6 ${python_libs}")
 869     fi
 870   fi
 871
 872   if test "${have_libpython}" = no; then
 873     case "${with_python}" in
 874     yes)
 875       AC_MSG_ERROR([python is missing or unusable])
 876       ;;
 877     auto)
 878       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 879       ;;
 880     *)
 881       AC_MSG_ERROR([no usable python found at ${with_python}])
 882       ;;
 883     esac
 884   else
 885     if test -n "${python_prefix}"; then
 886       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 887                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 888       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 889     fi
 890   fi
 891 fi
 892
 893 if test "${have_libpython}" != no; then
 894   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 895   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 896   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 897   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 898   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 899   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 900
 901   # Flags needed to compile Python code (taken from python-config --cflags).
 902   # We cannot call python-config directly because it will output whatever was
 903   # used when compiling the Python interpreter itself, including flags which
 904   # would make the python-related objects be compiled differently from the
 905   # rest of GDB (e.g., -O2 and -fPIC).
 906   if test "${GCC}" = yes; then
 907     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 908     # Python headers recommend -DNDEBUG, but it's unclear if that just
 909     # refers to building Python itself.  In release mode, though, it
 910     # doesn't hurt for the Python code in gdb to follow.
 911     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 912   fi
 913
 914   if test "x${tentative_python_cflags}" != x; then
 915     AC_MSG_CHECKING(compiler flags for python code)
 916     for flag in ${tentative_python_cflags}; do
 917       # Check that the compiler accepts it
 918       saved_CFLAGS="$CFLAGS"
 919       CFLAGS="$CFLAGS $flag"
 920       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 921       CFLAGS="$saved_CFLAGS"
 922     done
 923     AC_MSG_RESULT(${PYTHON_CFLAGS})
 924   fi
 925
 926   # On x64 Windows, Python's include headers, and pyconfig.h in
 927   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 928   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 929   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 930   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 931   # The issue was reported to the Python community, but still isn't
 932   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 933
 934   case "$gdb_host" in
 935     mingw64)
 936            if test "${GCC}" = yes; then
 937              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 938            fi
 939            ;;
 940   esac
 941 else
 942   # Even if Python support is not compiled in, we need to have this file
 943   # included so that the "python" command, et.al., still exists.
 944   CONFIG_OBS="$CONFIG_OBS python/python.o"
 945   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
 946 fi
 947
 948 # Work around Python http://bugs.python.org/issue10112.  See also
 949 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
 950 # no effect.  Note that the only test after this that uses Python is
 951 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
 952 # run without -export-dynamic too.
 953 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
 954
 955 AC_SUBST(PYTHON_CFLAGS)
 956 AC_SUBST(PYTHON_CPPFLAGS)
 957 AC_SUBST(PYTHON_LIBS)
 958 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
 959
 960 # -------------------- #
 961 # Check for libguile.  #
 962 # -------------------- #
 963
 964 dnl Utility to simplify finding libguile.
 965 dnl $1 = pkg-config-program
 966 dnl $2 = space-separate list of guile versions to try
 967 dnl $3 = yes|no, indicating whether to flag errors or ignore them
 968 dnl $4 = the shell variable to assign the result to
 969 dnl      If libguile is found we store "yes" here.
 970
 971 AC_DEFUN([AC_TRY_LIBGUILE],
 972 [
 973   pkg_config=$1
 974   guile_version_list=$2
 975   flag_errors=$3
 976   define([have_libguile_var],$4)
 977   found_usable_guile=checking
 978   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
 979   for guile_version in ${guile_version_list}; do
 980     ${pkg_config} --exists ${guile_version} 2>/dev/null
 981     if test $? != 0; then
 982       continue
 983     fi
 984     dnl pkg-config says the package exists, so if we get an error now,
 985     dnl that's bad.
 986     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
 987     if test $? != 0; then
 988       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
 989     fi
 990     new_LIBS=`${pkg_config} --libs ${guile_version}`
 991     if test $? != 0; then
 992       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
 993     fi
 994     dnl If we get this far, great.
 995     found_usable_guile=${guile_version}
 996     break
 997   done
 998   if test "${found_usable_guile}" = "checking"; then
 999     if test "${flag_errors}" = "yes"; then
1000       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1001     else
1002       found_usable_guile=no
1003     fi
1004   fi
1005   dnl One final sanity check.
1006   dnl The user could have said --with-guile=python-2.7.
1007   if test "${found_usable_guile}" != no; then
1008     save_CPPFLAGS=$CPPFLAGS
1009     save_LIBS=$LIBS
1010     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1011     LIBS="$LIBS $new_LIBS"
1012     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1013                                    [[scm_init_guile ();]])],
1014                    [have_libguile_var=yes
1015                     GUILE_CPPFLAGS=$new_CPPFLAGS
1016                     GUILE_LIBS=$new_LIBS],
1017                    [found_usable_guile=no])
1018     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1019     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1020       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1021                 [Define if Guile supports manual finalization.])
1022     )
1023     CPPFLAGS=$save_CPPFLAGS
1024     LIBS=$save_LIBS
1025     if test "${found_usable_guile}" = no; then
1026       if test "${flag_errors}" = yes; then
1027         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1028       fi
1029     fi
1030   fi
1031   AC_MSG_RESULT([${found_usable_guile}])
1032 ])
1033
1034 dnl There are several different values for --with-guile:
1035 dnl
1036 dnl no -   Don't include guile support.
1037 dnl yes -  Include guile support, error if it's missing.
1038 dnl        The pkg-config program must be in $PATH.
1039 dnl auto - Same as "yes", but if guile is missing from the system,
1040 dnl        fall back to "no".
1041 dnl guile-version [guile-version-choice-2 ...] -
1042 dnl        A space-separated list of guile package versions to try.
1043 dnl        These are passed to pkg-config as-is.
1044 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1045 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1046 dnl /path/to/pkg-config -
1047 dnl        Use this pkg-config program.
1048 dnl        NOTE: This needn't be the "real" pkg-config program.
1049 dnl        It could be a shell script.  It is invoked as:
1050 dnl        pkg-config --exists $version
1051 dnl        pkg-config --cflags $version
1052 dnl        pkg-config --libs $version
1053 dnl        pkg-config --variable guild $version
1054 dnl        The script will be called with $version having each value in
1055 dnl        $try_guile_versions until --exists indicates success.
1056
1057 AC_ARG_WITH(guile,
1058   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1059   [], [with_guile=auto])
1060 AC_MSG_CHECKING([whether to use guile])
1061 AC_MSG_RESULT([$with_guile])
1062
1063 dnl We check guile with pkg-config.
1064 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1065
1066 try_guile_versions="guile-2.0"
1067 have_libguile=no
1068 case "${with_guile}" in
1069 no)
1070   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1071   ;;
1072 auto)
1073   if test "${pkg_config_prog_path}" = "missing"; then
1074     AC_MSG_WARN([pkg-config not found, guile support disabled])
1075   else
1076     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1077   fi
1078   ;;
1079 yes)
1080   if test "${pkg_config_prog_path}" = "missing"; then
1081     AC_MSG_ERROR([pkg-config not found])
1082   fi
1083   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1084   ;;
1085 [[\\/]]* | ?:[[\\/]]*)
1086   if test -x "${with_guile}"; then
1087     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1088   else
1089     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1090   fi
1091   ;;
1092 "" | */*)
1093   # Disallow --with=guile="" and --with-guile=foo/bar.
1094   AC_MSG_ERROR([invalid value for --with-guile])
1095   ;;
1096 *)
1097   # A space separate list of guile versions to try, in order.
1098   if test "${pkg_config_prog_path}" = "missing"; then
1099     AC_MSG_ERROR([pkg-config not found])
1100   fi
1101   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1102   ;;
1103 esac
1104
1105 if test "${have_libguile}" != no; then
1106   dnl Get the name of the 'guild' program.
1107   case "${with_guile}" in
1108   [[\\/]]* | ?:[[\\/]]*)
1109     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1110     ;;
1111   *)
1112     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1113     ;;
1114   esac
1115
1116   dnl Make sure guild can handle this host.
1117   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1118   dnl If not, disable guile support.
1119   if test "$ac_cv_guild_ok" = no; then
1120     have_libguile=no
1121     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1122   fi
1123 fi
1124
1125 if test "${have_libguile}" != no; then
1126   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1127   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1128   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1129   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1130   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1131   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1132
1133   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1134   save_LIBS="$LIBS"
1135   save_CPPFLAGS="$CPPFLAGS"
1136   LIBS="$GUILE_LIBS"
1137   CPPFLAGS="$GUILE_CPPFLAGS"
1138   AC_CHECK_FUNCS([scm_new_smob])
1139   LIBS="$save_LIBS"
1140   CPPFLAGS="$save_CPPFLAGS"
1141 else
1142   # Even if Guile support is not compiled in, we need to have these files
1143   # included.
1144   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1145   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1146 fi
1147 AC_SUBST(GUILE_CPPFLAGS)
1148 AC_SUBST(GUILE_LIBS)
1149 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1150
1151 # ---------------------------- #
1152 # Check for source highlight.  #
1153 # ---------------------------- #
1154
1155 SRCHIGH_LIBS=
1156 SRCHIGH_CFLAGS=
1157
1158 AC_ARG_ENABLE(source-highlight,
1159   AS_HELP_STRING([--enable-source-highlight],
1160     [enable source-highlight for source listings]),
1161   [case "${enableval}" in
1162   yes)  enable_source_highlight=yes ;;
1163   no)   enable_source_highlight=no  ;;
1164   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1165 esac],
1166 [enable_source_highlight=auto])
1167
1168 if test "${enable_source_highlight}" != "no"; then
1169   AC_MSG_CHECKING([for the source-highlight library])
1170   if test "${pkg_config_prog_path}" = "missing"; then
1171     AC_MSG_RESULT([no - pkg-config not found])
1172     if test "${enable_source_highlight}" = "yes"; then
1173       AC_MSG_ERROR([pkg-config was not found in your system])
1174     fi
1175   else
1176     case "$LDFLAGS" in
1177       *static-libstdc*)
1178         AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1179 either use --disable-source-highlight or dnl
1180 --without-static-standard-libraries])
1181         ;;
1182     esac
1183
1184     if ${pkg_config_prog_path} --exists source-highlight; then
1185       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1186       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1187       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1188                 [Define to 1 if the source-highlight library is available])
1189       AC_MSG_RESULT([yes])
1190     else
1191       AC_MSG_RESULT([no])
1192       if test "${enable_source_highlight}" = "yes"; then
1193         AC_MSG_ERROR([source-highlight was not found in your system])
1194       fi
1195     fi
1196   fi
1197 fi
1198 AC_SUBST(SRCHIGH_LIBS)
1199 AC_SUBST(SRCHIGH_CFLAGS)
1200
1201 # ------------------------- #
1202 # Checks for header files.  #
1203 # ------------------------- #
1204
1205 AC_HEADER_STDC
1206 # elf_hp.h is for HP/UX 64-bit shared library support.
1207 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h \
1208                   thread_db.h \
1209                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1210                   sys/resource.h sys/ptrace.h ptrace.h \
1211                   sys/reg.h sys/debugreg.h sys/select.h \
1212                   termios.h elf_hp.h])
1213 AC_CHECK_HEADERS(sys/user.h, [], [],
1214 [#if HAVE_SYS_PARAM_H
1215 # include <sys/param.h>
1216 #endif
1217 ])
1218
1219 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1220 AC_CHECK_HEADERS(term.h, [], [],
1221 [#if HAVE_CURSES_H
1222 # include <curses.h>
1223 #endif
1224 ])
1225
1226 # ------------------------- #
1227 # Checks for declarations.  #
1228 # ------------------------- #
1229
1230 libiberty_INIT
1231
1232 AC_CHECK_DECLS([snprintf])
1233 AM_LC_MESSAGES
1234
1235 # ------------------ #
1236 # Checks for types.  #
1237 # ------------------ #
1238
1239 AC_CHECK_TYPES(socklen_t, [], [],
1240 [#include <sys/types.h>
1241 #include <sys/socket.h>
1242 ])
1243
1244 # ------------------------------------- #
1245 # Checks for compiler characteristics.  #
1246 # ------------------------------------- #
1247
1248 AC_C_CONST
1249 AC_C_INLINE
1250 AC_C_BIGENDIAN
1251
1252 # ------------------------------ #
1253 # Checks for library functions.  #
1254 # ------------------------------ #
1255
1256 AC_CHECK_FUNCS([getuid getgid \
1257                 pipe poll pread pread64 pwrite resize_term \
1258                 getpgid setsid \
1259                 sigaction sigsetmask socketpair \
1260                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1261                 setrlimit getrlimit posix_madvise waitpid \
1262                 use_default_colors])
1263 AM_LANGINFO_CODESET
1264 GDB_AC_COMMON
1265
1266 # Check the return and argument types of ptrace.
1267 GDB_AC_PTRACE
1268
1269 dnl AC_FUNC_SETPGRP does not work when cross compiling
1270 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1271 if test "$cross_compiling" = no; then
1272   AC_FUNC_SETPGRP
1273 else
1274   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1275     [AC_TRY_COMPILE([
1276 #include <unistd.h>
1277 ], [
1278   if (setpgrp(1,1) == -1)
1279     exit (0);
1280   else
1281     exit (1);
1282 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1283 if test "$ac_cv_func_setpgrp_void" = yes; then
1284   AC_DEFINE(SETPGRP_VOID, 1)
1285 fi
1286 fi
1287
1288 # Assume we'll default to using the included libiberty regex.
1289 gdb_use_included_regex=yes
1290
1291 # However, if the system regex is GNU regex, then default to *not*
1292 # using the included regex.
1293 AC_CACHE_CHECK(
1294   [for GNU regex],
1295   [gdb_cv_have_gnu_regex],
1296   [AC_TRY_COMPILE(
1297     [#include <gnu-versions.h>],
1298     [#define REGEX_INTERFACE_VERSION 1
1299 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1300 # error "Version mismatch"
1301 #endif],
1302     gdb_cv_have_gnu_regex=yes,
1303     gdb_cv_have_gnu_regex=no)])
1304 if test "$gdb_cv_have_gnu_regex" = yes; then
1305   gdb_use_included_regex=no
1306 fi
1307
1308 AC_ARG_WITH(included-regex,
1309   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1310   gdb_with_regex=$withval,
1311   gdb_with_regex=$gdb_use_included_regex)
1312 if test "$gdb_with_regex" = yes; then
1313   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1314     [Define to 1 if the regex included in libiberty should be used.])
1315 fi
1316
1317 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1318 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1319 [#include <sys/param.h>
1320 #include <sys/proc.h>
1321 ])
1322
1323 # See if <sys/lwp.h> defines `struct lwp`.
1324 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1325 [AC_TRY_COMPILE([#include <sys/param.h>
1326 #define _KMEMUSER
1327 #include <sys/lwp.h>], [struct lwp l;],
1328 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1329 if test "$gdb_cv_struct_lwp" = yes; then
1330   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1331             [Define to 1 if your system has struct lwp.])
1332 fi
1333
1334 # See if <machine/reg.h> degines `struct reg'.
1335 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1336 [AC_TRY_COMPILE([#include <sys/types.h>
1337 #include <machine/reg.h>], [struct reg r;],
1338 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1339 if test "$gdb_cv_struct_reg" = yes; then
1340   AC_DEFINE(HAVE_STRUCT_REG, 1,
1341             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1342 fi
1343
1344 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1345 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1346 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1347                  [#include <sys/types.h>
1348 #include <machine/reg.h>])
1349
1350 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1351 # Older amd64 Linux's don't have the fs_base and gs_base members of
1352 # `struct user_regs_struct'.
1353 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1354      [], [], [#include <sys/types.h>
1355 #include <sys/user.h>])
1356
1357 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1358 AC_MSG_CHECKING(for PTRACE_GETREGS)
1359 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1360 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1361                 [PTRACE_GETREGS;],
1362                 [gdb_cv_have_ptrace_getregs=yes],
1363                 [gdb_cv_have_ptrace_getregs=no])])
1364 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1365 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1366   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1367   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1368 fi
1369
1370 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1371 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1372 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1373 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1374                 [PTRACE_GETFPXREGS;],
1375                 [gdb_cv_have_ptrace_getfpxregs=yes],
1376                 [gdb_cv_have_ptrace_getfpxregs=no])])
1377 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1378 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1379   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1380   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1381 fi
1382
1383 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1384 AC_MSG_CHECKING(for PT_GETDBREGS)
1385 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1386 [AC_TRY_COMPILE([#include <sys/types.h>
1387 #include <sys/ptrace.h>],
1388                 [PT_GETDBREGS;],
1389                 [gdb_cv_have_pt_getdbregs=yes],
1390                 [gdb_cv_have_pt_getdbregs=no])])
1391 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1392 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1393   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1394   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1395 fi
1396
1397 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1398 AC_MSG_CHECKING(for PT_GETXMMREGS)
1399 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1400 [AC_TRY_COMPILE([#include <sys/types.h>
1401 #include <sys/ptrace.h>],
1402                 [PT_GETXMMREGS;],
1403                 [gdb_cv_have_pt_getxmmregs=yes],
1404                 [gdb_cv_have_pt_getxmmregs=no])])
1405 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1406 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1407   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1408   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1409 fi
1410
1411 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1412 # Older FreeBSD versions don't have the pl_tdname member of
1413 # `struct ptrace_lwpinfo'.
1414 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1415                  [#include <sys/ptrace.h>])
1416
1417 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1418 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1419 # FreeBSD 10.3.
1420 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1421                  [#include <sys/ptrace.h>])
1422
1423 # Check if the compiler supports the `long long' type.
1424
1425 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1426                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1427 [[extern long long foo;]],
1428 [[switch (foo & 2) { case 0: return 1; }]])],
1429                                   gdb_cv_c_long_long=yes,
1430                                   gdb_cv_c_long_long=no)])
1431 if test "$gdb_cv_c_long_long" != yes; then
1432   # libdecnumber requires long long.
1433   AC_MSG_ERROR([Compiler must support long long for GDB.])
1434 fi
1435
1436 # Check if the compiler and runtime support printing long longs.
1437
1438 AC_CACHE_CHECK([for long long support in printf],
1439                gdb_cv_printf_has_long_long,
1440                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1441 [[char buf[32];
1442   long long l = 0;
1443   l = (l << 16) + 0x0123;
1444   l = (l << 16) + 0x4567;
1445   l = (l << 16) + 0x89ab;
1446   l = (l << 16) + 0xcdef;
1447   sprintf (buf, "0x%016llx", l);
1448   return (strcmp ("0x0123456789abcdef", buf));]])],
1449                               gdb_cv_printf_has_long_long=yes,
1450                               gdb_cv_printf_has_long_long=no,
1451                               gdb_cv_printf_has_long_long=no)])
1452 if test "$gdb_cv_printf_has_long_long" = yes; then
1453   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1454             [Define to 1 if the "%ll" format works to print long longs.])
1455 fi
1456
1457 # Check if the compiler and runtime support printing decfloats.
1458
1459 AC_CACHE_CHECK([for decfloat support in printf],
1460                gdb_cv_printf_has_decfloat,
1461                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1462 [[char buf[64];
1463   _Decimal32 d32 = 1.2345df;
1464   _Decimal64 d64 = 1.2345dd;
1465   _Decimal128 d128 = 1.2345dl;
1466   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1467   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1468                               gdb_cv_printf_has_decfloat=yes,
1469                               gdb_cv_printf_has_decfloat=no,
1470                               gdb_cv_printf_has_decfloat=no)])
1471 if test "$gdb_cv_printf_has_decfloat" = yes; then
1472   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1473             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1474 fi
1475
1476 # Check if the compiler supports the `long double' type.  We can't use
1477 # AC_C_LONG_DOUBLE because that one does additional checks on the
1478 # constants defined in <float.h> that fail on some systems,
1479 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1480
1481 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1482                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1483                                   gdb_cv_c_long_double=yes,
1484                                   gdb_cv_c_long_double=no)])
1485 if test "$gdb_cv_c_long_double" = yes; then
1486   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1487            [Define to 1 if the compiler supports long double.])
1488 fi
1489
1490 # Check if the compiler and runtime support printing long doubles.
1491
1492 AC_CACHE_CHECK([for long double support in printf],
1493                gdb_cv_printf_has_long_double,
1494                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1495 [[char buf[16];
1496   long double f = 3.141592653;
1497   sprintf (buf, "%Lg", f);
1498   return (strncmp ("3.14159", buf, 7));]])],
1499                               gdb_cv_printf_has_long_double=yes,
1500                               gdb_cv_printf_has_long_double=no,
1501                               gdb_cv_printf_has_long_double=no)])
1502 if test "$gdb_cv_printf_has_long_double" = yes; then
1503   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1504             [Define to 1 if the "%Lg" format works to print long doubles.])
1505 fi
1506
1507 # Check if the compiler and runtime support scanning long doubles.
1508
1509 AC_CACHE_CHECK([for long double support in scanf],
1510                gdb_cv_scanf_has_long_double,
1511                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1512 [[#include <stdio.h>]],
1513 [[char *buf = "3.141592653";
1514   long double f = 0;
1515   sscanf (buf, "%Lg", &f);
1516   return !(f > 3.14159 && f < 3.14160);]])],
1517                               gdb_cv_scanf_has_long_double=yes,
1518                               gdb_cv_scanf_has_long_double=no,
1519                               gdb_cv_scanf_has_long_double=no)])
1520 if test "$gdb_cv_scanf_has_long_double" = yes; then
1521   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1522             [Define to 1 if the "%Lg" format works to scan long doubles.])
1523 fi
1524
1525 case ${host_os} in
1526 aix*)
1527   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1528     SAVE_LDFLAGS=$LDFLAGS
1529
1530     case $GCC in
1531     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1532     *) gdb_cv_bigtoc=-bbigtoc ;;
1533     esac
1534
1535     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1536     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1537     LDFLAGS="${SAVE_LDFLAGS}"
1538   ])
1539   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1540   ;;
1541 esac
1542
1543 AC_MSG_CHECKING(for the dynamic export flag)
1544 dynamic_list=false
1545 if test "${gdb_native}" = yes; then
1546    # The dynamically loaded libthread_db needs access to symbols in the gdb
1547    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1548    # may not be supported there.
1549    old_LDFLAGS="$LDFLAGS"
1550    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1551    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1552    LDFLAGS="$LDFLAGS $RDYNAMIC"
1553    if test "${have_libpython}" = no; then
1554      AC_TRY_LINK([], [], [dynamic_list=true])
1555    else
1556      # Workaround http://bugs.python.org/issue4434 where static
1557      # libpythonX.Y.a would get its symbols required for
1558      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1559      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1560
1561      # Note the workaround for Python
1562      # http://bugs.python.org/issue10112 earlier has removed
1563      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1564      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1565      # always pass.
1566      old_CFLAGS="$CFLAGS"
1567      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1568      old_LIBS="$LIBS"
1569      LIBS="$LIBS $PYTHON_LIBS"
1570      old_CPPFLAGS="$CPPFLAGS"
1571      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1572      AC_RUN_IFELSE(
1573        [AC_LANG_PROGRAM(
1574          [#include "Python.h"],
1575          [int err;
1576           Py_Initialize ();
1577           err = PyRun_SimpleString ("import itertools\n");
1578           Py_Finalize ();
1579           return err == 0 ? 0 : 1;])],
1580        [dynamic_list=true], [], [true])
1581      LIBS="$old_LIBS"
1582      CFLAGS="$old_CFLAGS"
1583      CPPFLAGS="$old_CPPFLAGS"
1584    fi
1585    LDFLAGS="$old_LDFLAGS"
1586 fi
1587 if $dynamic_list; then
1588   found="-Wl,--dynamic-list"
1589   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1590 else
1591   found="-rdynamic"
1592   RDYNAMIC="-rdynamic"
1593 fi
1594 AC_SUBST(RDYNAMIC)
1595 AC_MSG_RESULT($found)
1596
1597 dnl For certain native configurations, we need to check whether thread
1598 dnl support can be built in or not.
1599 dnl
1600 dnl Note that we only want this if we are both native (host == target),
1601 dnl and not doing a canadian cross build (build == host).
1602
1603 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1604    case ${host_os} in
1605    aix*)
1606       AC_MSG_CHECKING(for AiX thread debugging library)
1607       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1608                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1609                                    [#ifndef PTHDB_VERSION_3
1610                                     #error
1611                                     #endif],
1612                                    gdb_cv_have_aix_thread_debug=yes,
1613                                    gdb_cv_have_aix_thread_debug=no)])
1614       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1615       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1616          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1617          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1618          LIBS="$LIBS -lpthdebug"
1619
1620          # Older versions of AIX do not provide the declaration for
1621          # the getthrds function (it appears that it was introduced
1622          # with AIX 6.x).
1623          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1624       fi
1625       ;;
1626    esac
1627    AC_SUBST(CONFIG_LDFLAGS)
1628 fi
1629
1630 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1631 dnl other error codes.
1632 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1633    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1634                   gdb_cv_thread_db_h_has_td_notalloc,
1635      AC_TRY_COMPILE(
1636        [#include <thread_db.h>],
1637        [int i = TD_NOTALLOC;],
1638        gdb_cv_thread_db_h_has_td_notalloc=yes,
1639        gdb_cv_thread_db_h_has_td_notalloc=no
1640      )
1641    )
1642    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1643                   gdb_cv_thread_db_h_has_td_version,
1644      AC_TRY_COMPILE(
1645        [#include <thread_db.h>],
1646        [int i = TD_VERSION;],
1647        gdb_cv_thread_db_h_has_td_version=yes,
1648        gdb_cv_thread_db_h_has_td_version=no
1649      )
1650    )
1651    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1652                   gdb_cv_thread_db_h_has_td_notls,
1653      AC_TRY_COMPILE(
1654        [#include <thread_db.h>],
1655        [int i = TD_NOTLS;],
1656        gdb_cv_thread_db_h_has_td_notls=yes,
1657        gdb_cv_thread_db_h_has_td_notls=no
1658      )
1659    )
1660 fi
1661 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1662   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1663             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1664 fi
1665 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1666   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1667             [Define if <thread_db.h> has the TD_VERSION error code.])
1668 fi
1669 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1670   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1671             [Define if <thread_db.h> has the TD_NOTLS error code.])
1672 fi
1673
1674 dnl Set the host's .gdbinit filename.
1675 case $host_os in
1676   go32* | *djgpp*)
1677     gdbinit=gdb.ini
1678     ;;
1679   *)
1680     gdbinit=.gdbinit
1681     ;;
1682 esac
1683 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1684
1685 dnl Handle optional features that can be enabled.
1686
1687 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1688 # except that the argument to --with-sysroot is optional.
1689 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1690 if test "x$with_sysroot" = xyes; then
1691   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1692 fi
1693 AC_ARG_WITH(sysroot,
1694   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1695                  [search for usr/lib et al within DIR]),
1696   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1697 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1698               [search for usr/lib et al within DIR])
1699 AC_SUBST(TARGET_SYSTEM_ROOT)
1700 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1701
1702 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1703     [automatically load a system-wide gdbinit file],
1704     [])
1705 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1706     [automatically load system-wide gdbinit files from this directory],
1707     [])
1708
1709 AM_GDB_WARNINGS
1710 AM_GDB_UBSAN
1711
1712 # In the Cygwin environment, we need some additional flags.
1713 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1714 [AC_EGREP_CPP(^lose$, [
1715 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1716 lose
1717 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1718
1719
1720 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1721 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1722 case ${host} in
1723   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1724   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1725   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1726   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1727 esac
1728 AC_SUBST(SER_HARDWIRE)
1729
1730 # libreadline needs libuser32.a in a cygwin environment
1731 WIN32LIBS=
1732 if test x"$gdb_cv_os_cygwin" = xyes; then
1733     WIN32LIBS="-luser32"
1734     case "${target}" in
1735         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1736         ;;
1737     esac
1738 fi
1739
1740 # The ser-tcp.c module requires sockets.
1741 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1742 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1743
1744 # Add ELF support to GDB, but only if BFD includes ELF support.
1745 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1746                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1747 if test "$gdb_cv_var_elf" = yes; then
1748   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1749   AC_DEFINE(HAVE_ELF, 1,
1750             [Define if ELF support should be included.])
1751   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1752   if test "$plugins" = "yes"; then
1753     AC_SEARCH_LIBS(dlopen, dl)
1754   fi
1755 fi
1756
1757 # Add macho support to GDB, but only if BFD includes it.
1758 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1759                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1760 if test "$gdb_cv_var_macho" = yes; then
1761   CONFIG_OBS="$CONFIG_OBS machoread.o"
1762 fi
1763
1764 # Add any host-specific objects to GDB.
1765 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1766
1767 # If building on ELF, look for lzma support for embedded compressed debug info.
1768 if test "$gdb_cv_var_elf" = yes; then
1769   AC_ARG_WITH(lzma,
1770     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1771     [], [with_lzma=auto])
1772   AC_MSG_CHECKING([whether to use lzma])
1773   AC_MSG_RESULT([$with_lzma])
1774
1775   if test "${with_lzma}" != no; then
1776     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1777                           [lzma_index_iter iter;
1778                            lzma_index_iter_init (&iter, 0);
1779                            lzma_mf_is_supported (LZMA_MF_HC3);])
1780     if test "$HAVE_LIBLZMA" != yes; then
1781       if test "$with_lzma" = yes; then
1782         AC_MSG_ERROR([missing liblzma for --with-lzma])
1783       fi
1784     fi
1785   fi
1786 fi
1787
1788 LIBGUI="../libgui/src/libgui.a"
1789 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1790 AC_SUBST(LIBGUI)
1791 AC_SUBST(GUI_CFLAGS_X)
1792
1793 WIN32LDAPP=
1794 AC_SUBST(WIN32LIBS)
1795 AC_SUBST(WIN32LDAPP)
1796
1797 case "${host}" in
1798 *-*-cygwin* | *-*-mingw* )
1799     configdir="win"
1800     ;;
1801 *)
1802     configdir="unix"
1803     ;;
1804 esac
1805
1806 GDBTKLIBS=
1807 if test "${enable_gdbtk}" = "yes"; then
1808
1809     # Gdbtk must have an absolute path to srcdir in order to run
1810     # properly when not installed.
1811     here=`pwd`
1812     cd ${srcdir}
1813     GDBTK_SRC_DIR=`pwd`
1814     cd $here
1815
1816     SC_PATH_TCLCONFIG
1817
1818     # If $no_tk is nonempty, then we can't do Tk, and there is no
1819     # point to doing Tcl.
1820     SC_PATH_TKCONFIG
1821
1822     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1823         SC_LOAD_TCLCONFIG
1824
1825         # Check for in-tree tcl
1826         here=`pwd`
1827         cd ${srcdir}/..
1828         topdir=`pwd`
1829         cd ${here}
1830
1831         intree="no"
1832         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1833           intree="yes"
1834         fi
1835
1836         # Find Tcl private headers
1837         if test x"${intree}" = xno; then
1838           CY_AC_TCL_PRIVATE_HEADERS
1839           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1840           TCL_LIBRARY="${TCL_LIB_SPEC}"
1841           TCL_DEPS=""
1842         else
1843           # If building tcl in the same src tree, private headers
1844           # are not needed, but we need to be sure to use the right
1845           # headers library
1846           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1847           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1848           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1849         fi
1850         AC_SUBST(TCL_INCLUDE)
1851         AC_SUBST(TCL_LIBRARY)
1852         AC_SUBST(TCL_DEPS)
1853
1854         SC_LOAD_TKCONFIG
1855
1856         # Check for in-tree Tk
1857         intree="no"
1858         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1859           intree="yes"
1860         fi
1861
1862         # Find Tk private headers
1863         if test x"${intree}" = xno; then
1864           CY_AC_TK_PRIVATE_HEADERS
1865           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1866           TK_LIBRARY=${TK_LIB_SPEC}
1867           TK_DEPS=""
1868         else
1869           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1870           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1871           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1872         fi
1873         AC_SUBST(TK_INCLUDE)
1874         AC_SUBST(TK_LIBRARY)
1875         AC_SUBST(TK_DEPS)
1876         AC_SUBST(TK_XINCLUDES)
1877
1878         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1879
1880         # Include some libraries that Tcl and Tk want.
1881         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1882         # Yes, the ordering seems wrong here.  But it isn't.
1883         # TK_LIBS is the list of libraries that need to be linked
1884         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1885         # were in LIBS then any link tests after this point would
1886         # try to include things like `$(LIBGUI)', which wouldn't work.
1887         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1888
1889         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1890         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1891         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1892         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1893         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1894         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1895         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1896
1897         if test x"$gdb_cv_os_cygwin" = xyes; then
1898           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1899           WIN32LDAPP="-Wl,--subsystem,console"
1900           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1901         fi
1902
1903         AC_CONFIG_SUBDIRS(gdbtk)
1904     fi
1905 fi
1906
1907 AC_SUBST(X_CFLAGS)
1908 AC_SUBST(X_LDFLAGS)
1909 AC_SUBST(X_LIBS)
1910 AC_SUBST(GDBTKLIBS)
1911 AC_SUBST(GDBTK_CFLAGS)
1912 AC_SUBST(GDBTK_SRC_DIR)
1913
1914 AC_PATH_X
1915
1916 # Unlike the sim directory, whether a simulator is linked is controlled by
1917 # presence of a gdb_sim definition in the target configure.tgt entry.
1918 # This code just checks for a few cases where we'd like to ignore those
1919 # definitions, even when they're present in the '.mt' file.  These cases
1920 # are when --disable-sim is specified, or if the simulator directory is
1921 # not part of the source tree.
1922 #
1923 AC_ARG_ENABLE(sim,
1924 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1925 [echo "enable_sim = $enable_sim";
1926  echo "enableval = ${enableval}";
1927  case "${enableval}" in
1928   yes) ignore_sim=false ;;
1929   no)  ignore_sim=true ;;
1930   *)   ignore_sim=false ;;
1931  esac],
1932 [ignore_sim=false])
1933
1934 if test ! -d "${srcdir}/../sim"; then
1935   ignore_sim=true
1936 fi
1937
1938 SIM=
1939 SIM_OBS=
1940 if test "${ignore_sim}" = "false"; then
1941   if test x"${gdb_sim}" != x ; then
1942     SIM="${gdb_sim}"
1943     SIM_OBS="remote-sim.o"
1944     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1945
1946     # Some tdep code should only be compiled in when the ppc sim is
1947     # built.  PR sim/13418.
1948     case $target in
1949       powerpc*-*-*)
1950         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
1951         ;;
1952     esac
1953   fi
1954 fi
1955 AC_SUBST(SIM)
1956 AC_SUBST(SIM_OBS)
1957
1958 AC_SUBST(ENABLE_CFLAGS)
1959 AC_SUBST(PROFILE_CFLAGS)
1960
1961 AC_SUBST(CONFIG_OBS)
1962 AC_SUBST(CONFIG_DEPS)
1963 AC_SUBST(CONFIG_SRCS)
1964 AC_SUBST(CONFIG_ALL)
1965 AC_SUBST(CONFIG_CLEAN)
1966 AC_SUBST(CONFIG_INSTALL)
1967 AC_SUBST(CONFIG_UNINSTALL)
1968
1969 # List of host floatformats.
1970 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1971 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1972 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1973
1974 # target_subdir is used by the testsuite to find the target libraries.
1975 target_subdir=
1976 if test "${host}" != "${target}"; then
1977     target_subdir="${target_alias}/"
1978 fi
1979 AC_SUBST(target_subdir)
1980
1981 # Import nat definitions.
1982 nat_makefile_frag=/dev/null
1983 if test "${gdb_native}" = "yes"; then
1984   . ${srcdir}/configure.nat
1985   nativefile=$NAT_FILE
1986 fi
1987
1988 AC_SUBST(NAT_FILE)
1989 AC_SUBST(NATDEPFILES)
1990 AC_SUBST(NAT_CDEPS)
1991 AC_SUBST(LOADLIBES)
1992 AC_SUBST(MH_CFLAGS)
1993 AC_SUBST(XM_CLIBS)
1994 AC_SUBST(NAT_GENERATED_FILES)
1995 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
1996 AC_SUBST_FILE(nat_makefile_frag)
1997
1998 if test x"${gdb_osabi}" != x ; then
1999     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2000                        [Define to the default OS ABI for this configuration.])
2001 fi
2002
2003 # Check for babeltrace and babeltrace-ctf
2004 AC_ARG_WITH(babeltrace,
2005   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2006   [], [with_babeltrace=auto])
2007 AC_MSG_CHECKING([whether to use babeltrace])
2008 AC_MSG_RESULT([$with_babeltrace])
2009
2010 if test "x$with_babeltrace" = "xno"; then
2011   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2012 else
2013   # Append -Werror to CFLAGS so that configure can catch the warning
2014   # "assignment from incompatible pointer type", which is related to
2015   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2016   # in GDB, while babeltrace 1.0.3 is broken.
2017   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2018   # safe to save and restore CFLAGS here.
2019   saved_CFLAGS=$CFLAGS
2020   CFLAGS="$CFLAGS -Werror"
2021   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2022                         [#include <babeltrace/babeltrace.h>
2023                          #include <babeltrace/ctf/events.h>
2024                          #include <babeltrace/ctf/iterator.h>],
2025                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2026                         struct bt_ctf_event *event = NULL;
2027                         const struct bt_definition *scope;
2028
2029                         pos->type = BT_SEEK_BEGIN;
2030                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2031                         scope = bt_ctf_get_top_level_scope (event,
2032                                                            BT_STREAM_EVENT_HEADER);
2033                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2034                         ])
2035   CFLAGS=$saved_CFLAGS
2036
2037   if test "$HAVE_LIBBABELTRACE" != yes; then
2038      if test "$with_babeltrace" = yes; then
2039        AC_MSG_ERROR([babeltrace is missing or unusable])
2040      else
2041        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2042      fi
2043   fi
2044 fi
2045
2046 # Check for xxhash
2047 AC_ARG_WITH(xxhash,
2048   AC_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2049   [], [with_xxhash=auto])
2050
2051 if test "x$with_xxhash" != "xno"; then
2052   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2053                         [#include <xxhash.h>],
2054                         [XXH32("foo", 3, 0);
2055                         ])
2056   if test "$HAVE_LIBXXHASH" != yes; then
2057     if test "$with_xxhash" = yes; then
2058       AC_MSG_ERROR([xxhash is missing or unusable])
2059     fi
2060   fi
2061   if test "x$with_xxhash" = "xauto"; then
2062     with_xxhash="$HAVE_LIBXXHASH"
2063   fi
2064 fi
2065
2066 AC_MSG_CHECKING([whether to use xxhash])
2067 AC_MSG_RESULT([$with_xxhash])
2068
2069 NM_H=
2070 rm -f nm.h
2071 if test "${nativefile}" != ""; then
2072     case "${nativefile}" in
2073       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2074       * ) GDB_NM_FILE="${nativefile}"
2075     esac
2076     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2077                     [GDB_NM_FILE=$GDB_NM_FILE])
2078     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2079     NM_H=nm.h
2080 fi
2081 AC_SUBST(GDB_NM_FILE)
2082 AC_SUBST(NM_H)
2083
2084 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2085 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2086 if test "x$USE_MAINTAINER_MODE" = xyes; then
2087   if test "${XSLTPROC}" = missing; then
2088     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2089   fi
2090 fi
2091 AC_SUBST(XSLTPROC)
2092
2093 dnl Check for exe extension set on certain hosts (e.g. Win32)
2094 AC_EXEEXT
2095
2096 dnl  Detect the character set used by this host.
2097 dnl  At the moment, we just assume it's UTF-8.
2098 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2099           [Define to be a string naming the default host character set.])
2100
2101 GDB_AC_SELFTEST([
2102   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) selftest-arch.o"
2103   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) selftest-arch.c"
2104 ])
2105
2106 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2107 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2108 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2109 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2110
2111 AC_OUTPUT