gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2016 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # Dependency checking.
  42 ZW_CREATE_DEPDIR
  43 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  44
  45 # Check for the 'make' the user wants to use.
  46 AC_CHECK_PROGS(MAKE, make)
  47 MAKE_IS_GNU=
  48 case "`$MAKE --version 2>&1 | sed 1q`" in
  49   *GNU*)
  50     MAKE_IS_GNU=yes
  51     ;;
  52 esac
  53 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  54 AC_PROG_MAKE_SET
  55
  56 gnulib_extra_configure_args=
  57 # If large-file support is disabled, make sure gnulib does the same.
  58 if test "$enable_largefile" = no; then
  59 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  60 fi
  61
  62 # Configure gnulib.  We need to build gnulib under some other
  63 # directory not "gnulib", to avoid the problem of both GDB and
  64 # GDBserver wanting to build it in the same directory, when building
  65 # in the source dir.
  66 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  67                   ["$gnulib_extra_configure_args"])
  68
  69 dnl List of object files and targets accumulated by configure.
  70
  71 CONFIG_OBS=
  72 CONFIG_DEPS=
  73 CONFIG_SRCS=
  74 ENABLE_CFLAGS=
  75
  76 CONFIG_ALL=
  77 CONFIG_CLEAN=
  78 CONFIG_INSTALL=
  79 CONFIG_UNINSTALL=
  80
  81 dnl Set up for gettext.
  82 ZW_GNU_GETTEXT_SISTER_DIR
  83
  84 localedir='${datadir}/locale'
  85 AC_SUBST(localedir)
  86
  87 if test x"$USE_NLS" = xyes; then
  88    CONFIG_ALL="$CONFIG_ALL all-po"
  89    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  90    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  91    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  92 fi
  93
  94 GNULIB=build-gnulib/import
  95
  96 # For Makefile dependencies.
  97 GNULIB_STDINT_H=
  98 if test x"$STDINT_H" != x; then
  99   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 100 fi
 101 AC_SUBST(GNULIB_STDINT_H)
 102
 103 PACKAGE=gdb
 104 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 105 AC_SUBST(PACKAGE)
 106
 107 # We never need to detect it in this sub-configure.
 108 # But preserve it for config.status --recheck.
 109 AC_ARG_VAR(MAKEINFO,
 110   [Parent configure detects if it is of sufficient version.])
 111 AC_ARG_VAR(MAKEINFOFLAGS,
 112   [Parameters for MAKEINFO.])
 113
 114 MAKEINFO_EXTRA_FLAGS=""
 115 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 116   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 117   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 118     gdb_cv_have_makeinfo_click=yes
 119   else
 120     gdb_cv_have_makeinfo_click=no
 121   fi])
 122 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 123   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 124 fi
 125 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 126
 127 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 128     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 129     [${libdir}/debug])
 130
 131 # We can't pass paths as command line arguments.
 132 # Mingw32 tries to be clever and will convert the paths for us.
 133 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 134 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 135 # This breaks GDB's relocatable path conversions since paths passed in
 136 # config.h would not get so translated, the path prefixes no longer match.
 137 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 138
 139 # GDB's datadir relocation
 140
 141 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 142     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 143     [${datadir}/gdb])
 144
 145 AC_ARG_WITH(relocated-sources,
 146 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 147 [reloc_srcdir="${withval}"
 148  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 149               [Relocated directory for source files. ])
 150 ])
 151
 152 AC_MSG_CHECKING([for default auto-load directory])
 153 AC_ARG_WITH(auto-load-dir,
 154 AS_HELP_STRING([--with-auto-load-dir=PATH],
 155   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 156   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 157 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 158 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 159               [Directories from which to load auto-loaded scripts.])
 160 AC_MSG_RESULT([$with_auto_load_dir])
 161
 162 AC_MSG_CHECKING([for default auto-load safe-path])
 163 AC_ARG_WITH(auto-load-safe-path,
 164 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 165   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 166 AS_HELP_STRING([--without-auto-load-safe-path],
 167                [do not restrict auto-loaded files locations]),
 168     [if test "$with_auto_load_safe_path" = "no"; then
 169      with_auto_load_safe_path="/"
 170      fi],
 171 [with_auto_load_safe_path="$with_auto_load_dir"])
 172 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 173 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 174               [Directories safe to hold auto-loaded files.])
 175 AC_MSG_RESULT([$with_auto_load_safe_path])
 176
 177 AC_CONFIG_SUBDIRS(testsuite)
 178
 179 # Check whether to support alternative target configurations
 180 AC_ARG_ENABLE(targets,
 181 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 182 [case "${enableval}" in
 183   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 184             ;;
 185   no)       enable_targets= ;;
 186   *)        enable_targets=$enableval ;;
 187 esac])
 188
 189 # Check whether to enable 64-bit support on 32-bit hosts
 190 AC_ARG_ENABLE(64-bit-bfd,
 191 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 192 [case "${enableval}" in
 193   yes)  want64=true  ;;
 194   no)   want64=false ;;
 195   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 196 esac],[want64=false])dnl
 197
 198 # Provide defaults for some variables set by the per-host and per-target
 199 # configuration.
 200 gdb_host_obs=posix-hdep.o
 201
 202 if test "${target}" = "${host}"; then
 203   gdb_native=yes
 204 else
 205   gdb_native=no
 206 fi
 207
 208 . $srcdir/configure.host
 209
 210 # Add in the common host objects.
 211 . $srcdir/common/common.host
 212 gdb_host_obs="$gdb_host_obs $common_host_obs"
 213
 214 # Accumulate some settings from configure.tgt over all enabled targets
 215
 216 TARGET_OBS=
 217 all_targets=
 218 HAVE_NATIVE_GCORE_TARGET=
 219
 220 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 221 do
 222   if test "$targ_alias" = "all"; then
 223     all_targets=true
 224   else
 225     # Canonicalize the secondary target names.
 226     result=`$ac_config_sub $targ_alias 2>/dev/null`
 227     if test -n "$result"; then
 228         targ=$result
 229     else
 230         targ=$targ_alias
 231     fi
 232
 233     . ${srcdir}/configure.tgt
 234
 235     AS_IF([test -z "${gdb_target_obs}"],
 236       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 237
 238     # Target-specific object files
 239     for i in ${gdb_target_obs}; do
 240         case " $TARGET_OBS " in
 241         *" ${i} "*) ;;
 242         *)
 243           TARGET_OBS="$TARGET_OBS ${i}"
 244           ;;
 245         esac
 246     done
 247
 248     # Check whether this target needs 64-bit CORE_ADDR
 249     if test x${want64} = xfalse; then
 250       . ${srcdir}/../bfd/config.bfd
 251     fi
 252
 253     # Check whether this target is native and supports gcore.
 254     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 255        && $gdb_have_gcore; then
 256       HAVE_NATIVE_GCORE_TARGET=1
 257     fi
 258   fi
 259 done
 260
 261 if test x${all_targets} = xtrue; then
 262
 263   # We want all 64-bit targets if we either:
 264   #  - run on a 64-bit host  or
 265   #  - already require 64-bit support for some other target  or
 266   #  - the --enable-64-bit-bfd option was supplied
 267   # Otherwise we only support all 32-bit targets.
 268   #
 269   # NOTE: This test must be in sync with the corresponding
 270   #       tests in BFD!
 271
 272   if test x${want64} = xfalse; then
 273     AC_CHECK_SIZEOF(long)
 274     if test "x${ac_cv_sizeof_long}" = "x8"; then
 275       want64=true
 276     fi
 277   fi
 278   if test x${want64} = xtrue; then
 279     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 280   else
 281     TARGET_OBS='$(ALL_TARGET_OBS)'
 282   fi
 283 fi
 284
 285 AC_SUBST(TARGET_OBS)
 286 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 287
 288 # For other settings, only the main target counts.
 289 gdb_sim=
 290 gdb_osabi=
 291 build_gdbserver=
 292 targ=$target; . ${srcdir}/configure.tgt
 293
 294 # Fetch the default architecture and default target vector from BFD.
 295 targ=$target; . $srcdir/../bfd/config.bfd
 296
 297 # We only want the first architecture, so strip off the others if
 298 # there is more than one.
 299 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 300
 301 if test "x$targ_archs" != x; then
 302   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 303     [Define to BFD's default architecture. ])
 304 fi
 305 if test "x$targ_defvec" != x; then
 306   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 307     [Define to BFD's default target vector. ])
 308 fi
 309
 310 # The CLI cannot be disabled yet, but may be in the future.
 311
 312 # Enable CLI.
 313 AC_ARG_ENABLE(gdbcli,
 314 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 315   [case $enableval in
 316     yes)
 317       ;;
 318     no)
 319       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 320     *)
 321       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 322   esac],
 323   [enable_gdbcli=yes])
 324 if test x"$enable_gdbcli" = xyes; then
 325   if test -d $srcdir/cli; then
 326     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 327     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 328     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 329     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 330   fi
 331 fi
 332
 333 # Enable MI.
 334 AC_ARG_ENABLE(gdbmi,
 335 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 336   [case $enableval in
 337     yes | no)
 338       ;;
 339     *)
 340       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 341   esac],
 342   [enable_gdbmi=yes])
 343 if test x"$enable_gdbmi" = xyes; then
 344   if test -d $srcdir/mi; then
 345     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 346     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 347     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 348     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 349   fi
 350 fi
 351
 352 # Enable TUI.
 353 AC_ARG_ENABLE(tui,
 354 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 355   [case $enableval in
 356     yes | no | auto)
 357       ;;
 358     *)
 359       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 360   esac],enable_tui=auto)
 361
 362 # Enable gdbtk.
 363 AC_ARG_ENABLE(gdbtk,
 364 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 365   [case $enableval in
 366     yes | no)
 367       ;;
 368     *)
 369       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 370   esac],
 371   [if test -d $srcdir/gdbtk; then
 372     enable_gdbtk=yes
 373   else
 374     enable_gdbtk=no
 375   fi])
 376 # We unconditionally disable gdbtk tests on selected platforms.
 377 case $host_os in
 378   go32* | windows*)
 379     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 380     enable_gdbtk=no ;;
 381 esac
 382
 383 # Libunwind support for ia64.
 384
 385 AC_ARG_WITH(libunwind-ia64,
 386 AS_HELP_STRING([--with-libunwind-ia64],
 387                [use libunwind frame unwinding for ia64 targets]),,
 388             [with_libunwind_ia64=auto])
 389
 390 # Backward compatibility option.
 391 if test "${with_libunwind+set}" = set; then
 392   if test x"$with_libunwind_ia64" != xauto; then
 393     AC_MSG_ERROR(
 394       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 395   fi
 396   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 397   with_libunwind_ia64="$with_libunwind"
 398 fi
 399
 400 case "$with_libunwind_ia64" in
 401   yes | no)
 402     ;;
 403   auto)
 404     AC_CHECK_HEADERS(libunwind-ia64.h)
 405     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 406     ;;
 407   *)
 408     AC_MSG_ERROR(
 409       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 410     ;;
 411 esac
 412
 413 if test x"$with_libunwind_ia64" = xyes; then
 414   AC_CHECK_HEADERS(libunwind-ia64.h)
 415   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 416     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 417   fi
 418   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 419   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 420   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 421 fi
 422
 423 opt_curses=no
 424 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 425
 426 prefer_curses=no
 427 if test "$opt_curses" = "yes"; then
 428   prefer_curses=yes
 429 fi
 430
 431 # Profiling support.
 432 AC_ARG_ENABLE(profiling,
 433 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 434   [case $enableval in
 435     yes | no)
 436       ;;
 437     *)
 438       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 439   esac],
 440  [enable_profiling=no])
 441
 442 AC_CHECK_FUNCS(monstartup _mcleanup)
 443 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 444 [AC_TRY_LINK(
 445 [#include <stdlib.h>
 446 extern char _etext;
 447 ],
 448 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 449 if test $ac_cv_var__etext = yes; then
 450   AC_DEFINE(HAVE__ETEXT, 1,
 451             [Define to 1 if your system has the _etext variable. ])
 452 fi
 453 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 454 [AC_TRY_LINK(
 455 [#include <stdlib.h>
 456 extern char etext;
 457 ],
 458 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 459 if test $ac_cv_var_etext = yes; then
 460   AC_DEFINE(HAVE_ETEXT, 1,
 461             [Define to 1 if your system has the etext variable. ])
 462 fi
 463 if test "$enable_profiling" = yes ; then
 464   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 465     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 466   fi
 467   PROFILE_CFLAGS=-pg
 468   OLD_CFLAGS="$CFLAGS"
 469   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 470
 471   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 472     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 473      ac_cv_cc_supports_pg=no)])
 474
 475   if test $ac_cv_cc_supports_pg = no; then
 476     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 477   fi
 478
 479   CFLAGS="$OLD_CFLAGS"
 480 fi
 481
 482 ACX_PKGVERSION([GDB])
 483 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 484 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 485 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 486
 487 # --------------------- #
 488 # Checks for programs.  #
 489 # --------------------- #
 490
 491 AC_PROG_AWK
 492 AC_PROG_INSTALL
 493 AC_PROG_LN_S
 494 AC_PROG_RANLIB
 495 AC_PROG_YACC
 496
 497 AC_CHECK_TOOL(AR, ar)
 498 AC_CHECK_TOOL(DLLTOOL, dlltool)
 499 AC_CHECK_TOOL(WINDRES, windres)
 500
 501 case $host_os in
 502   gnu*)
 503     # Needed for GNU Hurd hosts.
 504     AC_CHECK_TOOL(MIG, mig)
 505     if test x"$MIG" = x; then
 506       AC_MSG_ERROR([MIG not found but required for $host hosts])
 507     fi
 508     ;;
 509 esac
 510
 511 # ---------------------- #
 512 # Checks for libraries.  #
 513 # ---------------------- #
 514
 515 # We might need to link with -lm; most simulators need it.
 516 AC_CHECK_LIB(m, main)
 517
 518 # We need to link with -lw to get `wctype' on Solaris before Solaris
 519 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 520 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 521 # is known to have this problem).  Therefore we avoid libw if we can.
 522 AC_CHECK_FUNC(wctype, [],
 523   [AC_CHECK_LIB(w, wctype)])
 524
 525 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 526 AC_SEARCH_LIBS(gethostbyname, nsl)
 527
 528 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 529 AC_SEARCH_LIBS(socketpair, socket)
 530
 531 # Link in zlib if we can.  This allows us to read compressed debug sections.
 532 AM_ZLIB
 533
 534 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 535 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 536 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 537   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 538             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 539
 540 AM_ICONV
 541
 542 # GDB may fork/exec the iconv program to get the list of supported character
 543 # sets.  Allow the user to specify where to find it.
 544 # There are several factors affecting the choice of option name:
 545 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 546 #   the build-time location of libiconv files.
 547 # - The program we need to find is iconv, which comes with glibc.  The user
 548 #   doesn't necessarily have libiconv installed.  Therefore naming this
 549 #   --with-libiconv-foo feels wrong.
 550 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 551 #   defined to work on directories not files (though it really doesn't know
 552 #   the difference).
 553 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 554 #   with --with-libiconv-prefix.
 555 # Putting these together is why the option name is --with-iconv-bin.
 556
 557 AC_ARG_WITH(iconv-bin,
 558 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 559 [iconv_bin="${withval}"
 560  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 561                     [Path of directory of iconv program.])
 562  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 563 ])
 564
 565 # For the TUI, we need enhanced curses functionality.
 566 if test x"$enable_tui" != xno; then
 567   prefer_curses=yes
 568 fi
 569
 570 curses_found=no
 571 if test x"$prefer_curses" = xyes; then
 572   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 573   # curses library because the latter might not provide all the
 574   # functionality we need.  However, this leads to problems on systems
 575   # where the linker searches /usr/local/lib, but the compiler doesn't
 576   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 577   # default installation of ncurses on alpha*-dec-osf* will lead to such
 578   # a situation.
 579   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 580
 581   if test "$ac_cv_search_waddstr" != no; then
 582     curses_found=yes
 583   fi
 584 fi
 585
 586 # Check whether we should enable the TUI, but only do so if we really
 587 # can.
 588 if test x"$enable_tui" != xno; then
 589   if test -d $srcdir/tui; then
 590     if test "$curses_found" != no; then
 591       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 592       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 593       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 594       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 595     else
 596       if test x"$enable_tui" = xyes; then
 597         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 598       else
 599         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 600       fi
 601     fi
 602   fi
 603 fi
 604
 605 # Since GDB uses Readline, we need termcap functionality.  In many
 606 # cases this will be provided by the curses library, but some systems
 607 # have a seperate termcap library, or no curses library at all.
 608
 609 case $host_os in
 610   cygwin*)
 611     if test -d $srcdir/libtermcap; then
 612       LIBS="../libtermcap/libtermcap.a $LIBS"
 613       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 614     fi ;;
 615   go32* | *djgpp*)
 616     ac_cv_search_tgetent="none required"
 617     ;;
 618 esac
 619
 620 # These are the libraries checked by Readline.
 621 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 622
 623 if test "$ac_cv_search_tgetent" = no; then
 624   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 625 fi
 626
 627 AC_ARG_WITH([system-readline],
 628   [AS_HELP_STRING([--with-system-readline],
 629                   [use installed readline library])])
 630
 631 if test "$with_system_readline" = yes; then
 632   READLINE=-lreadline
 633   READLINE_DEPS=
 634   READLINE_CFLAGS=
 635   READLINE_TEXI_INCFLAG=
 636 else
 637   READLINE='$(READLINE_DIR)/libreadline.a'
 638   READLINE_DEPS='$(READLINE)'
 639   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 640   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 641 fi
 642 AC_SUBST(READLINE)
 643 AC_SUBST(READLINE_DEPS)
 644 AC_SUBST(READLINE_CFLAGS)
 645 AC_SUBST(READLINE_TEXI_INCFLAG)
 646
 647 # Generate jit-reader.h
 648
 649 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 650 TARGET_PTR=
 651
 652 AC_CHECK_SIZEOF(unsigned long long)
 653 AC_CHECK_SIZEOF(unsigned long)
 654 AC_CHECK_SIZEOF(unsigned __int128)
 655
 656 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 657   TARGET_PTR="unsigned long"
 658 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 659   TARGET_PTR="unsigned long long"
 660 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 661   TARGET_PTR="unsigned __int128"
 662 else
 663   TARGET_PTR="unsigned long"
 664 fi
 665
 666 AC_SUBST(TARGET_PTR)
 667 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 668
 669 AC_SEARCH_LIBS(dlopen, dl)
 670
 671 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 672                 [directory to load the JIT readers from],
 673                 [${libdir}/gdb])
 674
 675 AC_ARG_WITH(expat,
 676   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 677   [], [with_expat=auto])
 678 AC_MSG_CHECKING([whether to use expat])
 679 AC_MSG_RESULT([$with_expat])
 680
 681 if test "${with_expat}" = no; then
 682   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 683   HAVE_LIBEXPAT=no
 684 else
 685   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 686                         [XML_Parser p = XML_ParserCreate (0);])
 687   if test "$HAVE_LIBEXPAT" != yes; then
 688     if test "$with_expat" = yes; then
 689       AC_MSG_ERROR([expat is missing or unusable])
 690     else
 691       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 692     fi
 693   else
 694     save_LIBS=$LIBS
 695     LIBS="$LIBS $LIBEXPAT"
 696     AC_CHECK_FUNCS(XML_StopParser)
 697     LIBS=$save_LIBS
 698   fi
 699 fi
 700
 701 # --------------------- #
 702 # Check for libpython.  #
 703 # --------------------- #
 704
 705 dnl Utility to simplify finding libpython.
 706 dnl $1 = pythonX.Y
 707 dnl $2 = the shell variable to assign the result to
 708 dnl      If libpython is found we store $version here.
 709 dnl $3 = additional flags to add to CPPFLAGS
 710 dnl $4 = additional flags to add to LIBS
 711
 712 AC_DEFUN([AC_TRY_LIBPYTHON],
 713 [
 714   version=$1
 715   define([have_libpython_var],$2)
 716   new_CPPFLAGS=$3
 717   new_LIBS=$4
 718   AC_MSG_CHECKING([for ${version}])
 719   save_CPPFLAGS=$CPPFLAGS
 720   save_LIBS=$LIBS
 721   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 722   LIBS="$LIBS $new_LIBS"
 723   found_usable_python=no
 724   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 725                                  [[Py_Initialize ();]]),
 726                  [have_libpython_var=${version}
 727                   found_usable_python=yes
 728                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 729                   PYTHON_LIBS=$new_LIBS])
 730   CPPFLAGS=$save_CPPFLAGS
 731   LIBS=$save_LIBS
 732   AC_MSG_RESULT([${found_usable_python}])
 733 ])
 734
 735 dnl There are several different values for --with-python:
 736 dnl
 737 dnl no -   Don't include python support.
 738 dnl yes -  Include python support, error if it's missing.
 739 dnl        If we find python in $PATH, use it to fetch configure options,
 740 dnl        otherwise assume the compiler can find it with no help from us.
 741 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 742 dnl auto - Same as "yes", but if python is missing from the system,
 743 dnl        fall back to "no".
 744 dnl /path/to/python/exec-prefix -
 745 dnl        Use the python located in this directory.
 746 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 747 dnl        the compilation parameters.  Otherwise use
 748 dnl        -I/path/to/python/exec-prefix/include,
 749 dnl        -L/path/to/python/exec-prefix/lib.
 750 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 751 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 752 dnl        but is deprecated.
 753 dnl /path/to/python/executable -
 754 dnl        Run python-config.py with this version of python to fetch the
 755 dnl        compilation parameters.
 756 dnl        NOTE: This needn't be the real python executable.
 757 dnl        In a cross-compilation scenario (build != host), this could be
 758 dnl        a shell script that provides what python-config.py provides for
 759 dnl        --ldflags, --includes, --exec-prefix.
 760 dnl python-executable -
 761 dnl        Find python-executable in $PATH, and then handle the same as
 762 dnl        /path/to/python/executable.
 763 dnl
 764 dnl If a python program is specified, it is used to run python-config.py and
 765 dnl is passed --ldflags, --includes, --exec-prefix.
 766
 767 AC_ARG_WITH(python,
 768   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 769   [], [with_python=auto])
 770 AC_MSG_CHECKING([whether to use python])
 771 AC_MSG_RESULT([$with_python])
 772
 773 if test "${with_python}" = no; then
 774   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 775   have_libpython=no
 776 else
 777   case "${with_python}" in
 778   [[\\/]]* | ?:[[\\/]]*)
 779     if test -d ${with_python}; then
 780       # Assume the python binary is ${with_python}/bin/python.
 781       python_prog="${with_python}/bin/python"
 782       python_prefix=
 783       # If python does not exit ${with_python}/bin, then try in
 784       # ${with_python}.  On Windows/MinGW, this is where the Python
 785       # executable is.
 786       if test ! -x "${python_prog}"; then
 787         python_prog="${with_python}/python"
 788         python_prefix=
 789       fi
 790       if test ! -x "${python_prog}"; then
 791         # Fall back to gdb 7.0/7.1 behaviour.
 792         python_prog=missing
 793         python_prefix=${with_python}
 794       fi
 795     elif test -x "${with_python}"; then
 796       # While we can't run python compiled for $host (unless host == build),
 797       # the user could write a script that provides the needed information,
 798       # so we support that.
 799       python_prog=${with_python}
 800       python_prefix=
 801     else
 802       AC_ERROR(invalid value for --with-python)
 803     fi
 804     ;;
 805   */*)
 806     # Disallow --with-python=foo/bar.
 807     AC_ERROR(invalid value for --with-python)
 808     ;;
 809   *)
 810     # The user has either specified auto, yes, or the name of the python
 811     # program assumed to be in $PATH.
 812     python_prefix=
 813     case "${with_python}" in
 814     yes | auto)
 815       if test ${build} = ${host}; then
 816         AC_PATH_PROG(python_prog_path, python, missing)
 817         if test "${python_prog_path}" = missing; then
 818           python_prog=missing
 819         else
 820           python_prog=${python_prog_path}
 821         fi
 822       else
 823         # Not much we can do except assume the cross-compiler will find the
 824         # right files.
 825         python_prog=missing
 826       fi
 827       ;;
 828     *)
 829       # While we can't run python compiled for $host (unless host == build),
 830       # the user could write a script that provides the needed information,
 831       # so we support that.
 832       python_prog="${with_python}"
 833       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 834       if test "${python_prog_path}" = missing; then
 835         AC_ERROR(unable to find python program ${python_prog})
 836       fi
 837       ;;
 838     esac
 839   esac
 840
 841   if test "${python_prog}" != missing; then
 842     # We have a python program to use, but it may be too old.
 843     # Don't flag an error for --with-python=auto (the default).
 844     have_python_config=yes
 845     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 846     if test $? != 0; then
 847       have_python_config=failed
 848       if test "${with_python}" != auto; then
 849         AC_ERROR(failure running python-config --includes)
 850       fi
 851     fi
 852     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 853     if test $? != 0; then
 854       have_python_config=failed
 855       if test "${with_python}" != auto; then
 856         AC_ERROR(failure running python-config --ldflags)
 857       fi
 858     fi
 859     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 860     if test $? != 0; then
 861       have_python_config=failed
 862       if test "${with_python}" != auto; then
 863         AC_ERROR(failure running python-config --exec-prefix)
 864       fi
 865     fi
 866   else
 867     # We do not have a python executable we can use to determine where
 868     # to find the Python headers and libs.  We cannot guess the include
 869     # path from the python_prefix either, because that include path
 870     # depends on the Python version.  So, there is nothing much we can
 871     # do except assume that the compiler will be able to find those files.
 872     python_includes=
 873     python_libs=
 874     have_python_config=no
 875   fi
 876
 877   # If we have python-config, only try the configuration it provides.
 878   # Otherwise fallback on the old way of trying different versions of
 879   # python in turn.
 880
 881   have_libpython=no
 882   if test "${have_python_config}" = yes; then
 883     # Determine the Python version by extracting "-lpython<version>"
 884     # part of the python_libs. <version> is usually X.Y with X and Y
 885     # being decimal numbers, but can also be XY (seen on Windows).
 886     #
 887     # The extraction is performed using sed with a regular expression.
 888     # Initially, the regexp used was using the '?' quantifier to make
 889     # the dot in the version number optional.  Unfortunately, this
 890     # does not work with non-GNU versions of sed because, because of
 891     # what looks like a limitation (the '?' quantifier does not work
 892     # with back-references).  We work around this limitation by using
 893     # the '*' quantifier instead.  It means that, in theory, we might
 894     # match unexpected version strings such as "-lpython2..7", but
 895     # this seems unlikely in practice.  And even if that happens,
 896     # an error will be triggered later on, when checking that version
 897     # number.
 898     python_version=`echo " ${python_libs} " \
 899                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 900     case "${python_version}" in
 901     python*)
 902       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 903                        ${python_includes}, ${python_libs})
 904       ;;
 905     *)
 906       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 907       ;;
 908     esac
 909   elif test "${have_python_config}" != failed; then
 910     if test "${have_libpython}" = no; then
 911       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 912                        ${python_includes}, "${python_libs} -lpython2.7")
 913     fi
 914     if test "${have_libpython}" = no; then
 915       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 916                        ${python_includes}, "${python_libs} -lpython2.6")
 917     fi
 918     if test ${have_libpython} = no; then
 919       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 920                        ${python_includes}, "${python_libs} -lpython2.5")
 921     fi
 922     if test ${have_libpython} = no; then
 923       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 924                        ${python_includes}, "${python_libs} -lpython2.4")
 925     fi
 926   fi
 927   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 928     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 929   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 930     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 931   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 933   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 935   fi
 936
 937   if test "${have_libpython}" = no; then
 938     case "${with_python}" in
 939     yes)
 940       AC_MSG_ERROR([python is missing or unusable])
 941       ;;
 942     auto)
 943       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 944       ;;
 945     *)
 946       AC_MSG_ERROR([no usable python found at ${with_python}])
 947       ;;
 948     esac
 949   else
 950     if test -n "${python_prefix}"; then
 951       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 952                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 953       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 954     fi
 955   fi
 956 fi
 957
 958 if test "${have_libpython}" != no; then
 959   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 960   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 961   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 962   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 963   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 964   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 965
 966   # Flags needed to compile Python code (taken from python-config --cflags).
 967   # We cannot call python-config directly because it will output whatever was
 968   # used when compiling the Python interpreter itself, including flags which
 969   # would make the python-related objects be compiled differently from the
 970   # rest of GDB (e.g., -O2 and -fPIC).
 971   if test "${GCC}" = yes; then
 972     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 973   fi
 974
 975   if test "x${tentative_python_cflags}" != x; then
 976     AC_MSG_CHECKING(compiler flags for python code)
 977     for flag in ${tentative_python_cflags}; do
 978       # Check that the compiler accepts it
 979       saved_CFLAGS="$CFLAGS"
 980       CFLAGS="$CFLAGS $flag"
 981       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 982       CFLAGS="$saved_CFLAGS"
 983     done
 984     AC_MSG_RESULT(${PYTHON_CFLAGS})
 985   fi
 986
 987   # On x64 Windows, Python's include headers, and pyconfig.h in
 988   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 989   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 990   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 991   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 992   # The issue was reported to the Python community, but still isn't
 993   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 994
 995   case "$gdb_host" in
 996     mingw64)
 997            if test "${GCC}" = yes; then
 998              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 999            fi
1000            ;;
1001   esac
1002
1003   # Note that "python -m threading" cannot be used to check for
1004   # threading support due to a bug in Python 2.7.3
1005   # (http://bugs.python.org/issue15567).
1006   AC_MSG_CHECKING(whether python supports threads)
1007   saved_CPPFLAGS="${CPPFLAGS}"
1008   CPPFLAGS="${PYTHON_CPPFLAGS}"
1009   # Note that the test is reversed so that python_has_threads=yes on
1010   # unexpected failures.
1011   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1012 #include <Python.h>
1013 #ifdef WITH_THREAD
1014 # error
1015 #endif
1016   ]]), [python_has_threads=no], [python_has_threads=yes])
1017   AC_MSG_RESULT(${python_has_threads})
1018   CPPFLAGS="${saved_CPPFLAGS}"
1019 else
1020   # Even if Python support is not compiled in, we need to have this file
1021   # included so that the "python" command, et.al., still exists.
1022   CONFIG_OBS="$CONFIG_OBS python.o"
1023   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1024 fi
1025
1026 # Work around Python http://bugs.python.org/issue10112.  See also
1027 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1028 # no effect.  Note that the only test after this that uses Python is
1029 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1030 # run without -export-dynamic too.
1031 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1032
1033 AC_SUBST(PYTHON_CFLAGS)
1034 AC_SUBST(PYTHON_CPPFLAGS)
1035 AC_SUBST(PYTHON_LIBS)
1036 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1037
1038 # -------------------- #
1039 # Check for libguile.  #
1040 # -------------------- #
1041
1042 dnl Utility to simplify finding libguile.
1043 dnl $1 = pkg-config-program
1044 dnl $2 = space-separate list of guile versions to try
1045 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1046 dnl $4 = the shell variable to assign the result to
1047 dnl      If libguile is found we store "yes" here.
1048
1049 AC_DEFUN([AC_TRY_LIBGUILE],
1050 [
1051   pkg_config=$1
1052   guile_version_list=$2
1053   flag_errors=$3
1054   define([have_libguile_var],$4)
1055   found_usable_guile=checking
1056   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1057   for guile_version in ${guile_version_list}; do
1058     ${pkg_config} --exists ${guile_version} 2>/dev/null
1059     if test $? != 0; then
1060       continue
1061     fi
1062     dnl pkg-config says the package exists, so if we get an error now,
1063     dnl that's bad.
1064     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1065     if test $? != 0; then
1066       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1067     fi
1068     new_LIBS=`${pkg_config} --libs ${guile_version}`
1069     if test $? != 0; then
1070       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1071     fi
1072     dnl If we get this far, great.
1073     found_usable_guile=${guile_version}
1074     break
1075   done
1076   if test "${found_usable_guile}" = "checking"; then
1077     if test "${flag_errors}" = "yes"; then
1078       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1079     else
1080       found_usable_guile=no
1081     fi
1082   fi
1083   dnl One final sanity check.
1084   dnl The user could have said --with-guile=python-2.7.
1085   if test "${found_usable_guile}" != no; then
1086     save_CPPFLAGS=$CPPFLAGS
1087     save_LIBS=$LIBS
1088     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1089     LIBS="$LIBS $new_LIBS"
1090     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1091                                    [[scm_init_guile ();]]),
1092                    [have_libguile_var=yes
1093                     GUILE_CPPFLAGS=$new_CPPFLAGS
1094                     GUILE_LIBS=$new_LIBS],
1095                    [found_usable_guile=no])
1096     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1097     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1098       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1099                 [Define if Guile supports manual finalization.])
1100     )
1101     CPPFLAGS=$save_CPPFLAGS
1102     LIBS=$save_LIBS
1103     if test "${found_usable_guile}" = no; then
1104       if test "${flag_errors}" = yes; then
1105         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1106       fi
1107     fi
1108   fi
1109   AC_MSG_RESULT([${found_usable_guile}])
1110 ])
1111
1112 dnl There are several different values for --with-guile:
1113 dnl
1114 dnl no -   Don't include guile support.
1115 dnl yes -  Include guile support, error if it's missing.
1116 dnl        The pkg-config program must be in $PATH.
1117 dnl auto - Same as "yes", but if guile is missing from the system,
1118 dnl        fall back to "no".
1119 dnl guile-version [guile-version-choice-2 ...] -
1120 dnl        A space-separated list of guile package versions to try.
1121 dnl        These are passed to pkg-config as-is.
1122 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1123 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1124 dnl /path/to/pkg-config -
1125 dnl        Use this pkg-config program.
1126 dnl        NOTE: This needn't be the "real" pkg-config program.
1127 dnl        It could be a shell script.  It is invoked as:
1128 dnl        pkg-config --exists $version
1129 dnl        pkg-config --cflags $version
1130 dnl        pkg-config --libs $version
1131 dnl        pkg-config --variable guild $version
1132 dnl        The script will be called with $version having each value in
1133 dnl        $try_guile_versions until --exists indicates success.
1134
1135 AC_ARG_WITH(guile,
1136   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1137   [], [with_guile=auto])
1138 AC_MSG_CHECKING([whether to use guile])
1139 AC_MSG_RESULT([$with_guile])
1140
1141 dnl We check guile with pkg-config.
1142 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1143
1144 try_guile_versions="guile-2.2 guile-2.0"
1145 have_libguile=no
1146 case "${with_guile}" in
1147 no)
1148   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1149   ;;
1150 auto)
1151   if test "${pkg_config_prog_path}" = "missing"; then
1152     AC_MSG_WARN([pkg-config not found, guile support disabled])
1153   else
1154     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1155   fi
1156   ;;
1157 yes)
1158   if test "${pkg_config_prog_path}" = "missing"; then
1159     AC_MSG_ERROR([pkg-config not found])
1160   fi
1161   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1162   ;;
1163 [[\\/]]* | ?:[[\\/]]*)
1164   if test -x "${with_guile}"; then
1165     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1166   else
1167     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1168   fi
1169   ;;
1170 "" | */*)
1171   # Disallow --with=guile="" and --with-guile=foo/bar.
1172   AC_MSG_ERROR([invalid value for --with-guile])
1173   ;;
1174 *)
1175   # A space separate list of guile versions to try, in order.
1176   if test "${pkg_config_prog_path}" = "missing"; then
1177     AC_MSG_ERROR([pkg-config not found])
1178   fi
1179   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1180   ;;
1181 esac
1182
1183 if test "${have_libguile}" != no; then
1184   dnl Get the name of the 'guild' program.
1185   case "${with_guile}" in
1186   [[\\/]]* | ?:[[\\/]]*)
1187     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1188     ;;
1189   *)
1190     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1191     ;;
1192   esac
1193
1194   dnl Make sure guild can handle this host.
1195   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1196   dnl If not, disable guile support.
1197   if test "$ac_cv_guild_ok" = no; then
1198     have_libguile=no
1199     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1200   fi
1201 fi
1202
1203 if test "${have_libguile}" != no; then
1204   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1205   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1206   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1207   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1208   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1209   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1210
1211   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1212   save_LIBS="$LIBS"
1213   save_CPPFLAGS="$CPPFLAGS"
1214   LIBS="$GUILE_LIBS"
1215   CPPFLAGS="$GUILE_CPPFLAGS"
1216   AC_CHECK_FUNCS([scm_new_smob])
1217   LIBS="$save_LIBS"
1218   CPPFLAGS="$save_CPPFLAGS"
1219 else
1220   # Even if Guile support is not compiled in, we need to have these files
1221   # included.
1222   CONFIG_OBS="$CONFIG_OBS guile.o"
1223   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1224 fi
1225 AC_SUBST(GUILE_CPPFLAGS)
1226 AC_SUBST(GUILE_LIBS)
1227 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1228
1229 # --------------------- #
1230 # Check for libmcheck.  #
1231 # --------------------- #
1232
1233 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1234 # but turn it off if Python is enabled with threads, since -lmcheck is
1235 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1236 # and for releases.
1237 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1238    && $development; then
1239   libmcheck_default=yes
1240 else
1241   libmcheck_default=no
1242 fi
1243 GDB_AC_LIBMCHECK(${libmcheck_default})
1244
1245 if test "$ENABLE_LIBMCHECK" = "yes" \
1246         -a "${have_libpython}" != "no" \
1247         -a "${python_has_threads}" = "yes" ; then
1248   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1249 fi
1250
1251 AC_ARG_WITH(intel_pt,
1252   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1253   [], [with_intel_pt=auto])
1254 AC_MSG_CHECKING([whether to use intel pt])
1255 AC_MSG_RESULT([$with_intel_pt])
1256
1257 if test "${with_intel_pt}" = no; then
1258   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1259   HAVE_LIBIPT=no
1260 else
1261   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1262 #include <linux/perf_event.h>
1263 #ifndef PERF_ATTR_SIZE_VER5
1264 # error
1265 #endif
1266   ]]), [perf_event=yes], [perf_event=no])
1267   if test "$perf_event" != yes; then
1268     if test "$with_intel_pt" = yes; then
1269       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1270     else
1271       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1272     fi
1273   fi
1274
1275   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1276   if test "$HAVE_LIBIPT" != yes; then
1277     if test "$with_intel_pt" = yes; then
1278       AC_MSG_ERROR([libipt is missing or unusable])
1279     else
1280       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1281     fi
1282   fi
1283 fi
1284
1285 # ------------------------- #
1286 # Checks for header files.  #
1287 # ------------------------- #
1288
1289 AC_HEADER_STDC
1290 # elf_hp.h is for HP/UX 64-bit shared library support.
1291 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1292                   thread_db.h \
1293                   sys/fault.h \
1294                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1295                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1296                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1297                   termios.h termio.h \
1298                   sgtty.h elf_hp.h \
1299                   dlfcn.h])
1300 AC_CHECK_HEADERS(sys/proc.h, [], [],
1301 [#if HAVE_SYS_PARAM_H
1302 # include <sys/param.h>
1303 #endif
1304 ])
1305 AC_CHECK_HEADERS(sys/user.h, [], [],
1306 [#if HAVE_SYS_PARAM_H
1307 # include <sys/param.h>
1308 #endif
1309 ])
1310
1311 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1312 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1313 # think that we don't have <curses.h> if we're using GCC.
1314 case $host_os in
1315   solaris2.[[789]])
1316     if test "$GCC" = yes; then
1317       AC_DEFINE(_MSE_INT_H, 1,
1318         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1319    Solaris 2.[789] when using GCC. ])
1320     fi ;;
1321 esac
1322 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1323 AC_CHECK_HEADERS(term.h, [], [],
1324 [#if HAVE_CURSES_H
1325 # include <curses.h>
1326 #endif
1327 ])
1328
1329 # ------------------------- #
1330 # Checks for declarations.  #
1331 # ------------------------- #
1332
1333 libiberty_INIT
1334
1335 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1336 AM_LC_MESSAGES
1337
1338 # ----------------------- #
1339 # Checks for structures.  #
1340 # ----------------------- #
1341
1342 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1343
1344 # ------------------ #
1345 # Checks for types.  #
1346 # ------------------ #
1347
1348 AC_CHECK_TYPES(socklen_t, [], [],
1349 [#include <sys/types.h>
1350 #include <sys/socket.h>
1351 ])
1352
1353 # ------------------------------------- #
1354 # Checks for compiler characteristics.  #
1355 # ------------------------------------- #
1356
1357 AC_C_CONST
1358 AC_C_INLINE
1359 AC_C_BIGENDIAN
1360
1361 # ------------------------------ #
1362 # Checks for library functions.  #
1363 # ------------------------------ #
1364
1365 AC_FUNC_MMAP
1366 AC_FUNC_VFORK
1367 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1368                 pipe poll pread pread64 pwrite resize_term \
1369                 sbrk setpgid setpgrp setsid \
1370                 sigaction sigprocmask sigsetmask socketpair \
1371                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1372                 setrlimit getrlimit posix_madvise waitpid \
1373                 ptrace64 sigaltstack mkdtemp setns])
1374 AM_LANGINFO_CODESET
1375 GDB_AC_COMMON
1376
1377 # Check the return and argument types of ptrace.
1378 GDB_AC_PTRACE
1379
1380 dnl AC_FUNC_SETPGRP does not work when cross compiling
1381 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1382 if test "$cross_compiling" = no; then
1383   AC_FUNC_SETPGRP
1384 else
1385   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1386     [AC_TRY_COMPILE([
1387 #include <unistd.h>
1388 ], [
1389   if (setpgrp(1,1) == -1)
1390     exit (0);
1391   else
1392     exit (1);
1393 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1394 if test $ac_cv_func_setpgrp_void = yes; then
1395   AC_DEFINE(SETPGRP_VOID, 1)
1396 fi
1397 fi
1398
1399 # Assume we'll default to using the included libiberty regex.
1400 gdb_use_included_regex=yes
1401
1402 # However, if the system regex is GNU regex, then default to *not*
1403 # using the included regex.
1404 AC_CACHE_CHECK(
1405   [for GNU regex],
1406   [gdb_cv_have_gnu_regex],
1407   [AC_TRY_COMPILE(
1408     [#include <gnu-versions.h>],
1409     [#define REGEX_INTERFACE_VERSION 1
1410 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1411 # error "Version mismatch"
1412 #endif],
1413     gdb_cv_have_gnu_regex=yes,
1414     gdb_cv_have_gnu_regex=no)])
1415 if test $gdb_cv_have_gnu_regex = yes; then
1416   gdb_use_included_regex=no
1417 fi
1418
1419 AC_ARG_WITH(included-regex,
1420   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1421   gdb_with_regex=$withval,
1422   gdb_with_regex=$gdb_use_included_regex)
1423 if test "$gdb_with_regex" = yes; then
1424   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1425     [Define to 1 if the regex included in libiberty should be used.])
1426 fi
1427
1428 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1429 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1430 [#include <sys/param.h>
1431 #include <sys/proc.h>
1432 ])
1433
1434 # See if <sys/lwp.h> defines `struct lwp`.
1435 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1436 [AC_TRY_COMPILE([#include <sys/param.h>
1437 #include <sys/lwp.h>], [struct lwp l;],
1438 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1439 if test $gdb_cv_struct_lwp = yes; then
1440   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1441             [Define to 1 if your system has struct lwp.])
1442 fi
1443
1444 # See if <machine/reg.h> degines `struct reg'.
1445 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1446 [AC_TRY_COMPILE([#include <sys/types.h>
1447 #include <machine/reg.h>], [struct reg r;],
1448 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1449 if test $gdb_cv_struct_reg = yes; then
1450   AC_DEFINE(HAVE_STRUCT_REG, 1,
1451             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1452 fi
1453
1454 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1455 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1456 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1457                  [#include <sys/types.h>
1458 #include <machine/reg.h>])
1459
1460 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1461 # Older amd64 Linux's don't have the fs_base and gs_base members of
1462 # `struct user_regs_struct'.
1463 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1464                  [], [], [#include <sys/user.h>])
1465
1466 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1467 AC_MSG_CHECKING(for PTRACE_GETREGS)
1468 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1469 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1470                 [PTRACE_GETREGS;],
1471                 [gdb_cv_have_ptrace_getregs=yes],
1472                 [gdb_cv_have_ptrace_getregs=no])])
1473 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1474 if test $gdb_cv_have_ptrace_getregs = yes; then
1475   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1476   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1477 fi
1478
1479 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1480 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1481 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1482 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1483                 [PTRACE_GETFPXREGS;],
1484                 [gdb_cv_have_ptrace_getfpxregs=yes],
1485                 [gdb_cv_have_ptrace_getfpxregs=no])])
1486 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1487 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1488   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1489   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1490 fi
1491
1492 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1493 AC_MSG_CHECKING(for PT_GETDBREGS)
1494 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1495 [AC_TRY_COMPILE([#include <sys/types.h>
1496 #include <sys/ptrace.h>],
1497                 [PT_GETDBREGS;],
1498                 [gdb_cv_have_pt_getdbregs=yes],
1499                 [gdb_cv_have_pt_getdbregs=no])])
1500 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1501 if test $gdb_cv_have_pt_getdbregs = yes; then
1502   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1503   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1504 fi
1505
1506 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1507 AC_MSG_CHECKING(for PT_GETXMMREGS)
1508 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1509 [AC_TRY_COMPILE([#include <sys/types.h>
1510 #include <sys/ptrace.h>],
1511                 [PT_GETXMMREGS;],
1512                 [gdb_cv_have_pt_getxmmregs=yes],
1513                 [gdb_cv_have_pt_getxmmregs=no])])
1514 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1515 if test $gdb_cv_have_pt_getxmmregs = yes; then
1516   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1517   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1518 fi
1519
1520 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1521 # Older FreeBSD versions don't have the pl_tdname member of
1522 # `struct ptrace_lwpinfo'.
1523 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1524                  [#include <sys/ptrace.h>])
1525
1526 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1527 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1528 # FreeBSD 10.3.
1529 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1530                  [#include <sys/ptrace.h>])
1531
1532 # Detect which type of /proc is in use, such as for Solaris.
1533
1534 if test "${target}" = "${host}"; then
1535   case "${host}" in
1536   *-*-sysv4.2* | *-*-sysv5* )
1537       AC_DEFINE(NEW_PROC_API, 1,
1538       [Define if you want to use new multi-fd /proc interface.])
1539       ;;
1540   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1541       AC_DEFINE(NEW_PROC_API, 1,
1542       [Define if you want to use new multi-fd /proc interface.])
1543       ;;
1544   mips-sgi-irix5*)
1545       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1546       AC_DEFINE([_KMEMUSER], 1,
1547       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1548        around a <sys/proc.h> problem on IRIX 5.])
1549       ;;
1550   esac
1551 fi
1552
1553 if test "$ac_cv_header_sys_procfs_h" = yes; then
1554   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1555   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1556   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1557   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1558   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1559   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1560   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1561   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1562   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1563   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1564   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1565
1566
1567   dnl Check for broken prfpregset_t type
1568
1569   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1570   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1571   dnl instead of the struct itself).  We detect this here, and work
1572   dnl around it in gdb_proc_service.h.
1573
1574   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1575     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1576     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1577       [AC_TRY_RUN([#include <sys/procfs.h>
1578        int main ()
1579        {
1580          if (sizeof (prfpregset_t) == sizeof (void *))
1581            return 1;
1582          return 0;
1583        }],
1584        gdb_cv_prfpregset_t_broken=no,
1585        gdb_cv_prfpregset_t_broken=yes,
1586        gdb_cv_prfpregset_t_broken=yes)])
1587     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1588     if test $gdb_cv_prfpregset_t_broken = yes; then
1589       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1590       [Define if the prfpregset_t type is broken.])
1591     fi
1592   fi
1593 fi
1594
1595 # Check if the compiler supports the `long long' type.
1596
1597 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1598                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1599 [[extern long long foo;]],
1600 [[switch (foo & 2) { case 0: return 1; }]])],
1601                                   gdb_cv_c_long_long=yes,
1602                                   gdb_cv_c_long_long=no)])
1603 if test $gdb_cv_c_long_long != yes; then
1604   # libdecnumber requires long long.
1605   AC_MSG_ERROR([Compiler must support long long for GDB.])
1606 fi
1607
1608 # Check if the compiler and runtime support printing long longs.
1609
1610 AC_CACHE_CHECK([for long long support in printf],
1611                gdb_cv_printf_has_long_long,
1612                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1613 [[char buf[32];
1614   long long l = 0;
1615   l = (l << 16) + 0x0123;
1616   l = (l << 16) + 0x4567;
1617   l = (l << 16) + 0x89ab;
1618   l = (l << 16) + 0xcdef;
1619   sprintf (buf, "0x%016llx", l);
1620   return (strcmp ("0x0123456789abcdef", buf));]])],
1621                               gdb_cv_printf_has_long_long=yes,
1622                               gdb_cv_printf_has_long_long=no,
1623                               gdb_cv_printf_has_long_long=no)])
1624 if test $gdb_cv_printf_has_long_long = yes; then
1625   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1626             [Define to 1 if the "%ll" format works to print long longs.])
1627 fi
1628
1629 # Check if the compiler and runtime support printing decfloats.
1630
1631 AC_CACHE_CHECK([for decfloat support in printf],
1632                gdb_cv_printf_has_decfloat,
1633                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1634 [[char buf[64];
1635   _Decimal32 d32 = 1.2345df;
1636   _Decimal64 d64 = 1.2345dd;
1637   _Decimal128 d128 = 1.2345dl;
1638   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1639   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1640                               gdb_cv_printf_has_decfloat=yes,
1641                               gdb_cv_printf_has_decfloat=no,
1642                               gdb_cv_printf_has_decfloat=no)])
1643 if test $gdb_cv_printf_has_decfloat = yes; then
1644   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1645             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1646 fi
1647
1648 # Check if the compiler supports the `long double' type.  We can't use
1649 # AC_C_LONG_DOUBLE because that one does additional checks on the
1650 # constants defined in <float.h> that fail on some systems,
1651 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1652
1653 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1654                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1655                                   gdb_cv_c_long_double=yes,
1656                                   gdb_cv_c_long_double=no)])
1657 if test $gdb_cv_c_long_double = yes; then
1658   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1659            [Define to 1 if the compiler supports long double.])
1660 fi
1661
1662 # Check if the compiler and runtime support printing long doubles.
1663
1664 AC_CACHE_CHECK([for long double support in printf],
1665                gdb_cv_printf_has_long_double,
1666                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1667 [[char buf[16];
1668   long double f = 3.141592653;
1669   sprintf (buf, "%Lg", f);
1670   return (strncmp ("3.14159", buf, 7));]])],
1671                               gdb_cv_printf_has_long_double=yes,
1672                               gdb_cv_printf_has_long_double=no,
1673                               gdb_cv_printf_has_long_double=no)])
1674 if test $gdb_cv_printf_has_long_double = yes; then
1675   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1676             [Define to 1 if the "%Lg" format works to print long doubles.])
1677 fi
1678
1679 # Check if the compiler and runtime support scanning long doubles.
1680
1681 AC_CACHE_CHECK([for long double support in scanf],
1682                gdb_cv_scanf_has_long_double,
1683                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1684 [[#include <stdio.h>]],
1685 [[char *buf = "3.141592653";
1686   long double f = 0;
1687   sscanf (buf, "%Lg", &f);
1688   return !(f > 3.14159 && f < 3.14160);]])],
1689                               gdb_cv_scanf_has_long_double=yes,
1690                               gdb_cv_scanf_has_long_double=no,
1691                               gdb_cv_scanf_has_long_double=no)])
1692 if test $gdb_cv_scanf_has_long_double = yes; then
1693   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1694             [Define to 1 if the "%Lg" format works to scan long doubles.])
1695 fi
1696
1697 case ${host_os} in
1698 aix*)
1699   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1700     SAVE_LDFLAGS=$LDFLAGS
1701
1702     case $GCC in
1703     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1704     *) gdb_cv_bigtoc=-bbigtoc ;;
1705     esac
1706
1707     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1708     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1709     LDFLAGS="${SAVE_LDFLAGS}"
1710   ])
1711   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1712   ;;
1713 esac
1714
1715 AC_MSG_CHECKING(for the dynamic export flag)
1716 dynamic_list=false
1717 if test "${gdb_native}" = yes; then
1718    # The dynamically loaded libthread_db needs access to symbols in the gdb
1719    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1720    # may not be supported there.
1721    old_LDFLAGS="$LDFLAGS"
1722    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1723    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1724    LDFLAGS="$LDFLAGS $RDYNAMIC"
1725    if test "${have_libpython}" = no; then
1726      AC_TRY_LINK([], [], [dynamic_list=true])
1727    else
1728      # Workaround http://bugs.python.org/issue4434 where static
1729      # libpythonX.Y.a would get its symbols required for
1730      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1731      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1732
1733      # Note the workaround for Python
1734      # http://bugs.python.org/issue10112 earlier has removed
1735      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1736      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1737      # always pass.
1738      old_CFLAGS="$CFLAGS"
1739      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1740      old_LIBS="$LIBS"
1741      LIBS="$LIBS $PYTHON_LIBS"
1742      old_CPPFLAGS="$CPPFLAGS"
1743      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1744      AC_RUN_IFELSE(
1745        AC_LANG_PROGRAM(
1746          [#include "Python.h"],
1747          [int err;
1748           Py_Initialize ();
1749           err = PyRun_SimpleString ("import itertools\n");
1750           Py_Finalize ();
1751           return err == 0 ? 0 : 1;]),
1752        [dynamic_list=true], [], [true])
1753      LIBS="$old_LIBS"
1754      CFLAGS="$old_CFLAGS"
1755      CPPFLAGS="$old_CPPFLAGS"
1756    fi
1757    LDFLAGS="$old_LDFLAGS"
1758 fi
1759 if $dynamic_list; then
1760   found="-Wl,--dynamic-list"
1761   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1762 else
1763   found="-rdynamic"
1764   RDYNAMIC="-rdynamic"
1765 fi
1766 AC_SUBST(RDYNAMIC)
1767 AC_MSG_RESULT($found)
1768
1769 dnl For certain native configurations, we need to check whether thread
1770 dnl support can be built in or not.
1771 dnl
1772 dnl Note that we only want this if we are both native (host == target),
1773 dnl and not doing a canadian cross build (build == host).
1774
1775 if test ${build} = ${host} -a ${host} = ${target} ; then
1776    case ${host_os} in
1777    solaris*)
1778       # See if thread_db library is around for Solaris thread debugging.
1779       # Note that we must explicitly test for version 1 of the library
1780       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1781       # the same API.
1782       AC_MSG_CHECKING(for Solaris thread debugging library)
1783       if test -f /usr/lib/libthread_db.so.1 ; then
1784          AC_MSG_RESULT(yes)
1785          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1786          [Define if using Solaris thread debugging.])
1787          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1788          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1789          AC_CHECK_LIB(dl, dlopen)
1790          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1791          # Sun randomly tweaked the prototypes in <proc_service.h>
1792          # at one point.
1793          AC_MSG_CHECKING(if <proc_service.h> is old)
1794          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1795             AC_TRY_COMPILE([
1796                 #include <proc_service.h>
1797                 ps_err_e ps_pdwrite
1798                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1799             ],, gdb_cv_proc_service_is_old=no,
1800                 gdb_cv_proc_service_is_old=yes)
1801          ])
1802          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1803          if test $gdb_cv_proc_service_is_old = yes; then
1804             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1805             [Define if <proc_service.h> on solaris uses int instead of
1806              size_t, and assorted other type changes.])
1807          fi
1808       else
1809          AC_MSG_RESULT(no)
1810       fi
1811       ;;
1812    aix*)
1813       AC_MSG_CHECKING(for AiX thread debugging library)
1814       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1815                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1816                                    [#ifndef PTHDB_VERSION_3
1817                                     #error
1818                                     #endif],
1819                                    gdb_cv_have_aix_thread_debug=yes,
1820                                    gdb_cv_have_aix_thread_debug=no)])
1821       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1822       if test $gdb_cv_have_aix_thread_debug = yes; then
1823          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1824          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1825          LIBS="$LIBS -lpthdebug"
1826
1827          # Older versions of AIX do not provide the declaration for
1828          # the getthrds function (it appears that it was introduced
1829          # with AIX 6.x).
1830          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1831       fi
1832       ;;
1833    esac
1834    AC_SUBST(CONFIG_LDFLAGS)
1835 fi
1836
1837 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1838 dnl other error codes.
1839 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1840    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1841                   gdb_cv_thread_db_h_has_td_notalloc,
1842      AC_TRY_COMPILE(
1843        [#include <thread_db.h>],
1844        [int i = TD_NOTALLOC;],
1845        gdb_cv_thread_db_h_has_td_notalloc=yes,
1846        gdb_cv_thread_db_h_has_td_notalloc=no
1847      )
1848    )
1849    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1850                   gdb_cv_thread_db_h_has_td_version,
1851      AC_TRY_COMPILE(
1852        [#include <thread_db.h>],
1853        [int i = TD_VERSION;],
1854        gdb_cv_thread_db_h_has_td_version=yes,
1855        gdb_cv_thread_db_h_has_td_version=no
1856      )
1857    )
1858    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1859                   gdb_cv_thread_db_h_has_td_notls,
1860      AC_TRY_COMPILE(
1861        [#include <thread_db.h>],
1862        [int i = TD_NOTLS;],
1863        gdb_cv_thread_db_h_has_td_notls=yes,
1864        gdb_cv_thread_db_h_has_td_notls=no
1865      )
1866    )
1867 fi
1868 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1869   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1870             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1871 fi
1872 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1873   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1874             [Define if <thread_db.h> has the TD_VERSION error code.])
1875 fi
1876 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1877   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1878             [Define if <thread_db.h> has the TD_NOTLS error code.])
1879 fi
1880
1881 dnl Check if we can disable the virtual address space randomization.
1882 dnl The functionality of setarch -R.
1883 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1884 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1885 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1886 #       define ADDR_NO_RANDOMIZE 0x0040000
1887 #      endif
1888        /* Test the flag could be set and stays set.  */
1889        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1890        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1891            return 1])])
1892 AC_RUN_IFELSE([PERSONALITY_TEST],
1893               [have_personality=true],
1894               [have_personality=false],
1895               [AC_LINK_IFELSE([PERSONALITY_TEST],
1896                               [have_personality=true],
1897                               [have_personality=false])])
1898 if $have_personality
1899 then
1900     AC_DEFINE([HAVE_PERSONALITY], 1,
1901               [Define if you support the personality syscall.])
1902 fi
1903
1904 dnl Set the host's .gdbinit filename.
1905 case $host_os in
1906   go32* | *djgpp*)
1907     gdbinit=gdb.ini
1908     ;;
1909   *)
1910     gdbinit=.gdbinit
1911     ;;
1912 esac
1913 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1914
1915 dnl Handle optional features that can be enabled.
1916
1917 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1918 # except that the argument to --with-sysroot is optional.
1919 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1920 if test "x$with_sysroot" = xyes; then
1921   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1922 fi
1923 AC_ARG_WITH(sysroot,
1924   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1925                  [search for usr/lib et al within DIR]),
1926   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1927 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1928               [search for usr/lib et al within DIR])
1929 AC_SUBST(TARGET_SYSTEM_ROOT)
1930 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1931
1932 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1933     [automatically load a system-wide gdbinit file],
1934     [])
1935
1936 AM_GDB_WARNINGS
1937
1938 # In the Cygwin environment, we need some additional flags.
1939 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1940 [AC_EGREP_CPP(^lose$, [
1941 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1942 lose
1943 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1944
1945
1946 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1947 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1948 case ${host} in
1949   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1950   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1951   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1952 esac
1953 AC_SUBST(SER_HARDWIRE)
1954
1955 # libreadline needs libuser32.a in a cygwin environment
1956 WIN32LIBS=
1957 if test x$gdb_cv_os_cygwin = xyes; then
1958     WIN32LIBS="-luser32"
1959     case "${target}" in
1960         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1961         ;;
1962     esac
1963 fi
1964
1965 # The ser-tcp.c module requires sockets.
1966 case ${host} in
1967   *mingw32*)
1968     AC_DEFINE(USE_WIN32API, 1,
1969               [Define if we should use the Windows API, instead of the
1970                POSIX API.  On Windows, we use the Windows API when
1971                building for MinGW, but the POSIX API when building
1972                for Cygwin.])
1973     WIN32LIBS="$WIN32LIBS -lws2_32"
1974     ;;
1975 esac
1976 AC_SUBST(WIN32LIBS)
1977
1978 # Add ELF support to GDB, but only if BFD includes ELF support.
1979 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1980                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1981 if test $gdb_cv_var_elf = yes; then
1982   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1983   AC_DEFINE(HAVE_ELF, 1,
1984             [Define if ELF support should be included.])
1985   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1986   if test "$plugins" = "yes"; then
1987     AC_SEARCH_LIBS(dlopen, dl)
1988   fi
1989 fi
1990
1991 # Add macho support to GDB, but only if BFD includes it.
1992 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1993                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1994 if test $gdb_cv_var_macho = yes; then
1995   CONFIG_OBS="$CONFIG_OBS machoread.o"
1996 fi
1997
1998 # Add any host-specific objects to GDB.
1999 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2000
2001 # If building on ELF, look for lzma support for embedded compressed debug info.
2002 if test $gdb_cv_var_elf = yes; then
2003   AC_ARG_WITH(lzma,
2004     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2005     [], [with_lzma=auto])
2006   AC_MSG_CHECKING([whether to use lzma])
2007   AC_MSG_RESULT([$with_lzma])
2008
2009   if test "${with_lzma}" != no; then
2010     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2011                           [lzma_index_iter iter;
2012                            lzma_index_iter_init (&iter, 0);
2013                            lzma_mf_is_supported (LZMA_MF_HC3);])
2014     if test "$HAVE_LIBLZMA" != yes; then
2015       if test "$with_lzma" = yes; then
2016         AC_MSG_ERROR([missing liblzma for --with-lzma])
2017       fi
2018     fi
2019   fi
2020 fi
2021
2022 LIBGUI="../libgui/src/libgui.a"
2023 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2024 AC_SUBST(LIBGUI)
2025 AC_SUBST(GUI_CFLAGS_X)
2026
2027 WIN32LDAPP=
2028 AC_SUBST(WIN32LIBS)
2029 AC_SUBST(WIN32LDAPP)
2030
2031 case "${host}" in
2032 *-*-cygwin* | *-*-mingw* )
2033     configdir="win"
2034     ;;
2035 *)
2036     configdir="unix"
2037     ;;
2038 esac
2039
2040 GDBTKLIBS=
2041 if test "${enable_gdbtk}" = "yes"; then
2042
2043     # Gdbtk must have an absolute path to srcdir in order to run
2044     # properly when not installed.
2045     here=`pwd`
2046     cd ${srcdir}
2047     GDBTK_SRC_DIR=`pwd`
2048     cd $here
2049
2050     SC_PATH_TCLCONFIG
2051
2052     # If $no_tk is nonempty, then we can't do Tk, and there is no
2053     # point to doing Tcl.
2054     SC_PATH_TKCONFIG
2055
2056     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2057         SC_LOAD_TCLCONFIG
2058
2059         # Check for in-tree tcl
2060         here=`pwd`
2061         cd ${srcdir}/..
2062         topdir=`pwd`
2063         cd ${here}
2064
2065         intree="no"
2066         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2067           intree="yes"
2068         fi
2069
2070         # Find Tcl private headers
2071         if test x"${intree}" = xno; then
2072           CY_AC_TCL_PRIVATE_HEADERS
2073           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2074           TCL_LIBRARY="${TCL_LIB_SPEC}"
2075           TCL_DEPS=""
2076         else
2077           # If building tcl in the same src tree, private headers
2078           # are not needed, but we need to be sure to use the right
2079           # headers library
2080           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2081           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2082           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2083         fi
2084         AC_SUBST(TCL_INCLUDE)
2085         AC_SUBST(TCL_LIBRARY)
2086         AC_SUBST(TCL_DEPS)
2087
2088         SC_LOAD_TKCONFIG
2089
2090         # Check for in-tree Tk
2091         intree="no"
2092         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2093           intree="yes"
2094         fi
2095
2096         # Find Tk private headers
2097         if test x"${intree}" = xno; then
2098           CY_AC_TK_PRIVATE_HEADERS
2099           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2100           TK_LIBRARY=${TK_LIB_SPEC}
2101           TK_DEPS=""
2102         else
2103           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2104           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2105           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2106         fi
2107         AC_SUBST(TK_INCLUDE)
2108         AC_SUBST(TK_LIBRARY)
2109         AC_SUBST(TK_DEPS)
2110         AC_SUBST(TK_XINCLUDES)
2111
2112         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2113
2114         # Include some libraries that Tcl and Tk want.
2115         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2116         # Yes, the ordering seems wrong here.  But it isn't.
2117         # TK_LIBS is the list of libraries that need to be linked
2118         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2119         # were in LIBS then any link tests after this point would
2120         # try to include things like `$(LIBGUI)', which wouldn't work.
2121         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2122
2123         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2124         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2125         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2126         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2127         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2128         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2129         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2130
2131         if test x$gdb_cv_os_cygwin = xyes; then
2132           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2133           WIN32LDAPP="-Wl,--subsystem,console"
2134           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2135         fi
2136
2137         AC_CONFIG_SUBDIRS(gdbtk)
2138     fi
2139 fi
2140
2141 AC_SUBST(X_CFLAGS)
2142 AC_SUBST(X_LDFLAGS)
2143 AC_SUBST(X_LIBS)
2144 AC_SUBST(GDBTKLIBS)
2145 AC_SUBST(GDBTK_CFLAGS)
2146 AC_SUBST(GDBTK_SRC_DIR)
2147
2148 AC_PATH_X
2149
2150 # Unlike the sim directory, whether a simulator is linked is controlled by
2151 # presence of a gdb_sim definition in the target configure.tgt entry.
2152 # This code just checks for a few cases where we'd like to ignore those
2153 # definitions, even when they're present in the '.mt' file.  These cases
2154 # are when --disable-sim is specified, or if the simulator directory is
2155 # not part of the source tree.
2156 #
2157 AC_ARG_ENABLE(sim,
2158 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2159 [echo "enable_sim = $enable_sim";
2160  echo "enableval = ${enableval}";
2161  case "${enableval}" in
2162   yes) ignore_sim=false ;;
2163   no)  ignore_sim=true ;;
2164   *)   ignore_sim=false ;;
2165  esac],
2166 [ignore_sim=false])
2167
2168 if test ! -d "${srcdir}/../sim"; then
2169   ignore_sim=true
2170 fi
2171
2172 SIM=
2173 SIM_OBS=
2174 if test "${ignore_sim}" = "false"; then
2175   if test x"${gdb_sim}" != x ; then
2176     SIM="${gdb_sim}"
2177     SIM_OBS="remote-sim.o"
2178     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2179
2180     # Some tdep code should only be compiled in when the ppc sim is
2181     # built.  PR sim/13418.
2182     case $target in
2183       powerpc*-*-*)
2184         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2185         ;;
2186     esac
2187   fi
2188 fi
2189 AC_SUBST(SIM)
2190 AC_SUBST(SIM_OBS)
2191
2192 AC_SUBST(ENABLE_CFLAGS)
2193 AC_SUBST(PROFILE_CFLAGS)
2194
2195 AC_SUBST(CONFIG_OBS)
2196 AC_SUBST(CONFIG_DEPS)
2197 AC_SUBST(CONFIG_SRCS)
2198 AC_SUBST(CONFIG_ALL)
2199 AC_SUBST(CONFIG_CLEAN)
2200 AC_SUBST(CONFIG_INSTALL)
2201 AC_SUBST(CONFIG_UNINSTALL)
2202
2203 # List of host floatformats.
2204 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2205 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2206 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2207
2208 # target_subdir is used by the testsuite to find the target libraries.
2209 target_subdir=
2210 if test "${host}" != "${target}"; then
2211     target_subdir="${target_alias}/"
2212 fi
2213 AC_SUBST(target_subdir)
2214
2215 frags=
2216 if test "${gdb_native}" = "yes"; then
2217   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2218   if test ! -f ${host_makefile_frag}; then
2219     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2220   fi
2221   frags="$frags $host_makefile_frag"
2222 else
2223   host_makefile_frag=/dev/null
2224 fi
2225
2226 AC_SUBST_FILE(host_makefile_frag)
2227 AC_SUBST(frags)
2228
2229 changequote(,)dnl
2230 if test "${gdb_native}" = "yes"; then
2231 # We pick this up from the host configuration file (.mh) because we
2232 # do not have a native configuration Makefile fragment.
2233 nativefile=`sed -n '
2234 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2235 ' ${host_makefile_frag}`
2236 fi
2237 changequote([,])
2238
2239 if test x"${gdb_osabi}" != x ; then
2240     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2241                        [Define to the default OS ABI for this configuration.])
2242 fi
2243
2244 # Enable multi-ice-gdb-server.
2245 AC_ARG_ENABLE(multi-ice,
2246 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2247   [case $enableval in
2248     yes | no)
2249       ;;
2250     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2251   esac])
2252 if test "x$enable_multi_ice" = xyes; then
2253    AC_CONFIG_SUBDIRS(multi-ice)
2254 fi
2255
2256 AC_ARG_ENABLE(gdbserver,
2257 AS_HELP_STRING([--enable-gdbserver],
2258                [automatically build gdbserver (yes/no/auto, default is auto)]),
2259 [case "${enableval}" in
2260   yes| no|auto) ;;
2261   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2262 esac],[enable_gdbserver=auto])
2263
2264 # We only build gdbserver automatically in a native configuration, and
2265 # only if the user did not explicitly disable its build.
2266 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2267   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2268   if test "x$build_gdbserver" = xyes; then
2269     AC_MSG_RESULT(yes)
2270     AC_CONFIG_SUBDIRS(gdbserver)
2271     gdbserver_build_enabled=yes
2272   else
2273     AC_MSG_RESULT(no)
2274   fi
2275 fi
2276
2277 # If the user explicitly request the gdbserver to be built, verify that
2278 # we were in fact able to enable it.
2279 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2280   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2281 fi
2282
2283 # Check for babeltrace and babeltrace-ctf
2284 AC_ARG_WITH(babeltrace,
2285   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2286   [], [with_babeltrace=auto])
2287 AC_MSG_CHECKING([whether to use babeltrace])
2288 AC_MSG_RESULT([$with_babeltrace])
2289
2290 if test "x$with_babeltrace" = "xno"; then
2291   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2292 else
2293   # Append -Werror to CFLAGS so that configure can catch the warning
2294   # "assignment from incompatible pointer type", which is related to
2295   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2296   # in GDB, while babeltrace 1.0.3 is broken.
2297   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2298   # safe to save and restore CFLAGS here.
2299   saved_CFLAGS=$CFLAGS
2300   CFLAGS="$CFLAGS -Werror"
2301   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2302                         [#include <babeltrace/babeltrace.h>
2303                          #include <babeltrace/ctf/events.h>
2304                          #include <babeltrace/ctf/iterator.h>],
2305                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2306                         struct bt_ctf_event *event = NULL;
2307                         const struct bt_definition *scope;
2308
2309                         pos->type = BT_SEEK_BEGIN;
2310                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2311                         scope = bt_ctf_get_top_level_scope (event,
2312                                                            BT_STREAM_EVENT_HEADER);
2313                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2314                         ])
2315   CFLAGS=$saved_CFLAGS
2316
2317   if test "$HAVE_LIBBABELTRACE" != yes; then
2318      if test "$with_babeltrace" = yes; then
2319        AC_MSG_ERROR([babeltrace is missing or unusable])
2320      else
2321        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2322      fi
2323   fi
2324 fi
2325
2326 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2327 # to an empty version.
2328
2329 files=
2330 links=
2331
2332 rm -f nm.h
2333 if test "${nativefile}" != ""; then
2334     case "${nativefile}" in
2335       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2336       * ) GDB_NM_FILE="${nativefile}"
2337     esac
2338     files="${files} ${GDB_NM_FILE}"
2339     links="${links} nm.h"
2340     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2341 fi
2342 AC_SUBST(GDB_NM_FILE)
2343
2344 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2345 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2346 if test "x$USE_MAINTAINER_MODE" = xyes; then
2347   if test "${XSLTPROC}" = missing; then
2348     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2349   fi
2350 fi
2351 AC_SUBST(XSLTPROC)
2352
2353 AC_LINK_FILES($files, $links)
2354
2355 dnl Check for exe extension set on certain hosts (e.g. Win32)
2356 AC_EXEEXT
2357
2358 dnl  Detect the character set used by this host.
2359 dnl  At the moment, we just assume it's UTF-8.
2360 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2361           [Define to be a string naming the default host character set.])
2362
2363 if $development; then
2364   AC_DEFINE(GDB_SELF_TEST, 1,
2365             [Define if self-testing features should be enabled])
2366 fi
2367
2368 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2369 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2370 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2371 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2372 [
2373 case x$CONFIG_HEADERS in
2374 xconfig.h:config.in)
2375 echo > stamp-h ;;
2376 esac
2377 ])
2378
2379 AC_OUTPUT