gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2014 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37 AC_ARG_PROGRAM
  38
  39 # Dependency checking.
  40 ZW_CREATE_DEPDIR
  41 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  42
  43 # Check for the 'make' the user wants to use.
  44 AC_CHECK_PROGS(MAKE, make)
  45 MAKE_IS_GNU=
  46 case "`$MAKE --version 2>&1 | sed 1q`" in
  47   *GNU*)
  48     MAKE_IS_GNU=yes
  49     ;;
  50 esac
  51 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  52 AC_PROG_MAKE_SET
  53
  54 # Configure gnulib.  We need to build gnulib under some other
  55 # directory not "gnulib", to avoid the problem of both GDB and
  56 # GDBserver wanting to build it in the same directory, when building
  57 # in the source dir.
  58 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  59
  60 dnl List of object files and targets accumulated by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66
  67 CONFIG_ALL=
  68 CONFIG_CLEAN=
  69 CONFIG_INSTALL=
  70 CONFIG_UNINSTALL=
  71
  72 dnl Set up for gettext.
  73 ZW_GNU_GETTEXT_SISTER_DIR
  74
  75 localedir='${datadir}/locale'
  76 AC_SUBST(localedir)
  77
  78 if test x"$USE_NLS" = xyes; then
  79    CONFIG_ALL="$CONFIG_ALL all-po"
  80    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  81    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  82    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  83 fi
  84
  85 GNULIB=build-gnulib/import
  86
  87 # For Makefile dependencies.
  88 GNULIB_STDINT_H=
  89 if test x"$STDINT_H" != x; then
  90   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  91 fi
  92 AC_SUBST(GNULIB_STDINT_H)
  93
  94 PACKAGE=gdb
  95 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  96 AC_SUBST(PACKAGE)
  97
  98 # We never need to detect it in this sub-configure.
  99 # But preserve it for config.status --recheck.
 100 AC_ARG_VAR(MAKEINFO,
 101   [Parent configure detects if it is of sufficient version.])
 102 AC_ARG_VAR(MAKEINFOFLAGS,
 103   [Parameters for MAKEINFO.])
 104
 105 MAKEINFO_EXTRA_FLAGS=""
 106 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 107   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 108   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 109     gdb_cv_have_makeinfo_click=yes
 110   else
 111     gdb_cv_have_makeinfo_click=no
 112   fi])
 113 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 114   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 115 fi
 116 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 117
 118 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 119     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 120     [${libdir}/debug])
 121
 122 # We can't pass paths as command line arguments.
 123 # Mingw32 tries to be clever and will convert the paths for us.
 124 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 125 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 126 # This breaks GDB's relocatable path conversions since paths passed in
 127 # config.h would not get so translated, the path prefixes no longer match.
 128 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_MSG_CHECKING([for default auto-load directory])
 144 AC_ARG_WITH(auto-load-dir,
 145 AS_HELP_STRING([--with-auto-load-dir=PATH],
 146   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 147   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 148 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 149 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 150               [Directories from which to load auto-loaded scripts.])
 151 AC_MSG_RESULT([$with_auto_load_dir])
 152
 153 AC_MSG_CHECKING([for default auto-load safe-path])
 154 AC_ARG_WITH(auto-load-safe-path,
 155 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 156   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 157 AS_HELP_STRING([--without-auto-load-safe-path],
 158                [do not restrict auto-loaded files locations]),
 159     [if test "$with_auto_load_safe_path" = "no"; then
 160      with_auto_load_safe_path="/"
 161      fi],
 162 [with_auto_load_safe_path="$with_auto_load_dir"])
 163 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 164 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 165               [Directories safe to hold auto-loaded files.])
 166 AC_MSG_RESULT([$with_auto_load_safe_path])
 167
 168 AC_CONFIG_SUBDIRS(testsuite)
 169
 170 # Check whether to support alternative target configurations
 171 AC_ARG_ENABLE(targets,
 172 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 173 [case "${enableval}" in
 174   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 175             ;;
 176   no)       enable_targets= ;;
 177   *)        enable_targets=$enableval ;;
 178 esac])
 179
 180 # Check whether to enable 64-bit support on 32-bit hosts
 181 AC_ARG_ENABLE(64-bit-bfd,
 182 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 183 [case "${enableval}" in
 184   yes)  want64=true  ;;
 185   no)   want64=false ;;
 186   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 187 esac],[want64=false])dnl
 188
 189 # Provide defaults for some variables set by the per-host and per-target
 190 # configuration.
 191 gdb_host_obs=posix-hdep.o
 192
 193 if test "${target}" = "${host}"; then
 194   gdb_native=yes
 195 else
 196   gdb_native=no
 197 fi
 198
 199 . $srcdir/configure.host
 200
 201 # Accumulate some settings from configure.tgt over all enabled targets
 202
 203 TARGET_OBS=
 204 all_targets=
 205 HAVE_NATIVE_GCORE_TARGET=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239
 240     # Check whether this target is native and supports gcore.
 241     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 242        && $gdb_have_gcore; then
 243       HAVE_NATIVE_GCORE_TARGET=1
 244     fi
 245   fi
 246 done
 247
 248 if test x${all_targets} = xtrue; then
 249
 250   # We want all 64-bit targets if we either:
 251   #  - run on a 64-bit host  or
 252   #  - already require 64-bit support for some other target  or
 253   #  - the --enable-64-bit-bfd option was supplied
 254   # Otherwise we only support all 32-bit targets.
 255   #
 256   # NOTE: This test must be in sync with the corresponding
 257   #       tests in BFD!
 258
 259   if test x${want64} = xfalse; then
 260     AC_CHECK_SIZEOF(long)
 261     if test "x${ac_cv_sizeof_long}" = "x8"; then
 262       want64=true
 263     fi
 264   fi
 265   if test x${want64} = xtrue; then
 266     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 267   else
 268     TARGET_OBS='$(ALL_TARGET_OBS)'
 269   fi
 270 fi
 271
 272 AC_SUBST(TARGET_OBS)
 273 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 274
 275 # For other settings, only the main target counts.
 276 gdb_sim=
 277 gdb_osabi=
 278 build_gdbserver=
 279 targ=$target; . ${srcdir}/configure.tgt
 280
 281 # Fetch the default architecture and default target vector from BFD.
 282 targ=$target; . $srcdir/../bfd/config.bfd
 283
 284 # We only want the first architecture, so strip off the others if
 285 # there is more than one.
 286 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 287
 288 if test "x$targ_archs" != x; then
 289   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 290     [Define to BFD's default architecture. ])
 291 fi
 292 if test "x$targ_defvec" != x; then
 293   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 294     [Define to BFD's default target vector. ])
 295 fi
 296
 297 # The CLI cannot be disabled yet, but may be in the future.
 298
 299 # Enable CLI.
 300 AC_ARG_ENABLE(gdbcli,
 301 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 302   [case $enableval in
 303     yes)
 304       ;;
 305     no)
 306       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 307     *)
 308       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 309   esac],
 310   [enable_gdbcli=yes])
 311 if test x"$enable_gdbcli" = xyes; then
 312   if test -d $srcdir/cli; then
 313     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 314     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 315     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 316     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 317   fi
 318 fi
 319
 320 # Enable MI.
 321 AC_ARG_ENABLE(gdbmi,
 322 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 323   [case $enableval in
 324     yes | no)
 325       ;;
 326     *)
 327       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 328   esac],
 329   [enable_gdbmi=yes])
 330 if test x"$enable_gdbmi" = xyes; then
 331   if test -d $srcdir/mi; then
 332     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 333     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 334     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 335     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 336   fi
 337 fi
 338
 339 # Enable TUI.
 340 AC_ARG_ENABLE(tui,
 341 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 342   [case $enableval in
 343     yes | no | auto)
 344       ;;
 345     *)
 346       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 347   esac],enable_tui=auto)
 348
 349 # Enable gdbtk.
 350 AC_ARG_ENABLE(gdbtk,
 351 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 352   [case $enableval in
 353     yes | no)
 354       ;;
 355     *)
 356       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 357   esac],
 358   [if test -d $srcdir/gdbtk; then
 359     enable_gdbtk=yes
 360   else
 361     enable_gdbtk=no
 362   fi])
 363 # We unconditionally disable gdbtk tests on selected platforms.
 364 case $host_os in
 365   go32* | windows*)
 366     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 367     enable_gdbtk=no ;;
 368 esac
 369
 370 # Libunwind support for ia64.
 371
 372 AC_ARG_WITH(libunwind-ia64,
 373 AS_HELP_STRING([--with-libunwind-ia64],
 374                [use libunwind frame unwinding for ia64 targets]),,
 375             [with_libunwind_ia64=auto])
 376
 377 # Backward compatibility option.
 378 if test "${with_libunwind+set}" = set; then
 379   if test x"$with_libunwind_ia64" != xauto; then
 380     AC_MSG_ERROR(
 381       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 382   fi
 383   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 384   with_libunwind_ia64="$with_libunwind"
 385 fi
 386
 387 case "$with_libunwind_ia64" in
 388   yes | no)
 389     ;;
 390   auto)
 391     AC_CHECK_HEADERS(libunwind-ia64.h)
 392     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 393     ;;
 394   *)
 395     AC_MSG_ERROR(
 396       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 397     ;;
 398 esac
 399
 400 if test x"$with_libunwind_ia64" = xyes; then
 401   AC_CHECK_HEADERS(libunwind-ia64.h)
 402   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 403     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 404   fi
 405   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 406   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 407   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 408 fi
 409
 410 opt_curses=no
 411 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 412
 413 prefer_curses=no
 414 if test "$opt_curses" = "yes"; then
 415   prefer_curses=yes
 416 fi
 417
 418 # Profiling support.
 419 AC_ARG_ENABLE(profiling,
 420 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 421   [case $enableval in
 422     yes | no)
 423       ;;
 424     *)
 425       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 426   esac],
 427  [enable_profiling=no])
 428
 429 AC_CHECK_FUNCS(monstartup _mcleanup)
 430 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 431 [AC_TRY_LINK(
 432 [#include <stdlib.h>
 433 extern char _etext;
 434 ],
 435 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 436 if test $ac_cv_var__etext = yes; then
 437   AC_DEFINE(HAVE__ETEXT, 1,
 438             [Define to 1 if your system has the _etext variable. ])
 439 fi
 440 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 441 [AC_TRY_LINK(
 442 [#include <stdlib.h>
 443 extern char etext;
 444 ],
 445 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 446 if test $ac_cv_var_etext = yes; then
 447   AC_DEFINE(HAVE_ETEXT, 1,
 448             [Define to 1 if your system has the etext variable. ])
 449 fi
 450 if test "$enable_profiling" = yes ; then
 451   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 452     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 453   fi
 454   PROFILE_CFLAGS=-pg
 455   OLD_CFLAGS="$CFLAGS"
 456   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 457
 458   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 459     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 460      ac_cv_cc_supports_pg=no)])
 461
 462   if test $ac_cv_cc_supports_pg = no; then
 463     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 464   fi
 465
 466   CFLAGS="$OLD_CFLAGS"
 467 fi
 468
 469 ACX_PKGVERSION([GDB])
 470 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 471 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 472 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 473
 474 # --------------------- #
 475 # Checks for programs.  #
 476 # --------------------- #
 477
 478 AC_PROG_AWK
 479 AC_PROG_INSTALL
 480 AC_PROG_LN_S
 481 AC_PROG_RANLIB
 482 AC_PROG_YACC
 483
 484 AC_CHECK_TOOL(AR, ar)
 485 AC_CHECK_TOOL(DLLTOOL, dlltool)
 486 AC_CHECK_TOOL(WINDRES, windres)
 487
 488 case $host_os in
 489   gnu*)
 490     # Needed for GNU Hurd hosts.
 491     AC_CHECK_TOOL(MIG, mig)
 492     if test x"$MIG" = x; then
 493       AC_MSG_ERROR([MIG not found but required for $host hosts])
 494     fi
 495     ;;
 496 esac
 497
 498 # ---------------------- #
 499 # Checks for libraries.  #
 500 # ---------------------- #
 501
 502 # We might need to link with -lm; most simulators need it.
 503 AC_CHECK_LIB(m, main)
 504
 505 # We need to link with -lw to get `wctype' on Solaris before Solaris
 506 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 507 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 508 # is known to have this problem).  Therefore we avoid libw if we can.
 509 AC_CHECK_FUNC(wctype, [],
 510   [AC_CHECK_LIB(w, wctype)])
 511
 512 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 513 AC_SEARCH_LIBS(gethostbyname, nsl)
 514
 515 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 516 AC_SEARCH_LIBS(socketpair, socket)
 517
 518 # Link in zlib if we can.  This allows us to read compressed debug sections.
 519 AM_ZLIB
 520
 521 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 522 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 523
 524 AM_ICONV
 525
 526 # GDB may fork/exec the iconv program to get the list of supported character
 527 # sets.  Allow the user to specify where to find it.
 528 # There are several factors affecting the choice of option name:
 529 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 530 #   the build-time location of libiconv files.
 531 # - The program we need to find is iconv, which comes with glibc.  The user
 532 #   doesn't necessarily have libiconv installed.  Therefore naming this
 533 #   --with-libiconv-foo feels wrong.
 534 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 535 #   defined to work on directories not files (though it really doesn't know
 536 #   the difference).
 537 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 538 #   with --with-libiconv-prefix.
 539 # Putting these together is why the option name is --with-iconv-bin.
 540
 541 AC_ARG_WITH(iconv-bin,
 542 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 543 [iconv_bin="${withval}"
 544  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 545                     [Path of directory of iconv program.])
 546  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 547 ])
 548
 549 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 550 # There is a very specific comment in /usr/include/curses.h explaining that
 551 # termcap routines built into libcurses must not be used.
 552 #
 553 # The symptoms we observed so far is GDB unexpectedly changing
 554 # the terminal settings when tgetent is called - this is particularly
 555 # visible as the output is missing carriage returns, and so rapidly
 556 # becomes very hard to read.
 557 #
 558 # The readline configure script has already decided that libtermcap
 559 # was enough for its purposes, and so decided to build readline using
 560 # libtermcap.  Since the TUI mode requires curses, building GDB with
 561 # TUI enabled results in both libraries to be used at the same time,
 562 # which is not allowed.  This basically means that GDB with TUI is
 563 # broken on alpha-osf.
 564
 565 case $host_os in
 566   osf* )
 567     if test x"$enable_tui" = xyes; then
 568       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 569     fi
 570     if test x"$enable_tui" = xauto; then
 571       enable_tui=no
 572     fi
 573     ;;
 574 esac
 575
 576 # For the TUI, we need enhanced curses functionality.
 577 if test x"$enable_tui" != xno; then
 578   prefer_curses=yes
 579 fi
 580
 581 curses_found=no
 582 if test x"$prefer_curses" = xyes; then
 583   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 584   # curses library because the latter might not provide all the
 585   # functionality we need.  However, this leads to problems on systems
 586   # where the linker searches /usr/local/lib, but the compiler doesn't
 587   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 588   # default installation of ncurses on alpha*-dec-osf* will lead to such
 589   # a situation.
 590   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 591
 592   if test "$ac_cv_search_waddstr" != no; then
 593     curses_found=yes
 594   fi
 595 fi
 596
 597 # Check whether we should enable the TUI, but only do so if we really
 598 # can.
 599 if test x"$enable_tui" != xno; then
 600   if test -d $srcdir/tui; then
 601     if test "$curses_found" != no; then
 602       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 603       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 604       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 605       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 606     else
 607       if test x"$enable_tui" = xyes; then
 608         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 609       else
 610         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 611       fi
 612     fi
 613   fi
 614 fi
 615
 616 # Since GDB uses Readline, we need termcap functionality.  In many
 617 # cases this will be provided by the curses library, but some systems
 618 # have a seperate termcap library, or no curses library at all.
 619
 620 case $host_os in
 621   cygwin*)
 622     if test -d $srcdir/libtermcap; then
 623       LIBS="../libtermcap/libtermcap.a $LIBS"
 624       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 625     fi ;;
 626   go32* | *djgpp*)
 627     ac_cv_search_tgetent="none required"
 628     ;;
 629   *mingw32*)
 630     ac_cv_search_tgetent="none required"
 631     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 632     ;;
 633 esac
 634
 635 # These are the libraries checked by Readline.
 636 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 637
 638 if test "$ac_cv_search_tgetent" = no; then
 639   AC_MSG_ERROR([no termcap library found])
 640 fi
 641
 642 AC_ARG_WITH([system-readline],
 643   [AS_HELP_STRING([--with-system-readline],
 644                   [use installed readline library])])
 645
 646 if test "$with_system_readline" = yes; then
 647   READLINE=-lreadline
 648   READLINE_DEPS=
 649   READLINE_CFLAGS=
 650   READLINE_TEXI_INCFLAG=
 651 else
 652   READLINE='$(READLINE_DIR)/libreadline.a'
 653   READLINE_DEPS='$(READLINE)'
 654   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 655   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 656 fi
 657 AC_SUBST(READLINE)
 658 AC_SUBST(READLINE_DEPS)
 659 AC_SUBST(READLINE_CFLAGS)
 660 AC_SUBST(READLINE_TEXI_INCFLAG)
 661
 662 # Generate jit-reader.h
 663
 664 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 665 TARGET_PTR=
 666
 667 AC_CHECK_SIZEOF(unsigned long long)
 668 AC_CHECK_SIZEOF(unsigned long)
 669 AC_CHECK_SIZEOF(unsigned __int128)
 670
 671 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 672   TARGET_PTR="unsigned long"
 673 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 674   TARGET_PTR="unsigned long long"
 675 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 676   TARGET_PTR="unsigned __int128"
 677 else
 678   TARGET_PTR="unsigned long"
 679 fi
 680
 681 AC_SUBST(TARGET_PTR)
 682 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 683
 684 AC_SEARCH_LIBS(dlopen, dl)
 685
 686 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 687                 [directory to load the JIT readers from],
 688                 [${libdir}/gdb])
 689
 690 AC_ARG_WITH(expat,
 691   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 692   [], [with_expat=auto])
 693 AC_MSG_CHECKING([whether to use expat])
 694 AC_MSG_RESULT([$with_expat])
 695
 696 if test "${with_expat}" = no; then
 697   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 698   HAVE_LIBEXPAT=no
 699 else
 700   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 701                         [XML_Parser p = XML_ParserCreate (0);])
 702   if test "$HAVE_LIBEXPAT" != yes; then
 703     if test "$with_expat" = yes; then
 704       AC_MSG_ERROR([expat is missing or unusable])
 705     else
 706       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 707     fi
 708   else
 709     save_LIBS=$LIBS
 710     LIBS="$LIBS $LIBEXPAT"
 711     AC_CHECK_FUNCS(XML_StopParser)
 712     LIBS=$save_LIBS
 713   fi
 714 fi
 715
 716 # --------------------- #
 717 # Check for libpython.  #
 718 # --------------------- #
 719
 720 dnl Utility to simplify finding libpython.
 721 dnl $1 = pythonX.Y
 722 dnl $2 = the shell variable to assign the result to
 723 dnl      If libpython is found we store $version here.
 724 dnl $3 = additional flags to add to CPPFLAGS
 725 dnl $4 = additional flags to add to LIBS
 726
 727 AC_DEFUN([AC_TRY_LIBPYTHON],
 728 [
 729   version=$1
 730   define([have_libpython_var],$2)
 731   new_CPPFLAGS=$3
 732   new_LIBS=$4
 733   AC_MSG_CHECKING([for ${version}])
 734   save_CPPFLAGS=$CPPFLAGS
 735   save_LIBS=$LIBS
 736   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 737   LIBS="$LIBS $new_LIBS"
 738   found_usable_python=no
 739   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 740                                  [[Py_Initialize ();]]),
 741                  [have_libpython_var=${version}
 742                   found_usable_python=yes
 743                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 744                   PYTHON_LIBS=$new_LIBS])
 745   CPPFLAGS=$save_CPPFLAGS
 746   LIBS=$save_LIBS
 747   AC_MSG_RESULT([${found_usable_python}])
 748 ])
 749
 750 dnl There are several different values for --with-python:
 751 dnl
 752 dnl no -   Don't include python support.
 753 dnl yes -  Include python support, error if it's missing.
 754 dnl        If we find python in $PATH, use it to fetch configure options,
 755 dnl        otherwise assume the compiler can find it with no help from us.
 756 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 757 dnl auto - Same as "yes", but if python is missing from the system,
 758 dnl        fall back to "no".
 759 dnl /path/to/python/exec-prefix -
 760 dnl        Use the python located in this directory.
 761 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 762 dnl        the compilation parameters.  Otherwise use
 763 dnl        -I/path/to/python/exec-prefix/include,
 764 dnl        -L/path/to/python/exec-prefix/lib.
 765 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 766 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 767 dnl        but is deprecated.
 768 dnl /path/to/python/executable -
 769 dnl        Run python-config.py with this version of python to fetch the
 770 dnl        compilation parameters.
 771 dnl        NOTE: This needn't be the real python executable.
 772 dnl        In a cross-compilation scenario (build != host), this could be
 773 dnl        a shell script that provides what python-config.py provides for
 774 dnl        --ldflags, --includes, --exec-prefix.
 775 dnl python-executable -
 776 dnl        Find python-executable in $PATH, and then handle the same as
 777 dnl        /path/to/python/executable.
 778 dnl
 779 dnl If a python program is specified, it is used to run python-config.py and
 780 dnl is passed --ldflags, --includes, --exec-prefix.
 781
 782 AC_ARG_WITH(python,
 783   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 784   [], [with_python=auto])
 785 AC_MSG_CHECKING([whether to use python])
 786 AC_MSG_RESULT([$with_python])
 787
 788 if test "${with_python}" = no; then
 789   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 790   have_libpython=no
 791 else
 792   case "${with_python}" in
 793   [[\\/]]* | ?:[[\\/]]*)
 794     if test -d ${with_python}; then
 795       # Assume the python binary is ${with_python}/bin/python.
 796       python_prog="${with_python}/bin/python"
 797       python_prefix=
 798       # If python does not exit ${with_python}/bin, then try in
 799       # ${with_python}.  On Windows/MinGW, this is where the Python
 800       # executable is.
 801       if test ! -x "${python_prog}"; then
 802         python_prog="${with_python}/python"
 803         python_prefix=
 804       fi
 805       if test ! -x "${python_prog}"; then
 806         # Fall back to gdb 7.0/7.1 behaviour.
 807         python_prog=missing
 808         python_prefix=${with_python}
 809       fi
 810     elif test -x "${with_python}"; then
 811       # While we can't run python compiled for $host (unless host == build),
 812       # the user could write a script that provides the needed information,
 813       # so we support that.
 814       python_prog=${with_python}
 815       python_prefix=
 816     else
 817       AC_ERROR(invalid value for --with-python)
 818     fi
 819     ;;
 820   */*)
 821     # Disallow --with-python=foo/bar.
 822     AC_ERROR(invalid value for --with-python)
 823     ;;
 824   *)
 825     # The user has either specified auto, yes, or the name of the python
 826     # program assumed to be in $PATH.
 827     python_prefix=
 828     case "${with_python}" in
 829     yes | auto)
 830       if test ${build} = ${host}; then
 831         AC_PATH_PROG(python_prog_path, python, missing)
 832         if test "${python_prog_path}" = missing; then
 833           python_prog=missing
 834         else
 835           python_prog=${python_prog_path}
 836         fi
 837       else
 838         # Not much we can do except assume the cross-compiler will find the
 839         # right files.
 840         python_prog=missing
 841       fi
 842       ;;
 843     *)
 844       # While we can't run python compiled for $host (unless host == build),
 845       # the user could write a script that provides the needed information,
 846       # so we support that.
 847       python_prog="${with_python}"
 848       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 849       if test "${python_prog_path}" = missing; then
 850         AC_ERROR(unable to find python program ${python_prog})
 851       fi
 852       ;;
 853     esac
 854   esac
 855
 856   if test "${python_prog}" != missing; then
 857     # We have a python program to use, but it may be too old.
 858     # Don't flag an error for --with-python=auto (the default).
 859     have_python_config=yes
 860     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 861     if test $? != 0; then
 862       have_python_config=failed
 863       if test "${with_python}" != auto; then
 864         AC_ERROR(failure running python-config --includes)
 865       fi
 866     fi
 867     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 868     if test $? != 0; then
 869       have_python_config=failed
 870       if test "${with_python}" != auto; then
 871         AC_ERROR(failure running python-config --ldflags)
 872       fi
 873     fi
 874     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 875     if test $? != 0; then
 876       have_python_config=failed
 877       if test "${with_python}" != auto; then
 878         AC_ERROR(failure running python-config --exec-prefix)
 879       fi
 880     fi
 881   else
 882     # We do not have a python executable we can use to determine where
 883     # to find the Python headers and libs.  We cannot guess the include
 884     # path from the python_prefix either, because that include path
 885     # depends on the Python version.  So, there is nothing much we can
 886     # do except assume that the compiler will be able to find those files.
 887     python_includes=
 888     python_libs=
 889     have_python_config=no
 890   fi
 891
 892   # If we have python-config, only try the configuration it provides.
 893   # Otherwise fallback on the old way of trying different versions of
 894   # python in turn.
 895
 896   have_libpython=no
 897   if test "${have_python_config}" = yes; then
 898     # Determine the Python version by extracting "-lpython<version>"
 899     # part of the python_libs. <version> is usually X.Y with X and Y
 900     # being decimal numbers, but can also be XY (seen on Windows).
 901     #
 902     # The extraction is performed using sed with a regular expression.
 903     # Initially, the regexp used was using the '?' quantifier to make
 904     # the dot in the version number optional.  Unfortunately, this
 905     # does not work with non-GNU versions of sed because, because of
 906     # what looks like a limitation (the '?' quantifier does not work
 907     # with back-references).  We work around this limitation by using
 908     # the '*' quantifier instead.  It means that, in theory, we might
 909     # match unexpected version strings such as "-lpython2..7", but
 910     # this seems unlikely in practice.  And even if that happens,
 911     # an error will be triggered later on, when checking that version
 912     # number.
 913     python_version=`echo " ${python_libs} " \
 914                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 915     case "${python_version}" in
 916     python*)
 917       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 918                        ${python_includes}, ${python_libs})
 919       ;;
 920     *)
 921       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 922       ;;
 923     esac
 924   elif test "${have_python_config}" != failed; then
 925     if test "${have_libpython}" = no; then
 926       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 927                        ${python_includes}, "${python_libs} -lpython2.7")
 928     fi
 929     if test "${have_libpython}" = no; then
 930       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 931                        ${python_includes}, "${python_libs} -lpython2.6")
 932     fi
 933     if test ${have_libpython} = no; then
 934       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 935                        ${python_includes}, "${python_libs} -lpython2.5")
 936     fi
 937     if test ${have_libpython} = no; then
 938       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 939                        ${python_includes}, "${python_libs} -lpython2.4")
 940     fi
 941   fi
 942   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 943     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 944   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 945     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 946   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 947     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 948   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 949     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 950   fi
 951
 952   if test "${have_libpython}" = no; then
 953     case "${with_python}" in
 954     yes)
 955       AC_MSG_ERROR([python is missing or unusable])
 956       ;;
 957     auto)
 958       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 959       ;;
 960     *)
 961       AC_MSG_ERROR([no usable python found at ${with_python}])
 962       ;;
 963     esac
 964   else
 965     if test -n "${python_prefix}"; then
 966       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 967                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 968       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 969     fi
 970   fi
 971 fi
 972
 973 if test "${have_libpython}" != no; then
 974   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 975   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 976   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 977   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 978   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 979   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 980
 981   # Flags needed to compile Python code (taken from python-config --cflags).
 982   # We cannot call python-config directly because it will output whatever was
 983   # used when compiling the Python interpreter itself, including flags which
 984   # would make the python-related objects be compiled differently from the
 985   # rest of GDB (e.g., -O2 and -fPIC).
 986   if test "${GCC}" = yes; then
 987     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 988   fi
 989
 990   if test "x${tentative_python_cflags}" != x; then
 991     AC_MSG_CHECKING(compiler flags for python code)
 992     for flag in ${tentative_python_cflags}; do
 993       # Check that the compiler accepts it
 994       saved_CFLAGS="$CFLAGS"
 995       CFLAGS="$CFLAGS $flag"
 996       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 997       CFLAGS="$saved_CFLAGS"
 998     done
 999     AC_MSG_RESULT(${PYTHON_CFLAGS})
1000   fi
1001
1002   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
1003   #    #if _SGIAPI
1004   #    #define siginfo __siginfo
1005   #    #endif
1006   # The problem is that including Python causes some XOPEN macros to be
1007   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
1008   # to false.  So, we work around this issue by defining siginfo ourself
1009   # though the command-line.
1010   #
1011   # On x64 Windows, Python's include headers, and pyconfig.h in
1012   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1013   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1014   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1015   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1016   # The issue was reported to the Python community, but still isn't
1017   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1018
1019   case "$gdb_host" in
1020     irix*) if test "${GCC}" = yes; then
1021              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1022            fi
1023            ;;
1024     mingw64)
1025            if test "${GCC}" = yes; then
1026              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1027            fi
1028            ;;
1029   esac
1030
1031   # Note that "python -m threading" cannot be used to check for
1032   # threading support due to a bug in Python 2.7.3
1033   # (http://bugs.python.org/issue15567).
1034   AC_MSG_CHECKING(whether python supports threads)
1035   saved_CPPFLAGS="${CPPFLAGS}"
1036   CPPFLAGS="${PYTHON_CPPFLAGS}"
1037   # Note that the test is reversed so that python_has_threads=yes on
1038   # unexpected failures.
1039   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1040 #include <Python.h>
1041 #ifdef WITH_THREAD
1042 # error
1043 #endif
1044   ]]), [python_has_threads=no], [python_has_threads=yes])
1045   AC_MSG_RESULT(${python_has_threads})
1046   CPPFLAGS="${saved_CPPFLAGS}"
1047 else
1048   # Even if Python support is not compiled in, we need to have this file
1049   # included so that the "python" command, et.al., still exists.
1050   CONFIG_OBS="$CONFIG_OBS python.o"
1051   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1052 fi
1053 AC_SUBST(PYTHON_CFLAGS)
1054 AC_SUBST(PYTHON_CPPFLAGS)
1055 AC_SUBST(PYTHON_LIBS)
1056
1057 # -------------------- #
1058 # Check for libguile.  #
1059 # -------------------- #
1060
1061 dnl We check guile with pkg-config.
1062
1063 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1064
1065 dnl Utility to simplify finding libguile.
1066 dnl $1 = pkg-config-program
1067 dnl $2 = space-separate list of guile versions to try
1068 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1069 dnl $4 = the shell variable to assign the result to
1070 dnl      If libguile is found we store "yes" here.
1071
1072 AC_DEFUN([AC_TRY_LIBGUILE],
1073 [
1074   pkg_config=$1
1075   guile_version_list=$2
1076   flag_errors=$3
1077   define([have_libguile_var],$4)
1078   if test "${pkg_config}" = "missing"; then
1079     AC_ERROR(pkg-config program not found)
1080   fi
1081   if test ! -f "${pkg_config}"; then
1082     AC_ERROR(pkg-config program ${pkg_config} not found)
1083   fi
1084   found_usable_guile=checking
1085   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1086   for guile_version in ${guile_version_list}; do
1087     ${pkg_config} --exists ${guile_version} 2>/dev/null
1088     if test $? != 0; then
1089       continue
1090     fi
1091     dnl pkg-config says the package exists, so if we get an error now,
1092     dnl that's bad.
1093     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1094     if test $? != 0; then
1095       AC_ERROR(failure running pkg-config --cflags ${guile_version})
1096     fi
1097     new_LIBS=`${pkg_config} --libs ${guile_version}`
1098     if test $? != 0; then
1099       AC_ERROR(failure running pkg-config --libs ${guile_version})
1100     fi
1101     dnl If we get this far, great.
1102     found_usable_guile=${guile_version}
1103     break
1104   done
1105   if test "${found_usable_guile}" = "checking"; then
1106     if test "${flag_errors}" = "yes"; then
1107       AC_ERROR(unable to find usable guile version from "${guile_version_list}")
1108     else
1109       found_usable_guile=no
1110     fi
1111   fi
1112   dnl One final sanity check.
1113   dnl The user could have said --with-guile=python-2.7.
1114   if test "${found_usable_guile}" != no; then
1115     save_CPPFLAGS=$CPPFLAGS
1116     save_LIBS=$LIBS
1117     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1118     LIBS="$LIBS $new_LIBS"
1119     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1120                                    [[scm_init_guile ();]]),
1121                    [have_libguile_var=yes
1122                     GUILE_CPPFLAGS=$new_CPPFLAGS
1123                     GUILE_LIBS=$new_LIBS],
1124                    [found_usable_guile=no])
1125     CPPFLAGS=$save_CPPFLAGS
1126     LIBS=$save_LIBS
1127     if test "${found_usable_guile}" = no; then
1128       if test "${flag_errors}" = yes; then
1129         AC_MSG_FAILURE(linking guile version ${guile_version} test program failed)
1130       fi
1131     fi
1132   fi
1133   AC_MSG_RESULT([${found_usable_guile}])
1134 ])
1135
1136 dnl There are several different values for --with-guile:
1137 dnl
1138 dnl no -   Don't include guile support.
1139 dnl yes -  Include guile support, error if it's missing.
1140 dnl        The pkg-config program must be in $PATH.
1141 dnl auto - Same as "yes", but if guile is missing from the system,
1142 dnl        fall back to "no".
1143 dnl guile-version [guile-version-choice-2 ...] -
1144 dnl        A space-separated list of guile package versions to try.
1145 dnl        These are passed to pkg-config as-is.
1146 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1147 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1148 dnl /path/to/pkg-config -
1149 dnl        Use this pkg-config program.
1150 dnl        NOTE: This needn't be the "real" pkg-config program.
1151 dnl        It could be a shell script.  It is invoked as:
1152 dnl        pkg-config --exists $version
1153 dnl        pkg-config --cflags $version
1154 dnl        pkg-config --libs $version
1155 dnl        $version will be the default guile version (currently guile-2.0),
1156 dnl        but the program is free to ignore this.
1157
1158 AC_ARG_WITH(guile,
1159   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1160   [], [with_guile=auto])
1161 AC_MSG_CHECKING([whether to use guile])
1162 AC_MSG_RESULT([$with_guile])
1163
1164 try_guile_versions="guile-2.0"
1165 have_libguile=no
1166 case "${with_guile}" in
1167 no)
1168   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1169   ;;
1170 auto)
1171   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1172   ;;
1173 yes)
1174   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1175   ;;
1176 [[\\/]]* | ?:[[\\/]]*)
1177   AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1178   ;;
1179 "" | */*)
1180   # Disallow --with=guile="" and --with-guile=foo/bar.
1181   AC_ERROR(invalid value for --with-guile)
1182   ;;
1183 *)
1184   # A space separate list of guile versions to try, in order.
1185   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1186   ;;
1187 esac
1188
1189 if test "${have_libguile}" != no; then
1190   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1191   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1192   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1193   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1194   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1195   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1196 else
1197   # Even if Guile support is not compiled in, we need to have these files
1198   # included.
1199   CONFIG_OBS="$CONFIG_OBS guile.o"
1200   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1201 fi
1202 AC_SUBST(GUILE_CPPFLAGS)
1203 AC_SUBST(GUILE_LIBS)
1204
1205 # --------------------- #
1206 # Check for libmcheck.  #
1207 # --------------------- #
1208
1209 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1210 # but turn it off if Python is enabled with threads, since -lmcheck is
1211 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1212 # and for releases.
1213 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1214    && $development; then
1215   libmcheck_default=yes
1216 else
1217   libmcheck_default=no
1218 fi
1219 GDB_AC_LIBMCHECK(${libmcheck_default})
1220
1221 if test "$ENABLE_LIBMCHECK" = "yes" \
1222         -a "${have_libpython}" != "no" \
1223         -a "${python_has_threads}" = "yes" ; then
1224   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1225 fi
1226
1227 # ------------------------- #
1228 # Checks for header files.  #
1229 # ------------------------- #
1230
1231 AC_HEADER_STDC
1232 # elf_hp.h is for HP/UX 64-bit shared library support.
1233 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1234                   thread_db.h \
1235                   sys/fault.h \
1236                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1237                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1238                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1239                   termios.h termio.h \
1240                   sgtty.h elf_hp.h \
1241                   dlfcn.h])
1242 AC_CHECK_HEADERS(sys/proc.h, [], [],
1243 [#if HAVE_SYS_PARAM_H
1244 # include <sys/param.h>
1245 #endif
1246 ])
1247 AC_CHECK_HEADERS(sys/user.h, [], [],
1248 [#if HAVE_SYS_PARAM_H
1249 # include <sys/param.h>
1250 #endif
1251 ])
1252
1253 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1254 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1255 # think that we don't have <curses.h> if we're using GCC.
1256 case $host_os in
1257   solaris2.[[789]])
1258     if test "$GCC" = yes; then
1259       AC_DEFINE(_MSE_INT_H, 1,
1260         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1261    Solaris 2.[789] when using GCC. ])
1262     fi ;;
1263 esac
1264 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1265 AC_CHECK_HEADERS(term.h, [], [],
1266 [#if HAVE_CURSES_H
1267 # include <curses.h>
1268 #endif
1269 ])
1270
1271 # ------------------------- #
1272 # Checks for declarations.  #
1273 # ------------------------- #
1274
1275 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1276 AM_LC_MESSAGES
1277
1278 # ----------------------- #
1279 # Checks for structures.  #
1280 # ----------------------- #
1281
1282 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1283
1284 # ------------------ #
1285 # Checks for types.  #
1286 # ------------------ #
1287
1288 AC_TYPE_SIGNAL
1289 AC_CHECK_TYPES(socklen_t, [], [],
1290 [#include <sys/types.h>
1291 #include <sys/socket.h>
1292 ])
1293
1294 # ------------------------------------- #
1295 # Checks for compiler characteristics.  #
1296 # ------------------------------------- #
1297
1298 AC_C_CONST
1299 AC_C_INLINE
1300 AC_C_BIGENDIAN
1301
1302 # ------------------------------ #
1303 # Checks for library functions.  #
1304 # ------------------------------ #
1305
1306 AC_FUNC_ALLOCA
1307 AC_FUNC_MMAP
1308 AC_FUNC_VFORK
1309 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1310                 pipe poll pread pread64 pwrite readlink resize_term \
1311                 sbrk setpgid setpgrp setsid \
1312                 sigaction sigprocmask sigsetmask socketpair \
1313                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1314                 setrlimit getrlimit posix_madvise waitpid lstat \
1315                 ptrace64])
1316 AM_LANGINFO_CODESET
1317 GDB_AC_COMMON
1318
1319 # Check the return and argument types of ptrace.  No canned test for
1320 # this, so roll our own.
1321 gdb_ptrace_headers='
1322 #include <sys/types.h>
1323 #if HAVE_SYS_PTRACE_H
1324 # include <sys/ptrace.h>
1325 #endif
1326 #if HAVE_UNISTD_H
1327 # include <unistd.h>
1328 #endif
1329 '
1330 # There is no point in checking if we don't have a prototype.
1331 AC_CHECK_DECLS(ptrace, [], [
1332   : ${gdb_cv_func_ptrace_ret='int'}
1333   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1334 ], $gdb_ptrace_headers)
1335 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1336 # empty argument list, so check for that explicitly.
1337 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1338   AC_TRY_COMPILE($gdb_ptrace_headers,
1339     [extern long ptrace (enum __ptrace_request, ...);],
1340     gdb_cv_func_ptrace_ret='long',
1341     AC_TRY_COMPILE($gdb_ptrace_headers,
1342       [extern int ptrace ();],
1343       gdb_cv_func_ptrace_ret='int',
1344       gdb_cv_func_ptrace_ret='long')))
1345 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1346   [Define as the return type of ptrace.])
1347 # Check argument types.
1348 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1349   AC_TRY_COMPILE($gdb_ptrace_headers,
1350     [extern long ptrace (enum __ptrace_request, ...);],
1351     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1352 for gdb_arg1 in 'int' 'long'; do
1353  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1354   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1355    for gdb_arg4 in 'int' 'long' 'void *'; do
1356      AC_TRY_COMPILE($gdb_ptrace_headers, [
1357 extern $gdb_cv_func_ptrace_ret
1358   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1359 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1360     break 4;])
1361     for gdb_arg5 in 'int *' 'int' 'long'; do
1362      AC_TRY_COMPILE($gdb_ptrace_headers, [
1363 extern $gdb_cv_func_ptrace_ret
1364   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1365 ], [
1366 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1367     break 5;])
1368     done
1369    done
1370   done
1371  done
1372 done
1373 # Provide a safe default value.
1374 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1375 ])])
1376 ac_save_IFS=$IFS; IFS=','
1377 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1378 IFS=$ac_save_IFS
1379 shift
1380 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1381   [Define to the type of arg 3 for ptrace.])
1382 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1383   [Define to the type of arg 4 for ptrace.])
1384 if test -n "$[5]"; then
1385   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1386     [Define to the type of arg 5 for ptrace.])
1387 fi
1388
1389 dnl AC_FUNC_SETPGRP does not work when cross compiling
1390 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1391 if test "$cross_compiling" = no; then
1392   AC_FUNC_SETPGRP
1393 else
1394   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1395     [AC_TRY_COMPILE([
1396 #include <unistd.h>
1397 ], [
1398   if (setpgrp(1,1) == -1)
1399     exit (0);
1400   else
1401     exit (1);
1402 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1403 if test $ac_cv_func_setpgrp_void = yes; then
1404   AC_DEFINE(SETPGRP_VOID, 1)
1405 fi
1406 fi
1407
1408 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1409 # since sigsetjmp might only be defined as a macro.
1410 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1411 [AC_TRY_COMPILE([
1412 #include <setjmp.h>
1413 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1414 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1415 if test $gdb_cv_func_sigsetjmp = yes; then
1416   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1417 fi
1418
1419 # Assume we'll default to using the included libiberty regex.
1420 gdb_use_included_regex=yes
1421
1422 # However, if the system regex is GNU regex, then default to *not*
1423 # using the included regex.
1424 AC_CACHE_CHECK(
1425   [for GNU regex],
1426   [gdb_cv_have_gnu_regex],
1427   [AC_TRY_COMPILE(
1428     [#include <gnu-versions.h>],
1429     [#define REGEX_INTERFACE_VERSION 1
1430 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1431 # error "Version mismatch"
1432 #endif],
1433     gdb_cv_have_gnu_regex=yes,
1434     gdb_cv_have_gnu_regex=no)])
1435 if test $gdb_cv_have_gnu_regex = yes; then
1436   gdb_use_included_regex=no
1437 fi
1438
1439 AC_ARG_WITH(included-regex,
1440   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1441   gdb_with_regex=$withval,
1442   gdb_with_regex=$gdb_use_included_regex)
1443 if test "$gdb_with_regex" = yes; then
1444   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1445     [Define to 1 if the regex included in libiberty should be used.])
1446 fi
1447
1448 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1449 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1450 [#include <sys/param.h>
1451 #include <sys/proc.h>
1452 ])
1453
1454 # See if <sys/lwp.h> defines `struct lwp`.
1455 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1456 [AC_TRY_COMPILE([#include <sys/param.h>
1457 #include <sys/lwp.h>], [struct lwp l;],
1458 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1459 if test $gdb_cv_struct_lwp = yes; then
1460   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1461             [Define to 1 if your system has struct lwp.])
1462 fi
1463
1464 # See if <machine/reg.h> degines `struct reg'.
1465 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1466 [AC_TRY_COMPILE([#include <sys/types.h>
1467 #include <machine/reg.h>], [struct reg r;],
1468 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1469 if test $gdb_cv_struct_reg = yes; then
1470   AC_DEFINE(HAVE_STRUCT_REG, 1,
1471             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1472 fi
1473
1474 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1475 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1476 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1477                  [#include <machine/reg.h>])
1478
1479 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1480 # Older amd64 Linux's don't have the fs_base and gs_base members of
1481 # `struct user_regs_struct'.
1482 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1483                  [], [], [#include <sys/user.h>])
1484
1485 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1486 AC_MSG_CHECKING(for PTRACE_GETREGS)
1487 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1488 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1489                 [PTRACE_GETREGS;],
1490                 [gdb_cv_have_ptrace_getregs=yes],
1491                 [gdb_cv_have_ptrace_getregs=no])])
1492 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1493 if test $gdb_cv_have_ptrace_getregs = yes; then
1494   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1495   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1496 fi
1497
1498 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1499 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1500 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1501 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1502                 [PTRACE_GETFPXREGS;],
1503                 [gdb_cv_have_ptrace_getfpxregs=yes],
1504                 [gdb_cv_have_ptrace_getfpxregs=no])])
1505 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1506 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1507   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1508   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1509 fi
1510
1511 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1512 AC_MSG_CHECKING(for PT_GETDBREGS)
1513 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1514 [AC_TRY_COMPILE([#include <sys/types.h>
1515 #include <sys/ptrace.h>],
1516                 [PT_GETDBREGS;],
1517                 [gdb_cv_have_pt_getdbregs=yes],
1518                 [gdb_cv_have_pt_getdbregs=no])])
1519 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1520 if test $gdb_cv_have_pt_getdbregs = yes; then
1521   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1522   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1523 fi
1524
1525 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1526 AC_MSG_CHECKING(for PT_GETXMMREGS)
1527 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1528 [AC_TRY_COMPILE([#include <sys/types.h>
1529 #include <sys/ptrace.h>],
1530                 [PT_GETXMMREGS;],
1531                 [gdb_cv_have_pt_getxmmregs=yes],
1532                 [gdb_cv_have_pt_getxmmregs=no])])
1533 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1534 if test $gdb_cv_have_pt_getxmmregs = yes; then
1535   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1536   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1537 fi
1538
1539 # Detect which type of /proc is in use, such as for Solaris.
1540
1541 if test "${target}" = "${host}"; then
1542   case "${host}" in
1543   *-*-sysv4.2* | *-*-sysv5* )
1544       AC_DEFINE(NEW_PROC_API, 1,
1545       [Define if you want to use new multi-fd /proc interface.])
1546       ;;
1547   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1548       AC_DEFINE(NEW_PROC_API, 1,
1549       [Define if you want to use new multi-fd /proc interface.])
1550       ;;
1551   mips-sgi-irix5*)
1552       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1553       AC_DEFINE([_KMEMUSER], 1,
1554       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1555        around a <sys/proc.h> problem on IRIX 5.])
1556       ;;
1557   esac
1558 fi
1559
1560 if test "$ac_cv_header_sys_procfs_h" = yes; then
1561   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1562   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1563   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1564   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1565   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1566   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1567   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1568   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1569   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1570   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1571   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1572
1573
1574   dnl Check for broken prfpregset_t type
1575
1576   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1577   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1578   dnl instead of the struct itself).  We detect this here, and work
1579   dnl around it in gdb_proc_service.h.
1580
1581   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1582     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1583     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1584       [AC_TRY_RUN([#include <sys/procfs.h>
1585        int main ()
1586        {
1587          if (sizeof (prfpregset_t) == sizeof (void *))
1588            return 1;
1589          return 0;
1590        }],
1591        gdb_cv_prfpregset_t_broken=no,
1592        gdb_cv_prfpregset_t_broken=yes,
1593        gdb_cv_prfpregset_t_broken=yes)])
1594     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1595     if test $gdb_cv_prfpregset_t_broken = yes; then
1596       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1597       [Define if the prfpregset_t type is broken.])
1598     fi
1599   fi
1600 fi
1601
1602 # Check if the compiler supports the `long long' type.
1603
1604 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1605                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1606 [[extern long long foo;]],
1607 [[switch (foo & 2) { case 0: return 1; }]])],
1608                                   gdb_cv_c_long_long=yes,
1609                                   gdb_cv_c_long_long=no)])
1610 if test $gdb_cv_c_long_long != yes; then
1611   # libdecnumber requires long long.
1612   AC_MSG_ERROR([Compiler must support long long for GDB.])
1613 fi
1614
1615 # Check if the compiler and runtime support printing long longs.
1616
1617 AC_CACHE_CHECK([for long long support in printf],
1618                gdb_cv_printf_has_long_long,
1619                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1620 [[char buf[32];
1621   long long l = 0;
1622   l = (l << 16) + 0x0123;
1623   l = (l << 16) + 0x4567;
1624   l = (l << 16) + 0x89ab;
1625   l = (l << 16) + 0xcdef;
1626   sprintf (buf, "0x%016llx", l);
1627   return (strcmp ("0x0123456789abcdef", buf));]])],
1628                               gdb_cv_printf_has_long_long=yes,
1629                               gdb_cv_printf_has_long_long=no,
1630                               gdb_cv_printf_has_long_long=no)])
1631 if test $gdb_cv_printf_has_long_long = yes; then
1632   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1633             [Define to 1 if the "%ll" format works to print long longs.])
1634 fi
1635
1636 # Check if the compiler and runtime support printing decfloats.
1637
1638 AC_CACHE_CHECK([for decfloat support in printf],
1639                gdb_cv_printf_has_decfloat,
1640                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1641 [[char buf[64];
1642   _Decimal32 d32 = 1.2345df;
1643   _Decimal64 d64 = 1.2345dd;
1644   _Decimal128 d128 = 1.2345dl;
1645   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1646   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1647                               gdb_cv_printf_has_decfloat=yes,
1648                               gdb_cv_printf_has_decfloat=no,
1649                               gdb_cv_printf_has_decfloat=no)])
1650 if test $gdb_cv_printf_has_decfloat = yes; then
1651   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1652             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1653 fi
1654
1655 # Check if the compiler supports the `long double' type.  We can't use
1656 # AC_C_LONG_DOUBLE because that one does additional checks on the
1657 # constants defined in <float.h> that fail on some systems,
1658 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1659
1660 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1661                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1662                                   gdb_cv_c_long_double=yes,
1663                                   gdb_cv_c_long_double=no)])
1664 if test $gdb_cv_c_long_double = yes; then
1665   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1666            [Define to 1 if the compiler supports long double.])
1667 fi
1668
1669 # Check if the compiler and runtime support printing long doubles.
1670
1671 AC_CACHE_CHECK([for long double support in printf],
1672                gdb_cv_printf_has_long_double,
1673                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1674 [[char buf[16];
1675   long double f = 3.141592653;
1676   sprintf (buf, "%Lg", f);
1677   return (strncmp ("3.14159", buf, 7));]])],
1678                               gdb_cv_printf_has_long_double=yes,
1679                               gdb_cv_printf_has_long_double=no,
1680                               gdb_cv_printf_has_long_double=no)])
1681 if test $gdb_cv_printf_has_long_double = yes; then
1682   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1683             [Define to 1 if the "%Lg" format works to print long doubles.])
1684 fi
1685
1686 # Check if the compiler and runtime support scanning long doubles.
1687
1688 AC_CACHE_CHECK([for long double support in scanf],
1689                gdb_cv_scanf_has_long_double,
1690                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1691 [[#include <stdio.h>]],
1692 [[char *buf = "3.141592653";
1693   long double f = 0;
1694   sscanf (buf, "%Lg", &f);
1695   return !(f > 3.14159 && f < 3.14160);]])],
1696                               gdb_cv_scanf_has_long_double=yes,
1697                               gdb_cv_scanf_has_long_double=no,
1698                               gdb_cv_scanf_has_long_double=no)])
1699 if test $gdb_cv_scanf_has_long_double = yes; then
1700   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1701             [Define to 1 if the "%Lg" format works to scan long doubles.])
1702 fi
1703
1704 case ${host_os} in
1705 aix*)
1706   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1707     SAVE_LDFLAGS=$LDFLAGS
1708
1709     case $GCC in
1710     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1711     *) gdb_cv_bigtoc=-bbigtoc ;;
1712     esac
1713
1714     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1715     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1716     LDFLAGS="${SAVE_LDFLAGS}"
1717   ])
1718   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1719   ;;
1720 esac
1721
1722 AC_MSG_CHECKING(for the dynamic export flag)
1723 dynamic_list=false
1724 if test "${gdb_native}" = yes; then
1725    # The dynamically loaded libthread_db needs access to symbols in the gdb
1726    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1727    # may not be supported there.
1728    old_LDFLAGS="$LDFLAGS"
1729    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1730    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1731    LDFLAGS="$LDFLAGS $RDYNAMIC"
1732    if test "${have_libpython}" = no; then
1733      AC_TRY_LINK([], [], [dynamic_list=true])
1734    else
1735      # Workaround http://bugs.python.org/issue4434 where static
1736      # libpythonX.Y.a would get its symbols required for
1737      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1738      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1739      old_CFLAGS="$CFLAGS"
1740      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1741      old_LIBS="$LIBS"
1742      LIBS="$LIBS $PYTHON_LIBS"
1743      AC_RUN_IFELSE(
1744        AC_LANG_PROGRAM(
1745          [#include "]${have_libpython}[/Python.h"],
1746          [int err;
1747           Py_Initialize ();
1748           err = PyRun_SimpleString ("import itertools\n");
1749           Py_Finalize ();
1750           return err == 0 ? 0 : 1;]),
1751        [dynamic_list=true], [], [true])
1752      LIBS="$old_LIBS"
1753      CFLAGS="$old_CFLAGS"
1754    fi
1755    LDFLAGS="$old_LDFLAGS"
1756 fi
1757 if $dynamic_list; then
1758   found="-Wl,--dynamic-list"
1759   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1760 else
1761   found="-rdynamic"
1762   RDYNAMIC="-rdynamic"
1763 fi
1764 AC_SUBST(RDYNAMIC)
1765 AC_MSG_RESULT($found)
1766
1767 dnl For certain native configurations, we need to check whether thread
1768 dnl support can be built in or not.
1769 dnl
1770 dnl Note that we only want this if we are both native (host == target),
1771 dnl and not doing a canadian cross build (build == host).
1772
1773 if test ${build} = ${host} -a ${host} = ${target} ; then
1774    case ${host_os} in
1775    solaris*)
1776       # See if thread_db library is around for Solaris thread debugging.
1777       # Note that we must explicitly test for version 1 of the library
1778       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1779       # the same API.
1780       AC_MSG_CHECKING(for Solaris thread debugging library)
1781       if test -f /usr/lib/libthread_db.so.1 ; then
1782          AC_MSG_RESULT(yes)
1783          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1784          [Define if using Solaris thread debugging.])
1785          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1786          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1787          AC_CHECK_LIB(dl, dlopen)
1788          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1789          # Sun randomly tweaked the prototypes in <proc_service.h>
1790          # at one point.
1791          AC_MSG_CHECKING(if <proc_service.h> is old)
1792          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1793             AC_TRY_COMPILE([
1794                 #include <proc_service.h>
1795                 ps_err_e ps_pdwrite
1796                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1797             ],, gdb_cv_proc_service_is_old=no,
1798                 gdb_cv_proc_service_is_old=yes)
1799          ])
1800          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1801          if test $gdb_cv_proc_service_is_old = yes; then
1802             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1803             [Define if <proc_service.h> on solaris uses int instead of
1804              size_t, and assorted other type changes.])
1805          fi
1806       else
1807          AC_MSG_RESULT(no)
1808       fi
1809       ;;
1810    aix*)
1811       AC_MSG_CHECKING(for AiX thread debugging library)
1812       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1813                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1814                                    [#ifndef PTHDB_VERSION_3
1815                                     #error
1816                                     #endif],
1817                                    gdb_cv_have_aix_thread_debug=yes,
1818                                    gdb_cv_have_aix_thread_debug=no)])
1819       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1820       if test $gdb_cv_have_aix_thread_debug = yes; then
1821          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1822          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1823          LIBS="$LIBS -lpthdebug"
1824
1825          # Older versions of AIX do not provide the declaration for
1826          # the getthrds function (it appears that it was introduced
1827          # with AIX 6.x).
1828          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1829       fi
1830       ;;
1831    esac
1832    AC_SUBST(CONFIG_LDFLAGS)
1833 fi
1834
1835 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1836 dnl other error codes.
1837 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1838    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1839                   gdb_cv_thread_db_h_has_td_notalloc,
1840      AC_TRY_COMPILE(
1841        [#include <thread_db.h>],
1842        [int i = TD_NOTALLOC;],
1843        gdb_cv_thread_db_h_has_td_notalloc=yes,
1844        gdb_cv_thread_db_h_has_td_notalloc=no
1845      )
1846    )
1847    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1848                   gdb_cv_thread_db_h_has_td_version,
1849      AC_TRY_COMPILE(
1850        [#include <thread_db.h>],
1851        [int i = TD_VERSION;],
1852        gdb_cv_thread_db_h_has_td_version=yes,
1853        gdb_cv_thread_db_h_has_td_version=no
1854      )
1855    )
1856    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1857                   gdb_cv_thread_db_h_has_td_notls,
1858      AC_TRY_COMPILE(
1859        [#include <thread_db.h>],
1860        [int i = TD_NOTLS;],
1861        gdb_cv_thread_db_h_has_td_notls=yes,
1862        gdb_cv_thread_db_h_has_td_notls=no
1863      )
1864    )
1865 fi
1866 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1867   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1868             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1869 fi
1870 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1871   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1872             [Define if <thread_db.h> has the TD_VERSION error code.])
1873 fi
1874 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1875   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1876             [Define if <thread_db.h> has the TD_NOTLS error code.])
1877 fi
1878
1879 dnl See if we have a sys/syscall header file that has __NR_tkill.
1880 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1881    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1882                   gdb_cv_sys_syscall_h_has_tkill,
1883      AC_TRY_COMPILE(
1884        [#include <sys/syscall.h>],
1885        [int i = __NR_tkill;],
1886        gdb_cv_sys_syscall_h_has_tkill=yes,
1887        gdb_cv_sys_syscall_h_has_tkill=no
1888      )
1889    )
1890 fi
1891 dnl See if we can issue tkill syscall.
1892 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1893   AC_CHECK_FUNC(syscall,
1894     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1895   )
1896 fi
1897
1898 dnl Check if we can disable the virtual address space randomization.
1899 dnl The functionality of setarch -R.
1900 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1901 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1902 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1903 #       define ADDR_NO_RANDOMIZE 0x0040000
1904 #      endif
1905        /* Test the flag could be set and stays set.  */
1906        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1907        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1908            return 1])])
1909 AC_RUN_IFELSE([PERSONALITY_TEST],
1910               [have_personality=true],
1911               [have_personality=false],
1912               [AC_LINK_IFELSE([PERSONALITY_TEST],
1913                               [have_personality=true],
1914                               [have_personality=false])])
1915 if $have_personality
1916 then
1917     AC_DEFINE([HAVE_PERSONALITY], 1,
1918               [Define if you support the personality syscall.])
1919 fi
1920
1921 dnl Set the host's .gdbinit filename.
1922 case $host_os in
1923   go32* | *djgpp*)
1924     gdbinit=gdb.ini
1925     ;;
1926   *)
1927     gdbinit=.gdbinit
1928     ;;
1929 esac
1930 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1931
1932 dnl Handle optional features that can be enabled.
1933
1934 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1935 # except that the argument to --with-sysroot is optional.
1936 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1937 if test "x$with_sysroot" = xyes; then
1938   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1939 fi
1940 AC_ARG_WITH(sysroot,
1941   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1942                  [search for usr/lib et al within DIR]),
1943   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1944 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1945               [search for usr/lib et al within DIR])
1946 AC_SUBST(TARGET_SYSTEM_ROOT)
1947 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1948
1949 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1950     [automatically load a system-wide gdbinit file],
1951     [])
1952
1953 AC_ARG_ENABLE(werror,
1954   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1955   [case "${enableval}" in
1956      yes | y) ERROR_ON_WARNING="yes" ;;
1957      no | n)  ERROR_ON_WARNING="no" ;;
1958      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1959    esac])
1960
1961 # Enable -Werror by default when using gcc.  Turn it off for releases.
1962 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1963     ERROR_ON_WARNING=yes
1964 fi
1965
1966 WERROR_CFLAGS=""
1967 if test "${ERROR_ON_WARNING}" = yes ; then
1968     WERROR_CFLAGS="-Werror"
1969 fi
1970
1971 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1972 -Wpointer-sign \
1973 -Wno-unused -Wunused-value -Wunused-function \
1974 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1975 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1976 -Wold-style-declaration -Wold-style-definition"
1977
1978 # Enable -Wno-format by default when using gcc on mingw since many
1979 # GCC versions complain about %I64.
1980 case "${host}" in
1981   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1982   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1983 esac
1984
1985 AC_ARG_ENABLE(build-warnings,
1986 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1987 [case "${enableval}" in
1988   yes)  ;;
1989   no)   build_warnings="-w";;
1990   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1991         build_warnings="${build_warnings} ${t}";;
1992   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1993         build_warnings="${t} ${build_warnings}";;
1994   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1995 esac
1996 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1997   echo "Setting compiler warning flags = $build_warnings" 6>&1
1998 fi])dnl
1999 AC_ARG_ENABLE(gdb-build-warnings,
2000 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
2001 [case "${enableval}" in
2002   yes)  ;;
2003   no)   build_warnings="-w";;
2004   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2005         build_warnings="${build_warnings} ${t}";;
2006   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2007         build_warnings="${t} ${build_warnings}";;
2008   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2009 esac
2010 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2011   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
2012 fi])dnl
2013 WARN_CFLAGS=""
2014 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2015 then
2016     AC_MSG_CHECKING(compiler warning flags)
2017     # Separate out the -Werror flag as some files just cannot be
2018     # compiled with it enabled.
2019     for w in ${build_warnings}; do
2020         case $w in
2021         -Werr*) WERROR_CFLAGS=-Werror ;;
2022         *) # Check that GCC accepts it
2023             saved_CFLAGS="$CFLAGS"
2024             CFLAGS="$CFLAGS $w"
2025             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2026             CFLAGS="$saved_CFLAGS"
2027         esac
2028     done
2029     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2030 fi
2031 AC_SUBST(WARN_CFLAGS)
2032 AC_SUBST(WERROR_CFLAGS)
2033
2034 # In the Cygwin environment, we need some additional flags.
2035 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2036 [AC_EGREP_CPP(^lose$, [
2037 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2038 lose
2039 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2040
2041
2042 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2043 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2044 case ${host} in
2045   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2046   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2047   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2048 esac
2049 AC_SUBST(SER_HARDWIRE)
2050
2051 # libreadline needs libuser32.a in a cygwin environment
2052 WIN32LIBS=
2053 if test x$gdb_cv_os_cygwin = xyes; then
2054     WIN32LIBS="-luser32"
2055     case "${target}" in
2056         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2057         ;;
2058     esac
2059 fi
2060
2061 # The ser-tcp.c module requires sockets.
2062 case ${host} in
2063   *mingw32*)
2064     AC_DEFINE(USE_WIN32API, 1,
2065               [Define if we should use the Windows API, instead of the
2066                POSIX API.  On Windows, we use the Windows API when
2067                building for MinGW, but the POSIX API when building
2068                for Cygwin.])
2069     WIN32LIBS="$WIN32LIBS -lws2_32"
2070     ;;
2071 esac
2072 AC_SUBST(WIN32LIBS)
2073
2074 # Add ELF support to GDB, but only if BFD includes ELF support.
2075 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2076                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2077 if test $gdb_cv_var_elf = yes; then
2078   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2079   AC_DEFINE(HAVE_ELF, 1,
2080             [Define if ELF support should be included.])
2081   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2082   if test "$plugins" = "yes"; then
2083     AC_SEARCH_LIBS(dlopen, dl)
2084   fi
2085 fi
2086
2087 # Add macho support to GDB, but only if BFD includes it.
2088 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2089                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2090 if test $gdb_cv_var_macho = yes; then
2091   CONFIG_OBS="$CONFIG_OBS machoread.o"
2092 fi
2093
2094 # Add SOM support to GDB, but only if BFD includes it.
2095 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2096                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2097 if test $gdb_cv_var_som = yes; then
2098   CONFIG_OBS="$CONFIG_OBS somread.o"
2099 fi
2100
2101 # Add any host-specific objects to GDB.
2102 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2103
2104 # If building on ELF, look for lzma support for embedded compressed debug info.
2105 if test $gdb_cv_var_elf = yes; then
2106   AC_ARG_WITH(lzma,
2107     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2108     [], [with_lzma=auto])
2109   AC_MSG_CHECKING([whether to use lzma])
2110   AC_MSG_RESULT([$with_lzma])
2111
2112   if test "${with_lzma}" != no; then
2113     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2114                           [lzma_index_iter iter;
2115                            lzma_index_iter_init (&iter, 0);
2116                            lzma_mf_is_supported (LZMA_MF_HC3);])
2117     if test "$HAVE_LIBLZMA" != yes; then
2118       if test "$with_lzma" = yes; then
2119         AC_MSG_ERROR([missing liblzma for --with-lzma])
2120       fi
2121     fi
2122   fi
2123 fi
2124
2125 LIBGUI="../libgui/src/libgui.a"
2126 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2127 AC_SUBST(LIBGUI)
2128 AC_SUBST(GUI_CFLAGS_X)
2129
2130 WIN32LDAPP=
2131 AC_SUBST(WIN32LIBS)
2132 AC_SUBST(WIN32LDAPP)
2133
2134 case "${host}" in
2135 *-*-cygwin* | *-*-mingw* )
2136     configdir="win"
2137     ;;
2138 *)
2139     configdir="unix"
2140     ;;
2141 esac
2142
2143 GDBTKLIBS=
2144 if test "${enable_gdbtk}" = "yes"; then
2145
2146     # Gdbtk must have an absolute path to srcdir in order to run
2147     # properly when not installed.
2148     here=`pwd`
2149     cd ${srcdir}
2150     GDBTK_SRC_DIR=`pwd`
2151     cd $here
2152
2153     SC_PATH_TCLCONFIG
2154
2155     # If $no_tk is nonempty, then we can't do Tk, and there is no
2156     # point to doing Tcl.
2157     SC_PATH_TKCONFIG
2158
2159     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2160         SC_LOAD_TCLCONFIG
2161
2162         # Check for in-tree tcl
2163         here=`pwd`
2164         cd ${srcdir}/..
2165         topdir=`pwd`
2166         cd ${here}
2167
2168         intree="no"
2169         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2170           intree="yes"
2171         fi
2172
2173         # Find Tcl private headers
2174         if test x"${intree}" = xno; then
2175           CY_AC_TCL_PRIVATE_HEADERS
2176           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2177           TCL_LIBRARY="${TCL_LIB_SPEC}"
2178           TCL_DEPS=""
2179         else
2180           # If building tcl in the same src tree, private headers
2181           # are not needed, but we need to be sure to use the right
2182           # headers library
2183           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2184           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2185           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2186         fi
2187         AC_SUBST(TCL_INCLUDE)
2188         AC_SUBST(TCL_LIBRARY)
2189         AC_SUBST(TCL_DEPS)
2190
2191         SC_LOAD_TKCONFIG
2192
2193         # Check for in-tree Tk
2194         intree="no"
2195         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2196           intree="yes"
2197         fi
2198
2199         # Find Tk private headers
2200         if test x"${intree}" = xno; then
2201           CY_AC_TK_PRIVATE_HEADERS
2202           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2203           TK_LIBRARY=${TK_LIB_SPEC}
2204           TK_DEPS=""
2205         else
2206           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2207           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2208           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2209         fi
2210         AC_SUBST(TK_INCLUDE)
2211         AC_SUBST(TK_LIBRARY)
2212         AC_SUBST(TK_DEPS)
2213         AC_SUBST(TK_XINCLUDES)
2214
2215         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2216
2217         # Include some libraries that Tcl and Tk want.
2218         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2219         # Yes, the ordering seems wrong here.  But it isn't.
2220         # TK_LIBS is the list of libraries that need to be linked
2221         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2222         # were in LIBS then any link tests after this point would
2223         # try to include things like `$(LIBGUI)', which wouldn't work.
2224         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2225
2226         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2227         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2228         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2229         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2230         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2231         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2232         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2233
2234         if test x$gdb_cv_os_cygwin = xyes; then
2235           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2236           WIN32LDAPP="-Wl,--subsystem,console"
2237           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2238         fi
2239
2240         AC_CONFIG_SUBDIRS(gdbtk)
2241     fi
2242 fi
2243
2244 AC_SUBST(X_CFLAGS)
2245 AC_SUBST(X_LDFLAGS)
2246 AC_SUBST(X_LIBS)
2247 AC_SUBST(GDBTKLIBS)
2248 AC_SUBST(GDBTK_CFLAGS)
2249 AC_SUBST(GDBTK_SRC_DIR)
2250
2251 AC_PATH_X
2252
2253 # Unlike the sim directory, whether a simulator is linked is controlled by
2254 # presence of a gdb_sim definition in the target configure.tgt entry.
2255 # This code just checks for a few cases where we'd like to ignore those
2256 # definitions, even when they're present in the '.mt' file.  These cases
2257 # are when --disable-sim is specified, or if the simulator directory is
2258 # not part of the source tree.
2259 #
2260 AC_ARG_ENABLE(sim,
2261 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2262 [echo "enable_sim = $enable_sim";
2263  echo "enableval = ${enableval}";
2264  case "${enableval}" in
2265   yes) ignore_sim=false ;;
2266   no)  ignore_sim=true ;;
2267   *)   ignore_sim=false ;;
2268  esac],
2269 [ignore_sim=false])
2270
2271 if test ! -d "${srcdir}/../sim"; then
2272   ignore_sim=true
2273 fi
2274
2275 SIM=
2276 SIM_OBS=
2277 if test "${ignore_sim}" = "false"; then
2278   if test x"${gdb_sim}" != x ; then
2279     SIM="${gdb_sim}"
2280     SIM_OBS="remote-sim.o"
2281     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2282   fi
2283 fi
2284 AC_SUBST(SIM)
2285 AC_SUBST(SIM_OBS)
2286
2287 AC_SUBST(ENABLE_CFLAGS)
2288 AC_SUBST(PROFILE_CFLAGS)
2289
2290 AC_SUBST(CONFIG_OBS)
2291 AC_SUBST(CONFIG_DEPS)
2292 AC_SUBST(CONFIG_SRCS)
2293 AC_SUBST(CONFIG_ALL)
2294 AC_SUBST(CONFIG_CLEAN)
2295 AC_SUBST(CONFIG_INSTALL)
2296 AC_SUBST(CONFIG_UNINSTALL)
2297
2298 # List of host floatformats.
2299 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2300 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2301 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2302
2303 # target_subdir is used by the testsuite to find the target libraries.
2304 target_subdir=
2305 if test "${host}" != "${target}"; then
2306     target_subdir="${target_alias}/"
2307 fi
2308 AC_SUBST(target_subdir)
2309
2310 frags=
2311 if test "${gdb_native}" = "yes"; then
2312   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2313   if test ! -f ${host_makefile_frag}; then
2314     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2315   fi
2316   frags="$frags $host_makefile_frag"
2317 else
2318   host_makefile_frag=/dev/null
2319 fi
2320
2321 AC_SUBST_FILE(host_makefile_frag)
2322 AC_SUBST(frags)
2323
2324 changequote(,)dnl
2325 if test "${gdb_native}" = "yes"; then
2326 # We pick this up from the host configuration file (.mh) because we
2327 # do not have a native configuration Makefile fragment.
2328 nativefile=`sed -n '
2329 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2330 ' ${host_makefile_frag}`
2331 fi
2332 changequote([,])
2333
2334 if test x"${gdb_osabi}" != x ; then
2335     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2336                        [Define to the default OS ABI for this configuration.])
2337 fi
2338
2339 # Enable multi-ice-gdb-server.
2340 AC_ARG_ENABLE(multi-ice,
2341 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2342   [case $enableval in
2343     yes | no)
2344       ;;
2345     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2346   esac])
2347 if test "x$enable_multi_ice" = xyes; then
2348    AC_CONFIG_SUBDIRS(multi-ice)
2349 fi
2350
2351 AC_ARG_ENABLE(gdbserver,
2352 AS_HELP_STRING([--enable-gdbserver],
2353                [automatically build gdbserver (yes/no/auto, default is auto)]),
2354 [case "${enableval}" in
2355   yes| no|auto) ;;
2356   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2357 esac],[enable_gdbserver=auto])
2358
2359 # We only build gdbserver automatically in a native configuration, and
2360 # only if the user did not explicitly disable its build.
2361 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2362   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2363   if test "x$build_gdbserver" = xyes; then
2364     AC_MSG_RESULT(yes)
2365     AC_CONFIG_SUBDIRS(gdbserver)
2366     gdbserver_build_enabled=yes
2367   else
2368     AC_MSG_RESULT(no)
2369   fi
2370 fi
2371
2372 # If the user explicitly request the gdbserver to be built, verify that
2373 # we were in fact able to enable it.
2374 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2375   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2376 fi
2377
2378 # Check for babeltrace and babeltrace-ctf
2379 AC_ARG_WITH(babeltrace,
2380   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2381   [], [with_babeltrace=auto])
2382 AC_MSG_CHECKING([whether to use babeltrace])
2383 AC_MSG_RESULT([$with_babeltrace])
2384
2385 if test "x$with_babeltrace" = "xno"; then
2386   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2387 else
2388   # Append -Werror to CFLAGS so that configure can catch the warning
2389   # "assignment from incompatible pointer type", which is related to
2390   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2391   # in GDB, while babeltrace 1.0.3 is broken.
2392   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2393   # safe to save and restore CFLAGS here.
2394   saved_CFLAGS=$CFLAGS
2395   CFLAGS="$CFLAGS -Werror"
2396   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2397                         [#include <babeltrace/babeltrace.h>
2398                          #include <babeltrace/ctf/events.h>
2399                          #include <babeltrace/ctf/iterator.h>],
2400                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2401                         struct bt_ctf_event *event = NULL;
2402                         const struct bt_definition *scope;
2403
2404                         scope = bt_ctf_get_top_level_scope (event,
2405                                                            BT_STREAM_EVENT_HEADER);
2406                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2407                         ])
2408   CFLAGS=$saved_CFLAGS
2409
2410   if test "$HAVE_LIBBABELTRACE" != yes; then
2411      if test "$with_babeltrace" = yes; then
2412        AC_MSG_ERROR([babeltrace is missing or unusable])
2413      else
2414        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2415      fi
2416   fi
2417 fi
2418
2419 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2420 # to an empty version.
2421
2422 files=
2423 links=
2424
2425 rm -f nm.h
2426 if test "${nativefile}" != ""; then
2427     case "${nativefile}" in
2428       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2429       * ) GDB_NM_FILE="${nativefile}"
2430     esac
2431     files="${files} ${GDB_NM_FILE}"
2432     links="${links} nm.h"
2433     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2434 fi
2435 AC_SUBST(GDB_NM_FILE)
2436
2437 AC_LINK_FILES($files, $links)
2438
2439 dnl Check for exe extension set on certain hosts (e.g. Win32)
2440 AC_EXEEXT
2441
2442 dnl  Detect the character set used by this host.
2443 dnl  At the moment, we just assume it's UTF-8.
2444 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2445           [Define to be a string naming the default host character set.])
2446
2447 # Undo the $ec_script escaping suitable for Makefile.
2448 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2449 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2450 if test "x$GDB_TRANSFORM_NAME" = x; then
2451   GDB_TRANSFORM_NAME=gdb
2452 fi
2453 AC_SUBST(GDB_TRANSFORM_NAME)
2454 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2455 if test "x$GCORE_TRANSFORM_NAME" = x; then
2456   GCORE_TRANSFORM_NAME=gcore
2457 fi
2458 AC_SUBST(GCORE_TRANSFORM_NAME)
2459 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2460
2461 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2462 [
2463 case x$CONFIG_HEADERS in
2464 xconfig.h:config.in)
2465 echo > stamp-h ;;
2466 esac
2467 ])
2468
2469 exit 0