gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2016 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  48
  49 # Check for the 'make' the user wants to use.
  50 AC_CHECK_PROGS(MAKE, make)
  51 MAKE_IS_GNU=
  52 case "`$MAKE --version 2>&1 | sed 1q`" in
  53   *GNU*)
  54     MAKE_IS_GNU=yes
  55     ;;
  56 esac
  57 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  58 AC_PROG_MAKE_SET
  59
  60 gnulib_extra_configure_args=
  61 # If large-file support is disabled, make sure gnulib does the same.
  62 if test "$enable_largefile" = no; then
  63 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  64 fi
  65
  66 # Configure gnulib.  We need to build gnulib under some other
  67 # directory not "gnulib", to avoid the problem of both GDB and
  68 # GDBserver wanting to build it in the same directory, when building
  69 # in the source dir.
  70 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  71                   ["$gnulib_extra_configure_args"])
  72
  73 dnl List of object files and targets accumulated by configure.
  74
  75 CONFIG_OBS=
  76 CONFIG_DEPS=
  77 CONFIG_SRCS=
  78 ENABLE_CFLAGS=
  79
  80 CONFIG_ALL=
  81 CONFIG_CLEAN=
  82 CONFIG_INSTALL=
  83 CONFIG_UNINSTALL=
  84
  85 dnl Set up for gettext.
  86 ZW_GNU_GETTEXT_SISTER_DIR
  87
  88 localedir='${datadir}/locale'
  89 AC_SUBST(localedir)
  90
  91 if test x"$USE_NLS" = xyes; then
  92    CONFIG_ALL="$CONFIG_ALL all-po"
  93    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  94    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  95    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  96 fi
  97
  98 GNULIB=build-gnulib/import
  99
 100 # For Makefile dependencies.
 101 GNULIB_STDINT_H=
 102 if test x"$STDINT_H" != x; then
 103   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 104 fi
 105 AC_SUBST(GNULIB_STDINT_H)
 106
 107 PACKAGE=gdb
 108 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 109 AC_SUBST(PACKAGE)
 110
 111 # We never need to detect it in this sub-configure.
 112 # But preserve it for config.status --recheck.
 113 AC_ARG_VAR(MAKEINFO,
 114   [Parent configure detects if it is of sufficient version.])
 115 AC_ARG_VAR(MAKEINFOFLAGS,
 116   [Parameters for MAKEINFO.])
 117
 118 MAKEINFO_EXTRA_FLAGS=""
 119 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 120   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 121   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 122     gdb_cv_have_makeinfo_click=yes
 123   else
 124     gdb_cv_have_makeinfo_click=no
 125   fi])
 126 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 127   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 128 fi
 129 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 130
 131 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 132     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 133     [${libdir}/debug])
 134
 135 # We can't pass paths as command line arguments.
 136 # Mingw32 tries to be clever and will convert the paths for us.
 137 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 138 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 139 # This breaks GDB's relocatable path conversions since paths passed in
 140 # config.h would not get so translated, the path prefixes no longer match.
 141 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 142
 143 # GDB's datadir relocation
 144
 145 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 146     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 147     [${datadir}/gdb])
 148
 149 AC_ARG_WITH(relocated-sources,
 150 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 151 [reloc_srcdir="${withval}"
 152  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 153               [Relocated directory for source files. ])
 154 ])
 155
 156 AC_MSG_CHECKING([for default auto-load directory])
 157 AC_ARG_WITH(auto-load-dir,
 158 AS_HELP_STRING([--with-auto-load-dir=PATH],
 159   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 160   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 161 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 162 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 163               [Directories from which to load auto-loaded scripts.])
 164 AC_MSG_RESULT([$with_auto_load_dir])
 165
 166 AC_MSG_CHECKING([for default auto-load safe-path])
 167 AC_ARG_WITH(auto-load-safe-path,
 168 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 169   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 170 AS_HELP_STRING([--without-auto-load-safe-path],
 171                [do not restrict auto-loaded files locations]),
 172     [if test "$with_auto_load_safe_path" = "no"; then
 173      with_auto_load_safe_path="/"
 174      fi],
 175 [with_auto_load_safe_path="$with_auto_load_dir"])
 176 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 177 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 178               [Directories safe to hold auto-loaded files.])
 179 AC_MSG_RESULT([$with_auto_load_safe_path])
 180
 181 AC_CONFIG_SUBDIRS(testsuite)
 182
 183 # Check whether to support alternative target configurations
 184 AC_ARG_ENABLE(targets,
 185 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 186 [case "${enableval}" in
 187   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 188             ;;
 189   no)       enable_targets= ;;
 190   *)        enable_targets=$enableval ;;
 191 esac])
 192
 193 # Check whether to enable 64-bit support on 32-bit hosts
 194 AC_ARG_ENABLE(64-bit-bfd,
 195 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 196 [case "${enableval}" in
 197   yes)  want64=true  ;;
 198   no)   want64=false ;;
 199   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 200 esac],[want64=false])dnl
 201
 202 # Provide defaults for some variables set by the per-host and per-target
 203 # configuration.
 204 gdb_host_obs=posix-hdep.o
 205
 206 if test "${target}" = "${host}"; then
 207   gdb_native=yes
 208 else
 209   gdb_native=no
 210 fi
 211
 212 . $srcdir/configure.host
 213
 214 # Add in the common host objects.
 215 . $srcdir/common/common.host
 216 gdb_host_obs="$gdb_host_obs $common_host_obs"
 217
 218 # Accumulate some settings from configure.tgt over all enabled targets
 219
 220 TARGET_OBS=
 221 all_targets=
 222 HAVE_NATIVE_GCORE_TARGET=
 223
 224 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 225 do
 226   if test "$targ_alias" = "all"; then
 227     all_targets=true
 228   else
 229     # Canonicalize the secondary target names.
 230     result=`$ac_config_sub $targ_alias 2>/dev/null`
 231     if test -n "$result"; then
 232         targ=$result
 233     else
 234         targ=$targ_alias
 235     fi
 236
 237     . ${srcdir}/configure.tgt
 238
 239     AS_IF([test -z "${gdb_target_obs}"],
 240       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 241
 242     # Target-specific object files
 243     for i in ${gdb_target_obs}; do
 244         case " $TARGET_OBS " in
 245         *" ${i} "*) ;;
 246         *)
 247           TARGET_OBS="$TARGET_OBS ${i}"
 248           ;;
 249         esac
 250     done
 251
 252     # Check whether this target needs 64-bit CORE_ADDR
 253     if test x${want64} = xfalse; then
 254       . ${srcdir}/../bfd/config.bfd
 255     fi
 256
 257     # Check whether this target is native and supports gcore.
 258     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 259        && $gdb_have_gcore; then
 260       HAVE_NATIVE_GCORE_TARGET=1
 261     fi
 262   fi
 263 done
 264
 265 if test x${all_targets} = xtrue; then
 266
 267   # We want all 64-bit targets if we either:
 268   #  - run on a 64-bit host  or
 269   #  - already require 64-bit support for some other target  or
 270   #  - the --enable-64-bit-bfd option was supplied
 271   # Otherwise we only support all 32-bit targets.
 272   #
 273   # NOTE: This test must be in sync with the corresponding
 274   #       tests in BFD!
 275
 276   if test x${want64} = xfalse; then
 277     AC_CHECK_SIZEOF(long)
 278     if test "x${ac_cv_sizeof_long}" = "x8"; then
 279       want64=true
 280     fi
 281   fi
 282   if test x${want64} = xtrue; then
 283     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 284   else
 285     TARGET_OBS='$(ALL_TARGET_OBS)'
 286   fi
 287 fi
 288
 289 AC_SUBST(TARGET_OBS)
 290 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 291
 292 # For other settings, only the main target counts.
 293 gdb_sim=
 294 gdb_osabi=
 295 build_gdbserver=
 296 targ=$target; . ${srcdir}/configure.tgt
 297
 298 # Fetch the default architecture and default target vector from BFD.
 299 targ=$target; . $srcdir/../bfd/config.bfd
 300
 301 # We only want the first architecture, so strip off the others if
 302 # there is more than one.
 303 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 304
 305 if test "x$targ_archs" != x; then
 306   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 307     [Define to BFD's default architecture. ])
 308 fi
 309 if test "x$targ_defvec" != x; then
 310   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 311     [Define to BFD's default target vector. ])
 312 fi
 313
 314 # The CLI cannot be disabled yet, but may be in the future.
 315
 316 # Enable CLI.
 317 AC_ARG_ENABLE(gdbcli,
 318 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 319   [case $enableval in
 320     yes)
 321       ;;
 322     no)
 323       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 324     *)
 325       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 326   esac],
 327   [enable_gdbcli=yes])
 328 if test x"$enable_gdbcli" = xyes; then
 329   if test -d $srcdir/cli; then
 330     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 331     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 332     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 333     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 334   fi
 335 fi
 336
 337 # Enable MI.
 338 AC_ARG_ENABLE(gdbmi,
 339 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 340   [case $enableval in
 341     yes | no)
 342       ;;
 343     *)
 344       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 345   esac],
 346   [enable_gdbmi=yes])
 347 if test x"$enable_gdbmi" = xyes; then
 348   if test -d $srcdir/mi; then
 349     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 350     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 351     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 352     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 353   fi
 354 fi
 355
 356 # Enable TUI.
 357 AC_ARG_ENABLE(tui,
 358 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 359   [case $enableval in
 360     yes | no | auto)
 361       ;;
 362     *)
 363       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 364   esac],enable_tui=auto)
 365
 366 # Enable gdbtk.
 367 AC_ARG_ENABLE(gdbtk,
 368 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 369   [case $enableval in
 370     yes | no)
 371       ;;
 372     *)
 373       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 374   esac],
 375   [if test -d $srcdir/gdbtk; then
 376     enable_gdbtk=yes
 377   else
 378     enable_gdbtk=no
 379   fi])
 380 # We unconditionally disable gdbtk tests on selected platforms.
 381 case $host_os in
 382   go32* | windows*)
 383     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 384     enable_gdbtk=no ;;
 385 esac
 386
 387 # Libunwind support for ia64.
 388
 389 AC_ARG_WITH(libunwind-ia64,
 390 AS_HELP_STRING([--with-libunwind-ia64],
 391                [use libunwind frame unwinding for ia64 targets]),,
 392             [with_libunwind_ia64=auto])
 393
 394 # Backward compatibility option.
 395 if test "${with_libunwind+set}" = set; then
 396   if test x"$with_libunwind_ia64" != xauto; then
 397     AC_MSG_ERROR(
 398       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 399   fi
 400   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 401   with_libunwind_ia64="$with_libunwind"
 402 fi
 403
 404 case "$with_libunwind_ia64" in
 405   yes | no)
 406     ;;
 407   auto)
 408     AC_CHECK_HEADERS(libunwind-ia64.h)
 409     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 410     ;;
 411   *)
 412     AC_MSG_ERROR(
 413       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 414     ;;
 415 esac
 416
 417 if test x"$with_libunwind_ia64" = xyes; then
 418   AC_CHECK_HEADERS(libunwind-ia64.h)
 419   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 420     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 421   fi
 422   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 423   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 424   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 425 fi
 426
 427 opt_curses=no
 428 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 429
 430 prefer_curses=no
 431 if test "$opt_curses" = "yes"; then
 432   prefer_curses=yes
 433 fi
 434
 435 # Profiling support.
 436 AC_ARG_ENABLE(profiling,
 437 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 438   [case $enableval in
 439     yes | no)
 440       ;;
 441     *)
 442       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 443   esac],
 444  [enable_profiling=no])
 445
 446 AC_CHECK_FUNCS(monstartup _mcleanup)
 447 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 448 [AC_TRY_LINK(
 449 [#include <stdlib.h>
 450 extern char _etext;
 451 ],
 452 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 453 if test $ac_cv_var__etext = yes; then
 454   AC_DEFINE(HAVE__ETEXT, 1,
 455             [Define to 1 if your system has the _etext variable. ])
 456 fi
 457 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 458 [AC_TRY_LINK(
 459 [#include <stdlib.h>
 460 extern char etext;
 461 ],
 462 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 463 if test $ac_cv_var_etext = yes; then
 464   AC_DEFINE(HAVE_ETEXT, 1,
 465             [Define to 1 if your system has the etext variable. ])
 466 fi
 467 if test "$enable_profiling" = yes ; then
 468   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 469     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 470   fi
 471   PROFILE_CFLAGS=-pg
 472   OLD_CFLAGS="$CFLAGS"
 473   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 474
 475   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 476     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 477      ac_cv_cc_supports_pg=no)])
 478
 479   if test $ac_cv_cc_supports_pg = no; then
 480     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 481   fi
 482
 483   CFLAGS="$OLD_CFLAGS"
 484 fi
 485
 486 ACX_PKGVERSION([GDB])
 487 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 488 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 489 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 490
 491 # --------------------- #
 492 # Checks for programs.  #
 493 # --------------------- #
 494
 495 AC_PROG_AWK
 496 AC_PROG_INSTALL
 497 AC_PROG_LN_S
 498 AC_PROG_RANLIB
 499 AC_PROG_YACC
 500
 501 AC_CHECK_TOOL(AR, ar)
 502 AC_CHECK_TOOL(DLLTOOL, dlltool)
 503 AC_CHECK_TOOL(WINDRES, windres)
 504
 505 case $host_os in
 506   gnu*)
 507     # Needed for GNU Hurd hosts.
 508     AC_CHECK_TOOL(MIG, mig)
 509     if test x"$MIG" = x; then
 510       AC_MSG_ERROR([MIG not found but required for $host hosts])
 511     fi
 512     ;;
 513 esac
 514
 515 # ---------------------- #
 516 # Checks for libraries.  #
 517 # ---------------------- #
 518
 519 # We might need to link with -lm; most simulators need it.
 520 AC_CHECK_LIB(m, main)
 521
 522 # We need to link with -lw to get `wctype' on Solaris before Solaris
 523 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 524 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 525 # is known to have this problem).  Therefore we avoid libw if we can.
 526 AC_CHECK_FUNC(wctype, [],
 527   [AC_CHECK_LIB(w, wctype)])
 528
 529 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 530 AC_SEARCH_LIBS(gethostbyname, nsl)
 531
 532 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 533 AC_SEARCH_LIBS(socketpair, socket)
 534
 535 # Link in zlib if we can.  This allows us to read compressed debug sections.
 536 AM_ZLIB
 537
 538 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 539 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 540 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 541   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 542             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 543
 544 AM_ICONV
 545
 546 # GDB may fork/exec the iconv program to get the list of supported character
 547 # sets.  Allow the user to specify where to find it.
 548 # There are several factors affecting the choice of option name:
 549 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 550 #   the build-time location of libiconv files.
 551 # - The program we need to find is iconv, which comes with glibc.  The user
 552 #   doesn't necessarily have libiconv installed.  Therefore naming this
 553 #   --with-libiconv-foo feels wrong.
 554 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 555 #   defined to work on directories not files (though it really doesn't know
 556 #   the difference).
 557 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 558 #   with --with-libiconv-prefix.
 559 # Putting these together is why the option name is --with-iconv-bin.
 560
 561 AC_ARG_WITH(iconv-bin,
 562 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 563 [iconv_bin="${withval}"
 564  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 565                     [Path of directory of iconv program.])
 566  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 567 ])
 568
 569 # For the TUI, we need enhanced curses functionality.
 570 if test x"$enable_tui" != xno; then
 571   prefer_curses=yes
 572 fi
 573
 574 curses_found=no
 575 if test x"$prefer_curses" = xyes; then
 576   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 577   # curses library because the latter might not provide all the
 578   # functionality we need.  However, this leads to problems on systems
 579   # where the linker searches /usr/local/lib, but the compiler doesn't
 580   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 581   # default installation of ncurses on alpha*-dec-osf* will lead to such
 582   # a situation.
 583   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 584
 585   if test "$ac_cv_search_waddstr" != no; then
 586     curses_found=yes
 587   fi
 588 fi
 589
 590 # Check whether we should enable the TUI, but only do so if we really
 591 # can.
 592 if test x"$enable_tui" != xno; then
 593   if test -d $srcdir/tui; then
 594     if test "$curses_found" != no; then
 595       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 596       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 597       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 598       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 599     else
 600       if test x"$enable_tui" = xyes; then
 601         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 602       else
 603         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 604       fi
 605     fi
 606   fi
 607 fi
 608
 609 # Since GDB uses Readline, we need termcap functionality.  In many
 610 # cases this will be provided by the curses library, but some systems
 611 # have a seperate termcap library, or no curses library at all.
 612
 613 case $host_os in
 614   cygwin*)
 615     if test -d $srcdir/libtermcap; then
 616       LIBS="../libtermcap/libtermcap.a $LIBS"
 617       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 618     fi ;;
 619   go32* | *djgpp*)
 620     ac_cv_search_tgetent="none required"
 621     ;;
 622 esac
 623
 624 # These are the libraries checked by Readline.
 625 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 626
 627 if test "$ac_cv_search_tgetent" = no; then
 628   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 629 fi
 630
 631 AC_ARG_WITH([system-readline],
 632   [AS_HELP_STRING([--with-system-readline],
 633                   [use installed readline library])])
 634
 635 if test "$with_system_readline" = yes; then
 636   READLINE=-lreadline
 637   READLINE_DEPS=
 638   READLINE_CFLAGS=
 639   READLINE_TEXI_INCFLAG=
 640 else
 641   READLINE='$(READLINE_DIR)/libreadline.a'
 642   READLINE_DEPS='$(READLINE)'
 643   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 644   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 645 fi
 646 AC_SUBST(READLINE)
 647 AC_SUBST(READLINE_DEPS)
 648 AC_SUBST(READLINE_CFLAGS)
 649 AC_SUBST(READLINE_TEXI_INCFLAG)
 650
 651 # Generate jit-reader.h
 652
 653 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 654 TARGET_PTR=
 655
 656 AC_CHECK_SIZEOF(unsigned long long)
 657 AC_CHECK_SIZEOF(unsigned long)
 658 AC_CHECK_SIZEOF(unsigned __int128)
 659
 660 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 661   TARGET_PTR="unsigned long"
 662 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 663   TARGET_PTR="unsigned long long"
 664 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 665   TARGET_PTR="unsigned __int128"
 666 else
 667   TARGET_PTR="unsigned long"
 668 fi
 669
 670 AC_SUBST(TARGET_PTR)
 671 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 672
 673 AC_SEARCH_LIBS(dlopen, dl)
 674
 675 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 676                 [directory to load the JIT readers from],
 677                 [${libdir}/gdb])
 678
 679 AC_ARG_WITH(expat,
 680   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 681   [], [with_expat=auto])
 682 AC_MSG_CHECKING([whether to use expat])
 683 AC_MSG_RESULT([$with_expat])
 684
 685 if test "${with_expat}" = no; then
 686   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 687   HAVE_LIBEXPAT=no
 688 else
 689   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 690                         [XML_Parser p = XML_ParserCreate (0);])
 691   if test "$HAVE_LIBEXPAT" != yes; then
 692     if test "$with_expat" = yes; then
 693       AC_MSG_ERROR([expat is missing or unusable])
 694     else
 695       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 696     fi
 697   else
 698     save_LIBS=$LIBS
 699     LIBS="$LIBS $LIBEXPAT"
 700     AC_CHECK_FUNCS(XML_StopParser)
 701     LIBS=$save_LIBS
 702   fi
 703 fi
 704
 705 # --------------------- #
 706 # Check for libpython.  #
 707 # --------------------- #
 708
 709 dnl Utility to simplify finding libpython.
 710 dnl $1 = pythonX.Y
 711 dnl $2 = the shell variable to assign the result to
 712 dnl      If libpython is found we store $version here.
 713 dnl $3 = additional flags to add to CPPFLAGS
 714 dnl $4 = additional flags to add to LIBS
 715
 716 AC_DEFUN([AC_TRY_LIBPYTHON],
 717 [
 718   version=$1
 719   define([have_libpython_var],$2)
 720   new_CPPFLAGS=$3
 721   new_LIBS=$4
 722   AC_MSG_CHECKING([for ${version}])
 723   save_CPPFLAGS=$CPPFLAGS
 724   save_LIBS=$LIBS
 725   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 726   LIBS="$LIBS $new_LIBS"
 727   found_usable_python=no
 728   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 729                                  [[Py_Initialize ();]]),
 730                  [have_libpython_var=${version}
 731                   found_usable_python=yes
 732                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 733                   PYTHON_LIBS=$new_LIBS])
 734   CPPFLAGS=$save_CPPFLAGS
 735   LIBS=$save_LIBS
 736   AC_MSG_RESULT([${found_usable_python}])
 737 ])
 738
 739 dnl There are several different values for --with-python:
 740 dnl
 741 dnl no -   Don't include python support.
 742 dnl yes -  Include python support, error if it's missing.
 743 dnl        If we find python in $PATH, use it to fetch configure options,
 744 dnl        otherwise assume the compiler can find it with no help from us.
 745 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 746 dnl auto - Same as "yes", but if python is missing from the system,
 747 dnl        fall back to "no".
 748 dnl /path/to/python/exec-prefix -
 749 dnl        Use the python located in this directory.
 750 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 751 dnl        the compilation parameters.  Otherwise use
 752 dnl        -I/path/to/python/exec-prefix/include,
 753 dnl        -L/path/to/python/exec-prefix/lib.
 754 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 755 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 756 dnl        but is deprecated.
 757 dnl /path/to/python/executable -
 758 dnl        Run python-config.py with this version of python to fetch the
 759 dnl        compilation parameters.
 760 dnl        NOTE: This needn't be the real python executable.
 761 dnl        In a cross-compilation scenario (build != host), this could be
 762 dnl        a shell script that provides what python-config.py provides for
 763 dnl        --ldflags, --includes, --exec-prefix.
 764 dnl python-executable -
 765 dnl        Find python-executable in $PATH, and then handle the same as
 766 dnl        /path/to/python/executable.
 767 dnl
 768 dnl If a python program is specified, it is used to run python-config.py and
 769 dnl is passed --ldflags, --includes, --exec-prefix.
 770
 771 AC_ARG_WITH(python,
 772   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 773   [], [with_python=auto])
 774 AC_MSG_CHECKING([whether to use python])
 775 AC_MSG_RESULT([$with_python])
 776
 777 if test "${with_python}" = no; then
 778   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 779   have_libpython=no
 780 else
 781   case "${with_python}" in
 782   [[\\/]]* | ?:[[\\/]]*)
 783     if test -d ${with_python}; then
 784       # Assume the python binary is ${with_python}/bin/python.
 785       python_prog="${with_python}/bin/python"
 786       python_prefix=
 787       # If python does not exit ${with_python}/bin, then try in
 788       # ${with_python}.  On Windows/MinGW, this is where the Python
 789       # executable is.
 790       if test ! -x "${python_prog}"; then
 791         python_prog="${with_python}/python"
 792         python_prefix=
 793       fi
 794       if test ! -x "${python_prog}"; then
 795         # Fall back to gdb 7.0/7.1 behaviour.
 796         python_prog=missing
 797         python_prefix=${with_python}
 798       fi
 799     elif test -x "${with_python}"; then
 800       # While we can't run python compiled for $host (unless host == build),
 801       # the user could write a script that provides the needed information,
 802       # so we support that.
 803       python_prog=${with_python}
 804       python_prefix=
 805     else
 806       AC_ERROR(invalid value for --with-python)
 807     fi
 808     ;;
 809   */*)
 810     # Disallow --with-python=foo/bar.
 811     AC_ERROR(invalid value for --with-python)
 812     ;;
 813   *)
 814     # The user has either specified auto, yes, or the name of the python
 815     # program assumed to be in $PATH.
 816     python_prefix=
 817     case "${with_python}" in
 818     yes | auto)
 819       if test ${build} = ${host}; then
 820         AC_PATH_PROG(python_prog_path, python, missing)
 821         if test "${python_prog_path}" = missing; then
 822           python_prog=missing
 823         else
 824           python_prog=${python_prog_path}
 825         fi
 826       else
 827         # Not much we can do except assume the cross-compiler will find the
 828         # right files.
 829         python_prog=missing
 830       fi
 831       ;;
 832     *)
 833       # While we can't run python compiled for $host (unless host == build),
 834       # the user could write a script that provides the needed information,
 835       # so we support that.
 836       python_prog="${with_python}"
 837       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 838       if test "${python_prog_path}" = missing; then
 839         AC_ERROR(unable to find python program ${python_prog})
 840       fi
 841       ;;
 842     esac
 843   esac
 844
 845   if test "${python_prog}" != missing; then
 846     # We have a python program to use, but it may be too old.
 847     # Don't flag an error for --with-python=auto (the default).
 848     have_python_config=yes
 849     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 850     if test $? != 0; then
 851       have_python_config=failed
 852       if test "${with_python}" != auto; then
 853         AC_ERROR(failure running python-config --includes)
 854       fi
 855     fi
 856     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 857     if test $? != 0; then
 858       have_python_config=failed
 859       if test "${with_python}" != auto; then
 860         AC_ERROR(failure running python-config --ldflags)
 861       fi
 862     fi
 863     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 864     if test $? != 0; then
 865       have_python_config=failed
 866       if test "${with_python}" != auto; then
 867         AC_ERROR(failure running python-config --exec-prefix)
 868       fi
 869     fi
 870   else
 871     # We do not have a python executable we can use to determine where
 872     # to find the Python headers and libs.  We cannot guess the include
 873     # path from the python_prefix either, because that include path
 874     # depends on the Python version.  So, there is nothing much we can
 875     # do except assume that the compiler will be able to find those files.
 876     python_includes=
 877     python_libs=
 878     have_python_config=no
 879   fi
 880
 881   # If we have python-config, only try the configuration it provides.
 882   # Otherwise fallback on the old way of trying different versions of
 883   # python in turn.
 884
 885   have_libpython=no
 886   if test "${have_python_config}" = yes; then
 887     # Determine the Python version by extracting "-lpython<version>"
 888     # part of the python_libs. <version> is usually X.Y with X and Y
 889     # being decimal numbers, but can also be XY (seen on Windows).
 890     #
 891     # The extraction is performed using sed with a regular expression.
 892     # Initially, the regexp used was using the '?' quantifier to make
 893     # the dot in the version number optional.  Unfortunately, this
 894     # does not work with non-GNU versions of sed because, because of
 895     # what looks like a limitation (the '?' quantifier does not work
 896     # with back-references).  We work around this limitation by using
 897     # the '*' quantifier instead.  It means that, in theory, we might
 898     # match unexpected version strings such as "-lpython2..7", but
 899     # this seems unlikely in practice.  And even if that happens,
 900     # an error will be triggered later on, when checking that version
 901     # number.
 902     python_version=`echo " ${python_libs} " \
 903                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 904     case "${python_version}" in
 905     python*)
 906       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 907                        ${python_includes}, ${python_libs})
 908       ;;
 909     *)
 910       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 911       ;;
 912     esac
 913   elif test "${have_python_config}" != failed; then
 914     if test "${have_libpython}" = no; then
 915       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 916                        ${python_includes}, "${python_libs} -lpython2.7")
 917     fi
 918     if test "${have_libpython}" = no; then
 919       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 920                        ${python_includes}, "${python_libs} -lpython2.6")
 921     fi
 922     if test ${have_libpython} = no; then
 923       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 924                        ${python_includes}, "${python_libs} -lpython2.5")
 925     fi
 926     if test ${have_libpython} = no; then
 927       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 928                        ${python_includes}, "${python_libs} -lpython2.4")
 929     fi
 930   fi
 931   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 933   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 935   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 936     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 937   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 938     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 939   fi
 940
 941   if test "${have_libpython}" = no; then
 942     case "${with_python}" in
 943     yes)
 944       AC_MSG_ERROR([python is missing or unusable])
 945       ;;
 946     auto)
 947       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 948       ;;
 949     *)
 950       AC_MSG_ERROR([no usable python found at ${with_python}])
 951       ;;
 952     esac
 953   else
 954     if test -n "${python_prefix}"; then
 955       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 956                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 957       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 958     fi
 959   fi
 960 fi
 961
 962 if test "${have_libpython}" != no; then
 963   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 964   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 965   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 966   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 967   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 968   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 969
 970   # Flags needed to compile Python code (taken from python-config --cflags).
 971   # We cannot call python-config directly because it will output whatever was
 972   # used when compiling the Python interpreter itself, including flags which
 973   # would make the python-related objects be compiled differently from the
 974   # rest of GDB (e.g., -O2 and -fPIC).
 975   if test "${GCC}" = yes; then
 976     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 977   fi
 978
 979   if test "x${tentative_python_cflags}" != x; then
 980     AC_MSG_CHECKING(compiler flags for python code)
 981     for flag in ${tentative_python_cflags}; do
 982       # Check that the compiler accepts it
 983       saved_CFLAGS="$CFLAGS"
 984       CFLAGS="$CFLAGS $flag"
 985       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 986       CFLAGS="$saved_CFLAGS"
 987     done
 988     AC_MSG_RESULT(${PYTHON_CFLAGS})
 989   fi
 990
 991   # On x64 Windows, Python's include headers, and pyconfig.h in
 992   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 993   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 994   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 995   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 996   # The issue was reported to the Python community, but still isn't
 997   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 998
 999   case "$gdb_host" in
1000     mingw64)
1001            if test "${GCC}" = yes; then
1002              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1003            fi
1004            ;;
1005   esac
1006
1007   # Note that "python -m threading" cannot be used to check for
1008   # threading support due to a bug in Python 2.7.3
1009   # (http://bugs.python.org/issue15567).
1010   AC_MSG_CHECKING(whether python supports threads)
1011   saved_CPPFLAGS="${CPPFLAGS}"
1012   CPPFLAGS="${PYTHON_CPPFLAGS}"
1013   # Note that the test is reversed so that python_has_threads=yes on
1014   # unexpected failures.
1015   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1016 #include <Python.h>
1017 #ifdef WITH_THREAD
1018 # error
1019 #endif
1020   ]]), [python_has_threads=no], [python_has_threads=yes])
1021   AC_MSG_RESULT(${python_has_threads})
1022   CPPFLAGS="${saved_CPPFLAGS}"
1023 else
1024   # Even if Python support is not compiled in, we need to have this file
1025   # included so that the "python" command, et.al., still exists.
1026   CONFIG_OBS="$CONFIG_OBS python.o"
1027   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1028 fi
1029
1030 # Work around Python http://bugs.python.org/issue10112.  See also
1031 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1032 # no effect.  Note that the only test after this that uses Python is
1033 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1034 # run without -export-dynamic too.
1035 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1036
1037 AC_SUBST(PYTHON_CFLAGS)
1038 AC_SUBST(PYTHON_CPPFLAGS)
1039 AC_SUBST(PYTHON_LIBS)
1040 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1041
1042 # -------------------- #
1043 # Check for libguile.  #
1044 # -------------------- #
1045
1046 dnl Utility to simplify finding libguile.
1047 dnl $1 = pkg-config-program
1048 dnl $2 = space-separate list of guile versions to try
1049 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1050 dnl $4 = the shell variable to assign the result to
1051 dnl      If libguile is found we store "yes" here.
1052
1053 AC_DEFUN([AC_TRY_LIBGUILE],
1054 [
1055   pkg_config=$1
1056   guile_version_list=$2
1057   flag_errors=$3
1058   define([have_libguile_var],$4)
1059   found_usable_guile=checking
1060   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1061   for guile_version in ${guile_version_list}; do
1062     ${pkg_config} --exists ${guile_version} 2>/dev/null
1063     if test $? != 0; then
1064       continue
1065     fi
1066     dnl pkg-config says the package exists, so if we get an error now,
1067     dnl that's bad.
1068     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1069     if test $? != 0; then
1070       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1071     fi
1072     new_LIBS=`${pkg_config} --libs ${guile_version}`
1073     if test $? != 0; then
1074       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1075     fi
1076     dnl If we get this far, great.
1077     found_usable_guile=${guile_version}
1078     break
1079   done
1080   if test "${found_usable_guile}" = "checking"; then
1081     if test "${flag_errors}" = "yes"; then
1082       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1083     else
1084       found_usable_guile=no
1085     fi
1086   fi
1087   dnl One final sanity check.
1088   dnl The user could have said --with-guile=python-2.7.
1089   if test "${found_usable_guile}" != no; then
1090     save_CPPFLAGS=$CPPFLAGS
1091     save_LIBS=$LIBS
1092     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1093     LIBS="$LIBS $new_LIBS"
1094     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1095                                    [[scm_init_guile ();]]),
1096                    [have_libguile_var=yes
1097                     GUILE_CPPFLAGS=$new_CPPFLAGS
1098                     GUILE_LIBS=$new_LIBS],
1099                    [found_usable_guile=no])
1100     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1101     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1102       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1103                 [Define if Guile supports manual finalization.])
1104     )
1105     CPPFLAGS=$save_CPPFLAGS
1106     LIBS=$save_LIBS
1107     if test "${found_usable_guile}" = no; then
1108       if test "${flag_errors}" = yes; then
1109         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1110       fi
1111     fi
1112   fi
1113   AC_MSG_RESULT([${found_usable_guile}])
1114 ])
1115
1116 dnl There are several different values for --with-guile:
1117 dnl
1118 dnl no -   Don't include guile support.
1119 dnl yes -  Include guile support, error if it's missing.
1120 dnl        The pkg-config program must be in $PATH.
1121 dnl auto - Same as "yes", but if guile is missing from the system,
1122 dnl        fall back to "no".
1123 dnl guile-version [guile-version-choice-2 ...] -
1124 dnl        A space-separated list of guile package versions to try.
1125 dnl        These are passed to pkg-config as-is.
1126 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1127 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1128 dnl /path/to/pkg-config -
1129 dnl        Use this pkg-config program.
1130 dnl        NOTE: This needn't be the "real" pkg-config program.
1131 dnl        It could be a shell script.  It is invoked as:
1132 dnl        pkg-config --exists $version
1133 dnl        pkg-config --cflags $version
1134 dnl        pkg-config --libs $version
1135 dnl        pkg-config --variable guild $version
1136 dnl        The script will be called with $version having each value in
1137 dnl        $try_guile_versions until --exists indicates success.
1138
1139 AC_ARG_WITH(guile,
1140   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1141   [], [with_guile=auto])
1142 AC_MSG_CHECKING([whether to use guile])
1143 AC_MSG_RESULT([$with_guile])
1144
1145 dnl We check guile with pkg-config.
1146 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1147
1148 try_guile_versions="guile-2.2 guile-2.0"
1149 have_libguile=no
1150 case "${with_guile}" in
1151 no)
1152   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1153   ;;
1154 auto)
1155   if test "${pkg_config_prog_path}" = "missing"; then
1156     AC_MSG_WARN([pkg-config not found, guile support disabled])
1157   else
1158     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1159   fi
1160   ;;
1161 yes)
1162   if test "${pkg_config_prog_path}" = "missing"; then
1163     AC_MSG_ERROR([pkg-config not found])
1164   fi
1165   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1166   ;;
1167 [[\\/]]* | ?:[[\\/]]*)
1168   if test -x "${with_guile}"; then
1169     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1170   else
1171     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1172   fi
1173   ;;
1174 "" | */*)
1175   # Disallow --with=guile="" and --with-guile=foo/bar.
1176   AC_MSG_ERROR([invalid value for --with-guile])
1177   ;;
1178 *)
1179   # A space separate list of guile versions to try, in order.
1180   if test "${pkg_config_prog_path}" = "missing"; then
1181     AC_MSG_ERROR([pkg-config not found])
1182   fi
1183   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1184   ;;
1185 esac
1186
1187 if test "${have_libguile}" != no; then
1188   dnl Get the name of the 'guild' program.
1189   case "${with_guile}" in
1190   [[\\/]]* | ?:[[\\/]]*)
1191     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1192     ;;
1193   *)
1194     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1195     ;;
1196   esac
1197
1198   dnl Make sure guild can handle this host.
1199   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1200   dnl If not, disable guile support.
1201   if test "$ac_cv_guild_ok" = no; then
1202     have_libguile=no
1203     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1204   fi
1205 fi
1206
1207 if test "${have_libguile}" != no; then
1208   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1209   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1210   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1211   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1212   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1213   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1214
1215   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1216   save_LIBS="$LIBS"
1217   save_CPPFLAGS="$CPPFLAGS"
1218   LIBS="$GUILE_LIBS"
1219   CPPFLAGS="$GUILE_CPPFLAGS"
1220   AC_CHECK_FUNCS([scm_new_smob])
1221   LIBS="$save_LIBS"
1222   CPPFLAGS="$save_CPPFLAGS"
1223 else
1224   # Even if Guile support is not compiled in, we need to have these files
1225   # included.
1226   CONFIG_OBS="$CONFIG_OBS guile.o"
1227   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1228 fi
1229 AC_SUBST(GUILE_CPPFLAGS)
1230 AC_SUBST(GUILE_LIBS)
1231 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1232
1233 # --------------------- #
1234 # Check for libmcheck.  #
1235 # --------------------- #
1236
1237 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1238 # but turn it off if Python is enabled with threads, since -lmcheck is
1239 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1240 # and for releases.
1241 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1242    && $development; then
1243   libmcheck_default=yes
1244 else
1245   libmcheck_default=no
1246 fi
1247 GDB_AC_LIBMCHECK(${libmcheck_default})
1248
1249 if test "$ENABLE_LIBMCHECK" = "yes" \
1250         -a "${have_libpython}" != "no" \
1251         -a "${python_has_threads}" = "yes" ; then
1252   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1253 fi
1254
1255 AC_ARG_WITH(intel_pt,
1256   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1257   [], [with_intel_pt=auto])
1258 AC_MSG_CHECKING([whether to use intel pt])
1259 AC_MSG_RESULT([$with_intel_pt])
1260
1261 if test "${with_intel_pt}" = no; then
1262   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1263   HAVE_LIBIPT=no
1264 else
1265   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1266 #include <linux/perf_event.h>
1267 #ifndef PERF_ATTR_SIZE_VER5
1268 # error
1269 #endif
1270   ]]), [perf_event=yes], [perf_event=no])
1271   if test "$perf_event" != yes; then
1272     if test "$with_intel_pt" = yes; then
1273       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1274     else
1275       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1276     fi
1277   fi
1278
1279   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1280   if test "$HAVE_LIBIPT" != yes; then
1281     if test "$with_intel_pt" = yes; then
1282       AC_MSG_ERROR([libipt is missing or unusable])
1283     else
1284       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1285     fi
1286   fi
1287 fi
1288
1289 # ------------------------- #
1290 # Checks for header files.  #
1291 # ------------------------- #
1292
1293 AC_HEADER_STDC
1294 # elf_hp.h is for HP/UX 64-bit shared library support.
1295 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1296                   thread_db.h \
1297                   sys/fault.h \
1298                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1299                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1300                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1301                   termios.h termio.h \
1302                   sgtty.h elf_hp.h \
1303                   dlfcn.h])
1304 AC_CHECK_HEADERS(sys/proc.h, [], [],
1305 [#if HAVE_SYS_PARAM_H
1306 # include <sys/param.h>
1307 #endif
1308 ])
1309 AC_CHECK_HEADERS(sys/user.h, [], [],
1310 [#if HAVE_SYS_PARAM_H
1311 # include <sys/param.h>
1312 #endif
1313 ])
1314
1315 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1316 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1317 # think that we don't have <curses.h> if we're using GCC.
1318 case $host_os in
1319   solaris2.[[789]])
1320     if test "$GCC" = yes; then
1321       AC_DEFINE(_MSE_INT_H, 1,
1322         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1323    Solaris 2.[789] when using GCC. ])
1324     fi ;;
1325 esac
1326 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1327 AC_CHECK_HEADERS(term.h, [], [],
1328 [#if HAVE_CURSES_H
1329 # include <curses.h>
1330 #endif
1331 ])
1332
1333 # ------------------------- #
1334 # Checks for declarations.  #
1335 # ------------------------- #
1336
1337 libiberty_INIT
1338
1339 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1340 AM_LC_MESSAGES
1341
1342 # ----------------------- #
1343 # Checks for structures.  #
1344 # ----------------------- #
1345
1346 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1347
1348 # ------------------ #
1349 # Checks for types.  #
1350 # ------------------ #
1351
1352 AC_CHECK_TYPES(socklen_t, [], [],
1353 [#include <sys/types.h>
1354 #include <sys/socket.h>
1355 ])
1356
1357 # ------------------------------------- #
1358 # Checks for compiler characteristics.  #
1359 # ------------------------------------- #
1360
1361 AC_C_CONST
1362 AC_C_INLINE
1363 AC_C_BIGENDIAN
1364
1365 # ------------------------------ #
1366 # Checks for library functions.  #
1367 # ------------------------------ #
1368
1369 AC_FUNC_MMAP
1370 AC_FUNC_VFORK
1371 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1372                 pipe poll pread pread64 pwrite resize_term \
1373                 sbrk setpgid setpgrp setsid \
1374                 sigaction sigprocmask sigsetmask socketpair \
1375                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1376                 setrlimit getrlimit posix_madvise waitpid \
1377                 ptrace64 sigaltstack mkdtemp setns])
1378 AM_LANGINFO_CODESET
1379 GDB_AC_COMMON
1380
1381 # Check the return and argument types of ptrace.
1382 GDB_AC_PTRACE
1383
1384 dnl AC_FUNC_SETPGRP does not work when cross compiling
1385 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1386 if test "$cross_compiling" = no; then
1387   AC_FUNC_SETPGRP
1388 else
1389   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1390     [AC_TRY_COMPILE([
1391 #include <unistd.h>
1392 ], [
1393   if (setpgrp(1,1) == -1)
1394     exit (0);
1395   else
1396     exit (1);
1397 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1398 if test $ac_cv_func_setpgrp_void = yes; then
1399   AC_DEFINE(SETPGRP_VOID, 1)
1400 fi
1401 fi
1402
1403 # Assume we'll default to using the included libiberty regex.
1404 gdb_use_included_regex=yes
1405
1406 # However, if the system regex is GNU regex, then default to *not*
1407 # using the included regex.
1408 AC_CACHE_CHECK(
1409   [for GNU regex],
1410   [gdb_cv_have_gnu_regex],
1411   [AC_TRY_COMPILE(
1412     [#include <gnu-versions.h>],
1413     [#define REGEX_INTERFACE_VERSION 1
1414 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1415 # error "Version mismatch"
1416 #endif],
1417     gdb_cv_have_gnu_regex=yes,
1418     gdb_cv_have_gnu_regex=no)])
1419 if test $gdb_cv_have_gnu_regex = yes; then
1420   gdb_use_included_regex=no
1421 fi
1422
1423 AC_ARG_WITH(included-regex,
1424   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1425   gdb_with_regex=$withval,
1426   gdb_with_regex=$gdb_use_included_regex)
1427 if test "$gdb_with_regex" = yes; then
1428   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1429     [Define to 1 if the regex included in libiberty should be used.])
1430 fi
1431
1432 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1433 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1434 [#include <sys/param.h>
1435 #include <sys/proc.h>
1436 ])
1437
1438 # See if <sys/lwp.h> defines `struct lwp`.
1439 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1440 [AC_TRY_COMPILE([#include <sys/param.h>
1441 #include <sys/lwp.h>], [struct lwp l;],
1442 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1443 if test $gdb_cv_struct_lwp = yes; then
1444   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1445             [Define to 1 if your system has struct lwp.])
1446 fi
1447
1448 # See if <machine/reg.h> degines `struct reg'.
1449 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1450 [AC_TRY_COMPILE([#include <sys/types.h>
1451 #include <machine/reg.h>], [struct reg r;],
1452 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1453 if test $gdb_cv_struct_reg = yes; then
1454   AC_DEFINE(HAVE_STRUCT_REG, 1,
1455             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1456 fi
1457
1458 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1459 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1460 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1461                  [#include <sys/types.h>
1462 #include <machine/reg.h>])
1463
1464 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1465 # Older amd64 Linux's don't have the fs_base and gs_base members of
1466 # `struct user_regs_struct'.
1467 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1468                  [], [], [#include <sys/user.h>])
1469
1470 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1471 AC_MSG_CHECKING(for PTRACE_GETREGS)
1472 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1473 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1474                 [PTRACE_GETREGS;],
1475                 [gdb_cv_have_ptrace_getregs=yes],
1476                 [gdb_cv_have_ptrace_getregs=no])])
1477 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1478 if test $gdb_cv_have_ptrace_getregs = yes; then
1479   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1480   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1481 fi
1482
1483 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1484 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1485 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1486 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1487                 [PTRACE_GETFPXREGS;],
1488                 [gdb_cv_have_ptrace_getfpxregs=yes],
1489                 [gdb_cv_have_ptrace_getfpxregs=no])])
1490 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1491 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1492   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1493   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1494 fi
1495
1496 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1497 AC_MSG_CHECKING(for PT_GETDBREGS)
1498 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1499 [AC_TRY_COMPILE([#include <sys/types.h>
1500 #include <sys/ptrace.h>],
1501                 [PT_GETDBREGS;],
1502                 [gdb_cv_have_pt_getdbregs=yes],
1503                 [gdb_cv_have_pt_getdbregs=no])])
1504 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1505 if test $gdb_cv_have_pt_getdbregs = yes; then
1506   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1507   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1508 fi
1509
1510 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1511 AC_MSG_CHECKING(for PT_GETXMMREGS)
1512 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1513 [AC_TRY_COMPILE([#include <sys/types.h>
1514 #include <sys/ptrace.h>],
1515                 [PT_GETXMMREGS;],
1516                 [gdb_cv_have_pt_getxmmregs=yes],
1517                 [gdb_cv_have_pt_getxmmregs=no])])
1518 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1519 if test $gdb_cv_have_pt_getxmmregs = yes; then
1520   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1521   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1522 fi
1523
1524 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1525 # Older FreeBSD versions don't have the pl_tdname member of
1526 # `struct ptrace_lwpinfo'.
1527 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1528                  [#include <sys/ptrace.h>])
1529
1530 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1531 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1532 # FreeBSD 10.3.
1533 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1534                  [#include <sys/ptrace.h>])
1535
1536 # Detect which type of /proc is in use, such as for Solaris.
1537
1538 if test "${target}" = "${host}"; then
1539   case "${host}" in
1540   *-*-sysv4.2* | *-*-sysv5* )
1541       AC_DEFINE(NEW_PROC_API, 1,
1542       [Define if you want to use new multi-fd /proc interface.])
1543       ;;
1544   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1545       AC_DEFINE(NEW_PROC_API, 1,
1546       [Define if you want to use new multi-fd /proc interface.])
1547       ;;
1548   esac
1549 fi
1550
1551 if test "$ac_cv_header_sys_procfs_h" = yes; then
1552   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1553   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1554   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1555   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1556   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1557   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1558   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1559   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1560   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1561   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1562   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1563
1564
1565   dnl Check for broken prfpregset_t type
1566
1567   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1568   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1569   dnl instead of the struct itself).  We detect this here, and work
1570   dnl around it in gdb_proc_service.h.
1571
1572   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1573     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1574     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1575       [AC_TRY_RUN([#include <sys/procfs.h>
1576        int main ()
1577        {
1578          if (sizeof (prfpregset_t) == sizeof (void *))
1579            return 1;
1580          return 0;
1581        }],
1582        gdb_cv_prfpregset_t_broken=no,
1583        gdb_cv_prfpregset_t_broken=yes,
1584        gdb_cv_prfpregset_t_broken=yes)])
1585     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1586     if test $gdb_cv_prfpregset_t_broken = yes; then
1587       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1588       [Define if the prfpregset_t type is broken.])
1589     fi
1590   fi
1591 fi
1592
1593 # Check if the compiler supports the `long long' type.
1594
1595 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1596                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1597 [[extern long long foo;]],
1598 [[switch (foo & 2) { case 0: return 1; }]])],
1599                                   gdb_cv_c_long_long=yes,
1600                                   gdb_cv_c_long_long=no)])
1601 if test $gdb_cv_c_long_long != yes; then
1602   # libdecnumber requires long long.
1603   AC_MSG_ERROR([Compiler must support long long for GDB.])
1604 fi
1605
1606 # Check if the compiler and runtime support printing long longs.
1607
1608 AC_CACHE_CHECK([for long long support in printf],
1609                gdb_cv_printf_has_long_long,
1610                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1611 [[char buf[32];
1612   long long l = 0;
1613   l = (l << 16) + 0x0123;
1614   l = (l << 16) + 0x4567;
1615   l = (l << 16) + 0x89ab;
1616   l = (l << 16) + 0xcdef;
1617   sprintf (buf, "0x%016llx", l);
1618   return (strcmp ("0x0123456789abcdef", buf));]])],
1619                               gdb_cv_printf_has_long_long=yes,
1620                               gdb_cv_printf_has_long_long=no,
1621                               gdb_cv_printf_has_long_long=no)])
1622 if test $gdb_cv_printf_has_long_long = yes; then
1623   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1624             [Define to 1 if the "%ll" format works to print long longs.])
1625 fi
1626
1627 # Check if the compiler and runtime support printing decfloats.
1628
1629 AC_CACHE_CHECK([for decfloat support in printf],
1630                gdb_cv_printf_has_decfloat,
1631                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1632 [[char buf[64];
1633   _Decimal32 d32 = 1.2345df;
1634   _Decimal64 d64 = 1.2345dd;
1635   _Decimal128 d128 = 1.2345dl;
1636   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1637   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1638                               gdb_cv_printf_has_decfloat=yes,
1639                               gdb_cv_printf_has_decfloat=no,
1640                               gdb_cv_printf_has_decfloat=no)])
1641 if test $gdb_cv_printf_has_decfloat = yes; then
1642   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1643             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1644 fi
1645
1646 # Check if the compiler supports the `long double' type.  We can't use
1647 # AC_C_LONG_DOUBLE because that one does additional checks on the
1648 # constants defined in <float.h> that fail on some systems,
1649 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1650
1651 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1652                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1653                                   gdb_cv_c_long_double=yes,
1654                                   gdb_cv_c_long_double=no)])
1655 if test $gdb_cv_c_long_double = yes; then
1656   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1657            [Define to 1 if the compiler supports long double.])
1658 fi
1659
1660 # Check if the compiler and runtime support printing long doubles.
1661
1662 AC_CACHE_CHECK([for long double support in printf],
1663                gdb_cv_printf_has_long_double,
1664                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1665 [[char buf[16];
1666   long double f = 3.141592653;
1667   sprintf (buf, "%Lg", f);
1668   return (strncmp ("3.14159", buf, 7));]])],
1669                               gdb_cv_printf_has_long_double=yes,
1670                               gdb_cv_printf_has_long_double=no,
1671                               gdb_cv_printf_has_long_double=no)])
1672 if test $gdb_cv_printf_has_long_double = yes; then
1673   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1674             [Define to 1 if the "%Lg" format works to print long doubles.])
1675 fi
1676
1677 # Check if the compiler and runtime support scanning long doubles.
1678
1679 AC_CACHE_CHECK([for long double support in scanf],
1680                gdb_cv_scanf_has_long_double,
1681                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1682 [[#include <stdio.h>]],
1683 [[char *buf = "3.141592653";
1684   long double f = 0;
1685   sscanf (buf, "%Lg", &f);
1686   return !(f > 3.14159 && f < 3.14160);]])],
1687                               gdb_cv_scanf_has_long_double=yes,
1688                               gdb_cv_scanf_has_long_double=no,
1689                               gdb_cv_scanf_has_long_double=no)])
1690 if test $gdb_cv_scanf_has_long_double = yes; then
1691   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1692             [Define to 1 if the "%Lg" format works to scan long doubles.])
1693 fi
1694
1695 case ${host_os} in
1696 aix*)
1697   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1698     SAVE_LDFLAGS=$LDFLAGS
1699
1700     case $GCC in
1701     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1702     *) gdb_cv_bigtoc=-bbigtoc ;;
1703     esac
1704
1705     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1706     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1707     LDFLAGS="${SAVE_LDFLAGS}"
1708   ])
1709   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1710   ;;
1711 esac
1712
1713 AC_MSG_CHECKING(for the dynamic export flag)
1714 dynamic_list=false
1715 if test "${gdb_native}" = yes; then
1716    # The dynamically loaded libthread_db needs access to symbols in the gdb
1717    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1718    # may not be supported there.
1719    old_LDFLAGS="$LDFLAGS"
1720    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1721    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1722    LDFLAGS="$LDFLAGS $RDYNAMIC"
1723    if test "${have_libpython}" = no; then
1724      AC_TRY_LINK([], [], [dynamic_list=true])
1725    else
1726      # Workaround http://bugs.python.org/issue4434 where static
1727      # libpythonX.Y.a would get its symbols required for
1728      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1729      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1730
1731      # Note the workaround for Python
1732      # http://bugs.python.org/issue10112 earlier has removed
1733      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1734      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1735      # always pass.
1736      old_CFLAGS="$CFLAGS"
1737      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1738      old_LIBS="$LIBS"
1739      LIBS="$LIBS $PYTHON_LIBS"
1740      old_CPPFLAGS="$CPPFLAGS"
1741      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1742      AC_RUN_IFELSE(
1743        AC_LANG_PROGRAM(
1744          [#include "Python.h"],
1745          [int err;
1746           Py_Initialize ();
1747           err = PyRun_SimpleString ("import itertools\n");
1748           Py_Finalize ();
1749           return err == 0 ? 0 : 1;]),
1750        [dynamic_list=true], [], [true])
1751      LIBS="$old_LIBS"
1752      CFLAGS="$old_CFLAGS"
1753      CPPFLAGS="$old_CPPFLAGS"
1754    fi
1755    LDFLAGS="$old_LDFLAGS"
1756 fi
1757 if $dynamic_list; then
1758   found="-Wl,--dynamic-list"
1759   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1760 else
1761   found="-rdynamic"
1762   RDYNAMIC="-rdynamic"
1763 fi
1764 AC_SUBST(RDYNAMIC)
1765 AC_MSG_RESULT($found)
1766
1767 dnl For certain native configurations, we need to check whether thread
1768 dnl support can be built in or not.
1769 dnl
1770 dnl Note that we only want this if we are both native (host == target),
1771 dnl and not doing a canadian cross build (build == host).
1772
1773 if test ${build} = ${host} -a ${host} = ${target} ; then
1774    case ${host_os} in
1775    solaris*)
1776       # See if thread_db library is around for Solaris thread debugging.
1777       # Note that we must explicitly test for version 1 of the library
1778       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1779       # the same API.
1780       AC_MSG_CHECKING(for Solaris thread debugging library)
1781       if test -f /usr/lib/libthread_db.so.1 ; then
1782          AC_MSG_RESULT(yes)
1783          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1784          [Define if using Solaris thread debugging.])
1785          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1786          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1787          AC_CHECK_LIB(dl, dlopen)
1788          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1789          # Sun randomly tweaked the prototypes in <proc_service.h>
1790          # at one point.
1791          AC_MSG_CHECKING(if <proc_service.h> is old)
1792          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1793             AC_TRY_COMPILE([
1794                 #include <proc_service.h>
1795                 ps_err_e ps_pdwrite
1796                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1797             ],, gdb_cv_proc_service_is_old=no,
1798                 gdb_cv_proc_service_is_old=yes)
1799          ])
1800          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1801          if test $gdb_cv_proc_service_is_old = yes; then
1802             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1803             [Define if <proc_service.h> on solaris uses int instead of
1804              size_t, and assorted other type changes.])
1805          fi
1806       else
1807          AC_MSG_RESULT(no)
1808       fi
1809       ;;
1810    aix*)
1811       AC_MSG_CHECKING(for AiX thread debugging library)
1812       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1813                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1814                                    [#ifndef PTHDB_VERSION_3
1815                                     #error
1816                                     #endif],
1817                                    gdb_cv_have_aix_thread_debug=yes,
1818                                    gdb_cv_have_aix_thread_debug=no)])
1819       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1820       if test $gdb_cv_have_aix_thread_debug = yes; then
1821          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1822          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1823          LIBS="$LIBS -lpthdebug"
1824
1825          # Older versions of AIX do not provide the declaration for
1826          # the getthrds function (it appears that it was introduced
1827          # with AIX 6.x).
1828          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1829       fi
1830       ;;
1831    esac
1832    AC_SUBST(CONFIG_LDFLAGS)
1833 fi
1834
1835 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1836 dnl other error codes.
1837 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1838    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1839                   gdb_cv_thread_db_h_has_td_notalloc,
1840      AC_TRY_COMPILE(
1841        [#include <thread_db.h>],
1842        [int i = TD_NOTALLOC;],
1843        gdb_cv_thread_db_h_has_td_notalloc=yes,
1844        gdb_cv_thread_db_h_has_td_notalloc=no
1845      )
1846    )
1847    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1848                   gdb_cv_thread_db_h_has_td_version,
1849      AC_TRY_COMPILE(
1850        [#include <thread_db.h>],
1851        [int i = TD_VERSION;],
1852        gdb_cv_thread_db_h_has_td_version=yes,
1853        gdb_cv_thread_db_h_has_td_version=no
1854      )
1855    )
1856    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1857                   gdb_cv_thread_db_h_has_td_notls,
1858      AC_TRY_COMPILE(
1859        [#include <thread_db.h>],
1860        [int i = TD_NOTLS;],
1861        gdb_cv_thread_db_h_has_td_notls=yes,
1862        gdb_cv_thread_db_h_has_td_notls=no
1863      )
1864    )
1865 fi
1866 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1867   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1868             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1869 fi
1870 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1871   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1872             [Define if <thread_db.h> has the TD_VERSION error code.])
1873 fi
1874 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1875   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1876             [Define if <thread_db.h> has the TD_NOTLS error code.])
1877 fi
1878
1879 dnl Check if we can disable the virtual address space randomization.
1880 dnl The functionality of setarch -R.
1881 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1882 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1883 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1884 #       define ADDR_NO_RANDOMIZE 0x0040000
1885 #      endif
1886        /* Test the flag could be set and stays set.  */
1887        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1888        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1889            return 1])])
1890 AC_RUN_IFELSE([PERSONALITY_TEST],
1891               [have_personality=true],
1892               [have_personality=false],
1893               [AC_LINK_IFELSE([PERSONALITY_TEST],
1894                               [have_personality=true],
1895                               [have_personality=false])])
1896 if $have_personality
1897 then
1898     AC_DEFINE([HAVE_PERSONALITY], 1,
1899               [Define if you support the personality syscall.])
1900 fi
1901
1902 dnl Set the host's .gdbinit filename.
1903 case $host_os in
1904   go32* | *djgpp*)
1905     gdbinit=gdb.ini
1906     ;;
1907   *)
1908     gdbinit=.gdbinit
1909     ;;
1910 esac
1911 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1912
1913 dnl Handle optional features that can be enabled.
1914
1915 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1916 # except that the argument to --with-sysroot is optional.
1917 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1918 if test "x$with_sysroot" = xyes; then
1919   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1920 fi
1921 AC_ARG_WITH(sysroot,
1922   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1923                  [search for usr/lib et al within DIR]),
1924   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1925 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1926               [search for usr/lib et al within DIR])
1927 AC_SUBST(TARGET_SYSTEM_ROOT)
1928 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1929
1930 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1931     [automatically load a system-wide gdbinit file],
1932     [])
1933
1934 AM_GDB_WARNINGS
1935
1936 # In the Cygwin environment, we need some additional flags.
1937 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1938 [AC_EGREP_CPP(^lose$, [
1939 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1940 lose
1941 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1942
1943
1944 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1945 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1946 case ${host} in
1947   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1948   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1949   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1950 esac
1951 AC_SUBST(SER_HARDWIRE)
1952
1953 # libreadline needs libuser32.a in a cygwin environment
1954 WIN32LIBS=
1955 if test x$gdb_cv_os_cygwin = xyes; then
1956     WIN32LIBS="-luser32"
1957     case "${target}" in
1958         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1959         ;;
1960     esac
1961 fi
1962
1963 # The ser-tcp.c module requires sockets.
1964 case ${host} in
1965   *mingw32*)
1966     AC_DEFINE(USE_WIN32API, 1,
1967               [Define if we should use the Windows API, instead of the
1968                POSIX API.  On Windows, we use the Windows API when
1969                building for MinGW, but the POSIX API when building
1970                for Cygwin.])
1971     WIN32LIBS="$WIN32LIBS -lws2_32"
1972     ;;
1973 esac
1974 AC_SUBST(WIN32LIBS)
1975
1976 # Add ELF support to GDB, but only if BFD includes ELF support.
1977 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1978                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1979 if test $gdb_cv_var_elf = yes; then
1980   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1981   AC_DEFINE(HAVE_ELF, 1,
1982             [Define if ELF support should be included.])
1983   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1984   if test "$plugins" = "yes"; then
1985     AC_SEARCH_LIBS(dlopen, dl)
1986   fi
1987 fi
1988
1989 # Add macho support to GDB, but only if BFD includes it.
1990 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1991                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1992 if test $gdb_cv_var_macho = yes; then
1993   CONFIG_OBS="$CONFIG_OBS machoread.o"
1994 fi
1995
1996 # Add any host-specific objects to GDB.
1997 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1998
1999 # If building on ELF, look for lzma support for embedded compressed debug info.
2000 if test $gdb_cv_var_elf = yes; then
2001   AC_ARG_WITH(lzma,
2002     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2003     [], [with_lzma=auto])
2004   AC_MSG_CHECKING([whether to use lzma])
2005   AC_MSG_RESULT([$with_lzma])
2006
2007   if test "${with_lzma}" != no; then
2008     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2009                           [lzma_index_iter iter;
2010                            lzma_index_iter_init (&iter, 0);
2011                            lzma_mf_is_supported (LZMA_MF_HC3);])
2012     if test "$HAVE_LIBLZMA" != yes; then
2013       if test "$with_lzma" = yes; then
2014         AC_MSG_ERROR([missing liblzma for --with-lzma])
2015       fi
2016     fi
2017   fi
2018 fi
2019
2020 LIBGUI="../libgui/src/libgui.a"
2021 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2022 AC_SUBST(LIBGUI)
2023 AC_SUBST(GUI_CFLAGS_X)
2024
2025 WIN32LDAPP=
2026 AC_SUBST(WIN32LIBS)
2027 AC_SUBST(WIN32LDAPP)
2028
2029 case "${host}" in
2030 *-*-cygwin* | *-*-mingw* )
2031     configdir="win"
2032     ;;
2033 *)
2034     configdir="unix"
2035     ;;
2036 esac
2037
2038 GDBTKLIBS=
2039 if test "${enable_gdbtk}" = "yes"; then
2040
2041     # Gdbtk must have an absolute path to srcdir in order to run
2042     # properly when not installed.
2043     here=`pwd`
2044     cd ${srcdir}
2045     GDBTK_SRC_DIR=`pwd`
2046     cd $here
2047
2048     SC_PATH_TCLCONFIG
2049
2050     # If $no_tk is nonempty, then we can't do Tk, and there is no
2051     # point to doing Tcl.
2052     SC_PATH_TKCONFIG
2053
2054     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2055         SC_LOAD_TCLCONFIG
2056
2057         # Check for in-tree tcl
2058         here=`pwd`
2059         cd ${srcdir}/..
2060         topdir=`pwd`
2061         cd ${here}
2062
2063         intree="no"
2064         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2065           intree="yes"
2066         fi
2067
2068         # Find Tcl private headers
2069         if test x"${intree}" = xno; then
2070           CY_AC_TCL_PRIVATE_HEADERS
2071           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2072           TCL_LIBRARY="${TCL_LIB_SPEC}"
2073           TCL_DEPS=""
2074         else
2075           # If building tcl in the same src tree, private headers
2076           # are not needed, but we need to be sure to use the right
2077           # headers library
2078           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2079           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2080           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2081         fi
2082         AC_SUBST(TCL_INCLUDE)
2083         AC_SUBST(TCL_LIBRARY)
2084         AC_SUBST(TCL_DEPS)
2085
2086         SC_LOAD_TKCONFIG
2087
2088         # Check for in-tree Tk
2089         intree="no"
2090         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2091           intree="yes"
2092         fi
2093
2094         # Find Tk private headers
2095         if test x"${intree}" = xno; then
2096           CY_AC_TK_PRIVATE_HEADERS
2097           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2098           TK_LIBRARY=${TK_LIB_SPEC}
2099           TK_DEPS=""
2100         else
2101           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2102           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2103           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2104         fi
2105         AC_SUBST(TK_INCLUDE)
2106         AC_SUBST(TK_LIBRARY)
2107         AC_SUBST(TK_DEPS)
2108         AC_SUBST(TK_XINCLUDES)
2109
2110         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2111
2112         # Include some libraries that Tcl and Tk want.
2113         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2114         # Yes, the ordering seems wrong here.  But it isn't.
2115         # TK_LIBS is the list of libraries that need to be linked
2116         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2117         # were in LIBS then any link tests after this point would
2118         # try to include things like `$(LIBGUI)', which wouldn't work.
2119         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2120
2121         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2122         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2123         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2124         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2125         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2126         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2127         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2128
2129         if test x$gdb_cv_os_cygwin = xyes; then
2130           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2131           WIN32LDAPP="-Wl,--subsystem,console"
2132           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2133         fi
2134
2135         AC_CONFIG_SUBDIRS(gdbtk)
2136     fi
2137 fi
2138
2139 AC_SUBST(X_CFLAGS)
2140 AC_SUBST(X_LDFLAGS)
2141 AC_SUBST(X_LIBS)
2142 AC_SUBST(GDBTKLIBS)
2143 AC_SUBST(GDBTK_CFLAGS)
2144 AC_SUBST(GDBTK_SRC_DIR)
2145
2146 AC_PATH_X
2147
2148 # Unlike the sim directory, whether a simulator is linked is controlled by
2149 # presence of a gdb_sim definition in the target configure.tgt entry.
2150 # This code just checks for a few cases where we'd like to ignore those
2151 # definitions, even when they're present in the '.mt' file.  These cases
2152 # are when --disable-sim is specified, or if the simulator directory is
2153 # not part of the source tree.
2154 #
2155 AC_ARG_ENABLE(sim,
2156 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2157 [echo "enable_sim = $enable_sim";
2158  echo "enableval = ${enableval}";
2159  case "${enableval}" in
2160   yes) ignore_sim=false ;;
2161   no)  ignore_sim=true ;;
2162   *)   ignore_sim=false ;;
2163  esac],
2164 [ignore_sim=false])
2165
2166 if test ! -d "${srcdir}/../sim"; then
2167   ignore_sim=true
2168 fi
2169
2170 SIM=
2171 SIM_OBS=
2172 if test "${ignore_sim}" = "false"; then
2173   if test x"${gdb_sim}" != x ; then
2174     SIM="${gdb_sim}"
2175     SIM_OBS="remote-sim.o"
2176     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2177
2178     # Some tdep code should only be compiled in when the ppc sim is
2179     # built.  PR sim/13418.
2180     case $target in
2181       powerpc*-*-*)
2182         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2183         ;;
2184     esac
2185   fi
2186 fi
2187 AC_SUBST(SIM)
2188 AC_SUBST(SIM_OBS)
2189
2190 AC_SUBST(ENABLE_CFLAGS)
2191 AC_SUBST(PROFILE_CFLAGS)
2192
2193 AC_SUBST(CONFIG_OBS)
2194 AC_SUBST(CONFIG_DEPS)
2195 AC_SUBST(CONFIG_SRCS)
2196 AC_SUBST(CONFIG_ALL)
2197 AC_SUBST(CONFIG_CLEAN)
2198 AC_SUBST(CONFIG_INSTALL)
2199 AC_SUBST(CONFIG_UNINSTALL)
2200
2201 # List of host floatformats.
2202 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2203 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2204 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2205
2206 # target_subdir is used by the testsuite to find the target libraries.
2207 target_subdir=
2208 if test "${host}" != "${target}"; then
2209     target_subdir="${target_alias}/"
2210 fi
2211 AC_SUBST(target_subdir)
2212
2213 frags=
2214 if test "${gdb_native}" = "yes"; then
2215   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2216   if test ! -f ${host_makefile_frag}; then
2217     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2218   fi
2219   frags="$frags $host_makefile_frag"
2220 else
2221   host_makefile_frag=/dev/null
2222 fi
2223
2224 AC_SUBST_FILE(host_makefile_frag)
2225 AC_SUBST(frags)
2226
2227 changequote(,)dnl
2228 if test "${gdb_native}" = "yes"; then
2229 # We pick this up from the host configuration file (.mh) because we
2230 # do not have a native configuration Makefile fragment.
2231 nativefile=`sed -n '
2232 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2233 ' ${host_makefile_frag}`
2234 fi
2235 changequote([,])
2236
2237 if test x"${gdb_osabi}" != x ; then
2238     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2239                        [Define to the default OS ABI for this configuration.])
2240 fi
2241
2242 # Enable multi-ice-gdb-server.
2243 AC_ARG_ENABLE(multi-ice,
2244 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2245   [case $enableval in
2246     yes | no)
2247       ;;
2248     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2249   esac])
2250 if test "x$enable_multi_ice" = xyes; then
2251    AC_CONFIG_SUBDIRS(multi-ice)
2252 fi
2253
2254 AC_ARG_ENABLE(gdbserver,
2255 AS_HELP_STRING([--enable-gdbserver],
2256                [automatically build gdbserver (yes/no/auto, default is auto)]),
2257 [case "${enableval}" in
2258   yes| no|auto) ;;
2259   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2260 esac],[enable_gdbserver=auto])
2261
2262 # We only build gdbserver automatically in a native configuration, and
2263 # only if the user did not explicitly disable its build.
2264 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2265   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2266   if test "x$build_gdbserver" = xyes; then
2267     AC_MSG_RESULT(yes)
2268     AC_CONFIG_SUBDIRS(gdbserver)
2269     gdbserver_build_enabled=yes
2270   else
2271     AC_MSG_RESULT(no)
2272   fi
2273 fi
2274
2275 # If the user explicitly request the gdbserver to be built, verify that
2276 # we were in fact able to enable it.
2277 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2278   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2279 fi
2280
2281 # Check for babeltrace and babeltrace-ctf
2282 AC_ARG_WITH(babeltrace,
2283   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2284   [], [with_babeltrace=auto])
2285 AC_MSG_CHECKING([whether to use babeltrace])
2286 AC_MSG_RESULT([$with_babeltrace])
2287
2288 if test "x$with_babeltrace" = "xno"; then
2289   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2290 else
2291   # Append -Werror to CFLAGS so that configure can catch the warning
2292   # "assignment from incompatible pointer type", which is related to
2293   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2294   # in GDB, while babeltrace 1.0.3 is broken.
2295   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2296   # safe to save and restore CFLAGS here.
2297   saved_CFLAGS=$CFLAGS
2298   CFLAGS="$CFLAGS -Werror"
2299   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2300                         [#include <babeltrace/babeltrace.h>
2301                          #include <babeltrace/ctf/events.h>
2302                          #include <babeltrace/ctf/iterator.h>],
2303                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2304                         struct bt_ctf_event *event = NULL;
2305                         const struct bt_definition *scope;
2306
2307                         pos->type = BT_SEEK_BEGIN;
2308                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2309                         scope = bt_ctf_get_top_level_scope (event,
2310                                                            BT_STREAM_EVENT_HEADER);
2311                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2312                         ])
2313   CFLAGS=$saved_CFLAGS
2314
2315   if test "$HAVE_LIBBABELTRACE" != yes; then
2316      if test "$with_babeltrace" = yes; then
2317        AC_MSG_ERROR([babeltrace is missing or unusable])
2318      else
2319        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2320      fi
2321   fi
2322 fi
2323
2324 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2325 # to an empty version.
2326
2327 files=
2328 links=
2329
2330 rm -f nm.h
2331 if test "${nativefile}" != ""; then
2332     case "${nativefile}" in
2333       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2334       * ) GDB_NM_FILE="${nativefile}"
2335     esac
2336     files="${files} ${GDB_NM_FILE}"
2337     links="${links} nm.h"
2338     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2339 fi
2340 AC_SUBST(GDB_NM_FILE)
2341
2342 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2343 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2344 if test "x$USE_MAINTAINER_MODE" = xyes; then
2345   if test "${XSLTPROC}" = missing; then
2346     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2347   fi
2348 fi
2349 AC_SUBST(XSLTPROC)
2350
2351 AC_LINK_FILES($files, $links)
2352
2353 dnl Check for exe extension set on certain hosts (e.g. Win32)
2354 AC_EXEEXT
2355
2356 dnl  Detect the character set used by this host.
2357 dnl  At the moment, we just assume it's UTF-8.
2358 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2359           [Define to be a string naming the default host character set.])
2360
2361 if $development; then
2362   AC_DEFINE(GDB_SELF_TEST, 1,
2363             [Define if self-testing features should be enabled])
2364 fi
2365
2366 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2367 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2368 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2369 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2370 [
2371 case x$CONFIG_HEADERS in
2372 xconfig.h:config.in)
2373 echo > stamp-h ;;
2374 esac
2375 ])
2376
2377 AC_OUTPUT