gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2016 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # See if we are building with C++, and substitute COMPILER.
  42 GDB_AC_BUILD_WITH_CXX
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 # Check for the 'make' the user wants to use.
  49 AC_CHECK_PROGS(MAKE, make)
  50 MAKE_IS_GNU=
  51 case "`$MAKE --version 2>&1 | sed 1q`" in
  52   *GNU*)
  53     MAKE_IS_GNU=yes
  54     ;;
  55 esac
  56 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  57 AC_PROG_MAKE_SET
  58
  59 gnulib_extra_configure_args=
  60 # If large-file support is disabled, make sure gnulib does the same.
  61 if test "$enable_largefile" = no; then
  62 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  63 fi
  64
  65 # Configure gnulib.  We need to build gnulib under some other
  66 # directory not "gnulib", to avoid the problem of both GDB and
  67 # GDBserver wanting to build it in the same directory, when building
  68 # in the source dir.
  69 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  70                   ["$gnulib_extra_configure_args"])
  71
  72 dnl List of object files and targets accumulated by configure.
  73
  74 CONFIG_OBS=
  75 CONFIG_DEPS=
  76 CONFIG_SRCS=
  77 ENABLE_CFLAGS=
  78
  79 CONFIG_ALL=
  80 CONFIG_CLEAN=
  81 CONFIG_INSTALL=
  82 CONFIG_UNINSTALL=
  83
  84 dnl Set up for gettext.
  85 ZW_GNU_GETTEXT_SISTER_DIR
  86
  87 localedir='${datadir}/locale'
  88 AC_SUBST(localedir)
  89
  90 if test x"$USE_NLS" = xyes; then
  91    CONFIG_ALL="$CONFIG_ALL all-po"
  92    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  93    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  94    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  95 fi
  96
  97 GNULIB=build-gnulib/import
  98
  99 # For Makefile dependencies.
 100 GNULIB_STDINT_H=
 101 if test x"$STDINT_H" != x; then
 102   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 103 fi
 104 AC_SUBST(GNULIB_STDINT_H)
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 # We never need to detect it in this sub-configure.
 111 # But preserve it for config.status --recheck.
 112 AC_ARG_VAR(MAKEINFO,
 113   [Parent configure detects if it is of sufficient version.])
 114 AC_ARG_VAR(MAKEINFOFLAGS,
 115   [Parameters for MAKEINFO.])
 116
 117 MAKEINFO_EXTRA_FLAGS=""
 118 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 119   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 120   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 121     gdb_cv_have_makeinfo_click=yes
 122   else
 123     gdb_cv_have_makeinfo_click=no
 124   fi])
 125 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 126   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 127 fi
 128 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 129
 130 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 131     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 132     [${libdir}/debug])
 133
 134 # We can't pass paths as command line arguments.
 135 # Mingw32 tries to be clever and will convert the paths for us.
 136 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 137 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 138 # This breaks GDB's relocatable path conversions since paths passed in
 139 # config.h would not get so translated, the path prefixes no longer match.
 140 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 141
 142 # GDB's datadir relocation
 143
 144 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 145     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 146     [${datadir}/gdb])
 147
 148 AC_ARG_WITH(relocated-sources,
 149 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 150 [reloc_srcdir="${withval}"
 151  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 152               [Relocated directory for source files. ])
 153 ])
 154
 155 AC_MSG_CHECKING([for default auto-load directory])
 156 AC_ARG_WITH(auto-load-dir,
 157 AS_HELP_STRING([--with-auto-load-dir=PATH],
 158   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 159   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 160 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 161 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 162               [Directories from which to load auto-loaded scripts.])
 163 AC_MSG_RESULT([$with_auto_load_dir])
 164
 165 AC_MSG_CHECKING([for default auto-load safe-path])
 166 AC_ARG_WITH(auto-load-safe-path,
 167 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 168   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 169 AS_HELP_STRING([--without-auto-load-safe-path],
 170                [do not restrict auto-loaded files locations]),
 171     [if test "$with_auto_load_safe_path" = "no"; then
 172      with_auto_load_safe_path="/"
 173      fi],
 174 [with_auto_load_safe_path="$with_auto_load_dir"])
 175 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 176 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 177               [Directories safe to hold auto-loaded files.])
 178 AC_MSG_RESULT([$with_auto_load_safe_path])
 179
 180 AC_CONFIG_SUBDIRS(testsuite)
 181
 182 # Check whether to support alternative target configurations
 183 AC_ARG_ENABLE(targets,
 184 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 185 [case "${enableval}" in
 186   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 187             ;;
 188   no)       enable_targets= ;;
 189   *)        enable_targets=$enableval ;;
 190 esac])
 191
 192 # Check whether to enable 64-bit support on 32-bit hosts
 193 AC_ARG_ENABLE(64-bit-bfd,
 194 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 195 [case "${enableval}" in
 196   yes)  want64=true  ;;
 197   no)   want64=false ;;
 198   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 199 esac],[want64=false])dnl
 200
 201 # Provide defaults for some variables set by the per-host and per-target
 202 # configuration.
 203 gdb_host_obs=posix-hdep.o
 204
 205 if test "${target}" = "${host}"; then
 206   gdb_native=yes
 207 else
 208   gdb_native=no
 209 fi
 210
 211 . $srcdir/configure.host
 212
 213 # Add in the common host objects.
 214 . $srcdir/common/common.host
 215 gdb_host_obs="$gdb_host_obs $common_host_obs"
 216
 217 # Accumulate some settings from configure.tgt over all enabled targets
 218
 219 TARGET_OBS=
 220 all_targets=
 221 HAVE_NATIVE_GCORE_TARGET=
 222
 223 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 224 do
 225   if test "$targ_alias" = "all"; then
 226     all_targets=true
 227   else
 228     # Canonicalize the secondary target names.
 229     result=`$ac_config_sub $targ_alias 2>/dev/null`
 230     if test -n "$result"; then
 231         targ=$result
 232     else
 233         targ=$targ_alias
 234     fi
 235
 236     . ${srcdir}/configure.tgt
 237
 238     AS_IF([test -z "${gdb_target_obs}"],
 239       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 240
 241     # Target-specific object files
 242     for i in ${gdb_target_obs}; do
 243         case " $TARGET_OBS " in
 244         *" ${i} "*) ;;
 245         *)
 246           TARGET_OBS="$TARGET_OBS ${i}"
 247           ;;
 248         esac
 249     done
 250
 251     # Check whether this target needs 64-bit CORE_ADDR
 252     if test x${want64} = xfalse; then
 253       . ${srcdir}/../bfd/config.bfd
 254     fi
 255
 256     # Check whether this target is native and supports gcore.
 257     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 258        && $gdb_have_gcore; then
 259       HAVE_NATIVE_GCORE_TARGET=1
 260     fi
 261   fi
 262 done
 263
 264 if test x${all_targets} = xtrue; then
 265
 266   # We want all 64-bit targets if we either:
 267   #  - run on a 64-bit host  or
 268   #  - already require 64-bit support for some other target  or
 269   #  - the --enable-64-bit-bfd option was supplied
 270   # Otherwise we only support all 32-bit targets.
 271   #
 272   # NOTE: This test must be in sync with the corresponding
 273   #       tests in BFD!
 274
 275   if test x${want64} = xfalse; then
 276     AC_CHECK_SIZEOF(long)
 277     if test "x${ac_cv_sizeof_long}" = "x8"; then
 278       want64=true
 279     fi
 280   fi
 281   if test x${want64} = xtrue; then
 282     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 283   else
 284     TARGET_OBS='$(ALL_TARGET_OBS)'
 285   fi
 286 fi
 287
 288 AC_SUBST(TARGET_OBS)
 289 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 290
 291 # For other settings, only the main target counts.
 292 gdb_sim=
 293 gdb_osabi=
 294 build_gdbserver=
 295 targ=$target; . ${srcdir}/configure.tgt
 296
 297 # Fetch the default architecture and default target vector from BFD.
 298 targ=$target; . $srcdir/../bfd/config.bfd
 299
 300 # We only want the first architecture, so strip off the others if
 301 # there is more than one.
 302 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 303
 304 if test "x$targ_archs" != x; then
 305   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 306     [Define to BFD's default architecture. ])
 307 fi
 308 if test "x$targ_defvec" != x; then
 309   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 310     [Define to BFD's default target vector. ])
 311 fi
 312
 313 # The CLI cannot be disabled yet, but may be in the future.
 314
 315 # Enable CLI.
 316 AC_ARG_ENABLE(gdbcli,
 317 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 318   [case $enableval in
 319     yes)
 320       ;;
 321     no)
 322       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 323     *)
 324       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 325   esac],
 326   [enable_gdbcli=yes])
 327 if test x"$enable_gdbcli" = xyes; then
 328   if test -d $srcdir/cli; then
 329     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 330     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 331     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 332     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 333   fi
 334 fi
 335
 336 # Enable MI.
 337 AC_ARG_ENABLE(gdbmi,
 338 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 339   [case $enableval in
 340     yes | no)
 341       ;;
 342     *)
 343       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 344   esac],
 345   [enable_gdbmi=yes])
 346 if test x"$enable_gdbmi" = xyes; then
 347   if test -d $srcdir/mi; then
 348     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 349     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 350     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 351     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 352   fi
 353 fi
 354
 355 # Enable TUI.
 356 AC_ARG_ENABLE(tui,
 357 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 358   [case $enableval in
 359     yes | no | auto)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 363   esac],enable_tui=auto)
 364
 365 # Enable gdbtk.
 366 AC_ARG_ENABLE(gdbtk,
 367 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 368   [case $enableval in
 369     yes | no)
 370       ;;
 371     *)
 372       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 373   esac],
 374   [if test -d $srcdir/gdbtk; then
 375     enable_gdbtk=yes
 376   else
 377     enable_gdbtk=no
 378   fi])
 379 # We unconditionally disable gdbtk tests on selected platforms.
 380 case $host_os in
 381   go32* | windows*)
 382     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 383     enable_gdbtk=no ;;
 384 esac
 385
 386 # Libunwind support for ia64.
 387
 388 AC_ARG_WITH(libunwind-ia64,
 389 AS_HELP_STRING([--with-libunwind-ia64],
 390                [use libunwind frame unwinding for ia64 targets]),,
 391             [with_libunwind_ia64=auto])
 392
 393 # Backward compatibility option.
 394 if test "${with_libunwind+set}" = set; then
 395   if test x"$with_libunwind_ia64" != xauto; then
 396     AC_MSG_ERROR(
 397       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 398   fi
 399   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 400   with_libunwind_ia64="$with_libunwind"
 401 fi
 402
 403 case "$with_libunwind_ia64" in
 404   yes | no)
 405     ;;
 406   auto)
 407     AC_CHECK_HEADERS(libunwind-ia64.h)
 408     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 409     ;;
 410   *)
 411     AC_MSG_ERROR(
 412       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 413     ;;
 414 esac
 415
 416 if test x"$with_libunwind_ia64" = xyes; then
 417   AC_CHECK_HEADERS(libunwind-ia64.h)
 418   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 419     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 420   fi
 421   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 422   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 423   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 424 fi
 425
 426 opt_curses=no
 427 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 428
 429 prefer_curses=no
 430 if test "$opt_curses" = "yes"; then
 431   prefer_curses=yes
 432 fi
 433
 434 # Profiling support.
 435 AC_ARG_ENABLE(profiling,
 436 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 437   [case $enableval in
 438     yes | no)
 439       ;;
 440     *)
 441       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 442   esac],
 443  [enable_profiling=no])
 444
 445 AC_CHECK_FUNCS(monstartup _mcleanup)
 446 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char _etext;
 450 ],
 451 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 452 if test $ac_cv_var__etext = yes; then
 453   AC_DEFINE(HAVE__ETEXT, 1,
 454             [Define to 1 if your system has the _etext variable. ])
 455 fi
 456 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 457 [AC_TRY_LINK(
 458 [#include <stdlib.h>
 459 extern char etext;
 460 ],
 461 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 462 if test $ac_cv_var_etext = yes; then
 463   AC_DEFINE(HAVE_ETEXT, 1,
 464             [Define to 1 if your system has the etext variable. ])
 465 fi
 466 if test "$enable_profiling" = yes ; then
 467   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 468     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 469   fi
 470   PROFILE_CFLAGS=-pg
 471   OLD_CFLAGS="$CFLAGS"
 472   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 473
 474   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 475     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 476      ac_cv_cc_supports_pg=no)])
 477
 478   if test $ac_cv_cc_supports_pg = no; then
 479     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 480   fi
 481
 482   CFLAGS="$OLD_CFLAGS"
 483 fi
 484
 485 ACX_PKGVERSION([GDB])
 486 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 487 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 488 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 489
 490 # --------------------- #
 491 # Checks for programs.  #
 492 # --------------------- #
 493
 494 AC_PROG_AWK
 495 AC_PROG_INSTALL
 496 AC_PROG_LN_S
 497 AC_PROG_RANLIB
 498 AC_PROG_YACC
 499
 500 AC_CHECK_TOOL(AR, ar)
 501 AC_CHECK_TOOL(DLLTOOL, dlltool)
 502 AC_CHECK_TOOL(WINDRES, windres)
 503
 504 case $host_os in
 505   gnu*)
 506     # Needed for GNU Hurd hosts.
 507     AC_CHECK_TOOL(MIG, mig)
 508     if test x"$MIG" = x; then
 509       AC_MSG_ERROR([MIG not found but required for $host hosts])
 510     fi
 511     ;;
 512 esac
 513
 514 # ---------------------- #
 515 # Checks for libraries.  #
 516 # ---------------------- #
 517
 518 # We might need to link with -lm; most simulators need it.
 519 AC_CHECK_LIB(m, main)
 520
 521 # We need to link with -lw to get `wctype' on Solaris before Solaris
 522 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 523 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 524 # is known to have this problem).  Therefore we avoid libw if we can.
 525 AC_CHECK_FUNC(wctype, [],
 526   [AC_CHECK_LIB(w, wctype)])
 527
 528 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 529 AC_SEARCH_LIBS(gethostbyname, nsl)
 530
 531 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 532 AC_SEARCH_LIBS(socketpair, socket)
 533
 534 # Link in zlib if we can.  This allows us to read compressed debug sections.
 535 AM_ZLIB
 536
 537 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 538 AC_SEARCH_LIBS(kinfo_getvmmap, util,
 539   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 540             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 541
 542 AM_ICONV
 543
 544 # GDB may fork/exec the iconv program to get the list of supported character
 545 # sets.  Allow the user to specify where to find it.
 546 # There are several factors affecting the choice of option name:
 547 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 548 #   the build-time location of libiconv files.
 549 # - The program we need to find is iconv, which comes with glibc.  The user
 550 #   doesn't necessarily have libiconv installed.  Therefore naming this
 551 #   --with-libiconv-foo feels wrong.
 552 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 553 #   defined to work on directories not files (though it really doesn't know
 554 #   the difference).
 555 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 556 #   with --with-libiconv-prefix.
 557 # Putting these together is why the option name is --with-iconv-bin.
 558
 559 AC_ARG_WITH(iconv-bin,
 560 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 561 [iconv_bin="${withval}"
 562  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 563                     [Path of directory of iconv program.])
 564  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 565 ])
 566
 567 # For the TUI, we need enhanced curses functionality.
 568 if test x"$enable_tui" != xno; then
 569   prefer_curses=yes
 570 fi
 571
 572 curses_found=no
 573 if test x"$prefer_curses" = xyes; then
 574   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 575   # curses library because the latter might not provide all the
 576   # functionality we need.  However, this leads to problems on systems
 577   # where the linker searches /usr/local/lib, but the compiler doesn't
 578   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 579   # default installation of ncurses on alpha*-dec-osf* will lead to such
 580   # a situation.
 581   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 582
 583   if test "$ac_cv_search_waddstr" != no; then
 584     curses_found=yes
 585   fi
 586 fi
 587
 588 # Check whether we should enable the TUI, but only do so if we really
 589 # can.
 590 if test x"$enable_tui" != xno; then
 591   if test -d $srcdir/tui; then
 592     if test "$curses_found" != no; then
 593       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 594       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 595       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 596       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 597     else
 598       if test x"$enable_tui" = xyes; then
 599         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 600       else
 601         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 602       fi
 603     fi
 604   fi
 605 fi
 606
 607 # Since GDB uses Readline, we need termcap functionality.  In many
 608 # cases this will be provided by the curses library, but some systems
 609 # have a seperate termcap library, or no curses library at all.
 610
 611 case $host_os in
 612   cygwin*)
 613     if test -d $srcdir/libtermcap; then
 614       LIBS="../libtermcap/libtermcap.a $LIBS"
 615       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 616     fi ;;
 617   go32* | *djgpp*)
 618     ac_cv_search_tgetent="none required"
 619     ;;
 620 esac
 621
 622 # These are the libraries checked by Readline.
 623 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 624
 625 if test "$ac_cv_search_tgetent" = no; then
 626   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 627 fi
 628
 629 AC_ARG_WITH([system-readline],
 630   [AS_HELP_STRING([--with-system-readline],
 631                   [use installed readline library])])
 632
 633 if test "$with_system_readline" = yes; then
 634   READLINE=-lreadline
 635   READLINE_DEPS=
 636   READLINE_CFLAGS=
 637   READLINE_TEXI_INCFLAG=
 638 else
 639   READLINE='$(READLINE_DIR)/libreadline.a'
 640   READLINE_DEPS='$(READLINE)'
 641   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 642   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 643 fi
 644 AC_SUBST(READLINE)
 645 AC_SUBST(READLINE_DEPS)
 646 AC_SUBST(READLINE_CFLAGS)
 647 AC_SUBST(READLINE_TEXI_INCFLAG)
 648
 649 # Generate jit-reader.h
 650
 651 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 652 TARGET_PTR=
 653
 654 AC_CHECK_SIZEOF(unsigned long long)
 655 AC_CHECK_SIZEOF(unsigned long)
 656 AC_CHECK_SIZEOF(unsigned __int128)
 657
 658 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 659   TARGET_PTR="unsigned long"
 660 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 661   TARGET_PTR="unsigned long long"
 662 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 663   TARGET_PTR="unsigned __int128"
 664 else
 665   TARGET_PTR="unsigned long"
 666 fi
 667
 668 AC_SUBST(TARGET_PTR)
 669 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 670
 671 AC_SEARCH_LIBS(dlopen, dl)
 672
 673 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 674                 [directory to load the JIT readers from],
 675                 [${libdir}/gdb])
 676
 677 AC_ARG_WITH(expat,
 678   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 679   [], [with_expat=auto])
 680 AC_MSG_CHECKING([whether to use expat])
 681 AC_MSG_RESULT([$with_expat])
 682
 683 if test "${with_expat}" = no; then
 684   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 685   HAVE_LIBEXPAT=no
 686 else
 687   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 688                         [XML_Parser p = XML_ParserCreate (0);])
 689   if test "$HAVE_LIBEXPAT" != yes; then
 690     if test "$with_expat" = yes; then
 691       AC_MSG_ERROR([expat is missing or unusable])
 692     else
 693       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 694     fi
 695   else
 696     save_LIBS=$LIBS
 697     LIBS="$LIBS $LIBEXPAT"
 698     AC_CHECK_FUNCS(XML_StopParser)
 699     LIBS=$save_LIBS
 700   fi
 701 fi
 702
 703 # --------------------- #
 704 # Check for libpython.  #
 705 # --------------------- #
 706
 707 dnl Utility to simplify finding libpython.
 708 dnl $1 = pythonX.Y
 709 dnl $2 = the shell variable to assign the result to
 710 dnl      If libpython is found we store $version here.
 711 dnl $3 = additional flags to add to CPPFLAGS
 712 dnl $4 = additional flags to add to LIBS
 713
 714 AC_DEFUN([AC_TRY_LIBPYTHON],
 715 [
 716   version=$1
 717   define([have_libpython_var],$2)
 718   new_CPPFLAGS=$3
 719   new_LIBS=$4
 720   AC_MSG_CHECKING([for ${version}])
 721   save_CPPFLAGS=$CPPFLAGS
 722   save_LIBS=$LIBS
 723   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 724   LIBS="$LIBS $new_LIBS"
 725   found_usable_python=no
 726   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 727                                  [[Py_Initialize ();]]),
 728                  [have_libpython_var=${version}
 729                   found_usable_python=yes
 730                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 731                   PYTHON_LIBS=$new_LIBS])
 732   CPPFLAGS=$save_CPPFLAGS
 733   LIBS=$save_LIBS
 734   AC_MSG_RESULT([${found_usable_python}])
 735 ])
 736
 737 dnl There are several different values for --with-python:
 738 dnl
 739 dnl no -   Don't include python support.
 740 dnl yes -  Include python support, error if it's missing.
 741 dnl        If we find python in $PATH, use it to fetch configure options,
 742 dnl        otherwise assume the compiler can find it with no help from us.
 743 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 744 dnl auto - Same as "yes", but if python is missing from the system,
 745 dnl        fall back to "no".
 746 dnl /path/to/python/exec-prefix -
 747 dnl        Use the python located in this directory.
 748 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 749 dnl        the compilation parameters.  Otherwise use
 750 dnl        -I/path/to/python/exec-prefix/include,
 751 dnl        -L/path/to/python/exec-prefix/lib.
 752 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 753 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 754 dnl        but is deprecated.
 755 dnl /path/to/python/executable -
 756 dnl        Run python-config.py with this version of python to fetch the
 757 dnl        compilation parameters.
 758 dnl        NOTE: This needn't be the real python executable.
 759 dnl        In a cross-compilation scenario (build != host), this could be
 760 dnl        a shell script that provides what python-config.py provides for
 761 dnl        --ldflags, --includes, --exec-prefix.
 762 dnl python-executable -
 763 dnl        Find python-executable in $PATH, and then handle the same as
 764 dnl        /path/to/python/executable.
 765 dnl
 766 dnl If a python program is specified, it is used to run python-config.py and
 767 dnl is passed --ldflags, --includes, --exec-prefix.
 768
 769 AC_ARG_WITH(python,
 770   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 771   [], [with_python=auto])
 772 AC_MSG_CHECKING([whether to use python])
 773 AC_MSG_RESULT([$with_python])
 774
 775 if test "${with_python}" = no; then
 776   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 777   have_libpython=no
 778 else
 779   case "${with_python}" in
 780   [[\\/]]* | ?:[[\\/]]*)
 781     if test -d ${with_python}; then
 782       # Assume the python binary is ${with_python}/bin/python.
 783       python_prog="${with_python}/bin/python"
 784       python_prefix=
 785       # If python does not exit ${with_python}/bin, then try in
 786       # ${with_python}.  On Windows/MinGW, this is where the Python
 787       # executable is.
 788       if test ! -x "${python_prog}"; then
 789         python_prog="${with_python}/python"
 790         python_prefix=
 791       fi
 792       if test ! -x "${python_prog}"; then
 793         # Fall back to gdb 7.0/7.1 behaviour.
 794         python_prog=missing
 795         python_prefix=${with_python}
 796       fi
 797     elif test -x "${with_python}"; then
 798       # While we can't run python compiled for $host (unless host == build),
 799       # the user could write a script that provides the needed information,
 800       # so we support that.
 801       python_prog=${with_python}
 802       python_prefix=
 803     else
 804       AC_ERROR(invalid value for --with-python)
 805     fi
 806     ;;
 807   */*)
 808     # Disallow --with-python=foo/bar.
 809     AC_ERROR(invalid value for --with-python)
 810     ;;
 811   *)
 812     # The user has either specified auto, yes, or the name of the python
 813     # program assumed to be in $PATH.
 814     python_prefix=
 815     case "${with_python}" in
 816     yes | auto)
 817       if test ${build} = ${host}; then
 818         AC_PATH_PROG(python_prog_path, python, missing)
 819         if test "${python_prog_path}" = missing; then
 820           python_prog=missing
 821         else
 822           python_prog=${python_prog_path}
 823         fi
 824       else
 825         # Not much we can do except assume the cross-compiler will find the
 826         # right files.
 827         python_prog=missing
 828       fi
 829       ;;
 830     *)
 831       # While we can't run python compiled for $host (unless host == build),
 832       # the user could write a script that provides the needed information,
 833       # so we support that.
 834       python_prog="${with_python}"
 835       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 836       if test "${python_prog_path}" = missing; then
 837         AC_ERROR(unable to find python program ${python_prog})
 838       fi
 839       ;;
 840     esac
 841   esac
 842
 843   if test "${python_prog}" != missing; then
 844     # We have a python program to use, but it may be too old.
 845     # Don't flag an error for --with-python=auto (the default).
 846     have_python_config=yes
 847     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --includes)
 852       fi
 853     fi
 854     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 855     if test $? != 0; then
 856       have_python_config=failed
 857       if test "${with_python}" != auto; then
 858         AC_ERROR(failure running python-config --ldflags)
 859       fi
 860     fi
 861     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 862     if test $? != 0; then
 863       have_python_config=failed
 864       if test "${with_python}" != auto; then
 865         AC_ERROR(failure running python-config --exec-prefix)
 866       fi
 867     fi
 868   else
 869     # We do not have a python executable we can use to determine where
 870     # to find the Python headers and libs.  We cannot guess the include
 871     # path from the python_prefix either, because that include path
 872     # depends on the Python version.  So, there is nothing much we can
 873     # do except assume that the compiler will be able to find those files.
 874     python_includes=
 875     python_libs=
 876     have_python_config=no
 877   fi
 878
 879   # If we have python-config, only try the configuration it provides.
 880   # Otherwise fallback on the old way of trying different versions of
 881   # python in turn.
 882
 883   have_libpython=no
 884   if test "${have_python_config}" = yes; then
 885     # Determine the Python version by extracting "-lpython<version>"
 886     # part of the python_libs. <version> is usually X.Y with X and Y
 887     # being decimal numbers, but can also be XY (seen on Windows).
 888     #
 889     # The extraction is performed using sed with a regular expression.
 890     # Initially, the regexp used was using the '?' quantifier to make
 891     # the dot in the version number optional.  Unfortunately, this
 892     # does not work with non-GNU versions of sed because, because of
 893     # what looks like a limitation (the '?' quantifier does not work
 894     # with back-references).  We work around this limitation by using
 895     # the '*' quantifier instead.  It means that, in theory, we might
 896     # match unexpected version strings such as "-lpython2..7", but
 897     # this seems unlikely in practice.  And even if that happens,
 898     # an error will be triggered later on, when checking that version
 899     # number.
 900     python_version=`echo " ${python_libs} " \
 901                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 902     case "${python_version}" in
 903     python*)
 904       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 905                        ${python_includes}, ${python_libs})
 906       ;;
 907     *)
 908       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 909       ;;
 910     esac
 911   elif test "${have_python_config}" != failed; then
 912     if test "${have_libpython}" = no; then
 913       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 914                        ${python_includes}, "${python_libs} -lpython2.7")
 915     fi
 916     if test "${have_libpython}" = no; then
 917       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 918                        ${python_includes}, "${python_libs} -lpython2.6")
 919     fi
 920     if test ${have_libpython} = no; then
 921       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 922                        ${python_includes}, "${python_libs} -lpython2.5")
 923     fi
 924     if test ${have_libpython} = no; then
 925       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 926                        ${python_includes}, "${python_libs} -lpython2.4")
 927     fi
 928   fi
 929   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 930     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 931   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 933   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 935   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 936     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 937   fi
 938
 939   if test "${have_libpython}" = no; then
 940     case "${with_python}" in
 941     yes)
 942       AC_MSG_ERROR([python is missing or unusable])
 943       ;;
 944     auto)
 945       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 946       ;;
 947     *)
 948       AC_MSG_ERROR([no usable python found at ${with_python}])
 949       ;;
 950     esac
 951   else
 952     if test -n "${python_prefix}"; then
 953       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 954                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 955       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 956     fi
 957   fi
 958 fi
 959
 960 if test "${have_libpython}" != no; then
 961   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 962   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 963   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 964   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 965   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 966   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 967
 968   # Flags needed to compile Python code (taken from python-config --cflags).
 969   # We cannot call python-config directly because it will output whatever was
 970   # used when compiling the Python interpreter itself, including flags which
 971   # would make the python-related objects be compiled differently from the
 972   # rest of GDB (e.g., -O2 and -fPIC).
 973   if test "${GCC}" = yes; then
 974     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 975   fi
 976
 977   if test "x${tentative_python_cflags}" != x; then
 978     AC_MSG_CHECKING(compiler flags for python code)
 979     for flag in ${tentative_python_cflags}; do
 980       # Check that the compiler accepts it
 981       saved_CFLAGS="$CFLAGS"
 982       CFLAGS="$CFLAGS $flag"
 983       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 984       CFLAGS="$saved_CFLAGS"
 985     done
 986     AC_MSG_RESULT(${PYTHON_CFLAGS})
 987   fi
 988
 989   # On x64 Windows, Python's include headers, and pyconfig.h in
 990   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 991   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 992   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 993   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 994   # The issue was reported to the Python community, but still isn't
 995   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 996
 997   case "$gdb_host" in
 998     mingw64)
 999            if test "${GCC}" = yes; then
1000              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1001            fi
1002            ;;
1003   esac
1004
1005   # Note that "python -m threading" cannot be used to check for
1006   # threading support due to a bug in Python 2.7.3
1007   # (http://bugs.python.org/issue15567).
1008   AC_MSG_CHECKING(whether python supports threads)
1009   saved_CPPFLAGS="${CPPFLAGS}"
1010   CPPFLAGS="${PYTHON_CPPFLAGS}"
1011   # Note that the test is reversed so that python_has_threads=yes on
1012   # unexpected failures.
1013   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1014 #include <Python.h>
1015 #ifdef WITH_THREAD
1016 # error
1017 #endif
1018   ]]), [python_has_threads=no], [python_has_threads=yes])
1019   AC_MSG_RESULT(${python_has_threads})
1020   CPPFLAGS="${saved_CPPFLAGS}"
1021 else
1022   # Even if Python support is not compiled in, we need to have this file
1023   # included so that the "python" command, et.al., still exists.
1024   CONFIG_OBS="$CONFIG_OBS python.o"
1025   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1026 fi
1027
1028 # Work around Python http://bugs.python.org/issue10112.  See also
1029 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1030 # no effect.  Note that the only test after this that uses Python is
1031 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1032 # run without -export-dynamic too.
1033 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1034
1035 AC_SUBST(PYTHON_CFLAGS)
1036 AC_SUBST(PYTHON_CPPFLAGS)
1037 AC_SUBST(PYTHON_LIBS)
1038 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1039
1040 # -------------------- #
1041 # Check for libguile.  #
1042 # -------------------- #
1043
1044 dnl Utility to simplify finding libguile.
1045 dnl $1 = pkg-config-program
1046 dnl $2 = space-separate list of guile versions to try
1047 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1048 dnl $4 = the shell variable to assign the result to
1049 dnl      If libguile is found we store "yes" here.
1050
1051 AC_DEFUN([AC_TRY_LIBGUILE],
1052 [
1053   pkg_config=$1
1054   guile_version_list=$2
1055   flag_errors=$3
1056   define([have_libguile_var],$4)
1057   found_usable_guile=checking
1058   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1059   for guile_version in ${guile_version_list}; do
1060     ${pkg_config} --exists ${guile_version} 2>/dev/null
1061     if test $? != 0; then
1062       continue
1063     fi
1064     dnl pkg-config says the package exists, so if we get an error now,
1065     dnl that's bad.
1066     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1067     if test $? != 0; then
1068       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1069     fi
1070     new_LIBS=`${pkg_config} --libs ${guile_version}`
1071     if test $? != 0; then
1072       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1073     fi
1074     dnl If we get this far, great.
1075     found_usable_guile=${guile_version}
1076     break
1077   done
1078   if test "${found_usable_guile}" = "checking"; then
1079     if test "${flag_errors}" = "yes"; then
1080       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1081     else
1082       found_usable_guile=no
1083     fi
1084   fi
1085   dnl One final sanity check.
1086   dnl The user could have said --with-guile=python-2.7.
1087   if test "${found_usable_guile}" != no; then
1088     save_CPPFLAGS=$CPPFLAGS
1089     save_LIBS=$LIBS
1090     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1091     LIBS="$LIBS $new_LIBS"
1092     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1093                                    [[scm_init_guile ();]]),
1094                    [have_libguile_var=yes
1095                     GUILE_CPPFLAGS=$new_CPPFLAGS
1096                     GUILE_LIBS=$new_LIBS],
1097                    [found_usable_guile=no])
1098     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1099     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1100       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1101                 [Define if Guile supports manual finalization.])
1102     )
1103     CPPFLAGS=$save_CPPFLAGS
1104     LIBS=$save_LIBS
1105     if test "${found_usable_guile}" = no; then
1106       if test "${flag_errors}" = yes; then
1107         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1108       fi
1109     fi
1110   fi
1111   AC_MSG_RESULT([${found_usable_guile}])
1112 ])
1113
1114 dnl There are several different values for --with-guile:
1115 dnl
1116 dnl no -   Don't include guile support.
1117 dnl yes -  Include guile support, error if it's missing.
1118 dnl        The pkg-config program must be in $PATH.
1119 dnl auto - Same as "yes", but if guile is missing from the system,
1120 dnl        fall back to "no".
1121 dnl guile-version [guile-version-choice-2 ...] -
1122 dnl        A space-separated list of guile package versions to try.
1123 dnl        These are passed to pkg-config as-is.
1124 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1125 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1126 dnl /path/to/pkg-config -
1127 dnl        Use this pkg-config program.
1128 dnl        NOTE: This needn't be the "real" pkg-config program.
1129 dnl        It could be a shell script.  It is invoked as:
1130 dnl        pkg-config --exists $version
1131 dnl        pkg-config --cflags $version
1132 dnl        pkg-config --libs $version
1133 dnl        pkg-config --variable guild $version
1134 dnl        The script will be called with $version having each value in
1135 dnl        $try_guile_versions until --exists indicates success.
1136
1137 AC_ARG_WITH(guile,
1138   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1139   [], [with_guile=auto])
1140 AC_MSG_CHECKING([whether to use guile])
1141 AC_MSG_RESULT([$with_guile])
1142
1143 dnl We check guile with pkg-config.
1144 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1145
1146 try_guile_versions="guile-2.2 guile-2.0"
1147 have_libguile=no
1148 case "${with_guile}" in
1149 no)
1150   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1151   ;;
1152 auto)
1153   if test "${pkg_config_prog_path}" = "missing"; then
1154     AC_MSG_WARN([pkg-config not found, guile support disabled])
1155   else
1156     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1157   fi
1158   ;;
1159 yes)
1160   if test "${pkg_config_prog_path}" = "missing"; then
1161     AC_MSG_ERROR([pkg-config not found])
1162   fi
1163   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1164   ;;
1165 [[\\/]]* | ?:[[\\/]]*)
1166   if test -x "${with_guile}"; then
1167     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1168   else
1169     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1170   fi
1171   ;;
1172 "" | */*)
1173   # Disallow --with=guile="" and --with-guile=foo/bar.
1174   AC_MSG_ERROR([invalid value for --with-guile])
1175   ;;
1176 *)
1177   # A space separate list of guile versions to try, in order.
1178   if test "${pkg_config_prog_path}" = "missing"; then
1179     AC_MSG_ERROR([pkg-config not found])
1180   fi
1181   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1182   ;;
1183 esac
1184
1185 if test "${have_libguile}" != no; then
1186   dnl Get the name of the 'guild' program.
1187   case "${with_guile}" in
1188   [[\\/]]* | ?:[[\\/]]*)
1189     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1190     ;;
1191   *)
1192     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1193     ;;
1194   esac
1195
1196   dnl Make sure guild can handle this host.
1197   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1198   dnl If not, disable guile support.
1199   if test "$ac_cv_guild_ok" = no; then
1200     have_libguile=no
1201     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1202   fi
1203 fi
1204
1205 if test "${have_libguile}" != no; then
1206   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1207   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1208   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1209   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1210   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1211   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1212
1213   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1214   save_LIBS="$LIBS"
1215   save_CPPFLAGS="$CPPFLAGS"
1216   LIBS="$GUILE_LIBS"
1217   CPPFLAGS="$GUILE_CPPFLAGS"
1218   AC_CHECK_FUNCS([scm_new_smob])
1219   LIBS="$save_LIBS"
1220   CPPFLAGS="$save_CPPFLAGS"
1221 else
1222   # Even if Guile support is not compiled in, we need to have these files
1223   # included.
1224   CONFIG_OBS="$CONFIG_OBS guile.o"
1225   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1226 fi
1227 AC_SUBST(GUILE_CPPFLAGS)
1228 AC_SUBST(GUILE_LIBS)
1229 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1230
1231 # --------------------- #
1232 # Check for libmcheck.  #
1233 # --------------------- #
1234
1235 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1236 # but turn it off if Python is enabled with threads, since -lmcheck is
1237 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1238 # and for releases.
1239 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1240    && $development; then
1241   libmcheck_default=yes
1242 else
1243   libmcheck_default=no
1244 fi
1245 GDB_AC_LIBMCHECK(${libmcheck_default})
1246
1247 if test "$ENABLE_LIBMCHECK" = "yes" \
1248         -a "${have_libpython}" != "no" \
1249         -a "${python_has_threads}" = "yes" ; then
1250   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1251 fi
1252
1253 AC_ARG_WITH(intel_pt,
1254   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1255   [], [with_intel_pt=auto])
1256 AC_MSG_CHECKING([whether to use intel pt])
1257 AC_MSG_RESULT([$with_intel_pt])
1258
1259 if test "${with_intel_pt}" = no; then
1260   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1261   HAVE_LIBIPT=no
1262 else
1263   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1264 #include <linux/perf_event.h>
1265 #ifndef PERF_ATTR_SIZE_VER5
1266 # error
1267 #endif
1268   ]]), [perf_event=yes], [perf_event=no])
1269   if test "$perf_event" != yes; then
1270     if test "$with_intel_pt" = yes; then
1271       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1272     else
1273       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1274     fi
1275   fi
1276
1277   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1278   if test "$HAVE_LIBIPT" != yes; then
1279     if test "$with_intel_pt" = yes; then
1280       AC_MSG_ERROR([libipt is missing or unusable])
1281     else
1282       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1283     fi
1284   fi
1285 fi
1286
1287 # ------------------------- #
1288 # Checks for header files.  #
1289 # ------------------------- #
1290
1291 AC_HEADER_STDC
1292 # elf_hp.h is for HP/UX 64-bit shared library support.
1293 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1294                   thread_db.h \
1295                   sys/fault.h \
1296                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1297                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1298                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1299                   termios.h termio.h \
1300                   sgtty.h elf_hp.h \
1301                   dlfcn.h])
1302 AC_CHECK_HEADERS(sys/proc.h, [], [],
1303 [#if HAVE_SYS_PARAM_H
1304 # include <sys/param.h>
1305 #endif
1306 ])
1307 AC_CHECK_HEADERS(sys/user.h, [], [],
1308 [#if HAVE_SYS_PARAM_H
1309 # include <sys/param.h>
1310 #endif
1311 ])
1312
1313 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1314 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1315 # think that we don't have <curses.h> if we're using GCC.
1316 case $host_os in
1317   solaris2.[[789]])
1318     if test "$GCC" = yes; then
1319       AC_DEFINE(_MSE_INT_H, 1,
1320         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1321    Solaris 2.[789] when using GCC. ])
1322     fi ;;
1323 esac
1324 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1325 AC_CHECK_HEADERS(term.h, [], [],
1326 [#if HAVE_CURSES_H
1327 # include <curses.h>
1328 #endif
1329 ])
1330
1331 # ------------------------- #
1332 # Checks for declarations.  #
1333 # ------------------------- #
1334
1335 libiberty_INIT
1336
1337 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1338 AM_LC_MESSAGES
1339
1340 # ----------------------- #
1341 # Checks for structures.  #
1342 # ----------------------- #
1343
1344 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1345
1346 # ------------------ #
1347 # Checks for types.  #
1348 # ------------------ #
1349
1350 AC_CHECK_TYPES(socklen_t, [], [],
1351 [#include <sys/types.h>
1352 #include <sys/socket.h>
1353 ])
1354
1355 # ------------------------------------- #
1356 # Checks for compiler characteristics.  #
1357 # ------------------------------------- #
1358
1359 AC_C_CONST
1360 AC_C_INLINE
1361 AC_C_BIGENDIAN
1362
1363 # ------------------------------ #
1364 # Checks for library functions.  #
1365 # ------------------------------ #
1366
1367 AC_FUNC_MMAP
1368 AC_FUNC_VFORK
1369 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1370                 pipe poll pread pread64 pwrite resize_term \
1371                 sbrk setpgid setpgrp setsid \
1372                 sigaction sigprocmask sigsetmask socketpair \
1373                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1374                 setrlimit getrlimit posix_madvise waitpid \
1375                 ptrace64 sigaltstack mkdtemp setns])
1376 AM_LANGINFO_CODESET
1377 GDB_AC_COMMON
1378
1379 # Check the return and argument types of ptrace.
1380 GDB_AC_PTRACE
1381
1382 dnl AC_FUNC_SETPGRP does not work when cross compiling
1383 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1384 if test "$cross_compiling" = no; then
1385   AC_FUNC_SETPGRP
1386 else
1387   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1388     [AC_TRY_COMPILE([
1389 #include <unistd.h>
1390 ], [
1391   if (setpgrp(1,1) == -1)
1392     exit (0);
1393   else
1394     exit (1);
1395 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1396 if test $ac_cv_func_setpgrp_void = yes; then
1397   AC_DEFINE(SETPGRP_VOID, 1)
1398 fi
1399 fi
1400
1401 # Assume we'll default to using the included libiberty regex.
1402 gdb_use_included_regex=yes
1403
1404 # However, if the system regex is GNU regex, then default to *not*
1405 # using the included regex.
1406 AC_CACHE_CHECK(
1407   [for GNU regex],
1408   [gdb_cv_have_gnu_regex],
1409   [AC_TRY_COMPILE(
1410     [#include <gnu-versions.h>],
1411     [#define REGEX_INTERFACE_VERSION 1
1412 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1413 # error "Version mismatch"
1414 #endif],
1415     gdb_cv_have_gnu_regex=yes,
1416     gdb_cv_have_gnu_regex=no)])
1417 if test $gdb_cv_have_gnu_regex = yes; then
1418   gdb_use_included_regex=no
1419 fi
1420
1421 AC_ARG_WITH(included-regex,
1422   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1423   gdb_with_regex=$withval,
1424   gdb_with_regex=$gdb_use_included_regex)
1425 if test "$gdb_with_regex" = yes; then
1426   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1427     [Define to 1 if the regex included in libiberty should be used.])
1428 fi
1429
1430 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1431 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1432 [#include <sys/param.h>
1433 #include <sys/proc.h>
1434 ])
1435
1436 # See if <sys/lwp.h> defines `struct lwp`.
1437 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1438 [AC_TRY_COMPILE([#include <sys/param.h>
1439 #include <sys/lwp.h>], [struct lwp l;],
1440 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1441 if test $gdb_cv_struct_lwp = yes; then
1442   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1443             [Define to 1 if your system has struct lwp.])
1444 fi
1445
1446 # See if <machine/reg.h> degines `struct reg'.
1447 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1448 [AC_TRY_COMPILE([#include <sys/types.h>
1449 #include <machine/reg.h>], [struct reg r;],
1450 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1451 if test $gdb_cv_struct_reg = yes; then
1452   AC_DEFINE(HAVE_STRUCT_REG, 1,
1453             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1454 fi
1455
1456 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1457 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1458 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1459                  [#include <sys/types.h>
1460 #include <machine/reg.h>])
1461
1462 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1463 # Older amd64 Linux's don't have the fs_base and gs_base members of
1464 # `struct user_regs_struct'.
1465 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1466                  [], [], [#include <sys/user.h>])
1467
1468 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1469 AC_MSG_CHECKING(for PTRACE_GETREGS)
1470 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1471 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1472                 [PTRACE_GETREGS;],
1473                 [gdb_cv_have_ptrace_getregs=yes],
1474                 [gdb_cv_have_ptrace_getregs=no])])
1475 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1476 if test $gdb_cv_have_ptrace_getregs = yes; then
1477   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1478   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1479 fi
1480
1481 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1482 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1483 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1484 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1485                 [PTRACE_GETFPXREGS;],
1486                 [gdb_cv_have_ptrace_getfpxregs=yes],
1487                 [gdb_cv_have_ptrace_getfpxregs=no])])
1488 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1489 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1490   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1491   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1492 fi
1493
1494 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1495 AC_MSG_CHECKING(for PT_GETDBREGS)
1496 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1497 [AC_TRY_COMPILE([#include <sys/types.h>
1498 #include <sys/ptrace.h>],
1499                 [PT_GETDBREGS;],
1500                 [gdb_cv_have_pt_getdbregs=yes],
1501                 [gdb_cv_have_pt_getdbregs=no])])
1502 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1503 if test $gdb_cv_have_pt_getdbregs = yes; then
1504   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1505   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1506 fi
1507
1508 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1509 AC_MSG_CHECKING(for PT_GETXMMREGS)
1510 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1511 [AC_TRY_COMPILE([#include <sys/types.h>
1512 #include <sys/ptrace.h>],
1513                 [PT_GETXMMREGS;],
1514                 [gdb_cv_have_pt_getxmmregs=yes],
1515                 [gdb_cv_have_pt_getxmmregs=no])])
1516 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1517 if test $gdb_cv_have_pt_getxmmregs = yes; then
1518   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1519   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1520 fi
1521
1522 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1523 # Older FreeBSD versions don't have the pl_tdname member of
1524 # `struct ptrace_lwpinfo'.
1525 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1526                  [#include <sys/ptrace.h>])
1527
1528
1529 # Detect which type of /proc is in use, such as for Solaris.
1530
1531 if test "${target}" = "${host}"; then
1532   case "${host}" in
1533   *-*-sysv4.2* | *-*-sysv5* )
1534       AC_DEFINE(NEW_PROC_API, 1,
1535       [Define if you want to use new multi-fd /proc interface.])
1536       ;;
1537   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1538       AC_DEFINE(NEW_PROC_API, 1,
1539       [Define if you want to use new multi-fd /proc interface.])
1540       ;;
1541   mips-sgi-irix5*)
1542       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1543       AC_DEFINE([_KMEMUSER], 1,
1544       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1545        around a <sys/proc.h> problem on IRIX 5.])
1546       ;;
1547   esac
1548 fi
1549
1550 if test "$ac_cv_header_sys_procfs_h" = yes; then
1551   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1552   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1553   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1554   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1555   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1556   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1557   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1558   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1559   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1560   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1561   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1562
1563
1564   dnl Check for broken prfpregset_t type
1565
1566   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1567   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1568   dnl instead of the struct itself).  We detect this here, and work
1569   dnl around it in gdb_proc_service.h.
1570
1571   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1572     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1573     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1574       [AC_TRY_RUN([#include <sys/procfs.h>
1575        int main ()
1576        {
1577          if (sizeof (prfpregset_t) == sizeof (void *))
1578            return 1;
1579          return 0;
1580        }],
1581        gdb_cv_prfpregset_t_broken=no,
1582        gdb_cv_prfpregset_t_broken=yes,
1583        gdb_cv_prfpregset_t_broken=yes)])
1584     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1585     if test $gdb_cv_prfpregset_t_broken = yes; then
1586       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1587       [Define if the prfpregset_t type is broken.])
1588     fi
1589   fi
1590 fi
1591
1592 # Check if the compiler supports the `long long' type.
1593
1594 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1595                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1596 [[extern long long foo;]],
1597 [[switch (foo & 2) { case 0: return 1; }]])],
1598                                   gdb_cv_c_long_long=yes,
1599                                   gdb_cv_c_long_long=no)])
1600 if test $gdb_cv_c_long_long != yes; then
1601   # libdecnumber requires long long.
1602   AC_MSG_ERROR([Compiler must support long long for GDB.])
1603 fi
1604
1605 # Check if the compiler and runtime support printing long longs.
1606
1607 AC_CACHE_CHECK([for long long support in printf],
1608                gdb_cv_printf_has_long_long,
1609                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1610 [[char buf[32];
1611   long long l = 0;
1612   l = (l << 16) + 0x0123;
1613   l = (l << 16) + 0x4567;
1614   l = (l << 16) + 0x89ab;
1615   l = (l << 16) + 0xcdef;
1616   sprintf (buf, "0x%016llx", l);
1617   return (strcmp ("0x0123456789abcdef", buf));]])],
1618                               gdb_cv_printf_has_long_long=yes,
1619                               gdb_cv_printf_has_long_long=no,
1620                               gdb_cv_printf_has_long_long=no)])
1621 if test $gdb_cv_printf_has_long_long = yes; then
1622   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1623             [Define to 1 if the "%ll" format works to print long longs.])
1624 fi
1625
1626 # Check if the compiler and runtime support printing decfloats.
1627
1628 AC_CACHE_CHECK([for decfloat support in printf],
1629                gdb_cv_printf_has_decfloat,
1630                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1631 [[char buf[64];
1632   _Decimal32 d32 = 1.2345df;
1633   _Decimal64 d64 = 1.2345dd;
1634   _Decimal128 d128 = 1.2345dl;
1635   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1636   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1637                               gdb_cv_printf_has_decfloat=yes,
1638                               gdb_cv_printf_has_decfloat=no,
1639                               gdb_cv_printf_has_decfloat=no)])
1640 if test $gdb_cv_printf_has_decfloat = yes; then
1641   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1642             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1643 fi
1644
1645 # Check if the compiler supports the `long double' type.  We can't use
1646 # AC_C_LONG_DOUBLE because that one does additional checks on the
1647 # constants defined in <float.h> that fail on some systems,
1648 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1649
1650 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1651                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1652                                   gdb_cv_c_long_double=yes,
1653                                   gdb_cv_c_long_double=no)])
1654 if test $gdb_cv_c_long_double = yes; then
1655   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1656            [Define to 1 if the compiler supports long double.])
1657 fi
1658
1659 # Check if the compiler and runtime support printing long doubles.
1660
1661 AC_CACHE_CHECK([for long double support in printf],
1662                gdb_cv_printf_has_long_double,
1663                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1664 [[char buf[16];
1665   long double f = 3.141592653;
1666   sprintf (buf, "%Lg", f);
1667   return (strncmp ("3.14159", buf, 7));]])],
1668                               gdb_cv_printf_has_long_double=yes,
1669                               gdb_cv_printf_has_long_double=no,
1670                               gdb_cv_printf_has_long_double=no)])
1671 if test $gdb_cv_printf_has_long_double = yes; then
1672   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1673             [Define to 1 if the "%Lg" format works to print long doubles.])
1674 fi
1675
1676 # Check if the compiler and runtime support scanning long doubles.
1677
1678 AC_CACHE_CHECK([for long double support in scanf],
1679                gdb_cv_scanf_has_long_double,
1680                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1681 [[#include <stdio.h>]],
1682 [[char *buf = "3.141592653";
1683   long double f = 0;
1684   sscanf (buf, "%Lg", &f);
1685   return !(f > 3.14159 && f < 3.14160);]])],
1686                               gdb_cv_scanf_has_long_double=yes,
1687                               gdb_cv_scanf_has_long_double=no,
1688                               gdb_cv_scanf_has_long_double=no)])
1689 if test $gdb_cv_scanf_has_long_double = yes; then
1690   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1691             [Define to 1 if the "%Lg" format works to scan long doubles.])
1692 fi
1693
1694 case ${host_os} in
1695 aix*)
1696   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1697     SAVE_LDFLAGS=$LDFLAGS
1698
1699     case $GCC in
1700     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1701     *) gdb_cv_bigtoc=-bbigtoc ;;
1702     esac
1703
1704     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1705     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1706     LDFLAGS="${SAVE_LDFLAGS}"
1707   ])
1708   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1709   ;;
1710 esac
1711
1712 AC_MSG_CHECKING(for the dynamic export flag)
1713 dynamic_list=false
1714 if test "${gdb_native}" = yes; then
1715    # The dynamically loaded libthread_db needs access to symbols in the gdb
1716    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1717    # may not be supported there.
1718    old_LDFLAGS="$LDFLAGS"
1719    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1720    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1721    LDFLAGS="$LDFLAGS $RDYNAMIC"
1722    if test "${have_libpython}" = no; then
1723      AC_TRY_LINK([], [], [dynamic_list=true])
1724    else
1725      # Workaround http://bugs.python.org/issue4434 where static
1726      # libpythonX.Y.a would get its symbols required for
1727      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1728      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1729
1730      # Note the workaround for Python
1731      # http://bugs.python.org/issue10112 earlier has removed
1732      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1733      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1734      # always pass.
1735      old_CFLAGS="$CFLAGS"
1736      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1737      old_LIBS="$LIBS"
1738      LIBS="$LIBS $PYTHON_LIBS"
1739      old_CPPFLAGS="$CPPFLAGS"
1740      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1741      AC_RUN_IFELSE(
1742        AC_LANG_PROGRAM(
1743          [#include "Python.h"],
1744          [int err;
1745           Py_Initialize ();
1746           err = PyRun_SimpleString ("import itertools\n");
1747           Py_Finalize ();
1748           return err == 0 ? 0 : 1;]),
1749        [dynamic_list=true], [], [true])
1750      LIBS="$old_LIBS"
1751      CFLAGS="$old_CFLAGS"
1752      CPPFLAGS="$old_CPPFLAGS"
1753    fi
1754    LDFLAGS="$old_LDFLAGS"
1755 fi
1756 if $dynamic_list; then
1757   found="-Wl,--dynamic-list"
1758   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1759 else
1760   found="-rdynamic"
1761   RDYNAMIC="-rdynamic"
1762 fi
1763 AC_SUBST(RDYNAMIC)
1764 AC_MSG_RESULT($found)
1765
1766 dnl For certain native configurations, we need to check whether thread
1767 dnl support can be built in or not.
1768 dnl
1769 dnl Note that we only want this if we are both native (host == target),
1770 dnl and not doing a canadian cross build (build == host).
1771
1772 if test ${build} = ${host} -a ${host} = ${target} ; then
1773    case ${host_os} in
1774    solaris*)
1775       # See if thread_db library is around for Solaris thread debugging.
1776       # Note that we must explicitly test for version 1 of the library
1777       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1778       # the same API.
1779       AC_MSG_CHECKING(for Solaris thread debugging library)
1780       if test -f /usr/lib/libthread_db.so.1 ; then
1781          AC_MSG_RESULT(yes)
1782          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1783          [Define if using Solaris thread debugging.])
1784          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1785          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1786          AC_CHECK_LIB(dl, dlopen)
1787          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1788          # Sun randomly tweaked the prototypes in <proc_service.h>
1789          # at one point.
1790          AC_MSG_CHECKING(if <proc_service.h> is old)
1791          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1792             AC_TRY_COMPILE([
1793                 #include <proc_service.h>
1794                 ps_err_e ps_pdwrite
1795                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1796             ],, gdb_cv_proc_service_is_old=no,
1797                 gdb_cv_proc_service_is_old=yes)
1798          ])
1799          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1800          if test $gdb_cv_proc_service_is_old = yes; then
1801             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1802             [Define if <proc_service.h> on solaris uses int instead of
1803              size_t, and assorted other type changes.])
1804          fi
1805       else
1806          AC_MSG_RESULT(no)
1807       fi
1808       ;;
1809    aix*)
1810       AC_MSG_CHECKING(for AiX thread debugging library)
1811       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1812                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1813                                    [#ifndef PTHDB_VERSION_3
1814                                     #error
1815                                     #endif],
1816                                    gdb_cv_have_aix_thread_debug=yes,
1817                                    gdb_cv_have_aix_thread_debug=no)])
1818       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1819       if test $gdb_cv_have_aix_thread_debug = yes; then
1820          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1821          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1822          LIBS="$LIBS -lpthdebug"
1823
1824          # Older versions of AIX do not provide the declaration for
1825          # the getthrds function (it appears that it was introduced
1826          # with AIX 6.x).
1827          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1828       fi
1829       ;;
1830    esac
1831    AC_SUBST(CONFIG_LDFLAGS)
1832 fi
1833
1834 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1835 dnl other error codes.
1836 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1837    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1838                   gdb_cv_thread_db_h_has_td_notalloc,
1839      AC_TRY_COMPILE(
1840        [#include <thread_db.h>],
1841        [int i = TD_NOTALLOC;],
1842        gdb_cv_thread_db_h_has_td_notalloc=yes,
1843        gdb_cv_thread_db_h_has_td_notalloc=no
1844      )
1845    )
1846    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1847                   gdb_cv_thread_db_h_has_td_version,
1848      AC_TRY_COMPILE(
1849        [#include <thread_db.h>],
1850        [int i = TD_VERSION;],
1851        gdb_cv_thread_db_h_has_td_version=yes,
1852        gdb_cv_thread_db_h_has_td_version=no
1853      )
1854    )
1855    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1856                   gdb_cv_thread_db_h_has_td_notls,
1857      AC_TRY_COMPILE(
1858        [#include <thread_db.h>],
1859        [int i = TD_NOTLS;],
1860        gdb_cv_thread_db_h_has_td_notls=yes,
1861        gdb_cv_thread_db_h_has_td_notls=no
1862      )
1863    )
1864 fi
1865 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1866   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1867             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1868 fi
1869 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1870   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1871             [Define if <thread_db.h> has the TD_VERSION error code.])
1872 fi
1873 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1874   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1875             [Define if <thread_db.h> has the TD_NOTLS error code.])
1876 fi
1877
1878 dnl Check if we can disable the virtual address space randomization.
1879 dnl The functionality of setarch -R.
1880 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1881 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1882 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1883 #       define ADDR_NO_RANDOMIZE 0x0040000
1884 #      endif
1885        /* Test the flag could be set and stays set.  */
1886        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1887        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1888            return 1])])
1889 AC_RUN_IFELSE([PERSONALITY_TEST],
1890               [have_personality=true],
1891               [have_personality=false],
1892               [AC_LINK_IFELSE([PERSONALITY_TEST],
1893                               [have_personality=true],
1894                               [have_personality=false])])
1895 if $have_personality
1896 then
1897     AC_DEFINE([HAVE_PERSONALITY], 1,
1898               [Define if you support the personality syscall.])
1899 fi
1900
1901 dnl Set the host's .gdbinit filename.
1902 case $host_os in
1903   go32* | *djgpp*)
1904     gdbinit=gdb.ini
1905     ;;
1906   *)
1907     gdbinit=.gdbinit
1908     ;;
1909 esac
1910 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1911
1912 dnl Handle optional features that can be enabled.
1913
1914 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1915 # except that the argument to --with-sysroot is optional.
1916 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1917 if test "x$with_sysroot" = xyes; then
1918   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1919 fi
1920 AC_ARG_WITH(sysroot,
1921   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1922                  [search for usr/lib et al within DIR]),
1923   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1924 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1925               [search for usr/lib et al within DIR])
1926 AC_SUBST(TARGET_SYSTEM_ROOT)
1927 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1928
1929 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1930     [automatically load a system-wide gdbinit file],
1931     [])
1932
1933 AM_GDB_WARNINGS
1934
1935 # In the Cygwin environment, we need some additional flags.
1936 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1937 [AC_EGREP_CPP(^lose$, [
1938 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1939 lose
1940 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1941
1942
1943 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1944 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1945 case ${host} in
1946   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1947   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1948   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1949 esac
1950 AC_SUBST(SER_HARDWIRE)
1951
1952 # libreadline needs libuser32.a in a cygwin environment
1953 WIN32LIBS=
1954 if test x$gdb_cv_os_cygwin = xyes; then
1955     WIN32LIBS="-luser32"
1956     case "${target}" in
1957         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1958         ;;
1959     esac
1960 fi
1961
1962 # The ser-tcp.c module requires sockets.
1963 case ${host} in
1964   *mingw32*)
1965     AC_DEFINE(USE_WIN32API, 1,
1966               [Define if we should use the Windows API, instead of the
1967                POSIX API.  On Windows, we use the Windows API when
1968                building for MinGW, but the POSIX API when building
1969                for Cygwin.])
1970     WIN32LIBS="$WIN32LIBS -lws2_32"
1971     ;;
1972 esac
1973 AC_SUBST(WIN32LIBS)
1974
1975 # Add ELF support to GDB, but only if BFD includes ELF support.
1976 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1977                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1978 if test $gdb_cv_var_elf = yes; then
1979   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1980   AC_DEFINE(HAVE_ELF, 1,
1981             [Define if ELF support should be included.])
1982   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1983   if test "$plugins" = "yes"; then
1984     AC_SEARCH_LIBS(dlopen, dl)
1985   fi
1986 fi
1987
1988 # Add macho support to GDB, but only if BFD includes it.
1989 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1990                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1991 if test $gdb_cv_var_macho = yes; then
1992   CONFIG_OBS="$CONFIG_OBS machoread.o"
1993 fi
1994
1995 # Add any host-specific objects to GDB.
1996 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1997
1998 # If building on ELF, look for lzma support for embedded compressed debug info.
1999 if test $gdb_cv_var_elf = yes; then
2000   AC_ARG_WITH(lzma,
2001     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2002     [], [with_lzma=auto])
2003   AC_MSG_CHECKING([whether to use lzma])
2004   AC_MSG_RESULT([$with_lzma])
2005
2006   if test "${with_lzma}" != no; then
2007     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2008                           [lzma_index_iter iter;
2009                            lzma_index_iter_init (&iter, 0);
2010                            lzma_mf_is_supported (LZMA_MF_HC3);])
2011     if test "$HAVE_LIBLZMA" != yes; then
2012       if test "$with_lzma" = yes; then
2013         AC_MSG_ERROR([missing liblzma for --with-lzma])
2014       fi
2015     fi
2016   fi
2017 fi
2018
2019 LIBGUI="../libgui/src/libgui.a"
2020 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2021 AC_SUBST(LIBGUI)
2022 AC_SUBST(GUI_CFLAGS_X)
2023
2024 WIN32LDAPP=
2025 AC_SUBST(WIN32LIBS)
2026 AC_SUBST(WIN32LDAPP)
2027
2028 case "${host}" in
2029 *-*-cygwin* | *-*-mingw* )
2030     configdir="win"
2031     ;;
2032 *)
2033     configdir="unix"
2034     ;;
2035 esac
2036
2037 GDBTKLIBS=
2038 if test "${enable_gdbtk}" = "yes"; then
2039
2040     # Gdbtk must have an absolute path to srcdir in order to run
2041     # properly when not installed.
2042     here=`pwd`
2043     cd ${srcdir}
2044     GDBTK_SRC_DIR=`pwd`
2045     cd $here
2046
2047     SC_PATH_TCLCONFIG
2048
2049     # If $no_tk is nonempty, then we can't do Tk, and there is no
2050     # point to doing Tcl.
2051     SC_PATH_TKCONFIG
2052
2053     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2054         SC_LOAD_TCLCONFIG
2055
2056         # Check for in-tree tcl
2057         here=`pwd`
2058         cd ${srcdir}/..
2059         topdir=`pwd`
2060         cd ${here}
2061
2062         intree="no"
2063         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2064           intree="yes"
2065         fi
2066
2067         # Find Tcl private headers
2068         if test x"${intree}" = xno; then
2069           CY_AC_TCL_PRIVATE_HEADERS
2070           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2071           TCL_LIBRARY="${TCL_LIB_SPEC}"
2072           TCL_DEPS=""
2073         else
2074           # If building tcl in the same src tree, private headers
2075           # are not needed, but we need to be sure to use the right
2076           # headers library
2077           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2078           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2079           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2080         fi
2081         AC_SUBST(TCL_INCLUDE)
2082         AC_SUBST(TCL_LIBRARY)
2083         AC_SUBST(TCL_DEPS)
2084
2085         SC_LOAD_TKCONFIG
2086
2087         # Check for in-tree Tk
2088         intree="no"
2089         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2090           intree="yes"
2091         fi
2092
2093         # Find Tk private headers
2094         if test x"${intree}" = xno; then
2095           CY_AC_TK_PRIVATE_HEADERS
2096           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2097           TK_LIBRARY=${TK_LIB_SPEC}
2098           TK_DEPS=""
2099         else
2100           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2101           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2102           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2103         fi
2104         AC_SUBST(TK_INCLUDE)
2105         AC_SUBST(TK_LIBRARY)
2106         AC_SUBST(TK_DEPS)
2107         AC_SUBST(TK_XINCLUDES)
2108
2109         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2110
2111         # Include some libraries that Tcl and Tk want.
2112         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2113         # Yes, the ordering seems wrong here.  But it isn't.
2114         # TK_LIBS is the list of libraries that need to be linked
2115         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2116         # were in LIBS then any link tests after this point would
2117         # try to include things like `$(LIBGUI)', which wouldn't work.
2118         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2119
2120         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2121         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2122         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2123         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2124         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2125         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2126         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2127
2128         if test x$gdb_cv_os_cygwin = xyes; then
2129           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2130           WIN32LDAPP="-Wl,--subsystem,console"
2131           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2132         fi
2133
2134         AC_CONFIG_SUBDIRS(gdbtk)
2135     fi
2136 fi
2137
2138 AC_SUBST(X_CFLAGS)
2139 AC_SUBST(X_LDFLAGS)
2140 AC_SUBST(X_LIBS)
2141 AC_SUBST(GDBTKLIBS)
2142 AC_SUBST(GDBTK_CFLAGS)
2143 AC_SUBST(GDBTK_SRC_DIR)
2144
2145 AC_PATH_X
2146
2147 # Unlike the sim directory, whether a simulator is linked is controlled by
2148 # presence of a gdb_sim definition in the target configure.tgt entry.
2149 # This code just checks for a few cases where we'd like to ignore those
2150 # definitions, even when they're present in the '.mt' file.  These cases
2151 # are when --disable-sim is specified, or if the simulator directory is
2152 # not part of the source tree.
2153 #
2154 AC_ARG_ENABLE(sim,
2155 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2156 [echo "enable_sim = $enable_sim";
2157  echo "enableval = ${enableval}";
2158  case "${enableval}" in
2159   yes) ignore_sim=false ;;
2160   no)  ignore_sim=true ;;
2161   *)   ignore_sim=false ;;
2162  esac],
2163 [ignore_sim=false])
2164
2165 if test ! -d "${srcdir}/../sim"; then
2166   ignore_sim=true
2167 fi
2168
2169 SIM=
2170 SIM_OBS=
2171 if test "${ignore_sim}" = "false"; then
2172   if test x"${gdb_sim}" != x ; then
2173     SIM="${gdb_sim}"
2174     SIM_OBS="remote-sim.o"
2175     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2176
2177     # Some tdep code should only be compiled in when the ppc sim is
2178     # built.  PR sim/13418.
2179     case $target in
2180       powerpc*-*-*)
2181         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2182         ;;
2183     esac
2184   fi
2185 fi
2186 AC_SUBST(SIM)
2187 AC_SUBST(SIM_OBS)
2188
2189 AC_SUBST(ENABLE_CFLAGS)
2190 AC_SUBST(PROFILE_CFLAGS)
2191
2192 AC_SUBST(CONFIG_OBS)
2193 AC_SUBST(CONFIG_DEPS)
2194 AC_SUBST(CONFIG_SRCS)
2195 AC_SUBST(CONFIG_ALL)
2196 AC_SUBST(CONFIG_CLEAN)
2197 AC_SUBST(CONFIG_INSTALL)
2198 AC_SUBST(CONFIG_UNINSTALL)
2199
2200 # List of host floatformats.
2201 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2202 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2203 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2204
2205 # target_subdir is used by the testsuite to find the target libraries.
2206 target_subdir=
2207 if test "${host}" != "${target}"; then
2208     target_subdir="${target_alias}/"
2209 fi
2210 AC_SUBST(target_subdir)
2211
2212 frags=
2213 if test "${gdb_native}" = "yes"; then
2214   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2215   if test ! -f ${host_makefile_frag}; then
2216     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2217   fi
2218   frags="$frags $host_makefile_frag"
2219 else
2220   host_makefile_frag=/dev/null
2221 fi
2222
2223 AC_SUBST_FILE(host_makefile_frag)
2224 AC_SUBST(frags)
2225
2226 changequote(,)dnl
2227 if test "${gdb_native}" = "yes"; then
2228 # We pick this up from the host configuration file (.mh) because we
2229 # do not have a native configuration Makefile fragment.
2230 nativefile=`sed -n '
2231 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2232 ' ${host_makefile_frag}`
2233 fi
2234 changequote([,])
2235
2236 if test x"${gdb_osabi}" != x ; then
2237     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2238                        [Define to the default OS ABI for this configuration.])
2239 fi
2240
2241 # Enable multi-ice-gdb-server.
2242 AC_ARG_ENABLE(multi-ice,
2243 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2244   [case $enableval in
2245     yes | no)
2246       ;;
2247     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2248   esac])
2249 if test "x$enable_multi_ice" = xyes; then
2250    AC_CONFIG_SUBDIRS(multi-ice)
2251 fi
2252
2253 AC_ARG_ENABLE(gdbserver,
2254 AS_HELP_STRING([--enable-gdbserver],
2255                [automatically build gdbserver (yes/no/auto, default is auto)]),
2256 [case "${enableval}" in
2257   yes| no|auto) ;;
2258   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2259 esac],[enable_gdbserver=auto])
2260
2261 # We only build gdbserver automatically in a native configuration, and
2262 # only if the user did not explicitly disable its build.
2263 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2264   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2265   if test "x$build_gdbserver" = xyes; then
2266     AC_MSG_RESULT(yes)
2267     AC_CONFIG_SUBDIRS(gdbserver)
2268     gdbserver_build_enabled=yes
2269   else
2270     AC_MSG_RESULT(no)
2271   fi
2272 fi
2273
2274 # If the user explicitly request the gdbserver to be built, verify that
2275 # we were in fact able to enable it.
2276 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2277   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2278 fi
2279
2280 # Check for babeltrace and babeltrace-ctf
2281 AC_ARG_WITH(babeltrace,
2282   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2283   [], [with_babeltrace=auto])
2284 AC_MSG_CHECKING([whether to use babeltrace])
2285 AC_MSG_RESULT([$with_babeltrace])
2286
2287 if test "x$with_babeltrace" = "xno"; then
2288   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2289 else
2290   # Append -Werror to CFLAGS so that configure can catch the warning
2291   # "assignment from incompatible pointer type", which is related to
2292   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2293   # in GDB, while babeltrace 1.0.3 is broken.
2294   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2295   # safe to save and restore CFLAGS here.
2296   saved_CFLAGS=$CFLAGS
2297   CFLAGS="$CFLAGS -Werror"
2298   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2299                         [#include <babeltrace/babeltrace.h>
2300                          #include <babeltrace/ctf/events.h>
2301                          #include <babeltrace/ctf/iterator.h>],
2302                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2303                         struct bt_ctf_event *event = NULL;
2304                         const struct bt_definition *scope;
2305
2306                         pos.type = BT_SEEK_BEGIN;
2307                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2308                         scope = bt_ctf_get_top_level_scope (event,
2309                                                            BT_STREAM_EVENT_HEADER);
2310                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2311                         ])
2312   CFLAGS=$saved_CFLAGS
2313
2314   if test "$HAVE_LIBBABELTRACE" != yes; then
2315      if test "$with_babeltrace" = yes; then
2316        AC_MSG_ERROR([babeltrace is missing or unusable])
2317      else
2318        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2319      fi
2320   fi
2321 fi
2322
2323 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2324 # to an empty version.
2325
2326 files=
2327 links=
2328
2329 rm -f nm.h
2330 if test "${nativefile}" != ""; then
2331     case "${nativefile}" in
2332       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2333       * ) GDB_NM_FILE="${nativefile}"
2334     esac
2335     files="${files} ${GDB_NM_FILE}"
2336     links="${links} nm.h"
2337     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2338 fi
2339 AC_SUBST(GDB_NM_FILE)
2340
2341 AC_LINK_FILES($files, $links)
2342
2343 dnl Check for exe extension set on certain hosts (e.g. Win32)
2344 AC_EXEEXT
2345
2346 dnl  Detect the character set used by this host.
2347 dnl  At the moment, we just assume it's UTF-8.
2348 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2349           [Define to be a string naming the default host character set.])
2350
2351 if $development; then
2352   AC_DEFINE(GDB_SELF_TEST, 1,
2353             [Define if self-testing features should be enabled])
2354 fi
2355
2356 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2357 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2358 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2359 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2360 [
2361 case x$CONFIG_HEADERS in
2362 xconfig.h:config.in)
2363 echo > stamp-h ;;
2364 esac
2365 ])
2366
2367 AC_OUTPUT