gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_USE_SYSTEM_EXTENSIONS
  28 gl_EARLY
  29 ACX_LARGEFILE
  30 AM_PROG_CC_STDC
  31
  32 AC_CONFIG_AUX_DIR(..)
  33 AC_CANONICAL_SYSTEM
  34
  35 # Dependency checking.
  36 ZW_CREATE_DEPDIR
  37 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  38
  39 # Check for the 'make' the user wants to use.
  40 AC_CHECK_PROGS(MAKE, make)
  41 MAKE_IS_GNU=
  42 case "`$MAKE --version 2>&1 | sed 1q`" in
  43   *GNU*)
  44     MAKE_IS_GNU=yes
  45     ;;
  46 esac
  47 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  48 AC_PROG_MAKE_SET
  49
  50 dnl List of object files and targets accumulated by configure.
  51
  52 CONFIG_OBS=
  53 CONFIG_DEPS=
  54 CONFIG_SRCS=
  55 ENABLE_CFLAGS=
  56
  57 CONFIG_ALL=
  58 CONFIG_CLEAN=
  59 CONFIG_INSTALL=
  60 CONFIG_UNINSTALL=
  61
  62 dnl Set up for gettext.
  63 ZW_GNU_GETTEXT_SISTER_DIR
  64
  65 localedir='${datadir}/locale'
  66 AC_SUBST(localedir)
  67
  68 if test x"$USE_NLS" = xyes; then
  69    CONFIG_ALL="$CONFIG_ALL all-po"
  70    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  71    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  72    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  73 fi
  74
  75 gl_INIT
  76
  77 # For Makefile dependencies.
  78 GNULIB_STDINT_H=
  79 if test x"$STDINT_H" != x; then
  80   GNULIB_STDINT_H=gnulib/$STDINT_H
  81 fi
  82 AC_SUBST(GNULIB_STDINT_H)
  83
  84 PACKAGE=gdb
  85 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  86 AC_SUBST(PACKAGE)
  87
  88 # We never need to detect it in this sub-configure.
  89 # But preserve it for config.status --recheck.
  90 AC_ARG_VAR(MAKEINFO,
  91   [Parent configure detects if it is of sufficient version.])
  92 AC_ARG_VAR(MAKEINFOFLAGS,
  93   [Parameters for MAKEINFO.])
  94
  95 MAKEINFO_EXTRA_FLAGS=""
  96 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  97   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  98   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  99     gdb_cv_have_makeinfo_click=yes
 100   else
 101     gdb_cv_have_makeinfo_click=no
 102   fi])
 103 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 104   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 105 fi
 106 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 107
 108 # GDB does not use automake, but gnulib does.  This line lets us
 109 # generate its Makefile.in.
 110 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
 111
 112 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 113     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 114     [${libdir}/debug])
 115
 116 # We can't pass paths as command line arguments.
 117 # Mingw32 tries to be clever and will convert the paths for us.
 118 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 119 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 120 # This breaks GDB's relocatable path conversions since paths passed in
 121 # config.h would not get so translated, the path prefixes no longer match.
 122 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 123
 124 # GDB's datadir relocation
 125
 126 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 127     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 128     [${datadir}/gdb])
 129
 130 AC_ARG_WITH(relocated-sources,
 131 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 132 [reloc_srcdir="${withval}"
 133  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 134               [Relocated directory for source files. ])
 135 ])
 136
 137 AC_CONFIG_SUBDIRS(testsuite)
 138
 139 # Check whether to support alternative target configurations
 140 AC_ARG_ENABLE(targets,
 141 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 142 [case "${enableval}" in
 143   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 144             ;;
 145   no)       enable_targets= ;;
 146   *)        enable_targets=$enableval ;;
 147 esac])
 148
 149 # Check whether to enable 64-bit support on 32-bit hosts
 150 AC_ARG_ENABLE(64-bit-bfd,
 151 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 152 [case "${enableval}" in
 153   yes)  want64=true  ;;
 154   no)   want64=false ;;
 155   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 156 esac],[want64=false])dnl
 157
 158 # Provide defaults for some variables set by the per-host and per-target
 159 # configuration.
 160 gdb_host_obs=posix-hdep.o
 161
 162 if test "${target}" = "${host}"; then
 163   gdb_native=yes
 164 else
 165   gdb_native=no
 166 fi
 167
 168 . $srcdir/configure.host
 169
 170 # Accumulate some settings from configure.tgt over all enabled targets
 171
 172 TARGET_OBS=
 173 all_targets=
 174
 175 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 176 do
 177   if test "$targ_alias" = "all"; then
 178     all_targets=true
 179   else
 180     # Canonicalize the secondary target names.
 181     result=`$ac_config_sub $targ_alias 2>/dev/null`
 182     if test -n "$result"; then
 183         targ=$result
 184     else
 185         targ=$targ_alias
 186     fi
 187
 188     . ${srcdir}/configure.tgt
 189
 190     AS_IF([test -z "${gdb_target_obs}"],
 191       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 192
 193     # Target-specific object files
 194     for i in ${gdb_target_obs}; do
 195         case " $TARGET_OBS " in
 196         *" ${i} "*) ;;
 197         *)
 198           TARGET_OBS="$TARGET_OBS ${i}"
 199           ;;
 200         esac
 201     done
 202
 203     # Check whether this target needs 64-bit CORE_ADDR
 204     if test x${want64} = xfalse; then
 205       . ${srcdir}/../bfd/config.bfd
 206     fi
 207   fi
 208 done
 209
 210 if test x${all_targets} = xtrue; then
 211
 212   # We want all 64-bit targets if we either:
 213   #  - run on a 64-bit host  or
 214   #  - already require 64-bit support for some other target  or
 215   #  - the --enable-64-bit-bfd option was supplied
 216   # Otherwise we only support all 32-bit targets.
 217   #
 218   # NOTE: This test must be in sync with the corresponding
 219   #       tests in BFD!
 220
 221   if test x${want64} = xfalse; then
 222     AC_CHECK_SIZEOF(long)
 223     if test "x${ac_cv_sizeof_long}" = "x8"; then
 224       want64=true
 225     fi
 226   fi
 227   if test x${want64} = xtrue; then
 228     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 229   else
 230     TARGET_OBS='$(ALL_TARGET_OBS)'
 231   fi
 232 fi
 233
 234 AC_SUBST(TARGET_OBS)
 235
 236 # For other settings, only the main target counts.
 237 gdb_sim=
 238 gdb_osabi=
 239 build_gdbserver=
 240 targ=$target; . ${srcdir}/configure.tgt
 241
 242 # Fetch the default architecture and default target vector from BFD.
 243 targ=$target; . $srcdir/../bfd/config.bfd
 244
 245 # We only want the first architecture, so strip off the others if
 246 # there is more than one.
 247 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 248
 249 if test "x$targ_archs" != x; then
 250   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 251     [Define to BFD's default architecture. ])
 252 fi
 253 if test "x$targ_defvec" != x; then
 254   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 255     [Define to BFD's default target vector. ])
 256 fi
 257
 258 # The CLI cannot be disabled yet, but may be in the future.
 259
 260 # Enable CLI.
 261 AC_ARG_ENABLE(gdbcli,
 262 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 263   [case $enableval in
 264     yes)
 265       ;;
 266     no)
 267       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 268     *)
 269       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 270   esac],
 271   [enable_gdbcli=yes])
 272 if test x"$enable_gdbcli" = xyes; then
 273   if test -d $srcdir/cli; then
 274     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 275     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 276     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 277     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 278   fi
 279 fi
 280
 281 # Enable MI.
 282 AC_ARG_ENABLE(gdbmi,
 283 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 284   [case $enableval in
 285     yes | no)
 286       ;;
 287     *)
 288       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 289   esac],
 290   [enable_gdbmi=yes])
 291 if test x"$enable_gdbmi" = xyes; then
 292   if test -d $srcdir/mi; then
 293     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 294     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 295     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 296     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 297   fi
 298 fi
 299
 300 # Enable TUI.
 301 AC_ARG_ENABLE(tui,
 302 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 303   [case $enableval in
 304     yes | no | auto)
 305       ;;
 306     *)
 307       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 308   esac],enable_tui=auto)
 309
 310 # Enable gdbtk.
 311 AC_ARG_ENABLE(gdbtk,
 312 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 313   [case $enableval in
 314     yes | no)
 315       ;;
 316     *)
 317       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 318   esac],
 319   [if test -d $srcdir/gdbtk; then
 320     enable_gdbtk=yes
 321   else
 322     enable_gdbtk=no
 323   fi])
 324 # We unconditionally disable gdbtk tests on selected platforms.
 325 case $host_os in
 326   go32* | windows*)
 327     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 328     enable_gdbtk=no ;;
 329 esac
 330
 331 # Libunwind support.
 332 AC_ARG_WITH(libunwind,
 333 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 334 [case "${withval}" in
 335   yes)  enable_libunwind=yes ;;
 336   no)   enable_libunwind=no ;;
 337   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 338 esac],[
 339   AC_CHECK_HEADERS(libunwind-ia64.h)
 340   if test x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 341     enable_libunwind=yes;
 342   fi
 343 ])
 344
 345 if test x"$enable_libunwind" = xyes; then
 346   AC_CHECK_HEADERS(libunwind-ia64.h)
 347   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 348   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 349   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 350   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 351 fi
 352
 353 opt_curses=no
 354 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 355
 356 prefer_curses=no
 357 if test "$opt_curses" = "yes"; then
 358   prefer_curses=yes
 359 fi
 360
 361 # Profiling support.
 362 AC_ARG_ENABLE(profiling,
 363 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 364   [case $enableval in
 365     yes | no)
 366       ;;
 367     *)
 368       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 369   esac],
 370  [enable_profiling=no])
 371
 372 AC_CHECK_FUNCS(monstartup _mcleanup)
 373 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 374 [AC_TRY_LINK(
 375 [#include <stdlib.h>
 376 extern char _etext;
 377 ],
 378 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 379 if test $ac_cv_var__etext = yes; then
 380   AC_DEFINE(HAVE__ETEXT, 1,
 381             [Define to 1 if your system has the _etext variable. ])
 382 fi
 383 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 384 [AC_TRY_LINK(
 385 [#include <stdlib.h>
 386 extern char etext;
 387 ],
 388 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 389 if test $ac_cv_var_etext = yes; then
 390   AC_DEFINE(HAVE_ETEXT, 1,
 391             [Define to 1 if your system has the etext variable. ])
 392 fi
 393 if test "$enable_profiling" = yes ; then
 394   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 395     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 396   fi
 397   PROFILE_CFLAGS=-pg
 398   OLD_CFLAGS="$CFLAGS"
 399   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 400
 401   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 402     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 403      ac_cv_cc_supports_pg=no)])
 404
 405   if test $ac_cv_cc_supports_pg = no; then
 406     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 407   fi
 408
 409   CFLAGS="$OLD_CFLAGS"
 410 fi
 411
 412 ACX_PKGVERSION([GDB])
 413 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 414 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 415 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 416
 417 # --------------------- #
 418 # Checks for programs.  #
 419 # --------------------- #
 420
 421 AC_PROG_AWK
 422 AC_PROG_INSTALL
 423 AC_PROG_LN_S
 424 AC_PROG_RANLIB
 425 AC_PROG_YACC
 426
 427 AC_CHECK_TOOL(AR, ar)
 428 AC_CHECK_TOOL(DLLTOOL, dlltool)
 429 AC_CHECK_TOOL(WINDRES, windres)
 430
 431 # Needed for GNU/Hurd.
 432 AC_CHECK_TOOL(MIG, mig)
 433
 434 # ---------------------- #
 435 # Checks for libraries.  #
 436 # ---------------------- #
 437
 438 # We might need to link with -lm; most simulators need it.
 439 AC_CHECK_LIB(m, main)
 440
 441 # We need to link with -lw to get `wctype' on Solaris before Solaris
 442 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 443 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 444 # is known to have this problem).  Therefore we avoid libw if we can.
 445 AC_CHECK_FUNC(wctype, [],
 446   [AC_CHECK_LIB(w, wctype)])
 447
 448 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 449 AC_SEARCH_LIBS(gethostbyname, nsl)
 450
 451 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 452 AC_SEARCH_LIBS(socketpair, socket)
 453
 454 # Link in zlib if we can.  This allows us to read compressed debug sections.
 455 AM_ZLIB
 456
 457 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 458 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 459
 460 AM_ICONV
 461
 462 # GDB may fork/exec the iconv program to get the list of supported character
 463 # sets.  Allow the user to specify where to find it.
 464 # There are several factors affecting the choice of option name:
 465 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 466 #   the build-time location of libiconv files.
 467 # - The program we need to find is iconv, which comes with glibc.  The user
 468 #   doesn't necessarily have libiconv installed.  Therefore naming this
 469 #   --with-libiconv-foo feels wrong.
 470 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 471 #   defined to work on directories not files (though it really doesn't know
 472 #   the difference).
 473 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 474 #   with --with-libiconv-prefix.
 475 # Putting these together is why the option name is --with-iconv-bin.
 476
 477 AC_ARG_WITH(iconv-bin,
 478 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 479 [iconv_bin="${withval}"
 480  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 481                     [Path of directory of iconv program.])
 482  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 483 ])
 484
 485 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 486 # There is a very specific comment in /usr/include/curses.h explaining that
 487 # termcap routines built into libcurses must not be used.
 488 #
 489 # The symptoms we observed so far is GDB unexpectedly changing
 490 # the terminal settings when tgetent is called - this is particularly
 491 # visible as the output is missing carriage returns, and so rapidly
 492 # becomes very hard to read.
 493 #
 494 # The readline configure script has already decided that libtermcap
 495 # was enough for its purposes, and so decided to build readline using
 496 # libtermcap.  Since the TUI mode requires curses, building GDB with
 497 # TUI enabled results in both libraries to be used at the same time,
 498 # which is not allowed.  This basically means that GDB with TUI is
 499 # broken on alpha-osf.
 500
 501 case $host_os in
 502   osf* )
 503     if test x"$enable_tui" = xyes; then
 504       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 505     fi
 506     if test x"$enable_tui" = xauto; then
 507       enable_tui=no
 508     fi
 509     ;;
 510 esac
 511
 512 # For the TUI, we need enhanced curses functionality.
 513 if test x"$enable_tui" != xno; then
 514   prefer_curses=yes
 515 fi
 516
 517 curses_found=no
 518 if test x"$prefer_curses" = xyes; then
 519   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 520   # curses library because the latter might not provide all the
 521   # functionality we need.  However, this leads to problems on systems
 522   # where the linker searches /usr/local/lib, but the compiler doesn't
 523   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 524   # default installation of ncurses on alpha*-dec-osf* will lead to such
 525   # a situation.
 526   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 527
 528   if test "$ac_cv_search_waddstr" != no; then
 529     curses_found=yes
 530   fi
 531 fi
 532
 533 # Check whether we should enable the TUI, but only do so if we really
 534 # can.
 535 if test x"$enable_tui" != xno; then
 536   if test -d $srcdir/tui; then
 537     if test "$curses_found" != no; then
 538       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 539       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 540       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 541       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 542     else
 543       if test x"$enable_tui" = xyes; then
 544         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 545       else
 546         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 547       fi
 548     fi
 549   fi
 550 fi
 551
 552 # Since GDB uses Readline, we need termcap functionality.  In many
 553 # cases this will be provided by the curses library, but some systems
 554 # have a seperate termcap library, or no curses library at all.
 555
 556 case $host_os in
 557   cygwin*)
 558     if test -d $srcdir/libtermcap; then
 559       LIBS="../libtermcap/libtermcap.a $LIBS"
 560       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 561     fi ;;
 562   go32* | *djgpp*)
 563     ac_cv_search_tgetent="none required"
 564     ;;
 565   *mingw32*)
 566     ac_cv_search_tgetent="none required"
 567     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 568     ;;
 569 esac
 570
 571 # These are the libraries checked by Readline.
 572 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 573
 574 if test "$ac_cv_search_tgetent" = no; then
 575   AC_MSG_ERROR([no termcap library found])
 576 fi
 577
 578 AC_ARG_WITH([system-readline],
 579   [AS_HELP_STRING([--with-system-readline],
 580                   [use installed readline library])])
 581
 582 if test "$with_system_readline" = yes; then
 583   READLINE=-lreadline
 584   READLINE_DEPS=
 585   READLINE_CFLAGS=
 586   READLINE_TEXI_INCFLAG=
 587 else
 588   READLINE='$(READLINE_DIR)/libreadline.a'
 589   READLINE_DEPS='$(READLINE)'
 590   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 591   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 592 fi
 593 AC_SUBST(READLINE)
 594 AC_SUBST(READLINE_DEPS)
 595 AC_SUBST(READLINE_CFLAGS)
 596 AC_SUBST(READLINE_TEXI_INCFLAG)
 597
 598 # Generate jit-reader.h
 599
 600 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 601 TARGET_PTR=
 602
 603 AC_CHECK_SIZEOF(unsigned long long)
 604 AC_CHECK_SIZEOF(unsigned long)
 605 AC_CHECK_SIZEOF(unsigned __int128)
 606
 607 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 608   TARGET_PTR="unsigned long"
 609 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 610   TARGET_PTR="unsigned long long"
 611 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 612   TARGET_PTR="unsigned __int128"
 613 else
 614   TARGET_PTR="unsigned long"
 615 fi
 616
 617 AC_SUBST(TARGET_PTR)
 618 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 619
 620 AC_SEARCH_LIBS(dlopen, dl)
 621
 622 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 623                 [directory to load the JIT readers from],
 624                 [${libdir}/gdb])
 625
 626 AC_ARG_WITH(expat,
 627   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 628   [], [with_expat=auto])
 629 AC_MSG_CHECKING([whether to use expat])
 630 AC_MSG_RESULT([$with_expat])
 631
 632 if test "${with_expat}" = no; then
 633   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 634   HAVE_LIBEXPAT=no
 635 else
 636   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 637                         [XML_Parser p = XML_ParserCreate (0);])
 638   if test "$HAVE_LIBEXPAT" != yes; then
 639     if test "$with_expat" = yes; then
 640       AC_MSG_ERROR([expat is missing or unusable])
 641     else
 642       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 643     fi
 644   else
 645     save_LIBS=$LIBS
 646     LIBS="$LIBS $LIBEXPAT"
 647     AC_CHECK_FUNCS(XML_StopParser)
 648     LIBS=$save_LIBS
 649   fi
 650 fi
 651
 652 dnl Utility to simplify finding libpython.
 653 dnl $1 = pythonX.Y
 654 dnl $2 = the shell variable to assign the result to
 655 dnl      If libpython is found we store $version here.
 656 dnl $3 = additional flags to add to CPPFLAGS
 657 dnl $4 = additional flags to add to LIBS
 658
 659 AC_DEFUN([AC_TRY_LIBPYTHON],
 660 [
 661   version=$1
 662   define([have_libpython_var],$2)
 663   new_CPPFLAGS=$3
 664   new_LIBS=$4
 665   AC_MSG_CHECKING([for ${version}])
 666   save_CPPFLAGS=$CPPFLAGS
 667   save_LIBS=$LIBS
 668   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 669   LIBS="$LIBS $new_LIBS"
 670   found_usable_python=no
 671   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 672                                  [[Py_Initialize ();]]),
 673                  [have_libpython_var=${version}
 674                   found_usable_python=yes
 675                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 676                   PYTHON_LIBS=$new_LIBS])
 677   CPPFLAGS=$save_CPPFLAGS
 678   LIBS=$save_LIBS
 679   AC_MSG_RESULT([${found_usable_python}])
 680 ])
 681
 682 dnl There are several different values for --with-python:
 683 dnl
 684 dnl no -   Don't include python support.
 685 dnl yes -  Include python support, error if it's missing.
 686 dnl        If we find python in $PATH, use it to fetch configure options,
 687 dnl        otherwise assume the compiler can find it with no help from us.
 688 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 689 dnl auto - Same as "yes", but if python is missing from the system,
 690 dnl        fall back to "no".
 691 dnl /path/to/python/exec-prefix -
 692 dnl        Use the python located in this directory.
 693 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 694 dnl        the compilation parameters.  Otherwise use
 695 dnl        -I/path/to/python/exec-prefix/include,
 696 dnl        -L/path/to/python/exec-prefix/lib.
 697 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 698 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 699 dnl        but is deprecated.
 700 dnl /path/to/python/executable -
 701 dnl        Run python-config.py with this version of python to fetch the
 702 dnl        compilation parameters.
 703 dnl        NOTE: This needn't be the real python executable.
 704 dnl        In a cross-compilation scenario (build != host), this could be
 705 dnl        a shell script that provides what python-config.py provides for
 706 dnl        --ldflags, --includes, --exec-prefix.
 707 dnl python-executable -
 708 dnl        Find python-executable in $PATH, and then handle the same as
 709 dnl        /path/to/python/executable.
 710 dnl
 711 dnl If a python program is specified, it is used to run python-config.py and
 712 dnl is passed --ldflags, --includes, --exec-prefix.
 713
 714 AC_ARG_WITH(python,
 715   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 716   [], [with_python=auto])
 717 AC_MSG_CHECKING([whether to use python])
 718 AC_MSG_RESULT([$with_python])
 719
 720 if test "${with_python}" = no; then
 721   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 722   have_libpython=no
 723 else
 724   case "${with_python}" in
 725   [[\\/]]* | ?:[[\\/]]*)
 726     if test -d ${with_python}; then
 727       # Assume the python binary is ${with_python}/bin/python.
 728       python_prog="${with_python}/bin/python"
 729       python_prefix=
 730       # If python does not exit ${with_python}/bin, then try in
 731       # ${with_python}.  On Windows/MinGW, this is where the Python
 732       # executable is.
 733       if test ! -x "${python_prog}"; then
 734         python_prog="${with_python}/python"
 735         python_prefix=
 736       fi
 737       if test ! -x "${python_prog}"; then
 738         # Fall back to gdb 7.0/7.1 behaviour.
 739         python_prog=missing
 740         python_prefix=${with_python}
 741       fi
 742     elif test -x "${with_python}"; then
 743       # While we can't run python compiled for $host (unless host == build),
 744       # the user could write a script that provides the needed information,
 745       # so we support that.
 746       python_prog=${with_python}
 747       python_prefix=
 748     else
 749       AC_ERROR(invalid value for --with-python)
 750     fi
 751     ;;
 752   */*)
 753     # Disallow --with-python=foo/bar.
 754     AC_ERROR(invalid value for --with-python)
 755     ;;
 756   *)
 757     # The user has either specified auto, yes, or the name of the python
 758     # program assumed to be in $PATH.
 759     python_prefix=
 760     case "${with_python}" in
 761     yes | auto)
 762       if test ${build} = ${host}; then
 763         AC_PATH_PROG(python_prog_path, python, missing)
 764         if test "${python_prog_path}" = missing; then
 765           python_prog=missing
 766         else
 767           python_prog=${python_prog_path}
 768         fi
 769       else
 770         # Not much we can do except assume the cross-compiler will find the
 771         # right files.
 772         python_prog=missing
 773       fi
 774       ;;
 775     *)
 776       # While we can't run python compiled for $host (unless host == build),
 777       # the user could write a script that provides the needed information,
 778       # so we support that.
 779       python_prog="${with_python}"
 780       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 781       if test "${python_prog_path}" = missing; then
 782         AC_ERROR(unable to find python program ${python_prog})
 783       fi
 784       ;;
 785     esac
 786   esac
 787
 788   if test "${python_prog}" != missing; then
 789     # We have a python program to use, but it may be too old.
 790     # Don't flag an error for --with-python=auto (the default).
 791     have_python_config=yes
 792     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 793     if test $? != 0; then
 794       have_python_config=failed
 795       if test "${with_python}" != auto; then
 796         AC_ERROR(failure running python-config --includes)
 797       fi
 798     fi
 799     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 800     if test $? != 0; then
 801       have_python_config=failed
 802       if test "${with_python}" != auto; then
 803         AC_ERROR(failure running python-config --ldflags)
 804       fi
 805     fi
 806     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 807     if test $? != 0; then
 808       have_python_config=failed
 809       if test "${with_python}" != auto; then
 810         AC_ERROR(failure running python-config --exec-prefix)
 811       fi
 812     fi
 813   else
 814     # We do not have a python executable we can use to determine where
 815     # to find the Python headers and libs.  We cannot guess the include
 816     # path from the python_prefix either, because that include path
 817     # depends on the Python version.  So, there is nothing much we can
 818     # do except assume that the compiler will be able to find those files.
 819     python_includes=
 820     python_libs=
 821     have_python_config=no
 822   fi
 823
 824   # If we have python-config, only try the configuration it provides.
 825   # Otherwise fallback on the old way of trying different versions of
 826   # python in turn.
 827
 828   have_libpython=no
 829   if test "${have_python_config}" = yes; then
 830     # Determine the Python version by extracting "-lpython<version>"
 831     # part of the python_libs. <version> is usually X.Y with X and Y
 832     # being decimal numbers, but can also be XY (seen on Windows).
 833     #
 834     # The extraction is performed using sed with a regular expression.
 835     # Initially, the regexp used was using the '?' quantifier to make
 836     # the dot in the version number optional.  Unfortunately, this
 837     # does not work with non-GNU versions of sed because, because of
 838     # what looks like a limitation (the '?' quantifier does not work
 839     # with back-references).  We work around this limitation by using
 840     # the '*' quantifier instead.  It means that, in theory, we might
 841     # match unexpected version strings such as "-lpython2..7", but
 842     # this seems unlikely in practice.  And even if that happens,
 843     # an error will be triggered later on, when checking that version
 844     # number.
 845     python_version=`echo " ${python_libs} " \
 846                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 847     case "${python_version}" in
 848     python*)
 849       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 850                        ${python_includes}, ${python_libs})
 851       ;;
 852     *)
 853       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 854       ;;
 855     esac
 856   elif test "${have_python_config}" != failed; then
 857     if test "${have_libpython}" = no; then
 858       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 859                        ${python_includes}, "${python_libs} -lpython2.7")
 860     fi
 861     if test "${have_libpython}" = no; then
 862       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 863                        ${python_includes}, "${python_libs} -lpython2.6")
 864     fi
 865     if test ${have_libpython} = no; then
 866       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 867                        ${python_includes}, "${python_libs} -lpython2.5")
 868     fi
 869     if test ${have_libpython} = no; then
 870       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 871                        ${python_includes}, "${python_libs} -lpython2.4")
 872     fi
 873   fi
 874   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 875     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 876   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 877     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 878   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 879     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 880   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 881     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 882   fi
 883
 884   if test "${have_libpython}" = no; then
 885     case "${with_python}" in
 886     yes)
 887       AC_MSG_ERROR([python is missing or unusable])
 888       ;;
 889     auto)
 890       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 891       ;;
 892     *)
 893       AC_MSG_ERROR([no usable python found at ${with_python}])
 894       ;;
 895     esac
 896   else
 897     if test -n "${python_prefix}"; then
 898       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 899                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 900       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 901     fi
 902   fi
 903 fi
 904
 905 if test "${have_libpython}" != no; then
 906   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 907   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 908   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 909   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 910   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 911   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 912
 913   # Flags needed to compile Python code (taken from python-config --cflags).
 914   # We cannot call python-config directly because it will output whatever was
 915   # used when compiling the Python interpreter itself, including flags which
 916   # would make the python-related objects be compiled differently from the
 917   # rest of GDB (e.g., -O2 and -fPIC).
 918   if test "${GCC}" = yes; then
 919     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 920   fi
 921
 922   if test "x${tentative_python_cflags}" != x; then
 923     AC_MSG_CHECKING(compiler flags for python code)
 924     for flag in ${tentative_python_cflags}; do
 925       # Check that the compiler accepts it
 926       saved_CFLAGS="$CFLAGS"
 927       CFLAGS="$CFLAGS $flag"
 928       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 929       CFLAGS="$saved_CFLAGS"
 930     done
 931     AC_MSG_RESULT(${PYTHON_CFLAGS})
 932   fi
 933
 934   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 935   #    #if _SGIAPI
 936   #    #define siginfo __siginfo
 937   #    #endif
 938   # The problem is that including Python causes some XOPEN macros to be
 939   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 940   # to false.  So, we work around this issue by defining siginfo ourself
 941   # though the command-line.
 942   case "$gdb_host" in
 943     irix*) if test "${GCC}" = yes; then
 944              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 945            fi
 946            ;;
 947   esac
 948 else
 949   # Even if Python support is not compiled in, we need to have these files
 950   # included.
 951   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 952   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 953         python/py-prettyprint.c python/py-auto-load.c"
 954 fi
 955 AC_SUBST(PYTHON_CFLAGS)
 956 AC_SUBST(PYTHON_CPPFLAGS)
 957 AC_SUBST(PYTHON_LIBS)
 958
 959 # ------------------------- #
 960 # Checks for header files.  #
 961 # ------------------------- #
 962
 963 AC_HEADER_DIRENT
 964 AC_HEADER_STAT
 965 AC_HEADER_STDC
 966 # elf_hp.h is for HP/UX 64-bit shared library support.
 967 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 968 # unconditionally, so what's the point in checking these?
 969 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 970                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 971                   stdlib.h string.h memory.h strings.h sys/fault.h \
 972                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 973                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 974                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 975                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 976                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
 977                   dlfcn.h])
 978 AC_CHECK_HEADERS(link.h, [], [],
 979 [#if HAVE_SYS_TYPES_H
 980 # include <sys/types.h>
 981 #endif
 982 #if HAVE_NLIST_H
 983 # include <nlist.h>
 984 #endif
 985 ])
 986 AC_CHECK_HEADERS(sys/proc.h, [], [],
 987 [#if HAVE_SYS_PARAM_H
 988 # include <sys/param.h>
 989 #endif
 990 ])
 991 AC_CHECK_HEADERS(sys/user.h, [], [],
 992 [#if HAVE_SYS_PARAM_H
 993 # include <sys/param.h>
 994 #endif
 995 ])
 996
 997 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 998 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 999 # think that we don't have <curses.h> if we're using GCC.
1000 case $host_os in
1001   solaris2.[[789]])
1002     if test "$GCC" = yes; then
1003       AC_DEFINE(_MSE_INT_H, 1,
1004         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1005    Solaris 2.[789] when using GCC. ])
1006     fi ;;
1007 esac
1008 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1009 AC_CHECK_HEADERS(term.h, [], [],
1010 [#if HAVE_CURSES_H
1011 # include <curses.h>
1012 #endif
1013 ])
1014
1015 # ------------------------- #
1016 # Checks for declarations.  #
1017 # ------------------------- #
1018
1019 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1020                 snprintf, vsnprintf])
1021 AM_LC_MESSAGES
1022
1023 # ----------------------- #
1024 # Checks for structures.  #
1025 # ----------------------- #
1026
1027 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1028
1029 # ------------------ #
1030 # Checks for types.  #
1031 # ------------------ #
1032
1033 AC_TYPE_SIGNAL
1034 AC_CHECK_TYPES(socklen_t, [], [],
1035 [#include <sys/types.h>
1036 #include <sys/socket.h>
1037 ])
1038
1039 # ------------------------------------- #
1040 # Checks for compiler characteristics.  #
1041 # ------------------------------------- #
1042
1043 AC_C_CONST
1044 AC_C_INLINE
1045 AC_C_BIGENDIAN
1046
1047 # ------------------------------ #
1048 # Checks for library functions.  #
1049 # ------------------------------ #
1050
1051 AC_FUNC_ALLOCA
1052 AC_FUNC_MMAP
1053 AC_FUNC_VFORK
1054 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1055                 pipe poll pread pread64 pwrite readlink resize_term \
1056                 sbrk setpgid setpgrp setsid \
1057                 sigaction sigprocmask sigsetmask socketpair syscall \
1058                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1059                 setrlimit getrlimit posix_madvise waitpid lstat])
1060 AM_LANGINFO_CODESET
1061
1062 # Check the return and argument types of ptrace.  No canned test for
1063 # this, so roll our own.
1064 gdb_ptrace_headers='
1065 #if HAVE_SYS_TYPES_H
1066 # include <sys/types.h>
1067 #endif
1068 #if HAVE_SYS_PTRACE_H
1069 # include <sys/ptrace.h>
1070 #endif
1071 #if HAVE_UNISTD_H
1072 # include <unistd.h>
1073 #endif
1074 '
1075 # There is no point in checking if we don't have a prototype.
1076 AC_CHECK_DECLS(ptrace, [], [
1077   : ${gdb_cv_func_ptrace_ret='int'}
1078   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1079 ], $gdb_ptrace_headers)
1080 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1081 # empty argument list, so check for that explicitly.
1082 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1083   AC_TRY_COMPILE($gdb_ptrace_headers,
1084     [extern long ptrace (enum __ptrace_request, ...);],
1085     gdb_cv_func_ptrace_ret='long',
1086     AC_TRY_COMPILE($gdb_ptrace_headers,
1087       [extern int ptrace ();],
1088       gdb_cv_func_ptrace_ret='int',
1089       gdb_cv_func_ptrace_ret='long')))
1090 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1091   [Define as the return type of ptrace.])
1092 # Check argument types.
1093 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1094   AC_TRY_COMPILE($gdb_ptrace_headers,
1095     [extern long ptrace (enum __ptrace_request, ...);],
1096     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1097 for gdb_arg1 in 'int' 'long'; do
1098  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1099   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1100    for gdb_arg4 in 'int' 'long'; do
1101      AC_TRY_COMPILE($gdb_ptrace_headers, [
1102 extern $gdb_cv_func_ptrace_ret
1103   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1104 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1105     break 4;])
1106     for gdb_arg5 in 'int *' 'int' 'long'; do
1107      AC_TRY_COMPILE($gdb_ptrace_headers, [
1108 extern $gdb_cv_func_ptrace_ret
1109   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1110 ], [
1111 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1112     break 5;])
1113     done
1114    done
1115   done
1116  done
1117 done
1118 # Provide a safe default value.
1119 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1120 ])])
1121 ac_save_IFS=$IFS; IFS=','
1122 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1123 IFS=$ac_save_IFS
1124 shift
1125 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1126   [Define to the type of arg 3 for ptrace.])
1127 if test -n "$[5]"; then
1128   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1129     [Define to the type of arg 5 for ptrace.])
1130 fi
1131
1132 dnl AC_FUNC_SETPGRP does not work when cross compiling
1133 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1134 if test "$cross_compiling" = no; then
1135   AC_FUNC_SETPGRP
1136 else
1137   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1138     [AC_TRY_COMPILE([
1139 #include <unistd.h>
1140 ], [
1141   if (setpgrp(1,1) == -1)
1142     exit (0);
1143   else
1144     exit (1);
1145 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1146 if test $ac_cv_func_setpgrp_void = yes; then
1147   AC_DEFINE(SETPGRP_VOID, 1)
1148 fi
1149 fi
1150
1151 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1152 # since sigsetjmp might only be defined as a macro.
1153 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1154 [AC_TRY_COMPILE([
1155 #include <setjmp.h>
1156 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1157 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1158 if test $gdb_cv_func_sigsetjmp = yes; then
1159   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1160 fi
1161
1162 # Assume we'll default to using the included libiberty regex.
1163 gdb_use_included_regex=yes
1164
1165 # However, if the system regex is GNU regex, then default to *not*
1166 # using the included regex.
1167 AC_CACHE_CHECK(
1168   [for GNU regex],
1169   [gdb_cv_have_gnu_regex],
1170   [AC_TRY_COMPILE(
1171     [#include <gnu-versions.h>],
1172     [#define REGEX_INTERFACE_VERSION 1
1173 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1174 # error "Version mismatch"
1175 #endif],
1176     gdb_cv_have_gnu_regex=yes,
1177     gdb_cv_have_gnu_regex=no)])
1178 if test $gdb_cv_have_gnu_regex = yes; then
1179   gdb_use_included_regex=no
1180 fi
1181
1182 AC_ARG_WITH(included-regex,
1183   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1184   gdb_with_regex=$withval,
1185   gdb_with_regex=$gdb_use_included_regex)
1186 if test "$gdb_with_regex" = yes; then
1187   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1188     [Define to 1 if the regex included in libiberty should be used.])
1189 fi
1190
1191 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1192 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1193 [#include <sys/param.h>
1194 #include <sys/proc.h>
1195 ])
1196
1197 # See if <sys/lwp.h> defines `struct lwp`.
1198 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1199 [AC_TRY_COMPILE([#include <sys/param.h>
1200 #include <sys/lwp.h>], [struct lwp l;],
1201 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1202 if test $gdb_cv_struct_lwp = yes; then
1203   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1204             [Define to 1 if your system has struct lwp.])
1205 fi
1206
1207 # See if <machine/reg.h> degines `struct reg'.
1208 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1209 [AC_TRY_COMPILE([#include <sys/types.h>
1210 #include <machine/reg.h>], [struct reg r;],
1211 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1212 if test $gdb_cv_struct_reg = yes; then
1213   AC_DEFINE(HAVE_STRUCT_REG, 1,
1214             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1215 fi
1216
1217 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1218 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1219 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1220                  [#include <machine/reg.h>])
1221
1222 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1223 AC_MSG_CHECKING(for PTRACE_GETREGS)
1224 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1225 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1226                 [PTRACE_GETREGS;],
1227                 [gdb_cv_have_ptrace_getregs=yes],
1228                 [gdb_cv_have_ptrace_getregs=no])])
1229 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1230 if test $gdb_cv_have_ptrace_getregs = yes; then
1231   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1232   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1233 fi
1234
1235 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1236 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1237 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1238 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1239                 [PTRACE_GETFPXREGS;],
1240                 [gdb_cv_have_ptrace_getfpxregs=yes],
1241                 [gdb_cv_have_ptrace_getfpxregs=no])])
1242 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1243 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1244   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1245   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1246 fi
1247
1248 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1249 AC_MSG_CHECKING(for PT_GETDBREGS)
1250 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1251 [AC_TRY_COMPILE([#include <sys/types.h>
1252 #include <sys/ptrace.h>],
1253                 [PT_GETDBREGS;],
1254                 [gdb_cv_have_pt_getdbregs=yes],
1255                 [gdb_cv_have_pt_getdbregs=no])])
1256 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1257 if test $gdb_cv_have_pt_getdbregs = yes; then
1258   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1259   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1260 fi
1261
1262 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1263 AC_MSG_CHECKING(for PT_GETXMMREGS)
1264 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1265 [AC_TRY_COMPILE([#include <sys/types.h>
1266 #include <sys/ptrace.h>],
1267                 [PT_GETXMMREGS;],
1268                 [gdb_cv_have_pt_getxmmregs=yes],
1269                 [gdb_cv_have_pt_getxmmregs=no])])
1270 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1271 if test $gdb_cv_have_pt_getxmmregs = yes; then
1272   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1273   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1274 fi
1275
1276 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1277
1278 if test "${target}" = "${host}"; then
1279   case "${host}" in
1280   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1281       AC_DEFINE(NEW_PROC_API, 1,
1282       [Define if you want to use new multi-fd /proc interface
1283        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1284       ;;
1285   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1286       AC_DEFINE(NEW_PROC_API, 1,
1287       [Define if you want to use new multi-fd /proc interface
1288        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1289       ;;
1290   mips-sgi-irix5*)
1291       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1292       AC_DEFINE([_KMEMUSER], 1,
1293       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1294        around a <sys/proc.h> problem on IRIX 5.])
1295       ;;
1296   esac
1297 fi
1298
1299 if test "$ac_cv_header_sys_procfs_h" = yes; then
1300   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1301   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1302   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1303   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1304   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1305   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1306   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1307   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1308   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1309   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1310   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1311   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1312   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1313   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1314
1315
1316   dnl Check for broken prfpregset_t type
1317
1318   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1319   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1320   dnl instead of the struct itself).  We detect this here, and work
1321   dnl around it in gdb_proc_service.h.
1322
1323   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1324     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1325     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1326       [AC_TRY_RUN([#include <sys/procfs.h>
1327        int main ()
1328        {
1329          if (sizeof (prfpregset_t) == sizeof (void *))
1330            return 1;
1331          return 0;
1332        }],
1333        gdb_cv_prfpregset_t_broken=no,
1334        gdb_cv_prfpregset_t_broken=yes,
1335        gdb_cv_prfpregset_t_broken=yes)])
1336     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1337     if test $gdb_cv_prfpregset_t_broken = yes; then
1338       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1339       [Define if the prfpregset_t type is broken.])
1340     fi
1341   fi
1342
1343   dnl Check for PIOCSET ioctl entry
1344
1345   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1346   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1347   [AC_TRY_COMPILE([#include <unistd.h>
1348 #include <sys/types.h>
1349 #include <sys/procfs.h>
1350 ], [
1351     int dummy;;
1352     dummy = ioctl(0, PIOCSET, &dummy);
1353   ],
1354   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1355   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1356   if test $gdb_cv_have_procfs_piocset = yes; then
1357     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1358     [Define if ioctl argument PIOCSET is available.])
1359   fi
1360 fi
1361
1362 dnl For native ports (host == target), check to see what kind of
1363 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1364 if test ${host} = ${target} ; then
1365   dnl Check for struct link_map with l_ members which are indicative
1366   dnl of SVR4-like shared libraries
1367
1368   AC_MSG_CHECKING(for member l_addr in struct link_map)
1369   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1370     [AC_TRY_COMPILE([#include <link.h>],
1371                     [struct link_map lm; (void) lm.l_addr;],
1372                     gdb_cv_have_struct_link_map_with_l_members=yes,
1373                     gdb_cv_have_struct_link_map_with_l_members=no)])
1374   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1375   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1376     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1377     [Define if <link.h> exists and defines struct link_map which has
1378      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1379      SVR4-like systems.)])
1380   fi
1381
1382   dnl Check for struct link_map with lm_ members which are indicative
1383   dnl of SunOS-like shared libraries
1384
1385   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1386   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1387     [AC_TRY_COMPILE([#include <sys/types.h>
1388 #include <link.h>],
1389                     [struct link_map lm; (void) lm.lm_addr;],
1390                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1391                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1392   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1393   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1394     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1395     [Define if <link.h> exists and defines struct link_map which has
1396      members with an ``lm_'' prefix.  (For SunOS.)])
1397   fi
1398
1399   dnl Check for struct so_map with som_ members which are found on
1400   dnl some *BSD systems.
1401
1402   AC_MSG_CHECKING(for member som_addr in struct so_map)
1403   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1404     [AC_TRY_COMPILE([#include <sys/types.h>
1405 #ifdef HAVE_NLIST_H
1406 #include <nlist.h>
1407 #endif
1408 #include <link.h>],
1409                     [struct so_map lm; (void) lm.som_addr;],
1410                     gdb_cv_have_struct_so_map_with_som_members=yes,
1411                     gdb_cv_have_struct_so_map_with_som_members=no)])
1412   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1413   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1414     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1415     [Define if <link.h> exists and defines a struct so_map which has
1416      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1417   fi
1418
1419   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1420   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1421
1422   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1423   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1424     [AC_TRY_COMPILE([#define _SYSCALL32
1425 #include <sys/link.h>], [struct link_map32 l;],
1426      gdb_cv_have_struct_link_map32=yes,
1427      gdb_cv_have_struct_link_map32=no)])
1428   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1429   if test $gdb_cv_have_struct_link_map32 = yes; then
1430     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1431     [Define if <sys/link.h> has struct link_map32])
1432     AC_DEFINE(_SYSCALL32, 1,
1433     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1434   fi
1435 fi
1436
1437 # Check if the compiler supports the `long long' type.
1438
1439 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1440                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1441 [[extern long long foo;]],
1442 [[switch (foo & 2) { case 0: return 1; }]])],
1443                                   gdb_cv_c_long_long=yes,
1444                                   gdb_cv_c_long_long=no)])
1445 if test $gdb_cv_c_long_long = yes; then
1446   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1447             [Define to 1 if the compiler supports long long.])
1448 fi
1449
1450 # Check if the compiler and runtime support printing long longs.
1451
1452 AC_CACHE_CHECK([for long long support in printf],
1453                gdb_cv_printf_has_long_long,
1454                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1455 [[char buf[32];
1456   long long l = 0;
1457   l = (l << 16) + 0x0123;
1458   l = (l << 16) + 0x4567;
1459   l = (l << 16) + 0x89ab;
1460   l = (l << 16) + 0xcdef;
1461   sprintf (buf, "0x%016llx", l);
1462   return (strcmp ("0x0123456789abcdef", buf));]])],
1463                               gdb_cv_printf_has_long_long=yes,
1464                               gdb_cv_printf_has_long_long=no,
1465                               gdb_cv_printf_has_long_long=no)])
1466 if test $gdb_cv_printf_has_long_long = yes; then
1467   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1468             [Define to 1 if the "%ll" format works to print long longs.])
1469 fi
1470
1471 # Check if the compiler and runtime support printing decfloats.
1472
1473 AC_CACHE_CHECK([for decfloat support in printf],
1474                gdb_cv_printf_has_decfloat,
1475                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1476 [[char buf[64];
1477   _Decimal32 d32 = 1.2345df;
1478   _Decimal64 d64 = 1.2345dd;
1479   _Decimal128 d128 = 1.2345dl;
1480   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1481   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1482                               gdb_cv_printf_has_decfloat=yes,
1483                               gdb_cv_printf_has_decfloat=no,
1484                               gdb_cv_printf_has_decfloat=no)])
1485 if test $gdb_cv_printf_has_decfloat = yes; then
1486   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1487             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1488 fi
1489
1490 # Check if the compiler supports the `long double' type.  We can't use
1491 # AC_C_LONG_DOUBLE because that one does additional checks on the
1492 # constants defined in <float.h> that fail on some systems,
1493 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1494
1495 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1496                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1497                                   gdb_cv_c_long_double=yes,
1498                                   gdb_cv_c_long_double=no)])
1499 if test $gdb_cv_c_long_double = yes; then
1500   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1501            [Define to 1 if the compiler supports long double.])
1502 fi
1503
1504 # Check if the compiler and runtime support printing long doubles.
1505
1506 AC_CACHE_CHECK([for long double support in printf],
1507                gdb_cv_printf_has_long_double,
1508                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1509 [[char buf[16];
1510   long double f = 3.141592653;
1511   sprintf (buf, "%Lg", f);
1512   return (strncmp ("3.14159", buf, 7));]])],
1513                               gdb_cv_printf_has_long_double=yes,
1514                               gdb_cv_printf_has_long_double=no,
1515                               gdb_cv_printf_has_long_double=no)])
1516 if test $gdb_cv_printf_has_long_double = yes; then
1517   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1518             [Define to 1 if the "%Lg" format works to print long doubles.])
1519 fi
1520
1521 # Check if the compiler and runtime support scanning long doubles.
1522
1523 AC_CACHE_CHECK([for long double support in scanf],
1524                gdb_cv_scanf_has_long_double,
1525                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1526 [[#include <stdio.h>]],
1527 [[char *buf = "3.141592653";
1528   long double f = 0;
1529   sscanf (buf, "%Lg", &f);
1530   return !(f > 3.14159 && f < 3.14160);]])],
1531                               gdb_cv_scanf_has_long_double=yes,
1532                               gdb_cv_scanf_has_long_double=no,
1533                               gdb_cv_scanf_has_long_double=no)])
1534 if test $gdb_cv_scanf_has_long_double = yes; then
1535   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1536             [Define to 1 if the "%Lg" format works to scan long doubles.])
1537 fi
1538
1539 case ${host_os} in
1540 aix*)
1541   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1542     SAVE_LDFLAGS=$LDFLAGS
1543
1544     case $GCC in
1545     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1546     *) gdb_cv_bigtoc=-bbigtoc ;;
1547     esac
1548
1549     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1550     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1551     LDFLAGS="${SAVE_LDFLAGS}"
1552   ])
1553   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1554   ;;
1555 esac
1556
1557 AC_MSG_CHECKING(for the dynamic export flag)
1558 dynamic_list=false
1559 if test "${gdb_native}" = yes; then
1560    # The dynamically loaded libthread_db needs access to symbols in the gdb
1561    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1562    # may not be supported there.
1563    old_LDFLAGS="$LDFLAGS"
1564    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1565    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1566    LDFLAGS="$LDFLAGS $RDYNAMIC"
1567    if test "${have_libpython}" = no; then
1568      AC_TRY_LINK([], [], [dynamic_list=true])
1569    else
1570      # Workaround http://bugs.python.org/issue4434 where static
1571      # libpythonX.Y.a would get its symbols required for
1572      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1573      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1574      old_CFLAGS="$CFLAGS"
1575      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1576      AC_RUN_IFELSE(
1577        AC_LANG_PROGRAM(
1578          [#include "]${have_libpython}[/Python.h"],
1579          [int err;
1580           Py_Initialize ();
1581           err = PyRun_SimpleString ("import itertools\n");
1582           Py_Finalize ();
1583           return err == 0 ? 0 : 1;]),
1584        [dynamic_list=true], [], [true])
1585      CFLAGS="$old_CFLAGS"
1586    fi
1587    LDFLAGS="$old_LDFLAGS"
1588 fi
1589 if $dynamic_list; then
1590   found="-Wl,--dynamic-list"
1591   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1592 else
1593   found="-rdynamic"
1594   RDYNAMIC="-rdynamic"
1595 fi
1596 AC_SUBST(RDYNAMIC)
1597 AC_MSG_RESULT($found)
1598
1599 dnl For certain native configurations, we need to check whether thread
1600 dnl support can be built in or not.
1601 dnl
1602 dnl Note that we only want this if we are both native (host == target),
1603 dnl and not doing a canadian cross build (build == host).
1604
1605 if test ${build} = ${host} -a ${host} = ${target} ; then
1606    case ${host_os} in
1607    solaris*)
1608       # See if thread_db library is around for Solaris thread debugging.
1609       # Note that we must explicitly test for version 1 of the library
1610       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1611       # the same API.
1612       AC_MSG_CHECKING(for Solaris thread debugging library)
1613       if test -f /usr/lib/libthread_db.so.1 ; then
1614          AC_MSG_RESULT(yes)
1615          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1616          [Define if using Solaris thread debugging.])
1617          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1618          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1619          AC_CHECK_LIB(dl, dlopen)
1620          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1621          # Sun randomly tweaked the prototypes in <proc_service.h>
1622          # at one point.
1623          AC_MSG_CHECKING(if <proc_service.h> is old)
1624          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1625             AC_TRY_COMPILE([
1626                 #include <proc_service.h>
1627                 ps_err_e ps_pdwrite
1628                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1629             ],, gdb_cv_proc_service_is_old=no,
1630                 gdb_cv_proc_service_is_old=yes)
1631          ])
1632          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1633          if test $gdb_cv_proc_service_is_old = yes; then
1634             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1635             [Define if <proc_service.h> on solaris uses int instead of
1636              size_t, and assorted other type changes.])
1637          fi
1638       else
1639          AC_MSG_RESULT(no)
1640       fi
1641       ;;
1642    aix*)
1643       AC_MSG_CHECKING(for AiX thread debugging library)
1644       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1645                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1646                                    [#ifndef PTHDB_VERSION_3
1647                                     #error
1648                                     #endif],
1649                                    gdb_cv_have_aix_thread_debug=yes,
1650                                    gdb_cv_have_aix_thread_debug=no)])
1651       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1652       if test $gdb_cv_have_aix_thread_debug = yes; then
1653          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1654          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1655          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1656
1657          # Older versions of AIX do not provide the declaration for
1658          # the getthrds function (it appears that it was introduced
1659          # with AIX 6.x).
1660          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1661       fi
1662       ;;
1663    esac
1664    AC_SUBST(CONFIG_LDFLAGS)
1665 fi
1666
1667 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1668 dnl other error codes.
1669 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1670    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1671                   gdb_cv_thread_db_h_has_td_notalloc,
1672      AC_TRY_COMPILE(
1673        [#include <thread_db.h>],
1674        [int i = TD_NOTALLOC;],
1675        gdb_cv_thread_db_h_has_td_notalloc=yes,
1676        gdb_cv_thread_db_h_has_td_notalloc=no
1677      )
1678    )
1679    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1680                   gdb_cv_thread_db_h_has_td_version,
1681      AC_TRY_COMPILE(
1682        [#include <thread_db.h>],
1683        [int i = TD_VERSION;],
1684        gdb_cv_thread_db_h_has_td_version=yes,
1685        gdb_cv_thread_db_h_has_td_version=no
1686      )
1687    )
1688    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1689                   gdb_cv_thread_db_h_has_td_notls,
1690      AC_TRY_COMPILE(
1691        [#include <thread_db.h>],
1692        [int i = TD_NOTLS;],
1693        gdb_cv_thread_db_h_has_td_notls=yes,
1694        gdb_cv_thread_db_h_has_td_notls=no
1695      )
1696    )
1697 fi
1698 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1699   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1700             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1701 fi
1702 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1703   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1704             [Define if <thread_db.h> has the TD_VERSION error code.])
1705 fi
1706 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1707   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1708             [Define if <thread_db.h> has the TD_NOTLS error code.])
1709 fi
1710
1711 dnl See if we have a sys/syscall header file that has __NR_tkill.
1712 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1713    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1714                   gdb_cv_sys_syscall_h_has_tkill,
1715      AC_TRY_COMPILE(
1716        [#include <sys/syscall.h>],
1717        [int i = __NR_tkill;],
1718        gdb_cv_sys_syscall_h_has_tkill=yes,
1719        gdb_cv_sys_syscall_h_has_tkill=no
1720      )
1721    )
1722 fi
1723 dnl See if we can issue tkill syscall.
1724 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1725   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1726 fi
1727
1728 dnl Check if we can disable the virtual address space randomization.
1729 dnl The functionality of setarch -R.
1730 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1731 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1732 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1733 #       define ADDR_NO_RANDOMIZE 0x0040000
1734 #      endif
1735        /* Test the flag could be set and stays set.  */
1736        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1737        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1738            return 1])])
1739 AC_RUN_IFELSE([PERSONALITY_TEST],
1740               [have_personality=true],
1741               [have_personality=false],
1742               [AC_LINK_IFELSE([PERSONALITY_TEST],
1743                               [have_personality=true],
1744                               [have_personality=false])])
1745 if $have_personality
1746 then
1747     AC_DEFINE([HAVE_PERSONALITY], 1,
1748               [Define if you support the personality syscall.])
1749 fi
1750
1751 dnl Handle optional features that can be enabled.
1752
1753 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1754 # except that the argument to --with-sysroot is optional.
1755 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1756 if test "x$with_sysroot" = xyes; then
1757   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1758 fi
1759 AC_ARG_WITH(sysroot,
1760   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1761                  [search for usr/lib et al within DIR]),
1762   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1763 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1764               [search for usr/lib et al within DIR])
1765 AC_SUBST(TARGET_SYSTEM_ROOT)
1766 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1767
1768 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1769     [automatically load a system-wide gdbinit file],
1770     [])
1771
1772 AC_ARG_ENABLE(werror,
1773   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1774   [case "${enableval}" in
1775      yes | y) ERROR_ON_WARNING="yes" ;;
1776      no | n)  ERROR_ON_WARNING="no" ;;
1777      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1778    esac])
1779
1780 # Enable -Werror by default when using gcc
1781 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1782     ERROR_ON_WARNING=yes
1783 fi
1784
1785 WERROR_CFLAGS=""
1786 if test "${ERROR_ON_WARNING}" = yes ; then
1787     WERROR_CFLAGS="-Werror"
1788 fi
1789
1790 # The entries after -Wno-pointer-sign are disabled warnings which may
1791 # be enabled in the future, which can not currently be used to build
1792 # GDB.
1793 # NOTE: If you change this list, remember to update
1794 # gdb/doc/gdbint.texinfo.
1795 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1796 -Wformat-nonliteral -Wno-pointer-sign \
1797 -Wno-unused -Wunused-value -Wunused-function \
1798 -Wno-switch -Wno-char-subscripts"
1799
1800 # Enable -Wno-format by default when using gcc on mingw since many
1801 # GCC versions complain about %I64.
1802 case "${host}" in
1803   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1804 esac
1805
1806 AC_ARG_ENABLE(build-warnings,
1807 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1808 [case "${enableval}" in
1809   yes)  ;;
1810   no)   build_warnings="-w";;
1811   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1812         build_warnings="${build_warnings} ${t}";;
1813   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1814         build_warnings="${t} ${build_warnings}";;
1815   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1816 esac
1817 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1818   echo "Setting compiler warning flags = $build_warnings" 6>&1
1819 fi])dnl
1820 AC_ARG_ENABLE(gdb-build-warnings,
1821 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1822 [case "${enableval}" in
1823   yes)  ;;
1824   no)   build_warnings="-w";;
1825   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1826         build_warnings="${build_warnings} ${t}";;
1827   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1828         build_warnings="${t} ${build_warnings}";;
1829   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1830 esac
1831 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1832   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1833 fi])dnl
1834 WARN_CFLAGS=""
1835 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1836 then
1837     AC_MSG_CHECKING(compiler warning flags)
1838     # Separate out the -Werror flag as some files just cannot be
1839     # compiled with it enabled.
1840     for w in ${build_warnings}; do
1841         case $w in
1842         -Werr*) WERROR_CFLAGS=-Werror ;;
1843         *) # Check that GCC accepts it
1844             saved_CFLAGS="$CFLAGS"
1845             CFLAGS="$CFLAGS $w"
1846             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1847             CFLAGS="$saved_CFLAGS"
1848         esac
1849     done
1850     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1851 fi
1852 AC_SUBST(WARN_CFLAGS)
1853 AC_SUBST(WERROR_CFLAGS)
1854
1855 # In the Cygwin environment, we need some additional flags.
1856 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1857 [AC_EGREP_CPP(lose, [
1858 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1859 lose
1860 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1861
1862
1863 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1864 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1865 case ${host} in
1866   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1867   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1868   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1869 esac
1870 AC_SUBST(SER_HARDWIRE)
1871
1872 # libreadline needs libuser32.a in a cygwin environment
1873 WIN32LIBS=
1874 if test x$gdb_cv_os_cygwin = xyes; then
1875     WIN32LIBS="-luser32"
1876     case "${target}" in
1877         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1878         ;;
1879     esac
1880 fi
1881
1882 # The ser-tcp.c module requires sockets.
1883 case ${host} in
1884   *mingw32*)
1885     AC_DEFINE(USE_WIN32API, 1,
1886               [Define if we should use the Windows API, instead of the
1887                POSIX API.  On Windows, we use the Windows API when
1888                building for MinGW, but the POSIX API when building
1889                for Cygwin.])
1890     WIN32LIBS="$WIN32LIBS -lws2_32"
1891     ;;
1892 esac
1893 AC_SUBST(WIN32LIBS)
1894
1895 # Add ELF support to GDB, but only if BFD includes ELF support.
1896 OLD_CFLAGS=$CFLAGS
1897 OLD_LDFLAGS=$LDFLAGS
1898 OLD_LIBS=$LIBS
1899 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1900 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
1901 # always want our bfd.
1902 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1903 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1904 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1905 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1906 if test "$plugins" = "yes"; then
1907   LIBS="-ldl $LIBS"
1908 fi
1909 LIBS="-lbfd -liberty $intl $LIBS"
1910 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1911 [AC_TRY_LINK(
1912 [#include <stdlib.h>
1913 #include "bfd.h"
1914 #include "elf-bfd.h"
1915 ],
1916 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1917 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1918 if test $gdb_cv_var_elf = yes; then
1919   CONFIG_OBS="$CONFIG_OBS elfread.o"
1920   AC_DEFINE(HAVE_ELF, 1,
1921             [Define if ELF support should be included.])
1922   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1923   if test "$plugins" = "yes"; then
1924     OLD_LIBS="-ldl $OLD_LIBS"
1925   fi
1926 fi
1927 CFLAGS=$OLD_CFLAGS
1928 LDFLAGS=$OLD_LDFLAGS
1929 LIBS=$OLD_LIBS
1930
1931 # Add any host-specific objects to GDB.
1932 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1933
1934 LIBGUI="../libgui/src/libgui.a"
1935 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1936 AC_SUBST(LIBGUI)
1937 AC_SUBST(GUI_CFLAGS_X)
1938
1939 WIN32LDAPP=
1940 AC_SUBST(WIN32LIBS)
1941 AC_SUBST(WIN32LDAPP)
1942
1943 case "${host}" in
1944 *-*-cygwin* | *-*-mingw* )
1945     configdir="win"
1946     ;;
1947 *)
1948     configdir="unix"
1949     ;;
1950 esac
1951
1952 GDBTKLIBS=
1953 if test "${enable_gdbtk}" = "yes"; then
1954
1955     # Gdbtk must have an absolute path to srcdir in order to run
1956     # properly when not installed.
1957     here=`pwd`
1958     cd ${srcdir}
1959     GDBTK_SRC_DIR=`pwd`
1960     cd $here
1961
1962     SC_PATH_TCLCONFIG
1963
1964     # If $no_tk is nonempty, then we can't do Tk, and there is no
1965     # point to doing Tcl.
1966     SC_PATH_TKCONFIG
1967
1968     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1969         SC_LOAD_TCLCONFIG
1970
1971         # Check for in-tree tcl
1972         here=`pwd`
1973         cd ${srcdir}/..
1974         topdir=`pwd`
1975         cd ${here}
1976
1977         intree="no"
1978         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1979           intree="yes"
1980         fi
1981
1982         # Find Tcl private headers
1983         if test x"${intree}" = xno; then
1984           CY_AC_TCL_PRIVATE_HEADERS
1985           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1986           TCL_LIBRARY="${TCL_LIB_SPEC}"
1987           TCL_DEPS=""
1988         else
1989           # If building tcl in the same src tree, private headers
1990           # are not needed, but we need to be sure to use the right
1991           # headers library
1992           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1993           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1994           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1995         fi
1996         AC_SUBST(TCL_INCLUDE)
1997         AC_SUBST(TCL_LIBRARY)
1998         AC_SUBST(TCL_DEPS)
1999
2000         SC_LOAD_TKCONFIG
2001
2002         # Check for in-tree Tk
2003         intree="no"
2004         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2005           intree="yes"
2006         fi
2007
2008         # Find Tk private headers
2009         if test x"${intree}" = xno; then
2010           CY_AC_TK_PRIVATE_HEADERS
2011           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2012           TK_LIBRARY=${TK_LIB_SPEC}
2013           TK_DEPS=""
2014         else
2015           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2016           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2017           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2018         fi
2019         AC_SUBST(TK_INCLUDE)
2020         AC_SUBST(TK_LIBRARY)
2021         AC_SUBST(TK_DEPS)
2022         AC_SUBST(TK_XINCLUDES)
2023
2024         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2025
2026         # Include some libraries that Tcl and Tk want.
2027         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2028         # Yes, the ordering seems wrong here.  But it isn't.
2029         # TK_LIBS is the list of libraries that need to be linked
2030         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2031         # were in LIBS then any link tests after this point would
2032         # try to include things like `$(LIBGUI)', which wouldn't work.
2033         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2034
2035         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2036         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2037         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2038         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2039         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2040         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2041         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2042
2043         if test x$gdb_cv_os_cygwin = xyes; then
2044           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2045           WIN32LDAPP="-Wl,--subsystem,console"
2046           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2047         fi
2048
2049         AC_CONFIG_SUBDIRS(gdbtk)
2050     fi
2051 fi
2052
2053 AC_SUBST(X_CFLAGS)
2054 AC_SUBST(X_LDFLAGS)
2055 AC_SUBST(X_LIBS)
2056 AC_SUBST(GDBTKLIBS)
2057 AC_SUBST(GDBTK_CFLAGS)
2058 AC_SUBST(GDBTK_SRC_DIR)
2059
2060 AC_PATH_X
2061
2062 # Unlike the sim directory, whether a simulator is linked is controlled by
2063 # presence of a gdb_sim definition in the target configure.tgt entry.
2064 # This code just checks for a few cases where we'd like to ignore those
2065 # definitions, even when they're present in the '.mt' file.  These cases
2066 # are when --disable-sim is specified, or if the simulator directory is
2067 # not part of the source tree.
2068 #
2069 AC_ARG_ENABLE(sim,
2070 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2071 [echo "enable_sim = $enable_sim";
2072  echo "enableval = ${enableval}";
2073  case "${enableval}" in
2074   yes) ignore_sim=false ;;
2075   no)  ignore_sim=true ;;
2076   *)   ignore_sim=false ;;
2077  esac],
2078 [ignore_sim=false])
2079
2080 if test ! -d "${srcdir}/../sim"; then
2081   ignore_sim=true
2082 fi
2083
2084 SIM=
2085 SIM_OBS=
2086 if test "${ignore_sim}" = "false"; then
2087   if test x"${gdb_sim}" != x ; then
2088     SIM="${gdb_sim}"
2089     SIM_OBS="remote-sim.o"
2090     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2091   fi
2092 fi
2093 AC_SUBST(SIM)
2094 AC_SUBST(SIM_OBS)
2095
2096 AC_SUBST(ENABLE_CFLAGS)
2097 AC_SUBST(PROFILE_CFLAGS)
2098
2099 AC_SUBST(CONFIG_OBS)
2100 AC_SUBST(CONFIG_DEPS)
2101 AC_SUBST(CONFIG_SRCS)
2102 AC_SUBST(CONFIG_ALL)
2103 AC_SUBST(CONFIG_CLEAN)
2104 AC_SUBST(CONFIG_INSTALL)
2105 AC_SUBST(CONFIG_UNINSTALL)
2106
2107 # List of host floatformats.
2108 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2109 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2110 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2111
2112 # target_subdir is used by the testsuite to find the target libraries.
2113 target_subdir=
2114 if test "${host}" != "${target}"; then
2115     target_subdir="${target_alias}/"
2116 fi
2117 AC_SUBST(target_subdir)
2118
2119 frags=
2120 if test "${gdb_native}" = "yes"; then
2121   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2122   if test ! -f ${host_makefile_frag}; then
2123     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2124   fi
2125   frags="$frags $host_makefile_frag"
2126 else
2127   host_makefile_frag=/dev/null
2128 fi
2129
2130 AC_SUBST_FILE(host_makefile_frag)
2131 AC_SUBST(frags)
2132
2133 changequote(,)dnl
2134 if test "${gdb_native}" = "yes"; then
2135 # We pick this up from the host configuration file (.mh) because we
2136 # do not have a native configuration Makefile fragment.
2137 nativefile=`sed -n '
2138 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2139 ' ${host_makefile_frag}`
2140 fi
2141 changequote([,])
2142
2143 if test x"${gdb_osabi}" != x ; then
2144     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2145                        [Define to the default OS ABI for this configuration.])
2146 fi
2147
2148 # Enable multi-ice-gdb-server.
2149 AC_ARG_ENABLE(multi-ice,
2150 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2151   [case $enableval in
2152     yes | no)
2153       ;;
2154     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2155   esac])
2156 if test "x$enable_multi_ice" = xyes; then
2157    AC_CONFIG_SUBDIRS(multi-ice)
2158 fi
2159
2160 AC_ARG_ENABLE(gdbserver,
2161 AS_HELP_STRING([--enable-gdbserver],
2162                [automatically build gdbserver (yes/no/auto, default is auto)]),
2163 [case "${enableval}" in
2164   yes| no|auto) ;;
2165   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2166 esac],[enable_gdbserver=auto])
2167
2168 # We only build gdbserver automatically in a native configuration, and
2169 # only if the user did not explicitly disable its build.
2170 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2171   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2172   if test "x$build_gdbserver" = xyes; then
2173     AC_MSG_RESULT(yes)
2174     AC_CONFIG_SUBDIRS(gdbserver)
2175     gdbserver_build_enabled=yes
2176   else
2177     AC_MSG_RESULT(no)
2178   fi
2179 fi
2180
2181 # If the user explicitly request the gdbserver to be built, verify that
2182 # we were in fact able to enable it.
2183 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2184   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2185 fi
2186
2187 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2188 # to an empty version.
2189
2190 files=
2191 links=
2192
2193 rm -f nm.h
2194 if test "${nativefile}" != ""; then
2195     case "${nativefile}" in
2196       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2197       * ) GDB_NM_FILE="${nativefile}"
2198     esac
2199     files="${files} ${GDB_NM_FILE}"
2200     links="${links} nm.h"
2201     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2202 fi
2203 AC_SUBST(GDB_NM_FILE)
2204
2205 AC_LINK_FILES($files, $links)
2206
2207 dnl Check for exe extension set on certain hosts (e.g. Win32)
2208 AC_EXEEXT
2209
2210 dnl  Detect the character set used by this host.
2211 dnl  At the moment, we just assume it's UTF-8.
2212 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2213           [Define to be a string naming the default host character set.])
2214
2215 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2216 [
2217 case x$CONFIG_HEADERS in
2218 xconfig.h:config.in)
2219 echo > stamp-h ;;
2220 esac
2221 ])
2222
2223 exit 0