projects / deliverable / binutils-gdb.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
gdb/
[deliverable/binutils-gdb.git] / gdb / configure.ac
1 dnl Autoconf configure script for GDB, the GNU debugger.
2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
3 dnl
4 dnl This file is part of GDB.
5 dnl
6 dnl This program is free software; you can redistribute it and/or modify
7 dnl it under the terms of the GNU General Public License as published by
8 dnl the Free Software Foundation; either version 3 of the License, or
9 dnl (at your option) any later version.
10 dnl
11 dnl This program is distributed in the hope that it will be useful,
12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 dnl GNU General Public License for more details.
15 dnl
16 dnl You should have received a copy of the GNU General Public License
17 dnl along with this program. If not, see <http://www.gnu.org/licenses/>.
18
19 dnl Process this file with autoconf to produce a configure script.
20
21 AC_PREREQ(2.59)dnl
22 AC_INIT(main.c)
23 AC_CONFIG_HEADER(config.h:config.in)
24 AM_MAINTAINER_MODE
25
26 AC_PROG_CC
27 AC_USE_SYSTEM_EXTENSIONS
28 ACX_LARGEFILE
29 AM_PROG_CC_STDC
30
31 AC_CONFIG_AUX_DIR(..)
32 AC_CANONICAL_SYSTEM
33 AC_ARG_PROGRAM
34
35 # Dependency checking.
36 ZW_CREATE_DEPDIR
37 ZW_PROG_COMPILER_DEPENDENCIES([CC])
38
39 # Check for the 'make' the user wants to use.
40 AC_CHECK_PROGS(MAKE, make)
41 MAKE_IS_GNU=
42 case "`$MAKE --version 2>&1 | sed 1q`" in
43 *GNU*)
44 MAKE_IS_GNU=yes
45 ;;
46 esac
47 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
48 AC_PROG_MAKE_SET
49
50 # Configure gnulib. We need to build gnulib under some other
51 # directory not "gnulib", to avoid the problem of both GDB and
52 # GDBserver wanting to build it in the same directory, when building
53 # in the source dir.
54 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
55
56 dnl List of object files and targets accumulated by configure.
57
58 CONFIG_OBS=
59 CONFIG_DEPS=
60 CONFIG_SRCS=
61 ENABLE_CFLAGS=
62
63 CONFIG_ALL=
64 CONFIG_CLEAN=
65 CONFIG_INSTALL=
66 CONFIG_UNINSTALL=
67
68 dnl Set up for gettext.
69 ZW_GNU_GETTEXT_SISTER_DIR
70
71 localedir='${datadir}/locale'
72 AC_SUBST(localedir)
73
74 if test x"$USE_NLS" = xyes; then
75 CONFIG_ALL="$CONFIG_ALL all-po"
76 CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
77 CONFIG_INSTALL="$CONFIG_INSTALL install-po"
78 CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
79 fi
80
81 GNULIB=build-gnulib/import
82
83 # For Makefile dependencies.
84 GNULIB_STDINT_H=
85 if test x"$STDINT_H" != x; then
86 GNULIB_STDINT_H=$GNULIB/$STDINT_H
87 fi
88 AC_SUBST(GNULIB_STDINT_H)
89
90 PACKAGE=gdb
91 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
92 AC_SUBST(PACKAGE)
93
94 # We never need to detect it in this sub-configure.
95 # But preserve it for config.status --recheck.
96 AC_ARG_VAR(MAKEINFO,
97 [Parent configure detects if it is of sufficient version.])
98 AC_ARG_VAR(MAKEINFOFLAGS,
99 [Parameters for MAKEINFO.])
100
101 MAKEINFO_EXTRA_FLAGS=""
102 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
103 [echo '@clicksequence{a @click{} b}' >conftest.texinfo
104 if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
105 gdb_cv_have_makeinfo_click=yes
106 else
107 gdb_cv_have_makeinfo_click=no
108 fi])
109 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
110 MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
111 fi
112 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
113
114 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
115 [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
116 [${libdir}/debug])
117
118 # We can't pass paths as command line arguments.
119 # Mingw32 tries to be clever and will convert the paths for us.
120 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
121 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
122 # This breaks GDB's relocatable path conversions since paths passed in
123 # config.h would not get so translated, the path prefixes no longer match.
124 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
125
126 # GDB's datadir relocation
127
128 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
129 [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
130 [${datadir}/gdb])
131
132 AC_ARG_WITH(relocated-sources,
133 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
134 [reloc_srcdir="${withval}"
135 AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
136 [Relocated directory for source files. ])
137 ])
138
139 AC_MSG_CHECKING([for default auto-load directory])
140 AC_ARG_WITH(auto-load-dir,
141 AS_HELP_STRING([--with-auto-load-dir=PATH],
142 [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
143 [with_auto_load_dir='$debugdir:$datadir/auto-load'])
144 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
145 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
146 [Directories from which to load auto-loaded scripts.])
147 AC_MSG_RESULT([$with_auto_load_dir])
148
149 AC_MSG_CHECKING([for default auto-load safe-path])
150 AC_ARG_WITH(auto-load-safe-path,
151 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
152 [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
153 AS_HELP_STRING([--without-auto-load-safe-path],
154 [do not restrict auto-loaded files locations]),
155 [if test "$with_auto_load_safe_path" = "no"; then
156 with_auto_load_safe_path="/"
157 fi],
158 [with_auto_load_safe_path="$with_auto_load_dir"])
159 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
160 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
161 [Directories safe to hold auto-loaded files.])
162 AC_MSG_RESULT([$with_auto_load_safe_path])
163
164 AC_CONFIG_SUBDIRS(testsuite)
165
166 # Check whether to support alternative target configurations
167 AC_ARG_ENABLE(targets,
168 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
169 [case "${enableval}" in
170 yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
171 ;;
172 no) enable_targets= ;;
173 *) enable_targets=$enableval ;;
174 esac])
175
176 # Check whether to enable 64-bit support on 32-bit hosts
177 AC_ARG_ENABLE(64-bit-bfd,
178 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
179 [case "${enableval}" in
180 yes) want64=true ;;
181 no) want64=false ;;
182 *) AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
183 esac],[want64=false])dnl
184
185 # Provide defaults for some variables set by the per-host and per-target
186 # configuration.
187 gdb_host_obs=posix-hdep.o
188
189 if test "${target}" = "${host}"; then
190 gdb_native=yes
191 else
192 gdb_native=no
193 fi
194
195 . $srcdir/configure.host
196
197 # Accumulate some settings from configure.tgt over all enabled targets
198
199 TARGET_OBS=
200 all_targets=
201
202 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
203 do
204 if test "$targ_alias" = "all"; then
205 all_targets=true
206 else
207 # Canonicalize the secondary target names.
208 result=`$ac_config_sub $targ_alias 2>/dev/null`
209 if test -n "$result"; then
210 targ=$result
211 else
212 targ=$targ_alias
213 fi
214
215 . ${srcdir}/configure.tgt
216
217 AS_IF([test -z "${gdb_target_obs}"],
218 [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
219
220 # Target-specific object files
221 for i in ${gdb_target_obs}; do
222 case " $TARGET_OBS " in
223 *" ${i} "*) ;;
224 *)
225 TARGET_OBS="$TARGET_OBS ${i}"
226 ;;
227 esac
228 done
229
230 # Check whether this target needs 64-bit CORE_ADDR
231 if test x${want64} = xfalse; then
232 . ${srcdir}/../bfd/config.bfd
233 fi
234 fi
235 done
236
237 if test x${all_targets} = xtrue; then
238
239 # We want all 64-bit targets if we either:
240 # - run on a 64-bit host or
241 # - already require 64-bit support for some other target or
242 # - the --enable-64-bit-bfd option was supplied
243 # Otherwise we only support all 32-bit targets.
244 #
245 # NOTE: This test must be in sync with the corresponding
246 # tests in BFD!
247
248 if test x${want64} = xfalse; then
249 AC_CHECK_SIZEOF(long)
250 if test "x${ac_cv_sizeof_long}" = "x8"; then
251 want64=true
252 fi
253 fi
254 if test x${want64} = xtrue; then
255 TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
256 else
257 TARGET_OBS='$(ALL_TARGET_OBS)'
258 fi
259 fi
260
261 AC_SUBST(TARGET_OBS)
262
263 # For other settings, only the main target counts.
264 gdb_sim=
265 gdb_osabi=
266 build_gdbserver=
267 targ=$target; . ${srcdir}/configure.tgt
268
269 # Fetch the default architecture and default target vector from BFD.
270 targ=$target; . $srcdir/../bfd/config.bfd
271
272 # We only want the first architecture, so strip off the others if
273 # there is more than one.
274 targ_archs=`echo $targ_archs | sed 's/ .*//'`
275
276 if test "x$targ_archs" != x; then
277 AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
278 [Define to BFD's default architecture. ])
279 fi
280 if test "x$targ_defvec" != x; then
281 AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
282 [Define to BFD's default target vector. ])
283 fi
284
285 # The CLI cannot be disabled yet, but may be in the future.
286
287 # Enable CLI.
288 AC_ARG_ENABLE(gdbcli,
289 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
290 [case $enableval in
291 yes)
292 ;;
293 no)
294 AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
295 *)
296 AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
297 esac],
298 [enable_gdbcli=yes])
299 if test x"$enable_gdbcli" = xyes; then
300 if test -d $srcdir/cli; then
301 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
302 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
303 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
304 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
305 fi
306 fi
307
308 # Enable MI.
309 AC_ARG_ENABLE(gdbmi,
310 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
311 [case $enableval in
312 yes | no)
313 ;;
314 *)
315 AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
316 esac],
317 [enable_gdbmi=yes])
318 if test x"$enable_gdbmi" = xyes; then
319 if test -d $srcdir/mi; then
320 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
321 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
322 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
323 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
324 fi
325 fi
326
327 # Enable TUI.
328 AC_ARG_ENABLE(tui,
329 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
330 [case $enableval in
331 yes | no | auto)
332 ;;
333 *)
334 AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
335 esac],enable_tui=auto)
336
337 # Enable gdbtk.
338 AC_ARG_ENABLE(gdbtk,
339 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
340 [case $enableval in
341 yes | no)
342 ;;
343 *)
344 AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
345 esac],
346 [if test -d $srcdir/gdbtk; then
347 enable_gdbtk=yes
348 else
349 enable_gdbtk=no
350 fi])
351 # We unconditionally disable gdbtk tests on selected platforms.
352 case $host_os in
353 go32* | windows*)
354 AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
355 enable_gdbtk=no ;;
356 esac
357
358 # Libunwind support for ia64.
359
360 AC_ARG_WITH(libunwind-ia64,
361 AS_HELP_STRING([--with-libunwind-ia64],
362 [use libunwind frame unwinding for ia64 targets]),,
363 [with_libunwind_ia64=auto])
364
365 # Backward compatibility option.
366 if test "${with_libunwind+set}" = set; then
367 if test x"$with_libunwind_ia64" != xauto; then
368 AC_MSG_ERROR(
369 [option --with-libunwind is deprecated, use --with-libunwind-ia64])
370 fi
371 AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
372 with_libunwind_ia64="$with_libunwind"
373 fi
374
375 case "$with_libunwind_ia64" in
376 yes | no)
377 ;;
378 auto)
379 AC_CHECK_HEADERS(libunwind-ia64.h)
380 with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
381 ;;
382 *)
383 AC_MSG_ERROR(
384 [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
385 ;;
386 esac
387
388 if test x"$with_libunwind_ia64" = xyes; then
389 AC_CHECK_HEADERS(libunwind-ia64.h)
390 if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
391 AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
392 fi
393 CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
394 CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
395 CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
396 fi
397
398 opt_curses=no
399 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
400
401 prefer_curses=no
402 if test "$opt_curses" = "yes"; then
403 prefer_curses=yes
404 fi
405
406 # Profiling support.
407 AC_ARG_ENABLE(profiling,
408 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
409 [case $enableval in
410 yes | no)
411 ;;
412 *)
413 AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
414 esac],
415 [enable_profiling=no])
416
417 AC_CHECK_FUNCS(monstartup _mcleanup)
418 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
419 [AC_TRY_LINK(
420 [#include <stdlib.h>
421 extern char _etext;
422 ],
423 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
424 if test $ac_cv_var__etext = yes; then
425 AC_DEFINE(HAVE__ETEXT, 1,
426 [Define to 1 if your system has the _etext variable. ])
427 fi
428 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
429 [AC_TRY_LINK(
430 [#include <stdlib.h>
431 extern char etext;
432 ],
433 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
434 if test $ac_cv_var_etext = yes; then
435 AC_DEFINE(HAVE_ETEXT, 1,
436 [Define to 1 if your system has the etext variable. ])
437 fi
438 if test "$enable_profiling" = yes ; then
439 if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
440 AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
441 fi
442 PROFILE_CFLAGS=-pg
443 OLD_CFLAGS="$CFLAGS"
444 CFLAGS="$CFLAGS $PROFILE_CFLAGS"
445
446 AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
447 [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
448 ac_cv_cc_supports_pg=no)])
449
450 if test $ac_cv_cc_supports_pg = no; then
451 AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
452 fi
453
454 CFLAGS="$OLD_CFLAGS"
455 fi
456
457 ACX_PKGVERSION([GDB])
458 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
459 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
460 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
461
462 # --------------------- #
463 # Checks for programs. #
464 # --------------------- #
465
466 AC_PROG_AWK
467 AC_PROG_INSTALL
468 AC_PROG_LN_S
469 AC_PROG_RANLIB
470 AC_PROG_YACC
471
472 AC_CHECK_TOOL(AR, ar)
473 AC_CHECK_TOOL(DLLTOOL, dlltool)
474 AC_CHECK_TOOL(WINDRES, windres)
475
476 # Needed for GNU/Hurd.
477 AC_CHECK_TOOL(MIG, mig)
478
479 # ---------------------- #
480 # Checks for libraries. #
481 # ---------------------- #
482
483 # We might need to link with -lm; most simulators need it.
484 AC_CHECK_LIB(m, main)
485
486 # We need to link with -lw to get `wctype' on Solaris before Solaris
487 # 2.6. Solaris 2.6 and beyond have this function in libc, and have a
488 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
489 # is known to have this problem). Therefore we avoid libw if we can.
490 AC_CHECK_FUNC(wctype, [],
491 [AC_CHECK_LIB(w, wctype)])
492
493 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
494 AC_SEARCH_LIBS(gethostbyname, nsl)
495
496 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
497 AC_SEARCH_LIBS(socketpair, socket)
498
499 # Link in zlib if we can. This allows us to read compressed debug sections.
500 AM_ZLIB
501
502 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
503 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
504
505 AM_ICONV
506
507 # GDB may fork/exec the iconv program to get the list of supported character
508 # sets. Allow the user to specify where to find it.
509 # There are several factors affecting the choice of option name:
510 # - There is already --with-libiconv-prefix but we can't use it, it specifies
511 # the build-time location of libiconv files.
512 # - The program we need to find is iconv, which comes with glibc. The user
513 # doesn't necessarily have libiconv installed. Therefore naming this
514 # --with-libiconv-foo feels wrong.
515 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
516 # defined to work on directories not files (though it really doesn't know
517 # the difference).
518 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
519 # with --with-libiconv-prefix.
520 # Putting these together is why the option name is --with-iconv-bin.
521
522 AC_ARG_WITH(iconv-bin,
523 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
524 [iconv_bin="${withval}"
525 AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
526 [Path of directory of iconv program.])
527 GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
528 ])
529
530 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
531 # There is a very specific comment in /usr/include/curses.h explaining that
532 # termcap routines built into libcurses must not be used.
533 #
534 # The symptoms we observed so far is GDB unexpectedly changing
535 # the terminal settings when tgetent is called - this is particularly
536 # visible as the output is missing carriage returns, and so rapidly
537 # becomes very hard to read.
538 #
539 # The readline configure script has already decided that libtermcap
540 # was enough for its purposes, and so decided to build readline using
541 # libtermcap. Since the TUI mode requires curses, building GDB with
542 # TUI enabled results in both libraries to be used at the same time,
543 # which is not allowed. This basically means that GDB with TUI is
544 # broken on alpha-osf.
545
546 case $host_os in
547 osf* )
548 if test x"$enable_tui" = xyes; then
549 AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
550 fi
551 if test x"$enable_tui" = xauto; then
552 enable_tui=no
553 fi
554 ;;
555 esac
556
557 # For the TUI, we need enhanced curses functionality.
558 if test x"$enable_tui" != xno; then
559 prefer_curses=yes
560 fi
561
562 curses_found=no
563 if test x"$prefer_curses" = xyes; then
564 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
565 # curses library because the latter might not provide all the
566 # functionality we need. However, this leads to problems on systems
567 # where the linker searches /usr/local/lib, but the compiler doesn't
568 # search /usr/local/include, if ncurses is installed in /usr/local. A
569 # default installation of ncurses on alpha*-dec-osf* will lead to such
570 # a situation.
571 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
572
573 if test "$ac_cv_search_waddstr" != no; then
574 curses_found=yes
575 fi
576 fi
577
578 # Check whether we should enable the TUI, but only do so if we really
579 # can.
580 if test x"$enable_tui" != xno; then
581 if test -d $srcdir/tui; then
582 if test "$curses_found" != no; then
583 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
584 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
585 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
586 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
587 else
588 if test x"$enable_tui" = xyes; then
589 AC_MSG_ERROR([no enhanced curses library found; disable TUI])
590 else
591 AC_MSG_WARN([no enhanced curses library found; disabling TUI])
592 fi
593 fi
594 fi
595 fi
596
597 # Since GDB uses Readline, we need termcap functionality. In many
598 # cases this will be provided by the curses library, but some systems
599 # have a seperate termcap library, or no curses library at all.
600
601 case $host_os in
602 cygwin*)
603 if test -d $srcdir/libtermcap; then
604 LIBS="../libtermcap/libtermcap.a $LIBS"
605 ac_cv_search_tgetent="../libtermcap/libtermcap.a"
606 fi ;;
607 go32* | *djgpp*)
608 ac_cv_search_tgetent="none required"
609 ;;
610 *mingw32*)
611 ac_cv_search_tgetent="none required"
612 CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
613 ;;
614 esac
615
616 # These are the libraries checked by Readline.
617 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
618
619 if test "$ac_cv_search_tgetent" = no; then
620 AC_MSG_ERROR([no termcap library found])
621 fi
622
623 AC_ARG_WITH([system-readline],
624 [AS_HELP_STRING([--with-system-readline],
625 [use installed readline library])])
626
627 if test "$with_system_readline" = yes; then
628 READLINE=-lreadline
629 READLINE_DEPS=
630 READLINE_CFLAGS=
631 READLINE_TEXI_INCFLAG=
632 else
633 READLINE='$(READLINE_DIR)/libreadline.a'
634 READLINE_DEPS='$(READLINE)'
635 READLINE_CFLAGS='-I$(READLINE_SRC)/..'
636 READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
637 fi
638 AC_SUBST(READLINE)
639 AC_SUBST(READLINE_DEPS)
640 AC_SUBST(READLINE_CFLAGS)
641 AC_SUBST(READLINE_TEXI_INCFLAG)
642
643 # Generate jit-reader.h
644
645 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
646 TARGET_PTR=
647
648 AC_CHECK_SIZEOF(unsigned long long)
649 AC_CHECK_SIZEOF(unsigned long)
650 AC_CHECK_SIZEOF(unsigned __int128)
651
652 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
653 TARGET_PTR="unsigned long"
654 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
655 TARGET_PTR="unsigned long long"
656 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
657 TARGET_PTR="unsigned __int128"
658 else
659 TARGET_PTR="unsigned long"
660 fi
661
662 AC_SUBST(TARGET_PTR)
663 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
664
665 AC_SEARCH_LIBS(dlopen, dl)
666
667 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
668 [directory to load the JIT readers from],
669 [${libdir}/gdb])
670
671 AC_ARG_WITH(expat,
672 AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
673 [], [with_expat=auto])
674 AC_MSG_CHECKING([whether to use expat])
675 AC_MSG_RESULT([$with_expat])
676
677 if test "${with_expat}" = no; then
678 AC_MSG_WARN([expat support disabled; some features may be unavailable.])
679 HAVE_LIBEXPAT=no
680 else
681 AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
682 [XML_Parser p = XML_ParserCreate (0);])
683 if test "$HAVE_LIBEXPAT" != yes; then
684 if test "$with_expat" = yes; then
685 AC_MSG_ERROR([expat is missing or unusable])
686 else
687 AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
688 fi
689 else
690 save_LIBS=$LIBS
691 LIBS="$LIBS $LIBEXPAT"
692 AC_CHECK_FUNCS(XML_StopParser)
693 LIBS=$save_LIBS
694 fi
695 fi
696
697 dnl Utility to simplify finding libpython.
698 dnl $1 = pythonX.Y
699 dnl $2 = the shell variable to assign the result to
700 dnl If libpython is found we store $version here.
701 dnl $3 = additional flags to add to CPPFLAGS
702 dnl $4 = additional flags to add to LIBS
703
704 AC_DEFUN([AC_TRY_LIBPYTHON],
705 [
706 version=$1
707 define([have_libpython_var],$2)
708 new_CPPFLAGS=$3
709 new_LIBS=$4
710 AC_MSG_CHECKING([for ${version}])
711 save_CPPFLAGS=$CPPFLAGS
712 save_LIBS=$LIBS
713 CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
714 LIBS="$LIBS $new_LIBS"
715 found_usable_python=no
716 AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
717 [[Py_Initialize ();]]),
718 [have_libpython_var=${version}
719 found_usable_python=yes
720 PYTHON_CPPFLAGS=$new_CPPFLAGS
721 PYTHON_LIBS=$new_LIBS])
722 CPPFLAGS=$save_CPPFLAGS
723 LIBS=$save_LIBS
724 AC_MSG_RESULT([${found_usable_python}])
725 ])
726
727 dnl There are several different values for --with-python:
728 dnl
729 dnl no - Don't include python support.
730 dnl yes - Include python support, error if it's missing.
731 dnl If we find python in $PATH, use it to fetch configure options,
732 dnl otherwise assume the compiler can find it with no help from us.
733 dnl Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
734 dnl auto - Same as "yes", but if python is missing from the system,
735 dnl fall back to "no".
736 dnl /path/to/python/exec-prefix -
737 dnl Use the python located in this directory.
738 dnl If /path/to/python/exec-prefix/bin/python exists, use it to find
739 dnl the compilation parameters. Otherwise use
740 dnl -I/path/to/python/exec-prefix/include,
741 dnl -L/path/to/python/exec-prefix/lib.
742 dnl Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
743 dnl NOTE: This case is historical. It is what was done for 7.0/7.1
744 dnl but is deprecated.
745 dnl /path/to/python/executable -
746 dnl Run python-config.py with this version of python to fetch the
747 dnl compilation parameters.
748 dnl NOTE: This needn't be the real python executable.
749 dnl In a cross-compilation scenario (build != host), this could be
750 dnl a shell script that provides what python-config.py provides for
751 dnl --ldflags, --includes, --exec-prefix.
752 dnl python-executable -
753 dnl Find python-executable in $PATH, and then handle the same as
754 dnl /path/to/python/executable.
755 dnl
756 dnl If a python program is specified, it is used to run python-config.py and
757 dnl is passed --ldflags, --includes, --exec-prefix.
758
759 AC_ARG_WITH(python,
760 AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
761 [], [with_python=auto])
762 AC_MSG_CHECKING([whether to use python])
763 AC_MSG_RESULT([$with_python])
764
765 if test "${with_python}" = no; then
766 AC_MSG_WARN([python support disabled; some features may be unavailable.])
767 have_libpython=no
768 else
769 case "${with_python}" in
770 [[\\/]]* | ?:[[\\/]]*)
771 if test -d ${with_python}; then
772 # Assume the python binary is ${with_python}/bin/python.
773 python_prog="${with_python}/bin/python"
774 python_prefix=
775 # If python does not exit ${with_python}/bin, then try in
776 # ${with_python}. On Windows/MinGW, this is where the Python
777 # executable is.
778 if test ! -x "${python_prog}"; then
779 python_prog="${with_python}/python"
780 python_prefix=
781 fi
782 if test ! -x "${python_prog}"; then
783 # Fall back to gdb 7.0/7.1 behaviour.
784 python_prog=missing
785 python_prefix=${with_python}
786 fi
787 elif test -x "${with_python}"; then
788 # While we can't run python compiled for $host (unless host == build),
789 # the user could write a script that provides the needed information,
790 # so we support that.
791 python_prog=${with_python}
792 python_prefix=
793 else
794 AC_ERROR(invalid value for --with-python)
795 fi
796 ;;
797 */*)
798 # Disallow --with-python=foo/bar.
799 AC_ERROR(invalid value for --with-python)
800 ;;
801 *)
802 # The user has either specified auto, yes, or the name of the python
803 # program assumed to be in $PATH.
804 python_prefix=
805 case "${with_python}" in
806 yes | auto)
807 if test ${build} = ${host}; then
808 AC_PATH_PROG(python_prog_path, python, missing)
809 if test "${python_prog_path}" = missing; then
810 python_prog=missing
811 else
812 python_prog=${python_prog_path}
813 fi
814 else
815 # Not much we can do except assume the cross-compiler will find the
816 # right files.
817 python_prog=missing
818 fi
819 ;;
820 *)
821 # While we can't run python compiled for $host (unless host == build),
822 # the user could write a script that provides the needed information,
823 # so we support that.
824 python_prog="${with_python}"
825 AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
826 if test "${python_prog_path}" = missing; then
827 AC_ERROR(unable to find python program ${python_prog})
828 fi
829 ;;
830 esac
831 esac
832
833 if test "${python_prog}" != missing; then
834 # We have a python program to use, but it may be too old.
835 # Don't flag an error for --with-python=auto (the default).
836 have_python_config=yes
837 python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
838 if test $? != 0; then
839 have_python_config=failed
840 if test "${with_python}" != auto; then
841 AC_ERROR(failure running python-config --includes)
842 fi
843 fi
844 python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
845 if test $? != 0; then
846 have_python_config=failed
847 if test "${with_python}" != auto; then
848 AC_ERROR(failure running python-config --ldflags)
849 fi
850 fi
851 python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
852 if test $? != 0; then
853 have_python_config=failed
854 if test "${with_python}" != auto; then
855 AC_ERROR(failure running python-config --exec-prefix)
856 fi
857 fi
858 else
859 # We do not have a python executable we can use to determine where
860 # to find the Python headers and libs. We cannot guess the include
861 # path from the python_prefix either, because that include path
862 # depends on the Python version. So, there is nothing much we can
863 # do except assume that the compiler will be able to find those files.
864 python_includes=
865 python_libs=
866 have_python_config=no
867 fi
868
869 # If we have python-config, only try the configuration it provides.
870 # Otherwise fallback on the old way of trying different versions of
871 # python in turn.
872
873 have_libpython=no
874 if test "${have_python_config}" = yes; then
875 # Determine the Python version by extracting "-lpython<version>"
876 # part of the python_libs. <version> is usually X.Y with X and Y
877 # being decimal numbers, but can also be XY (seen on Windows).
878 #
879 # The extraction is performed using sed with a regular expression.
880 # Initially, the regexp used was using the '?' quantifier to make
881 # the dot in the version number optional. Unfortunately, this
882 # does not work with non-GNU versions of sed because, because of
883 # what looks like a limitation (the '?' quantifier does not work
884 # with back-references). We work around this limitation by using
885 # the '*' quantifier instead. It means that, in theory, we might
886 # match unexpected version strings such as "-lpython2..7", but
887 # this seems unlikely in practice. And even if that happens,
888 # an error will be triggered later on, when checking that version
889 # number.
890 python_version=`echo " ${python_libs} " \
891 | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
892 case "${python_version}" in
893 python*)
894 AC_TRY_LIBPYTHON(${python_version}, have_libpython,
895 ${python_includes}, ${python_libs})
896 ;;
897 *)
898 AC_MSG_ERROR([unable to determine python version from ${python_libs}])
899 ;;
900 esac
901 elif test "${have_python_config}" != failed; then
902 if test "${have_libpython}" = no; then
903 AC_TRY_LIBPYTHON(python2.7, have_libpython,
904 ${python_includes}, "${python_libs} -lpython2.7")
905 fi
906 if test "${have_libpython}" = no; then
907 AC_TRY_LIBPYTHON(python2.6, have_libpython,
908 ${python_includes}, "${python_libs} -lpython2.6")
909 fi
910 if test ${have_libpython} = no; then
911 AC_TRY_LIBPYTHON(python2.5, have_libpython,
912 ${python_includes}, "${python_libs} -lpython2.5")
913 fi
914 if test ${have_libpython} = no; then
915 AC_TRY_LIBPYTHON(python2.4, have_libpython,
916 ${python_includes}, "${python_libs} -lpython2.4")
917 fi
918 fi
919 if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
920 AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
921 elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
922 AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
923 elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
924 AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
925 elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
926 AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
927 fi
928
929 if test "${have_libpython}" = no; then
930 case "${with_python}" in
931 yes)
932 AC_MSG_ERROR([python is missing or unusable])
933 ;;
934 auto)
935 AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
936 ;;
937 *)
938 AC_MSG_ERROR([no usable python found at ${with_python}])
939 ;;
940 esac
941 else
942 if test -n "${python_prefix}"; then
943 AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
944 [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
945 GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
946 fi
947 fi
948 fi
949
950 if test "${have_libpython}" != no; then
951 AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
952 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
953 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
954 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
955 CONFIG_INSTALL="$CONFIG_INSTALL install-python"
956 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
957
958 # Flags needed to compile Python code (taken from python-config --cflags).
959 # We cannot call python-config directly because it will output whatever was
960 # used when compiling the Python interpreter itself, including flags which
961 # would make the python-related objects be compiled differently from the
962 # rest of GDB (e.g., -O2 and -fPIC).
963 if test "${GCC}" = yes; then
964 tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
965 fi
966
967 if test "x${tentative_python_cflags}" != x; then
968 AC_MSG_CHECKING(compiler flags for python code)
969 for flag in ${tentative_python_cflags}; do
970 # Check that the compiler accepts it
971 saved_CFLAGS="$CFLAGS"
972 CFLAGS="$CFLAGS $flag"
973 AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
974 CFLAGS="$saved_CFLAGS"
975 done
976 AC_MSG_RESULT(${PYTHON_CFLAGS})
977 fi
978
979 # On IRIX, type siginfo is not defined. Instead, sys/siginfo.h provides:
980 # #if _SGIAPI
981 # #define siginfo __siginfo
982 # #endif
983 # The problem is that including Python causes some XOPEN macros to be
984 # unilaterally defined, and that in turn causes _SGIAPI to evaluate
985 # to false. So, we work around this issue by defining siginfo ourself
986 # though the command-line.
987 case "$gdb_host" in
988 irix*) if test "${GCC}" = yes; then
989 CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
990 fi
991 ;;
992 esac
993 else
994 # Even if Python support is not compiled in, we need to have these files
995 # included.
996 CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
997 CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
998 python/py-prettyprint.c python/py-auto-load.c"
999 fi
1000 AC_SUBST(PYTHON_CFLAGS)
1001 AC_SUBST(PYTHON_CPPFLAGS)
1002 AC_SUBST(PYTHON_LIBS)
1003
1004 # ------------------------- #
1005 # Checks for header files. #
1006 # ------------------------- #
1007
1008 AC_HEADER_DIRENT
1009 AC_HEADER_STAT
1010 AC_HEADER_STDC
1011 # elf_hp.h is for HP/UX 64-bit shared library support.
1012 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
1013 # unconditionally, so what's the point in checking these?
1014 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1015 thread_db.h gnu/libc-version.h signal.h stddef.h \
1016 stdlib.h string.h memory.h strings.h sys/fault.h \
1017 sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1018 sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1019 sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1020 sys/types.h sys/wait.h wait.h termios.h termio.h \
1021 sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
1022 dlfcn.h sys/socket.h sys/un.h])
1023 AC_CHECK_HEADERS(link.h, [], [],
1024 [#if HAVE_SYS_TYPES_H
1025 # include <sys/types.h>
1026 #endif
1027 #if HAVE_NLIST_H
1028 # include <nlist.h>
1029 #endif
1030 ])
1031 AC_CHECK_HEADERS(sys/proc.h, [], [],
1032 [#if HAVE_SYS_PARAM_H
1033 # include <sys/param.h>
1034 #endif
1035 ])
1036 AC_CHECK_HEADERS(sys/user.h, [], [],
1037 [#if HAVE_SYS_PARAM_H
1038 # include <sys/param.h>
1039 #endif
1040 ])
1041
1042 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1043 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1044 # think that we don't have <curses.h> if we're using GCC.
1045 case $host_os in
1046 solaris2.[[789]])
1047 if test "$GCC" = yes; then
1048 AC_DEFINE(_MSE_INT_H, 1,
1049 [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1050 Solaris 2.[789] when using GCC. ])
1051 fi ;;
1052 esac
1053 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1054 AC_CHECK_HEADERS(term.h, [], [],
1055 [#if HAVE_CURSES_H
1056 # include <curses.h>
1057 #endif
1058 ])
1059
1060 # ------------------------- #
1061 # Checks for declarations. #
1062 # ------------------------- #
1063
1064 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1065 snprintf, vsnprintf])
1066 AM_LC_MESSAGES
1067
1068 # ----------------------- #
1069 # Checks for structures. #
1070 # ----------------------- #
1071
1072 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1073
1074 # ------------------ #
1075 # Checks for types. #
1076 # ------------------ #
1077
1078 AC_TYPE_SIGNAL
1079 AC_CHECK_TYPES(socklen_t, [], [],
1080 [#include <sys/types.h>
1081 #include <sys/socket.h>
1082 ])
1083
1084 # ------------------------------------- #
1085 # Checks for compiler characteristics. #
1086 # ------------------------------------- #
1087
1088 AC_C_CONST
1089 AC_C_INLINE
1090 AC_C_BIGENDIAN
1091
1092 # ------------------------------ #
1093 # Checks for library functions. #
1094 # ------------------------------ #
1095
1096 AC_FUNC_ALLOCA
1097 AC_FUNC_MMAP
1098 AC_FUNC_VFORK
1099 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1100 pipe poll pread pread64 pwrite readlink resize_term \
1101 sbrk setpgid setpgrp setsid \
1102 sigaction sigprocmask sigsetmask socketpair syscall \
1103 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1104 setrlimit getrlimit posix_madvise waitpid lstat])
1105 AM_LANGINFO_CODESET
1106
1107 # Check the return and argument types of ptrace. No canned test for
1108 # this, so roll our own.
1109 gdb_ptrace_headers='
1110 #if HAVE_SYS_TYPES_H
1111 # include <sys/types.h>
1112 #endif
1113 #if HAVE_SYS_PTRACE_H
1114 # include <sys/ptrace.h>
1115 #endif
1116 #if HAVE_UNISTD_H
1117 # include <unistd.h>
1118 #endif
1119 '
1120 # There is no point in checking if we don't have a prototype.
1121 AC_CHECK_DECLS(ptrace, [], [
1122 : ${gdb_cv_func_ptrace_ret='int'}
1123 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1124 ], $gdb_ptrace_headers)
1125 # Check return type. Varargs (used on GNU/Linux) conflict with the
1126 # empty argument list, so check for that explicitly.
1127 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1128 AC_TRY_COMPILE($gdb_ptrace_headers,
1129 [extern long ptrace (enum __ptrace_request, ...);],
1130 gdb_cv_func_ptrace_ret='long',
1131 AC_TRY_COMPILE($gdb_ptrace_headers,
1132 [extern int ptrace ();],
1133 gdb_cv_func_ptrace_ret='int',
1134 gdb_cv_func_ptrace_ret='long')))
1135 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1136 [Define as the return type of ptrace.])
1137 # Check argument types.
1138 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1139 AC_TRY_COMPILE($gdb_ptrace_headers,
1140 [extern long ptrace (enum __ptrace_request, ...);],
1141 [gdb_cv_func_ptrace_args='int,int,long,long'],[
1142 for gdb_arg1 in 'int' 'long'; do
1143 for gdb_arg2 in 'pid_t' 'int' 'long'; do
1144 for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1145 for gdb_arg4 in 'int' 'long'; do
1146 AC_TRY_COMPILE($gdb_ptrace_headers, [
1147 extern $gdb_cv_func_ptrace_ret
1148 ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1149 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1150 break 4;])
1151 for gdb_arg5 in 'int *' 'int' 'long'; do
1152 AC_TRY_COMPILE($gdb_ptrace_headers, [
1153 extern $gdb_cv_func_ptrace_ret
1154 ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1155 ], [
1156 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1157 break 5;])
1158 done
1159 done
1160 done
1161 done
1162 done
1163 # Provide a safe default value.
1164 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1165 ])])
1166 ac_save_IFS=$IFS; IFS=','
1167 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1168 IFS=$ac_save_IFS
1169 shift
1170 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1171 [Define to the type of arg 3 for ptrace.])
1172 if test -n "$[5]"; then
1173 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1174 [Define to the type of arg 5 for ptrace.])
1175 fi
1176
1177 dnl AC_FUNC_SETPGRP does not work when cross compiling
1178 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1179 if test "$cross_compiling" = no; then
1180 AC_FUNC_SETPGRP
1181 else
1182 AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1183 [AC_TRY_COMPILE([
1184 #include <unistd.h>
1185 ], [
1186 if (setpgrp(1,1) == -1)
1187 exit (0);
1188 else
1189 exit (1);
1190 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1191 if test $ac_cv_func_setpgrp_void = yes; then
1192 AC_DEFINE(SETPGRP_VOID, 1)
1193 fi
1194 fi
1195
1196 # Check if sigsetjmp is available. Using AC_CHECK_FUNCS won't do
1197 # since sigsetjmp might only be defined as a macro.
1198 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1199 [AC_TRY_COMPILE([
1200 #include <setjmp.h>
1201 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1202 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1203 if test $gdb_cv_func_sigsetjmp = yes; then
1204 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1205 fi
1206
1207 # Assume we'll default to using the included libiberty regex.
1208 gdb_use_included_regex=yes
1209
1210 # However, if the system regex is GNU regex, then default to *not*
1211 # using the included regex.
1212 AC_CACHE_CHECK(
1213 [for GNU regex],
1214 [gdb_cv_have_gnu_regex],
1215 [AC_TRY_COMPILE(
1216 [#include <gnu-versions.h>],
1217 [#define REGEX_INTERFACE_VERSION 1
1218 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1219 # error "Version mismatch"
1220 #endif],
1221 gdb_cv_have_gnu_regex=yes,
1222 gdb_cv_have_gnu_regex=no)])
1223 if test $gdb_cv_have_gnu_regex = yes; then
1224 gdb_use_included_regex=no
1225 fi
1226
1227 AC_ARG_WITH(included-regex,
1228 AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1229 gdb_with_regex=$withval,
1230 gdb_with_regex=$gdb_use_included_regex)
1231 if test "$gdb_with_regex" = yes; then
1232 AC_DEFINE(USE_INCLUDED_REGEX, 1,
1233 [Define to 1 if the regex included in libiberty should be used.])
1234 fi
1235
1236 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1237 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1238 [#include <sys/param.h>
1239 #include <sys/proc.h>
1240 ])
1241
1242 # See if <sys/lwp.h> defines `struct lwp`.
1243 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1244 [AC_TRY_COMPILE([#include <sys/param.h>
1245 #include <sys/lwp.h>], [struct lwp l;],
1246 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1247 if test $gdb_cv_struct_lwp = yes; then
1248 AC_DEFINE(HAVE_STRUCT_LWP, 1,
1249 [Define to 1 if your system has struct lwp.])
1250 fi
1251
1252 # See if <machine/reg.h> degines `struct reg'.
1253 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1254 [AC_TRY_COMPILE([#include <sys/types.h>
1255 #include <machine/reg.h>], [struct reg r;],
1256 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1257 if test $gdb_cv_struct_reg = yes; then
1258 AC_DEFINE(HAVE_STRUCT_REG, 1,
1259 [Define to 1 if your system has struct reg in <machine/reg.h>.])
1260 fi
1261
1262 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1263 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1264 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1265 [#include <machine/reg.h>])
1266
1267 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1268 AC_MSG_CHECKING(for PTRACE_GETREGS)
1269 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1270 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1271 [PTRACE_GETREGS;],
1272 [gdb_cv_have_ptrace_getregs=yes],
1273 [gdb_cv_have_ptrace_getregs=no])])
1274 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1275 if test $gdb_cv_have_ptrace_getregs = yes; then
1276 AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1277 [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1278 fi
1279
1280 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1281 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1282 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1283 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1284 [PTRACE_GETFPXREGS;],
1285 [gdb_cv_have_ptrace_getfpxregs=yes],
1286 [gdb_cv_have_ptrace_getfpxregs=no])])
1287 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1288 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1289 AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1290 [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1291 fi
1292
1293 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1294 AC_MSG_CHECKING(for PT_GETDBREGS)
1295 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1296 [AC_TRY_COMPILE([#include <sys/types.h>
1297 #include <sys/ptrace.h>],
1298 [PT_GETDBREGS;],
1299 [gdb_cv_have_pt_getdbregs=yes],
1300 [gdb_cv_have_pt_getdbregs=no])])
1301 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1302 if test $gdb_cv_have_pt_getdbregs = yes; then
1303 AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1304 [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1305 fi
1306
1307 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1308 AC_MSG_CHECKING(for PT_GETXMMREGS)
1309 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1310 [AC_TRY_COMPILE([#include <sys/types.h>
1311 #include <sys/ptrace.h>],
1312 [PT_GETXMMREGS;],
1313 [gdb_cv_have_pt_getxmmregs=yes],
1314 [gdb_cv_have_pt_getxmmregs=no])])
1315 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1316 if test $gdb_cv_have_pt_getxmmregs = yes; then
1317 AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1318 [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1319 fi
1320
1321 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1322
1323 if test "${target}" = "${host}"; then
1324 case "${host}" in
1325 *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1326 AC_DEFINE(NEW_PROC_API, 1,
1327 [Define if you want to use new multi-fd /proc interface
1328 (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1329 ;;
1330 *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1331 AC_DEFINE(NEW_PROC_API, 1,
1332 [Define if you want to use new multi-fd /proc interface
1333 (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1334 ;;
1335 mips-sgi-irix5*)
1336 # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1337 AC_DEFINE([_KMEMUSER], 1,
1338 [Define to 1 so <sys/proc.h> gets a definition of anon_hdl. Works
1339 around a <sys/proc.h> problem on IRIX 5.])
1340 ;;
1341 esac
1342 fi
1343
1344 if test "$ac_cv_header_sys_procfs_h" = yes; then
1345 BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1346 BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1347 BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1348 BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1349 BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1350 BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1351 BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1352 BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1353 BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1354 BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1355 BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1356 BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1357 BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1358 BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1359
1360
1361 dnl Check for broken prfpregset_t type
1362
1363 dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1364 dnl prfpregset_t type (it's a typedef for the pointer to a struct
1365 dnl instead of the struct itself). We detect this here, and work
1366 dnl around it in gdb_proc_service.h.
1367
1368 if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1369 AC_MSG_CHECKING(whether prfpregset_t type is broken)
1370 AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1371 [AC_TRY_RUN([#include <sys/procfs.h>
1372 int main ()
1373 {
1374 if (sizeof (prfpregset_t) == sizeof (void *))
1375 return 1;
1376 return 0;
1377 }],
1378 gdb_cv_prfpregset_t_broken=no,
1379 gdb_cv_prfpregset_t_broken=yes,
1380 gdb_cv_prfpregset_t_broken=yes)])
1381 AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1382 if test $gdb_cv_prfpregset_t_broken = yes; then
1383 AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1384 [Define if the prfpregset_t type is broken.])
1385 fi
1386 fi
1387
1388 dnl Check for PIOCSET ioctl entry
1389
1390 AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1391 AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1392 [AC_TRY_COMPILE([#include <unistd.h>
1393 #include <sys/types.h>
1394 #include <sys/procfs.h>
1395 ], [
1396 int dummy;;
1397 dummy = ioctl(0, PIOCSET, &dummy);
1398 ],
1399 gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1400 AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1401 if test $gdb_cv_have_procfs_piocset = yes; then
1402 AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1403 [Define if ioctl argument PIOCSET is available.])
1404 fi
1405 fi
1406
1407 dnl For native ports (host == target), check to see what kind of
1408 dnl legacy link.h support is needed. (See solib-legacy.c.)
1409 if test ${host} = ${target} ; then
1410 dnl Check for struct link_map with l_ members which are indicative
1411 dnl of SVR4-like shared libraries
1412
1413 AC_MSG_CHECKING(for member l_addr in struct link_map)
1414 AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1415 [AC_TRY_COMPILE([#include <link.h>],
1416 [struct link_map lm; (void) lm.l_addr;],
1417 gdb_cv_have_struct_link_map_with_l_members=yes,
1418 gdb_cv_have_struct_link_map_with_l_members=no)])
1419 AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1420 if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1421 AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1422 [Define if <link.h> exists and defines struct link_map which has
1423 members with an ``l_'' prefix. (For Solaris, SVR4, and
1424 SVR4-like systems.)])
1425 fi
1426
1427 dnl Check for struct link_map with lm_ members which are indicative
1428 dnl of SunOS-like shared libraries
1429
1430 AC_MSG_CHECKING(for member lm_addr in struct link_map)
1431 AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1432 [AC_TRY_COMPILE([#include <sys/types.h>
1433 #include <link.h>],
1434 [struct link_map lm; (void) lm.lm_addr;],
1435 gdb_cv_have_struct_link_map_with_lm_members=yes,
1436 gdb_cv_have_struct_link_map_with_lm_members=no)])
1437 AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1438 if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1439 AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1440 [Define if <link.h> exists and defines struct link_map which has
1441 members with an ``lm_'' prefix. (For SunOS.)])
1442 fi
1443
1444 dnl Check for struct so_map with som_ members which are found on
1445 dnl some *BSD systems.
1446
1447 AC_MSG_CHECKING(for member som_addr in struct so_map)
1448 AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1449 [AC_TRY_COMPILE([#include <sys/types.h>
1450 #ifdef HAVE_NLIST_H
1451 #include <nlist.h>
1452 #endif
1453 #include <link.h>],
1454 [struct so_map lm; (void) lm.som_addr;],
1455 gdb_cv_have_struct_so_map_with_som_members=yes,
1456 gdb_cv_have_struct_so_map_with_som_members=no)])
1457 AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1458 if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1459 AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1460 [Define if <link.h> exists and defines a struct so_map which has
1461 members with an ``som_'' prefix. (Found on older *BSD systems.)])
1462 fi
1463
1464 dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1465 dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1466
1467 AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1468 AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1469 [AC_TRY_COMPILE([#define _SYSCALL32
1470 #include <sys/link.h>], [struct link_map32 l;],
1471 gdb_cv_have_struct_link_map32=yes,
1472 gdb_cv_have_struct_link_map32=no)])
1473 AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1474 if test $gdb_cv_have_struct_link_map32 = yes; then
1475 AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1476 [Define if <sys/link.h> has struct link_map32])
1477 AC_DEFINE(_SYSCALL32, 1,
1478 [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1479 fi
1480 fi
1481
1482 # Check if the compiler supports the `long long' type.
1483
1484 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1485 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1486 [[extern long long foo;]],
1487 [[switch (foo & 2) { case 0: return 1; }]])],
1488 gdb_cv_c_long_long=yes,
1489 gdb_cv_c_long_long=no)])
1490 if test $gdb_cv_c_long_long = yes; then
1491 AC_DEFINE(CC_HAS_LONG_LONG, 1,
1492 [Define to 1 if the compiler supports long long.])
1493 fi
1494
1495 # Check if the compiler and runtime support printing long longs.
1496
1497 AC_CACHE_CHECK([for long long support in printf],
1498 gdb_cv_printf_has_long_long,
1499 [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1500 [[char buf[32];
1501 long long l = 0;
1502 l = (l << 16) + 0x0123;
1503 l = (l << 16) + 0x4567;
1504 l = (l << 16) + 0x89ab;
1505 l = (l << 16) + 0xcdef;
1506 sprintf (buf, "0x%016llx", l);
1507 return (strcmp ("0x0123456789abcdef", buf));]])],
1508 gdb_cv_printf_has_long_long=yes,
1509 gdb_cv_printf_has_long_long=no,
1510 gdb_cv_printf_has_long_long=no)])
1511 if test $gdb_cv_printf_has_long_long = yes; then
1512 AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1513 [Define to 1 if the "%ll" format works to print long longs.])
1514 fi
1515
1516 # Check if the compiler and runtime support printing decfloats.
1517
1518 AC_CACHE_CHECK([for decfloat support in printf],
1519 gdb_cv_printf_has_decfloat,
1520 [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1521 [[char buf[64];
1522 _Decimal32 d32 = 1.2345df;
1523 _Decimal64 d64 = 1.2345dd;
1524 _Decimal128 d128 = 1.2345dl;
1525 sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1526 return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1527 gdb_cv_printf_has_decfloat=yes,
1528 gdb_cv_printf_has_decfloat=no,
1529 gdb_cv_printf_has_decfloat=no)])
1530 if test $gdb_cv_printf_has_decfloat = yes; then
1531 AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1532 [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1533 fi
1534
1535 # Check if the compiler supports the `long double' type. We can't use
1536 # AC_C_LONG_DOUBLE because that one does additional checks on the
1537 # constants defined in <float.h> that fail on some systems,
1538 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1539
1540 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1541 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1542 gdb_cv_c_long_double=yes,
1543 gdb_cv_c_long_double=no)])
1544 if test $gdb_cv_c_long_double = yes; then
1545 AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1546 [Define to 1 if the compiler supports long double.])
1547 fi
1548
1549 # Check if the compiler and runtime support printing long doubles.
1550
1551 AC_CACHE_CHECK([for long double support in printf],
1552 gdb_cv_printf_has_long_double,
1553 [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1554 [[char buf[16];
1555 long double f = 3.141592653;
1556 sprintf (buf, "%Lg", f);
1557 return (strncmp ("3.14159", buf, 7));]])],
1558 gdb_cv_printf_has_long_double=yes,
1559 gdb_cv_printf_has_long_double=no,
1560 gdb_cv_printf_has_long_double=no)])
1561 if test $gdb_cv_printf_has_long_double = yes; then
1562 AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1563 [Define to 1 if the "%Lg" format works to print long doubles.])
1564 fi
1565
1566 # Check if the compiler and runtime support scanning long doubles.
1567
1568 AC_CACHE_CHECK([for long double support in scanf],
1569 gdb_cv_scanf_has_long_double,
1570 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1571 [[#include <stdio.h>]],
1572 [[char *buf = "3.141592653";
1573 long double f = 0;
1574 sscanf (buf, "%Lg", &f);
1575 return !(f > 3.14159 && f < 3.14160);]])],
1576 gdb_cv_scanf_has_long_double=yes,
1577 gdb_cv_scanf_has_long_double=no,
1578 gdb_cv_scanf_has_long_double=no)])
1579 if test $gdb_cv_scanf_has_long_double = yes; then
1580 AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1581 [Define to 1 if the "%Lg" format works to scan long doubles.])
1582 fi
1583
1584 case ${host_os} in
1585 aix*)
1586 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1587 SAVE_LDFLAGS=$LDFLAGS
1588
1589 case $GCC in
1590 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1591 *) gdb_cv_bigtoc=-bbigtoc ;;
1592 esac
1593
1594 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1595 AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1596 LDFLAGS="${SAVE_LDFLAGS}"
1597 ])
1598 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1599 ;;
1600 esac
1601
1602 AC_MSG_CHECKING(for the dynamic export flag)
1603 dynamic_list=false
1604 if test "${gdb_native}" = yes; then
1605 # The dynamically loaded libthread_db needs access to symbols in the gdb
1606 # executable. Older GNU ld supports --export-dynamic but --dynamic-list
1607 # may not be supported there.
1608 old_LDFLAGS="$LDFLAGS"
1609 # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1610 RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1611 LDFLAGS="$LDFLAGS $RDYNAMIC"
1612 if test "${have_libpython}" = no; then
1613 AC_TRY_LINK([], [], [dynamic_list=true])
1614 else
1615 # Workaround http://bugs.python.org/issue4434 where static
1616 # libpythonX.Y.a would get its symbols required for
1617 # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1618 # Problem does not happen for the recommended libpythonX.Y.so linkage.
1619 old_CFLAGS="$CFLAGS"
1620 CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1621 AC_RUN_IFELSE(
1622 AC_LANG_PROGRAM(
1623 [#include "]${have_libpython}[/Python.h"],
1624 [int err;
1625 Py_Initialize ();
1626 err = PyRun_SimpleString ("import itertools\n");
1627 Py_Finalize ();
1628 return err == 0 ? 0 : 1;]),
1629 [dynamic_list=true], [], [true])
1630 CFLAGS="$old_CFLAGS"
1631 fi
1632 LDFLAGS="$old_LDFLAGS"
1633 fi
1634 if $dynamic_list; then
1635 found="-Wl,--dynamic-list"
1636 RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1637 else
1638 found="-rdynamic"
1639 RDYNAMIC="-rdynamic"
1640 fi
1641 AC_SUBST(RDYNAMIC)
1642 AC_MSG_RESULT($found)
1643
1644 dnl For certain native configurations, we need to check whether thread
1645 dnl support can be built in or not.
1646 dnl
1647 dnl Note that we only want this if we are both native (host == target),
1648 dnl and not doing a canadian cross build (build == host).
1649
1650 if test ${build} = ${host} -a ${host} = ${target} ; then
1651 case ${host_os} in
1652 solaris*)
1653 # See if thread_db library is around for Solaris thread debugging.
1654 # Note that we must explicitly test for version 1 of the library
1655 # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1656 # the same API.
1657 AC_MSG_CHECKING(for Solaris thread debugging library)
1658 if test -f /usr/lib/libthread_db.so.1 ; then
1659 AC_MSG_RESULT(yes)
1660 AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1661 [Define if using Solaris thread debugging.])
1662 CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1663 CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1664 AC_CHECK_LIB(dl, dlopen)
1665 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1666 # Sun randomly tweaked the prototypes in <proc_service.h>
1667 # at one point.
1668 AC_MSG_CHECKING(if <proc_service.h> is old)
1669 AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1670 AC_TRY_COMPILE([
1671 #include <proc_service.h>
1672 ps_err_e ps_pdwrite
1673 (struct ps_prochandle*, psaddr_t, const void*, size_t);
1674 ],, gdb_cv_proc_service_is_old=no,
1675 gdb_cv_proc_service_is_old=yes)
1676 ])
1677 AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1678 if test $gdb_cv_proc_service_is_old = yes; then
1679 AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1680 [Define if <proc_service.h> on solaris uses int instead of
1681 size_t, and assorted other type changes.])
1682 fi
1683 else
1684 AC_MSG_RESULT(no)
1685 fi
1686 ;;
1687 aix*)
1688 AC_MSG_CHECKING(for AiX thread debugging library)
1689 AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1690 [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1691 [#ifndef PTHDB_VERSION_3
1692 #error
1693 #endif],
1694 gdb_cv_have_aix_thread_debug=yes,
1695 gdb_cv_have_aix_thread_debug=no)])
1696 AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1697 if test $gdb_cv_have_aix_thread_debug = yes; then
1698 CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1699 CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1700 LIBS="$LIBS -lpthdebug"
1701
1702 # Older versions of AIX do not provide the declaration for
1703 # the getthrds function (it appears that it was introduced
1704 # with AIX 6.x).
1705 AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1706 fi
1707 ;;
1708 esac
1709 AC_SUBST(CONFIG_LDFLAGS)
1710 fi
1711
1712 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1713 dnl other error codes.
1714 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1715 AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1716 gdb_cv_thread_db_h_has_td_notalloc,
1717 AC_TRY_COMPILE(
1718 [#include <thread_db.h>],
1719 [int i = TD_NOTALLOC;],
1720 gdb_cv_thread_db_h_has_td_notalloc=yes,
1721 gdb_cv_thread_db_h_has_td_notalloc=no
1722 )
1723 )
1724 AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1725 gdb_cv_thread_db_h_has_td_version,
1726 AC_TRY_COMPILE(
1727 [#include <thread_db.h>],
1728 [int i = TD_VERSION;],
1729 gdb_cv_thread_db_h_has_td_version=yes,
1730 gdb_cv_thread_db_h_has_td_version=no
1731 )
1732 )
1733 AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1734 gdb_cv_thread_db_h_has_td_notls,
1735 AC_TRY_COMPILE(
1736 [#include <thread_db.h>],
1737 [int i = TD_NOTLS;],
1738 gdb_cv_thread_db_h_has_td_notls=yes,
1739 gdb_cv_thread_db_h_has_td_notls=no
1740 )
1741 )
1742 fi
1743 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1744 AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1745 [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1746 fi
1747 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1748 AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1749 [Define if <thread_db.h> has the TD_VERSION error code.])
1750 fi
1751 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1752 AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1753 [Define if <thread_db.h> has the TD_NOTLS error code.])
1754 fi
1755
1756 dnl See if we have a sys/syscall header file that has __NR_tkill.
1757 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1758 AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1759 gdb_cv_sys_syscall_h_has_tkill,
1760 AC_TRY_COMPILE(
1761 [#include <sys/syscall.h>],
1762 [int i = __NR_tkill;],
1763 gdb_cv_sys_syscall_h_has_tkill=yes,
1764 gdb_cv_sys_syscall_h_has_tkill=no
1765 )
1766 )
1767 fi
1768 dnl See if we can issue tkill syscall.
1769 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1770 AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1771 fi
1772
1773 dnl Check if we can disable the virtual address space randomization.
1774 dnl The functionality of setarch -R.
1775 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1776 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1777 # if !HAVE_DECL_ADDR_NO_RANDOMIZE
1778 # define ADDR_NO_RANDOMIZE 0x0040000
1779 # endif
1780 /* Test the flag could be set and stays set. */
1781 personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1782 if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1783 return 1])])
1784 AC_RUN_IFELSE([PERSONALITY_TEST],
1785 [have_personality=true],
1786 [have_personality=false],
1787 [AC_LINK_IFELSE([PERSONALITY_TEST],
1788 [have_personality=true],
1789 [have_personality=false])])
1790 if $have_personality
1791 then
1792 AC_DEFINE([HAVE_PERSONALITY], 1,
1793 [Define if you support the personality syscall.])
1794 fi
1795
1796 dnl Handle optional features that can be enabled.
1797
1798 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1799 # except that the argument to --with-sysroot is optional.
1800 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1801 if test "x$with_sysroot" = xyes; then
1802 with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1803 fi
1804 AC_ARG_WITH(sysroot,
1805 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1806 [search for usr/lib et al within DIR]),
1807 [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1808 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1809 [search for usr/lib et al within DIR])
1810 AC_SUBST(TARGET_SYSTEM_ROOT)
1811 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1812
1813 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1814 [automatically load a system-wide gdbinit file],
1815 [])
1816
1817 AC_ARG_ENABLE(werror,
1818 AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1819 [case "${enableval}" in
1820 yes | y) ERROR_ON_WARNING="yes" ;;
1821 no | n) ERROR_ON_WARNING="no" ;;
1822 *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1823 esac])
1824
1825 # Enable -Werror by default when using gcc
1826 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1827 ERROR_ON_WARNING=yes
1828 fi
1829
1830 WERROR_CFLAGS=""
1831 if test "${ERROR_ON_WARNING}" = yes ; then
1832 WERROR_CFLAGS="-Werror"
1833 fi
1834
1835 # The entries after -Wno-pointer-sign are disabled warnings which may
1836 # be enabled in the future, which can not currently be used to build
1837 # GDB.
1838 # NOTE: If you change this list, remember to update
1839 # gdb/doc/gdbint.texinfo.
1840 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1841 -Wformat-nonliteral -Wno-pointer-sign \
1842 -Wno-unused -Wunused-value -Wunused-function \
1843 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes"
1844
1845 # Enable -Wno-format by default when using gcc on mingw since many
1846 # GCC versions complain about %I64.
1847 case "${host}" in
1848 *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1849 esac
1850
1851 AC_ARG_ENABLE(build-warnings,
1852 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1853 [case "${enableval}" in
1854 yes) ;;
1855 no) build_warnings="-w";;
1856 ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"`
1857 build_warnings="${build_warnings} ${t}";;
1858 *,) t=`echo "${enableval}" | sed -e "s/,/ /g"`
1859 build_warnings="${t} ${build_warnings}";;
1860 *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1861 esac
1862 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1863 echo "Setting compiler warning flags = $build_warnings" 6>&1
1864 fi])dnl
1865 AC_ARG_ENABLE(gdb-build-warnings,
1866 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1867 [case "${enableval}" in
1868 yes) ;;
1869 no) build_warnings="-w";;
1870 ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"`
1871 build_warnings="${build_warnings} ${t}";;
1872 *,) t=`echo "${enableval}" | sed -e "s/,/ /g"`
1873 build_warnings="${t} ${build_warnings}";;
1874 *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1875 esac
1876 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1877 echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1878 fi])dnl
1879 WARN_CFLAGS=""
1880 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1881 then
1882 AC_MSG_CHECKING(compiler warning flags)
1883 # Separate out the -Werror flag as some files just cannot be
1884 # compiled with it enabled.
1885 for w in ${build_warnings}; do
1886 case $w in
1887 -Werr*) WERROR_CFLAGS=-Werror ;;
1888 *) # Check that GCC accepts it
1889 saved_CFLAGS="$CFLAGS"
1890 CFLAGS="$CFLAGS $w"
1891 AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1892 CFLAGS="$saved_CFLAGS"
1893 esac
1894 done
1895 AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1896 fi
1897 AC_SUBST(WARN_CFLAGS)
1898 AC_SUBST(WERROR_CFLAGS)
1899
1900 # In the Cygwin environment, we need some additional flags.
1901 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1902 [AC_EGREP_CPP(lose, [
1903 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1904 lose
1905 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1906
1907
1908 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1909 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1910 case ${host} in
1911 *go32* ) SER_HARDWIRE=ser-go32.o ;;
1912 *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1913 *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1914 esac
1915 AC_SUBST(SER_HARDWIRE)
1916
1917 # libreadline needs libuser32.a in a cygwin environment
1918 WIN32LIBS=
1919 if test x$gdb_cv_os_cygwin = xyes; then
1920 WIN32LIBS="-luser32"
1921 case "${target}" in
1922 *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1923 ;;
1924 esac
1925 fi
1926
1927 # The ser-tcp.c module requires sockets.
1928 case ${host} in
1929 *mingw32*)
1930 AC_DEFINE(USE_WIN32API, 1,
1931 [Define if we should use the Windows API, instead of the
1932 POSIX API. On Windows, we use the Windows API when
1933 building for MinGW, but the POSIX API when building
1934 for Cygwin.])
1935 WIN32LIBS="$WIN32LIBS -lws2_32"
1936 ;;
1937 esac
1938 AC_SUBST(WIN32LIBS)
1939
1940 # Add ELF support to GDB, but only if BFD includes ELF support.
1941 OLD_CFLAGS=$CFLAGS
1942 OLD_LDFLAGS=$LDFLAGS
1943 OLD_LIBS=$LIBS
1944 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1945 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib. We
1946 # always want our bfd.
1947 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1948 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1949 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1950 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1951 if test "$plugins" = "yes"; then
1952 LIBS="-ldl $LIBS"
1953 fi
1954 LIBS="-lbfd -liberty $intl $LIBS"
1955 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1956 [AC_TRY_LINK(
1957 [#include <stdlib.h>
1958 #include "bfd.h"
1959 #include "elf-bfd.h"
1960 ],
1961 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1962 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1963 if test $gdb_cv_var_elf = yes; then
1964 CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
1965 AC_DEFINE(HAVE_ELF, 1,
1966 [Define if ELF support should be included.])
1967 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1968 if test "$plugins" = "yes"; then
1969 OLD_LIBS="-ldl $OLD_LIBS"
1970 fi
1971 fi
1972 CFLAGS=$OLD_CFLAGS
1973 LDFLAGS=$OLD_LDFLAGS
1974 LIBS=$OLD_LIBS
1975
1976 # Add any host-specific objects to GDB.
1977 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1978
1979 LIBGUI="../libgui/src/libgui.a"
1980 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1981 AC_SUBST(LIBGUI)
1982 AC_SUBST(GUI_CFLAGS_X)
1983
1984 WIN32LDAPP=
1985 AC_SUBST(WIN32LIBS)
1986 AC_SUBST(WIN32LDAPP)
1987
1988 case "${host}" in
1989 *-*-cygwin* | *-*-mingw* )
1990 configdir="win"
1991 ;;
1992 *)
1993 configdir="unix"
1994 ;;
1995 esac
1996
1997 GDBTKLIBS=
1998 if test "${enable_gdbtk}" = "yes"; then
1999
2000 # Gdbtk must have an absolute path to srcdir in order to run
2001 # properly when not installed.
2002 here=`pwd`
2003 cd ${srcdir}
2004 GDBTK_SRC_DIR=`pwd`
2005 cd $here
2006
2007 SC_PATH_TCLCONFIG
2008
2009 # If $no_tk is nonempty, then we can't do Tk, and there is no
2010 # point to doing Tcl.
2011 SC_PATH_TKCONFIG
2012
2013 if test -z "${no_tcl}" -a -z "${no_tk}"; then
2014 SC_LOAD_TCLCONFIG
2015
2016 # Check for in-tree tcl
2017 here=`pwd`
2018 cd ${srcdir}/..
2019 topdir=`pwd`
2020 cd ${here}
2021
2022 intree="no"
2023 if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2024 intree="yes"
2025 fi
2026
2027 # Find Tcl private headers
2028 if test x"${intree}" = xno; then
2029 CY_AC_TCL_PRIVATE_HEADERS
2030 TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2031 TCL_LIBRARY="${TCL_LIB_SPEC}"
2032 TCL_DEPS=""
2033 else
2034 # If building tcl in the same src tree, private headers
2035 # are not needed, but we need to be sure to use the right
2036 # headers library
2037 TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2038 TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2039 TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2040 fi
2041 AC_SUBST(TCL_INCLUDE)
2042 AC_SUBST(TCL_LIBRARY)
2043 AC_SUBST(TCL_DEPS)
2044
2045 SC_LOAD_TKCONFIG
2046
2047 # Check for in-tree Tk
2048 intree="no"
2049 if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2050 intree="yes"
2051 fi
2052
2053 # Find Tk private headers
2054 if test x"${intree}" = xno; then
2055 CY_AC_TK_PRIVATE_HEADERS
2056 TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2057 TK_LIBRARY=${TK_LIB_SPEC}
2058 TK_DEPS=""
2059 else
2060 TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2061 TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2062 TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2063 fi
2064 AC_SUBST(TK_INCLUDE)
2065 AC_SUBST(TK_LIBRARY)
2066 AC_SUBST(TK_DEPS)
2067 AC_SUBST(TK_XINCLUDES)
2068
2069 ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2070
2071 # Include some libraries that Tcl and Tk want.
2072 TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2073 # Yes, the ordering seems wrong here. But it isn't.
2074 # TK_LIBS is the list of libraries that need to be linked
2075 # after Tcl/Tk. Note that this isn't put into LIBS. If it
2076 # were in LIBS then any link tests after this point would
2077 # try to include things like `$(LIBGUI)', which wouldn't work.
2078 GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2079
2080 CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2081 CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2082 CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2083 CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2084 CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2085 CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2086 CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2087
2088 if test x$gdb_cv_os_cygwin = xyes; then
2089 WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2090 WIN32LDAPP="-Wl,--subsystem,console"
2091 CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2092 fi
2093
2094 AC_CONFIG_SUBDIRS(gdbtk)
2095 fi
2096 fi
2097
2098 AC_SUBST(X_CFLAGS)
2099 AC_SUBST(X_LDFLAGS)
2100 AC_SUBST(X_LIBS)
2101 AC_SUBST(GDBTKLIBS)
2102 AC_SUBST(GDBTK_CFLAGS)
2103 AC_SUBST(GDBTK_SRC_DIR)
2104
2105 AC_PATH_X
2106
2107 # Unlike the sim directory, whether a simulator is linked is controlled by
2108 # presence of a gdb_sim definition in the target configure.tgt entry.
2109 # This code just checks for a few cases where we'd like to ignore those
2110 # definitions, even when they're present in the '.mt' file. These cases
2111 # are when --disable-sim is specified, or if the simulator directory is
2112 # not part of the source tree.
2113 #
2114 AC_ARG_ENABLE(sim,
2115 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2116 [echo "enable_sim = $enable_sim";
2117 echo "enableval = ${enableval}";
2118 case "${enableval}" in
2119 yes) ignore_sim=false ;;
2120 no) ignore_sim=true ;;
2121 *) ignore_sim=false ;;
2122 esac],
2123 [ignore_sim=false])
2124
2125 if test ! -d "${srcdir}/../sim"; then
2126 ignore_sim=true
2127 fi
2128
2129 SIM=
2130 SIM_OBS=
2131 if test "${ignore_sim}" = "false"; then
2132 if test x"${gdb_sim}" != x ; then
2133 SIM="${gdb_sim}"
2134 SIM_OBS="remote-sim.o"
2135 AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2136 fi
2137 fi
2138 AC_SUBST(SIM)
2139 AC_SUBST(SIM_OBS)
2140
2141 AC_SUBST(ENABLE_CFLAGS)
2142 AC_SUBST(PROFILE_CFLAGS)
2143
2144 AC_SUBST(CONFIG_OBS)
2145 AC_SUBST(CONFIG_DEPS)
2146 AC_SUBST(CONFIG_SRCS)
2147 AC_SUBST(CONFIG_ALL)
2148 AC_SUBST(CONFIG_CLEAN)
2149 AC_SUBST(CONFIG_INSTALL)
2150 AC_SUBST(CONFIG_UNINSTALL)
2151
2152 # List of host floatformats.
2153 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2154 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2155 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2156
2157 # target_subdir is used by the testsuite to find the target libraries.
2158 target_subdir=
2159 if test "${host}" != "${target}"; then
2160 target_subdir="${target_alias}/"
2161 fi
2162 AC_SUBST(target_subdir)
2163
2164 frags=
2165 if test "${gdb_native}" = "yes"; then
2166 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2167 if test ! -f ${host_makefile_frag}; then
2168 AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2169 fi
2170 frags="$frags $host_makefile_frag"
2171 else
2172 host_makefile_frag=/dev/null
2173 fi
2174
2175 AC_SUBST_FILE(host_makefile_frag)
2176 AC_SUBST(frags)
2177
2178 changequote(,)dnl
2179 if test "${gdb_native}" = "yes"; then
2180 # We pick this up from the host configuration file (.mh) because we
2181 # do not have a native configuration Makefile fragment.
2182 nativefile=`sed -n '
2183 s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
2184 ' ${host_makefile_frag}`
2185 fi
2186 changequote([,])
2187
2188 if test x"${gdb_osabi}" != x ; then
2189 AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2190 [Define to the default OS ABI for this configuration.])
2191 fi
2192
2193 # Enable multi-ice-gdb-server.
2194 AC_ARG_ENABLE(multi-ice,
2195 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2196 [case $enableval in
2197 yes | no)
2198 ;;
2199 *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2200 esac])
2201 if test "x$enable_multi_ice" = xyes; then
2202 AC_CONFIG_SUBDIRS(multi-ice)
2203 fi
2204
2205 AC_ARG_ENABLE(gdbserver,
2206 AS_HELP_STRING([--enable-gdbserver],
2207 [automatically build gdbserver (yes/no/auto, default is auto)]),
2208 [case "${enableval}" in
2209 yes| no|auto) ;;
2210 *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2211 esac],[enable_gdbserver=auto])
2212
2213 # We only build gdbserver automatically in a native configuration, and
2214 # only if the user did not explicitly disable its build.
2215 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2216 AC_MSG_CHECKING(whether gdbserver is supported on this host)
2217 if test "x$build_gdbserver" = xyes; then
2218 AC_MSG_RESULT(yes)
2219 AC_CONFIG_SUBDIRS(gdbserver)
2220 gdbserver_build_enabled=yes
2221 else
2222 AC_MSG_RESULT(no)
2223 fi
2224 fi
2225
2226 # If the user explicitly request the gdbserver to be built, verify that
2227 # we were in fact able to enable it.
2228 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2229 AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2230 fi
2231
2232 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2233 # to an empty version.
2234
2235 files=
2236 links=
2237
2238 rm -f nm.h
2239 if test "${nativefile}" != ""; then
2240 case "${nativefile}" in
2241 nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2242 * ) GDB_NM_FILE="${nativefile}"
2243 esac
2244 files="${files} ${GDB_NM_FILE}"
2245 links="${links} nm.h"
2246 AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2247 fi
2248 AC_SUBST(GDB_NM_FILE)
2249
2250 AC_LINK_FILES($files, $links)
2251
2252 dnl Check for exe extension set on certain hosts (e.g. Win32)
2253 AC_EXEEXT
2254
2255 dnl Detect the character set used by this host.
2256 dnl At the moment, we just assume it's UTF-8.
2257 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2258 [Define to be a string naming the default host character set.])
2259
2260 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2261 [
2262 case x$CONFIG_HEADERS in
2263 xconfig.h:config.in)
2264 echo > stamp-h ;;
2265 esac
2266 ])
2267
2268 exit 0
GDB Binutils - Deliverables
This page took 0.089559 seconds and 5 git commands to generate.