gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2015 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # See if we are building with C++, and substitute COMPILER.
  42 GDB_AC_BUILD_WITH_CXX
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 # Check for the 'make' the user wants to use.
  49 AC_CHECK_PROGS(MAKE, make)
  50 MAKE_IS_GNU=
  51 case "`$MAKE --version 2>&1 | sed 1q`" in
  52   *GNU*)
  53     MAKE_IS_GNU=yes
  54     ;;
  55 esac
  56 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  57 AC_PROG_MAKE_SET
  58
  59 gnulib_extra_configure_args=
  60 # If large-file support is disabled, make sure gnulib does the same.
  61 if test "$enable_largefile" = no; then
  62 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  63 fi
  64
  65 # Configure gnulib.  We need to build gnulib under some other
  66 # directory not "gnulib", to avoid the problem of both GDB and
  67 # GDBserver wanting to build it in the same directory, when building
  68 # in the source dir.
  69 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  70                   ["$gnulib_extra_configure_args"])
  71
  72 dnl List of object files and targets accumulated by configure.
  73
  74 CONFIG_OBS=
  75 CONFIG_DEPS=
  76 CONFIG_SRCS=
  77 ENABLE_CFLAGS=
  78
  79 CONFIG_ALL=
  80 CONFIG_CLEAN=
  81 CONFIG_INSTALL=
  82 CONFIG_UNINSTALL=
  83
  84 dnl Set up for gettext.
  85 ZW_GNU_GETTEXT_SISTER_DIR
  86
  87 localedir='${datadir}/locale'
  88 AC_SUBST(localedir)
  89
  90 if test x"$USE_NLS" = xyes; then
  91    CONFIG_ALL="$CONFIG_ALL all-po"
  92    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  93    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  94    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  95 fi
  96
  97 GNULIB=build-gnulib/import
  98
  99 # For Makefile dependencies.
 100 GNULIB_STDINT_H=
 101 if test x"$STDINT_H" != x; then
 102   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 103 fi
 104 AC_SUBST(GNULIB_STDINT_H)
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 # We never need to detect it in this sub-configure.
 111 # But preserve it for config.status --recheck.
 112 AC_ARG_VAR(MAKEINFO,
 113   [Parent configure detects if it is of sufficient version.])
 114 AC_ARG_VAR(MAKEINFOFLAGS,
 115   [Parameters for MAKEINFO.])
 116
 117 MAKEINFO_EXTRA_FLAGS=""
 118 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 119   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 120   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 121     gdb_cv_have_makeinfo_click=yes
 122   else
 123     gdb_cv_have_makeinfo_click=no
 124   fi])
 125 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 126   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 127 fi
 128 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 129
 130 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 131     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 132     [${libdir}/debug])
 133
 134 # We can't pass paths as command line arguments.
 135 # Mingw32 tries to be clever and will convert the paths for us.
 136 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 137 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 138 # This breaks GDB's relocatable path conversions since paths passed in
 139 # config.h would not get so translated, the path prefixes no longer match.
 140 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 141
 142 # GDB's datadir relocation
 143
 144 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 145     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 146     [${datadir}/gdb])
 147
 148 AC_ARG_WITH(relocated-sources,
 149 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 150 [reloc_srcdir="${withval}"
 151  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 152               [Relocated directory for source files. ])
 153 ])
 154
 155 AC_MSG_CHECKING([for default auto-load directory])
 156 AC_ARG_WITH(auto-load-dir,
 157 AS_HELP_STRING([--with-auto-load-dir=PATH],
 158   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 159   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 160 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 161 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 162               [Directories from which to load auto-loaded scripts.])
 163 AC_MSG_RESULT([$with_auto_load_dir])
 164
 165 AC_MSG_CHECKING([for default auto-load safe-path])
 166 AC_ARG_WITH(auto-load-safe-path,
 167 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 168   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 169 AS_HELP_STRING([--without-auto-load-safe-path],
 170                [do not restrict auto-loaded files locations]),
 171     [if test "$with_auto_load_safe_path" = "no"; then
 172      with_auto_load_safe_path="/"
 173      fi],
 174 [with_auto_load_safe_path="$with_auto_load_dir"])
 175 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 176 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 177               [Directories safe to hold auto-loaded files.])
 178 AC_MSG_RESULT([$with_auto_load_safe_path])
 179
 180 AC_CONFIG_SUBDIRS(testsuite)
 181
 182 # Check whether to support alternative target configurations
 183 AC_ARG_ENABLE(targets,
 184 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 185 [case "${enableval}" in
 186   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 187             ;;
 188   no)       enable_targets= ;;
 189   *)        enable_targets=$enableval ;;
 190 esac])
 191
 192 # Check whether to enable 64-bit support on 32-bit hosts
 193 AC_ARG_ENABLE(64-bit-bfd,
 194 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 195 [case "${enableval}" in
 196   yes)  want64=true  ;;
 197   no)   want64=false ;;
 198   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 199 esac],[want64=false])dnl
 200
 201 # Provide defaults for some variables set by the per-host and per-target
 202 # configuration.
 203 gdb_host_obs=posix-hdep.o
 204
 205 if test "${target}" = "${host}"; then
 206   gdb_native=yes
 207 else
 208   gdb_native=no
 209 fi
 210
 211 . $srcdir/configure.host
 212
 213 # Add in the common host objects.
 214 . $srcdir/common/common.host
 215 gdb_host_obs="$gdb_host_obs $common_host_obs"
 216
 217 # Accumulate some settings from configure.tgt over all enabled targets
 218
 219 TARGET_OBS=
 220 all_targets=
 221 HAVE_NATIVE_GCORE_TARGET=
 222
 223 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 224 do
 225   if test "$targ_alias" = "all"; then
 226     all_targets=true
 227   else
 228     # Canonicalize the secondary target names.
 229     result=`$ac_config_sub $targ_alias 2>/dev/null`
 230     if test -n "$result"; then
 231         targ=$result
 232     else
 233         targ=$targ_alias
 234     fi
 235
 236     . ${srcdir}/configure.tgt
 237
 238     AS_IF([test -z "${gdb_target_obs}"],
 239       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 240
 241     # Target-specific object files
 242     for i in ${gdb_target_obs}; do
 243         case " $TARGET_OBS " in
 244         *" ${i} "*) ;;
 245         *)
 246           TARGET_OBS="$TARGET_OBS ${i}"
 247           ;;
 248         esac
 249     done
 250
 251     # Check whether this target needs 64-bit CORE_ADDR
 252     if test x${want64} = xfalse; then
 253       . ${srcdir}/../bfd/config.bfd
 254     fi
 255
 256     # Check whether this target is native and supports gcore.
 257     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 258        && $gdb_have_gcore; then
 259       HAVE_NATIVE_GCORE_TARGET=1
 260     fi
 261   fi
 262 done
 263
 264 if test x${all_targets} = xtrue; then
 265
 266   # We want all 64-bit targets if we either:
 267   #  - run on a 64-bit host  or
 268   #  - already require 64-bit support for some other target  or
 269   #  - the --enable-64-bit-bfd option was supplied
 270   # Otherwise we only support all 32-bit targets.
 271   #
 272   # NOTE: This test must be in sync with the corresponding
 273   #       tests in BFD!
 274
 275   if test x${want64} = xfalse; then
 276     AC_CHECK_SIZEOF(long)
 277     if test "x${ac_cv_sizeof_long}" = "x8"; then
 278       want64=true
 279     fi
 280   fi
 281   if test x${want64} = xtrue; then
 282     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 283   else
 284     TARGET_OBS='$(ALL_TARGET_OBS)'
 285   fi
 286 fi
 287
 288 AC_SUBST(TARGET_OBS)
 289 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 290
 291 # For other settings, only the main target counts.
 292 gdb_sim=
 293 gdb_osabi=
 294 build_gdbserver=
 295 targ=$target; . ${srcdir}/configure.tgt
 296
 297 # Fetch the default architecture and default target vector from BFD.
 298 targ=$target; . $srcdir/../bfd/config.bfd
 299
 300 # We only want the first architecture, so strip off the others if
 301 # there is more than one.
 302 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 303
 304 if test "x$targ_archs" != x; then
 305   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 306     [Define to BFD's default architecture. ])
 307 fi
 308 if test "x$targ_defvec" != x; then
 309   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 310     [Define to BFD's default target vector. ])
 311 fi
 312
 313 # The CLI cannot be disabled yet, but may be in the future.
 314
 315 # Enable CLI.
 316 AC_ARG_ENABLE(gdbcli,
 317 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 318   [case $enableval in
 319     yes)
 320       ;;
 321     no)
 322       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 323     *)
 324       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 325   esac],
 326   [enable_gdbcli=yes])
 327 if test x"$enable_gdbcli" = xyes; then
 328   if test -d $srcdir/cli; then
 329     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 330     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 331     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 332     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 333   fi
 334 fi
 335
 336 # Enable MI.
 337 AC_ARG_ENABLE(gdbmi,
 338 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 339   [case $enableval in
 340     yes | no)
 341       ;;
 342     *)
 343       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 344   esac],
 345   [enable_gdbmi=yes])
 346 if test x"$enable_gdbmi" = xyes; then
 347   if test -d $srcdir/mi; then
 348     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 349     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 350     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 351     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 352   fi
 353 fi
 354
 355 # Enable TUI.
 356 AC_ARG_ENABLE(tui,
 357 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 358   [case $enableval in
 359     yes | no | auto)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 363   esac],enable_tui=auto)
 364
 365 # Enable gdbtk.
 366 AC_ARG_ENABLE(gdbtk,
 367 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 368   [case $enableval in
 369     yes | no)
 370       ;;
 371     *)
 372       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 373   esac],
 374   [if test -d $srcdir/gdbtk; then
 375     enable_gdbtk=yes
 376   else
 377     enable_gdbtk=no
 378   fi])
 379 # We unconditionally disable gdbtk tests on selected platforms.
 380 case $host_os in
 381   go32* | windows*)
 382     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 383     enable_gdbtk=no ;;
 384 esac
 385
 386 # Libunwind support for ia64.
 387
 388 AC_ARG_WITH(libunwind-ia64,
 389 AS_HELP_STRING([--with-libunwind-ia64],
 390                [use libunwind frame unwinding for ia64 targets]),,
 391             [with_libunwind_ia64=auto])
 392
 393 # Backward compatibility option.
 394 if test "${with_libunwind+set}" = set; then
 395   if test x"$with_libunwind_ia64" != xauto; then
 396     AC_MSG_ERROR(
 397       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 398   fi
 399   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 400   with_libunwind_ia64="$with_libunwind"
 401 fi
 402
 403 case "$with_libunwind_ia64" in
 404   yes | no)
 405     ;;
 406   auto)
 407     AC_CHECK_HEADERS(libunwind-ia64.h)
 408     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 409     ;;
 410   *)
 411     AC_MSG_ERROR(
 412       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 413     ;;
 414 esac
 415
 416 if test x"$with_libunwind_ia64" = xyes; then
 417   AC_CHECK_HEADERS(libunwind-ia64.h)
 418   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 419     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 420   fi
 421   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 422   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 423   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 424 fi
 425
 426 opt_curses=no
 427 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 428
 429 prefer_curses=no
 430 if test "$opt_curses" = "yes"; then
 431   prefer_curses=yes
 432 fi
 433
 434 # Profiling support.
 435 AC_ARG_ENABLE(profiling,
 436 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 437   [case $enableval in
 438     yes | no)
 439       ;;
 440     *)
 441       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 442   esac],
 443  [enable_profiling=no])
 444
 445 AC_CHECK_FUNCS(monstartup _mcleanup)
 446 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char _etext;
 450 ],
 451 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 452 if test $ac_cv_var__etext = yes; then
 453   AC_DEFINE(HAVE__ETEXT, 1,
 454             [Define to 1 if your system has the _etext variable. ])
 455 fi
 456 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 457 [AC_TRY_LINK(
 458 [#include <stdlib.h>
 459 extern char etext;
 460 ],
 461 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 462 if test $ac_cv_var_etext = yes; then
 463   AC_DEFINE(HAVE_ETEXT, 1,
 464             [Define to 1 if your system has the etext variable. ])
 465 fi
 466 if test "$enable_profiling" = yes ; then
 467   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 468     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 469   fi
 470   PROFILE_CFLAGS=-pg
 471   OLD_CFLAGS="$CFLAGS"
 472   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 473
 474   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 475     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 476      ac_cv_cc_supports_pg=no)])
 477
 478   if test $ac_cv_cc_supports_pg = no; then
 479     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 480   fi
 481
 482   CFLAGS="$OLD_CFLAGS"
 483 fi
 484
 485 ACX_PKGVERSION([GDB])
 486 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 487 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 488 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 489
 490 # --------------------- #
 491 # Checks for programs.  #
 492 # --------------------- #
 493
 494 AC_PROG_AWK
 495 AC_PROG_INSTALL
 496 AC_PROG_LN_S
 497 AC_PROG_RANLIB
 498 AC_PROG_YACC
 499
 500 AC_CHECK_TOOL(AR, ar)
 501 AC_CHECK_TOOL(DLLTOOL, dlltool)
 502 AC_CHECK_TOOL(WINDRES, windres)
 503
 504 case $host_os in
 505   gnu*)
 506     # Needed for GNU Hurd hosts.
 507     AC_CHECK_TOOL(MIG, mig)
 508     if test x"$MIG" = x; then
 509       AC_MSG_ERROR([MIG not found but required for $host hosts])
 510     fi
 511     ;;
 512 esac
 513
 514 # ---------------------- #
 515 # Checks for libraries.  #
 516 # ---------------------- #
 517
 518 # We might need to link with -lm; most simulators need it.
 519 AC_CHECK_LIB(m, main)
 520
 521 # We need to link with -lw to get `wctype' on Solaris before Solaris
 522 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 523 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 524 # is known to have this problem).  Therefore we avoid libw if we can.
 525 AC_CHECK_FUNC(wctype, [],
 526   [AC_CHECK_LIB(w, wctype)])
 527
 528 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 529 AC_SEARCH_LIBS(gethostbyname, nsl)
 530
 531 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 532 AC_SEARCH_LIBS(socketpair, socket)
 533
 534 # Link in zlib if we can.  This allows us to read compressed debug sections.
 535 AM_ZLIB
 536
 537 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 538 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 539
 540 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 541 AC_SEARCH_LIBS(kinfo_getvmmap, util,
 542   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 543             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 544
 545 AM_ICONV
 546
 547 # GDB may fork/exec the iconv program to get the list of supported character
 548 # sets.  Allow the user to specify where to find it.
 549 # There are several factors affecting the choice of option name:
 550 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 551 #   the build-time location of libiconv files.
 552 # - The program we need to find is iconv, which comes with glibc.  The user
 553 #   doesn't necessarily have libiconv installed.  Therefore naming this
 554 #   --with-libiconv-foo feels wrong.
 555 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 556 #   defined to work on directories not files (though it really doesn't know
 557 #   the difference).
 558 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 559 #   with --with-libiconv-prefix.
 560 # Putting these together is why the option name is --with-iconv-bin.
 561
 562 AC_ARG_WITH(iconv-bin,
 563 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 564 [iconv_bin="${withval}"
 565  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 566                     [Path of directory of iconv program.])
 567  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 568 ])
 569
 570 # For the TUI, we need enhanced curses functionality.
 571 if test x"$enable_tui" != xno; then
 572   prefer_curses=yes
 573 fi
 574
 575 curses_found=no
 576 if test x"$prefer_curses" = xyes; then
 577   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 578   # curses library because the latter might not provide all the
 579   # functionality we need.  However, this leads to problems on systems
 580   # where the linker searches /usr/local/lib, but the compiler doesn't
 581   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 582   # default installation of ncurses on alpha*-dec-osf* will lead to such
 583   # a situation.
 584   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 585
 586   if test "$ac_cv_search_waddstr" != no; then
 587     curses_found=yes
 588   fi
 589 fi
 590
 591 # Check whether we should enable the TUI, but only do so if we really
 592 # can.
 593 if test x"$enable_tui" != xno; then
 594   if test -d $srcdir/tui; then
 595     if test "$curses_found" != no; then
 596       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 597       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 598       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 599       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 600     else
 601       if test x"$enable_tui" = xyes; then
 602         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 603       else
 604         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 605       fi
 606     fi
 607   fi
 608 fi
 609
 610 # Since GDB uses Readline, we need termcap functionality.  In many
 611 # cases this will be provided by the curses library, but some systems
 612 # have a seperate termcap library, or no curses library at all.
 613
 614 case $host_os in
 615   cygwin*)
 616     if test -d $srcdir/libtermcap; then
 617       LIBS="../libtermcap/libtermcap.a $LIBS"
 618       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 619     fi ;;
 620   go32* | *djgpp*)
 621     ac_cv_search_tgetent="none required"
 622     ;;
 623   *mingw32*)
 624     if test x"$curses_found" != xyes; then
 625       ac_cv_search_tgetent="none required"
 626       CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 627     fi ;;
 628 esac
 629
 630 # These are the libraries checked by Readline.
 631 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 632
 633 if test "$ac_cv_search_tgetent" = no; then
 634   AC_MSG_ERROR([no termcap library found])
 635 fi
 636
 637 AC_ARG_WITH([system-readline],
 638   [AS_HELP_STRING([--with-system-readline],
 639                   [use installed readline library])])
 640
 641 if test "$with_system_readline" = yes; then
 642   READLINE=-lreadline
 643   READLINE_DEPS=
 644   READLINE_CFLAGS=
 645   READLINE_TEXI_INCFLAG=
 646 else
 647   READLINE='$(READLINE_DIR)/libreadline.a'
 648   READLINE_DEPS='$(READLINE)'
 649   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 650   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 651 fi
 652 AC_SUBST(READLINE)
 653 AC_SUBST(READLINE_DEPS)
 654 AC_SUBST(READLINE_CFLAGS)
 655 AC_SUBST(READLINE_TEXI_INCFLAG)
 656
 657 # Generate jit-reader.h
 658
 659 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 660 TARGET_PTR=
 661
 662 AC_CHECK_SIZEOF(unsigned long long)
 663 AC_CHECK_SIZEOF(unsigned long)
 664 AC_CHECK_SIZEOF(unsigned __int128)
 665
 666 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 667   TARGET_PTR="unsigned long"
 668 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 669   TARGET_PTR="unsigned long long"
 670 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 671   TARGET_PTR="unsigned __int128"
 672 else
 673   TARGET_PTR="unsigned long"
 674 fi
 675
 676 AC_SUBST(TARGET_PTR)
 677 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 678
 679 AC_SEARCH_LIBS(dlopen, dl)
 680
 681 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 682                 [directory to load the JIT readers from],
 683                 [${libdir}/gdb])
 684
 685 AC_ARG_WITH(expat,
 686   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 687   [], [with_expat=auto])
 688 AC_MSG_CHECKING([whether to use expat])
 689 AC_MSG_RESULT([$with_expat])
 690
 691 if test "${with_expat}" = no; then
 692   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 693   HAVE_LIBEXPAT=no
 694 else
 695   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 696                         [XML_Parser p = XML_ParserCreate (0);])
 697   if test "$HAVE_LIBEXPAT" != yes; then
 698     if test "$with_expat" = yes; then
 699       AC_MSG_ERROR([expat is missing or unusable])
 700     else
 701       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 702     fi
 703   else
 704     save_LIBS=$LIBS
 705     LIBS="$LIBS $LIBEXPAT"
 706     AC_CHECK_FUNCS(XML_StopParser)
 707     LIBS=$save_LIBS
 708   fi
 709 fi
 710
 711 # --------------------- #
 712 # Check for libpython.  #
 713 # --------------------- #
 714
 715 dnl Utility to simplify finding libpython.
 716 dnl $1 = pythonX.Y
 717 dnl $2 = the shell variable to assign the result to
 718 dnl      If libpython is found we store $version here.
 719 dnl $3 = additional flags to add to CPPFLAGS
 720 dnl $4 = additional flags to add to LIBS
 721
 722 AC_DEFUN([AC_TRY_LIBPYTHON],
 723 [
 724   version=$1
 725   define([have_libpython_var],$2)
 726   new_CPPFLAGS=$3
 727   new_LIBS=$4
 728   AC_MSG_CHECKING([for ${version}])
 729   save_CPPFLAGS=$CPPFLAGS
 730   save_LIBS=$LIBS
 731   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 732   LIBS="$LIBS $new_LIBS"
 733   found_usable_python=no
 734   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 735                                  [[Py_Initialize ();]]),
 736                  [have_libpython_var=${version}
 737                   found_usable_python=yes
 738                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 739                   PYTHON_LIBS=$new_LIBS])
 740   CPPFLAGS=$save_CPPFLAGS
 741   LIBS=$save_LIBS
 742   AC_MSG_RESULT([${found_usable_python}])
 743 ])
 744
 745 dnl There are several different values for --with-python:
 746 dnl
 747 dnl no -   Don't include python support.
 748 dnl yes -  Include python support, error if it's missing.
 749 dnl        If we find python in $PATH, use it to fetch configure options,
 750 dnl        otherwise assume the compiler can find it with no help from us.
 751 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 752 dnl auto - Same as "yes", but if python is missing from the system,
 753 dnl        fall back to "no".
 754 dnl /path/to/python/exec-prefix -
 755 dnl        Use the python located in this directory.
 756 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 757 dnl        the compilation parameters.  Otherwise use
 758 dnl        -I/path/to/python/exec-prefix/include,
 759 dnl        -L/path/to/python/exec-prefix/lib.
 760 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 761 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 762 dnl        but is deprecated.
 763 dnl /path/to/python/executable -
 764 dnl        Run python-config.py with this version of python to fetch the
 765 dnl        compilation parameters.
 766 dnl        NOTE: This needn't be the real python executable.
 767 dnl        In a cross-compilation scenario (build != host), this could be
 768 dnl        a shell script that provides what python-config.py provides for
 769 dnl        --ldflags, --includes, --exec-prefix.
 770 dnl python-executable -
 771 dnl        Find python-executable in $PATH, and then handle the same as
 772 dnl        /path/to/python/executable.
 773 dnl
 774 dnl If a python program is specified, it is used to run python-config.py and
 775 dnl is passed --ldflags, --includes, --exec-prefix.
 776
 777 AC_ARG_WITH(python,
 778   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 779   [], [with_python=auto])
 780 AC_MSG_CHECKING([whether to use python])
 781 AC_MSG_RESULT([$with_python])
 782
 783 if test "${with_python}" = no; then
 784   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 785   have_libpython=no
 786 else
 787   case "${with_python}" in
 788   [[\\/]]* | ?:[[\\/]]*)
 789     if test -d ${with_python}; then
 790       # Assume the python binary is ${with_python}/bin/python.
 791       python_prog="${with_python}/bin/python"
 792       python_prefix=
 793       # If python does not exit ${with_python}/bin, then try in
 794       # ${with_python}.  On Windows/MinGW, this is where the Python
 795       # executable is.
 796       if test ! -x "${python_prog}"; then
 797         python_prog="${with_python}/python"
 798         python_prefix=
 799       fi
 800       if test ! -x "${python_prog}"; then
 801         # Fall back to gdb 7.0/7.1 behaviour.
 802         python_prog=missing
 803         python_prefix=${with_python}
 804       fi
 805     elif test -x "${with_python}"; then
 806       # While we can't run python compiled for $host (unless host == build),
 807       # the user could write a script that provides the needed information,
 808       # so we support that.
 809       python_prog=${with_python}
 810       python_prefix=
 811     else
 812       AC_ERROR(invalid value for --with-python)
 813     fi
 814     ;;
 815   */*)
 816     # Disallow --with-python=foo/bar.
 817     AC_ERROR(invalid value for --with-python)
 818     ;;
 819   *)
 820     # The user has either specified auto, yes, or the name of the python
 821     # program assumed to be in $PATH.
 822     python_prefix=
 823     case "${with_python}" in
 824     yes | auto)
 825       if test ${build} = ${host}; then
 826         AC_PATH_PROG(python_prog_path, python, missing)
 827         if test "${python_prog_path}" = missing; then
 828           python_prog=missing
 829         else
 830           python_prog=${python_prog_path}
 831         fi
 832       else
 833         # Not much we can do except assume the cross-compiler will find the
 834         # right files.
 835         python_prog=missing
 836       fi
 837       ;;
 838     *)
 839       # While we can't run python compiled for $host (unless host == build),
 840       # the user could write a script that provides the needed information,
 841       # so we support that.
 842       python_prog="${with_python}"
 843       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 844       if test "${python_prog_path}" = missing; then
 845         AC_ERROR(unable to find python program ${python_prog})
 846       fi
 847       ;;
 848     esac
 849   esac
 850
 851   if test "${python_prog}" != missing; then
 852     # We have a python program to use, but it may be too old.
 853     # Don't flag an error for --with-python=auto (the default).
 854     have_python_config=yes
 855     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 856     if test $? != 0; then
 857       have_python_config=failed
 858       if test "${with_python}" != auto; then
 859         AC_ERROR(failure running python-config --includes)
 860       fi
 861     fi
 862     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 863     if test $? != 0; then
 864       have_python_config=failed
 865       if test "${with_python}" != auto; then
 866         AC_ERROR(failure running python-config --ldflags)
 867       fi
 868     fi
 869     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 870     if test $? != 0; then
 871       have_python_config=failed
 872       if test "${with_python}" != auto; then
 873         AC_ERROR(failure running python-config --exec-prefix)
 874       fi
 875     fi
 876   else
 877     # We do not have a python executable we can use to determine where
 878     # to find the Python headers and libs.  We cannot guess the include
 879     # path from the python_prefix either, because that include path
 880     # depends on the Python version.  So, there is nothing much we can
 881     # do except assume that the compiler will be able to find those files.
 882     python_includes=
 883     python_libs=
 884     have_python_config=no
 885   fi
 886
 887   # If we have python-config, only try the configuration it provides.
 888   # Otherwise fallback on the old way of trying different versions of
 889   # python in turn.
 890
 891   have_libpython=no
 892   if test "${have_python_config}" = yes; then
 893     # Determine the Python version by extracting "-lpython<version>"
 894     # part of the python_libs. <version> is usually X.Y with X and Y
 895     # being decimal numbers, but can also be XY (seen on Windows).
 896     #
 897     # The extraction is performed using sed with a regular expression.
 898     # Initially, the regexp used was using the '?' quantifier to make
 899     # the dot in the version number optional.  Unfortunately, this
 900     # does not work with non-GNU versions of sed because, because of
 901     # what looks like a limitation (the '?' quantifier does not work
 902     # with back-references).  We work around this limitation by using
 903     # the '*' quantifier instead.  It means that, in theory, we might
 904     # match unexpected version strings such as "-lpython2..7", but
 905     # this seems unlikely in practice.  And even if that happens,
 906     # an error will be triggered later on, when checking that version
 907     # number.
 908     python_version=`echo " ${python_libs} " \
 909                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 910     case "${python_version}" in
 911     python*)
 912       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 913                        ${python_includes}, ${python_libs})
 914       ;;
 915     *)
 916       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 917       ;;
 918     esac
 919   elif test "${have_python_config}" != failed; then
 920     if test "${have_libpython}" = no; then
 921       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 922                        ${python_includes}, "${python_libs} -lpython2.7")
 923     fi
 924     if test "${have_libpython}" = no; then
 925       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 926                        ${python_includes}, "${python_libs} -lpython2.6")
 927     fi
 928     if test ${have_libpython} = no; then
 929       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 930                        ${python_includes}, "${python_libs} -lpython2.5")
 931     fi
 932     if test ${have_libpython} = no; then
 933       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 934                        ${python_includes}, "${python_libs} -lpython2.4")
 935     fi
 936   fi
 937   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 938     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 939   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 940     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 941   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 942     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 943   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 944     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 945   fi
 946
 947   if test "${have_libpython}" = no; then
 948     case "${with_python}" in
 949     yes)
 950       AC_MSG_ERROR([python is missing or unusable])
 951       ;;
 952     auto)
 953       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 954       ;;
 955     *)
 956       AC_MSG_ERROR([no usable python found at ${with_python}])
 957       ;;
 958     esac
 959   else
 960     if test -n "${python_prefix}"; then
 961       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 962                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 963       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 964     fi
 965   fi
 966 fi
 967
 968 if test "${have_libpython}" != no; then
 969   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 970   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 971   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 972   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 973   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 974   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 975
 976   # Flags needed to compile Python code (taken from python-config --cflags).
 977   # We cannot call python-config directly because it will output whatever was
 978   # used when compiling the Python interpreter itself, including flags which
 979   # would make the python-related objects be compiled differently from the
 980   # rest of GDB (e.g., -O2 and -fPIC).
 981   if test "${GCC}" = yes; then
 982     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 983   fi
 984
 985   if test "x${tentative_python_cflags}" != x; then
 986     AC_MSG_CHECKING(compiler flags for python code)
 987     for flag in ${tentative_python_cflags}; do
 988       # Check that the compiler accepts it
 989       saved_CFLAGS="$CFLAGS"
 990       CFLAGS="$CFLAGS $flag"
 991       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 992       CFLAGS="$saved_CFLAGS"
 993     done
 994     AC_MSG_RESULT(${PYTHON_CFLAGS})
 995   fi
 996
 997   # On x64 Windows, Python's include headers, and pyconfig.h in
 998   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 999   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1000   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1001   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1002   # The issue was reported to the Python community, but still isn't
1003   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1004
1005   case "$gdb_host" in
1006     mingw64)
1007            if test "${GCC}" = yes; then
1008              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1009            fi
1010            ;;
1011   esac
1012
1013   # Note that "python -m threading" cannot be used to check for
1014   # threading support due to a bug in Python 2.7.3
1015   # (http://bugs.python.org/issue15567).
1016   AC_MSG_CHECKING(whether python supports threads)
1017   saved_CPPFLAGS="${CPPFLAGS}"
1018   CPPFLAGS="${PYTHON_CPPFLAGS}"
1019   # Note that the test is reversed so that python_has_threads=yes on
1020   # unexpected failures.
1021   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1022 #include <Python.h>
1023 #ifdef WITH_THREAD
1024 # error
1025 #endif
1026   ]]), [python_has_threads=no], [python_has_threads=yes])
1027   AC_MSG_RESULT(${python_has_threads})
1028   CPPFLAGS="${saved_CPPFLAGS}"
1029 else
1030   # Even if Python support is not compiled in, we need to have this file
1031   # included so that the "python" command, et.al., still exists.
1032   CONFIG_OBS="$CONFIG_OBS python.o"
1033   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1034 fi
1035 AC_SUBST(PYTHON_CFLAGS)
1036 AC_SUBST(PYTHON_CPPFLAGS)
1037 AC_SUBST(PYTHON_LIBS)
1038 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1039
1040 # -------------------- #
1041 # Check for libguile.  #
1042 # -------------------- #
1043
1044 dnl Utility to simplify finding libguile.
1045 dnl $1 = pkg-config-program
1046 dnl $2 = space-separate list of guile versions to try
1047 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1048 dnl $4 = the shell variable to assign the result to
1049 dnl      If libguile is found we store "yes" here.
1050
1051 AC_DEFUN([AC_TRY_LIBGUILE],
1052 [
1053   pkg_config=$1
1054   guile_version_list=$2
1055   flag_errors=$3
1056   define([have_libguile_var],$4)
1057   found_usable_guile=checking
1058   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1059   for guile_version in ${guile_version_list}; do
1060     ${pkg_config} --exists ${guile_version} 2>/dev/null
1061     if test $? != 0; then
1062       continue
1063     fi
1064     dnl pkg-config says the package exists, so if we get an error now,
1065     dnl that's bad.
1066     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1067     if test $? != 0; then
1068       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1069     fi
1070     new_LIBS=`${pkg_config} --libs ${guile_version}`
1071     if test $? != 0; then
1072       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1073     fi
1074     dnl If we get this far, great.
1075     found_usable_guile=${guile_version}
1076     break
1077   done
1078   if test "${found_usable_guile}" = "checking"; then
1079     if test "${flag_errors}" = "yes"; then
1080       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1081     else
1082       found_usable_guile=no
1083     fi
1084   fi
1085   dnl One final sanity check.
1086   dnl The user could have said --with-guile=python-2.7.
1087   if test "${found_usable_guile}" != no; then
1088     save_CPPFLAGS=$CPPFLAGS
1089     save_LIBS=$LIBS
1090     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1091     LIBS="$LIBS $new_LIBS"
1092     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1093                                    [[scm_init_guile ();]]),
1094                    [have_libguile_var=yes
1095                     GUILE_CPPFLAGS=$new_CPPFLAGS
1096                     GUILE_LIBS=$new_LIBS],
1097                    [found_usable_guile=no])
1098     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1099     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1100       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1101                 [Define if Guile supports manual finalization.])
1102     )
1103     CPPFLAGS=$save_CPPFLAGS
1104     LIBS=$save_LIBS
1105     if test "${found_usable_guile}" = no; then
1106       if test "${flag_errors}" = yes; then
1107         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1108       fi
1109     fi
1110   fi
1111   AC_MSG_RESULT([${found_usable_guile}])
1112 ])
1113
1114 dnl There are several different values for --with-guile:
1115 dnl
1116 dnl no -   Don't include guile support.
1117 dnl yes -  Include guile support, error if it's missing.
1118 dnl        The pkg-config program must be in $PATH.
1119 dnl auto - Same as "yes", but if guile is missing from the system,
1120 dnl        fall back to "no".
1121 dnl guile-version [guile-version-choice-2 ...] -
1122 dnl        A space-separated list of guile package versions to try.
1123 dnl        These are passed to pkg-config as-is.
1124 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1125 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1126 dnl /path/to/pkg-config -
1127 dnl        Use this pkg-config program.
1128 dnl        NOTE: This needn't be the "real" pkg-config program.
1129 dnl        It could be a shell script.  It is invoked as:
1130 dnl        pkg-config --exists $version
1131 dnl        pkg-config --cflags $version
1132 dnl        pkg-config --libs $version
1133 dnl        pkg-config --variable guild $version
1134 dnl        The script will be called with $version having each value in
1135 dnl        $try_guile_versions until --exists indicates success.
1136
1137 AC_ARG_WITH(guile,
1138   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1139   [], [with_guile=auto])
1140 AC_MSG_CHECKING([whether to use guile])
1141 AC_MSG_RESULT([$with_guile])
1142
1143 dnl We check guile with pkg-config.
1144 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1145
1146 try_guile_versions="guile-2.2 guile-2.0"
1147 have_libguile=no
1148 case "${with_guile}" in
1149 no)
1150   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1151   ;;
1152 auto)
1153   if test "${pkg_config_prog_path}" = "missing"; then
1154     AC_MSG_WARN([pkg-config not found, guile support disabled])
1155   else
1156     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1157   fi
1158   ;;
1159 yes)
1160   if test "${pkg_config_prog_path}" = "missing"; then
1161     AC_MSG_ERROR([pkg-config not found])
1162   fi
1163   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1164   ;;
1165 [[\\/]]* | ?:[[\\/]]*)
1166   if test -x "${with_guile}"; then
1167     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1168   else
1169     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1170   fi
1171   ;;
1172 "" | */*)
1173   # Disallow --with=guile="" and --with-guile=foo/bar.
1174   AC_MSG_ERROR([invalid value for --with-guile])
1175   ;;
1176 *)
1177   # A space separate list of guile versions to try, in order.
1178   if test "${pkg_config_prog_path}" = "missing"; then
1179     AC_MSG_ERROR([pkg-config not found])
1180   fi
1181   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1182   ;;
1183 esac
1184
1185 if test "${have_libguile}" != no; then
1186   dnl Get the name of the 'guild' program.
1187   case "${with_guile}" in
1188   [[\\/]]* | ?:[[\\/]]*)
1189     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1190     ;;
1191   *)
1192     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1193     ;;
1194   esac
1195
1196   dnl Make sure guild can handle this host.
1197   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1198   dnl If not, disable guile support.
1199   if test "$ac_cv_guild_ok" = no; then
1200     have_libguile=no
1201     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1202   fi
1203 fi
1204
1205 if test "${have_libguile}" != no; then
1206   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1207   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1208   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1209   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1210   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1211   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1212
1213   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1214   save_LIBS="$LIBS"
1215   save_CPPFLAGS="$CPPFLAGS"
1216   LIBS="$GUILE_LIBS"
1217   CPPFLAGS="$GUILE_CPPFLAGS"
1218   AC_CHECK_FUNCS([scm_new_smob])
1219   LIBS="$save_LIBS"
1220   CPPFLAGS="$save_CPPFLAGS"
1221 else
1222   # Even if Guile support is not compiled in, we need to have these files
1223   # included.
1224   CONFIG_OBS="$CONFIG_OBS guile.o"
1225   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1226 fi
1227 AC_SUBST(GUILE_CPPFLAGS)
1228 AC_SUBST(GUILE_LIBS)
1229 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1230
1231 # --------------------- #
1232 # Check for libmcheck.  #
1233 # --------------------- #
1234
1235 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1236 # but turn it off if Python is enabled with threads, since -lmcheck is
1237 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1238 # and for releases.
1239 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1240    && $development; then
1241   libmcheck_default=yes
1242 else
1243   libmcheck_default=no
1244 fi
1245 GDB_AC_LIBMCHECK(${libmcheck_default})
1246
1247 if test "$ENABLE_LIBMCHECK" = "yes" \
1248         -a "${have_libpython}" != "no" \
1249         -a "${python_has_threads}" = "yes" ; then
1250   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1251 fi
1252
1253 # ------------------------- #
1254 # Checks for header files.  #
1255 # ------------------------- #
1256
1257 AC_HEADER_STDC
1258 # elf_hp.h is for HP/UX 64-bit shared library support.
1259 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1260                   thread_db.h \
1261                   sys/fault.h \
1262                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1263                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1264                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1265                   termios.h termio.h \
1266                   sgtty.h elf_hp.h \
1267                   dlfcn.h])
1268 AC_CHECK_HEADERS(sys/proc.h, [], [],
1269 [#if HAVE_SYS_PARAM_H
1270 # include <sys/param.h>
1271 #endif
1272 ])
1273 AC_CHECK_HEADERS(sys/user.h, [], [],
1274 [#if HAVE_SYS_PARAM_H
1275 # include <sys/param.h>
1276 #endif
1277 ])
1278
1279 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1280 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1281 # think that we don't have <curses.h> if we're using GCC.
1282 case $host_os in
1283   solaris2.[[789]])
1284     if test "$GCC" = yes; then
1285       AC_DEFINE(_MSE_INT_H, 1,
1286         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1287    Solaris 2.[789] when using GCC. ])
1288     fi ;;
1289 esac
1290 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1291 AC_CHECK_HEADERS(term.h, [], [],
1292 [#if HAVE_CURSES_H
1293 # include <curses.h>
1294 #endif
1295 ])
1296
1297 # ------------------------- #
1298 # Checks for declarations.  #
1299 # ------------------------- #
1300
1301 libiberty_INIT
1302
1303 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1304 AM_LC_MESSAGES
1305
1306 # ----------------------- #
1307 # Checks for structures.  #
1308 # ----------------------- #
1309
1310 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1311
1312 # ------------------ #
1313 # Checks for types.  #
1314 # ------------------ #
1315
1316 AC_TYPE_SIGNAL
1317 AC_CHECK_TYPES(socklen_t, [], [],
1318 [#include <sys/types.h>
1319 #include <sys/socket.h>
1320 ])
1321
1322 # ------------------------------------- #
1323 # Checks for compiler characteristics.  #
1324 # ------------------------------------- #
1325
1326 AC_C_CONST
1327 AC_C_INLINE
1328 AC_C_BIGENDIAN
1329
1330 # ------------------------------ #
1331 # Checks for library functions.  #
1332 # ------------------------------ #
1333
1334 AC_FUNC_MMAP
1335 AC_FUNC_VFORK
1336 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1337                 pipe poll pread pread64 pwrite resize_term \
1338                 sbrk setpgid setpgrp setsid \
1339                 sigaction sigprocmask sigsetmask socketpair \
1340                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1341                 setrlimit getrlimit posix_madvise waitpid \
1342                 ptrace64 sigaltstack mkdtemp])
1343 AM_LANGINFO_CODESET
1344 GDB_AC_COMMON
1345
1346 # Check the return and argument types of ptrace.  No canned test for
1347 # this, so roll our own.
1348 gdb_ptrace_headers='
1349 #include <sys/types.h>
1350 #if HAVE_SYS_PTRACE_H
1351 # include <sys/ptrace.h>
1352 #endif
1353 #if HAVE_UNISTD_H
1354 # include <unistd.h>
1355 #endif
1356 '
1357 # There is no point in checking if we don't have a prototype.
1358 AC_CHECK_DECLS(ptrace, [], [
1359   : ${gdb_cv_func_ptrace_ret='int'}
1360   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1361 ], $gdb_ptrace_headers)
1362 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1363 # empty argument list, so check for that explicitly.
1364 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1365   AC_TRY_COMPILE($gdb_ptrace_headers,
1366     [extern long ptrace (enum __ptrace_request, ...);],
1367     gdb_cv_func_ptrace_ret='long',
1368     AC_TRY_COMPILE($gdb_ptrace_headers,
1369       [extern int ptrace ();],
1370       gdb_cv_func_ptrace_ret='int',
1371       gdb_cv_func_ptrace_ret='long')))
1372 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1373   [Define as the return type of ptrace.])
1374 # Check argument types.
1375 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1376   AC_TRY_COMPILE($gdb_ptrace_headers,
1377     [extern long ptrace (enum __ptrace_request, ...);],
1378     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1379 for gdb_arg1 in 'int' 'long'; do
1380  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1381   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1382    for gdb_arg4 in 'int' 'long' 'void *'; do
1383      AC_TRY_COMPILE($gdb_ptrace_headers, [
1384 extern $gdb_cv_func_ptrace_ret
1385   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1386 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1387     break 4;])
1388     for gdb_arg5 in 'int *' 'int' 'long'; do
1389      AC_TRY_COMPILE($gdb_ptrace_headers, [
1390 extern $gdb_cv_func_ptrace_ret
1391   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1392 ], [
1393 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1394     break 5;])
1395     done
1396    done
1397   done
1398  done
1399 done
1400 # Provide a safe default value.
1401 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1402 ])])
1403 ac_save_IFS=$IFS; IFS=','
1404 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1405 IFS=$ac_save_IFS
1406 shift
1407 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1408   [Define to the type of arg 3 for ptrace.])
1409 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1410   [Define to the type of arg 4 for ptrace.])
1411 if test -n "$[5]"; then
1412   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1413     [Define to the type of arg 5 for ptrace.])
1414 fi
1415
1416 dnl AC_FUNC_SETPGRP does not work when cross compiling
1417 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1418 if test "$cross_compiling" = no; then
1419   AC_FUNC_SETPGRP
1420 else
1421   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1422     [AC_TRY_COMPILE([
1423 #include <unistd.h>
1424 ], [
1425   if (setpgrp(1,1) == -1)
1426     exit (0);
1427   else
1428     exit (1);
1429 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1430 if test $ac_cv_func_setpgrp_void = yes; then
1431   AC_DEFINE(SETPGRP_VOID, 1)
1432 fi
1433 fi
1434
1435 # Assume we'll default to using the included libiberty regex.
1436 gdb_use_included_regex=yes
1437
1438 # However, if the system regex is GNU regex, then default to *not*
1439 # using the included regex.
1440 AC_CACHE_CHECK(
1441   [for GNU regex],
1442   [gdb_cv_have_gnu_regex],
1443   [AC_TRY_COMPILE(
1444     [#include <gnu-versions.h>],
1445     [#define REGEX_INTERFACE_VERSION 1
1446 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1447 # error "Version mismatch"
1448 #endif],
1449     gdb_cv_have_gnu_regex=yes,
1450     gdb_cv_have_gnu_regex=no)])
1451 if test $gdb_cv_have_gnu_regex = yes; then
1452   gdb_use_included_regex=no
1453 fi
1454
1455 AC_ARG_WITH(included-regex,
1456   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1457   gdb_with_regex=$withval,
1458   gdb_with_regex=$gdb_use_included_regex)
1459 if test "$gdb_with_regex" = yes; then
1460   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1461     [Define to 1 if the regex included in libiberty should be used.])
1462 fi
1463
1464 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1465 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1466 [#include <sys/param.h>
1467 #include <sys/proc.h>
1468 ])
1469
1470 # See if <sys/lwp.h> defines `struct lwp`.
1471 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1472 [AC_TRY_COMPILE([#include <sys/param.h>
1473 #include <sys/lwp.h>], [struct lwp l;],
1474 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1475 if test $gdb_cv_struct_lwp = yes; then
1476   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1477             [Define to 1 if your system has struct lwp.])
1478 fi
1479
1480 # See if <machine/reg.h> degines `struct reg'.
1481 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1482 [AC_TRY_COMPILE([#include <sys/types.h>
1483 #include <machine/reg.h>], [struct reg r;],
1484 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1485 if test $gdb_cv_struct_reg = yes; then
1486   AC_DEFINE(HAVE_STRUCT_REG, 1,
1487             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1488 fi
1489
1490 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1491 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1492 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1493                  [#include <machine/reg.h>])
1494
1495 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1496 # Older amd64 Linux's don't have the fs_base and gs_base members of
1497 # `struct user_regs_struct'.
1498 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1499                  [], [], [#include <sys/user.h>])
1500
1501 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1502 AC_MSG_CHECKING(for PTRACE_GETREGS)
1503 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1504 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1505                 [PTRACE_GETREGS;],
1506                 [gdb_cv_have_ptrace_getregs=yes],
1507                 [gdb_cv_have_ptrace_getregs=no])])
1508 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1509 if test $gdb_cv_have_ptrace_getregs = yes; then
1510   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1511   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1512 fi
1513
1514 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1515 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1516 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1517 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1518                 [PTRACE_GETFPXREGS;],
1519                 [gdb_cv_have_ptrace_getfpxregs=yes],
1520                 [gdb_cv_have_ptrace_getfpxregs=no])])
1521 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1522 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1523   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1524   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1525 fi
1526
1527 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1528 AC_MSG_CHECKING(for PT_GETDBREGS)
1529 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1530 [AC_TRY_COMPILE([#include <sys/types.h>
1531 #include <sys/ptrace.h>],
1532                 [PT_GETDBREGS;],
1533                 [gdb_cv_have_pt_getdbregs=yes],
1534                 [gdb_cv_have_pt_getdbregs=no])])
1535 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1536 if test $gdb_cv_have_pt_getdbregs = yes; then
1537   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1538   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1539 fi
1540
1541 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1542 AC_MSG_CHECKING(for PT_GETXMMREGS)
1543 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1544 [AC_TRY_COMPILE([#include <sys/types.h>
1545 #include <sys/ptrace.h>],
1546                 [PT_GETXMMREGS;],
1547                 [gdb_cv_have_pt_getxmmregs=yes],
1548                 [gdb_cv_have_pt_getxmmregs=no])])
1549 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1550 if test $gdb_cv_have_pt_getxmmregs = yes; then
1551   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1552   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1553 fi
1554
1555 # Detect which type of /proc is in use, such as for Solaris.
1556
1557 if test "${target}" = "${host}"; then
1558   case "${host}" in
1559   *-*-sysv4.2* | *-*-sysv5* )
1560       AC_DEFINE(NEW_PROC_API, 1,
1561       [Define if you want to use new multi-fd /proc interface.])
1562       ;;
1563   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1564       AC_DEFINE(NEW_PROC_API, 1,
1565       [Define if you want to use new multi-fd /proc interface.])
1566       ;;
1567   mips-sgi-irix5*)
1568       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1569       AC_DEFINE([_KMEMUSER], 1,
1570       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1571        around a <sys/proc.h> problem on IRIX 5.])
1572       ;;
1573   esac
1574 fi
1575
1576 if test "$ac_cv_header_sys_procfs_h" = yes; then
1577   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1578   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1579   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1580   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1581   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1582   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1583   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1584   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1585   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1586   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1587   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1588
1589
1590   dnl Check for broken prfpregset_t type
1591
1592   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1593   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1594   dnl instead of the struct itself).  We detect this here, and work
1595   dnl around it in gdb_proc_service.h.
1596
1597   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1598     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1599     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1600       [AC_TRY_RUN([#include <sys/procfs.h>
1601        int main ()
1602        {
1603          if (sizeof (prfpregset_t) == sizeof (void *))
1604            return 1;
1605          return 0;
1606        }],
1607        gdb_cv_prfpregset_t_broken=no,
1608        gdb_cv_prfpregset_t_broken=yes,
1609        gdb_cv_prfpregset_t_broken=yes)])
1610     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1611     if test $gdb_cv_prfpregset_t_broken = yes; then
1612       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1613       [Define if the prfpregset_t type is broken.])
1614     fi
1615   fi
1616 fi
1617
1618 # Check if the compiler supports the `long long' type.
1619
1620 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1621                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1622 [[extern long long foo;]],
1623 [[switch (foo & 2) { case 0: return 1; }]])],
1624                                   gdb_cv_c_long_long=yes,
1625                                   gdb_cv_c_long_long=no)])
1626 if test $gdb_cv_c_long_long != yes; then
1627   # libdecnumber requires long long.
1628   AC_MSG_ERROR([Compiler must support long long for GDB.])
1629 fi
1630
1631 # Check if the compiler and runtime support printing long longs.
1632
1633 AC_CACHE_CHECK([for long long support in printf],
1634                gdb_cv_printf_has_long_long,
1635                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1636 [[char buf[32];
1637   long long l = 0;
1638   l = (l << 16) + 0x0123;
1639   l = (l << 16) + 0x4567;
1640   l = (l << 16) + 0x89ab;
1641   l = (l << 16) + 0xcdef;
1642   sprintf (buf, "0x%016llx", l);
1643   return (strcmp ("0x0123456789abcdef", buf));]])],
1644                               gdb_cv_printf_has_long_long=yes,
1645                               gdb_cv_printf_has_long_long=no,
1646                               gdb_cv_printf_has_long_long=no)])
1647 if test $gdb_cv_printf_has_long_long = yes; then
1648   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1649             [Define to 1 if the "%ll" format works to print long longs.])
1650 fi
1651
1652 # Check if the compiler and runtime support printing decfloats.
1653
1654 AC_CACHE_CHECK([for decfloat support in printf],
1655                gdb_cv_printf_has_decfloat,
1656                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1657 [[char buf[64];
1658   _Decimal32 d32 = 1.2345df;
1659   _Decimal64 d64 = 1.2345dd;
1660   _Decimal128 d128 = 1.2345dl;
1661   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1662   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1663                               gdb_cv_printf_has_decfloat=yes,
1664                               gdb_cv_printf_has_decfloat=no,
1665                               gdb_cv_printf_has_decfloat=no)])
1666 if test $gdb_cv_printf_has_decfloat = yes; then
1667   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1668             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1669 fi
1670
1671 # Check if the compiler supports the `long double' type.  We can't use
1672 # AC_C_LONG_DOUBLE because that one does additional checks on the
1673 # constants defined in <float.h> that fail on some systems,
1674 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1675
1676 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1677                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1678                                   gdb_cv_c_long_double=yes,
1679                                   gdb_cv_c_long_double=no)])
1680 if test $gdb_cv_c_long_double = yes; then
1681   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1682            [Define to 1 if the compiler supports long double.])
1683 fi
1684
1685 # Check if the compiler and runtime support printing long doubles.
1686
1687 AC_CACHE_CHECK([for long double support in printf],
1688                gdb_cv_printf_has_long_double,
1689                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1690 [[char buf[16];
1691   long double f = 3.141592653;
1692   sprintf (buf, "%Lg", f);
1693   return (strncmp ("3.14159", buf, 7));]])],
1694                               gdb_cv_printf_has_long_double=yes,
1695                               gdb_cv_printf_has_long_double=no,
1696                               gdb_cv_printf_has_long_double=no)])
1697 if test $gdb_cv_printf_has_long_double = yes; then
1698   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1699             [Define to 1 if the "%Lg" format works to print long doubles.])
1700 fi
1701
1702 # Check if the compiler and runtime support scanning long doubles.
1703
1704 AC_CACHE_CHECK([for long double support in scanf],
1705                gdb_cv_scanf_has_long_double,
1706                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1707 [[#include <stdio.h>]],
1708 [[char *buf = "3.141592653";
1709   long double f = 0;
1710   sscanf (buf, "%Lg", &f);
1711   return !(f > 3.14159 && f < 3.14160);]])],
1712                               gdb_cv_scanf_has_long_double=yes,
1713                               gdb_cv_scanf_has_long_double=no,
1714                               gdb_cv_scanf_has_long_double=no)])
1715 if test $gdb_cv_scanf_has_long_double = yes; then
1716   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1717             [Define to 1 if the "%Lg" format works to scan long doubles.])
1718 fi
1719
1720 case ${host_os} in
1721 aix*)
1722   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1723     SAVE_LDFLAGS=$LDFLAGS
1724
1725     case $GCC in
1726     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1727     *) gdb_cv_bigtoc=-bbigtoc ;;
1728     esac
1729
1730     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1731     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1732     LDFLAGS="${SAVE_LDFLAGS}"
1733   ])
1734   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1735   ;;
1736 esac
1737
1738 AC_MSG_CHECKING(for the dynamic export flag)
1739 dynamic_list=false
1740 if test "${gdb_native}" = yes; then
1741    # The dynamically loaded libthread_db needs access to symbols in the gdb
1742    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1743    # may not be supported there.
1744    old_LDFLAGS="$LDFLAGS"
1745    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1746    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1747    LDFLAGS="$LDFLAGS $RDYNAMIC"
1748    if test "${have_libpython}" = no; then
1749      AC_TRY_LINK([], [], [dynamic_list=true])
1750    else
1751      # Workaround http://bugs.python.org/issue4434 where static
1752      # libpythonX.Y.a would get its symbols required for
1753      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1754      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1755      old_CFLAGS="$CFLAGS"
1756      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1757      old_LIBS="$LIBS"
1758      LIBS="$LIBS $PYTHON_LIBS"
1759      AC_RUN_IFELSE(
1760        AC_LANG_PROGRAM(
1761          [#include "]${have_libpython}[/Python.h"],
1762          [int err;
1763           Py_Initialize ();
1764           err = PyRun_SimpleString ("import itertools\n");
1765           Py_Finalize ();
1766           return err == 0 ? 0 : 1;]),
1767        [dynamic_list=true], [], [true])
1768      LIBS="$old_LIBS"
1769      CFLAGS="$old_CFLAGS"
1770    fi
1771    LDFLAGS="$old_LDFLAGS"
1772 fi
1773 if $dynamic_list; then
1774   found="-Wl,--dynamic-list"
1775   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1776 else
1777   found="-rdynamic"
1778   RDYNAMIC="-rdynamic"
1779 fi
1780 AC_SUBST(RDYNAMIC)
1781 AC_MSG_RESULT($found)
1782
1783 dnl For certain native configurations, we need to check whether thread
1784 dnl support can be built in or not.
1785 dnl
1786 dnl Note that we only want this if we are both native (host == target),
1787 dnl and not doing a canadian cross build (build == host).
1788
1789 if test ${build} = ${host} -a ${host} = ${target} ; then
1790    case ${host_os} in
1791    solaris*)
1792       # See if thread_db library is around for Solaris thread debugging.
1793       # Note that we must explicitly test for version 1 of the library
1794       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1795       # the same API.
1796       AC_MSG_CHECKING(for Solaris thread debugging library)
1797       if test -f /usr/lib/libthread_db.so.1 ; then
1798          AC_MSG_RESULT(yes)
1799          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1800          [Define if using Solaris thread debugging.])
1801          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1802          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1803          AC_CHECK_LIB(dl, dlopen)
1804          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1805          # Sun randomly tweaked the prototypes in <proc_service.h>
1806          # at one point.
1807          AC_MSG_CHECKING(if <proc_service.h> is old)
1808          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1809             AC_TRY_COMPILE([
1810                 #include <proc_service.h>
1811                 ps_err_e ps_pdwrite
1812                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1813             ],, gdb_cv_proc_service_is_old=no,
1814                 gdb_cv_proc_service_is_old=yes)
1815          ])
1816          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1817          if test $gdb_cv_proc_service_is_old = yes; then
1818             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1819             [Define if <proc_service.h> on solaris uses int instead of
1820              size_t, and assorted other type changes.])
1821          fi
1822       else
1823          AC_MSG_RESULT(no)
1824       fi
1825       ;;
1826    aix*)
1827       AC_MSG_CHECKING(for AiX thread debugging library)
1828       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1829                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1830                                    [#ifndef PTHDB_VERSION_3
1831                                     #error
1832                                     #endif],
1833                                    gdb_cv_have_aix_thread_debug=yes,
1834                                    gdb_cv_have_aix_thread_debug=no)])
1835       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1836       if test $gdb_cv_have_aix_thread_debug = yes; then
1837          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1838          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1839          LIBS="$LIBS -lpthdebug"
1840
1841          # Older versions of AIX do not provide the declaration for
1842          # the getthrds function (it appears that it was introduced
1843          # with AIX 6.x).
1844          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1845       fi
1846       ;;
1847    esac
1848    AC_SUBST(CONFIG_LDFLAGS)
1849 fi
1850
1851 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1852 dnl other error codes.
1853 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1854    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1855                   gdb_cv_thread_db_h_has_td_notalloc,
1856      AC_TRY_COMPILE(
1857        [#include <thread_db.h>],
1858        [int i = TD_NOTALLOC;],
1859        gdb_cv_thread_db_h_has_td_notalloc=yes,
1860        gdb_cv_thread_db_h_has_td_notalloc=no
1861      )
1862    )
1863    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1864                   gdb_cv_thread_db_h_has_td_version,
1865      AC_TRY_COMPILE(
1866        [#include <thread_db.h>],
1867        [int i = TD_VERSION;],
1868        gdb_cv_thread_db_h_has_td_version=yes,
1869        gdb_cv_thread_db_h_has_td_version=no
1870      )
1871    )
1872    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1873                   gdb_cv_thread_db_h_has_td_notls,
1874      AC_TRY_COMPILE(
1875        [#include <thread_db.h>],
1876        [int i = TD_NOTLS;],
1877        gdb_cv_thread_db_h_has_td_notls=yes,
1878        gdb_cv_thread_db_h_has_td_notls=no
1879      )
1880    )
1881 fi
1882 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1883   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1884             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1885 fi
1886 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1887   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1888             [Define if <thread_db.h> has the TD_VERSION error code.])
1889 fi
1890 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1891   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1892             [Define if <thread_db.h> has the TD_NOTLS error code.])
1893 fi
1894
1895 dnl See if we have a sys/syscall header file that has __NR_tkill.
1896 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1897    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1898                   gdb_cv_sys_syscall_h_has_tkill,
1899      AC_TRY_COMPILE(
1900        [#include <sys/syscall.h>],
1901        [int i = __NR_tkill;],
1902        gdb_cv_sys_syscall_h_has_tkill=yes,
1903        gdb_cv_sys_syscall_h_has_tkill=no
1904      )
1905    )
1906 fi
1907 dnl See if we can issue tkill syscall.
1908 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1909   AC_CHECK_FUNC(syscall,
1910     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1911   )
1912 fi
1913
1914 dnl Check if we can disable the virtual address space randomization.
1915 dnl The functionality of setarch -R.
1916 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1917 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1918 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1919 #       define ADDR_NO_RANDOMIZE 0x0040000
1920 #      endif
1921        /* Test the flag could be set and stays set.  */
1922        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1923        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1924            return 1])])
1925 AC_RUN_IFELSE([PERSONALITY_TEST],
1926               [have_personality=true],
1927               [have_personality=false],
1928               [AC_LINK_IFELSE([PERSONALITY_TEST],
1929                               [have_personality=true],
1930                               [have_personality=false])])
1931 if $have_personality
1932 then
1933     AC_DEFINE([HAVE_PERSONALITY], 1,
1934               [Define if you support the personality syscall.])
1935 fi
1936
1937 dnl Set the host's .gdbinit filename.
1938 case $host_os in
1939   go32* | *djgpp*)
1940     gdbinit=gdb.ini
1941     ;;
1942   *)
1943     gdbinit=.gdbinit
1944     ;;
1945 esac
1946 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1947
1948 dnl Handle optional features that can be enabled.
1949
1950 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1951 # except that the argument to --with-sysroot is optional.
1952 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1953 if test "x$with_sysroot" = xyes; then
1954   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1955 fi
1956 AC_ARG_WITH(sysroot,
1957   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1958                  [search for usr/lib et al within DIR]),
1959   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1960 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1961               [search for usr/lib et al within DIR])
1962 AC_SUBST(TARGET_SYSTEM_ROOT)
1963 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1964
1965 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1966     [automatically load a system-wide gdbinit file],
1967     [])
1968
1969 AC_ARG_ENABLE(werror,
1970   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1971   [case "${enableval}" in
1972      yes | y) ERROR_ON_WARNING="yes" ;;
1973      no | n)  ERROR_ON_WARNING="no" ;;
1974      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1975    esac])
1976
1977 # Enable -Werror by default when using gcc in C mode.  Leave it off
1978 # for C++ until we're warning clean.  Turn it off for releases.
1979 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" \
1980    && test x"$enable_build_with_cxx" != x"yes" \
1981    && $development; then
1982     ERROR_ON_WARNING=yes
1983 fi
1984
1985 WERROR_CFLAGS=""
1986 if test "${ERROR_ON_WARNING}" = yes ; then
1987     WERROR_CFLAGS="-Werror"
1988 fi
1989
1990 # These options work in either C or C++ modes.
1991 build_warnings="-Wall -Wpointer-arith \
1992 -Wno-unused -Wunused-value -Wunused-function \
1993 -Wno-switch -Wno-char-subscripts \
1994 -Wempty-body"
1995
1996 # Now add in C and C++ specific options, depending on mode.
1997 if test "$enable_build_with_cxx" = "yes"; then
1998    build_warnings="$build_warnings -Wno-sign-compare -Wno-write-strings \
1999 -Wno-narrowing"
2000 else
2001    build_warnings="$build_warnings -Wpointer-sign -Wmissing-prototypes \
2002 -Wdeclaration-after-statement -Wmissing-parameter-type \
2003 -Wold-style-declaration -Wold-style-definition"
2004 fi
2005
2006 # Enable -Wno-format by default when using gcc on mingw since many
2007 # GCC versions complain about %I64.
2008 case "${host}" in
2009   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
2010   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
2011 esac
2012
2013 AC_ARG_ENABLE(build-warnings,
2014 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
2015 [case "${enableval}" in
2016   yes)  ;;
2017   no)   build_warnings="-w";;
2018   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2019         build_warnings="${build_warnings} ${t}";;
2020   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2021         build_warnings="${t} ${build_warnings}";;
2022   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2023 esac
2024 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2025   echo "Setting compiler warning flags = $build_warnings" 6>&1
2026 fi])dnl
2027 AC_ARG_ENABLE(gdb-build-warnings,
2028 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
2029 [case "${enableval}" in
2030   yes)  ;;
2031   no)   build_warnings="-w";;
2032   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2033         build_warnings="${build_warnings} ${t}";;
2034   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2035         build_warnings="${t} ${build_warnings}";;
2036   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2037 esac
2038 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2039   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
2040 fi])dnl
2041
2042 # The set of warnings supported by a C++ compiler is not the same as
2043 # of the C compiler.
2044 if test "$enable_build_with_cxx" = "yes"; then
2045     AC_LANG_PUSH([C++])
2046 fi
2047
2048 WARN_CFLAGS=""
2049 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2050 then
2051     AC_MSG_CHECKING(compiler warning flags)
2052     # Separate out the -Werror flag as some files just cannot be
2053     # compiled with it enabled.
2054     for w in ${build_warnings}; do
2055         case $w in
2056         -Werr*) WERROR_CFLAGS=-Werror ;;
2057         *)
2058             # Check whether GCC accepts it.
2059             saved_CFLAGS="$CFLAGS"
2060             CFLAGS="$CFLAGS $w"
2061             saved_CXXFLAGS="$CXXFLAGS"
2062             CXXFLAGS="$CXXFLAGS $w"
2063             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2064             CFLAGS="$saved_CFLAGS"
2065             CXXFLAGS="$saved_CXXFLAGS"
2066         esac
2067     done
2068     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2069 fi
2070 AC_SUBST(WARN_CFLAGS)
2071 AC_SUBST(WERROR_CFLAGS)
2072
2073 if test "$enable_build_with_cxx" = "yes"; then
2074    AC_LANG_POP([C++])
2075 fi
2076
2077 # In the Cygwin environment, we need some additional flags.
2078 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2079 [AC_EGREP_CPP(^lose$, [
2080 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2081 lose
2082 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2083
2084
2085 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2086 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2087 case ${host} in
2088   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2089   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2090   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2091 esac
2092 AC_SUBST(SER_HARDWIRE)
2093
2094 # libreadline needs libuser32.a in a cygwin environment
2095 WIN32LIBS=
2096 if test x$gdb_cv_os_cygwin = xyes; then
2097     WIN32LIBS="-luser32"
2098     case "${target}" in
2099         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2100         ;;
2101     esac
2102 fi
2103
2104 # The ser-tcp.c module requires sockets.
2105 case ${host} in
2106   *mingw32*)
2107     AC_DEFINE(USE_WIN32API, 1,
2108               [Define if we should use the Windows API, instead of the
2109                POSIX API.  On Windows, we use the Windows API when
2110                building for MinGW, but the POSIX API when building
2111                for Cygwin.])
2112     WIN32LIBS="$WIN32LIBS -lws2_32"
2113     ;;
2114 esac
2115 AC_SUBST(WIN32LIBS)
2116
2117 # Add ELF support to GDB, but only if BFD includes ELF support.
2118 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2119                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2120 if test $gdb_cv_var_elf = yes; then
2121   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
2122   AC_DEFINE(HAVE_ELF, 1,
2123             [Define if ELF support should be included.])
2124   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2125   if test "$plugins" = "yes"; then
2126     AC_SEARCH_LIBS(dlopen, dl)
2127   fi
2128 fi
2129
2130 # Add macho support to GDB, but only if BFD includes it.
2131 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2132                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2133 if test $gdb_cv_var_macho = yes; then
2134   CONFIG_OBS="$CONFIG_OBS machoread.o"
2135 fi
2136
2137 # Add SOM support to GDB, but only if BFD includes it.
2138 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2139                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2140 if test $gdb_cv_var_som = yes; then
2141   CONFIG_OBS="$CONFIG_OBS somread.o"
2142 fi
2143
2144 # Add any host-specific objects to GDB.
2145 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2146
2147 # If building on ELF, look for lzma support for embedded compressed debug info.
2148 if test $gdb_cv_var_elf = yes; then
2149   AC_ARG_WITH(lzma,
2150     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2151     [], [with_lzma=auto])
2152   AC_MSG_CHECKING([whether to use lzma])
2153   AC_MSG_RESULT([$with_lzma])
2154
2155   if test "${with_lzma}" != no; then
2156     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2157                           [lzma_index_iter iter;
2158                            lzma_index_iter_init (&iter, 0);
2159                            lzma_mf_is_supported (LZMA_MF_HC3);])
2160     if test "$HAVE_LIBLZMA" != yes; then
2161       if test "$with_lzma" = yes; then
2162         AC_MSG_ERROR([missing liblzma for --with-lzma])
2163       fi
2164     fi
2165   fi
2166 fi
2167
2168 LIBGUI="../libgui/src/libgui.a"
2169 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2170 AC_SUBST(LIBGUI)
2171 AC_SUBST(GUI_CFLAGS_X)
2172
2173 WIN32LDAPP=
2174 AC_SUBST(WIN32LIBS)
2175 AC_SUBST(WIN32LDAPP)
2176
2177 case "${host}" in
2178 *-*-cygwin* | *-*-mingw* )
2179     configdir="win"
2180     ;;
2181 *)
2182     configdir="unix"
2183     ;;
2184 esac
2185
2186 GDBTKLIBS=
2187 if test "${enable_gdbtk}" = "yes"; then
2188
2189     # Gdbtk must have an absolute path to srcdir in order to run
2190     # properly when not installed.
2191     here=`pwd`
2192     cd ${srcdir}
2193     GDBTK_SRC_DIR=`pwd`
2194     cd $here
2195
2196     SC_PATH_TCLCONFIG
2197
2198     # If $no_tk is nonempty, then we can't do Tk, and there is no
2199     # point to doing Tcl.
2200     SC_PATH_TKCONFIG
2201
2202     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2203         SC_LOAD_TCLCONFIG
2204
2205         # Check for in-tree tcl
2206         here=`pwd`
2207         cd ${srcdir}/..
2208         topdir=`pwd`
2209         cd ${here}
2210
2211         intree="no"
2212         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2213           intree="yes"
2214         fi
2215
2216         # Find Tcl private headers
2217         if test x"${intree}" = xno; then
2218           CY_AC_TCL_PRIVATE_HEADERS
2219           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2220           TCL_LIBRARY="${TCL_LIB_SPEC}"
2221           TCL_DEPS=""
2222         else
2223           # If building tcl in the same src tree, private headers
2224           # are not needed, but we need to be sure to use the right
2225           # headers library
2226           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2227           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2228           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2229         fi
2230         AC_SUBST(TCL_INCLUDE)
2231         AC_SUBST(TCL_LIBRARY)
2232         AC_SUBST(TCL_DEPS)
2233
2234         SC_LOAD_TKCONFIG
2235
2236         # Check for in-tree Tk
2237         intree="no"
2238         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2239           intree="yes"
2240         fi
2241
2242         # Find Tk private headers
2243         if test x"${intree}" = xno; then
2244           CY_AC_TK_PRIVATE_HEADERS
2245           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2246           TK_LIBRARY=${TK_LIB_SPEC}
2247           TK_DEPS=""
2248         else
2249           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2250           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2251           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2252         fi
2253         AC_SUBST(TK_INCLUDE)
2254         AC_SUBST(TK_LIBRARY)
2255         AC_SUBST(TK_DEPS)
2256         AC_SUBST(TK_XINCLUDES)
2257
2258         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2259
2260         # Include some libraries that Tcl and Tk want.
2261         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2262         # Yes, the ordering seems wrong here.  But it isn't.
2263         # TK_LIBS is the list of libraries that need to be linked
2264         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2265         # were in LIBS then any link tests after this point would
2266         # try to include things like `$(LIBGUI)', which wouldn't work.
2267         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2268
2269         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2270         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2271         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2272         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2273         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2274         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2275         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2276
2277         if test x$gdb_cv_os_cygwin = xyes; then
2278           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2279           WIN32LDAPP="-Wl,--subsystem,console"
2280           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2281         fi
2282
2283         AC_CONFIG_SUBDIRS(gdbtk)
2284     fi
2285 fi
2286
2287 AC_SUBST(X_CFLAGS)
2288 AC_SUBST(X_LDFLAGS)
2289 AC_SUBST(X_LIBS)
2290 AC_SUBST(GDBTKLIBS)
2291 AC_SUBST(GDBTK_CFLAGS)
2292 AC_SUBST(GDBTK_SRC_DIR)
2293
2294 AC_PATH_X
2295
2296 # Unlike the sim directory, whether a simulator is linked is controlled by
2297 # presence of a gdb_sim definition in the target configure.tgt entry.
2298 # This code just checks for a few cases where we'd like to ignore those
2299 # definitions, even when they're present in the '.mt' file.  These cases
2300 # are when --disable-sim is specified, or if the simulator directory is
2301 # not part of the source tree.
2302 #
2303 AC_ARG_ENABLE(sim,
2304 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2305 [echo "enable_sim = $enable_sim";
2306  echo "enableval = ${enableval}";
2307  case "${enableval}" in
2308   yes) ignore_sim=false ;;
2309   no)  ignore_sim=true ;;
2310   *)   ignore_sim=false ;;
2311  esac],
2312 [ignore_sim=false])
2313
2314 if test ! -d "${srcdir}/../sim"; then
2315   ignore_sim=true
2316 fi
2317
2318 SIM=
2319 SIM_OBS=
2320 if test "${ignore_sim}" = "false"; then
2321   if test x"${gdb_sim}" != x ; then
2322     SIM="${gdb_sim}"
2323     SIM_OBS="remote-sim.o"
2324     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2325   fi
2326 fi
2327 AC_SUBST(SIM)
2328 AC_SUBST(SIM_OBS)
2329
2330 AC_SUBST(ENABLE_CFLAGS)
2331 AC_SUBST(PROFILE_CFLAGS)
2332
2333 AC_SUBST(CONFIG_OBS)
2334 AC_SUBST(CONFIG_DEPS)
2335 AC_SUBST(CONFIG_SRCS)
2336 AC_SUBST(CONFIG_ALL)
2337 AC_SUBST(CONFIG_CLEAN)
2338 AC_SUBST(CONFIG_INSTALL)
2339 AC_SUBST(CONFIG_UNINSTALL)
2340
2341 # List of host floatformats.
2342 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2343 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2344 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2345
2346 # target_subdir is used by the testsuite to find the target libraries.
2347 target_subdir=
2348 if test "${host}" != "${target}"; then
2349     target_subdir="${target_alias}/"
2350 fi
2351 AC_SUBST(target_subdir)
2352
2353 frags=
2354 if test "${gdb_native}" = "yes"; then
2355   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2356   if test ! -f ${host_makefile_frag}; then
2357     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2358   fi
2359   frags="$frags $host_makefile_frag"
2360 else
2361   host_makefile_frag=/dev/null
2362 fi
2363
2364 AC_SUBST_FILE(host_makefile_frag)
2365 AC_SUBST(frags)
2366
2367 changequote(,)dnl
2368 if test "${gdb_native}" = "yes"; then
2369 # We pick this up from the host configuration file (.mh) because we
2370 # do not have a native configuration Makefile fragment.
2371 nativefile=`sed -n '
2372 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2373 ' ${host_makefile_frag}`
2374 fi
2375 changequote([,])
2376
2377 if test x"${gdb_osabi}" != x ; then
2378     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2379                        [Define to the default OS ABI for this configuration.])
2380 fi
2381
2382 # Enable multi-ice-gdb-server.
2383 AC_ARG_ENABLE(multi-ice,
2384 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2385   [case $enableval in
2386     yes | no)
2387       ;;
2388     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2389   esac])
2390 if test "x$enable_multi_ice" = xyes; then
2391    AC_CONFIG_SUBDIRS(multi-ice)
2392 fi
2393
2394 AC_ARG_ENABLE(gdbserver,
2395 AS_HELP_STRING([--enable-gdbserver],
2396                [automatically build gdbserver (yes/no/auto, default is auto)]),
2397 [case "${enableval}" in
2398   yes| no|auto) ;;
2399   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2400 esac],[enable_gdbserver=auto])
2401
2402 # We only build gdbserver automatically in a native configuration, and
2403 # only if the user did not explicitly disable its build.
2404 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2405   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2406   if test "x$build_gdbserver" = xyes; then
2407     AC_MSG_RESULT(yes)
2408     AC_CONFIG_SUBDIRS(gdbserver)
2409     gdbserver_build_enabled=yes
2410   else
2411     AC_MSG_RESULT(no)
2412   fi
2413 fi
2414
2415 # If the user explicitly request the gdbserver to be built, verify that
2416 # we were in fact able to enable it.
2417 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2418   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2419 fi
2420
2421 # Check for babeltrace and babeltrace-ctf
2422 AC_ARG_WITH(babeltrace,
2423   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2424   [], [with_babeltrace=auto])
2425 AC_MSG_CHECKING([whether to use babeltrace])
2426 AC_MSG_RESULT([$with_babeltrace])
2427
2428 if test "x$with_babeltrace" = "xno"; then
2429   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2430 else
2431   # Append -Werror to CFLAGS so that configure can catch the warning
2432   # "assignment from incompatible pointer type", which is related to
2433   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2434   # in GDB, while babeltrace 1.0.3 is broken.
2435   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2436   # safe to save and restore CFLAGS here.
2437   saved_CFLAGS=$CFLAGS
2438   CFLAGS="$CFLAGS -Werror"
2439   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2440                         [#include <babeltrace/babeltrace.h>
2441                          #include <babeltrace/ctf/events.h>
2442                          #include <babeltrace/ctf/iterator.h>],
2443                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2444                         struct bt_ctf_event *event = NULL;
2445                         const struct bt_definition *scope;
2446
2447                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2448                         scope = bt_ctf_get_top_level_scope (event,
2449                                                            BT_STREAM_EVENT_HEADER);
2450                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2451                         ])
2452   CFLAGS=$saved_CFLAGS
2453
2454   if test "$HAVE_LIBBABELTRACE" != yes; then
2455      if test "$with_babeltrace" = yes; then
2456        AC_MSG_ERROR([babeltrace is missing or unusable])
2457      else
2458        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2459      fi
2460   fi
2461 fi
2462
2463 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2464 # to an empty version.
2465
2466 files=
2467 links=
2468
2469 rm -f nm.h
2470 if test "${nativefile}" != ""; then
2471     case "${nativefile}" in
2472       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2473       * ) GDB_NM_FILE="${nativefile}"
2474     esac
2475     files="${files} ${GDB_NM_FILE}"
2476     links="${links} nm.h"
2477     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2478 fi
2479 AC_SUBST(GDB_NM_FILE)
2480
2481 AC_LINK_FILES($files, $links)
2482
2483 dnl Check for exe extension set on certain hosts (e.g. Win32)
2484 AC_EXEEXT
2485
2486 dnl  Detect the character set used by this host.
2487 dnl  At the moment, we just assume it's UTF-8.
2488 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2489           [Define to be a string naming the default host character set.])
2490
2491 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2492 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2493 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2494
2495 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2496 [
2497 case x$CONFIG_HEADERS in
2498 xconfig.h:config.in)
2499 echo > stamp-h ;;
2500 esac
2501 ])
2502
2503 exit 0