gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 dnl Boston, MA 02110-1301, USA.
  21
  22 dnl Process this file with autoconf to produce a configure script.
  23
  24 AC_PREREQ(2.59)dnl
  25 AC_INIT(main.c)
  26 AC_CONFIG_HEADER(config.h:config.in)
  27 AM_MAINTAINER_MODE
  28
  29 AC_PROG_CC
  30 AC_GNU_SOURCE
  31 AC_AIX
  32 AC_ISC_POSIX
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  36 AC_CANONICAL_SYSTEM
  37
  38 dnl List of object files and targets accumulated by configure.
  39
  40 CONFIG_OBS=
  41 CONFIG_DEPS=
  42 CONFIG_SRCS=
  43 ENABLE_CFLAGS=
  44
  45 CONFIG_ALL=
  46 CONFIG_CLEAN=
  47 CONFIG_INSTALL=
  48 CONFIG_UNINSTALL=
  49
  50 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  51
  52 CY_GNU_GETTEXT
  53
  54 localedir='${datadir}/locale'
  55 AC_SUBST(localedir)
  56
  57 if test "x$POSUB" != x; then
  58
  59   dnl Lifted from GCC's config/gettext.m4.
  60   AC_MSG_CHECKING(for catalogs to be installed)
  61   # Look for .po and .gmo files in the source directory.
  62   CATALOGS=  AC_SUBST(CATALOGS)
  63   XLINGUAS=
  64   for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
  65     # If there aren't any .gmo files the shell will give us the
  66     # literal string "../path/to/srcdir/po/*.gmo" which has to be
  67     # weeded out.
  68     case "$cat" in *\**)
  69       continue;;
  70     esac
  71     # The quadruple backslash is collapsed to a double backslash
  72     # by the backticks, then collapsed again by the double quotes,
  73     # leaving us with one backslash in the sed expression (right
  74     # before the dot that mustn't act as a wildcard).
  75     cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
  76     lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
  77     # The user is allowed to set LINGUAS to a list of languages to
  78     # install catalogs for.  If it's empty that means "all of them."
  79     if test "x$LINGUAS" = x; then
  80       CATALOGS="$CATALOGS $cat"
  81       XLINGUAS="$XLINGUAS $lang"
  82     else
  83       case "$LINGUAS" in *$lang*)
  84         CATALOGS="$CATALOGS $cat"
  85         XLINGUAS="$XLINGUAS $lang"
  86         ;;
  87       esac
  88     fi
  89   done
  90   LINGUAS="$XLINGUAS"
  91   AC_MSG_RESULT($LINGUAS)
  92
  93    CONFIG_ALL="$CONFIG_ALL all-po"
  94    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  95    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  96    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  97 fi
  98
  99 PACKAGE=gdb
 100 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 101 AC_SUBST(PACKAGE)
 102
 103 debugdir=${libdir}/debug
 104
 105 AC_ARG_WITH(separate-debug-dir,
 106 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
 107 [debugdir="${withval}"])
 108
 109 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 110               [Global directory for separate debug files. ])
 111 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 112
 113 AC_CONFIG_SUBDIRS(doc testsuite)
 114
 115 . $srcdir/configure.host
 116
 117 . $srcdir/configure.tgt
 118
 119 # Fetch the default architecture and default target vector from BFD.
 120 targ=$target; . $srcdir/../bfd/config.bfd
 121
 122 # We only want the first architecture, so strip off the others if
 123 # there is more than one.
 124 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 125
 126 if test "x$targ_archs" != x; then
 127   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 128     [Define to BFD's default architecture. ])
 129 fi
 130 if test "x$targ_defvec" != x; then
 131   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 132     [Define to BFD's default target vector. ])
 133 fi
 134
 135 AC_ARG_PROGRAM
 136
 137 # The CLI cannot be disabled yet, but may be in the future.
 138
 139 # Enable CLI.
 140 AC_ARG_ENABLE(gdbcli,
 141 [  --disable-gdbcli        disable command-line interface (CLI)],
 142   [case $enableval in
 143     yes)
 144       ;;
 145     no)
 146       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 147     *)
 148       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 149   esac],
 150   [enable_gdbcli=yes])
 151 if test x"$enable_gdbcli" = xyes; then
 152   if test -d $srcdir/cli; then
 153     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 154     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 155     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 156     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 157   fi
 158 fi
 159
 160 # Enable MI.
 161 AC_ARG_ENABLE(gdbmi,
 162 [  --disable-gdbmi         disable machine-interface (MI)],
 163   [case $enableval in
 164     yes | no)
 165       ;;
 166     *)
 167       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 168   esac],
 169   [enable_gdbmi=yes])
 170 if test x"$enable_gdbmi" = xyes; then
 171   if test -d $srcdir/mi; then
 172     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 173     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 174     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 175     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 176   fi
 177 fi
 178
 179 # Enable TUI.
 180 AC_ARG_ENABLE(tui,
 181 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 182   [case $enableval in
 183     yes | no)
 184       ;;
 185     *)
 186       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 187   esac],enable_tui=yes)
 188
 189 # Enable gdbtk.
 190 AC_ARG_ENABLE(gdbtk,
 191 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 192   [case $enableval in
 193     yes | no)
 194       ;;
 195     *)
 196       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 197   esac],
 198   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 199     enable_gdbtk=yes
 200   else
 201     enable_gdbtk=no
 202   fi])
 203 # We unconditionally disable gdbtk tests on selected platforms.
 204 case $host_os in
 205   go32* | windows*)
 206     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 207     enable_gdbtk=no ;;
 208 esac
 209
 210 # Libunwind support.
 211 AC_ARG_WITH(libunwind,
 212 [  --with-libunwind            Use libunwind frame unwinding support],
 213 [case "${withval}" in
 214   yes)  enable_libunwind=yes ;;
 215   no)   enable_libunwind=no ;;
 216   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 217 esac],[
 218   AC_CHECK_HEADERS(libunwind.h)
 219   AC_CHECK_HEADERS(libunwind-ia64.h)
 220   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 221     enable_libunwind=yes;
 222   fi
 223 ])
 224
 225 if test x"$enable_libunwind" = xyes; then
 226   AC_CHECK_HEADERS(libunwind.h)
 227   AC_CHECK_HEADERS(libunwind-ia64.h)
 228   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 229   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 230   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 231   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 232 fi
 233
 234 # Profiling support.
 235 AC_ARG_ENABLE(profiling,
 236 [  --enable-profiling      enable profiling of GDB],
 237   [case $enableval in
 238     yes | no)
 239       ;;
 240     *)
 241       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 242   esac],
 243  [enable_profiling=no])
 244
 245 AC_CHECK_FUNCS(monstartup _mcleanup)
 246 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 247 [AC_TRY_LINK(
 248 [#include <stdlib.h>
 249 extern char _etext;
 250 ],
 251 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 252 if test $ac_cv_var__etext = yes; then
 253   AC_DEFINE(HAVE__ETEXT, 1,
 254             [Define to 1 if your system has the _etext variable. ])
 255 fi
 256 if test "$enable_profiling" = yes ; then
 257   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 258     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 259   fi
 260   PROFILE_CFLAGS=-pg
 261   OLD_CFLAGS="$CFLAGS"
 262   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 263
 264   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 265     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 266      ac_cv_cc_supports_pg=no)])
 267
 268   if test $ac_cv_cc_supports_pg = no; then
 269     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 270   fi
 271
 272   CFLAGS="$OLD_CFLAGS"
 273 fi
 274
 275 # --------------------- #
 276 # Checks for programs.  #
 277 # --------------------- #
 278
 279 AC_PROG_AWK
 280 AC_PROG_INSTALL
 281 AC_PROG_LN_S
 282 AC_PROG_RANLIB
 283 AC_PROG_YACC
 284
 285 AC_CHECK_TOOL(AR, ar)
 286 AC_CHECK_TOOL(DLLTOOL, dlltool)
 287 AC_CHECK_TOOL(WINDRES, windres)
 288
 289 # Needed for GNU/Hurd.
 290 AC_CHECK_TOOL(MIG, mig)
 291
 292 # ---------------------- #
 293 # Checks for libraries.  #
 294 # ---------------------- #
 295
 296 # We might need to link with -lm; most simulators need it.
 297 AC_CHECK_LIB(m, main)
 298
 299 # We need to link with -lw to get `wctype' on Solaris before Solaris
 300 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 301 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 302 # is known to have this problem).  Therefore we avoid libw if we can.
 303 AC_CHECK_FUNC(wctype, [],
 304   [AC_CHECK_LIB(w, wctype)])
 305
 306 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 307 AC_SEARCH_LIBS(gethostbyname, nsl)
 308
 309 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 310 AC_SEARCH_LIBS(socketpair, socket)
 311
 312 # For the TUI, we need enhanced curses functionality.
 313 #
 314 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 315 # curses library because the latter might not provide all the
 316 # functionality we need.  However, this leads to problems on systems
 317 # where the linker searches /usr/local/lib, but the compiler doesn't
 318 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 319 # default installation of ncurses on alpha*-dec-osf* will lead to such
 320 # a situation.
 321 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 322
 323 # Since GDB uses Readline, we need termcap functionality.  In many
 324 # cases this will be provided by the curses library, but some systems
 325 # have a seperate termcap library, or no curses library at all.
 326
 327 case $host_os in
 328   cygwin*)
 329     if test -d $srcdir/libtermcap; then
 330       LIBS="../libtermcap/libtermcap.a $LIBS"
 331       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 332     fi ;;
 333   go32* | *djgpp*)
 334     ac_cv_search_tgetent="none required"
 335     ;;
 336   *mingw32*)
 337     ac_cv_search_tgetent="none required"
 338     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 339     ;;
 340 esac
 341
 342 # These are the libraries checked by Readline.
 343 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 344
 345 if test "$ac_cv_search_tgetent" = no; then
 346   AC_MSG_ERROR([no termcap library found])
 347 fi
 348
 349 # ------------------------- #
 350 # Checks for header files.  #
 351 # ------------------------- #
 352
 353 AC_HEADER_DIRENT
 354 AC_HEADER_STAT
 355 AC_HEADER_STDC
 356 AC_CHECK_HEADERS(nlist.h)
 357 AC_CHECK_HEADERS(link.h, [], [],
 358 [#if HAVE_SYS_TYPES_H
 359 # include <sys/types.h>
 360 #endif
 361 #if HAVE_NLIST_H
 362 # include <nlist.h>
 363 #endif
 364 ])
 365 AC_CHECK_HEADERS(machine/reg.h)
 366 AC_CHECK_HEADERS(poll.h sys/poll.h)
 367 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 368 AC_CHECK_HEADERS(stddef.h)
 369 AC_CHECK_HEADERS(stdlib.h)
 370 AC_CHECK_HEADERS(stdint.h)
 371 AC_CHECK_HEADERS(string.h memory.h strings.h)
 372 AC_CHECK_HEADERS(sys/fault.h)
 373 AC_CHECK_HEADERS(sys/file.h)
 374 AC_CHECK_HEADERS(sys/filio.h)
 375 AC_CHECK_HEADERS(sys/ioctl.h)
 376 AC_CHECK_HEADERS(sys/param.h)
 377 AC_CHECK_HEADERS(sys/proc.h, [], [],
 378 [#if HAVE_SYS_PARAM_H
 379 # include <sys/param.h>
 380 #endif
 381 ])
 382 AC_CHECK_HEADERS(sys/procfs.h)
 383 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 384 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 385 AC_CHECK_HEADERS(sys/select.h)
 386 AC_CHECK_HEADERS(sys/syscall.h)
 387 AC_CHECK_HEADERS(sys/types.h)
 388 AC_CHECK_HEADERS(sys/user.h, [], [],
 389 [#if HAVE_SYS_PARAM_H
 390 # include <sys/param.h>
 391 #endif
 392 ])
 393 AC_CHECK_HEADERS(sys/wait.h wait.h)
 394 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 395 AC_CHECK_HEADERS(unistd.h)
 396
 397 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 398 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 399 # think that we don't have <curses.h> if we're using GCC.
 400 case $host_os in
 401   solaris2.[[789]])
 402     if test "$GCC" = yes; then
 403       AC_DEFINE(_MSE_INT_H, 1,
 404         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 405    Solaris 2.[789] when using GCC. ])
 406     fi ;;
 407 esac
 408 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 409 AC_CHECK_HEADERS(ncurses/term.h)
 410 AC_CHECK_HEADERS(term.h, [], [],
 411 [#if HAVE_CURSES_H
 412 # include <curses.h>
 413 #endif
 414 ])
 415
 416 # FIXME: kettenis/20030102: In most cases we include these
 417 # unconditionally, so what's the point in checking these?
 418 AC_CHECK_HEADERS(ctype.h time.h)
 419
 420 # ------------------------- #
 421 # Checks for declarations.  #
 422 # ------------------------- #
 423
 424 AC_CHECK_DECLS([free, malloc, realloc])
 425 AC_CHECK_DECLS([strerror, strstr])
 426 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 427
 428 # ----------------------- #
 429 # Checks for structures.  #
 430 # ----------------------- #
 431
 432 AC_CHECK_MEMBERS([struct stat.st_blocks])
 433 AC_CHECK_MEMBERS([struct stat.st_blksize])
 434
 435 # ------------------ #
 436 # Checks for types.  #
 437 # ------------------ #
 438
 439 AC_TYPE_SIGNAL
 440 AC_CHECK_TYPES(socklen_t, [], [],
 441 [#include <sys/types.h>
 442 #include <sys/socket.h>
 443 ])
 444 AC_CHECK_TYPES(uintptr_t, [], [], [#include <stdint.h>])
 445
 446 # ------------------------------------- #
 447 # Checks for compiler characteristics.  #
 448 # ------------------------------------- #
 449
 450 AC_C_CONST
 451 AC_C_INLINE
 452
 453 # ------------------------------ #
 454 # Checks for library functions.  #
 455 # ------------------------------ #
 456
 457 AC_FUNC_ALLOCA
 458 AC_FUNC_MMAP
 459 AC_FUNC_VFORK
 460 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 461 AC_CHECK_FUNCS(getuid getgid)
 462 AC_CHECK_FUNCS(poll)
 463 AC_CHECK_FUNCS(pread64)
 464 AC_CHECK_FUNCS(sbrk)
 465 AC_CHECK_FUNCS(setpgid setpgrp)
 466 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 467 AC_CHECK_FUNCS(socketpair)
 468 AC_CHECK_FUNCS(syscall)
 469 AC_CHECK_FUNCS(ttrace)
 470 AC_CHECK_FUNCS(wborder)
 471
 472 # Check the return and argument types of ptrace.  No canned test for
 473 # this, so roll our own.
 474 gdb_ptrace_headers='
 475 #if HAVE_SYS_TYPES_H
 476 # include <sys/types.h>
 477 #endif
 478 #if HAVE_SYS_PTRACE_H
 479 # include <sys/ptrace.h>
 480 #endif
 481 #if HAVE_UNISTD_H
 482 # include <unistd.h>
 483 #endif
 484 '
 485 # There is no point in checking if we don't have a prototype.
 486 AC_CHECK_DECLS(ptrace, [], [
 487   : ${gdb_cv_func_ptrace_ret='int'}
 488   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 489 ], $gdb_ptrace_headers)
 490 # Check return type.
 491 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 492   AC_TRY_COMPILE($gdb_ptrace_headers,
 493     [extern int ptrace ();],
 494     gdb_cv_func_ptrace_ret='int',
 495     gdb_cv_func_ptrace_ret='long'))
 496 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 497   [Define as the return type of ptrace.])
 498 # Check argument types.
 499 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 500 for gdb_arg1 in 'int' 'long'; do
 501  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 502   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 503    for gdb_arg4 in 'int' 'long'; do
 504      AC_TRY_COMPILE($gdb_ptrace_headers, [
 505 extern $gdb_cv_func_ptrace_ret
 506   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 507 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 508     break 4;])
 509     for gdb_arg5 in 'int *' 'int' 'long'; do
 510      AC_TRY_COMPILE($gdb_ptrace_headers, [
 511 extern $gdb_cv_func_ptrace_ret
 512   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 513 ], [
 514 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 515     break 5;])
 516     done
 517    done
 518   done
 519  done
 520 done
 521 # Provide a safe default value.
 522 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 523 ])
 524 ac_save_IFS=$IFS; IFS=','
 525 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 526 IFS=$ac_save_IFS
 527 shift
 528 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 529   [Define to the type of arg 3 for ptrace.])
 530 if test -n "$[5]"; then
 531   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 532     [Define to the type of arg 5 for ptrace.])
 533 fi
 534
 535 dnl AC_FUNC_SETPGRP does not work when cross compiling
 536 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 537 if test "$cross_compiling" = no; then
 538   AC_FUNC_SETPGRP
 539 else
 540   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 541     [AC_TRY_COMPILE([
 542 #include <unistd.h>
 543 ], [
 544   if (setpgrp(1,1) == -1)
 545     exit (0);
 546   else
 547     exit (1);
 548 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 549 if test $ac_cv_func_setpgrp_void = yes; then
 550   AC_DEFINE(SETPGRP_VOID, 1)
 551 fi
 552 fi
 553
 554 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 555 # since sigsetjmp might only be defined as a macro.
 556 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 557 [AC_TRY_COMPILE([
 558 #include <setjmp.h>
 559 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 560 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 561 if test $gdb_cv_func_sigsetjmp = yes; then
 562   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 563 fi
 564
 565 # Assume we'll default to using the included libiberty regex.
 566 gdb_use_included_regex=yes
 567
 568 # However, if the system regex is GNU regex, then default to *not*
 569 # using the included regex.
 570 AC_CACHE_CHECK(
 571   [for GNU regex],
 572   [gdb_cv_have_gnu_regex],
 573   [AC_TRY_COMPILE(
 574     [#include <gnu-versions.h>],
 575     [#define REGEX_INTERFACE_VERSION 1
 576 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 577 # error "Version mismatch"
 578 #endif],
 579     gdb_cv_have_gnu_regex=yes,
 580     gdb_cv_have_gnu_regex=no)])
 581 if test $gdb_cv_have_gnu_regex = yes; then
 582   gdb_use_included_regex=no
 583 fi
 584
 585 AC_ARG_WITH(included-regex,
 586   [  --without-included-regex don't use included regex; this is the default
 587                           on systems with version 2 of the GNU C library
 588                           (use with caution on other system)],
 589   gdb_with_regex=$withval,
 590   gdb_with_regex=$gdb_use_included_regex)
 591 if test "$gdb_with_regex" = yes; then
 592   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 593     [Define to 1 if the regex included in libiberty should be used.])
 594 fi
 595
 596 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 597 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 598 [#include <sys/param.h>
 599 #include <sys/proc.h>
 600 ])
 601
 602 # See if <sys/lwp.h> defines `struct lwp`.
 603 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 604 [AC_TRY_COMPILE([#include <sys/param.h>
 605 #include <sys/lwp.h>], [struct lwp l;],
 606 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 607 if test $gdb_cv_struct_lwp = yes; then
 608   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 609             [Define to 1 if your system has struct lwp.])
 610 fi
 611
 612 # See if <machine/reg.h> degines `struct reg'.
 613 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 614 [AC_TRY_COMPILE([#include <sys/types.h>
 615 #include <machine/reg.h>], [struct reg r;],
 616 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 617 if test $gdb_cv_struct_reg = yes; then
 618   AC_DEFINE(HAVE_STRUCT_REG, 1,
 619             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 620 fi
 621
 622 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 623 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 624 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 625                  [#include <machine/reg.h>])
 626
 627 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 628 AC_MSG_CHECKING(for PTRACE_GETREGS)
 629 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 630 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 631                 [PTRACE_GETREGS;],
 632                 [gdb_cv_have_ptrace_getregs=yes],
 633                 [gdb_cv_have_ptrace_getregs=no])])
 634 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 635 if test $gdb_cv_have_ptrace_getregs = yes; then
 636   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 637   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 638 fi
 639
 640 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 641 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 642 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 643 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 644                 [PTRACE_GETFPXREGS;],
 645                 [gdb_cv_have_ptrace_getfpxregs=yes],
 646                 [gdb_cv_have_ptrace_getfpxregs=no])])
 647 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 648 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 649   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 650   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 651 fi
 652
 653 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 654 AC_MSG_CHECKING(for PT_GETDBREGS)
 655 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 656 [AC_TRY_COMPILE([#include <sys/types.h>
 657 #include <sys/ptrace.h>],
 658                 [PT_GETDBREGS;],
 659                 [gdb_cv_have_pt_getdbregs=yes],
 660                 [gdb_cv_have_pt_getdbregs=no])])
 661 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 662 if test $gdb_cv_have_pt_getdbregs = yes; then
 663   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 664   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 665 fi
 666
 667 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 668 AC_MSG_CHECKING(for PT_GETXMMREGS)
 669 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 670 [AC_TRY_COMPILE([#include <sys/types.h>
 671 #include <sys/ptrace.h>],
 672                 [PT_GETXMMREGS;],
 673                 [gdb_cv_have_pt_getxmmregs=yes],
 674                 [gdb_cv_have_pt_getxmmregs=no])])
 675 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 676 if test $gdb_cv_have_pt_getxmmregs = yes; then
 677   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 678   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 679 fi
 680
 681 # If we are configured native on GNU/Linux, work around problems with
 682 # sys/procfs.h
 683 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 684
 685 if test "${target}" = "${host}"; then
 686   case "${host}" in
 687   i[[3456]]86-*-linux*)
 688         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED, 2,
 689         [Define on a GNU/Linux system to work around problems in sys/procfs.h.])
 690         AC_DEFINE(sys_quotactl, 1,
 691         [Define on a GNU/Linux system to work around problems in sys/procfs.h.])
 692         ;;
 693   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 694       AC_DEFINE(NEW_PROC_API, 1,
 695       [Define if you want to use new multi-fd /proc interface
 696        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 697       ;;
 698   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 699       AC_DEFINE(NEW_PROC_API, 1,
 700       [Define if you want to use new multi-fd /proc interface
 701        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 702       ;;
 703   mips-sgi-irix5*)
 704       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 705       AC_DEFINE([_KMEMUSER], 1,
 706       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 707        around a <sys/proc.h> problem on IRIX 5.])
 708       ;;
 709   esac
 710 fi
 711
 712 if test "$ac_cv_header_sys_procfs_h" = yes; then
 713   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 714   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 715   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 716   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 717   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 718   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 719   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 720   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 721   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 722   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 723   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 724   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 725   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 726   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 727
 728
 729   dnl Check for broken prfpregset_t type
 730
 731   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 732   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 733   dnl instead of the struct itself).  We detect this here, and work
 734   dnl around it in gdb_proc_service.h.
 735
 736   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 737     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 738     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 739       [AC_TRY_RUN([#include <sys/procfs.h>
 740        int main ()
 741        {
 742          if (sizeof (prfpregset_t) == sizeof (void *))
 743            return 1;
 744          return 0;
 745        }],
 746        gdb_cv_prfpregset_t_broken=no,
 747        gdb_cv_prfpregset_t_broken=yes,
 748        gdb_cv_prfpregset_t_broken=yes)])
 749     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 750     if test $gdb_cv_prfpregset_t_broken = yes; then
 751       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
 752       [Define if the prfpregset_t type is broken.])
 753     fi
 754   fi
 755
 756   dnl Check for PIOCSET ioctl entry
 757
 758   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 759   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 760   [AC_TRY_COMPILE([#include <unistd.h>
 761 #include <sys/types.h>
 762 #include <sys/procfs.h>
 763 ], [
 764     int dummy;;
 765     dummy = ioctl(0, PIOCSET, &dummy);
 766   ],
 767   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 768   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 769   if test $gdb_cv_have_procfs_piocset = yes; then
 770     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
 771     [Define if ioctl argument PIOCSET is available.])
 772   fi
 773 fi
 774
 775 dnl For native ports (host == target), check to see what kind of
 776 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 777 if test ${host} = ${target} ; then
 778   dnl Check for struct link_map with l_ members which are indicative
 779   dnl of SVR4-like shared libraries
 780
 781   AC_MSG_CHECKING(for member l_addr in struct link_map)
 782   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 783     [AC_TRY_COMPILE([#include <link.h>],
 784                     [struct link_map lm; (void) lm.l_addr;],
 785                     gdb_cv_have_struct_link_map_with_l_members=yes,
 786                     gdb_cv_have_struct_link_map_with_l_members=no)])
 787   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 788   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 789     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
 790     [Define if <link.h> exists and defines struct link_map which has
 791      members with an ``l_'' prefix.  (For Solaris, SVR4, and
 792      SVR4-like systems.)])
 793   fi
 794
 795   dnl Check for struct link_map with lm_ members which are indicative
 796   dnl of SunOS-like shared libraries
 797
 798   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 799   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 800     [AC_TRY_COMPILE([#include <sys/types.h>
 801 #include <link.h>],
 802                     [struct link_map lm; (void) lm.lm_addr;],
 803                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 804                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 805   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 806   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 807     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
 808     [Define if <link.h> exists and defines struct link_map which has
 809      members with an ``lm_'' prefix.  (For SunOS.)])
 810   fi
 811
 812   dnl Check for struct so_map with som_ members which are found on
 813   dnl some *BSD systems.
 814
 815   AC_MSG_CHECKING(for member som_addr in struct so_map)
 816   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 817     [AC_TRY_COMPILE([#include <sys/types.h>
 818 #ifdef HAVE_NLIST_H
 819 #include <nlist.h>
 820 #endif
 821 #include <link.h>],
 822                     [struct so_map lm; (void) lm.som_addr;],
 823                     gdb_cv_have_struct_so_map_with_som_members=yes,
 824                     gdb_cv_have_struct_so_map_with_som_members=no)])
 825   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 826   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 827     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
 828     [Define if <link.h> exists and defines a struct so_map which has
 829      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
 830   fi
 831
 832   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 833   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 834
 835   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 836   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 837     [AC_TRY_COMPILE([#define _SYSCALL32
 838 #include <sys/link.h>], [struct link_map32 l;],
 839      gdb_cv_have_struct_link_map32=yes,
 840      gdb_cv_have_struct_link_map32=no)])
 841   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 842   if test $gdb_cv_have_struct_link_map32 = yes; then
 843     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
 844     [Define if <sys/link.h> has struct link_map32])
 845     AC_DEFINE(_SYSCALL32, 1,
 846     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
 847   fi
 848 fi
 849
 850 # Check if the compiler supports the `long long' type.
 851
 852 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 853                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 854 [[extern long long foo;]],
 855 [[switch (foo & 2) { case 0: return 1; }]])],
 856                                   gdb_cv_c_long_long=yes,
 857                                   gdb_cv_c_long_long=no)])
 858 if test $gdb_cv_c_long_long = yes; then
 859   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 860             [Define to 1 if the compiler supports long long.])
 861 fi
 862
 863 # Check if the compiler and runtime support printing long longs.
 864
 865 AC_CACHE_CHECK([for long long support in printf],
 866                gdb_cv_printf_has_long_long,
 867                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 868 [[char buf[32];
 869   long long l = 0;
 870   l = (l << 16) + 0x0123;
 871   l = (l << 16) + 0x4567;
 872   l = (l << 16) + 0x89ab;
 873   l = (l << 16) + 0xcdef;
 874   sprintf (buf, "0x%016llx", l);
 875   return (strcmp ("0x0123456789abcdef", buf));]])],
 876                               gdb_cv_printf_has_long_long=yes,
 877                               gdb_cv_printf_has_long_long=no,
 878                               gdb_cv_printf_has_long_long=no)])
 879 if test $gdb_cv_printf_has_long_long = yes; then
 880   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 881             [Define to 1 if the "%ll" format works to print long longs.])
 882 fi
 883
 884 # Check if the compiler supports the `long double' type.  We can't use
 885 # AC_C_LONG_DOUBLE because that one does additional checks on the
 886 # constants defined in <float.h> that fail on some systems,
 887 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 888
 889 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 890                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 891                                   gdb_cv_c_long_double=yes,
 892                                   gdb_cv_c_long_double=no)])
 893 if test $gdb_cv_c_long_double = yes; then
 894   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 895            [Define to 1 if the compiler supports long double.])
 896 fi
 897
 898 # Check if the compiler and runtime support printing long doubles.
 899
 900 AC_CACHE_CHECK([for long double support in printf],
 901                gdb_cv_printf_has_long_double,
 902                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 903 [[char buf[16];
 904   long double f = 3.141592653;
 905   sprintf (buf, "%Lg", f);
 906   return (strncmp ("3.14159", buf, 7));]])],
 907                               gdb_cv_printf_has_long_double=yes,
 908                               gdb_cv_printf_has_long_double=no,
 909                               gdb_cv_printf_has_long_double=no)])
 910 if test $gdb_cv_printf_has_long_double = yes; then
 911   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 912             [Define to 1 if the "%Lg" format works to print long doubles.])
 913 fi
 914
 915 # Check if the compiler and runtime support scanning long doubles.
 916
 917 AC_CACHE_CHECK([for long double support in scanf],
 918                gdb_cv_scanf_has_long_double,
 919                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 920 [[#include <stdio.h>]],
 921 [[char *buf = "3.141592653";
 922   long double f = 0;
 923   sscanf (buf, "%Lg", &f);
 924   return !(f > 3.14159 && f < 3.14160);]])],
 925                               gdb_cv_scanf_has_long_double=yes,
 926                               gdb_cv_scanf_has_long_double=no,
 927                               gdb_cv_scanf_has_long_double=no)])
 928 if test $gdb_cv_scanf_has_long_double = yes; then
 929   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 930             [Define to 1 if the "%Lg" format works to scan long doubles.])
 931 fi
 932
 933 case ${host_os} in
 934 aix*)
 935   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 936     SAVE_LDFLAGS=$LDFLAGS
 937
 938     case $GCC in
 939     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 940     *) gdb_cv_bigtoc=-bbigtoc ;;
 941     esac
 942
 943     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 944     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 945     LDFLAGS="${SAVE_LDFLAGS}"
 946   ])
 947   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 948   ;;
 949 esac
 950
 951
 952 dnl For certain native configurations, we need to check whether thread
 953 dnl support can be built in or not.
 954 dnl
 955 dnl Note that we only want this if we are both native (host == target),
 956 dnl and not doing a canadian cross build (build == host).
 957
 958 if test ${build} = ${host} -a ${host} = ${target} ; then
 959    case ${host_os} in
 960    hpux*)
 961       AC_MSG_CHECKING(for HPUX/OSF thread support)
 962       if test -f /usr/include/dce/cma_config.h ; then
 963          if test "$GCC" = "yes" ; then
 964             AC_MSG_RESULT(yes)
 965             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
 966             [Define if you have HPUX threads])
 967             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 968             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 969          else
 970             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 971          fi
 972       else
 973          AC_MSG_RESULT(no)
 974       fi
 975       ;;
 976    solaris*)
 977       # See if thread_db library is around for Solaris thread debugging.
 978       # Note that we must explicitly test for version 1 of the library
 979       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 980       # the same API.
 981       AC_MSG_CHECKING(for Solaris thread debugging library)
 982       if test -f /usr/lib/libthread_db.so.1 ; then
 983          AC_MSG_RESULT(yes)
 984          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
 985          [Define if using Solaris thread debugging.])
 986          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 987          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 988          AC_CHECK_LIB(dl, dlopen)
 989          if test "$GCC" = "yes" ; then
 990             # The GNU linker requires the -export-dynamic option to make
 991             # all symbols visible in the dynamic symbol table.
 992             hold_ldflags=$LDFLAGS
 993             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 994             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 995             AC_TRY_LINK(, [int i;], found=yes, found=no)
 996             LDFLAGS=$hold_ldflags
 997             AC_MSG_RESULT($found)
 998             if test $found = yes; then
 999                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1000             fi
1001          fi
1002          # Sun randomly tweaked the prototypes in <proc_service.h>
1003          # at one point.
1004          AC_MSG_CHECKING(if <proc_service.h> is old)
1005          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1006             AC_TRY_COMPILE([
1007                 #include <proc_service.h>
1008                 ps_err_e ps_pdwrite
1009                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1010             ],, gdb_cv_proc_service_is_old=no,
1011                 gdb_cv_proc_service_is_old=yes)
1012          ])
1013          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1014          if test $gdb_cv_proc_service_is_old = yes; then
1015             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1016             [Define if <proc_service.h> on solaris uses int instead of
1017              size_t, and assorted other type changes.])
1018          fi
1019       else
1020          AC_MSG_RESULT(no)
1021       fi
1022       ;;
1023    aix*)
1024       AC_MSG_CHECKING(for AiX thread debugging library)
1025       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1026                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1027                                    [#ifndef PTHDB_VERSION_3
1028                                     #error
1029                                     #endif],
1030                                    gdb_cv_have_aix_thread_debug=yes,
1031                                    gdb_cv_have_aix_thread_debug=no)])
1032       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1033       if test $gdb_cv_have_aix_thread_debug = yes; then
1034          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1035          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1036          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1037       fi
1038       ;;
1039    esac
1040    AC_SUBST(CONFIG_LDFLAGS)
1041 fi
1042
1043 dnl See if we have a thread_db header file that has TD_NOTALLOC.
1044 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1045    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1046                   gdb_cv_thread_db_h_has_td_notalloc,
1047      AC_TRY_COMPILE(
1048        [#include <thread_db.h>],
1049        [int i = TD_NOTALLOC;],
1050        gdb_cv_thread_db_h_has_td_notalloc=yes,
1051        gdb_cv_thread_db_h_has_td_notalloc=no
1052      )
1053    )
1054 fi
1055 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1056   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1057             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1058 fi
1059
1060 dnl See if we have a sys/syscall header file that has __NR_tkill.
1061 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1062    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1063                   gdb_cv_sys_syscall_h_has_tkill,
1064      AC_TRY_COMPILE(
1065        [#include <sys/syscall.h>],
1066        [int i = __NR_tkill;],
1067        gdb_cv_sys_syscall_h_has_tkill=yes,
1068        gdb_cv_sys_syscall_h_has_tkill=no
1069      )
1070    )
1071 fi
1072 dnl See if we can issue tkill syscall.
1073 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1074   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1075 fi
1076
1077 dnl Handle optional features that can be enabled.
1078
1079 AC_ARG_WITH(sysroot,
1080 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1081 [
1082  case ${with_sysroot} in
1083  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1084  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1085  esac
1086
1087  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1088
1089  if test "x$exec_prefix" = xNONE; then
1090   if test "x$prefix" = xNONE; then
1091    test_prefix=/usr/local
1092   else
1093    test_prefix=$prefix
1094   fi
1095  else
1096   test_prefix=$exec_prefix
1097  fi
1098  case ${TARGET_SYSTEM_ROOT} in
1099  "${test_prefix}"|"${test_prefix}/"*|\
1100  '${exec_prefix}'|'${exec_prefix}/'*)
1101    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1102    TARGET_SYSTEM_ROOT_DEFINE="$t"
1103    ;;
1104  esac
1105 ], [
1106  TARGET_SYSTEM_ROOT=
1107  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1108 ])
1109 AC_SUBST(TARGET_SYSTEM_ROOT)
1110 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1111
1112 # NOTE: Don't add -Wall or -Wunused, they both include
1113 # -Wunused-parameter which reports bogus warnings.
1114 # NOTE: If you add to this list, remember to update
1115 # gdb/doc/gdbint.texinfo.
1116 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1117 -Wformat -Wparentheses -Wpointer-arith -Wformat-nonliteral \
1118 -Wunused-label -Wunused-function"
1119
1120 # GCC supports -Wuninitialized only with -O or -On, n != 0.
1121 if test x${CFLAGS+set} = xset; then
1122   case "${CFLAGS}" in
1123     *"-O0"* ) ;;
1124     *"-O"* )
1125       build_warnings="${build_warnings} -Wuninitialized"
1126     ;;
1127   esac
1128 else
1129   build_warnings="${build_warnings} -Wuninitialized"
1130 fi
1131
1132 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1133 # -Wunused-function -Wunused-variable -Wunused-value
1134 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1135 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1136 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1137 # -Woverloaded-virtual -Winline -Werror"
1138 AC_ARG_ENABLE(build-warnings,
1139 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1140 [case "${enableval}" in
1141   yes)  ;;
1142   no)   build_warnings="-w";;
1143   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1144         build_warnings="${build_warnings} ${t}";;
1145   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1146         build_warnings="${t} ${build_warnings}";;
1147   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1148 esac
1149 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1150   echo "Setting compiler warning flags = $build_warnings" 6>&1
1151 fi])dnl
1152 AC_ARG_ENABLE(gdb-build-warnings,
1153 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1154 [case "${enableval}" in
1155   yes)  ;;
1156   no)   build_warnings="-w";;
1157   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1158         build_warnings="${build_warnings} ${t}";;
1159   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1160         build_warnings="${t} ${build_warnings}";;
1161   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1162 esac
1163 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1164   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1165 fi])dnl
1166 WARN_CFLAGS=""
1167 WERROR_CFLAGS=""
1168 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1169 then
1170     AC_MSG_CHECKING(compiler warning flags)
1171     # Separate out the -Werror flag as some files just cannot be
1172     # compiled with it enabled.
1173     for w in ${build_warnings}; do
1174         case $w in
1175         -Werr*) WERROR_CFLAGS=-Werror ;;
1176         *) # Check that GCC accepts it
1177             saved_CFLAGS="$CFLAGS"
1178             CFLAGS="$CFLAGS $w"
1179             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1180             CFLAGS="$saved_CFLAGS"
1181         esac
1182     done
1183     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1184 fi
1185 AC_SUBST(WARN_CFLAGS)
1186 AC_SUBST(WERROR_CFLAGS)
1187
1188 # In the Cygwin environment, we need some additional flags.
1189 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1190 [AC_EGREP_CPP(lose, [
1191 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1192 lose
1193 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1194
1195
1196 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1197 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1198 case ${host} in
1199   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1200   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1201   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o" ;;
1202 esac
1203 AC_SUBST(SER_HARDWIRE)
1204
1205 # libreadline needs libuser32.a in a cygwin environment
1206 WIN32LIBS=
1207 if test x$gdb_cv_os_cygwin = xyes; then
1208     WIN32LIBS="-luser32"
1209     case "${target}" in
1210         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1211         ;;
1212     esac
1213 fi
1214
1215 # The ser-tcp.c module requires sockets.
1216 case ${host} in
1217   *mingw32*)
1218     AC_DEFINE(USE_WIN32API, 1,
1219               [Define if we should use the Windows API, instead of the
1220                POSIX API.  On Windows, we use the Windows API when
1221                building for MinGW, but the POSIX API when building
1222                for Cygwin.])
1223     WIN32LIBS="$WIN32LIBS -lws2_32"
1224     ;;
1225 esac
1226 AC_SUBST(WIN32LIBS)
1227
1228 LIBGUI="../libgui/src/libgui.a"
1229 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1230 AC_SUBST(LIBGUI)
1231 AC_SUBST(GUI_CFLAGS_X)
1232
1233 WIN32LDAPP=
1234 AC_SUBST(WIN32LIBS)
1235 AC_SUBST(WIN32LDAPP)
1236
1237 case "${host}" in
1238 *-*-cygwin*)
1239     configdir="win"
1240     ;;
1241 *)
1242     configdir="unix"
1243     ;;
1244 esac
1245
1246 GDBTKLIBS=
1247 if test "${enable_gdbtk}" = "yes"; then
1248
1249     # Gdbtk must have an absolute path to srcdir in order to run
1250     # properly when not installed.
1251     here=`pwd`
1252     cd ${srcdir}
1253     GDBTK_SRC_DIR=`pwd`
1254     cd $here
1255
1256     CY_AC_PATH_TCLCONFIG
1257     if test -z "${no_tcl}"; then
1258         CY_AC_LOAD_TCLCONFIG
1259         CY_AC_PATH_TKCONFIG
1260
1261         # now look for Tcl library stuff
1262
1263         tcldir="../tcl/${configdir}/"
1264
1265         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1266
1267         # If $no_tk is nonempty, then we can't do Tk, and there is no
1268         # point to doing Tcl.
1269         if test -z "${no_tk}"; then
1270            CY_AC_LOAD_TKCONFIG
1271            CY_AC_PATH_TCLH
1272            CY_AC_PATH_TKH
1273            CY_AC_PATH_ITCLH
1274            CY_AC_PATH_ITKH
1275
1276
1277            # now look for Tk library stuff
1278
1279            tkdir="../tk/${configdir}/"
1280
1281            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1282
1283            # now look for Itcl library stuff
1284
1285            CY_AC_PATH_ITCLCONFIG
1286            if test -z "${no_itcl}"; then
1287              CY_AC_LOAD_ITCLCONFIG
1288
1289              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1290              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1291            fi
1292
1293
1294            # now look for Itk library stuff
1295            CY_AC_PATH_ITKCONFIG
1296            if test -z "${no_itcl}"; then
1297              CY_AC_LOAD_ITKCONFIG
1298
1299              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1300              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1301            fi
1302
1303            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1304
1305            # Include some libraries that Tcl and Tk want.
1306            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1307            # Yes, the ordering seems wrong here.  But it isn't.
1308            # TK_LIBS is the list of libraries that need to be linked
1309            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1310            # were in LIBS then any link tests after this point would
1311            # try to include things like `$(LIBGUI)', which wouldn't work.
1312            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1313
1314            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1315            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1316            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1317            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1318            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1319            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1320            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1321
1322            if test x$gdb_cv_os_cygwin = xyes; then
1323               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1324               WIN32LDAPP="-Wl,--subsystem,console"
1325               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1326            fi
1327         fi
1328     fi
1329
1330     AC_CONFIG_SUBDIRS(gdbtk)
1331 fi
1332
1333 AC_SUBST(X_CFLAGS)
1334 AC_SUBST(X_LDFLAGS)
1335 AC_SUBST(X_LIBS)
1336 AC_SUBST(TCL_DEPS)
1337 AC_SUBST(TK_DEPS)
1338 AC_SUBST(ITCLLIB)
1339 AC_SUBST(ITCL_DEPS)
1340 AC_SUBST(ITKLIB)
1341 AC_SUBST(ITK_DEPS)
1342 AC_SUBST(GDBTKLIBS)
1343 AC_SUBST(GDBTK_CFLAGS)
1344 AC_SUBST(GDBTK_SRC_DIR)
1345
1346 AC_PATH_X
1347
1348 # Check whether we should enable the TUI, but only do so if we really
1349 # can.
1350 if test x"$enable_tui" = xyes; then
1351   if test -d $srcdir/tui; then
1352     if test "$ac_cv_search_waddstr" != no; then
1353       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1354       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1355       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1356       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1357       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1358       CONFIG_ALL="${CONFIG_ALL} all-tui"
1359       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1360       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1361       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1362     else
1363       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1364     fi
1365   fi
1366 fi
1367
1368 # Unlike the sim directory, whether a simulator is linked is controlled by
1369 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1370 # This code just checks for a few cases where we'd like to ignore those
1371 # definitions, even when they're present in the '.mt' file.  These cases
1372 # are when --disable-sim is specified, or if the simulator directory is
1373 # not part of the source tree.
1374 #
1375 AC_ARG_ENABLE(sim,
1376 [  --enable-sim            Link gdb with simulator],
1377 [echo "enable_sim = $enable_sim";
1378  echo "enableval = ${enableval}";
1379  case "${enableval}" in
1380   yes) ignore_sim=false ;;
1381   no)  ignore_sim=true ;;
1382   *)   ignore_sim=false ;;
1383  esac],
1384 [ignore_sim=false])
1385
1386 if test ! -d "${srcdir}/../sim"; then
1387   ignore_sim=true
1388 fi
1389
1390 if test "${ignore_sim}" = "true"; then
1391     IGNORE_SIM="SIM="
1392     IGNORE_SIM_OBS="SIM_OBS="
1393 else
1394     IGNORE_SIM=""
1395     IGNORE_SIM_OBS=""
1396     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1397 fi
1398 AC_SUBST(IGNORE_SIM)
1399 AC_SUBST(IGNORE_SIM_OBS)
1400
1401 AC_SUBST(ENABLE_CFLAGS)
1402 AC_SUBST(PROFILE_CFLAGS)
1403
1404 AC_SUBST(CONFIG_OBS)
1405 AC_SUBST(CONFIG_DEPS)
1406 AC_SUBST(CONFIG_SRCS)
1407 AC_SUBST(CONFIG_ALL)
1408 AC_SUBST(CONFIG_CLEAN)
1409 AC_SUBST(CONFIG_INSTALL)
1410 AC_SUBST(CONFIG_UNINSTALL)
1411
1412 # List of host floatformats.
1413 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1414 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1415 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1416
1417 # target_subdir is used by the testsuite to find the target libraries.
1418 target_subdir=
1419 if test "${host}" != "${target}"; then
1420     target_subdir="${target_alias}/"
1421 fi
1422 AC_SUBST(target_subdir)
1423
1424 frags=
1425 if test "${target}" = "${host}"; then
1426   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1427   if test ! -f ${host_makefile_frag}; then
1428     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1429   fi
1430   frags="$frags $host_makefile_frag"
1431 else
1432   host_makefile_frag=/dev/null
1433 fi
1434
1435 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1436 if test ! -f ${target_makefile_frag}; then
1437   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1438 fi
1439 frags="$frags $target_makefile_frag"
1440
1441 AC_SUBST_FILE(host_makefile_frag)
1442 AC_SUBST_FILE(target_makefile_frag)
1443 AC_SUBST(frags)
1444
1445 changequote(,)dnl
1446 hostfile=`sed -n '
1447 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1448 ' ${host_makefile_frag}`
1449
1450 targetfile=`sed -n '
1451 s/DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1452 ' ${target_makefile_frag}`
1453
1454 if test "${target}" = "${host}"; then
1455 # We pick this up from the host configuration file (.mh) because we
1456 # do not have a native configuration Makefile fragment.
1457 nativefile=`sed -n '
1458 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1459 ' ${host_makefile_frag}`
1460 fi
1461 changequote([,])
1462
1463 if test x"${gdb_osabi}" != x ; then
1464     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1465                        [Define to the default OS ABI for this configuration.])
1466 fi
1467
1468 # Enable multi-ice-gdb-server.
1469 AC_ARG_ENABLE(multi-ice,
1470 [  --enable-multi-ice      build the multi-ice-gdb-server],
1471   [case $enableval in
1472     yes | no)
1473       ;;
1474     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1475   esac])
1476 if test "x$enable_multi_ice" = xyes; then
1477    AC_CONFIG_SUBDIRS(multi-ice)
1478 fi
1479
1480 # We only build gdbserver automatically if host and target are the same.
1481 if test "x$target" = "x$host"; then
1482   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1483   if test "x$build_gdbserver" = xyes; then
1484     AC_MSG_RESULT(yes)
1485     AC_CONFIG_SUBDIRS(gdbserver)
1486   else
1487     AC_MSG_RESULT(no)
1488   fi
1489 fi
1490
1491 # We build rdi-share on ARM-based targets, as instructed by configure.tgt.
1492 if test "x$build_rdi_share" = xyes; then
1493    AC_CONFIG_SUBDIRS(rdi-share)
1494 fi
1495
1496 # We configure the nlm subdirectory on netware targets, as instructed
1497 # by configure.tgt.
1498 if test "x$build_nlm" = xyes; then
1499    AC_CONFIG_SUBDIRS(nlm)
1500 fi
1501
1502 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1503 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1504 # to an empty version.
1505
1506 files=
1507 links=
1508
1509 rm -f xm.h
1510 xm_h=""
1511 if test "${hostfile}" != ""; then
1512     xm_h=xm.h
1513     case "${hostfile}" in
1514       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1515       * ) GDB_XM_FILE="${hostfile}"
1516     esac
1517     files="${files} ${GDB_XM_FILE}"
1518     links="${links} xm.h"
1519     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}", [hostfile])
1520 fi
1521 AC_SUBST(xm_h)
1522
1523 rm -f tm.h
1524 tm_h=""
1525 if test "${targetfile}" != ""; then
1526     tm_h=tm.h
1527     case "${targetfile}" in
1528       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1529       * ) GDB_TM_FILE="${targetfile}"
1530     esac
1531     files="${files} ${GDB_TM_FILE}"
1532     links="${links} tm.h"
1533     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}", [targetfile])
1534 fi
1535 AC_SUBST(tm_h)
1536
1537 rm -f nm.h
1538 nm_h=""
1539 if test "${nativefile}" != ""; then
1540     nm_h=nm.h
1541     case "${nativefile}" in
1542       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1543       * ) GDB_NM_FILE="${nativefile}"
1544     esac
1545     files="${files} ${GDB_NM_FILE}"
1546     links="${links} nm.h"
1547     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1548 fi
1549 AC_SUBST(nm_h)
1550
1551 AC_LINK_FILES($files, $links)
1552
1553 dnl Check for exe extension set on certain hosts (e.g. Win32)
1554 AC_EXEEXT
1555
1556 dnl  Detect the character set used by this host.
1557
1558 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1559 dnl  superset of ASCII containing the characters needed for French,
1560 dnl  German, Spanish, Italian, and possibly others), but if were
1561 dnl  *were* to support any host character sets other than ISO-8859-1,
1562 dnl  here's where we'd detect it.
1563 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1564           [Define to be a string naming the default host character set.])
1565
1566 AM_ICONV
1567
1568 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1569 [
1570 dnl Autoconf doesn't provide a mechanism for modifying definitions
1571 dnl provided by makefile fragments.
1572 dnl
1573
1574 changequote(,)dnl
1575 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1576 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1577 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1578 mv -f Makefile.tmp Makefile
1579 changequote([,])dnl
1580
1581
1582 case x$CONFIG_HEADERS in
1583 xconfig.h:config.in)
1584 echo > stamp-h ;;
1585 esac
1586 ],
1587 [
1588 gdb_host_cpu=$gdb_host_cpu
1589 gdb_target_cpu=$gdb_target_cpu
1590 nativefile=$nativefile
1591 ])
1592
1593 exit 0