gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 dnl 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  91 # rely on it - libiberty is built before texinfo.
  92 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  93 if test "x$MAKEINFO" = "x"; then
  94   AC_ERROR([makeinfo is required for compilation])
  95 else
  96   case "$MAKEINFO" in
  97     */missing\ makeinfo*)
  98       AC_ERROR([makeinfo is required for compilation])
  99       ;;
 100   esac
 101 fi
 102 AC_SUBST(MAKEINFO)
 103
 104 # --split-size=5000000 may be already in $MAKEINFO from parent configure.
 105 # Re-running configure in gdb/ would lose it so ensure it stays present.
 106 MAKEINFOFLAGS=${MAKEINFOFLAGS---split-size=5000000}
 107 AC_SUBST(MAKEINFOFLAGS)
 108
 109 MAKEINFO_EXTRA_FLAGS=""
 110 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 111   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 112   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 113     gdb_cv_have_makeinfo_click=yes
 114   else
 115     gdb_cv_have_makeinfo_click=no
 116   fi])
 117 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 118   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 119 fi
 120 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 121
 122 # GDB does not use automake, but gnulib does.  This line lets us
 123 # generate its Makefile.in.
 124 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
 125
 126 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 127     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 128     [${libdir}/debug])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_CONFIG_SUBDIRS(testsuite)
 144
 145 # Check whether to support alternative target configurations
 146 AC_ARG_ENABLE(targets,
 147 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 148 [case "${enableval}" in
 149   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 150             ;;
 151   no)       enable_targets= ;;
 152   *)        enable_targets=$enableval ;;
 153 esac])
 154
 155 # Check whether to enable 64-bit support on 32-bit hosts
 156 AC_ARG_ENABLE(64-bit-bfd,
 157 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 158 [case "${enableval}" in
 159   yes)  want64=true  ;;
 160   no)   want64=false ;;
 161   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 162 esac],[want64=false])dnl
 163
 164 # Provide defaults for some variables set by the per-host and per-target
 165 # configuration.
 166 gdb_host_obs=posix-hdep.o
 167
 168 if test "${target}" = "${host}"; then
 169   gdb_native=yes
 170 else
 171   gdb_native=no
 172 fi
 173
 174 . $srcdir/configure.host
 175
 176 # Accumulate some settings from configure.tgt over all enabled targets
 177
 178 TARGET_OBS=
 179 all_targets=
 180
 181 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 182 do
 183   if test "$targ_alias" = "all"; then
 184     all_targets=true
 185   else
 186     # Canonicalize the secondary target names.
 187     result=`$ac_config_sub $targ_alias 2>/dev/null`
 188     if test -n "$result"; then
 189         targ=$result
 190     else
 191         targ=$targ_alias
 192     fi
 193
 194     . ${srcdir}/configure.tgt
 195
 196     AS_IF([test -z "${gdb_target_obs}"],
 197       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 198
 199     # Target-specific object files
 200     for i in ${gdb_target_obs}; do
 201         case " $TARGET_OBS " in
 202         *" ${i} "*) ;;
 203         *)
 204           TARGET_OBS="$TARGET_OBS ${i}"
 205           ;;
 206         esac
 207     done
 208
 209     # Check whether this target needs 64-bit CORE_ADDR
 210     if test x${want64} = xfalse; then
 211       . ${srcdir}/../bfd/config.bfd
 212     fi
 213   fi
 214 done
 215
 216 if test x${all_targets} = xtrue; then
 217
 218   # We want all 64-bit targets if we either:
 219   #  - run on a 64-bit host  or
 220   #  - already require 64-bit support for some other target  or
 221   #  - the --enable-64-bit-bfd option was supplied
 222   # Otherwise we only support all 32-bit targets.
 223   #
 224   # NOTE: This test must be in sync with the corresponding
 225   #       tests in BFD!
 226
 227   if test x${want64} = xfalse; then
 228     AC_CHECK_SIZEOF(long)
 229     if test "x${ac_cv_sizeof_long}" = "x8"; then
 230       want64=true
 231     fi
 232   fi
 233   if test x${want64} = xtrue; then
 234     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 235   else
 236     TARGET_OBS='$(ALL_TARGET_OBS)'
 237   fi
 238 fi
 239
 240 AC_SUBST(TARGET_OBS)
 241
 242 # For other settings, only the main target counts.
 243 gdb_sim=
 244 gdb_osabi=
 245 build_gdbserver=
 246 targ=$target; . ${srcdir}/configure.tgt
 247
 248 # Fetch the default architecture and default target vector from BFD.
 249 targ=$target; . $srcdir/../bfd/config.bfd
 250
 251 # We only want the first architecture, so strip off the others if
 252 # there is more than one.
 253 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 254
 255 if test "x$targ_archs" != x; then
 256   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 257     [Define to BFD's default architecture. ])
 258 fi
 259 if test "x$targ_defvec" != x; then
 260   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 261     [Define to BFD's default target vector. ])
 262 fi
 263
 264 # The CLI cannot be disabled yet, but may be in the future.
 265
 266 # Enable CLI.
 267 AC_ARG_ENABLE(gdbcli,
 268 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 269   [case $enableval in
 270     yes)
 271       ;;
 272     no)
 273       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 274     *)
 275       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 276   esac],
 277   [enable_gdbcli=yes])
 278 if test x"$enable_gdbcli" = xyes; then
 279   if test -d $srcdir/cli; then
 280     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 281     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 282     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 283     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 284   fi
 285 fi
 286
 287 # Enable MI.
 288 AC_ARG_ENABLE(gdbmi,
 289 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 290   [case $enableval in
 291     yes | no)
 292       ;;
 293     *)
 294       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 295   esac],
 296   [enable_gdbmi=yes])
 297 if test x"$enable_gdbmi" = xyes; then
 298   if test -d $srcdir/mi; then
 299     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 300     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 301     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 302     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 303   fi
 304 fi
 305
 306 # Enable TUI.
 307 AC_ARG_ENABLE(tui,
 308 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 309   [case $enableval in
 310     yes | no | auto)
 311       ;;
 312     *)
 313       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 314   esac],enable_tui=auto)
 315
 316 # Enable gdbtk.
 317 AC_ARG_ENABLE(gdbtk,
 318 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 319   [case $enableval in
 320     yes | no)
 321       ;;
 322     *)
 323       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 324   esac],
 325   [if test -d $srcdir/gdbtk; then
 326     enable_gdbtk=yes
 327   else
 328     enable_gdbtk=no
 329   fi])
 330 # We unconditionally disable gdbtk tests on selected platforms.
 331 case $host_os in
 332   go32* | windows*)
 333     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 334     enable_gdbtk=no ;;
 335 esac
 336
 337 # Libunwind support.
 338 AC_ARG_WITH(libunwind,
 339 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 340 [case "${withval}" in
 341   yes)  enable_libunwind=yes ;;
 342   no)   enable_libunwind=no ;;
 343   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 344 esac],[
 345   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 346   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 347     enable_libunwind=yes;
 348   fi
 349 ])
 350
 351 if test x"$enable_libunwind" = xyes; then
 352   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 353   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 354   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 355   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 356   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 357 fi
 358
 359 opt_curses=no
 360 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 361
 362 prefer_curses=no
 363 if test "$opt_curses" = "yes"; then
 364   prefer_curses=yes
 365 fi
 366
 367 # Profiling support.
 368 AC_ARG_ENABLE(profiling,
 369 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 370   [case $enableval in
 371     yes | no)
 372       ;;
 373     *)
 374       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 375   esac],
 376  [enable_profiling=no])
 377
 378 AC_CHECK_FUNCS(monstartup _mcleanup)
 379 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 380 [AC_TRY_LINK(
 381 [#include <stdlib.h>
 382 extern char _etext;
 383 ],
 384 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 385 if test $ac_cv_var__etext = yes; then
 386   AC_DEFINE(HAVE__ETEXT, 1,
 387             [Define to 1 if your system has the _etext variable. ])
 388 fi
 389 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 390 [AC_TRY_LINK(
 391 [#include <stdlib.h>
 392 extern char etext;
 393 ],
 394 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 395 if test $ac_cv_var_etext = yes; then
 396   AC_DEFINE(HAVE_ETEXT, 1,
 397             [Define to 1 if your system has the etext variable. ])
 398 fi
 399 if test "$enable_profiling" = yes ; then
 400   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 401     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 402   fi
 403   PROFILE_CFLAGS=-pg
 404   OLD_CFLAGS="$CFLAGS"
 405   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 406
 407   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 408     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 409      ac_cv_cc_supports_pg=no)])
 410
 411   if test $ac_cv_cc_supports_pg = no; then
 412     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 413   fi
 414
 415   CFLAGS="$OLD_CFLAGS"
 416 fi
 417
 418 ACX_PKGVERSION([GDB])
 419 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 420 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 421 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 422
 423 # --------------------- #
 424 # Checks for programs.  #
 425 # --------------------- #
 426
 427 AC_PROG_AWK
 428 AC_PROG_INSTALL
 429 AC_PROG_LN_S
 430 AC_PROG_RANLIB
 431 AC_PROG_YACC
 432
 433 AC_CHECK_TOOL(AR, ar)
 434 AC_CHECK_TOOL(DLLTOOL, dlltool)
 435 AC_CHECK_TOOL(WINDRES, windres)
 436
 437 # Needed for GNU/Hurd.
 438 AC_CHECK_TOOL(MIG, mig)
 439
 440 # ---------------------- #
 441 # Checks for libraries.  #
 442 # ---------------------- #
 443
 444 # We might need to link with -lm; most simulators need it.
 445 AC_CHECK_LIB(m, main)
 446
 447 # We need to link with -lw to get `wctype' on Solaris before Solaris
 448 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 449 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 450 # is known to have this problem).  Therefore we avoid libw if we can.
 451 AC_CHECK_FUNC(wctype, [],
 452   [AC_CHECK_LIB(w, wctype)])
 453
 454 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 455 AC_SEARCH_LIBS(gethostbyname, nsl)
 456
 457 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 458 AC_SEARCH_LIBS(socketpair, socket)
 459
 460 # Link in zlib if we can.  This allows us to read compressed debug sections.
 461 AM_ZLIB
 462
 463 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 464 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 465
 466 AM_ICONV
 467
 468 # GDB may fork/exec the iconv program to get the list of supported character
 469 # sets.  Allow the user to specify where to find it.
 470 # There are several factors affecting the choice of option name:
 471 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 472 #   the build-time location of libiconv files.
 473 # - The program we need to find is iconv, which comes with glibc.  The user
 474 #   doesn't necessarily have libiconv installed.  Therefore naming this
 475 #   --with-libiconv-foo feels wrong.
 476 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 477 #   defined to work on directories not files (though it really doesn't know
 478 #   the difference).
 479 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 480 #   with --with-libiconv-prefix.
 481 # Putting these together is why the option name is --with-iconv-bin.
 482
 483 AC_ARG_WITH(iconv-bin,
 484 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 485 [iconv_bin="${withval}"
 486  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 487                     [Path of directory of iconv program.])
 488  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 489 ])
 490
 491 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 492 # There is a very specific comment in /usr/include/curses.h explaining that
 493 # termcap routines built into libcurses must not be used.
 494 #
 495 # The symptoms we observed so far is GDB unexpectedly changing
 496 # the terminal settings when tgetent is called - this is particularly
 497 # visible as the output is missing carriage returns, and so rapidly
 498 # becomes very hard to read.
 499 #
 500 # The readline configure script has already decided that libtermcap
 501 # was enough for its purposes, and so decided to build readline using
 502 # libtermcap.  Since the TUI mode requires curses, building GDB with
 503 # TUI enabled results in both libraries to be used at the same time,
 504 # which is not allowed.  This basically means that GDB with TUI is
 505 # broken on alpha-osf.
 506
 507 case $host_os in
 508   osf* )
 509     if test x"$enable_tui" = xyes; then
 510       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 511     fi
 512     if test x"$enable_tui" = xauto; then
 513       enable_tui=no
 514     fi
 515     ;;
 516 esac
 517
 518 # For the TUI, we need enhanced curses functionality.
 519 if test x"$enable_tui" != xno; then
 520   prefer_curses=yes
 521 fi
 522
 523 curses_found=no
 524 if test x"$prefer_curses" = xyes; then
 525   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 526   # curses library because the latter might not provide all the
 527   # functionality we need.  However, this leads to problems on systems
 528   # where the linker searches /usr/local/lib, but the compiler doesn't
 529   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 530   # default installation of ncurses on alpha*-dec-osf* will lead to such
 531   # a situation.
 532   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 533
 534   if test "$ac_cv_search_waddstr" != no; then
 535     curses_found=yes
 536   fi
 537 fi
 538
 539 # Check whether we should enable the TUI, but only do so if we really
 540 # can.
 541 if test x"$enable_tui" != xno; then
 542   if test -d $srcdir/tui; then
 543     if test "$curses_found" != no; then
 544       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 545       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 546       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 547       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 548       CONFIG_ALL="${CONFIG_ALL} all-tui"
 549       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 550       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 551       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 552     else
 553       if test x"$enable_tui" = xyes; then
 554         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 555       else
 556         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 557       fi
 558     fi
 559   fi
 560 fi
 561
 562 # Since GDB uses Readline, we need termcap functionality.  In many
 563 # cases this will be provided by the curses library, but some systems
 564 # have a seperate termcap library, or no curses library at all.
 565
 566 case $host_os in
 567   cygwin*)
 568     if test -d $srcdir/libtermcap; then
 569       LIBS="../libtermcap/libtermcap.a $LIBS"
 570       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 571     fi ;;
 572   go32* | *djgpp*)
 573     ac_cv_search_tgetent="none required"
 574     ;;
 575   *mingw32*)
 576     ac_cv_search_tgetent="none required"
 577     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 578     ;;
 579 esac
 580
 581 # These are the libraries checked by Readline.
 582 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 583
 584 if test "$ac_cv_search_tgetent" = no; then
 585   AC_MSG_ERROR([no termcap library found])
 586 fi
 587
 588 AC_ARG_WITH([system-readline],
 589   [AS_HELP_STRING([--with-system-readline],
 590                   [use installed readline library])])
 591
 592 if test "$with_system_readline" = yes; then
 593   READLINE=-lreadline
 594   READLINE_DEPS=
 595   READLINE_CFLAGS=
 596   READLINE_TEXI_INCFLAG=
 597 else
 598   READLINE='$(READLINE_DIR)/libreadline.a'
 599   READLINE_DEPS='$(READLINE)'
 600   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 601   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 602 fi
 603 AC_SUBST(READLINE)
 604 AC_SUBST(READLINE_DEPS)
 605 AC_SUBST(READLINE_CFLAGS)
 606 AC_SUBST(READLINE_TEXI_INCFLAG)
 607
 608 # Generate jit-reader.h
 609
 610 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 611 TARGET_PTR=
 612
 613 AC_CHECK_SIZEOF(unsigned long long)
 614 AC_CHECK_SIZEOF(unsigned long)
 615 AC_CHECK_SIZEOF(unsigned __int128)
 616
 617 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 618   TARGET_PTR="unsigned long"
 619 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 620   TARGET_PTR="unsigned long long"
 621 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 622   TARGET_PTR="unsigned __int128"
 623 else
 624   TARGET_PTR="unsigned long"
 625 fi
 626
 627 AC_SUBST(TARGET_PTR)
 628 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 629
 630 AC_SEARCH_LIBS(dlopen, dl)
 631
 632 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 633                 [directory to load the JIT readers from],
 634                 [${libdir}/gdb])
 635
 636 AC_ARG_WITH(expat,
 637   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 638   [], [with_expat=auto])
 639 AC_MSG_CHECKING([whether to use expat])
 640 AC_MSG_RESULT([$with_expat])
 641
 642 if test "${with_expat}" = no; then
 643   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 644   HAVE_LIBEXPAT=no
 645 else
 646   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 647                         [XML_Parser p = XML_ParserCreate (0);])
 648   if test "$HAVE_LIBEXPAT" != yes; then
 649     if test "$with_expat" = yes; then
 650       AC_MSG_ERROR([expat is missing or unusable])
 651     else
 652       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 653     fi
 654   else
 655     save_LIBS=$LIBS
 656     LIBS="$LIBS $LIBEXPAT"
 657     AC_CHECK_FUNCS(XML_StopParser)
 658     LIBS=$save_LIBS
 659   fi
 660 fi
 661
 662 dnl Utility to simplify finding libpython.
 663 dnl $1 = pythonX.Y
 664 dnl $2 = the shell variable to assign the result to
 665 dnl      If libpython is found we store $version here.
 666 dnl $3 = additional flags to add to CPPFLAGS
 667 dnl $4 = additional flags to add to LIBS
 668
 669 AC_DEFUN([AC_TRY_LIBPYTHON],
 670 [
 671   version=$1
 672   define([have_libpython_var],$2)
 673   new_CPPFLAGS=$3
 674   new_LIBS=$4
 675   AC_MSG_CHECKING([for ${version}])
 676   save_CPPFLAGS=$CPPFLAGS
 677   save_LIBS=$LIBS
 678   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 679   LIBS="$LIBS $new_LIBS"
 680   found_usable_python=no
 681   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 682                                  [[Py_Initialize ();]]),
 683                  [have_libpython_var=${version}
 684                   found_usable_python=yes
 685                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 686                   PYTHON_LIBS=$new_LIBS])
 687   CPPFLAGS=$save_CPPFLAGS
 688   LIBS=$save_LIBS
 689   AC_MSG_RESULT([${found_usable_python}])
 690 ])
 691
 692 dnl There are several different values for --with-python:
 693 dnl
 694 dnl no -   Don't include python support.
 695 dnl yes -  Include python support, error if it's missing.
 696 dnl        If we find python in $PATH, use it to fetch configure options,
 697 dnl        otherwise assume the compiler can find it with no help from us.
 698 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 699 dnl auto - Same as "yes", but if python is missing from the system,
 700 dnl        fall back to "no".
 701 dnl /path/to/python/exec-prefix -
 702 dnl        Use the python located in this directory.
 703 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 704 dnl        the compilation parameters.  Otherwise use
 705 dnl        -I/path/to/python/exec-prefix/include,
 706 dnl        -L/path/to/python/exec-prefix/lib.
 707 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 708 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 709 dnl        but is deprecated.
 710 dnl /path/to/python/executable -
 711 dnl        Run python-config.py with this version of python to fetch the
 712 dnl        compilation parameters.
 713 dnl        NOTE: This needn't be the real python executable.
 714 dnl        In a cross-compilation scenario (build != host), this could be
 715 dnl        a shell script that provides what python-config.py provides for
 716 dnl        --ldflags, --includes, --exec-prefix.
 717 dnl python-executable -
 718 dnl        Find python-executable in $PATH, and then handle the same as
 719 dnl        /path/to/python/executable.
 720 dnl
 721 dnl If a python program is specified, it is used to run python-config.py and
 722 dnl is passed --ldflags, --includes, --exec-prefix.
 723
 724 AC_ARG_WITH(python,
 725   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 726   [], [with_python=auto])
 727 AC_MSG_CHECKING([whether to use python])
 728 AC_MSG_RESULT([$with_python])
 729
 730 if test "${with_python}" = no; then
 731   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 732   have_libpython=no
 733 else
 734   case "${with_python}" in
 735   /*)
 736     if test -d ${with_python}; then
 737       # Assume the python binary is ${with_python}/bin/python.
 738       python_prog="${with_python}/bin/python"
 739       python_prefix=
 740       # If python does not exit ${with_python}/bin, then try in
 741       # ${with_python}.  On Windows/MinGW, this is where the Python
 742       # executable is.
 743       if test ! -x "${python_prog}"; then
 744         python_prog="${with_python}/python"
 745         python_prefix=
 746       fi
 747       if test ! -x "${python_prog}"; then
 748         # Fall back to gdb 7.0/7.1 behaviour.
 749         python_prog=missing
 750         python_prefix=${with_python}
 751       fi
 752     elif test -x "${with_python}"; then
 753       # While we can't run python compiled for $host (unless host == build),
 754       # the user could write a script that provides the needed information,
 755       # so we support that.
 756       python_prog=${with_python}
 757       python_prefix=
 758     else
 759       AC_ERROR(invalid value for --with-python)
 760     fi
 761     ;;
 762   */*)
 763     # Disallow --with-python=foo/bar.
 764     AC_ERROR(invalid value for --with-python)
 765     ;;
 766   *)
 767     # The user has either specified auto, yes, or the name of the python
 768     # program assumed to be in $PATH.
 769     python_prefix=
 770     case "${with_python}" in
 771     yes | auto)
 772       if test ${build} = ${host}; then
 773         AC_PATH_PROG(python_prog_path, python, missing)
 774         if test "${python_prog_path}" = missing; then
 775           python_prog=missing
 776         else
 777           python_prog=${python_prog_path}
 778         fi
 779       else
 780         # Not much we can do except assume the cross-compiler will find the
 781         # right files.
 782         python_prog=missing
 783       fi
 784       ;;
 785     *)
 786       # While we can't run python compiled for $host (unless host == build),
 787       # the user could write a script that provides the needed information,
 788       # so we support that.
 789       python_prog="${with_python}"
 790       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 791       if test "${python_prog_path}" = missing; then
 792         AC_ERROR(unable to find python program ${python_prog})
 793       fi
 794       ;;
 795     esac
 796   esac
 797
 798   if test "${python_prog}" != missing; then
 799     # We have a python program to use, but it may be too old.
 800     # Don't flag an error for --with-python=auto (the default).
 801     have_python_config=yes
 802     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 803     if test $? != 0; then
 804       have_python_config=failed
 805       if test "${with_python}" != auto; then
 806         AC_ERROR(failure running python-config --includes)
 807       fi
 808     fi
 809     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 810     if test $? != 0; then
 811       have_python_config=failed
 812       if test "${with_python}" != auto; then
 813         AC_ERROR(failure running python-config --ldflags)
 814       fi
 815     fi
 816     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 817     if test $? != 0; then
 818       have_python_config=failed
 819       if test "${with_python}" != auto; then
 820         AC_ERROR(failure running python-config --exec-prefix)
 821       fi
 822     fi
 823   else
 824     # We do not have a python executable we can use to determine where
 825     # to find the Python headers and libs.  We cannot guess the include
 826     # path from the python_prefix either, because that include path
 827     # depends on the Python version.  So, there is nothing much we can
 828     # do except assume that the compiler will be able to find those files.
 829     python_includes=
 830     python_libs=
 831     have_python_config=no
 832   fi
 833
 834   # If we have python-config, only try the configuration it provides.
 835   # Otherwise fallback on the old way of trying different versions of
 836   # python in turn.
 837
 838   have_libpython=no
 839   if test "${have_python_config}" = yes; then
 840     # Determine the Python version by extracting "-lpython<version>"
 841     # part of the python_libs. <version> is usually X.Y with X and Y
 842     # being decimal numbers, but can also be XY (seen on Windows).
 843     #
 844     # The extraction is performed using sed with a regular expression.
 845     # Initially, the regexp used was using the '?' quantifier to make
 846     # the dot in the version number optional.  Unfortunately, this
 847     # does not work with non-GNU versions of sed because, because of
 848     # what looks like a limitation (the '?' quantifier does not work
 849     # with back-references).  We work around this limitation by using
 850     # the '*' quantifier instead.  It means that, in theory, we might
 851     # match unexpected version strings such as "-lpython2..7", but
 852     # this seems unlikely in practice.  And even if that happens,
 853     # an error will be triggered later on, when checking that version
 854     # number.
 855     python_version=`echo " ${python_libs} " \
 856                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 857     case "${python_version}" in
 858     python*)
 859       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 860                        ${python_includes}, ${python_libs})
 861       ;;
 862     *)
 863       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 864       ;;
 865     esac
 866   elif test "${have_python_config}" != failed; then
 867     if test "${have_libpython}" = no; then
 868       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 869                        ${python_includes}, "${python_libs} -lpython2.7")
 870     fi
 871     if test "${have_libpython}" = no; then
 872       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 873                        ${python_includes}, "${python_libs} -lpython2.6")
 874     fi
 875     if test ${have_libpython} = no; then
 876       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 877                        ${python_includes}, "${python_libs} -lpython2.5")
 878     fi
 879     if test ${have_libpython} = no; then
 880       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 881                        ${python_includes}, "${python_libs} -lpython2.4")
 882     fi
 883   fi
 884   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 885     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 886   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 887     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 888   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 889     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 890   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 891     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 892   fi
 893
 894   if test "${have_libpython}" = no; then
 895     case "${with_python}" in
 896     yes)
 897       AC_MSG_ERROR([python is missing or unusable])
 898       ;;
 899     auto)
 900       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 901       ;;
 902     *)
 903       AC_MSG_ERROR([no usable python found at ${with_python}])
 904       ;;
 905     esac
 906   else
 907     if test -n "${python_prefix}"; then
 908       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 909                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 910       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 911     fi
 912   fi
 913 fi
 914
 915 if test "${have_libpython}" != no; then
 916   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 917   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 918   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 919   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 920   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 921   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 922
 923   # Flags needed to compile Python code (taken from python-config --cflags).
 924   # We cannot call python-config directly because it will output whatever was
 925   # used when compiling the Python interpreter itself, including flags which
 926   # would make the python-related objects be compiled differently from the
 927   # rest of GDB (e.g., -O2 and -fPIC).
 928   if test "${GCC}" = yes; then
 929     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 930   fi
 931
 932   if test "x${tentative_python_cflags}" != x; then
 933     AC_MSG_CHECKING(compiler flags for python code)
 934     for flag in ${tentative_python_cflags}; do
 935       # Check that the compiler accepts it
 936       saved_CFLAGS="$CFLAGS"
 937       CFLAGS="$CFLAGS $flag"
 938       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 939       CFLAGS="$saved_CFLAGS"
 940     done
 941     AC_MSG_RESULT(${PYTHON_CFLAGS})
 942   fi
 943
 944   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 945   #    #if _SGIAPI
 946   #    #define siginfo __siginfo
 947   #    #endif
 948   # The problem is that including Python causes some XOPEN macros to be
 949   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 950   # to false.  So, we work around this issue by defining siginfo ourself
 951   # though the command-line.
 952   case "$gdb_host" in
 953     irix*) if test "${GCC}" = yes; then
 954              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 955            fi
 956            ;;
 957   esac
 958 else
 959   # Even if Python support is not compiled in, we need to have these files
 960   # included.
 961   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 962   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 963         python/py-prettyprint.c python/py-auto-load.c"
 964 fi
 965 AC_SUBST(PYTHON_CFLAGS)
 966 AC_SUBST(PYTHON_CPPFLAGS)
 967 AC_SUBST(PYTHON_LIBS)
 968
 969 # ------------------------- #
 970 # Checks for header files.  #
 971 # ------------------------- #
 972
 973 AC_HEADER_DIRENT
 974 AC_HEADER_STAT
 975 AC_HEADER_STDC
 976 # elf_hp.h is for HP/UX 64-bit shared library support.
 977 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 978 # unconditionally, so what's the point in checking these?
 979 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 980                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 981                   stdlib.h string.h memory.h strings.h sys/fault.h \
 982                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 983                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 984                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 985                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 986                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
 987                   dlfcn.h])
 988 AC_CHECK_HEADERS(link.h, [], [],
 989 [#if HAVE_SYS_TYPES_H
 990 # include <sys/types.h>
 991 #endif
 992 #if HAVE_NLIST_H
 993 # include <nlist.h>
 994 #endif
 995 ])
 996 AC_CHECK_HEADERS(sys/proc.h, [], [],
 997 [#if HAVE_SYS_PARAM_H
 998 # include <sys/param.h>
 999 #endif
1000 ])
1001 AC_CHECK_HEADERS(sys/user.h, [], [],
1002 [#if HAVE_SYS_PARAM_H
1003 # include <sys/param.h>
1004 #endif
1005 ])
1006
1007 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1008 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1009 # think that we don't have <curses.h> if we're using GCC.
1010 case $host_os in
1011   solaris2.[[789]])
1012     if test "$GCC" = yes; then
1013       AC_DEFINE(_MSE_INT_H, 1,
1014         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1015    Solaris 2.[789] when using GCC. ])
1016     fi ;;
1017 esac
1018 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1019 AC_CHECK_HEADERS(term.h, [], [],
1020 [#if HAVE_CURSES_H
1021 # include <curses.h>
1022 #endif
1023 ])
1024
1025 # ------------------------- #
1026 # Checks for declarations.  #
1027 # ------------------------- #
1028
1029 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1030                 snprintf, vsnprintf])
1031 AM_LC_MESSAGES
1032
1033 # ----------------------- #
1034 # Checks for structures.  #
1035 # ----------------------- #
1036
1037 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1038
1039 # ------------------ #
1040 # Checks for types.  #
1041 # ------------------ #
1042
1043 AC_TYPE_SIGNAL
1044 AC_CHECK_TYPES(socklen_t, [], [],
1045 [#include <sys/types.h>
1046 #include <sys/socket.h>
1047 ])
1048
1049 # ------------------------------------- #
1050 # Checks for compiler characteristics.  #
1051 # ------------------------------------- #
1052
1053 AC_C_CONST
1054 AC_C_INLINE
1055 AC_C_BIGENDIAN
1056
1057 # ------------------------------ #
1058 # Checks for library functions.  #
1059 # ------------------------------ #
1060
1061 AC_FUNC_ALLOCA
1062 AC_FUNC_MMAP
1063 AC_FUNC_VFORK
1064 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
1065                 getgid pipe poll pread64 resize_term sbrk setpgid setpgrp setsid \
1066                 sigaction sigprocmask sigsetmask socketpair syscall \
1067                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1068                 setrlimit getrlimit posix_madvise waitpid])
1069 AM_LANGINFO_CODESET
1070
1071 # Check the return and argument types of ptrace.  No canned test for
1072 # this, so roll our own.
1073 gdb_ptrace_headers='
1074 #if HAVE_SYS_TYPES_H
1075 # include <sys/types.h>
1076 #endif
1077 #if HAVE_SYS_PTRACE_H
1078 # include <sys/ptrace.h>
1079 #endif
1080 #if HAVE_UNISTD_H
1081 # include <unistd.h>
1082 #endif
1083 '
1084 # There is no point in checking if we don't have a prototype.
1085 AC_CHECK_DECLS(ptrace, [], [
1086   : ${gdb_cv_func_ptrace_ret='int'}
1087   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1088 ], $gdb_ptrace_headers)
1089 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1090 # empty argument list, so check for that explicitly.
1091 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1092   AC_TRY_COMPILE($gdb_ptrace_headers,
1093     [extern long ptrace (enum __ptrace_request, ...);],
1094     gdb_cv_func_ptrace_ret='long',
1095     AC_TRY_COMPILE($gdb_ptrace_headers,
1096       [extern int ptrace ();],
1097       gdb_cv_func_ptrace_ret='int',
1098       gdb_cv_func_ptrace_ret='long')))
1099 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1100   [Define as the return type of ptrace.])
1101 # Check argument types.
1102 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1103   AC_TRY_COMPILE($gdb_ptrace_headers,
1104     [extern long ptrace (enum __ptrace_request, ...);],
1105     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1106 for gdb_arg1 in 'int' 'long'; do
1107  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1108   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1109    for gdb_arg4 in 'int' 'long'; do
1110      AC_TRY_COMPILE($gdb_ptrace_headers, [
1111 extern $gdb_cv_func_ptrace_ret
1112   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1113 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1114     break 4;])
1115     for gdb_arg5 in 'int *' 'int' 'long'; do
1116      AC_TRY_COMPILE($gdb_ptrace_headers, [
1117 extern $gdb_cv_func_ptrace_ret
1118   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1119 ], [
1120 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1121     break 5;])
1122     done
1123    done
1124   done
1125  done
1126 done
1127 # Provide a safe default value.
1128 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1129 ])])
1130 ac_save_IFS=$IFS; IFS=','
1131 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1132 IFS=$ac_save_IFS
1133 shift
1134 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1135   [Define to the type of arg 3 for ptrace.])
1136 if test -n "$[5]"; then
1137   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1138     [Define to the type of arg 5 for ptrace.])
1139 fi
1140
1141 dnl AC_FUNC_SETPGRP does not work when cross compiling
1142 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1143 if test "$cross_compiling" = no; then
1144   AC_FUNC_SETPGRP
1145 else
1146   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1147     [AC_TRY_COMPILE([
1148 #include <unistd.h>
1149 ], [
1150   if (setpgrp(1,1) == -1)
1151     exit (0);
1152   else
1153     exit (1);
1154 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1155 if test $ac_cv_func_setpgrp_void = yes; then
1156   AC_DEFINE(SETPGRP_VOID, 1)
1157 fi
1158 fi
1159
1160 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1161 # since sigsetjmp might only be defined as a macro.
1162 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1163 [AC_TRY_COMPILE([
1164 #include <setjmp.h>
1165 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1166 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1167 if test $gdb_cv_func_sigsetjmp = yes; then
1168   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1169 fi
1170
1171 # Assume we'll default to using the included libiberty regex.
1172 gdb_use_included_regex=yes
1173
1174 # However, if the system regex is GNU regex, then default to *not*
1175 # using the included regex.
1176 AC_CACHE_CHECK(
1177   [for GNU regex],
1178   [gdb_cv_have_gnu_regex],
1179   [AC_TRY_COMPILE(
1180     [#include <gnu-versions.h>],
1181     [#define REGEX_INTERFACE_VERSION 1
1182 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1183 # error "Version mismatch"
1184 #endif],
1185     gdb_cv_have_gnu_regex=yes,
1186     gdb_cv_have_gnu_regex=no)])
1187 if test $gdb_cv_have_gnu_regex = yes; then
1188   gdb_use_included_regex=no
1189 fi
1190
1191 AC_ARG_WITH(included-regex,
1192   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1193   gdb_with_regex=$withval,
1194   gdb_with_regex=$gdb_use_included_regex)
1195 if test "$gdb_with_regex" = yes; then
1196   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1197     [Define to 1 if the regex included in libiberty should be used.])
1198 fi
1199
1200 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1201 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1202 [#include <sys/param.h>
1203 #include <sys/proc.h>
1204 ])
1205
1206 # See if <sys/lwp.h> defines `struct lwp`.
1207 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1208 [AC_TRY_COMPILE([#include <sys/param.h>
1209 #include <sys/lwp.h>], [struct lwp l;],
1210 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1211 if test $gdb_cv_struct_lwp = yes; then
1212   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1213             [Define to 1 if your system has struct lwp.])
1214 fi
1215
1216 # See if <machine/reg.h> degines `struct reg'.
1217 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1218 [AC_TRY_COMPILE([#include <sys/types.h>
1219 #include <machine/reg.h>], [struct reg r;],
1220 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1221 if test $gdb_cv_struct_reg = yes; then
1222   AC_DEFINE(HAVE_STRUCT_REG, 1,
1223             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1224 fi
1225
1226 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1227 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1228 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1229                  [#include <machine/reg.h>])
1230
1231 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1232 AC_MSG_CHECKING(for PTRACE_GETREGS)
1233 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1234 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1235                 [PTRACE_GETREGS;],
1236                 [gdb_cv_have_ptrace_getregs=yes],
1237                 [gdb_cv_have_ptrace_getregs=no])])
1238 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1239 if test $gdb_cv_have_ptrace_getregs = yes; then
1240   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1241   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1242 fi
1243
1244 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1245 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1246 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1247 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1248                 [PTRACE_GETFPXREGS;],
1249                 [gdb_cv_have_ptrace_getfpxregs=yes],
1250                 [gdb_cv_have_ptrace_getfpxregs=no])])
1251 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1252 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1253   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1254   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1255 fi
1256
1257 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1258 AC_MSG_CHECKING(for PT_GETDBREGS)
1259 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1260 [AC_TRY_COMPILE([#include <sys/types.h>
1261 #include <sys/ptrace.h>],
1262                 [PT_GETDBREGS;],
1263                 [gdb_cv_have_pt_getdbregs=yes],
1264                 [gdb_cv_have_pt_getdbregs=no])])
1265 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1266 if test $gdb_cv_have_pt_getdbregs = yes; then
1267   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1268   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1269 fi
1270
1271 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1272 AC_MSG_CHECKING(for PT_GETXMMREGS)
1273 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1274 [AC_TRY_COMPILE([#include <sys/types.h>
1275 #include <sys/ptrace.h>],
1276                 [PT_GETXMMREGS;],
1277                 [gdb_cv_have_pt_getxmmregs=yes],
1278                 [gdb_cv_have_pt_getxmmregs=no])])
1279 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1280 if test $gdb_cv_have_pt_getxmmregs = yes; then
1281   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1282   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1283 fi
1284
1285 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1286
1287 if test "${target}" = "${host}"; then
1288   case "${host}" in
1289   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1290       AC_DEFINE(NEW_PROC_API, 1,
1291       [Define if you want to use new multi-fd /proc interface
1292        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1293       ;;
1294   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1295       AC_DEFINE(NEW_PROC_API, 1,
1296       [Define if you want to use new multi-fd /proc interface
1297        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1298       ;;
1299   mips-sgi-irix5*)
1300       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1301       AC_DEFINE([_KMEMUSER], 1,
1302       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1303        around a <sys/proc.h> problem on IRIX 5.])
1304       ;;
1305   esac
1306 fi
1307
1308 if test "$ac_cv_header_sys_procfs_h" = yes; then
1309   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1310   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1311   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1312   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1313   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1314   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1315   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1316   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1317   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1318   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1319   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1320   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1321   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1322   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1323
1324
1325   dnl Check for broken prfpregset_t type
1326
1327   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1328   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1329   dnl instead of the struct itself).  We detect this here, and work
1330   dnl around it in gdb_proc_service.h.
1331
1332   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1333     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1334     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1335       [AC_TRY_RUN([#include <sys/procfs.h>
1336        int main ()
1337        {
1338          if (sizeof (prfpregset_t) == sizeof (void *))
1339            return 1;
1340          return 0;
1341        }],
1342        gdb_cv_prfpregset_t_broken=no,
1343        gdb_cv_prfpregset_t_broken=yes,
1344        gdb_cv_prfpregset_t_broken=yes)])
1345     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1346     if test $gdb_cv_prfpregset_t_broken = yes; then
1347       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1348       [Define if the prfpregset_t type is broken.])
1349     fi
1350   fi
1351
1352   dnl Check for PIOCSET ioctl entry
1353
1354   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1355   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1356   [AC_TRY_COMPILE([#include <unistd.h>
1357 #include <sys/types.h>
1358 #include <sys/procfs.h>
1359 ], [
1360     int dummy;;
1361     dummy = ioctl(0, PIOCSET, &dummy);
1362   ],
1363   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1364   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1365   if test $gdb_cv_have_procfs_piocset = yes; then
1366     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1367     [Define if ioctl argument PIOCSET is available.])
1368   fi
1369 fi
1370
1371 dnl For native ports (host == target), check to see what kind of
1372 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1373 if test ${host} = ${target} ; then
1374   dnl Check for struct link_map with l_ members which are indicative
1375   dnl of SVR4-like shared libraries
1376
1377   AC_MSG_CHECKING(for member l_addr in struct link_map)
1378   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1379     [AC_TRY_COMPILE([#include <link.h>],
1380                     [struct link_map lm; (void) lm.l_addr;],
1381                     gdb_cv_have_struct_link_map_with_l_members=yes,
1382                     gdb_cv_have_struct_link_map_with_l_members=no)])
1383   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1384   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1385     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1386     [Define if <link.h> exists and defines struct link_map which has
1387      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1388      SVR4-like systems.)])
1389   fi
1390
1391   dnl Check for struct link_map with lm_ members which are indicative
1392   dnl of SunOS-like shared libraries
1393
1394   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1395   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1396     [AC_TRY_COMPILE([#include <sys/types.h>
1397 #include <link.h>],
1398                     [struct link_map lm; (void) lm.lm_addr;],
1399                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1400                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1401   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1402   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1403     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1404     [Define if <link.h> exists and defines struct link_map which has
1405      members with an ``lm_'' prefix.  (For SunOS.)])
1406   fi
1407
1408   dnl Check for struct so_map with som_ members which are found on
1409   dnl some *BSD systems.
1410
1411   AC_MSG_CHECKING(for member som_addr in struct so_map)
1412   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1413     [AC_TRY_COMPILE([#include <sys/types.h>
1414 #ifdef HAVE_NLIST_H
1415 #include <nlist.h>
1416 #endif
1417 #include <link.h>],
1418                     [struct so_map lm; (void) lm.som_addr;],
1419                     gdb_cv_have_struct_so_map_with_som_members=yes,
1420                     gdb_cv_have_struct_so_map_with_som_members=no)])
1421   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1422   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1423     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1424     [Define if <link.h> exists and defines a struct so_map which has
1425      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1426   fi
1427
1428   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1429   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1430
1431   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1432   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1433     [AC_TRY_COMPILE([#define _SYSCALL32
1434 #include <sys/link.h>], [struct link_map32 l;],
1435      gdb_cv_have_struct_link_map32=yes,
1436      gdb_cv_have_struct_link_map32=no)])
1437   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1438   if test $gdb_cv_have_struct_link_map32 = yes; then
1439     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1440     [Define if <sys/link.h> has struct link_map32])
1441     AC_DEFINE(_SYSCALL32, 1,
1442     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1443   fi
1444 fi
1445
1446 # Check if the compiler supports the `long long' type.
1447
1448 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1449                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1450 [[extern long long foo;]],
1451 [[switch (foo & 2) { case 0: return 1; }]])],
1452                                   gdb_cv_c_long_long=yes,
1453                                   gdb_cv_c_long_long=no)])
1454 if test $gdb_cv_c_long_long = yes; then
1455   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1456             [Define to 1 if the compiler supports long long.])
1457 fi
1458
1459 # Check if the compiler and runtime support printing long longs.
1460
1461 AC_CACHE_CHECK([for long long support in printf],
1462                gdb_cv_printf_has_long_long,
1463                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1464 [[char buf[32];
1465   long long l = 0;
1466   l = (l << 16) + 0x0123;
1467   l = (l << 16) + 0x4567;
1468   l = (l << 16) + 0x89ab;
1469   l = (l << 16) + 0xcdef;
1470   sprintf (buf, "0x%016llx", l);
1471   return (strcmp ("0x0123456789abcdef", buf));]])],
1472                               gdb_cv_printf_has_long_long=yes,
1473                               gdb_cv_printf_has_long_long=no,
1474                               gdb_cv_printf_has_long_long=no)])
1475 if test $gdb_cv_printf_has_long_long = yes; then
1476   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1477             [Define to 1 if the "%ll" format works to print long longs.])
1478 fi
1479
1480 # Check if the compiler and runtime support printing decfloats.
1481
1482 AC_CACHE_CHECK([for decfloat support in printf],
1483                gdb_cv_printf_has_decfloat,
1484                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1485 [[char buf[64];
1486   _Decimal32 d32 = 1.2345df;
1487   _Decimal64 d64 = 1.2345dd;
1488   _Decimal128 d128 = 1.2345dl;
1489   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1490   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1491                               gdb_cv_printf_has_decfloat=yes,
1492                               gdb_cv_printf_has_decfloat=no,
1493                               gdb_cv_printf_has_decfloat=no)])
1494 if test $gdb_cv_printf_has_decfloat = yes; then
1495   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1496             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1497 fi
1498
1499 # Check if the compiler supports the `long double' type.  We can't use
1500 # AC_C_LONG_DOUBLE because that one does additional checks on the
1501 # constants defined in <float.h> that fail on some systems,
1502 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1503
1504 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1505                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1506                                   gdb_cv_c_long_double=yes,
1507                                   gdb_cv_c_long_double=no)])
1508 if test $gdb_cv_c_long_double = yes; then
1509   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1510            [Define to 1 if the compiler supports long double.])
1511 fi
1512
1513 # Check if the compiler and runtime support printing long doubles.
1514
1515 AC_CACHE_CHECK([for long double support in printf],
1516                gdb_cv_printf_has_long_double,
1517                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1518 [[char buf[16];
1519   long double f = 3.141592653;
1520   sprintf (buf, "%Lg", f);
1521   return (strncmp ("3.14159", buf, 7));]])],
1522                               gdb_cv_printf_has_long_double=yes,
1523                               gdb_cv_printf_has_long_double=no,
1524                               gdb_cv_printf_has_long_double=no)])
1525 if test $gdb_cv_printf_has_long_double = yes; then
1526   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1527             [Define to 1 if the "%Lg" format works to print long doubles.])
1528 fi
1529
1530 # Check if the compiler and runtime support scanning long doubles.
1531
1532 AC_CACHE_CHECK([for long double support in scanf],
1533                gdb_cv_scanf_has_long_double,
1534                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1535 [[#include <stdio.h>]],
1536 [[char *buf = "3.141592653";
1537   long double f = 0;
1538   sscanf (buf, "%Lg", &f);
1539   return !(f > 3.14159 && f < 3.14160);]])],
1540                               gdb_cv_scanf_has_long_double=yes,
1541                               gdb_cv_scanf_has_long_double=no,
1542                               gdb_cv_scanf_has_long_double=no)])
1543 if test $gdb_cv_scanf_has_long_double = yes; then
1544   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1545             [Define to 1 if the "%Lg" format works to scan long doubles.])
1546 fi
1547
1548 case ${host_os} in
1549 aix*)
1550   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1551     SAVE_LDFLAGS=$LDFLAGS
1552
1553     case $GCC in
1554     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1555     *) gdb_cv_bigtoc=-bbigtoc ;;
1556     esac
1557
1558     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1559     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1560     LDFLAGS="${SAVE_LDFLAGS}"
1561   ])
1562   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1563   ;;
1564 esac
1565
1566 AC_MSG_CHECKING(for the dynamic export flag)
1567 dynamic_list=false
1568 if test "${gdb_native}" = yes; then
1569    # The dynamically loaded libthread_db needs access to symbols in the gdb
1570    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1571    # may not be supported there.
1572    old_LDFLAGS="$LDFLAGS"
1573    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1574    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1575    LDFLAGS="$LDFLAGS $RDYNAMIC"
1576    if test "${have_libpython}" = no; then
1577      AC_TRY_LINK([], [], [dynamic_list=true])
1578    else
1579      # Workaround http://bugs.python.org/issue4434 where static
1580      # libpythonX.Y.a would get its symbols required for
1581      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1582      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1583      old_CFLAGS="$CFLAGS"
1584      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1585      AC_RUN_IFELSE(
1586        AC_LANG_PROGRAM(
1587          [#include "]${have_libpython}[/Python.h"],
1588          [int err;
1589           Py_Initialize ();
1590           err = PyRun_SimpleString ("import itertools\n");
1591           Py_Finalize ();
1592           return err == 0 ? 0 : 1;]),
1593        [dynamic_list=true], [], [true])
1594      CFLAGS="$old_CFLAGS"
1595    fi
1596    LDFLAGS="$old_LDFLAGS"
1597 fi
1598 if $dynamic_list; then
1599   found="-Wl,--dynamic-list"
1600   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1601 else
1602   found="-rdynamic"
1603   RDYNAMIC="-rdynamic"
1604 fi
1605 AC_SUBST(RDYNAMIC)
1606 AC_MSG_RESULT($found)
1607
1608 dnl For certain native configurations, we need to check whether thread
1609 dnl support can be built in or not.
1610 dnl
1611 dnl Note that we only want this if we are both native (host == target),
1612 dnl and not doing a canadian cross build (build == host).
1613
1614 if test ${build} = ${host} -a ${host} = ${target} ; then
1615    case ${host_os} in
1616    solaris*)
1617       # See if thread_db library is around for Solaris thread debugging.
1618       # Note that we must explicitly test for version 1 of the library
1619       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1620       # the same API.
1621       AC_MSG_CHECKING(for Solaris thread debugging library)
1622       if test -f /usr/lib/libthread_db.so.1 ; then
1623          AC_MSG_RESULT(yes)
1624          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1625          [Define if using Solaris thread debugging.])
1626          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1627          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1628          AC_CHECK_LIB(dl, dlopen)
1629          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1630          # Sun randomly tweaked the prototypes in <proc_service.h>
1631          # at one point.
1632          AC_MSG_CHECKING(if <proc_service.h> is old)
1633          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1634             AC_TRY_COMPILE([
1635                 #include <proc_service.h>
1636                 ps_err_e ps_pdwrite
1637                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1638             ],, gdb_cv_proc_service_is_old=no,
1639                 gdb_cv_proc_service_is_old=yes)
1640          ])
1641          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1642          if test $gdb_cv_proc_service_is_old = yes; then
1643             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1644             [Define if <proc_service.h> on solaris uses int instead of
1645              size_t, and assorted other type changes.])
1646          fi
1647       else
1648          AC_MSG_RESULT(no)
1649       fi
1650       ;;
1651    aix*)
1652       AC_MSG_CHECKING(for AiX thread debugging library)
1653       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1654                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1655                                    [#ifndef PTHDB_VERSION_3
1656                                     #error
1657                                     #endif],
1658                                    gdb_cv_have_aix_thread_debug=yes,
1659                                    gdb_cv_have_aix_thread_debug=no)])
1660       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1661       if test $gdb_cv_have_aix_thread_debug = yes; then
1662          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1663          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1664          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1665
1666          # Older versions of AIX do not provide the declaration for
1667          # the getthrds function (it appears that it was introduced
1668          # with AIX 6.x).
1669          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1670       fi
1671       ;;
1672    esac
1673    AC_SUBST(CONFIG_LDFLAGS)
1674 fi
1675
1676 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1677 dnl other error codes.
1678 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1679    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1680                   gdb_cv_thread_db_h_has_td_notalloc,
1681      AC_TRY_COMPILE(
1682        [#include <thread_db.h>],
1683        [int i = TD_NOTALLOC;],
1684        gdb_cv_thread_db_h_has_td_notalloc=yes,
1685        gdb_cv_thread_db_h_has_td_notalloc=no
1686      )
1687    )
1688    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1689                   gdb_cv_thread_db_h_has_td_version,
1690      AC_TRY_COMPILE(
1691        [#include <thread_db.h>],
1692        [int i = TD_VERSION;],
1693        gdb_cv_thread_db_h_has_td_version=yes,
1694        gdb_cv_thread_db_h_has_td_version=no
1695      )
1696    )
1697    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1698                   gdb_cv_thread_db_h_has_td_notls,
1699      AC_TRY_COMPILE(
1700        [#include <thread_db.h>],
1701        [int i = TD_NOTLS;],
1702        gdb_cv_thread_db_h_has_td_notls=yes,
1703        gdb_cv_thread_db_h_has_td_notls=no
1704      )
1705    )
1706 fi
1707 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1708   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1709             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1710 fi
1711 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1712   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1713             [Define if <thread_db.h> has the TD_VERSION error code.])
1714 fi
1715 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1716   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1717             [Define if <thread_db.h> has the TD_NOTLS error code.])
1718 fi
1719
1720 dnl See if we have a sys/syscall header file that has __NR_tkill.
1721 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1722    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1723                   gdb_cv_sys_syscall_h_has_tkill,
1724      AC_TRY_COMPILE(
1725        [#include <sys/syscall.h>],
1726        [int i = __NR_tkill;],
1727        gdb_cv_sys_syscall_h_has_tkill=yes,
1728        gdb_cv_sys_syscall_h_has_tkill=no
1729      )
1730    )
1731 fi
1732 dnl See if we can issue tkill syscall.
1733 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1734   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1735 fi
1736
1737 dnl Check if we can disable the virtual address space randomization.
1738 dnl The functionality of setarch -R.
1739 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1740 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1741 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1742 #       define ADDR_NO_RANDOMIZE 0x0040000
1743 #      endif
1744        /* Test the flag could be set and stays set.  */
1745        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1746        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1747            return 1])])
1748 AC_RUN_IFELSE([PERSONALITY_TEST],
1749               [have_personality=true],
1750               [have_personality=false],
1751               [AC_LINK_IFELSE([PERSONALITY_TEST],
1752                               [have_personality=true],
1753                               [have_personality=false])])
1754 if $have_personality
1755 then
1756     AC_DEFINE([HAVE_PERSONALITY], 1,
1757               [Define if you support the personality syscall.])
1758 fi
1759
1760 dnl Handle optional features that can be enabled.
1761
1762 target_sysroot_reloc=0
1763 AC_ARG_WITH(sysroot,
1764 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1765 [
1766  case ${with_sysroot} in
1767  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1768  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1769  esac
1770
1771  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1772
1773  if test "x$prefix" = xNONE; then
1774   test_prefix=/usr/local
1775  else
1776   test_prefix=$prefix
1777  fi
1778  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1779   test_exec_prefix=$test_prefix
1780  else
1781   test_exec_prefix=$exec_prefix
1782  fi
1783  case ${TARGET_SYSTEM_ROOT} in
1784  "${test_prefix}"|"${test_prefix}/"*|\
1785  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1786  '${prefix}'|'${prefix}/'*|\
1787  '${exec_prefix}'|'${exec_prefix}/'*)
1788    target_sysroot_reloc=1
1789    ;;
1790  esac
1791 ], [
1792  TARGET_SYSTEM_ROOT=
1793  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1794 ])
1795 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1796 AC_SUBST(TARGET_SYSTEM_ROOT)
1797 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1798
1799 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1800     [automatically load a system-wide gdbinit file],
1801     [])
1802
1803 AC_ARG_ENABLE(werror,
1804   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1805   [case "${enableval}" in
1806      yes | y) ERROR_ON_WARNING="yes" ;;
1807      no | n)  ERROR_ON_WARNING="no" ;;
1808      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1809    esac])
1810
1811 # Enable -Werror by default when using gcc
1812 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1813     ERROR_ON_WARNING=yes
1814 fi
1815
1816 WERROR_CFLAGS=""
1817 if test "${ERROR_ON_WARNING}" = yes ; then
1818     WERROR_CFLAGS="-Werror"
1819 fi
1820
1821 # The entries after -Wno-pointer-sign are disabled warnings which may
1822 # be enabled in the future, which can not currently be used to build
1823 # GDB.
1824 # NOTE: If you change this list, remember to update
1825 # gdb/doc/gdbint.texinfo.
1826 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1827 -Wformat-nonliteral -Wno-pointer-sign \
1828 -Wno-unused -Wunused-value -Wunused-function \
1829 -Wno-switch -Wno-char-subscripts"
1830
1831 # Enable -Wno-format by default when using gcc on mingw since many
1832 # GCC versions complain about %I64.
1833 case "${host}" in
1834   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1835 esac
1836
1837 AC_ARG_ENABLE(build-warnings,
1838 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1839 [case "${enableval}" in
1840   yes)  ;;
1841   no)   build_warnings="-w";;
1842   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1843         build_warnings="${build_warnings} ${t}";;
1844   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1845         build_warnings="${t} ${build_warnings}";;
1846   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1847 esac
1848 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1849   echo "Setting compiler warning flags = $build_warnings" 6>&1
1850 fi])dnl
1851 AC_ARG_ENABLE(gdb-build-warnings,
1852 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1853 [case "${enableval}" in
1854   yes)  ;;
1855   no)   build_warnings="-w";;
1856   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1857         build_warnings="${build_warnings} ${t}";;
1858   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1859         build_warnings="${t} ${build_warnings}";;
1860   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1861 esac
1862 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1863   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1864 fi])dnl
1865 WARN_CFLAGS=""
1866 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1867 then
1868     AC_MSG_CHECKING(compiler warning flags)
1869     # Separate out the -Werror flag as some files just cannot be
1870     # compiled with it enabled.
1871     for w in ${build_warnings}; do
1872         case $w in
1873         -Werr*) WERROR_CFLAGS=-Werror ;;
1874         *) # Check that GCC accepts it
1875             saved_CFLAGS="$CFLAGS"
1876             CFLAGS="$CFLAGS $w"
1877             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1878             CFLAGS="$saved_CFLAGS"
1879         esac
1880     done
1881     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1882 fi
1883 AC_SUBST(WARN_CFLAGS)
1884 AC_SUBST(WERROR_CFLAGS)
1885
1886 # In the Cygwin environment, we need some additional flags.
1887 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1888 [AC_EGREP_CPP(lose, [
1889 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1890 lose
1891 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1892
1893
1894 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1895 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1896 case ${host} in
1897   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1898   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1899   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1900 esac
1901 AC_SUBST(SER_HARDWIRE)
1902
1903 # libreadline needs libuser32.a in a cygwin environment
1904 WIN32LIBS=
1905 if test x$gdb_cv_os_cygwin = xyes; then
1906     WIN32LIBS="-luser32"
1907     case "${target}" in
1908         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1909         ;;
1910     esac
1911 fi
1912
1913 # The ser-tcp.c module requires sockets.
1914 case ${host} in
1915   *mingw32*)
1916     AC_DEFINE(USE_WIN32API, 1,
1917               [Define if we should use the Windows API, instead of the
1918                POSIX API.  On Windows, we use the Windows API when
1919                building for MinGW, but the POSIX API when building
1920                for Cygwin.])
1921     WIN32LIBS="$WIN32LIBS -lws2_32"
1922     ;;
1923 esac
1924 AC_SUBST(WIN32LIBS)
1925
1926 # Add ELF support to GDB, but only if BFD includes ELF support.
1927 OLD_CFLAGS=$CFLAGS
1928 OLD_LDFLAGS=$LDFLAGS
1929 OLD_LIBS=$LIBS
1930 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1931 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1932 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1933 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1934 if test "$plugins" = "yes"; then
1935   LIBS="-ldl $LIBS"
1936 fi
1937 LIBS="-lbfd -liberty $intl $LIBS"
1938 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1939 [AC_TRY_LINK(
1940 [#include <stdlib.h>
1941 #include "bfd.h"
1942 #include "elf-bfd.h"
1943 ],
1944 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1945 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1946 if test $gdb_cv_var_elf = yes; then
1947   CONFIG_OBS="$CONFIG_OBS elfread.o"
1948   AC_DEFINE(HAVE_ELF, 1,
1949             [Define if ELF support should be included.])
1950   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1951   if test "$plugins" = "yes"; then
1952     OLD_LIBS="-ldl $OLD_LIBS"
1953   fi
1954 fi
1955 CFLAGS=$OLD_CFLAGS
1956 LDFLAGS=$OLD_LDFLAGS
1957 LIBS=$OLD_LIBS
1958
1959 # Add any host-specific objects to GDB.
1960 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1961
1962 LIBGUI="../libgui/src/libgui.a"
1963 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1964 AC_SUBST(LIBGUI)
1965 AC_SUBST(GUI_CFLAGS_X)
1966
1967 WIN32LDAPP=
1968 AC_SUBST(WIN32LIBS)
1969 AC_SUBST(WIN32LDAPP)
1970
1971 case "${host}" in
1972 *-*-cygwin* | *-*-mingw* )
1973     configdir="win"
1974     ;;
1975 *)
1976     configdir="unix"
1977     ;;
1978 esac
1979
1980 GDBTKLIBS=
1981 if test "${enable_gdbtk}" = "yes"; then
1982
1983     # Gdbtk must have an absolute path to srcdir in order to run
1984     # properly when not installed.
1985     here=`pwd`
1986     cd ${srcdir}
1987     GDBTK_SRC_DIR=`pwd`
1988     cd $here
1989
1990     SC_PATH_TCLCONFIG
1991
1992     # If $no_tk is nonempty, then we can't do Tk, and there is no
1993     # point to doing Tcl.
1994     SC_PATH_TKCONFIG
1995
1996     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1997         SC_LOAD_TCLCONFIG
1998
1999         # Check for in-tree tcl
2000         here=`pwd`
2001         cd ${srcdir}/..
2002         topdir=`pwd`
2003         cd ${here}
2004
2005         intree="no"
2006         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2007           intree="yes"
2008         fi
2009
2010         # Find Tcl private headers
2011         if test x"${intree}" = xno; then
2012           CY_AC_TCL_PRIVATE_HEADERS
2013           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2014           TCL_LIBRARY="${TCL_LIB_SPEC}"
2015           TCL_DEPS=""
2016         else
2017           # If building tcl in the same src tree, private headers
2018           # are not needed, but we need to be sure to use the right
2019           # headers library
2020           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2021           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2022           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2023         fi
2024         AC_SUBST(TCL_INCLUDE)
2025         AC_SUBST(TCL_LIBRARY)
2026         AC_SUBST(TCL_DEPS)
2027
2028         SC_LOAD_TKCONFIG
2029
2030         # Check for in-tree Tk
2031         intree="no"
2032         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2033           intree="yes"
2034         fi
2035
2036         # Find Tk private headers
2037         if test x"${intree}" = xno; then
2038           CY_AC_TK_PRIVATE_HEADERS
2039           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2040           TK_LIBRARY=${TK_LIB_SPEC}
2041           TK_DEPS=""
2042         else
2043           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2044           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2045           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2046         fi
2047         AC_SUBST(TK_INCLUDE)
2048         AC_SUBST(TK_LIBRARY)
2049         AC_SUBST(TK_DEPS)
2050         AC_SUBST(TK_XINCLUDES)
2051
2052         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2053
2054         # Include some libraries that Tcl and Tk want.
2055         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2056         # Yes, the ordering seems wrong here.  But it isn't.
2057         # TK_LIBS is the list of libraries that need to be linked
2058         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2059         # were in LIBS then any link tests after this point would
2060         # try to include things like `$(LIBGUI)', which wouldn't work.
2061         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2062
2063         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2064         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2065         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2066         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2067         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2068         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2069         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2070
2071         if test x$gdb_cv_os_cygwin = xyes; then
2072           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2073           WIN32LDAPP="-Wl,--subsystem,console"
2074           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2075         fi
2076
2077         AC_CONFIG_SUBDIRS(gdbtk)
2078     fi
2079 fi
2080
2081 AC_SUBST(X_CFLAGS)
2082 AC_SUBST(X_LDFLAGS)
2083 AC_SUBST(X_LIBS)
2084 AC_SUBST(GDBTKLIBS)
2085 AC_SUBST(GDBTK_CFLAGS)
2086 AC_SUBST(GDBTK_SRC_DIR)
2087
2088 AC_PATH_X
2089
2090 # Unlike the sim directory, whether a simulator is linked is controlled by
2091 # presence of a gdb_sim definition in the target configure.tgt entry.
2092 # This code just checks for a few cases where we'd like to ignore those
2093 # definitions, even when they're present in the '.mt' file.  These cases
2094 # are when --disable-sim is specified, or if the simulator directory is
2095 # not part of the source tree.
2096 #
2097 AC_ARG_ENABLE(sim,
2098 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2099 [echo "enable_sim = $enable_sim";
2100  echo "enableval = ${enableval}";
2101  case "${enableval}" in
2102   yes) ignore_sim=false ;;
2103   no)  ignore_sim=true ;;
2104   *)   ignore_sim=false ;;
2105  esac],
2106 [ignore_sim=false])
2107
2108 if test ! -d "${srcdir}/../sim"; then
2109   ignore_sim=true
2110 fi
2111
2112 SIM=
2113 SIM_OBS=
2114 if test "${ignore_sim}" = "false"; then
2115   if test x"${gdb_sim}" != x ; then
2116     SIM="${gdb_sim}"
2117     SIM_OBS="remote-sim.o"
2118     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2119   fi
2120 fi
2121 AC_SUBST(SIM)
2122 AC_SUBST(SIM_OBS)
2123
2124 AC_SUBST(ENABLE_CFLAGS)
2125 AC_SUBST(PROFILE_CFLAGS)
2126
2127 AC_SUBST(CONFIG_OBS)
2128 AC_SUBST(CONFIG_DEPS)
2129 AC_SUBST(CONFIG_SRCS)
2130 AC_SUBST(CONFIG_ALL)
2131 AC_SUBST(CONFIG_CLEAN)
2132 AC_SUBST(CONFIG_INSTALL)
2133 AC_SUBST(CONFIG_UNINSTALL)
2134
2135 # List of host floatformats.
2136 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2137 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2138 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2139
2140 # target_subdir is used by the testsuite to find the target libraries.
2141 target_subdir=
2142 if test "${host}" != "${target}"; then
2143     target_subdir="${target_alias}/"
2144 fi
2145 AC_SUBST(target_subdir)
2146
2147 frags=
2148 if test "${gdb_native}" = "yes"; then
2149   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2150   if test ! -f ${host_makefile_frag}; then
2151     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2152   fi
2153   frags="$frags $host_makefile_frag"
2154 else
2155   host_makefile_frag=/dev/null
2156 fi
2157
2158 AC_SUBST_FILE(host_makefile_frag)
2159 AC_SUBST(frags)
2160
2161 changequote(,)dnl
2162 if test "${gdb_native}" = "yes"; then
2163 # We pick this up from the host configuration file (.mh) because we
2164 # do not have a native configuration Makefile fragment.
2165 nativefile=`sed -n '
2166 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2167 ' ${host_makefile_frag}`
2168 fi
2169 changequote([,])
2170
2171 if test x"${gdb_osabi}" != x ; then
2172     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2173                        [Define to the default OS ABI for this configuration.])
2174 fi
2175
2176 # Enable multi-ice-gdb-server.
2177 AC_ARG_ENABLE(multi-ice,
2178 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2179   [case $enableval in
2180     yes | no)
2181       ;;
2182     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2183   esac])
2184 if test "x$enable_multi_ice" = xyes; then
2185    AC_CONFIG_SUBDIRS(multi-ice)
2186 fi
2187
2188 AC_ARG_ENABLE(gdbserver,
2189 AS_HELP_STRING([--enable-gdbserver],
2190                [automatically build gdbserver (yes/no/auto, default is auto)]),
2191 [case "${enableval}" in
2192   yes| no|auto) ;;
2193   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2194 esac],[enable_gdbserver=auto])
2195
2196 # We only build gdbserver automatically in a native configuration, and
2197 # only if the user did not explicitly disable its build.
2198 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2199   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2200   if test "x$build_gdbserver" = xyes; then
2201     AC_MSG_RESULT(yes)
2202     AC_CONFIG_SUBDIRS(gdbserver)
2203     gdbserver_build_enabled=yes
2204   else
2205     AC_MSG_RESULT(no)
2206   fi
2207 fi
2208
2209 # If the user explicitly request the gdbserver to be built, verify that
2210 # we were in fact able to enable it.
2211 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2212   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2213 fi
2214
2215 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2216 # to an empty version.
2217
2218 files=
2219 links=
2220
2221 rm -f nm.h
2222 if test "${nativefile}" != ""; then
2223     case "${nativefile}" in
2224       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2225       * ) GDB_NM_FILE="${nativefile}"
2226     esac
2227     files="${files} ${GDB_NM_FILE}"
2228     links="${links} nm.h"
2229     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2230 fi
2231 AC_SUBST(GDB_NM_FILE)
2232
2233 AC_LINK_FILES($files, $links)
2234
2235 dnl Check for exe extension set on certain hosts (e.g. Win32)
2236 AC_EXEEXT
2237
2238 dnl  Detect the character set used by this host.
2239 dnl  At the moment, we just assume it's UTF-8.
2240 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2241           [Define to be a string naming the default host character set.])
2242
2243 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2244 [
2245 case x$CONFIG_HEADERS in
2246 xconfig.h:config.in)
2247 echo > stamp-h ;;
2248 esac
2249 ])
2250
2251 exit 0