gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADER(config.h:config.in)
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 gnulib_extra_configure_args=
  49 # If large-file support is disabled, make sure gnulib does the same.
  50 if test "$enable_largefile" = no; then
  51 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  52 fi
  53
  54 # Configure gnulib.  We need to build gnulib under some other
  55 # directory not "gnulib", to avoid the problem of both GDB and
  56 # GDBserver wanting to build it in the same directory, when building
  57 # in the source dir.
  58 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  59                   ["$gnulib_extra_configure_args"])
  60
  61 dnl List of object files and targets accumulated by configure.
  62
  63 CONFIG_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 ENABLE_CFLAGS=
  67
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 dnl Set up for gettext.
  74 ZW_GNU_GETTEXT_SISTER_DIR
  75
  76 localedir='${datadir}/locale'
  77 AC_SUBST(localedir)
  78
  79 if test x"$USE_NLS" = xyes; then
  80    CONFIG_ALL="$CONFIG_ALL all-po"
  81    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  82    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  83    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  84 fi
  85
  86 GNULIB=build-gnulib/import
  87
  88 # For Makefile dependencies.
  89 GNULIB_STDINT_H=
  90 if test x"$STDINT_H" != x; then
  91   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  92 fi
  93 AC_SUBST(GNULIB_STDINT_H)
  94
  95 PACKAGE=gdb
  96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  97 AC_SUBST(PACKAGE)
  98
  99 # We never need to detect it in this sub-configure.
 100 # But preserve it for config.status --recheck.
 101 AC_ARG_VAR(MAKEINFO,
 102   [Parent configure detects if it is of sufficient version.])
 103 AC_ARG_VAR(MAKEINFOFLAGS,
 104   [Parameters for MAKEINFO.])
 105
 106 MAKEINFO_EXTRA_FLAGS=""
 107 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 108   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 109   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 110     gdb_cv_have_makeinfo_click=yes
 111   else
 112     gdb_cv_have_makeinfo_click=no
 113   fi])
 114 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 115   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 116 fi
 117 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 118
 119 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 120     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 121     [${libdir}/debug])
 122
 123 # We can't pass paths as command line arguments.
 124 # Mingw32 tries to be clever and will convert the paths for us.
 125 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 126 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 127 # This breaks GDB's relocatable path conversions since paths passed in
 128 # config.h would not get so translated, the path prefixes no longer match.
 129 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 130
 131 # GDB's datadir relocation
 132
 133 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 134     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 135     [${datadir}/gdb])
 136
 137 AC_ARG_WITH(relocated-sources,
 138 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 139 [reloc_srcdir="${withval}"
 140  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 141               [Relocated directory for source files. ])
 142 ])
 143
 144 AC_MSG_CHECKING([for default auto-load directory])
 145 AC_ARG_WITH(auto-load-dir,
 146 AS_HELP_STRING([--with-auto-load-dir=PATH],
 147   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 148   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 149 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 151               [Directories from which to load auto-loaded scripts.])
 152 AC_MSG_RESULT([$with_auto_load_dir])
 153
 154 AC_MSG_CHECKING([for default auto-load safe-path])
 155 AC_ARG_WITH(auto-load-safe-path,
 156 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 157   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 158 AS_HELP_STRING([--without-auto-load-safe-path],
 159                [do not restrict auto-loaded files locations]),
 160     [if test "$with_auto_load_safe_path" = "no"; then
 161      with_auto_load_safe_path="/"
 162      fi],
 163 [with_auto_load_safe_path="$with_auto_load_dir"])
 164 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 165 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 166               [Directories safe to hold auto-loaded files.])
 167 AC_MSG_RESULT([$with_auto_load_safe_path])
 168
 169 AC_CONFIG_SUBDIRS(testsuite)
 170
 171 # Check whether to support alternative target configurations
 172 AC_ARG_ENABLE(targets,
 173 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 174 [case "${enableval}" in
 175   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 176             ;;
 177   no)       enable_targets= ;;
 178   *)        enable_targets=$enableval ;;
 179 esac])
 180
 181 # Check whether to enable 64-bit support on 32-bit hosts
 182 AC_ARG_ENABLE(64-bit-bfd,
 183 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 184 [case "${enableval}" in
 185   yes)  want64=true  ;;
 186   no)   want64=false ;;
 187   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 188 esac],[want64=false])dnl
 189
 190 # Provide defaults for some variables set by the per-host and per-target
 191 # configuration.
 192 gdb_host_obs=posix-hdep.o
 193
 194 if test "${target}" = "${host}"; then
 195   gdb_native=yes
 196 else
 197   gdb_native=no
 198 fi
 199
 200 . $srcdir/configure.host
 201
 202 # Add in the common host objects.
 203 . $srcdir/common/common.host
 204 gdb_host_obs="$gdb_host_obs $common_host_obs"
 205
 206 # Accumulate some settings from configure.tgt over all enabled targets
 207
 208 TARGET_OBS=
 209 all_targets=
 210 HAVE_NATIVE_GCORE_TARGET=
 211
 212 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 213 do
 214   if test "$targ_alias" = "all"; then
 215     all_targets=true
 216   else
 217     # Canonicalize the secondary target names.
 218     result=`$ac_config_sub $targ_alias 2>/dev/null`
 219     if test -n "$result"; then
 220         targ=$result
 221     else
 222         targ=$targ_alias
 223     fi
 224
 225     . ${srcdir}/configure.tgt
 226
 227     AS_IF([test -z "${gdb_target_obs}"],
 228       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 229
 230     # Target-specific object files
 231     for i in ${gdb_target_obs}; do
 232         case " $TARGET_OBS " in
 233         *" ${i} "*) ;;
 234         *)
 235           TARGET_OBS="$TARGET_OBS ${i}"
 236           ;;
 237         esac
 238     done
 239
 240     # Check whether this target needs 64-bit CORE_ADDR
 241     if test x${want64} = xfalse; then
 242       . ${srcdir}/../bfd/config.bfd
 243     fi
 244
 245     # Check whether this target is native and supports gcore.
 246     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 247        && $gdb_have_gcore; then
 248       HAVE_NATIVE_GCORE_TARGET=1
 249     fi
 250   fi
 251 done
 252
 253 if test x${all_targets} = xtrue; then
 254
 255   # We want all 64-bit targets if we either:
 256   #  - run on a 64-bit host  or
 257   #  - already require 64-bit support for some other target  or
 258   #  - the --enable-64-bit-bfd option was supplied
 259   # Otherwise we only support all 32-bit targets.
 260   #
 261   # NOTE: This test must be in sync with the corresponding
 262   #       tests in BFD!
 263
 264   if test x${want64} = xfalse; then
 265     AC_CHECK_SIZEOF(long)
 266     if test "x${ac_cv_sizeof_long}" = "x8"; then
 267       want64=true
 268     fi
 269   fi
 270   if test x${want64} = xtrue; then
 271     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 272   else
 273     TARGET_OBS='$(ALL_TARGET_OBS)'
 274   fi
 275 fi
 276
 277 AC_SUBST(TARGET_OBS)
 278 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 279
 280 # For other settings, only the main target counts.
 281 gdb_sim=
 282 gdb_osabi=
 283 build_gdbserver=
 284 targ=$target; . ${srcdir}/configure.tgt
 285
 286 # Fetch the default architecture and default target vector from BFD.
 287 targ=$target; . $srcdir/../bfd/config.bfd
 288
 289 # We only want the first architecture, so strip off the others if
 290 # there is more than one.
 291 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 292
 293 if test "x$targ_archs" != x; then
 294   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 295     [Define to BFD's default architecture. ])
 296 fi
 297 if test "x$targ_defvec" != x; then
 298   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 299     [Define to BFD's default target vector. ])
 300 fi
 301
 302 # The CLI cannot be disabled yet, but may be in the future.
 303
 304 # Enable CLI.
 305 AC_ARG_ENABLE(gdbcli,
 306 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 307   [case $enableval in
 308     yes)
 309       ;;
 310     no)
 311       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 312     *)
 313       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 314   esac],
 315   [enable_gdbcli=yes])
 316 if test x"$enable_gdbcli" = xyes; then
 317   if test -d $srcdir/cli; then
 318     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 319     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 320     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 321     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 322   fi
 323 fi
 324
 325 # Enable MI.
 326 AC_ARG_ENABLE(gdbmi,
 327 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 328   [case $enableval in
 329     yes | no)
 330       ;;
 331     *)
 332       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 333   esac],
 334   [enable_gdbmi=yes])
 335 if test x"$enable_gdbmi" = xyes; then
 336   if test -d $srcdir/mi; then
 337     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 338     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 339     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 340     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 341   fi
 342 fi
 343
 344 # Enable TUI.
 345 AC_ARG_ENABLE(tui,
 346 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 347   [case $enableval in
 348     yes | no | auto)
 349       ;;
 350     *)
 351       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 352   esac],enable_tui=auto)
 353
 354 # Enable gdbtk.
 355 AC_ARG_ENABLE(gdbtk,
 356 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 357   [case $enableval in
 358     yes | no)
 359       ;;
 360     *)
 361       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 362   esac],
 363   [if test -d $srcdir/gdbtk; then
 364     enable_gdbtk=yes
 365   else
 366     enable_gdbtk=no
 367   fi])
 368 # We unconditionally disable gdbtk tests on selected platforms.
 369 case $host_os in
 370   go32* | windows*)
 371     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 372     enable_gdbtk=no ;;
 373 esac
 374
 375 # Libunwind support for ia64.
 376
 377 AC_ARG_WITH(libunwind-ia64,
 378 AS_HELP_STRING([--with-libunwind-ia64],
 379                [use libunwind frame unwinding for ia64 targets]),,
 380             [with_libunwind_ia64=auto])
 381
 382 # Backward compatibility option.
 383 if test "${with_libunwind+set}" = set; then
 384   if test x"$with_libunwind_ia64" != xauto; then
 385     AC_MSG_ERROR(
 386       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 387   fi
 388   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 389   with_libunwind_ia64="$with_libunwind"
 390 fi
 391
 392 case "$with_libunwind_ia64" in
 393   yes | no)
 394     ;;
 395   auto)
 396     AC_CHECK_HEADERS(libunwind-ia64.h)
 397     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 398     ;;
 399   *)
 400     AC_MSG_ERROR(
 401       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 402     ;;
 403 esac
 404
 405 if test x"$with_libunwind_ia64" = xyes; then
 406   AC_CHECK_HEADERS(libunwind-ia64.h)
 407   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 408     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 409   fi
 410   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 411   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 412   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 413 fi
 414
 415 opt_curses=no
 416 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 417
 418 prefer_curses=no
 419 if test "$opt_curses" = "yes"; then
 420   prefer_curses=yes
 421 fi
 422
 423 # Profiling support.
 424 AC_ARG_ENABLE(profiling,
 425 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 426   [case $enableval in
 427     yes | no)
 428       ;;
 429     *)
 430       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 431   esac],
 432  [enable_profiling=no])
 433
 434 AC_CHECK_FUNCS(monstartup _mcleanup)
 435 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 436 [AC_TRY_LINK(
 437 [#include <stdlib.h>
 438 extern char _etext;
 439 ],
 440 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 441 if test $ac_cv_var__etext = yes; then
 442   AC_DEFINE(HAVE__ETEXT, 1,
 443             [Define to 1 if your system has the _etext variable. ])
 444 fi
 445 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 446 [AC_TRY_LINK(
 447 [#include <stdlib.h>
 448 extern char etext;
 449 ],
 450 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 451 if test $ac_cv_var_etext = yes; then
 452   AC_DEFINE(HAVE_ETEXT, 1,
 453             [Define to 1 if your system has the etext variable. ])
 454 fi
 455 if test "$enable_profiling" = yes ; then
 456   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 457     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 458   fi
 459   PROFILE_CFLAGS=-pg
 460   OLD_CFLAGS="$CFLAGS"
 461   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 462
 463   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 464     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 465      ac_cv_cc_supports_pg=no)])
 466
 467   if test $ac_cv_cc_supports_pg = no; then
 468     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 469   fi
 470
 471   CFLAGS="$OLD_CFLAGS"
 472 fi
 473
 474 ACX_PKGVERSION([GDB])
 475 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 476 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 477 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 478
 479 # --------------------- #
 480 # Checks for programs.  #
 481 # --------------------- #
 482
 483 AC_PROG_AWK
 484 AC_PROG_INSTALL
 485 AC_PROG_LN_S
 486 AC_PROG_RANLIB
 487 AC_PROG_YACC
 488
 489 AC_CHECK_TOOL(AR, ar)
 490 AC_CHECK_TOOL(DLLTOOL, dlltool)
 491 AC_CHECK_TOOL(WINDRES, windres)
 492
 493 case $host_os in
 494   gnu*)
 495     # Needed for GNU Hurd hosts.
 496     AC_CHECK_TOOL(MIG, mig)
 497     if test x"$MIG" = x; then
 498       AC_MSG_ERROR([MIG not found but required for $host hosts])
 499     fi
 500     ;;
 501 esac
 502
 503 # ---------------------- #
 504 # Checks for libraries.  #
 505 # ---------------------- #
 506
 507 # We might need to link with -lm; most simulators need it.
 508 AC_CHECK_LIB(m, main)
 509
 510 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 511 AC_SEARCH_LIBS(gethostbyname, nsl)
 512
 513 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 514 AC_SEARCH_LIBS(socketpair, socket)
 515
 516 # Link in zlib if we can.  This allows us to read compressed debug sections.
 517 AM_ZLIB
 518
 519 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 520 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 521 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 522   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 523             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 524
 525 # fbsd-nat.c can also use kinfo_getfile.
 526 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 527   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 528             [Define to 1 if your system has the kinfo_getfile function. ])])
 529
 530 AM_ICONV
 531
 532 # GDB may fork/exec the iconv program to get the list of supported character
 533 # sets.  Allow the user to specify where to find it.
 534 # There are several factors affecting the choice of option name:
 535 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 536 #   the build-time location of libiconv files.
 537 # - The program we need to find is iconv, which comes with glibc.  The user
 538 #   doesn't necessarily have libiconv installed.  Therefore naming this
 539 #   --with-libiconv-foo feels wrong.
 540 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 541 #   defined to work on directories not files (though it really doesn't know
 542 #   the difference).
 543 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 544 #   with --with-libiconv-prefix.
 545 # Putting these together is why the option name is --with-iconv-bin.
 546
 547 AC_ARG_WITH(iconv-bin,
 548 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 549 [iconv_bin="${withval}"
 550  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 551                     [Path of directory of iconv program.])
 552  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 553 ])
 554
 555 # For the TUI, we need enhanced curses functionality.
 556 if test x"$enable_tui" != xno; then
 557   prefer_curses=yes
 558 fi
 559
 560 curses_found=no
 561 if test x"$prefer_curses" = xyes; then
 562   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 563   # curses library because the latter might not provide all the
 564   # functionality we need.  However, this leads to problems on systems
 565   # where the linker searches /usr/local/lib, but the compiler doesn't
 566   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 567   # default installation of ncurses on alpha*-dec-osf* will lead to such
 568   # a situation.
 569   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 570
 571   if test "$ac_cv_search_waddstr" != no; then
 572     curses_found=yes
 573   fi
 574 fi
 575
 576 # Check whether we should enable the TUI, but only do so if we really
 577 # can.
 578 if test x"$enable_tui" != xno; then
 579   if test -d $srcdir/tui; then
 580     if test "$curses_found" != no; then
 581       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 582       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 583       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 584       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 585     else
 586       if test x"$enable_tui" = xyes; then
 587         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 588       else
 589         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 590       fi
 591     fi
 592   fi
 593 fi
 594
 595 # Since GDB uses Readline, we need termcap functionality.  In many
 596 # cases this will be provided by the curses library, but some systems
 597 # have a separate termcap library, or no curses library at all.
 598
 599 case $host_os in
 600   cygwin*)
 601     if test -d $srcdir/libtermcap; then
 602       LIBS="../libtermcap/libtermcap.a $LIBS"
 603       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 604     fi ;;
 605   go32* | *djgpp*)
 606     ac_cv_search_tgetent="none required"
 607     ;;
 608 esac
 609
 610 # These are the libraries checked by Readline.
 611 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncursesw ncurses])
 612
 613 if test "$ac_cv_search_tgetent" = no; then
 614   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 615 fi
 616
 617 AC_ARG_WITH([system-readline],
 618   [AS_HELP_STRING([--with-system-readline],
 619                   [use installed readline library])])
 620
 621 if test "$with_system_readline" = yes; then
 622   READLINE=-lreadline
 623   READLINE_DEPS=
 624   READLINE_CFLAGS=
 625   READLINE_TEXI_INCFLAG=
 626 else
 627   READLINE='$(READLINE_DIR)/libreadline.a'
 628   READLINE_DEPS='$(READLINE)'
 629   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 630   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 631 fi
 632 AC_SUBST(READLINE)
 633 AC_SUBST(READLINE_DEPS)
 634 AC_SUBST(READLINE_CFLAGS)
 635 AC_SUBST(READLINE_TEXI_INCFLAG)
 636
 637 # Generate jit-reader.h
 638
 639 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 640 TARGET_PTR=
 641
 642 AC_CHECK_SIZEOF(unsigned long long)
 643 AC_CHECK_SIZEOF(unsigned long)
 644 AC_CHECK_SIZEOF(unsigned __int128)
 645
 646 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 647   TARGET_PTR="unsigned long"
 648 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 649   TARGET_PTR="unsigned long long"
 650 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 651   TARGET_PTR="unsigned __int128"
 652 else
 653   TARGET_PTR="unsigned long"
 654 fi
 655
 656 AC_SUBST(TARGET_PTR)
 657 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 658
 659 AC_SEARCH_LIBS(dlopen, dl)
 660
 661 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 662                 [directory to load the JIT readers from],
 663                 [${libdir}/gdb])
 664
 665 AC_ARG_WITH(expat,
 666   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 667   [], [with_expat=auto])
 668 AC_MSG_CHECKING([whether to use expat])
 669 AC_MSG_RESULT([$with_expat])
 670
 671 if test "${with_expat}" = no; then
 672   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 673   HAVE_LIBEXPAT=no
 674 else
 675   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 676                         [XML_Parser p = XML_ParserCreate (0);])
 677   if test "$HAVE_LIBEXPAT" != yes; then
 678     if test "$with_expat" = yes; then
 679       AC_MSG_ERROR([expat is missing or unusable])
 680     else
 681       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 682     fi
 683   else
 684     save_LIBS=$LIBS
 685     LIBS="$LIBS $LIBEXPAT"
 686     AC_CHECK_FUNCS(XML_StopParser)
 687     LIBS=$save_LIBS
 688   fi
 689 fi
 690
 691 AC_ARG_WITH(mpfr,
 692   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 693   [], [with_mpfr=auto])
 694 AC_MSG_CHECKING([whether to use MPFR])
 695 AC_MSG_RESULT([$with_mpfr])
 696
 697 if test "${with_mpfr}" = no; then
 698   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 699   HAVE_LIBMPFR=no
 700 else
 701   AC_LIB_HAVE_LINKFLAGS([mpfr], [], [#include <mpfr.h>],
 702                         [mpfr_exp_t exp; mpfr_t x;
 703                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 704   if test "$HAVE_LIBMPFR" != yes; then
 705     if test "$with_mpfr" = yes; then
 706       AC_MSG_ERROR([MPFR is missing or unusable])
 707     else
 708       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 709     fi
 710   fi
 711 fi
 712
 713 # --------------------- #
 714 # Check for libpython.  #
 715 # --------------------- #
 716
 717 dnl Utility to simplify finding libpython.
 718 dnl $1 = pythonX.Y
 719 dnl $2 = the shell variable to assign the result to
 720 dnl      If libpython is found we store $version here.
 721 dnl $3 = additional flags to add to CPPFLAGS
 722 dnl $4 = additional flags to add to LIBS
 723
 724 AC_DEFUN([AC_TRY_LIBPYTHON],
 725 [
 726   version=$1
 727   define([have_libpython_var],$2)
 728   new_CPPFLAGS=$3
 729   new_LIBS=$4
 730   AC_MSG_CHECKING([for ${version}])
 731   save_CPPFLAGS=$CPPFLAGS
 732   save_LIBS=$LIBS
 733   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 734   LIBS="$new_LIBS $LIBS"
 735   found_usable_python=no
 736   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 737                                  [[Py_Initialize ();]])],
 738                  [have_libpython_var=${version}
 739                   found_usable_python=yes
 740                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 741                   PYTHON_LIBS=$new_LIBS])
 742   CPPFLAGS=$save_CPPFLAGS
 743   LIBS=$save_LIBS
 744   AC_MSG_RESULT([${found_usable_python}])
 745 ])
 746
 747 dnl There are several different values for --with-python:
 748 dnl
 749 dnl no -   Don't include python support.
 750 dnl yes -  Include python support, error if it's missing.
 751 dnl        If we find python in $PATH, use it to fetch configure options,
 752 dnl        otherwise assume the compiler can find it with no help from us.
 753 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 754 dnl auto - Same as "yes", but if python is missing from the system,
 755 dnl        fall back to "no".
 756 dnl /path/to/python/exec-prefix -
 757 dnl        Use the python located in this directory.
 758 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 759 dnl        the compilation parameters.  Otherwise use
 760 dnl        -I/path/to/python/exec-prefix/include,
 761 dnl        -L/path/to/python/exec-prefix/lib.
 762 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 763 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 764 dnl        but is deprecated.
 765 dnl /path/to/python/executable -
 766 dnl        Run python-config.py with this version of python to fetch the
 767 dnl        compilation parameters.
 768 dnl        NOTE: This needn't be the real python executable.
 769 dnl        In a cross-compilation scenario (build != host), this could be
 770 dnl        a shell script that provides what python-config.py provides for
 771 dnl        --ldflags, --includes, --exec-prefix.
 772 dnl python-executable -
 773 dnl        Find python-executable in $PATH, and then handle the same as
 774 dnl        /path/to/python/executable.
 775 dnl
 776 dnl If a python program is specified, it is used to run python-config.py and
 777 dnl is passed --ldflags, --includes, --exec-prefix.
 778
 779 AC_ARG_WITH(python,
 780   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 781   [], [with_python=auto])
 782 AC_MSG_CHECKING([whether to use python])
 783 AC_MSG_RESULT([$with_python])
 784
 785 if test "${with_python}" = no; then
 786   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 787   have_libpython=no
 788 else
 789   case "${with_python}" in
 790   [[\\/]]* | ?:[[\\/]]*)
 791     if test -d ${with_python}; then
 792       # Assume the python binary is ${with_python}/bin/python.
 793       python_prog="${with_python}/bin/python"
 794       python_prefix=
 795       # If python does not exit ${with_python}/bin, then try in
 796       # ${with_python}.  On Windows/MinGW, this is where the Python
 797       # executable is.
 798       if test ! -x "${python_prog}"; then
 799         python_prog="${with_python}/python"
 800         python_prefix=
 801       fi
 802       if test ! -x "${python_prog}"; then
 803         # Fall back to gdb 7.0/7.1 behaviour.
 804         python_prog=missing
 805         python_prefix=${with_python}
 806       fi
 807     elif test -x "${with_python}"; then
 808       # While we can't run python compiled for $host (unless host == build),
 809       # the user could write a script that provides the needed information,
 810       # so we support that.
 811       python_prog=${with_python}
 812       python_prefix=
 813     else
 814       AC_ERROR(invalid value for --with-python)
 815     fi
 816     ;;
 817   */*)
 818     # Disallow --with-python=foo/bar.
 819     AC_ERROR(invalid value for --with-python)
 820     ;;
 821   *)
 822     # The user has either specified auto, yes, or the name of the python
 823     # program assumed to be in $PATH.
 824     python_prefix=
 825     case "${with_python}" in
 826     yes | auto)
 827       if test ${build} = ${host}; then
 828         AC_PATH_PROG(python_prog_path, python, missing)
 829         if test "${python_prog_path}" = missing; then
 830           python_prog=missing
 831         else
 832           python_prog=${python_prog_path}
 833         fi
 834       else
 835         # Not much we can do except assume the cross-compiler will find the
 836         # right files.
 837         python_prog=missing
 838       fi
 839       ;;
 840     *)
 841       # While we can't run python compiled for $host (unless host == build),
 842       # the user could write a script that provides the needed information,
 843       # so we support that.
 844       python_prog="${with_python}"
 845       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 846       if test "${python_prog_path}" = missing; then
 847         AC_ERROR(unable to find python program ${python_prog})
 848       fi
 849       ;;
 850     esac
 851   esac
 852
 853   if test "${python_prog}" != missing; then
 854     # We have a python program to use, but it may be too old.
 855     # Don't flag an error for --with-python=auto (the default).
 856     have_python_config=yes
 857     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 858     if test $? != 0; then
 859       have_python_config=failed
 860       if test "${with_python}" != auto; then
 861         AC_ERROR(failure running python-config --includes)
 862       fi
 863     fi
 864     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 865     if test $? != 0; then
 866       have_python_config=failed
 867       if test "${with_python}" != auto; then
 868         AC_ERROR(failure running python-config --ldflags)
 869       fi
 870     fi
 871     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 872     if test $? != 0; then
 873       have_python_config=failed
 874       if test "${with_python}" != auto; then
 875         AC_ERROR(failure running python-config --exec-prefix)
 876       fi
 877     fi
 878   else
 879     # We do not have a python executable we can use to determine where
 880     # to find the Python headers and libs.  We cannot guess the include
 881     # path from the python_prefix either, because that include path
 882     # depends on the Python version.  So, there is nothing much we can
 883     # do except assume that the compiler will be able to find those files.
 884     python_includes=
 885     python_libs=
 886     have_python_config=no
 887   fi
 888
 889   # If we have python-config, only try the configuration it provides.
 890   # Otherwise fallback on the old way of trying different versions of
 891   # python in turn.
 892
 893   have_libpython=no
 894   if test "${have_python_config}" = yes; then
 895     # Determine the Python version by extracting "-lpython<version>"
 896     # part of the python_libs. <version> is usually X.Y with X and Y
 897     # being decimal numbers, but can also be XY (seen on Windows).
 898     #
 899     # The extraction is performed using sed with a regular expression.
 900     # Initially, the regexp used was using the '?' quantifier to make
 901     # the dot in the version number optional.  Unfortunately, this
 902     # does not work with non-GNU versions of sed because, because of
 903     # what looks like a limitation (the '?' quantifier does not work
 904     # with back-references).  We work around this limitation by using
 905     # the '*' quantifier instead.  It means that, in theory, we might
 906     # match unexpected version strings such as "-lpython2..7", but
 907     # this seems unlikely in practice.  And even if that happens,
 908     # an error will be triggered later on, when checking that version
 909     # number.
 910     python_version=`echo " ${python_libs} " \
 911                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 912     case "${python_version}" in
 913     python*)
 914       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 915                        ${python_includes}, ${python_libs})
 916       ;;
 917     *)
 918       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 919       ;;
 920     esac
 921   elif test "${have_python_config}" != failed; then
 922     if test "${have_libpython}" = no; then
 923       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 924                        ${python_includes}, "-lpython2.7 ${python_libs}")
 925     fi
 926     if test "${have_libpython}" = no; then
 927       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 928                        ${python_includes}, "-lpython2.6 ${python_libs}")
 929     fi
 930     if test ${have_libpython} = no; then
 931       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 932                        ${python_includes}, "-lpython2.5 ${python_libs}")
 933     fi
 934     if test ${have_libpython} = no; then
 935       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 936                        ${python_includes}, "-lpython2.4 ${python_libs}")
 937     fi
 938   fi
 939   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 940     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 941   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 942     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 943   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 944     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 945   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 946     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 947   fi
 948
 949   if test "${have_libpython}" = no; then
 950     case "${with_python}" in
 951     yes)
 952       AC_MSG_ERROR([python is missing or unusable])
 953       ;;
 954     auto)
 955       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 956       ;;
 957     *)
 958       AC_MSG_ERROR([no usable python found at ${with_python}])
 959       ;;
 960     esac
 961   else
 962     if test -n "${python_prefix}"; then
 963       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 964                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 965       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 966     fi
 967   fi
 968 fi
 969
 970 if test "${have_libpython}" != no; then
 971   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 972   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 973   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 974   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 975   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 976   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 977
 978   # Flags needed to compile Python code (taken from python-config --cflags).
 979   # We cannot call python-config directly because it will output whatever was
 980   # used when compiling the Python interpreter itself, including flags which
 981   # would make the python-related objects be compiled differently from the
 982   # rest of GDB (e.g., -O2 and -fPIC).
 983   if test "${GCC}" = yes; then
 984     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 985   fi
 986
 987   if test "x${tentative_python_cflags}" != x; then
 988     AC_MSG_CHECKING(compiler flags for python code)
 989     for flag in ${tentative_python_cflags}; do
 990       # Check that the compiler accepts it
 991       saved_CFLAGS="$CFLAGS"
 992       CFLAGS="$CFLAGS $flag"
 993       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 994       CFLAGS="$saved_CFLAGS"
 995     done
 996     AC_MSG_RESULT(${PYTHON_CFLAGS})
 997   fi
 998
 999   # On x64 Windows, Python's include headers, and pyconfig.h in
1000   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1001   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1002   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1003   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1004   # The issue was reported to the Python community, but still isn't
1005   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1006
1007   case "$gdb_host" in
1008     mingw64)
1009            if test "${GCC}" = yes; then
1010              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1011            fi
1012            ;;
1013   esac
1014
1015   # Note that "python -m threading" cannot be used to check for
1016   # threading support due to a bug in Python 2.7.3
1017   # (http://bugs.python.org/issue15567).
1018   AC_MSG_CHECKING(whether python supports threads)
1019   saved_CPPFLAGS="${CPPFLAGS}"
1020   CPPFLAGS="${PYTHON_CPPFLAGS}"
1021   # Note that the test is reversed so that python_has_threads=yes on
1022   # unexpected failures.
1023   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1024 #include <Python.h>
1025 #ifdef WITH_THREAD
1026 # error
1027 #endif
1028   ]])], [python_has_threads=no], [python_has_threads=yes])
1029   AC_MSG_RESULT(${python_has_threads})
1030   CPPFLAGS="${saved_CPPFLAGS}"
1031 else
1032   # Even if Python support is not compiled in, we need to have this file
1033   # included so that the "python" command, et.al., still exists.
1034   CONFIG_OBS="$CONFIG_OBS python/python.o"
1035   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1036 fi
1037
1038 # Work around Python http://bugs.python.org/issue10112.  See also
1039 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1040 # no effect.  Note that the only test after this that uses Python is
1041 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1042 # run without -export-dynamic too.
1043 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1044
1045 AC_SUBST(PYTHON_CFLAGS)
1046 AC_SUBST(PYTHON_CPPFLAGS)
1047 AC_SUBST(PYTHON_LIBS)
1048 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1049
1050 # -------------------- #
1051 # Check for libguile.  #
1052 # -------------------- #
1053
1054 dnl Utility to simplify finding libguile.
1055 dnl $1 = pkg-config-program
1056 dnl $2 = space-separate list of guile versions to try
1057 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1058 dnl $4 = the shell variable to assign the result to
1059 dnl      If libguile is found we store "yes" here.
1060
1061 AC_DEFUN([AC_TRY_LIBGUILE],
1062 [
1063   pkg_config=$1
1064   guile_version_list=$2
1065   flag_errors=$3
1066   define([have_libguile_var],$4)
1067   found_usable_guile=checking
1068   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1069   for guile_version in ${guile_version_list}; do
1070     ${pkg_config} --exists ${guile_version} 2>/dev/null
1071     if test $? != 0; then
1072       continue
1073     fi
1074     dnl pkg-config says the package exists, so if we get an error now,
1075     dnl that's bad.
1076     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1077     if test $? != 0; then
1078       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1079     fi
1080     new_LIBS=`${pkg_config} --libs ${guile_version}`
1081     if test $? != 0; then
1082       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1083     fi
1084     dnl If we get this far, great.
1085     found_usable_guile=${guile_version}
1086     break
1087   done
1088   if test "${found_usable_guile}" = "checking"; then
1089     if test "${flag_errors}" = "yes"; then
1090       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1091     else
1092       found_usable_guile=no
1093     fi
1094   fi
1095   dnl One final sanity check.
1096   dnl The user could have said --with-guile=python-2.7.
1097   if test "${found_usable_guile}" != no; then
1098     save_CPPFLAGS=$CPPFLAGS
1099     save_LIBS=$LIBS
1100     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1101     LIBS="$LIBS $new_LIBS"
1102     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1103                                    [[scm_init_guile ();]])],
1104                    [have_libguile_var=yes
1105                     GUILE_CPPFLAGS=$new_CPPFLAGS
1106                     GUILE_LIBS=$new_LIBS],
1107                    [found_usable_guile=no])
1108     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1109     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1110       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1111                 [Define if Guile supports manual finalization.])
1112     )
1113     CPPFLAGS=$save_CPPFLAGS
1114     LIBS=$save_LIBS
1115     if test "${found_usable_guile}" = no; then
1116       if test "${flag_errors}" = yes; then
1117         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1118       fi
1119     fi
1120   fi
1121   AC_MSG_RESULT([${found_usable_guile}])
1122 ])
1123
1124 dnl There are several different values for --with-guile:
1125 dnl
1126 dnl no -   Don't include guile support.
1127 dnl yes -  Include guile support, error if it's missing.
1128 dnl        The pkg-config program must be in $PATH.
1129 dnl auto - Same as "yes", but if guile is missing from the system,
1130 dnl        fall back to "no".
1131 dnl guile-version [guile-version-choice-2 ...] -
1132 dnl        A space-separated list of guile package versions to try.
1133 dnl        These are passed to pkg-config as-is.
1134 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1135 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1136 dnl /path/to/pkg-config -
1137 dnl        Use this pkg-config program.
1138 dnl        NOTE: This needn't be the "real" pkg-config program.
1139 dnl        It could be a shell script.  It is invoked as:
1140 dnl        pkg-config --exists $version
1141 dnl        pkg-config --cflags $version
1142 dnl        pkg-config --libs $version
1143 dnl        pkg-config --variable guild $version
1144 dnl        The script will be called with $version having each value in
1145 dnl        $try_guile_versions until --exists indicates success.
1146
1147 AC_ARG_WITH(guile,
1148   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1149   [], [with_guile=auto])
1150 AC_MSG_CHECKING([whether to use guile])
1151 AC_MSG_RESULT([$with_guile])
1152
1153 dnl We check guile with pkg-config.
1154 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1155
1156 try_guile_versions="guile-2.0"
1157 have_libguile=no
1158 case "${with_guile}" in
1159 no)
1160   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1161   ;;
1162 auto)
1163   if test "${pkg_config_prog_path}" = "missing"; then
1164     AC_MSG_WARN([pkg-config not found, guile support disabled])
1165   else
1166     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1167   fi
1168   ;;
1169 yes)
1170   if test "${pkg_config_prog_path}" = "missing"; then
1171     AC_MSG_ERROR([pkg-config not found])
1172   fi
1173   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1174   ;;
1175 [[\\/]]* | ?:[[\\/]]*)
1176   if test -x "${with_guile}"; then
1177     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1178   else
1179     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1180   fi
1181   ;;
1182 "" | */*)
1183   # Disallow --with=guile="" and --with-guile=foo/bar.
1184   AC_MSG_ERROR([invalid value for --with-guile])
1185   ;;
1186 *)
1187   # A space separate list of guile versions to try, in order.
1188   if test "${pkg_config_prog_path}" = "missing"; then
1189     AC_MSG_ERROR([pkg-config not found])
1190   fi
1191   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1192   ;;
1193 esac
1194
1195 if test "${have_libguile}" != no; then
1196   dnl Get the name of the 'guild' program.
1197   case "${with_guile}" in
1198   [[\\/]]* | ?:[[\\/]]*)
1199     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1200     ;;
1201   *)
1202     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1203     ;;
1204   esac
1205
1206   dnl Make sure guild can handle this host.
1207   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1208   dnl If not, disable guile support.
1209   if test "$ac_cv_guild_ok" = no; then
1210     have_libguile=no
1211     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1212   fi
1213 fi
1214
1215 if test "${have_libguile}" != no; then
1216   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1217   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1218   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1219   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1220   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1221   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1222
1223   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1224   save_LIBS="$LIBS"
1225   save_CPPFLAGS="$CPPFLAGS"
1226   LIBS="$GUILE_LIBS"
1227   CPPFLAGS="$GUILE_CPPFLAGS"
1228   AC_CHECK_FUNCS([scm_new_smob])
1229   LIBS="$save_LIBS"
1230   CPPFLAGS="$save_CPPFLAGS"
1231 else
1232   # Even if Guile support is not compiled in, we need to have these files
1233   # included.
1234   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1235   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1236 fi
1237 AC_SUBST(GUILE_CPPFLAGS)
1238 AC_SUBST(GUILE_LIBS)
1239 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1240
1241 # --------------------- #
1242 # Check for libmcheck.  #
1243 # --------------------- #
1244
1245 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1246 # but turn it off if Python is enabled with threads, since -lmcheck is
1247 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1248 # and for releases.
1249 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1250    && $development; then
1251   libmcheck_default=yes
1252 else
1253   libmcheck_default=no
1254 fi
1255 GDB_AC_LIBMCHECK(${libmcheck_default})
1256
1257 if test "$ENABLE_LIBMCHECK" = "yes" \
1258         -a "${have_libpython}" != "no" \
1259         -a "${python_has_threads}" = "yes" ; then
1260   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1261 fi
1262
1263 AC_ARG_WITH(intel_pt,
1264   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1265   [], [with_intel_pt=auto])
1266 AC_MSG_CHECKING([whether to use intel pt])
1267 AC_MSG_RESULT([$with_intel_pt])
1268
1269 if test "${with_intel_pt}" = no; then
1270   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1271   HAVE_LIBIPT=no
1272 else
1273   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1274 #include <linux/perf_event.h>
1275 #ifndef PERF_ATTR_SIZE_VER5
1276 # error
1277 #endif
1278   ]])], [perf_event=yes], [perf_event=no])
1279   if test "$perf_event" != yes; then
1280     if test "$with_intel_pt" = yes; then
1281       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1282     else
1283       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1284     fi
1285   fi
1286
1287   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1288   if test "$HAVE_LIBIPT" != yes; then
1289     if test "$with_intel_pt" = yes; then
1290       AC_MSG_ERROR([libipt is missing or unusable])
1291     else
1292       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1293     fi
1294   else
1295     save_LIBS=$LIBS
1296     LIBS="$LIBS $LIBIPT"
1297     AC_CHECK_FUNCS(pt_insn_event)
1298     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1299                      [#include <intel-pt.h>])
1300     LIBS=$save_LIBS
1301   fi
1302 fi
1303
1304 # ------------------------- #
1305 # Checks for header files.  #
1306 # ------------------------- #
1307
1308 AC_HEADER_STDC
1309 # elf_hp.h is for HP/UX 64-bit shared library support.
1310 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1311                   thread_db.h \
1312                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1313                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1314                   sys/reg.h sys/debugreg.h sys/select.h \
1315                   termios.h elf_hp.h \
1316                   dlfcn.h])
1317 AC_CHECK_HEADERS(sys/user.h, [], [],
1318 [#if HAVE_SYS_PARAM_H
1319 # include <sys/param.h>
1320 #endif
1321 ])
1322
1323 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1324 AC_CHECK_HEADERS(term.h, [], [],
1325 [#if HAVE_CURSES_H
1326 # include <curses.h>
1327 #endif
1328 ])
1329
1330 # ------------------------- #
1331 # Checks for declarations.  #
1332 # ------------------------- #
1333
1334 libiberty_INIT
1335
1336 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1337 AM_LC_MESSAGES
1338
1339 # ----------------------- #
1340 # Checks for structures.  #
1341 # ----------------------- #
1342
1343 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1344
1345 # ------------------ #
1346 # Checks for types.  #
1347 # ------------------ #
1348
1349 AC_CHECK_TYPES(socklen_t, [], [],
1350 [#include <sys/types.h>
1351 #include <sys/socket.h>
1352 ])
1353
1354 # ------------------------------------- #
1355 # Checks for compiler characteristics.  #
1356 # ------------------------------------- #
1357
1358 AC_C_CONST
1359 AC_C_INLINE
1360 AC_C_BIGENDIAN
1361
1362 # ------------------------------ #
1363 # Checks for library functions.  #
1364 # ------------------------------ #
1365
1366 AC_FUNC_MMAP
1367 AC_FUNC_VFORK
1368 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1369                 pipe poll pread pread64 pwrite resize_term \
1370                 sbrk getpgid setpgid setpgrp setsid \
1371                 sigaction sigprocmask sigsetmask socketpair \
1372                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1373                 setrlimit getrlimit posix_madvise waitpid \
1374                 ptrace64 sigaltstack mkdtemp setns])
1375 AM_LANGINFO_CODESET
1376 GDB_AC_COMMON
1377
1378 # Check the return and argument types of ptrace.
1379 GDB_AC_PTRACE
1380
1381 dnl AC_FUNC_SETPGRP does not work when cross compiling
1382 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1383 if test "$cross_compiling" = no; then
1384   AC_FUNC_SETPGRP
1385 else
1386   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1387     [AC_TRY_COMPILE([
1388 #include <unistd.h>
1389 ], [
1390   if (setpgrp(1,1) == -1)
1391     exit (0);
1392   else
1393     exit (1);
1394 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1395 if test $ac_cv_func_setpgrp_void = yes; then
1396   AC_DEFINE(SETPGRP_VOID, 1)
1397 fi
1398 fi
1399
1400 # Assume we'll default to using the included libiberty regex.
1401 gdb_use_included_regex=yes
1402
1403 # However, if the system regex is GNU regex, then default to *not*
1404 # using the included regex.
1405 AC_CACHE_CHECK(
1406   [for GNU regex],
1407   [gdb_cv_have_gnu_regex],
1408   [AC_TRY_COMPILE(
1409     [#include <gnu-versions.h>],
1410     [#define REGEX_INTERFACE_VERSION 1
1411 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1412 # error "Version mismatch"
1413 #endif],
1414     gdb_cv_have_gnu_regex=yes,
1415     gdb_cv_have_gnu_regex=no)])
1416 if test $gdb_cv_have_gnu_regex = yes; then
1417   gdb_use_included_regex=no
1418 fi
1419
1420 AC_ARG_WITH(included-regex,
1421   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1422   gdb_with_regex=$withval,
1423   gdb_with_regex=$gdb_use_included_regex)
1424 if test "$gdb_with_regex" = yes; then
1425   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1426     [Define to 1 if the regex included in libiberty should be used.])
1427 fi
1428
1429 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1430 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1431 [#include <sys/param.h>
1432 #include <sys/proc.h>
1433 ])
1434
1435 # See if <sys/lwp.h> defines `struct lwp`.
1436 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1437 [AC_TRY_COMPILE([#include <sys/param.h>
1438 #define _KMEMUSER
1439 #include <sys/lwp.h>], [struct lwp l;],
1440 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1441 if test $gdb_cv_struct_lwp = yes; then
1442   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1443             [Define to 1 if your system has struct lwp.])
1444 fi
1445
1446 # See if <machine/reg.h> degines `struct reg'.
1447 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1448 [AC_TRY_COMPILE([#include <sys/types.h>
1449 #include <machine/reg.h>], [struct reg r;],
1450 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1451 if test $gdb_cv_struct_reg = yes; then
1452   AC_DEFINE(HAVE_STRUCT_REG, 1,
1453             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1454 fi
1455
1456 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1457 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1458 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1459                  [#include <sys/types.h>
1460 #include <machine/reg.h>])
1461
1462 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1463 # Older amd64 Linux's don't have the fs_base and gs_base members of
1464 # `struct user_regs_struct'.
1465 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1466      [], [], [#include <sys/types.h>
1467 #include <sys/user.h>])
1468
1469 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1470 AC_MSG_CHECKING(for PTRACE_GETREGS)
1471 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1472 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1473                 [PTRACE_GETREGS;],
1474                 [gdb_cv_have_ptrace_getregs=yes],
1475                 [gdb_cv_have_ptrace_getregs=no])])
1476 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1477 if test $gdb_cv_have_ptrace_getregs = yes; then
1478   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1479   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1480 fi
1481
1482 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1483 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1484 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1485 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1486                 [PTRACE_GETFPXREGS;],
1487                 [gdb_cv_have_ptrace_getfpxregs=yes],
1488                 [gdb_cv_have_ptrace_getfpxregs=no])])
1489 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1490 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1491   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1492   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1493 fi
1494
1495 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1496 AC_MSG_CHECKING(for PT_GETDBREGS)
1497 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1498 [AC_TRY_COMPILE([#include <sys/types.h>
1499 #include <sys/ptrace.h>],
1500                 [PT_GETDBREGS;],
1501                 [gdb_cv_have_pt_getdbregs=yes],
1502                 [gdb_cv_have_pt_getdbregs=no])])
1503 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1504 if test $gdb_cv_have_pt_getdbregs = yes; then
1505   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1506   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1507 fi
1508
1509 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1510 AC_MSG_CHECKING(for PT_GETXMMREGS)
1511 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1512 [AC_TRY_COMPILE([#include <sys/types.h>
1513 #include <sys/ptrace.h>],
1514                 [PT_GETXMMREGS;],
1515                 [gdb_cv_have_pt_getxmmregs=yes],
1516                 [gdb_cv_have_pt_getxmmregs=no])])
1517 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1518 if test $gdb_cv_have_pt_getxmmregs = yes; then
1519   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1520   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1521 fi
1522
1523 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1524 # Older FreeBSD versions don't have the pl_tdname member of
1525 # `struct ptrace_lwpinfo'.
1526 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1527                  [#include <sys/ptrace.h>])
1528
1529 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1530 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1531 # FreeBSD 10.3.
1532 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1533                  [#include <sys/ptrace.h>])
1534
1535 if test "$ac_cv_header_sys_procfs_h" = yes; then
1536   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1537   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1538   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1539   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1540   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1541   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1542   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1543
1544   dnl Check for broken prfpregset_t type
1545
1546   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1547   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1548   dnl instead of the struct itself).  We detect this here, and work
1549   dnl around it in gdb_proc_service.h.
1550
1551   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1552     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1553     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1554       [AC_TRY_RUN([#include <sys/procfs.h>
1555        int main ()
1556        {
1557          if (sizeof (prfpregset_t) == sizeof (void *))
1558            return 1;
1559          return 0;
1560        }],
1561        gdb_cv_prfpregset_t_broken=no,
1562        gdb_cv_prfpregset_t_broken=yes,
1563        gdb_cv_prfpregset_t_broken=yes)])
1564     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1565     if test $gdb_cv_prfpregset_t_broken = yes; then
1566       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1567       [Define if the prfpregset_t type is broken.])
1568     fi
1569   fi
1570 fi
1571
1572 # Check if the compiler supports the `long long' type.
1573
1574 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1575                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1576 [[extern long long foo;]],
1577 [[switch (foo & 2) { case 0: return 1; }]])],
1578                                   gdb_cv_c_long_long=yes,
1579                                   gdb_cv_c_long_long=no)])
1580 if test $gdb_cv_c_long_long != yes; then
1581   # libdecnumber requires long long.
1582   AC_MSG_ERROR([Compiler must support long long for GDB.])
1583 fi
1584
1585 # Check if the compiler and runtime support printing long longs.
1586
1587 AC_CACHE_CHECK([for long long support in printf],
1588                gdb_cv_printf_has_long_long,
1589                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1590 [[char buf[32];
1591   long long l = 0;
1592   l = (l << 16) + 0x0123;
1593   l = (l << 16) + 0x4567;
1594   l = (l << 16) + 0x89ab;
1595   l = (l << 16) + 0xcdef;
1596   sprintf (buf, "0x%016llx", l);
1597   return (strcmp ("0x0123456789abcdef", buf));]])],
1598                               gdb_cv_printf_has_long_long=yes,
1599                               gdb_cv_printf_has_long_long=no,
1600                               gdb_cv_printf_has_long_long=no)])
1601 if test $gdb_cv_printf_has_long_long = yes; then
1602   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1603             [Define to 1 if the "%ll" format works to print long longs.])
1604 fi
1605
1606 # Check if the compiler and runtime support printing decfloats.
1607
1608 AC_CACHE_CHECK([for decfloat support in printf],
1609                gdb_cv_printf_has_decfloat,
1610                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1611 [[char buf[64];
1612   _Decimal32 d32 = 1.2345df;
1613   _Decimal64 d64 = 1.2345dd;
1614   _Decimal128 d128 = 1.2345dl;
1615   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1616   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1617                               gdb_cv_printf_has_decfloat=yes,
1618                               gdb_cv_printf_has_decfloat=no,
1619                               gdb_cv_printf_has_decfloat=no)])
1620 if test $gdb_cv_printf_has_decfloat = yes; then
1621   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1622             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1623 fi
1624
1625 # Check if the compiler supports the `long double' type.  We can't use
1626 # AC_C_LONG_DOUBLE because that one does additional checks on the
1627 # constants defined in <float.h> that fail on some systems,
1628 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1629
1630 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1631                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1632                                   gdb_cv_c_long_double=yes,
1633                                   gdb_cv_c_long_double=no)])
1634 if test $gdb_cv_c_long_double = yes; then
1635   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1636            [Define to 1 if the compiler supports long double.])
1637 fi
1638
1639 # Check if the compiler and runtime support printing long doubles.
1640
1641 AC_CACHE_CHECK([for long double support in printf],
1642                gdb_cv_printf_has_long_double,
1643                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1644 [[char buf[16];
1645   long double f = 3.141592653;
1646   sprintf (buf, "%Lg", f);
1647   return (strncmp ("3.14159", buf, 7));]])],
1648                               gdb_cv_printf_has_long_double=yes,
1649                               gdb_cv_printf_has_long_double=no,
1650                               gdb_cv_printf_has_long_double=no)])
1651 if test $gdb_cv_printf_has_long_double = yes; then
1652   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1653             [Define to 1 if the "%Lg" format works to print long doubles.])
1654 fi
1655
1656 # Check if the compiler and runtime support scanning long doubles.
1657
1658 AC_CACHE_CHECK([for long double support in scanf],
1659                gdb_cv_scanf_has_long_double,
1660                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1661 [[#include <stdio.h>]],
1662 [[char *buf = "3.141592653";
1663   long double f = 0;
1664   sscanf (buf, "%Lg", &f);
1665   return !(f > 3.14159 && f < 3.14160);]])],
1666                               gdb_cv_scanf_has_long_double=yes,
1667                               gdb_cv_scanf_has_long_double=no,
1668                               gdb_cv_scanf_has_long_double=no)])
1669 if test $gdb_cv_scanf_has_long_double = yes; then
1670   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1671             [Define to 1 if the "%Lg" format works to scan long doubles.])
1672 fi
1673
1674 case ${host_os} in
1675 aix*)
1676   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1677     SAVE_LDFLAGS=$LDFLAGS
1678
1679     case $GCC in
1680     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1681     *) gdb_cv_bigtoc=-bbigtoc ;;
1682     esac
1683
1684     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1685     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1686     LDFLAGS="${SAVE_LDFLAGS}"
1687   ])
1688   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1689   ;;
1690 esac
1691
1692 AC_MSG_CHECKING(for the dynamic export flag)
1693 dynamic_list=false
1694 if test "${gdb_native}" = yes; then
1695    # The dynamically loaded libthread_db needs access to symbols in the gdb
1696    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1697    # may not be supported there.
1698    old_LDFLAGS="$LDFLAGS"
1699    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1700    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1701    LDFLAGS="$LDFLAGS $RDYNAMIC"
1702    if test "${have_libpython}" = no; then
1703      AC_TRY_LINK([], [], [dynamic_list=true])
1704    else
1705      # Workaround http://bugs.python.org/issue4434 where static
1706      # libpythonX.Y.a would get its symbols required for
1707      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1708      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1709
1710      # Note the workaround for Python
1711      # http://bugs.python.org/issue10112 earlier has removed
1712      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1713      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1714      # always pass.
1715      old_CFLAGS="$CFLAGS"
1716      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1717      old_LIBS="$LIBS"
1718      LIBS="$LIBS $PYTHON_LIBS"
1719      old_CPPFLAGS="$CPPFLAGS"
1720      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1721      AC_RUN_IFELSE(
1722        [AC_LANG_PROGRAM(
1723          [#include "Python.h"],
1724          [int err;
1725           Py_Initialize ();
1726           err = PyRun_SimpleString ("import itertools\n");
1727           Py_Finalize ();
1728           return err == 0 ? 0 : 1;])],
1729        [dynamic_list=true], [], [true])
1730      LIBS="$old_LIBS"
1731      CFLAGS="$old_CFLAGS"
1732      CPPFLAGS="$old_CPPFLAGS"
1733    fi
1734    LDFLAGS="$old_LDFLAGS"
1735 fi
1736 if $dynamic_list; then
1737   found="-Wl,--dynamic-list"
1738   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1739 else
1740   found="-rdynamic"
1741   RDYNAMIC="-rdynamic"
1742 fi
1743 AC_SUBST(RDYNAMIC)
1744 AC_MSG_RESULT($found)
1745
1746 dnl For certain native configurations, we need to check whether thread
1747 dnl support can be built in or not.
1748 dnl
1749 dnl Note that we only want this if we are both native (host == target),
1750 dnl and not doing a canadian cross build (build == host).
1751
1752 if test ${build} = ${host} -a ${host} = ${target} ; then
1753    case ${host_os} in
1754    aix*)
1755       AC_MSG_CHECKING(for AiX thread debugging library)
1756       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1757                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1758                                    [#ifndef PTHDB_VERSION_3
1759                                     #error
1760                                     #endif],
1761                                    gdb_cv_have_aix_thread_debug=yes,
1762                                    gdb_cv_have_aix_thread_debug=no)])
1763       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1764       if test $gdb_cv_have_aix_thread_debug = yes; then
1765          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1766          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1767          LIBS="$LIBS -lpthdebug"
1768
1769          # Older versions of AIX do not provide the declaration for
1770          # the getthrds function (it appears that it was introduced
1771          # with AIX 6.x).
1772          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1773       fi
1774       ;;
1775    esac
1776    AC_SUBST(CONFIG_LDFLAGS)
1777 fi
1778
1779 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1780 dnl other error codes.
1781 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1782    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1783                   gdb_cv_thread_db_h_has_td_notalloc,
1784      AC_TRY_COMPILE(
1785        [#include <thread_db.h>],
1786        [int i = TD_NOTALLOC;],
1787        gdb_cv_thread_db_h_has_td_notalloc=yes,
1788        gdb_cv_thread_db_h_has_td_notalloc=no
1789      )
1790    )
1791    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1792                   gdb_cv_thread_db_h_has_td_version,
1793      AC_TRY_COMPILE(
1794        [#include <thread_db.h>],
1795        [int i = TD_VERSION;],
1796        gdb_cv_thread_db_h_has_td_version=yes,
1797        gdb_cv_thread_db_h_has_td_version=no
1798      )
1799    )
1800    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1801                   gdb_cv_thread_db_h_has_td_notls,
1802      AC_TRY_COMPILE(
1803        [#include <thread_db.h>],
1804        [int i = TD_NOTLS;],
1805        gdb_cv_thread_db_h_has_td_notls=yes,
1806        gdb_cv_thread_db_h_has_td_notls=no
1807      )
1808    )
1809 fi
1810 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1811   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1812             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1813 fi
1814 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1815   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1816             [Define if <thread_db.h> has the TD_VERSION error code.])
1817 fi
1818 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1819   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1820             [Define if <thread_db.h> has the TD_NOTLS error code.])
1821 fi
1822
1823 dnl Check if we can disable the virtual address space randomization.
1824 dnl The functionality of setarch -R.
1825 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1826 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1827 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1828 #       define ADDR_NO_RANDOMIZE 0x0040000
1829 #      endif
1830        /* Test the flag could be set and stays set.  */
1831        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1832        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1833            return 1])])
1834 AC_RUN_IFELSE([PERSONALITY_TEST],
1835               [have_personality=true],
1836               [have_personality=false],
1837               [AC_LINK_IFELSE([PERSONALITY_TEST],
1838                               [have_personality=true],
1839                               [have_personality=false])])
1840 if $have_personality
1841 then
1842     AC_DEFINE([HAVE_PERSONALITY], 1,
1843               [Define if you support the personality syscall.])
1844 fi
1845
1846 dnl Set the host's .gdbinit filename.
1847 case $host_os in
1848   go32* | *djgpp*)
1849     gdbinit=gdb.ini
1850     ;;
1851   *)
1852     gdbinit=.gdbinit
1853     ;;
1854 esac
1855 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1856
1857 dnl Handle optional features that can be enabled.
1858
1859 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1860 # except that the argument to --with-sysroot is optional.
1861 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1862 if test "x$with_sysroot" = xyes; then
1863   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1864 fi
1865 AC_ARG_WITH(sysroot,
1866   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1867                  [search for usr/lib et al within DIR]),
1868   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1869 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1870               [search for usr/lib et al within DIR])
1871 AC_SUBST(TARGET_SYSTEM_ROOT)
1872 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1873
1874 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1875     [automatically load a system-wide gdbinit file],
1876     [])
1877
1878 AM_GDB_WARNINGS
1879
1880 # In the Cygwin environment, we need some additional flags.
1881 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1882 [AC_EGREP_CPP(^lose$, [
1883 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1884 lose
1885 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1886
1887
1888 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1889 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1890 case ${host} in
1891   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1892   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1893   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1894 esac
1895 AC_SUBST(SER_HARDWIRE)
1896
1897 # libreadline needs libuser32.a in a cygwin environment
1898 WIN32LIBS=
1899 if test x$gdb_cv_os_cygwin = xyes; then
1900     WIN32LIBS="-luser32"
1901     case "${target}" in
1902         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1903         ;;
1904     esac
1905 fi
1906
1907 # The ser-tcp.c module requires sockets.
1908 case ${host} in
1909   *mingw32*)
1910     AC_DEFINE(USE_WIN32API, 1,
1911               [Define if we should use the Windows API, instead of the
1912                POSIX API.  On Windows, we use the Windows API when
1913                building for MinGW, but the POSIX API when building
1914                for Cygwin.])
1915     WIN32LIBS="$WIN32LIBS -lws2_32"
1916     ;;
1917 esac
1918 AC_SUBST(WIN32LIBS)
1919
1920 # Add ELF support to GDB, but only if BFD includes ELF support.
1921 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1922                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1923 if test $gdb_cv_var_elf = yes; then
1924   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1925   AC_DEFINE(HAVE_ELF, 1,
1926             [Define if ELF support should be included.])
1927   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1928   if test "$plugins" = "yes"; then
1929     AC_SEARCH_LIBS(dlopen, dl)
1930   fi
1931 fi
1932
1933 # Add macho support to GDB, but only if BFD includes it.
1934 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1935                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1936 if test $gdb_cv_var_macho = yes; then
1937   CONFIG_OBS="$CONFIG_OBS machoread.o"
1938 fi
1939
1940 # Add any host-specific objects to GDB.
1941 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1942
1943 # If building on ELF, look for lzma support for embedded compressed debug info.
1944 if test $gdb_cv_var_elf = yes; then
1945   AC_ARG_WITH(lzma,
1946     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1947     [], [with_lzma=auto])
1948   AC_MSG_CHECKING([whether to use lzma])
1949   AC_MSG_RESULT([$with_lzma])
1950
1951   if test "${with_lzma}" != no; then
1952     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1953                           [lzma_index_iter iter;
1954                            lzma_index_iter_init (&iter, 0);
1955                            lzma_mf_is_supported (LZMA_MF_HC3);])
1956     if test "$HAVE_LIBLZMA" != yes; then
1957       if test "$with_lzma" = yes; then
1958         AC_MSG_ERROR([missing liblzma for --with-lzma])
1959       fi
1960     fi
1961   fi
1962 fi
1963
1964 LIBGUI="../libgui/src/libgui.a"
1965 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1966 AC_SUBST(LIBGUI)
1967 AC_SUBST(GUI_CFLAGS_X)
1968
1969 WIN32LDAPP=
1970 AC_SUBST(WIN32LIBS)
1971 AC_SUBST(WIN32LDAPP)
1972
1973 case "${host}" in
1974 *-*-cygwin* | *-*-mingw* )
1975     configdir="win"
1976     ;;
1977 *)
1978     configdir="unix"
1979     ;;
1980 esac
1981
1982 GDBTKLIBS=
1983 if test "${enable_gdbtk}" = "yes"; then
1984
1985     # Gdbtk must have an absolute path to srcdir in order to run
1986     # properly when not installed.
1987     here=`pwd`
1988     cd ${srcdir}
1989     GDBTK_SRC_DIR=`pwd`
1990     cd $here
1991
1992     SC_PATH_TCLCONFIG
1993
1994     # If $no_tk is nonempty, then we can't do Tk, and there is no
1995     # point to doing Tcl.
1996     SC_PATH_TKCONFIG
1997
1998     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1999         SC_LOAD_TCLCONFIG
2000
2001         # Check for in-tree tcl
2002         here=`pwd`
2003         cd ${srcdir}/..
2004         topdir=`pwd`
2005         cd ${here}
2006
2007         intree="no"
2008         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2009           intree="yes"
2010         fi
2011
2012         # Find Tcl private headers
2013         if test x"${intree}" = xno; then
2014           CY_AC_TCL_PRIVATE_HEADERS
2015           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2016           TCL_LIBRARY="${TCL_LIB_SPEC}"
2017           TCL_DEPS=""
2018         else
2019           # If building tcl in the same src tree, private headers
2020           # are not needed, but we need to be sure to use the right
2021           # headers library
2022           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2023           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2024           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2025         fi
2026         AC_SUBST(TCL_INCLUDE)
2027         AC_SUBST(TCL_LIBRARY)
2028         AC_SUBST(TCL_DEPS)
2029
2030         SC_LOAD_TKCONFIG
2031
2032         # Check for in-tree Tk
2033         intree="no"
2034         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2035           intree="yes"
2036         fi
2037
2038         # Find Tk private headers
2039         if test x"${intree}" = xno; then
2040           CY_AC_TK_PRIVATE_HEADERS
2041           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2042           TK_LIBRARY=${TK_LIB_SPEC}
2043           TK_DEPS=""
2044         else
2045           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2046           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2047           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2048         fi
2049         AC_SUBST(TK_INCLUDE)
2050         AC_SUBST(TK_LIBRARY)
2051         AC_SUBST(TK_DEPS)
2052         AC_SUBST(TK_XINCLUDES)
2053
2054         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2055
2056         # Include some libraries that Tcl and Tk want.
2057         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2058         # Yes, the ordering seems wrong here.  But it isn't.
2059         # TK_LIBS is the list of libraries that need to be linked
2060         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2061         # were in LIBS then any link tests after this point would
2062         # try to include things like `$(LIBGUI)', which wouldn't work.
2063         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2064
2065         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2066         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2067         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2068         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2069         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2070         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2071         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2072
2073         if test x$gdb_cv_os_cygwin = xyes; then
2074           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2075           WIN32LDAPP="-Wl,--subsystem,console"
2076           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2077         fi
2078
2079         AC_CONFIG_SUBDIRS(gdbtk)
2080     fi
2081 fi
2082
2083 AC_SUBST(X_CFLAGS)
2084 AC_SUBST(X_LDFLAGS)
2085 AC_SUBST(X_LIBS)
2086 AC_SUBST(GDBTKLIBS)
2087 AC_SUBST(GDBTK_CFLAGS)
2088 AC_SUBST(GDBTK_SRC_DIR)
2089
2090 AC_PATH_X
2091
2092 # Unlike the sim directory, whether a simulator is linked is controlled by
2093 # presence of a gdb_sim definition in the target configure.tgt entry.
2094 # This code just checks for a few cases where we'd like to ignore those
2095 # definitions, even when they're present in the '.mt' file.  These cases
2096 # are when --disable-sim is specified, or if the simulator directory is
2097 # not part of the source tree.
2098 #
2099 AC_ARG_ENABLE(sim,
2100 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2101 [echo "enable_sim = $enable_sim";
2102  echo "enableval = ${enableval}";
2103  case "${enableval}" in
2104   yes) ignore_sim=false ;;
2105   no)  ignore_sim=true ;;
2106   *)   ignore_sim=false ;;
2107  esac],
2108 [ignore_sim=false])
2109
2110 if test ! -d "${srcdir}/../sim"; then
2111   ignore_sim=true
2112 fi
2113
2114 SIM=
2115 SIM_OBS=
2116 if test "${ignore_sim}" = "false"; then
2117   if test x"${gdb_sim}" != x ; then
2118     SIM="${gdb_sim}"
2119     SIM_OBS="remote-sim.o"
2120     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2121
2122     # Some tdep code should only be compiled in when the ppc sim is
2123     # built.  PR sim/13418.
2124     case $target in
2125       powerpc*-*-*)
2126         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2127         ;;
2128     esac
2129   fi
2130 fi
2131 AC_SUBST(SIM)
2132 AC_SUBST(SIM_OBS)
2133
2134 AC_SUBST(ENABLE_CFLAGS)
2135 AC_SUBST(PROFILE_CFLAGS)
2136
2137 AC_SUBST(CONFIG_OBS)
2138 AC_SUBST(CONFIG_DEPS)
2139 AC_SUBST(CONFIG_SRCS)
2140 AC_SUBST(CONFIG_ALL)
2141 AC_SUBST(CONFIG_CLEAN)
2142 AC_SUBST(CONFIG_INSTALL)
2143 AC_SUBST(CONFIG_UNINSTALL)
2144
2145 # List of host floatformats.
2146 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2147 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2148 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2149
2150 # target_subdir is used by the testsuite to find the target libraries.
2151 target_subdir=
2152 if test "${host}" != "${target}"; then
2153     target_subdir="${target_alias}/"
2154 fi
2155 AC_SUBST(target_subdir)
2156
2157 # Import nat definitions.
2158 nat_makefile_frag=/dev/null
2159 if test "${gdb_native}" = "yes"; then
2160   . ${srcdir}/configure.nat
2161   nativefile=$NAT_FILE
2162 fi
2163
2164 AC_SUBST(NAT_FILE)
2165 AC_SUBST(NATDEPFILES)
2166 AC_SUBST(NAT_CDEPS)
2167 AC_SUBST(LOADLIBES)
2168 AC_SUBST(MH_CFLAGS)
2169 AC_SUBST(XM_CLIBS)
2170 AC_SUBST(NAT_GENERATED_FILES)
2171 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2172 AC_SUBST_FILE(nat_makefile_frag)
2173
2174 if test x"${gdb_osabi}" != x ; then
2175     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2176                        [Define to the default OS ABI for this configuration.])
2177 fi
2178
2179 # Enable multi-ice-gdb-server.
2180 AC_ARG_ENABLE(multi-ice,
2181 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2182   [case $enableval in
2183     yes | no)
2184       ;;
2185     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2186   esac])
2187 if test "x$enable_multi_ice" = xyes; then
2188    AC_CONFIG_SUBDIRS(multi-ice)
2189 fi
2190
2191 AC_ARG_ENABLE(gdbserver,
2192 AS_HELP_STRING([--enable-gdbserver],
2193                [automatically build gdbserver (yes/no/auto, default is auto)]),
2194 [case "${enableval}" in
2195   yes| no|auto) ;;
2196   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2197 esac],[enable_gdbserver=auto])
2198
2199 # We only build gdbserver automatically in a native configuration, and
2200 # only if the user did not explicitly disable its build.
2201 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2202   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2203   if test "x$build_gdbserver" = xyes; then
2204     AC_MSG_RESULT(yes)
2205     AC_CONFIG_SUBDIRS(gdbserver)
2206     gdbserver_build_enabled=yes
2207   else
2208     AC_MSG_RESULT(no)
2209   fi
2210 fi
2211
2212 # If the user explicitly request the gdbserver to be built, verify that
2213 # we were in fact able to enable it.
2214 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2215   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2216 fi
2217
2218 # Check for babeltrace and babeltrace-ctf
2219 AC_ARG_WITH(babeltrace,
2220   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2221   [], [with_babeltrace=auto])
2222 AC_MSG_CHECKING([whether to use babeltrace])
2223 AC_MSG_RESULT([$with_babeltrace])
2224
2225 if test "x$with_babeltrace" = "xno"; then
2226   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2227 else
2228   # Append -Werror to CFLAGS so that configure can catch the warning
2229   # "assignment from incompatible pointer type", which is related to
2230   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2231   # in GDB, while babeltrace 1.0.3 is broken.
2232   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2233   # safe to save and restore CFLAGS here.
2234   saved_CFLAGS=$CFLAGS
2235   CFLAGS="$CFLAGS -Werror"
2236   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2237                         [#include <babeltrace/babeltrace.h>
2238                          #include <babeltrace/ctf/events.h>
2239                          #include <babeltrace/ctf/iterator.h>],
2240                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2241                         struct bt_ctf_event *event = NULL;
2242                         const struct bt_definition *scope;
2243
2244                         pos->type = BT_SEEK_BEGIN;
2245                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2246                         scope = bt_ctf_get_top_level_scope (event,
2247                                                            BT_STREAM_EVENT_HEADER);
2248                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2249                         ])
2250   CFLAGS=$saved_CFLAGS
2251
2252   if test "$HAVE_LIBBABELTRACE" != yes; then
2253      if test "$with_babeltrace" = yes; then
2254        AC_MSG_ERROR([babeltrace is missing or unusable])
2255      else
2256        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2257      fi
2258   fi
2259 fi
2260
2261 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2262 # empty version.
2263
2264 files=
2265 links=
2266
2267 rm -f nm.h
2268 if test "${nativefile}" != ""; then
2269     case "${nativefile}" in
2270       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2271       * ) GDB_NM_FILE="${nativefile}"
2272     esac
2273     files="${files} ${GDB_NM_FILE}"
2274     links="${links} nm.h"
2275     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2276 fi
2277 AC_SUBST(GDB_NM_FILE)
2278
2279 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2280 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2281 if test "x$USE_MAINTAINER_MODE" = xyes; then
2282   if test "${XSLTPROC}" = missing; then
2283     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2284   fi
2285 fi
2286 AC_SUBST(XSLTPROC)
2287
2288 AC_LINK_FILES($files, $links)
2289
2290 dnl Check for exe extension set on certain hosts (e.g. Win32)
2291 AC_EXEEXT
2292
2293 dnl  Detect the character set used by this host.
2294 dnl  At the moment, we just assume it's UTF-8.
2295 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2296           [Define to be a string naming the default host character set.])
2297
2298 if $development; then
2299   AC_DEFINE(GDB_SELF_TEST, 1,
2300             [Define if self-testing features should be enabled])
2301   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) common/selftest.o selftest-arch.o"
2302   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) common/selftest.c selftest-arch.c"
2303 fi
2304
2305 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2306 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2307 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2308 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2309 [
2310 case x$CONFIG_HEADERS in
2311 xconfig.h:config.in)
2312 echo > stamp-h ;;
2313 esac
2314 ])
2315
2316 AC_OUTPUT