gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009, 2010
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # GDB does not use automake, but gnulib does.  This line lets us
  91 # generate its Makefile.in.
  92 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  93
  94 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  95     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  96     [${libdir}/debug])
  97
  98 # GDB's datadir relocation
  99
 100 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 101     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 102     [${datadir}/gdb])
 103
 104 AC_ARG_WITH(relocated-sources,
 105 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 106 [reloc_srcdir="${withval}"
 107  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 108               [Relocated directory for source files. ])
 109 ])
 110
 111 AC_CONFIG_SUBDIRS(doc testsuite)
 112
 113 # Check whether to support alternative target configurations
 114 AC_ARG_ENABLE(targets,
 115 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 116 [case "${enableval}" in
 117   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 118             ;;
 119   no)       enable_targets= ;;
 120   *)        enable_targets=$enableval ;;
 121 esac])
 122
 123 # Check whether to enable 64-bit support on 32-bit hosts
 124 AC_ARG_ENABLE(64-bit-bfd,
 125 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 126 [case "${enableval}" in
 127   yes)  want64=true  ;;
 128   no)   want64=false ;;
 129   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 130 esac],[want64=false])dnl
 131
 132 # Provide defaults for some variables set by the per-host and per-target
 133 # configuration.
 134 gdb_host_obs=posix-hdep.o
 135
 136 if test "${target}" = "${host}"; then
 137   gdb_native=yes
 138 else
 139   gdb_native=no
 140 fi
 141
 142 . $srcdir/configure.host
 143
 144 # Accumulate some settings from configure.tgt over all enabled targets
 145
 146 TARGET_OBS=
 147 all_targets=
 148
 149 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 150 do
 151   if test "$targ_alias" = "all"; then
 152     all_targets=true
 153   else
 154     # Canonicalize the secondary target names.
 155     result=`$ac_config_sub $targ_alias 2>/dev/null`
 156     if test -n "$result"; then
 157         targ=$result
 158     else
 159         targ=$targ_alias
 160     fi
 161
 162     . ${srcdir}/configure.tgt
 163
 164     AS_IF([test -z "${gdb_target_obs}"],
 165       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 166
 167     # Target-specific object files
 168     for i in ${gdb_target_obs}; do
 169         case " $TARGET_OBS " in
 170         *" ${i} "*) ;;
 171         *)
 172           TARGET_OBS="$TARGET_OBS ${i}"
 173           ;;
 174         esac
 175     done
 176
 177     # Check whether this target needs 64-bit CORE_ADDR
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181   fi
 182 done
 183
 184 if test x${all_targets} = xtrue; then
 185
 186   # We want all 64-bit targets if we either:
 187   #  - run on a 64-bit host  or
 188   #  - already require 64-bit support for some other target  or
 189   #  - the --enable-64-bit-bfd option was supplied
 190   # Otherwise we only support all 32-bit targets.
 191   #
 192   # NOTE: This test must be in sync with the corresponding
 193   #       tests in BFD!
 194
 195   if test x${want64} = xfalse; then
 196     AC_CHECK_SIZEOF(long)
 197     if test "x${ac_cv_sizeof_long}" = "x8"; then
 198       want64=true
 199     fi
 200   fi
 201   if test x${want64} = xtrue; then
 202     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 203   else
 204     TARGET_OBS='$(ALL_TARGET_OBS)'
 205   fi
 206 fi
 207
 208 AC_SUBST(TARGET_OBS)
 209
 210 # For other settings, only the main target counts.
 211 gdb_sim=
 212 gdb_osabi=
 213 build_gdbserver=
 214 targ=$target; . ${srcdir}/configure.tgt
 215
 216 # Fetch the default architecture and default target vector from BFD.
 217 targ=$target; . $srcdir/../bfd/config.bfd
 218
 219 # We only want the first architecture, so strip off the others if
 220 # there is more than one.
 221 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 222
 223 if test "x$targ_archs" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 225     [Define to BFD's default architecture. ])
 226 fi
 227 if test "x$targ_defvec" != x; then
 228   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 229     [Define to BFD's default target vector. ])
 230 fi
 231
 232 # The CLI cannot be disabled yet, but may be in the future.
 233
 234 # Enable CLI.
 235 AC_ARG_ENABLE(gdbcli,
 236 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 237   [case $enableval in
 238     yes)
 239       ;;
 240     no)
 241       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 242     *)
 243       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 244   esac],
 245   [enable_gdbcli=yes])
 246 if test x"$enable_gdbcli" = xyes; then
 247   if test -d $srcdir/cli; then
 248     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 249     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 250     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 251     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 252   fi
 253 fi
 254
 255 # Enable MI.
 256 AC_ARG_ENABLE(gdbmi,
 257 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 258   [case $enableval in
 259     yes | no)
 260       ;;
 261     *)
 262       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 263   esac],
 264   [enable_gdbmi=yes])
 265 if test x"$enable_gdbmi" = xyes; then
 266   if test -d $srcdir/mi; then
 267     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 268     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 269     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 270     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 271   fi
 272 fi
 273
 274 # Enable TUI.
 275 AC_ARG_ENABLE(tui,
 276 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 277   [case $enableval in
 278     yes | no | auto)
 279       ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 282   esac],enable_tui=auto)
 283
 284 # Enable gdbtk.
 285 AC_ARG_ENABLE(gdbtk,
 286 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 292   esac],
 293   [if test -d $srcdir/gdbtk; then
 294     enable_gdbtk=yes
 295   else
 296     enable_gdbtk=no
 297   fi])
 298 # We unconditionally disable gdbtk tests on selected platforms.
 299 case $host_os in
 300   go32* | windows*)
 301     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 302     enable_gdbtk=no ;;
 303 esac
 304
 305 # Libunwind support.
 306 AC_ARG_WITH(libunwind,
 307 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 308 [case "${withval}" in
 309   yes)  enable_libunwind=yes ;;
 310   no)   enable_libunwind=no ;;
 311   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 312 esac],[
 313   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 314   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 315     enable_libunwind=yes;
 316   fi
 317 ])
 318
 319 if test x"$enable_libunwind" = xyes; then
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 322   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 323   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 324   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 325 fi
 326
 327 opt_curses=no
 328 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 329
 330 prefer_curses=no
 331 if test "$opt_curses" = "yes"; then
 332   prefer_curses=yes
 333 fi
 334
 335 # Profiling support.
 336 AC_ARG_ENABLE(profiling,
 337 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 338   [case $enableval in
 339     yes | no)
 340       ;;
 341     *)
 342       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 343   esac],
 344  [enable_profiling=no])
 345
 346 AC_CHECK_FUNCS(monstartup _mcleanup)
 347 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 348 [AC_TRY_LINK(
 349 [#include <stdlib.h>
 350 extern char _etext;
 351 ],
 352 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 353 if test $ac_cv_var__etext = yes; then
 354   AC_DEFINE(HAVE__ETEXT, 1,
 355             [Define to 1 if your system has the _etext variable. ])
 356 fi
 357 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 358 [AC_TRY_LINK(
 359 [#include <stdlib.h>
 360 extern char etext;
 361 ],
 362 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 363 if test $ac_cv_var_etext = yes; then
 364   AC_DEFINE(HAVE_ETEXT, 1,
 365             [Define to 1 if your system has the etext variable. ])
 366 fi
 367 if test "$enable_profiling" = yes ; then
 368   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 369     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 370   fi
 371   PROFILE_CFLAGS=-pg
 372   OLD_CFLAGS="$CFLAGS"
 373   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 374
 375   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 376     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 377      ac_cv_cc_supports_pg=no)])
 378
 379   if test $ac_cv_cc_supports_pg = no; then
 380     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 381   fi
 382
 383   CFLAGS="$OLD_CFLAGS"
 384 fi
 385
 386 ACX_PKGVERSION([GDB])
 387 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 388 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 389 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 390
 391 # --------------------- #
 392 # Checks for programs.  #
 393 # --------------------- #
 394
 395 AC_PROG_AWK
 396 AC_PROG_INSTALL
 397 AC_PROG_LN_S
 398 AC_PROG_RANLIB
 399 AC_PROG_YACC
 400
 401 AC_CHECK_TOOL(AR, ar)
 402 AC_CHECK_TOOL(DLLTOOL, dlltool)
 403 AC_CHECK_TOOL(WINDRES, windres)
 404
 405 # Needed for GNU/Hurd.
 406 AC_CHECK_TOOL(MIG, mig)
 407
 408 # ---------------------- #
 409 # Checks for libraries.  #
 410 # ---------------------- #
 411
 412 # We might need to link with -lm; most simulators need it.
 413 AC_CHECK_LIB(m, main)
 414
 415 # We need to link with -lw to get `wctype' on Solaris before Solaris
 416 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 417 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 418 # is known to have this problem).  Therefore we avoid libw if we can.
 419 AC_CHECK_FUNC(wctype, [],
 420   [AC_CHECK_LIB(w, wctype)])
 421
 422 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 423 AC_SEARCH_LIBS(gethostbyname, nsl)
 424
 425 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 426 AC_SEARCH_LIBS(socketpair, socket)
 427
 428 # Link in zlib if we can.  This allows us to read compressed debug sections.
 429 AM_ZLIB
 430
 431 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 432 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 433
 434 AM_ICONV
 435
 436 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 437 # There is a very specific comment in /usr/include/curses.h explaining that
 438 # termcap routines built into libcurses must not be used.
 439 #
 440 # The symptoms we observed so far is GDB unexpectedly changing
 441 # the terminal settings when tgetent is called - this is particularly
 442 # visible as the output is missing carriage returns, and so rapidly
 443 # becomes very hard to read.
 444 #
 445 # The readline configure script has already decided that libtermcap
 446 # was enough for its purposes, and so decided to build readline using
 447 # libtermcap.  Since the TUI mode requires curses, building GDB with
 448 # TUI enabled results in both libraries to be used at the same time,
 449 # which is not allowed.  This basically means that GDB with TUI is
 450 # broken on alpha-osf.
 451
 452 case $host_os in
 453   osf* )
 454     if test x"$enable_tui" = xyes; then
 455       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 456     fi
 457     if test x"$enable_tui" = xauto; then
 458       enable_tui=no
 459     fi
 460     ;;
 461 esac
 462
 463 # For the TUI, we need enhanced curses functionality.
 464 if test x"$enable_tui" != xno; then
 465   prefer_curses=yes
 466 fi
 467
 468 curses_found=no
 469 if test x"$prefer_curses" = xyes; then
 470   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 471   # curses library because the latter might not provide all the
 472   # functionality we need.  However, this leads to problems on systems
 473   # where the linker searches /usr/local/lib, but the compiler doesn't
 474   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 475   # default installation of ncurses on alpha*-dec-osf* will lead to such
 476   # a situation.
 477   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 478
 479   if test "$ac_cv_search_waddstr" != no; then
 480     curses_found=yes
 481   fi
 482 fi
 483
 484 # Check whether we should enable the TUI, but only do so if we really
 485 # can.
 486 if test x"$enable_tui" != xno; then
 487   if test -d $srcdir/tui; then
 488     if test "$curses_found" != no; then
 489       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 490       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 491       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 492       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 493       CONFIG_ALL="${CONFIG_ALL} all-tui"
 494       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 495       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 496       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 497     else
 498       if test x"$enable_tui" = xyes; then
 499         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 500       else
 501         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 502       fi
 503     fi
 504   fi
 505 fi
 506
 507 # Since GDB uses Readline, we need termcap functionality.  In many
 508 # cases this will be provided by the curses library, but some systems
 509 # have a seperate termcap library, or no curses library at all.
 510
 511 case $host_os in
 512   cygwin*)
 513     if test -d $srcdir/libtermcap; then
 514       LIBS="../libtermcap/libtermcap.a $LIBS"
 515       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 516     fi ;;
 517   go32* | *djgpp*)
 518     ac_cv_search_tgetent="none required"
 519     ;;
 520   *mingw32*)
 521     ac_cv_search_tgetent="none required"
 522     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 523     ;;
 524 esac
 525
 526 # These are the libraries checked by Readline.
 527 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 528
 529 if test "$ac_cv_search_tgetent" = no; then
 530   AC_MSG_ERROR([no termcap library found])
 531 fi
 532
 533 AC_ARG_WITH([system-readline],
 534   [AS_HELP_STRING([--with-system-readline],
 535                   [use installed readline library])])
 536
 537 if test "$with_system_readline" = yes; then
 538   READLINE=-lreadline
 539   READLINE_DEPS=
 540   READLINE_CFLAGS=
 541
 542   # readline-6.0 started to use the name `_rl_echoing_p'.
 543   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 544
 545   AC_MSG_CHECKING([for readline_echoing_p])
 546   save_LIBS=$LIBS
 547   LIBS="$LIBS $READLINE"
 548   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 549                                     return readline_echoing_p;]]),
 550                  [READLINE_ECHOING_P=yes],
 551                  [READLINE_ECHOING_P=no
 552                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 553                             [readline-6.0 started to use different name.])])
 554   LIBS="$save_LIBS"
 555   AC_MSG_RESULT([$READLINE_ECHOING_P])
 556 else
 557   READLINE='$(READLINE_DIR)/libreadline.a'
 558   READLINE_DEPS='$(READLINE)'
 559   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 560 fi
 561 AC_SUBST(READLINE)
 562 AC_SUBST(READLINE_DEPS)
 563 AC_SUBST(READLINE_CFLAGS)
 564
 565 AC_ARG_WITH(expat,
 566   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 567   [], [with_expat=auto])
 568 AC_MSG_CHECKING([whether to use expat])
 569 AC_MSG_RESULT([$with_expat])
 570
 571 if test "${with_expat}" = no; then
 572   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 573   HAVE_LIBEXPAT=no
 574 else
 575   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 576                         [XML_Parser p = XML_ParserCreate (0);])
 577   if test "$HAVE_LIBEXPAT" != yes; then
 578     if test "$with_expat" = yes; then
 579       AC_MSG_ERROR([expat is missing or unusable])
 580     else
 581       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 582     fi
 583   else
 584     save_LIBS=$LIBS
 585     LIBS="$LIBS $LIBEXPAT"
 586     AC_CHECK_FUNCS(XML_StopParser)
 587     LIBS=$save_LIBS
 588   fi
 589 fi
 590
 591 dnl Utility to simplify finding libpython.
 592 dnl $1 = pythonX.Y
 593 dnl $2 = the shell variable to assign the result to
 594 dnl      If libpython is found we store $version here.
 595 dnl $3 = additional flags to add to CPPFLAGS
 596 dnl $4 = additional flags to add to LIBS
 597
 598 AC_DEFUN([AC_TRY_LIBPYTHON],
 599 [
 600   version=$1
 601   define([have_libpython_var],$2)
 602   new_CPPFLAGS=$3
 603   new_LIBS=$4
 604   AC_MSG_CHECKING([for ${version}])
 605   save_CPPFLAGS=$CPPFLAGS
 606   save_LIBS=$LIBS
 607   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 608   LIBS="$LIBS $new_LIBS"
 609   found_usable_python=no
 610   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 611                                  [[Py_Initialize ();]]),
 612                  [have_libpython_var=${version}
 613                   found_usable_python=yes],
 614                  [CPPFLAGS=$save_CPPFLAGS
 615                   LIBS=$save_LIBS])
 616   AC_MSG_RESULT([${found_usable_python}])
 617 ])
 618
 619 dnl There are several different values for --with-python:
 620 dnl
 621 dnl no -   Don't include python support.
 622 dnl yes -  Include python support, error if it's missing.
 623 dnl        If we find python in $PATH, use it to fetch configure options,
 624 dnl        otherwise assume the compiler can find it with no help from us.
 625 dnl        Python 2.6, 2.5, and then 2.4 are tried in turn.
 626 dnl auto - Same as "yes", but if python is missing from the system,
 627 dnl        fall back to "no".
 628 dnl /path/to/python/exec-prefix -
 629 dnl        Use the python located in this directory.
 630 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 631 dnl        the compilation parameters.  Otherwise use
 632 dnl        -I/path/to/python/exec-prefix/include,
 633 dnl        -L/path/to/python/exec-prefix/lib.
 634 dnl        Python 2.6, 2.5, and then 2.4 are tried in turn.
 635 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 636 dnl        but is deprecated.
 637 dnl /path/to/python/executable -
 638 dnl        Run python-config.py with this version of python to fetch the
 639 dnl        compilation parameters.
 640 dnl        NOTE: This needn't be the real python executable.
 641 dnl        In a cross-compilation scenario (build != host), this could be
 642 dnl        a shell script that provides what python-config.py provides for
 643 dnl        --ldflags, --includes, --exec-prefix.
 644 dnl python-executable -
 645 dnl        Find python-executable in $PATH, and then handle the same as
 646 dnl        /path/to/python/executable.
 647 dnl
 648 dnl If a python program is specified, it is used to run python-config.py and
 649 dnl is passed --ldflags, --includes, --exec-prefix.
 650
 651 AC_ARG_WITH(python,
 652   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 653   [], [with_python=auto])
 654 AC_MSG_CHECKING([whether to use python])
 655 AC_MSG_RESULT([$with_python])
 656
 657 if test "${with_python}" = no; then
 658   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 659   have_libpython=no
 660 else
 661   case "${with_python}" in
 662   /*)
 663     if test -d ${with_python}; then
 664       # Assume the python binary is ${with_python}/bin/python.
 665       python_prog="${with_python}/bin/python"
 666       python_prefix=
 667       if test ! -x "${python_prog}"; then
 668         # Fall back to gdb 7.0/7.1 behaviour.
 669         python_prog=missing
 670         python_prefix=${with_python}
 671       fi
 672     elif test -x "${with_python}"; then
 673       # While we can't run python compiled for $host (unless host == build),
 674       # the user could write a script that provides the needed information,
 675       # so we support that.
 676       python_prog=${with_python}
 677       python_prefix=
 678     else
 679       AC_ERROR(invalid value for --with-python)
 680     fi
 681     ;;
 682   */*)
 683     # Disallow --with-python=foo/bar.
 684     AC_ERROR(invalid value for --with-python)
 685     ;;
 686   *)
 687     # The user has either specified auto, yes, or the name of the python
 688     # program assumed to be in $PATH.
 689     python_prefix=
 690     case "${with_python}" in
 691     yes | auto)
 692       if test ${build} = ${host}; then
 693         AC_PATH_PROG(python_prog_path, python, missing)
 694         if test "${python_prog_path}" = missing; then
 695           python_prog=missing
 696         else
 697           python_prog=${python_prog_path}
 698         fi
 699       else
 700         # Not much we can do except assume the cross-compiler will find the
 701         # right files.
 702         python_prog=missing
 703       fi
 704       ;;
 705     *)
 706       # While we can't run python compiled for $host (unless host == build),
 707       # the user could write a script that provides the needed information,
 708       # so we support that.
 709       python_prog="${with_python}"
 710       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 711       if test "${python_prog_path}" = missing; then
 712         AC_ERROR(unable to find python program ${python_prog})
 713       fi
 714       ;;
 715     esac
 716   esac
 717
 718   if test "${python_prog}" != missing; then
 719     # We have a python program to use, but it may be too old.
 720     # Don't flag an error for --with-python=auto (the default).
 721     have_python_config=yes
 722     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 723     if test $? != 0; then
 724       have_python_config=failed
 725       if test "${with_python}" != auto; then
 726         AC_ERROR(failure running python-config --includes)
 727       fi
 728     fi
 729     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 730     if test $? != 0; then
 731       have_python_config=failed
 732       if test "${with_python}" != auto; then
 733         AC_ERROR(failure running python-config --ldflags)
 734       fi
 735     fi
 736     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 737     if test $? != 0; then
 738       have_python_config=failed
 739       if test "${with_python}" != auto; then
 740         AC_ERROR(failure running python-config --exec-prefix)
 741       fi
 742     fi
 743   else
 744     # Fall back to gdb 7.0/7.1 behaviour.
 745     if test -z ${python_prefix}; then
 746       python_includes=
 747       python_libs=
 748     else
 749       python_includes="-I${python_prefix}/include"
 750       python_libs="-L${python_prefix}/lib"
 751     fi
 752     have_python_config=no
 753   fi
 754
 755   # Having "/pythonX.Y" in the include path is awkward.
 756   # All those python headers get bubbled up to the top inviting lots
 757   # of random collisions.  GDB originally didn't use python-config to
 758   # find the compilation parameters and includes "pythonX.Y/" in the
 759   # path of the, umm, include file.  So strip away this part of the
 760   # output of python-config --includes.
 761   python_includes=`echo "${python_includes} " \
 762                         | sed -e 's,/python[[0-9]]*[[.]][[0-9]]* , ,g'`
 763
 764   # If we have python-config, only try the configuration it provides.
 765   # Otherwise fallback on the old way of trying different versions of
 766   # python in turn.
 767
 768   have_libpython=no
 769   if test "${have_python_config}" = yes; then
 770     python_version=`echo " ${python_libs} " \
 771                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]][[0-9]]*\) .*$,\1,'`
 772     case "${python_version}" in
 773     python*)
 774       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 775                        ${python_includes}, ${python_libs})
 776       ;;
 777     *)
 778       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 779       ;;
 780     esac
 781   elif test "${have_python_config}" != failed; then
 782     if test "${have_libpython}" = no; then
 783       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 784                        ${python_includes}, "${python_libs} -lpython2.6")
 785     fi
 786     if test ${have_libpython} = no; then
 787       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 788                        ${python_includes}, "${python_libs} -lpython2.5")
 789     fi
 790     if test ${have_libpython} = no; then
 791       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 792                        ${python_includes}, "${python_libs} -lpython2.4")
 793     fi
 794   fi
 795   if test "${have_libpython}" = python2.7; then
 796     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 797   elif test "${have_libpython}" = python2.6; then
 798     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 799   elif test "${have_libpython}" = python2.5; then
 800     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 801   elif test "${have_libpython}" = python2.4; then
 802     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 803   fi
 804
 805   if test "${have_libpython}" = no; then
 806     case "${with_python}" in
 807     yes)
 808       AC_MSG_ERROR([python is missing or unusable])
 809       ;;
 810     auto)
 811       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 812       ;;
 813     *)
 814       AC_MSG_ERROR([no usable python found at ${with_python}])
 815       ;;
 816     esac
 817   else
 818     if test -n "${python_prefix}"; then
 819       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 820                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 821       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 822     fi
 823   fi
 824 fi
 825
 826 if test "${have_libpython}" != no; then
 827   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 828   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 829   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 830   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 831   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 832
 833   # Flags needed to compile Python code (taken from python-config --cflags).
 834   # We cannot call python-config directly because it will output whatever was
 835   # used when compiling the Python interpreter itself, including flags which
 836   # would make the python-related objects be compiled differently from the
 837   # rest of GDB (e.g., -O2 and -fPIC).
 838   if test "${GCC}" = yes; then
 839     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 840   fi
 841
 842   if test "x${tentative_python_cflags}" != x; then
 843     AC_MSG_CHECKING(compiler flags for python code)
 844     for flag in ${tentative_python_cflags}; do
 845       # Check that the compiler accepts it
 846       saved_CFLAGS="$CFLAGS"
 847       CFLAGS="$CFLAGS $flag"
 848       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 849       CFLAGS="$saved_CFLAGS"
 850     done
 851     AC_MSG_RESULT(${PYTHON_CFLAGS})
 852   fi
 853 else
 854   # Even if Python support is not compiled in, we need to have these files
 855   # included.
 856   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 857   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 858         python/py-prettyprint.c python/py-auto-load.c"
 859 fi
 860 AC_SUBST(PYTHON_CFLAGS)
 861
 862 # ------------------------- #
 863 # Checks for header files.  #
 864 # ------------------------- #
 865
 866 AC_HEADER_DIRENT
 867 AC_HEADER_STAT
 868 AC_HEADER_STDC
 869 # elf_hp.h is for HP/UX 64-bit shared library support.
 870 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 871 # unconditionally, so what's the point in checking these?
 872 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 873                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 874                   stdlib.h string.h memory.h strings.h sys/fault.h \
 875                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 876                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 877                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 878                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 879                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 880 AC_CHECK_HEADERS(link.h, [], [],
 881 [#if HAVE_SYS_TYPES_H
 882 # include <sys/types.h>
 883 #endif
 884 #if HAVE_NLIST_H
 885 # include <nlist.h>
 886 #endif
 887 ])
 888 AC_CHECK_HEADERS(sys/proc.h, [], [],
 889 [#if HAVE_SYS_PARAM_H
 890 # include <sys/param.h>
 891 #endif
 892 ])
 893 AC_CHECK_HEADERS(sys/user.h, [], [],
 894 [#if HAVE_SYS_PARAM_H
 895 # include <sys/param.h>
 896 #endif
 897 ])
 898
 899 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 900 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 901 # think that we don't have <curses.h> if we're using GCC.
 902 case $host_os in
 903   solaris2.[[789]])
 904     if test "$GCC" = yes; then
 905       AC_DEFINE(_MSE_INT_H, 1,
 906         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 907    Solaris 2.[789] when using GCC. ])
 908     fi ;;
 909 esac
 910 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 911 AC_CHECK_HEADERS(term.h, [], [],
 912 [#if HAVE_CURSES_H
 913 # include <curses.h>
 914 #endif
 915 ])
 916
 917 # ------------------------- #
 918 # Checks for declarations.  #
 919 # ------------------------- #
 920
 921 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 922                 snprintf, vsnprintf])
 923 AM_LC_MESSAGES
 924
 925 # ----------------------- #
 926 # Checks for structures.  #
 927 # ----------------------- #
 928
 929 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 930
 931 # ------------------ #
 932 # Checks for types.  #
 933 # ------------------ #
 934
 935 AC_TYPE_SIGNAL
 936 AC_CHECK_TYPES(socklen_t, [], [],
 937 [#include <sys/types.h>
 938 #include <sys/socket.h>
 939 ])
 940
 941 # ------------------------------------- #
 942 # Checks for compiler characteristics.  #
 943 # ------------------------------------- #
 944
 945 AC_C_CONST
 946 AC_C_INLINE
 947 AC_C_BIGENDIAN
 948
 949 # ------------------------------ #
 950 # Checks for library functions.  #
 951 # ------------------------------ #
 952
 953 AC_FUNC_ALLOCA
 954 AC_FUNC_MMAP
 955 AC_FUNC_VFORK
 956 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 957                 getgid pipe poll pread64 sbrk setpgid setpgrp setsid \
 958                 sigaction sigprocmask sigsetmask socketpair syscall \
 959                 ttrace wborder setlocale iconvlist libiconvlist btowc \
 960                 setrlimit getrlimit posix_madvise])
 961 AM_LANGINFO_CODESET
 962
 963 # Check the return and argument types of ptrace.  No canned test for
 964 # this, so roll our own.
 965 gdb_ptrace_headers='
 966 #if HAVE_SYS_TYPES_H
 967 # include <sys/types.h>
 968 #endif
 969 #if HAVE_SYS_PTRACE_H
 970 # include <sys/ptrace.h>
 971 #endif
 972 #if HAVE_UNISTD_H
 973 # include <unistd.h>
 974 #endif
 975 '
 976 # There is no point in checking if we don't have a prototype.
 977 AC_CHECK_DECLS(ptrace, [], [
 978   : ${gdb_cv_func_ptrace_ret='int'}
 979   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 980 ], $gdb_ptrace_headers)
 981 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 982 # empty argument list, so check for that explicitly.
 983 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 984   AC_TRY_COMPILE($gdb_ptrace_headers,
 985     [extern long ptrace (enum __ptrace_request, ...);],
 986     gdb_cv_func_ptrace_ret='long',
 987     AC_TRY_COMPILE($gdb_ptrace_headers,
 988       [extern int ptrace ();],
 989       gdb_cv_func_ptrace_ret='int',
 990       gdb_cv_func_ptrace_ret='long')))
 991 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 992   [Define as the return type of ptrace.])
 993 # Check argument types.
 994 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 995   AC_TRY_COMPILE($gdb_ptrace_headers,
 996     [extern long ptrace (enum __ptrace_request, ...);],
 997     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 998 for gdb_arg1 in 'int' 'long'; do
 999  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1000   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1001    for gdb_arg4 in 'int' 'long'; do
1002      AC_TRY_COMPILE($gdb_ptrace_headers, [
1003 extern $gdb_cv_func_ptrace_ret
1004   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1005 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1006     break 4;])
1007     for gdb_arg5 in 'int *' 'int' 'long'; do
1008      AC_TRY_COMPILE($gdb_ptrace_headers, [
1009 extern $gdb_cv_func_ptrace_ret
1010   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1011 ], [
1012 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1013     break 5;])
1014     done
1015    done
1016   done
1017  done
1018 done
1019 # Provide a safe default value.
1020 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1021 ])])
1022 ac_save_IFS=$IFS; IFS=','
1023 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1024 IFS=$ac_save_IFS
1025 shift
1026 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1027   [Define to the type of arg 3 for ptrace.])
1028 if test -n "$[5]"; then
1029   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1030     [Define to the type of arg 5 for ptrace.])
1031 fi
1032
1033 dnl AC_FUNC_SETPGRP does not work when cross compiling
1034 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1035 if test "$cross_compiling" = no; then
1036   AC_FUNC_SETPGRP
1037 else
1038   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1039     [AC_TRY_COMPILE([
1040 #include <unistd.h>
1041 ], [
1042   if (setpgrp(1,1) == -1)
1043     exit (0);
1044   else
1045     exit (1);
1046 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1047 if test $ac_cv_func_setpgrp_void = yes; then
1048   AC_DEFINE(SETPGRP_VOID, 1)
1049 fi
1050 fi
1051
1052 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1053 # since sigsetjmp might only be defined as a macro.
1054 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1055 [AC_TRY_COMPILE([
1056 #include <setjmp.h>
1057 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1058 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1059 if test $gdb_cv_func_sigsetjmp = yes; then
1060   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1061 fi
1062
1063 # Assume we'll default to using the included libiberty regex.
1064 gdb_use_included_regex=yes
1065
1066 # However, if the system regex is GNU regex, then default to *not*
1067 # using the included regex.
1068 AC_CACHE_CHECK(
1069   [for GNU regex],
1070   [gdb_cv_have_gnu_regex],
1071   [AC_TRY_COMPILE(
1072     [#include <gnu-versions.h>],
1073     [#define REGEX_INTERFACE_VERSION 1
1074 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1075 # error "Version mismatch"
1076 #endif],
1077     gdb_cv_have_gnu_regex=yes,
1078     gdb_cv_have_gnu_regex=no)])
1079 if test $gdb_cv_have_gnu_regex = yes; then
1080   gdb_use_included_regex=no
1081 fi
1082
1083 AC_ARG_WITH(included-regex,
1084   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1085   gdb_with_regex=$withval,
1086   gdb_with_regex=$gdb_use_included_regex)
1087 if test "$gdb_with_regex" = yes; then
1088   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1089     [Define to 1 if the regex included in libiberty should be used.])
1090 fi
1091
1092 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1093 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1094 [#include <sys/param.h>
1095 #include <sys/proc.h>
1096 ])
1097
1098 # See if <sys/lwp.h> defines `struct lwp`.
1099 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1100 [AC_TRY_COMPILE([#include <sys/param.h>
1101 #include <sys/lwp.h>], [struct lwp l;],
1102 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1103 if test $gdb_cv_struct_lwp = yes; then
1104   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1105             [Define to 1 if your system has struct lwp.])
1106 fi
1107
1108 # See if <machine/reg.h> degines `struct reg'.
1109 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1110 [AC_TRY_COMPILE([#include <sys/types.h>
1111 #include <machine/reg.h>], [struct reg r;],
1112 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1113 if test $gdb_cv_struct_reg = yes; then
1114   AC_DEFINE(HAVE_STRUCT_REG, 1,
1115             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1116 fi
1117
1118 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1119 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1120 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1121                  [#include <machine/reg.h>])
1122
1123 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1124 AC_MSG_CHECKING(for PTRACE_GETREGS)
1125 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1126 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1127                 [PTRACE_GETREGS;],
1128                 [gdb_cv_have_ptrace_getregs=yes],
1129                 [gdb_cv_have_ptrace_getregs=no])])
1130 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1131 if test $gdb_cv_have_ptrace_getregs = yes; then
1132   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1133   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1134 fi
1135
1136 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1137 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1138 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1139 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1140                 [PTRACE_GETFPXREGS;],
1141                 [gdb_cv_have_ptrace_getfpxregs=yes],
1142                 [gdb_cv_have_ptrace_getfpxregs=no])])
1143 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1144 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1145   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1146   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1147 fi
1148
1149 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1150 AC_MSG_CHECKING(for PT_GETDBREGS)
1151 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1152 [AC_TRY_COMPILE([#include <sys/types.h>
1153 #include <sys/ptrace.h>],
1154                 [PT_GETDBREGS;],
1155                 [gdb_cv_have_pt_getdbregs=yes],
1156                 [gdb_cv_have_pt_getdbregs=no])])
1157 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1158 if test $gdb_cv_have_pt_getdbregs = yes; then
1159   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1160   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1161 fi
1162
1163 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1164 AC_MSG_CHECKING(for PT_GETXMMREGS)
1165 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1166 [AC_TRY_COMPILE([#include <sys/types.h>
1167 #include <sys/ptrace.h>],
1168                 [PT_GETXMMREGS;],
1169                 [gdb_cv_have_pt_getxmmregs=yes],
1170                 [gdb_cv_have_pt_getxmmregs=no])])
1171 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1172 if test $gdb_cv_have_pt_getxmmregs = yes; then
1173   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1174   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1175 fi
1176
1177 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1178
1179 if test "${target}" = "${host}"; then
1180   case "${host}" in
1181   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1182       AC_DEFINE(NEW_PROC_API, 1,
1183       [Define if you want to use new multi-fd /proc interface
1184        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1185       ;;
1186   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1187       AC_DEFINE(NEW_PROC_API, 1,
1188       [Define if you want to use new multi-fd /proc interface
1189        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1190       ;;
1191   mips-sgi-irix5*)
1192       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1193       AC_DEFINE([_KMEMUSER], 1,
1194       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1195        around a <sys/proc.h> problem on IRIX 5.])
1196       ;;
1197   esac
1198 fi
1199
1200 if test "$ac_cv_header_sys_procfs_h" = yes; then
1201   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1202   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1203   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1204   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1205   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1206   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1207   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1208   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1209   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1210   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1211   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1212   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1213   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1214   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1215
1216
1217   dnl Check for broken prfpregset_t type
1218
1219   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1220   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1221   dnl instead of the struct itself).  We detect this here, and work
1222   dnl around it in gdb_proc_service.h.
1223
1224   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1225     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1226     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1227       [AC_TRY_RUN([#include <sys/procfs.h>
1228        int main ()
1229        {
1230          if (sizeof (prfpregset_t) == sizeof (void *))
1231            return 1;
1232          return 0;
1233        }],
1234        gdb_cv_prfpregset_t_broken=no,
1235        gdb_cv_prfpregset_t_broken=yes,
1236        gdb_cv_prfpregset_t_broken=yes)])
1237     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1238     if test $gdb_cv_prfpregset_t_broken = yes; then
1239       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1240       [Define if the prfpregset_t type is broken.])
1241     fi
1242   fi
1243
1244   dnl Check for PIOCSET ioctl entry
1245
1246   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1247   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1248   [AC_TRY_COMPILE([#include <unistd.h>
1249 #include <sys/types.h>
1250 #include <sys/procfs.h>
1251 ], [
1252     int dummy;;
1253     dummy = ioctl(0, PIOCSET, &dummy);
1254   ],
1255   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1256   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1257   if test $gdb_cv_have_procfs_piocset = yes; then
1258     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1259     [Define if ioctl argument PIOCSET is available.])
1260   fi
1261 fi
1262
1263 dnl For native ports (host == target), check to see what kind of
1264 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1265 if test ${host} = ${target} ; then
1266   dnl Check for struct link_map with l_ members which are indicative
1267   dnl of SVR4-like shared libraries
1268
1269   AC_MSG_CHECKING(for member l_addr in struct link_map)
1270   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1271     [AC_TRY_COMPILE([#include <link.h>],
1272                     [struct link_map lm; (void) lm.l_addr;],
1273                     gdb_cv_have_struct_link_map_with_l_members=yes,
1274                     gdb_cv_have_struct_link_map_with_l_members=no)])
1275   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1276   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1277     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1278     [Define if <link.h> exists and defines struct link_map which has
1279      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1280      SVR4-like systems.)])
1281   fi
1282
1283   dnl Check for struct link_map with lm_ members which are indicative
1284   dnl of SunOS-like shared libraries
1285
1286   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1287   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1288     [AC_TRY_COMPILE([#include <sys/types.h>
1289 #include <link.h>],
1290                     [struct link_map lm; (void) lm.lm_addr;],
1291                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1292                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1293   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1294   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1295     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1296     [Define if <link.h> exists and defines struct link_map which has
1297      members with an ``lm_'' prefix.  (For SunOS.)])
1298   fi
1299
1300   dnl Check for struct so_map with som_ members which are found on
1301   dnl some *BSD systems.
1302
1303   AC_MSG_CHECKING(for member som_addr in struct so_map)
1304   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1305     [AC_TRY_COMPILE([#include <sys/types.h>
1306 #ifdef HAVE_NLIST_H
1307 #include <nlist.h>
1308 #endif
1309 #include <link.h>],
1310                     [struct so_map lm; (void) lm.som_addr;],
1311                     gdb_cv_have_struct_so_map_with_som_members=yes,
1312                     gdb_cv_have_struct_so_map_with_som_members=no)])
1313   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1314   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1315     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1316     [Define if <link.h> exists and defines a struct so_map which has
1317      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1318   fi
1319
1320   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1321   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1322
1323   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1324   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1325     [AC_TRY_COMPILE([#define _SYSCALL32
1326 #include <sys/link.h>], [struct link_map32 l;],
1327      gdb_cv_have_struct_link_map32=yes,
1328      gdb_cv_have_struct_link_map32=no)])
1329   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1330   if test $gdb_cv_have_struct_link_map32 = yes; then
1331     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1332     [Define if <sys/link.h> has struct link_map32])
1333     AC_DEFINE(_SYSCALL32, 1,
1334     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1335   fi
1336 fi
1337
1338 # Check if the compiler supports the `long long' type.
1339
1340 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1341                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1342 [[extern long long foo;]],
1343 [[switch (foo & 2) { case 0: return 1; }]])],
1344                                   gdb_cv_c_long_long=yes,
1345                                   gdb_cv_c_long_long=no)])
1346 if test $gdb_cv_c_long_long = yes; then
1347   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1348             [Define to 1 if the compiler supports long long.])
1349 fi
1350
1351 # Check if the compiler and runtime support printing long longs.
1352
1353 AC_CACHE_CHECK([for long long support in printf],
1354                gdb_cv_printf_has_long_long,
1355                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1356 [[char buf[32];
1357   long long l = 0;
1358   l = (l << 16) + 0x0123;
1359   l = (l << 16) + 0x4567;
1360   l = (l << 16) + 0x89ab;
1361   l = (l << 16) + 0xcdef;
1362   sprintf (buf, "0x%016llx", l);
1363   return (strcmp ("0x0123456789abcdef", buf));]])],
1364                               gdb_cv_printf_has_long_long=yes,
1365                               gdb_cv_printf_has_long_long=no,
1366                               gdb_cv_printf_has_long_long=no)])
1367 if test $gdb_cv_printf_has_long_long = yes; then
1368   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1369             [Define to 1 if the "%ll" format works to print long longs.])
1370 fi
1371
1372 # Check if the compiler and runtime support printing decfloats.
1373
1374 AC_CACHE_CHECK([for decfloat support in printf],
1375                gdb_cv_printf_has_decfloat,
1376                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1377 [[char buf[64];
1378   _Decimal32 d32 = 1.2345df;
1379   _Decimal64 d64 = 1.2345dd;
1380   _Decimal128 d128 = 1.2345dl;
1381   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1382   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1383                               gdb_cv_printf_has_decfloat=yes,
1384                               gdb_cv_printf_has_decfloat=no,
1385                               gdb_cv_printf_has_decfloat=no)])
1386 if test $gdb_cv_printf_has_decfloat = yes; then
1387   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1388             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1389 fi
1390
1391 # Check if the compiler supports the `long double' type.  We can't use
1392 # AC_C_LONG_DOUBLE because that one does additional checks on the
1393 # constants defined in <float.h> that fail on some systems,
1394 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1395
1396 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1397                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1398                                   gdb_cv_c_long_double=yes,
1399                                   gdb_cv_c_long_double=no)])
1400 if test $gdb_cv_c_long_double = yes; then
1401   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1402            [Define to 1 if the compiler supports long double.])
1403 fi
1404
1405 # Check if the compiler and runtime support printing long doubles.
1406
1407 AC_CACHE_CHECK([for long double support in printf],
1408                gdb_cv_printf_has_long_double,
1409                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1410 [[char buf[16];
1411   long double f = 3.141592653;
1412   sprintf (buf, "%Lg", f);
1413   return (strncmp ("3.14159", buf, 7));]])],
1414                               gdb_cv_printf_has_long_double=yes,
1415                               gdb_cv_printf_has_long_double=no,
1416                               gdb_cv_printf_has_long_double=no)])
1417 if test $gdb_cv_printf_has_long_double = yes; then
1418   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1419             [Define to 1 if the "%Lg" format works to print long doubles.])
1420 fi
1421
1422 # Check if the compiler and runtime support scanning long doubles.
1423
1424 AC_CACHE_CHECK([for long double support in scanf],
1425                gdb_cv_scanf_has_long_double,
1426                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1427 [[#include <stdio.h>]],
1428 [[char *buf = "3.141592653";
1429   long double f = 0;
1430   sscanf (buf, "%Lg", &f);
1431   return !(f > 3.14159 && f < 3.14160);]])],
1432                               gdb_cv_scanf_has_long_double=yes,
1433                               gdb_cv_scanf_has_long_double=no,
1434                               gdb_cv_scanf_has_long_double=no)])
1435 if test $gdb_cv_scanf_has_long_double = yes; then
1436   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1437             [Define to 1 if the "%Lg" format works to scan long doubles.])
1438 fi
1439
1440 case ${host_os} in
1441 aix*)
1442   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1443     SAVE_LDFLAGS=$LDFLAGS
1444
1445     case $GCC in
1446     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1447     *) gdb_cv_bigtoc=-bbigtoc ;;
1448     esac
1449
1450     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1451     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1452     LDFLAGS="${SAVE_LDFLAGS}"
1453   ])
1454   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1455   ;;
1456 esac
1457
1458 AC_MSG_CHECKING(for the dynamic export flag)
1459 dynamic_list=false
1460 if test "${gdb_native}" = yes; then
1461    # The dynamically loaded libthread_db needs access to symbols in the gdb
1462    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1463    # may not be supported there.
1464    old_LDFLAGS="$LDFLAGS"
1465    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1466    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1467    LDFLAGS="$LDFLAGS $RDYNAMIC"
1468    if test "${have_libpython}" = no; then
1469      AC_TRY_LINK([], [], [dynamic_list=true])
1470    else
1471      # Workaround http://bugs.python.org/issue4434 where static
1472      # libpythonX.Y.a would get its symbols required for
1473      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1474      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1475      old_CFLAGS="$CFLAGS"
1476      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1477      AC_RUN_IFELSE(
1478        AC_LANG_PROGRAM(
1479          [#include "]${have_libpython}[/Python.h"],
1480          [int err;
1481           Py_Initialize ();
1482           err = PyRun_SimpleString ("import itertools\n");
1483           Py_Finalize ();
1484           return err == 0 ? 0 : 1;]),
1485        [dynamic_list=true], [], [true])
1486      CFLAGS="$old_CFLAGS"
1487    fi
1488    LDFLAGS="$old_LDFLAGS"
1489 fi
1490 if $dynamic_list; then
1491   found="-Wl,--dynamic-list"
1492   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1493 else
1494   found="-rdynamic"
1495   RDYNAMIC="-rdynamic"
1496 fi
1497 AC_SUBST(RDYNAMIC)
1498 AC_MSG_RESULT($found)
1499
1500 dnl For certain native configurations, we need to check whether thread
1501 dnl support can be built in or not.
1502 dnl
1503 dnl Note that we only want this if we are both native (host == target),
1504 dnl and not doing a canadian cross build (build == host).
1505
1506 if test ${build} = ${host} -a ${host} = ${target} ; then
1507    case ${host_os} in
1508    hpux*)
1509       AC_MSG_CHECKING(for HPUX/OSF thread support)
1510       if test -f /usr/include/dce/cma_config.h ; then
1511          if test "$GCC" = "yes" ; then
1512             AC_MSG_RESULT(yes)
1513             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1514             [Define if you have HPUX threads])
1515             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1516             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1517          else
1518             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1519          fi
1520       else
1521          AC_MSG_RESULT(no)
1522       fi
1523       ;;
1524    solaris*)
1525       # See if thread_db library is around for Solaris thread debugging.
1526       # Note that we must explicitly test for version 1 of the library
1527       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1528       # the same API.
1529       AC_MSG_CHECKING(for Solaris thread debugging library)
1530       if test -f /usr/lib/libthread_db.so.1 ; then
1531          AC_MSG_RESULT(yes)
1532          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1533          [Define if using Solaris thread debugging.])
1534          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1535          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1536          AC_CHECK_LIB(dl, dlopen)
1537          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1538          # Sun randomly tweaked the prototypes in <proc_service.h>
1539          # at one point.
1540          AC_MSG_CHECKING(if <proc_service.h> is old)
1541          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1542             AC_TRY_COMPILE([
1543                 #include <proc_service.h>
1544                 ps_err_e ps_pdwrite
1545                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1546             ],, gdb_cv_proc_service_is_old=no,
1547                 gdb_cv_proc_service_is_old=yes)
1548          ])
1549          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1550          if test $gdb_cv_proc_service_is_old = yes; then
1551             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1552             [Define if <proc_service.h> on solaris uses int instead of
1553              size_t, and assorted other type changes.])
1554          fi
1555       else
1556          AC_MSG_RESULT(no)
1557       fi
1558       ;;
1559    aix*)
1560       AC_MSG_CHECKING(for AiX thread debugging library)
1561       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1562                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1563                                    [#ifndef PTHDB_VERSION_3
1564                                     #error
1565                                     #endif],
1566                                    gdb_cv_have_aix_thread_debug=yes,
1567                                    gdb_cv_have_aix_thread_debug=no)])
1568       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1569       if test $gdb_cv_have_aix_thread_debug = yes; then
1570          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1571          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1572          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1573       fi
1574       ;;
1575    esac
1576    AC_SUBST(CONFIG_LDFLAGS)
1577 fi
1578
1579 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1580 dnl other error codes.
1581 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1582    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1583                   gdb_cv_thread_db_h_has_td_notalloc,
1584      AC_TRY_COMPILE(
1585        [#include <thread_db.h>],
1586        [int i = TD_NOTALLOC;],
1587        gdb_cv_thread_db_h_has_td_notalloc=yes,
1588        gdb_cv_thread_db_h_has_td_notalloc=no
1589      )
1590    )
1591    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1592                   gdb_cv_thread_db_h_has_td_version,
1593      AC_TRY_COMPILE(
1594        [#include <thread_db.h>],
1595        [int i = TD_VERSION;],
1596        gdb_cv_thread_db_h_has_td_version=yes,
1597        gdb_cv_thread_db_h_has_td_version=no
1598      )
1599    )
1600    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1601                   gdb_cv_thread_db_h_has_td_notls,
1602      AC_TRY_COMPILE(
1603        [#include <thread_db.h>],
1604        [int i = TD_NOTLS;],
1605        gdb_cv_thread_db_h_has_td_notls=yes,
1606        gdb_cv_thread_db_h_has_td_notls=no
1607      )
1608    )
1609 fi
1610 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1611   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1612             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1613 fi
1614 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1615   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1616             [Define if <thread_db.h> has the TD_VERSION error code.])
1617 fi
1618 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1619   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1620             [Define if <thread_db.h> has the TD_NOTLS error code.])
1621 fi
1622
1623 dnl See if we have a sys/syscall header file that has __NR_tkill.
1624 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1625    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1626                   gdb_cv_sys_syscall_h_has_tkill,
1627      AC_TRY_COMPILE(
1628        [#include <sys/syscall.h>],
1629        [int i = __NR_tkill;],
1630        gdb_cv_sys_syscall_h_has_tkill=yes,
1631        gdb_cv_sys_syscall_h_has_tkill=no
1632      )
1633    )
1634 fi
1635 dnl See if we can issue tkill syscall.
1636 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1637   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1638 fi
1639
1640 dnl Check if we can disable the virtual address space randomization.
1641 dnl The functionality of setarch -R.
1642 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1643 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1644 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1645 #       define ADDR_NO_RANDOMIZE 0x0040000
1646 #      endif
1647        /* Test the flag could be set and stays set.  */
1648        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1649        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1650            return 1])])
1651 AC_RUN_IFELSE([PERSONALITY_TEST],
1652               [have_personality=true],
1653               [have_personality=false],
1654               [AC_LINK_IFELSE([PERSONALITY_TEST],
1655                               [have_personality=true],
1656                               [have_personality=false])])
1657 if $have_personality
1658 then
1659     AC_DEFINE([HAVE_PERSONALITY], 1,
1660               [Define if you support the personality syscall.])
1661 fi
1662
1663 dnl Handle optional features that can be enabled.
1664
1665 target_sysroot_reloc=0
1666 AC_ARG_WITH(sysroot,
1667 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1668 [
1669  case ${with_sysroot} in
1670  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1671  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1672  esac
1673
1674  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1675
1676  if test "x$prefix" = xNONE; then
1677   test_prefix=/usr/local
1678  else
1679   test_prefix=$prefix
1680  fi
1681  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1682   test_exec_prefix=$test_prefix
1683  else
1684   test_exec_prefix=$exec_prefix
1685  fi
1686  case ${TARGET_SYSTEM_ROOT} in
1687  "${test_prefix}"|"${test_prefix}/"*|\
1688  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1689  '${prefix}'|'${prefix}/'*|\
1690  '${exec_prefix}'|'${exec_prefix}/'*)
1691    target_sysroot_reloc=1
1692    ;;
1693  esac
1694 ], [
1695  TARGET_SYSTEM_ROOT=
1696  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1697 ])
1698 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1699 AC_SUBST(TARGET_SYSTEM_ROOT)
1700 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1701
1702 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1703     [automatically load a system-wide gdbinit file],
1704     [])
1705
1706 AC_ARG_ENABLE(werror,
1707   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1708   [case "${enableval}" in
1709      yes | y) ERROR_ON_WARNING="yes" ;;
1710      no | n)  ERROR_ON_WARNING="no" ;;
1711      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1712    esac])
1713
1714 # Enable -Werror by default when using gcc
1715 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1716     ERROR_ON_WARNING=yes
1717 fi
1718
1719 WERROR_CFLAGS=""
1720 if test "${ERROR_ON_WARNING}" = yes ; then
1721     WERROR_CFLAGS="-Werror"
1722 fi
1723
1724 # The entries after -Wno-pointer-sign are disabled warnings which may
1725 # be enabled in the future, which can not currently be used to build
1726 # GDB.
1727 # NOTE: If you change this list, remember to update
1728 # gdb/doc/gdbint.texinfo.
1729 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1730 -Wformat-nonliteral -Wno-pointer-sign \
1731 -Wno-unused -Wunused-value -Wunused-function \
1732 -Wno-switch -Wno-char-subscripts"
1733
1734 # Enable -Wno-format by default when using gcc on mingw since many
1735 # GCC versions complain about %I64.
1736 case "${host}" in
1737   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1738 esac
1739
1740 AC_ARG_ENABLE(build-warnings,
1741 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1742 [case "${enableval}" in
1743   yes)  ;;
1744   no)   build_warnings="-w";;
1745   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1746         build_warnings="${build_warnings} ${t}";;
1747   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1748         build_warnings="${t} ${build_warnings}";;
1749   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1750 esac
1751 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1752   echo "Setting compiler warning flags = $build_warnings" 6>&1
1753 fi])dnl
1754 AC_ARG_ENABLE(gdb-build-warnings,
1755 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1756 [case "${enableval}" in
1757   yes)  ;;
1758   no)   build_warnings="-w";;
1759   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1760         build_warnings="${build_warnings} ${t}";;
1761   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1762         build_warnings="${t} ${build_warnings}";;
1763   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1764 esac
1765 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1766   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1767 fi])dnl
1768 WARN_CFLAGS=""
1769 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1770 then
1771     AC_MSG_CHECKING(compiler warning flags)
1772     # Separate out the -Werror flag as some files just cannot be
1773     # compiled with it enabled.
1774     for w in ${build_warnings}; do
1775         case $w in
1776         -Werr*) WERROR_CFLAGS=-Werror ;;
1777         *) # Check that GCC accepts it
1778             saved_CFLAGS="$CFLAGS"
1779             CFLAGS="$CFLAGS $w"
1780             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1781             CFLAGS="$saved_CFLAGS"
1782         esac
1783     done
1784     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1785 fi
1786 AC_SUBST(WARN_CFLAGS)
1787 AC_SUBST(WERROR_CFLAGS)
1788
1789 # In the Cygwin environment, we need some additional flags.
1790 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1791 [AC_EGREP_CPP(lose, [
1792 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1793 lose
1794 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1795
1796
1797 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1798 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1799 case ${host} in
1800   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1801   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1802   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1803 esac
1804 AC_SUBST(SER_HARDWIRE)
1805
1806 # libreadline needs libuser32.a in a cygwin environment
1807 WIN32LIBS=
1808 if test x$gdb_cv_os_cygwin = xyes; then
1809     WIN32LIBS="-luser32"
1810     case "${target}" in
1811         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1812         ;;
1813     esac
1814 fi
1815
1816 # The ser-tcp.c module requires sockets.
1817 case ${host} in
1818   *mingw32*)
1819     AC_DEFINE(USE_WIN32API, 1,
1820               [Define if we should use the Windows API, instead of the
1821                POSIX API.  On Windows, we use the Windows API when
1822                building for MinGW, but the POSIX API when building
1823                for Cygwin.])
1824     WIN32LIBS="$WIN32LIBS -lws2_32"
1825     ;;
1826 esac
1827 AC_SUBST(WIN32LIBS)
1828
1829 # Add ELF support to GDB, but only if BFD includes ELF support.
1830 OLD_CFLAGS=$CFLAGS
1831 OLD_LDFLAGS=$LDFLAGS
1832 OLD_LIBS=$LIBS
1833 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1834 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1835 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1836 LIBS="-lbfd -liberty $intl $LIBS"
1837 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1838 [AC_TRY_LINK(
1839 [#include <stdlib.h>
1840 #include "bfd.h"
1841 #include "elf-bfd.h"
1842 ],
1843 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1844 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1845 if test $gdb_cv_var_elf = yes; then
1846   CONFIG_OBS="$CONFIG_OBS elfread.o"
1847   AC_DEFINE(HAVE_ELF, 1,
1848             [Define if ELF support should be included.])
1849 fi
1850 CFLAGS=$OLD_CFLAGS
1851 LDFLAGS=$OLD_LDFLAGS
1852 LIBS=$OLD_LIBS
1853
1854 # Add any host-specific objects to GDB.
1855 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1856
1857 LIBGUI="../libgui/src/libgui.a"
1858 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1859 AC_SUBST(LIBGUI)
1860 AC_SUBST(GUI_CFLAGS_X)
1861
1862 WIN32LDAPP=
1863 AC_SUBST(WIN32LIBS)
1864 AC_SUBST(WIN32LDAPP)
1865
1866 case "${host}" in
1867 *-*-cygwin* | *-*-mingw* )
1868     configdir="win"
1869     ;;
1870 *)
1871     configdir="unix"
1872     ;;
1873 esac
1874
1875 GDBTKLIBS=
1876 if test "${enable_gdbtk}" = "yes"; then
1877
1878     # Gdbtk must have an absolute path to srcdir in order to run
1879     # properly when not installed.
1880     here=`pwd`
1881     cd ${srcdir}
1882     GDBTK_SRC_DIR=`pwd`
1883     cd $here
1884
1885     SC_PATH_TCLCONFIG
1886
1887     # If $no_tk is nonempty, then we can't do Tk, and there is no
1888     # point to doing Tcl.
1889     SC_PATH_TKCONFIG
1890
1891     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1892         SC_LOAD_TCLCONFIG
1893
1894         # Check for in-tree tcl
1895         here=`pwd`
1896         cd ${srcdir}/..
1897         topdir=`pwd`
1898         cd ${here}
1899
1900         intree="no"
1901         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1902           intree="yes"
1903         fi
1904
1905         # Find Tcl private headers
1906         if test x"${intree}" = xno; then
1907           CY_AC_TCL_PRIVATE_HEADERS
1908           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1909           TCL_LIBRARY="${TCL_LIB_SPEC}"
1910           TCL_DEPS=""
1911         else
1912           # If building tcl in the same src tree, private headers
1913           # are not needed, but we need to be sure to use the right
1914           # headers library
1915           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1916           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1917           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1918         fi
1919         AC_SUBST(TCL_INCLUDE)
1920         AC_SUBST(TCL_LIBRARY)
1921         AC_SUBST(TCL_DEPS)
1922
1923         SC_LOAD_TKCONFIG
1924
1925         # Check for in-tree Tk
1926         intree="no"
1927         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1928           intree="yes"
1929         fi
1930
1931         # Find Tk private headers
1932         if test x"${intree}" = xno; then
1933           CY_AC_TK_PRIVATE_HEADERS
1934           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1935           TK_LIBRARY=${TK_LIB_SPEC}
1936           TK_DEPS=""
1937         else
1938           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1939           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1940           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1941         fi
1942         AC_SUBST(TK_INCLUDE)
1943         AC_SUBST(TK_LIBRARY)
1944         AC_SUBST(TK_DEPS)
1945         AC_SUBST(TK_XINCLUDES)
1946
1947         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1948
1949         # Include some libraries that Tcl and Tk want.
1950         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1951         # Yes, the ordering seems wrong here.  But it isn't.
1952         # TK_LIBS is the list of libraries that need to be linked
1953         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1954         # were in LIBS then any link tests after this point would
1955         # try to include things like `$(LIBGUI)', which wouldn't work.
1956         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1957
1958         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1959         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1960         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1961         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1962         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1963         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1964         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1965
1966         if test x$gdb_cv_os_cygwin = xyes; then
1967           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1968           WIN32LDAPP="-Wl,--subsystem,console"
1969           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1970         fi
1971
1972         AC_CONFIG_SUBDIRS(gdbtk)
1973     fi
1974 fi
1975
1976 AC_SUBST(X_CFLAGS)
1977 AC_SUBST(X_LDFLAGS)
1978 AC_SUBST(X_LIBS)
1979 AC_SUBST(GDBTKLIBS)
1980 AC_SUBST(GDBTK_CFLAGS)
1981 AC_SUBST(GDBTK_SRC_DIR)
1982
1983 AC_PATH_X
1984
1985 # Unlike the sim directory, whether a simulator is linked is controlled by
1986 # presence of a gdb_sim definition in the target configure.tgt entry.
1987 # This code just checks for a few cases where we'd like to ignore those
1988 # definitions, even when they're present in the '.mt' file.  These cases
1989 # are when --disable-sim is specified, or if the simulator directory is
1990 # not part of the source tree.
1991 #
1992 AC_ARG_ENABLE(sim,
1993 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1994 [echo "enable_sim = $enable_sim";
1995  echo "enableval = ${enableval}";
1996  case "${enableval}" in
1997   yes) ignore_sim=false ;;
1998   no)  ignore_sim=true ;;
1999   *)   ignore_sim=false ;;
2000  esac],
2001 [ignore_sim=false])
2002
2003 if test ! -d "${srcdir}/../sim"; then
2004   ignore_sim=true
2005 fi
2006
2007 SIM=
2008 SIM_OBS=
2009 if test "${ignore_sim}" = "false"; then
2010   if test x"${gdb_sim}" != x ; then
2011     SIM="${gdb_sim}"
2012     SIM_OBS="remote-sim.o"
2013     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2014   fi
2015 fi
2016 AC_SUBST(SIM)
2017 AC_SUBST(SIM_OBS)
2018
2019 AC_SUBST(ENABLE_CFLAGS)
2020 AC_SUBST(PROFILE_CFLAGS)
2021
2022 AC_SUBST(CONFIG_OBS)
2023 AC_SUBST(CONFIG_DEPS)
2024 AC_SUBST(CONFIG_SRCS)
2025 AC_SUBST(CONFIG_ALL)
2026 AC_SUBST(CONFIG_CLEAN)
2027 AC_SUBST(CONFIG_INSTALL)
2028 AC_SUBST(CONFIG_UNINSTALL)
2029
2030 # List of host floatformats.
2031 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2032 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2033 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2034
2035 # target_subdir is used by the testsuite to find the target libraries.
2036 target_subdir=
2037 if test "${host}" != "${target}"; then
2038     target_subdir="${target_alias}/"
2039 fi
2040 AC_SUBST(target_subdir)
2041
2042 frags=
2043 if test "${gdb_native}" = "yes"; then
2044   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2045   if test ! -f ${host_makefile_frag}; then
2046     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2047   fi
2048   frags="$frags $host_makefile_frag"
2049 else
2050   host_makefile_frag=/dev/null
2051 fi
2052
2053 AC_SUBST_FILE(host_makefile_frag)
2054 AC_SUBST(frags)
2055
2056 changequote(,)dnl
2057 if test "${gdb_native}" = "yes"; then
2058 # We pick this up from the host configuration file (.mh) because we
2059 # do not have a native configuration Makefile fragment.
2060 nativefile=`sed -n '
2061 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2062 ' ${host_makefile_frag}`
2063 fi
2064 changequote([,])
2065
2066 if test x"${gdb_osabi}" != x ; then
2067     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2068                        [Define to the default OS ABI for this configuration.])
2069 fi
2070
2071 # Enable multi-ice-gdb-server.
2072 AC_ARG_ENABLE(multi-ice,
2073 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2074   [case $enableval in
2075     yes | no)
2076       ;;
2077     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2078   esac])
2079 if test "x$enable_multi_ice" = xyes; then
2080    AC_CONFIG_SUBDIRS(multi-ice)
2081 fi
2082
2083 # We only build gdbserver automatically in a native configuration.
2084 if test "$gdb_native" = "yes"; then
2085   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2086   if test "x$build_gdbserver" = xyes; then
2087     AC_MSG_RESULT(yes)
2088     AC_CONFIG_SUBDIRS(gdbserver)
2089   else
2090     AC_MSG_RESULT(no)
2091   fi
2092 fi
2093
2094 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2095 # to an empty version.
2096
2097 files=
2098 links=
2099
2100 rm -f nm.h
2101 if test "${nativefile}" != ""; then
2102     case "${nativefile}" in
2103       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2104       * ) GDB_NM_FILE="${nativefile}"
2105     esac
2106     files="${files} ${GDB_NM_FILE}"
2107     links="${links} nm.h"
2108     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2109 fi
2110 AC_SUBST(GDB_NM_FILE)
2111
2112 AC_LINK_FILES($files, $links)
2113
2114 dnl Check for exe extension set on certain hosts (e.g. Win32)
2115 AC_EXEEXT
2116
2117 dnl  Detect the character set used by this host.
2118 dnl  At the moment, we just assume it's UTF-8.
2119 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2120           [Define to be a string naming the default host character set.])
2121
2122 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
2123 [
2124 case x$CONFIG_HEADERS in
2125 xconfig.h:config.in)
2126 echo > stamp-h ;;
2127 esac
2128 ])
2129
2130 exit 0