gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 gl_EARLY
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37
  38 # Dependency checking.
  39 ZW_CREATE_DEPDIR
  40 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  41
  42 # Check for the 'make' the user wants to use.
  43 AC_CHECK_PROGS(MAKE, make)
  44 MAKE_IS_GNU=
  45 case "`$MAKE --version 2>&1 | sed 1q`" in
  46   *GNU*)
  47     MAKE_IS_GNU=yes
  48     ;;
  49 esac
  50 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  51 AC_PROG_MAKE_SET
  52
  53 dnl List of object files and targets accumulated by configure.
  54
  55 CONFIG_OBS=
  56 CONFIG_DEPS=
  57 CONFIG_SRCS=
  58 ENABLE_CFLAGS=
  59
  60 CONFIG_ALL=
  61 CONFIG_CLEAN=
  62 CONFIG_INSTALL=
  63 CONFIG_UNINSTALL=
  64
  65 dnl Set up for gettext.
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67
  68 localedir='${datadir}/locale'
  69 AC_SUBST(localedir)
  70
  71 if test x"$USE_NLS" = xyes; then
  72    CONFIG_ALL="$CONFIG_ALL all-po"
  73    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  74    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  75    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  76 fi
  77
  78 gl_INIT
  79
  80 # For Makefile dependencies.
  81 GNULIB_STDINT_H=
  82 if test x"$STDINT_H" != x; then
  83   GNULIB_STDINT_H=gnulib/$STDINT_H
  84 fi
  85 AC_SUBST(GNULIB_STDINT_H)
  86
  87 PACKAGE=gdb
  88 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  89 AC_SUBST(PACKAGE)
  90
  91 # GDB does not use automake, but gnulib does.  This line lets us
  92 # generate its Makefile.in.
  93 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  94
  95 debugdir=${libdir}/debug
  96
  97 AC_ARG_WITH(separate-debug-dir,
  98 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  99 [debugdir="${withval}"])
 100
 101 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 102               [Global directory for separate debug files. ])
 103 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 104
 105 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
 106   if test "x$prefix" = xNONE; then
 107     test_prefix=/usr/local
 108   else
 109     test_prefix=$prefix
 110   fi
 111 else
 112   test_prefix=$exec_prefix
 113 fi
 114 case ${debugdir} in
 115 "${test_prefix}"|"${test_prefix}/"*|\
 116 '${exec_prefix}'|'${exec_prefix}/'*)
 117   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
 118   ;;
 119 esac
 120
 121 AC_CONFIG_SUBDIRS(doc testsuite)
 122
 123 # Check whether to support alternative target configurations
 124 AC_ARG_ENABLE(targets,
 125 [  --enable-targets        alternative target configurations],
 126 [case "${enableval}" in
 127   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 128             ;;
 129   no)       enable_targets= ;;
 130   *)        enable_targets=$enableval ;;
 131 esac])
 132
 133 # Check whether to enable 64-bit support on 32-bit hosts
 134 AC_ARG_ENABLE(64-bit-bfd,
 135 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
 136 [case "${enableval}" in
 137   yes)  want64=true  ;;
 138   no)   want64=false ;;
 139   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 140 esac],[want64=false])dnl
 141
 142 # Provide defaults for some variables set by the per-host and per-target
 143 # configuration.
 144 gdb_host_obs=posix-hdep.o
 145
 146 if test "${target}" = "${host}"; then
 147   gdb_native=yes
 148 else
 149   gdb_native=no
 150 fi
 151
 152 . $srcdir/configure.host
 153
 154 # Accumulate some settings from configure.tgt over all enabled targets
 155
 156 TARGET_OBS=
 157 all_targets=
 158
 159 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 160 do
 161   if test "$targ_alias" = "all"; then
 162     all_targets=true
 163   else
 164     # Canonicalize the secondary target names.
 165     result=`$ac_config_sub $targ_alias 2>/dev/null`
 166     if test -n "$result"; then
 167         targ=$result
 168     else
 169         targ=$targ_alias
 170     fi
 171
 172     . ${srcdir}/configure.tgt
 173
 174     # Target-specific object files
 175     for i in ${gdb_target_obs}; do
 176         case " $TARGET_OBS " in
 177         *" ${i} "*) ;;
 178         *)
 179           TARGET_OBS="$TARGET_OBS ${i}"
 180           ;;
 181         esac
 182     done
 183
 184     # Check whether this target needs 64-bit CORE_ADDR
 185     if test x${want64} = xfalse; then
 186       . ${srcdir}/../bfd/config.bfd
 187     fi
 188   fi
 189 done
 190
 191 if test x${all_targets} = xtrue; then
 192
 193   # We want all 64-bit targets if we either:
 194   #  - run on a 64-bit host  or
 195   #  - already require 64-bit support for some other target  or
 196   #  - the --enable-64-bit-bfd option was supplied
 197   # Otherwise we only support all 32-bit targets.
 198   #
 199   # NOTE: This test must be in sync with the corresponding
 200   #       tests in BFD!
 201
 202   if test x${want64} = xfalse; then
 203     AC_CHECK_SIZEOF(long)
 204     if test "x${ac_cv_sizeof_long}" = "x8"; then
 205       want64=true
 206     fi
 207   fi
 208   if test x${want64} = xtrue; then
 209     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 210   else
 211     TARGET_OBS='$(ALL_TARGET_OBS)'
 212   fi
 213 fi
 214
 215 AC_SUBST(TARGET_OBS)
 216
 217 # For other settings, only the main target counts.
 218 gdb_sim=
 219 gdb_osabi=
 220 build_gdbserver=
 221 targ=$target; . ${srcdir}/configure.tgt
 222
 223 # Fetch the default architecture and default target vector from BFD.
 224 targ=$target; . $srcdir/../bfd/config.bfd
 225
 226 # We only want the first architecture, so strip off the others if
 227 # there is more than one.
 228 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 229
 230 if test "x$targ_archs" != x; then
 231   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 232     [Define to BFD's default architecture. ])
 233 fi
 234 if test "x$targ_defvec" != x; then
 235   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 236     [Define to BFD's default target vector. ])
 237 fi
 238
 239 # The CLI cannot be disabled yet, but may be in the future.
 240
 241 # Enable CLI.
 242 AC_ARG_ENABLE(gdbcli,
 243 [  --disable-gdbcli        disable command-line interface (CLI)],
 244   [case $enableval in
 245     yes)
 246       ;;
 247     no)
 248       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 249     *)
 250       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 251   esac],
 252   [enable_gdbcli=yes])
 253 if test x"$enable_gdbcli" = xyes; then
 254   if test -d $srcdir/cli; then
 255     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 256     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 257     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 258     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 259   fi
 260 fi
 261
 262 # Enable MI.
 263 AC_ARG_ENABLE(gdbmi,
 264 [  --disable-gdbmi         disable machine-interface (MI)],
 265   [case $enableval in
 266     yes | no)
 267       ;;
 268     *)
 269       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 270   esac],
 271   [enable_gdbmi=yes])
 272 if test x"$enable_gdbmi" = xyes; then
 273   if test -d $srcdir/mi; then
 274     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 275     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 276     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 277     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 278   fi
 279 fi
 280
 281 # Enable TUI.
 282 AC_ARG_ENABLE(tui,
 283 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 284   [case $enableval in
 285     yes | no | auto)
 286       ;;
 287     *)
 288       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 289   esac],enable_tui=auto)
 290
 291 # Enable gdbtk.
 292 AC_ARG_ENABLE(gdbtk,
 293 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 294   [case $enableval in
 295     yes | no)
 296       ;;
 297     *)
 298       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 299   esac],
 300   [if test -d $srcdir/gdbtk; then
 301     enable_gdbtk=yes
 302   else
 303     enable_gdbtk=no
 304   fi])
 305 # We unconditionally disable gdbtk tests on selected platforms.
 306 case $host_os in
 307   go32* | windows*)
 308     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 309     enable_gdbtk=no ;;
 310 esac
 311
 312 # Libunwind support.
 313 AC_ARG_WITH(libunwind,
 314 [  --with-libunwind            Use libunwind frame unwinding support],
 315 [case "${withval}" in
 316   yes)  enable_libunwind=yes ;;
 317   no)   enable_libunwind=no ;;
 318   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 319 esac],[
 320   AC_CHECK_HEADERS(libunwind.h)
 321   AC_CHECK_HEADERS(libunwind-ia64.h)
 322   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 323     enable_libunwind=yes;
 324   fi
 325 ])
 326
 327 if test x"$enable_libunwind" = xyes; then
 328   AC_CHECK_HEADERS(libunwind.h)
 329   AC_CHECK_HEADERS(libunwind-ia64.h)
 330   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 331   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 332   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 333   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 334 fi
 335
 336 # Profiling support.
 337 AC_ARG_ENABLE(profiling,
 338 [  --enable-profiling      enable profiling of GDB],
 339   [case $enableval in
 340     yes | no)
 341       ;;
 342     *)
 343       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 344   esac],
 345  [enable_profiling=no])
 346
 347 AC_CHECK_FUNCS(monstartup _mcleanup)
 348 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 349 [AC_TRY_LINK(
 350 [#include <stdlib.h>
 351 extern char _etext;
 352 ],
 353 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 354 if test $ac_cv_var__etext = yes; then
 355   AC_DEFINE(HAVE__ETEXT, 1,
 356             [Define to 1 if your system has the _etext variable. ])
 357 fi
 358 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 359 [AC_TRY_LINK(
 360 [#include <stdlib.h>
 361 extern char etext;
 362 ],
 363 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 364 if test $ac_cv_var_etext = yes; then
 365   AC_DEFINE(HAVE_ETEXT, 1,
 366             [Define to 1 if your system has the etext variable. ])
 367 fi
 368 if test "$enable_profiling" = yes ; then
 369   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 370     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 371   fi
 372   PROFILE_CFLAGS=-pg
 373   OLD_CFLAGS="$CFLAGS"
 374   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 375
 376   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 377     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 378      ac_cv_cc_supports_pg=no)])
 379
 380   if test $ac_cv_cc_supports_pg = no; then
 381     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 382   fi
 383
 384   CFLAGS="$OLD_CFLAGS"
 385 fi
 386
 387 ACX_PKGVERSION([GDB])
 388 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 389 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 390 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 391
 392 # --------------------- #
 393 # Checks for programs.  #
 394 # --------------------- #
 395
 396 AC_PROG_AWK
 397 AC_PROG_INSTALL
 398 AC_PROG_LN_S
 399 AC_PROG_RANLIB
 400 AC_PROG_YACC
 401
 402 AC_CHECK_TOOL(AR, ar)
 403 AC_CHECK_TOOL(DLLTOOL, dlltool)
 404 AC_CHECK_TOOL(WINDRES, windres)
 405
 406 # Needed for GNU/Hurd.
 407 AC_CHECK_TOOL(MIG, mig)
 408
 409 # ---------------------- #
 410 # Checks for libraries.  #
 411 # ---------------------- #
 412
 413 # We might need to link with -lm; most simulators need it.
 414 AC_CHECK_LIB(m, main)
 415
 416 # We need to link with -lw to get `wctype' on Solaris before Solaris
 417 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 418 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 419 # is known to have this problem).  Therefore we avoid libw if we can.
 420 AC_CHECK_FUNC(wctype, [],
 421   [AC_CHECK_LIB(w, wctype)])
 422
 423 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 424 AC_SEARCH_LIBS(gethostbyname, nsl)
 425
 426 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 427 AC_SEARCH_LIBS(socketpair, socket)
 428
 429 # Link in zlib if we can.  This allows us to read compressed debug sections.
 430 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 431
 432 # For the TUI, we need enhanced curses functionality.
 433 #
 434 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 435 # curses library because the latter might not provide all the
 436 # functionality we need.  However, this leads to problems on systems
 437 # where the linker searches /usr/local/lib, but the compiler doesn't
 438 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 439 # default installation of ncurses on alpha*-dec-osf* will lead to such
 440 # a situation.
 441 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 442
 443 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 444 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 445
 446 # Since GDB uses Readline, we need termcap functionality.  In many
 447 # cases this will be provided by the curses library, but some systems
 448 # have a seperate termcap library, or no curses library at all.
 449
 450 case $host_os in
 451   cygwin*)
 452     if test -d $srcdir/libtermcap; then
 453       LIBS="../libtermcap/libtermcap.a $LIBS"
 454       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 455     fi ;;
 456   go32* | *djgpp*)
 457     ac_cv_search_tgetent="none required"
 458     ;;
 459   *mingw32*)
 460     ac_cv_search_tgetent="none required"
 461     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 462     ;;
 463 esac
 464
 465 # These are the libraries checked by Readline.
 466 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 467
 468 if test "$ac_cv_search_tgetent" = no; then
 469   AC_MSG_ERROR([no termcap library found])
 470 fi
 471
 472 AC_ARG_WITH([system-readline],
 473   [AS_HELP_STRING([--with-system-readline],
 474                   [use installed readline library])])
 475
 476 if test "$with_system_readline" = yes; then
 477   READLINE=-lreadline
 478   READLINE_DEPS=
 479   READLINE_CFLAGS=
 480 else
 481   READLINE='$(READLINE_DIR)/libreadline.a'
 482   READLINE_DEPS='$(READLINE)'
 483   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 484 fi
 485 AC_SUBST(READLINE)
 486 AC_SUBST(READLINE_DEPS)
 487 AC_SUBST(READLINE_CFLAGS)
 488
 489 AC_ARG_WITH(expat,
 490   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 491   [], [with_expat=auto])
 492 AC_MSG_CHECKING([whether to use expat])
 493 AC_MSG_RESULT([$with_expat])
 494
 495 if test "${with_expat}" = no; then
 496   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 497   HAVE_LIBEXPAT=no
 498 else
 499   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 500                         [XML_Parser p = XML_ParserCreate (0);])
 501   if test "$HAVE_LIBEXPAT" != yes; then
 502     if test "$with_expat" = yes; then
 503       AC_MSG_ERROR([expat is missing or unusable])
 504     else
 505       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 506     fi
 507   else
 508     save_LIBS=$LIBS
 509     LIBS="$LIBS $LIBEXPAT"
 510     AC_CHECK_FUNCS(XML_StopParser)
 511     LIBS=$save_LIBS
 512   fi
 513 fi
 514
 515 dnl Utility to simplify finding libpython.
 516 AC_DEFUN([AC_TRY_LIBPYTHON],
 517 [
 518   version=$1
 519   define([have_libpython_var],$2)
 520   define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
 521                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
 522   [HAVE_LIB]VERSION=no
 523   AC_MSG_CHECKING([for ${version}])
 524   save_LIBS=$LIBS
 525   LIBS="$LIBS -l${version}"
 526   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 527                                  [[Py_Initialize ();]]),
 528                  [[HAVE_LIB]VERSION=yes
 529                   have_libpython_var=yes],
 530                  [LIBS=$save_LIBS])
 531   AC_MSG_RESULT([$[HAVE_LIB]VERSION])
 532 ])
 533
 534 AC_ARG_WITH(python,
 535   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 536   [], [with_python=auto])
 537 AC_MSG_CHECKING([whether to use python])
 538 AC_MSG_RESULT([$with_python])
 539
 540 if test "${with_python}" = no; then
 541   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 542   have_libpython=no
 543 else
 544   case "${with_python}" in
 545   yes | auto)
 546     # Leave as empty, use defaults.
 547     python_includes=
 548     python_libs=
 549     ;;
 550   /*)
 551     python_includes="-I${with_python}/include"
 552     python_libs="-L${with_python}/lib"
 553     ;;
 554   *)
 555     AC_ERROR(invalid value for --with-python)
 556     ;;
 557   esac
 558
 559   save_CPPFLAGS=$CPPFLAGS
 560   CPPFLAGS="$CPPFLAGS ${python_includes}"
 561   save_LIBS=$LIBS
 562   LIBS="$LIBS ${python_libs}"
 563   have_libpython=no
 564   if test "${have_libpython}" = no; then
 565     AC_TRY_LIBPYTHON(python2.6, have_libpython)
 566     if test "${HAVE_LIBPYTHON2_6}" = yes; then
 567       AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 568     fi
 569   fi
 570   if test ${have_libpython} = no; then
 571     AC_TRY_LIBPYTHON(python2.5, have_libpython)
 572     if test "${HAVE_LIBPYTHON2_5}" = yes; then
 573       AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 574     fi
 575   fi
 576   if test ${have_libpython} = no; then
 577     AC_TRY_LIBPYTHON(python2.4, have_libpython)
 578     if test "${HAVE_LIBPYTHON2_4}" = yes; then
 579       AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 580     fi
 581   fi
 582   if test ${have_libpython} = no; then
 583     case "${with_python}" in
 584     yes)
 585       AC_MSG_ERROR([python is missing or unusable])
 586       ;;
 587     auto)
 588       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 589       ;;
 590     *)
 591       AC_MSG_ERROR([no usable python found at ${with_python}])
 592       ;;
 593     esac
 594     CPPFLAGS=$save_CPPFLAGS
 595     LIBS=$save_LIBS
 596   fi
 597 fi
 598
 599 if test "${have_libpython}" = yes; then
 600   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 601   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 602   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 603   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 604   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 605
 606   # Flags needed to compile Python code (taken from python-config --cflags).
 607   # We cannot call python-config directly because it will output whatever was
 608   # used when compiling the Python interpreter itself, including flags which
 609   # would make the python-related objects be compiled differently from the
 610   # rest of GDB (e.g., -O2 and -fPIC).
 611   if test "${GCC}" = yes; then
 612     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 613   fi
 614
 615   if test "x${tentative_python_cflags}" != x; then
 616     AC_MSG_CHECKING(compiler flags for python code)
 617     for flag in ${tentative_python_cflags}; do
 618       # Check that the compiler accepts it
 619       saved_CFLAGS="$CFLAGS"
 620       CFLAGS="$CFLAGS $flag"
 621       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 622       CFLAGS="$saved_CFLAGS"
 623     done
 624     AC_MSG_RESULT(${PYTHON_CFLAGS})
 625   fi
 626 else
 627   # Even if Python support is not compiled in, we need to have these files
 628   # included in order to recognize the GDB command "python".
 629   CONFIG_OBS="$CONFIG_OBS python.o python-value.o"
 630   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/python-value.c"
 631 fi
 632 AC_SUBST(PYTHON_CFLAGS)
 633
 634 # ------------------------- #
 635 # Checks for header files.  #
 636 # ------------------------- #
 637
 638 AC_HEADER_DIRENT
 639 AC_HEADER_STAT
 640 AC_HEADER_STDC
 641 AC_CHECK_HEADERS(nlist.h)
 642 AC_CHECK_HEADERS(link.h, [], [],
 643 [#if HAVE_SYS_TYPES_H
 644 # include <sys/types.h>
 645 #endif
 646 #if HAVE_NLIST_H
 647 # include <nlist.h>
 648 #endif
 649 ])
 650 AC_CHECK_HEADERS(machine/reg.h)
 651 AC_CHECK_HEADERS(poll.h sys/poll.h)
 652 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 653 AC_CHECK_HEADERS(signal.h)
 654 AC_CHECK_HEADERS(stddef.h)
 655 AC_CHECK_HEADERS(stdlib.h)
 656 AC_CHECK_HEADERS(string.h memory.h strings.h)
 657 AC_CHECK_HEADERS(sys/fault.h)
 658 AC_CHECK_HEADERS(sys/file.h)
 659 AC_CHECK_HEADERS(sys/filio.h)
 660 AC_CHECK_HEADERS(sys/ioctl.h)
 661 AC_CHECK_HEADERS(sys/param.h)
 662 AC_CHECK_HEADERS(sys/resource.h)
 663 AC_CHECK_HEADERS(sys/proc.h, [], [],
 664 [#if HAVE_SYS_PARAM_H
 665 # include <sys/param.h>
 666 #endif
 667 ])
 668 AC_CHECK_HEADERS(sys/procfs.h)
 669 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 670 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 671 AC_CHECK_HEADERS(sys/select.h)
 672 AC_CHECK_HEADERS(sys/syscall.h)
 673 AC_CHECK_HEADERS(sys/types.h)
 674 AC_CHECK_HEADERS(sys/user.h, [], [],
 675 [#if HAVE_SYS_PARAM_H
 676 # include <sys/param.h>
 677 #endif
 678 ])
 679 AC_CHECK_HEADERS(sys/wait.h wait.h)
 680 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 681 AC_CHECK_HEADERS(unistd.h)
 682
 683 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 684 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 685 # think that we don't have <curses.h> if we're using GCC.
 686 case $host_os in
 687   solaris2.[[789]])
 688     if test "$GCC" = yes; then
 689       AC_DEFINE(_MSE_INT_H, 1,
 690         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 691    Solaris 2.[789] when using GCC. ])
 692     fi ;;
 693 esac
 694 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 695 AC_CHECK_HEADERS(ncurses/term.h)
 696 AC_CHECK_HEADERS(term.h, [], [],
 697 [#if HAVE_CURSES_H
 698 # include <curses.h>
 699 #endif
 700 ])
 701
 702 # Check for HP/UX 64-bit shared library support
 703 AC_CHECK_HEADERS(elf_hp.h)
 704
 705 # FIXME: kettenis/20030102: In most cases we include these
 706 # unconditionally, so what's the point in checking these?
 707 AC_CHECK_HEADERS(ctype.h time.h)
 708
 709 # ------------------------- #
 710 # Checks for declarations.  #
 711 # ------------------------- #
 712
 713 AC_CHECK_DECLS([free, malloc, realloc])
 714 AC_CHECK_DECLS([strerror, strstr])
 715 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 716
 717 # ----------------------- #
 718 # Checks for structures.  #
 719 # ----------------------- #
 720
 721 AC_CHECK_MEMBERS([struct stat.st_blocks])
 722 AC_CHECK_MEMBERS([struct stat.st_blksize])
 723
 724 # ------------------ #
 725 # Checks for types.  #
 726 # ------------------ #
 727
 728 AC_TYPE_SIGNAL
 729 AC_CHECK_TYPES(socklen_t, [], [],
 730 [#include <sys/types.h>
 731 #include <sys/socket.h>
 732 ])
 733
 734 # ------------------------------------- #
 735 # Checks for compiler characteristics.  #
 736 # ------------------------------------- #
 737
 738 AC_C_CONST
 739 AC_C_INLINE
 740 AC_C_BIGENDIAN
 741
 742 # ------------------------------ #
 743 # Checks for library functions.  #
 744 # ------------------------------ #
 745
 746 AC_FUNC_ALLOCA
 747 AC_FUNC_MMAP
 748 AC_FUNC_VFORK
 749 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 750 AC_CHECK_FUNCS(getrusage)
 751 AC_CHECK_FUNCS(getuid getgid)
 752 AC_CHECK_FUNCS(poll)
 753 AC_CHECK_FUNCS(pread64)
 754 AC_CHECK_FUNCS(sbrk)
 755 AC_CHECK_FUNCS(setpgid setpgrp setsid)
 756 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 757 AC_CHECK_FUNCS(socketpair)
 758 AC_CHECK_FUNCS(syscall)
 759 AC_CHECK_FUNCS(ttrace)
 760 AC_CHECK_FUNCS(wborder)
 761
 762 # Check the return and argument types of ptrace.  No canned test for
 763 # this, so roll our own.
 764 gdb_ptrace_headers='
 765 #if HAVE_SYS_TYPES_H
 766 # include <sys/types.h>
 767 #endif
 768 #if HAVE_SYS_PTRACE_H
 769 # include <sys/ptrace.h>
 770 #endif
 771 #if HAVE_UNISTD_H
 772 # include <unistd.h>
 773 #endif
 774 '
 775 # There is no point in checking if we don't have a prototype.
 776 AC_CHECK_DECLS(ptrace, [], [
 777   : ${gdb_cv_func_ptrace_ret='int'}
 778   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 779 ], $gdb_ptrace_headers)
 780 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 781 # empty argument list, so check for that explicitly.
 782 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 783   AC_TRY_COMPILE($gdb_ptrace_headers,
 784     [extern long ptrace (enum __ptrace_request, ...);],
 785     gdb_cv_func_ptrace_ret='long',
 786     AC_TRY_COMPILE($gdb_ptrace_headers,
 787       [extern int ptrace ();],
 788       gdb_cv_func_ptrace_ret='int',
 789       gdb_cv_func_ptrace_ret='long')))
 790 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 791   [Define as the return type of ptrace.])
 792 # Check argument types.
 793 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 794   AC_TRY_COMPILE($gdb_ptrace_headers,
 795     [extern long ptrace (enum __ptrace_request, ...);],
 796     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 797 for gdb_arg1 in 'int' 'long'; do
 798  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 799   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 800    for gdb_arg4 in 'int' 'long'; do
 801      AC_TRY_COMPILE($gdb_ptrace_headers, [
 802 extern $gdb_cv_func_ptrace_ret
 803   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 804 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 805     break 4;])
 806     for gdb_arg5 in 'int *' 'int' 'long'; do
 807      AC_TRY_COMPILE($gdb_ptrace_headers, [
 808 extern $gdb_cv_func_ptrace_ret
 809   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 810 ], [
 811 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 812     break 5;])
 813     done
 814    done
 815   done
 816  done
 817 done
 818 # Provide a safe default value.
 819 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 820 ])])
 821 ac_save_IFS=$IFS; IFS=','
 822 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 823 IFS=$ac_save_IFS
 824 shift
 825 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 826   [Define to the type of arg 3 for ptrace.])
 827 if test -n "$[5]"; then
 828   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 829     [Define to the type of arg 5 for ptrace.])
 830 fi
 831
 832 dnl AC_FUNC_SETPGRP does not work when cross compiling
 833 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 834 if test "$cross_compiling" = no; then
 835   AC_FUNC_SETPGRP
 836 else
 837   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 838     [AC_TRY_COMPILE([
 839 #include <unistd.h>
 840 ], [
 841   if (setpgrp(1,1) == -1)
 842     exit (0);
 843   else
 844     exit (1);
 845 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 846 if test $ac_cv_func_setpgrp_void = yes; then
 847   AC_DEFINE(SETPGRP_VOID, 1)
 848 fi
 849 fi
 850
 851 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 852 # since sigsetjmp might only be defined as a macro.
 853 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 854 [AC_TRY_COMPILE([
 855 #include <setjmp.h>
 856 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 857 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 858 if test $gdb_cv_func_sigsetjmp = yes; then
 859   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 860 fi
 861
 862 # Assume we'll default to using the included libiberty regex.
 863 gdb_use_included_regex=yes
 864
 865 # However, if the system regex is GNU regex, then default to *not*
 866 # using the included regex.
 867 AC_CACHE_CHECK(
 868   [for GNU regex],
 869   [gdb_cv_have_gnu_regex],
 870   [AC_TRY_COMPILE(
 871     [#include <gnu-versions.h>],
 872     [#define REGEX_INTERFACE_VERSION 1
 873 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 874 # error "Version mismatch"
 875 #endif],
 876     gdb_cv_have_gnu_regex=yes,
 877     gdb_cv_have_gnu_regex=no)])
 878 if test $gdb_cv_have_gnu_regex = yes; then
 879   gdb_use_included_regex=no
 880 fi
 881
 882 AC_ARG_WITH(included-regex,
 883   [  --without-included-regex don't use included regex; this is the default
 884                           on systems with version 2 of the GNU C library
 885                           (use with caution on other system)],
 886   gdb_with_regex=$withval,
 887   gdb_with_regex=$gdb_use_included_regex)
 888 if test "$gdb_with_regex" = yes; then
 889   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 890     [Define to 1 if the regex included in libiberty should be used.])
 891 fi
 892
 893 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 894 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 895 [#include <sys/param.h>
 896 #include <sys/proc.h>
 897 ])
 898
 899 # See if <sys/lwp.h> defines `struct lwp`.
 900 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 901 [AC_TRY_COMPILE([#include <sys/param.h>
 902 #include <sys/lwp.h>], [struct lwp l;],
 903 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 904 if test $gdb_cv_struct_lwp = yes; then
 905   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 906             [Define to 1 if your system has struct lwp.])
 907 fi
 908
 909 # See if <machine/reg.h> degines `struct reg'.
 910 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 911 [AC_TRY_COMPILE([#include <sys/types.h>
 912 #include <machine/reg.h>], [struct reg r;],
 913 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 914 if test $gdb_cv_struct_reg = yes; then
 915   AC_DEFINE(HAVE_STRUCT_REG, 1,
 916             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 917 fi
 918
 919 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 920 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 921 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 922                  [#include <machine/reg.h>])
 923
 924 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 925 AC_MSG_CHECKING(for PTRACE_GETREGS)
 926 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 927 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 928                 [PTRACE_GETREGS;],
 929                 [gdb_cv_have_ptrace_getregs=yes],
 930                 [gdb_cv_have_ptrace_getregs=no])])
 931 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 932 if test $gdb_cv_have_ptrace_getregs = yes; then
 933   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 934   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 935 fi
 936
 937 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 938 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 939 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 940 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 941                 [PTRACE_GETFPXREGS;],
 942                 [gdb_cv_have_ptrace_getfpxregs=yes],
 943                 [gdb_cv_have_ptrace_getfpxregs=no])])
 944 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 945 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 946   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 947   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 948 fi
 949
 950 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 951 AC_MSG_CHECKING(for PT_GETDBREGS)
 952 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 953 [AC_TRY_COMPILE([#include <sys/types.h>
 954 #include <sys/ptrace.h>],
 955                 [PT_GETDBREGS;],
 956                 [gdb_cv_have_pt_getdbregs=yes],
 957                 [gdb_cv_have_pt_getdbregs=no])])
 958 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 959 if test $gdb_cv_have_pt_getdbregs = yes; then
 960   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 961   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 962 fi
 963
 964 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 965 AC_MSG_CHECKING(for PT_GETXMMREGS)
 966 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 967 [AC_TRY_COMPILE([#include <sys/types.h>
 968 #include <sys/ptrace.h>],
 969                 [PT_GETXMMREGS;],
 970                 [gdb_cv_have_pt_getxmmregs=yes],
 971                 [gdb_cv_have_pt_getxmmregs=no])])
 972 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 973 if test $gdb_cv_have_pt_getxmmregs = yes; then
 974   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 975   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 976 fi
 977
 978 # Detect which type of /proc is in use, such as for Unixware or Solaris.
 979
 980 if test "${target}" = "${host}"; then
 981   case "${host}" in
 982   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 983       AC_DEFINE(NEW_PROC_API, 1,
 984       [Define if you want to use new multi-fd /proc interface
 985        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 986       ;;
 987   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
 988       AC_DEFINE(NEW_PROC_API, 1,
 989       [Define if you want to use new multi-fd /proc interface
 990        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 991       ;;
 992   mips-sgi-irix5*)
 993       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 994       AC_DEFINE([_KMEMUSER], 1,
 995       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 996        around a <sys/proc.h> problem on IRIX 5.])
 997       ;;
 998   esac
 999 fi
1000
1001 if test "$ac_cv_header_sys_procfs_h" = yes; then
1002   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1003   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1004   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1005   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1006   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1007   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1008   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1009   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1010   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1011   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1012   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1013   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1014   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1015   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1016
1017
1018   dnl Check for broken prfpregset_t type
1019
1020   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1021   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1022   dnl instead of the struct itself).  We detect this here, and work
1023   dnl around it in gdb_proc_service.h.
1024
1025   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1026     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1027     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1028       [AC_TRY_RUN([#include <sys/procfs.h>
1029        int main ()
1030        {
1031          if (sizeof (prfpregset_t) == sizeof (void *))
1032            return 1;
1033          return 0;
1034        }],
1035        gdb_cv_prfpregset_t_broken=no,
1036        gdb_cv_prfpregset_t_broken=yes,
1037        gdb_cv_prfpregset_t_broken=yes)])
1038     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1039     if test $gdb_cv_prfpregset_t_broken = yes; then
1040       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1041       [Define if the prfpregset_t type is broken.])
1042     fi
1043   fi
1044
1045   dnl Check for PIOCSET ioctl entry
1046
1047   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1048   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1049   [AC_TRY_COMPILE([#include <unistd.h>
1050 #include <sys/types.h>
1051 #include <sys/procfs.h>
1052 ], [
1053     int dummy;;
1054     dummy = ioctl(0, PIOCSET, &dummy);
1055   ],
1056   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1057   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1058   if test $gdb_cv_have_procfs_piocset = yes; then
1059     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1060     [Define if ioctl argument PIOCSET is available.])
1061   fi
1062 fi
1063
1064 dnl For native ports (host == target), check to see what kind of
1065 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1066 if test ${host} = ${target} ; then
1067   dnl Check for struct link_map with l_ members which are indicative
1068   dnl of SVR4-like shared libraries
1069
1070   AC_MSG_CHECKING(for member l_addr in struct link_map)
1071   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1072     [AC_TRY_COMPILE([#include <link.h>],
1073                     [struct link_map lm; (void) lm.l_addr;],
1074                     gdb_cv_have_struct_link_map_with_l_members=yes,
1075                     gdb_cv_have_struct_link_map_with_l_members=no)])
1076   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1077   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1078     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1079     [Define if <link.h> exists and defines struct link_map which has
1080      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1081      SVR4-like systems.)])
1082   fi
1083
1084   dnl Check for struct link_map with lm_ members which are indicative
1085   dnl of SunOS-like shared libraries
1086
1087   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1088   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1089     [AC_TRY_COMPILE([#include <sys/types.h>
1090 #include <link.h>],
1091                     [struct link_map lm; (void) lm.lm_addr;],
1092                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1093                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1094   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1095   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1096     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1097     [Define if <link.h> exists and defines struct link_map which has
1098      members with an ``lm_'' prefix.  (For SunOS.)])
1099   fi
1100
1101   dnl Check for struct so_map with som_ members which are found on
1102   dnl some *BSD systems.
1103
1104   AC_MSG_CHECKING(for member som_addr in struct so_map)
1105   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1106     [AC_TRY_COMPILE([#include <sys/types.h>
1107 #ifdef HAVE_NLIST_H
1108 #include <nlist.h>
1109 #endif
1110 #include <link.h>],
1111                     [struct so_map lm; (void) lm.som_addr;],
1112                     gdb_cv_have_struct_so_map_with_som_members=yes,
1113                     gdb_cv_have_struct_so_map_with_som_members=no)])
1114   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1115   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1116     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1117     [Define if <link.h> exists and defines a struct so_map which has
1118      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1119   fi
1120
1121   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1122   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1123
1124   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1125   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1126     [AC_TRY_COMPILE([#define _SYSCALL32
1127 #include <sys/link.h>], [struct link_map32 l;],
1128      gdb_cv_have_struct_link_map32=yes,
1129      gdb_cv_have_struct_link_map32=no)])
1130   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1131   if test $gdb_cv_have_struct_link_map32 = yes; then
1132     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1133     [Define if <sys/link.h> has struct link_map32])
1134     AC_DEFINE(_SYSCALL32, 1,
1135     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1136   fi
1137 fi
1138
1139 # Check if the compiler supports the `long long' type.
1140
1141 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1142                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1143 [[extern long long foo;]],
1144 [[switch (foo & 2) { case 0: return 1; }]])],
1145                                   gdb_cv_c_long_long=yes,
1146                                   gdb_cv_c_long_long=no)])
1147 if test $gdb_cv_c_long_long = yes; then
1148   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1149             [Define to 1 if the compiler supports long long.])
1150 fi
1151
1152 # Check if the compiler and runtime support printing long longs.
1153
1154 AC_CACHE_CHECK([for long long support in printf],
1155                gdb_cv_printf_has_long_long,
1156                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1157 [[char buf[32];
1158   long long l = 0;
1159   l = (l << 16) + 0x0123;
1160   l = (l << 16) + 0x4567;
1161   l = (l << 16) + 0x89ab;
1162   l = (l << 16) + 0xcdef;
1163   sprintf (buf, "0x%016llx", l);
1164   return (strcmp ("0x0123456789abcdef", buf));]])],
1165                               gdb_cv_printf_has_long_long=yes,
1166                               gdb_cv_printf_has_long_long=no,
1167                               gdb_cv_printf_has_long_long=no)])
1168 if test $gdb_cv_printf_has_long_long = yes; then
1169   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1170             [Define to 1 if the "%ll" format works to print long longs.])
1171 fi
1172
1173 # Check if the compiler and runtime support printing decfloats.
1174
1175 AC_CACHE_CHECK([for decfloat support in printf],
1176                gdb_cv_printf_has_decfloat,
1177                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1178 [[char buf[64];
1179   _Decimal32 d32 = 1.2345df;
1180   _Decimal64 d64 = 1.2345dd;
1181   _Decimal128 d128 = 1.2345dl;
1182   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1183   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1184                               gdb_cv_printf_has_decfloat=yes,
1185                               gdb_cv_printf_has_decfloat=no,
1186                               gdb_cv_printf_has_decfloat=no)])
1187 if test $gdb_cv_printf_has_decfloat = yes; then
1188   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1189             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1190 fi
1191
1192 # Check if the compiler supports the `long double' type.  We can't use
1193 # AC_C_LONG_DOUBLE because that one does additional checks on the
1194 # constants defined in <float.h> that fail on some systems,
1195 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1196
1197 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1198                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1199                                   gdb_cv_c_long_double=yes,
1200                                   gdb_cv_c_long_double=no)])
1201 if test $gdb_cv_c_long_double = yes; then
1202   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1203            [Define to 1 if the compiler supports long double.])
1204 fi
1205
1206 # Check if the compiler and runtime support printing long doubles.
1207
1208 AC_CACHE_CHECK([for long double support in printf],
1209                gdb_cv_printf_has_long_double,
1210                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1211 [[char buf[16];
1212   long double f = 3.141592653;
1213   sprintf (buf, "%Lg", f);
1214   return (strncmp ("3.14159", buf, 7));]])],
1215                               gdb_cv_printf_has_long_double=yes,
1216                               gdb_cv_printf_has_long_double=no,
1217                               gdb_cv_printf_has_long_double=no)])
1218 if test $gdb_cv_printf_has_long_double = yes; then
1219   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1220             [Define to 1 if the "%Lg" format works to print long doubles.])
1221 fi
1222
1223 # Check if the compiler and runtime support scanning long doubles.
1224
1225 AC_CACHE_CHECK([for long double support in scanf],
1226                gdb_cv_scanf_has_long_double,
1227                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1228 [[#include <stdio.h>]],
1229 [[char *buf = "3.141592653";
1230   long double f = 0;
1231   sscanf (buf, "%Lg", &f);
1232   return !(f > 3.14159 && f < 3.14160);]])],
1233                               gdb_cv_scanf_has_long_double=yes,
1234                               gdb_cv_scanf_has_long_double=no,
1235                               gdb_cv_scanf_has_long_double=no)])
1236 if test $gdb_cv_scanf_has_long_double = yes; then
1237   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1238             [Define to 1 if the "%Lg" format works to scan long doubles.])
1239 fi
1240
1241 case ${host_os} in
1242 aix*)
1243   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1244     SAVE_LDFLAGS=$LDFLAGS
1245
1246     case $GCC in
1247     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1248     *) gdb_cv_bigtoc=-bbigtoc ;;
1249     esac
1250
1251     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1252     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1253     LDFLAGS="${SAVE_LDFLAGS}"
1254   ])
1255   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1256   ;;
1257 esac
1258
1259
1260 dnl For certain native configurations, we need to check whether thread
1261 dnl support can be built in or not.
1262 dnl
1263 dnl Note that we only want this if we are both native (host == target),
1264 dnl and not doing a canadian cross build (build == host).
1265
1266 if test ${build} = ${host} -a ${host} = ${target} ; then
1267    case ${host_os} in
1268    hpux*)
1269       AC_MSG_CHECKING(for HPUX/OSF thread support)
1270       if test -f /usr/include/dce/cma_config.h ; then
1271          if test "$GCC" = "yes" ; then
1272             AC_MSG_RESULT(yes)
1273             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1274             [Define if you have HPUX threads])
1275             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1276             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1277          else
1278             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1279          fi
1280       else
1281          AC_MSG_RESULT(no)
1282       fi
1283       ;;
1284    solaris*)
1285       # See if thread_db library is around for Solaris thread debugging.
1286       # Note that we must explicitly test for version 1 of the library
1287       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1288       # the same API.
1289       AC_MSG_CHECKING(for Solaris thread debugging library)
1290       if test -f /usr/lib/libthread_db.so.1 ; then
1291          AC_MSG_RESULT(yes)
1292          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1293          [Define if using Solaris thread debugging.])
1294          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1295          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1296          AC_CHECK_LIB(dl, dlopen)
1297          if test "$GCC" = "yes" ; then
1298             # The GNU linker requires the -export-dynamic option to make
1299             # all symbols visible in the dynamic symbol table.
1300             hold_ldflags=$LDFLAGS
1301             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1302             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1303             AC_TRY_LINK(, [int i;], found=yes, found=no)
1304             LDFLAGS=$hold_ldflags
1305             AC_MSG_RESULT($found)
1306             if test $found = yes; then
1307                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1308             fi
1309          fi
1310          # Sun randomly tweaked the prototypes in <proc_service.h>
1311          # at one point.
1312          AC_MSG_CHECKING(if <proc_service.h> is old)
1313          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1314             AC_TRY_COMPILE([
1315                 #include <proc_service.h>
1316                 ps_err_e ps_pdwrite
1317                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1318             ],, gdb_cv_proc_service_is_old=no,
1319                 gdb_cv_proc_service_is_old=yes)
1320          ])
1321          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1322          if test $gdb_cv_proc_service_is_old = yes; then
1323             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1324             [Define if <proc_service.h> on solaris uses int instead of
1325              size_t, and assorted other type changes.])
1326          fi
1327       else
1328          AC_MSG_RESULT(no)
1329       fi
1330       ;;
1331    aix*)
1332       AC_MSG_CHECKING(for AiX thread debugging library)
1333       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1334                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1335                                    [#ifndef PTHDB_VERSION_3
1336                                     #error
1337                                     #endif],
1338                                    gdb_cv_have_aix_thread_debug=yes,
1339                                    gdb_cv_have_aix_thread_debug=no)])
1340       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1341       if test $gdb_cv_have_aix_thread_debug = yes; then
1342          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1343          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1344          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1345       fi
1346       ;;
1347    esac
1348    AC_SUBST(CONFIG_LDFLAGS)
1349 fi
1350
1351 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1352 dnl other error codes.
1353 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1354    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1355                   gdb_cv_thread_db_h_has_td_notalloc,
1356      AC_TRY_COMPILE(
1357        [#include <thread_db.h>],
1358        [int i = TD_NOTALLOC;],
1359        gdb_cv_thread_db_h_has_td_notalloc=yes,
1360        gdb_cv_thread_db_h_has_td_notalloc=no
1361      )
1362    )
1363    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1364                   gdb_cv_thread_db_h_has_td_version,
1365      AC_TRY_COMPILE(
1366        [#include <thread_db.h>],
1367        [int i = TD_VERSION;],
1368        gdb_cv_thread_db_h_has_td_version=yes,
1369        gdb_cv_thread_db_h_has_td_version=no
1370      )
1371    )
1372    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1373                   gdb_cv_thread_db_h_has_td_notls,
1374      AC_TRY_COMPILE(
1375        [#include <thread_db.h>],
1376        [int i = TD_NOTLS;],
1377        gdb_cv_thread_db_h_has_td_notls=yes,
1378        gdb_cv_thread_db_h_has_td_notls=no
1379      )
1380    )
1381 fi
1382 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1383   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1384             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1385 fi
1386 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1387   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1388             [Define if <thread_db.h> has the TD_VERSION error code.])
1389 fi
1390 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1391   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1392             [Define if <thread_db.h> has the TD_NOTLS error code.])
1393 fi
1394
1395 dnl See if we have a sys/syscall header file that has __NR_tkill.
1396 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1397    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1398                   gdb_cv_sys_syscall_h_has_tkill,
1399      AC_TRY_COMPILE(
1400        [#include <sys/syscall.h>],
1401        [int i = __NR_tkill;],
1402        gdb_cv_sys_syscall_h_has_tkill=yes,
1403        gdb_cv_sys_syscall_h_has_tkill=no
1404      )
1405    )
1406 fi
1407 dnl See if we can issue tkill syscall.
1408 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1409   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1410 fi
1411
1412 dnl Check if we can disable the virtual address space randomization.
1413 dnl The functionality of setarch -R.
1414 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1415 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1416 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1417 #       define ADDR_NO_RANDOMIZE 0x0040000
1418 #      endif
1419        /* Test the flag could be set and stays set.  */
1420        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1421        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1422            return 1])])
1423 AC_RUN_IFELSE([PERSONALITY_TEST],
1424               [have_personality=true],
1425               [have_personality=false],
1426               [AC_LINK_IFELSE([PERSONALITY_TEST],
1427                               [have_personality=true],
1428                               [have_personality=false])])
1429 if $have_personality
1430 then
1431     AC_DEFINE([HAVE_PERSONALITY], 1,
1432               [Define if you support the personality syscall.])
1433 fi
1434
1435 dnl Handle optional features that can be enabled.
1436
1437 AC_ARG_WITH(sysroot,
1438 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1439 [
1440  case ${with_sysroot} in
1441  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1442  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1443  esac
1444
1445  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1446
1447  if test "x$prefix" = xNONE; then
1448   test_prefix=/usr/local
1449  else
1450   test_prefix=$prefix
1451  fi
1452  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1453   test_exec_prefix=$test_prefix
1454  else
1455   test_exec_prefix=$exec_prefix
1456  fi
1457  case ${TARGET_SYSTEM_ROOT} in
1458  "${test_prefix}"|"${test_prefix}/"*|\
1459  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1460  '${prefix}'|'${prefix}/'*|\
1461  '${exec_prefix}'|'${exec_prefix}/'*)
1462    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1463    TARGET_SYSTEM_ROOT_DEFINE="$t"
1464    ;;
1465  esac
1466 ], [
1467  TARGET_SYSTEM_ROOT=
1468  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1469 ])
1470 AC_SUBST(TARGET_SYSTEM_ROOT)
1471 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1472
1473 AC_ARG_ENABLE(werror,
1474   [  --enable-werror    treat compile warnings as errors],
1475   [case "${enableval}" in
1476      yes | y) ERROR_ON_WARNING="yes" ;;
1477      no | n)  ERROR_ON_WARNING="no" ;;
1478      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1479    esac])
1480
1481 # Enable -Werror by default when using gcc
1482 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1483     ERROR_ON_WARNING=yes
1484 fi
1485
1486 WERROR_CFLAGS=""
1487 if test "${ERROR_ON_WARNING}" = yes ; then
1488     WERROR_CFLAGS="-Werror"
1489 fi
1490
1491 # The entries after -Wno-pointer-sign are disabled warnings which may
1492 # be enabled in the future, which can not currently be used to build
1493 # GDB.
1494 # NOTE: If you change this list, remember to update
1495 # gdb/doc/gdbint.texinfo.
1496 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1497 -Wformat-nonliteral -Wno-pointer-sign \
1498 -Wno-unused -Wno-switch -Wno-char-subscripts"
1499
1500 # Enable -Wno-format by default when using gcc on mingw since many
1501 # GCC versions complain about %I64.
1502 case "${host}" in
1503   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1504 esac
1505
1506 AC_ARG_ENABLE(build-warnings,
1507 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1508 [case "${enableval}" in
1509   yes)  ;;
1510   no)   build_warnings="-w";;
1511   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1512         build_warnings="${build_warnings} ${t}";;
1513   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1514         build_warnings="${t} ${build_warnings}";;
1515   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1516 esac
1517 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1518   echo "Setting compiler warning flags = $build_warnings" 6>&1
1519 fi])dnl
1520 AC_ARG_ENABLE(gdb-build-warnings,
1521 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1522 [case "${enableval}" in
1523   yes)  ;;
1524   no)   build_warnings="-w";;
1525   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1526         build_warnings="${build_warnings} ${t}";;
1527   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1528         build_warnings="${t} ${build_warnings}";;
1529   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1530 esac
1531 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1532   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1533 fi])dnl
1534 WARN_CFLAGS=""
1535 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1536 then
1537     AC_MSG_CHECKING(compiler warning flags)
1538     # Separate out the -Werror flag as some files just cannot be
1539     # compiled with it enabled.
1540     for w in ${build_warnings}; do
1541         case $w in
1542         -Werr*) WERROR_CFLAGS=-Werror ;;
1543         *) # Check that GCC accepts it
1544             saved_CFLAGS="$CFLAGS"
1545             CFLAGS="$CFLAGS $w"
1546             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1547             CFLAGS="$saved_CFLAGS"
1548         esac
1549     done
1550     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1551 fi
1552 AC_SUBST(WARN_CFLAGS)
1553 AC_SUBST(WERROR_CFLAGS)
1554
1555 # In the Cygwin environment, we need some additional flags.
1556 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1557 [AC_EGREP_CPP(lose, [
1558 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1559 lose
1560 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1561
1562
1563 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1564 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1565 case ${host} in
1566   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1567   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1568   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1569 esac
1570 AC_SUBST(SER_HARDWIRE)
1571
1572 # libreadline needs libuser32.a in a cygwin environment
1573 WIN32LIBS=
1574 if test x$gdb_cv_os_cygwin = xyes; then
1575     WIN32LIBS="-luser32"
1576     case "${target}" in
1577         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1578         ;;
1579     esac
1580 fi
1581
1582 # The ser-tcp.c module requires sockets.
1583 case ${host} in
1584   *mingw32*)
1585     AC_DEFINE(USE_WIN32API, 1,
1586               [Define if we should use the Windows API, instead of the
1587                POSIX API.  On Windows, we use the Windows API when
1588                building for MinGW, but the POSIX API when building
1589                for Cygwin.])
1590     WIN32LIBS="$WIN32LIBS -lws2_32"
1591     ;;
1592 esac
1593 AC_SUBST(WIN32LIBS)
1594
1595 # Add ELF support to GDB, but only if BFD includes ELF support.
1596 OLD_CFLAGS=$CFLAGS
1597 OLD_LDFLAGS=$LDFLAGS
1598 OLD_LIBS=$LIBS
1599 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1600 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1601 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1602 LIBS="-lbfd -liberty $intl $LIBS"
1603 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1604 [AC_TRY_LINK(
1605 [#include <stdlib.h>
1606 #include "bfd.h"
1607 #include "elf-bfd.h"
1608 ],
1609 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1610 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1611 if test $gdb_cv_var_elf = yes; then
1612   CONFIG_OBS="$CONFIG_OBS elfread.o"
1613   AC_DEFINE(HAVE_ELF, 1,
1614             [Define if ELF support should be included.])
1615 fi
1616 CFLAGS=$OLD_CFLAGS
1617 LDFLAGS=$OLD_LDFLAGS
1618 LIBS=$OLD_LIBS
1619
1620 # Add any host-specific objects to GDB.
1621 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1622
1623 LIBGUI="../libgui/src/libgui.a"
1624 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1625 AC_SUBST(LIBGUI)
1626 AC_SUBST(GUI_CFLAGS_X)
1627
1628 WIN32LDAPP=
1629 AC_SUBST(WIN32LIBS)
1630 AC_SUBST(WIN32LDAPP)
1631
1632 case "${host}" in
1633 *-*-cygwin* | *-*-mingw* )
1634     configdir="win"
1635     ;;
1636 *)
1637     configdir="unix"
1638     ;;
1639 esac
1640
1641 GDBTKLIBS=
1642 if test "${enable_gdbtk}" = "yes"; then
1643
1644     # Gdbtk must have an absolute path to srcdir in order to run
1645     # properly when not installed.
1646     here=`pwd`
1647     cd ${srcdir}
1648     GDBTK_SRC_DIR=`pwd`
1649     cd $here
1650
1651     SC_PATH_TCLCONFIG
1652     if test -z "${no_tcl}"; then
1653         SC_LOAD_TCLCONFIG
1654
1655         # Check for in-tree tcl
1656         here=`pwd`
1657         cd ${srcdir}/..
1658         topdir=`pwd`
1659         cd ${here}
1660
1661         intree="no"
1662         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1663           intree="yes"
1664         fi
1665
1666         # Find Tcl private headers
1667         if test x"${intree}" = xno; then
1668           CY_AC_TCL_PRIVATE_HEADERS
1669           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1670           TCL_LIBRARY="${TCL_LIB_SPEC}"
1671           TCL_DEPS=""
1672         else
1673           # If building tcl in the same src tree, private headers
1674           # are not needed, but we need to be sure to use the right
1675           # headers library
1676           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1677           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1678           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1679         fi
1680         AC_SUBST(TCL_INCLUDE)
1681         AC_SUBST(TCL_LIBRARY)
1682         AC_SUBST(TCL_DEPS)
1683
1684         # If $no_tk is nonempty, then we can't do Tk, and there is no
1685         # point to doing Tcl.
1686         if test -z "${no_tk}"; then
1687            SC_PATH_TKCONFIG
1688            SC_LOAD_TKCONFIG
1689
1690            # Check for in-tree Tk
1691            intree="no"
1692            if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1693              intree="yes"
1694            fi
1695
1696            # Find Tk private headers
1697            if test x"${intree}" = xno; then
1698              CY_AC_TK_PRIVATE_HEADERS
1699              TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1700              TK_LIBRARY=${TK_LIB_SPEC}
1701              TK_DEPS=""
1702            else
1703              TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1704              TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1705              TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1706            fi
1707            AC_SUBST(TK_INCLUDE)
1708            AC_SUBST(TK_LIBRARY)
1709            AC_SUBST(TK_DEPS)
1710            AC_SUBST(TK_XINCLUDES)
1711
1712            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1713
1714            # Include some libraries that Tcl and Tk want.
1715            TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1716            # Yes, the ordering seems wrong here.  But it isn't.
1717            # TK_LIBS is the list of libraries that need to be linked
1718            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1719            # were in LIBS then any link tests after this point would
1720            # try to include things like `$(LIBGUI)', which wouldn't work.
1721            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1722
1723            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1724            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1725            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1726            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1727            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1728            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1729            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1730
1731            if test x$gdb_cv_os_cygwin = xyes; then
1732               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1733               WIN32LDAPP="-Wl,--subsystem,console"
1734               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1735            fi
1736         fi
1737     fi
1738
1739     AC_CONFIG_SUBDIRS(gdbtk)
1740 fi
1741
1742 AC_SUBST(X_CFLAGS)
1743 AC_SUBST(X_LDFLAGS)
1744 AC_SUBST(X_LIBS)
1745 AC_SUBST(GDBTKLIBS)
1746 AC_SUBST(GDBTK_CFLAGS)
1747 AC_SUBST(GDBTK_SRC_DIR)
1748
1749 AC_PATH_X
1750
1751 # Check whether we should enable the TUI, but only do so if we really
1752 # can.
1753 if test x"$enable_tui" != xno; then
1754   if test -d $srcdir/tui; then
1755     if test "$ac_cv_search_waddstr" != no; then
1756       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1757       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1758       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1759       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1760       CONFIG_ALL="${CONFIG_ALL} all-tui"
1761       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1762       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1763       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1764     else
1765       if test x"$enable_tui" = xyes; then
1766         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
1767       else
1768         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1769       fi
1770     fi
1771   fi
1772 fi
1773
1774 # Unlike the sim directory, whether a simulator is linked is controlled by
1775 # presence of a gdb_sim definition in the target configure.tgt entry.
1776 # This code just checks for a few cases where we'd like to ignore those
1777 # definitions, even when they're present in the '.mt' file.  These cases
1778 # are when --disable-sim is specified, or if the simulator directory is
1779 # not part of the source tree.
1780 #
1781 AC_ARG_ENABLE(sim,
1782 [  --enable-sim            Link gdb with simulator],
1783 [echo "enable_sim = $enable_sim";
1784  echo "enableval = ${enableval}";
1785  case "${enableval}" in
1786   yes) ignore_sim=false ;;
1787   no)  ignore_sim=true ;;
1788   *)   ignore_sim=false ;;
1789  esac],
1790 [ignore_sim=false])
1791
1792 if test ! -d "${srcdir}/../sim"; then
1793   ignore_sim=true
1794 fi
1795
1796 SIM=
1797 SIM_OBS=
1798 if test "${ignore_sim}" = "false"; then
1799   if test x"${gdb_sim}" != x ; then
1800     SIM="${gdb_sim}"
1801     SIM_OBS="remote-sim.o"
1802     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1803   fi
1804 fi
1805 AC_SUBST(SIM)
1806 AC_SUBST(SIM_OBS)
1807
1808 AC_SUBST(ENABLE_CFLAGS)
1809 AC_SUBST(PROFILE_CFLAGS)
1810
1811 AC_SUBST(CONFIG_OBS)
1812 AC_SUBST(CONFIG_DEPS)
1813 AC_SUBST(CONFIG_SRCS)
1814 AC_SUBST(CONFIG_ALL)
1815 AC_SUBST(CONFIG_CLEAN)
1816 AC_SUBST(CONFIG_INSTALL)
1817 AC_SUBST(CONFIG_UNINSTALL)
1818
1819 # List of host floatformats.
1820 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1821 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1822 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1823
1824 # target_subdir is used by the testsuite to find the target libraries.
1825 target_subdir=
1826 if test "${host}" != "${target}"; then
1827     target_subdir="${target_alias}/"
1828 fi
1829 AC_SUBST(target_subdir)
1830
1831 frags=
1832 if test "${gdb_native}" = "yes"; then
1833   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1834   if test ! -f ${host_makefile_frag}; then
1835     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1836   fi
1837   frags="$frags $host_makefile_frag"
1838 else
1839   host_makefile_frag=/dev/null
1840 fi
1841
1842 AC_SUBST_FILE(host_makefile_frag)
1843 AC_SUBST(frags)
1844
1845 changequote(,)dnl
1846 if test "${gdb_native}" = "yes"; then
1847 # We pick this up from the host configuration file (.mh) because we
1848 # do not have a native configuration Makefile fragment.
1849 nativefile=`sed -n '
1850 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1851 ' ${host_makefile_frag}`
1852 fi
1853 changequote([,])
1854
1855 if test x"${gdb_osabi}" != x ; then
1856     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1857                        [Define to the default OS ABI for this configuration.])
1858 fi
1859
1860 # Enable multi-ice-gdb-server.
1861 AC_ARG_ENABLE(multi-ice,
1862 [  --enable-multi-ice      build the multi-ice-gdb-server],
1863   [case $enableval in
1864     yes | no)
1865       ;;
1866     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1867   esac])
1868 if test "x$enable_multi_ice" = xyes; then
1869    AC_CONFIG_SUBDIRS(multi-ice)
1870 fi
1871
1872 # We only build gdbserver automatically in a native configuration.
1873 if test "$gdb_native" = "yes"; then
1874   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1875   if test "x$build_gdbserver" = xyes; then
1876     AC_MSG_RESULT(yes)
1877     AC_CONFIG_SUBDIRS(gdbserver)
1878   else
1879     AC_MSG_RESULT(no)
1880   fi
1881 fi
1882
1883 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1884 # to an empty version.
1885
1886 files=
1887 links=
1888
1889 rm -f nm.h
1890 nm_h=""
1891 if test "${nativefile}" != ""; then
1892     nm_h=nm.h
1893     case "${nativefile}" in
1894       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1895       * ) GDB_NM_FILE="${nativefile}"
1896     esac
1897     files="${files} ${GDB_NM_FILE}"
1898     links="${links} nm.h"
1899     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1900 fi
1901 AC_SUBST(nm_h)
1902
1903 AC_LINK_FILES($files, $links)
1904
1905 dnl Check for exe extension set on certain hosts (e.g. Win32)
1906 AC_EXEEXT
1907
1908 dnl  Detect the character set used by this host.
1909
1910 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1911 dnl  superset of ASCII containing the characters needed for French,
1912 dnl  German, Spanish, Italian, and possibly others), but if were
1913 dnl  *were* to support any host character sets other than ISO-8859-1,
1914 dnl  here's where we'd detect it.
1915 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1916           [Define to be a string naming the default host character set.])
1917
1918 AM_ICONV
1919
1920 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1921 [
1922 dnl Autoconf doesn't provide a mechanism for modifying definitions
1923 dnl provided by makefile fragments.
1924 dnl
1925
1926 changequote(,)dnl
1927 sed -e '/^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1928 mv -f Makefile.tmp Makefile
1929 changequote([,])dnl
1930
1931
1932 case x$CONFIG_HEADERS in
1933 xconfig.h:config.in)
1934 echo > stamp-h ;;
1935 esac
1936 ],
1937 [
1938 gdb_host_cpu=$gdb_host_cpu
1939 nativefile=$nativefile
1940 ])
1941
1942 exit 0