gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 2 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor,
  21 dnl Boston, MA 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25 AC_PREREQ(2.59)dnl
  26 AC_INIT(main.c)
  27 AC_CONFIG_HEADER(config.h:config.in)
  28 AM_MAINTAINER_MODE
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_AIX
  33 AC_ISC_POSIX
  34 AM_PROG_CC_STDC
  35
  36 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  37 AC_CANONICAL_SYSTEM
  38
  39 dnl List of object files and targets accumulated by configure.
  40
  41 CONFIG_OBS=
  42 CONFIG_DEPS=
  43 CONFIG_SRCS=
  44 ENABLE_CFLAGS=
  45
  46 CONFIG_ALL=
  47 CONFIG_CLEAN=
  48 CONFIG_INSTALL=
  49 CONFIG_UNINSTALL=
  50
  51 dnl Set up for gettext.
  52 ZW_GNU_GETTEXT_SISTER_DIR
  53
  54 localedir='${datadir}/locale'
  55 AC_SUBST(localedir)
  56
  57 if test x"$USE_NLS" = xyes; then
  58    CONFIG_ALL="$CONFIG_ALL all-po"
  59    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  60    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  61    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  62 fi
  63
  64 PACKAGE=gdb
  65 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  66 AC_SUBST(PACKAGE)
  67
  68 debugdir=${libdir}/debug
  69
  70 AC_ARG_WITH(separate-debug-dir,
  71 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  72 [debugdir="${withval}"])
  73
  74 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  75               [Global directory for separate debug files. ])
  76 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  77
  78 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
  79   if test "x$prefix" = xNONE; then
  80     test_prefix=/usr/local
  81   else
  82     test_prefix=$prefix
  83   fi
  84 else
  85   test_prefix=$exec_prefix
  86 fi
  87 case ${debugdir} in
  88 "${test_prefix}"|"${test_prefix}/"*|\
  89 '${exec_prefix}'|'${exec_prefix}/'*)
  90   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
  91   ;;
  92 esac
  93
  94 AC_CONFIG_SUBDIRS(doc testsuite)
  95
  96 # Provide defaults for some variables set by the per-host and per-target
  97 # configuration.
  98 gdb_host_obs=posix-hdep.o
  99
 100 if test "${target}" = "${host}"; then
 101   gdb_native=yes
 102 else
 103   gdb_native=no
 104 fi
 105
 106 . $srcdir/configure.host
 107
 108 . $srcdir/configure.tgt
 109
 110 # Fetch the default architecture and default target vector from BFD.
 111 targ=$target; . $srcdir/../bfd/config.bfd
 112
 113 # We only want the first architecture, so strip off the others if
 114 # there is more than one.
 115 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 116
 117 if test "x$targ_archs" != x; then
 118   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 119     [Define to BFD's default architecture. ])
 120 fi
 121 if test "x$targ_defvec" != x; then
 122   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 123     [Define to BFD's default target vector. ])
 124 fi
 125
 126 AC_ARG_PROGRAM
 127
 128 # The CLI cannot be disabled yet, but may be in the future.
 129
 130 # Enable CLI.
 131 AC_ARG_ENABLE(gdbcli,
 132 [  --disable-gdbcli        disable command-line interface (CLI)],
 133   [case $enableval in
 134     yes)
 135       ;;
 136     no)
 137       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 138     *)
 139       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 140   esac],
 141   [enable_gdbcli=yes])
 142 if test x"$enable_gdbcli" = xyes; then
 143   if test -d $srcdir/cli; then
 144     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 145     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 146     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 147     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 148   fi
 149 fi
 150
 151 # Enable MI.
 152 AC_ARG_ENABLE(gdbmi,
 153 [  --disable-gdbmi         disable machine-interface (MI)],
 154   [case $enableval in
 155     yes | no)
 156       ;;
 157     *)
 158       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 159   esac],
 160   [enable_gdbmi=yes])
 161 if test x"$enable_gdbmi" = xyes; then
 162   if test -d $srcdir/mi; then
 163     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 164     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 165     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 166     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 167   fi
 168 fi
 169
 170 # Enable TUI.
 171 AC_ARG_ENABLE(tui,
 172 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 173   [case $enableval in
 174     yes | no)
 175       ;;
 176     *)
 177       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 178   esac],enable_tui=yes)
 179
 180 # Enable gdbtk.
 181 AC_ARG_ENABLE(gdbtk,
 182 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 183   [case $enableval in
 184     yes | no)
 185       ;;
 186     *)
 187       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 188   esac],
 189   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 190     enable_gdbtk=yes
 191   else
 192     enable_gdbtk=no
 193   fi])
 194 # We unconditionally disable gdbtk tests on selected platforms.
 195 case $host_os in
 196   go32* | windows*)
 197     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 198     enable_gdbtk=no ;;
 199 esac
 200
 201 # Libunwind support.
 202 AC_ARG_WITH(libunwind,
 203 [  --with-libunwind            Use libunwind frame unwinding support],
 204 [case "${withval}" in
 205   yes)  enable_libunwind=yes ;;
 206   no)   enable_libunwind=no ;;
 207   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 208 esac],[
 209   AC_CHECK_HEADERS(libunwind.h)
 210   AC_CHECK_HEADERS(libunwind-ia64.h)
 211   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 212     enable_libunwind=yes;
 213   fi
 214 ])
 215
 216 if test x"$enable_libunwind" = xyes; then
 217   AC_CHECK_HEADERS(libunwind.h)
 218   AC_CHECK_HEADERS(libunwind-ia64.h)
 219   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 220   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 221   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 222   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 223 fi
 224
 225 # Profiling support.
 226 AC_ARG_ENABLE(profiling,
 227 [  --enable-profiling      enable profiling of GDB],
 228   [case $enableval in
 229     yes | no)
 230       ;;
 231     *)
 232       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 233   esac],
 234  [enable_profiling=no])
 235
 236 AC_CHECK_FUNCS(monstartup _mcleanup)
 237 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 238 [AC_TRY_LINK(
 239 [#include <stdlib.h>
 240 extern char _etext;
 241 ],
 242 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 243 if test $ac_cv_var__etext = yes; then
 244   AC_DEFINE(HAVE__ETEXT, 1,
 245             [Define to 1 if your system has the _etext variable. ])
 246 fi
 247 if test "$enable_profiling" = yes ; then
 248   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 249     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 250   fi
 251   PROFILE_CFLAGS=-pg
 252   OLD_CFLAGS="$CFLAGS"
 253   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 254
 255   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 256     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 257      ac_cv_cc_supports_pg=no)])
 258
 259   if test $ac_cv_cc_supports_pg = no; then
 260     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 261   fi
 262
 263   CFLAGS="$OLD_CFLAGS"
 264 fi
 265
 266 # --------------------- #
 267 # Checks for programs.  #
 268 # --------------------- #
 269
 270 AC_PROG_AWK
 271 AC_PROG_INSTALL
 272 AC_PROG_LN_S
 273 AC_PROG_RANLIB
 274 AC_PROG_YACC
 275
 276 AC_CHECK_TOOL(AR, ar)
 277 AC_CHECK_TOOL(DLLTOOL, dlltool)
 278 AC_CHECK_TOOL(WINDRES, windres)
 279
 280 # Needed for GNU/Hurd.
 281 AC_CHECK_TOOL(MIG, mig)
 282
 283 # ---------------------- #
 284 # Checks for libraries.  #
 285 # ---------------------- #
 286
 287 # We might need to link with -lm; most simulators need it.
 288 AC_CHECK_LIB(m, main)
 289
 290 # We need to link with -lw to get `wctype' on Solaris before Solaris
 291 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 292 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 293 # is known to have this problem).  Therefore we avoid libw if we can.
 294 AC_CHECK_FUNC(wctype, [],
 295   [AC_CHECK_LIB(w, wctype)])
 296
 297 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 298 AC_SEARCH_LIBS(gethostbyname, nsl)
 299
 300 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 301 AC_SEARCH_LIBS(socketpair, socket)
 302
 303 # For the TUI, we need enhanced curses functionality.
 304 #
 305 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 306 # curses library because the latter might not provide all the
 307 # functionality we need.  However, this leads to problems on systems
 308 # where the linker searches /usr/local/lib, but the compiler doesn't
 309 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 310 # default installation of ncurses on alpha*-dec-osf* will lead to such
 311 # a situation.
 312 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 313
 314 # Since GDB uses Readline, we need termcap functionality.  In many
 315 # cases this will be provided by the curses library, but some systems
 316 # have a seperate termcap library, or no curses library at all.
 317
 318 case $host_os in
 319   cygwin*)
 320     if test -d $srcdir/libtermcap; then
 321       LIBS="../libtermcap/libtermcap.a $LIBS"
 322       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 323     fi ;;
 324   go32* | *djgpp*)
 325     ac_cv_search_tgetent="none required"
 326     ;;
 327   *mingw32*)
 328     ac_cv_search_tgetent="none required"
 329     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 330     ;;
 331 esac
 332
 333 # These are the libraries checked by Readline.
 334 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 335
 336 if test "$ac_cv_search_tgetent" = no; then
 337   AC_MSG_ERROR([no termcap library found])
 338 fi
 339
 340 AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 341                       [XML_Parser p = XML_ParserCreate (0);])
 342 if test "$HAVE_LIBEXPAT" != yes; then
 343   AC_MSG_WARN([expat is missing or unusable; some features may be disabled.])
 344 else
 345   save_LIBS=$LIBS
 346   LIBS="$LIBS $LIBEXPAT"
 347   AC_CHECK_FUNCS(XML_StopParser)
 348   LIBS=$save_LIBS
 349 fi
 350
 351 # ------------------------- #
 352 # Checks for header files.  #
 353 # ------------------------- #
 354
 355 AC_HEADER_DIRENT
 356 AC_HEADER_STAT
 357 AC_HEADER_STDC
 358 AC_CHECK_HEADERS(nlist.h)
 359 AC_CHECK_HEADERS(link.h, [], [],
 360 [#if HAVE_SYS_TYPES_H
 361 # include <sys/types.h>
 362 #endif
 363 #if HAVE_NLIST_H
 364 # include <nlist.h>
 365 #endif
 366 ])
 367 AC_CHECK_HEADERS(machine/reg.h)
 368 AC_CHECK_HEADERS(poll.h sys/poll.h)
 369 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 370 AC_CHECK_HEADERS(signal.h)
 371 AC_CHECK_HEADERS(stddef.h)
 372 AC_CHECK_HEADERS(stdlib.h)
 373 AC_CHECK_HEADERS(stdint.h)
 374 AC_CHECK_HEADERS(string.h memory.h strings.h)
 375 AC_CHECK_HEADERS(sys/fault.h)
 376 AC_CHECK_HEADERS(sys/file.h)
 377 AC_CHECK_HEADERS(sys/filio.h)
 378 AC_CHECK_HEADERS(sys/ioctl.h)
 379 AC_CHECK_HEADERS(sys/param.h)
 380 AC_CHECK_HEADERS(sys/resource.h)
 381 AC_CHECK_HEADERS(sys/proc.h, [], [],
 382 [#if HAVE_SYS_PARAM_H
 383 # include <sys/param.h>
 384 #endif
 385 ])
 386 AC_CHECK_HEADERS(sys/procfs.h)
 387 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 388 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 389 AC_CHECK_HEADERS(sys/select.h)
 390 AC_CHECK_HEADERS(sys/syscall.h)
 391 AC_CHECK_HEADERS(sys/types.h)
 392 AC_CHECK_HEADERS(sys/user.h, [], [],
 393 [#if HAVE_SYS_PARAM_H
 394 # include <sys/param.h>
 395 #endif
 396 ])
 397 AC_CHECK_HEADERS(sys/wait.h wait.h)
 398 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 399 AC_CHECK_HEADERS(unistd.h)
 400
 401 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 402 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 403 # think that we don't have <curses.h> if we're using GCC.
 404 case $host_os in
 405   solaris2.[[789]])
 406     if test "$GCC" = yes; then
 407       AC_DEFINE(_MSE_INT_H, 1,
 408         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 409    Solaris 2.[789] when using GCC. ])
 410     fi ;;
 411 esac
 412 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 413 AC_CHECK_HEADERS(ncurses/term.h)
 414 AC_CHECK_HEADERS(term.h, [], [],
 415 [#if HAVE_CURSES_H
 416 # include <curses.h>
 417 #endif
 418 ])
 419
 420 # FIXME: kettenis/20030102: In most cases we include these
 421 # unconditionally, so what's the point in checking these?
 422 AC_CHECK_HEADERS(ctype.h time.h)
 423
 424 # Create a header we can use portably to get the standard integer types.
 425 GCC_HEADER_STDINT(gdb_stdint.h)
 426
 427 # ------------------------- #
 428 # Checks for declarations.  #
 429 # ------------------------- #
 430
 431 AC_CHECK_DECLS([free, malloc, realloc])
 432 AC_CHECK_DECLS([strerror, strstr])
 433 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 434
 435 # ----------------------- #
 436 # Checks for structures.  #
 437 # ----------------------- #
 438
 439 AC_CHECK_MEMBERS([struct stat.st_blocks])
 440 AC_CHECK_MEMBERS([struct stat.st_blksize])
 441
 442 # ------------------ #
 443 # Checks for types.  #
 444 # ------------------ #
 445
 446 AC_TYPE_SIGNAL
 447 AC_CHECK_TYPES(socklen_t, [], [],
 448 [#include <sys/types.h>
 449 #include <sys/socket.h>
 450 ])
 451 AC_CHECK_TYPES(uintptr_t, [], [], [#include <stdint.h>])
 452
 453 # ------------------------------------- #
 454 # Checks for compiler characteristics.  #
 455 # ------------------------------------- #
 456
 457 AC_C_CONST
 458 AC_C_INLINE
 459
 460 # ------------------------------ #
 461 # Checks for library functions.  #
 462 # ------------------------------ #
 463
 464 AC_FUNC_ALLOCA
 465 AC_FUNC_MMAP
 466 AC_FUNC_VFORK
 467 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 468 AC_CHECK_FUNCS(getrusage)
 469 AC_CHECK_FUNCS(getuid getgid)
 470 AC_CHECK_FUNCS(poll)
 471 AC_CHECK_FUNCS(pread64)
 472 AC_CHECK_FUNCS(sbrk)
 473 AC_CHECK_FUNCS(setpgid setpgrp)
 474 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 475 AC_CHECK_FUNCS(socketpair)
 476 AC_CHECK_FUNCS(syscall)
 477 AC_CHECK_FUNCS(ttrace)
 478 AC_CHECK_FUNCS(wborder)
 479
 480 # Check the return and argument types of ptrace.  No canned test for
 481 # this, so roll our own.
 482 gdb_ptrace_headers='
 483 #if HAVE_SYS_TYPES_H
 484 # include <sys/types.h>
 485 #endif
 486 #if HAVE_SYS_PTRACE_H
 487 # include <sys/ptrace.h>
 488 #endif
 489 #if HAVE_UNISTD_H
 490 # include <unistd.h>
 491 #endif
 492 '
 493 # There is no point in checking if we don't have a prototype.
 494 AC_CHECK_DECLS(ptrace, [], [
 495   : ${gdb_cv_func_ptrace_ret='int'}
 496   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 497 ], $gdb_ptrace_headers)
 498 # Check return type.
 499 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 500   AC_TRY_COMPILE($gdb_ptrace_headers,
 501     [extern int ptrace ();],
 502     gdb_cv_func_ptrace_ret='int',
 503     gdb_cv_func_ptrace_ret='long'))
 504 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 505   [Define as the return type of ptrace.])
 506 # Check argument types.
 507 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 508 for gdb_arg1 in 'int' 'long'; do
 509  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 510   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 511    for gdb_arg4 in 'int' 'long'; do
 512      AC_TRY_COMPILE($gdb_ptrace_headers, [
 513 extern $gdb_cv_func_ptrace_ret
 514   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 515 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 516     break 4;])
 517     for gdb_arg5 in 'int *' 'int' 'long'; do
 518      AC_TRY_COMPILE($gdb_ptrace_headers, [
 519 extern $gdb_cv_func_ptrace_ret
 520   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 521 ], [
 522 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 523     break 5;])
 524     done
 525    done
 526   done
 527  done
 528 done
 529 # Provide a safe default value.
 530 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 531 ])
 532 ac_save_IFS=$IFS; IFS=','
 533 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 534 IFS=$ac_save_IFS
 535 shift
 536 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 537   [Define to the type of arg 3 for ptrace.])
 538 if test -n "$[5]"; then
 539   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 540     [Define to the type of arg 5 for ptrace.])
 541 fi
 542
 543 dnl AC_FUNC_SETPGRP does not work when cross compiling
 544 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 545 if test "$cross_compiling" = no; then
 546   AC_FUNC_SETPGRP
 547 else
 548   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 549     [AC_TRY_COMPILE([
 550 #include <unistd.h>
 551 ], [
 552   if (setpgrp(1,1) == -1)
 553     exit (0);
 554   else
 555     exit (1);
 556 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 557 if test $ac_cv_func_setpgrp_void = yes; then
 558   AC_DEFINE(SETPGRP_VOID, 1)
 559 fi
 560 fi
 561
 562 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 563 # since sigsetjmp might only be defined as a macro.
 564 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 565 [AC_TRY_COMPILE([
 566 #include <setjmp.h>
 567 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 568 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 569 if test $gdb_cv_func_sigsetjmp = yes; then
 570   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 571 fi
 572
 573 # Assume we'll default to using the included libiberty regex.
 574 gdb_use_included_regex=yes
 575
 576 # However, if the system regex is GNU regex, then default to *not*
 577 # using the included regex.
 578 AC_CACHE_CHECK(
 579   [for GNU regex],
 580   [gdb_cv_have_gnu_regex],
 581   [AC_TRY_COMPILE(
 582     [#include <gnu-versions.h>],
 583     [#define REGEX_INTERFACE_VERSION 1
 584 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 585 # error "Version mismatch"
 586 #endif],
 587     gdb_cv_have_gnu_regex=yes,
 588     gdb_cv_have_gnu_regex=no)])
 589 if test $gdb_cv_have_gnu_regex = yes; then
 590   gdb_use_included_regex=no
 591 fi
 592
 593 AC_ARG_WITH(included-regex,
 594   [  --without-included-regex don't use included regex; this is the default
 595                           on systems with version 2 of the GNU C library
 596                           (use with caution on other system)],
 597   gdb_with_regex=$withval,
 598   gdb_with_regex=$gdb_use_included_regex)
 599 if test "$gdb_with_regex" = yes; then
 600   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 601     [Define to 1 if the regex included in libiberty should be used.])
 602 fi
 603
 604 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 605 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 606 [#include <sys/param.h>
 607 #include <sys/proc.h>
 608 ])
 609
 610 # See if <sys/lwp.h> defines `struct lwp`.
 611 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 612 [AC_TRY_COMPILE([#include <sys/param.h>
 613 #include <sys/lwp.h>], [struct lwp l;],
 614 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 615 if test $gdb_cv_struct_lwp = yes; then
 616   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 617             [Define to 1 if your system has struct lwp.])
 618 fi
 619
 620 # See if <machine/reg.h> degines `struct reg'.
 621 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 622 [AC_TRY_COMPILE([#include <sys/types.h>
 623 #include <machine/reg.h>], [struct reg r;],
 624 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 625 if test $gdb_cv_struct_reg = yes; then
 626   AC_DEFINE(HAVE_STRUCT_REG, 1,
 627             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 628 fi
 629
 630 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 631 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 632 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 633                  [#include <machine/reg.h>])
 634
 635 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 636 AC_MSG_CHECKING(for PTRACE_GETREGS)
 637 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 638 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 639                 [PTRACE_GETREGS;],
 640                 [gdb_cv_have_ptrace_getregs=yes],
 641                 [gdb_cv_have_ptrace_getregs=no])])
 642 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 643 if test $gdb_cv_have_ptrace_getregs = yes; then
 644   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 645   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 646 fi
 647
 648 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 649 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 650 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 651 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 652                 [PTRACE_GETFPXREGS;],
 653                 [gdb_cv_have_ptrace_getfpxregs=yes],
 654                 [gdb_cv_have_ptrace_getfpxregs=no])])
 655 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 656 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 657   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 658   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 659 fi
 660
 661 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 662 AC_MSG_CHECKING(for PT_GETDBREGS)
 663 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 664 [AC_TRY_COMPILE([#include <sys/types.h>
 665 #include <sys/ptrace.h>],
 666                 [PT_GETDBREGS;],
 667                 [gdb_cv_have_pt_getdbregs=yes],
 668                 [gdb_cv_have_pt_getdbregs=no])])
 669 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 670 if test $gdb_cv_have_pt_getdbregs = yes; then
 671   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 672   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 673 fi
 674
 675 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 676 AC_MSG_CHECKING(for PT_GETXMMREGS)
 677 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 678 [AC_TRY_COMPILE([#include <sys/types.h>
 679 #include <sys/ptrace.h>],
 680                 [PT_GETXMMREGS;],
 681                 [gdb_cv_have_pt_getxmmregs=yes],
 682                 [gdb_cv_have_pt_getxmmregs=no])])
 683 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 684 if test $gdb_cv_have_pt_getxmmregs = yes; then
 685   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 686   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 687 fi
 688
 689 # If we are configured native on GNU/Linux, work around problems with
 690 # sys/procfs.h
 691 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 692
 693 if test "${target}" = "${host}"; then
 694   case "${host}" in
 695   i[[3456]]86-*-linux*)
 696         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED, 2,
 697         [Define on a GNU/Linux system to work around problems in sys/procfs.h.])
 698         AC_DEFINE(sys_quotactl, 1,
 699         [Define on a GNU/Linux system to work around problems in sys/procfs.h.])
 700         ;;
 701   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 702       AC_DEFINE(NEW_PROC_API, 1,
 703       [Define if you want to use new multi-fd /proc interface
 704        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 705       ;;
 706   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 707       AC_DEFINE(NEW_PROC_API, 1,
 708       [Define if you want to use new multi-fd /proc interface
 709        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 710       ;;
 711   mips-sgi-irix5*)
 712       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 713       AC_DEFINE([_KMEMUSER], 1,
 714       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 715        around a <sys/proc.h> problem on IRIX 5.])
 716       ;;
 717   esac
 718 fi
 719
 720 if test "$ac_cv_header_sys_procfs_h" = yes; then
 721   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 722   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 723   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 724   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 725   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 726   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 727   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 728   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 729   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 730   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 731   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 732   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 733   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 734   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 735
 736
 737   dnl Check for broken prfpregset_t type
 738
 739   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 740   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 741   dnl instead of the struct itself).  We detect this here, and work
 742   dnl around it in gdb_proc_service.h.
 743
 744   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 745     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 746     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 747       [AC_TRY_RUN([#include <sys/procfs.h>
 748        int main ()
 749        {
 750          if (sizeof (prfpregset_t) == sizeof (void *))
 751            return 1;
 752          return 0;
 753        }],
 754        gdb_cv_prfpregset_t_broken=no,
 755        gdb_cv_prfpregset_t_broken=yes,
 756        gdb_cv_prfpregset_t_broken=yes)])
 757     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 758     if test $gdb_cv_prfpregset_t_broken = yes; then
 759       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
 760       [Define if the prfpregset_t type is broken.])
 761     fi
 762   fi
 763
 764   dnl Check for PIOCSET ioctl entry
 765
 766   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 767   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 768   [AC_TRY_COMPILE([#include <unistd.h>
 769 #include <sys/types.h>
 770 #include <sys/procfs.h>
 771 ], [
 772     int dummy;;
 773     dummy = ioctl(0, PIOCSET, &dummy);
 774   ],
 775   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 776   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 777   if test $gdb_cv_have_procfs_piocset = yes; then
 778     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
 779     [Define if ioctl argument PIOCSET is available.])
 780   fi
 781 fi
 782
 783 dnl For native ports (host == target), check to see what kind of
 784 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 785 if test ${host} = ${target} ; then
 786   dnl Check for struct link_map with l_ members which are indicative
 787   dnl of SVR4-like shared libraries
 788
 789   AC_MSG_CHECKING(for member l_addr in struct link_map)
 790   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 791     [AC_TRY_COMPILE([#include <link.h>],
 792                     [struct link_map lm; (void) lm.l_addr;],
 793                     gdb_cv_have_struct_link_map_with_l_members=yes,
 794                     gdb_cv_have_struct_link_map_with_l_members=no)])
 795   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 796   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 797     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
 798     [Define if <link.h> exists and defines struct link_map which has
 799      members with an ``l_'' prefix.  (For Solaris, SVR4, and
 800      SVR4-like systems.)])
 801   fi
 802
 803   dnl Check for struct link_map with lm_ members which are indicative
 804   dnl of SunOS-like shared libraries
 805
 806   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 807   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 808     [AC_TRY_COMPILE([#include <sys/types.h>
 809 #include <link.h>],
 810                     [struct link_map lm; (void) lm.lm_addr;],
 811                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 812                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 813   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 814   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 815     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
 816     [Define if <link.h> exists and defines struct link_map which has
 817      members with an ``lm_'' prefix.  (For SunOS.)])
 818   fi
 819
 820   dnl Check for struct so_map with som_ members which are found on
 821   dnl some *BSD systems.
 822
 823   AC_MSG_CHECKING(for member som_addr in struct so_map)
 824   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 825     [AC_TRY_COMPILE([#include <sys/types.h>
 826 #ifdef HAVE_NLIST_H
 827 #include <nlist.h>
 828 #endif
 829 #include <link.h>],
 830                     [struct so_map lm; (void) lm.som_addr;],
 831                     gdb_cv_have_struct_so_map_with_som_members=yes,
 832                     gdb_cv_have_struct_so_map_with_som_members=no)])
 833   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 834   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 835     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
 836     [Define if <link.h> exists and defines a struct so_map which has
 837      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
 838   fi
 839
 840   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 841   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 842
 843   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 844   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 845     [AC_TRY_COMPILE([#define _SYSCALL32
 846 #include <sys/link.h>], [struct link_map32 l;],
 847      gdb_cv_have_struct_link_map32=yes,
 848      gdb_cv_have_struct_link_map32=no)])
 849   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 850   if test $gdb_cv_have_struct_link_map32 = yes; then
 851     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
 852     [Define if <sys/link.h> has struct link_map32])
 853     AC_DEFINE(_SYSCALL32, 1,
 854     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
 855   fi
 856 fi
 857
 858 # Check if the compiler supports the `long long' type.
 859
 860 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 861                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 862 [[extern long long foo;]],
 863 [[switch (foo & 2) { case 0: return 1; }]])],
 864                                   gdb_cv_c_long_long=yes,
 865                                   gdb_cv_c_long_long=no)])
 866 if test $gdb_cv_c_long_long = yes; then
 867   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 868             [Define to 1 if the compiler supports long long.])
 869 fi
 870
 871 # Check if the compiler and runtime support printing long longs.
 872
 873 AC_CACHE_CHECK([for long long support in printf],
 874                gdb_cv_printf_has_long_long,
 875                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 876 [[char buf[32];
 877   long long l = 0;
 878   l = (l << 16) + 0x0123;
 879   l = (l << 16) + 0x4567;
 880   l = (l << 16) + 0x89ab;
 881   l = (l << 16) + 0xcdef;
 882   sprintf (buf, "0x%016llx", l);
 883   return (strcmp ("0x0123456789abcdef", buf));]])],
 884                               gdb_cv_printf_has_long_long=yes,
 885                               gdb_cv_printf_has_long_long=no,
 886                               gdb_cv_printf_has_long_long=no)])
 887 if test $gdb_cv_printf_has_long_long = yes; then
 888   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 889             [Define to 1 if the "%ll" format works to print long longs.])
 890 fi
 891
 892 # Check if the compiler supports the `long double' type.  We can't use
 893 # AC_C_LONG_DOUBLE because that one does additional checks on the
 894 # constants defined in <float.h> that fail on some systems,
 895 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 896
 897 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 898                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 899                                   gdb_cv_c_long_double=yes,
 900                                   gdb_cv_c_long_double=no)])
 901 if test $gdb_cv_c_long_double = yes; then
 902   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 903            [Define to 1 if the compiler supports long double.])
 904 fi
 905
 906 # Check if the compiler and runtime support printing long doubles.
 907
 908 AC_CACHE_CHECK([for long double support in printf],
 909                gdb_cv_printf_has_long_double,
 910                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 911 [[char buf[16];
 912   long double f = 3.141592653;
 913   sprintf (buf, "%Lg", f);
 914   return (strncmp ("3.14159", buf, 7));]])],
 915                               gdb_cv_printf_has_long_double=yes,
 916                               gdb_cv_printf_has_long_double=no,
 917                               gdb_cv_printf_has_long_double=no)])
 918 if test $gdb_cv_printf_has_long_double = yes; then
 919   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 920             [Define to 1 if the "%Lg" format works to print long doubles.])
 921 fi
 922
 923 # Check if the compiler and runtime support scanning long doubles.
 924
 925 AC_CACHE_CHECK([for long double support in scanf],
 926                gdb_cv_scanf_has_long_double,
 927                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 928 [[#include <stdio.h>]],
 929 [[char *buf = "3.141592653";
 930   long double f = 0;
 931   sscanf (buf, "%Lg", &f);
 932   return !(f > 3.14159 && f < 3.14160);]])],
 933                               gdb_cv_scanf_has_long_double=yes,
 934                               gdb_cv_scanf_has_long_double=no,
 935                               gdb_cv_scanf_has_long_double=no)])
 936 if test $gdb_cv_scanf_has_long_double = yes; then
 937   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 938             [Define to 1 if the "%Lg" format works to scan long doubles.])
 939 fi
 940
 941 case ${host_os} in
 942 aix*)
 943   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 944     SAVE_LDFLAGS=$LDFLAGS
 945
 946     case $GCC in
 947     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 948     *) gdb_cv_bigtoc=-bbigtoc ;;
 949     esac
 950
 951     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 952     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 953     LDFLAGS="${SAVE_LDFLAGS}"
 954   ])
 955   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 956   ;;
 957 esac
 958
 959
 960 dnl For certain native configurations, we need to check whether thread
 961 dnl support can be built in or not.
 962 dnl
 963 dnl Note that we only want this if we are both native (host == target),
 964 dnl and not doing a canadian cross build (build == host).
 965
 966 if test ${build} = ${host} -a ${host} = ${target} ; then
 967    case ${host_os} in
 968    hpux*)
 969       AC_MSG_CHECKING(for HPUX/OSF thread support)
 970       if test -f /usr/include/dce/cma_config.h ; then
 971          if test "$GCC" = "yes" ; then
 972             AC_MSG_RESULT(yes)
 973             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
 974             [Define if you have HPUX threads])
 975             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 976             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 977          else
 978             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 979          fi
 980       else
 981          AC_MSG_RESULT(no)
 982       fi
 983       ;;
 984    solaris*)
 985       # See if thread_db library is around for Solaris thread debugging.
 986       # Note that we must explicitly test for version 1 of the library
 987       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 988       # the same API.
 989       AC_MSG_CHECKING(for Solaris thread debugging library)
 990       if test -f /usr/lib/libthread_db.so.1 ; then
 991          AC_MSG_RESULT(yes)
 992          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
 993          [Define if using Solaris thread debugging.])
 994          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 995          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 996          AC_CHECK_LIB(dl, dlopen)
 997          if test "$GCC" = "yes" ; then
 998             # The GNU linker requires the -export-dynamic option to make
 999             # all symbols visible in the dynamic symbol table.
1000             hold_ldflags=$LDFLAGS
1001             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1002             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1003             AC_TRY_LINK(, [int i;], found=yes, found=no)
1004             LDFLAGS=$hold_ldflags
1005             AC_MSG_RESULT($found)
1006             if test $found = yes; then
1007                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1008             fi
1009          fi
1010          # Sun randomly tweaked the prototypes in <proc_service.h>
1011          # at one point.
1012          AC_MSG_CHECKING(if <proc_service.h> is old)
1013          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1014             AC_TRY_COMPILE([
1015                 #include <proc_service.h>
1016                 ps_err_e ps_pdwrite
1017                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1018             ],, gdb_cv_proc_service_is_old=no,
1019                 gdb_cv_proc_service_is_old=yes)
1020          ])
1021          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1022          if test $gdb_cv_proc_service_is_old = yes; then
1023             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1024             [Define if <proc_service.h> on solaris uses int instead of
1025              size_t, and assorted other type changes.])
1026          fi
1027       else
1028          AC_MSG_RESULT(no)
1029       fi
1030       ;;
1031    aix*)
1032       AC_MSG_CHECKING(for AiX thread debugging library)
1033       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1034                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1035                                    [#ifndef PTHDB_VERSION_3
1036                                     #error
1037                                     #endif],
1038                                    gdb_cv_have_aix_thread_debug=yes,
1039                                    gdb_cv_have_aix_thread_debug=no)])
1040       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1041       if test $gdb_cv_have_aix_thread_debug = yes; then
1042          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1043          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1044          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1045       fi
1046       ;;
1047    esac
1048    AC_SUBST(CONFIG_LDFLAGS)
1049 fi
1050
1051 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1052 dnl other error codes.
1053 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1054    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1055                   gdb_cv_thread_db_h_has_td_notalloc,
1056      AC_TRY_COMPILE(
1057        [#include <thread_db.h>],
1058        [int i = TD_NOTALLOC;],
1059        gdb_cv_thread_db_h_has_td_notalloc=yes,
1060        gdb_cv_thread_db_h_has_td_notalloc=no
1061      )
1062    )
1063    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1064                   gdb_cv_thread_db_h_has_td_version,
1065      AC_TRY_COMPILE(
1066        [#include <thread_db.h>],
1067        [int i = TD_VERSION;],
1068        gdb_cv_thread_db_h_has_td_version=yes,
1069        gdb_cv_thread_db_h_has_td_version=no
1070      )
1071    )
1072    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1073                   gdb_cv_thread_db_h_has_td_notls,
1074      AC_TRY_COMPILE(
1075        [#include <thread_db.h>],
1076        [int i = TD_NOTLS;],
1077        gdb_cv_thread_db_h_has_td_notls=yes,
1078        gdb_cv_thread_db_h_has_td_notls=no
1079      )
1080    )
1081 fi
1082 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1083   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1084             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1085 fi
1086 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1087   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1088             [Define if <thread_db.h> has the TD_VERSION error code.])
1089 fi
1090 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1091   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1092             [Define if <thread_db.h> has the TD_NOTLS error code.])
1093 fi
1094
1095 dnl See if we have a sys/syscall header file that has __NR_tkill.
1096 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1097    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1098                   gdb_cv_sys_syscall_h_has_tkill,
1099      AC_TRY_COMPILE(
1100        [#include <sys/syscall.h>],
1101        [int i = __NR_tkill;],
1102        gdb_cv_sys_syscall_h_has_tkill=yes,
1103        gdb_cv_sys_syscall_h_has_tkill=no
1104      )
1105    )
1106 fi
1107 dnl See if we can issue tkill syscall.
1108 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1109   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1110 fi
1111
1112 dnl Handle optional features that can be enabled.
1113
1114 AC_ARG_WITH(sysroot,
1115 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1116 [
1117  case ${with_sysroot} in
1118  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1119  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1120  esac
1121
1122  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1123
1124  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1125   if test "x$prefix" = xNONE; then
1126    test_prefix=/usr/local
1127   else
1128    test_prefix=$prefix
1129   fi
1130  else
1131   test_prefix=$exec_prefix
1132  fi
1133  case ${TARGET_SYSTEM_ROOT} in
1134  "${test_prefix}"|"${test_prefix}/"*|\
1135  '${exec_prefix}'|'${exec_prefix}/'*)
1136    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1137    TARGET_SYSTEM_ROOT_DEFINE="$t"
1138    ;;
1139  esac
1140 ], [
1141  TARGET_SYSTEM_ROOT=
1142  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1143 ])
1144 AC_SUBST(TARGET_SYSTEM_ROOT)
1145 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1146
1147 AC_ARG_ENABLE(werror,
1148   [  --enable-werror    treat compile warnings as errors],
1149   [case "${enableval}" in
1150      yes | y) ERROR_ON_WARNING="yes" ;;
1151      no | n)  ERROR_ON_WARNING="no" ;;
1152      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1153    esac])
1154
1155 # Enable -Werror by default when using gcc
1156 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1157     ERROR_ON_WARNING=yes
1158 fi
1159
1160 WERROR_CFLAGS=""
1161 if test "${ERROR_ON_WARNING}" = yes ; then
1162     WERROR_CFLAGS="-Werror"
1163 fi
1164
1165 # The entries after -Wno-pointer-sign are disabled warnings which may
1166 # be enabled in the future, which can not currently be used to build
1167 # GDB.
1168 # NOTE: If you change this list, remember to update
1169 # gdb/doc/gdbint.texinfo.
1170 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1171 -Wformat-nonliteral -Wno-pointer-sign \
1172 -Wno-unused -Wno-switch -Wno-char-subscripts"
1173
1174 AC_ARG_ENABLE(build-warnings,
1175 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1176 [case "${enableval}" in
1177   yes)  ;;
1178   no)   build_warnings="-w";;
1179   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1180         build_warnings="${build_warnings} ${t}";;
1181   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1182         build_warnings="${t} ${build_warnings}";;
1183   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1184 esac
1185 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1186   echo "Setting compiler warning flags = $build_warnings" 6>&1
1187 fi])dnl
1188 AC_ARG_ENABLE(gdb-build-warnings,
1189 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1190 [case "${enableval}" in
1191   yes)  ;;
1192   no)   build_warnings="-w";;
1193   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1194         build_warnings="${build_warnings} ${t}";;
1195   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1196         build_warnings="${t} ${build_warnings}";;
1197   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1198 esac
1199 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1200   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1201 fi])dnl
1202 WARN_CFLAGS=""
1203 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1204 then
1205     AC_MSG_CHECKING(compiler warning flags)
1206     # Separate out the -Werror flag as some files just cannot be
1207     # compiled with it enabled.
1208     for w in ${build_warnings}; do
1209         case $w in
1210         -Werr*) WERROR_CFLAGS=-Werror ;;
1211         *) # Check that GCC accepts it
1212             saved_CFLAGS="$CFLAGS"
1213             CFLAGS="$CFLAGS $w"
1214             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1215             CFLAGS="$saved_CFLAGS"
1216         esac
1217     done
1218     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1219 fi
1220 AC_SUBST(WARN_CFLAGS)
1221 AC_SUBST(WERROR_CFLAGS)
1222
1223 # In the Cygwin environment, we need some additional flags.
1224 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1225 [AC_EGREP_CPP(lose, [
1226 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1227 lose
1228 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1229
1230
1231 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1232 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1233 case ${host} in
1234   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1235   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1236   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1237 esac
1238 AC_SUBST(SER_HARDWIRE)
1239
1240 # libreadline needs libuser32.a in a cygwin environment
1241 WIN32LIBS=
1242 if test x$gdb_cv_os_cygwin = xyes; then
1243     WIN32LIBS="-luser32"
1244     case "${target}" in
1245         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1246         ;;
1247     esac
1248 fi
1249
1250 # The ser-tcp.c module requires sockets.
1251 case ${host} in
1252   *mingw32*)
1253     AC_DEFINE(USE_WIN32API, 1,
1254               [Define if we should use the Windows API, instead of the
1255                POSIX API.  On Windows, we use the Windows API when
1256                building for MinGW, but the POSIX API when building
1257                for Cygwin.])
1258     WIN32LIBS="$WIN32LIBS -lws2_32"
1259     ;;
1260 esac
1261 AC_SUBST(WIN32LIBS)
1262
1263 # Add any host-specific objects to GDB.
1264 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1265
1266 LIBGUI="../libgui/src/libgui.a"
1267 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1268 AC_SUBST(LIBGUI)
1269 AC_SUBST(GUI_CFLAGS_X)
1270
1271 WIN32LDAPP=
1272 AC_SUBST(WIN32LIBS)
1273 AC_SUBST(WIN32LDAPP)
1274
1275 case "${host}" in
1276 *-*-cygwin*)
1277     configdir="win"
1278     ;;
1279 *)
1280     configdir="unix"
1281     ;;
1282 esac
1283
1284 GDBTKLIBS=
1285 if test "${enable_gdbtk}" = "yes"; then
1286
1287     # Gdbtk must have an absolute path to srcdir in order to run
1288     # properly when not installed.
1289     here=`pwd`
1290     cd ${srcdir}
1291     GDBTK_SRC_DIR=`pwd`
1292     cd $here
1293
1294     CY_AC_PATH_TCLCONFIG
1295     if test -z "${no_tcl}"; then
1296         CY_AC_LOAD_TCLCONFIG
1297         CY_AC_PATH_TKCONFIG
1298
1299         # now look for Tcl library stuff
1300
1301         tcldir="../tcl/${configdir}/"
1302
1303         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1304
1305         # If $no_tk is nonempty, then we can't do Tk, and there is no
1306         # point to doing Tcl.
1307         if test -z "${no_tk}"; then
1308            CY_AC_LOAD_TKCONFIG
1309            CY_AC_PATH_TCLH
1310            CY_AC_PATH_TKH
1311            CY_AC_PATH_ITCLH
1312            CY_AC_PATH_ITKH
1313
1314
1315            # now look for Tk library stuff
1316
1317            tkdir="../tk/${configdir}/"
1318
1319            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1320
1321            # now look for Itcl library stuff
1322
1323            CY_AC_PATH_ITCLCONFIG
1324            if test -z "${no_itcl}"; then
1325              CY_AC_LOAD_ITCLCONFIG
1326
1327              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1328              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1329            fi
1330
1331
1332            # now look for Itk library stuff
1333            CY_AC_PATH_ITKCONFIG
1334            if test -z "${no_itcl}"; then
1335              CY_AC_LOAD_ITKCONFIG
1336
1337              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1338              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1339            fi
1340
1341            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1342
1343            # Include some libraries that Tcl and Tk want.
1344            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1345            # Yes, the ordering seems wrong here.  But it isn't.
1346            # TK_LIBS is the list of libraries that need to be linked
1347            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1348            # were in LIBS then any link tests after this point would
1349            # try to include things like `$(LIBGUI)', which wouldn't work.
1350            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1351
1352            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1353            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1354            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1355            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1356            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1357            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1358            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1359
1360            if test x$gdb_cv_os_cygwin = xyes; then
1361               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1362               WIN32LDAPP="-Wl,--subsystem,console"
1363               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1364            fi
1365         fi
1366     fi
1367
1368     AC_CONFIG_SUBDIRS(gdbtk)
1369 fi
1370
1371 AC_SUBST(X_CFLAGS)
1372 AC_SUBST(X_LDFLAGS)
1373 AC_SUBST(X_LIBS)
1374 AC_SUBST(TCL_DEPS)
1375 AC_SUBST(TK_DEPS)
1376 AC_SUBST(ITCLLIB)
1377 AC_SUBST(ITCL_DEPS)
1378 AC_SUBST(ITKLIB)
1379 AC_SUBST(ITK_DEPS)
1380 AC_SUBST(GDBTKLIBS)
1381 AC_SUBST(GDBTK_CFLAGS)
1382 AC_SUBST(GDBTK_SRC_DIR)
1383
1384 AC_PATH_X
1385
1386 # Check whether we should enable the TUI, but only do so if we really
1387 # can.
1388 if test x"$enable_tui" = xyes; then
1389   if test -d $srcdir/tui; then
1390     if test "$ac_cv_search_waddstr" != no; then
1391       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1392       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1393       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1394       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1395       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1396       CONFIG_ALL="${CONFIG_ALL} all-tui"
1397       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1398       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1399       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1400     else
1401       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1402     fi
1403   fi
1404 fi
1405
1406 # Unlike the sim directory, whether a simulator is linked is controlled by
1407 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1408 # This code just checks for a few cases where we'd like to ignore those
1409 # definitions, even when they're present in the '.mt' file.  These cases
1410 # are when --disable-sim is specified, or if the simulator directory is
1411 # not part of the source tree.
1412 #
1413 AC_ARG_ENABLE(sim,
1414 [  --enable-sim            Link gdb with simulator],
1415 [echo "enable_sim = $enable_sim";
1416  echo "enableval = ${enableval}";
1417  case "${enableval}" in
1418   yes) ignore_sim=false ;;
1419   no)  ignore_sim=true ;;
1420   *)   ignore_sim=false ;;
1421  esac],
1422 [ignore_sim=false])
1423
1424 if test ! -d "${srcdir}/../sim"; then
1425   ignore_sim=true
1426 fi
1427
1428 if test "${ignore_sim}" = "true"; then
1429     IGNORE_SIM="SIM="
1430     IGNORE_SIM_OBS="SIM_OBS="
1431 else
1432     IGNORE_SIM=""
1433     IGNORE_SIM_OBS=""
1434     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1435 fi
1436 AC_SUBST(IGNORE_SIM)
1437 AC_SUBST(IGNORE_SIM_OBS)
1438
1439 AC_SUBST(ENABLE_CFLAGS)
1440 AC_SUBST(PROFILE_CFLAGS)
1441
1442 AC_SUBST(CONFIG_OBS)
1443 AC_SUBST(CONFIG_DEPS)
1444 AC_SUBST(CONFIG_SRCS)
1445 AC_SUBST(CONFIG_ALL)
1446 AC_SUBST(CONFIG_CLEAN)
1447 AC_SUBST(CONFIG_INSTALL)
1448 AC_SUBST(CONFIG_UNINSTALL)
1449
1450 # List of host floatformats.
1451 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1452 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1453 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1454
1455 # target_subdir is used by the testsuite to find the target libraries.
1456 target_subdir=
1457 if test "${host}" != "${target}"; then
1458     target_subdir="${target_alias}/"
1459 fi
1460 AC_SUBST(target_subdir)
1461
1462 frags=
1463 if test "${gdb_native}" = "yes"; then
1464   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1465   if test ! -f ${host_makefile_frag}; then
1466     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1467   fi
1468   frags="$frags $host_makefile_frag"
1469 else
1470   host_makefile_frag=/dev/null
1471 fi
1472
1473 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1474 if test ! -f ${target_makefile_frag}; then
1475   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1476 fi
1477 frags="$frags $target_makefile_frag"
1478
1479 AC_SUBST_FILE(host_makefile_frag)
1480 AC_SUBST_FILE(target_makefile_frag)
1481 AC_SUBST(frags)
1482
1483 changequote(,)dnl
1484 hostfile=`sed -n '
1485 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1486 ' ${host_makefile_frag}`
1487
1488 targetfile=`sed -n '
1489 s/^[    ]*DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1490 ' ${target_makefile_frag}`
1491
1492 if test "${gdb_native}" = "yes"; then
1493 # We pick this up from the host configuration file (.mh) because we
1494 # do not have a native configuration Makefile fragment.
1495 nativefile=`sed -n '
1496 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1497 ' ${host_makefile_frag}`
1498 fi
1499 changequote([,])
1500
1501 if test x"${gdb_osabi}" != x ; then
1502     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1503                        [Define to the default OS ABI for this configuration.])
1504 fi
1505
1506 # Enable multi-ice-gdb-server.
1507 AC_ARG_ENABLE(multi-ice,
1508 [  --enable-multi-ice      build the multi-ice-gdb-server],
1509   [case $enableval in
1510     yes | no)
1511       ;;
1512     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1513   esac])
1514 if test "x$enable_multi_ice" = xyes; then
1515    AC_CONFIG_SUBDIRS(multi-ice)
1516 fi
1517
1518 # We only build gdbserver automatically in a native configuration.
1519 if test "$gdb_native" = "yes"; then
1520   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1521   if test "x$build_gdbserver" = xyes; then
1522     AC_MSG_RESULT(yes)
1523     AC_CONFIG_SUBDIRS(gdbserver)
1524   else
1525     AC_MSG_RESULT(no)
1526   fi
1527 fi
1528
1529 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1530 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1531 # to an empty version.
1532
1533 files=
1534 links=
1535
1536 rm -f xm.h
1537 xm_h=""
1538 if test "${hostfile}" != ""; then
1539     xm_h=xm.h
1540     case "${hostfile}" in
1541       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1542       * ) GDB_XM_FILE="${hostfile}"
1543     esac
1544     files="${files} ${GDB_XM_FILE}"
1545     links="${links} xm.h"
1546     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}", [hostfile])
1547 fi
1548 AC_SUBST(xm_h)
1549
1550 rm -f tm.h
1551 tm_h=""
1552 if test "${targetfile}" != ""; then
1553     tm_h=tm.h
1554     case "${targetfile}" in
1555       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1556       * ) GDB_TM_FILE="${targetfile}"
1557     esac
1558     files="${files} ${GDB_TM_FILE}"
1559     links="${links} tm.h"
1560     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}", [targetfile])
1561 fi
1562 AC_SUBST(tm_h)
1563
1564 rm -f nm.h
1565 nm_h=""
1566 if test "${nativefile}" != ""; then
1567     nm_h=nm.h
1568     case "${nativefile}" in
1569       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1570       * ) GDB_NM_FILE="${nativefile}"
1571     esac
1572     files="${files} ${GDB_NM_FILE}"
1573     links="${links} nm.h"
1574     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1575 fi
1576 AC_SUBST(nm_h)
1577
1578 AC_LINK_FILES($files, $links)
1579
1580 dnl Check for exe extension set on certain hosts (e.g. Win32)
1581 AC_EXEEXT
1582
1583 dnl  Detect the character set used by this host.
1584
1585 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1586 dnl  superset of ASCII containing the characters needed for French,
1587 dnl  German, Spanish, Italian, and possibly others), but if were
1588 dnl  *were* to support any host character sets other than ISO-8859-1,
1589 dnl  here's where we'd detect it.
1590 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1591           [Define to be a string naming the default host character set.])
1592
1593 AM_ICONV
1594
1595 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1596 [
1597 dnl Autoconf doesn't provide a mechanism for modifying definitions
1598 dnl provided by makefile fragments.
1599 dnl
1600
1601 changequote(,)dnl
1602 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1603 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1604 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1605 mv -f Makefile.tmp Makefile
1606 changequote([,])dnl
1607
1608
1609 case x$CONFIG_HEADERS in
1610 xconfig.h:config.in)
1611 echo > stamp-h ;;
1612 esac
1613 ],
1614 [
1615 gdb_host_cpu=$gdb_host_cpu
1616 gdb_target_cpu=$gdb_target_cpu
1617 nativefile=$nativefile
1618 ])
1619
1620 exit 0