gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2014 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37 AC_ARG_PROGRAM
  38
  39 # Dependency checking.
  40 ZW_CREATE_DEPDIR
  41 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  42
  43 # Check for the 'make' the user wants to use.
  44 AC_CHECK_PROGS(MAKE, make)
  45 MAKE_IS_GNU=
  46 case "`$MAKE --version 2>&1 | sed 1q`" in
  47   *GNU*)
  48     MAKE_IS_GNU=yes
  49     ;;
  50 esac
  51 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  52 AC_PROG_MAKE_SET
  53
  54 # Configure gnulib.  We need to build gnulib under some other
  55 # directory not "gnulib", to avoid the problem of both GDB and
  56 # GDBserver wanting to build it in the same directory, when building
  57 # in the source dir.
  58 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  59
  60 dnl List of object files and targets accumulated by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66
  67 CONFIG_ALL=
  68 CONFIG_CLEAN=
  69 CONFIG_INSTALL=
  70 CONFIG_UNINSTALL=
  71
  72 dnl Set up for gettext.
  73 ZW_GNU_GETTEXT_SISTER_DIR
  74
  75 localedir='${datadir}/locale'
  76 AC_SUBST(localedir)
  77
  78 if test x"$USE_NLS" = xyes; then
  79    CONFIG_ALL="$CONFIG_ALL all-po"
  80    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  81    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  82    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  83 fi
  84
  85 GNULIB=build-gnulib/import
  86
  87 # For Makefile dependencies.
  88 GNULIB_STDINT_H=
  89 if test x"$STDINT_H" != x; then
  90   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  91 fi
  92 AC_SUBST(GNULIB_STDINT_H)
  93
  94 PACKAGE=gdb
  95 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  96 AC_SUBST(PACKAGE)
  97
  98 # We never need to detect it in this sub-configure.
  99 # But preserve it for config.status --recheck.
 100 AC_ARG_VAR(MAKEINFO,
 101   [Parent configure detects if it is of sufficient version.])
 102 AC_ARG_VAR(MAKEINFOFLAGS,
 103   [Parameters for MAKEINFO.])
 104
 105 MAKEINFO_EXTRA_FLAGS=""
 106 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 107   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 108   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 109     gdb_cv_have_makeinfo_click=yes
 110   else
 111     gdb_cv_have_makeinfo_click=no
 112   fi])
 113 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 114   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 115 fi
 116 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 117
 118 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 119     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 120     [${libdir}/debug])
 121
 122 # We can't pass paths as command line arguments.
 123 # Mingw32 tries to be clever and will convert the paths for us.
 124 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 125 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 126 # This breaks GDB's relocatable path conversions since paths passed in
 127 # config.h would not get so translated, the path prefixes no longer match.
 128 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_MSG_CHECKING([for default auto-load directory])
 144 AC_ARG_WITH(auto-load-dir,
 145 AS_HELP_STRING([--with-auto-load-dir=PATH],
 146   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 147   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 148 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 149 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 150               [Directories from which to load auto-loaded scripts.])
 151 AC_MSG_RESULT([$with_auto_load_dir])
 152
 153 AC_MSG_CHECKING([for default auto-load safe-path])
 154 AC_ARG_WITH(auto-load-safe-path,
 155 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 156   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 157 AS_HELP_STRING([--without-auto-load-safe-path],
 158                [do not restrict auto-loaded files locations]),
 159     [if test "$with_auto_load_safe_path" = "no"; then
 160      with_auto_load_safe_path="/"
 161      fi],
 162 [with_auto_load_safe_path="$with_auto_load_dir"])
 163 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 164 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 165               [Directories safe to hold auto-loaded files.])
 166 AC_MSG_RESULT([$with_auto_load_safe_path])
 167
 168 AC_CONFIG_SUBDIRS(testsuite)
 169
 170 # Check whether to support alternative target configurations
 171 AC_ARG_ENABLE(targets,
 172 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 173 [case "${enableval}" in
 174   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 175             ;;
 176   no)       enable_targets= ;;
 177   *)        enable_targets=$enableval ;;
 178 esac])
 179
 180 # Check whether to enable 64-bit support on 32-bit hosts
 181 AC_ARG_ENABLE(64-bit-bfd,
 182 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 183 [case "${enableval}" in
 184   yes)  want64=true  ;;
 185   no)   want64=false ;;
 186   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 187 esac],[want64=false])dnl
 188
 189 # Provide defaults for some variables set by the per-host and per-target
 190 # configuration.
 191 gdb_host_obs=posix-hdep.o
 192
 193 if test "${target}" = "${host}"; then
 194   gdb_native=yes
 195 else
 196   gdb_native=no
 197 fi
 198
 199 . $srcdir/configure.host
 200
 201 # Accumulate some settings from configure.tgt over all enabled targets
 202
 203 TARGET_OBS=
 204 all_targets=
 205 HAVE_NATIVE_GCORE_TARGET=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239
 240     # Check whether this target is native and supports gcore.
 241     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 242        && $gdb_have_gcore; then
 243       HAVE_NATIVE_GCORE_TARGET=1
 244     fi
 245   fi
 246 done
 247
 248 if test x${all_targets} = xtrue; then
 249
 250   # We want all 64-bit targets if we either:
 251   #  - run on a 64-bit host  or
 252   #  - already require 64-bit support for some other target  or
 253   #  - the --enable-64-bit-bfd option was supplied
 254   # Otherwise we only support all 32-bit targets.
 255   #
 256   # NOTE: This test must be in sync with the corresponding
 257   #       tests in BFD!
 258
 259   if test x${want64} = xfalse; then
 260     AC_CHECK_SIZEOF(long)
 261     if test "x${ac_cv_sizeof_long}" = "x8"; then
 262       want64=true
 263     fi
 264   fi
 265   if test x${want64} = xtrue; then
 266     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 267   else
 268     TARGET_OBS='$(ALL_TARGET_OBS)'
 269   fi
 270 fi
 271
 272 AC_SUBST(TARGET_OBS)
 273 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 274
 275 # For other settings, only the main target counts.
 276 gdb_sim=
 277 gdb_osabi=
 278 build_gdbserver=
 279 targ=$target; . ${srcdir}/configure.tgt
 280
 281 # Fetch the default architecture and default target vector from BFD.
 282 targ=$target; . $srcdir/../bfd/config.bfd
 283
 284 # We only want the first architecture, so strip off the others if
 285 # there is more than one.
 286 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 287
 288 if test "x$targ_archs" != x; then
 289   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 290     [Define to BFD's default architecture. ])
 291 fi
 292 if test "x$targ_defvec" != x; then
 293   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 294     [Define to BFD's default target vector. ])
 295 fi
 296
 297 # The CLI cannot be disabled yet, but may be in the future.
 298
 299 # Enable CLI.
 300 AC_ARG_ENABLE(gdbcli,
 301 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 302   [case $enableval in
 303     yes)
 304       ;;
 305     no)
 306       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 307     *)
 308       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 309   esac],
 310   [enable_gdbcli=yes])
 311 if test x"$enable_gdbcli" = xyes; then
 312   if test -d $srcdir/cli; then
 313     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 314     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 315     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 316     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 317   fi
 318 fi
 319
 320 # Enable MI.
 321 AC_ARG_ENABLE(gdbmi,
 322 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 323   [case $enableval in
 324     yes | no)
 325       ;;
 326     *)
 327       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 328   esac],
 329   [enable_gdbmi=yes])
 330 if test x"$enable_gdbmi" = xyes; then
 331   if test -d $srcdir/mi; then
 332     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 333     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 334     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 335     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 336   fi
 337 fi
 338
 339 # Enable TUI.
 340 AC_ARG_ENABLE(tui,
 341 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 342   [case $enableval in
 343     yes | no | auto)
 344       ;;
 345     *)
 346       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 347   esac],enable_tui=auto)
 348
 349 # Enable gdbtk.
 350 AC_ARG_ENABLE(gdbtk,
 351 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 352   [case $enableval in
 353     yes | no)
 354       ;;
 355     *)
 356       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 357   esac],
 358   [if test -d $srcdir/gdbtk; then
 359     enable_gdbtk=yes
 360   else
 361     enable_gdbtk=no
 362   fi])
 363 # We unconditionally disable gdbtk tests on selected platforms.
 364 case $host_os in
 365   go32* | windows*)
 366     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 367     enable_gdbtk=no ;;
 368 esac
 369
 370 # Libunwind support for ia64.
 371
 372 AC_ARG_WITH(libunwind-ia64,
 373 AS_HELP_STRING([--with-libunwind-ia64],
 374                [use libunwind frame unwinding for ia64 targets]),,
 375             [with_libunwind_ia64=auto])
 376
 377 # Backward compatibility option.
 378 if test "${with_libunwind+set}" = set; then
 379   if test x"$with_libunwind_ia64" != xauto; then
 380     AC_MSG_ERROR(
 381       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 382   fi
 383   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 384   with_libunwind_ia64="$with_libunwind"
 385 fi
 386
 387 case "$with_libunwind_ia64" in
 388   yes | no)
 389     ;;
 390   auto)
 391     AC_CHECK_HEADERS(libunwind-ia64.h)
 392     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 393     ;;
 394   *)
 395     AC_MSG_ERROR(
 396       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 397     ;;
 398 esac
 399
 400 if test x"$with_libunwind_ia64" = xyes; then
 401   AC_CHECK_HEADERS(libunwind-ia64.h)
 402   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 403     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 404   fi
 405   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 406   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 407   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 408 fi
 409
 410 opt_curses=no
 411 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 412
 413 prefer_curses=no
 414 if test "$opt_curses" = "yes"; then
 415   prefer_curses=yes
 416 fi
 417
 418 # Profiling support.
 419 AC_ARG_ENABLE(profiling,
 420 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 421   [case $enableval in
 422     yes | no)
 423       ;;
 424     *)
 425       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 426   esac],
 427  [enable_profiling=no])
 428
 429 AC_CHECK_FUNCS(monstartup _mcleanup)
 430 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 431 [AC_TRY_LINK(
 432 [#include <stdlib.h>
 433 extern char _etext;
 434 ],
 435 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 436 if test $ac_cv_var__etext = yes; then
 437   AC_DEFINE(HAVE__ETEXT, 1,
 438             [Define to 1 if your system has the _etext variable. ])
 439 fi
 440 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 441 [AC_TRY_LINK(
 442 [#include <stdlib.h>
 443 extern char etext;
 444 ],
 445 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 446 if test $ac_cv_var_etext = yes; then
 447   AC_DEFINE(HAVE_ETEXT, 1,
 448             [Define to 1 if your system has the etext variable. ])
 449 fi
 450 if test "$enable_profiling" = yes ; then
 451   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 452     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 453   fi
 454   PROFILE_CFLAGS=-pg
 455   OLD_CFLAGS="$CFLAGS"
 456   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 457
 458   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 459     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 460      ac_cv_cc_supports_pg=no)])
 461
 462   if test $ac_cv_cc_supports_pg = no; then
 463     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 464   fi
 465
 466   CFLAGS="$OLD_CFLAGS"
 467 fi
 468
 469 ACX_PKGVERSION([GDB])
 470 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 471 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 472 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 473
 474 # --------------------- #
 475 # Checks for programs.  #
 476 # --------------------- #
 477
 478 AC_PROG_AWK
 479 AC_PROG_INSTALL
 480 AC_PROG_LN_S
 481 AC_PROG_RANLIB
 482 AC_PROG_YACC
 483
 484 AC_CHECK_TOOL(AR, ar)
 485 AC_CHECK_TOOL(DLLTOOL, dlltool)
 486 AC_CHECK_TOOL(WINDRES, windres)
 487
 488 case $host_os in
 489   gnu*)
 490     # Needed for GNU Hurd hosts.
 491     AC_CHECK_TOOL(MIG, mig)
 492     if test x"$MIG" = x; then
 493       AC_MSG_ERROR([MIG not found but required for $host hosts])
 494     fi
 495     ;;
 496 esac
 497
 498 # ---------------------- #
 499 # Checks for libraries.  #
 500 # ---------------------- #
 501
 502 # We might need to link with -lm; most simulators need it.
 503 AC_CHECK_LIB(m, main)
 504
 505 # We need to link with -lw to get `wctype' on Solaris before Solaris
 506 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 507 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 508 # is known to have this problem).  Therefore we avoid libw if we can.
 509 AC_CHECK_FUNC(wctype, [],
 510   [AC_CHECK_LIB(w, wctype)])
 511
 512 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 513 AC_SEARCH_LIBS(gethostbyname, nsl)
 514
 515 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 516 AC_SEARCH_LIBS(socketpair, socket)
 517
 518 # Link in zlib if we can.  This allows us to read compressed debug sections.
 519 AM_ZLIB
 520
 521 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 522 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 523
 524 AM_ICONV
 525
 526 # GDB may fork/exec the iconv program to get the list of supported character
 527 # sets.  Allow the user to specify where to find it.
 528 # There are several factors affecting the choice of option name:
 529 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 530 #   the build-time location of libiconv files.
 531 # - The program we need to find is iconv, which comes with glibc.  The user
 532 #   doesn't necessarily have libiconv installed.  Therefore naming this
 533 #   --with-libiconv-foo feels wrong.
 534 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 535 #   defined to work on directories not files (though it really doesn't know
 536 #   the difference).
 537 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 538 #   with --with-libiconv-prefix.
 539 # Putting these together is why the option name is --with-iconv-bin.
 540
 541 AC_ARG_WITH(iconv-bin,
 542 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 543 [iconv_bin="${withval}"
 544  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 545                     [Path of directory of iconv program.])
 546  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 547 ])
 548
 549 # For the TUI, we need enhanced curses functionality.
 550 if test x"$enable_tui" != xno; then
 551   prefer_curses=yes
 552 fi
 553
 554 curses_found=no
 555 if test x"$prefer_curses" = xyes; then
 556   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 557   # curses library because the latter might not provide all the
 558   # functionality we need.  However, this leads to problems on systems
 559   # where the linker searches /usr/local/lib, but the compiler doesn't
 560   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 561   # default installation of ncurses on alpha*-dec-osf* will lead to such
 562   # a situation.
 563   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 564
 565   if test "$ac_cv_search_waddstr" != no; then
 566     curses_found=yes
 567   fi
 568 fi
 569
 570 # Check whether we should enable the TUI, but only do so if we really
 571 # can.
 572 if test x"$enable_tui" != xno; then
 573   if test -d $srcdir/tui; then
 574     if test "$curses_found" != no; then
 575       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 576       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 577       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 578       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 579     else
 580       if test x"$enable_tui" = xyes; then
 581         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 582       else
 583         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 584       fi
 585     fi
 586   fi
 587 fi
 588
 589 # Since GDB uses Readline, we need termcap functionality.  In many
 590 # cases this will be provided by the curses library, but some systems
 591 # have a seperate termcap library, or no curses library at all.
 592
 593 case $host_os in
 594   cygwin*)
 595     if test -d $srcdir/libtermcap; then
 596       LIBS="../libtermcap/libtermcap.a $LIBS"
 597       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 598     fi ;;
 599   go32* | *djgpp*)
 600     ac_cv_search_tgetent="none required"
 601     ;;
 602   *mingw32*)
 603     ac_cv_search_tgetent="none required"
 604     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 605     ;;
 606 esac
 607
 608 # These are the libraries checked by Readline.
 609 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 610
 611 if test "$ac_cv_search_tgetent" = no; then
 612   AC_MSG_ERROR([no termcap library found])
 613 fi
 614
 615 AC_ARG_WITH([system-readline],
 616   [AS_HELP_STRING([--with-system-readline],
 617                   [use installed readline library])])
 618
 619 if test "$with_system_readline" = yes; then
 620   READLINE=-lreadline
 621   READLINE_DEPS=
 622   READLINE_CFLAGS=
 623   READLINE_TEXI_INCFLAG=
 624 else
 625   READLINE='$(READLINE_DIR)/libreadline.a'
 626   READLINE_DEPS='$(READLINE)'
 627   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 628   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 629 fi
 630 AC_SUBST(READLINE)
 631 AC_SUBST(READLINE_DEPS)
 632 AC_SUBST(READLINE_CFLAGS)
 633 AC_SUBST(READLINE_TEXI_INCFLAG)
 634
 635 # Generate jit-reader.h
 636
 637 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 638 TARGET_PTR=
 639
 640 AC_CHECK_SIZEOF(unsigned long long)
 641 AC_CHECK_SIZEOF(unsigned long)
 642 AC_CHECK_SIZEOF(unsigned __int128)
 643
 644 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 645   TARGET_PTR="unsigned long"
 646 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 647   TARGET_PTR="unsigned long long"
 648 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 649   TARGET_PTR="unsigned __int128"
 650 else
 651   TARGET_PTR="unsigned long"
 652 fi
 653
 654 AC_SUBST(TARGET_PTR)
 655 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 656
 657 AC_SEARCH_LIBS(dlopen, dl)
 658
 659 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 660                 [directory to load the JIT readers from],
 661                 [${libdir}/gdb])
 662
 663 AC_ARG_WITH(expat,
 664   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 665   [], [with_expat=auto])
 666 AC_MSG_CHECKING([whether to use expat])
 667 AC_MSG_RESULT([$with_expat])
 668
 669 if test "${with_expat}" = no; then
 670   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 671   HAVE_LIBEXPAT=no
 672 else
 673   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 674                         [XML_Parser p = XML_ParserCreate (0);])
 675   if test "$HAVE_LIBEXPAT" != yes; then
 676     if test "$with_expat" = yes; then
 677       AC_MSG_ERROR([expat is missing or unusable])
 678     else
 679       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 680     fi
 681   else
 682     save_LIBS=$LIBS
 683     LIBS="$LIBS $LIBEXPAT"
 684     AC_CHECK_FUNCS(XML_StopParser)
 685     LIBS=$save_LIBS
 686   fi
 687 fi
 688
 689 # --------------------- #
 690 # Check for libpython.  #
 691 # --------------------- #
 692
 693 dnl Utility to simplify finding libpython.
 694 dnl $1 = pythonX.Y
 695 dnl $2 = the shell variable to assign the result to
 696 dnl      If libpython is found we store $version here.
 697 dnl $3 = additional flags to add to CPPFLAGS
 698 dnl $4 = additional flags to add to LIBS
 699
 700 AC_DEFUN([AC_TRY_LIBPYTHON],
 701 [
 702   version=$1
 703   define([have_libpython_var],$2)
 704   new_CPPFLAGS=$3
 705   new_LIBS=$4
 706   AC_MSG_CHECKING([for ${version}])
 707   save_CPPFLAGS=$CPPFLAGS
 708   save_LIBS=$LIBS
 709   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 710   LIBS="$LIBS $new_LIBS"
 711   found_usable_python=no
 712   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 713                                  [[Py_Initialize ();]]),
 714                  [have_libpython_var=${version}
 715                   found_usable_python=yes
 716                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 717                   PYTHON_LIBS=$new_LIBS])
 718   CPPFLAGS=$save_CPPFLAGS
 719   LIBS=$save_LIBS
 720   AC_MSG_RESULT([${found_usable_python}])
 721 ])
 722
 723 dnl There are several different values for --with-python:
 724 dnl
 725 dnl no -   Don't include python support.
 726 dnl yes -  Include python support, error if it's missing.
 727 dnl        If we find python in $PATH, use it to fetch configure options,
 728 dnl        otherwise assume the compiler can find it with no help from us.
 729 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 730 dnl auto - Same as "yes", but if python is missing from the system,
 731 dnl        fall back to "no".
 732 dnl /path/to/python/exec-prefix -
 733 dnl        Use the python located in this directory.
 734 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 735 dnl        the compilation parameters.  Otherwise use
 736 dnl        -I/path/to/python/exec-prefix/include,
 737 dnl        -L/path/to/python/exec-prefix/lib.
 738 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 739 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 740 dnl        but is deprecated.
 741 dnl /path/to/python/executable -
 742 dnl        Run python-config.py with this version of python to fetch the
 743 dnl        compilation parameters.
 744 dnl        NOTE: This needn't be the real python executable.
 745 dnl        In a cross-compilation scenario (build != host), this could be
 746 dnl        a shell script that provides what python-config.py provides for
 747 dnl        --ldflags, --includes, --exec-prefix.
 748 dnl python-executable -
 749 dnl        Find python-executable in $PATH, and then handle the same as
 750 dnl        /path/to/python/executable.
 751 dnl
 752 dnl If a python program is specified, it is used to run python-config.py and
 753 dnl is passed --ldflags, --includes, --exec-prefix.
 754
 755 AC_ARG_WITH(python,
 756   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 757   [], [with_python=auto])
 758 AC_MSG_CHECKING([whether to use python])
 759 AC_MSG_RESULT([$with_python])
 760
 761 if test "${with_python}" = no; then
 762   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 763   have_libpython=no
 764 else
 765   case "${with_python}" in
 766   [[\\/]]* | ?:[[\\/]]*)
 767     if test -d ${with_python}; then
 768       # Assume the python binary is ${with_python}/bin/python.
 769       python_prog="${with_python}/bin/python"
 770       python_prefix=
 771       # If python does not exit ${with_python}/bin, then try in
 772       # ${with_python}.  On Windows/MinGW, this is where the Python
 773       # executable is.
 774       if test ! -x "${python_prog}"; then
 775         python_prog="${with_python}/python"
 776         python_prefix=
 777       fi
 778       if test ! -x "${python_prog}"; then
 779         # Fall back to gdb 7.0/7.1 behaviour.
 780         python_prog=missing
 781         python_prefix=${with_python}
 782       fi
 783     elif test -x "${with_python}"; then
 784       # While we can't run python compiled for $host (unless host == build),
 785       # the user could write a script that provides the needed information,
 786       # so we support that.
 787       python_prog=${with_python}
 788       python_prefix=
 789     else
 790       AC_ERROR(invalid value for --with-python)
 791     fi
 792     ;;
 793   */*)
 794     # Disallow --with-python=foo/bar.
 795     AC_ERROR(invalid value for --with-python)
 796     ;;
 797   *)
 798     # The user has either specified auto, yes, or the name of the python
 799     # program assumed to be in $PATH.
 800     python_prefix=
 801     case "${with_python}" in
 802     yes | auto)
 803       if test ${build} = ${host}; then
 804         AC_PATH_PROG(python_prog_path, python, missing)
 805         if test "${python_prog_path}" = missing; then
 806           python_prog=missing
 807         else
 808           python_prog=${python_prog_path}
 809         fi
 810       else
 811         # Not much we can do except assume the cross-compiler will find the
 812         # right files.
 813         python_prog=missing
 814       fi
 815       ;;
 816     *)
 817       # While we can't run python compiled for $host (unless host == build),
 818       # the user could write a script that provides the needed information,
 819       # so we support that.
 820       python_prog="${with_python}"
 821       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 822       if test "${python_prog_path}" = missing; then
 823         AC_ERROR(unable to find python program ${python_prog})
 824       fi
 825       ;;
 826     esac
 827   esac
 828
 829   if test "${python_prog}" != missing; then
 830     # We have a python program to use, but it may be too old.
 831     # Don't flag an error for --with-python=auto (the default).
 832     have_python_config=yes
 833     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 834     if test $? != 0; then
 835       have_python_config=failed
 836       if test "${with_python}" != auto; then
 837         AC_ERROR(failure running python-config --includes)
 838       fi
 839     fi
 840     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 841     if test $? != 0; then
 842       have_python_config=failed
 843       if test "${with_python}" != auto; then
 844         AC_ERROR(failure running python-config --ldflags)
 845       fi
 846     fi
 847     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --exec-prefix)
 852       fi
 853     fi
 854   else
 855     # We do not have a python executable we can use to determine where
 856     # to find the Python headers and libs.  We cannot guess the include
 857     # path from the python_prefix either, because that include path
 858     # depends on the Python version.  So, there is nothing much we can
 859     # do except assume that the compiler will be able to find those files.
 860     python_includes=
 861     python_libs=
 862     have_python_config=no
 863   fi
 864
 865   # If we have python-config, only try the configuration it provides.
 866   # Otherwise fallback on the old way of trying different versions of
 867   # python in turn.
 868
 869   have_libpython=no
 870   if test "${have_python_config}" = yes; then
 871     # Determine the Python version by extracting "-lpython<version>"
 872     # part of the python_libs. <version> is usually X.Y with X and Y
 873     # being decimal numbers, but can also be XY (seen on Windows).
 874     #
 875     # The extraction is performed using sed with a regular expression.
 876     # Initially, the regexp used was using the '?' quantifier to make
 877     # the dot in the version number optional.  Unfortunately, this
 878     # does not work with non-GNU versions of sed because, because of
 879     # what looks like a limitation (the '?' quantifier does not work
 880     # with back-references).  We work around this limitation by using
 881     # the '*' quantifier instead.  It means that, in theory, we might
 882     # match unexpected version strings such as "-lpython2..7", but
 883     # this seems unlikely in practice.  And even if that happens,
 884     # an error will be triggered later on, when checking that version
 885     # number.
 886     python_version=`echo " ${python_libs} " \
 887                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 888     case "${python_version}" in
 889     python*)
 890       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 891                        ${python_includes}, ${python_libs})
 892       ;;
 893     *)
 894       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 895       ;;
 896     esac
 897   elif test "${have_python_config}" != failed; then
 898     if test "${have_libpython}" = no; then
 899       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 900                        ${python_includes}, "${python_libs} -lpython2.7")
 901     fi
 902     if test "${have_libpython}" = no; then
 903       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 904                        ${python_includes}, "${python_libs} -lpython2.6")
 905     fi
 906     if test ${have_libpython} = no; then
 907       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 908                        ${python_includes}, "${python_libs} -lpython2.5")
 909     fi
 910     if test ${have_libpython} = no; then
 911       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 912                        ${python_includes}, "${python_libs} -lpython2.4")
 913     fi
 914   fi
 915   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 916     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 917   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 918     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 919   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 920     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 921   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 922     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 923   fi
 924
 925   if test "${have_libpython}" = no; then
 926     case "${with_python}" in
 927     yes)
 928       AC_MSG_ERROR([python is missing or unusable])
 929       ;;
 930     auto)
 931       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 932       ;;
 933     *)
 934       AC_MSG_ERROR([no usable python found at ${with_python}])
 935       ;;
 936     esac
 937   else
 938     if test -n "${python_prefix}"; then
 939       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 940                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 941       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 942     fi
 943   fi
 944 fi
 945
 946 if test "${have_libpython}" != no; then
 947   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 948   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 949   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 950   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 951   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 952   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 953
 954   # Flags needed to compile Python code (taken from python-config --cflags).
 955   # We cannot call python-config directly because it will output whatever was
 956   # used when compiling the Python interpreter itself, including flags which
 957   # would make the python-related objects be compiled differently from the
 958   # rest of GDB (e.g., -O2 and -fPIC).
 959   if test "${GCC}" = yes; then
 960     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 961   fi
 962
 963   if test "x${tentative_python_cflags}" != x; then
 964     AC_MSG_CHECKING(compiler flags for python code)
 965     for flag in ${tentative_python_cflags}; do
 966       # Check that the compiler accepts it
 967       saved_CFLAGS="$CFLAGS"
 968       CFLAGS="$CFLAGS $flag"
 969       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 970       CFLAGS="$saved_CFLAGS"
 971     done
 972     AC_MSG_RESULT(${PYTHON_CFLAGS})
 973   fi
 974
 975   # On x64 Windows, Python's include headers, and pyconfig.h in
 976   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 977   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 978   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 979   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 980   # The issue was reported to the Python community, but still isn't
 981   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 982
 983   case "$gdb_host" in
 984     mingw64)
 985            if test "${GCC}" = yes; then
 986              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 987            fi
 988            ;;
 989   esac
 990
 991   # Note that "python -m threading" cannot be used to check for
 992   # threading support due to a bug in Python 2.7.3
 993   # (http://bugs.python.org/issue15567).
 994   AC_MSG_CHECKING(whether python supports threads)
 995   saved_CPPFLAGS="${CPPFLAGS}"
 996   CPPFLAGS="${PYTHON_CPPFLAGS}"
 997   # Note that the test is reversed so that python_has_threads=yes on
 998   # unexpected failures.
 999   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1000 #include <Python.h>
1001 #ifdef WITH_THREAD
1002 # error
1003 #endif
1004   ]]), [python_has_threads=no], [python_has_threads=yes])
1005   AC_MSG_RESULT(${python_has_threads})
1006   CPPFLAGS="${saved_CPPFLAGS}"
1007 else
1008   # Even if Python support is not compiled in, we need to have this file
1009   # included so that the "python" command, et.al., still exists.
1010   CONFIG_OBS="$CONFIG_OBS python.o"
1011   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1012 fi
1013 AC_SUBST(PYTHON_CFLAGS)
1014 AC_SUBST(PYTHON_CPPFLAGS)
1015 AC_SUBST(PYTHON_LIBS)
1016 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1017
1018 # -------------------- #
1019 # Check for libguile.  #
1020 # -------------------- #
1021
1022 dnl Utility to simplify finding libguile.
1023 dnl $1 = pkg-config-program
1024 dnl $2 = space-separate list of guile versions to try
1025 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1026 dnl $4 = the shell variable to assign the result to
1027 dnl      If libguile is found we store "yes" here.
1028
1029 AC_DEFUN([AC_TRY_LIBGUILE],
1030 [
1031   pkg_config=$1
1032   guile_version_list=$2
1033   flag_errors=$3
1034   define([have_libguile_var],$4)
1035   found_usable_guile=checking
1036   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1037   for guile_version in ${guile_version_list}; do
1038     ${pkg_config} --exists ${guile_version} 2>/dev/null
1039     if test $? != 0; then
1040       continue
1041     fi
1042     dnl pkg-config says the package exists, so if we get an error now,
1043     dnl that's bad.
1044     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1045     if test $? != 0; then
1046       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1047     fi
1048     new_LIBS=`${pkg_config} --libs ${guile_version}`
1049     if test $? != 0; then
1050       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1051     fi
1052     dnl If we get this far, great.
1053     found_usable_guile=${guile_version}
1054     break
1055   done
1056   if test "${found_usable_guile}" = "checking"; then
1057     if test "${flag_errors}" = "yes"; then
1058       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1059     else
1060       found_usable_guile=no
1061     fi
1062   fi
1063   dnl One final sanity check.
1064   dnl The user could have said --with-guile=python-2.7.
1065   if test "${found_usable_guile}" != no; then
1066     save_CPPFLAGS=$CPPFLAGS
1067     save_LIBS=$LIBS
1068     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1069     LIBS="$LIBS $new_LIBS"
1070     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1071                                    [[scm_init_guile ();]]),
1072                    [have_libguile_var=yes
1073                     GUILE_CPPFLAGS=$new_CPPFLAGS
1074                     GUILE_LIBS=$new_LIBS],
1075                    [found_usable_guile=no])
1076     CPPFLAGS=$save_CPPFLAGS
1077     LIBS=$save_LIBS
1078     if test "${found_usable_guile}" = no; then
1079       if test "${flag_errors}" = yes; then
1080         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1081       fi
1082     fi
1083   fi
1084   AC_MSG_RESULT([${found_usable_guile}])
1085 ])
1086
1087 dnl There are several different values for --with-guile:
1088 dnl
1089 dnl no -   Don't include guile support.
1090 dnl yes -  Include guile support, error if it's missing.
1091 dnl        The pkg-config program must be in $PATH.
1092 dnl auto - Same as "yes", but if guile is missing from the system,
1093 dnl        fall back to "no".
1094 dnl guile-version [guile-version-choice-2 ...] -
1095 dnl        A space-separated list of guile package versions to try.
1096 dnl        These are passed to pkg-config as-is.
1097 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1098 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1099 dnl /path/to/pkg-config -
1100 dnl        Use this pkg-config program.
1101 dnl        NOTE: This needn't be the "real" pkg-config program.
1102 dnl        It could be a shell script.  It is invoked as:
1103 dnl        pkg-config --exists $version
1104 dnl        pkg-config --cflags $version
1105 dnl        pkg-config --libs $version
1106 dnl        pkg-config --variable guild $version
1107 dnl        The script will be called with $version having each value in
1108 dnl        $try_guile_versions until --exists indicates success.
1109
1110 AC_ARG_WITH(guile,
1111   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1112   [], [with_guile=auto])
1113 AC_MSG_CHECKING([whether to use guile])
1114 AC_MSG_RESULT([$with_guile])
1115
1116 dnl We check guile with pkg-config.
1117 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1118
1119 try_guile_versions="guile-2.2 guile-2.0"
1120 have_libguile=no
1121 case "${with_guile}" in
1122 no)
1123   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1124   ;;
1125 auto)
1126   if test "${pkg_config_prog_path}" = "missing"; then
1127     AC_MSG_WARN([pkg-config not found, guile support disabled])
1128   else
1129     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1130   fi
1131   ;;
1132 yes)
1133   if test "${pkg_config_prog_path}" = "missing"; then
1134     AC_MSG_ERROR([pkg-config not found])
1135   fi
1136   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1137   ;;
1138 [[\\/]]* | ?:[[\\/]]*)
1139   if test -x "${with_guile}"; then
1140     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1141   else
1142     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1143   fi
1144   ;;
1145 "" | */*)
1146   # Disallow --with=guile="" and --with-guile=foo/bar.
1147   AC_MSG_ERROR([invalid value for --with-guile])
1148   ;;
1149 *)
1150   # A space separate list of guile versions to try, in order.
1151   if test "${pkg_config_prog_path}" = "missing"; then
1152     AC_MSG_ERROR([pkg-config not found])
1153   fi
1154   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1155   ;;
1156 esac
1157
1158 if test "${have_libguile}" != no; then
1159   dnl Get the name of the 'guild' program.
1160   case "${with_guile}" in
1161   [[\\/]]* | ?:[[\\/]]*)
1162     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1163     ;;
1164   *)
1165     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1166     ;;
1167   esac
1168
1169   dnl Make sure guild can handle this host.
1170   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1171   dnl If not, disable guile support.
1172   if test "$ac_cv_guild_ok" = no; then
1173     have_libguile=no
1174     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1175   fi
1176 fi
1177
1178 if test "${have_libguile}" != no; then
1179   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1180   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1181   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1182   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1183   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1184   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1185
1186   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1187   save_LIBS="$LIBS"
1188   save_CPPFLAGS="$CPPFLAGS"
1189   LIBS="$GUILE_LIBS"
1190   CPPFLAGS="$GUILE_CPPFLAGS"
1191   AC_CHECK_FUNCS([scm_new_smob])
1192   LIBS="$save_LIBS"
1193   CPPFLAGS="$save_CPPFLAGS"
1194 else
1195   # Even if Guile support is not compiled in, we need to have these files
1196   # included.
1197   CONFIG_OBS="$CONFIG_OBS guile.o"
1198   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1199 fi
1200 AC_SUBST(GUILE_CPPFLAGS)
1201 AC_SUBST(GUILE_LIBS)
1202 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1203
1204 # --------------------- #
1205 # Check for libmcheck.  #
1206 # --------------------- #
1207
1208 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1209 # but turn it off if Python is enabled with threads, since -lmcheck is
1210 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1211 # and for releases.
1212 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1213    && $development; then
1214   libmcheck_default=yes
1215 else
1216   libmcheck_default=no
1217 fi
1218 GDB_AC_LIBMCHECK(${libmcheck_default})
1219
1220 if test "$ENABLE_LIBMCHECK" = "yes" \
1221         -a "${have_libpython}" != "no" \
1222         -a "${python_has_threads}" = "yes" ; then
1223   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1224 fi
1225
1226 # ------------------------- #
1227 # Checks for header files.  #
1228 # ------------------------- #
1229
1230 AC_HEADER_STDC
1231 # elf_hp.h is for HP/UX 64-bit shared library support.
1232 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1233                   thread_db.h \
1234                   sys/fault.h \
1235                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1236                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1237                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1238                   termios.h termio.h \
1239                   sgtty.h elf_hp.h \
1240                   dlfcn.h])
1241 AC_CHECK_HEADERS(sys/proc.h, [], [],
1242 [#if HAVE_SYS_PARAM_H
1243 # include <sys/param.h>
1244 #endif
1245 ])
1246 AC_CHECK_HEADERS(sys/user.h, [], [],
1247 [#if HAVE_SYS_PARAM_H
1248 # include <sys/param.h>
1249 #endif
1250 ])
1251
1252 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1253 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1254 # think that we don't have <curses.h> if we're using GCC.
1255 case $host_os in
1256   solaris2.[[789]])
1257     if test "$GCC" = yes; then
1258       AC_DEFINE(_MSE_INT_H, 1,
1259         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1260    Solaris 2.[789] when using GCC. ])
1261     fi ;;
1262 esac
1263 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1264 AC_CHECK_HEADERS(term.h, [], [],
1265 [#if HAVE_CURSES_H
1266 # include <curses.h>
1267 #endif
1268 ])
1269
1270 # ------------------------- #
1271 # Checks for declarations.  #
1272 # ------------------------- #
1273
1274 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1275 AM_LC_MESSAGES
1276
1277 # ----------------------- #
1278 # Checks for structures.  #
1279 # ----------------------- #
1280
1281 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1282
1283 # ------------------ #
1284 # Checks for types.  #
1285 # ------------------ #
1286
1287 AC_TYPE_SIGNAL
1288 AC_CHECK_TYPES(socklen_t, [], [],
1289 [#include <sys/types.h>
1290 #include <sys/socket.h>
1291 ])
1292
1293 # ------------------------------------- #
1294 # Checks for compiler characteristics.  #
1295 # ------------------------------------- #
1296
1297 AC_C_CONST
1298 AC_C_INLINE
1299 AC_C_BIGENDIAN
1300
1301 # ------------------------------ #
1302 # Checks for library functions.  #
1303 # ------------------------------ #
1304
1305 AC_FUNC_ALLOCA
1306 AC_FUNC_MMAP
1307 AC_FUNC_VFORK
1308 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1309                 pipe poll pread pread64 pwrite readlink resize_term \
1310                 sbrk setpgid setpgrp setsid \
1311                 sigaction sigprocmask sigsetmask socketpair \
1312                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1313                 setrlimit getrlimit posix_madvise waitpid lstat \
1314                 ptrace64 sigaltstack])
1315 AM_LANGINFO_CODESET
1316 GDB_AC_COMMON
1317
1318 # Check the return and argument types of ptrace.  No canned test for
1319 # this, so roll our own.
1320 gdb_ptrace_headers='
1321 #include <sys/types.h>
1322 #if HAVE_SYS_PTRACE_H
1323 # include <sys/ptrace.h>
1324 #endif
1325 #if HAVE_UNISTD_H
1326 # include <unistd.h>
1327 #endif
1328 '
1329 # There is no point in checking if we don't have a prototype.
1330 AC_CHECK_DECLS(ptrace, [], [
1331   : ${gdb_cv_func_ptrace_ret='int'}
1332   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1333 ], $gdb_ptrace_headers)
1334 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1335 # empty argument list, so check for that explicitly.
1336 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1337   AC_TRY_COMPILE($gdb_ptrace_headers,
1338     [extern long ptrace (enum __ptrace_request, ...);],
1339     gdb_cv_func_ptrace_ret='long',
1340     AC_TRY_COMPILE($gdb_ptrace_headers,
1341       [extern int ptrace ();],
1342       gdb_cv_func_ptrace_ret='int',
1343       gdb_cv_func_ptrace_ret='long')))
1344 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1345   [Define as the return type of ptrace.])
1346 # Check argument types.
1347 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1348   AC_TRY_COMPILE($gdb_ptrace_headers,
1349     [extern long ptrace (enum __ptrace_request, ...);],
1350     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1351 for gdb_arg1 in 'int' 'long'; do
1352  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1353   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1354    for gdb_arg4 in 'int' 'long' 'void *'; do
1355      AC_TRY_COMPILE($gdb_ptrace_headers, [
1356 extern $gdb_cv_func_ptrace_ret
1357   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1358 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1359     break 4;])
1360     for gdb_arg5 in 'int *' 'int' 'long'; do
1361      AC_TRY_COMPILE($gdb_ptrace_headers, [
1362 extern $gdb_cv_func_ptrace_ret
1363   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1364 ], [
1365 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1366     break 5;])
1367     done
1368    done
1369   done
1370  done
1371 done
1372 # Provide a safe default value.
1373 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1374 ])])
1375 ac_save_IFS=$IFS; IFS=','
1376 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1377 IFS=$ac_save_IFS
1378 shift
1379 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1380   [Define to the type of arg 3 for ptrace.])
1381 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1382   [Define to the type of arg 4 for ptrace.])
1383 if test -n "$[5]"; then
1384   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1385     [Define to the type of arg 5 for ptrace.])
1386 fi
1387
1388 dnl AC_FUNC_SETPGRP does not work when cross compiling
1389 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1390 if test "$cross_compiling" = no; then
1391   AC_FUNC_SETPGRP
1392 else
1393   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1394     [AC_TRY_COMPILE([
1395 #include <unistd.h>
1396 ], [
1397   if (setpgrp(1,1) == -1)
1398     exit (0);
1399   else
1400     exit (1);
1401 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1402 if test $ac_cv_func_setpgrp_void = yes; then
1403   AC_DEFINE(SETPGRP_VOID, 1)
1404 fi
1405 fi
1406
1407 # Assume we'll default to using the included libiberty regex.
1408 gdb_use_included_regex=yes
1409
1410 # However, if the system regex is GNU regex, then default to *not*
1411 # using the included regex.
1412 AC_CACHE_CHECK(
1413   [for GNU regex],
1414   [gdb_cv_have_gnu_regex],
1415   [AC_TRY_COMPILE(
1416     [#include <gnu-versions.h>],
1417     [#define REGEX_INTERFACE_VERSION 1
1418 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1419 # error "Version mismatch"
1420 #endif],
1421     gdb_cv_have_gnu_regex=yes,
1422     gdb_cv_have_gnu_regex=no)])
1423 if test $gdb_cv_have_gnu_regex = yes; then
1424   gdb_use_included_regex=no
1425 fi
1426
1427 AC_ARG_WITH(included-regex,
1428   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1429   gdb_with_regex=$withval,
1430   gdb_with_regex=$gdb_use_included_regex)
1431 if test "$gdb_with_regex" = yes; then
1432   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1433     [Define to 1 if the regex included in libiberty should be used.])
1434 fi
1435
1436 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1437 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1438 [#include <sys/param.h>
1439 #include <sys/proc.h>
1440 ])
1441
1442 # See if <sys/lwp.h> defines `struct lwp`.
1443 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1444 [AC_TRY_COMPILE([#include <sys/param.h>
1445 #include <sys/lwp.h>], [struct lwp l;],
1446 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1447 if test $gdb_cv_struct_lwp = yes; then
1448   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1449             [Define to 1 if your system has struct lwp.])
1450 fi
1451
1452 # See if <machine/reg.h> degines `struct reg'.
1453 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1454 [AC_TRY_COMPILE([#include <sys/types.h>
1455 #include <machine/reg.h>], [struct reg r;],
1456 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1457 if test $gdb_cv_struct_reg = yes; then
1458   AC_DEFINE(HAVE_STRUCT_REG, 1,
1459             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1460 fi
1461
1462 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1463 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1464 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1465                  [#include <machine/reg.h>])
1466
1467 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1468 # Older amd64 Linux's don't have the fs_base and gs_base members of
1469 # `struct user_regs_struct'.
1470 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1471                  [], [], [#include <sys/user.h>])
1472
1473 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1474 AC_MSG_CHECKING(for PTRACE_GETREGS)
1475 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1476 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1477                 [PTRACE_GETREGS;],
1478                 [gdb_cv_have_ptrace_getregs=yes],
1479                 [gdb_cv_have_ptrace_getregs=no])])
1480 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1481 if test $gdb_cv_have_ptrace_getregs = yes; then
1482   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1483   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1484 fi
1485
1486 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1487 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1488 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1489 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1490                 [PTRACE_GETFPXREGS;],
1491                 [gdb_cv_have_ptrace_getfpxregs=yes],
1492                 [gdb_cv_have_ptrace_getfpxregs=no])])
1493 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1494 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1495   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1496   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1497 fi
1498
1499 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1500 AC_MSG_CHECKING(for PT_GETDBREGS)
1501 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1502 [AC_TRY_COMPILE([#include <sys/types.h>
1503 #include <sys/ptrace.h>],
1504                 [PT_GETDBREGS;],
1505                 [gdb_cv_have_pt_getdbregs=yes],
1506                 [gdb_cv_have_pt_getdbregs=no])])
1507 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1508 if test $gdb_cv_have_pt_getdbregs = yes; then
1509   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1510   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1511 fi
1512
1513 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1514 AC_MSG_CHECKING(for PT_GETXMMREGS)
1515 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1516 [AC_TRY_COMPILE([#include <sys/types.h>
1517 #include <sys/ptrace.h>],
1518                 [PT_GETXMMREGS;],
1519                 [gdb_cv_have_pt_getxmmregs=yes],
1520                 [gdb_cv_have_pt_getxmmregs=no])])
1521 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1522 if test $gdb_cv_have_pt_getxmmregs = yes; then
1523   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1524   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1525 fi
1526
1527 # Detect which type of /proc is in use, such as for Solaris.
1528
1529 if test "${target}" = "${host}"; then
1530   case "${host}" in
1531   *-*-sysv4.2* | *-*-sysv5* )
1532       AC_DEFINE(NEW_PROC_API, 1,
1533       [Define if you want to use new multi-fd /proc interface.])
1534       ;;
1535   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1536       AC_DEFINE(NEW_PROC_API, 1,
1537       [Define if you want to use new multi-fd /proc interface.])
1538       ;;
1539   mips-sgi-irix5*)
1540       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1541       AC_DEFINE([_KMEMUSER], 1,
1542       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1543        around a <sys/proc.h> problem on IRIX 5.])
1544       ;;
1545   esac
1546 fi
1547
1548 if test "$ac_cv_header_sys_procfs_h" = yes; then
1549   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1550   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1551   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1552   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1553   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1554   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1555   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1556   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1557   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1558   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1559   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1560
1561
1562   dnl Check for broken prfpregset_t type
1563
1564   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1565   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1566   dnl instead of the struct itself).  We detect this here, and work
1567   dnl around it in gdb_proc_service.h.
1568
1569   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1570     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1571     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1572       [AC_TRY_RUN([#include <sys/procfs.h>
1573        int main ()
1574        {
1575          if (sizeof (prfpregset_t) == sizeof (void *))
1576            return 1;
1577          return 0;
1578        }],
1579        gdb_cv_prfpregset_t_broken=no,
1580        gdb_cv_prfpregset_t_broken=yes,
1581        gdb_cv_prfpregset_t_broken=yes)])
1582     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1583     if test $gdb_cv_prfpregset_t_broken = yes; then
1584       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1585       [Define if the prfpregset_t type is broken.])
1586     fi
1587   fi
1588 fi
1589
1590 # Check if the compiler supports the `long long' type.
1591
1592 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1593                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1594 [[extern long long foo;]],
1595 [[switch (foo & 2) { case 0: return 1; }]])],
1596                                   gdb_cv_c_long_long=yes,
1597                                   gdb_cv_c_long_long=no)])
1598 if test $gdb_cv_c_long_long != yes; then
1599   # libdecnumber requires long long.
1600   AC_MSG_ERROR([Compiler must support long long for GDB.])
1601 fi
1602
1603 # Check if the compiler and runtime support printing long longs.
1604
1605 AC_CACHE_CHECK([for long long support in printf],
1606                gdb_cv_printf_has_long_long,
1607                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1608 [[char buf[32];
1609   long long l = 0;
1610   l = (l << 16) + 0x0123;
1611   l = (l << 16) + 0x4567;
1612   l = (l << 16) + 0x89ab;
1613   l = (l << 16) + 0xcdef;
1614   sprintf (buf, "0x%016llx", l);
1615   return (strcmp ("0x0123456789abcdef", buf));]])],
1616                               gdb_cv_printf_has_long_long=yes,
1617                               gdb_cv_printf_has_long_long=no,
1618                               gdb_cv_printf_has_long_long=no)])
1619 if test $gdb_cv_printf_has_long_long = yes; then
1620   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1621             [Define to 1 if the "%ll" format works to print long longs.])
1622 fi
1623
1624 # Check if the compiler and runtime support printing decfloats.
1625
1626 AC_CACHE_CHECK([for decfloat support in printf],
1627                gdb_cv_printf_has_decfloat,
1628                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1629 [[char buf[64];
1630   _Decimal32 d32 = 1.2345df;
1631   _Decimal64 d64 = 1.2345dd;
1632   _Decimal128 d128 = 1.2345dl;
1633   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1634   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1635                               gdb_cv_printf_has_decfloat=yes,
1636                               gdb_cv_printf_has_decfloat=no,
1637                               gdb_cv_printf_has_decfloat=no)])
1638 if test $gdb_cv_printf_has_decfloat = yes; then
1639   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1640             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1641 fi
1642
1643 # Check if the compiler supports the `long double' type.  We can't use
1644 # AC_C_LONG_DOUBLE because that one does additional checks on the
1645 # constants defined in <float.h> that fail on some systems,
1646 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1647
1648 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1649                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1650                                   gdb_cv_c_long_double=yes,
1651                                   gdb_cv_c_long_double=no)])
1652 if test $gdb_cv_c_long_double = yes; then
1653   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1654            [Define to 1 if the compiler supports long double.])
1655 fi
1656
1657 # Check if the compiler and runtime support printing long doubles.
1658
1659 AC_CACHE_CHECK([for long double support in printf],
1660                gdb_cv_printf_has_long_double,
1661                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1662 [[char buf[16];
1663   long double f = 3.141592653;
1664   sprintf (buf, "%Lg", f);
1665   return (strncmp ("3.14159", buf, 7));]])],
1666                               gdb_cv_printf_has_long_double=yes,
1667                               gdb_cv_printf_has_long_double=no,
1668                               gdb_cv_printf_has_long_double=no)])
1669 if test $gdb_cv_printf_has_long_double = yes; then
1670   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1671             [Define to 1 if the "%Lg" format works to print long doubles.])
1672 fi
1673
1674 # Check if the compiler and runtime support scanning long doubles.
1675
1676 AC_CACHE_CHECK([for long double support in scanf],
1677                gdb_cv_scanf_has_long_double,
1678                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1679 [[#include <stdio.h>]],
1680 [[char *buf = "3.141592653";
1681   long double f = 0;
1682   sscanf (buf, "%Lg", &f);
1683   return !(f > 3.14159 && f < 3.14160);]])],
1684                               gdb_cv_scanf_has_long_double=yes,
1685                               gdb_cv_scanf_has_long_double=no,
1686                               gdb_cv_scanf_has_long_double=no)])
1687 if test $gdb_cv_scanf_has_long_double = yes; then
1688   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1689             [Define to 1 if the "%Lg" format works to scan long doubles.])
1690 fi
1691
1692 case ${host_os} in
1693 aix*)
1694   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1695     SAVE_LDFLAGS=$LDFLAGS
1696
1697     case $GCC in
1698     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1699     *) gdb_cv_bigtoc=-bbigtoc ;;
1700     esac
1701
1702     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1703     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1704     LDFLAGS="${SAVE_LDFLAGS}"
1705   ])
1706   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1707   ;;
1708 esac
1709
1710 AC_MSG_CHECKING(for the dynamic export flag)
1711 dynamic_list=false
1712 if test "${gdb_native}" = yes; then
1713    # The dynamically loaded libthread_db needs access to symbols in the gdb
1714    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1715    # may not be supported there.
1716    old_LDFLAGS="$LDFLAGS"
1717    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1718    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1719    LDFLAGS="$LDFLAGS $RDYNAMIC"
1720    if test "${have_libpython}" = no; then
1721      AC_TRY_LINK([], [], [dynamic_list=true])
1722    else
1723      # Workaround http://bugs.python.org/issue4434 where static
1724      # libpythonX.Y.a would get its symbols required for
1725      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1726      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1727      old_CFLAGS="$CFLAGS"
1728      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1729      old_LIBS="$LIBS"
1730      LIBS="$LIBS $PYTHON_LIBS"
1731      AC_RUN_IFELSE(
1732        AC_LANG_PROGRAM(
1733          [#include "]${have_libpython}[/Python.h"],
1734          [int err;
1735           Py_Initialize ();
1736           err = PyRun_SimpleString ("import itertools\n");
1737           Py_Finalize ();
1738           return err == 0 ? 0 : 1;]),
1739        [dynamic_list=true], [], [true])
1740      LIBS="$old_LIBS"
1741      CFLAGS="$old_CFLAGS"
1742    fi
1743    LDFLAGS="$old_LDFLAGS"
1744 fi
1745 if $dynamic_list; then
1746   found="-Wl,--dynamic-list"
1747   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1748 else
1749   found="-rdynamic"
1750   RDYNAMIC="-rdynamic"
1751 fi
1752 AC_SUBST(RDYNAMIC)
1753 AC_MSG_RESULT($found)
1754
1755 dnl For certain native configurations, we need to check whether thread
1756 dnl support can be built in or not.
1757 dnl
1758 dnl Note that we only want this if we are both native (host == target),
1759 dnl and not doing a canadian cross build (build == host).
1760
1761 if test ${build} = ${host} -a ${host} = ${target} ; then
1762    case ${host_os} in
1763    solaris*)
1764       # See if thread_db library is around for Solaris thread debugging.
1765       # Note that we must explicitly test for version 1 of the library
1766       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1767       # the same API.
1768       AC_MSG_CHECKING(for Solaris thread debugging library)
1769       if test -f /usr/lib/libthread_db.so.1 ; then
1770          AC_MSG_RESULT(yes)
1771          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1772          [Define if using Solaris thread debugging.])
1773          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1774          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1775          AC_CHECK_LIB(dl, dlopen)
1776          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1777          # Sun randomly tweaked the prototypes in <proc_service.h>
1778          # at one point.
1779          AC_MSG_CHECKING(if <proc_service.h> is old)
1780          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1781             AC_TRY_COMPILE([
1782                 #include <proc_service.h>
1783                 ps_err_e ps_pdwrite
1784                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1785             ],, gdb_cv_proc_service_is_old=no,
1786                 gdb_cv_proc_service_is_old=yes)
1787          ])
1788          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1789          if test $gdb_cv_proc_service_is_old = yes; then
1790             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1791             [Define if <proc_service.h> on solaris uses int instead of
1792              size_t, and assorted other type changes.])
1793          fi
1794       else
1795          AC_MSG_RESULT(no)
1796       fi
1797       ;;
1798    aix*)
1799       AC_MSG_CHECKING(for AiX thread debugging library)
1800       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1801                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1802                                    [#ifndef PTHDB_VERSION_3
1803                                     #error
1804                                     #endif],
1805                                    gdb_cv_have_aix_thread_debug=yes,
1806                                    gdb_cv_have_aix_thread_debug=no)])
1807       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1808       if test $gdb_cv_have_aix_thread_debug = yes; then
1809          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1810          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1811          LIBS="$LIBS -lpthdebug"
1812
1813          # Older versions of AIX do not provide the declaration for
1814          # the getthrds function (it appears that it was introduced
1815          # with AIX 6.x).
1816          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1817       fi
1818       ;;
1819    esac
1820    AC_SUBST(CONFIG_LDFLAGS)
1821 fi
1822
1823 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1824 dnl other error codes.
1825 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1826    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1827                   gdb_cv_thread_db_h_has_td_notalloc,
1828      AC_TRY_COMPILE(
1829        [#include <thread_db.h>],
1830        [int i = TD_NOTALLOC;],
1831        gdb_cv_thread_db_h_has_td_notalloc=yes,
1832        gdb_cv_thread_db_h_has_td_notalloc=no
1833      )
1834    )
1835    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1836                   gdb_cv_thread_db_h_has_td_version,
1837      AC_TRY_COMPILE(
1838        [#include <thread_db.h>],
1839        [int i = TD_VERSION;],
1840        gdb_cv_thread_db_h_has_td_version=yes,
1841        gdb_cv_thread_db_h_has_td_version=no
1842      )
1843    )
1844    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1845                   gdb_cv_thread_db_h_has_td_notls,
1846      AC_TRY_COMPILE(
1847        [#include <thread_db.h>],
1848        [int i = TD_NOTLS;],
1849        gdb_cv_thread_db_h_has_td_notls=yes,
1850        gdb_cv_thread_db_h_has_td_notls=no
1851      )
1852    )
1853 fi
1854 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1855   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1856             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1857 fi
1858 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1859   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1860             [Define if <thread_db.h> has the TD_VERSION error code.])
1861 fi
1862 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1863   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1864             [Define if <thread_db.h> has the TD_NOTLS error code.])
1865 fi
1866
1867 dnl See if we have a sys/syscall header file that has __NR_tkill.
1868 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1869    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1870                   gdb_cv_sys_syscall_h_has_tkill,
1871      AC_TRY_COMPILE(
1872        [#include <sys/syscall.h>],
1873        [int i = __NR_tkill;],
1874        gdb_cv_sys_syscall_h_has_tkill=yes,
1875        gdb_cv_sys_syscall_h_has_tkill=no
1876      )
1877    )
1878 fi
1879 dnl See if we can issue tkill syscall.
1880 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1881   AC_CHECK_FUNC(syscall,
1882     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1883   )
1884 fi
1885
1886 dnl Check if we can disable the virtual address space randomization.
1887 dnl The functionality of setarch -R.
1888 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1889 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1890 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1891 #       define ADDR_NO_RANDOMIZE 0x0040000
1892 #      endif
1893        /* Test the flag could be set and stays set.  */
1894        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1895        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1896            return 1])])
1897 AC_RUN_IFELSE([PERSONALITY_TEST],
1898               [have_personality=true],
1899               [have_personality=false],
1900               [AC_LINK_IFELSE([PERSONALITY_TEST],
1901                               [have_personality=true],
1902                               [have_personality=false])])
1903 if $have_personality
1904 then
1905     AC_DEFINE([HAVE_PERSONALITY], 1,
1906               [Define if you support the personality syscall.])
1907 fi
1908
1909 dnl Set the host's .gdbinit filename.
1910 case $host_os in
1911   go32* | *djgpp*)
1912     gdbinit=gdb.ini
1913     ;;
1914   *)
1915     gdbinit=.gdbinit
1916     ;;
1917 esac
1918 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1919
1920 dnl Handle optional features that can be enabled.
1921
1922 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1923 # except that the argument to --with-sysroot is optional.
1924 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1925 if test "x$with_sysroot" = xyes; then
1926   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1927 fi
1928 AC_ARG_WITH(sysroot,
1929   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1930                  [search for usr/lib et al within DIR]),
1931   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1932 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1933               [search for usr/lib et al within DIR])
1934 AC_SUBST(TARGET_SYSTEM_ROOT)
1935 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1936
1937 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1938     [automatically load a system-wide gdbinit file],
1939     [])
1940
1941 AC_ARG_ENABLE(werror,
1942   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1943   [case "${enableval}" in
1944      yes | y) ERROR_ON_WARNING="yes" ;;
1945      no | n)  ERROR_ON_WARNING="no" ;;
1946      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1947    esac])
1948
1949 # Enable -Werror by default when using gcc.  Turn it off for releases.
1950 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1951     ERROR_ON_WARNING=yes
1952 fi
1953
1954 WERROR_CFLAGS=""
1955 if test "${ERROR_ON_WARNING}" = yes ; then
1956     WERROR_CFLAGS="-Werror"
1957 fi
1958
1959 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1960 -Wpointer-sign \
1961 -Wno-unused -Wunused-value -Wunused-function \
1962 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1963 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1964 -Wold-style-declaration -Wold-style-definition"
1965
1966 # Enable -Wno-format by default when using gcc on mingw since many
1967 # GCC versions complain about %I64.
1968 case "${host}" in
1969   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1970   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1971 esac
1972
1973 AC_ARG_ENABLE(build-warnings,
1974 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1975 [case "${enableval}" in
1976   yes)  ;;
1977   no)   build_warnings="-w";;
1978   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1979         build_warnings="${build_warnings} ${t}";;
1980   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1981         build_warnings="${t} ${build_warnings}";;
1982   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1983 esac
1984 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1985   echo "Setting compiler warning flags = $build_warnings" 6>&1
1986 fi])dnl
1987 AC_ARG_ENABLE(gdb-build-warnings,
1988 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1989 [case "${enableval}" in
1990   yes)  ;;
1991   no)   build_warnings="-w";;
1992   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1993         build_warnings="${build_warnings} ${t}";;
1994   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1995         build_warnings="${t} ${build_warnings}";;
1996   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1997 esac
1998 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1999   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
2000 fi])dnl
2001 WARN_CFLAGS=""
2002 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2003 then
2004     AC_MSG_CHECKING(compiler warning flags)
2005     # Separate out the -Werror flag as some files just cannot be
2006     # compiled with it enabled.
2007     for w in ${build_warnings}; do
2008         case $w in
2009         -Werr*) WERROR_CFLAGS=-Werror ;;
2010         *) # Check that GCC accepts it
2011             saved_CFLAGS="$CFLAGS"
2012             CFLAGS="$CFLAGS $w"
2013             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2014             CFLAGS="$saved_CFLAGS"
2015         esac
2016     done
2017     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2018 fi
2019 AC_SUBST(WARN_CFLAGS)
2020 AC_SUBST(WERROR_CFLAGS)
2021
2022 # In the Cygwin environment, we need some additional flags.
2023 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2024 [AC_EGREP_CPP(^lose$, [
2025 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2026 lose
2027 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2028
2029
2030 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2031 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2032 case ${host} in
2033   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2034   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2035   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2036 esac
2037 AC_SUBST(SER_HARDWIRE)
2038
2039 # libreadline needs libuser32.a in a cygwin environment
2040 WIN32LIBS=
2041 if test x$gdb_cv_os_cygwin = xyes; then
2042     WIN32LIBS="-luser32"
2043     case "${target}" in
2044         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2045         ;;
2046     esac
2047 fi
2048
2049 # The ser-tcp.c module requires sockets.
2050 case ${host} in
2051   *mingw32*)
2052     AC_DEFINE(USE_WIN32API, 1,
2053               [Define if we should use the Windows API, instead of the
2054                POSIX API.  On Windows, we use the Windows API when
2055                building for MinGW, but the POSIX API when building
2056                for Cygwin.])
2057     WIN32LIBS="$WIN32LIBS -lws2_32"
2058     ;;
2059 esac
2060 AC_SUBST(WIN32LIBS)
2061
2062 # Add ELF support to GDB, but only if BFD includes ELF support.
2063 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2064                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2065 if test $gdb_cv_var_elf = yes; then
2066   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2067   AC_DEFINE(HAVE_ELF, 1,
2068             [Define if ELF support should be included.])
2069   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2070   if test "$plugins" = "yes"; then
2071     AC_SEARCH_LIBS(dlopen, dl)
2072   fi
2073 fi
2074
2075 # Add macho support to GDB, but only if BFD includes it.
2076 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2077                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2078 if test $gdb_cv_var_macho = yes; then
2079   CONFIG_OBS="$CONFIG_OBS machoread.o"
2080 fi
2081
2082 # Add SOM support to GDB, but only if BFD includes it.
2083 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2084                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2085 if test $gdb_cv_var_som = yes; then
2086   CONFIG_OBS="$CONFIG_OBS somread.o"
2087 fi
2088
2089 # Add any host-specific objects to GDB.
2090 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2091
2092 # If building on ELF, look for lzma support for embedded compressed debug info.
2093 if test $gdb_cv_var_elf = yes; then
2094   AC_ARG_WITH(lzma,
2095     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2096     [], [with_lzma=auto])
2097   AC_MSG_CHECKING([whether to use lzma])
2098   AC_MSG_RESULT([$with_lzma])
2099
2100   if test "${with_lzma}" != no; then
2101     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2102                           [lzma_index_iter iter;
2103                            lzma_index_iter_init (&iter, 0);
2104                            lzma_mf_is_supported (LZMA_MF_HC3);])
2105     if test "$HAVE_LIBLZMA" != yes; then
2106       if test "$with_lzma" = yes; then
2107         AC_MSG_ERROR([missing liblzma for --with-lzma])
2108       fi
2109     fi
2110   fi
2111 fi
2112
2113 LIBGUI="../libgui/src/libgui.a"
2114 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2115 AC_SUBST(LIBGUI)
2116 AC_SUBST(GUI_CFLAGS_X)
2117
2118 WIN32LDAPP=
2119 AC_SUBST(WIN32LIBS)
2120 AC_SUBST(WIN32LDAPP)
2121
2122 case "${host}" in
2123 *-*-cygwin* | *-*-mingw* )
2124     configdir="win"
2125     ;;
2126 *)
2127     configdir="unix"
2128     ;;
2129 esac
2130
2131 GDBTKLIBS=
2132 if test "${enable_gdbtk}" = "yes"; then
2133
2134     # Gdbtk must have an absolute path to srcdir in order to run
2135     # properly when not installed.
2136     here=`pwd`
2137     cd ${srcdir}
2138     GDBTK_SRC_DIR=`pwd`
2139     cd $here
2140
2141     SC_PATH_TCLCONFIG
2142
2143     # If $no_tk is nonempty, then we can't do Tk, and there is no
2144     # point to doing Tcl.
2145     SC_PATH_TKCONFIG
2146
2147     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2148         SC_LOAD_TCLCONFIG
2149
2150         # Check for in-tree tcl
2151         here=`pwd`
2152         cd ${srcdir}/..
2153         topdir=`pwd`
2154         cd ${here}
2155
2156         intree="no"
2157         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2158           intree="yes"
2159         fi
2160
2161         # Find Tcl private headers
2162         if test x"${intree}" = xno; then
2163           CY_AC_TCL_PRIVATE_HEADERS
2164           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2165           TCL_LIBRARY="${TCL_LIB_SPEC}"
2166           TCL_DEPS=""
2167         else
2168           # If building tcl in the same src tree, private headers
2169           # are not needed, but we need to be sure to use the right
2170           # headers library
2171           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2172           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2173           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2174         fi
2175         AC_SUBST(TCL_INCLUDE)
2176         AC_SUBST(TCL_LIBRARY)
2177         AC_SUBST(TCL_DEPS)
2178
2179         SC_LOAD_TKCONFIG
2180
2181         # Check for in-tree Tk
2182         intree="no"
2183         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2184           intree="yes"
2185         fi
2186
2187         # Find Tk private headers
2188         if test x"${intree}" = xno; then
2189           CY_AC_TK_PRIVATE_HEADERS
2190           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2191           TK_LIBRARY=${TK_LIB_SPEC}
2192           TK_DEPS=""
2193         else
2194           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2195           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2196           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2197         fi
2198         AC_SUBST(TK_INCLUDE)
2199         AC_SUBST(TK_LIBRARY)
2200         AC_SUBST(TK_DEPS)
2201         AC_SUBST(TK_XINCLUDES)
2202
2203         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2204
2205         # Include some libraries that Tcl and Tk want.
2206         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2207         # Yes, the ordering seems wrong here.  But it isn't.
2208         # TK_LIBS is the list of libraries that need to be linked
2209         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2210         # were in LIBS then any link tests after this point would
2211         # try to include things like `$(LIBGUI)', which wouldn't work.
2212         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2213
2214         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2215         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2216         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2217         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2218         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2219         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2220         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2221
2222         if test x$gdb_cv_os_cygwin = xyes; then
2223           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2224           WIN32LDAPP="-Wl,--subsystem,console"
2225           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2226         fi
2227
2228         AC_CONFIG_SUBDIRS(gdbtk)
2229     fi
2230 fi
2231
2232 AC_SUBST(X_CFLAGS)
2233 AC_SUBST(X_LDFLAGS)
2234 AC_SUBST(X_LIBS)
2235 AC_SUBST(GDBTKLIBS)
2236 AC_SUBST(GDBTK_CFLAGS)
2237 AC_SUBST(GDBTK_SRC_DIR)
2238
2239 AC_PATH_X
2240
2241 # Unlike the sim directory, whether a simulator is linked is controlled by
2242 # presence of a gdb_sim definition in the target configure.tgt entry.
2243 # This code just checks for a few cases where we'd like to ignore those
2244 # definitions, even when they're present in the '.mt' file.  These cases
2245 # are when --disable-sim is specified, or if the simulator directory is
2246 # not part of the source tree.
2247 #
2248 AC_ARG_ENABLE(sim,
2249 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2250 [echo "enable_sim = $enable_sim";
2251  echo "enableval = ${enableval}";
2252  case "${enableval}" in
2253   yes) ignore_sim=false ;;
2254   no)  ignore_sim=true ;;
2255   *)   ignore_sim=false ;;
2256  esac],
2257 [ignore_sim=false])
2258
2259 if test ! -d "${srcdir}/../sim"; then
2260   ignore_sim=true
2261 fi
2262
2263 SIM=
2264 SIM_OBS=
2265 if test "${ignore_sim}" = "false"; then
2266   if test x"${gdb_sim}" != x ; then
2267     SIM="${gdb_sim}"
2268     SIM_OBS="remote-sim.o"
2269     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2270   fi
2271 fi
2272 AC_SUBST(SIM)
2273 AC_SUBST(SIM_OBS)
2274
2275 AC_SUBST(ENABLE_CFLAGS)
2276 AC_SUBST(PROFILE_CFLAGS)
2277
2278 AC_SUBST(CONFIG_OBS)
2279 AC_SUBST(CONFIG_DEPS)
2280 AC_SUBST(CONFIG_SRCS)
2281 AC_SUBST(CONFIG_ALL)
2282 AC_SUBST(CONFIG_CLEAN)
2283 AC_SUBST(CONFIG_INSTALL)
2284 AC_SUBST(CONFIG_UNINSTALL)
2285
2286 # List of host floatformats.
2287 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2288 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2289 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2290
2291 # target_subdir is used by the testsuite to find the target libraries.
2292 target_subdir=
2293 if test "${host}" != "${target}"; then
2294     target_subdir="${target_alias}/"
2295 fi
2296 AC_SUBST(target_subdir)
2297
2298 frags=
2299 if test "${gdb_native}" = "yes"; then
2300   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2301   if test ! -f ${host_makefile_frag}; then
2302     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2303   fi
2304   frags="$frags $host_makefile_frag"
2305 else
2306   host_makefile_frag=/dev/null
2307 fi
2308
2309 AC_SUBST_FILE(host_makefile_frag)
2310 AC_SUBST(frags)
2311
2312 changequote(,)dnl
2313 if test "${gdb_native}" = "yes"; then
2314 # We pick this up from the host configuration file (.mh) because we
2315 # do not have a native configuration Makefile fragment.
2316 nativefile=`sed -n '
2317 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2318 ' ${host_makefile_frag}`
2319 fi
2320 changequote([,])
2321
2322 if test x"${gdb_osabi}" != x ; then
2323     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2324                        [Define to the default OS ABI for this configuration.])
2325 fi
2326
2327 # Enable multi-ice-gdb-server.
2328 AC_ARG_ENABLE(multi-ice,
2329 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2330   [case $enableval in
2331     yes | no)
2332       ;;
2333     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2334   esac])
2335 if test "x$enable_multi_ice" = xyes; then
2336    AC_CONFIG_SUBDIRS(multi-ice)
2337 fi
2338
2339 AC_ARG_ENABLE(gdbserver,
2340 AS_HELP_STRING([--enable-gdbserver],
2341                [automatically build gdbserver (yes/no/auto, default is auto)]),
2342 [case "${enableval}" in
2343   yes| no|auto) ;;
2344   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2345 esac],[enable_gdbserver=auto])
2346
2347 # We only build gdbserver automatically in a native configuration, and
2348 # only if the user did not explicitly disable its build.
2349 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2350   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2351   if test "x$build_gdbserver" = xyes; then
2352     AC_MSG_RESULT(yes)
2353     AC_CONFIG_SUBDIRS(gdbserver)
2354     gdbserver_build_enabled=yes
2355   else
2356     AC_MSG_RESULT(no)
2357   fi
2358 fi
2359
2360 # If the user explicitly request the gdbserver to be built, verify that
2361 # we were in fact able to enable it.
2362 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2363   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2364 fi
2365
2366 # Check for babeltrace and babeltrace-ctf
2367 AC_ARG_WITH(babeltrace,
2368   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2369   [], [with_babeltrace=auto])
2370 AC_MSG_CHECKING([whether to use babeltrace])
2371 AC_MSG_RESULT([$with_babeltrace])
2372
2373 if test "x$with_babeltrace" = "xno"; then
2374   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2375 else
2376   # Append -Werror to CFLAGS so that configure can catch the warning
2377   # "assignment from incompatible pointer type", which is related to
2378   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2379   # in GDB, while babeltrace 1.0.3 is broken.
2380   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2381   # safe to save and restore CFLAGS here.
2382   saved_CFLAGS=$CFLAGS
2383   CFLAGS="$CFLAGS -Werror"
2384   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2385                         [#include <babeltrace/babeltrace.h>
2386                          #include <babeltrace/ctf/events.h>
2387                          #include <babeltrace/ctf/iterator.h>],
2388                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2389                         struct bt_ctf_event *event = NULL;
2390                         const struct bt_definition *scope;
2391
2392                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2393                         scope = bt_ctf_get_top_level_scope (event,
2394                                                            BT_STREAM_EVENT_HEADER);
2395                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2396                         ])
2397   CFLAGS=$saved_CFLAGS
2398
2399   if test "$HAVE_LIBBABELTRACE" != yes; then
2400      if test "$with_babeltrace" = yes; then
2401        AC_MSG_ERROR([babeltrace is missing or unusable])
2402      else
2403        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2404      fi
2405   fi
2406 fi
2407
2408 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2409 # to an empty version.
2410
2411 files=
2412 links=
2413
2414 rm -f nm.h
2415 if test "${nativefile}" != ""; then
2416     case "${nativefile}" in
2417       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2418       * ) GDB_NM_FILE="${nativefile}"
2419     esac
2420     files="${files} ${GDB_NM_FILE}"
2421     links="${links} nm.h"
2422     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2423 fi
2424 AC_SUBST(GDB_NM_FILE)
2425
2426 AC_LINK_FILES($files, $links)
2427
2428 dnl Check for exe extension set on certain hosts (e.g. Win32)
2429 AC_EXEEXT
2430
2431 dnl  Detect the character set used by this host.
2432 dnl  At the moment, we just assume it's UTF-8.
2433 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2434           [Define to be a string naming the default host character set.])
2435
2436 # Undo the $ec_script escaping suitable for Makefile.
2437 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2438 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2439 if test "x$GDB_TRANSFORM_NAME" = x; then
2440   GDB_TRANSFORM_NAME=gdb
2441 fi
2442 AC_SUBST(GDB_TRANSFORM_NAME)
2443 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2444 if test "x$GCORE_TRANSFORM_NAME" = x; then
2445   GCORE_TRANSFORM_NAME=gcore
2446 fi
2447 AC_SUBST(GCORE_TRANSFORM_NAME)
2448 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2449
2450 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2451 [
2452 case x$CONFIG_HEADERS in
2453 xconfig.h:config.in)
2454 echo > stamp-h ;;
2455 esac
2456 ])
2457
2458 exit 0