gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 dnl 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # GDB does not use automake, but gnulib does.  This line lets us
  91 # generate its Makefile.in.
  92 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  93
  94 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  95     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  96     [${libdir}/debug])
  97
  98 # GDB's datadir relocation
  99
 100 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 101     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 102     [${datadir}/gdb])
 103
 104 AC_ARG_WITH(relocated-sources,
 105 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 106 [reloc_srcdir="${withval}"
 107  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 108               [Relocated directory for source files. ])
 109 ])
 110
 111 AC_CONFIG_SUBDIRS(testsuite)
 112
 113 # Check whether to support alternative target configurations
 114 AC_ARG_ENABLE(targets,
 115 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 116 [case "${enableval}" in
 117   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 118             ;;
 119   no)       enable_targets= ;;
 120   *)        enable_targets=$enableval ;;
 121 esac])
 122
 123 # Check whether to enable 64-bit support on 32-bit hosts
 124 AC_ARG_ENABLE(64-bit-bfd,
 125 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 126 [case "${enableval}" in
 127   yes)  want64=true  ;;
 128   no)   want64=false ;;
 129   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 130 esac],[want64=false])dnl
 131
 132 # Provide defaults for some variables set by the per-host and per-target
 133 # configuration.
 134 gdb_host_obs=posix-hdep.o
 135
 136 if test "${target}" = "${host}"; then
 137   gdb_native=yes
 138 else
 139   gdb_native=no
 140 fi
 141
 142 . $srcdir/configure.host
 143
 144 # Accumulate some settings from configure.tgt over all enabled targets
 145
 146 TARGET_OBS=
 147 all_targets=
 148
 149 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 150 do
 151   if test "$targ_alias" = "all"; then
 152     all_targets=true
 153   else
 154     # Canonicalize the secondary target names.
 155     result=`$ac_config_sub $targ_alias 2>/dev/null`
 156     if test -n "$result"; then
 157         targ=$result
 158     else
 159         targ=$targ_alias
 160     fi
 161
 162     . ${srcdir}/configure.tgt
 163
 164     AS_IF([test -z "${gdb_target_obs}"],
 165       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 166
 167     # Target-specific object files
 168     for i in ${gdb_target_obs}; do
 169         case " $TARGET_OBS " in
 170         *" ${i} "*) ;;
 171         *)
 172           TARGET_OBS="$TARGET_OBS ${i}"
 173           ;;
 174         esac
 175     done
 176
 177     # Check whether this target needs 64-bit CORE_ADDR
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181   fi
 182 done
 183
 184 if test x${all_targets} = xtrue; then
 185
 186   # We want all 64-bit targets if we either:
 187   #  - run on a 64-bit host  or
 188   #  - already require 64-bit support for some other target  or
 189   #  - the --enable-64-bit-bfd option was supplied
 190   # Otherwise we only support all 32-bit targets.
 191   #
 192   # NOTE: This test must be in sync with the corresponding
 193   #       tests in BFD!
 194
 195   if test x${want64} = xfalse; then
 196     AC_CHECK_SIZEOF(long)
 197     if test "x${ac_cv_sizeof_long}" = "x8"; then
 198       want64=true
 199     fi
 200   fi
 201   if test x${want64} = xtrue; then
 202     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 203   else
 204     TARGET_OBS='$(ALL_TARGET_OBS)'
 205   fi
 206 fi
 207
 208 AC_SUBST(TARGET_OBS)
 209
 210 # For other settings, only the main target counts.
 211 gdb_sim=
 212 gdb_osabi=
 213 build_gdbserver=
 214 targ=$target; . ${srcdir}/configure.tgt
 215
 216 # Fetch the default architecture and default target vector from BFD.
 217 targ=$target; . $srcdir/../bfd/config.bfd
 218
 219 # We only want the first architecture, so strip off the others if
 220 # there is more than one.
 221 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 222
 223 if test "x$targ_archs" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 225     [Define to BFD's default architecture. ])
 226 fi
 227 if test "x$targ_defvec" != x; then
 228   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 229     [Define to BFD's default target vector. ])
 230 fi
 231
 232 # The CLI cannot be disabled yet, but may be in the future.
 233
 234 # Enable CLI.
 235 AC_ARG_ENABLE(gdbcli,
 236 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 237   [case $enableval in
 238     yes)
 239       ;;
 240     no)
 241       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 242     *)
 243       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 244   esac],
 245   [enable_gdbcli=yes])
 246 if test x"$enable_gdbcli" = xyes; then
 247   if test -d $srcdir/cli; then
 248     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 249     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 250     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 251     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 252   fi
 253 fi
 254
 255 # Enable MI.
 256 AC_ARG_ENABLE(gdbmi,
 257 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 258   [case $enableval in
 259     yes | no)
 260       ;;
 261     *)
 262       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 263   esac],
 264   [enable_gdbmi=yes])
 265 if test x"$enable_gdbmi" = xyes; then
 266   if test -d $srcdir/mi; then
 267     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 268     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 269     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 270     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 271   fi
 272 fi
 273
 274 # Enable TUI.
 275 AC_ARG_ENABLE(tui,
 276 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 277   [case $enableval in
 278     yes | no | auto)
 279       ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 282   esac],enable_tui=auto)
 283
 284 # Enable gdbtk.
 285 AC_ARG_ENABLE(gdbtk,
 286 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 292   esac],
 293   [if test -d $srcdir/gdbtk; then
 294     enable_gdbtk=yes
 295   else
 296     enable_gdbtk=no
 297   fi])
 298 # We unconditionally disable gdbtk tests on selected platforms.
 299 case $host_os in
 300   go32* | windows*)
 301     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 302     enable_gdbtk=no ;;
 303 esac
 304
 305 # Libunwind support.
 306 AC_ARG_WITH(libunwind,
 307 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 308 [case "${withval}" in
 309   yes)  enable_libunwind=yes ;;
 310   no)   enable_libunwind=no ;;
 311   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 312 esac],[
 313   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 314   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 315     enable_libunwind=yes;
 316   fi
 317 ])
 318
 319 if test x"$enable_libunwind" = xyes; then
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 322   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 323   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 324   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 325 fi
 326
 327 opt_curses=no
 328 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 329
 330 prefer_curses=no
 331 if test "$opt_curses" = "yes"; then
 332   prefer_curses=yes
 333 fi
 334
 335 # Profiling support.
 336 AC_ARG_ENABLE(profiling,
 337 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 338   [case $enableval in
 339     yes | no)
 340       ;;
 341     *)
 342       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 343   esac],
 344  [enable_profiling=no])
 345
 346 AC_CHECK_FUNCS(monstartup _mcleanup)
 347 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 348 [AC_TRY_LINK(
 349 [#include <stdlib.h>
 350 extern char _etext;
 351 ],
 352 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 353 if test $ac_cv_var__etext = yes; then
 354   AC_DEFINE(HAVE__ETEXT, 1,
 355             [Define to 1 if your system has the _etext variable. ])
 356 fi
 357 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 358 [AC_TRY_LINK(
 359 [#include <stdlib.h>
 360 extern char etext;
 361 ],
 362 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 363 if test $ac_cv_var_etext = yes; then
 364   AC_DEFINE(HAVE_ETEXT, 1,
 365             [Define to 1 if your system has the etext variable. ])
 366 fi
 367 if test "$enable_profiling" = yes ; then
 368   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 369     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 370   fi
 371   PROFILE_CFLAGS=-pg
 372   OLD_CFLAGS="$CFLAGS"
 373   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 374
 375   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 376     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 377      ac_cv_cc_supports_pg=no)])
 378
 379   if test $ac_cv_cc_supports_pg = no; then
 380     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 381   fi
 382
 383   CFLAGS="$OLD_CFLAGS"
 384 fi
 385
 386 ACX_PKGVERSION([GDB])
 387 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 388 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 389 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 390
 391 # --------------------- #
 392 # Checks for programs.  #
 393 # --------------------- #
 394
 395 AC_PROG_AWK
 396 AC_PROG_INSTALL
 397 AC_PROG_LN_S
 398 AC_PROG_RANLIB
 399 AC_PROG_YACC
 400
 401 AC_CHECK_TOOL(AR, ar)
 402 AC_CHECK_TOOL(DLLTOOL, dlltool)
 403 AC_CHECK_TOOL(WINDRES, windres)
 404
 405 # Needed for GNU/Hurd.
 406 AC_CHECK_TOOL(MIG, mig)
 407
 408 # ---------------------- #
 409 # Checks for libraries.  #
 410 # ---------------------- #
 411
 412 # We might need to link with -lm; most simulators need it.
 413 AC_CHECK_LIB(m, main)
 414
 415 # We need to link with -lw to get `wctype' on Solaris before Solaris
 416 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 417 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 418 # is known to have this problem).  Therefore we avoid libw if we can.
 419 AC_CHECK_FUNC(wctype, [],
 420   [AC_CHECK_LIB(w, wctype)])
 421
 422 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 423 AC_SEARCH_LIBS(gethostbyname, nsl)
 424
 425 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 426 AC_SEARCH_LIBS(socketpair, socket)
 427
 428 # Link in zlib if we can.  This allows us to read compressed debug sections.
 429 AM_ZLIB
 430
 431 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 432 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 433
 434 AM_ICONV
 435
 436 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 437 # There is a very specific comment in /usr/include/curses.h explaining that
 438 # termcap routines built into libcurses must not be used.
 439 #
 440 # The symptoms we observed so far is GDB unexpectedly changing
 441 # the terminal settings when tgetent is called - this is particularly
 442 # visible as the output is missing carriage returns, and so rapidly
 443 # becomes very hard to read.
 444 #
 445 # The readline configure script has already decided that libtermcap
 446 # was enough for its purposes, and so decided to build readline using
 447 # libtermcap.  Since the TUI mode requires curses, building GDB with
 448 # TUI enabled results in both libraries to be used at the same time,
 449 # which is not allowed.  This basically means that GDB with TUI is
 450 # broken on alpha-osf.
 451
 452 case $host_os in
 453   osf* )
 454     if test x"$enable_tui" = xyes; then
 455       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 456     fi
 457     if test x"$enable_tui" = xauto; then
 458       enable_tui=no
 459     fi
 460     ;;
 461 esac
 462
 463 # For the TUI, we need enhanced curses functionality.
 464 if test x"$enable_tui" != xno; then
 465   prefer_curses=yes
 466 fi
 467
 468 curses_found=no
 469 if test x"$prefer_curses" = xyes; then
 470   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 471   # curses library because the latter might not provide all the
 472   # functionality we need.  However, this leads to problems on systems
 473   # where the linker searches /usr/local/lib, but the compiler doesn't
 474   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 475   # default installation of ncurses on alpha*-dec-osf* will lead to such
 476   # a situation.
 477   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 478
 479   if test "$ac_cv_search_waddstr" != no; then
 480     curses_found=yes
 481   fi
 482 fi
 483
 484 # Check whether we should enable the TUI, but only do so if we really
 485 # can.
 486 if test x"$enable_tui" != xno; then
 487   if test -d $srcdir/tui; then
 488     if test "$curses_found" != no; then
 489       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 490       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 491       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 492       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 493       CONFIG_ALL="${CONFIG_ALL} all-tui"
 494       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 495       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 496       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 497     else
 498       if test x"$enable_tui" = xyes; then
 499         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 500       else
 501         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 502       fi
 503     fi
 504   fi
 505 fi
 506
 507 # Since GDB uses Readline, we need termcap functionality.  In many
 508 # cases this will be provided by the curses library, but some systems
 509 # have a seperate termcap library, or no curses library at all.
 510
 511 case $host_os in
 512   cygwin*)
 513     if test -d $srcdir/libtermcap; then
 514       LIBS="../libtermcap/libtermcap.a $LIBS"
 515       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 516     fi ;;
 517   go32* | *djgpp*)
 518     ac_cv_search_tgetent="none required"
 519     ;;
 520   *mingw32*)
 521     ac_cv_search_tgetent="none required"
 522     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 523     ;;
 524 esac
 525
 526 # These are the libraries checked by Readline.
 527 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 528
 529 if test "$ac_cv_search_tgetent" = no; then
 530   AC_MSG_ERROR([no termcap library found])
 531 fi
 532
 533 AC_ARG_WITH([system-readline],
 534   [AS_HELP_STRING([--with-system-readline],
 535                   [use installed readline library])])
 536
 537 if test "$with_system_readline" = yes; then
 538   READLINE=-lreadline
 539   READLINE_DEPS=
 540   READLINE_CFLAGS=
 541   READLINE_TEXI_INCFLAG=
 542
 543   # readline-6.0 started to use the name `_rl_echoing_p'.
 544   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 545
 546   AC_MSG_CHECKING([for readline_echoing_p])
 547   save_LIBS=$LIBS
 548   LIBS="$LIBS $READLINE"
 549   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 550                                     return readline_echoing_p;]]),
 551                  [READLINE_ECHOING_P=yes],
 552                  [READLINE_ECHOING_P=no
 553                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 554                             [readline-6.0 started to use different name.])])
 555   LIBS="$save_LIBS"
 556   AC_MSG_RESULT([$READLINE_ECHOING_P])
 557 else
 558   READLINE='$(READLINE_DIR)/libreadline.a'
 559   READLINE_DEPS='$(READLINE)'
 560   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 561   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 562 fi
 563 AC_SUBST(READLINE)
 564 AC_SUBST(READLINE_DEPS)
 565 AC_SUBST(READLINE_CFLAGS)
 566 AC_SUBST(READLINE_TEXI_INCFLAG)
 567
 568 AC_ARG_WITH(expat,
 569   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 570   [], [with_expat=auto])
 571 AC_MSG_CHECKING([whether to use expat])
 572 AC_MSG_RESULT([$with_expat])
 573
 574 if test "${with_expat}" = no; then
 575   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 576   HAVE_LIBEXPAT=no
 577 else
 578   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 579                         [XML_Parser p = XML_ParserCreate (0);])
 580   if test "$HAVE_LIBEXPAT" != yes; then
 581     if test "$with_expat" = yes; then
 582       AC_MSG_ERROR([expat is missing or unusable])
 583     else
 584       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 585     fi
 586   else
 587     save_LIBS=$LIBS
 588     LIBS="$LIBS $LIBEXPAT"
 589     AC_CHECK_FUNCS(XML_StopParser)
 590     LIBS=$save_LIBS
 591   fi
 592 fi
 593
 594 dnl Utility to simplify finding libpython.
 595 dnl $1 = pythonX.Y
 596 dnl $2 = the shell variable to assign the result to
 597 dnl      If libpython is found we store $version here.
 598 dnl $3 = additional flags to add to CPPFLAGS
 599 dnl $4 = additional flags to add to LIBS
 600
 601 AC_DEFUN([AC_TRY_LIBPYTHON],
 602 [
 603   version=$1
 604   define([have_libpython_var],$2)
 605   new_CPPFLAGS=$3
 606   new_LIBS=$4
 607   AC_MSG_CHECKING([for ${version}])
 608   save_CPPFLAGS=$CPPFLAGS
 609   save_LIBS=$LIBS
 610   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 611   LIBS="$LIBS $new_LIBS"
 612   found_usable_python=no
 613   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 614                                  [[Py_Initialize ();]]),
 615                  [have_libpython_var=${version}
 616                   found_usable_python=yes
 617                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 618                   PYTHON_LIBS=$new_LIBS])
 619   CPPFLAGS=$save_CPPFLAGS
 620   LIBS=$save_LIBS
 621   AC_MSG_RESULT([${found_usable_python}])
 622 ])
 623
 624 dnl There are several different values for --with-python:
 625 dnl
 626 dnl no -   Don't include python support.
 627 dnl yes -  Include python support, error if it's missing.
 628 dnl        If we find python in $PATH, use it to fetch configure options,
 629 dnl        otherwise assume the compiler can find it with no help from us.
 630 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 631 dnl auto - Same as "yes", but if python is missing from the system,
 632 dnl        fall back to "no".
 633 dnl /path/to/python/exec-prefix -
 634 dnl        Use the python located in this directory.
 635 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 636 dnl        the compilation parameters.  Otherwise use
 637 dnl        -I/path/to/python/exec-prefix/include,
 638 dnl        -L/path/to/python/exec-prefix/lib.
 639 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 640 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 641 dnl        but is deprecated.
 642 dnl /path/to/python/executable -
 643 dnl        Run python-config.py with this version of python to fetch the
 644 dnl        compilation parameters.
 645 dnl        NOTE: This needn't be the real python executable.
 646 dnl        In a cross-compilation scenario (build != host), this could be
 647 dnl        a shell script that provides what python-config.py provides for
 648 dnl        --ldflags, --includes, --exec-prefix.
 649 dnl python-executable -
 650 dnl        Find python-executable in $PATH, and then handle the same as
 651 dnl        /path/to/python/executable.
 652 dnl
 653 dnl If a python program is specified, it is used to run python-config.py and
 654 dnl is passed --ldflags, --includes, --exec-prefix.
 655
 656 AC_ARG_WITH(python,
 657   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 658   [], [with_python=auto])
 659 AC_MSG_CHECKING([whether to use python])
 660 AC_MSG_RESULT([$with_python])
 661
 662 if test "${with_python}" = no; then
 663   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 664   have_libpython=no
 665 else
 666   case "${with_python}" in
 667   /*)
 668     if test -d ${with_python}; then
 669       # Assume the python binary is ${with_python}/bin/python.
 670       python_prog="${with_python}/bin/python"
 671       python_prefix=
 672       # If python does not exit ${with_python}/bin, then try in
 673       # ${with_python}.  On Windows/MinGW, this is where the Python
 674       # executable is.
 675       if test ! -x "${python_prog}"; then
 676         python_prog="${with_python}/python"
 677         python_prefix=
 678       fi
 679       if test ! -x "${python_prog}"; then
 680         # Fall back to gdb 7.0/7.1 behaviour.
 681         python_prog=missing
 682         python_prefix=${with_python}
 683       fi
 684     elif test -x "${with_python}"; then
 685       # While we can't run python compiled for $host (unless host == build),
 686       # the user could write a script that provides the needed information,
 687       # so we support that.
 688       python_prog=${with_python}
 689       python_prefix=
 690     else
 691       AC_ERROR(invalid value for --with-python)
 692     fi
 693     ;;
 694   */*)
 695     # Disallow --with-python=foo/bar.
 696     AC_ERROR(invalid value for --with-python)
 697     ;;
 698   *)
 699     # The user has either specified auto, yes, or the name of the python
 700     # program assumed to be in $PATH.
 701     python_prefix=
 702     case "${with_python}" in
 703     yes | auto)
 704       if test ${build} = ${host}; then
 705         AC_PATH_PROG(python_prog_path, python, missing)
 706         if test "${python_prog_path}" = missing; then
 707           python_prog=missing
 708         else
 709           python_prog=${python_prog_path}
 710         fi
 711       else
 712         # Not much we can do except assume the cross-compiler will find the
 713         # right files.
 714         python_prog=missing
 715       fi
 716       ;;
 717     *)
 718       # While we can't run python compiled for $host (unless host == build),
 719       # the user could write a script that provides the needed information,
 720       # so we support that.
 721       python_prog="${with_python}"
 722       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 723       if test "${python_prog_path}" = missing; then
 724         AC_ERROR(unable to find python program ${python_prog})
 725       fi
 726       ;;
 727     esac
 728   esac
 729
 730   if test "${python_prog}" != missing; then
 731     # We have a python program to use, but it may be too old.
 732     # Don't flag an error for --with-python=auto (the default).
 733     have_python_config=yes
 734     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 735     if test $? != 0; then
 736       have_python_config=failed
 737       if test "${with_python}" != auto; then
 738         AC_ERROR(failure running python-config --includes)
 739       fi
 740     fi
 741     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 742     if test $? != 0; then
 743       have_python_config=failed
 744       if test "${with_python}" != auto; then
 745         AC_ERROR(failure running python-config --ldflags)
 746       fi
 747     fi
 748     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 749     if test $? != 0; then
 750       have_python_config=failed
 751       if test "${with_python}" != auto; then
 752         AC_ERROR(failure running python-config --exec-prefix)
 753       fi
 754     fi
 755   else
 756     # We do not have a python executable we can use to determine where
 757     # to find the Python headers and libs.  We cannot guess the include
 758     # path from the python_prefix either, because that include path
 759     # depends on the Python version.  So, there is nothing much we can
 760     # do except assume that the compiler will be able to find those files.
 761     python_includes=
 762     python_libs=
 763     have_python_config=no
 764   fi
 765
 766   # If we have python-config, only try the configuration it provides.
 767   # Otherwise fallback on the old way of trying different versions of
 768   # python in turn.
 769
 770   have_libpython=no
 771   if test "${have_python_config}" = yes; then
 772     python_version=`echo " ${python_libs} " \
 773                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]\?[[0-9]]*\).*$,\1,'`
 774     case "${python_version}" in
 775     python*)
 776       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 777                        ${python_includes}, ${python_libs})
 778       ;;
 779     *)
 780       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 781       ;;
 782     esac
 783   elif test "${have_python_config}" != failed; then
 784     if test "${have_libpython}" = no; then
 785       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 786                        ${python_includes}, "${python_libs} -lpython2.7")
 787     fi
 788     if test "${have_libpython}" = no; then
 789       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 790                        ${python_includes}, "${python_libs} -lpython2.6")
 791     fi
 792     if test ${have_libpython} = no; then
 793       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 794                        ${python_includes}, "${python_libs} -lpython2.5")
 795     fi
 796     if test ${have_libpython} = no; then
 797       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 798                        ${python_includes}, "${python_libs} -lpython2.4")
 799     fi
 800   fi
 801   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 802     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 803   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 804     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 805   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 806     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 807   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 808     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 809   fi
 810
 811   if test "${have_libpython}" = no; then
 812     case "${with_python}" in
 813     yes)
 814       AC_MSG_ERROR([python is missing or unusable])
 815       ;;
 816     auto)
 817       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 818       ;;
 819     *)
 820       AC_MSG_ERROR([no usable python found at ${with_python}])
 821       ;;
 822     esac
 823   else
 824     if test -n "${python_prefix}"; then
 825       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 826                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 827       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 828     fi
 829   fi
 830 fi
 831
 832 if test "${have_libpython}" != no; then
 833   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 834   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 835   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 836   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 837   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 838   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 839
 840   # Flags needed to compile Python code (taken from python-config --cflags).
 841   # We cannot call python-config directly because it will output whatever was
 842   # used when compiling the Python interpreter itself, including flags which
 843   # would make the python-related objects be compiled differently from the
 844   # rest of GDB (e.g., -O2 and -fPIC).
 845   if test "${GCC}" = yes; then
 846     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 847   fi
 848
 849   if test "x${tentative_python_cflags}" != x; then
 850     AC_MSG_CHECKING(compiler flags for python code)
 851     for flag in ${tentative_python_cflags}; do
 852       # Check that the compiler accepts it
 853       saved_CFLAGS="$CFLAGS"
 854       CFLAGS="$CFLAGS $flag"
 855       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 856       CFLAGS="$saved_CFLAGS"
 857     done
 858     AC_MSG_RESULT(${PYTHON_CFLAGS})
 859   fi
 860
 861   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 862   #    #if _SGIAPI
 863   #    #define siginfo __siginfo
 864   #    #endif
 865   # The problem is that including Python causes some XOPEN macros to be
 866   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 867   # to false.  So, we work around this issue by defining siginfo ourself
 868   # though the command-line.
 869   case "$gdb_host" in
 870     irix*) if test "${GCC}" = yes; then
 871              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 872            fi
 873            ;;
 874   esac
 875 else
 876   # Even if Python support is not compiled in, we need to have these files
 877   # included.
 878   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 879   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 880         python/py-prettyprint.c python/py-auto-load.c"
 881 fi
 882 AC_SUBST(PYTHON_CFLAGS)
 883 AC_SUBST(PYTHON_CPPFLAGS)
 884 AC_SUBST(PYTHON_LIBS)
 885
 886 # ------------------------- #
 887 # Checks for header files.  #
 888 # ------------------------- #
 889
 890 AC_HEADER_DIRENT
 891 AC_HEADER_STAT
 892 AC_HEADER_STDC
 893 # elf_hp.h is for HP/UX 64-bit shared library support.
 894 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 895 # unconditionally, so what's the point in checking these?
 896 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 897                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 898                   stdlib.h string.h memory.h strings.h sys/fault.h \
 899                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 900                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 901                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 902                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 903                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 904 AC_CHECK_HEADERS(link.h, [], [],
 905 [#if HAVE_SYS_TYPES_H
 906 # include <sys/types.h>
 907 #endif
 908 #if HAVE_NLIST_H
 909 # include <nlist.h>
 910 #endif
 911 ])
 912 AC_CHECK_HEADERS(sys/proc.h, [], [],
 913 [#if HAVE_SYS_PARAM_H
 914 # include <sys/param.h>
 915 #endif
 916 ])
 917 AC_CHECK_HEADERS(sys/user.h, [], [],
 918 [#if HAVE_SYS_PARAM_H
 919 # include <sys/param.h>
 920 #endif
 921 ])
 922
 923 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 924 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 925 # think that we don't have <curses.h> if we're using GCC.
 926 case $host_os in
 927   solaris2.[[789]])
 928     if test "$GCC" = yes; then
 929       AC_DEFINE(_MSE_INT_H, 1,
 930         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 931    Solaris 2.[789] when using GCC. ])
 932     fi ;;
 933 esac
 934 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 935 AC_CHECK_HEADERS(term.h, [], [],
 936 [#if HAVE_CURSES_H
 937 # include <curses.h>
 938 #endif
 939 ])
 940
 941 # ------------------------- #
 942 # Checks for declarations.  #
 943 # ------------------------- #
 944
 945 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 946                 snprintf, vsnprintf])
 947 AM_LC_MESSAGES
 948
 949 # ----------------------- #
 950 # Checks for structures.  #
 951 # ----------------------- #
 952
 953 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 954
 955 # ------------------ #
 956 # Checks for types.  #
 957 # ------------------ #
 958
 959 AC_TYPE_SIGNAL
 960 AC_CHECK_TYPES(socklen_t, [], [],
 961 [#include <sys/types.h>
 962 #include <sys/socket.h>
 963 ])
 964
 965 # ------------------------------------- #
 966 # Checks for compiler characteristics.  #
 967 # ------------------------------------- #
 968
 969 AC_C_CONST
 970 AC_C_INLINE
 971 AC_C_BIGENDIAN
 972
 973 # ------------------------------ #
 974 # Checks for library functions.  #
 975 # ------------------------------ #
 976
 977 AC_FUNC_ALLOCA
 978 AC_FUNC_MMAP
 979 AC_FUNC_VFORK
 980 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 981                 getgid pipe poll pread64 resize_term sbrk setpgid setpgrp setsid \
 982                 sigaction sigprocmask sigsetmask socketpair syscall \
 983                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
 984                 setrlimit getrlimit posix_madvise waitpid])
 985 AM_LANGINFO_CODESET
 986
 987 # Check the return and argument types of ptrace.  No canned test for
 988 # this, so roll our own.
 989 gdb_ptrace_headers='
 990 #if HAVE_SYS_TYPES_H
 991 # include <sys/types.h>
 992 #endif
 993 #if HAVE_SYS_PTRACE_H
 994 # include <sys/ptrace.h>
 995 #endif
 996 #if HAVE_UNISTD_H
 997 # include <unistd.h>
 998 #endif
 999 '
1000 # There is no point in checking if we don't have a prototype.
1001 AC_CHECK_DECLS(ptrace, [], [
1002   : ${gdb_cv_func_ptrace_ret='int'}
1003   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1004 ], $gdb_ptrace_headers)
1005 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1006 # empty argument list, so check for that explicitly.
1007 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1008   AC_TRY_COMPILE($gdb_ptrace_headers,
1009     [extern long ptrace (enum __ptrace_request, ...);],
1010     gdb_cv_func_ptrace_ret='long',
1011     AC_TRY_COMPILE($gdb_ptrace_headers,
1012       [extern int ptrace ();],
1013       gdb_cv_func_ptrace_ret='int',
1014       gdb_cv_func_ptrace_ret='long')))
1015 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1016   [Define as the return type of ptrace.])
1017 # Check argument types.
1018 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1019   AC_TRY_COMPILE($gdb_ptrace_headers,
1020     [extern long ptrace (enum __ptrace_request, ...);],
1021     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1022 for gdb_arg1 in 'int' 'long'; do
1023  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1024   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1025    for gdb_arg4 in 'int' 'long'; do
1026      AC_TRY_COMPILE($gdb_ptrace_headers, [
1027 extern $gdb_cv_func_ptrace_ret
1028   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1029 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1030     break 4;])
1031     for gdb_arg5 in 'int *' 'int' 'long'; do
1032      AC_TRY_COMPILE($gdb_ptrace_headers, [
1033 extern $gdb_cv_func_ptrace_ret
1034   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1035 ], [
1036 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1037     break 5;])
1038     done
1039    done
1040   done
1041  done
1042 done
1043 # Provide a safe default value.
1044 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1045 ])])
1046 ac_save_IFS=$IFS; IFS=','
1047 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1048 IFS=$ac_save_IFS
1049 shift
1050 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1051   [Define to the type of arg 3 for ptrace.])
1052 if test -n "$[5]"; then
1053   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1054     [Define to the type of arg 5 for ptrace.])
1055 fi
1056
1057 dnl AC_FUNC_SETPGRP does not work when cross compiling
1058 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1059 if test "$cross_compiling" = no; then
1060   AC_FUNC_SETPGRP
1061 else
1062   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1063     [AC_TRY_COMPILE([
1064 #include <unistd.h>
1065 ], [
1066   if (setpgrp(1,1) == -1)
1067     exit (0);
1068   else
1069     exit (1);
1070 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1071 if test $ac_cv_func_setpgrp_void = yes; then
1072   AC_DEFINE(SETPGRP_VOID, 1)
1073 fi
1074 fi
1075
1076 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1077 # since sigsetjmp might only be defined as a macro.
1078 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1079 [AC_TRY_COMPILE([
1080 #include <setjmp.h>
1081 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1082 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1083 if test $gdb_cv_func_sigsetjmp = yes; then
1084   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1085 fi
1086
1087 # Assume we'll default to using the included libiberty regex.
1088 gdb_use_included_regex=yes
1089
1090 # However, if the system regex is GNU regex, then default to *not*
1091 # using the included regex.
1092 AC_CACHE_CHECK(
1093   [for GNU regex],
1094   [gdb_cv_have_gnu_regex],
1095   [AC_TRY_COMPILE(
1096     [#include <gnu-versions.h>],
1097     [#define REGEX_INTERFACE_VERSION 1
1098 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1099 # error "Version mismatch"
1100 #endif],
1101     gdb_cv_have_gnu_regex=yes,
1102     gdb_cv_have_gnu_regex=no)])
1103 if test $gdb_cv_have_gnu_regex = yes; then
1104   gdb_use_included_regex=no
1105 fi
1106
1107 AC_ARG_WITH(included-regex,
1108   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1109   gdb_with_regex=$withval,
1110   gdb_with_regex=$gdb_use_included_regex)
1111 if test "$gdb_with_regex" = yes; then
1112   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1113     [Define to 1 if the regex included in libiberty should be used.])
1114 fi
1115
1116 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1117 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1118 [#include <sys/param.h>
1119 #include <sys/proc.h>
1120 ])
1121
1122 # See if <sys/lwp.h> defines `struct lwp`.
1123 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1124 [AC_TRY_COMPILE([#include <sys/param.h>
1125 #include <sys/lwp.h>], [struct lwp l;],
1126 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1127 if test $gdb_cv_struct_lwp = yes; then
1128   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1129             [Define to 1 if your system has struct lwp.])
1130 fi
1131
1132 # See if <machine/reg.h> degines `struct reg'.
1133 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1134 [AC_TRY_COMPILE([#include <sys/types.h>
1135 #include <machine/reg.h>], [struct reg r;],
1136 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1137 if test $gdb_cv_struct_reg = yes; then
1138   AC_DEFINE(HAVE_STRUCT_REG, 1,
1139             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1140 fi
1141
1142 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1143 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1144 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1145                  [#include <machine/reg.h>])
1146
1147 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1148 AC_MSG_CHECKING(for PTRACE_GETREGS)
1149 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1150 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1151                 [PTRACE_GETREGS;],
1152                 [gdb_cv_have_ptrace_getregs=yes],
1153                 [gdb_cv_have_ptrace_getregs=no])])
1154 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1155 if test $gdb_cv_have_ptrace_getregs = yes; then
1156   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1157   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1158 fi
1159
1160 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1161 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1162 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1163 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1164                 [PTRACE_GETFPXREGS;],
1165                 [gdb_cv_have_ptrace_getfpxregs=yes],
1166                 [gdb_cv_have_ptrace_getfpxregs=no])])
1167 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1168 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1169   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1170   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1171 fi
1172
1173 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1174 AC_MSG_CHECKING(for PT_GETDBREGS)
1175 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1176 [AC_TRY_COMPILE([#include <sys/types.h>
1177 #include <sys/ptrace.h>],
1178                 [PT_GETDBREGS;],
1179                 [gdb_cv_have_pt_getdbregs=yes],
1180                 [gdb_cv_have_pt_getdbregs=no])])
1181 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1182 if test $gdb_cv_have_pt_getdbregs = yes; then
1183   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1184   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1185 fi
1186
1187 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1188 AC_MSG_CHECKING(for PT_GETXMMREGS)
1189 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1190 [AC_TRY_COMPILE([#include <sys/types.h>
1191 #include <sys/ptrace.h>],
1192                 [PT_GETXMMREGS;],
1193                 [gdb_cv_have_pt_getxmmregs=yes],
1194                 [gdb_cv_have_pt_getxmmregs=no])])
1195 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1196 if test $gdb_cv_have_pt_getxmmregs = yes; then
1197   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1198   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1199 fi
1200
1201 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1202
1203 if test "${target}" = "${host}"; then
1204   case "${host}" in
1205   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1206       AC_DEFINE(NEW_PROC_API, 1,
1207       [Define if you want to use new multi-fd /proc interface
1208        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1209       ;;
1210   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1211       AC_DEFINE(NEW_PROC_API, 1,
1212       [Define if you want to use new multi-fd /proc interface
1213        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1214       ;;
1215   mips-sgi-irix5*)
1216       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1217       AC_DEFINE([_KMEMUSER], 1,
1218       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1219        around a <sys/proc.h> problem on IRIX 5.])
1220       ;;
1221   esac
1222 fi
1223
1224 if test "$ac_cv_header_sys_procfs_h" = yes; then
1225   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1226   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1227   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1228   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1229   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1230   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1231   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1232   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1233   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1234   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1235   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1236   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1237   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1238   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1239
1240
1241   dnl Check for broken prfpregset_t type
1242
1243   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1244   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1245   dnl instead of the struct itself).  We detect this here, and work
1246   dnl around it in gdb_proc_service.h.
1247
1248   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1249     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1250     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1251       [AC_TRY_RUN([#include <sys/procfs.h>
1252        int main ()
1253        {
1254          if (sizeof (prfpregset_t) == sizeof (void *))
1255            return 1;
1256          return 0;
1257        }],
1258        gdb_cv_prfpregset_t_broken=no,
1259        gdb_cv_prfpregset_t_broken=yes,
1260        gdb_cv_prfpregset_t_broken=yes)])
1261     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1262     if test $gdb_cv_prfpregset_t_broken = yes; then
1263       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1264       [Define if the prfpregset_t type is broken.])
1265     fi
1266   fi
1267
1268   dnl Check for PIOCSET ioctl entry
1269
1270   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1271   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1272   [AC_TRY_COMPILE([#include <unistd.h>
1273 #include <sys/types.h>
1274 #include <sys/procfs.h>
1275 ], [
1276     int dummy;;
1277     dummy = ioctl(0, PIOCSET, &dummy);
1278   ],
1279   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1280   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1281   if test $gdb_cv_have_procfs_piocset = yes; then
1282     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1283     [Define if ioctl argument PIOCSET is available.])
1284   fi
1285 fi
1286
1287 dnl For native ports (host == target), check to see what kind of
1288 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1289 if test ${host} = ${target} ; then
1290   dnl Check for struct link_map with l_ members which are indicative
1291   dnl of SVR4-like shared libraries
1292
1293   AC_MSG_CHECKING(for member l_addr in struct link_map)
1294   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1295     [AC_TRY_COMPILE([#include <link.h>],
1296                     [struct link_map lm; (void) lm.l_addr;],
1297                     gdb_cv_have_struct_link_map_with_l_members=yes,
1298                     gdb_cv_have_struct_link_map_with_l_members=no)])
1299   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1300   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1301     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1302     [Define if <link.h> exists and defines struct link_map which has
1303      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1304      SVR4-like systems.)])
1305   fi
1306
1307   dnl Check for struct link_map with lm_ members which are indicative
1308   dnl of SunOS-like shared libraries
1309
1310   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1311   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1312     [AC_TRY_COMPILE([#include <sys/types.h>
1313 #include <link.h>],
1314                     [struct link_map lm; (void) lm.lm_addr;],
1315                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1316                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1317   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1318   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1319     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1320     [Define if <link.h> exists and defines struct link_map which has
1321      members with an ``lm_'' prefix.  (For SunOS.)])
1322   fi
1323
1324   dnl Check for struct so_map with som_ members which are found on
1325   dnl some *BSD systems.
1326
1327   AC_MSG_CHECKING(for member som_addr in struct so_map)
1328   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1329     [AC_TRY_COMPILE([#include <sys/types.h>
1330 #ifdef HAVE_NLIST_H
1331 #include <nlist.h>
1332 #endif
1333 #include <link.h>],
1334                     [struct so_map lm; (void) lm.som_addr;],
1335                     gdb_cv_have_struct_so_map_with_som_members=yes,
1336                     gdb_cv_have_struct_so_map_with_som_members=no)])
1337   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1338   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1339     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1340     [Define if <link.h> exists and defines a struct so_map which has
1341      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1342   fi
1343
1344   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1345   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1346
1347   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1348   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1349     [AC_TRY_COMPILE([#define _SYSCALL32
1350 #include <sys/link.h>], [struct link_map32 l;],
1351      gdb_cv_have_struct_link_map32=yes,
1352      gdb_cv_have_struct_link_map32=no)])
1353   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1354   if test $gdb_cv_have_struct_link_map32 = yes; then
1355     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1356     [Define if <sys/link.h> has struct link_map32])
1357     AC_DEFINE(_SYSCALL32, 1,
1358     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1359   fi
1360 fi
1361
1362 # Check if the compiler supports the `long long' type.
1363
1364 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1365                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1366 [[extern long long foo;]],
1367 [[switch (foo & 2) { case 0: return 1; }]])],
1368                                   gdb_cv_c_long_long=yes,
1369                                   gdb_cv_c_long_long=no)])
1370 if test $gdb_cv_c_long_long = yes; then
1371   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1372             [Define to 1 if the compiler supports long long.])
1373 fi
1374
1375 # Check if the compiler and runtime support printing long longs.
1376
1377 AC_CACHE_CHECK([for long long support in printf],
1378                gdb_cv_printf_has_long_long,
1379                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1380 [[char buf[32];
1381   long long l = 0;
1382   l = (l << 16) + 0x0123;
1383   l = (l << 16) + 0x4567;
1384   l = (l << 16) + 0x89ab;
1385   l = (l << 16) + 0xcdef;
1386   sprintf (buf, "0x%016llx", l);
1387   return (strcmp ("0x0123456789abcdef", buf));]])],
1388                               gdb_cv_printf_has_long_long=yes,
1389                               gdb_cv_printf_has_long_long=no,
1390                               gdb_cv_printf_has_long_long=no)])
1391 if test $gdb_cv_printf_has_long_long = yes; then
1392   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1393             [Define to 1 if the "%ll" format works to print long longs.])
1394 fi
1395
1396 # Check if the compiler and runtime support printing decfloats.
1397
1398 AC_CACHE_CHECK([for decfloat support in printf],
1399                gdb_cv_printf_has_decfloat,
1400                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1401 [[char buf[64];
1402   _Decimal32 d32 = 1.2345df;
1403   _Decimal64 d64 = 1.2345dd;
1404   _Decimal128 d128 = 1.2345dl;
1405   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1406   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1407                               gdb_cv_printf_has_decfloat=yes,
1408                               gdb_cv_printf_has_decfloat=no,
1409                               gdb_cv_printf_has_decfloat=no)])
1410 if test $gdb_cv_printf_has_decfloat = yes; then
1411   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1412             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1413 fi
1414
1415 # Check if the compiler supports the `long double' type.  We can't use
1416 # AC_C_LONG_DOUBLE because that one does additional checks on the
1417 # constants defined in <float.h> that fail on some systems,
1418 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1419
1420 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1421                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1422                                   gdb_cv_c_long_double=yes,
1423                                   gdb_cv_c_long_double=no)])
1424 if test $gdb_cv_c_long_double = yes; then
1425   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1426            [Define to 1 if the compiler supports long double.])
1427 fi
1428
1429 # Check if the compiler and runtime support printing long doubles.
1430
1431 AC_CACHE_CHECK([for long double support in printf],
1432                gdb_cv_printf_has_long_double,
1433                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1434 [[char buf[16];
1435   long double f = 3.141592653;
1436   sprintf (buf, "%Lg", f);
1437   return (strncmp ("3.14159", buf, 7));]])],
1438                               gdb_cv_printf_has_long_double=yes,
1439                               gdb_cv_printf_has_long_double=no,
1440                               gdb_cv_printf_has_long_double=no)])
1441 if test $gdb_cv_printf_has_long_double = yes; then
1442   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1443             [Define to 1 if the "%Lg" format works to print long doubles.])
1444 fi
1445
1446 # Check if the compiler and runtime support scanning long doubles.
1447
1448 AC_CACHE_CHECK([for long double support in scanf],
1449                gdb_cv_scanf_has_long_double,
1450                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1451 [[#include <stdio.h>]],
1452 [[char *buf = "3.141592653";
1453   long double f = 0;
1454   sscanf (buf, "%Lg", &f);
1455   return !(f > 3.14159 && f < 3.14160);]])],
1456                               gdb_cv_scanf_has_long_double=yes,
1457                               gdb_cv_scanf_has_long_double=no,
1458                               gdb_cv_scanf_has_long_double=no)])
1459 if test $gdb_cv_scanf_has_long_double = yes; then
1460   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1461             [Define to 1 if the "%Lg" format works to scan long doubles.])
1462 fi
1463
1464 case ${host_os} in
1465 aix*)
1466   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1467     SAVE_LDFLAGS=$LDFLAGS
1468
1469     case $GCC in
1470     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1471     *) gdb_cv_bigtoc=-bbigtoc ;;
1472     esac
1473
1474     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1475     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1476     LDFLAGS="${SAVE_LDFLAGS}"
1477   ])
1478   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1479   ;;
1480 esac
1481
1482 AC_MSG_CHECKING(for the dynamic export flag)
1483 dynamic_list=false
1484 if test "${gdb_native}" = yes; then
1485    # The dynamically loaded libthread_db needs access to symbols in the gdb
1486    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1487    # may not be supported there.
1488    old_LDFLAGS="$LDFLAGS"
1489    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1490    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1491    LDFLAGS="$LDFLAGS $RDYNAMIC"
1492    if test "${have_libpython}" = no; then
1493      AC_TRY_LINK([], [], [dynamic_list=true])
1494    else
1495      # Workaround http://bugs.python.org/issue4434 where static
1496      # libpythonX.Y.a would get its symbols required for
1497      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1498      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1499      old_CFLAGS="$CFLAGS"
1500      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1501      AC_RUN_IFELSE(
1502        AC_LANG_PROGRAM(
1503          [#include "]${have_libpython}[/Python.h"],
1504          [int err;
1505           Py_Initialize ();
1506           err = PyRun_SimpleString ("import itertools\n");
1507           Py_Finalize ();
1508           return err == 0 ? 0 : 1;]),
1509        [dynamic_list=true], [], [true])
1510      CFLAGS="$old_CFLAGS"
1511    fi
1512    LDFLAGS="$old_LDFLAGS"
1513 fi
1514 if $dynamic_list; then
1515   found="-Wl,--dynamic-list"
1516   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1517 else
1518   found="-rdynamic"
1519   RDYNAMIC="-rdynamic"
1520 fi
1521 AC_SUBST(RDYNAMIC)
1522 AC_MSG_RESULT($found)
1523
1524 dnl For certain native configurations, we need to check whether thread
1525 dnl support can be built in or not.
1526 dnl
1527 dnl Note that we only want this if we are both native (host == target),
1528 dnl and not doing a canadian cross build (build == host).
1529
1530 if test ${build} = ${host} -a ${host} = ${target} ; then
1531    case ${host_os} in
1532    solaris*)
1533       # See if thread_db library is around for Solaris thread debugging.
1534       # Note that we must explicitly test for version 1 of the library
1535       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1536       # the same API.
1537       AC_MSG_CHECKING(for Solaris thread debugging library)
1538       if test -f /usr/lib/libthread_db.so.1 ; then
1539          AC_MSG_RESULT(yes)
1540          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1541          [Define if using Solaris thread debugging.])
1542          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1543          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1544          AC_CHECK_LIB(dl, dlopen)
1545          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1546          # Sun randomly tweaked the prototypes in <proc_service.h>
1547          # at one point.
1548          AC_MSG_CHECKING(if <proc_service.h> is old)
1549          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1550             AC_TRY_COMPILE([
1551                 #include <proc_service.h>
1552                 ps_err_e ps_pdwrite
1553                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1554             ],, gdb_cv_proc_service_is_old=no,
1555                 gdb_cv_proc_service_is_old=yes)
1556          ])
1557          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1558          if test $gdb_cv_proc_service_is_old = yes; then
1559             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1560             [Define if <proc_service.h> on solaris uses int instead of
1561              size_t, and assorted other type changes.])
1562          fi
1563       else
1564          AC_MSG_RESULT(no)
1565       fi
1566       ;;
1567    aix*)
1568       AC_MSG_CHECKING(for AiX thread debugging library)
1569       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1570                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1571                                    [#ifndef PTHDB_VERSION_3
1572                                     #error
1573                                     #endif],
1574                                    gdb_cv_have_aix_thread_debug=yes,
1575                                    gdb_cv_have_aix_thread_debug=no)])
1576       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1577       if test $gdb_cv_have_aix_thread_debug = yes; then
1578          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1579          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1580          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1581       fi
1582       ;;
1583    esac
1584    AC_SUBST(CONFIG_LDFLAGS)
1585 fi
1586
1587 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1588 dnl other error codes.
1589 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1590    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1591                   gdb_cv_thread_db_h_has_td_notalloc,
1592      AC_TRY_COMPILE(
1593        [#include <thread_db.h>],
1594        [int i = TD_NOTALLOC;],
1595        gdb_cv_thread_db_h_has_td_notalloc=yes,
1596        gdb_cv_thread_db_h_has_td_notalloc=no
1597      )
1598    )
1599    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1600                   gdb_cv_thread_db_h_has_td_version,
1601      AC_TRY_COMPILE(
1602        [#include <thread_db.h>],
1603        [int i = TD_VERSION;],
1604        gdb_cv_thread_db_h_has_td_version=yes,
1605        gdb_cv_thread_db_h_has_td_version=no
1606      )
1607    )
1608    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1609                   gdb_cv_thread_db_h_has_td_notls,
1610      AC_TRY_COMPILE(
1611        [#include <thread_db.h>],
1612        [int i = TD_NOTLS;],
1613        gdb_cv_thread_db_h_has_td_notls=yes,
1614        gdb_cv_thread_db_h_has_td_notls=no
1615      )
1616    )
1617 fi
1618 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1619   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1620             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1621 fi
1622 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1623   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1624             [Define if <thread_db.h> has the TD_VERSION error code.])
1625 fi
1626 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1627   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1628             [Define if <thread_db.h> has the TD_NOTLS error code.])
1629 fi
1630
1631 dnl See if we have a sys/syscall header file that has __NR_tkill.
1632 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1633    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1634                   gdb_cv_sys_syscall_h_has_tkill,
1635      AC_TRY_COMPILE(
1636        [#include <sys/syscall.h>],
1637        [int i = __NR_tkill;],
1638        gdb_cv_sys_syscall_h_has_tkill=yes,
1639        gdb_cv_sys_syscall_h_has_tkill=no
1640      )
1641    )
1642 fi
1643 dnl See if we can issue tkill syscall.
1644 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1645   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1646 fi
1647
1648 dnl Check if we can disable the virtual address space randomization.
1649 dnl The functionality of setarch -R.
1650 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1651 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1652 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1653 #       define ADDR_NO_RANDOMIZE 0x0040000
1654 #      endif
1655        /* Test the flag could be set and stays set.  */
1656        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1657        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1658            return 1])])
1659 AC_RUN_IFELSE([PERSONALITY_TEST],
1660               [have_personality=true],
1661               [have_personality=false],
1662               [AC_LINK_IFELSE([PERSONALITY_TEST],
1663                               [have_personality=true],
1664                               [have_personality=false])])
1665 if $have_personality
1666 then
1667     AC_DEFINE([HAVE_PERSONALITY], 1,
1668               [Define if you support the personality syscall.])
1669 fi
1670
1671 dnl Handle optional features that can be enabled.
1672
1673 target_sysroot_reloc=0
1674 AC_ARG_WITH(sysroot,
1675 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1676 [
1677  case ${with_sysroot} in
1678  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1679  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1680  esac
1681
1682  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1683
1684  if test "x$prefix" = xNONE; then
1685   test_prefix=/usr/local
1686  else
1687   test_prefix=$prefix
1688  fi
1689  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1690   test_exec_prefix=$test_prefix
1691  else
1692   test_exec_prefix=$exec_prefix
1693  fi
1694  case ${TARGET_SYSTEM_ROOT} in
1695  "${test_prefix}"|"${test_prefix}/"*|\
1696  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1697  '${prefix}'|'${prefix}/'*|\
1698  '${exec_prefix}'|'${exec_prefix}/'*)
1699    target_sysroot_reloc=1
1700    ;;
1701  esac
1702 ], [
1703  TARGET_SYSTEM_ROOT=
1704  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1705 ])
1706 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1707 AC_SUBST(TARGET_SYSTEM_ROOT)
1708 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1709
1710 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1711     [automatically load a system-wide gdbinit file],
1712     [])
1713
1714 AC_ARG_ENABLE(werror,
1715   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1716   [case "${enableval}" in
1717      yes | y) ERROR_ON_WARNING="yes" ;;
1718      no | n)  ERROR_ON_WARNING="no" ;;
1719      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1720    esac])
1721
1722 # Enable -Werror by default when using gcc
1723 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1724     ERROR_ON_WARNING=yes
1725 fi
1726
1727 WERROR_CFLAGS=""
1728 if test "${ERROR_ON_WARNING}" = yes ; then
1729     WERROR_CFLAGS="-Werror"
1730 fi
1731
1732 # The entries after -Wno-pointer-sign are disabled warnings which may
1733 # be enabled in the future, which can not currently be used to build
1734 # GDB.
1735 # NOTE: If you change this list, remember to update
1736 # gdb/doc/gdbint.texinfo.
1737 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1738 -Wformat-nonliteral -Wno-pointer-sign \
1739 -Wno-unused -Wunused-value -Wunused-function \
1740 -Wno-switch -Wno-char-subscripts"
1741
1742 # Enable -Wno-format by default when using gcc on mingw since many
1743 # GCC versions complain about %I64.
1744 case "${host}" in
1745   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1746 esac
1747
1748 AC_ARG_ENABLE(build-warnings,
1749 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1750 [case "${enableval}" in
1751   yes)  ;;
1752   no)   build_warnings="-w";;
1753   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1754         build_warnings="${build_warnings} ${t}";;
1755   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1756         build_warnings="${t} ${build_warnings}";;
1757   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1758 esac
1759 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1760   echo "Setting compiler warning flags = $build_warnings" 6>&1
1761 fi])dnl
1762 AC_ARG_ENABLE(gdb-build-warnings,
1763 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1764 [case "${enableval}" in
1765   yes)  ;;
1766   no)   build_warnings="-w";;
1767   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1768         build_warnings="${build_warnings} ${t}";;
1769   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1770         build_warnings="${t} ${build_warnings}";;
1771   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1772 esac
1773 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1774   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1775 fi])dnl
1776 WARN_CFLAGS=""
1777 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1778 then
1779     AC_MSG_CHECKING(compiler warning flags)
1780     # Separate out the -Werror flag as some files just cannot be
1781     # compiled with it enabled.
1782     for w in ${build_warnings}; do
1783         case $w in
1784         -Werr*) WERROR_CFLAGS=-Werror ;;
1785         *) # Check that GCC accepts it
1786             saved_CFLAGS="$CFLAGS"
1787             CFLAGS="$CFLAGS $w"
1788             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1789             CFLAGS="$saved_CFLAGS"
1790         esac
1791     done
1792     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1793 fi
1794 AC_SUBST(WARN_CFLAGS)
1795 AC_SUBST(WERROR_CFLAGS)
1796
1797 # In the Cygwin environment, we need some additional flags.
1798 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1799 [AC_EGREP_CPP(lose, [
1800 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1801 lose
1802 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1803
1804
1805 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1806 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1807 case ${host} in
1808   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1809   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1810   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1811 esac
1812 AC_SUBST(SER_HARDWIRE)
1813
1814 # libreadline needs libuser32.a in a cygwin environment
1815 WIN32LIBS=
1816 if test x$gdb_cv_os_cygwin = xyes; then
1817     WIN32LIBS="-luser32"
1818     case "${target}" in
1819         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1820         ;;
1821     esac
1822 fi
1823
1824 # The ser-tcp.c module requires sockets.
1825 case ${host} in
1826   *mingw32*)
1827     AC_DEFINE(USE_WIN32API, 1,
1828               [Define if we should use the Windows API, instead of the
1829                POSIX API.  On Windows, we use the Windows API when
1830                building for MinGW, but the POSIX API when building
1831                for Cygwin.])
1832     WIN32LIBS="$WIN32LIBS -lws2_32"
1833     ;;
1834 esac
1835 AC_SUBST(WIN32LIBS)
1836
1837 # Add ELF support to GDB, but only if BFD includes ELF support.
1838 OLD_CFLAGS=$CFLAGS
1839 OLD_LDFLAGS=$LDFLAGS
1840 OLD_LIBS=$LIBS
1841 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1842 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1843 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1844 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1845 if test "$plugins" = "yes"; then
1846   LIBS="-ldl $LIBS"
1847 fi
1848 LIBS="-lbfd -liberty $intl $LIBS"
1849 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1850 [AC_TRY_LINK(
1851 [#include <stdlib.h>
1852 #include "bfd.h"
1853 #include "elf-bfd.h"
1854 ],
1855 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1856 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1857 if test $gdb_cv_var_elf = yes; then
1858   CONFIG_OBS="$CONFIG_OBS elfread.o"
1859   AC_DEFINE(HAVE_ELF, 1,
1860             [Define if ELF support should be included.])
1861   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1862   if test "$plugins" = "yes"; then
1863     OLD_LIBS="-ldl $OLD_LIBS"
1864   fi
1865 fi
1866 CFLAGS=$OLD_CFLAGS
1867 LDFLAGS=$OLD_LDFLAGS
1868 LIBS=$OLD_LIBS
1869
1870 # Add any host-specific objects to GDB.
1871 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1872
1873 LIBGUI="../libgui/src/libgui.a"
1874 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1875 AC_SUBST(LIBGUI)
1876 AC_SUBST(GUI_CFLAGS_X)
1877
1878 WIN32LDAPP=
1879 AC_SUBST(WIN32LIBS)
1880 AC_SUBST(WIN32LDAPP)
1881
1882 case "${host}" in
1883 *-*-cygwin* | *-*-mingw* )
1884     configdir="win"
1885     ;;
1886 *)
1887     configdir="unix"
1888     ;;
1889 esac
1890
1891 GDBTKLIBS=
1892 if test "${enable_gdbtk}" = "yes"; then
1893
1894     # Gdbtk must have an absolute path to srcdir in order to run
1895     # properly when not installed.
1896     here=`pwd`
1897     cd ${srcdir}
1898     GDBTK_SRC_DIR=`pwd`
1899     cd $here
1900
1901     SC_PATH_TCLCONFIG
1902
1903     # If $no_tk is nonempty, then we can't do Tk, and there is no
1904     # point to doing Tcl.
1905     SC_PATH_TKCONFIG
1906
1907     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1908         SC_LOAD_TCLCONFIG
1909
1910         # Check for in-tree tcl
1911         here=`pwd`
1912         cd ${srcdir}/..
1913         topdir=`pwd`
1914         cd ${here}
1915
1916         intree="no"
1917         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1918           intree="yes"
1919         fi
1920
1921         # Find Tcl private headers
1922         if test x"${intree}" = xno; then
1923           CY_AC_TCL_PRIVATE_HEADERS
1924           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1925           TCL_LIBRARY="${TCL_LIB_SPEC}"
1926           TCL_DEPS=""
1927         else
1928           # If building tcl in the same src tree, private headers
1929           # are not needed, but we need to be sure to use the right
1930           # headers library
1931           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1932           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1933           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1934         fi
1935         AC_SUBST(TCL_INCLUDE)
1936         AC_SUBST(TCL_LIBRARY)
1937         AC_SUBST(TCL_DEPS)
1938
1939         SC_LOAD_TKCONFIG
1940
1941         # Check for in-tree Tk
1942         intree="no"
1943         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1944           intree="yes"
1945         fi
1946
1947         # Find Tk private headers
1948         if test x"${intree}" = xno; then
1949           CY_AC_TK_PRIVATE_HEADERS
1950           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1951           TK_LIBRARY=${TK_LIB_SPEC}
1952           TK_DEPS=""
1953         else
1954           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1955           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1956           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1957         fi
1958         AC_SUBST(TK_INCLUDE)
1959         AC_SUBST(TK_LIBRARY)
1960         AC_SUBST(TK_DEPS)
1961         AC_SUBST(TK_XINCLUDES)
1962
1963         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1964
1965         # Include some libraries that Tcl and Tk want.
1966         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1967         # Yes, the ordering seems wrong here.  But it isn't.
1968         # TK_LIBS is the list of libraries that need to be linked
1969         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1970         # were in LIBS then any link tests after this point would
1971         # try to include things like `$(LIBGUI)', which wouldn't work.
1972         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1973
1974         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1975         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1976         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1977         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1978         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1979         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1980         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1981
1982         if test x$gdb_cv_os_cygwin = xyes; then
1983           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1984           WIN32LDAPP="-Wl,--subsystem,console"
1985           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1986         fi
1987
1988         AC_CONFIG_SUBDIRS(gdbtk)
1989     fi
1990 fi
1991
1992 AC_SUBST(X_CFLAGS)
1993 AC_SUBST(X_LDFLAGS)
1994 AC_SUBST(X_LIBS)
1995 AC_SUBST(GDBTKLIBS)
1996 AC_SUBST(GDBTK_CFLAGS)
1997 AC_SUBST(GDBTK_SRC_DIR)
1998
1999 AC_PATH_X
2000
2001 # Unlike the sim directory, whether a simulator is linked is controlled by
2002 # presence of a gdb_sim definition in the target configure.tgt entry.
2003 # This code just checks for a few cases where we'd like to ignore those
2004 # definitions, even when they're present in the '.mt' file.  These cases
2005 # are when --disable-sim is specified, or if the simulator directory is
2006 # not part of the source tree.
2007 #
2008 AC_ARG_ENABLE(sim,
2009 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2010 [echo "enable_sim = $enable_sim";
2011  echo "enableval = ${enableval}";
2012  case "${enableval}" in
2013   yes) ignore_sim=false ;;
2014   no)  ignore_sim=true ;;
2015   *)   ignore_sim=false ;;
2016  esac],
2017 [ignore_sim=false])
2018
2019 if test ! -d "${srcdir}/../sim"; then
2020   ignore_sim=true
2021 fi
2022
2023 SIM=
2024 SIM_OBS=
2025 if test "${ignore_sim}" = "false"; then
2026   if test x"${gdb_sim}" != x ; then
2027     SIM="${gdb_sim}"
2028     SIM_OBS="remote-sim.o"
2029     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2030   fi
2031 fi
2032 AC_SUBST(SIM)
2033 AC_SUBST(SIM_OBS)
2034
2035 AC_SUBST(ENABLE_CFLAGS)
2036 AC_SUBST(PROFILE_CFLAGS)
2037
2038 AC_SUBST(CONFIG_OBS)
2039 AC_SUBST(CONFIG_DEPS)
2040 AC_SUBST(CONFIG_SRCS)
2041 AC_SUBST(CONFIG_ALL)
2042 AC_SUBST(CONFIG_CLEAN)
2043 AC_SUBST(CONFIG_INSTALL)
2044 AC_SUBST(CONFIG_UNINSTALL)
2045
2046 # List of host floatformats.
2047 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2048 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2049 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2050
2051 # target_subdir is used by the testsuite to find the target libraries.
2052 target_subdir=
2053 if test "${host}" != "${target}"; then
2054     target_subdir="${target_alias}/"
2055 fi
2056 AC_SUBST(target_subdir)
2057
2058 frags=
2059 if test "${gdb_native}" = "yes"; then
2060   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2061   if test ! -f ${host_makefile_frag}; then
2062     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2063   fi
2064   frags="$frags $host_makefile_frag"
2065 else
2066   host_makefile_frag=/dev/null
2067 fi
2068
2069 AC_SUBST_FILE(host_makefile_frag)
2070 AC_SUBST(frags)
2071
2072 changequote(,)dnl
2073 if test "${gdb_native}" = "yes"; then
2074 # We pick this up from the host configuration file (.mh) because we
2075 # do not have a native configuration Makefile fragment.
2076 nativefile=`sed -n '
2077 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2078 ' ${host_makefile_frag}`
2079 fi
2080 changequote([,])
2081
2082 if test x"${gdb_osabi}" != x ; then
2083     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2084                        [Define to the default OS ABI for this configuration.])
2085 fi
2086
2087 # Enable multi-ice-gdb-server.
2088 AC_ARG_ENABLE(multi-ice,
2089 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2090   [case $enableval in
2091     yes | no)
2092       ;;
2093     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2094   esac])
2095 if test "x$enable_multi_ice" = xyes; then
2096    AC_CONFIG_SUBDIRS(multi-ice)
2097 fi
2098
2099 AC_ARG_ENABLE(gdbserver,
2100 AS_HELP_STRING([--enable-gdbserver],
2101                [automatically build gdbserver (yes/no/auto, default is auto)]),
2102 [case "${enableval}" in
2103   yes| no|auto) ;;
2104   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2105 esac],[enable_gdbserver=auto])
2106
2107 # We only build gdbserver automatically in a native configuration, and
2108 # only if the user did not explicitly disable its build.
2109 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2110   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2111   if test "x$build_gdbserver" = xyes; then
2112     AC_MSG_RESULT(yes)
2113     AC_CONFIG_SUBDIRS(gdbserver)
2114     gdbserver_build_enabled=yes
2115   else
2116     AC_MSG_RESULT(no)
2117   fi
2118 fi
2119
2120 # If the user explicitly request the gdbserver to be built, verify that
2121 # we were in fact able to enable it.
2122 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2123   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2124 fi
2125
2126 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2127 # to an empty version.
2128
2129 files=
2130 links=
2131
2132 rm -f nm.h
2133 if test "${nativefile}" != ""; then
2134     case "${nativefile}" in
2135       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2136       * ) GDB_NM_FILE="${nativefile}"
2137     esac
2138     files="${files} ${GDB_NM_FILE}"
2139     links="${links} nm.h"
2140     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2141 fi
2142 AC_SUBST(GDB_NM_FILE)
2143
2144 AC_LINK_FILES($files, $links)
2145
2146 dnl Check for exe extension set on certain hosts (e.g. Win32)
2147 AC_EXEEXT
2148
2149 dnl  Detect the character set used by this host.
2150 dnl  At the moment, we just assume it's UTF-8.
2151 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2152           [Define to be a string naming the default host character set.])
2153
2154 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2155 [
2156 case x$CONFIG_HEADERS in
2157 xconfig.h:config.in)
2158 echo > stamp-h ;;
2159 esac
2160 ])
2161
2162 exit 0