gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_USE_SYSTEM_EXTENSIONS
  28 gl_EARLY
  29 ACX_LARGEFILE
  30 AM_PROG_CC_STDC
  31
  32 AC_CONFIG_AUX_DIR(..)
  33 AC_CANONICAL_SYSTEM
  34
  35 # Dependency checking.
  36 ZW_CREATE_DEPDIR
  37 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  38
  39 # Check for the 'make' the user wants to use.
  40 AC_CHECK_PROGS(MAKE, make)
  41 MAKE_IS_GNU=
  42 case "`$MAKE --version 2>&1 | sed 1q`" in
  43   *GNU*)
  44     MAKE_IS_GNU=yes
  45     ;;
  46 esac
  47 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  48 AC_PROG_MAKE_SET
  49
  50 dnl List of object files and targets accumulated by configure.
  51
  52 CONFIG_OBS=
  53 CONFIG_DEPS=
  54 CONFIG_SRCS=
  55 ENABLE_CFLAGS=
  56
  57 CONFIG_ALL=
  58 CONFIG_CLEAN=
  59 CONFIG_INSTALL=
  60 CONFIG_UNINSTALL=
  61
  62 dnl Set up for gettext.
  63 ZW_GNU_GETTEXT_SISTER_DIR
  64
  65 localedir='${datadir}/locale'
  66 AC_SUBST(localedir)
  67
  68 if test x"$USE_NLS" = xyes; then
  69    CONFIG_ALL="$CONFIG_ALL all-po"
  70    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  71    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  72    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  73 fi
  74
  75 gl_INIT
  76
  77 # For Makefile dependencies.
  78 GNULIB_STDINT_H=
  79 if test x"$STDINT_H" != x; then
  80   GNULIB_STDINT_H=gnulib/$STDINT_H
  81 fi
  82 AC_SUBST(GNULIB_STDINT_H)
  83
  84 PACKAGE=gdb
  85 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  86 AC_SUBST(PACKAGE)
  87
  88 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  89 # rely on it - libiberty is built before texinfo.
  90 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  91 if test "x$MAKEINFO" = "x"; then
  92   AC_ERROR([makeinfo is required for compilation])
  93 else
  94   case "$MAKEINFO" in
  95     */missing\ makeinfo*)
  96       AC_ERROR([makeinfo is required for compilation])
  97       ;;
  98   esac
  99 fi
 100 AC_SUBST(MAKEINFO)
 101
 102 # --split-size=5000000 may be already in $MAKEINFO from parent configure.
 103 # Re-running configure in gdb/ would lose it so ensure it stays present.
 104 MAKEINFOFLAGS=${MAKEINFOFLAGS---split-size=5000000}
 105 AC_SUBST(MAKEINFOFLAGS)
 106
 107 MAKEINFO_EXTRA_FLAGS=""
 108 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 109   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 110   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 111     gdb_cv_have_makeinfo_click=yes
 112   else
 113     gdb_cv_have_makeinfo_click=no
 114   fi])
 115 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 116   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 117 fi
 118 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 119
 120 # GDB does not use automake, but gnulib does.  This line lets us
 121 # generate its Makefile.in.
 122 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
 123
 124 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 125     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 126     [${libdir}/debug])
 127
 128 # We can't pass paths as command line arguments.
 129 # Mingw32 tries to be clever and will convert the paths for us.
 130 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 131 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 132 # This breaks GDB's relocatable path conversions since paths passed in
 133 # config.h would not get so translated, the path prefixes no longer match.
 134 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 135
 136 # GDB's datadir relocation
 137
 138 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 139     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 140     [${datadir}/gdb])
 141
 142 AC_ARG_WITH(relocated-sources,
 143 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 144 [reloc_srcdir="${withval}"
 145  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 146               [Relocated directory for source files. ])
 147 ])
 148
 149 AC_CONFIG_SUBDIRS(testsuite)
 150
 151 # Check whether to support alternative target configurations
 152 AC_ARG_ENABLE(targets,
 153 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 154 [case "${enableval}" in
 155   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 156             ;;
 157   no)       enable_targets= ;;
 158   *)        enable_targets=$enableval ;;
 159 esac])
 160
 161 # Check whether to enable 64-bit support on 32-bit hosts
 162 AC_ARG_ENABLE(64-bit-bfd,
 163 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 164 [case "${enableval}" in
 165   yes)  want64=true  ;;
 166   no)   want64=false ;;
 167   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 168 esac],[want64=false])dnl
 169
 170 # Provide defaults for some variables set by the per-host and per-target
 171 # configuration.
 172 gdb_host_obs=posix-hdep.o
 173
 174 if test "${target}" = "${host}"; then
 175   gdb_native=yes
 176 else
 177   gdb_native=no
 178 fi
 179
 180 . $srcdir/configure.host
 181
 182 # Accumulate some settings from configure.tgt over all enabled targets
 183
 184 TARGET_OBS=
 185 all_targets=
 186
 187 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 188 do
 189   if test "$targ_alias" = "all"; then
 190     all_targets=true
 191   else
 192     # Canonicalize the secondary target names.
 193     result=`$ac_config_sub $targ_alias 2>/dev/null`
 194     if test -n "$result"; then
 195         targ=$result
 196     else
 197         targ=$targ_alias
 198     fi
 199
 200     . ${srcdir}/configure.tgt
 201
 202     AS_IF([test -z "${gdb_target_obs}"],
 203       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 204
 205     # Target-specific object files
 206     for i in ${gdb_target_obs}; do
 207         case " $TARGET_OBS " in
 208         *" ${i} "*) ;;
 209         *)
 210           TARGET_OBS="$TARGET_OBS ${i}"
 211           ;;
 212         esac
 213     done
 214
 215     # Check whether this target needs 64-bit CORE_ADDR
 216     if test x${want64} = xfalse; then
 217       . ${srcdir}/../bfd/config.bfd
 218     fi
 219   fi
 220 done
 221
 222 if test x${all_targets} = xtrue; then
 223
 224   # We want all 64-bit targets if we either:
 225   #  - run on a 64-bit host  or
 226   #  - already require 64-bit support for some other target  or
 227   #  - the --enable-64-bit-bfd option was supplied
 228   # Otherwise we only support all 32-bit targets.
 229   #
 230   # NOTE: This test must be in sync with the corresponding
 231   #       tests in BFD!
 232
 233   if test x${want64} = xfalse; then
 234     AC_CHECK_SIZEOF(long)
 235     if test "x${ac_cv_sizeof_long}" = "x8"; then
 236       want64=true
 237     fi
 238   fi
 239   if test x${want64} = xtrue; then
 240     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 241   else
 242     TARGET_OBS='$(ALL_TARGET_OBS)'
 243   fi
 244 fi
 245
 246 AC_SUBST(TARGET_OBS)
 247
 248 # For other settings, only the main target counts.
 249 gdb_sim=
 250 gdb_osabi=
 251 build_gdbserver=
 252 targ=$target; . ${srcdir}/configure.tgt
 253
 254 # Fetch the default architecture and default target vector from BFD.
 255 targ=$target; . $srcdir/../bfd/config.bfd
 256
 257 # We only want the first architecture, so strip off the others if
 258 # there is more than one.
 259 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 260
 261 if test "x$targ_archs" != x; then
 262   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 263     [Define to BFD's default architecture. ])
 264 fi
 265 if test "x$targ_defvec" != x; then
 266   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 267     [Define to BFD's default target vector. ])
 268 fi
 269
 270 # The CLI cannot be disabled yet, but may be in the future.
 271
 272 # Enable CLI.
 273 AC_ARG_ENABLE(gdbcli,
 274 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 275   [case $enableval in
 276     yes)
 277       ;;
 278     no)
 279       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 282   esac],
 283   [enable_gdbcli=yes])
 284 if test x"$enable_gdbcli" = xyes; then
 285   if test -d $srcdir/cli; then
 286     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 287     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 288     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 289     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 290   fi
 291 fi
 292
 293 # Enable MI.
 294 AC_ARG_ENABLE(gdbmi,
 295 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 296   [case $enableval in
 297     yes | no)
 298       ;;
 299     *)
 300       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 301   esac],
 302   [enable_gdbmi=yes])
 303 if test x"$enable_gdbmi" = xyes; then
 304   if test -d $srcdir/mi; then
 305     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 306     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 307     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 308     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 309   fi
 310 fi
 311
 312 # Enable TUI.
 313 AC_ARG_ENABLE(tui,
 314 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 315   [case $enableval in
 316     yes | no | auto)
 317       ;;
 318     *)
 319       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 320   esac],enable_tui=auto)
 321
 322 # Enable gdbtk.
 323 AC_ARG_ENABLE(gdbtk,
 324 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 325   [case $enableval in
 326     yes | no)
 327       ;;
 328     *)
 329       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 330   esac],
 331   [if test -d $srcdir/gdbtk; then
 332     enable_gdbtk=yes
 333   else
 334     enable_gdbtk=no
 335   fi])
 336 # We unconditionally disable gdbtk tests on selected platforms.
 337 case $host_os in
 338   go32* | windows*)
 339     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 340     enable_gdbtk=no ;;
 341 esac
 342
 343 # Libunwind support.
 344 AC_ARG_WITH(libunwind,
 345 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 346 [case "${withval}" in
 347   yes)  enable_libunwind=yes ;;
 348   no)   enable_libunwind=no ;;
 349   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 350 esac],[
 351   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 352   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 353     enable_libunwind=yes;
 354   fi
 355 ])
 356
 357 if test x"$enable_libunwind" = xyes; then
 358   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 359   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 360   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 361   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 362   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 363 fi
 364
 365 opt_curses=no
 366 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 367
 368 prefer_curses=no
 369 if test "$opt_curses" = "yes"; then
 370   prefer_curses=yes
 371 fi
 372
 373 # Profiling support.
 374 AC_ARG_ENABLE(profiling,
 375 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 376   [case $enableval in
 377     yes | no)
 378       ;;
 379     *)
 380       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 381   esac],
 382  [enable_profiling=no])
 383
 384 AC_CHECK_FUNCS(monstartup _mcleanup)
 385 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 386 [AC_TRY_LINK(
 387 [#include <stdlib.h>
 388 extern char _etext;
 389 ],
 390 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 391 if test $ac_cv_var__etext = yes; then
 392   AC_DEFINE(HAVE__ETEXT, 1,
 393             [Define to 1 if your system has the _etext variable. ])
 394 fi
 395 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 396 [AC_TRY_LINK(
 397 [#include <stdlib.h>
 398 extern char etext;
 399 ],
 400 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 401 if test $ac_cv_var_etext = yes; then
 402   AC_DEFINE(HAVE_ETEXT, 1,
 403             [Define to 1 if your system has the etext variable. ])
 404 fi
 405 if test "$enable_profiling" = yes ; then
 406   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 407     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 408   fi
 409   PROFILE_CFLAGS=-pg
 410   OLD_CFLAGS="$CFLAGS"
 411   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 412
 413   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 414     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 415      ac_cv_cc_supports_pg=no)])
 416
 417   if test $ac_cv_cc_supports_pg = no; then
 418     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 419   fi
 420
 421   CFLAGS="$OLD_CFLAGS"
 422 fi
 423
 424 ACX_PKGVERSION([GDB])
 425 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 426 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 427 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 428
 429 # --------------------- #
 430 # Checks for programs.  #
 431 # --------------------- #
 432
 433 AC_PROG_AWK
 434 AC_PROG_INSTALL
 435 AC_PROG_LN_S
 436 AC_PROG_RANLIB
 437 AC_PROG_YACC
 438
 439 AC_CHECK_TOOL(AR, ar)
 440 AC_CHECK_TOOL(DLLTOOL, dlltool)
 441 AC_CHECK_TOOL(WINDRES, windres)
 442
 443 # Needed for GNU/Hurd.
 444 AC_CHECK_TOOL(MIG, mig)
 445
 446 # ---------------------- #
 447 # Checks for libraries.  #
 448 # ---------------------- #
 449
 450 # We might need to link with -lm; most simulators need it.
 451 AC_CHECK_LIB(m, main)
 452
 453 # We need to link with -lw to get `wctype' on Solaris before Solaris
 454 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 455 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 456 # is known to have this problem).  Therefore we avoid libw if we can.
 457 AC_CHECK_FUNC(wctype, [],
 458   [AC_CHECK_LIB(w, wctype)])
 459
 460 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 461 AC_SEARCH_LIBS(gethostbyname, nsl)
 462
 463 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 464 AC_SEARCH_LIBS(socketpair, socket)
 465
 466 # Link in zlib if we can.  This allows us to read compressed debug sections.
 467 AM_ZLIB
 468
 469 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 470 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 471
 472 AM_ICONV
 473
 474 # GDB may fork/exec the iconv program to get the list of supported character
 475 # sets.  Allow the user to specify where to find it.
 476 # There are several factors affecting the choice of option name:
 477 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 478 #   the build-time location of libiconv files.
 479 # - The program we need to find is iconv, which comes with glibc.  The user
 480 #   doesn't necessarily have libiconv installed.  Therefore naming this
 481 #   --with-libiconv-foo feels wrong.
 482 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 483 #   defined to work on directories not files (though it really doesn't know
 484 #   the difference).
 485 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 486 #   with --with-libiconv-prefix.
 487 # Putting these together is why the option name is --with-iconv-bin.
 488
 489 AC_ARG_WITH(iconv-bin,
 490 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 491 [iconv_bin="${withval}"
 492  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 493                     [Path of directory of iconv program.])
 494  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 495 ])
 496
 497 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 498 # There is a very specific comment in /usr/include/curses.h explaining that
 499 # termcap routines built into libcurses must not be used.
 500 #
 501 # The symptoms we observed so far is GDB unexpectedly changing
 502 # the terminal settings when tgetent is called - this is particularly
 503 # visible as the output is missing carriage returns, and so rapidly
 504 # becomes very hard to read.
 505 #
 506 # The readline configure script has already decided that libtermcap
 507 # was enough for its purposes, and so decided to build readline using
 508 # libtermcap.  Since the TUI mode requires curses, building GDB with
 509 # TUI enabled results in both libraries to be used at the same time,
 510 # which is not allowed.  This basically means that GDB with TUI is
 511 # broken on alpha-osf.
 512
 513 case $host_os in
 514   osf* )
 515     if test x"$enable_tui" = xyes; then
 516       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 517     fi
 518     if test x"$enable_tui" = xauto; then
 519       enable_tui=no
 520     fi
 521     ;;
 522 esac
 523
 524 # For the TUI, we need enhanced curses functionality.
 525 if test x"$enable_tui" != xno; then
 526   prefer_curses=yes
 527 fi
 528
 529 curses_found=no
 530 if test x"$prefer_curses" = xyes; then
 531   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 532   # curses library because the latter might not provide all the
 533   # functionality we need.  However, this leads to problems on systems
 534   # where the linker searches /usr/local/lib, but the compiler doesn't
 535   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 536   # default installation of ncurses on alpha*-dec-osf* will lead to such
 537   # a situation.
 538   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 539
 540   if test "$ac_cv_search_waddstr" != no; then
 541     curses_found=yes
 542   fi
 543 fi
 544
 545 # Check whether we should enable the TUI, but only do so if we really
 546 # can.
 547 if test x"$enable_tui" != xno; then
 548   if test -d $srcdir/tui; then
 549     if test "$curses_found" != no; then
 550       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 551       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 552       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 553       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 554     else
 555       if test x"$enable_tui" = xyes; then
 556         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 557       else
 558         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 559       fi
 560     fi
 561   fi
 562 fi
 563
 564 # Since GDB uses Readline, we need termcap functionality.  In many
 565 # cases this will be provided by the curses library, but some systems
 566 # have a seperate termcap library, or no curses library at all.
 567
 568 case $host_os in
 569   cygwin*)
 570     if test -d $srcdir/libtermcap; then
 571       LIBS="../libtermcap/libtermcap.a $LIBS"
 572       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 573     fi ;;
 574   go32* | *djgpp*)
 575     ac_cv_search_tgetent="none required"
 576     ;;
 577   *mingw32*)
 578     ac_cv_search_tgetent="none required"
 579     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 580     ;;
 581 esac
 582
 583 # These are the libraries checked by Readline.
 584 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 585
 586 if test "$ac_cv_search_tgetent" = no; then
 587   AC_MSG_ERROR([no termcap library found])
 588 fi
 589
 590 AC_ARG_WITH([system-readline],
 591   [AS_HELP_STRING([--with-system-readline],
 592                   [use installed readline library])])
 593
 594 if test "$with_system_readline" = yes; then
 595   READLINE=-lreadline
 596   READLINE_DEPS=
 597   READLINE_CFLAGS=
 598   READLINE_TEXI_INCFLAG=
 599 else
 600   READLINE='$(READLINE_DIR)/libreadline.a'
 601   READLINE_DEPS='$(READLINE)'
 602   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 603   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 604 fi
 605 AC_SUBST(READLINE)
 606 AC_SUBST(READLINE_DEPS)
 607 AC_SUBST(READLINE_CFLAGS)
 608 AC_SUBST(READLINE_TEXI_INCFLAG)
 609
 610 # Generate jit-reader.h
 611
 612 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 613 TARGET_PTR=
 614
 615 AC_CHECK_SIZEOF(unsigned long long)
 616 AC_CHECK_SIZEOF(unsigned long)
 617 AC_CHECK_SIZEOF(unsigned __int128)
 618
 619 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 620   TARGET_PTR="unsigned long"
 621 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 622   TARGET_PTR="unsigned long long"
 623 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 624   TARGET_PTR="unsigned __int128"
 625 else
 626   TARGET_PTR="unsigned long"
 627 fi
 628
 629 AC_SUBST(TARGET_PTR)
 630 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 631
 632 AC_SEARCH_LIBS(dlopen, dl)
 633
 634 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 635                 [directory to load the JIT readers from],
 636                 [${libdir}/gdb])
 637
 638 AC_ARG_WITH(expat,
 639   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 640   [], [with_expat=auto])
 641 AC_MSG_CHECKING([whether to use expat])
 642 AC_MSG_RESULT([$with_expat])
 643
 644 if test "${with_expat}" = no; then
 645   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 646   HAVE_LIBEXPAT=no
 647 else
 648   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 649                         [XML_Parser p = XML_ParserCreate (0);])
 650   if test "$HAVE_LIBEXPAT" != yes; then
 651     if test "$with_expat" = yes; then
 652       AC_MSG_ERROR([expat is missing or unusable])
 653     else
 654       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 655     fi
 656   else
 657     save_LIBS=$LIBS
 658     LIBS="$LIBS $LIBEXPAT"
 659     AC_CHECK_FUNCS(XML_StopParser)
 660     LIBS=$save_LIBS
 661   fi
 662 fi
 663
 664 dnl Utility to simplify finding libpython.
 665 dnl $1 = pythonX.Y
 666 dnl $2 = the shell variable to assign the result to
 667 dnl      If libpython is found we store $version here.
 668 dnl $3 = additional flags to add to CPPFLAGS
 669 dnl $4 = additional flags to add to LIBS
 670
 671 AC_DEFUN([AC_TRY_LIBPYTHON],
 672 [
 673   version=$1
 674   define([have_libpython_var],$2)
 675   new_CPPFLAGS=$3
 676   new_LIBS=$4
 677   AC_MSG_CHECKING([for ${version}])
 678   save_CPPFLAGS=$CPPFLAGS
 679   save_LIBS=$LIBS
 680   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 681   LIBS="$LIBS $new_LIBS"
 682   found_usable_python=no
 683   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 684                                  [[Py_Initialize ();]]),
 685                  [have_libpython_var=${version}
 686                   found_usable_python=yes
 687                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 688                   PYTHON_LIBS=$new_LIBS])
 689   CPPFLAGS=$save_CPPFLAGS
 690   LIBS=$save_LIBS
 691   AC_MSG_RESULT([${found_usable_python}])
 692 ])
 693
 694 dnl There are several different values for --with-python:
 695 dnl
 696 dnl no -   Don't include python support.
 697 dnl yes -  Include python support, error if it's missing.
 698 dnl        If we find python in $PATH, use it to fetch configure options,
 699 dnl        otherwise assume the compiler can find it with no help from us.
 700 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 701 dnl auto - Same as "yes", but if python is missing from the system,
 702 dnl        fall back to "no".
 703 dnl /path/to/python/exec-prefix -
 704 dnl        Use the python located in this directory.
 705 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 706 dnl        the compilation parameters.  Otherwise use
 707 dnl        -I/path/to/python/exec-prefix/include,
 708 dnl        -L/path/to/python/exec-prefix/lib.
 709 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 710 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 711 dnl        but is deprecated.
 712 dnl /path/to/python/executable -
 713 dnl        Run python-config.py with this version of python to fetch the
 714 dnl        compilation parameters.
 715 dnl        NOTE: This needn't be the real python executable.
 716 dnl        In a cross-compilation scenario (build != host), this could be
 717 dnl        a shell script that provides what python-config.py provides for
 718 dnl        --ldflags, --includes, --exec-prefix.
 719 dnl python-executable -
 720 dnl        Find python-executable in $PATH, and then handle the same as
 721 dnl        /path/to/python/executable.
 722 dnl
 723 dnl If a python program is specified, it is used to run python-config.py and
 724 dnl is passed --ldflags, --includes, --exec-prefix.
 725
 726 AC_ARG_WITH(python,
 727   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 728   [], [with_python=auto])
 729 AC_MSG_CHECKING([whether to use python])
 730 AC_MSG_RESULT([$with_python])
 731
 732 if test "${with_python}" = no; then
 733   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 734   have_libpython=no
 735 else
 736   case "${with_python}" in
 737   /*)
 738     if test -d ${with_python}; then
 739       # Assume the python binary is ${with_python}/bin/python.
 740       python_prog="${with_python}/bin/python"
 741       python_prefix=
 742       # If python does not exit ${with_python}/bin, then try in
 743       # ${with_python}.  On Windows/MinGW, this is where the Python
 744       # executable is.
 745       if test ! -x "${python_prog}"; then
 746         python_prog="${with_python}/python"
 747         python_prefix=
 748       fi
 749       if test ! -x "${python_prog}"; then
 750         # Fall back to gdb 7.0/7.1 behaviour.
 751         python_prog=missing
 752         python_prefix=${with_python}
 753       fi
 754     elif test -x "${with_python}"; then
 755       # While we can't run python compiled for $host (unless host == build),
 756       # the user could write a script that provides the needed information,
 757       # so we support that.
 758       python_prog=${with_python}
 759       python_prefix=
 760     else
 761       AC_ERROR(invalid value for --with-python)
 762     fi
 763     ;;
 764   */*)
 765     # Disallow --with-python=foo/bar.
 766     AC_ERROR(invalid value for --with-python)
 767     ;;
 768   *)
 769     # The user has either specified auto, yes, or the name of the python
 770     # program assumed to be in $PATH.
 771     python_prefix=
 772     case "${with_python}" in
 773     yes | auto)
 774       if test ${build} = ${host}; then
 775         AC_PATH_PROG(python_prog_path, python, missing)
 776         if test "${python_prog_path}" = missing; then
 777           python_prog=missing
 778         else
 779           python_prog=${python_prog_path}
 780         fi
 781       else
 782         # Not much we can do except assume the cross-compiler will find the
 783         # right files.
 784         python_prog=missing
 785       fi
 786       ;;
 787     *)
 788       # While we can't run python compiled for $host (unless host == build),
 789       # the user could write a script that provides the needed information,
 790       # so we support that.
 791       python_prog="${with_python}"
 792       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 793       if test "${python_prog_path}" = missing; then
 794         AC_ERROR(unable to find python program ${python_prog})
 795       fi
 796       ;;
 797     esac
 798   esac
 799
 800   if test "${python_prog}" != missing; then
 801     # We have a python program to use, but it may be too old.
 802     # Don't flag an error for --with-python=auto (the default).
 803     have_python_config=yes
 804     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 805     if test $? != 0; then
 806       have_python_config=failed
 807       if test "${with_python}" != auto; then
 808         AC_ERROR(failure running python-config --includes)
 809       fi
 810     fi
 811     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 812     if test $? != 0; then
 813       have_python_config=failed
 814       if test "${with_python}" != auto; then
 815         AC_ERROR(failure running python-config --ldflags)
 816       fi
 817     fi
 818     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 819     if test $? != 0; then
 820       have_python_config=failed
 821       if test "${with_python}" != auto; then
 822         AC_ERROR(failure running python-config --exec-prefix)
 823       fi
 824     fi
 825   else
 826     # We do not have a python executable we can use to determine where
 827     # to find the Python headers and libs.  We cannot guess the include
 828     # path from the python_prefix either, because that include path
 829     # depends on the Python version.  So, there is nothing much we can
 830     # do except assume that the compiler will be able to find those files.
 831     python_includes=
 832     python_libs=
 833     have_python_config=no
 834   fi
 835
 836   # If we have python-config, only try the configuration it provides.
 837   # Otherwise fallback on the old way of trying different versions of
 838   # python in turn.
 839
 840   have_libpython=no
 841   if test "${have_python_config}" = yes; then
 842     # Determine the Python version by extracting "-lpython<version>"
 843     # part of the python_libs. <version> is usually X.Y with X and Y
 844     # being decimal numbers, but can also be XY (seen on Windows).
 845     #
 846     # The extraction is performed using sed with a regular expression.
 847     # Initially, the regexp used was using the '?' quantifier to make
 848     # the dot in the version number optional.  Unfortunately, this
 849     # does not work with non-GNU versions of sed because, because of
 850     # what looks like a limitation (the '?' quantifier does not work
 851     # with back-references).  We work around this limitation by using
 852     # the '*' quantifier instead.  It means that, in theory, we might
 853     # match unexpected version strings such as "-lpython2..7", but
 854     # this seems unlikely in practice.  And even if that happens,
 855     # an error will be triggered later on, when checking that version
 856     # number.
 857     python_version=`echo " ${python_libs} " \
 858                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 859     case "${python_version}" in
 860     python*)
 861       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 862                        ${python_includes}, ${python_libs})
 863       ;;
 864     *)
 865       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 866       ;;
 867     esac
 868   elif test "${have_python_config}" != failed; then
 869     if test "${have_libpython}" = no; then
 870       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 871                        ${python_includes}, "${python_libs} -lpython2.7")
 872     fi
 873     if test "${have_libpython}" = no; then
 874       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 875                        ${python_includes}, "${python_libs} -lpython2.6")
 876     fi
 877     if test ${have_libpython} = no; then
 878       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 879                        ${python_includes}, "${python_libs} -lpython2.5")
 880     fi
 881     if test ${have_libpython} = no; then
 882       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 883                        ${python_includes}, "${python_libs} -lpython2.4")
 884     fi
 885   fi
 886   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 887     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 888   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 889     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 890   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 891     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 892   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 893     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 894   fi
 895
 896   if test "${have_libpython}" = no; then
 897     case "${with_python}" in
 898     yes)
 899       AC_MSG_ERROR([python is missing or unusable])
 900       ;;
 901     auto)
 902       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 903       ;;
 904     *)
 905       AC_MSG_ERROR([no usable python found at ${with_python}])
 906       ;;
 907     esac
 908   else
 909     if test -n "${python_prefix}"; then
 910       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 911                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 912       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 913     fi
 914   fi
 915 fi
 916
 917 if test "${have_libpython}" != no; then
 918   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 919   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 920   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 921   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 922   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 923   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 924
 925   # Flags needed to compile Python code (taken from python-config --cflags).
 926   # We cannot call python-config directly because it will output whatever was
 927   # used when compiling the Python interpreter itself, including flags which
 928   # would make the python-related objects be compiled differently from the
 929   # rest of GDB (e.g., -O2 and -fPIC).
 930   if test "${GCC}" = yes; then
 931     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 932   fi
 933
 934   if test "x${tentative_python_cflags}" != x; then
 935     AC_MSG_CHECKING(compiler flags for python code)
 936     for flag in ${tentative_python_cflags}; do
 937       # Check that the compiler accepts it
 938       saved_CFLAGS="$CFLAGS"
 939       CFLAGS="$CFLAGS $flag"
 940       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 941       CFLAGS="$saved_CFLAGS"
 942     done
 943     AC_MSG_RESULT(${PYTHON_CFLAGS})
 944   fi
 945
 946   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 947   #    #if _SGIAPI
 948   #    #define siginfo __siginfo
 949   #    #endif
 950   # The problem is that including Python causes some XOPEN macros to be
 951   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 952   # to false.  So, we work around this issue by defining siginfo ourself
 953   # though the command-line.
 954   case "$gdb_host" in
 955     irix*) if test "${GCC}" = yes; then
 956              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 957            fi
 958            ;;
 959   esac
 960 else
 961   # Even if Python support is not compiled in, we need to have these files
 962   # included.
 963   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 964   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 965         python/py-prettyprint.c python/py-auto-load.c"
 966 fi
 967 AC_SUBST(PYTHON_CFLAGS)
 968 AC_SUBST(PYTHON_CPPFLAGS)
 969 AC_SUBST(PYTHON_LIBS)
 970
 971 # ------------------------- #
 972 # Checks for header files.  #
 973 # ------------------------- #
 974
 975 AC_HEADER_DIRENT
 976 AC_HEADER_STAT
 977 AC_HEADER_STDC
 978 # elf_hp.h is for HP/UX 64-bit shared library support.
 979 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 980 # unconditionally, so what's the point in checking these?
 981 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 982                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 983                   stdlib.h string.h memory.h strings.h sys/fault.h \
 984                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 985                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 986                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 987                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 988                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
 989                   dlfcn.h])
 990 AC_CHECK_HEADERS(link.h, [], [],
 991 [#if HAVE_SYS_TYPES_H
 992 # include <sys/types.h>
 993 #endif
 994 #if HAVE_NLIST_H
 995 # include <nlist.h>
 996 #endif
 997 ])
 998 AC_CHECK_HEADERS(sys/proc.h, [], [],
 999 [#if HAVE_SYS_PARAM_H
1000 # include <sys/param.h>
1001 #endif
1002 ])
1003 AC_CHECK_HEADERS(sys/user.h, [], [],
1004 [#if HAVE_SYS_PARAM_H
1005 # include <sys/param.h>
1006 #endif
1007 ])
1008
1009 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1010 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1011 # think that we don't have <curses.h> if we're using GCC.
1012 case $host_os in
1013   solaris2.[[789]])
1014     if test "$GCC" = yes; then
1015       AC_DEFINE(_MSE_INT_H, 1,
1016         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1017    Solaris 2.[789] when using GCC. ])
1018     fi ;;
1019 esac
1020 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1021 AC_CHECK_HEADERS(term.h, [], [],
1022 [#if HAVE_CURSES_H
1023 # include <curses.h>
1024 #endif
1025 ])
1026
1027 # ------------------------- #
1028 # Checks for declarations.  #
1029 # ------------------------- #
1030
1031 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1032                 snprintf, vsnprintf])
1033 AM_LC_MESSAGES
1034
1035 # ----------------------- #
1036 # Checks for structures.  #
1037 # ----------------------- #
1038
1039 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1040
1041 # ------------------ #
1042 # Checks for types.  #
1043 # ------------------ #
1044
1045 AC_TYPE_SIGNAL
1046 AC_CHECK_TYPES(socklen_t, [], [],
1047 [#include <sys/types.h>
1048 #include <sys/socket.h>
1049 ])
1050
1051 # ------------------------------------- #
1052 # Checks for compiler characteristics.  #
1053 # ------------------------------------- #
1054
1055 AC_C_CONST
1056 AC_C_INLINE
1057 AC_C_BIGENDIAN
1058
1059 # ------------------------------ #
1060 # Checks for library functions.  #
1061 # ------------------------------ #
1062
1063 AC_FUNC_ALLOCA
1064 AC_FUNC_MMAP
1065 AC_FUNC_VFORK
1066 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1067                 pipe poll pread pread64 pwrite resize_term \
1068                 sbrk setpgid setpgrp setsid \
1069                 sigaction sigprocmask sigsetmask socketpair syscall \
1070                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1071                 setrlimit getrlimit posix_madvise waitpid lstat])
1072 AM_LANGINFO_CODESET
1073
1074 # Check the return and argument types of ptrace.  No canned test for
1075 # this, so roll our own.
1076 gdb_ptrace_headers='
1077 #if HAVE_SYS_TYPES_H
1078 # include <sys/types.h>
1079 #endif
1080 #if HAVE_SYS_PTRACE_H
1081 # include <sys/ptrace.h>
1082 #endif
1083 #if HAVE_UNISTD_H
1084 # include <unistd.h>
1085 #endif
1086 '
1087 # There is no point in checking if we don't have a prototype.
1088 AC_CHECK_DECLS(ptrace, [], [
1089   : ${gdb_cv_func_ptrace_ret='int'}
1090   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1091 ], $gdb_ptrace_headers)
1092 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1093 # empty argument list, so check for that explicitly.
1094 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1095   AC_TRY_COMPILE($gdb_ptrace_headers,
1096     [extern long ptrace (enum __ptrace_request, ...);],
1097     gdb_cv_func_ptrace_ret='long',
1098     AC_TRY_COMPILE($gdb_ptrace_headers,
1099       [extern int ptrace ();],
1100       gdb_cv_func_ptrace_ret='int',
1101       gdb_cv_func_ptrace_ret='long')))
1102 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1103   [Define as the return type of ptrace.])
1104 # Check argument types.
1105 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1106   AC_TRY_COMPILE($gdb_ptrace_headers,
1107     [extern long ptrace (enum __ptrace_request, ...);],
1108     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1109 for gdb_arg1 in 'int' 'long'; do
1110  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1111   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1112    for gdb_arg4 in 'int' 'long'; do
1113      AC_TRY_COMPILE($gdb_ptrace_headers, [
1114 extern $gdb_cv_func_ptrace_ret
1115   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1116 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1117     break 4;])
1118     for gdb_arg5 in 'int *' 'int' 'long'; do
1119      AC_TRY_COMPILE($gdb_ptrace_headers, [
1120 extern $gdb_cv_func_ptrace_ret
1121   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1122 ], [
1123 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1124     break 5;])
1125     done
1126    done
1127   done
1128  done
1129 done
1130 # Provide a safe default value.
1131 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1132 ])])
1133 ac_save_IFS=$IFS; IFS=','
1134 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1135 IFS=$ac_save_IFS
1136 shift
1137 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1138   [Define to the type of arg 3 for ptrace.])
1139 if test -n "$[5]"; then
1140   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1141     [Define to the type of arg 5 for ptrace.])
1142 fi
1143
1144 dnl AC_FUNC_SETPGRP does not work when cross compiling
1145 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1146 if test "$cross_compiling" = no; then
1147   AC_FUNC_SETPGRP
1148 else
1149   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1150     [AC_TRY_COMPILE([
1151 #include <unistd.h>
1152 ], [
1153   if (setpgrp(1,1) == -1)
1154     exit (0);
1155   else
1156     exit (1);
1157 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1158 if test $ac_cv_func_setpgrp_void = yes; then
1159   AC_DEFINE(SETPGRP_VOID, 1)
1160 fi
1161 fi
1162
1163 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1164 # since sigsetjmp might only be defined as a macro.
1165 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1166 [AC_TRY_COMPILE([
1167 #include <setjmp.h>
1168 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1169 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1170 if test $gdb_cv_func_sigsetjmp = yes; then
1171   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1172 fi
1173
1174 # Assume we'll default to using the included libiberty regex.
1175 gdb_use_included_regex=yes
1176
1177 # However, if the system regex is GNU regex, then default to *not*
1178 # using the included regex.
1179 AC_CACHE_CHECK(
1180   [for GNU regex],
1181   [gdb_cv_have_gnu_regex],
1182   [AC_TRY_COMPILE(
1183     [#include <gnu-versions.h>],
1184     [#define REGEX_INTERFACE_VERSION 1
1185 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1186 # error "Version mismatch"
1187 #endif],
1188     gdb_cv_have_gnu_regex=yes,
1189     gdb_cv_have_gnu_regex=no)])
1190 if test $gdb_cv_have_gnu_regex = yes; then
1191   gdb_use_included_regex=no
1192 fi
1193
1194 AC_ARG_WITH(included-regex,
1195   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1196   gdb_with_regex=$withval,
1197   gdb_with_regex=$gdb_use_included_regex)
1198 if test "$gdb_with_regex" = yes; then
1199   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1200     [Define to 1 if the regex included in libiberty should be used.])
1201 fi
1202
1203 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1204 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1205 [#include <sys/param.h>
1206 #include <sys/proc.h>
1207 ])
1208
1209 # See if <sys/lwp.h> defines `struct lwp`.
1210 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1211 [AC_TRY_COMPILE([#include <sys/param.h>
1212 #include <sys/lwp.h>], [struct lwp l;],
1213 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1214 if test $gdb_cv_struct_lwp = yes; then
1215   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1216             [Define to 1 if your system has struct lwp.])
1217 fi
1218
1219 # See if <machine/reg.h> degines `struct reg'.
1220 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1221 [AC_TRY_COMPILE([#include <sys/types.h>
1222 #include <machine/reg.h>], [struct reg r;],
1223 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1224 if test $gdb_cv_struct_reg = yes; then
1225   AC_DEFINE(HAVE_STRUCT_REG, 1,
1226             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1227 fi
1228
1229 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1230 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1231 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1232                  [#include <machine/reg.h>])
1233
1234 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1235 AC_MSG_CHECKING(for PTRACE_GETREGS)
1236 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1237 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1238                 [PTRACE_GETREGS;],
1239                 [gdb_cv_have_ptrace_getregs=yes],
1240                 [gdb_cv_have_ptrace_getregs=no])])
1241 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1242 if test $gdb_cv_have_ptrace_getregs = yes; then
1243   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1244   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1245 fi
1246
1247 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1248 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1249 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1250 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1251                 [PTRACE_GETFPXREGS;],
1252                 [gdb_cv_have_ptrace_getfpxregs=yes],
1253                 [gdb_cv_have_ptrace_getfpxregs=no])])
1254 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1255 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1256   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1257   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1258 fi
1259
1260 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1261 AC_MSG_CHECKING(for PT_GETDBREGS)
1262 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1263 [AC_TRY_COMPILE([#include <sys/types.h>
1264 #include <sys/ptrace.h>],
1265                 [PT_GETDBREGS;],
1266                 [gdb_cv_have_pt_getdbregs=yes],
1267                 [gdb_cv_have_pt_getdbregs=no])])
1268 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1269 if test $gdb_cv_have_pt_getdbregs = yes; then
1270   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1271   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1272 fi
1273
1274 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1275 AC_MSG_CHECKING(for PT_GETXMMREGS)
1276 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1277 [AC_TRY_COMPILE([#include <sys/types.h>
1278 #include <sys/ptrace.h>],
1279                 [PT_GETXMMREGS;],
1280                 [gdb_cv_have_pt_getxmmregs=yes],
1281                 [gdb_cv_have_pt_getxmmregs=no])])
1282 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1283 if test $gdb_cv_have_pt_getxmmregs = yes; then
1284   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1285   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1286 fi
1287
1288 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1289
1290 if test "${target}" = "${host}"; then
1291   case "${host}" in
1292   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1293       AC_DEFINE(NEW_PROC_API, 1,
1294       [Define if you want to use new multi-fd /proc interface
1295        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1296       ;;
1297   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1298       AC_DEFINE(NEW_PROC_API, 1,
1299       [Define if you want to use new multi-fd /proc interface
1300        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1301       ;;
1302   mips-sgi-irix5*)
1303       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1304       AC_DEFINE([_KMEMUSER], 1,
1305       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1306        around a <sys/proc.h> problem on IRIX 5.])
1307       ;;
1308   esac
1309 fi
1310
1311 if test "$ac_cv_header_sys_procfs_h" = yes; then
1312   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1313   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1314   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1315   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1316   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1317   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1318   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1319   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1320   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1321   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1322   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1323   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1324   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1325   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1326
1327
1328   dnl Check for broken prfpregset_t type
1329
1330   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1331   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1332   dnl instead of the struct itself).  We detect this here, and work
1333   dnl around it in gdb_proc_service.h.
1334
1335   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1336     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1337     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1338       [AC_TRY_RUN([#include <sys/procfs.h>
1339        int main ()
1340        {
1341          if (sizeof (prfpregset_t) == sizeof (void *))
1342            return 1;
1343          return 0;
1344        }],
1345        gdb_cv_prfpregset_t_broken=no,
1346        gdb_cv_prfpregset_t_broken=yes,
1347        gdb_cv_prfpregset_t_broken=yes)])
1348     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1349     if test $gdb_cv_prfpregset_t_broken = yes; then
1350       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1351       [Define if the prfpregset_t type is broken.])
1352     fi
1353   fi
1354
1355   dnl Check for PIOCSET ioctl entry
1356
1357   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1358   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1359   [AC_TRY_COMPILE([#include <unistd.h>
1360 #include <sys/types.h>
1361 #include <sys/procfs.h>
1362 ], [
1363     int dummy;;
1364     dummy = ioctl(0, PIOCSET, &dummy);
1365   ],
1366   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1367   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1368   if test $gdb_cv_have_procfs_piocset = yes; then
1369     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1370     [Define if ioctl argument PIOCSET is available.])
1371   fi
1372 fi
1373
1374 dnl For native ports (host == target), check to see what kind of
1375 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1376 if test ${host} = ${target} ; then
1377   dnl Check for struct link_map with l_ members which are indicative
1378   dnl of SVR4-like shared libraries
1379
1380   AC_MSG_CHECKING(for member l_addr in struct link_map)
1381   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1382     [AC_TRY_COMPILE([#include <link.h>],
1383                     [struct link_map lm; (void) lm.l_addr;],
1384                     gdb_cv_have_struct_link_map_with_l_members=yes,
1385                     gdb_cv_have_struct_link_map_with_l_members=no)])
1386   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1387   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1388     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1389     [Define if <link.h> exists and defines struct link_map which has
1390      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1391      SVR4-like systems.)])
1392   fi
1393
1394   dnl Check for struct link_map with lm_ members which are indicative
1395   dnl of SunOS-like shared libraries
1396
1397   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1398   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1399     [AC_TRY_COMPILE([#include <sys/types.h>
1400 #include <link.h>],
1401                     [struct link_map lm; (void) lm.lm_addr;],
1402                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1403                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1404   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1405   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1406     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1407     [Define if <link.h> exists and defines struct link_map which has
1408      members with an ``lm_'' prefix.  (For SunOS.)])
1409   fi
1410
1411   dnl Check for struct so_map with som_ members which are found on
1412   dnl some *BSD systems.
1413
1414   AC_MSG_CHECKING(for member som_addr in struct so_map)
1415   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1416     [AC_TRY_COMPILE([#include <sys/types.h>
1417 #ifdef HAVE_NLIST_H
1418 #include <nlist.h>
1419 #endif
1420 #include <link.h>],
1421                     [struct so_map lm; (void) lm.som_addr;],
1422                     gdb_cv_have_struct_so_map_with_som_members=yes,
1423                     gdb_cv_have_struct_so_map_with_som_members=no)])
1424   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1425   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1426     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1427     [Define if <link.h> exists and defines a struct so_map which has
1428      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1429   fi
1430
1431   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1432   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1433
1434   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1435   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1436     [AC_TRY_COMPILE([#define _SYSCALL32
1437 #include <sys/link.h>], [struct link_map32 l;],
1438      gdb_cv_have_struct_link_map32=yes,
1439      gdb_cv_have_struct_link_map32=no)])
1440   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1441   if test $gdb_cv_have_struct_link_map32 = yes; then
1442     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1443     [Define if <sys/link.h> has struct link_map32])
1444     AC_DEFINE(_SYSCALL32, 1,
1445     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1446   fi
1447 fi
1448
1449 # Check if the compiler supports the `long long' type.
1450
1451 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1452                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1453 [[extern long long foo;]],
1454 [[switch (foo & 2) { case 0: return 1; }]])],
1455                                   gdb_cv_c_long_long=yes,
1456                                   gdb_cv_c_long_long=no)])
1457 if test $gdb_cv_c_long_long = yes; then
1458   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1459             [Define to 1 if the compiler supports long long.])
1460 fi
1461
1462 # Check if the compiler and runtime support printing long longs.
1463
1464 AC_CACHE_CHECK([for long long support in printf],
1465                gdb_cv_printf_has_long_long,
1466                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1467 [[char buf[32];
1468   long long l = 0;
1469   l = (l << 16) + 0x0123;
1470   l = (l << 16) + 0x4567;
1471   l = (l << 16) + 0x89ab;
1472   l = (l << 16) + 0xcdef;
1473   sprintf (buf, "0x%016llx", l);
1474   return (strcmp ("0x0123456789abcdef", buf));]])],
1475                               gdb_cv_printf_has_long_long=yes,
1476                               gdb_cv_printf_has_long_long=no,
1477                               gdb_cv_printf_has_long_long=no)])
1478 if test $gdb_cv_printf_has_long_long = yes; then
1479   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1480             [Define to 1 if the "%ll" format works to print long longs.])
1481 fi
1482
1483 # Check if the compiler and runtime support printing decfloats.
1484
1485 AC_CACHE_CHECK([for decfloat support in printf],
1486                gdb_cv_printf_has_decfloat,
1487                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1488 [[char buf[64];
1489   _Decimal32 d32 = 1.2345df;
1490   _Decimal64 d64 = 1.2345dd;
1491   _Decimal128 d128 = 1.2345dl;
1492   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1493   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1494                               gdb_cv_printf_has_decfloat=yes,
1495                               gdb_cv_printf_has_decfloat=no,
1496                               gdb_cv_printf_has_decfloat=no)])
1497 if test $gdb_cv_printf_has_decfloat = yes; then
1498   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1499             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1500 fi
1501
1502 # Check if the compiler supports the `long double' type.  We can't use
1503 # AC_C_LONG_DOUBLE because that one does additional checks on the
1504 # constants defined in <float.h> that fail on some systems,
1505 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1506
1507 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1508                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1509                                   gdb_cv_c_long_double=yes,
1510                                   gdb_cv_c_long_double=no)])
1511 if test $gdb_cv_c_long_double = yes; then
1512   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1513            [Define to 1 if the compiler supports long double.])
1514 fi
1515
1516 # Check if the compiler and runtime support printing long doubles.
1517
1518 AC_CACHE_CHECK([for long double support in printf],
1519                gdb_cv_printf_has_long_double,
1520                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1521 [[char buf[16];
1522   long double f = 3.141592653;
1523   sprintf (buf, "%Lg", f);
1524   return (strncmp ("3.14159", buf, 7));]])],
1525                               gdb_cv_printf_has_long_double=yes,
1526                               gdb_cv_printf_has_long_double=no,
1527                               gdb_cv_printf_has_long_double=no)])
1528 if test $gdb_cv_printf_has_long_double = yes; then
1529   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1530             [Define to 1 if the "%Lg" format works to print long doubles.])
1531 fi
1532
1533 # Check if the compiler and runtime support scanning long doubles.
1534
1535 AC_CACHE_CHECK([for long double support in scanf],
1536                gdb_cv_scanf_has_long_double,
1537                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1538 [[#include <stdio.h>]],
1539 [[char *buf = "3.141592653";
1540   long double f = 0;
1541   sscanf (buf, "%Lg", &f);
1542   return !(f > 3.14159 && f < 3.14160);]])],
1543                               gdb_cv_scanf_has_long_double=yes,
1544                               gdb_cv_scanf_has_long_double=no,
1545                               gdb_cv_scanf_has_long_double=no)])
1546 if test $gdb_cv_scanf_has_long_double = yes; then
1547   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1548             [Define to 1 if the "%Lg" format works to scan long doubles.])
1549 fi
1550
1551 case ${host_os} in
1552 aix*)
1553   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1554     SAVE_LDFLAGS=$LDFLAGS
1555
1556     case $GCC in
1557     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1558     *) gdb_cv_bigtoc=-bbigtoc ;;
1559     esac
1560
1561     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1562     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1563     LDFLAGS="${SAVE_LDFLAGS}"
1564   ])
1565   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1566   ;;
1567 esac
1568
1569 AC_MSG_CHECKING(for the dynamic export flag)
1570 dynamic_list=false
1571 if test "${gdb_native}" = yes; then
1572    # The dynamically loaded libthread_db needs access to symbols in the gdb
1573    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1574    # may not be supported there.
1575    old_LDFLAGS="$LDFLAGS"
1576    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1577    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1578    LDFLAGS="$LDFLAGS $RDYNAMIC"
1579    if test "${have_libpython}" = no; then
1580      AC_TRY_LINK([], [], [dynamic_list=true])
1581    else
1582      # Workaround http://bugs.python.org/issue4434 where static
1583      # libpythonX.Y.a would get its symbols required for
1584      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1585      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1586      old_CFLAGS="$CFLAGS"
1587      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1588      AC_RUN_IFELSE(
1589        AC_LANG_PROGRAM(
1590          [#include "]${have_libpython}[/Python.h"],
1591          [int err;
1592           Py_Initialize ();
1593           err = PyRun_SimpleString ("import itertools\n");
1594           Py_Finalize ();
1595           return err == 0 ? 0 : 1;]),
1596        [dynamic_list=true], [], [true])
1597      CFLAGS="$old_CFLAGS"
1598    fi
1599    LDFLAGS="$old_LDFLAGS"
1600 fi
1601 if $dynamic_list; then
1602   found="-Wl,--dynamic-list"
1603   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1604 else
1605   found="-rdynamic"
1606   RDYNAMIC="-rdynamic"
1607 fi
1608 AC_SUBST(RDYNAMIC)
1609 AC_MSG_RESULT($found)
1610
1611 dnl For certain native configurations, we need to check whether thread
1612 dnl support can be built in or not.
1613 dnl
1614 dnl Note that we only want this if we are both native (host == target),
1615 dnl and not doing a canadian cross build (build == host).
1616
1617 if test ${build} = ${host} -a ${host} = ${target} ; then
1618    case ${host_os} in
1619    solaris*)
1620       # See if thread_db library is around for Solaris thread debugging.
1621       # Note that we must explicitly test for version 1 of the library
1622       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1623       # the same API.
1624       AC_MSG_CHECKING(for Solaris thread debugging library)
1625       if test -f /usr/lib/libthread_db.so.1 ; then
1626          AC_MSG_RESULT(yes)
1627          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1628          [Define if using Solaris thread debugging.])
1629          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1630          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1631          AC_CHECK_LIB(dl, dlopen)
1632          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1633          # Sun randomly tweaked the prototypes in <proc_service.h>
1634          # at one point.
1635          AC_MSG_CHECKING(if <proc_service.h> is old)
1636          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1637             AC_TRY_COMPILE([
1638                 #include <proc_service.h>
1639                 ps_err_e ps_pdwrite
1640                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1641             ],, gdb_cv_proc_service_is_old=no,
1642                 gdb_cv_proc_service_is_old=yes)
1643          ])
1644          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1645          if test $gdb_cv_proc_service_is_old = yes; then
1646             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1647             [Define if <proc_service.h> on solaris uses int instead of
1648              size_t, and assorted other type changes.])
1649          fi
1650       else
1651          AC_MSG_RESULT(no)
1652       fi
1653       ;;
1654    aix*)
1655       AC_MSG_CHECKING(for AiX thread debugging library)
1656       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1657                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1658                                    [#ifndef PTHDB_VERSION_3
1659                                     #error
1660                                     #endif],
1661                                    gdb_cv_have_aix_thread_debug=yes,
1662                                    gdb_cv_have_aix_thread_debug=no)])
1663       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1664       if test $gdb_cv_have_aix_thread_debug = yes; then
1665          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1666          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1667          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1668
1669          # Older versions of AIX do not provide the declaration for
1670          # the getthrds function (it appears that it was introduced
1671          # with AIX 6.x).
1672          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1673       fi
1674       ;;
1675    esac
1676    AC_SUBST(CONFIG_LDFLAGS)
1677 fi
1678
1679 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1680 dnl other error codes.
1681 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1682    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1683                   gdb_cv_thread_db_h_has_td_notalloc,
1684      AC_TRY_COMPILE(
1685        [#include <thread_db.h>],
1686        [int i = TD_NOTALLOC;],
1687        gdb_cv_thread_db_h_has_td_notalloc=yes,
1688        gdb_cv_thread_db_h_has_td_notalloc=no
1689      )
1690    )
1691    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1692                   gdb_cv_thread_db_h_has_td_version,
1693      AC_TRY_COMPILE(
1694        [#include <thread_db.h>],
1695        [int i = TD_VERSION;],
1696        gdb_cv_thread_db_h_has_td_version=yes,
1697        gdb_cv_thread_db_h_has_td_version=no
1698      )
1699    )
1700    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1701                   gdb_cv_thread_db_h_has_td_notls,
1702      AC_TRY_COMPILE(
1703        [#include <thread_db.h>],
1704        [int i = TD_NOTLS;],
1705        gdb_cv_thread_db_h_has_td_notls=yes,
1706        gdb_cv_thread_db_h_has_td_notls=no
1707      )
1708    )
1709 fi
1710 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1711   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1712             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1713 fi
1714 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1715   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1716             [Define if <thread_db.h> has the TD_VERSION error code.])
1717 fi
1718 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1719   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1720             [Define if <thread_db.h> has the TD_NOTLS error code.])
1721 fi
1722
1723 dnl See if we have a sys/syscall header file that has __NR_tkill.
1724 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1725    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1726                   gdb_cv_sys_syscall_h_has_tkill,
1727      AC_TRY_COMPILE(
1728        [#include <sys/syscall.h>],
1729        [int i = __NR_tkill;],
1730        gdb_cv_sys_syscall_h_has_tkill=yes,
1731        gdb_cv_sys_syscall_h_has_tkill=no
1732      )
1733    )
1734 fi
1735 dnl See if we can issue tkill syscall.
1736 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1737   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1738 fi
1739
1740 dnl Check if we can disable the virtual address space randomization.
1741 dnl The functionality of setarch -R.
1742 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1743 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1744 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1745 #       define ADDR_NO_RANDOMIZE 0x0040000
1746 #      endif
1747        /* Test the flag could be set and stays set.  */
1748        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1749        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1750            return 1])])
1751 AC_RUN_IFELSE([PERSONALITY_TEST],
1752               [have_personality=true],
1753               [have_personality=false],
1754               [AC_LINK_IFELSE([PERSONALITY_TEST],
1755                               [have_personality=true],
1756                               [have_personality=false])])
1757 if $have_personality
1758 then
1759     AC_DEFINE([HAVE_PERSONALITY], 1,
1760               [Define if you support the personality syscall.])
1761 fi
1762
1763 dnl Handle optional features that can be enabled.
1764
1765 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1766 # except that the argument to --with-sysroot is optional.
1767 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1768 if test "x$with_sysroot" = xyes; then
1769   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1770 fi
1771 AC_ARG_WITH(sysroot,
1772   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1773                  [search for usr/lib et al within DIR]),
1774   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1775 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1776               [search for usr/lib et al within DIR])
1777 AC_SUBST(TARGET_SYSTEM_ROOT)
1778 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1779
1780 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1781     [automatically load a system-wide gdbinit file],
1782     [])
1783
1784 AC_ARG_ENABLE(werror,
1785   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1786   [case "${enableval}" in
1787      yes | y) ERROR_ON_WARNING="yes" ;;
1788      no | n)  ERROR_ON_WARNING="no" ;;
1789      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1790    esac])
1791
1792 # Enable -Werror by default when using gcc
1793 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1794     ERROR_ON_WARNING=yes
1795 fi
1796
1797 WERROR_CFLAGS=""
1798 if test "${ERROR_ON_WARNING}" = yes ; then
1799     WERROR_CFLAGS="-Werror"
1800 fi
1801
1802 # The entries after -Wno-pointer-sign are disabled warnings which may
1803 # be enabled in the future, which can not currently be used to build
1804 # GDB.
1805 # NOTE: If you change this list, remember to update
1806 # gdb/doc/gdbint.texinfo.
1807 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1808 -Wformat-nonliteral -Wno-pointer-sign \
1809 -Wno-unused -Wunused-value -Wunused-function \
1810 -Wno-switch -Wno-char-subscripts"
1811
1812 # Enable -Wno-format by default when using gcc on mingw since many
1813 # GCC versions complain about %I64.
1814 case "${host}" in
1815   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1816 esac
1817
1818 AC_ARG_ENABLE(build-warnings,
1819 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1820 [case "${enableval}" in
1821   yes)  ;;
1822   no)   build_warnings="-w";;
1823   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1824         build_warnings="${build_warnings} ${t}";;
1825   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1826         build_warnings="${t} ${build_warnings}";;
1827   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1828 esac
1829 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1830   echo "Setting compiler warning flags = $build_warnings" 6>&1
1831 fi])dnl
1832 AC_ARG_ENABLE(gdb-build-warnings,
1833 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1834 [case "${enableval}" in
1835   yes)  ;;
1836   no)   build_warnings="-w";;
1837   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1838         build_warnings="${build_warnings} ${t}";;
1839   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1840         build_warnings="${t} ${build_warnings}";;
1841   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1842 esac
1843 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1844   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1845 fi])dnl
1846 WARN_CFLAGS=""
1847 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1848 then
1849     AC_MSG_CHECKING(compiler warning flags)
1850     # Separate out the -Werror flag as some files just cannot be
1851     # compiled with it enabled.
1852     for w in ${build_warnings}; do
1853         case $w in
1854         -Werr*) WERROR_CFLAGS=-Werror ;;
1855         *) # Check that GCC accepts it
1856             saved_CFLAGS="$CFLAGS"
1857             CFLAGS="$CFLAGS $w"
1858             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1859             CFLAGS="$saved_CFLAGS"
1860         esac
1861     done
1862     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1863 fi
1864 AC_SUBST(WARN_CFLAGS)
1865 AC_SUBST(WERROR_CFLAGS)
1866
1867 # In the Cygwin environment, we need some additional flags.
1868 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1869 [AC_EGREP_CPP(lose, [
1870 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1871 lose
1872 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1873
1874
1875 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1876 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1877 case ${host} in
1878   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1879   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1880   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1881 esac
1882 AC_SUBST(SER_HARDWIRE)
1883
1884 # libreadline needs libuser32.a in a cygwin environment
1885 WIN32LIBS=
1886 if test x$gdb_cv_os_cygwin = xyes; then
1887     WIN32LIBS="-luser32"
1888     case "${target}" in
1889         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1890         ;;
1891     esac
1892 fi
1893
1894 # The ser-tcp.c module requires sockets.
1895 case ${host} in
1896   *mingw32*)
1897     AC_DEFINE(USE_WIN32API, 1,
1898               [Define if we should use the Windows API, instead of the
1899                POSIX API.  On Windows, we use the Windows API when
1900                building for MinGW, but the POSIX API when building
1901                for Cygwin.])
1902     WIN32LIBS="$WIN32LIBS -lws2_32"
1903     ;;
1904 esac
1905 AC_SUBST(WIN32LIBS)
1906
1907 # Add ELF support to GDB, but only if BFD includes ELF support.
1908 OLD_CFLAGS=$CFLAGS
1909 OLD_LDFLAGS=$LDFLAGS
1910 OLD_LIBS=$LIBS
1911 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1912 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1913 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1914 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1915 if test "$plugins" = "yes"; then
1916   LIBS="-ldl $LIBS"
1917 fi
1918 LIBS="-lbfd -liberty $intl $LIBS"
1919 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1920 [AC_TRY_LINK(
1921 [#include <stdlib.h>
1922 #include "bfd.h"
1923 #include "elf-bfd.h"
1924 ],
1925 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1926 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1927 if test $gdb_cv_var_elf = yes; then
1928   CONFIG_OBS="$CONFIG_OBS elfread.o"
1929   AC_DEFINE(HAVE_ELF, 1,
1930             [Define if ELF support should be included.])
1931   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1932   if test "$plugins" = "yes"; then
1933     OLD_LIBS="-ldl $OLD_LIBS"
1934   fi
1935 fi
1936 CFLAGS=$OLD_CFLAGS
1937 LDFLAGS=$OLD_LDFLAGS
1938 LIBS=$OLD_LIBS
1939
1940 # Add any host-specific objects to GDB.
1941 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1942
1943 LIBGUI="../libgui/src/libgui.a"
1944 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1945 AC_SUBST(LIBGUI)
1946 AC_SUBST(GUI_CFLAGS_X)
1947
1948 WIN32LDAPP=
1949 AC_SUBST(WIN32LIBS)
1950 AC_SUBST(WIN32LDAPP)
1951
1952 case "${host}" in
1953 *-*-cygwin* | *-*-mingw* )
1954     configdir="win"
1955     ;;
1956 *)
1957     configdir="unix"
1958     ;;
1959 esac
1960
1961 GDBTKLIBS=
1962 if test "${enable_gdbtk}" = "yes"; then
1963
1964     # Gdbtk must have an absolute path to srcdir in order to run
1965     # properly when not installed.
1966     here=`pwd`
1967     cd ${srcdir}
1968     GDBTK_SRC_DIR=`pwd`
1969     cd $here
1970
1971     SC_PATH_TCLCONFIG
1972
1973     # If $no_tk is nonempty, then we can't do Tk, and there is no
1974     # point to doing Tcl.
1975     SC_PATH_TKCONFIG
1976
1977     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1978         SC_LOAD_TCLCONFIG
1979
1980         # Check for in-tree tcl
1981         here=`pwd`
1982         cd ${srcdir}/..
1983         topdir=`pwd`
1984         cd ${here}
1985
1986         intree="no"
1987         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1988           intree="yes"
1989         fi
1990
1991         # Find Tcl private headers
1992         if test x"${intree}" = xno; then
1993           CY_AC_TCL_PRIVATE_HEADERS
1994           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1995           TCL_LIBRARY="${TCL_LIB_SPEC}"
1996           TCL_DEPS=""
1997         else
1998           # If building tcl in the same src tree, private headers
1999           # are not needed, but we need to be sure to use the right
2000           # headers library
2001           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2002           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2003           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2004         fi
2005         AC_SUBST(TCL_INCLUDE)
2006         AC_SUBST(TCL_LIBRARY)
2007         AC_SUBST(TCL_DEPS)
2008
2009         SC_LOAD_TKCONFIG
2010
2011         # Check for in-tree Tk
2012         intree="no"
2013         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2014           intree="yes"
2015         fi
2016
2017         # Find Tk private headers
2018         if test x"${intree}" = xno; then
2019           CY_AC_TK_PRIVATE_HEADERS
2020           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2021           TK_LIBRARY=${TK_LIB_SPEC}
2022           TK_DEPS=""
2023         else
2024           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2025           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2026           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2027         fi
2028         AC_SUBST(TK_INCLUDE)
2029         AC_SUBST(TK_LIBRARY)
2030         AC_SUBST(TK_DEPS)
2031         AC_SUBST(TK_XINCLUDES)
2032
2033         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2034
2035         # Include some libraries that Tcl and Tk want.
2036         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2037         # Yes, the ordering seems wrong here.  But it isn't.
2038         # TK_LIBS is the list of libraries that need to be linked
2039         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2040         # were in LIBS then any link tests after this point would
2041         # try to include things like `$(LIBGUI)', which wouldn't work.
2042         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2043
2044         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2045         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2046         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2047         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2048         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2049         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2050         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2051
2052         if test x$gdb_cv_os_cygwin = xyes; then
2053           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2054           WIN32LDAPP="-Wl,--subsystem,console"
2055           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2056         fi
2057
2058         AC_CONFIG_SUBDIRS(gdbtk)
2059     fi
2060 fi
2061
2062 AC_SUBST(X_CFLAGS)
2063 AC_SUBST(X_LDFLAGS)
2064 AC_SUBST(X_LIBS)
2065 AC_SUBST(GDBTKLIBS)
2066 AC_SUBST(GDBTK_CFLAGS)
2067 AC_SUBST(GDBTK_SRC_DIR)
2068
2069 AC_PATH_X
2070
2071 # Unlike the sim directory, whether a simulator is linked is controlled by
2072 # presence of a gdb_sim definition in the target configure.tgt entry.
2073 # This code just checks for a few cases where we'd like to ignore those
2074 # definitions, even when they're present in the '.mt' file.  These cases
2075 # are when --disable-sim is specified, or if the simulator directory is
2076 # not part of the source tree.
2077 #
2078 AC_ARG_ENABLE(sim,
2079 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2080 [echo "enable_sim = $enable_sim";
2081  echo "enableval = ${enableval}";
2082  case "${enableval}" in
2083   yes) ignore_sim=false ;;
2084   no)  ignore_sim=true ;;
2085   *)   ignore_sim=false ;;
2086  esac],
2087 [ignore_sim=false])
2088
2089 if test ! -d "${srcdir}/../sim"; then
2090   ignore_sim=true
2091 fi
2092
2093 SIM=
2094 SIM_OBS=
2095 if test "${ignore_sim}" = "false"; then
2096   if test x"${gdb_sim}" != x ; then
2097     SIM="${gdb_sim}"
2098     SIM_OBS="remote-sim.o"
2099     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2100   fi
2101 fi
2102 AC_SUBST(SIM)
2103 AC_SUBST(SIM_OBS)
2104
2105 AC_SUBST(ENABLE_CFLAGS)
2106 AC_SUBST(PROFILE_CFLAGS)
2107
2108 AC_SUBST(CONFIG_OBS)
2109 AC_SUBST(CONFIG_DEPS)
2110 AC_SUBST(CONFIG_SRCS)
2111 AC_SUBST(CONFIG_ALL)
2112 AC_SUBST(CONFIG_CLEAN)
2113 AC_SUBST(CONFIG_INSTALL)
2114 AC_SUBST(CONFIG_UNINSTALL)
2115
2116 # List of host floatformats.
2117 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2118 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2119 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2120
2121 # target_subdir is used by the testsuite to find the target libraries.
2122 target_subdir=
2123 if test "${host}" != "${target}"; then
2124     target_subdir="${target_alias}/"
2125 fi
2126 AC_SUBST(target_subdir)
2127
2128 frags=
2129 if test "${gdb_native}" = "yes"; then
2130   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2131   if test ! -f ${host_makefile_frag}; then
2132     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2133   fi
2134   frags="$frags $host_makefile_frag"
2135 else
2136   host_makefile_frag=/dev/null
2137 fi
2138
2139 AC_SUBST_FILE(host_makefile_frag)
2140 AC_SUBST(frags)
2141
2142 changequote(,)dnl
2143 if test "${gdb_native}" = "yes"; then
2144 # We pick this up from the host configuration file (.mh) because we
2145 # do not have a native configuration Makefile fragment.
2146 nativefile=`sed -n '
2147 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2148 ' ${host_makefile_frag}`
2149 fi
2150 changequote([,])
2151
2152 if test x"${gdb_osabi}" != x ; then
2153     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2154                        [Define to the default OS ABI for this configuration.])
2155 fi
2156
2157 # Enable multi-ice-gdb-server.
2158 AC_ARG_ENABLE(multi-ice,
2159 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2160   [case $enableval in
2161     yes | no)
2162       ;;
2163     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2164   esac])
2165 if test "x$enable_multi_ice" = xyes; then
2166    AC_CONFIG_SUBDIRS(multi-ice)
2167 fi
2168
2169 AC_ARG_ENABLE(gdbserver,
2170 AS_HELP_STRING([--enable-gdbserver],
2171                [automatically build gdbserver (yes/no/auto, default is auto)]),
2172 [case "${enableval}" in
2173   yes| no|auto) ;;
2174   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2175 esac],[enable_gdbserver=auto])
2176
2177 # We only build gdbserver automatically in a native configuration, and
2178 # only if the user did not explicitly disable its build.
2179 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2180   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2181   if test "x$build_gdbserver" = xyes; then
2182     AC_MSG_RESULT(yes)
2183     AC_CONFIG_SUBDIRS(gdbserver)
2184     gdbserver_build_enabled=yes
2185   else
2186     AC_MSG_RESULT(no)
2187   fi
2188 fi
2189
2190 # If the user explicitly request the gdbserver to be built, verify that
2191 # we were in fact able to enable it.
2192 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2193   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2194 fi
2195
2196 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2197 # to an empty version.
2198
2199 files=
2200 links=
2201
2202 rm -f nm.h
2203 if test "${nativefile}" != ""; then
2204     case "${nativefile}" in
2205       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2206       * ) GDB_NM_FILE="${nativefile}"
2207     esac
2208     files="${files} ${GDB_NM_FILE}"
2209     links="${links} nm.h"
2210     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2211 fi
2212 AC_SUBST(GDB_NM_FILE)
2213
2214 AC_LINK_FILES($files, $links)
2215
2216 dnl Check for exe extension set on certain hosts (e.g. Win32)
2217 AC_EXEEXT
2218
2219 dnl  Detect the character set used by this host.
2220 dnl  At the moment, we just assume it's UTF-8.
2221 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2222           [Define to be a string naming the default host character set.])
2223
2224 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2225 [
2226 case x$CONFIG_HEADERS in
2227 xconfig.h:config.in)
2228 echo > stamp-h ;;
2229 esac
2230 ])
2231
2232 exit 0