gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2013 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Provide more thorough testing by -lmcheck.
  27 # Set it to 'true' for development snapshots, 'false' for releases or
  28 # pre-releases.
  29 development=true
  30
  31 AC_PROG_CC
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # Dependency checking.
  41 ZW_CREATE_DEPDIR
  42 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  43
  44 # Check for the 'make' the user wants to use.
  45 AC_CHECK_PROGS(MAKE, make)
  46 MAKE_IS_GNU=
  47 case "`$MAKE --version 2>&1 | sed 1q`" in
  48   *GNU*)
  49     MAKE_IS_GNU=yes
  50     ;;
  51 esac
  52 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  53 AC_PROG_MAKE_SET
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  60
  61 dnl List of object files and targets accumulated by configure.
  62
  63 CONFIG_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 ENABLE_CFLAGS=
  67
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 dnl Set up for gettext.
  74 ZW_GNU_GETTEXT_SISTER_DIR
  75
  76 localedir='${datadir}/locale'
  77 AC_SUBST(localedir)
  78
  79 if test x"$USE_NLS" = xyes; then
  80    CONFIG_ALL="$CONFIG_ALL all-po"
  81    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  82    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  83    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  84 fi
  85
  86 GNULIB=build-gnulib/import
  87
  88 # For Makefile dependencies.
  89 GNULIB_STDINT_H=
  90 if test x"$STDINT_H" != x; then
  91   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  92 fi
  93 AC_SUBST(GNULIB_STDINT_H)
  94
  95 PACKAGE=gdb
  96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  97 AC_SUBST(PACKAGE)
  98
  99 # We never need to detect it in this sub-configure.
 100 # But preserve it for config.status --recheck.
 101 AC_ARG_VAR(MAKEINFO,
 102   [Parent configure detects if it is of sufficient version.])
 103 AC_ARG_VAR(MAKEINFOFLAGS,
 104   [Parameters for MAKEINFO.])
 105
 106 MAKEINFO_EXTRA_FLAGS=""
 107 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 108   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 109   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 110     gdb_cv_have_makeinfo_click=yes
 111   else
 112     gdb_cv_have_makeinfo_click=no
 113   fi])
 114 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 115   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 116 fi
 117 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 118
 119 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 120     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 121     [${libdir}/debug])
 122
 123 # We can't pass paths as command line arguments.
 124 # Mingw32 tries to be clever and will convert the paths for us.
 125 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 126 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 127 # This breaks GDB's relocatable path conversions since paths passed in
 128 # config.h would not get so translated, the path prefixes no longer match.
 129 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 130
 131 # GDB's datadir relocation
 132
 133 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 134     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 135     [${datadir}/gdb])
 136
 137 AC_ARG_WITH(relocated-sources,
 138 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 139 [reloc_srcdir="${withval}"
 140  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 141               [Relocated directory for source files. ])
 142 ])
 143
 144 AC_MSG_CHECKING([for default auto-load directory])
 145 AC_ARG_WITH(auto-load-dir,
 146 AS_HELP_STRING([--with-auto-load-dir=PATH],
 147   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 148   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 149 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 151               [Directories from which to load auto-loaded scripts.])
 152 AC_MSG_RESULT([$with_auto_load_dir])
 153
 154 AC_MSG_CHECKING([for default auto-load safe-path])
 155 AC_ARG_WITH(auto-load-safe-path,
 156 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 157   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 158 AS_HELP_STRING([--without-auto-load-safe-path],
 159                [do not restrict auto-loaded files locations]),
 160     [if test "$with_auto_load_safe_path" = "no"; then
 161      with_auto_load_safe_path="/"
 162      fi],
 163 [with_auto_load_safe_path="$with_auto_load_dir"])
 164 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 165 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 166               [Directories safe to hold auto-loaded files.])
 167 AC_MSG_RESULT([$with_auto_load_safe_path])
 168
 169 AC_CONFIG_SUBDIRS(testsuite)
 170
 171 # Check whether to support alternative target configurations
 172 AC_ARG_ENABLE(targets,
 173 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 174 [case "${enableval}" in
 175   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 176             ;;
 177   no)       enable_targets= ;;
 178   *)        enable_targets=$enableval ;;
 179 esac])
 180
 181 # Check whether to enable 64-bit support on 32-bit hosts
 182 AC_ARG_ENABLE(64-bit-bfd,
 183 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 184 [case "${enableval}" in
 185   yes)  want64=true  ;;
 186   no)   want64=false ;;
 187   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 188 esac],[want64=false])dnl
 189
 190 # Provide defaults for some variables set by the per-host and per-target
 191 # configuration.
 192 gdb_host_obs=posix-hdep.o
 193
 194 if test "${target}" = "${host}"; then
 195   gdb_native=yes
 196 else
 197   gdb_native=no
 198 fi
 199
 200 . $srcdir/configure.host
 201
 202 # Accumulate some settings from configure.tgt over all enabled targets
 203
 204 TARGET_OBS=
 205 all_targets=
 206 HAVE_NATIVE_GCORE_TARGET=
 207
 208 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 209 do
 210   if test "$targ_alias" = "all"; then
 211     all_targets=true
 212   else
 213     # Canonicalize the secondary target names.
 214     result=`$ac_config_sub $targ_alias 2>/dev/null`
 215     if test -n "$result"; then
 216         targ=$result
 217     else
 218         targ=$targ_alias
 219     fi
 220
 221     . ${srcdir}/configure.tgt
 222
 223     AS_IF([test -z "${gdb_target_obs}"],
 224       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 225
 226     # Target-specific object files
 227     for i in ${gdb_target_obs}; do
 228         case " $TARGET_OBS " in
 229         *" ${i} "*) ;;
 230         *)
 231           TARGET_OBS="$TARGET_OBS ${i}"
 232           ;;
 233         esac
 234     done
 235
 236     # Check whether this target needs 64-bit CORE_ADDR
 237     if test x${want64} = xfalse; then
 238       . ${srcdir}/../bfd/config.bfd
 239     fi
 240
 241     # Check whether this target is native and supports gcore.
 242     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 243        && $gdb_have_gcore; then
 244       HAVE_NATIVE_GCORE_TARGET=1
 245     fi
 246   fi
 247 done
 248
 249 if test x${all_targets} = xtrue; then
 250
 251   # We want all 64-bit targets if we either:
 252   #  - run on a 64-bit host  or
 253   #  - already require 64-bit support for some other target  or
 254   #  - the --enable-64-bit-bfd option was supplied
 255   # Otherwise we only support all 32-bit targets.
 256   #
 257   # NOTE: This test must be in sync with the corresponding
 258   #       tests in BFD!
 259
 260   if test x${want64} = xfalse; then
 261     AC_CHECK_SIZEOF(long)
 262     if test "x${ac_cv_sizeof_long}" = "x8"; then
 263       want64=true
 264     fi
 265   fi
 266   if test x${want64} = xtrue; then
 267     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 268   else
 269     TARGET_OBS='$(ALL_TARGET_OBS)'
 270   fi
 271 fi
 272
 273 AC_SUBST(TARGET_OBS)
 274 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 275
 276 # For other settings, only the main target counts.
 277 gdb_sim=
 278 gdb_osabi=
 279 build_gdbserver=
 280 targ=$target; . ${srcdir}/configure.tgt
 281
 282 # Fetch the default architecture and default target vector from BFD.
 283 targ=$target; . $srcdir/../bfd/config.bfd
 284
 285 # We only want the first architecture, so strip off the others if
 286 # there is more than one.
 287 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 288
 289 if test "x$targ_archs" != x; then
 290   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 291     [Define to BFD's default architecture. ])
 292 fi
 293 if test "x$targ_defvec" != x; then
 294   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 295     [Define to BFD's default target vector. ])
 296 fi
 297
 298 # The CLI cannot be disabled yet, but may be in the future.
 299
 300 # Enable CLI.
 301 AC_ARG_ENABLE(gdbcli,
 302 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 303   [case $enableval in
 304     yes)
 305       ;;
 306     no)
 307       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 308     *)
 309       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 310   esac],
 311   [enable_gdbcli=yes])
 312 if test x"$enable_gdbcli" = xyes; then
 313   if test -d $srcdir/cli; then
 314     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 315     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 316     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 317     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 318   fi
 319 fi
 320
 321 # Enable MI.
 322 AC_ARG_ENABLE(gdbmi,
 323 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 324   [case $enableval in
 325     yes | no)
 326       ;;
 327     *)
 328       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 329   esac],
 330   [enable_gdbmi=yes])
 331 if test x"$enable_gdbmi" = xyes; then
 332   if test -d $srcdir/mi; then
 333     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 334     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 335     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 336     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 337   fi
 338 fi
 339
 340 # Enable TUI.
 341 AC_ARG_ENABLE(tui,
 342 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 343   [case $enableval in
 344     yes | no | auto)
 345       ;;
 346     *)
 347       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 348   esac],enable_tui=auto)
 349
 350 # Enable gdbtk.
 351 AC_ARG_ENABLE(gdbtk,
 352 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 353   [case $enableval in
 354     yes | no)
 355       ;;
 356     *)
 357       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 358   esac],
 359   [if test -d $srcdir/gdbtk; then
 360     enable_gdbtk=yes
 361   else
 362     enable_gdbtk=no
 363   fi])
 364 # We unconditionally disable gdbtk tests on selected platforms.
 365 case $host_os in
 366   go32* | windows*)
 367     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 368     enable_gdbtk=no ;;
 369 esac
 370
 371 # Libunwind support for ia64.
 372
 373 AC_ARG_WITH(libunwind-ia64,
 374 AS_HELP_STRING([--with-libunwind-ia64],
 375                [use libunwind frame unwinding for ia64 targets]),,
 376             [with_libunwind_ia64=auto])
 377
 378 # Backward compatibility option.
 379 if test "${with_libunwind+set}" = set; then
 380   if test x"$with_libunwind_ia64" != xauto; then
 381     AC_MSG_ERROR(
 382       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 383   fi
 384   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 385   with_libunwind_ia64="$with_libunwind"
 386 fi
 387
 388 case "$with_libunwind_ia64" in
 389   yes | no)
 390     ;;
 391   auto)
 392     AC_CHECK_HEADERS(libunwind-ia64.h)
 393     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 394     ;;
 395   *)
 396     AC_MSG_ERROR(
 397       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 398     ;;
 399 esac
 400
 401 if test x"$with_libunwind_ia64" = xyes; then
 402   AC_CHECK_HEADERS(libunwind-ia64.h)
 403   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 404     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 405   fi
 406   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 407   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 408   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 409 fi
 410
 411 opt_curses=no
 412 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 413
 414 prefer_curses=no
 415 if test "$opt_curses" = "yes"; then
 416   prefer_curses=yes
 417 fi
 418
 419 # Profiling support.
 420 AC_ARG_ENABLE(profiling,
 421 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 422   [case $enableval in
 423     yes | no)
 424       ;;
 425     *)
 426       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 427   esac],
 428  [enable_profiling=no])
 429
 430 AC_CHECK_FUNCS(monstartup _mcleanup)
 431 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 432 [AC_TRY_LINK(
 433 [#include <stdlib.h>
 434 extern char _etext;
 435 ],
 436 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 437 if test $ac_cv_var__etext = yes; then
 438   AC_DEFINE(HAVE__ETEXT, 1,
 439             [Define to 1 if your system has the _etext variable. ])
 440 fi
 441 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 442 [AC_TRY_LINK(
 443 [#include <stdlib.h>
 444 extern char etext;
 445 ],
 446 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 447 if test $ac_cv_var_etext = yes; then
 448   AC_DEFINE(HAVE_ETEXT, 1,
 449             [Define to 1 if your system has the etext variable. ])
 450 fi
 451 if test "$enable_profiling" = yes ; then
 452   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 453     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 454   fi
 455   PROFILE_CFLAGS=-pg
 456   OLD_CFLAGS="$CFLAGS"
 457   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 458
 459   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 460     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 461      ac_cv_cc_supports_pg=no)])
 462
 463   if test $ac_cv_cc_supports_pg = no; then
 464     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 465   fi
 466
 467   CFLAGS="$OLD_CFLAGS"
 468 fi
 469
 470 ACX_PKGVERSION([GDB])
 471 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 472 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 473 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 474
 475 # --------------------- #
 476 # Checks for programs.  #
 477 # --------------------- #
 478
 479 AC_PROG_AWK
 480 AC_PROG_INSTALL
 481 AC_PROG_LN_S
 482 AC_PROG_RANLIB
 483 AC_PROG_YACC
 484
 485 AC_CHECK_TOOL(AR, ar)
 486 AC_CHECK_TOOL(DLLTOOL, dlltool)
 487 AC_CHECK_TOOL(WINDRES, windres)
 488
 489 # Needed for GNU/Hurd.
 490 AC_CHECK_TOOL(MIG, mig)
 491
 492 # ---------------------- #
 493 # Checks for libraries.  #
 494 # ---------------------- #
 495
 496 # We might need to link with -lm; most simulators need it.
 497 AC_CHECK_LIB(m, main)
 498
 499 # We need to link with -lw to get `wctype' on Solaris before Solaris
 500 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 501 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 502 # is known to have this problem).  Therefore we avoid libw if we can.
 503 AC_CHECK_FUNC(wctype, [],
 504   [AC_CHECK_LIB(w, wctype)])
 505
 506 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 507 AC_SEARCH_LIBS(gethostbyname, nsl)
 508
 509 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 510 AC_SEARCH_LIBS(socketpair, socket)
 511
 512 # Link in zlib if we can.  This allows us to read compressed debug sections.
 513 AM_ZLIB
 514
 515 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 516 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 517
 518 AM_ICONV
 519
 520 # GDB may fork/exec the iconv program to get the list of supported character
 521 # sets.  Allow the user to specify where to find it.
 522 # There are several factors affecting the choice of option name:
 523 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 524 #   the build-time location of libiconv files.
 525 # - The program we need to find is iconv, which comes with glibc.  The user
 526 #   doesn't necessarily have libiconv installed.  Therefore naming this
 527 #   --with-libiconv-foo feels wrong.
 528 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 529 #   defined to work on directories not files (though it really doesn't know
 530 #   the difference).
 531 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 532 #   with --with-libiconv-prefix.
 533 # Putting these together is why the option name is --with-iconv-bin.
 534
 535 AC_ARG_WITH(iconv-bin,
 536 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 537 [iconv_bin="${withval}"
 538  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 539                     [Path of directory of iconv program.])
 540  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 541 ])
 542
 543 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 544 # There is a very specific comment in /usr/include/curses.h explaining that
 545 # termcap routines built into libcurses must not be used.
 546 #
 547 # The symptoms we observed so far is GDB unexpectedly changing
 548 # the terminal settings when tgetent is called - this is particularly
 549 # visible as the output is missing carriage returns, and so rapidly
 550 # becomes very hard to read.
 551 #
 552 # The readline configure script has already decided that libtermcap
 553 # was enough for its purposes, and so decided to build readline using
 554 # libtermcap.  Since the TUI mode requires curses, building GDB with
 555 # TUI enabled results in both libraries to be used at the same time,
 556 # which is not allowed.  This basically means that GDB with TUI is
 557 # broken on alpha-osf.
 558
 559 case $host_os in
 560   osf* )
 561     if test x"$enable_tui" = xyes; then
 562       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 563     fi
 564     if test x"$enable_tui" = xauto; then
 565       enable_tui=no
 566     fi
 567     ;;
 568 esac
 569
 570 # For the TUI, we need enhanced curses functionality.
 571 if test x"$enable_tui" != xno; then
 572   prefer_curses=yes
 573 fi
 574
 575 curses_found=no
 576 if test x"$prefer_curses" = xyes; then
 577   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 578   # curses library because the latter might not provide all the
 579   # functionality we need.  However, this leads to problems on systems
 580   # where the linker searches /usr/local/lib, but the compiler doesn't
 581   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 582   # default installation of ncurses on alpha*-dec-osf* will lead to such
 583   # a situation.
 584   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 585
 586   if test "$ac_cv_search_waddstr" != no; then
 587     curses_found=yes
 588   fi
 589 fi
 590
 591 # Check whether we should enable the TUI, but only do so if we really
 592 # can.
 593 if test x"$enable_tui" != xno; then
 594   if test -d $srcdir/tui; then
 595     if test "$curses_found" != no; then
 596       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 597       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 598       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 599       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 600     else
 601       if test x"$enable_tui" = xyes; then
 602         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 603       else
 604         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 605       fi
 606     fi
 607   fi
 608 fi
 609
 610 # Since GDB uses Readline, we need termcap functionality.  In many
 611 # cases this will be provided by the curses library, but some systems
 612 # have a seperate termcap library, or no curses library at all.
 613
 614 case $host_os in
 615   cygwin*)
 616     if test -d $srcdir/libtermcap; then
 617       LIBS="../libtermcap/libtermcap.a $LIBS"
 618       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 619     fi ;;
 620   go32* | *djgpp*)
 621     ac_cv_search_tgetent="none required"
 622     ;;
 623   *mingw32*)
 624     ac_cv_search_tgetent="none required"
 625     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 626     ;;
 627 esac
 628
 629 # These are the libraries checked by Readline.
 630 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 631
 632 if test "$ac_cv_search_tgetent" = no; then
 633   AC_MSG_ERROR([no termcap library found])
 634 fi
 635
 636 AC_ARG_WITH([system-readline],
 637   [AS_HELP_STRING([--with-system-readline],
 638                   [use installed readline library])])
 639
 640 if test "$with_system_readline" = yes; then
 641   READLINE=-lreadline
 642   READLINE_DEPS=
 643   READLINE_CFLAGS=
 644   READLINE_TEXI_INCFLAG=
 645 else
 646   READLINE='$(READLINE_DIR)/libreadline.a'
 647   READLINE_DEPS='$(READLINE)'
 648   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 649   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 650 fi
 651 AC_SUBST(READLINE)
 652 AC_SUBST(READLINE_DEPS)
 653 AC_SUBST(READLINE_CFLAGS)
 654 AC_SUBST(READLINE_TEXI_INCFLAG)
 655
 656 # Generate jit-reader.h
 657
 658 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 659 TARGET_PTR=
 660
 661 AC_CHECK_SIZEOF(unsigned long long)
 662 AC_CHECK_SIZEOF(unsigned long)
 663 AC_CHECK_SIZEOF(unsigned __int128)
 664
 665 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 666   TARGET_PTR="unsigned long"
 667 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 668   TARGET_PTR="unsigned long long"
 669 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 670   TARGET_PTR="unsigned __int128"
 671 else
 672   TARGET_PTR="unsigned long"
 673 fi
 674
 675 AC_SUBST(TARGET_PTR)
 676 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 677
 678 AC_SEARCH_LIBS(dlopen, dl)
 679
 680 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 681                 [directory to load the JIT readers from],
 682                 [${libdir}/gdb])
 683
 684 AC_ARG_WITH(expat,
 685   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 686   [], [with_expat=auto])
 687 AC_MSG_CHECKING([whether to use expat])
 688 AC_MSG_RESULT([$with_expat])
 689
 690 if test "${with_expat}" = no; then
 691   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 692   HAVE_LIBEXPAT=no
 693 else
 694   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 695                         [XML_Parser p = XML_ParserCreate (0);])
 696   if test "$HAVE_LIBEXPAT" != yes; then
 697     if test "$with_expat" = yes; then
 698       AC_MSG_ERROR([expat is missing or unusable])
 699     else
 700       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 701     fi
 702   else
 703     save_LIBS=$LIBS
 704     LIBS="$LIBS $LIBEXPAT"
 705     AC_CHECK_FUNCS(XML_StopParser)
 706     LIBS=$save_LIBS
 707   fi
 708 fi
 709
 710 dnl Utility to simplify finding libpython.
 711 dnl $1 = pythonX.Y
 712 dnl $2 = the shell variable to assign the result to
 713 dnl      If libpython is found we store $version here.
 714 dnl $3 = additional flags to add to CPPFLAGS
 715 dnl $4 = additional flags to add to LIBS
 716
 717 AC_DEFUN([AC_TRY_LIBPYTHON],
 718 [
 719   version=$1
 720   define([have_libpython_var],$2)
 721   new_CPPFLAGS=$3
 722   new_LIBS=$4
 723   AC_MSG_CHECKING([for ${version}])
 724   save_CPPFLAGS=$CPPFLAGS
 725   save_LIBS=$LIBS
 726   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 727   LIBS="$LIBS $new_LIBS"
 728   found_usable_python=no
 729   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 730                                  [[Py_Initialize ();]]),
 731                  [have_libpython_var=${version}
 732                   found_usable_python=yes
 733                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 734                   PYTHON_LIBS=$new_LIBS])
 735   CPPFLAGS=$save_CPPFLAGS
 736   LIBS=$save_LIBS
 737   AC_MSG_RESULT([${found_usable_python}])
 738 ])
 739
 740 dnl There are several different values for --with-python:
 741 dnl
 742 dnl no -   Don't include python support.
 743 dnl yes -  Include python support, error if it's missing.
 744 dnl        If we find python in $PATH, use it to fetch configure options,
 745 dnl        otherwise assume the compiler can find it with no help from us.
 746 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 747 dnl auto - Same as "yes", but if python is missing from the system,
 748 dnl        fall back to "no".
 749 dnl /path/to/python/exec-prefix -
 750 dnl        Use the python located in this directory.
 751 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 752 dnl        the compilation parameters.  Otherwise use
 753 dnl        -I/path/to/python/exec-prefix/include,
 754 dnl        -L/path/to/python/exec-prefix/lib.
 755 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 756 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 757 dnl        but is deprecated.
 758 dnl /path/to/python/executable -
 759 dnl        Run python-config.py with this version of python to fetch the
 760 dnl        compilation parameters.
 761 dnl        NOTE: This needn't be the real python executable.
 762 dnl        In a cross-compilation scenario (build != host), this could be
 763 dnl        a shell script that provides what python-config.py provides for
 764 dnl        --ldflags, --includes, --exec-prefix.
 765 dnl python-executable -
 766 dnl        Find python-executable in $PATH, and then handle the same as
 767 dnl        /path/to/python/executable.
 768 dnl
 769 dnl If a python program is specified, it is used to run python-config.py and
 770 dnl is passed --ldflags, --includes, --exec-prefix.
 771
 772 AC_ARG_WITH(python,
 773   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 774   [], [with_python=auto])
 775 AC_MSG_CHECKING([whether to use python])
 776 AC_MSG_RESULT([$with_python])
 777
 778 if test "${with_python}" = no; then
 779   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 780   have_libpython=no
 781 else
 782   case "${with_python}" in
 783   [[\\/]]* | ?:[[\\/]]*)
 784     if test -d ${with_python}; then
 785       # Assume the python binary is ${with_python}/bin/python.
 786       python_prog="${with_python}/bin/python"
 787       python_prefix=
 788       # If python does not exit ${with_python}/bin, then try in
 789       # ${with_python}.  On Windows/MinGW, this is where the Python
 790       # executable is.
 791       if test ! -x "${python_prog}"; then
 792         python_prog="${with_python}/python"
 793         python_prefix=
 794       fi
 795       if test ! -x "${python_prog}"; then
 796         # Fall back to gdb 7.0/7.1 behaviour.
 797         python_prog=missing
 798         python_prefix=${with_python}
 799       fi
 800     elif test -x "${with_python}"; then
 801       # While we can't run python compiled for $host (unless host == build),
 802       # the user could write a script that provides the needed information,
 803       # so we support that.
 804       python_prog=${with_python}
 805       python_prefix=
 806     else
 807       AC_ERROR(invalid value for --with-python)
 808     fi
 809     ;;
 810   */*)
 811     # Disallow --with-python=foo/bar.
 812     AC_ERROR(invalid value for --with-python)
 813     ;;
 814   *)
 815     # The user has either specified auto, yes, or the name of the python
 816     # program assumed to be in $PATH.
 817     python_prefix=
 818     case "${with_python}" in
 819     yes | auto)
 820       if test ${build} = ${host}; then
 821         AC_PATH_PROG(python_prog_path, python, missing)
 822         if test "${python_prog_path}" = missing; then
 823           python_prog=missing
 824         else
 825           python_prog=${python_prog_path}
 826         fi
 827       else
 828         # Not much we can do except assume the cross-compiler will find the
 829         # right files.
 830         python_prog=missing
 831       fi
 832       ;;
 833     *)
 834       # While we can't run python compiled for $host (unless host == build),
 835       # the user could write a script that provides the needed information,
 836       # so we support that.
 837       python_prog="${with_python}"
 838       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 839       if test "${python_prog_path}" = missing; then
 840         AC_ERROR(unable to find python program ${python_prog})
 841       fi
 842       ;;
 843     esac
 844   esac
 845
 846   if test "${python_prog}" != missing; then
 847     # We have a python program to use, but it may be too old.
 848     # Don't flag an error for --with-python=auto (the default).
 849     have_python_config=yes
 850     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 851     if test $? != 0; then
 852       have_python_config=failed
 853       if test "${with_python}" != auto; then
 854         AC_ERROR(failure running python-config --includes)
 855       fi
 856     fi
 857     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 858     if test $? != 0; then
 859       have_python_config=failed
 860       if test "${with_python}" != auto; then
 861         AC_ERROR(failure running python-config --ldflags)
 862       fi
 863     fi
 864     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 865     if test $? != 0; then
 866       have_python_config=failed
 867       if test "${with_python}" != auto; then
 868         AC_ERROR(failure running python-config --exec-prefix)
 869       fi
 870     fi
 871   else
 872     # We do not have a python executable we can use to determine where
 873     # to find the Python headers and libs.  We cannot guess the include
 874     # path from the python_prefix either, because that include path
 875     # depends on the Python version.  So, there is nothing much we can
 876     # do except assume that the compiler will be able to find those files.
 877     python_includes=
 878     python_libs=
 879     have_python_config=no
 880   fi
 881
 882   # If we have python-config, only try the configuration it provides.
 883   # Otherwise fallback on the old way of trying different versions of
 884   # python in turn.
 885
 886   have_libpython=no
 887   if test "${have_python_config}" = yes; then
 888     # Determine the Python version by extracting "-lpython<version>"
 889     # part of the python_libs. <version> is usually X.Y with X and Y
 890     # being decimal numbers, but can also be XY (seen on Windows).
 891     #
 892     # The extraction is performed using sed with a regular expression.
 893     # Initially, the regexp used was using the '?' quantifier to make
 894     # the dot in the version number optional.  Unfortunately, this
 895     # does not work with non-GNU versions of sed because, because of
 896     # what looks like a limitation (the '?' quantifier does not work
 897     # with back-references).  We work around this limitation by using
 898     # the '*' quantifier instead.  It means that, in theory, we might
 899     # match unexpected version strings such as "-lpython2..7", but
 900     # this seems unlikely in practice.  And even if that happens,
 901     # an error will be triggered later on, when checking that version
 902     # number.
 903     python_version=`echo " ${python_libs} " \
 904                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 905     case "${python_version}" in
 906     python*)
 907       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 908                        ${python_includes}, ${python_libs})
 909       ;;
 910     *)
 911       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 912       ;;
 913     esac
 914   elif test "${have_python_config}" != failed; then
 915     if test "${have_libpython}" = no; then
 916       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 917                        ${python_includes}, "${python_libs} -lpython2.7")
 918     fi
 919     if test "${have_libpython}" = no; then
 920       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 921                        ${python_includes}, "${python_libs} -lpython2.6")
 922     fi
 923     if test ${have_libpython} = no; then
 924       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 925                        ${python_includes}, "${python_libs} -lpython2.5")
 926     fi
 927     if test ${have_libpython} = no; then
 928       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 929                        ${python_includes}, "${python_libs} -lpython2.4")
 930     fi
 931   fi
 932   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 933     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 934   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 935     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 936   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 937     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 938   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 939     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 940   fi
 941
 942   if test "${have_libpython}" = no; then
 943     case "${with_python}" in
 944     yes)
 945       AC_MSG_ERROR([python is missing or unusable])
 946       ;;
 947     auto)
 948       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 949       ;;
 950     *)
 951       AC_MSG_ERROR([no usable python found at ${with_python}])
 952       ;;
 953     esac
 954   else
 955     if test -n "${python_prefix}"; then
 956       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 957                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 958       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 959     fi
 960   fi
 961 fi
 962
 963 if test "${have_libpython}" != no; then
 964   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 965   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 966   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 967   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 968   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 969   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 970
 971   # Flags needed to compile Python code (taken from python-config --cflags).
 972   # We cannot call python-config directly because it will output whatever was
 973   # used when compiling the Python interpreter itself, including flags which
 974   # would make the python-related objects be compiled differently from the
 975   # rest of GDB (e.g., -O2 and -fPIC).
 976   if test "${GCC}" = yes; then
 977     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 978   fi
 979
 980   if test "x${tentative_python_cflags}" != x; then
 981     AC_MSG_CHECKING(compiler flags for python code)
 982     for flag in ${tentative_python_cflags}; do
 983       # Check that the compiler accepts it
 984       saved_CFLAGS="$CFLAGS"
 985       CFLAGS="$CFLAGS $flag"
 986       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 987       CFLAGS="$saved_CFLAGS"
 988     done
 989     AC_MSG_RESULT(${PYTHON_CFLAGS})
 990   fi
 991
 992   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 993   #    #if _SGIAPI
 994   #    #define siginfo __siginfo
 995   #    #endif
 996   # The problem is that including Python causes some XOPEN macros to be
 997   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 998   # to false.  So, we work around this issue by defining siginfo ourself
 999   # though the command-line.
1000   #
1001   # On x64 Windows, Python's include headers, and pyconfig.h in
1002   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1003   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1004   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1005   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1006   # The issue was reported to the Python community, but still isn't
1007   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1008
1009   case "$gdb_host" in
1010     irix*) if test "${GCC}" = yes; then
1011              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1012            fi
1013            ;;
1014     mingw64)
1015            if test "${GCC}" = yes; then
1016              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1017            fi
1018            ;;
1019   esac
1020
1021   # Note that "python -m threading" cannot be used to check for
1022   # threading support due to a bug in Python 2.7.3
1023   # (http://bugs.python.org/issue15567).
1024   AC_MSG_CHECKING(whether python supports threads)
1025   saved_CPPFLAGS="${CPPFLAGS}"
1026   CPPFLAGS="${PYTHON_CPPFLAGS}"
1027   # Note that the test is reversed so that python_has_threads=yes on
1028   # unexpected failures.
1029   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1030 #include <Python.h>
1031 #ifdef WITH_THREAD
1032 # error
1033 #endif
1034   ]]), [python_has_threads=no], [python_has_threads=yes])
1035   AC_MSG_RESULT(${python_has_threads})
1036   CPPFLAGS="${saved_CPPFLAGS}"
1037 else
1038   # Even if Python support is not compiled in, we need to have these files
1039   # included.
1040   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
1041   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
1042         python/py-prettyprint.c python/py-auto-load.c"
1043 fi
1044 AC_SUBST(PYTHON_CFLAGS)
1045 AC_SUBST(PYTHON_CPPFLAGS)
1046 AC_SUBST(PYTHON_LIBS)
1047
1048 # Provide a --enable-libmcheck/--disable-libmcheck set of options
1049 # allowing a user to enable this option even when building releases,
1050 # or to disable it when building a snapshot.
1051 AC_ARG_ENABLE(libmcheck,
1052   AS_HELP_STRING([--enable-libmcheck],
1053                  [Try building GDB with -lmcheck if available]),
1054   [case "${enableval}" in
1055      yes | y) ENABLE_LIBMCHECK="yes" ;;
1056      no | n)  ENABLE_LIBMCHECK="no" ;;
1057      *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmcheck) ;;
1058    esac])
1059
1060 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1061 # but turn it off if Python is enabled with threads, since -lmcheck is
1062 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1063 # and for releases.
1064 if test -z "${ENABLE_LIBMCHECK}" \
1065         -a \( "${have_libpython}" = "no" \
1066              -o "${python_has_threads}" = "no" \) \
1067     && $development; then
1068   ENABLE_LIBMCHECK=yes
1069 fi
1070
1071 if test "$ENABLE_LIBMCHECK" = "yes" ; then
1072   if test "${have_libpython}" != "no" -a "${python_has_threads}" = "yes" ; then
1073     AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1074   fi
1075   AC_CHECK_LIB(mcheck, main)
1076 fi
1077
1078 # ------------------------- #
1079 # Checks for header files.  #
1080 # ------------------------- #
1081
1082 AC_HEADER_DIRENT
1083 AC_HEADER_STDC
1084 # elf_hp.h is for HP/UX 64-bit shared library support.
1085 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1086                   thread_db.h signal.h stddef.h \
1087                   stdlib.h string.h memory.h strings.h sys/fault.h \
1088                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1089                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1090                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1091                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1092                   sgtty.h unistd.h elf_hp.h locale.h \
1093                   dlfcn.h sys/un.h linux/perf_event.h])
1094 AC_CHECK_HEADERS(link.h, [], [],
1095 [#if HAVE_SYS_TYPES_H
1096 # include <sys/types.h>
1097 #endif
1098 #if HAVE_NLIST_H
1099 # include <nlist.h>
1100 #endif
1101 ])
1102 AC_CHECK_HEADERS(sys/proc.h, [], [],
1103 [#if HAVE_SYS_PARAM_H
1104 # include <sys/param.h>
1105 #endif
1106 ])
1107 AC_CHECK_HEADERS(sys/user.h, [], [],
1108 [#if HAVE_SYS_PARAM_H
1109 # include <sys/param.h>
1110 #endif
1111 ])
1112
1113 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1114 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1115 # think that we don't have <curses.h> if we're using GCC.
1116 case $host_os in
1117   solaris2.[[789]])
1118     if test "$GCC" = yes; then
1119       AC_DEFINE(_MSE_INT_H, 1,
1120         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1121    Solaris 2.[789] when using GCC. ])
1122     fi ;;
1123 esac
1124 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1125 AC_CHECK_HEADERS(term.h, [], [],
1126 [#if HAVE_CURSES_H
1127 # include <curses.h>
1128 #endif
1129 ])
1130
1131 # ------------------------- #
1132 # Checks for declarations.  #
1133 # ------------------------- #
1134
1135 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1136                 snprintf, vsnprintf])
1137 AM_LC_MESSAGES
1138
1139 # ----------------------- #
1140 # Checks for structures.  #
1141 # ----------------------- #
1142
1143 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1144
1145 # ------------------ #
1146 # Checks for types.  #
1147 # ------------------ #
1148
1149 AC_TYPE_SIGNAL
1150 AC_CHECK_TYPES(socklen_t, [], [],
1151 [#include <sys/types.h>
1152 #include <sys/socket.h>
1153 ])
1154
1155 # ------------------------------------- #
1156 # Checks for compiler characteristics.  #
1157 # ------------------------------------- #
1158
1159 AC_C_CONST
1160 AC_C_INLINE
1161 AC_C_BIGENDIAN
1162
1163 # ------------------------------ #
1164 # Checks for library functions.  #
1165 # ------------------------------ #
1166
1167 AC_FUNC_ALLOCA
1168 AC_FUNC_MMAP
1169 AC_FUNC_VFORK
1170 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1171                 pipe poll pread pread64 pwrite readlink resize_term \
1172                 sbrk setpgid setpgrp setsid \
1173                 sigaction sigprocmask sigsetmask socketpair syscall \
1174                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1175                 setrlimit getrlimit posix_madvise waitpid lstat \
1176                 fdwalk pipe2])
1177 AM_LANGINFO_CODESET
1178
1179 # Check the return and argument types of ptrace.  No canned test for
1180 # this, so roll our own.
1181 gdb_ptrace_headers='
1182 #if HAVE_SYS_TYPES_H
1183 # include <sys/types.h>
1184 #endif
1185 #if HAVE_SYS_PTRACE_H
1186 # include <sys/ptrace.h>
1187 #endif
1188 #if HAVE_UNISTD_H
1189 # include <unistd.h>
1190 #endif
1191 '
1192 # There is no point in checking if we don't have a prototype.
1193 AC_CHECK_DECLS(ptrace, [], [
1194   : ${gdb_cv_func_ptrace_ret='int'}
1195   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1196 ], $gdb_ptrace_headers)
1197 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1198 # empty argument list, so check for that explicitly.
1199 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1200   AC_TRY_COMPILE($gdb_ptrace_headers,
1201     [extern long ptrace (enum __ptrace_request, ...);],
1202     gdb_cv_func_ptrace_ret='long',
1203     AC_TRY_COMPILE($gdb_ptrace_headers,
1204       [extern int ptrace ();],
1205       gdb_cv_func_ptrace_ret='int',
1206       gdb_cv_func_ptrace_ret='long')))
1207 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1208   [Define as the return type of ptrace.])
1209 # Check argument types.
1210 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1211   AC_TRY_COMPILE($gdb_ptrace_headers,
1212     [extern long ptrace (enum __ptrace_request, ...);],
1213     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1214 for gdb_arg1 in 'int' 'long'; do
1215  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1216   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1217    for gdb_arg4 in 'int' 'long'; do
1218      AC_TRY_COMPILE($gdb_ptrace_headers, [
1219 extern $gdb_cv_func_ptrace_ret
1220   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1221 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1222     break 4;])
1223     for gdb_arg5 in 'int *' 'int' 'long'; do
1224      AC_TRY_COMPILE($gdb_ptrace_headers, [
1225 extern $gdb_cv_func_ptrace_ret
1226   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1227 ], [
1228 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1229     break 5;])
1230     done
1231    done
1232   done
1233  done
1234 done
1235 # Provide a safe default value.
1236 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1237 ])])
1238 ac_save_IFS=$IFS; IFS=','
1239 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1240 IFS=$ac_save_IFS
1241 shift
1242 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1243   [Define to the type of arg 3 for ptrace.])
1244 if test -n "$[5]"; then
1245   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1246     [Define to the type of arg 5 for ptrace.])
1247 fi
1248
1249 dnl AC_FUNC_SETPGRP does not work when cross compiling
1250 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1251 if test "$cross_compiling" = no; then
1252   AC_FUNC_SETPGRP
1253 else
1254   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1255     [AC_TRY_COMPILE([
1256 #include <unistd.h>
1257 ], [
1258   if (setpgrp(1,1) == -1)
1259     exit (0);
1260   else
1261     exit (1);
1262 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1263 if test $ac_cv_func_setpgrp_void = yes; then
1264   AC_DEFINE(SETPGRP_VOID, 1)
1265 fi
1266 fi
1267
1268 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1269 # since sigsetjmp might only be defined as a macro.
1270 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1271 [AC_TRY_COMPILE([
1272 #include <setjmp.h>
1273 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1274 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1275 if test $gdb_cv_func_sigsetjmp = yes; then
1276   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1277 fi
1278
1279 # Assume we'll default to using the included libiberty regex.
1280 gdb_use_included_regex=yes
1281
1282 # However, if the system regex is GNU regex, then default to *not*
1283 # using the included regex.
1284 AC_CACHE_CHECK(
1285   [for GNU regex],
1286   [gdb_cv_have_gnu_regex],
1287   [AC_TRY_COMPILE(
1288     [#include <gnu-versions.h>],
1289     [#define REGEX_INTERFACE_VERSION 1
1290 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1291 # error "Version mismatch"
1292 #endif],
1293     gdb_cv_have_gnu_regex=yes,
1294     gdb_cv_have_gnu_regex=no)])
1295 if test $gdb_cv_have_gnu_regex = yes; then
1296   gdb_use_included_regex=no
1297 fi
1298
1299 AC_ARG_WITH(included-regex,
1300   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1301   gdb_with_regex=$withval,
1302   gdb_with_regex=$gdb_use_included_regex)
1303 if test "$gdb_with_regex" = yes; then
1304   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1305     [Define to 1 if the regex included in libiberty should be used.])
1306 fi
1307
1308 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1309 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1310 [#include <sys/param.h>
1311 #include <sys/proc.h>
1312 ])
1313
1314 # See if <sys/lwp.h> defines `struct lwp`.
1315 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1316 [AC_TRY_COMPILE([#include <sys/param.h>
1317 #include <sys/lwp.h>], [struct lwp l;],
1318 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1319 if test $gdb_cv_struct_lwp = yes; then
1320   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1321             [Define to 1 if your system has struct lwp.])
1322 fi
1323
1324 # See if <machine/reg.h> degines `struct reg'.
1325 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1326 [AC_TRY_COMPILE([#include <sys/types.h>
1327 #include <machine/reg.h>], [struct reg r;],
1328 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1329 if test $gdb_cv_struct_reg = yes; then
1330   AC_DEFINE(HAVE_STRUCT_REG, 1,
1331             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1332 fi
1333
1334 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1335 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1336 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1337                  [#include <machine/reg.h>])
1338
1339 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1340 # Older amd64 Linux's don't have the fs_base and gs_base members of
1341 # `struct user_regs_struct'.
1342 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1343                  [], [], [#include <sys/user.h>])
1344
1345 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1346 AC_MSG_CHECKING(for PTRACE_GETREGS)
1347 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1348 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1349                 [PTRACE_GETREGS;],
1350                 [gdb_cv_have_ptrace_getregs=yes],
1351                 [gdb_cv_have_ptrace_getregs=no])])
1352 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1353 if test $gdb_cv_have_ptrace_getregs = yes; then
1354   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1355   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1356 fi
1357
1358 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1359 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1360 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1361 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1362                 [PTRACE_GETFPXREGS;],
1363                 [gdb_cv_have_ptrace_getfpxregs=yes],
1364                 [gdb_cv_have_ptrace_getfpxregs=no])])
1365 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1366 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1367   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1368   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1369 fi
1370
1371 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1372 AC_MSG_CHECKING(for PT_GETDBREGS)
1373 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1374 [AC_TRY_COMPILE([#include <sys/types.h>
1375 #include <sys/ptrace.h>],
1376                 [PT_GETDBREGS;],
1377                 [gdb_cv_have_pt_getdbregs=yes],
1378                 [gdb_cv_have_pt_getdbregs=no])])
1379 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1380 if test $gdb_cv_have_pt_getdbregs = yes; then
1381   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1382   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1383 fi
1384
1385 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1386 AC_MSG_CHECKING(for PT_GETXMMREGS)
1387 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1388 [AC_TRY_COMPILE([#include <sys/types.h>
1389 #include <sys/ptrace.h>],
1390                 [PT_GETXMMREGS;],
1391                 [gdb_cv_have_pt_getxmmregs=yes],
1392                 [gdb_cv_have_pt_getxmmregs=no])])
1393 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1394 if test $gdb_cv_have_pt_getxmmregs = yes; then
1395   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1396   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1397 fi
1398
1399 # Detect which type of /proc is in use, such as for Solaris.
1400
1401 if test "${target}" = "${host}"; then
1402   case "${host}" in
1403   *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1404       AC_DEFINE(NEW_PROC_API, 1,
1405       [Define if you want to use new multi-fd /proc interface
1406        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1407       ;;
1408   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1409       AC_DEFINE(NEW_PROC_API, 1,
1410       [Define if you want to use new multi-fd /proc interface
1411        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1412       ;;
1413   mips-sgi-irix5*)
1414       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1415       AC_DEFINE([_KMEMUSER], 1,
1416       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1417        around a <sys/proc.h> problem on IRIX 5.])
1418       ;;
1419   esac
1420 fi
1421
1422 if test "$ac_cv_header_sys_procfs_h" = yes; then
1423   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1424   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1425   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1426   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1427   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1428   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1429   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1430   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1431   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1432   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1433   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1434   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1435   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1436   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1437
1438
1439   dnl Check for broken prfpregset_t type
1440
1441   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1442   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1443   dnl instead of the struct itself).  We detect this here, and work
1444   dnl around it in gdb_proc_service.h.
1445
1446   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1447     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1448     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1449       [AC_TRY_RUN([#include <sys/procfs.h>
1450        int main ()
1451        {
1452          if (sizeof (prfpregset_t) == sizeof (void *))
1453            return 1;
1454          return 0;
1455        }],
1456        gdb_cv_prfpregset_t_broken=no,
1457        gdb_cv_prfpregset_t_broken=yes,
1458        gdb_cv_prfpregset_t_broken=yes)])
1459     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1460     if test $gdb_cv_prfpregset_t_broken = yes; then
1461       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1462       [Define if the prfpregset_t type is broken.])
1463     fi
1464   fi
1465
1466   dnl Check for PIOCSET ioctl entry
1467
1468   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1469   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1470   [AC_TRY_COMPILE([#include <unistd.h>
1471 #include <sys/types.h>
1472 #include <sys/procfs.h>
1473 ], [
1474     int dummy;;
1475     dummy = ioctl(0, PIOCSET, &dummy);
1476   ],
1477   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1478   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1479   if test $gdb_cv_have_procfs_piocset = yes; then
1480     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1481     [Define if ioctl argument PIOCSET is available.])
1482   fi
1483 fi
1484
1485 dnl For native ports (host == target), check to see what kind of
1486 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1487 if test ${host} = ${target} ; then
1488   dnl Check for struct link_map with l_ members which are indicative
1489   dnl of SVR4-like shared libraries
1490
1491   AC_MSG_CHECKING(for member l_addr in struct link_map)
1492   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1493     [AC_TRY_COMPILE([#include <link.h>],
1494                     [struct link_map lm; (void) lm.l_addr;],
1495                     gdb_cv_have_struct_link_map_with_l_members=yes,
1496                     gdb_cv_have_struct_link_map_with_l_members=no)])
1497   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1498   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1499     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1500     [Define if <link.h> exists and defines struct link_map which has
1501      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1502      SVR4-like systems.)])
1503   fi
1504
1505   dnl Check for struct link_map with lm_ members which are indicative
1506   dnl of SunOS-like shared libraries
1507
1508   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1509   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1510     [AC_TRY_COMPILE([#include <sys/types.h>
1511 #include <link.h>],
1512                     [struct link_map lm; (void) lm.lm_addr;],
1513                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1514                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1515   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1516   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1517     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1518     [Define if <link.h> exists and defines struct link_map which has
1519      members with an ``lm_'' prefix.  (For SunOS.)])
1520   fi
1521
1522   dnl Check for struct so_map with som_ members which are found on
1523   dnl some *BSD systems.
1524
1525   AC_MSG_CHECKING(for member som_addr in struct so_map)
1526   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1527     [AC_TRY_COMPILE([#include <sys/types.h>
1528 #ifdef HAVE_NLIST_H
1529 #include <nlist.h>
1530 #endif
1531 #include <link.h>],
1532                     [struct so_map lm; (void) lm.som_addr;],
1533                     gdb_cv_have_struct_so_map_with_som_members=yes,
1534                     gdb_cv_have_struct_so_map_with_som_members=no)])
1535   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1536   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1537     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1538     [Define if <link.h> exists and defines a struct so_map which has
1539      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1540   fi
1541
1542   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1543   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1544
1545   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1546   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1547     [AC_TRY_COMPILE([#define _SYSCALL32
1548 #include <sys/link.h>], [struct link_map32 l;],
1549      gdb_cv_have_struct_link_map32=yes,
1550      gdb_cv_have_struct_link_map32=no)])
1551   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1552   if test $gdb_cv_have_struct_link_map32 = yes; then
1553     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1554     [Define if <sys/link.h> has struct link_map32])
1555     AC_DEFINE(_SYSCALL32, 1,
1556     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1557   fi
1558 fi
1559
1560 # Check if the compiler supports the `long long' type.
1561
1562 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1563                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1564 [[extern long long foo;]],
1565 [[switch (foo & 2) { case 0: return 1; }]])],
1566                                   gdb_cv_c_long_long=yes,
1567                                   gdb_cv_c_long_long=no)])
1568 if test $gdb_cv_c_long_long != yes; then
1569   # libdecnumber requires long long.
1570   AC_MSG_ERROR([Compiler must support long long for GDB.])
1571 fi
1572
1573 # Check if the compiler and runtime support printing long longs.
1574
1575 AC_CACHE_CHECK([for long long support in printf],
1576                gdb_cv_printf_has_long_long,
1577                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1578 [[char buf[32];
1579   long long l = 0;
1580   l = (l << 16) + 0x0123;
1581   l = (l << 16) + 0x4567;
1582   l = (l << 16) + 0x89ab;
1583   l = (l << 16) + 0xcdef;
1584   sprintf (buf, "0x%016llx", l);
1585   return (strcmp ("0x0123456789abcdef", buf));]])],
1586                               gdb_cv_printf_has_long_long=yes,
1587                               gdb_cv_printf_has_long_long=no,
1588                               gdb_cv_printf_has_long_long=no)])
1589 if test $gdb_cv_printf_has_long_long = yes; then
1590   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1591             [Define to 1 if the "%ll" format works to print long longs.])
1592 fi
1593
1594 # Check if the compiler and runtime support printing decfloats.
1595
1596 AC_CACHE_CHECK([for decfloat support in printf],
1597                gdb_cv_printf_has_decfloat,
1598                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1599 [[char buf[64];
1600   _Decimal32 d32 = 1.2345df;
1601   _Decimal64 d64 = 1.2345dd;
1602   _Decimal128 d128 = 1.2345dl;
1603   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1604   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1605                               gdb_cv_printf_has_decfloat=yes,
1606                               gdb_cv_printf_has_decfloat=no,
1607                               gdb_cv_printf_has_decfloat=no)])
1608 if test $gdb_cv_printf_has_decfloat = yes; then
1609   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1610             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1611 fi
1612
1613 # Check if the compiler supports the `long double' type.  We can't use
1614 # AC_C_LONG_DOUBLE because that one does additional checks on the
1615 # constants defined in <float.h> that fail on some systems,
1616 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1617
1618 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1619                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1620                                   gdb_cv_c_long_double=yes,
1621                                   gdb_cv_c_long_double=no)])
1622 if test $gdb_cv_c_long_double = yes; then
1623   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1624            [Define to 1 if the compiler supports long double.])
1625 fi
1626
1627 # Check if the compiler and runtime support printing long doubles.
1628
1629 AC_CACHE_CHECK([for long double support in printf],
1630                gdb_cv_printf_has_long_double,
1631                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1632 [[char buf[16];
1633   long double f = 3.141592653;
1634   sprintf (buf, "%Lg", f);
1635   return (strncmp ("3.14159", buf, 7));]])],
1636                               gdb_cv_printf_has_long_double=yes,
1637                               gdb_cv_printf_has_long_double=no,
1638                               gdb_cv_printf_has_long_double=no)])
1639 if test $gdb_cv_printf_has_long_double = yes; then
1640   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1641             [Define to 1 if the "%Lg" format works to print long doubles.])
1642 fi
1643
1644 # Check if the compiler and runtime support scanning long doubles.
1645
1646 AC_CACHE_CHECK([for long double support in scanf],
1647                gdb_cv_scanf_has_long_double,
1648                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1649 [[#include <stdio.h>]],
1650 [[char *buf = "3.141592653";
1651   long double f = 0;
1652   sscanf (buf, "%Lg", &f);
1653   return !(f > 3.14159 && f < 3.14160);]])],
1654                               gdb_cv_scanf_has_long_double=yes,
1655                               gdb_cv_scanf_has_long_double=no,
1656                               gdb_cv_scanf_has_long_double=no)])
1657 if test $gdb_cv_scanf_has_long_double = yes; then
1658   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1659             [Define to 1 if the "%Lg" format works to scan long doubles.])
1660 fi
1661
1662 case ${host_os} in
1663 aix*)
1664   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1665     SAVE_LDFLAGS=$LDFLAGS
1666
1667     case $GCC in
1668     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1669     *) gdb_cv_bigtoc=-bbigtoc ;;
1670     esac
1671
1672     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1673     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1674     LDFLAGS="${SAVE_LDFLAGS}"
1675   ])
1676   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1677   ;;
1678 esac
1679
1680 AC_MSG_CHECKING(for the dynamic export flag)
1681 dynamic_list=false
1682 if test "${gdb_native}" = yes; then
1683    # The dynamically loaded libthread_db needs access to symbols in the gdb
1684    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1685    # may not be supported there.
1686    old_LDFLAGS="$LDFLAGS"
1687    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1688    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1689    LDFLAGS="$LDFLAGS $RDYNAMIC"
1690    if test "${have_libpython}" = no; then
1691      AC_TRY_LINK([], [], [dynamic_list=true])
1692    else
1693      # Workaround http://bugs.python.org/issue4434 where static
1694      # libpythonX.Y.a would get its symbols required for
1695      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1696      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1697      old_CFLAGS="$CFLAGS"
1698      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1699      old_LIBS="$LIBS"
1700      LIBS="$LIBS $PYTHON_LIBS"
1701      AC_RUN_IFELSE(
1702        AC_LANG_PROGRAM(
1703          [#include "]${have_libpython}[/Python.h"],
1704          [int err;
1705           Py_Initialize ();
1706           err = PyRun_SimpleString ("import itertools\n");
1707           Py_Finalize ();
1708           return err == 0 ? 0 : 1;]),
1709        [dynamic_list=true], [], [true])
1710      LIBS="$old_LIBS"
1711      CFLAGS="$old_CFLAGS"
1712    fi
1713    LDFLAGS="$old_LDFLAGS"
1714 fi
1715 if $dynamic_list; then
1716   found="-Wl,--dynamic-list"
1717   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1718 else
1719   found="-rdynamic"
1720   RDYNAMIC="-rdynamic"
1721 fi
1722 AC_SUBST(RDYNAMIC)
1723 AC_MSG_RESULT($found)
1724
1725 dnl For certain native configurations, we need to check whether thread
1726 dnl support can be built in or not.
1727 dnl
1728 dnl Note that we only want this if we are both native (host == target),
1729 dnl and not doing a canadian cross build (build == host).
1730
1731 if test ${build} = ${host} -a ${host} = ${target} ; then
1732    case ${host_os} in
1733    solaris*)
1734       # See if thread_db library is around for Solaris thread debugging.
1735       # Note that we must explicitly test for version 1 of the library
1736       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1737       # the same API.
1738       AC_MSG_CHECKING(for Solaris thread debugging library)
1739       if test -f /usr/lib/libthread_db.so.1 ; then
1740          AC_MSG_RESULT(yes)
1741          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1742          [Define if using Solaris thread debugging.])
1743          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1744          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1745          # On SPARC CPUs, we also need to build sparc-sol-thread.
1746          case ${host_cpu} in
1747            sparc*)
1748              CONFIG_OBS="${CONFIG_OBS} sparc-sol-thread.o"
1749              CONFIG_SRCS="${CONFIG_SRCS} sparc-sol-thread.c"
1750              ;;
1751          esac
1752          AC_CHECK_LIB(dl, dlopen)
1753          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1754          # Sun randomly tweaked the prototypes in <proc_service.h>
1755          # at one point.
1756          AC_MSG_CHECKING(if <proc_service.h> is old)
1757          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1758             AC_TRY_COMPILE([
1759                 #include <proc_service.h>
1760                 ps_err_e ps_pdwrite
1761                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1762             ],, gdb_cv_proc_service_is_old=no,
1763                 gdb_cv_proc_service_is_old=yes)
1764          ])
1765          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1766          if test $gdb_cv_proc_service_is_old = yes; then
1767             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1768             [Define if <proc_service.h> on solaris uses int instead of
1769              size_t, and assorted other type changes.])
1770          fi
1771       else
1772          AC_MSG_RESULT(no)
1773       fi
1774       ;;
1775    aix*)
1776       AC_MSG_CHECKING(for AiX thread debugging library)
1777       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1778                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1779                                    [#ifndef PTHDB_VERSION_3
1780                                     #error
1781                                     #endif],
1782                                    gdb_cv_have_aix_thread_debug=yes,
1783                                    gdb_cv_have_aix_thread_debug=no)])
1784       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1785       if test $gdb_cv_have_aix_thread_debug = yes; then
1786          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1787          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1788          LIBS="$LIBS -lpthdebug"
1789
1790          # Older versions of AIX do not provide the declaration for
1791          # the getthrds function (it appears that it was introduced
1792          # with AIX 6.x).
1793          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1794       fi
1795       ;;
1796    esac
1797    AC_SUBST(CONFIG_LDFLAGS)
1798 fi
1799
1800 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1801 dnl other error codes.
1802 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1803    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1804                   gdb_cv_thread_db_h_has_td_notalloc,
1805      AC_TRY_COMPILE(
1806        [#include <thread_db.h>],
1807        [int i = TD_NOTALLOC;],
1808        gdb_cv_thread_db_h_has_td_notalloc=yes,
1809        gdb_cv_thread_db_h_has_td_notalloc=no
1810      )
1811    )
1812    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1813                   gdb_cv_thread_db_h_has_td_version,
1814      AC_TRY_COMPILE(
1815        [#include <thread_db.h>],
1816        [int i = TD_VERSION;],
1817        gdb_cv_thread_db_h_has_td_version=yes,
1818        gdb_cv_thread_db_h_has_td_version=no
1819      )
1820    )
1821    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1822                   gdb_cv_thread_db_h_has_td_notls,
1823      AC_TRY_COMPILE(
1824        [#include <thread_db.h>],
1825        [int i = TD_NOTLS;],
1826        gdb_cv_thread_db_h_has_td_notls=yes,
1827        gdb_cv_thread_db_h_has_td_notls=no
1828      )
1829    )
1830 fi
1831 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1832   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1833             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1834 fi
1835 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1836   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1837             [Define if <thread_db.h> has the TD_VERSION error code.])
1838 fi
1839 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1840   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1841             [Define if <thread_db.h> has the TD_NOTLS error code.])
1842 fi
1843
1844 dnl See if we have a sys/syscall header file that has __NR_tkill.
1845 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1846    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1847                   gdb_cv_sys_syscall_h_has_tkill,
1848      AC_TRY_COMPILE(
1849        [#include <sys/syscall.h>],
1850        [int i = __NR_tkill;],
1851        gdb_cv_sys_syscall_h_has_tkill=yes,
1852        gdb_cv_sys_syscall_h_has_tkill=no
1853      )
1854    )
1855 fi
1856 dnl See if we can issue tkill syscall.
1857 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1858   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1859 fi
1860
1861 dnl Check if we can disable the virtual address space randomization.
1862 dnl The functionality of setarch -R.
1863 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1864 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1865 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1866 #       define ADDR_NO_RANDOMIZE 0x0040000
1867 #      endif
1868        /* Test the flag could be set and stays set.  */
1869        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1870        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1871            return 1])])
1872 AC_RUN_IFELSE([PERSONALITY_TEST],
1873               [have_personality=true],
1874               [have_personality=false],
1875               [AC_LINK_IFELSE([PERSONALITY_TEST],
1876                               [have_personality=true],
1877                               [have_personality=false])])
1878 if $have_personality
1879 then
1880     AC_DEFINE([HAVE_PERSONALITY], 1,
1881               [Define if you support the personality syscall.])
1882 fi
1883
1884 dnl Handle optional features that can be enabled.
1885
1886 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1887 # except that the argument to --with-sysroot is optional.
1888 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1889 if test "x$with_sysroot" = xyes; then
1890   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1891 fi
1892 AC_ARG_WITH(sysroot,
1893   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1894                  [search for usr/lib et al within DIR]),
1895   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1896 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1897               [search for usr/lib et al within DIR])
1898 AC_SUBST(TARGET_SYSTEM_ROOT)
1899 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1900
1901 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1902     [automatically load a system-wide gdbinit file],
1903     [])
1904
1905 AC_ARG_ENABLE(werror,
1906   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1907   [case "${enableval}" in
1908      yes | y) ERROR_ON_WARNING="yes" ;;
1909      no | n)  ERROR_ON_WARNING="no" ;;
1910      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1911    esac])
1912
1913 # Enable -Werror by default when using gcc.  Turn it off for releases.
1914 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1915     ERROR_ON_WARNING=yes
1916 fi
1917
1918 WERROR_CFLAGS=""
1919 if test "${ERROR_ON_WARNING}" = yes ; then
1920     WERROR_CFLAGS="-Werror"
1921 fi
1922
1923 # The entries after -Wno-pointer-sign are disabled warnings which may
1924 # be enabled in the future, which can not currently be used to build
1925 # GDB.
1926 # NOTE: If you change this list, remember to update
1927 # gdb/doc/gdbint.texinfo.
1928 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1929 -Wformat-nonliteral -Wpointer-sign \
1930 -Wno-unused -Wunused-value -Wunused-function \
1931 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1932 -Wdeclaration-after-statement -Wempty-body"
1933
1934 # Enable -Wno-format by default when using gcc on mingw since many
1935 # GCC versions complain about %I64.
1936 case "${host}" in
1937   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1938 esac
1939
1940 AC_ARG_ENABLE(build-warnings,
1941 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1942 [case "${enableval}" in
1943   yes)  ;;
1944   no)   build_warnings="-w";;
1945   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1946         build_warnings="${build_warnings} ${t}";;
1947   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1948         build_warnings="${t} ${build_warnings}";;
1949   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1950 esac
1951 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1952   echo "Setting compiler warning flags = $build_warnings" 6>&1
1953 fi])dnl
1954 AC_ARG_ENABLE(gdb-build-warnings,
1955 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1956 [case "${enableval}" in
1957   yes)  ;;
1958   no)   build_warnings="-w";;
1959   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1960         build_warnings="${build_warnings} ${t}";;
1961   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1962         build_warnings="${t} ${build_warnings}";;
1963   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1964 esac
1965 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1966   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1967 fi])dnl
1968 WARN_CFLAGS=""
1969 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1970 then
1971     AC_MSG_CHECKING(compiler warning flags)
1972     # Separate out the -Werror flag as some files just cannot be
1973     # compiled with it enabled.
1974     for w in ${build_warnings}; do
1975         case $w in
1976         -Werr*) WERROR_CFLAGS=-Werror ;;
1977         *) # Check that GCC accepts it
1978             saved_CFLAGS="$CFLAGS"
1979             CFLAGS="$CFLAGS $w"
1980             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1981             CFLAGS="$saved_CFLAGS"
1982         esac
1983     done
1984     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1985 fi
1986 AC_SUBST(WARN_CFLAGS)
1987 AC_SUBST(WERROR_CFLAGS)
1988
1989 # In the Cygwin environment, we need some additional flags.
1990 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1991 [AC_EGREP_CPP(lose, [
1992 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1993 lose
1994 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1995
1996
1997 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1998 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1999 case ${host} in
2000   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2001   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2002   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2003 esac
2004 AC_SUBST(SER_HARDWIRE)
2005
2006 # libreadline needs libuser32.a in a cygwin environment
2007 WIN32LIBS=
2008 if test x$gdb_cv_os_cygwin = xyes; then
2009     WIN32LIBS="-luser32"
2010     case "${target}" in
2011         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2012         ;;
2013     esac
2014 fi
2015
2016 # The ser-tcp.c module requires sockets.
2017 case ${host} in
2018   *mingw32*)
2019     AC_DEFINE(USE_WIN32API, 1,
2020               [Define if we should use the Windows API, instead of the
2021                POSIX API.  On Windows, we use the Windows API when
2022                building for MinGW, but the POSIX API when building
2023                for Cygwin.])
2024     WIN32LIBS="$WIN32LIBS -lws2_32"
2025     ;;
2026 esac
2027 AC_SUBST(WIN32LIBS)
2028
2029 # Add ELF support to GDB, but only if BFD includes ELF support.
2030 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2031                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2032 if test $gdb_cv_var_elf = yes; then
2033   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2034   AC_DEFINE(HAVE_ELF, 1,
2035             [Define if ELF support should be included.])
2036   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2037   if test "$plugins" = "yes"; then
2038     LIBS="-ldl $LIBS"
2039   fi
2040 fi
2041
2042 # Add macho support to GDB, but only if BFD includes it.
2043 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2044                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2045 if test $gdb_cv_var_macho = yes; then
2046   CONFIG_OBS="$CONFIG_OBS machoread.o"
2047 fi
2048
2049 # Add SOM support to GDB, but only if BFD includes it.
2050 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2051                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2052 if test $gdb_cv_var_som = yes; then
2053   CONFIG_OBS="$CONFIG_OBS somread.o"
2054 fi
2055
2056 # Add any host-specific objects to GDB.
2057 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2058
2059 # If building on ELF, look for lzma support for embedded compressed debug info.
2060 if test $gdb_cv_var_elf = yes; then
2061   AC_ARG_WITH(lzma,
2062     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2063     [], [with_lzma=auto])
2064   AC_MSG_CHECKING([whether to use lzma])
2065   AC_MSG_RESULT([$with_lzma])
2066
2067   if test "${with_lzma}" != no; then
2068     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2069                           [lzma_index_iter iter;
2070                            lzma_index_iter_init (&iter, 0);
2071                            lzma_mf_is_supported (LZMA_MF_HC3);])
2072     if test "$HAVE_LIBLZMA" != yes; then
2073       if test "$with_lzma" = yes; then
2074         AC_MSG_ERROR([missing liblzma for --with-lzma])
2075       fi
2076     fi
2077   fi
2078 fi
2079
2080 LIBGUI="../libgui/src/libgui.a"
2081 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2082 AC_SUBST(LIBGUI)
2083 AC_SUBST(GUI_CFLAGS_X)
2084
2085 WIN32LDAPP=
2086 AC_SUBST(WIN32LIBS)
2087 AC_SUBST(WIN32LDAPP)
2088
2089 case "${host}" in
2090 *-*-cygwin* | *-*-mingw* )
2091     configdir="win"
2092     ;;
2093 *)
2094     configdir="unix"
2095     ;;
2096 esac
2097
2098 GDBTKLIBS=
2099 if test "${enable_gdbtk}" = "yes"; then
2100
2101     # Gdbtk must have an absolute path to srcdir in order to run
2102     # properly when not installed.
2103     here=`pwd`
2104     cd ${srcdir}
2105     GDBTK_SRC_DIR=`pwd`
2106     cd $here
2107
2108     SC_PATH_TCLCONFIG
2109
2110     # If $no_tk is nonempty, then we can't do Tk, and there is no
2111     # point to doing Tcl.
2112     SC_PATH_TKCONFIG
2113
2114     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2115         SC_LOAD_TCLCONFIG
2116
2117         # Check for in-tree tcl
2118         here=`pwd`
2119         cd ${srcdir}/..
2120         topdir=`pwd`
2121         cd ${here}
2122
2123         intree="no"
2124         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2125           intree="yes"
2126         fi
2127
2128         # Find Tcl private headers
2129         if test x"${intree}" = xno; then
2130           CY_AC_TCL_PRIVATE_HEADERS
2131           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2132           TCL_LIBRARY="${TCL_LIB_SPEC}"
2133           TCL_DEPS=""
2134         else
2135           # If building tcl in the same src tree, private headers
2136           # are not needed, but we need to be sure to use the right
2137           # headers library
2138           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2139           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2140           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2141         fi
2142         AC_SUBST(TCL_INCLUDE)
2143         AC_SUBST(TCL_LIBRARY)
2144         AC_SUBST(TCL_DEPS)
2145
2146         SC_LOAD_TKCONFIG
2147
2148         # Check for in-tree Tk
2149         intree="no"
2150         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2151           intree="yes"
2152         fi
2153
2154         # Find Tk private headers
2155         if test x"${intree}" = xno; then
2156           CY_AC_TK_PRIVATE_HEADERS
2157           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2158           TK_LIBRARY=${TK_LIB_SPEC}
2159           TK_DEPS=""
2160         else
2161           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2162           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2163           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2164         fi
2165         AC_SUBST(TK_INCLUDE)
2166         AC_SUBST(TK_LIBRARY)
2167         AC_SUBST(TK_DEPS)
2168         AC_SUBST(TK_XINCLUDES)
2169
2170         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2171
2172         # Include some libraries that Tcl and Tk want.
2173         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2174         # Yes, the ordering seems wrong here.  But it isn't.
2175         # TK_LIBS is the list of libraries that need to be linked
2176         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2177         # were in LIBS then any link tests after this point would
2178         # try to include things like `$(LIBGUI)', which wouldn't work.
2179         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2180
2181         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2182         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2183         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2184         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2185         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2186         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2187         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2188
2189         if test x$gdb_cv_os_cygwin = xyes; then
2190           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2191           WIN32LDAPP="-Wl,--subsystem,console"
2192           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2193         fi
2194
2195         AC_CONFIG_SUBDIRS(gdbtk)
2196     fi
2197 fi
2198
2199 AC_SUBST(X_CFLAGS)
2200 AC_SUBST(X_LDFLAGS)
2201 AC_SUBST(X_LIBS)
2202 AC_SUBST(GDBTKLIBS)
2203 AC_SUBST(GDBTK_CFLAGS)
2204 AC_SUBST(GDBTK_SRC_DIR)
2205
2206 AC_PATH_X
2207
2208 # Unlike the sim directory, whether a simulator is linked is controlled by
2209 # presence of a gdb_sim definition in the target configure.tgt entry.
2210 # This code just checks for a few cases where we'd like to ignore those
2211 # definitions, even when they're present in the '.mt' file.  These cases
2212 # are when --disable-sim is specified, or if the simulator directory is
2213 # not part of the source tree.
2214 #
2215 AC_ARG_ENABLE(sim,
2216 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2217 [echo "enable_sim = $enable_sim";
2218  echo "enableval = ${enableval}";
2219  case "${enableval}" in
2220   yes) ignore_sim=false ;;
2221   no)  ignore_sim=true ;;
2222   *)   ignore_sim=false ;;
2223  esac],
2224 [ignore_sim=false])
2225
2226 if test ! -d "${srcdir}/../sim"; then
2227   ignore_sim=true
2228 fi
2229
2230 SIM=
2231 SIM_OBS=
2232 if test "${ignore_sim}" = "false"; then
2233   if test x"${gdb_sim}" != x ; then
2234     SIM="${gdb_sim}"
2235     SIM_OBS="remote-sim.o"
2236     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2237   fi
2238 fi
2239 AC_SUBST(SIM)
2240 AC_SUBST(SIM_OBS)
2241
2242 AC_SUBST(ENABLE_CFLAGS)
2243 AC_SUBST(PROFILE_CFLAGS)
2244
2245 AC_SUBST(CONFIG_OBS)
2246 AC_SUBST(CONFIG_DEPS)
2247 AC_SUBST(CONFIG_SRCS)
2248 AC_SUBST(CONFIG_ALL)
2249 AC_SUBST(CONFIG_CLEAN)
2250 AC_SUBST(CONFIG_INSTALL)
2251 AC_SUBST(CONFIG_UNINSTALL)
2252
2253 # List of host floatformats.
2254 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2255 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2256 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2257
2258 # target_subdir is used by the testsuite to find the target libraries.
2259 target_subdir=
2260 if test "${host}" != "${target}"; then
2261     target_subdir="${target_alias}/"
2262 fi
2263 AC_SUBST(target_subdir)
2264
2265 frags=
2266 if test "${gdb_native}" = "yes"; then
2267   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2268   if test ! -f ${host_makefile_frag}; then
2269     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2270   fi
2271   frags="$frags $host_makefile_frag"
2272 else
2273   host_makefile_frag=/dev/null
2274 fi
2275
2276 AC_SUBST_FILE(host_makefile_frag)
2277 AC_SUBST(frags)
2278
2279 changequote(,)dnl
2280 if test "${gdb_native}" = "yes"; then
2281 # We pick this up from the host configuration file (.mh) because we
2282 # do not have a native configuration Makefile fragment.
2283 nativefile=`sed -n '
2284 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2285 ' ${host_makefile_frag}`
2286 fi
2287 changequote([,])
2288
2289 if test x"${gdb_osabi}" != x ; then
2290     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2291                        [Define to the default OS ABI for this configuration.])
2292 fi
2293
2294 # Enable multi-ice-gdb-server.
2295 AC_ARG_ENABLE(multi-ice,
2296 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2297   [case $enableval in
2298     yes | no)
2299       ;;
2300     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2301   esac])
2302 if test "x$enable_multi_ice" = xyes; then
2303    AC_CONFIG_SUBDIRS(multi-ice)
2304 fi
2305
2306 AC_ARG_ENABLE(gdbserver,
2307 AS_HELP_STRING([--enable-gdbserver],
2308                [automatically build gdbserver (yes/no/auto, default is auto)]),
2309 [case "${enableval}" in
2310   yes| no|auto) ;;
2311   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2312 esac],[enable_gdbserver=auto])
2313
2314 # We only build gdbserver automatically in a native configuration, and
2315 # only if the user did not explicitly disable its build.
2316 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2317   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2318   if test "x$build_gdbserver" = xyes; then
2319     AC_MSG_RESULT(yes)
2320     AC_CONFIG_SUBDIRS(gdbserver)
2321     gdbserver_build_enabled=yes
2322   else
2323     AC_MSG_RESULT(no)
2324   fi
2325 fi
2326
2327 # If the user explicitly request the gdbserver to be built, verify that
2328 # we were in fact able to enable it.
2329 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2330   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2331 fi
2332
2333 # Check for babeltrace and babeltrace-ctf
2334 AC_ARG_WITH(babeltrace,
2335   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2336   [], [with_babeltrace=auto])
2337 AC_MSG_CHECKING([whether to use babeltrace])
2338 AC_MSG_RESULT([$with_babeltrace])
2339
2340 if test "x$with_babeltrace" = "xno"; then
2341   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2342 else
2343   # Append -Werror to CFLAGS so that configure can catch the warning
2344   # "assignment from incompatible pointer type", which is related to
2345   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2346   # in GDB, while babeltrace 1.0.3 is broken.
2347   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2348   # safe to save and restore CFLAGS here.
2349   saved_CFLAGS=$CFLAGS
2350   CFLAGS="$CFLAGS -Werror"
2351   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2352                         [#include <babeltrace/babeltrace.h>
2353                          #include <babeltrace/ctf/events.h>
2354                          #include <babeltrace/ctf/iterator.h>],
2355                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2356                         struct bt_ctf_event *event = NULL;
2357                         const struct bt_definition *scope;
2358
2359                         scope = bt_ctf_get_top_level_scope (event,
2360                                                            BT_STREAM_EVENT_HEADER);
2361                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2362                         ])
2363   CFLAGS=$saved_CFLAGS
2364
2365   if test "$HAVE_LIBBABELTRACE" != yes; then
2366      if test "$with_babeltrace" = yes; then
2367        AC_MSG_ERROR([babeltrace is missing or unusable])
2368      else
2369        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2370      fi
2371   fi
2372 fi
2373
2374 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2375 # to an empty version.
2376
2377 files=
2378 links=
2379
2380 rm -f nm.h
2381 if test "${nativefile}" != ""; then
2382     case "${nativefile}" in
2383       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2384       * ) GDB_NM_FILE="${nativefile}"
2385     esac
2386     files="${files} ${GDB_NM_FILE}"
2387     links="${links} nm.h"
2388     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2389 fi
2390 AC_SUBST(GDB_NM_FILE)
2391
2392 AC_LINK_FILES($files, $links)
2393
2394 dnl Check for exe extension set on certain hosts (e.g. Win32)
2395 AC_EXEEXT
2396
2397 dnl  Detect the character set used by this host.
2398 dnl  At the moment, we just assume it's UTF-8.
2399 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2400           [Define to be a string naming the default host character set.])
2401
2402 # Undo the $ec_script escaping suitable for Makefile.
2403 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2404 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2405 if test "x$GDB_TRANSFORM_NAME" = x; then
2406   GDB_TRANSFORM_NAME=gdb
2407 fi
2408 AC_SUBST(GDB_TRANSFORM_NAME)
2409 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2410 if test "x$GCORE_TRANSFORM_NAME" = x; then
2411   GCORE_TRANSFORM_NAME=gcore
2412 fi
2413 AC_SUBST(GCORE_TRANSFORM_NAME)
2414 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2415
2416 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2417 [
2418 case x$CONFIG_HEADERS in
2419 xconfig.h:config.in)
2420 echo > stamp-h ;;
2421 esac
2422 ])
2423
2424 exit 0