gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2019 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADER(config.h:config.in)
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 dnl List of object files and targets accumulated by configure.
  49
  50 CONFIG_OBS=
  51 CONFIG_DEPS=
  52 CONFIG_SRCS=
  53 ENABLE_CFLAGS=
  54
  55 CONFIG_ALL=
  56 CONFIG_CLEAN=
  57 CONFIG_INSTALL=
  58 CONFIG_UNINSTALL=
  59
  60 dnl Set up for gettext.
  61 ZW_GNU_GETTEXT_SISTER_DIR
  62
  63 localedir='${datadir}/locale'
  64 AC_SUBST(localedir)
  65
  66 if test x"$USE_NLS" = xyes; then
  67    CONFIG_ALL="$CONFIG_ALL all-po"
  68    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  69    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  70    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  71 fi
  72
  73 PACKAGE=gdb
  74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  75 AC_SUBST(PACKAGE)
  76
  77 # We never need to detect it in this sub-configure.
  78 # But preserve it for config.status --recheck.
  79 AC_ARG_VAR(MAKEINFO,
  80   [Parent configure detects if it is of sufficient version.])
  81 AC_ARG_VAR(MAKEINFOFLAGS,
  82   [Parameters for MAKEINFO.])
  83
  84 MAKEINFO_EXTRA_FLAGS=""
  85 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  86   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  87   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  88     gdb_cv_have_makeinfo_click=yes
  89   else
  90     gdb_cv_have_makeinfo_click=no
  91   fi])
  92 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
  93   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
  94 fi
  95 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
  96
  97 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  98     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  99     [${libdir}/debug])
 100
 101 # We can't pass paths as command line arguments.
 102 # Mingw32 tries to be clever and will convert the paths for us.
 103 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 104 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 105 # This breaks GDB's relocatable path conversions since paths passed in
 106 # config.h would not get so translated, the path prefixes no longer match.
 107 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 108
 109 # GDB's datadir relocation
 110
 111 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 112     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 113     [${datadir}/gdb])
 114
 115 AC_ARG_WITH(relocated-sources,
 116 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 117 [reloc_srcdir="${withval}"
 118  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 119               [Relocated directory for source files. ])
 120 ])
 121
 122 AC_MSG_CHECKING([for default auto-load directory])
 123 AC_ARG_WITH(auto-load-dir,
 124 AS_HELP_STRING([--with-auto-load-dir=PATH],
 125   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 126   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 127 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 128 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 129               [Directories from which to load auto-loaded scripts.])
 130 AC_MSG_RESULT([$with_auto_load_dir])
 131
 132 AC_MSG_CHECKING([for default auto-load safe-path])
 133 AC_ARG_WITH(auto-load-safe-path,
 134 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 135   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 136 AS_HELP_STRING([--without-auto-load-safe-path],
 137                [do not restrict auto-loaded files locations]),
 138     [if test "$with_auto_load_safe_path" = "no"; then
 139      with_auto_load_safe_path="/"
 140      fi],
 141 [with_auto_load_safe_path="$with_auto_load_dir"])
 142 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 143 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 144               [Directories safe to hold auto-loaded files.])
 145 AC_MSG_RESULT([$with_auto_load_safe_path])
 146
 147 AC_CONFIG_SUBDIRS(testsuite)
 148
 149 # Check whether to support alternative target configurations
 150 AC_ARG_ENABLE(targets,
 151 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 152 [case "${enableval}" in
 153   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 154             ;;
 155   no)       enable_targets= ;;
 156   *)        enable_targets=$enableval ;;
 157 esac])
 158
 159 # Check whether to enable 64-bit support on 32-bit hosts
 160 AC_ARG_ENABLE(64-bit-bfd,
 161 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 162 [case "${enableval}" in
 163   yes)  want64=true  ;;
 164   no)   want64=false ;;
 165   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 166 esac],[want64=false])dnl
 167
 168 # Provide defaults for some variables set by the per-host and per-target
 169 # configuration.
 170 gdb_host_obs=posix-hdep.o
 171
 172 if test "${target}" = "${host}"; then
 173   gdb_native=yes
 174 else
 175   gdb_native=no
 176 fi
 177
 178 . $srcdir/configure.host
 179
 180 # Add in the common host objects.
 181 . $srcdir/common/common.host
 182 gdb_host_obs="$gdb_host_obs $common_host_obs"
 183
 184 # Accumulate some settings from configure.tgt over all enabled targets
 185
 186 TARGET_OBS=
 187 all_targets=
 188 HAVE_NATIVE_GCORE_TARGET=
 189
 190 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 191 do
 192   if test "$targ_alias" = "all"; then
 193     all_targets=true
 194   else
 195     # Canonicalize the secondary target names.
 196     result=`$ac_config_sub $targ_alias 2>/dev/null`
 197     if test -n "$result"; then
 198         targ=$result
 199     else
 200         targ=$targ_alias
 201     fi
 202
 203     . ${srcdir}/configure.tgt
 204
 205     AS_IF([test -z "${gdb_target_obs}"],
 206       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 207
 208     # Target-specific object files
 209     for i in ${gdb_target_obs}; do
 210         case " $TARGET_OBS " in
 211         *" ${i} "*) ;;
 212         *)
 213           TARGET_OBS="$TARGET_OBS ${i}"
 214           ;;
 215         esac
 216     done
 217
 218     # Check whether this target needs 64-bit CORE_ADDR
 219     if test x${want64} = xfalse; then
 220       . ${srcdir}/../bfd/config.bfd
 221     fi
 222
 223     # Check whether this target is native and supports gcore.
 224     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 225        && $gdb_have_gcore; then
 226       HAVE_NATIVE_GCORE_TARGET=1
 227     fi
 228   fi
 229 done
 230
 231 if test x${all_targets} = xtrue; then
 232
 233   # We want all 64-bit targets if we either:
 234   #  - run on a 64-bit host  or
 235   #  - already require 64-bit support for some other target  or
 236   #  - the --enable-64-bit-bfd option was supplied
 237   # Otherwise we only support all 32-bit targets.
 238   #
 239   # NOTE: This test must be in sync with the corresponding
 240   #       tests in BFD!
 241
 242   if test x${want64} = xfalse; then
 243     AC_CHECK_SIZEOF(long)
 244     if test "x${ac_cv_sizeof_long}" = "x8"; then
 245       want64=true
 246     fi
 247   fi
 248   if test x${want64} = xtrue; then
 249     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 250   else
 251     TARGET_OBS='$(ALL_TARGET_OBS)'
 252   fi
 253 fi
 254
 255 AC_SUBST(TARGET_OBS)
 256 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 257
 258 # For other settings, only the main target counts.
 259 gdb_sim=
 260 gdb_osabi=
 261 build_gdbserver=
 262 targ=$target; . ${srcdir}/configure.tgt
 263
 264 # Fetch the default architecture and default target vector from BFD.
 265 targ=$target; . $srcdir/../bfd/config.bfd
 266
 267 # We only want the first architecture, so strip off the others if
 268 # there is more than one.
 269 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 270
 271 if test "x$targ_archs" != x; then
 272   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 273     [Define to BFD's default architecture. ])
 274 fi
 275 if test "x$targ_defvec" != x; then
 276   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 277     [Define to BFD's default target vector. ])
 278 fi
 279
 280 # Enable MI.
 281 AC_ARG_ENABLE(gdbmi,
 282 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 283   [case $enableval in
 284     yes | no)
 285       ;;
 286     *)
 287       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 288   esac],
 289   [enable_gdbmi=yes])
 290 if test x"$enable_gdbmi" = xyes; then
 291   if test -d $srcdir/mi; then
 292     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 293     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 294     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 295     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 296   fi
 297 fi
 298
 299 # Enable TUI.
 300 AC_ARG_ENABLE(tui,
 301 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 302   [case $enableval in
 303     yes | no | auto)
 304       ;;
 305     *)
 306       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 307   esac],enable_tui=auto)
 308
 309 # Enable gdbtk.
 310 AC_ARG_ENABLE(gdbtk,
 311 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 312   [case $enableval in
 313     yes | no)
 314       ;;
 315     *)
 316       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 317   esac],
 318   [if test -d $srcdir/gdbtk; then
 319     enable_gdbtk=yes
 320   else
 321     enable_gdbtk=no
 322   fi])
 323 # We unconditionally disable gdbtk tests on selected platforms.
 324 case $host_os in
 325   go32* | windows*)
 326     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 327     enable_gdbtk=no ;;
 328 esac
 329
 330 # Libunwind support for ia64.
 331
 332 AC_ARG_WITH(libunwind-ia64,
 333 AS_HELP_STRING([--with-libunwind-ia64],
 334                [use libunwind frame unwinding for ia64 targets]),,
 335             [with_libunwind_ia64=auto])
 336
 337 # Backward compatibility option.
 338 if test "${with_libunwind+set}" = set; then
 339   if test x"$with_libunwind_ia64" != xauto; then
 340     AC_MSG_ERROR(
 341       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 342   fi
 343   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 344   with_libunwind_ia64="$with_libunwind"
 345 fi
 346
 347 case "$with_libunwind_ia64" in
 348   yes | no)
 349     ;;
 350   auto)
 351     AC_CHECK_HEADERS(libunwind-ia64.h)
 352     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 353     ;;
 354   *)
 355     AC_MSG_ERROR(
 356       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 357     ;;
 358 esac
 359
 360 if test x"$with_libunwind_ia64" = xyes; then
 361   AC_CHECK_HEADERS(libunwind-ia64.h)
 362   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 363     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 364   fi
 365   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 366   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 367   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 368 fi
 369
 370 opt_curses=no
 371 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 372
 373 prefer_curses=no
 374 if test "$opt_curses" = "yes"; then
 375   prefer_curses=yes
 376 fi
 377
 378 # Profiling support.
 379 AC_ARG_ENABLE(profiling,
 380 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 381   [case $enableval in
 382     yes | no)
 383       ;;
 384     *)
 385       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 386   esac],
 387  [enable_profiling=no])
 388
 389 AC_CHECK_FUNCS(monstartup _mcleanup)
 390 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 391 [AC_TRY_LINK(
 392 [#include <stdlib.h>
 393 extern char _etext;
 394 ],
 395 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 396 if test $ac_cv_var__etext = yes; then
 397   AC_DEFINE(HAVE__ETEXT, 1,
 398             [Define to 1 if your system has the _etext variable. ])
 399 fi
 400 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 401 [AC_TRY_LINK(
 402 [#include <stdlib.h>
 403 extern char etext;
 404 ],
 405 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 406 if test $ac_cv_var_etext = yes; then
 407   AC_DEFINE(HAVE_ETEXT, 1,
 408             [Define to 1 if your system has the etext variable. ])
 409 fi
 410 if test "$enable_profiling" = yes ; then
 411   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 412     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 413   fi
 414   PROFILE_CFLAGS=-pg
 415   OLD_CFLAGS="$CFLAGS"
 416   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 417
 418   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 419     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 420      ac_cv_cc_supports_pg=no)])
 421
 422   if test $ac_cv_cc_supports_pg = no; then
 423     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 424   fi
 425
 426   CFLAGS="$OLD_CFLAGS"
 427 fi
 428
 429 CODESIGN_CERT=
 430 AC_ARG_ENABLE([codesign],
 431   AS_HELP_STRING([--enable-codesign=CERT],
 432                  [sign gdb with 'codesign -s CERT']),
 433   [CODESIGN_CERT=$enableval])
 434 AC_SUBST([CODESIGN_CERT])
 435
 436 ACX_PKGVERSION([GDB])
 437 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 438 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 439 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 440
 441 # --------------------- #
 442 # Checks for programs.  #
 443 # --------------------- #
 444
 445 AC_PROG_AWK
 446 AC_PROG_INSTALL
 447 AC_PROG_LN_S
 448 AC_PROG_RANLIB
 449 AC_PROG_YACC
 450
 451 AC_CHECK_TOOL(AR, ar)
 452 AC_CHECK_TOOL(DLLTOOL, dlltool)
 453 AC_CHECK_TOOL(WINDRES, windres)
 454
 455 case $host_os in
 456   gnu*)
 457     # Needed for GNU Hurd hosts.
 458     AC_CHECK_TOOL(MIG, mig)
 459     if test x"$MIG" = x; then
 460       AC_MSG_ERROR([MIG not found but required for $host hosts])
 461     fi
 462     ;;
 463 esac
 464
 465 # ---------------------- #
 466 # Checks for libraries.  #
 467 # ---------------------- #
 468
 469 # We might need to link with -lm; most simulators need it.
 470 AC_CHECK_LIB(m, main)
 471
 472 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 473 AC_SEARCH_LIBS(gethostbyname, nsl)
 474
 475 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 476 AC_SEARCH_LIBS(socketpair, socket)
 477
 478 # Link in zlib if we can.  This allows us to read compressed debug sections.
 479 AM_ZLIB
 480
 481 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 482 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 483 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 484   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 485             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 486
 487 # fbsd-nat.c can also use kinfo_getfile.
 488 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 489   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 490             [Define to 1 if your system has the kinfo_getfile function. ])])
 491
 492 AM_ICONV
 493
 494 # GDB may fork/exec the iconv program to get the list of supported character
 495 # sets.  Allow the user to specify where to find it.
 496 # There are several factors affecting the choice of option name:
 497 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 498 #   the build-time location of libiconv files.
 499 # - The program we need to find is iconv, which comes with glibc.  The user
 500 #   doesn't necessarily have libiconv installed.  Therefore naming this
 501 #   --with-libiconv-foo feels wrong.
 502 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 503 #   defined to work on directories not files (though it really doesn't know
 504 #   the difference).
 505 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 506 #   with --with-libiconv-prefix.
 507 # Putting these together is why the option name is --with-iconv-bin.
 508
 509 AC_ARG_WITH(iconv-bin,
 510 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 511 [iconv_bin="${withval}"
 512  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 513                     [Path of directory of iconv program.])
 514  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 515 ])
 516
 517 # For the TUI, we need enhanced curses functionality.
 518 if test x"$enable_tui" != xno; then
 519   prefer_curses=yes
 520 fi
 521
 522 curses_found=no
 523 if test x"$prefer_curses" = xyes; then
 524   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 525   # curses library because the latter might not provide all the
 526   # functionality we need.  However, this leads to problems on systems
 527   # where the linker searches /usr/local/lib, but the compiler doesn't
 528   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 529   # default installation of ncurses on alpha*-dec-osf* will lead to such
 530   # a situation.
 531   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 532
 533   if test "$ac_cv_search_waddstr" != no; then
 534     curses_found=yes
 535   fi
 536 fi
 537
 538 # Check whether we should enable the TUI, but only do so if we really
 539 # can.
 540 if test x"$enable_tui" != xno; then
 541   if test -d $srcdir/tui; then
 542     if test "$curses_found" != no; then
 543       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 544       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 545       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 546       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 547     else
 548       if test x"$enable_tui" = xyes; then
 549         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 550       else
 551         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 552       fi
 553     fi
 554   fi
 555 fi
 556
 557 # Since GDB uses Readline, we need termcap functionality.  In many
 558 # cases this will be provided by the curses library, but some systems
 559 # have a separate termcap library, or no curses library at all.
 560
 561 case $host_os in
 562   cygwin*)
 563     if test -d $srcdir/libtermcap; then
 564       LIBS="../libtermcap/libtermcap.a $LIBS"
 565       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 566     fi ;;
 567   go32* | *djgpp*)
 568     ac_cv_search_tgetent="none required"
 569     ;;
 570 esac
 571
 572 # These are the libraries checked by Readline.
 573 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 574
 575 if test "$ac_cv_search_tgetent" = no; then
 576   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 577 fi
 578
 579 AC_ARG_WITH([system-readline],
 580   [AS_HELP_STRING([--with-system-readline],
 581                   [use installed readline library])])
 582
 583 if test "$with_system_readline" = yes; then
 584   READLINE=-lreadline
 585   READLINE_DEPS=
 586   READLINE_CFLAGS=
 587   READLINE_TEXI_INCFLAG=
 588 else
 589   READLINE='$(READLINE_DIR)/libreadline.a'
 590   READLINE_DEPS='$(READLINE)'
 591   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 592   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 593 fi
 594 AC_SUBST(READLINE)
 595 AC_SUBST(READLINE_DEPS)
 596 AC_SUBST(READLINE_CFLAGS)
 597 AC_SUBST(READLINE_TEXI_INCFLAG)
 598
 599 # Generate jit-reader.h
 600
 601 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 602 TARGET_PTR=
 603
 604 AC_CHECK_SIZEOF(unsigned long long)
 605 AC_CHECK_SIZEOF(unsigned long)
 606 AC_CHECK_SIZEOF(unsigned __int128)
 607
 608 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 609   TARGET_PTR="unsigned long"
 610 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 611   TARGET_PTR="unsigned long long"
 612 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 613   TARGET_PTR="unsigned __int128"
 614 else
 615   TARGET_PTR="unsigned long"
 616 fi
 617
 618 AC_SUBST(TARGET_PTR)
 619 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 620
 621 AC_SEARCH_LIBS(dlopen, dl)
 622
 623 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 624                 [directory to load the JIT readers from],
 625                 [${libdir}/gdb])
 626
 627 AC_ARG_WITH(expat,
 628   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 629   [], [with_expat=auto])
 630 AC_MSG_CHECKING([whether to use expat])
 631 AC_MSG_RESULT([$with_expat])
 632
 633 if test "${with_expat}" = no; then
 634   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 635   HAVE_LIBEXPAT=no
 636 else
 637   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 638                         [XML_Parser p = XML_ParserCreate (0);])
 639   if test "$HAVE_LIBEXPAT" != yes; then
 640     if test "$with_expat" = yes; then
 641       AC_MSG_ERROR([expat is missing or unusable])
 642     else
 643       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 644     fi
 645   else
 646     save_LIBS=$LIBS
 647     LIBS="$LIBS $LIBEXPAT"
 648     AC_CHECK_FUNCS(XML_StopParser)
 649     LIBS=$save_LIBS
 650   fi
 651 fi
 652
 653 AC_ARG_WITH(mpfr,
 654   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 655   [], [with_mpfr=auto])
 656 AC_MSG_CHECKING([whether to use MPFR])
 657 AC_MSG_RESULT([$with_mpfr])
 658
 659 if test "${with_mpfr}" = no; then
 660   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 661   HAVE_LIBMPFR=no
 662 else
 663   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 664                         [mpfr_exp_t exp; mpfr_t x;
 665                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 666   if test "$HAVE_LIBMPFR" != yes; then
 667     if test "$with_mpfr" = yes; then
 668       AC_MSG_ERROR([MPFR is missing or unusable])
 669     else
 670       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 671     fi
 672   fi
 673 fi
 674
 675 # --------------------- #
 676 # Check for libpython.  #
 677 # --------------------- #
 678
 679 dnl Utility to simplify finding libpython.
 680 dnl $1 = pythonX.Y
 681 dnl $2 = the shell variable to assign the result to
 682 dnl      If libpython is found we store $version here.
 683 dnl $3 = additional flags to add to CPPFLAGS
 684 dnl $4 = additional flags to add to LIBS
 685
 686 AC_DEFUN([AC_TRY_LIBPYTHON],
 687 [
 688   version=$1
 689   define([have_libpython_var],$2)
 690   new_CPPFLAGS=$3
 691   new_LIBS=$4
 692   AC_MSG_CHECKING([for ${version}])
 693   save_CPPFLAGS=$CPPFLAGS
 694   save_LIBS=$LIBS
 695   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 696   LIBS="$new_LIBS $LIBS"
 697   found_usable_python=no
 698   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 699                                  [[Py_Initialize ();]])],
 700                  [have_libpython_var=${version}
 701                   found_usable_python=yes
 702                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 703                   PYTHON_LIBS=$new_LIBS])
 704   CPPFLAGS=$save_CPPFLAGS
 705   LIBS=$save_LIBS
 706   AC_MSG_RESULT([${found_usable_python}])
 707 ])
 708
 709 dnl There are several different values for --with-python:
 710 dnl
 711 dnl no -   Don't include python support.
 712 dnl yes -  Include python support, error if it's missing.
 713 dnl        If we find python in $PATH, use it to fetch configure options,
 714 dnl        otherwise assume the compiler can find it with no help from us.
 715 dnl        Python 2.7 and 2.6 are tried in turn.
 716 dnl auto - Same as "yes", but if python is missing from the system,
 717 dnl        fall back to "no".
 718 dnl /path/to/python/exec-prefix -
 719 dnl        Use the python located in this directory.
 720 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 721 dnl        the compilation parameters.  Otherwise use
 722 dnl        -I/path/to/python/exec-prefix/include,
 723 dnl        -L/path/to/python/exec-prefix/lib.
 724 dnl        Python 2.7 and 2.6 are tried in turn.
 725 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 726 dnl        but is deprecated.
 727 dnl /path/to/python/executable -
 728 dnl        Run python-config.py with this version of python to fetch the
 729 dnl        compilation parameters.
 730 dnl        NOTE: This needn't be the real python executable.
 731 dnl        In a cross-compilation scenario (build != host), this could be
 732 dnl        a shell script that provides what python-config.py provides for
 733 dnl        --ldflags, --includes, --exec-prefix.
 734 dnl python-executable -
 735 dnl        Find python-executable in $PATH, and then handle the same as
 736 dnl        /path/to/python/executable.
 737 dnl
 738 dnl If a python program is specified, it is used to run python-config.py and
 739 dnl is passed --ldflags, --includes, --exec-prefix.
 740
 741 AC_ARG_WITH(python,
 742   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 743   [], [with_python=auto])
 744 AC_MSG_CHECKING([whether to use python])
 745 AC_MSG_RESULT([$with_python])
 746
 747 if test "${with_python}" = no; then
 748   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 749   have_libpython=no
 750 else
 751   case "${with_python}" in
 752   [[\\/]]* | ?:[[\\/]]*)
 753     if test -d ${with_python}; then
 754       # Assume the python binary is ${with_python}/bin/python.
 755       python_prog="${with_python}/bin/python"
 756       python_prefix=
 757       # If python does not exit ${with_python}/bin, then try in
 758       # ${with_python}.  On Windows/MinGW, this is where the Python
 759       # executable is.
 760       if test ! -x "${python_prog}"; then
 761         python_prog="${with_python}/python"
 762         python_prefix=
 763       fi
 764       if test ! -x "${python_prog}"; then
 765         # Fall back to gdb 7.0/7.1 behaviour.
 766         python_prog=missing
 767         python_prefix=${with_python}
 768       fi
 769     elif test -x "${with_python}"; then
 770       # While we can't run python compiled for $host (unless host == build),
 771       # the user could write a script that provides the needed information,
 772       # so we support that.
 773       python_prog=${with_python}
 774       python_prefix=
 775     else
 776       AC_ERROR(invalid value for --with-python)
 777     fi
 778     ;;
 779   */*)
 780     # Disallow --with-python=foo/bar.
 781     AC_ERROR(invalid value for --with-python)
 782     ;;
 783   *)
 784     # The user has either specified auto, yes, or the name of the python
 785     # program assumed to be in $PATH.
 786     python_prefix=
 787     case "${with_python}" in
 788     yes | auto)
 789       if test ${build} = ${host}; then
 790         AC_PATH_PROG(python_prog_path, python, missing)
 791         if test "${python_prog_path}" = missing; then
 792           python_prog=missing
 793         else
 794           python_prog=${python_prog_path}
 795         fi
 796       else
 797         # Not much we can do except assume the cross-compiler will find the
 798         # right files.
 799         python_prog=missing
 800       fi
 801       ;;
 802     *)
 803       # While we can't run python compiled for $host (unless host == build),
 804       # the user could write a script that provides the needed information,
 805       # so we support that.
 806       python_prog="${with_python}"
 807       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 808       if test "${python_prog_path}" = missing; then
 809         AC_ERROR(unable to find python program ${python_prog})
 810       fi
 811       ;;
 812     esac
 813   esac
 814
 815   if test "${python_prog}" != missing; then
 816     # We have a python program to use, but it may be too old.
 817     # Don't flag an error for --with-python=auto (the default).
 818     have_python_config=yes
 819     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 820     if test $? != 0; then
 821       have_python_config=failed
 822       if test "${with_python}" != auto; then
 823         AC_ERROR(failure running python-config --includes)
 824       fi
 825     fi
 826     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 827     if test $? != 0; then
 828       have_python_config=failed
 829       if test "${with_python}" != auto; then
 830         AC_ERROR(failure running python-config --ldflags)
 831       fi
 832     fi
 833     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 834     if test $? != 0; then
 835       have_python_config=failed
 836       if test "${with_python}" != auto; then
 837         AC_ERROR(failure running python-config --exec-prefix)
 838       fi
 839     fi
 840   else
 841     # We do not have a python executable we can use to determine where
 842     # to find the Python headers and libs.  We cannot guess the include
 843     # path from the python_prefix either, because that include path
 844     # depends on the Python version.  So, there is nothing much we can
 845     # do except assume that the compiler will be able to find those files.
 846     python_includes=
 847     python_libs=
 848     have_python_config=no
 849   fi
 850
 851   # If we have python-config, only try the configuration it provides.
 852   # Otherwise fallback on the old way of trying different versions of
 853   # python in turn.
 854
 855   have_libpython=no
 856   if test "${have_python_config}" = yes; then
 857     # Determine the Python version by extracting "-lpython<version>"
 858     # part of the python_libs. <version> is usually X.Y with X and Y
 859     # being decimal numbers, but can also be XY (seen on Windows).
 860     #
 861     # The extraction is performed using sed with a regular expression.
 862     # Initially, the regexp used was using the '?' quantifier to make
 863     # the dot in the version number optional.  Unfortunately, this
 864     # does not work with non-GNU versions of sed because, because of
 865     # what looks like a limitation (the '?' quantifier does not work
 866     # with back-references).  We work around this limitation by using
 867     # the '*' quantifier instead.  It means that, in theory, we might
 868     # match unexpected version strings such as "-lpython2..7", but
 869     # this seems unlikely in practice.  And even if that happens,
 870     # an error will be triggered later on, when checking that version
 871     # number.
 872     python_version=`echo " ${python_libs} " \
 873                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 874     case "${python_version}" in
 875     python*)
 876       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 877                        ${python_includes}, ${python_libs})
 878       ;;
 879     *)
 880       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 881       ;;
 882     esac
 883   elif test "${have_python_config}" != failed; then
 884     if test "${have_libpython}" = no; then
 885       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 886                        ${python_includes}, "-lpython2.7 ${python_libs}")
 887     fi
 888     if test "${have_libpython}" = no; then
 889       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 890                        ${python_includes}, "-lpython2.6 ${python_libs}")
 891     fi
 892   fi
 893   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 894     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 895   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 896     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 897   fi
 898
 899   if test "${have_libpython}" = no; then
 900     case "${with_python}" in
 901     yes)
 902       AC_MSG_ERROR([python is missing or unusable])
 903       ;;
 904     auto)
 905       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 906       ;;
 907     *)
 908       AC_MSG_ERROR([no usable python found at ${with_python}])
 909       ;;
 910     esac
 911   else
 912     if test -n "${python_prefix}"; then
 913       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 914                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 915       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 916     fi
 917   fi
 918 fi
 919
 920 if test "${have_libpython}" != no; then
 921   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 922   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 923   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 924   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 925   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 926   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 927
 928   # Flags needed to compile Python code (taken from python-config --cflags).
 929   # We cannot call python-config directly because it will output whatever was
 930   # used when compiling the Python interpreter itself, including flags which
 931   # would make the python-related objects be compiled differently from the
 932   # rest of GDB (e.g., -O2 and -fPIC).
 933   if test "${GCC}" = yes; then
 934     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 935     # Python headers recommend -DNDEBUG, but it's unclear if that just
 936     # refers to building Python itself.  In release mode, though, it
 937     # doesn't hurt for the Python code in gdb to follow.
 938     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 939   fi
 940
 941   if test "x${tentative_python_cflags}" != x; then
 942     AC_MSG_CHECKING(compiler flags for python code)
 943     for flag in ${tentative_python_cflags}; do
 944       # Check that the compiler accepts it
 945       saved_CFLAGS="$CFLAGS"
 946       CFLAGS="$CFLAGS $flag"
 947       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 948       CFLAGS="$saved_CFLAGS"
 949     done
 950     AC_MSG_RESULT(${PYTHON_CFLAGS})
 951   fi
 952
 953   # On x64 Windows, Python's include headers, and pyconfig.h in
 954   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 955   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 956   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 957   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 958   # The issue was reported to the Python community, but still isn't
 959   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 960
 961   case "$gdb_host" in
 962     mingw64)
 963            if test "${GCC}" = yes; then
 964              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 965            fi
 966            ;;
 967   esac
 968
 969   # Note that "python -m threading" cannot be used to check for
 970   # threading support due to a bug in Python 2.7.3
 971   # (http://bugs.python.org/issue15567).
 972   AC_MSG_CHECKING(whether python supports threads)
 973   saved_CPPFLAGS="${CPPFLAGS}"
 974   CPPFLAGS="${PYTHON_CPPFLAGS}"
 975   # Note that the test is reversed so that python_has_threads=yes on
 976   # unexpected failures.
 977   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 978 #include <Python.h>
 979 #ifdef WITH_THREAD
 980 # error
 981 #endif
 982   ]])], [python_has_threads=no], [python_has_threads=yes])
 983   AC_MSG_RESULT(${python_has_threads})
 984   CPPFLAGS="${saved_CPPFLAGS}"
 985 else
 986   # Even if Python support is not compiled in, we need to have this file
 987   # included so that the "python" command, et.al., still exists.
 988   CONFIG_OBS="$CONFIG_OBS python/python.o"
 989   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
 990 fi
 991
 992 # Work around Python http://bugs.python.org/issue10112.  See also
 993 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
 994 # no effect.  Note that the only test after this that uses Python is
 995 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
 996 # run without -export-dynamic too.
 997 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
 998
 999 AC_SUBST(PYTHON_CFLAGS)
1000 AC_SUBST(PYTHON_CPPFLAGS)
1001 AC_SUBST(PYTHON_LIBS)
1002 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1003
1004 # -------------------- #
1005 # Check for libguile.  #
1006 # -------------------- #
1007
1008 dnl Utility to simplify finding libguile.
1009 dnl $1 = pkg-config-program
1010 dnl $2 = space-separate list of guile versions to try
1011 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1012 dnl $4 = the shell variable to assign the result to
1013 dnl      If libguile is found we store "yes" here.
1014
1015 AC_DEFUN([AC_TRY_LIBGUILE],
1016 [
1017   pkg_config=$1
1018   guile_version_list=$2
1019   flag_errors=$3
1020   define([have_libguile_var],$4)
1021   found_usable_guile=checking
1022   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1023   for guile_version in ${guile_version_list}; do
1024     ${pkg_config} --exists ${guile_version} 2>/dev/null
1025     if test $? != 0; then
1026       continue
1027     fi
1028     dnl pkg-config says the package exists, so if we get an error now,
1029     dnl that's bad.
1030     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1031     if test $? != 0; then
1032       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1033     fi
1034     new_LIBS=`${pkg_config} --libs ${guile_version}`
1035     if test $? != 0; then
1036       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1037     fi
1038     dnl If we get this far, great.
1039     found_usable_guile=${guile_version}
1040     break
1041   done
1042   if test "${found_usable_guile}" = "checking"; then
1043     if test "${flag_errors}" = "yes"; then
1044       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1045     else
1046       found_usable_guile=no
1047     fi
1048   fi
1049   dnl One final sanity check.
1050   dnl The user could have said --with-guile=python-2.7.
1051   if test "${found_usable_guile}" != no; then
1052     save_CPPFLAGS=$CPPFLAGS
1053     save_LIBS=$LIBS
1054     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1055     LIBS="$LIBS $new_LIBS"
1056     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1057                                    [[scm_init_guile ();]])],
1058                    [have_libguile_var=yes
1059                     GUILE_CPPFLAGS=$new_CPPFLAGS
1060                     GUILE_LIBS=$new_LIBS],
1061                    [found_usable_guile=no])
1062     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1063     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1064       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1065                 [Define if Guile supports manual finalization.])
1066     )
1067     CPPFLAGS=$save_CPPFLAGS
1068     LIBS=$save_LIBS
1069     if test "${found_usable_guile}" = no; then
1070       if test "${flag_errors}" = yes; then
1071         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1072       fi
1073     fi
1074   fi
1075   AC_MSG_RESULT([${found_usable_guile}])
1076 ])
1077
1078 dnl There are several different values for --with-guile:
1079 dnl
1080 dnl no -   Don't include guile support.
1081 dnl yes -  Include guile support, error if it's missing.
1082 dnl        The pkg-config program must be in $PATH.
1083 dnl auto - Same as "yes", but if guile is missing from the system,
1084 dnl        fall back to "no".
1085 dnl guile-version [guile-version-choice-2 ...] -
1086 dnl        A space-separated list of guile package versions to try.
1087 dnl        These are passed to pkg-config as-is.
1088 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1089 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1090 dnl /path/to/pkg-config -
1091 dnl        Use this pkg-config program.
1092 dnl        NOTE: This needn't be the "real" pkg-config program.
1093 dnl        It could be a shell script.  It is invoked as:
1094 dnl        pkg-config --exists $version
1095 dnl        pkg-config --cflags $version
1096 dnl        pkg-config --libs $version
1097 dnl        pkg-config --variable guild $version
1098 dnl        The script will be called with $version having each value in
1099 dnl        $try_guile_versions until --exists indicates success.
1100
1101 AC_ARG_WITH(guile,
1102   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1103   [], [with_guile=auto])
1104 AC_MSG_CHECKING([whether to use guile])
1105 AC_MSG_RESULT([$with_guile])
1106
1107 dnl We check guile with pkg-config.
1108 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1109
1110 try_guile_versions="guile-2.0"
1111 have_libguile=no
1112 case "${with_guile}" in
1113 no)
1114   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1115   ;;
1116 auto)
1117   if test "${pkg_config_prog_path}" = "missing"; then
1118     AC_MSG_WARN([pkg-config not found, guile support disabled])
1119   else
1120     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1121   fi
1122   ;;
1123 yes)
1124   if test "${pkg_config_prog_path}" = "missing"; then
1125     AC_MSG_ERROR([pkg-config not found])
1126   fi
1127   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1128   ;;
1129 [[\\/]]* | ?:[[\\/]]*)
1130   if test -x "${with_guile}"; then
1131     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1132   else
1133     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1134   fi
1135   ;;
1136 "" | */*)
1137   # Disallow --with=guile="" and --with-guile=foo/bar.
1138   AC_MSG_ERROR([invalid value for --with-guile])
1139   ;;
1140 *)
1141   # A space separate list of guile versions to try, in order.
1142   if test "${pkg_config_prog_path}" = "missing"; then
1143     AC_MSG_ERROR([pkg-config not found])
1144   fi
1145   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1146   ;;
1147 esac
1148
1149 if test "${have_libguile}" != no; then
1150   dnl Get the name of the 'guild' program.
1151   case "${with_guile}" in
1152   [[\\/]]* | ?:[[\\/]]*)
1153     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1154     ;;
1155   *)
1156     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1157     ;;
1158   esac
1159
1160   dnl Make sure guild can handle this host.
1161   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1162   dnl If not, disable guile support.
1163   if test "$ac_cv_guild_ok" = no; then
1164     have_libguile=no
1165     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1166   fi
1167 fi
1168
1169 if test "${have_libguile}" != no; then
1170   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1171   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1172   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1173   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1174   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1175   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1176
1177   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1178   save_LIBS="$LIBS"
1179   save_CPPFLAGS="$CPPFLAGS"
1180   LIBS="$GUILE_LIBS"
1181   CPPFLAGS="$GUILE_CPPFLAGS"
1182   AC_CHECK_FUNCS([scm_new_smob])
1183   LIBS="$save_LIBS"
1184   CPPFLAGS="$save_CPPFLAGS"
1185 else
1186   # Even if Guile support is not compiled in, we need to have these files
1187   # included.
1188   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1189   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1190 fi
1191 AC_SUBST(GUILE_CPPFLAGS)
1192 AC_SUBST(GUILE_LIBS)
1193 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1194
1195 # ---------------------------- #
1196 # Check for source highlight.  #
1197 # ---------------------------- #
1198
1199 SRCHIGH_LIBS=
1200 SRCHIGH_CFLAGS=
1201
1202 AC_ARG_ENABLE(source-highlight,
1203   AS_HELP_STRING([--enable-source-highlight],
1204     [enable source-highlight for source listings]),
1205   [case "${enableval}" in
1206   yes)  enable_source_highlight=yes ;;
1207   no)   enable_source_highlight=no  ;;
1208   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1209 esac],
1210 [enable_source_highlight=auto])
1211
1212 if test "${enable_source_highlight}" != "no"; then
1213   AC_MSG_CHECKING([for the source-highlight library])
1214   if test "${pkg_config_prog_path}" = "missing"; then
1215     AC_MSG_RESULT([no - pkg-config not found])
1216     if test "${enable_source_highlight}" = "yes"; then
1217       AC_MSG_ERROR([pkg-config was not found in your system])
1218     fi
1219   else
1220     if ${pkg_config_prog_path} --exists source-highlight; then
1221       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1222       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1223       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1224                 [Define to 1 if the source-highlight library is available])
1225       AC_MSG_RESULT([yes])
1226     else
1227       AC_MSG_RESULT([no])
1228       if test "${enable_source_highlight}" = "yes"; then
1229         AC_MSG_ERROR([source-highlight was not found in your system])
1230       fi
1231     fi
1232   fi
1233 fi
1234 AC_SUBST(SRCHIGH_LIBS)
1235 AC_SUBST(SRCHIGH_CFLAGS)
1236
1237 # --------------------- #
1238 # Check for libmcheck.  #
1239 # --------------------- #
1240
1241 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1242 # but turn it off if Python is enabled with threads, since -lmcheck is
1243 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1244 # and for releases.
1245 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1246    && $development; then
1247   libmcheck_default=yes
1248 else
1249   libmcheck_default=no
1250 fi
1251 GDB_AC_LIBMCHECK(${libmcheck_default})
1252
1253 if test "$ENABLE_LIBMCHECK" = "yes" \
1254         -a "${have_libpython}" != "no" \
1255         -a "${python_has_threads}" = "yes" ; then
1256   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1257 fi
1258
1259 AC_ARG_WITH(intel_pt,
1260   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1261   [], [with_intel_pt=auto])
1262 AC_MSG_CHECKING([whether to use intel pt])
1263 AC_MSG_RESULT([$with_intel_pt])
1264
1265 if test "${with_intel_pt}" = no; then
1266   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1267   HAVE_LIBIPT=no
1268 else
1269   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1270 #include <linux/perf_event.h>
1271 #ifndef PERF_ATTR_SIZE_VER5
1272 # error
1273 #endif
1274   ]])], [perf_event=yes], [perf_event=no])
1275   if test "$perf_event" != yes; then
1276     if test "$with_intel_pt" = yes; then
1277       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1278     else
1279       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1280     fi
1281   fi
1282
1283   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1284   if test "$HAVE_LIBIPT" != yes; then
1285     if test "$with_intel_pt" = yes; then
1286       AC_MSG_ERROR([libipt is missing or unusable])
1287     else
1288       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1289     fi
1290   else
1291     save_LIBS=$LIBS
1292     LIBS="$LIBS $LIBIPT"
1293     AC_CHECK_FUNCS(pt_insn_event)
1294     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1295                      [#include <intel-pt.h>])
1296     LIBS=$save_LIBS
1297   fi
1298 fi
1299
1300 # ------------------------- #
1301 # Checks for header files.  #
1302 # ------------------------- #
1303
1304 AC_HEADER_STDC
1305 # elf_hp.h is for HP/UX 64-bit shared library support.
1306 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1307                   thread_db.h linux/elf.h \
1308                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1309                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1310                   sys/reg.h sys/debugreg.h sys/select.h \
1311                   termios.h elf_hp.h \
1312                   dlfcn.h])
1313 AC_CHECK_HEADERS(sys/user.h, [], [],
1314 [#if HAVE_SYS_PARAM_H
1315 # include <sys/param.h>
1316 #endif
1317 ])
1318
1319 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1320 AC_CHECK_HEADERS(term.h, [], [],
1321 [#if HAVE_CURSES_H
1322 # include <curses.h>
1323 #endif
1324 ])
1325
1326 # ------------------------- #
1327 # Checks for declarations.  #
1328 # ------------------------- #
1329
1330 libiberty_INIT
1331
1332 AC_CHECK_DECLS([snprintf])
1333 AM_LC_MESSAGES
1334
1335 # ----------------------- #
1336 # Checks for structures.  #
1337 # ----------------------- #
1338
1339 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1340
1341 # ------------------ #
1342 # Checks for types.  #
1343 # ------------------ #
1344
1345 AC_CHECK_TYPES(socklen_t, [], [],
1346 [#include <sys/types.h>
1347 #include <sys/socket.h>
1348 ])
1349
1350 # ------------------------------------- #
1351 # Checks for compiler characteristics.  #
1352 # ------------------------------------- #
1353
1354 AC_C_CONST
1355 AC_C_INLINE
1356 AC_C_BIGENDIAN
1357
1358 # ------------------------------ #
1359 # Checks for library functions.  #
1360 # ------------------------------ #
1361
1362 AC_FUNC_MMAP
1363 AC_FUNC_VFORK
1364 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1365                 pipe poll pread pread64 pwrite resize_term \
1366                 sbrk getpgid setpgid setpgrp setsid \
1367                 sigaction sigprocmask sigsetmask socketpair \
1368                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1369                 setrlimit getrlimit posix_madvise waitpid \
1370                 ptrace64 sigaltstack setns use_default_colors])
1371 AM_LANGINFO_CODESET
1372 GDB_AC_COMMON
1373
1374 # Check the return and argument types of ptrace.
1375 GDB_AC_PTRACE
1376
1377 dnl AC_FUNC_SETPGRP does not work when cross compiling
1378 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1379 if test "$cross_compiling" = no; then
1380   AC_FUNC_SETPGRP
1381 else
1382   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1383     [AC_TRY_COMPILE([
1384 #include <unistd.h>
1385 ], [
1386   if (setpgrp(1,1) == -1)
1387     exit (0);
1388   else
1389     exit (1);
1390 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1391 if test $ac_cv_func_setpgrp_void = yes; then
1392   AC_DEFINE(SETPGRP_VOID, 1)
1393 fi
1394 fi
1395
1396 # Assume we'll default to using the included libiberty regex.
1397 gdb_use_included_regex=yes
1398
1399 # However, if the system regex is GNU regex, then default to *not*
1400 # using the included regex.
1401 AC_CACHE_CHECK(
1402   [for GNU regex],
1403   [gdb_cv_have_gnu_regex],
1404   [AC_TRY_COMPILE(
1405     [#include <gnu-versions.h>],
1406     [#define REGEX_INTERFACE_VERSION 1
1407 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1408 # error "Version mismatch"
1409 #endif],
1410     gdb_cv_have_gnu_regex=yes,
1411     gdb_cv_have_gnu_regex=no)])
1412 if test $gdb_cv_have_gnu_regex = yes; then
1413   gdb_use_included_regex=no
1414 fi
1415
1416 AC_ARG_WITH(included-regex,
1417   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1418   gdb_with_regex=$withval,
1419   gdb_with_regex=$gdb_use_included_regex)
1420 if test "$gdb_with_regex" = yes; then
1421   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1422     [Define to 1 if the regex included in libiberty should be used.])
1423 fi
1424
1425 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1426 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1427 [#include <sys/param.h>
1428 #include <sys/proc.h>
1429 ])
1430
1431 # See if <sys/lwp.h> defines `struct lwp`.
1432 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1433 [AC_TRY_COMPILE([#include <sys/param.h>
1434 #define _KMEMUSER
1435 #include <sys/lwp.h>], [struct lwp l;],
1436 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1437 if test $gdb_cv_struct_lwp = yes; then
1438   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1439             [Define to 1 if your system has struct lwp.])
1440 fi
1441
1442 # See if <machine/reg.h> degines `struct reg'.
1443 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1444 [AC_TRY_COMPILE([#include <sys/types.h>
1445 #include <machine/reg.h>], [struct reg r;],
1446 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1447 if test $gdb_cv_struct_reg = yes; then
1448   AC_DEFINE(HAVE_STRUCT_REG, 1,
1449             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1450 fi
1451
1452 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1453 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1454 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1455                  [#include <sys/types.h>
1456 #include <machine/reg.h>])
1457
1458 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1459 # Older amd64 Linux's don't have the fs_base and gs_base members of
1460 # `struct user_regs_struct'.
1461 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1462      [], [], [#include <sys/types.h>
1463 #include <sys/user.h>])
1464
1465 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1466 AC_MSG_CHECKING(for PTRACE_GETREGS)
1467 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1468 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1469                 [PTRACE_GETREGS;],
1470                 [gdb_cv_have_ptrace_getregs=yes],
1471                 [gdb_cv_have_ptrace_getregs=no])])
1472 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1473 if test $gdb_cv_have_ptrace_getregs = yes; then
1474   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1475   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1476 fi
1477
1478 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1479 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1480 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1481 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1482                 [PTRACE_GETFPXREGS;],
1483                 [gdb_cv_have_ptrace_getfpxregs=yes],
1484                 [gdb_cv_have_ptrace_getfpxregs=no])])
1485 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1486 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1487   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1488   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1489 fi
1490
1491 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1492 AC_MSG_CHECKING(for PT_GETDBREGS)
1493 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1494 [AC_TRY_COMPILE([#include <sys/types.h>
1495 #include <sys/ptrace.h>],
1496                 [PT_GETDBREGS;],
1497                 [gdb_cv_have_pt_getdbregs=yes],
1498                 [gdb_cv_have_pt_getdbregs=no])])
1499 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1500 if test $gdb_cv_have_pt_getdbregs = yes; then
1501   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1502   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1503 fi
1504
1505 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1506 AC_MSG_CHECKING(for PT_GETXMMREGS)
1507 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1508 [AC_TRY_COMPILE([#include <sys/types.h>
1509 #include <sys/ptrace.h>],
1510                 [PT_GETXMMREGS;],
1511                 [gdb_cv_have_pt_getxmmregs=yes],
1512                 [gdb_cv_have_pt_getxmmregs=no])])
1513 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1514 if test $gdb_cv_have_pt_getxmmregs = yes; then
1515   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1516   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1517 fi
1518
1519 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1520 # Older FreeBSD versions don't have the pl_tdname member of
1521 # `struct ptrace_lwpinfo'.
1522 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1523                  [#include <sys/ptrace.h>])
1524
1525 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1526 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1527 # FreeBSD 10.3.
1528 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1529                  [#include <sys/ptrace.h>])
1530
1531 if test "$ac_cv_header_sys_procfs_h" = yes; then
1532   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1533   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1534   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1535   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1536   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1537   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1538   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1539   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
1540 fi
1541
1542 # Check if the compiler supports the `long long' type.
1543
1544 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1545                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1546 [[extern long long foo;]],
1547 [[switch (foo & 2) { case 0: return 1; }]])],
1548                                   gdb_cv_c_long_long=yes,
1549                                   gdb_cv_c_long_long=no)])
1550 if test $gdb_cv_c_long_long != yes; then
1551   # libdecnumber requires long long.
1552   AC_MSG_ERROR([Compiler must support long long for GDB.])
1553 fi
1554
1555 # Check if the compiler and runtime support printing long longs.
1556
1557 AC_CACHE_CHECK([for long long support in printf],
1558                gdb_cv_printf_has_long_long,
1559                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1560 [[char buf[32];
1561   long long l = 0;
1562   l = (l << 16) + 0x0123;
1563   l = (l << 16) + 0x4567;
1564   l = (l << 16) + 0x89ab;
1565   l = (l << 16) + 0xcdef;
1566   sprintf (buf, "0x%016llx", l);
1567   return (strcmp ("0x0123456789abcdef", buf));]])],
1568                               gdb_cv_printf_has_long_long=yes,
1569                               gdb_cv_printf_has_long_long=no,
1570                               gdb_cv_printf_has_long_long=no)])
1571 if test $gdb_cv_printf_has_long_long = yes; then
1572   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1573             [Define to 1 if the "%ll" format works to print long longs.])
1574 fi
1575
1576 # Check if the compiler and runtime support printing decfloats.
1577
1578 AC_CACHE_CHECK([for decfloat support in printf],
1579                gdb_cv_printf_has_decfloat,
1580                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1581 [[char buf[64];
1582   _Decimal32 d32 = 1.2345df;
1583   _Decimal64 d64 = 1.2345dd;
1584   _Decimal128 d128 = 1.2345dl;
1585   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1586   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1587                               gdb_cv_printf_has_decfloat=yes,
1588                               gdb_cv_printf_has_decfloat=no,
1589                               gdb_cv_printf_has_decfloat=no)])
1590 if test $gdb_cv_printf_has_decfloat = yes; then
1591   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1592             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1593 fi
1594
1595 # Check if the compiler supports the `long double' type.  We can't use
1596 # AC_C_LONG_DOUBLE because that one does additional checks on the
1597 # constants defined in <float.h> that fail on some systems,
1598 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1599
1600 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1601                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1602                                   gdb_cv_c_long_double=yes,
1603                                   gdb_cv_c_long_double=no)])
1604 if test $gdb_cv_c_long_double = yes; then
1605   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1606            [Define to 1 if the compiler supports long double.])
1607 fi
1608
1609 # Check if the compiler and runtime support printing long doubles.
1610
1611 AC_CACHE_CHECK([for long double support in printf],
1612                gdb_cv_printf_has_long_double,
1613                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1614 [[char buf[16];
1615   long double f = 3.141592653;
1616   sprintf (buf, "%Lg", f);
1617   return (strncmp ("3.14159", buf, 7));]])],
1618                               gdb_cv_printf_has_long_double=yes,
1619                               gdb_cv_printf_has_long_double=no,
1620                               gdb_cv_printf_has_long_double=no)])
1621 if test $gdb_cv_printf_has_long_double = yes; then
1622   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1623             [Define to 1 if the "%Lg" format works to print long doubles.])
1624 fi
1625
1626 # Check if the compiler and runtime support scanning long doubles.
1627
1628 AC_CACHE_CHECK([for long double support in scanf],
1629                gdb_cv_scanf_has_long_double,
1630                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1631 [[#include <stdio.h>]],
1632 [[char *buf = "3.141592653";
1633   long double f = 0;
1634   sscanf (buf, "%Lg", &f);
1635   return !(f > 3.14159 && f < 3.14160);]])],
1636                               gdb_cv_scanf_has_long_double=yes,
1637                               gdb_cv_scanf_has_long_double=no,
1638                               gdb_cv_scanf_has_long_double=no)])
1639 if test $gdb_cv_scanf_has_long_double = yes; then
1640   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1641             [Define to 1 if the "%Lg" format works to scan long doubles.])
1642 fi
1643
1644 case ${host_os} in
1645 aix*)
1646   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1647     SAVE_LDFLAGS=$LDFLAGS
1648
1649     case $GCC in
1650     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1651     *) gdb_cv_bigtoc=-bbigtoc ;;
1652     esac
1653
1654     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1655     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1656     LDFLAGS="${SAVE_LDFLAGS}"
1657   ])
1658   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1659   ;;
1660 esac
1661
1662 AC_MSG_CHECKING(for the dynamic export flag)
1663 dynamic_list=false
1664 if test "${gdb_native}" = yes; then
1665    # The dynamically loaded libthread_db needs access to symbols in the gdb
1666    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1667    # may not be supported there.
1668    old_LDFLAGS="$LDFLAGS"
1669    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1670    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1671    LDFLAGS="$LDFLAGS $RDYNAMIC"
1672    if test "${have_libpython}" = no; then
1673      AC_TRY_LINK([], [], [dynamic_list=true])
1674    else
1675      # Workaround http://bugs.python.org/issue4434 where static
1676      # libpythonX.Y.a would get its symbols required for
1677      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1678      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1679
1680      # Note the workaround for Python
1681      # http://bugs.python.org/issue10112 earlier has removed
1682      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1683      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1684      # always pass.
1685      old_CFLAGS="$CFLAGS"
1686      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1687      old_LIBS="$LIBS"
1688      LIBS="$LIBS $PYTHON_LIBS"
1689      old_CPPFLAGS="$CPPFLAGS"
1690      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1691      AC_RUN_IFELSE(
1692        [AC_LANG_PROGRAM(
1693          [#include "Python.h"],
1694          [int err;
1695           Py_Initialize ();
1696           err = PyRun_SimpleString ("import itertools\n");
1697           Py_Finalize ();
1698           return err == 0 ? 0 : 1;])],
1699        [dynamic_list=true], [], [true])
1700      LIBS="$old_LIBS"
1701      CFLAGS="$old_CFLAGS"
1702      CPPFLAGS="$old_CPPFLAGS"
1703    fi
1704    LDFLAGS="$old_LDFLAGS"
1705 fi
1706 if $dynamic_list; then
1707   found="-Wl,--dynamic-list"
1708   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1709 else
1710   found="-rdynamic"
1711   RDYNAMIC="-rdynamic"
1712 fi
1713 AC_SUBST(RDYNAMIC)
1714 AC_MSG_RESULT($found)
1715
1716 dnl For certain native configurations, we need to check whether thread
1717 dnl support can be built in or not.
1718 dnl
1719 dnl Note that we only want this if we are both native (host == target),
1720 dnl and not doing a canadian cross build (build == host).
1721
1722 if test ${build} = ${host} -a ${host} = ${target} ; then
1723    case ${host_os} in
1724    aix*)
1725       AC_MSG_CHECKING(for AiX thread debugging library)
1726       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1727                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1728                                    [#ifndef PTHDB_VERSION_3
1729                                     #error
1730                                     #endif],
1731                                    gdb_cv_have_aix_thread_debug=yes,
1732                                    gdb_cv_have_aix_thread_debug=no)])
1733       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1734       if test $gdb_cv_have_aix_thread_debug = yes; then
1735          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1736          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1737          LIBS="$LIBS -lpthdebug"
1738
1739          # Older versions of AIX do not provide the declaration for
1740          # the getthrds function (it appears that it was introduced
1741          # with AIX 6.x).
1742          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1743       fi
1744       ;;
1745    esac
1746    AC_SUBST(CONFIG_LDFLAGS)
1747 fi
1748
1749 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1750 dnl other error codes.
1751 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1752    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1753                   gdb_cv_thread_db_h_has_td_notalloc,
1754      AC_TRY_COMPILE(
1755        [#include <thread_db.h>],
1756        [int i = TD_NOTALLOC;],
1757        gdb_cv_thread_db_h_has_td_notalloc=yes,
1758        gdb_cv_thread_db_h_has_td_notalloc=no
1759      )
1760    )
1761    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1762                   gdb_cv_thread_db_h_has_td_version,
1763      AC_TRY_COMPILE(
1764        [#include <thread_db.h>],
1765        [int i = TD_VERSION;],
1766        gdb_cv_thread_db_h_has_td_version=yes,
1767        gdb_cv_thread_db_h_has_td_version=no
1768      )
1769    )
1770    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1771                   gdb_cv_thread_db_h_has_td_notls,
1772      AC_TRY_COMPILE(
1773        [#include <thread_db.h>],
1774        [int i = TD_NOTLS;],
1775        gdb_cv_thread_db_h_has_td_notls=yes,
1776        gdb_cv_thread_db_h_has_td_notls=no
1777      )
1778    )
1779 fi
1780 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1781   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1782             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1783 fi
1784 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1785   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1786             [Define if <thread_db.h> has the TD_VERSION error code.])
1787 fi
1788 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1789   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1790             [Define if <thread_db.h> has the TD_NOTLS error code.])
1791 fi
1792
1793 dnl Check if we can disable the virtual address space randomization.
1794 dnl The functionality of setarch -R.
1795 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1796 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1797 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1798 #       define ADDR_NO_RANDOMIZE 0x0040000
1799 #      endif
1800        /* Test the flag could be set and stays set.  */
1801        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1802        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1803            return 1])])
1804 AC_RUN_IFELSE([PERSONALITY_TEST],
1805               [have_personality=true],
1806               [have_personality=false],
1807               [AC_LINK_IFELSE([PERSONALITY_TEST],
1808                               [have_personality=true],
1809                               [have_personality=false])])
1810 if $have_personality
1811 then
1812     AC_DEFINE([HAVE_PERSONALITY], 1,
1813               [Define if you support the personality syscall.])
1814 fi
1815
1816 dnl Set the host's .gdbinit filename.
1817 case $host_os in
1818   go32* | *djgpp*)
1819     gdbinit=gdb.ini
1820     ;;
1821   *)
1822     gdbinit=.gdbinit
1823     ;;
1824 esac
1825 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1826
1827 dnl Handle optional features that can be enabled.
1828
1829 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1830 # except that the argument to --with-sysroot is optional.
1831 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1832 if test "x$with_sysroot" = xyes; then
1833   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1834 fi
1835 AC_ARG_WITH(sysroot,
1836   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1837                  [search for usr/lib et al within DIR]),
1838   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1839 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1840               [search for usr/lib et al within DIR])
1841 AC_SUBST(TARGET_SYSTEM_ROOT)
1842 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1843
1844 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1845     [automatically load a system-wide gdbinit file],
1846     [])
1847
1848 AM_GDB_WARNINGS
1849 AM_GDB_UBSAN
1850
1851 # In the Cygwin environment, we need some additional flags.
1852 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1853 [AC_EGREP_CPP(^lose$, [
1854 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1855 lose
1856 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1857
1858
1859 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1860 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1861 case ${host} in
1862   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1863   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1864   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1865   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1866 esac
1867 AC_SUBST(SER_HARDWIRE)
1868
1869 # libreadline needs libuser32.a in a cygwin environment
1870 WIN32LIBS=
1871 if test x$gdb_cv_os_cygwin = xyes; then
1872     WIN32LIBS="-luser32"
1873     case "${target}" in
1874         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1875         ;;
1876     esac
1877 fi
1878
1879 # The ser-tcp.c module requires sockets.
1880 case ${host} in
1881   *mingw32*)
1882     AC_DEFINE(USE_WIN32API, 1,
1883               [Define if we should use the Windows API, instead of the
1884                POSIX API.  On Windows, we use the Windows API when
1885                building for MinGW, but the POSIX API when building
1886                for Cygwin.])
1887     WIN32LIBS="$WIN32LIBS -lws2_32"
1888     ;;
1889 esac
1890 AC_SUBST(WIN32LIBS)
1891
1892 # Add ELF support to GDB, but only if BFD includes ELF support.
1893 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1894                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1895 if test $gdb_cv_var_elf = yes; then
1896   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1897   AC_DEFINE(HAVE_ELF, 1,
1898             [Define if ELF support should be included.])
1899   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1900   if test "$plugins" = "yes"; then
1901     AC_SEARCH_LIBS(dlopen, dl)
1902   fi
1903 fi
1904
1905 # Add macho support to GDB, but only if BFD includes it.
1906 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1907                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1908 if test $gdb_cv_var_macho = yes; then
1909   CONFIG_OBS="$CONFIG_OBS machoread.o"
1910 fi
1911
1912 # Add any host-specific objects to GDB.
1913 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1914
1915 # If building on ELF, look for lzma support for embedded compressed debug info.
1916 if test $gdb_cv_var_elf = yes; then
1917   AC_ARG_WITH(lzma,
1918     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1919     [], [with_lzma=auto])
1920   AC_MSG_CHECKING([whether to use lzma])
1921   AC_MSG_RESULT([$with_lzma])
1922
1923   if test "${with_lzma}" != no; then
1924     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1925                           [lzma_index_iter iter;
1926                            lzma_index_iter_init (&iter, 0);
1927                            lzma_mf_is_supported (LZMA_MF_HC3);])
1928     if test "$HAVE_LIBLZMA" != yes; then
1929       if test "$with_lzma" = yes; then
1930         AC_MSG_ERROR([missing liblzma for --with-lzma])
1931       fi
1932     fi
1933   fi
1934 fi
1935
1936 LIBGUI="../libgui/src/libgui.a"
1937 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1938 AC_SUBST(LIBGUI)
1939 AC_SUBST(GUI_CFLAGS_X)
1940
1941 WIN32LDAPP=
1942 AC_SUBST(WIN32LIBS)
1943 AC_SUBST(WIN32LDAPP)
1944
1945 case "${host}" in
1946 *-*-cygwin* | *-*-mingw* )
1947     configdir="win"
1948     ;;
1949 *)
1950     configdir="unix"
1951     ;;
1952 esac
1953
1954 GDBTKLIBS=
1955 if test "${enable_gdbtk}" = "yes"; then
1956
1957     # Gdbtk must have an absolute path to srcdir in order to run
1958     # properly when not installed.
1959     here=`pwd`
1960     cd ${srcdir}
1961     GDBTK_SRC_DIR=`pwd`
1962     cd $here
1963
1964     SC_PATH_TCLCONFIG
1965
1966     # If $no_tk is nonempty, then we can't do Tk, and there is no
1967     # point to doing Tcl.
1968     SC_PATH_TKCONFIG
1969
1970     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1971         SC_LOAD_TCLCONFIG
1972
1973         # Check for in-tree tcl
1974         here=`pwd`
1975         cd ${srcdir}/..
1976         topdir=`pwd`
1977         cd ${here}
1978
1979         intree="no"
1980         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1981           intree="yes"
1982         fi
1983
1984         # Find Tcl private headers
1985         if test x"${intree}" = xno; then
1986           CY_AC_TCL_PRIVATE_HEADERS
1987           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1988           TCL_LIBRARY="${TCL_LIB_SPEC}"
1989           TCL_DEPS=""
1990         else
1991           # If building tcl in the same src tree, private headers
1992           # are not needed, but we need to be sure to use the right
1993           # headers library
1994           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1995           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1996           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1997         fi
1998         AC_SUBST(TCL_INCLUDE)
1999         AC_SUBST(TCL_LIBRARY)
2000         AC_SUBST(TCL_DEPS)
2001
2002         SC_LOAD_TKCONFIG
2003
2004         # Check for in-tree Tk
2005         intree="no"
2006         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2007           intree="yes"
2008         fi
2009
2010         # Find Tk private headers
2011         if test x"${intree}" = xno; then
2012           CY_AC_TK_PRIVATE_HEADERS
2013           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2014           TK_LIBRARY=${TK_LIB_SPEC}
2015           TK_DEPS=""
2016         else
2017           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2018           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2019           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2020         fi
2021         AC_SUBST(TK_INCLUDE)
2022         AC_SUBST(TK_LIBRARY)
2023         AC_SUBST(TK_DEPS)
2024         AC_SUBST(TK_XINCLUDES)
2025
2026         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2027
2028         # Include some libraries that Tcl and Tk want.
2029         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2030         # Yes, the ordering seems wrong here.  But it isn't.
2031         # TK_LIBS is the list of libraries that need to be linked
2032         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2033         # were in LIBS then any link tests after this point would
2034         # try to include things like `$(LIBGUI)', which wouldn't work.
2035         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2036
2037         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2038         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2039         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2040         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2041         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2042         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2043         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2044
2045         if test x$gdb_cv_os_cygwin = xyes; then
2046           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2047           WIN32LDAPP="-Wl,--subsystem,console"
2048           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2049         fi
2050
2051         AC_CONFIG_SUBDIRS(gdbtk)
2052     fi
2053 fi
2054
2055 AC_SUBST(X_CFLAGS)
2056 AC_SUBST(X_LDFLAGS)
2057 AC_SUBST(X_LIBS)
2058 AC_SUBST(GDBTKLIBS)
2059 AC_SUBST(GDBTK_CFLAGS)
2060 AC_SUBST(GDBTK_SRC_DIR)
2061
2062 AC_PATH_X
2063
2064 # Unlike the sim directory, whether a simulator is linked is controlled by
2065 # presence of a gdb_sim definition in the target configure.tgt entry.
2066 # This code just checks for a few cases where we'd like to ignore those
2067 # definitions, even when they're present in the '.mt' file.  These cases
2068 # are when --disable-sim is specified, or if the simulator directory is
2069 # not part of the source tree.
2070 #
2071 AC_ARG_ENABLE(sim,
2072 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2073 [echo "enable_sim = $enable_sim";
2074  echo "enableval = ${enableval}";
2075  case "${enableval}" in
2076   yes) ignore_sim=false ;;
2077   no)  ignore_sim=true ;;
2078   *)   ignore_sim=false ;;
2079  esac],
2080 [ignore_sim=false])
2081
2082 if test ! -d "${srcdir}/../sim"; then
2083   ignore_sim=true
2084 fi
2085
2086 SIM=
2087 SIM_OBS=
2088 if test "${ignore_sim}" = "false"; then
2089   if test x"${gdb_sim}" != x ; then
2090     SIM="${gdb_sim}"
2091     SIM_OBS="remote-sim.o"
2092     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2093
2094     # Some tdep code should only be compiled in when the ppc sim is
2095     # built.  PR sim/13418.
2096     case $target in
2097       powerpc*-*-*)
2098         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2099         ;;
2100     esac
2101   fi
2102 fi
2103 AC_SUBST(SIM)
2104 AC_SUBST(SIM_OBS)
2105
2106 AC_SUBST(ENABLE_CFLAGS)
2107 AC_SUBST(PROFILE_CFLAGS)
2108
2109 AC_SUBST(CONFIG_OBS)
2110 AC_SUBST(CONFIG_DEPS)
2111 AC_SUBST(CONFIG_SRCS)
2112 AC_SUBST(CONFIG_ALL)
2113 AC_SUBST(CONFIG_CLEAN)
2114 AC_SUBST(CONFIG_INSTALL)
2115 AC_SUBST(CONFIG_UNINSTALL)
2116
2117 # List of host floatformats.
2118 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2119 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2120 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2121
2122 # target_subdir is used by the testsuite to find the target libraries.
2123 target_subdir=
2124 if test "${host}" != "${target}"; then
2125     target_subdir="${target_alias}/"
2126 fi
2127 AC_SUBST(target_subdir)
2128
2129 # Import nat definitions.
2130 nat_makefile_frag=/dev/null
2131 if test "${gdb_native}" = "yes"; then
2132   . ${srcdir}/configure.nat
2133   nativefile=$NAT_FILE
2134 fi
2135
2136 AC_SUBST(NAT_FILE)
2137 AC_SUBST(NATDEPFILES)
2138 AC_SUBST(NAT_CDEPS)
2139 AC_SUBST(LOADLIBES)
2140 AC_SUBST(MH_CFLAGS)
2141 AC_SUBST(XM_CLIBS)
2142 AC_SUBST(NAT_GENERATED_FILES)
2143 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2144 AC_SUBST_FILE(nat_makefile_frag)
2145
2146 if test x"${gdb_osabi}" != x ; then
2147     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2148                        [Define to the default OS ABI for this configuration.])
2149 fi
2150
2151 AC_ARG_ENABLE(gdbserver,
2152 AS_HELP_STRING([--enable-gdbserver],
2153                [automatically build gdbserver (yes/no/auto, default is auto)]),
2154 [case "${enableval}" in
2155   yes| no|auto) ;;
2156   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2157 esac],[enable_gdbserver=auto])
2158
2159 # We only build gdbserver automatically in a native configuration, and
2160 # only if the user did not explicitly disable its build.
2161 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2162   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2163   if test "x$build_gdbserver" = xyes; then
2164     AC_MSG_RESULT(yes)
2165     AC_CONFIG_SUBDIRS(gdbserver)
2166     gdbserver_build_enabled=yes
2167   else
2168     AC_MSG_RESULT(no)
2169   fi
2170 fi
2171
2172 # If the user explicitly request the gdbserver to be built, verify that
2173 # we were in fact able to enable it.
2174 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2175   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2176 fi
2177
2178 # Check for babeltrace and babeltrace-ctf
2179 AC_ARG_WITH(babeltrace,
2180   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2181   [], [with_babeltrace=auto])
2182 AC_MSG_CHECKING([whether to use babeltrace])
2183 AC_MSG_RESULT([$with_babeltrace])
2184
2185 if test "x$with_babeltrace" = "xno"; then
2186   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2187 else
2188   # Append -Werror to CFLAGS so that configure can catch the warning
2189   # "assignment from incompatible pointer type", which is related to
2190   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2191   # in GDB, while babeltrace 1.0.3 is broken.
2192   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2193   # safe to save and restore CFLAGS here.
2194   saved_CFLAGS=$CFLAGS
2195   CFLAGS="$CFLAGS -Werror"
2196   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2197                         [#include <babeltrace/babeltrace.h>
2198                          #include <babeltrace/ctf/events.h>
2199                          #include <babeltrace/ctf/iterator.h>],
2200                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2201                         struct bt_ctf_event *event = NULL;
2202                         const struct bt_definition *scope;
2203
2204                         pos->type = BT_SEEK_BEGIN;
2205                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2206                         scope = bt_ctf_get_top_level_scope (event,
2207                                                            BT_STREAM_EVENT_HEADER);
2208                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2209                         ])
2210   CFLAGS=$saved_CFLAGS
2211
2212   if test "$HAVE_LIBBABELTRACE" != yes; then
2213      if test "$with_babeltrace" = yes; then
2214        AC_MSG_ERROR([babeltrace is missing or unusable])
2215      else
2216        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2217      fi
2218   fi
2219 fi
2220
2221 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2222 # empty version.
2223
2224 files=
2225 links=
2226
2227 rm -f nm.h
2228 if test "${nativefile}" != ""; then
2229     case "${nativefile}" in
2230       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2231       * ) GDB_NM_FILE="${nativefile}"
2232     esac
2233     files="${files} ${GDB_NM_FILE}"
2234     links="${links} nm.h"
2235     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2236 fi
2237 AC_SUBST(GDB_NM_FILE)
2238
2239 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2240 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2241 if test "x$USE_MAINTAINER_MODE" = xyes; then
2242   if test "${XSLTPROC}" = missing; then
2243     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2244   fi
2245 fi
2246 AC_SUBST(XSLTPROC)
2247
2248 AC_LINK_FILES($files, $links)
2249
2250 dnl Check for exe extension set on certain hosts (e.g. Win32)
2251 AC_EXEEXT
2252
2253 dnl  Detect the character set used by this host.
2254 dnl  At the moment, we just assume it's UTF-8.
2255 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2256           [Define to be a string naming the default host character set.])
2257
2258 GDB_AC_SELFTEST([
2259   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) common/selftest.o selftest-arch.o"
2260   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) common/selftest.c selftest-arch.c"
2261 ])
2262
2263 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2264 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2265 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2266 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile],
2267 [
2268 case x$CONFIG_HEADERS in
2269 xconfig.h:config.in)
2270 echo > stamp-h ;;
2271 esac
2272 ])
2273
2274 AC_OUTPUT