gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2013 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Provide more thorough testing by -lmcheck.
  27 # Set it to 'true' for development snapshots, 'false' for releases or
  28 # pre-releases.
  29 development=true
  30
  31 AC_PROG_CC
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # Dependency checking.
  41 ZW_CREATE_DEPDIR
  42 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  43
  44 # Check for the 'make' the user wants to use.
  45 AC_CHECK_PROGS(MAKE, make)
  46 MAKE_IS_GNU=
  47 case "`$MAKE --version 2>&1 | sed 1q`" in
  48   *GNU*)
  49     MAKE_IS_GNU=yes
  50     ;;
  51 esac
  52 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  53 AC_PROG_MAKE_SET
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  60
  61 dnl List of object files and targets accumulated by configure.
  62
  63 CONFIG_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 ENABLE_CFLAGS=
  67
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 dnl Set up for gettext.
  74 ZW_GNU_GETTEXT_SISTER_DIR
  75
  76 localedir='${datadir}/locale'
  77 AC_SUBST(localedir)
  78
  79 if test x"$USE_NLS" = xyes; then
  80    CONFIG_ALL="$CONFIG_ALL all-po"
  81    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  82    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  83    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  84 fi
  85
  86 GNULIB=build-gnulib/import
  87
  88 # For Makefile dependencies.
  89 GNULIB_STDINT_H=
  90 if test x"$STDINT_H" != x; then
  91   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  92 fi
  93 AC_SUBST(GNULIB_STDINT_H)
  94
  95 PACKAGE=gdb
  96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  97 AC_SUBST(PACKAGE)
  98
  99 # We never need to detect it in this sub-configure.
 100 # But preserve it for config.status --recheck.
 101 AC_ARG_VAR(MAKEINFO,
 102   [Parent configure detects if it is of sufficient version.])
 103 AC_ARG_VAR(MAKEINFOFLAGS,
 104   [Parameters for MAKEINFO.])
 105
 106 MAKEINFO_EXTRA_FLAGS=""
 107 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 108   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 109   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 110     gdb_cv_have_makeinfo_click=yes
 111   else
 112     gdb_cv_have_makeinfo_click=no
 113   fi])
 114 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 115   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 116 fi
 117 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 118
 119 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 120     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 121     [${libdir}/debug])
 122
 123 # We can't pass paths as command line arguments.
 124 # Mingw32 tries to be clever and will convert the paths for us.
 125 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 126 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 127 # This breaks GDB's relocatable path conversions since paths passed in
 128 # config.h would not get so translated, the path prefixes no longer match.
 129 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 130
 131 # GDB's datadir relocation
 132
 133 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 134     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 135     [${datadir}/gdb])
 136
 137 AC_ARG_WITH(relocated-sources,
 138 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 139 [reloc_srcdir="${withval}"
 140  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 141               [Relocated directory for source files. ])
 142 ])
 143
 144 AC_MSG_CHECKING([for default auto-load directory])
 145 AC_ARG_WITH(auto-load-dir,
 146 AS_HELP_STRING([--with-auto-load-dir=PATH],
 147   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 148   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 149 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 151               [Directories from which to load auto-loaded scripts.])
 152 AC_MSG_RESULT([$with_auto_load_dir])
 153
 154 AC_MSG_CHECKING([for default auto-load safe-path])
 155 AC_ARG_WITH(auto-load-safe-path,
 156 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 157   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 158 AS_HELP_STRING([--without-auto-load-safe-path],
 159                [do not restrict auto-loaded files locations]),
 160     [if test "$with_auto_load_safe_path" = "no"; then
 161      with_auto_load_safe_path="/"
 162      fi],
 163 [with_auto_load_safe_path="$with_auto_load_dir"])
 164 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 165 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 166               [Directories safe to hold auto-loaded files.])
 167 AC_MSG_RESULT([$with_auto_load_safe_path])
 168
 169 AC_CONFIG_SUBDIRS(testsuite)
 170
 171 # Check whether to support alternative target configurations
 172 AC_ARG_ENABLE(targets,
 173 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 174 [case "${enableval}" in
 175   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 176             ;;
 177   no)       enable_targets= ;;
 178   *)        enable_targets=$enableval ;;
 179 esac])
 180
 181 # Check whether to enable 64-bit support on 32-bit hosts
 182 AC_ARG_ENABLE(64-bit-bfd,
 183 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 184 [case "${enableval}" in
 185   yes)  want64=true  ;;
 186   no)   want64=false ;;
 187   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 188 esac],[want64=false])dnl
 189
 190 # Provide defaults for some variables set by the per-host and per-target
 191 # configuration.
 192 gdb_host_obs=posix-hdep.o
 193
 194 if test "${target}" = "${host}"; then
 195   gdb_native=yes
 196 else
 197   gdb_native=no
 198 fi
 199
 200 . $srcdir/configure.host
 201
 202 # Accumulate some settings from configure.tgt over all enabled targets
 203
 204 TARGET_OBS=
 205 all_targets=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239   fi
 240 done
 241
 242 if test x${all_targets} = xtrue; then
 243
 244   # We want all 64-bit targets if we either:
 245   #  - run on a 64-bit host  or
 246   #  - already require 64-bit support for some other target  or
 247   #  - the --enable-64-bit-bfd option was supplied
 248   # Otherwise we only support all 32-bit targets.
 249   #
 250   # NOTE: This test must be in sync with the corresponding
 251   #       tests in BFD!
 252
 253   if test x${want64} = xfalse; then
 254     AC_CHECK_SIZEOF(long)
 255     if test "x${ac_cv_sizeof_long}" = "x8"; then
 256       want64=true
 257     fi
 258   fi
 259   if test x${want64} = xtrue; then
 260     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 261   else
 262     TARGET_OBS='$(ALL_TARGET_OBS)'
 263   fi
 264 fi
 265
 266 AC_SUBST(TARGET_OBS)
 267
 268 # For other settings, only the main target counts.
 269 gdb_sim=
 270 gdb_osabi=
 271 build_gdbserver=
 272 targ=$target; . ${srcdir}/configure.tgt
 273
 274 # Fetch the default architecture and default target vector from BFD.
 275 targ=$target; . $srcdir/../bfd/config.bfd
 276
 277 # We only want the first architecture, so strip off the others if
 278 # there is more than one.
 279 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 280
 281 if test "x$targ_archs" != x; then
 282   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 283     [Define to BFD's default architecture. ])
 284 fi
 285 if test "x$targ_defvec" != x; then
 286   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 287     [Define to BFD's default target vector. ])
 288 fi
 289
 290 # The CLI cannot be disabled yet, but may be in the future.
 291
 292 # Enable CLI.
 293 AC_ARG_ENABLE(gdbcli,
 294 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 295   [case $enableval in
 296     yes)
 297       ;;
 298     no)
 299       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 300     *)
 301       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 302   esac],
 303   [enable_gdbcli=yes])
 304 if test x"$enable_gdbcli" = xyes; then
 305   if test -d $srcdir/cli; then
 306     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 307     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 308     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 309     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 310   fi
 311 fi
 312
 313 # Enable MI.
 314 AC_ARG_ENABLE(gdbmi,
 315 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 316   [case $enableval in
 317     yes | no)
 318       ;;
 319     *)
 320       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 321   esac],
 322   [enable_gdbmi=yes])
 323 if test x"$enable_gdbmi" = xyes; then
 324   if test -d $srcdir/mi; then
 325     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 326     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 327     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 328     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 329   fi
 330 fi
 331
 332 # Enable TUI.
 333 AC_ARG_ENABLE(tui,
 334 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 335   [case $enableval in
 336     yes | no | auto)
 337       ;;
 338     *)
 339       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 340   esac],enable_tui=auto)
 341
 342 # Enable gdbtk.
 343 AC_ARG_ENABLE(gdbtk,
 344 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 345   [case $enableval in
 346     yes | no)
 347       ;;
 348     *)
 349       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 350   esac],
 351   [if test -d $srcdir/gdbtk; then
 352     enable_gdbtk=yes
 353   else
 354     enable_gdbtk=no
 355   fi])
 356 # We unconditionally disable gdbtk tests on selected platforms.
 357 case $host_os in
 358   go32* | windows*)
 359     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 360     enable_gdbtk=no ;;
 361 esac
 362
 363 # Libunwind support for ia64.
 364
 365 AC_ARG_WITH(libunwind-ia64,
 366 AS_HELP_STRING([--with-libunwind-ia64],
 367                [use libunwind frame unwinding for ia64 targets]),,
 368             [with_libunwind_ia64=auto])
 369
 370 # Backward compatibility option.
 371 if test "${with_libunwind+set}" = set; then
 372   if test x"$with_libunwind_ia64" != xauto; then
 373     AC_MSG_ERROR(
 374       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 375   fi
 376   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 377   with_libunwind_ia64="$with_libunwind"
 378 fi
 379
 380 case "$with_libunwind_ia64" in
 381   yes | no)
 382     ;;
 383   auto)
 384     AC_CHECK_HEADERS(libunwind-ia64.h)
 385     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 386     ;;
 387   *)
 388     AC_MSG_ERROR(
 389       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 390     ;;
 391 esac
 392
 393 if test x"$with_libunwind_ia64" = xyes; then
 394   AC_CHECK_HEADERS(libunwind-ia64.h)
 395   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 396     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 397   fi
 398   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 399   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 400   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 401 fi
 402
 403 opt_curses=no
 404 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 405
 406 prefer_curses=no
 407 if test "$opt_curses" = "yes"; then
 408   prefer_curses=yes
 409 fi
 410
 411 # Profiling support.
 412 AC_ARG_ENABLE(profiling,
 413 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 414   [case $enableval in
 415     yes | no)
 416       ;;
 417     *)
 418       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 419   esac],
 420  [enable_profiling=no])
 421
 422 AC_CHECK_FUNCS(monstartup _mcleanup)
 423 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 424 [AC_TRY_LINK(
 425 [#include <stdlib.h>
 426 extern char _etext;
 427 ],
 428 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 429 if test $ac_cv_var__etext = yes; then
 430   AC_DEFINE(HAVE__ETEXT, 1,
 431             [Define to 1 if your system has the _etext variable. ])
 432 fi
 433 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 434 [AC_TRY_LINK(
 435 [#include <stdlib.h>
 436 extern char etext;
 437 ],
 438 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 439 if test $ac_cv_var_etext = yes; then
 440   AC_DEFINE(HAVE_ETEXT, 1,
 441             [Define to 1 if your system has the etext variable. ])
 442 fi
 443 if test "$enable_profiling" = yes ; then
 444   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 445     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 446   fi
 447   PROFILE_CFLAGS=-pg
 448   OLD_CFLAGS="$CFLAGS"
 449   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 450
 451   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 452     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 453      ac_cv_cc_supports_pg=no)])
 454
 455   if test $ac_cv_cc_supports_pg = no; then
 456     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 457   fi
 458
 459   CFLAGS="$OLD_CFLAGS"
 460 fi
 461
 462 ACX_PKGVERSION([GDB])
 463 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 464 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 465 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 466
 467 # --------------------- #
 468 # Checks for programs.  #
 469 # --------------------- #
 470
 471 AC_PROG_AWK
 472 AC_PROG_INSTALL
 473 AC_PROG_LN_S
 474 AC_PROG_RANLIB
 475 AC_PROG_YACC
 476
 477 AC_CHECK_TOOL(AR, ar)
 478 AC_CHECK_TOOL(DLLTOOL, dlltool)
 479 AC_CHECK_TOOL(WINDRES, windres)
 480
 481 # Needed for GNU/Hurd.
 482 AC_CHECK_TOOL(MIG, mig)
 483
 484 # ---------------------- #
 485 # Checks for libraries.  #
 486 # ---------------------- #
 487
 488 # We might need to link with -lm; most simulators need it.
 489 AC_CHECK_LIB(m, main)
 490
 491 # We need to link with -lw to get `wctype' on Solaris before Solaris
 492 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 493 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 494 # is known to have this problem).  Therefore we avoid libw if we can.
 495 AC_CHECK_FUNC(wctype, [],
 496   [AC_CHECK_LIB(w, wctype)])
 497
 498 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 499 AC_SEARCH_LIBS(gethostbyname, nsl)
 500
 501 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 502 AC_SEARCH_LIBS(socketpair, socket)
 503
 504 # Link in zlib if we can.  This allows us to read compressed debug sections.
 505 AM_ZLIB
 506
 507 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 508 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 509
 510 AM_ICONV
 511
 512 # GDB may fork/exec the iconv program to get the list of supported character
 513 # sets.  Allow the user to specify where to find it.
 514 # There are several factors affecting the choice of option name:
 515 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 516 #   the build-time location of libiconv files.
 517 # - The program we need to find is iconv, which comes with glibc.  The user
 518 #   doesn't necessarily have libiconv installed.  Therefore naming this
 519 #   --with-libiconv-foo feels wrong.
 520 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 521 #   defined to work on directories not files (though it really doesn't know
 522 #   the difference).
 523 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 524 #   with --with-libiconv-prefix.
 525 # Putting these together is why the option name is --with-iconv-bin.
 526
 527 AC_ARG_WITH(iconv-bin,
 528 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 529 [iconv_bin="${withval}"
 530  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 531                     [Path of directory of iconv program.])
 532  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 533 ])
 534
 535 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 536 # There is a very specific comment in /usr/include/curses.h explaining that
 537 # termcap routines built into libcurses must not be used.
 538 #
 539 # The symptoms we observed so far is GDB unexpectedly changing
 540 # the terminal settings when tgetent is called - this is particularly
 541 # visible as the output is missing carriage returns, and so rapidly
 542 # becomes very hard to read.
 543 #
 544 # The readline configure script has already decided that libtermcap
 545 # was enough for its purposes, and so decided to build readline using
 546 # libtermcap.  Since the TUI mode requires curses, building GDB with
 547 # TUI enabled results in both libraries to be used at the same time,
 548 # which is not allowed.  This basically means that GDB with TUI is
 549 # broken on alpha-osf.
 550
 551 case $host_os in
 552   osf* )
 553     if test x"$enable_tui" = xyes; then
 554       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 555     fi
 556     if test x"$enable_tui" = xauto; then
 557       enable_tui=no
 558     fi
 559     ;;
 560 esac
 561
 562 # For the TUI, we need enhanced curses functionality.
 563 if test x"$enable_tui" != xno; then
 564   prefer_curses=yes
 565 fi
 566
 567 curses_found=no
 568 if test x"$prefer_curses" = xyes; then
 569   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 570   # curses library because the latter might not provide all the
 571   # functionality we need.  However, this leads to problems on systems
 572   # where the linker searches /usr/local/lib, but the compiler doesn't
 573   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 574   # default installation of ncurses on alpha*-dec-osf* will lead to such
 575   # a situation.
 576   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 577
 578   if test "$ac_cv_search_waddstr" != no; then
 579     curses_found=yes
 580   fi
 581 fi
 582
 583 # Check whether we should enable the TUI, but only do so if we really
 584 # can.
 585 if test x"$enable_tui" != xno; then
 586   if test -d $srcdir/tui; then
 587     if test "$curses_found" != no; then
 588       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 589       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 590       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 591       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 592     else
 593       if test x"$enable_tui" = xyes; then
 594         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 595       else
 596         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 597       fi
 598     fi
 599   fi
 600 fi
 601
 602 # Since GDB uses Readline, we need termcap functionality.  In many
 603 # cases this will be provided by the curses library, but some systems
 604 # have a seperate termcap library, or no curses library at all.
 605
 606 case $host_os in
 607   cygwin*)
 608     if test -d $srcdir/libtermcap; then
 609       LIBS="../libtermcap/libtermcap.a $LIBS"
 610       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 611     fi ;;
 612   go32* | *djgpp*)
 613     ac_cv_search_tgetent="none required"
 614     ;;
 615   *mingw32*)
 616     ac_cv_search_tgetent="none required"
 617     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 618     ;;
 619 esac
 620
 621 # These are the libraries checked by Readline.
 622 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 623
 624 if test "$ac_cv_search_tgetent" = no; then
 625   AC_MSG_ERROR([no termcap library found])
 626 fi
 627
 628 AC_ARG_WITH([system-readline],
 629   [AS_HELP_STRING([--with-system-readline],
 630                   [use installed readline library])])
 631
 632 if test "$with_system_readline" = yes; then
 633   READLINE=-lreadline
 634   READLINE_DEPS=
 635   READLINE_CFLAGS=
 636   READLINE_TEXI_INCFLAG=
 637 else
 638   READLINE='$(READLINE_DIR)/libreadline.a'
 639   READLINE_DEPS='$(READLINE)'
 640   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 641   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 642 fi
 643 AC_SUBST(READLINE)
 644 AC_SUBST(READLINE_DEPS)
 645 AC_SUBST(READLINE_CFLAGS)
 646 AC_SUBST(READLINE_TEXI_INCFLAG)
 647
 648 # Generate jit-reader.h
 649
 650 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 651 TARGET_PTR=
 652
 653 AC_CHECK_SIZEOF(unsigned long long)
 654 AC_CHECK_SIZEOF(unsigned long)
 655 AC_CHECK_SIZEOF(unsigned __int128)
 656
 657 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 658   TARGET_PTR="unsigned long"
 659 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 660   TARGET_PTR="unsigned long long"
 661 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 662   TARGET_PTR="unsigned __int128"
 663 else
 664   TARGET_PTR="unsigned long"
 665 fi
 666
 667 AC_SUBST(TARGET_PTR)
 668 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 669
 670 AC_SEARCH_LIBS(dlopen, dl)
 671
 672 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 673                 [directory to load the JIT readers from],
 674                 [${libdir}/gdb])
 675
 676 AC_ARG_WITH(expat,
 677   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 678   [], [with_expat=auto])
 679 AC_MSG_CHECKING([whether to use expat])
 680 AC_MSG_RESULT([$with_expat])
 681
 682 if test "${with_expat}" = no; then
 683   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 684   HAVE_LIBEXPAT=no
 685 else
 686   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 687                         [XML_Parser p = XML_ParserCreate (0);])
 688   if test "$HAVE_LIBEXPAT" != yes; then
 689     if test "$with_expat" = yes; then
 690       AC_MSG_ERROR([expat is missing or unusable])
 691     else
 692       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 693     fi
 694   else
 695     save_LIBS=$LIBS
 696     LIBS="$LIBS $LIBEXPAT"
 697     AC_CHECK_FUNCS(XML_StopParser)
 698     LIBS=$save_LIBS
 699   fi
 700 fi
 701
 702 dnl Utility to simplify finding libpython.
 703 dnl $1 = pythonX.Y
 704 dnl $2 = the shell variable to assign the result to
 705 dnl      If libpython is found we store $version here.
 706 dnl $3 = additional flags to add to CPPFLAGS
 707 dnl $4 = additional flags to add to LIBS
 708
 709 AC_DEFUN([AC_TRY_LIBPYTHON],
 710 [
 711   version=$1
 712   define([have_libpython_var],$2)
 713   new_CPPFLAGS=$3
 714   new_LIBS=$4
 715   AC_MSG_CHECKING([for ${version}])
 716   save_CPPFLAGS=$CPPFLAGS
 717   save_LIBS=$LIBS
 718   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 719   LIBS="$LIBS $new_LIBS"
 720   found_usable_python=no
 721   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 722                                  [[Py_Initialize ();]]),
 723                  [have_libpython_var=${version}
 724                   found_usable_python=yes
 725                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 726                   PYTHON_LIBS=$new_LIBS])
 727   CPPFLAGS=$save_CPPFLAGS
 728   LIBS=$save_LIBS
 729   AC_MSG_RESULT([${found_usable_python}])
 730 ])
 731
 732 dnl There are several different values for --with-python:
 733 dnl
 734 dnl no -   Don't include python support.
 735 dnl yes -  Include python support, error if it's missing.
 736 dnl        If we find python in $PATH, use it to fetch configure options,
 737 dnl        otherwise assume the compiler can find it with no help from us.
 738 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 739 dnl auto - Same as "yes", but if python is missing from the system,
 740 dnl        fall back to "no".
 741 dnl /path/to/python/exec-prefix -
 742 dnl        Use the python located in this directory.
 743 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 744 dnl        the compilation parameters.  Otherwise use
 745 dnl        -I/path/to/python/exec-prefix/include,
 746 dnl        -L/path/to/python/exec-prefix/lib.
 747 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 748 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 749 dnl        but is deprecated.
 750 dnl /path/to/python/executable -
 751 dnl        Run python-config.py with this version of python to fetch the
 752 dnl        compilation parameters.
 753 dnl        NOTE: This needn't be the real python executable.
 754 dnl        In a cross-compilation scenario (build != host), this could be
 755 dnl        a shell script that provides what python-config.py provides for
 756 dnl        --ldflags, --includes, --exec-prefix.
 757 dnl python-executable -
 758 dnl        Find python-executable in $PATH, and then handle the same as
 759 dnl        /path/to/python/executable.
 760 dnl
 761 dnl If a python program is specified, it is used to run python-config.py and
 762 dnl is passed --ldflags, --includes, --exec-prefix.
 763
 764 AC_ARG_WITH(python,
 765   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 766   [], [with_python=auto])
 767 AC_MSG_CHECKING([whether to use python])
 768 AC_MSG_RESULT([$with_python])
 769
 770 if test "${with_python}" = no; then
 771   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 772   have_libpython=no
 773 else
 774   case "${with_python}" in
 775   [[\\/]]* | ?:[[\\/]]*)
 776     if test -d ${with_python}; then
 777       # Assume the python binary is ${with_python}/bin/python.
 778       python_prog="${with_python}/bin/python"
 779       python_prefix=
 780       # If python does not exit ${with_python}/bin, then try in
 781       # ${with_python}.  On Windows/MinGW, this is where the Python
 782       # executable is.
 783       if test ! -x "${python_prog}"; then
 784         python_prog="${with_python}/python"
 785         python_prefix=
 786       fi
 787       if test ! -x "${python_prog}"; then
 788         # Fall back to gdb 7.0/7.1 behaviour.
 789         python_prog=missing
 790         python_prefix=${with_python}
 791       fi
 792     elif test -x "${with_python}"; then
 793       # While we can't run python compiled for $host (unless host == build),
 794       # the user could write a script that provides the needed information,
 795       # so we support that.
 796       python_prog=${with_python}
 797       python_prefix=
 798     else
 799       AC_ERROR(invalid value for --with-python)
 800     fi
 801     ;;
 802   */*)
 803     # Disallow --with-python=foo/bar.
 804     AC_ERROR(invalid value for --with-python)
 805     ;;
 806   *)
 807     # The user has either specified auto, yes, or the name of the python
 808     # program assumed to be in $PATH.
 809     python_prefix=
 810     case "${with_python}" in
 811     yes | auto)
 812       if test ${build} = ${host}; then
 813         AC_PATH_PROG(python_prog_path, python, missing)
 814         if test "${python_prog_path}" = missing; then
 815           python_prog=missing
 816         else
 817           python_prog=${python_prog_path}
 818         fi
 819       else
 820         # Not much we can do except assume the cross-compiler will find the
 821         # right files.
 822         python_prog=missing
 823       fi
 824       ;;
 825     *)
 826       # While we can't run python compiled for $host (unless host == build),
 827       # the user could write a script that provides the needed information,
 828       # so we support that.
 829       python_prog="${with_python}"
 830       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 831       if test "${python_prog_path}" = missing; then
 832         AC_ERROR(unable to find python program ${python_prog})
 833       fi
 834       ;;
 835     esac
 836   esac
 837
 838   if test "${python_prog}" != missing; then
 839     # We have a python program to use, but it may be too old.
 840     # Don't flag an error for --with-python=auto (the default).
 841     have_python_config=yes
 842     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 843     if test $? != 0; then
 844       have_python_config=failed
 845       if test "${with_python}" != auto; then
 846         AC_ERROR(failure running python-config --includes)
 847       fi
 848     fi
 849     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 850     if test $? != 0; then
 851       have_python_config=failed
 852       if test "${with_python}" != auto; then
 853         AC_ERROR(failure running python-config --ldflags)
 854       fi
 855     fi
 856     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 857     if test $? != 0; then
 858       have_python_config=failed
 859       if test "${with_python}" != auto; then
 860         AC_ERROR(failure running python-config --exec-prefix)
 861       fi
 862     fi
 863   else
 864     # We do not have a python executable we can use to determine where
 865     # to find the Python headers and libs.  We cannot guess the include
 866     # path from the python_prefix either, because that include path
 867     # depends on the Python version.  So, there is nothing much we can
 868     # do except assume that the compiler will be able to find those files.
 869     python_includes=
 870     python_libs=
 871     have_python_config=no
 872   fi
 873
 874   # If we have python-config, only try the configuration it provides.
 875   # Otherwise fallback on the old way of trying different versions of
 876   # python in turn.
 877
 878   have_libpython=no
 879   if test "${have_python_config}" = yes; then
 880     # Determine the Python version by extracting "-lpython<version>"
 881     # part of the python_libs. <version> is usually X.Y with X and Y
 882     # being decimal numbers, but can also be XY (seen on Windows).
 883     #
 884     # The extraction is performed using sed with a regular expression.
 885     # Initially, the regexp used was using the '?' quantifier to make
 886     # the dot in the version number optional.  Unfortunately, this
 887     # does not work with non-GNU versions of sed because, because of
 888     # what looks like a limitation (the '?' quantifier does not work
 889     # with back-references).  We work around this limitation by using
 890     # the '*' quantifier instead.  It means that, in theory, we might
 891     # match unexpected version strings such as "-lpython2..7", but
 892     # this seems unlikely in practice.  And even if that happens,
 893     # an error will be triggered later on, when checking that version
 894     # number.
 895     python_version=`echo " ${python_libs} " \
 896                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 897     case "${python_version}" in
 898     python*)
 899       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 900                        ${python_includes}, ${python_libs})
 901       ;;
 902     *)
 903       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 904       ;;
 905     esac
 906   elif test "${have_python_config}" != failed; then
 907     if test "${have_libpython}" = no; then
 908       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 909                        ${python_includes}, "${python_libs} -lpython2.7")
 910     fi
 911     if test "${have_libpython}" = no; then
 912       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 913                        ${python_includes}, "${python_libs} -lpython2.6")
 914     fi
 915     if test ${have_libpython} = no; then
 916       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 917                        ${python_includes}, "${python_libs} -lpython2.5")
 918     fi
 919     if test ${have_libpython} = no; then
 920       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 921                        ${python_includes}, "${python_libs} -lpython2.4")
 922     fi
 923   fi
 924   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 925     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 926   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 927     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 928   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 929     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 930   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 931     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 932   fi
 933
 934   if test "${have_libpython}" = no; then
 935     case "${with_python}" in
 936     yes)
 937       AC_MSG_ERROR([python is missing or unusable])
 938       ;;
 939     auto)
 940       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 941       ;;
 942     *)
 943       AC_MSG_ERROR([no usable python found at ${with_python}])
 944       ;;
 945     esac
 946   else
 947     if test -n "${python_prefix}"; then
 948       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 949                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 950       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 951     fi
 952   fi
 953 fi
 954
 955 if test "${have_libpython}" != no; then
 956   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 957   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 958   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 959   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 960   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 961   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 962
 963   # Flags needed to compile Python code (taken from python-config --cflags).
 964   # We cannot call python-config directly because it will output whatever was
 965   # used when compiling the Python interpreter itself, including flags which
 966   # would make the python-related objects be compiled differently from the
 967   # rest of GDB (e.g., -O2 and -fPIC).
 968   if test "${GCC}" = yes; then
 969     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 970   fi
 971
 972   if test "x${tentative_python_cflags}" != x; then
 973     AC_MSG_CHECKING(compiler flags for python code)
 974     for flag in ${tentative_python_cflags}; do
 975       # Check that the compiler accepts it
 976       saved_CFLAGS="$CFLAGS"
 977       CFLAGS="$CFLAGS $flag"
 978       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 979       CFLAGS="$saved_CFLAGS"
 980     done
 981     AC_MSG_RESULT(${PYTHON_CFLAGS})
 982   fi
 983
 984   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 985   #    #if _SGIAPI
 986   #    #define siginfo __siginfo
 987   #    #endif
 988   # The problem is that including Python causes some XOPEN macros to be
 989   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 990   # to false.  So, we work around this issue by defining siginfo ourself
 991   # though the command-line.
 992   #
 993   # On x64 Windows, Python's include headers, and pyconfig.h in
 994   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 995   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 996   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 997   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 998   # The issue was reported to the Python community, but still isn't
 999   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1000
1001   case "$gdb_host" in
1002     irix*) if test "${GCC}" = yes; then
1003              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1004            fi
1005            ;;
1006     mingw64)
1007            if test "${GCC}" = yes; then
1008              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1009            fi
1010            ;;
1011   esac
1012
1013   # Note that "python -m threading" cannot be used to check for
1014   # threading support due to a bug in Python 2.7.3
1015   # (http://bugs.python.org/issue15567).
1016   AC_MSG_CHECKING(whether python supports threads)
1017   saved_CPPFLAGS="${CPPFLAGS}"
1018   CPPFLAGS="${PYTHON_CPPFLAGS}"
1019   # Note that the test is reversed so that python_has_threads=yes on
1020   # unexpected failures.
1021   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1022 #include <Python.h>
1023 #ifdef WITH_THREAD
1024 # error
1025 #endif
1026   ]]), [python_has_threads=no], [python_has_threads=yes])
1027   AC_MSG_RESULT(${python_has_threads})
1028   CPPFLAGS="${saved_CPPFLAGS}"
1029 else
1030   # Even if Python support is not compiled in, we need to have these files
1031   # included.
1032   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
1033   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
1034         python/py-prettyprint.c python/py-auto-load.c"
1035 fi
1036 AC_SUBST(PYTHON_CFLAGS)
1037 AC_SUBST(PYTHON_CPPFLAGS)
1038 AC_SUBST(PYTHON_LIBS)
1039
1040 # Provide a --enable-libmcheck/--disable-libmcheck set of options
1041 # allowing a user to enable this option even when building releases,
1042 # or to disable it when building a snapshot.
1043 AC_ARG_ENABLE(libmcheck,
1044   AS_HELP_STRING([--enable-libmcheck],
1045                  [Try building GDB with -lmcheck if available]),
1046   [case "${enableval}" in
1047      yes | y) ENABLE_LIBMCHECK="yes" ;;
1048      no | n)  ENABLE_LIBMCHECK="no" ;;
1049      *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmcheck) ;;
1050    esac])
1051
1052 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1053 # but turn it off if Python is enabled with threads, since -lmcheck is
1054 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1055 # and for releases.
1056 if test -z "${ENABLE_LIBMCHECK}" \
1057         -a \( "${have_libpython}" = "no" \
1058              -o "${python_has_threads}" = "no" \) \
1059     && $development; then
1060   ENABLE_LIBMCHECK=yes
1061 fi
1062
1063 if test "$ENABLE_LIBMCHECK" = "yes" ; then
1064   if test "${have_libpython}" != "no" -a "${python_has_threads}" = "yes" ; then
1065     AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1066   fi
1067   AC_CHECK_LIB(mcheck, main)
1068 fi
1069
1070 # ------------------------- #
1071 # Checks for header files.  #
1072 # ------------------------- #
1073
1074 AC_HEADER_DIRENT
1075 AC_HEADER_STDC
1076 # elf_hp.h is for HP/UX 64-bit shared library support.
1077 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1078                   thread_db.h signal.h stddef.h \
1079                   stdlib.h string.h memory.h strings.h sys/fault.h \
1080                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1081                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1082                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1083                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1084                   sgtty.h unistd.h elf_hp.h locale.h \
1085                   dlfcn.h sys/socket.h sys/un.h linux/perf_event.h])
1086 AC_CHECK_HEADERS(link.h, [], [],
1087 [#if HAVE_SYS_TYPES_H
1088 # include <sys/types.h>
1089 #endif
1090 #if HAVE_NLIST_H
1091 # include <nlist.h>
1092 #endif
1093 ])
1094 AC_CHECK_HEADERS(sys/proc.h, [], [],
1095 [#if HAVE_SYS_PARAM_H
1096 # include <sys/param.h>
1097 #endif
1098 ])
1099 AC_CHECK_HEADERS(sys/user.h, [], [],
1100 [#if HAVE_SYS_PARAM_H
1101 # include <sys/param.h>
1102 #endif
1103 ])
1104
1105 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1106 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1107 # think that we don't have <curses.h> if we're using GCC.
1108 case $host_os in
1109   solaris2.[[789]])
1110     if test "$GCC" = yes; then
1111       AC_DEFINE(_MSE_INT_H, 1,
1112         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1113    Solaris 2.[789] when using GCC. ])
1114     fi ;;
1115 esac
1116 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1117 AC_CHECK_HEADERS(term.h, [], [],
1118 [#if HAVE_CURSES_H
1119 # include <curses.h>
1120 #endif
1121 ])
1122
1123 # ------------------------- #
1124 # Checks for declarations.  #
1125 # ------------------------- #
1126
1127 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1128                 snprintf, vsnprintf])
1129 AM_LC_MESSAGES
1130
1131 # ----------------------- #
1132 # Checks for structures.  #
1133 # ----------------------- #
1134
1135 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1136
1137 # ------------------ #
1138 # Checks for types.  #
1139 # ------------------ #
1140
1141 AC_TYPE_SIGNAL
1142 AC_CHECK_TYPES(socklen_t, [], [],
1143 [#include <sys/types.h>
1144 #include <sys/socket.h>
1145 ])
1146
1147 # ------------------------------------- #
1148 # Checks for compiler characteristics.  #
1149 # ------------------------------------- #
1150
1151 AC_C_CONST
1152 AC_C_INLINE
1153 AC_C_BIGENDIAN
1154
1155 # ------------------------------ #
1156 # Checks for library functions.  #
1157 # ------------------------------ #
1158
1159 AC_FUNC_ALLOCA
1160 AC_FUNC_MMAP
1161 AC_FUNC_VFORK
1162 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1163                 pipe poll pread pread64 pwrite readlink resize_term \
1164                 sbrk setpgid setpgrp setsid \
1165                 sigaction sigprocmask sigsetmask socketpair syscall \
1166                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1167                 setrlimit getrlimit posix_madvise waitpid lstat])
1168 AM_LANGINFO_CODESET
1169
1170 # Check the return and argument types of ptrace.  No canned test for
1171 # this, so roll our own.
1172 gdb_ptrace_headers='
1173 #if HAVE_SYS_TYPES_H
1174 # include <sys/types.h>
1175 #endif
1176 #if HAVE_SYS_PTRACE_H
1177 # include <sys/ptrace.h>
1178 #endif
1179 #if HAVE_UNISTD_H
1180 # include <unistd.h>
1181 #endif
1182 '
1183 # There is no point in checking if we don't have a prototype.
1184 AC_CHECK_DECLS(ptrace, [], [
1185   : ${gdb_cv_func_ptrace_ret='int'}
1186   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1187 ], $gdb_ptrace_headers)
1188 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1189 # empty argument list, so check for that explicitly.
1190 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1191   AC_TRY_COMPILE($gdb_ptrace_headers,
1192     [extern long ptrace (enum __ptrace_request, ...);],
1193     gdb_cv_func_ptrace_ret='long',
1194     AC_TRY_COMPILE($gdb_ptrace_headers,
1195       [extern int ptrace ();],
1196       gdb_cv_func_ptrace_ret='int',
1197       gdb_cv_func_ptrace_ret='long')))
1198 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1199   [Define as the return type of ptrace.])
1200 # Check argument types.
1201 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1202   AC_TRY_COMPILE($gdb_ptrace_headers,
1203     [extern long ptrace (enum __ptrace_request, ...);],
1204     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1205 for gdb_arg1 in 'int' 'long'; do
1206  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1207   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1208    for gdb_arg4 in 'int' 'long'; do
1209      AC_TRY_COMPILE($gdb_ptrace_headers, [
1210 extern $gdb_cv_func_ptrace_ret
1211   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1212 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1213     break 4;])
1214     for gdb_arg5 in 'int *' 'int' 'long'; do
1215      AC_TRY_COMPILE($gdb_ptrace_headers, [
1216 extern $gdb_cv_func_ptrace_ret
1217   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1218 ], [
1219 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1220     break 5;])
1221     done
1222    done
1223   done
1224  done
1225 done
1226 # Provide a safe default value.
1227 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1228 ])])
1229 ac_save_IFS=$IFS; IFS=','
1230 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1231 IFS=$ac_save_IFS
1232 shift
1233 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1234   [Define to the type of arg 3 for ptrace.])
1235 if test -n "$[5]"; then
1236   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1237     [Define to the type of arg 5 for ptrace.])
1238 fi
1239
1240 dnl AC_FUNC_SETPGRP does not work when cross compiling
1241 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1242 if test "$cross_compiling" = no; then
1243   AC_FUNC_SETPGRP
1244 else
1245   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1246     [AC_TRY_COMPILE([
1247 #include <unistd.h>
1248 ], [
1249   if (setpgrp(1,1) == -1)
1250     exit (0);
1251   else
1252     exit (1);
1253 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1254 if test $ac_cv_func_setpgrp_void = yes; then
1255   AC_DEFINE(SETPGRP_VOID, 1)
1256 fi
1257 fi
1258
1259 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1260 # since sigsetjmp might only be defined as a macro.
1261 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1262 [AC_TRY_COMPILE([
1263 #include <setjmp.h>
1264 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1265 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1266 if test $gdb_cv_func_sigsetjmp = yes; then
1267   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1268 fi
1269
1270 # Assume we'll default to using the included libiberty regex.
1271 gdb_use_included_regex=yes
1272
1273 # However, if the system regex is GNU regex, then default to *not*
1274 # using the included regex.
1275 AC_CACHE_CHECK(
1276   [for GNU regex],
1277   [gdb_cv_have_gnu_regex],
1278   [AC_TRY_COMPILE(
1279     [#include <gnu-versions.h>],
1280     [#define REGEX_INTERFACE_VERSION 1
1281 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1282 # error "Version mismatch"
1283 #endif],
1284     gdb_cv_have_gnu_regex=yes,
1285     gdb_cv_have_gnu_regex=no)])
1286 if test $gdb_cv_have_gnu_regex = yes; then
1287   gdb_use_included_regex=no
1288 fi
1289
1290 AC_ARG_WITH(included-regex,
1291   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1292   gdb_with_regex=$withval,
1293   gdb_with_regex=$gdb_use_included_regex)
1294 if test "$gdb_with_regex" = yes; then
1295   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1296     [Define to 1 if the regex included in libiberty should be used.])
1297 fi
1298
1299 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1300 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1301 [#include <sys/param.h>
1302 #include <sys/proc.h>
1303 ])
1304
1305 # See if <sys/lwp.h> defines `struct lwp`.
1306 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1307 [AC_TRY_COMPILE([#include <sys/param.h>
1308 #include <sys/lwp.h>], [struct lwp l;],
1309 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1310 if test $gdb_cv_struct_lwp = yes; then
1311   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1312             [Define to 1 if your system has struct lwp.])
1313 fi
1314
1315 # See if <machine/reg.h> degines `struct reg'.
1316 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1317 [AC_TRY_COMPILE([#include <sys/types.h>
1318 #include <machine/reg.h>], [struct reg r;],
1319 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1320 if test $gdb_cv_struct_reg = yes; then
1321   AC_DEFINE(HAVE_STRUCT_REG, 1,
1322             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1323 fi
1324
1325 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1326 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1327 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1328                  [#include <machine/reg.h>])
1329
1330 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1331 # Older amd64 Linux's don't have the fs_base and gs_base members of
1332 # `struct user_regs_struct'.
1333 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1334                  [], [], [#include <sys/user.h>])
1335
1336 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1337 AC_MSG_CHECKING(for PTRACE_GETREGS)
1338 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1339 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1340                 [PTRACE_GETREGS;],
1341                 [gdb_cv_have_ptrace_getregs=yes],
1342                 [gdb_cv_have_ptrace_getregs=no])])
1343 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1344 if test $gdb_cv_have_ptrace_getregs = yes; then
1345   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1346   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1347 fi
1348
1349 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1350 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1351 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1352 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1353                 [PTRACE_GETFPXREGS;],
1354                 [gdb_cv_have_ptrace_getfpxregs=yes],
1355                 [gdb_cv_have_ptrace_getfpxregs=no])])
1356 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1357 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1358   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1359   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1360 fi
1361
1362 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1363 AC_MSG_CHECKING(for PT_GETDBREGS)
1364 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1365 [AC_TRY_COMPILE([#include <sys/types.h>
1366 #include <sys/ptrace.h>],
1367                 [PT_GETDBREGS;],
1368                 [gdb_cv_have_pt_getdbregs=yes],
1369                 [gdb_cv_have_pt_getdbregs=no])])
1370 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1371 if test $gdb_cv_have_pt_getdbregs = yes; then
1372   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1373   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1374 fi
1375
1376 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1377 AC_MSG_CHECKING(for PT_GETXMMREGS)
1378 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1379 [AC_TRY_COMPILE([#include <sys/types.h>
1380 #include <sys/ptrace.h>],
1381                 [PT_GETXMMREGS;],
1382                 [gdb_cv_have_pt_getxmmregs=yes],
1383                 [gdb_cv_have_pt_getxmmregs=no])])
1384 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1385 if test $gdb_cv_have_pt_getxmmregs = yes; then
1386   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1387   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1388 fi
1389
1390 # Detect which type of /proc is in use, such as for Solaris.
1391
1392 if test "${target}" = "${host}"; then
1393   case "${host}" in
1394   *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1395       AC_DEFINE(NEW_PROC_API, 1,
1396       [Define if you want to use new multi-fd /proc interface
1397        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1398       ;;
1399   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1400       AC_DEFINE(NEW_PROC_API, 1,
1401       [Define if you want to use new multi-fd /proc interface
1402        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1403       ;;
1404   mips-sgi-irix5*)
1405       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1406       AC_DEFINE([_KMEMUSER], 1,
1407       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1408        around a <sys/proc.h> problem on IRIX 5.])
1409       ;;
1410   esac
1411 fi
1412
1413 if test "$ac_cv_header_sys_procfs_h" = yes; then
1414   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1415   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1416   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1417   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1418   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1419   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1420   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1421   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1422   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1423   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1424   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1425   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1426   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1427   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1428
1429
1430   dnl Check for broken prfpregset_t type
1431
1432   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1433   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1434   dnl instead of the struct itself).  We detect this here, and work
1435   dnl around it in gdb_proc_service.h.
1436
1437   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1438     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1439     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1440       [AC_TRY_RUN([#include <sys/procfs.h>
1441        int main ()
1442        {
1443          if (sizeof (prfpregset_t) == sizeof (void *))
1444            return 1;
1445          return 0;
1446        }],
1447        gdb_cv_prfpregset_t_broken=no,
1448        gdb_cv_prfpregset_t_broken=yes,
1449        gdb_cv_prfpregset_t_broken=yes)])
1450     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1451     if test $gdb_cv_prfpregset_t_broken = yes; then
1452       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1453       [Define if the prfpregset_t type is broken.])
1454     fi
1455   fi
1456
1457   dnl Check for PIOCSET ioctl entry
1458
1459   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1460   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1461   [AC_TRY_COMPILE([#include <unistd.h>
1462 #include <sys/types.h>
1463 #include <sys/procfs.h>
1464 ], [
1465     int dummy;;
1466     dummy = ioctl(0, PIOCSET, &dummy);
1467   ],
1468   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1469   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1470   if test $gdb_cv_have_procfs_piocset = yes; then
1471     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1472     [Define if ioctl argument PIOCSET is available.])
1473   fi
1474 fi
1475
1476 dnl For native ports (host == target), check to see what kind of
1477 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1478 if test ${host} = ${target} ; then
1479   dnl Check for struct link_map with l_ members which are indicative
1480   dnl of SVR4-like shared libraries
1481
1482   AC_MSG_CHECKING(for member l_addr in struct link_map)
1483   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1484     [AC_TRY_COMPILE([#include <link.h>],
1485                     [struct link_map lm; (void) lm.l_addr;],
1486                     gdb_cv_have_struct_link_map_with_l_members=yes,
1487                     gdb_cv_have_struct_link_map_with_l_members=no)])
1488   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1489   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1490     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1491     [Define if <link.h> exists and defines struct link_map which has
1492      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1493      SVR4-like systems.)])
1494   fi
1495
1496   dnl Check for struct link_map with lm_ members which are indicative
1497   dnl of SunOS-like shared libraries
1498
1499   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1500   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1501     [AC_TRY_COMPILE([#include <sys/types.h>
1502 #include <link.h>],
1503                     [struct link_map lm; (void) lm.lm_addr;],
1504                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1505                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1506   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1507   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1508     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1509     [Define if <link.h> exists and defines struct link_map which has
1510      members with an ``lm_'' prefix.  (For SunOS.)])
1511   fi
1512
1513   dnl Check for struct so_map with som_ members which are found on
1514   dnl some *BSD systems.
1515
1516   AC_MSG_CHECKING(for member som_addr in struct so_map)
1517   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1518     [AC_TRY_COMPILE([#include <sys/types.h>
1519 #ifdef HAVE_NLIST_H
1520 #include <nlist.h>
1521 #endif
1522 #include <link.h>],
1523                     [struct so_map lm; (void) lm.som_addr;],
1524                     gdb_cv_have_struct_so_map_with_som_members=yes,
1525                     gdb_cv_have_struct_so_map_with_som_members=no)])
1526   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1527   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1528     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1529     [Define if <link.h> exists and defines a struct so_map which has
1530      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1531   fi
1532
1533   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1534   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1535
1536   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1537   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1538     [AC_TRY_COMPILE([#define _SYSCALL32
1539 #include <sys/link.h>], [struct link_map32 l;],
1540      gdb_cv_have_struct_link_map32=yes,
1541      gdb_cv_have_struct_link_map32=no)])
1542   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1543   if test $gdb_cv_have_struct_link_map32 = yes; then
1544     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1545     [Define if <sys/link.h> has struct link_map32])
1546     AC_DEFINE(_SYSCALL32, 1,
1547     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1548   fi
1549 fi
1550
1551 # Check if the compiler supports the `long long' type.
1552
1553 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1554                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1555 [[extern long long foo;]],
1556 [[switch (foo & 2) { case 0: return 1; }]])],
1557                                   gdb_cv_c_long_long=yes,
1558                                   gdb_cv_c_long_long=no)])
1559 if test $gdb_cv_c_long_long != yes; then
1560   # libdecnumber requires long long.
1561   AC_MSG_ERROR([Compiler must support long long for GDB.])
1562 fi
1563
1564 # Check if the compiler and runtime support printing long longs.
1565
1566 AC_CACHE_CHECK([for long long support in printf],
1567                gdb_cv_printf_has_long_long,
1568                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1569 [[char buf[32];
1570   long long l = 0;
1571   l = (l << 16) + 0x0123;
1572   l = (l << 16) + 0x4567;
1573   l = (l << 16) + 0x89ab;
1574   l = (l << 16) + 0xcdef;
1575   sprintf (buf, "0x%016llx", l);
1576   return (strcmp ("0x0123456789abcdef", buf));]])],
1577                               gdb_cv_printf_has_long_long=yes,
1578                               gdb_cv_printf_has_long_long=no,
1579                               gdb_cv_printf_has_long_long=no)])
1580 if test $gdb_cv_printf_has_long_long = yes; then
1581   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1582             [Define to 1 if the "%ll" format works to print long longs.])
1583 fi
1584
1585 # Check if the compiler and runtime support printing decfloats.
1586
1587 AC_CACHE_CHECK([for decfloat support in printf],
1588                gdb_cv_printf_has_decfloat,
1589                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1590 [[char buf[64];
1591   _Decimal32 d32 = 1.2345df;
1592   _Decimal64 d64 = 1.2345dd;
1593   _Decimal128 d128 = 1.2345dl;
1594   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1595   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1596                               gdb_cv_printf_has_decfloat=yes,
1597                               gdb_cv_printf_has_decfloat=no,
1598                               gdb_cv_printf_has_decfloat=no)])
1599 if test $gdb_cv_printf_has_decfloat = yes; then
1600   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1601             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1602 fi
1603
1604 # Check if the compiler supports the `long double' type.  We can't use
1605 # AC_C_LONG_DOUBLE because that one does additional checks on the
1606 # constants defined in <float.h> that fail on some systems,
1607 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1608
1609 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1610                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1611                                   gdb_cv_c_long_double=yes,
1612                                   gdb_cv_c_long_double=no)])
1613 if test $gdb_cv_c_long_double = yes; then
1614   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1615            [Define to 1 if the compiler supports long double.])
1616 fi
1617
1618 # Check if the compiler and runtime support printing long doubles.
1619
1620 AC_CACHE_CHECK([for long double support in printf],
1621                gdb_cv_printf_has_long_double,
1622                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1623 [[char buf[16];
1624   long double f = 3.141592653;
1625   sprintf (buf, "%Lg", f);
1626   return (strncmp ("3.14159", buf, 7));]])],
1627                               gdb_cv_printf_has_long_double=yes,
1628                               gdb_cv_printf_has_long_double=no,
1629                               gdb_cv_printf_has_long_double=no)])
1630 if test $gdb_cv_printf_has_long_double = yes; then
1631   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1632             [Define to 1 if the "%Lg" format works to print long doubles.])
1633 fi
1634
1635 # Check if the compiler and runtime support scanning long doubles.
1636
1637 AC_CACHE_CHECK([for long double support in scanf],
1638                gdb_cv_scanf_has_long_double,
1639                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1640 [[#include <stdio.h>]],
1641 [[char *buf = "3.141592653";
1642   long double f = 0;
1643   sscanf (buf, "%Lg", &f);
1644   return !(f > 3.14159 && f < 3.14160);]])],
1645                               gdb_cv_scanf_has_long_double=yes,
1646                               gdb_cv_scanf_has_long_double=no,
1647                               gdb_cv_scanf_has_long_double=no)])
1648 if test $gdb_cv_scanf_has_long_double = yes; then
1649   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1650             [Define to 1 if the "%Lg" format works to scan long doubles.])
1651 fi
1652
1653 case ${host_os} in
1654 aix*)
1655   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1656     SAVE_LDFLAGS=$LDFLAGS
1657
1658     case $GCC in
1659     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1660     *) gdb_cv_bigtoc=-bbigtoc ;;
1661     esac
1662
1663     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1664     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1665     LDFLAGS="${SAVE_LDFLAGS}"
1666   ])
1667   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1668   ;;
1669 esac
1670
1671 AC_MSG_CHECKING(for the dynamic export flag)
1672 dynamic_list=false
1673 if test "${gdb_native}" = yes; then
1674    # The dynamically loaded libthread_db needs access to symbols in the gdb
1675    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1676    # may not be supported there.
1677    old_LDFLAGS="$LDFLAGS"
1678    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1679    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1680    LDFLAGS="$LDFLAGS $RDYNAMIC"
1681    if test "${have_libpython}" = no; then
1682      AC_TRY_LINK([], [], [dynamic_list=true])
1683    else
1684      # Workaround http://bugs.python.org/issue4434 where static
1685      # libpythonX.Y.a would get its symbols required for
1686      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1687      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1688      old_CFLAGS="$CFLAGS"
1689      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1690      old_LIBS="$LIBS"
1691      LIBS="$LIBS $PYTHON_LIBS"
1692      AC_RUN_IFELSE(
1693        AC_LANG_PROGRAM(
1694          [#include "]${have_libpython}[/Python.h"],
1695          [int err;
1696           Py_Initialize ();
1697           err = PyRun_SimpleString ("import itertools\n");
1698           Py_Finalize ();
1699           return err == 0 ? 0 : 1;]),
1700        [dynamic_list=true], [], [true])
1701      LIBS="$old_LIBS"
1702      CFLAGS="$old_CFLAGS"
1703    fi
1704    LDFLAGS="$old_LDFLAGS"
1705 fi
1706 if $dynamic_list; then
1707   found="-Wl,--dynamic-list"
1708   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1709 else
1710   found="-rdynamic"
1711   RDYNAMIC="-rdynamic"
1712 fi
1713 AC_SUBST(RDYNAMIC)
1714 AC_MSG_RESULT($found)
1715
1716 dnl For certain native configurations, we need to check whether thread
1717 dnl support can be built in or not.
1718 dnl
1719 dnl Note that we only want this if we are both native (host == target),
1720 dnl and not doing a canadian cross build (build == host).
1721
1722 if test ${build} = ${host} -a ${host} = ${target} ; then
1723    case ${host_os} in
1724    solaris*)
1725       # See if thread_db library is around for Solaris thread debugging.
1726       # Note that we must explicitly test for version 1 of the library
1727       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1728       # the same API.
1729       AC_MSG_CHECKING(for Solaris thread debugging library)
1730       if test -f /usr/lib/libthread_db.so.1 ; then
1731          AC_MSG_RESULT(yes)
1732          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1733          [Define if using Solaris thread debugging.])
1734          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1735          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1736          # On SPARC CPUs, we also need to build sparc-sol-thread.
1737          case ${host_cpu} in
1738            sparc*)
1739              CONFIG_OBS="${CONFIG_OBS} sparc-sol-thread.o"
1740              CONFIG_SRCS="${CONFIG_SRCS} sparc-sol-thread.c"
1741              ;;
1742          esac
1743          AC_CHECK_LIB(dl, dlopen)
1744          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1745          # Sun randomly tweaked the prototypes in <proc_service.h>
1746          # at one point.
1747          AC_MSG_CHECKING(if <proc_service.h> is old)
1748          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1749             AC_TRY_COMPILE([
1750                 #include <proc_service.h>
1751                 ps_err_e ps_pdwrite
1752                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1753             ],, gdb_cv_proc_service_is_old=no,
1754                 gdb_cv_proc_service_is_old=yes)
1755          ])
1756          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1757          if test $gdb_cv_proc_service_is_old = yes; then
1758             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1759             [Define if <proc_service.h> on solaris uses int instead of
1760              size_t, and assorted other type changes.])
1761          fi
1762       else
1763          AC_MSG_RESULT(no)
1764       fi
1765       ;;
1766    aix*)
1767       AC_MSG_CHECKING(for AiX thread debugging library)
1768       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1769                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1770                                    [#ifndef PTHDB_VERSION_3
1771                                     #error
1772                                     #endif],
1773                                    gdb_cv_have_aix_thread_debug=yes,
1774                                    gdb_cv_have_aix_thread_debug=no)])
1775       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1776       if test $gdb_cv_have_aix_thread_debug = yes; then
1777          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1778          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1779          LIBS="$LIBS -lpthdebug"
1780
1781          # Older versions of AIX do not provide the declaration for
1782          # the getthrds function (it appears that it was introduced
1783          # with AIX 6.x).
1784          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1785       fi
1786       ;;
1787    esac
1788    AC_SUBST(CONFIG_LDFLAGS)
1789 fi
1790
1791 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1792 dnl other error codes.
1793 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1794    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1795                   gdb_cv_thread_db_h_has_td_notalloc,
1796      AC_TRY_COMPILE(
1797        [#include <thread_db.h>],
1798        [int i = TD_NOTALLOC;],
1799        gdb_cv_thread_db_h_has_td_notalloc=yes,
1800        gdb_cv_thread_db_h_has_td_notalloc=no
1801      )
1802    )
1803    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1804                   gdb_cv_thread_db_h_has_td_version,
1805      AC_TRY_COMPILE(
1806        [#include <thread_db.h>],
1807        [int i = TD_VERSION;],
1808        gdb_cv_thread_db_h_has_td_version=yes,
1809        gdb_cv_thread_db_h_has_td_version=no
1810      )
1811    )
1812    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1813                   gdb_cv_thread_db_h_has_td_notls,
1814      AC_TRY_COMPILE(
1815        [#include <thread_db.h>],
1816        [int i = TD_NOTLS;],
1817        gdb_cv_thread_db_h_has_td_notls=yes,
1818        gdb_cv_thread_db_h_has_td_notls=no
1819      )
1820    )
1821 fi
1822 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1823   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1824             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1825 fi
1826 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1827   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1828             [Define if <thread_db.h> has the TD_VERSION error code.])
1829 fi
1830 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1831   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1832             [Define if <thread_db.h> has the TD_NOTLS error code.])
1833 fi
1834
1835 dnl See if we have a sys/syscall header file that has __NR_tkill.
1836 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1837    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1838                   gdb_cv_sys_syscall_h_has_tkill,
1839      AC_TRY_COMPILE(
1840        [#include <sys/syscall.h>],
1841        [int i = __NR_tkill;],
1842        gdb_cv_sys_syscall_h_has_tkill=yes,
1843        gdb_cv_sys_syscall_h_has_tkill=no
1844      )
1845    )
1846 fi
1847 dnl See if we can issue tkill syscall.
1848 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1849   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1850 fi
1851
1852 dnl Check if we can disable the virtual address space randomization.
1853 dnl The functionality of setarch -R.
1854 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1855 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1856 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1857 #       define ADDR_NO_RANDOMIZE 0x0040000
1858 #      endif
1859        /* Test the flag could be set and stays set.  */
1860        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1861        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1862            return 1])])
1863 AC_RUN_IFELSE([PERSONALITY_TEST],
1864               [have_personality=true],
1865               [have_personality=false],
1866               [AC_LINK_IFELSE([PERSONALITY_TEST],
1867                               [have_personality=true],
1868                               [have_personality=false])])
1869 if $have_personality
1870 then
1871     AC_DEFINE([HAVE_PERSONALITY], 1,
1872               [Define if you support the personality syscall.])
1873 fi
1874
1875 dnl Handle optional features that can be enabled.
1876
1877 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1878 # except that the argument to --with-sysroot is optional.
1879 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1880 if test "x$with_sysroot" = xyes; then
1881   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1882 fi
1883 AC_ARG_WITH(sysroot,
1884   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1885                  [search for usr/lib et al within DIR]),
1886   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1887 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1888               [search for usr/lib et al within DIR])
1889 AC_SUBST(TARGET_SYSTEM_ROOT)
1890 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1891
1892 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1893     [automatically load a system-wide gdbinit file],
1894     [])
1895
1896 AC_ARG_ENABLE(werror,
1897   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1898   [case "${enableval}" in
1899      yes | y) ERROR_ON_WARNING="yes" ;;
1900      no | n)  ERROR_ON_WARNING="no" ;;
1901      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1902    esac])
1903
1904 # Enable -Werror by default when using gcc.  Turn it off for releases.
1905 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1906     ERROR_ON_WARNING=yes
1907 fi
1908
1909 WERROR_CFLAGS=""
1910 if test "${ERROR_ON_WARNING}" = yes ; then
1911     WERROR_CFLAGS="-Werror"
1912 fi
1913
1914 # The entries after -Wno-pointer-sign are disabled warnings which may
1915 # be enabled in the future, which can not currently be used to build
1916 # GDB.
1917 # NOTE: If you change this list, remember to update
1918 # gdb/doc/gdbint.texinfo.
1919 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1920 -Wformat-nonliteral -Wno-pointer-sign \
1921 -Wno-unused -Wunused-value -Wunused-function \
1922 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1923 -Wdeclaration-after-statement -Wempty-body"
1924
1925 # Enable -Wno-format by default when using gcc on mingw since many
1926 # GCC versions complain about %I64.
1927 case "${host}" in
1928   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1929 esac
1930
1931 AC_ARG_ENABLE(build-warnings,
1932 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1933 [case "${enableval}" in
1934   yes)  ;;
1935   no)   build_warnings="-w";;
1936   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1937         build_warnings="${build_warnings} ${t}";;
1938   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1939         build_warnings="${t} ${build_warnings}";;
1940   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1941 esac
1942 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1943   echo "Setting compiler warning flags = $build_warnings" 6>&1
1944 fi])dnl
1945 AC_ARG_ENABLE(gdb-build-warnings,
1946 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1947 [case "${enableval}" in
1948   yes)  ;;
1949   no)   build_warnings="-w";;
1950   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1951         build_warnings="${build_warnings} ${t}";;
1952   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1953         build_warnings="${t} ${build_warnings}";;
1954   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1955 esac
1956 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1957   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1958 fi])dnl
1959 WARN_CFLAGS=""
1960 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1961 then
1962     AC_MSG_CHECKING(compiler warning flags)
1963     # Separate out the -Werror flag as some files just cannot be
1964     # compiled with it enabled.
1965     for w in ${build_warnings}; do
1966         case $w in
1967         -Werr*) WERROR_CFLAGS=-Werror ;;
1968         *) # Check that GCC accepts it
1969             saved_CFLAGS="$CFLAGS"
1970             CFLAGS="$CFLAGS $w"
1971             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1972             CFLAGS="$saved_CFLAGS"
1973         esac
1974     done
1975     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1976 fi
1977 AC_SUBST(WARN_CFLAGS)
1978 AC_SUBST(WERROR_CFLAGS)
1979
1980 # In the Cygwin environment, we need some additional flags.
1981 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1982 [AC_EGREP_CPP(lose, [
1983 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1984 lose
1985 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1986
1987
1988 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1989 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1990 case ${host} in
1991   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1992   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1993   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1994 esac
1995 AC_SUBST(SER_HARDWIRE)
1996
1997 # libreadline needs libuser32.a in a cygwin environment
1998 WIN32LIBS=
1999 if test x$gdb_cv_os_cygwin = xyes; then
2000     WIN32LIBS="-luser32"
2001     case "${target}" in
2002         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2003         ;;
2004     esac
2005 fi
2006
2007 # The ser-tcp.c module requires sockets.
2008 case ${host} in
2009   *mingw32*)
2010     AC_DEFINE(USE_WIN32API, 1,
2011               [Define if we should use the Windows API, instead of the
2012                POSIX API.  On Windows, we use the Windows API when
2013                building for MinGW, but the POSIX API when building
2014                for Cygwin.])
2015     WIN32LIBS="$WIN32LIBS -lws2_32"
2016     ;;
2017 esac
2018 AC_SUBST(WIN32LIBS)
2019
2020 # Add ELF support to GDB, but only if BFD includes ELF support.
2021 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2022                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2023 if test $gdb_cv_var_elf = yes; then
2024   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2025   AC_DEFINE(HAVE_ELF, 1,
2026             [Define if ELF support should be included.])
2027   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2028   if test "$plugins" = "yes"; then
2029     LIBS="-ldl $LIBS"
2030   fi
2031 fi
2032
2033 # Add macho support to GDB, but only if BFD includes it.
2034 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2035                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2036 if test $gdb_cv_var_macho = yes; then
2037   CONFIG_OBS="$CONFIG_OBS machoread.o"
2038 fi
2039
2040 # Add SOM support to GDB, but only if BFD includes it.
2041 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2042                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2043 if test $gdb_cv_var_som = yes; then
2044   CONFIG_OBS="$CONFIG_OBS somread.o"
2045 fi
2046
2047 # Add any host-specific objects to GDB.
2048 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2049
2050 # If building on ELF, look for lzma support for embedded compressed debug info.
2051 if test $gdb_cv_var_elf = yes; then
2052   AC_ARG_WITH(lzma,
2053     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2054     [], [with_lzma=auto])
2055   AC_MSG_CHECKING([whether to use lzma])
2056   AC_MSG_RESULT([$with_lzma])
2057
2058   if test "${with_lzma}" != no; then
2059     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2060                           [lzma_index_iter iter;
2061                            lzma_index_iter_init (&iter, 0);
2062                            lzma_mf_is_supported (LZMA_MF_HC3);])
2063     if test "$HAVE_LIBLZMA" != yes; then
2064       if test "$with_lzma" = yes; then
2065         AC_MSG_ERROR([missing liblzma for --with-lzma])
2066       fi
2067     fi
2068   fi
2069 fi
2070
2071 LIBGUI="../libgui/src/libgui.a"
2072 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2073 AC_SUBST(LIBGUI)
2074 AC_SUBST(GUI_CFLAGS_X)
2075
2076 WIN32LDAPP=
2077 AC_SUBST(WIN32LIBS)
2078 AC_SUBST(WIN32LDAPP)
2079
2080 case "${host}" in
2081 *-*-cygwin* | *-*-mingw* )
2082     configdir="win"
2083     ;;
2084 *)
2085     configdir="unix"
2086     ;;
2087 esac
2088
2089 GDBTKLIBS=
2090 if test "${enable_gdbtk}" = "yes"; then
2091
2092     # Gdbtk must have an absolute path to srcdir in order to run
2093     # properly when not installed.
2094     here=`pwd`
2095     cd ${srcdir}
2096     GDBTK_SRC_DIR=`pwd`
2097     cd $here
2098
2099     SC_PATH_TCLCONFIG
2100
2101     # If $no_tk is nonempty, then we can't do Tk, and there is no
2102     # point to doing Tcl.
2103     SC_PATH_TKCONFIG
2104
2105     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2106         SC_LOAD_TCLCONFIG
2107
2108         # Check for in-tree tcl
2109         here=`pwd`
2110         cd ${srcdir}/..
2111         topdir=`pwd`
2112         cd ${here}
2113
2114         intree="no"
2115         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2116           intree="yes"
2117         fi
2118
2119         # Find Tcl private headers
2120         if test x"${intree}" = xno; then
2121           CY_AC_TCL_PRIVATE_HEADERS
2122           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2123           TCL_LIBRARY="${TCL_LIB_SPEC}"
2124           TCL_DEPS=""
2125         else
2126           # If building tcl in the same src tree, private headers
2127           # are not needed, but we need to be sure to use the right
2128           # headers library
2129           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2130           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2131           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2132         fi
2133         AC_SUBST(TCL_INCLUDE)
2134         AC_SUBST(TCL_LIBRARY)
2135         AC_SUBST(TCL_DEPS)
2136
2137         SC_LOAD_TKCONFIG
2138
2139         # Check for in-tree Tk
2140         intree="no"
2141         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2142           intree="yes"
2143         fi
2144
2145         # Find Tk private headers
2146         if test x"${intree}" = xno; then
2147           CY_AC_TK_PRIVATE_HEADERS
2148           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2149           TK_LIBRARY=${TK_LIB_SPEC}
2150           TK_DEPS=""
2151         else
2152           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2153           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2154           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2155         fi
2156         AC_SUBST(TK_INCLUDE)
2157         AC_SUBST(TK_LIBRARY)
2158         AC_SUBST(TK_DEPS)
2159         AC_SUBST(TK_XINCLUDES)
2160
2161         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2162
2163         # Include some libraries that Tcl and Tk want.
2164         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2165         # Yes, the ordering seems wrong here.  But it isn't.
2166         # TK_LIBS is the list of libraries that need to be linked
2167         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2168         # were in LIBS then any link tests after this point would
2169         # try to include things like `$(LIBGUI)', which wouldn't work.
2170         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2171
2172         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2173         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2174         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2175         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2176         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2177         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2178         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2179
2180         if test x$gdb_cv_os_cygwin = xyes; then
2181           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2182           WIN32LDAPP="-Wl,--subsystem,console"
2183           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2184         fi
2185
2186         AC_CONFIG_SUBDIRS(gdbtk)
2187     fi
2188 fi
2189
2190 AC_SUBST(X_CFLAGS)
2191 AC_SUBST(X_LDFLAGS)
2192 AC_SUBST(X_LIBS)
2193 AC_SUBST(GDBTKLIBS)
2194 AC_SUBST(GDBTK_CFLAGS)
2195 AC_SUBST(GDBTK_SRC_DIR)
2196
2197 AC_PATH_X
2198
2199 # Unlike the sim directory, whether a simulator is linked is controlled by
2200 # presence of a gdb_sim definition in the target configure.tgt entry.
2201 # This code just checks for a few cases where we'd like to ignore those
2202 # definitions, even when they're present in the '.mt' file.  These cases
2203 # are when --disable-sim is specified, or if the simulator directory is
2204 # not part of the source tree.
2205 #
2206 AC_ARG_ENABLE(sim,
2207 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2208 [echo "enable_sim = $enable_sim";
2209  echo "enableval = ${enableval}";
2210  case "${enableval}" in
2211   yes) ignore_sim=false ;;
2212   no)  ignore_sim=true ;;
2213   *)   ignore_sim=false ;;
2214  esac],
2215 [ignore_sim=false])
2216
2217 if test ! -d "${srcdir}/../sim"; then
2218   ignore_sim=true
2219 fi
2220
2221 SIM=
2222 SIM_OBS=
2223 if test "${ignore_sim}" = "false"; then
2224   if test x"${gdb_sim}" != x ; then
2225     SIM="${gdb_sim}"
2226     SIM_OBS="remote-sim.o"
2227     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2228   fi
2229 fi
2230 AC_SUBST(SIM)
2231 AC_SUBST(SIM_OBS)
2232
2233 AC_SUBST(ENABLE_CFLAGS)
2234 AC_SUBST(PROFILE_CFLAGS)
2235
2236 AC_SUBST(CONFIG_OBS)
2237 AC_SUBST(CONFIG_DEPS)
2238 AC_SUBST(CONFIG_SRCS)
2239 AC_SUBST(CONFIG_ALL)
2240 AC_SUBST(CONFIG_CLEAN)
2241 AC_SUBST(CONFIG_INSTALL)
2242 AC_SUBST(CONFIG_UNINSTALL)
2243
2244 # List of host floatformats.
2245 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2246 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2247 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2248
2249 # target_subdir is used by the testsuite to find the target libraries.
2250 target_subdir=
2251 if test "${host}" != "${target}"; then
2252     target_subdir="${target_alias}/"
2253 fi
2254 AC_SUBST(target_subdir)
2255
2256 frags=
2257 if test "${gdb_native}" = "yes"; then
2258   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2259   if test ! -f ${host_makefile_frag}; then
2260     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2261   fi
2262   frags="$frags $host_makefile_frag"
2263 else
2264   host_makefile_frag=/dev/null
2265 fi
2266
2267 AC_SUBST_FILE(host_makefile_frag)
2268 AC_SUBST(frags)
2269
2270 changequote(,)dnl
2271 if test "${gdb_native}" = "yes"; then
2272 # We pick this up from the host configuration file (.mh) because we
2273 # do not have a native configuration Makefile fragment.
2274 nativefile=`sed -n '
2275 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2276 ' ${host_makefile_frag}`
2277 fi
2278 changequote([,])
2279
2280 if test x"${gdb_osabi}" != x ; then
2281     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2282                        [Define to the default OS ABI for this configuration.])
2283 fi
2284
2285 # Enable multi-ice-gdb-server.
2286 AC_ARG_ENABLE(multi-ice,
2287 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2288   [case $enableval in
2289     yes | no)
2290       ;;
2291     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2292   esac])
2293 if test "x$enable_multi_ice" = xyes; then
2294    AC_CONFIG_SUBDIRS(multi-ice)
2295 fi
2296
2297 AC_ARG_ENABLE(gdbserver,
2298 AS_HELP_STRING([--enable-gdbserver],
2299                [automatically build gdbserver (yes/no/auto, default is auto)]),
2300 [case "${enableval}" in
2301   yes| no|auto) ;;
2302   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2303 esac],[enable_gdbserver=auto])
2304
2305 # We only build gdbserver automatically in a native configuration, and
2306 # only if the user did not explicitly disable its build.
2307 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2308   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2309   if test "x$build_gdbserver" = xyes; then
2310     AC_MSG_RESULT(yes)
2311     AC_CONFIG_SUBDIRS(gdbserver)
2312     gdbserver_build_enabled=yes
2313   else
2314     AC_MSG_RESULT(no)
2315   fi
2316 fi
2317
2318 # If the user explicitly request the gdbserver to be built, verify that
2319 # we were in fact able to enable it.
2320 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2321   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2322 fi
2323
2324 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2325 # to an empty version.
2326
2327 files=
2328 links=
2329
2330 rm -f nm.h
2331 if test "${nativefile}" != ""; then
2332     case "${nativefile}" in
2333       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2334       * ) GDB_NM_FILE="${nativefile}"
2335     esac
2336     files="${files} ${GDB_NM_FILE}"
2337     links="${links} nm.h"
2338     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2339 fi
2340 AC_SUBST(GDB_NM_FILE)
2341
2342 AC_LINK_FILES($files, $links)
2343
2344 dnl Check for exe extension set on certain hosts (e.g. Win32)
2345 AC_EXEEXT
2346
2347 dnl  Detect the character set used by this host.
2348 dnl  At the moment, we just assume it's UTF-8.
2349 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2350           [Define to be a string naming the default host character set.])
2351
2352 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2353 [
2354 case x$CONFIG_HEADERS in
2355 xconfig.h:config.in)
2356 echo > stamp-h ;;
2357 esac
2358 ])
2359
2360 exit 0