gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009, 2010
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # GDB does not use automake, but gnulib does.  This line lets us
  91 # generate its Makefile.in.
  92 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  93
  94 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  95     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  96     [${libdir}/debug])
  97
  98 # GDB's datadir relocation
  99
 100 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 101     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 102     [${datadir}/gdb])
 103
 104 AC_ARG_WITH(relocated-sources,
 105 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 106 [reloc_srcdir="${withval}"
 107  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 108               [Relocated directory for source files. ])
 109 ])
 110
 111 AC_CONFIG_SUBDIRS(doc testsuite)
 112
 113 # Check whether to support alternative target configurations
 114 AC_ARG_ENABLE(targets,
 115 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 116 [case "${enableval}" in
 117   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 118             ;;
 119   no)       enable_targets= ;;
 120   *)        enable_targets=$enableval ;;
 121 esac])
 122
 123 # Check whether to enable 64-bit support on 32-bit hosts
 124 AC_ARG_ENABLE(64-bit-bfd,
 125 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 126 [case "${enableval}" in
 127   yes)  want64=true  ;;
 128   no)   want64=false ;;
 129   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 130 esac],[want64=false])dnl
 131
 132 # Provide defaults for some variables set by the per-host and per-target
 133 # configuration.
 134 gdb_host_obs=posix-hdep.o
 135
 136 if test "${target}" = "${host}"; then
 137   gdb_native=yes
 138 else
 139   gdb_native=no
 140 fi
 141
 142 . $srcdir/configure.host
 143
 144 # Accumulate some settings from configure.tgt over all enabled targets
 145
 146 TARGET_OBS=
 147 all_targets=
 148
 149 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 150 do
 151   if test "$targ_alias" = "all"; then
 152     all_targets=true
 153   else
 154     # Canonicalize the secondary target names.
 155     result=`$ac_config_sub $targ_alias 2>/dev/null`
 156     if test -n "$result"; then
 157         targ=$result
 158     else
 159         targ=$targ_alias
 160     fi
 161
 162     . ${srcdir}/configure.tgt
 163
 164     AS_IF([test -z "${gdb_target_obs}"],
 165       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 166
 167     # Target-specific object files
 168     for i in ${gdb_target_obs}; do
 169         case " $TARGET_OBS " in
 170         *" ${i} "*) ;;
 171         *)
 172           TARGET_OBS="$TARGET_OBS ${i}"
 173           ;;
 174         esac
 175     done
 176
 177     # Check whether this target needs 64-bit CORE_ADDR
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181   fi
 182 done
 183
 184 if test x${all_targets} = xtrue; then
 185
 186   # We want all 64-bit targets if we either:
 187   #  - run on a 64-bit host  or
 188   #  - already require 64-bit support for some other target  or
 189   #  - the --enable-64-bit-bfd option was supplied
 190   # Otherwise we only support all 32-bit targets.
 191   #
 192   # NOTE: This test must be in sync with the corresponding
 193   #       tests in BFD!
 194
 195   if test x${want64} = xfalse; then
 196     AC_CHECK_SIZEOF(long)
 197     if test "x${ac_cv_sizeof_long}" = "x8"; then
 198       want64=true
 199     fi
 200   fi
 201   if test x${want64} = xtrue; then
 202     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 203   else
 204     TARGET_OBS='$(ALL_TARGET_OBS)'
 205   fi
 206 fi
 207
 208 AC_SUBST(TARGET_OBS)
 209
 210 # For other settings, only the main target counts.
 211 gdb_sim=
 212 gdb_osabi=
 213 build_gdbserver=
 214 targ=$target; . ${srcdir}/configure.tgt
 215
 216 # Fetch the default architecture and default target vector from BFD.
 217 targ=$target; . $srcdir/../bfd/config.bfd
 218
 219 # We only want the first architecture, so strip off the others if
 220 # there is more than one.
 221 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 222
 223 if test "x$targ_archs" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 225     [Define to BFD's default architecture. ])
 226 fi
 227 if test "x$targ_defvec" != x; then
 228   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 229     [Define to BFD's default target vector. ])
 230 fi
 231
 232 # The CLI cannot be disabled yet, but may be in the future.
 233
 234 # Enable CLI.
 235 AC_ARG_ENABLE(gdbcli,
 236 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 237   [case $enableval in
 238     yes)
 239       ;;
 240     no)
 241       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 242     *)
 243       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 244   esac],
 245   [enable_gdbcli=yes])
 246 if test x"$enable_gdbcli" = xyes; then
 247   if test -d $srcdir/cli; then
 248     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 249     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 250     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 251     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 252   fi
 253 fi
 254
 255 # Enable MI.
 256 AC_ARG_ENABLE(gdbmi,
 257 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 258   [case $enableval in
 259     yes | no)
 260       ;;
 261     *)
 262       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 263   esac],
 264   [enable_gdbmi=yes])
 265 if test x"$enable_gdbmi" = xyes; then
 266   if test -d $srcdir/mi; then
 267     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 268     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 269     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 270     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 271   fi
 272 fi
 273
 274 # Enable TUI.
 275 AC_ARG_ENABLE(tui,
 276 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 277   [case $enableval in
 278     yes | no | auto)
 279       ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 282   esac],enable_tui=auto)
 283
 284 # Enable gdbtk.
 285 AC_ARG_ENABLE(gdbtk,
 286 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 292   esac],
 293   [if test -d $srcdir/gdbtk; then
 294     enable_gdbtk=yes
 295   else
 296     enable_gdbtk=no
 297   fi])
 298 # We unconditionally disable gdbtk tests on selected platforms.
 299 case $host_os in
 300   go32* | windows*)
 301     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 302     enable_gdbtk=no ;;
 303 esac
 304
 305 # Libunwind support.
 306 AC_ARG_WITH(libunwind,
 307 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 308 [case "${withval}" in
 309   yes)  enable_libunwind=yes ;;
 310   no)   enable_libunwind=no ;;
 311   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 312 esac],[
 313   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 314   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 315     enable_libunwind=yes;
 316   fi
 317 ])
 318
 319 if test x"$enable_libunwind" = xyes; then
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 322   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 323   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 324   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 325 fi
 326
 327 opt_curses=no
 328 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 329
 330 prefer_curses=no
 331 if test "$opt_curses" = "yes"; then
 332   prefer_curses=yes
 333 fi
 334
 335 # Profiling support.
 336 AC_ARG_ENABLE(profiling,
 337 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 338   [case $enableval in
 339     yes | no)
 340       ;;
 341     *)
 342       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 343   esac],
 344  [enable_profiling=no])
 345
 346 AC_CHECK_FUNCS(monstartup _mcleanup)
 347 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 348 [AC_TRY_LINK(
 349 [#include <stdlib.h>
 350 extern char _etext;
 351 ],
 352 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 353 if test $ac_cv_var__etext = yes; then
 354   AC_DEFINE(HAVE__ETEXT, 1,
 355             [Define to 1 if your system has the _etext variable. ])
 356 fi
 357 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 358 [AC_TRY_LINK(
 359 [#include <stdlib.h>
 360 extern char etext;
 361 ],
 362 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 363 if test $ac_cv_var_etext = yes; then
 364   AC_DEFINE(HAVE_ETEXT, 1,
 365             [Define to 1 if your system has the etext variable. ])
 366 fi
 367 if test "$enable_profiling" = yes ; then
 368   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 369     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 370   fi
 371   PROFILE_CFLAGS=-pg
 372   OLD_CFLAGS="$CFLAGS"
 373   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 374
 375   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 376     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 377      ac_cv_cc_supports_pg=no)])
 378
 379   if test $ac_cv_cc_supports_pg = no; then
 380     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 381   fi
 382
 383   CFLAGS="$OLD_CFLAGS"
 384 fi
 385
 386 ACX_PKGVERSION([GDB])
 387 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 388 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 389 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 390
 391 # --------------------- #
 392 # Checks for programs.  #
 393 # --------------------- #
 394
 395 AC_PROG_AWK
 396 AC_PROG_INSTALL
 397 AC_PROG_LN_S
 398 AC_PROG_RANLIB
 399 AC_PROG_YACC
 400
 401 AC_CHECK_TOOL(AR, ar)
 402 AC_CHECK_TOOL(DLLTOOL, dlltool)
 403 AC_CHECK_TOOL(WINDRES, windres)
 404
 405 # Needed for GNU/Hurd.
 406 AC_CHECK_TOOL(MIG, mig)
 407
 408 # ---------------------- #
 409 # Checks for libraries.  #
 410 # ---------------------- #
 411
 412 # We might need to link with -lm; most simulators need it.
 413 AC_CHECK_LIB(m, main)
 414
 415 # We need to link with -lw to get `wctype' on Solaris before Solaris
 416 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 417 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 418 # is known to have this problem).  Therefore we avoid libw if we can.
 419 AC_CHECK_FUNC(wctype, [],
 420   [AC_CHECK_LIB(w, wctype)])
 421
 422 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 423 AC_SEARCH_LIBS(gethostbyname, nsl)
 424
 425 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 426 AC_SEARCH_LIBS(socketpair, socket)
 427
 428 # Link in zlib if we can.  This allows us to read compressed debug sections.
 429 AM_ZLIB
 430
 431 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 432 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 433
 434 AM_ICONV
 435
 436 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 437 # There is a very specific comment in /usr/include/curses.h explaining that
 438 # termcap routines built into libcurses must not be used.
 439 #
 440 # The symptoms we observed so far is GDB unexpectedly changing
 441 # the terminal settings when tgetent is called - this is particularly
 442 # visible as the output is missing carriage returns, and so rapidly
 443 # becomes very hard to read.
 444 #
 445 # The readline configure script has already decided that libtermcap
 446 # was enough for its purposes, and so decided to build readline using
 447 # libtermcap.  Since the TUI mode requires curses, building GDB with
 448 # TUI enabled results in both libraries to be used at the same time,
 449 # which is not allowed.  This basically means that GDB with TUI is
 450 # broken on alpha-osf.
 451
 452 case $host_os in
 453   osf* )
 454     if test x"$enable_tui" = xyes; then
 455       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 456     fi
 457     if test x"$enable_tui" = xauto; then
 458       enable_tui=no
 459     fi
 460     ;;
 461 esac
 462
 463 # For the TUI, we need enhanced curses functionality.
 464 if test x"$enable_tui" != xno; then
 465   prefer_curses=yes
 466 fi
 467
 468 curses_found=no
 469 if test x"$prefer_curses" = xyes; then
 470   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 471   # curses library because the latter might not provide all the
 472   # functionality we need.  However, this leads to problems on systems
 473   # where the linker searches /usr/local/lib, but the compiler doesn't
 474   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 475   # default installation of ncurses on alpha*-dec-osf* will lead to such
 476   # a situation.
 477   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 478
 479   if test "$ac_cv_search_waddstr" != no; then
 480     curses_found=yes
 481   fi
 482 fi
 483
 484 # Check whether we should enable the TUI, but only do so if we really
 485 # can.
 486 if test x"$enable_tui" != xno; then
 487   if test -d $srcdir/tui; then
 488     if test "$curses_found" != no; then
 489       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 490       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 491       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 492       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 493       CONFIG_ALL="${CONFIG_ALL} all-tui"
 494       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 495       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 496       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 497     else
 498       if test x"$enable_tui" = xyes; then
 499         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 500       else
 501         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 502       fi
 503     fi
 504   fi
 505 fi
 506
 507 # Since GDB uses Readline, we need termcap functionality.  In many
 508 # cases this will be provided by the curses library, but some systems
 509 # have a seperate termcap library, or no curses library at all.
 510
 511 case $host_os in
 512   cygwin*)
 513     if test -d $srcdir/libtermcap; then
 514       LIBS="../libtermcap/libtermcap.a $LIBS"
 515       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 516     fi ;;
 517   go32* | *djgpp*)
 518     ac_cv_search_tgetent="none required"
 519     ;;
 520   *mingw32*)
 521     ac_cv_search_tgetent="none required"
 522     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 523     ;;
 524 esac
 525
 526 # These are the libraries checked by Readline.
 527 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 528
 529 if test "$ac_cv_search_tgetent" = no; then
 530   AC_MSG_ERROR([no termcap library found])
 531 fi
 532
 533 AC_ARG_WITH([system-readline],
 534   [AS_HELP_STRING([--with-system-readline],
 535                   [use installed readline library])])
 536
 537 if test "$with_system_readline" = yes; then
 538   READLINE=-lreadline
 539   READLINE_DEPS=
 540   READLINE_CFLAGS=
 541
 542   # readline-6.0 started to use the name `_rl_echoing_p'.
 543   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 544
 545   AC_MSG_CHECKING([for readline_echoing_p])
 546   save_LIBS=$LIBS
 547   LIBS="$LIBS $READLINE"
 548   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 549                                     return readline_echoing_p;]]),
 550                  [READLINE_ECHOING_P=yes],
 551                  [READLINE_ECHOING_P=no
 552                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 553                             [readline-6.0 started to use different name.])])
 554   LIBS="$save_LIBS"
 555   AC_MSG_RESULT([$READLINE_ECHOING_P])
 556 else
 557   READLINE='$(READLINE_DIR)/libreadline.a'
 558   READLINE_DEPS='$(READLINE)'
 559   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 560 fi
 561 AC_SUBST(READLINE)
 562 AC_SUBST(READLINE_DEPS)
 563 AC_SUBST(READLINE_CFLAGS)
 564
 565 AC_ARG_WITH(expat,
 566   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 567   [], [with_expat=auto])
 568 AC_MSG_CHECKING([whether to use expat])
 569 AC_MSG_RESULT([$with_expat])
 570
 571 if test "${with_expat}" = no; then
 572   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 573   HAVE_LIBEXPAT=no
 574 else
 575   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 576                         [XML_Parser p = XML_ParserCreate (0);])
 577   if test "$HAVE_LIBEXPAT" != yes; then
 578     if test "$with_expat" = yes; then
 579       AC_MSG_ERROR([expat is missing or unusable])
 580     else
 581       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 582     fi
 583   else
 584     save_LIBS=$LIBS
 585     LIBS="$LIBS $LIBEXPAT"
 586     AC_CHECK_FUNCS(XML_StopParser)
 587     LIBS=$save_LIBS
 588   fi
 589 fi
 590
 591 dnl Utility to simplify finding libpython.
 592 dnl $1 = pythonX.Y
 593 dnl $2 = the shell variable to assign the result to
 594 dnl      If libpython is found we store $version here.
 595 dnl $3 = additional flags to add to CPPFLAGS
 596 dnl $4 = additional flags to add to LIBS
 597
 598 AC_DEFUN([AC_TRY_LIBPYTHON],
 599 [
 600   version=$1
 601   define([have_libpython_var],$2)
 602   new_CPPFLAGS=$3
 603   new_LIBS=$4
 604   AC_MSG_CHECKING([for ${version}])
 605   save_CPPFLAGS=$CPPFLAGS
 606   save_LIBS=$LIBS
 607   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 608   LIBS="$LIBS $new_LIBS"
 609   found_usable_python=no
 610   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 611                                  [[Py_Initialize ();]]),
 612                  [have_libpython_var=${version}
 613                   found_usable_python=yes],
 614                  [CPPFLAGS=$save_CPPFLAGS
 615                   LIBS=$save_LIBS])
 616   AC_MSG_RESULT([${found_usable_python}])
 617 ])
 618
 619 AC_ARG_WITH(python,
 620   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 621   [], [with_python=auto])
 622 AC_MSG_CHECKING([whether to use python])
 623 AC_MSG_RESULT([$with_python])
 624
 625 if test "${with_python}" = no; then
 626   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 627   have_libpython=no
 628 else
 629   have_python_config=no
 630   case "${with_python}" in
 631   /*)
 632     if test -d ${with_python}; then
 633       # Assume the python binary is ${with_python}/bin/python.
 634       python_prefix=${with_python}
 635       python_prog="${with_python}/bin/python"
 636       if test ! -x ${python_prog}; then
 637         # Fall back to gdb 7.0/7.1 behaviour.
 638         python_prog=missing
 639       fi
 640     elif test -x ${with_python}; then
 641       # While we can't run python compiled for $host (unless host == build),
 642       # the user could write a script that provides the needed information,
 643       # so we support that.
 644       python_prefix=
 645       python_prog=${with_python}
 646     else
 647       AC_ERROR(invalid value for --with-python)
 648     fi
 649     ;;
 650   */*)
 651     # Disallow --with-python=foo/bar.
 652     AC_ERROR(invalid value for --with-python)
 653     ;;
 654   *)
 655     # The user has either specified auto, yes, or the name of the python
 656     # program assumed to be in $PATH.
 657     python_prefix=
 658     case "${with_python}" in
 659     yes | auto)
 660       if test ${build} = ${host}; then
 661         AC_PATH_PROG(python_prog_path, python, missing)
 662         if test "${python_prog_path}" = missing; then
 663           python_prog=missing
 664         else
 665           python_prog=${python_prog_path}
 666         fi
 667       else
 668         # Not much we can do except assume the cross-compiler will find the
 669         # right files.
 670         python_prog=missing
 671       fi
 672       ;;
 673     *)
 674       # While we can't run python compiled for $host (unless host == build),
 675       # the user could write a script that provides the needed information,
 676       # so we support that.
 677       python_prog="${with_python}"
 678       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 679       if test "${python_prog_path}" = missing; then
 680         AC_ERROR(unable to find python program ${python_prog})
 681       fi
 682       ;;
 683     esac
 684   esac
 685
 686   if test "${python_prog}" != missing; then
 687     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 688     if test $? != 0; then
 689       AC_ERROR(failure running python-config --includes)
 690     fi
 691     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 692     if test $? != 0; then
 693       AC_ERROR(failure running python-config --ldflags)
 694     fi
 695     have_python_config=yes
 696   else
 697     # Fall back to gdb 7.0/7.1 behaviour.
 698     if test -z ${python_prefix}; then
 699       python_includes=
 700       python_libs=
 701     else
 702       python_includes="-I${python_prefix}/include"
 703       python_libs="-L${python_prefix}/lib"
 704     fi
 705   fi
 706
 707   # Having "/pythonX.Y" in the include path is awkward.
 708   # All those python headers get bubbled up to the top inviting lots
 709   # of random collisions.  GDB originally didn't use python-config to
 710   # find the compilation parameters and includes "pythonX.Y/" in the
 711   # path of the, umm, include file.  So strip away this part of the
 712   # output of python-config --includes.
 713   python_includes=`echo "${python_includes} " \
 714                         | sed -e 's,/python[[0-9]]*[[.]][[0-9]]* , ,g'`
 715
 716   # If we have python-config, only try the configuration it provides.
 717   # Otherwise fallback on the old way of trying different versions of
 718   # python in turn.
 719
 720   have_libpython=no
 721   if test "${have_python_config}" = yes; then
 722     python_version=`echo " ${python_libs} " \
 723                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]][[0-9]]*\) .*$,\1,'`
 724     if test "${python_version}" != ""; then
 725       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 726                        ${python_includes}, ${python_libs})
 727     else
 728       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 729     fi
 730   else
 731     if test "${have_libpython}" = no; then
 732       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 733                        ${python_includes}, "${python_libs} -lpython2.6")
 734     fi
 735     if test ${have_libpython} = no; then
 736       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 737                        ${python_includes}, "${python_libs} -lpython2.5")
 738     fi
 739     if test ${have_libpython} = no; then
 740       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 741                        ${python_includes}, "${python_libs} -lpython2.4")
 742     fi
 743   fi
 744   if test "${have_libpython}" = python2.6; then
 745     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 746   elif test "${have_libpython}" = python2.5; then
 747     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 748   elif test "${have_libpython}" = python2.4; then
 749     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 750   fi
 751
 752   if test "${have_libpython}" = no; then
 753     case "${with_python}" in
 754     yes)
 755       AC_MSG_ERROR([python is missing or unusable])
 756       ;;
 757     auto)
 758       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 759       ;;
 760     *)
 761       AC_MSG_ERROR([no usable python found at ${with_python}])
 762       ;;
 763     esac
 764   fi
 765 fi
 766
 767 if test "${have_libpython}" != no; then
 768   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 769   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 770   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 771   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 772   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 773
 774   # Flags needed to compile Python code (taken from python-config --cflags).
 775   # We cannot call python-config directly because it will output whatever was
 776   # used when compiling the Python interpreter itself, including flags which
 777   # would make the python-related objects be compiled differently from the
 778   # rest of GDB (e.g., -O2 and -fPIC).
 779   if test "${GCC}" = yes; then
 780     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 781   fi
 782
 783   if test "x${tentative_python_cflags}" != x; then
 784     AC_MSG_CHECKING(compiler flags for python code)
 785     for flag in ${tentative_python_cflags}; do
 786       # Check that the compiler accepts it
 787       saved_CFLAGS="$CFLAGS"
 788       CFLAGS="$CFLAGS $flag"
 789       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 790       CFLAGS="$saved_CFLAGS"
 791     done
 792     AC_MSG_RESULT(${PYTHON_CFLAGS})
 793   fi
 794 else
 795   # Even if Python support is not compiled in, we need to have these files
 796   # included.
 797   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 798   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 799         python/py-prettyprint.c python/py-auto-load.c"
 800 fi
 801 AC_SUBST(PYTHON_CFLAGS)
 802
 803 # ------------------------- #
 804 # Checks for header files.  #
 805 # ------------------------- #
 806
 807 AC_HEADER_DIRENT
 808 AC_HEADER_STAT
 809 AC_HEADER_STDC
 810 # elf_hp.h is for HP/UX 64-bit shared library support.
 811 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 812 # unconditionally, so what's the point in checking these?
 813 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 814                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 815                   stdlib.h string.h memory.h strings.h sys/fault.h \
 816                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 817                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 818                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 819                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 820                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 821 AC_CHECK_HEADERS(link.h, [], [],
 822 [#if HAVE_SYS_TYPES_H
 823 # include <sys/types.h>
 824 #endif
 825 #if HAVE_NLIST_H
 826 # include <nlist.h>
 827 #endif
 828 ])
 829 AC_CHECK_HEADERS(sys/proc.h, [], [],
 830 [#if HAVE_SYS_PARAM_H
 831 # include <sys/param.h>
 832 #endif
 833 ])
 834 AC_CHECK_HEADERS(sys/user.h, [], [],
 835 [#if HAVE_SYS_PARAM_H
 836 # include <sys/param.h>
 837 #endif
 838 ])
 839
 840 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 841 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 842 # think that we don't have <curses.h> if we're using GCC.
 843 case $host_os in
 844   solaris2.[[789]])
 845     if test "$GCC" = yes; then
 846       AC_DEFINE(_MSE_INT_H, 1,
 847         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 848    Solaris 2.[789] when using GCC. ])
 849     fi ;;
 850 esac
 851 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 852 AC_CHECK_HEADERS(term.h, [], [],
 853 [#if HAVE_CURSES_H
 854 # include <curses.h>
 855 #endif
 856 ])
 857
 858 # ------------------------- #
 859 # Checks for declarations.  #
 860 # ------------------------- #
 861
 862 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 863                 snprintf, vsnprintf])
 864 AM_LC_MESSAGES
 865
 866 # ----------------------- #
 867 # Checks for structures.  #
 868 # ----------------------- #
 869
 870 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 871
 872 # ------------------ #
 873 # Checks for types.  #
 874 # ------------------ #
 875
 876 AC_TYPE_SIGNAL
 877 AC_CHECK_TYPES(socklen_t, [], [],
 878 [#include <sys/types.h>
 879 #include <sys/socket.h>
 880 ])
 881
 882 # ------------------------------------- #
 883 # Checks for compiler characteristics.  #
 884 # ------------------------------------- #
 885
 886 AC_C_CONST
 887 AC_C_INLINE
 888 AC_C_BIGENDIAN
 889
 890 # ------------------------------ #
 891 # Checks for library functions.  #
 892 # ------------------------------ #
 893
 894 AC_FUNC_ALLOCA
 895 AC_FUNC_MMAP
 896 AC_FUNC_VFORK
 897 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 898                 getgid pipe poll pread64 sbrk setpgid setpgrp setsid \
 899                 sigaction sigprocmask sigsetmask socketpair syscall \
 900                 ttrace wborder setlocale iconvlist libiconvlist btowc \
 901                 setrlimit getrlimit posix_madvise])
 902 AM_LANGINFO_CODESET
 903
 904 # Check the return and argument types of ptrace.  No canned test for
 905 # this, so roll our own.
 906 gdb_ptrace_headers='
 907 #if HAVE_SYS_TYPES_H
 908 # include <sys/types.h>
 909 #endif
 910 #if HAVE_SYS_PTRACE_H
 911 # include <sys/ptrace.h>
 912 #endif
 913 #if HAVE_UNISTD_H
 914 # include <unistd.h>
 915 #endif
 916 '
 917 # There is no point in checking if we don't have a prototype.
 918 AC_CHECK_DECLS(ptrace, [], [
 919   : ${gdb_cv_func_ptrace_ret='int'}
 920   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 921 ], $gdb_ptrace_headers)
 922 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 923 # empty argument list, so check for that explicitly.
 924 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 925   AC_TRY_COMPILE($gdb_ptrace_headers,
 926     [extern long ptrace (enum __ptrace_request, ...);],
 927     gdb_cv_func_ptrace_ret='long',
 928     AC_TRY_COMPILE($gdb_ptrace_headers,
 929       [extern int ptrace ();],
 930       gdb_cv_func_ptrace_ret='int',
 931       gdb_cv_func_ptrace_ret='long')))
 932 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 933   [Define as the return type of ptrace.])
 934 # Check argument types.
 935 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 936   AC_TRY_COMPILE($gdb_ptrace_headers,
 937     [extern long ptrace (enum __ptrace_request, ...);],
 938     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 939 for gdb_arg1 in 'int' 'long'; do
 940  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 941   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 942    for gdb_arg4 in 'int' 'long'; do
 943      AC_TRY_COMPILE($gdb_ptrace_headers, [
 944 extern $gdb_cv_func_ptrace_ret
 945   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 946 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 947     break 4;])
 948     for gdb_arg5 in 'int *' 'int' 'long'; do
 949      AC_TRY_COMPILE($gdb_ptrace_headers, [
 950 extern $gdb_cv_func_ptrace_ret
 951   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 952 ], [
 953 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 954     break 5;])
 955     done
 956    done
 957   done
 958  done
 959 done
 960 # Provide a safe default value.
 961 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 962 ])])
 963 ac_save_IFS=$IFS; IFS=','
 964 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 965 IFS=$ac_save_IFS
 966 shift
 967 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 968   [Define to the type of arg 3 for ptrace.])
 969 if test -n "$[5]"; then
 970   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 971     [Define to the type of arg 5 for ptrace.])
 972 fi
 973
 974 dnl AC_FUNC_SETPGRP does not work when cross compiling
 975 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 976 if test "$cross_compiling" = no; then
 977   AC_FUNC_SETPGRP
 978 else
 979   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 980     [AC_TRY_COMPILE([
 981 #include <unistd.h>
 982 ], [
 983   if (setpgrp(1,1) == -1)
 984     exit (0);
 985   else
 986     exit (1);
 987 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 988 if test $ac_cv_func_setpgrp_void = yes; then
 989   AC_DEFINE(SETPGRP_VOID, 1)
 990 fi
 991 fi
 992
 993 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 994 # since sigsetjmp might only be defined as a macro.
 995 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 996 [AC_TRY_COMPILE([
 997 #include <setjmp.h>
 998 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 999 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1000 if test $gdb_cv_func_sigsetjmp = yes; then
1001   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1002 fi
1003
1004 # Assume we'll default to using the included libiberty regex.
1005 gdb_use_included_regex=yes
1006
1007 # However, if the system regex is GNU regex, then default to *not*
1008 # using the included regex.
1009 AC_CACHE_CHECK(
1010   [for GNU regex],
1011   [gdb_cv_have_gnu_regex],
1012   [AC_TRY_COMPILE(
1013     [#include <gnu-versions.h>],
1014     [#define REGEX_INTERFACE_VERSION 1
1015 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1016 # error "Version mismatch"
1017 #endif],
1018     gdb_cv_have_gnu_regex=yes,
1019     gdb_cv_have_gnu_regex=no)])
1020 if test $gdb_cv_have_gnu_regex = yes; then
1021   gdb_use_included_regex=no
1022 fi
1023
1024 AC_ARG_WITH(included-regex,
1025   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1026   gdb_with_regex=$withval,
1027   gdb_with_regex=$gdb_use_included_regex)
1028 if test "$gdb_with_regex" = yes; then
1029   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1030     [Define to 1 if the regex included in libiberty should be used.])
1031 fi
1032
1033 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1034 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1035 [#include <sys/param.h>
1036 #include <sys/proc.h>
1037 ])
1038
1039 # See if <sys/lwp.h> defines `struct lwp`.
1040 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1041 [AC_TRY_COMPILE([#include <sys/param.h>
1042 #include <sys/lwp.h>], [struct lwp l;],
1043 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1044 if test $gdb_cv_struct_lwp = yes; then
1045   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1046             [Define to 1 if your system has struct lwp.])
1047 fi
1048
1049 # See if <machine/reg.h> degines `struct reg'.
1050 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1051 [AC_TRY_COMPILE([#include <sys/types.h>
1052 #include <machine/reg.h>], [struct reg r;],
1053 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1054 if test $gdb_cv_struct_reg = yes; then
1055   AC_DEFINE(HAVE_STRUCT_REG, 1,
1056             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1057 fi
1058
1059 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1060 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1061 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1062                  [#include <machine/reg.h>])
1063
1064 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1065 AC_MSG_CHECKING(for PTRACE_GETREGS)
1066 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1067 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1068                 [PTRACE_GETREGS;],
1069                 [gdb_cv_have_ptrace_getregs=yes],
1070                 [gdb_cv_have_ptrace_getregs=no])])
1071 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1072 if test $gdb_cv_have_ptrace_getregs = yes; then
1073   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1074   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1075 fi
1076
1077 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1078 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1079 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1080 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1081                 [PTRACE_GETFPXREGS;],
1082                 [gdb_cv_have_ptrace_getfpxregs=yes],
1083                 [gdb_cv_have_ptrace_getfpxregs=no])])
1084 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1085 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1086   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1087   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1088 fi
1089
1090 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1091 AC_MSG_CHECKING(for PT_GETDBREGS)
1092 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1093 [AC_TRY_COMPILE([#include <sys/types.h>
1094 #include <sys/ptrace.h>],
1095                 [PT_GETDBREGS;],
1096                 [gdb_cv_have_pt_getdbregs=yes],
1097                 [gdb_cv_have_pt_getdbregs=no])])
1098 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1099 if test $gdb_cv_have_pt_getdbregs = yes; then
1100   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1101   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1102 fi
1103
1104 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1105 AC_MSG_CHECKING(for PT_GETXMMREGS)
1106 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1107 [AC_TRY_COMPILE([#include <sys/types.h>
1108 #include <sys/ptrace.h>],
1109                 [PT_GETXMMREGS;],
1110                 [gdb_cv_have_pt_getxmmregs=yes],
1111                 [gdb_cv_have_pt_getxmmregs=no])])
1112 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1113 if test $gdb_cv_have_pt_getxmmregs = yes; then
1114   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1115   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1116 fi
1117
1118 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1119
1120 if test "${target}" = "${host}"; then
1121   case "${host}" in
1122   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1123       AC_DEFINE(NEW_PROC_API, 1,
1124       [Define if you want to use new multi-fd /proc interface
1125        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1126       ;;
1127   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1128       AC_DEFINE(NEW_PROC_API, 1,
1129       [Define if you want to use new multi-fd /proc interface
1130        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1131       ;;
1132   mips-sgi-irix5*)
1133       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1134       AC_DEFINE([_KMEMUSER], 1,
1135       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1136        around a <sys/proc.h> problem on IRIX 5.])
1137       ;;
1138   esac
1139 fi
1140
1141 if test "$ac_cv_header_sys_procfs_h" = yes; then
1142   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1143   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1144   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1145   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1146   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1147   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1148   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1149   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1150   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1151   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1152   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1153   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1154   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1155   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1156
1157
1158   dnl Check for broken prfpregset_t type
1159
1160   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1161   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1162   dnl instead of the struct itself).  We detect this here, and work
1163   dnl around it in gdb_proc_service.h.
1164
1165   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1166     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1167     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1168       [AC_TRY_RUN([#include <sys/procfs.h>
1169        int main ()
1170        {
1171          if (sizeof (prfpregset_t) == sizeof (void *))
1172            return 1;
1173          return 0;
1174        }],
1175        gdb_cv_prfpregset_t_broken=no,
1176        gdb_cv_prfpregset_t_broken=yes,
1177        gdb_cv_prfpregset_t_broken=yes)])
1178     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1179     if test $gdb_cv_prfpregset_t_broken = yes; then
1180       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1181       [Define if the prfpregset_t type is broken.])
1182     fi
1183   fi
1184
1185   dnl Check for PIOCSET ioctl entry
1186
1187   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1188   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1189   [AC_TRY_COMPILE([#include <unistd.h>
1190 #include <sys/types.h>
1191 #include <sys/procfs.h>
1192 ], [
1193     int dummy;;
1194     dummy = ioctl(0, PIOCSET, &dummy);
1195   ],
1196   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1197   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1198   if test $gdb_cv_have_procfs_piocset = yes; then
1199     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1200     [Define if ioctl argument PIOCSET is available.])
1201   fi
1202 fi
1203
1204 dnl For native ports (host == target), check to see what kind of
1205 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1206 if test ${host} = ${target} ; then
1207   dnl Check for struct link_map with l_ members which are indicative
1208   dnl of SVR4-like shared libraries
1209
1210   AC_MSG_CHECKING(for member l_addr in struct link_map)
1211   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1212     [AC_TRY_COMPILE([#include <link.h>],
1213                     [struct link_map lm; (void) lm.l_addr;],
1214                     gdb_cv_have_struct_link_map_with_l_members=yes,
1215                     gdb_cv_have_struct_link_map_with_l_members=no)])
1216   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1217   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1218     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1219     [Define if <link.h> exists and defines struct link_map which has
1220      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1221      SVR4-like systems.)])
1222   fi
1223
1224   dnl Check for struct link_map with lm_ members which are indicative
1225   dnl of SunOS-like shared libraries
1226
1227   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1228   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1229     [AC_TRY_COMPILE([#include <sys/types.h>
1230 #include <link.h>],
1231                     [struct link_map lm; (void) lm.lm_addr;],
1232                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1233                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1234   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1235   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1236     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1237     [Define if <link.h> exists and defines struct link_map which has
1238      members with an ``lm_'' prefix.  (For SunOS.)])
1239   fi
1240
1241   dnl Check for struct so_map with som_ members which are found on
1242   dnl some *BSD systems.
1243
1244   AC_MSG_CHECKING(for member som_addr in struct so_map)
1245   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1246     [AC_TRY_COMPILE([#include <sys/types.h>
1247 #ifdef HAVE_NLIST_H
1248 #include <nlist.h>
1249 #endif
1250 #include <link.h>],
1251                     [struct so_map lm; (void) lm.som_addr;],
1252                     gdb_cv_have_struct_so_map_with_som_members=yes,
1253                     gdb_cv_have_struct_so_map_with_som_members=no)])
1254   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1255   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1256     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1257     [Define if <link.h> exists and defines a struct so_map which has
1258      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1259   fi
1260
1261   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1262   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1263
1264   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1265   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1266     [AC_TRY_COMPILE([#define _SYSCALL32
1267 #include <sys/link.h>], [struct link_map32 l;],
1268      gdb_cv_have_struct_link_map32=yes,
1269      gdb_cv_have_struct_link_map32=no)])
1270   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1271   if test $gdb_cv_have_struct_link_map32 = yes; then
1272     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1273     [Define if <sys/link.h> has struct link_map32])
1274     AC_DEFINE(_SYSCALL32, 1,
1275     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1276   fi
1277 fi
1278
1279 # Check if the compiler supports the `long long' type.
1280
1281 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1282                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1283 [[extern long long foo;]],
1284 [[switch (foo & 2) { case 0: return 1; }]])],
1285                                   gdb_cv_c_long_long=yes,
1286                                   gdb_cv_c_long_long=no)])
1287 if test $gdb_cv_c_long_long = yes; then
1288   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1289             [Define to 1 if the compiler supports long long.])
1290 fi
1291
1292 # Check if the compiler and runtime support printing long longs.
1293
1294 AC_CACHE_CHECK([for long long support in printf],
1295                gdb_cv_printf_has_long_long,
1296                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1297 [[char buf[32];
1298   long long l = 0;
1299   l = (l << 16) + 0x0123;
1300   l = (l << 16) + 0x4567;
1301   l = (l << 16) + 0x89ab;
1302   l = (l << 16) + 0xcdef;
1303   sprintf (buf, "0x%016llx", l);
1304   return (strcmp ("0x0123456789abcdef", buf));]])],
1305                               gdb_cv_printf_has_long_long=yes,
1306                               gdb_cv_printf_has_long_long=no,
1307                               gdb_cv_printf_has_long_long=no)])
1308 if test $gdb_cv_printf_has_long_long = yes; then
1309   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1310             [Define to 1 if the "%ll" format works to print long longs.])
1311 fi
1312
1313 # Check if the compiler and runtime support printing decfloats.
1314
1315 AC_CACHE_CHECK([for decfloat support in printf],
1316                gdb_cv_printf_has_decfloat,
1317                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1318 [[char buf[64];
1319   _Decimal32 d32 = 1.2345df;
1320   _Decimal64 d64 = 1.2345dd;
1321   _Decimal128 d128 = 1.2345dl;
1322   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1323   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1324                               gdb_cv_printf_has_decfloat=yes,
1325                               gdb_cv_printf_has_decfloat=no,
1326                               gdb_cv_printf_has_decfloat=no)])
1327 if test $gdb_cv_printf_has_decfloat = yes; then
1328   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1329             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1330 fi
1331
1332 # Check if the compiler supports the `long double' type.  We can't use
1333 # AC_C_LONG_DOUBLE because that one does additional checks on the
1334 # constants defined in <float.h> that fail on some systems,
1335 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1336
1337 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1338                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1339                                   gdb_cv_c_long_double=yes,
1340                                   gdb_cv_c_long_double=no)])
1341 if test $gdb_cv_c_long_double = yes; then
1342   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1343            [Define to 1 if the compiler supports long double.])
1344 fi
1345
1346 # Check if the compiler and runtime support printing long doubles.
1347
1348 AC_CACHE_CHECK([for long double support in printf],
1349                gdb_cv_printf_has_long_double,
1350                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1351 [[char buf[16];
1352   long double f = 3.141592653;
1353   sprintf (buf, "%Lg", f);
1354   return (strncmp ("3.14159", buf, 7));]])],
1355                               gdb_cv_printf_has_long_double=yes,
1356                               gdb_cv_printf_has_long_double=no,
1357                               gdb_cv_printf_has_long_double=no)])
1358 if test $gdb_cv_printf_has_long_double = yes; then
1359   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1360             [Define to 1 if the "%Lg" format works to print long doubles.])
1361 fi
1362
1363 # Check if the compiler and runtime support scanning long doubles.
1364
1365 AC_CACHE_CHECK([for long double support in scanf],
1366                gdb_cv_scanf_has_long_double,
1367                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1368 [[#include <stdio.h>]],
1369 [[char *buf = "3.141592653";
1370   long double f = 0;
1371   sscanf (buf, "%Lg", &f);
1372   return !(f > 3.14159 && f < 3.14160);]])],
1373                               gdb_cv_scanf_has_long_double=yes,
1374                               gdb_cv_scanf_has_long_double=no,
1375                               gdb_cv_scanf_has_long_double=no)])
1376 if test $gdb_cv_scanf_has_long_double = yes; then
1377   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1378             [Define to 1 if the "%Lg" format works to scan long doubles.])
1379 fi
1380
1381 case ${host_os} in
1382 aix*)
1383   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1384     SAVE_LDFLAGS=$LDFLAGS
1385
1386     case $GCC in
1387     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1388     *) gdb_cv_bigtoc=-bbigtoc ;;
1389     esac
1390
1391     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1392     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1393     LDFLAGS="${SAVE_LDFLAGS}"
1394   ])
1395   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1396   ;;
1397 esac
1398
1399
1400 dnl For certain native configurations, we need to check whether thread
1401 dnl support can be built in or not.
1402 dnl
1403 dnl Note that we only want this if we are both native (host == target),
1404 dnl and not doing a canadian cross build (build == host).
1405
1406 if test ${build} = ${host} -a ${host} = ${target} ; then
1407    case ${host_os} in
1408    hpux*)
1409       AC_MSG_CHECKING(for HPUX/OSF thread support)
1410       if test -f /usr/include/dce/cma_config.h ; then
1411          if test "$GCC" = "yes" ; then
1412             AC_MSG_RESULT(yes)
1413             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1414             [Define if you have HPUX threads])
1415             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1416             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1417          else
1418             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1419          fi
1420       else
1421          AC_MSG_RESULT(no)
1422       fi
1423       ;;
1424    solaris*)
1425       # See if thread_db library is around for Solaris thread debugging.
1426       # Note that we must explicitly test for version 1 of the library
1427       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1428       # the same API.
1429       AC_MSG_CHECKING(for Solaris thread debugging library)
1430       if test -f /usr/lib/libthread_db.so.1 ; then
1431          AC_MSG_RESULT(yes)
1432          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1433          [Define if using Solaris thread debugging.])
1434          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1435          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1436          AC_CHECK_LIB(dl, dlopen)
1437          if test "$GCC" = "yes" ; then
1438             # The GNU linker requires the -export-dynamic option to make
1439             # all symbols visible in the dynamic symbol table.
1440             hold_ldflags=$LDFLAGS
1441             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1442             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1443             AC_TRY_LINK(, [int i;], found=yes, found=no)
1444             LDFLAGS=$hold_ldflags
1445             AC_MSG_RESULT($found)
1446             if test $found = yes; then
1447                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1448             fi
1449          fi
1450          # Sun randomly tweaked the prototypes in <proc_service.h>
1451          # at one point.
1452          AC_MSG_CHECKING(if <proc_service.h> is old)
1453          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1454             AC_TRY_COMPILE([
1455                 #include <proc_service.h>
1456                 ps_err_e ps_pdwrite
1457                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1458             ],, gdb_cv_proc_service_is_old=no,
1459                 gdb_cv_proc_service_is_old=yes)
1460          ])
1461          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1462          if test $gdb_cv_proc_service_is_old = yes; then
1463             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1464             [Define if <proc_service.h> on solaris uses int instead of
1465              size_t, and assorted other type changes.])
1466          fi
1467       else
1468          AC_MSG_RESULT(no)
1469       fi
1470       ;;
1471    aix*)
1472       AC_MSG_CHECKING(for AiX thread debugging library)
1473       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1474                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1475                                    [#ifndef PTHDB_VERSION_3
1476                                     #error
1477                                     #endif],
1478                                    gdb_cv_have_aix_thread_debug=yes,
1479                                    gdb_cv_have_aix_thread_debug=no)])
1480       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1481       if test $gdb_cv_have_aix_thread_debug = yes; then
1482          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1483          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1484          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1485       fi
1486       ;;
1487    esac
1488    AC_SUBST(CONFIG_LDFLAGS)
1489 fi
1490
1491 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1492 dnl other error codes.
1493 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1494    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1495                   gdb_cv_thread_db_h_has_td_notalloc,
1496      AC_TRY_COMPILE(
1497        [#include <thread_db.h>],
1498        [int i = TD_NOTALLOC;],
1499        gdb_cv_thread_db_h_has_td_notalloc=yes,
1500        gdb_cv_thread_db_h_has_td_notalloc=no
1501      )
1502    )
1503    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1504                   gdb_cv_thread_db_h_has_td_version,
1505      AC_TRY_COMPILE(
1506        [#include <thread_db.h>],
1507        [int i = TD_VERSION;],
1508        gdb_cv_thread_db_h_has_td_version=yes,
1509        gdb_cv_thread_db_h_has_td_version=no
1510      )
1511    )
1512    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1513                   gdb_cv_thread_db_h_has_td_notls,
1514      AC_TRY_COMPILE(
1515        [#include <thread_db.h>],
1516        [int i = TD_NOTLS;],
1517        gdb_cv_thread_db_h_has_td_notls=yes,
1518        gdb_cv_thread_db_h_has_td_notls=no
1519      )
1520    )
1521 fi
1522 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1523   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1524             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1525 fi
1526 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1527   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1528             [Define if <thread_db.h> has the TD_VERSION error code.])
1529 fi
1530 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1531   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1532             [Define if <thread_db.h> has the TD_NOTLS error code.])
1533 fi
1534
1535 dnl See if we have a sys/syscall header file that has __NR_tkill.
1536 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1537    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1538                   gdb_cv_sys_syscall_h_has_tkill,
1539      AC_TRY_COMPILE(
1540        [#include <sys/syscall.h>],
1541        [int i = __NR_tkill;],
1542        gdb_cv_sys_syscall_h_has_tkill=yes,
1543        gdb_cv_sys_syscall_h_has_tkill=no
1544      )
1545    )
1546 fi
1547 dnl See if we can issue tkill syscall.
1548 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1549   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1550 fi
1551
1552 dnl Check if we can disable the virtual address space randomization.
1553 dnl The functionality of setarch -R.
1554 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1555 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1556 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1557 #       define ADDR_NO_RANDOMIZE 0x0040000
1558 #      endif
1559        /* Test the flag could be set and stays set.  */
1560        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1561        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1562            return 1])])
1563 AC_RUN_IFELSE([PERSONALITY_TEST],
1564               [have_personality=true],
1565               [have_personality=false],
1566               [AC_LINK_IFELSE([PERSONALITY_TEST],
1567                               [have_personality=true],
1568                               [have_personality=false])])
1569 if $have_personality
1570 then
1571     AC_DEFINE([HAVE_PERSONALITY], 1,
1572               [Define if you support the personality syscall.])
1573 fi
1574
1575 dnl Handle optional features that can be enabled.
1576
1577 target_sysroot_reloc=0
1578 AC_ARG_WITH(sysroot,
1579 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1580 [
1581  case ${with_sysroot} in
1582  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1583  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1584  esac
1585
1586  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1587
1588  if test "x$prefix" = xNONE; then
1589   test_prefix=/usr/local
1590  else
1591   test_prefix=$prefix
1592  fi
1593  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1594   test_exec_prefix=$test_prefix
1595  else
1596   test_exec_prefix=$exec_prefix
1597  fi
1598  case ${TARGET_SYSTEM_ROOT} in
1599  "${test_prefix}"|"${test_prefix}/"*|\
1600  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1601  '${prefix}'|'${prefix}/'*|\
1602  '${exec_prefix}'|'${exec_prefix}/'*)
1603    target_sysroot_reloc=1
1604    ;;
1605  esac
1606 ], [
1607  TARGET_SYSTEM_ROOT=
1608  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1609 ])
1610 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1611 AC_SUBST(TARGET_SYSTEM_ROOT)
1612 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1613
1614 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1615     [automatically load a system-wide gdbinit file],
1616     [])
1617
1618 AC_ARG_ENABLE(werror,
1619   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1620   [case "${enableval}" in
1621      yes | y) ERROR_ON_WARNING="yes" ;;
1622      no | n)  ERROR_ON_WARNING="no" ;;
1623      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1624    esac])
1625
1626 # Enable -Werror by default when using gcc
1627 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1628     ERROR_ON_WARNING=yes
1629 fi
1630
1631 WERROR_CFLAGS=""
1632 if test "${ERROR_ON_WARNING}" = yes ; then
1633     WERROR_CFLAGS="-Werror"
1634 fi
1635
1636 # The entries after -Wno-pointer-sign are disabled warnings which may
1637 # be enabled in the future, which can not currently be used to build
1638 # GDB.
1639 # NOTE: If you change this list, remember to update
1640 # gdb/doc/gdbint.texinfo.
1641 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1642 -Wformat-nonliteral -Wno-pointer-sign \
1643 -Wno-unused -Wunused-value -Wunused-function \
1644 -Wno-switch -Wno-char-subscripts"
1645
1646 # Enable -Wno-format by default when using gcc on mingw since many
1647 # GCC versions complain about %I64.
1648 case "${host}" in
1649   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1650 esac
1651
1652 AC_ARG_ENABLE(build-warnings,
1653 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1654 [case "${enableval}" in
1655   yes)  ;;
1656   no)   build_warnings="-w";;
1657   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1658         build_warnings="${build_warnings} ${t}";;
1659   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1660         build_warnings="${t} ${build_warnings}";;
1661   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1662 esac
1663 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1664   echo "Setting compiler warning flags = $build_warnings" 6>&1
1665 fi])dnl
1666 AC_ARG_ENABLE(gdb-build-warnings,
1667 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1668 [case "${enableval}" in
1669   yes)  ;;
1670   no)   build_warnings="-w";;
1671   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1672         build_warnings="${build_warnings} ${t}";;
1673   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1674         build_warnings="${t} ${build_warnings}";;
1675   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1676 esac
1677 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1678   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1679 fi])dnl
1680 WARN_CFLAGS=""
1681 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1682 then
1683     AC_MSG_CHECKING(compiler warning flags)
1684     # Separate out the -Werror flag as some files just cannot be
1685     # compiled with it enabled.
1686     for w in ${build_warnings}; do
1687         case $w in
1688         -Werr*) WERROR_CFLAGS=-Werror ;;
1689         *) # Check that GCC accepts it
1690             saved_CFLAGS="$CFLAGS"
1691             CFLAGS="$CFLAGS $w"
1692             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1693             CFLAGS="$saved_CFLAGS"
1694         esac
1695     done
1696     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1697 fi
1698 AC_SUBST(WARN_CFLAGS)
1699 AC_SUBST(WERROR_CFLAGS)
1700
1701 # In the Cygwin environment, we need some additional flags.
1702 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1703 [AC_EGREP_CPP(lose, [
1704 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1705 lose
1706 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1707
1708
1709 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1710 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1711 case ${host} in
1712   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1713   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1714   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1715 esac
1716 AC_SUBST(SER_HARDWIRE)
1717
1718 # libreadline needs libuser32.a in a cygwin environment
1719 WIN32LIBS=
1720 if test x$gdb_cv_os_cygwin = xyes; then
1721     WIN32LIBS="-luser32"
1722     case "${target}" in
1723         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1724         ;;
1725     esac
1726 fi
1727
1728 # The ser-tcp.c module requires sockets.
1729 case ${host} in
1730   *mingw32*)
1731     AC_DEFINE(USE_WIN32API, 1,
1732               [Define if we should use the Windows API, instead of the
1733                POSIX API.  On Windows, we use the Windows API when
1734                building for MinGW, but the POSIX API when building
1735                for Cygwin.])
1736     WIN32LIBS="$WIN32LIBS -lws2_32"
1737     ;;
1738 esac
1739 AC_SUBST(WIN32LIBS)
1740
1741 # Add ELF support to GDB, but only if BFD includes ELF support.
1742 OLD_CFLAGS=$CFLAGS
1743 OLD_LDFLAGS=$LDFLAGS
1744 OLD_LIBS=$LIBS
1745 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1746 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1747 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1748 LIBS="-lbfd -liberty $intl $LIBS"
1749 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1750 [AC_TRY_LINK(
1751 [#include <stdlib.h>
1752 #include "bfd.h"
1753 #include "elf-bfd.h"
1754 ],
1755 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1756 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1757 if test $gdb_cv_var_elf = yes; then
1758   CONFIG_OBS="$CONFIG_OBS elfread.o"
1759   AC_DEFINE(HAVE_ELF, 1,
1760             [Define if ELF support should be included.])
1761 fi
1762 CFLAGS=$OLD_CFLAGS
1763 LDFLAGS=$OLD_LDFLAGS
1764 LIBS=$OLD_LIBS
1765
1766 # Add any host-specific objects to GDB.
1767 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1768
1769 LIBGUI="../libgui/src/libgui.a"
1770 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1771 AC_SUBST(LIBGUI)
1772 AC_SUBST(GUI_CFLAGS_X)
1773
1774 WIN32LDAPP=
1775 AC_SUBST(WIN32LIBS)
1776 AC_SUBST(WIN32LDAPP)
1777
1778 case "${host}" in
1779 *-*-cygwin* | *-*-mingw* )
1780     configdir="win"
1781     ;;
1782 *)
1783     configdir="unix"
1784     ;;
1785 esac
1786
1787 GDBTKLIBS=
1788 if test "${enable_gdbtk}" = "yes"; then
1789
1790     # Gdbtk must have an absolute path to srcdir in order to run
1791     # properly when not installed.
1792     here=`pwd`
1793     cd ${srcdir}
1794     GDBTK_SRC_DIR=`pwd`
1795     cd $here
1796
1797     SC_PATH_TCLCONFIG
1798
1799     # If $no_tk is nonempty, then we can't do Tk, and there is no
1800     # point to doing Tcl.
1801     SC_PATH_TKCONFIG
1802
1803     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1804         SC_LOAD_TCLCONFIG
1805
1806         # Check for in-tree tcl
1807         here=`pwd`
1808         cd ${srcdir}/..
1809         topdir=`pwd`
1810         cd ${here}
1811
1812         intree="no"
1813         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1814           intree="yes"
1815         fi
1816
1817         # Find Tcl private headers
1818         if test x"${intree}" = xno; then
1819           CY_AC_TCL_PRIVATE_HEADERS
1820           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1821           TCL_LIBRARY="${TCL_LIB_SPEC}"
1822           TCL_DEPS=""
1823         else
1824           # If building tcl in the same src tree, private headers
1825           # are not needed, but we need to be sure to use the right
1826           # headers library
1827           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1828           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1829           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1830         fi
1831         AC_SUBST(TCL_INCLUDE)
1832         AC_SUBST(TCL_LIBRARY)
1833         AC_SUBST(TCL_DEPS)
1834
1835         SC_LOAD_TKCONFIG
1836
1837         # Check for in-tree Tk
1838         intree="no"
1839         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1840           intree="yes"
1841         fi
1842
1843         # Find Tk private headers
1844         if test x"${intree}" = xno; then
1845           CY_AC_TK_PRIVATE_HEADERS
1846           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1847           TK_LIBRARY=${TK_LIB_SPEC}
1848           TK_DEPS=""
1849         else
1850           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1851           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1852           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1853         fi
1854         AC_SUBST(TK_INCLUDE)
1855         AC_SUBST(TK_LIBRARY)
1856         AC_SUBST(TK_DEPS)
1857         AC_SUBST(TK_XINCLUDES)
1858
1859         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1860
1861         # Include some libraries that Tcl and Tk want.
1862         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1863         # Yes, the ordering seems wrong here.  But it isn't.
1864         # TK_LIBS is the list of libraries that need to be linked
1865         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1866         # were in LIBS then any link tests after this point would
1867         # try to include things like `$(LIBGUI)', which wouldn't work.
1868         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1869
1870         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1871         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1872         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1873         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1874         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1875         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1876         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1877
1878         if test x$gdb_cv_os_cygwin = xyes; then
1879           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1880           WIN32LDAPP="-Wl,--subsystem,console"
1881           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1882         fi
1883
1884         AC_CONFIG_SUBDIRS(gdbtk)
1885     fi
1886 fi
1887
1888 AC_SUBST(X_CFLAGS)
1889 AC_SUBST(X_LDFLAGS)
1890 AC_SUBST(X_LIBS)
1891 AC_SUBST(GDBTKLIBS)
1892 AC_SUBST(GDBTK_CFLAGS)
1893 AC_SUBST(GDBTK_SRC_DIR)
1894
1895 AC_PATH_X
1896
1897 # Unlike the sim directory, whether a simulator is linked is controlled by
1898 # presence of a gdb_sim definition in the target configure.tgt entry.
1899 # This code just checks for a few cases where we'd like to ignore those
1900 # definitions, even when they're present in the '.mt' file.  These cases
1901 # are when --disable-sim is specified, or if the simulator directory is
1902 # not part of the source tree.
1903 #
1904 AC_ARG_ENABLE(sim,
1905 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1906 [echo "enable_sim = $enable_sim";
1907  echo "enableval = ${enableval}";
1908  case "${enableval}" in
1909   yes) ignore_sim=false ;;
1910   no)  ignore_sim=true ;;
1911   *)   ignore_sim=false ;;
1912  esac],
1913 [ignore_sim=false])
1914
1915 if test ! -d "${srcdir}/../sim"; then
1916   ignore_sim=true
1917 fi
1918
1919 SIM=
1920 SIM_OBS=
1921 if test "${ignore_sim}" = "false"; then
1922   if test x"${gdb_sim}" != x ; then
1923     SIM="${gdb_sim}"
1924     SIM_OBS="remote-sim.o"
1925     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1926   fi
1927 fi
1928 AC_SUBST(SIM)
1929 AC_SUBST(SIM_OBS)
1930
1931 AC_SUBST(ENABLE_CFLAGS)
1932 AC_SUBST(PROFILE_CFLAGS)
1933
1934 AC_SUBST(CONFIG_OBS)
1935 AC_SUBST(CONFIG_DEPS)
1936 AC_SUBST(CONFIG_SRCS)
1937 AC_SUBST(CONFIG_ALL)
1938 AC_SUBST(CONFIG_CLEAN)
1939 AC_SUBST(CONFIG_INSTALL)
1940 AC_SUBST(CONFIG_UNINSTALL)
1941
1942 # List of host floatformats.
1943 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1944 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1945 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1946
1947 # target_subdir is used by the testsuite to find the target libraries.
1948 target_subdir=
1949 if test "${host}" != "${target}"; then
1950     target_subdir="${target_alias}/"
1951 fi
1952 AC_SUBST(target_subdir)
1953
1954 frags=
1955 if test "${gdb_native}" = "yes"; then
1956   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1957   if test ! -f ${host_makefile_frag}; then
1958     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1959   fi
1960   frags="$frags $host_makefile_frag"
1961 else
1962   host_makefile_frag=/dev/null
1963 fi
1964
1965 AC_SUBST_FILE(host_makefile_frag)
1966 AC_SUBST(frags)
1967
1968 changequote(,)dnl
1969 if test "${gdb_native}" = "yes"; then
1970 # We pick this up from the host configuration file (.mh) because we
1971 # do not have a native configuration Makefile fragment.
1972 nativefile=`sed -n '
1973 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1974 ' ${host_makefile_frag}`
1975 fi
1976 changequote([,])
1977
1978 if test x"${gdb_osabi}" != x ; then
1979     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1980                        [Define to the default OS ABI for this configuration.])
1981 fi
1982
1983 # Enable multi-ice-gdb-server.
1984 AC_ARG_ENABLE(multi-ice,
1985 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
1986   [case $enableval in
1987     yes | no)
1988       ;;
1989     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1990   esac])
1991 if test "x$enable_multi_ice" = xyes; then
1992    AC_CONFIG_SUBDIRS(multi-ice)
1993 fi
1994
1995 # We only build gdbserver automatically in a native configuration.
1996 if test "$gdb_native" = "yes"; then
1997   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1998   if test "x$build_gdbserver" = xyes; then
1999     AC_MSG_RESULT(yes)
2000     AC_CONFIG_SUBDIRS(gdbserver)
2001   else
2002     AC_MSG_RESULT(no)
2003   fi
2004 fi
2005
2006 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2007 # to an empty version.
2008
2009 files=
2010 links=
2011
2012 rm -f nm.h
2013 if test "${nativefile}" != ""; then
2014     case "${nativefile}" in
2015       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2016       * ) GDB_NM_FILE="${nativefile}"
2017     esac
2018     files="${files} ${GDB_NM_FILE}"
2019     links="${links} nm.h"
2020     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2021 fi
2022 AC_SUBST(GDB_NM_FILE)
2023
2024 AC_LINK_FILES($files, $links)
2025
2026 dnl Check for exe extension set on certain hosts (e.g. Win32)
2027 AC_EXEEXT
2028
2029 dnl  Detect the character set used by this host.
2030 dnl  At the moment, we just assume it's UTF-8.
2031 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2032           [Define to be a string naming the default host character set.])
2033
2034 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
2035 [
2036 case x$CONFIG_HEADERS in
2037 xconfig.h:config.in)
2038 echo > stamp-h ;;
2039 esac
2040 ])
2041
2042 exit 0