gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl List of object files and targets accumulated by configure.
  46
  47 CONFIG_OBS=
  48 CONFIG_DEPS=
  49 CONFIG_SRCS=
  50 ENABLE_CFLAGS=
  51
  52 CONFIG_ALL=
  53 CONFIG_CLEAN=
  54 CONFIG_INSTALL=
  55 CONFIG_UNINSTALL=
  56
  57 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  58
  59 CY_GNU_GETTEXT
  60
  61 localedir='${datadir}/locale'
  62 AC_SUBST(localedir)
  63
  64 if test "x$POSUB" != x; then
  65
  66   dnl Lifted from GCC's config/gettext.m4.
  67   AC_MSG_CHECKING(for catalogs to be installed)
  68   # Look for .po and .gmo files in the source directory.
  69   CATALOGS=  AC_SUBST(CATALOGS)
  70   XLINGUAS=
  71   for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
  72     # If there aren't any .gmo files the shell will give us the
  73     # literal string "../path/to/srcdir/po/*.gmo" which has to be
  74     # weeded out.
  75     case "$cat" in *\**)
  76       continue;;
  77     esac
  78     # The quadruple backslash is collapsed to a double backslash
  79     # by the backticks, then collapsed again by the double quotes,
  80     # leaving us with one backslash in the sed expression (right
  81     # before the dot that mustn't act as a wildcard).
  82     cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
  83     lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
  84     # The user is allowed to set LINGUAS to a list of languages to
  85     # install catalogs for.  If it's empty that means "all of them."
  86     if test "x$LINGUAS" = x; then
  87       CATALOGS="$CATALOGS $cat"
  88       XLINGUAS="$XLINGUAS $lang"
  89     else
  90       case "$LINGUAS" in *$lang*)
  91         CATALOGS="$CATALOGS $cat"
  92         XLINGUAS="$XLINGUAS $lang"
  93         ;;
  94       esac
  95     fi
  96   done
  97   LINGUAS="$XLINGUAS"
  98   AC_MSG_RESULT($LINGUAS)
  99
 100    CONFIG_ALL="$CONFIG_ALL all-po"
 101    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
 102    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
 103    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
 104 fi
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 debugdir=${libdir}/debug
 111
 112 AC_ARG_WITH(separate-debug-dir,
 113 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
 114 [debugdir="${withval}"])
 115
 116 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 117               [Global directory for separate debug files. ])
 118 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 119
 120 AC_CONFIG_SUBDIRS(doc testsuite)
 121
 122 . $srcdir/configure.host
 123
 124 . $srcdir/configure.tgt
 125
 126 # Fetch the default architecture and default target vector from BFD.
 127 targ=$target; . $srcdir/../bfd/config.bfd
 128
 129 # We only want the first architecture, so strip off the others if
 130 # there is more than one.
 131 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 132
 133 if test "x$targ_archs" != x; then
 134   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 135     [Define to BFD's default architecture. ])
 136 fi
 137 if test "x$targ_defvec" != x; then
 138   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 139     [Define to BFD's default target vector. ])
 140 fi
 141
 142 AC_ARG_PROGRAM
 143
 144 # The CLI cannot be disabled yet, but may be in the future.
 145
 146 # Enable CLI.
 147 AC_ARG_ENABLE(gdbcli,
 148 [  --disable-gdbcli        disable command-line interface (CLI)],
 149   [case $enableval in
 150     yes)
 151       ;;
 152     no)
 153       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 154     *)
 155       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 156   esac],
 157   [enable_gdbcli=yes])
 158 if test x"$enable_gdbcli" = xyes; then
 159   if test -d $srcdir/cli; then
 160     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 161     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 162     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 163     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 164   fi
 165 fi
 166
 167 # Enable MI.
 168 AC_ARG_ENABLE(gdbmi,
 169 [  --disable-gdbmi         disable machine-interface (MI)],
 170   [case $enableval in
 171     yes | no)
 172       ;;
 173     *)
 174       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 175   esac],
 176   [enable_gdbmi=yes])
 177 if test x"$enable_gdbmi" = xyes; then
 178   if test -d $srcdir/mi; then
 179     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 180     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 181     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 182     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 183   fi
 184 fi
 185
 186 # Enable TUI.
 187 AC_ARG_ENABLE(tui,
 188 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 189   [case $enableval in
 190     yes | no)
 191       ;;
 192     *)
 193       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 194   esac],enable_tui=yes)
 195
 196 # Enable gdbtk.
 197 AC_ARG_ENABLE(gdbtk,
 198 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 199   [case $enableval in
 200     yes | no)
 201       ;;
 202     *)
 203       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 204   esac],
 205   [if test -d $srcdir/gdbtk; then
 206     enable_gdbtk=yes
 207   else
 208     enable_gdbtk=no
 209   fi])
 210 # We unconditionally disable gdbtk tests on selected platforms.
 211 case $host_os in
 212   go32* | windows*)
 213     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 214     enable_gdbtk=no ;;
 215 esac
 216
 217 # Libunwind support.
 218 AC_ARG_WITH(libunwind,
 219 [  --with-libunwind            Use libunwind frame unwinding support],
 220 [case "${withval}" in
 221   yes)  enable_libunwind=yes ;;
 222   no)   enable_libunwind=no ;;
 223   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 224 esac],[
 225   AC_CHECK_HEADERS(libunwind.h)
 226   AC_CHECK_HEADERS(libunwind-ia64.h)
 227   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 228     enable_libunwind=yes;
 229   fi
 230 ])
 231
 232 if test x"$enable_libunwind" = xyes; then
 233   AC_CHECK_HEADERS(libunwind.h)
 234   AC_CHECK_HEADERS(libunwind-ia64.h)
 235   AC_DEFINE(HAVE_LIBUNWIND, 1)
 236   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 237   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 238   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 239 fi
 240
 241 # Profiling support.
 242 AC_ARG_ENABLE(profiling,
 243 [  --enable-profiling      enable profiling of GDB],
 244   [case $enableval in
 245     yes | no)
 246       ;;
 247     *)
 248       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 249   esac],
 250  [enable_profiling=no])
 251
 252 AC_CHECK_FUNCS(monstartup _mcleanup)
 253 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 254 [AC_TRY_LINK(
 255 [#include <stdlib.h>
 256 extern char _etext;
 257 ],
 258 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 259 if test $ac_cv_var__etext = yes; then
 260   AC_DEFINE(HAVE__ETEXT, 1,
 261             [Define to 1 if your system has the _etext variable. ])
 262 fi
 263 if test "$enable_profiling" = yes ; then
 264   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 265     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 266   fi
 267   PROFILE_CFLAGS=-pg
 268   OLD_CFLAGS="$CFLAGS"
 269   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 270
 271   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 272     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 273      ac_cv_cc_supports_pg=no)])
 274
 275   if test $ac_cv_cc_supports_pg = no; then
 276     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 277   fi
 278
 279   CFLAGS="$OLD_CFLAGS"
 280 fi
 281
 282 # --------------------- #
 283 # Checks for programs.  #
 284 # --------------------- #
 285
 286 AC_PROG_AWK
 287 AC_PROG_INSTALL
 288 AC_PROG_LN_S
 289 AC_PROG_RANLIB
 290 AC_PROG_YACC
 291
 292 AC_CHECK_TOOL(AR, ar)
 293 AC_CHECK_TOOL(DLLTOOL, dlltool)
 294 AC_CHECK_TOOL(WINDRES, windres)
 295
 296 # Needed for GNU/Hurd.
 297 AC_CHECK_TOOL(MIG, mig)
 298
 299 # ---------------------- #
 300 # Checks for libraries.  #
 301 # ---------------------- #
 302
 303 # We might need to link with -lm; most simulators need it.
 304 AC_CHECK_LIB(m, main)
 305
 306 # We need to link with -lw to get `wctype' on Solaris before Solaris
 307 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 308 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 309 # is known to have this problem).  Therefore we avoid libw if we can.
 310 AC_CHECK_FUNC(wctype, [],
 311   [AC_CHECK_LIB(w, wctype)])
 312
 313 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 314 AC_SEARCH_LIBS(gethostbyname, nsl)
 315
 316 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 317 AC_SEARCH_LIBS(socketpair, socket)
 318
 319 # For the TUI, we need enhanced curses functionality.
 320 #
 321 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 322 # curses library because the latter might not provide all the
 323 # functionality we need.  However, this leads to problems on systems
 324 # where the linker searches /usr/local/lib, but the compiler doesn't
 325 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 326 # default installation of ncurses on alpha*-dec-osf* will lead to such
 327 # a situation.
 328 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 329
 330 # Since GDB uses Readline, we need termcap functionality.  In many
 331 # cases this will be provided by the curses library, but some systems
 332 # have a seperate termcap library, or no curses library at all.
 333
 334 case $host_os in
 335   cygwin*)
 336     if test -d $srcdir/libtermcap; then
 337       LIBS="../libtermcap/libtermcap.a $LIBS"
 338       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 339     fi ;;
 340   go32* | *djgpp*)
 341     ac_cv_search_tgetent="none required"
 342     ;;
 343 esac
 344
 345 # These are the libraries checked by Readline.
 346 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 347
 348 if test "$ac_cv_search_tgetent" = no; then
 349   AC_MSG_ERROR([no termcap library found])
 350 fi
 351
 352 # ------------------------- #
 353 # Checks for header files.  #
 354 # ------------------------- #
 355
 356 AC_HEADER_DIRENT
 357 AC_HEADER_STAT
 358 AC_HEADER_STDC
 359 AC_CHECK_HEADERS(nlist.h)
 360 AC_CHECK_HEADERS(link.h, [], [],
 361 [#if HAVE_SYS_TYPES_H
 362 # include <sys/types.h>
 363 #endif
 364 #if HAVE_NLIST_H
 365 # include <nlist.h>
 366 #endif
 367 ])
 368 AC_CHECK_HEADERS(machine/reg.h)
 369 AC_CHECK_HEADERS(poll.h sys/poll.h)
 370 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 371 AC_CHECK_HEADERS(stddef.h)
 372 AC_CHECK_HEADERS(stdlib.h)
 373 AC_CHECK_HEADERS(stdint.h)
 374 AC_CHECK_HEADERS(string.h memory.h strings.h)
 375 AC_CHECK_HEADERS(sys/fault.h)
 376 AC_CHECK_HEADERS(sys/file.h)
 377 AC_CHECK_HEADERS(sys/filio.h)
 378 AC_CHECK_HEADERS(sys/ioctl.h)
 379 AC_CHECK_HEADERS(sys/param.h)
 380 AC_CHECK_HEADERS(sys/proc.h, [], [],
 381 [#if HAVE_SYS_PARAM_H
 382 # include <sys/param.h>
 383 #endif
 384 ])
 385 AC_CHECK_HEADERS(sys/procfs.h)
 386 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 387 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 388 AC_CHECK_HEADERS(sys/select.h)
 389 AC_CHECK_HEADERS(sys/syscall.h)
 390 AC_CHECK_HEADERS(sys/types.h)
 391 AC_CHECK_HEADERS(sys/user.h, [], [],
 392 [#if HAVE_SYS_PARAM_H
 393 # include <sys/param.h>
 394 #endif
 395 ])
 396 AC_CHECK_HEADERS(sys/wait.h wait.h)
 397 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 398 AC_CHECK_HEADERS(unistd.h)
 399
 400 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 401 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 402 # think that we don't have <curses.h> if we're using GCC.
 403 case $host_os in
 404   solaris2.[[789]])
 405     if test "$GCC" = yes; then
 406       AC_DEFINE(_MSE_INT_H, 1,
 407         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 408    Solaris 2.[789] when using GCC. ]])
 409     fi ;;
 410 esac
 411 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 412 AC_CHECK_HEADERS(ncurses/term.h)
 413 AC_CHECK_HEADERS(term.h, [], [],
 414 [#if HAVE_CURSES_H
 415 # include <curses.h>
 416 #endif
 417 ])
 418
 419 # FIXME: kettenis/20030102: In most cases we include these
 420 # unconditionally, so what's the point in checking these?
 421 AC_CHECK_HEADERS(ctype.h time.h)
 422
 423 # ------------------------- #
 424 # Checks for declarations.  #
 425 # ------------------------- #
 426
 427 gcc_AC_CHECK_DECLS(getopt)
 428
 429 # ----------------------- #
 430 # Checks for structures.  #
 431 # ----------------------- #
 432
 433 AC_CHECK_MEMBERS([struct stat.st_blocks])
 434
 435 # ------------------ #
 436 # Checks for types.  #
 437 # ------------------ #
 438
 439 AC_TYPE_SIGNAL
 440
 441 # ------------------------------------- #
 442 # Checks for compiler characteristics.  #
 443 # ------------------------------------- #
 444
 445 AC_C_CONST
 446 AC_C_INLINE
 447
 448 # ------------------------------ #
 449 # Checks for library functions.  #
 450 # ------------------------------ #
 451
 452 AC_FUNC_ALLOCA
 453 AC_FUNC_MMAP
 454 AC_FUNC_VFORK
 455 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 456 AC_CHECK_FUNCS(poll)
 457 AC_CHECK_FUNCS(pread64)
 458 AC_CHECK_FUNCS(sbrk)
 459 AC_CHECK_FUNCS(setpgid setpgrp)
 460 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 461 AC_CHECK_FUNCS(socketpair)
 462 AC_CHECK_FUNCS(syscall)
 463 AC_CHECK_FUNCS(ttrace)
 464 AC_CHECK_FUNCS(wborder)
 465
 466 # Check the return and argument types of ptrace.  No canned test for
 467 # this, so roll our own.
 468 gdb_ptrace_headers='
 469 #if HAVE_SYS_TYPES_H
 470 # include <sys/types.h>
 471 #endif
 472 #if HAVE_SYS_PTRACE_H
 473 # include <sys/ptrace.h>
 474 #endif
 475 #if HAVE_UNISTD_H
 476 # include <unistd.h>
 477 #endif
 478 '
 479 # There is no point in checking if we don't have a prototype.
 480 gcc_AC_CHECK_DECLS(ptrace, , [
 481   : ${gdb_cv_func_ptrace_ret='int'}
 482   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 483 ], $gdb_ptrace_headers)
 484 # Check return type.
 485 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 486   AC_TRY_COMPILE($gdb_ptrace_headers,
 487     [extern int ptrace ();],
 488     gdb_cv_func_ptrace_ret='int',
 489     gdb_cv_func_ptrace_ret='long'))
 490 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 491   [Define as the return type of ptrace.])
 492 # Check argument types.
 493 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 494 for gdb_arg1 in 'int' 'long'; do
 495  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 496   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 497    for gdb_arg4 in 'int' 'long'; do
 498      AC_TRY_COMPILE($gdb_ptrace_headers, [
 499 extern $gdb_cv_func_ptrace_ret
 500   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 501 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 502     break 4;])
 503     for gdb_arg5 in 'int *' 'int' 'long'; do
 504      AC_TRY_COMPILE($gdb_ptrace_headers, [
 505 extern $gdb_cv_func_ptrace_ret
 506   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 507 ], [
 508 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 509     break 5;])
 510     done
 511    done
 512   done
 513  done
 514 done
 515 # Provide a safe default value.
 516 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 517 ])
 518 ac_save_IFS=$IFS; IFS=','
 519 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 520 IFS=$ac_save_IFS
 521 shift
 522 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 523   [Define to the type of arg 3 for ptrace.])
 524 if test -n "$[5]"; then
 525   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 526     [Define to the type of arg 5 for ptrace.])
 527 fi
 528
 529 dnl AC_FUNC_SETPGRP does not work when cross compiling
 530 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 531 if test "$cross_compiling" = no; then
 532   AC_FUNC_SETPGRP
 533 else
 534   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 535     [AC_TRY_COMPILE([
 536 #include <unistd.h>
 537 ], [
 538   if (setpgrp(1,1) == -1)
 539     exit (0);
 540   else
 541     exit (1);
 542 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 543 if test $ac_cv_func_setpgrp_void = yes; then
 544   AC_DEFINE(SETPGRP_VOID, 1)
 545 fi
 546 fi
 547
 548 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 549 # since sigsetjmp might only be defined as a macro.
 550 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 551 [AC_TRY_COMPILE([
 552 #include <setjmp.h>
 553 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 554 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 555 if test $gdb_cv_func_sigsetjmp = yes; then
 556   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 557 fi
 558
 559 # Assume we'll default to using the included libiberty regex.
 560 gdb_use_included_regex=yes
 561
 562 # However, if the system regex is GNU regex, then default to *not*
 563 # using the included regex.
 564 AC_CACHE_CHECK(
 565   [for GNU regex],
 566   [gdb_cv_have_gnu_regex],
 567   [AC_TRY_COMPILE(
 568     [#include <gnu-versions.h>],
 569     [#define REGEX_INTERFACE_VERSION 1
 570 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 571 # error "Version mismatch"
 572 #endif],
 573     gdb_cv_have_gnu_regex=yes,
 574     gdb_cv_have_gnu_regex=no)])
 575 if test $gdb_cv_have_gnu_regex = yes; then
 576   gdb_use_included_regex=no
 577 fi
 578
 579 AC_ARG_WITH(included-regex,
 580   [  --without-included-regex don't use included regex; this is the default
 581                           on systems with version 2 of the GNU C library
 582                           (use with caution on other system)],
 583   gdb_with_regex=$withval,
 584   gdb_with_regex=$gdb_use_included_regex)
 585 if test "$gdb_with_regex" = yes; then
 586   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 587     [Define to 1 if the regex included in libiberty should be used.])
 588 fi
 589
 590 # See if <sys/proc.h> defines `struct thread' with a td_pcb member.
 591 AC_CACHE_CHECK([for td_pcb in struct thread], gdb_cv_struct_thread_td_pcb,
 592 [AC_TRY_COMPILE([#include <sys/param.h>
 593 #include <sys/proc.h>], [struct thread td; td.td_pcb;],
 594 gdb_cv_struct_thread_td_pcb=yes, gdb_cv_struct_thread_td_pcb=no)])
 595 if test $gdb_cv_struct_thread_td_pcb = yes; then
 596   AC_DEFINE(HAVE_STRUCT_THREAD_TD_PCB, 1,
 597             [Define to 1 if your system has td_pcb in struct thread.])
 598 fi
 599
 600 # See if <sys/lwp.h> defines `struct lwp`.
 601 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 602 [AC_TRY_COMPILE([#include <sys/param.h>
 603 #include <sys/lwp.h>], [struct lwp l;],
 604 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 605 if test $gdb_cv_struct_lwp = yes; then
 606   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 607             [Define to 1 if your system has struct lwp.])
 608 fi
 609
 610 # See if <machine/reg.h> degines `struct reg'.
 611 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 612 [AC_TRY_COMPILE([#include <sys/types.h>
 613 #include <machine/reg.h>], [struct reg r;],
 614 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 615 if test $gdb_cv_struct_reg = yes; then
 616   AC_DEFINE(HAVE_STRUCT_REG, 1,
 617             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 618 fi
 619
 620 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 621 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 622 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 623 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 624 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 625 if test $gdb_cv_struct_reg_r_fs = yes; then
 626   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 627 fi
 628 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 629 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 630 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 631 if test $gdb_cv_struct_reg_r_gs = yes; then
 632   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 633 fi
 634
 635 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 636 AC_MSG_CHECKING(for PTRACE_GETREGS)
 637 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 638 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 639                 [PTRACE_GETREGS;],
 640                 [gdb_cv_have_ptrace_getregs=yes],
 641                 [gdb_cv_have_ptrace_getregs=no])])
 642 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 643 if test $gdb_cv_have_ptrace_getregs = yes; then
 644   AC_DEFINE(HAVE_PTRACE_GETREGS)
 645 fi
 646
 647 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 648 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 649 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 650 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 651                 [PTRACE_GETFPXREGS;],
 652                 [gdb_cv_have_ptrace_getfpxregs=yes],
 653                 [gdb_cv_have_ptrace_getfpxregs=no])])
 654 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 655 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 656   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 657 fi
 658
 659 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 660 AC_MSG_CHECKING(for PT_GETDBREGS)
 661 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 662 [AC_TRY_COMPILE([#include <sys/types.h>
 663 #include <sys/ptrace.h>],
 664                 [PT_GETDBREGS;],
 665                 [gdb_cv_have_pt_getdbregs=yes],
 666                 [gdb_cv_have_pt_getdbregs=no])])
 667 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 668 if test $gdb_cv_have_pt_getdbregs = yes; then
 669   AC_DEFINE(HAVE_PT_GETDBREGS)
 670 fi
 671
 672 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 673 AC_MSG_CHECKING(for PT_GETXMMREGS)
 674 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 675 [AC_TRY_COMPILE([#include <sys/types.h>
 676 #include <sys/ptrace.h>],
 677                 [PT_GETXMMREGS;],
 678                 [gdb_cv_have_pt_getxmmregs=yes],
 679                 [gdb_cv_have_pt_getxmmregs=no])])
 680 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 681 if test $gdb_cv_have_pt_getxmmregs = yes; then
 682   AC_DEFINE(HAVE_PT_GETXMMREGS)
 683 fi
 684
 685 # See if stdint.h provides the uintptr_t type.
 686 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 687 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 688   [AC_TRY_COMPILE(
 689     [#include <stdint.h>],
 690     [uintptr_t foo = 0;],
 691     gdb_cv_have_uintptr_t=yes,
 692     gdb_cv_have_uintptr_t=no)])
 693 if test $gdb_cv_have_uintptr_t = yes; then
 694   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 695 fi
 696
 697 BFD_NEED_DECLARATION(malloc)
 698 BFD_NEED_DECLARATION(realloc)
 699 BFD_NEED_DECLARATION(free)
 700 BFD_NEED_DECLARATION(strerror)
 701 BFD_NEED_DECLARATION(strdup)
 702 BFD_NEED_DECLARATION(strstr)
 703 BFD_NEED_DECLARATION(canonicalize_file_name)
 704
 705 # If we are configured native on GNU/Linux, work around problems with
 706 # sys/procfs.h
 707 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 708
 709 if test "${target}" = "${host}"; then
 710   case "${host}" in
 711   i[[3456]]86-*-linux*)
 712         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 713         AC_DEFINE(sys_quotactl)
 714         ;;
 715   ia64-*-aix*)
 716       AC_DEFINE(NEW_PROC_API)
 717       ;;
 718   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 719       AC_DEFINE(NEW_PROC_API)
 720       ;;
 721   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 722       AC_DEFINE(NEW_PROC_API)
 723       ;;
 724   mips-sgi-irix5*)
 725       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 726       AC_DEFINE([_KMEMUSER], 1)
 727       ;;
 728   esac
 729 fi
 730
 731 if test "$ac_cv_header_sys_procfs_h" = yes; then
 732   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 733   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 734   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 735   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 736   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 737   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 738   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 739   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 740   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 741   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 742   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 743   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 744   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 745   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 746
 747
 748   dnl Check for broken prfpregset_t type
 749
 750   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 751   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 752   dnl instead of the struct itself).  We detect this here, and work
 753   dnl around it in gdb_proc_service.h.
 754
 755   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 756     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 757     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 758       [AC_TRY_RUN([#include <sys/procfs.h>
 759        int main ()
 760        {
 761          if (sizeof (prfpregset_t) == sizeof (void *))
 762            return 1;
 763          return 0;
 764        }],
 765        gdb_cv_prfpregset_t_broken=no,
 766        gdb_cv_prfpregset_t_broken=yes,
 767        gdb_cv_prfpregset_t_broken=yes)])
 768     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 769     if test $gdb_cv_prfpregset_t_broken = yes; then
 770       AC_DEFINE(PRFPREGSET_T_BROKEN)
 771     fi
 772   fi
 773
 774   dnl Check for PIOCSET ioctl entry
 775
 776   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 777   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 778   [AC_TRY_COMPILE([#include <unistd.h>
 779 #include <sys/types.h>
 780 #include <sys/procfs.h>
 781 ], [
 782     int dummy;;
 783     dummy = ioctl(0, PIOCSET, &dummy);
 784   ],
 785   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 786   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 787   if test $gdb_cv_have_procfs_piocset = yes; then
 788     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 789   fi
 790 fi
 791
 792 dnl For native ports (host == target), check to see what kind of
 793 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 794 if test ${host} = ${target} ; then
 795   dnl Check for struct link_map with l_ members which are indicative
 796   dnl of SVR4-like shared libraries
 797
 798   AC_MSG_CHECKING(for member l_addr in struct link_map)
 799   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 800     [AC_TRY_COMPILE([#include <link.h>],
 801                     [struct link_map lm; (void) lm.l_addr;],
 802                     gdb_cv_have_struct_link_map_with_l_members=yes,
 803                     gdb_cv_have_struct_link_map_with_l_members=no)])
 804   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 805   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 806     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 807   fi
 808
 809   dnl Check for struct link_map with lm_ members which are indicative
 810   dnl of SunOS-like shared libraries
 811
 812   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 813   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 814     [AC_TRY_COMPILE([#include <sys/types.h>
 815 #include <link.h>],
 816                     [struct link_map lm; (void) lm.lm_addr;],
 817                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 818                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 819   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 820   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 821     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 822   fi
 823
 824   dnl Check for struct so_map with som_ members which are found on
 825   dnl some *BSD systems.
 826
 827   AC_MSG_CHECKING(for member som_addr in struct so_map)
 828   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 829     [AC_TRY_COMPILE([#include <sys/types.h>
 830 #ifdef HAVE_NLIST_H
 831 #include <nlist.h>
 832 #endif
 833 #include <link.h>],
 834                     [struct so_map lm; (void) lm.som_addr;],
 835                     gdb_cv_have_struct_so_map_with_som_members=yes,
 836                     gdb_cv_have_struct_so_map_with_som_members=no)])
 837   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 838   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 839     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 840   fi
 841
 842   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 843   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 844
 845   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 846   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 847     [AC_TRY_COMPILE([#define _SYSCALL32
 848 #include <sys/link.h>], [struct link_map32 l;],
 849      gdb_cv_have_struct_link_map32=yes,
 850      gdb_cv_have_struct_link_map32=no)])
 851   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 852   if test $gdb_cv_have_struct_link_map32 = yes; then
 853     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 854     AC_DEFINE(_SYSCALL32)
 855   fi
 856 fi
 857
 858 # Check if the compiler supports the `long long' type.
 859
 860 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 861                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 862 [[extern long long foo;]],
 863 [[switch (foo & 2) { case 0: return 1; }]])],
 864                                   gdb_cv_c_long_long=yes,
 865                                   gdb_cv_c_long_long=no)])
 866 if test $gdb_cv_c_long_long = yes; then
 867   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 868             [Define to 1 if the compiler supports long long.])
 869 fi
 870
 871 # Check if the compiler and runtime support printing long longs.
 872
 873 AC_CACHE_CHECK([for long long support in printf],
 874                gdb_cv_printf_has_long_long,
 875                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 876 [[char buf[32];
 877   long long l = 0;
 878   l = (l << 16) + 0x0123;
 879   l = (l << 16) + 0x4567;
 880   l = (l << 16) + 0x89ab;
 881   l = (l << 16) + 0xcdef;
 882   sprintf (buf, "0x%016llx", l);
 883   return (strcmp ("0x0123456789abcdef", buf));]])],
 884                               gdb_cv_printf_has_long_long=yes,
 885                               gdb_cv_printf_has_long_long=no,
 886                               gdb_cv_printf_has_long_long=no)])
 887 if test $gdb_cv_printf_has_long_long = yes; then
 888   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 889             [Define to 1 if the "%ll" format works to print long longs.])
 890 fi
 891
 892 # Check if the compiler supports the `long double' type.  We can't use
 893 # AC_C_LONG_DOUBLE because that one does additional checks on the
 894 # constants defined in <float.h> that fail on some systems,
 895 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 896
 897 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 898                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 899                                   gdb_cv_c_long_double=yes,
 900                                   gdb_cv_c_long_double=no)])
 901 if test $gdb_cv_c_long_double = yes; then
 902   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 903            [Define to 1 if the compiler supports long double.])
 904 fi
 905
 906 # Check if the compiler and runtime support printing long doubles.
 907
 908 AC_CACHE_CHECK([for long double support in printf],
 909                gdb_cv_printf_has_long_double,
 910                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 911 [[char buf[16];
 912   long double f = 3.141592653;
 913   sprintf (buf, "%Lg", f);
 914   return (strncmp ("3.14159", buf, 7));]])],
 915                               gdb_cv_printf_has_long_double=yes,
 916                               gdb_cv_printf_has_long_double=no,
 917                               gdb_cv_printf_has_long_double=no)])
 918 if test $gdb_cv_printf_has_long_double = yes; then
 919   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 920             [Define to 1 if the "%Lg" format works to print long doubles.])
 921 fi
 922
 923 # Check if the compiler and runtime support scanning long doubles.
 924
 925 AC_CACHE_CHECK([for long double support in scanf],
 926                gdb_cv_scanf_has_long_double,
 927                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 928 [[#include <stdio.h>]],
 929 [[char *buf = "3.141592653";
 930   long double f = 0;
 931   sscanf (buf, "%Lg", &f);
 932   return !(f > 3.14159 && f < 3.14160);]])],
 933                               gdb_cv_scanf_has_long_double=yes,
 934                               gdb_cv_scanf_has_long_double=no,
 935                               gdb_cv_scanf_has_long_double=no)])
 936 if test $gdb_cv_scanf_has_long_double = yes; then
 937   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 938             [Define to 1 if the "%Lg" format works to scan long doubles.])
 939 fi
 940
 941 case ${host_os} in
 942 aix*)
 943   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 944     SAVE_LDFLAGS=$LDFLAGS
 945
 946     case $GCC in
 947     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 948     *) gdb_cv_bigtoc=-bbigtoc ;;
 949     esac
 950
 951     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 952     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 953     LDFLAGS="${SAVE_LDFLAGS}"
 954   ])
 955   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 956   ;;
 957 esac
 958
 959
 960 dnl For certain native configurations, we need to check whether thread
 961 dnl support can be built in or not.
 962 dnl
 963 dnl Note that we only want this if we are both native (host == target),
 964 dnl and not doing a canadian cross build (build == host).
 965
 966 if test ${build} = ${host} -a ${host} = ${target} ; then
 967    case ${host_os} in
 968    hpux*)
 969       AC_MSG_CHECKING(for HPUX/OSF thread support)
 970       if test -f /usr/include/dce/cma_config.h ; then
 971          if test "$GCC" = "yes" ; then
 972             AC_MSG_RESULT(yes)
 973             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 974             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 975             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 976          else
 977             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 978          fi
 979       else
 980          AC_MSG_RESULT(no)
 981       fi
 982       ;;
 983    solaris*)
 984       # See if thread_db library is around for Solaris thread debugging.
 985       # Note that we must explicitly test for version 1 of the library
 986       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 987       # the same API.
 988       AC_MSG_CHECKING(for Solaris thread debugging library)
 989       if test -f /usr/lib/libthread_db.so.1 ; then
 990          AC_MSG_RESULT(yes)
 991          AC_DEFINE(HAVE_THREAD_DB_LIB)
 992          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 993          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 994          AC_CHECK_LIB(dl, dlopen)
 995          if test "$GCC" = "yes" ; then
 996             # The GNU linker requires the -export-dynamic option to make
 997             # all symbols visible in the dynamic symbol table.
 998             hold_ldflags=$LDFLAGS
 999             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1000             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1001             AC_TRY_LINK(, [int i;], found=yes, found=no)
1002             LDFLAGS=$hold_ldflags
1003             AC_MSG_RESULT($found)
1004             if test $found = yes; then
1005                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1006             fi
1007          fi
1008          # Sun randomly tweaked the prototypes in <proc_service.h>
1009          # at one point.
1010          AC_MSG_CHECKING(if <proc_service.h> is old)
1011          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1012             AC_TRY_COMPILE([
1013                 #include <proc_service.h>
1014                 ps_err_e ps_pdwrite
1015                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1016             ],, gdb_cv_proc_service_is_old=no,
1017                 gdb_cv_proc_service_is_old=yes)
1018          ])
1019          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1020          if test $gdb_cv_proc_service_is_old = yes; then
1021             AC_DEFINE(PROC_SERVICE_IS_OLD)
1022          fi
1023       else
1024          AC_MSG_RESULT(no)
1025       fi
1026       ;;
1027    aix*)
1028       AC_MSG_CHECKING(for AiX thread debugging library)
1029       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1030                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1031                                    [#ifndef PTHDB_VERSION_3
1032                                     #error
1033                                     #endif],
1034                                    gdb_cv_have_aix_thread_debug=yes,
1035                                    gdb_cv_have_aix_thread_debug=no)])
1036       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1037       if test $gdb_cv_have_aix_thread_debug = yes; then
1038          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1039          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1040          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1041       fi
1042       ;;
1043    esac
1044    AC_SUBST(CONFIG_LDFLAGS)
1045 fi
1046
1047 dnl See if we have a thread_db header file that has TD_NOTALLOC.
1048 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1049    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1050                   gdb_cv_thread_db_h_has_td_notalloc,
1051      AC_TRY_COMPILE(
1052        [#include <thread_db.h>],
1053        [int i = TD_NOTALLOC;],
1054        gdb_cv_thread_db_h_has_td_notalloc=yes,
1055        gdb_cv_thread_db_h_has_td_notalloc=no
1056      )
1057    )
1058 fi
1059 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1060   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1061             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1062 fi
1063
1064 dnl See if we have a sys/syscall header file that has __NR_tkill.
1065 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1066    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1067                   gdb_cv_sys_syscall_h_has_tkill,
1068      AC_TRY_COMPILE(
1069        [#include <sys/syscall.h>],
1070        [int i = __NR_tkill;],
1071        gdb_cv_sys_syscall_h_has_tkill=yes,
1072        gdb_cv_sys_syscall_h_has_tkill=no
1073      )
1074    )
1075 fi
1076 dnl See if we can issue tkill syscall.
1077 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1078   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
1079             [Define if we can use the tkill syscall.])
1080 fi
1081
1082 dnl Handle optional features that can be enabled.
1083
1084 AC_ARG_WITH(sysroot,
1085 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1086 [
1087  case ${with_sysroot} in
1088  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1089  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1090  esac
1091
1092  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1093
1094  if test "x$exec_prefix" = xNONE; then
1095   if test "x$prefix" = xNONE; then
1096    test_prefix=/usr/local
1097   else
1098    test_prefix=$prefix
1099   fi
1100  else
1101   test_prefix=$exec_prefix
1102  fi
1103  case ${TARGET_SYSTEM_ROOT} in
1104  "${test_prefix}"|"${test_prefix}/"*|\
1105  '${exec_prefix}'|'${exec_prefix}/'*)
1106    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1107    TARGET_SYSTEM_ROOT_DEFINE="$t"
1108    ;;
1109  esac
1110 ], [
1111  TARGET_SYSTEM_ROOT=
1112  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1113 ])
1114 AC_SUBST(TARGET_SYSTEM_ROOT)
1115 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1116
1117 # NOTE: Don't add -Wall or -Wunused, they both include
1118 # -Wunused-parameter which reports bogus warnings.
1119 # NOTE: If you add to this list, remember to update
1120 # gdb/doc/gdbint.texinfo.
1121 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1122 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1123 -Wunused-label -Wunused-function"
1124 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1125 # -Wunused-function -Wunused-variable -Wunused-value
1126 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1127 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1128 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1129 # -Woverloaded-virtual -Winline -Werror"
1130 AC_ARG_ENABLE(build-warnings,
1131 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1132 [case "${enableval}" in
1133   yes)  ;;
1134   no)   build_warnings="-w";;
1135   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1136         build_warnings="${build_warnings} ${t}";;
1137   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1138         build_warnings="${t} ${build_warnings}";;
1139   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1140 esac
1141 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1142   echo "Setting compiler warning flags = $build_warnings" 6>&1
1143 fi])dnl
1144 AC_ARG_ENABLE(gdb-build-warnings,
1145 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1146 [case "${enableval}" in
1147   yes)  ;;
1148   no)   build_warnings="-w";;
1149   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1150         build_warnings="${build_warnings} ${t}";;
1151   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1152         build_warnings="${t} ${build_warnings}";;
1153   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1154 esac
1155 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1156   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1157 fi])dnl
1158 WARN_CFLAGS=""
1159 WERROR_CFLAGS=""
1160 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1161 then
1162     AC_MSG_CHECKING(compiler warning flags)
1163     # Separate out the -Werror flag as some files just cannot be
1164     # compiled with it enabled.
1165     for w in ${build_warnings}; do
1166         case $w in
1167         -Werr*) WERROR_CFLAGS=-Werror ;;
1168         *) # Check that GCC accepts it
1169             saved_CFLAGS="$CFLAGS"
1170             CFLAGS="$CFLAGS $w"
1171             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1172             CFLAGS="$saved_CFLAGS"
1173         esac
1174     done
1175     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1176 fi
1177 AC_SUBST(WARN_CFLAGS)
1178 AC_SUBST(WERROR_CFLAGS)
1179
1180 # In the Cygwin environment, we need some additional flags.
1181 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1182 [AC_EGREP_CPP(lose, [
1183 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1184 lose
1185 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1186
1187
1188 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1189 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1190 case ${host} in
1191   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1192   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1193 esac
1194 AC_SUBST(SER_HARDWIRE)
1195
1196 # libreadline needs libuser32.a in a cygwin environment
1197 WIN32LIBS=
1198 if test x$gdb_cv_os_cygwin = xyes; then
1199     WIN32LIBS="-luser32"
1200     case "${target}" in
1201         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1202         ;;
1203     esac
1204 fi
1205 AC_SUBST(WIN32LIBS)
1206
1207 LIBGUI="../libgui/src/libgui.a"
1208 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1209 AC_SUBST(LIBGUI)
1210 AC_SUBST(GUI_CFLAGS_X)
1211
1212 WIN32LDAPP=
1213 AC_SUBST(WIN32LIBS)
1214 AC_SUBST(WIN32LDAPP)
1215
1216 case "${host}" in
1217 *-*-cygwin*)
1218     configdir="win"
1219     ;;
1220 *)
1221     configdir="unix"
1222     ;;
1223 esac
1224
1225 GDBTKLIBS=
1226 if test "${enable_gdbtk}" = "yes"; then
1227
1228     # Gdbtk must have an absolute path to srcdir in order to run
1229     # properly when not installed.
1230     here=`pwd`
1231     cd ${srcdir}
1232     GDBTK_SRC_DIR=`pwd`
1233     cd $here
1234
1235     CY_AC_PATH_TCLCONFIG
1236     if test -z "${no_tcl}"; then
1237         CY_AC_LOAD_TCLCONFIG
1238         CY_AC_PATH_TKCONFIG
1239
1240         # now look for Tcl library stuff
1241
1242         tcldir="../tcl/${configdir}/"
1243
1244         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1245
1246         # If $no_tk is nonempty, then we can't do Tk, and there is no
1247         # point to doing Tcl.
1248         if test -z "${no_tk}"; then
1249            CY_AC_LOAD_TKCONFIG
1250            CY_AC_PATH_TCLH
1251            CY_AC_PATH_TKH
1252            CY_AC_PATH_ITCLH
1253            CY_AC_PATH_ITKH
1254
1255
1256            # now look for Tk library stuff
1257
1258            tkdir="../tk/${configdir}/"
1259
1260            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1261
1262            # now look for Itcl library stuff
1263
1264            CY_AC_PATH_ITCLCONFIG
1265            if test -z "${no_itcl}"; then
1266              CY_AC_LOAD_ITCLCONFIG
1267
1268              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1269              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1270            fi
1271
1272
1273            # now look for Itk library stuff
1274            CY_AC_PATH_ITKCONFIG
1275            if test -z "${no_itcl}"; then
1276              CY_AC_LOAD_ITKCONFIG
1277
1278              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1279              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1280            fi
1281
1282            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1283            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1284            # know whether 8.2 will or not, but I bet it will.
1285            # I don't have to worry about 7.x since we don't support it.
1286            GDBTK_CFLAGS=""
1287            if test "$GCC" = "yes"; then
1288                if test "$TCL_VERSION" != "8.0" ; then
1289                    GDBTK_CFLAGS="-fwritable-strings"
1290                fi
1291            fi
1292
1293            # Include some libraries that Tcl and Tk want.
1294            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1295            # Yes, the ordering seems wrong here.  But it isn't.
1296            # TK_LIBS is the list of libraries that need to be linked
1297            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1298            # were in LIBS then any link tests after this point would
1299            # try to include things like `$(LIBGUI)', which wouldn't work.
1300            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1301
1302            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1303            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1304            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1305            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1306            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1307            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1308            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1309
1310            if test x$gdb_cv_os_cygwin = xyes; then
1311               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1312               WIN32LDAPP="-Wl,--subsystem,console"
1313               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1314            fi
1315         fi
1316     fi
1317
1318     AC_CONFIG_SUBDIRS(gdbtk)
1319 fi
1320
1321 AC_SUBST(X_CFLAGS)
1322 AC_SUBST(X_LDFLAGS)
1323 AC_SUBST(X_LIBS)
1324 AC_SUBST(TCL_DEPS)
1325 AC_SUBST(TK_DEPS)
1326 AC_SUBST(ITCLLIB)
1327 AC_SUBST(ITCL_DEPS)
1328 AC_SUBST(ITKLIB)
1329 AC_SUBST(ITK_DEPS)
1330 AC_SUBST(GDBTKLIBS)
1331 AC_SUBST(GDBTK_CFLAGS)
1332 AC_SUBST(GDBTK_SRC_DIR)
1333
1334 AC_PATH_X
1335
1336 # Check whether we should enable the TUI, but only do so if we really
1337 # can.
1338 if test x"$enable_tui" = xyes; then
1339   if test -d $srcdir/tui; then
1340     if test "$ac_cv_search_waddstr" != no; then
1341       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1342       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1343       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1344       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1345       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1346       CONFIG_ALL="${CONFIG_ALL} all-tui"
1347       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1348       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1349       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1350     else
1351       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1352     fi
1353   fi
1354 fi
1355
1356 # Unlike the sim directory, whether a simulator is linked is controlled by
1357 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1358 # This code just checks for a few cases where we'd like to ignore those
1359 # definitions, even when they're present in the '.mt' file.  These cases
1360 # are when --disable-sim is specified, or if the simulator directory is
1361 # not part of the source tree.
1362 #
1363 AC_ARG_ENABLE(sim,
1364 [  --enable-sim            Link gdb with simulator],
1365 [echo "enable_sim = $enable_sim";
1366  echo "enableval = ${enableval}";
1367  case "${enableval}" in
1368   yes) ignore_sim=false ;;
1369   no)  ignore_sim=true ;;
1370   *)   ignore_sim=false ;;
1371  esac],
1372 [ignore_sim=false])
1373
1374 if test ! -d "${srcdir}/../sim"; then
1375   ignore_sim=true
1376 fi
1377
1378 if test "${ignore_sim}" = "true"; then
1379     IGNORE_SIM="SIM="
1380     IGNORE_SIM_OBS="SIM_OBS="
1381 else
1382     IGNORE_SIM=""
1383     IGNORE_SIM_OBS=""
1384     AC_DEFINE(WITH_SIM)
1385 fi
1386 AC_SUBST(IGNORE_SIM)
1387 AC_SUBST(IGNORE_SIM_OBS)
1388
1389 AC_SUBST(ENABLE_CFLAGS)
1390 AC_SUBST(PROFILE_CFLAGS)
1391
1392 AC_SUBST(CONFIG_OBS)
1393 AC_SUBST(CONFIG_DEPS)
1394 AC_SUBST(CONFIG_SRCS)
1395 AC_SUBST(CONFIG_ALL)
1396 AC_SUBST(CONFIG_CLEAN)
1397 AC_SUBST(CONFIG_INSTALL)
1398 AC_SUBST(CONFIG_UNINSTALL)
1399
1400 # List of host floatformats.
1401 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1402 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1403 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1404
1405 # target_subdir is used by the testsuite to find the target libraries.
1406 target_subdir=
1407 if test "${host}" != "${target}"; then
1408     target_subdir="${target_alias}/"
1409 fi
1410 AC_SUBST(target_subdir)
1411
1412 frags=
1413 if test "${target}" = "${host}"; then
1414   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1415   if test ! -f ${host_makefile_frag}; then
1416     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1417   fi
1418   frags="$frags $host_makefile_frag"
1419 else
1420   host_makefile_frag=/dev/null
1421 fi
1422
1423 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1424 if test ! -f ${target_makefile_frag}; then
1425   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1426 fi
1427 frags="$frags $target_makefile_frag"
1428
1429 AC_SUBST_FILE(host_makefile_frag)
1430 AC_SUBST_FILE(target_makefile_frag)
1431 AC_SUBST(frags)
1432
1433 changequote(,)dnl
1434 hostfile=`sed -n '
1435 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1436 ' ${host_makefile_frag}`
1437
1438 targetfile=`sed -n '
1439 s/DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1440 ' ${target_makefile_frag}`
1441
1442 if test "${target}" = "${host}"; then
1443 # We pick this up from the host configuration file (.mh) because we
1444 # do not have a native configuration Makefile fragment.
1445 nativefile=`sed -n '
1446 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1447 ' ${host_makefile_frag}`
1448 fi
1449 changequote([,])
1450
1451 if test x"${gdb_osabi}" != x ; then
1452     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1453                        [Define to the default OS ABI for this configuration.])
1454 fi
1455
1456 # Enable multi-ice-gdb-server.
1457 AC_ARG_ENABLE(multi-ice,
1458 [  --enable-multi-ice      build the multi-ice-gdb-server],
1459   [case $enableval in
1460     yes | no)
1461       ;;
1462     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1463   esac])
1464 if test "x$enable_multi_ice" = xyes; then
1465    AC_CONFIG_SUBDIRS(multi-ice)
1466 fi
1467
1468 # We only build gdbserver automatically if host and target are the same.
1469 if test "x$target" = "x$host"; then
1470   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1471   if test "x$build_gdbserver" = xyes; then
1472     AC_MSG_RESULT(yes)
1473     AC_CONFIG_SUBDIRS(gdbserver)
1474   else
1475     AC_MSG_RESULT(no)
1476   fi
1477 fi
1478
1479 # We build rdi-share on ARM-based targets, as instructed by configure.tgt.
1480 if test "x$build_rdi_share" = xyes; then
1481    AC_CONFIG_SUBDIRS(rdi-share)
1482 fi
1483
1484 # We configure the nlm subdirectory on netware targets, as instructed
1485 # by configure.tgt.
1486 if test "x$build_nlm" = xyes; then
1487    AC_CONFIG_SUBDIRS(nlm)
1488 fi
1489
1490 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1491 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1492 # to an empty version.
1493
1494 files=
1495 links=
1496
1497 rm -f xm.h
1498 xm_h=""
1499 if test "${hostfile}" != ""; then
1500     xm_h=xm.h
1501     case "${hostfile}" in
1502       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1503       * ) GDB_XM_FILE="${hostfile}"
1504     esac
1505     files="${files} ${GDB_XM_FILE}"
1506     links="${links} xm.h"
1507     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}")
1508 fi
1509 AC_SUBST(xm_h)
1510
1511 rm -f tm.h
1512 tm_h=""
1513 if test "${targetfile}" != ""; then
1514     tm_h=tm.h
1515     case "${targetfile}" in
1516       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1517       * ) GDB_TM_FILE="${targetfile}"
1518     esac
1519     files="${files} ${GDB_TM_FILE}"
1520     links="${links} tm.h"
1521     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}")
1522 fi
1523 AC_SUBST(tm_h)
1524
1525 rm -f nm.h
1526 nm_h=""
1527 if test "${nativefile}" != ""; then
1528     nm_h=nm.h
1529     case "${nativefile}" in
1530       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1531       * ) GDB_NM_FILE="${nativefile}"
1532     esac
1533     files="${files} ${GDB_NM_FILE}"
1534     links="${links} nm.h"
1535     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}")
1536 fi
1537 AC_SUBST(nm_h)
1538
1539 AC_LINK_FILES($files, $links)
1540
1541 dnl Check for exe extension set on certain hosts (e.g. Win32)
1542 AC_EXEEXT
1543
1544 dnl  Detect the character set used by this host.
1545
1546 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1547 dnl  superset of ASCII containing the characters needed for French,
1548 dnl  German, Spanish, Italian, and possibly others), but if were
1549 dnl  *were* to support any host character sets other than ISO-8859-1,
1550 dnl  here's where we'd detect it.
1551 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1552           [Define to be a string naming the default host character set.])
1553
1554 AM_ICONV
1555
1556 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1557 [
1558 dnl Autoconf doesn't provide a mechanism for modifying definitions
1559 dnl provided by makefile fragments.
1560 dnl
1561
1562 changequote(,)dnl
1563 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1564 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1565 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1566 mv -f Makefile.tmp Makefile
1567 changequote([,])dnl
1568
1569
1570 case x$CONFIG_HEADERS in
1571 xconfig.h:config.in)
1572 echo > stamp-h ;;
1573 esac
1574 ],
1575 [
1576 gdb_host_cpu=$gdb_host_cpu
1577 gdb_target_cpu=$gdb_target_cpu
1578 nativefile=$nativefile
1579 ])
1580
1581 exit 0