gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 gl_EARLY
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37
  38 # Dependency checking.
  39 ZW_CREATE_DEPDIR
  40 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  41
  42 # Check for the 'make' the user wants to use.
  43 AC_CHECK_PROGS(MAKE, make)
  44 MAKE_IS_GNU=
  45 case "`$MAKE --version 2>&1 | sed 1q`" in
  46   *GNU*)
  47     MAKE_IS_GNU=yes
  48     ;;
  49 esac
  50 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  51 AC_PROG_MAKE_SET
  52
  53 dnl List of object files and targets accumulated by configure.
  54
  55 CONFIG_OBS=
  56 CONFIG_DEPS=
  57 CONFIG_SRCS=
  58 ENABLE_CFLAGS=
  59
  60 CONFIG_ALL=
  61 CONFIG_CLEAN=
  62 CONFIG_INSTALL=
  63 CONFIG_UNINSTALL=
  64
  65 dnl Set up for gettext.
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67
  68 localedir='${datadir}/locale'
  69 AC_SUBST(localedir)
  70
  71 if test x"$USE_NLS" = xyes; then
  72    CONFIG_ALL="$CONFIG_ALL all-po"
  73    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  74    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  75    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  76 fi
  77
  78 gl_INIT
  79
  80 # For Makefile dependencies.
  81 GNULIB_STDINT_H=
  82 if test x"$STDINT_H" != x; then
  83   GNULIB_STDINT_H=gnulib/$STDINT_H
  84 fi
  85 AC_SUBST(GNULIB_STDINT_H)
  86
  87 PACKAGE=gdb
  88 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  89 AC_SUBST(PACKAGE)
  90
  91 # GDB does not use automake, but gnulib does.  This line lets us
  92 # generate its Makefile.in.
  93 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  94
  95 debugdir=${libdir}/debug
  96
  97 AC_ARG_WITH(separate-debug-dir,
  98 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  99 [debugdir="${withval}"])
 100
 101 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 102               [Global directory for separate debug files. ])
 103 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 104
 105 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
 106   if test "x$prefix" = xNONE; then
 107     test_prefix=/usr/local
 108   else
 109     test_prefix=$prefix
 110   fi
 111 else
 112   test_prefix=$exec_prefix
 113 fi
 114 case ${debugdir} in
 115 "${test_prefix}"|"${test_prefix}/"*|\
 116 '${exec_prefix}'|'${exec_prefix}/'*)
 117   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
 118   ;;
 119 esac
 120
 121 AC_CONFIG_SUBDIRS(doc testsuite)
 122
 123 # Check whether to support alternative target configurations
 124 AC_ARG_ENABLE(targets,
 125 [  --enable-targets        alternative target configurations],
 126 [case "${enableval}" in
 127   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 128             ;;
 129   no)       enable_targets= ;;
 130   *)        enable_targets=$enableval ;;
 131 esac])
 132
 133 # Check whether to enable 64-bit support on 32-bit hosts
 134 AC_ARG_ENABLE(64-bit-bfd,
 135 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
 136 [case "${enableval}" in
 137   yes)  want64=true  ;;
 138   no)   want64=false ;;
 139   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 140 esac],[want64=false])dnl
 141
 142 # Provide defaults for some variables set by the per-host and per-target
 143 # configuration.
 144 gdb_host_obs=posix-hdep.o
 145
 146 if test "${target}" = "${host}"; then
 147   gdb_native=yes
 148 else
 149   gdb_native=no
 150 fi
 151
 152 . $srcdir/configure.host
 153
 154 # Accumulate some settings from configure.tgt over all enabled targets
 155
 156 TARGET_OBS=
 157 all_targets=
 158
 159 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 160 do
 161   if test "$targ_alias" = "all"; then
 162     all_targets=true
 163   else
 164     # Canonicalize the secondary target names.
 165     result=`$ac_config_sub $targ_alias 2>/dev/null`
 166     if test -n "$result"; then
 167         targ=$result
 168     else
 169         targ=$targ_alias
 170     fi
 171
 172     . ${srcdir}/configure.tgt
 173
 174     # Target-specific object files
 175     for i in ${gdb_target_obs}; do
 176         case " $TARGET_OBS " in
 177         *" ${i} "*) ;;
 178         *)
 179           TARGET_OBS="$TARGET_OBS ${i}"
 180           ;;
 181         esac
 182     done
 183
 184     # Check whether this target needs 64-bit CORE_ADDR
 185     if test x${want64} = xfalse; then
 186       . ${srcdir}/../bfd/config.bfd
 187     fi
 188   fi
 189 done
 190
 191 if test x${all_targets} = xtrue; then
 192
 193   # We want all 64-bit targets if we either:
 194   #  - run on a 64-bit host  or
 195   #  - already require 64-bit support for some other target  or
 196   #  - the --enable-64-bit-bfd option was supplied
 197   # Otherwise we only support all 32-bit targets.
 198   #
 199   # NOTE: This test must be in sync with the corresponding
 200   #       tests in BFD!
 201
 202   if test x${want64} = xfalse; then
 203     AC_CHECK_SIZEOF(long)
 204     if test "x${ac_cv_sizeof_long}" = "x8"; then
 205       want64=true
 206     fi
 207   fi
 208   if test x${want64} = xtrue; then
 209     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 210   else
 211     TARGET_OBS='$(ALL_TARGET_OBS)'
 212   fi
 213 fi
 214
 215 AC_SUBST(TARGET_OBS)
 216
 217 # For other settings, only the main target counts.
 218 gdb_sim=
 219 gdb_osabi=
 220 build_gdbserver=
 221 targ=$target; . ${srcdir}/configure.tgt
 222
 223 # Fetch the default architecture and default target vector from BFD.
 224 targ=$target; . $srcdir/../bfd/config.bfd
 225
 226 # We only want the first architecture, so strip off the others if
 227 # there is more than one.
 228 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 229
 230 if test "x$targ_archs" != x; then
 231   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 232     [Define to BFD's default architecture. ])
 233 fi
 234 if test "x$targ_defvec" != x; then
 235   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 236     [Define to BFD's default target vector. ])
 237 fi
 238
 239 # The CLI cannot be disabled yet, but may be in the future.
 240
 241 # Enable CLI.
 242 AC_ARG_ENABLE(gdbcli,
 243 [  --disable-gdbcli        disable command-line interface (CLI)],
 244   [case $enableval in
 245     yes)
 246       ;;
 247     no)
 248       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 249     *)
 250       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 251   esac],
 252   [enable_gdbcli=yes])
 253 if test x"$enable_gdbcli" = xyes; then
 254   if test -d $srcdir/cli; then
 255     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 256     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 257     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 258     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 259   fi
 260 fi
 261
 262 # Enable MI.
 263 AC_ARG_ENABLE(gdbmi,
 264 [  --disable-gdbmi         disable machine-interface (MI)],
 265   [case $enableval in
 266     yes | no)
 267       ;;
 268     *)
 269       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 270   esac],
 271   [enable_gdbmi=yes])
 272 if test x"$enable_gdbmi" = xyes; then
 273   if test -d $srcdir/mi; then
 274     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 275     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 276     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 277     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 278   fi
 279 fi
 280
 281 # Enable TUI.
 282 AC_ARG_ENABLE(tui,
 283 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 284   [case $enableval in
 285     yes | no | auto)
 286       ;;
 287     *)
 288       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 289   esac],enable_tui=auto)
 290
 291 # Enable gdbtk.
 292 AC_ARG_ENABLE(gdbtk,
 293 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 294   [case $enableval in
 295     yes | no)
 296       ;;
 297     *)
 298       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 299   esac],
 300   [if test -d $srcdir/gdbtk; then
 301     enable_gdbtk=yes
 302   else
 303     enable_gdbtk=no
 304   fi])
 305 # We unconditionally disable gdbtk tests on selected platforms.
 306 case $host_os in
 307   go32* | windows*)
 308     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 309     enable_gdbtk=no ;;
 310 esac
 311
 312 # Libunwind support.
 313 AC_ARG_WITH(libunwind,
 314 [  --with-libunwind            Use libunwind frame unwinding support],
 315 [case "${withval}" in
 316   yes)  enable_libunwind=yes ;;
 317   no)   enable_libunwind=no ;;
 318   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 319 esac],[
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 322     enable_libunwind=yes;
 323   fi
 324 ])
 325
 326 if test x"$enable_libunwind" = xyes; then
 327   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 328   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 329   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 330   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 331   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 332 fi
 333
 334 opt_curses=no
 335 AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 336
 337 prefer_curses=no
 338 if test "$opt_curses" = "yes"; then
 339   prefer_curses=yes
 340 fi
 341
 342 # Profiling support.
 343 AC_ARG_ENABLE(profiling,
 344 [  --enable-profiling      enable profiling of GDB],
 345   [case $enableval in
 346     yes | no)
 347       ;;
 348     *)
 349       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 350   esac],
 351  [enable_profiling=no])
 352
 353 AC_CHECK_FUNCS(monstartup _mcleanup)
 354 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 355 [AC_TRY_LINK(
 356 [#include <stdlib.h>
 357 extern char _etext;
 358 ],
 359 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 360 if test $ac_cv_var__etext = yes; then
 361   AC_DEFINE(HAVE__ETEXT, 1,
 362             [Define to 1 if your system has the _etext variable. ])
 363 fi
 364 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 365 [AC_TRY_LINK(
 366 [#include <stdlib.h>
 367 extern char etext;
 368 ],
 369 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 370 if test $ac_cv_var_etext = yes; then
 371   AC_DEFINE(HAVE_ETEXT, 1,
 372             [Define to 1 if your system has the etext variable. ])
 373 fi
 374 if test "$enable_profiling" = yes ; then
 375   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 376     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 377   fi
 378   PROFILE_CFLAGS=-pg
 379   OLD_CFLAGS="$CFLAGS"
 380   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 381
 382   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 383     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 384      ac_cv_cc_supports_pg=no)])
 385
 386   if test $ac_cv_cc_supports_pg = no; then
 387     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 388   fi
 389
 390   CFLAGS="$OLD_CFLAGS"
 391 fi
 392
 393 ACX_PKGVERSION([GDB])
 394 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 395 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 396 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 397
 398 # --------------------- #
 399 # Checks for programs.  #
 400 # --------------------- #
 401
 402 AC_PROG_AWK
 403 AC_PROG_INSTALL
 404 AC_PROG_LN_S
 405 AC_PROG_RANLIB
 406 AC_PROG_YACC
 407
 408 AC_CHECK_TOOL(AR, ar)
 409 AC_CHECK_TOOL(DLLTOOL, dlltool)
 410 AC_CHECK_TOOL(WINDRES, windres)
 411
 412 # Needed for GNU/Hurd.
 413 AC_CHECK_TOOL(MIG, mig)
 414
 415 # ---------------------- #
 416 # Checks for libraries.  #
 417 # ---------------------- #
 418
 419 # We might need to link with -lm; most simulators need it.
 420 AC_CHECK_LIB(m, main)
 421
 422 # We need to link with -lw to get `wctype' on Solaris before Solaris
 423 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 424 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 425 # is known to have this problem).  Therefore we avoid libw if we can.
 426 AC_CHECK_FUNC(wctype, [],
 427   [AC_CHECK_LIB(w, wctype)])
 428
 429 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 430 AC_SEARCH_LIBS(gethostbyname, nsl)
 431
 432 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 433 AC_SEARCH_LIBS(socketpair, socket)
 434
 435 # Link in zlib if we can.  This allows us to read compressed debug sections.
 436 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 437
 438 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 439 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 440
 441 AM_ICONV
 442
 443 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 444 # There is a very specific comment in /usr/include/curses.h explaining that
 445 # termcap routines built into libcurses must not be used.
 446 #
 447 # The symptoms we observed so far is GDB unexpectedly changing
 448 # the terminal settings when tgetent is called - this is particularly
 449 # visible as the output is missing carriage returns, and so rapidly
 450 # becomes very hard to read.
 451 #
 452 # The readline configure script has already decided that libtermcap
 453 # was enough for its purposes, and so decided to build readline using
 454 # libtermcap.  Since the TUI mode requires curses, building GDB with
 455 # TUI enabled results in both libraries to be used at the same time,
 456 # which is not allowed.  This basically means that GDB with TUI is
 457 # broken on alpha-osf.
 458
 459 case $host_os in
 460   alpha*-*-osf* )
 461     if "$enable_tui" = "yes"; then
 462       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 463     fi
 464     if "$enable_tui" = "auto"; then
 465       enable_tui=no
 466     fi
 467     ;;
 468 esac
 469
 470 # For the TUI, we need enhanced curses functionality.
 471 if test x"$enable_tui" != xno; then
 472   prefer_curses=yes
 473 fi
 474
 475 curses_found=no
 476 if test x"$prefer_curses" = xyes; then
 477   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 478   # curses library because the latter might not provide all the
 479   # functionality we need.  However, this leads to problems on systems
 480   # where the linker searches /usr/local/lib, but the compiler doesn't
 481   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 482   # default installation of ncurses on alpha*-dec-osf* will lead to such
 483   # a situation.
 484   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 485
 486   if test "$ac_cv_search_waddstr" != no; then
 487     curses_found=yes
 488   fi
 489 fi
 490
 491 # Check whether we should enable the TUI, but only do so if we really
 492 # can.
 493 if test x"$enable_tui" != xno; then
 494   if test -d $srcdir/tui; then
 495     if test "$curses_found" != no; then
 496       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 497       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 498       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 499       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 500       CONFIG_ALL="${CONFIG_ALL} all-tui"
 501       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 502       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 503       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 504     else
 505       if test x"$enable_tui" = xyes; then
 506         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 507       else
 508         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 509       fi
 510     fi
 511   fi
 512 fi
 513
 514 # Since GDB uses Readline, we need termcap functionality.  In many
 515 # cases this will be provided by the curses library, but some systems
 516 # have a seperate termcap library, or no curses library at all.
 517
 518 case $host_os in
 519   cygwin*)
 520     if test -d $srcdir/libtermcap; then
 521       LIBS="../libtermcap/libtermcap.a $LIBS"
 522       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 523     fi ;;
 524   go32* | *djgpp*)
 525     ac_cv_search_tgetent="none required"
 526     ;;
 527   *mingw32*)
 528     ac_cv_search_tgetent="none required"
 529     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 530     ;;
 531 esac
 532
 533 # These are the libraries checked by Readline.
 534 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 535
 536 if test "$ac_cv_search_tgetent" = no; then
 537   AC_MSG_ERROR([no termcap library found])
 538 fi
 539
 540 AC_ARG_WITH([system-readline],
 541   [AS_HELP_STRING([--with-system-readline],
 542                   [use installed readline library])])
 543
 544 if test "$with_system_readline" = yes; then
 545   READLINE=-lreadline
 546   READLINE_DEPS=
 547   READLINE_CFLAGS=
 548 else
 549   READLINE='$(READLINE_DIR)/libreadline.a'
 550   READLINE_DEPS='$(READLINE)'
 551   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 552 fi
 553 AC_SUBST(READLINE)
 554 AC_SUBST(READLINE_DEPS)
 555 AC_SUBST(READLINE_CFLAGS)
 556
 557 AC_ARG_WITH(expat,
 558   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 559   [], [with_expat=auto])
 560 AC_MSG_CHECKING([whether to use expat])
 561 AC_MSG_RESULT([$with_expat])
 562
 563 if test "${with_expat}" = no; then
 564   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 565   HAVE_LIBEXPAT=no
 566 else
 567   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 568                         [XML_Parser p = XML_ParserCreate (0);])
 569   if test "$HAVE_LIBEXPAT" != yes; then
 570     if test "$with_expat" = yes; then
 571       AC_MSG_ERROR([expat is missing or unusable])
 572     else
 573       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 574     fi
 575   else
 576     save_LIBS=$LIBS
 577     LIBS="$LIBS $LIBEXPAT"
 578     AC_CHECK_FUNCS(XML_StopParser)
 579     LIBS=$save_LIBS
 580   fi
 581 fi
 582
 583 dnl Utility to simplify finding libpython.
 584 AC_DEFUN([AC_TRY_LIBPYTHON],
 585 [
 586   version=$1
 587   define([have_libpython_var],$2)
 588   define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
 589                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
 590   [HAVE_LIB]VERSION=no
 591   AC_MSG_CHECKING([for ${version}])
 592   save_LIBS=$LIBS
 593   LIBS="$LIBS -l${version}"
 594   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 595                                  [[Py_Initialize ();]]),
 596                  [[HAVE_LIB]VERSION=yes
 597                   have_libpython_var=yes],
 598                  [LIBS=$save_LIBS])
 599   AC_MSG_RESULT([$[HAVE_LIB]VERSION])
 600 ])
 601
 602 AC_ARG_WITH(python,
 603   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 604   [], [with_python=auto])
 605 AC_MSG_CHECKING([whether to use python])
 606 AC_MSG_RESULT([$with_python])
 607
 608 if test "${with_python}" = no; then
 609   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 610   have_libpython=no
 611 else
 612   case "${with_python}" in
 613   yes | auto)
 614     # Leave as empty, use defaults.
 615     python_includes=
 616     python_libs=
 617     ;;
 618   /*)
 619     python_includes="-I${with_python}/include"
 620     python_libs="-L${with_python}/lib"
 621     ;;
 622   *)
 623     AC_ERROR(invalid value for --with-python)
 624     ;;
 625   esac
 626
 627   save_CPPFLAGS=$CPPFLAGS
 628   CPPFLAGS="$CPPFLAGS ${python_includes}"
 629   save_LIBS=$LIBS
 630   LIBS="$LIBS ${python_libs}"
 631   have_libpython=no
 632   if test "${have_libpython}" = no; then
 633     AC_TRY_LIBPYTHON(python2.6, have_libpython)
 634     if test "${HAVE_LIBPYTHON2_6}" = yes; then
 635       AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 636     fi
 637   fi
 638   if test ${have_libpython} = no; then
 639     AC_TRY_LIBPYTHON(python2.5, have_libpython)
 640     if test "${HAVE_LIBPYTHON2_5}" = yes; then
 641       AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 642     fi
 643   fi
 644   if test ${have_libpython} = no; then
 645     AC_TRY_LIBPYTHON(python2.4, have_libpython)
 646     if test "${HAVE_LIBPYTHON2_4}" = yes; then
 647       AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 648     fi
 649   fi
 650   if test ${have_libpython} = no; then
 651     case "${with_python}" in
 652     yes)
 653       AC_MSG_ERROR([python is missing or unusable])
 654       ;;
 655     auto)
 656       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 657       ;;
 658     *)
 659       AC_MSG_ERROR([no usable python found at ${with_python}])
 660       ;;
 661     esac
 662     CPPFLAGS=$save_CPPFLAGS
 663     LIBS=$save_LIBS
 664   fi
 665 fi
 666
 667 if test "${have_libpython}" = yes; then
 668   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 669   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 670   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 671   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 672   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 673
 674   # Flags needed to compile Python code (taken from python-config --cflags).
 675   # We cannot call python-config directly because it will output whatever was
 676   # used when compiling the Python interpreter itself, including flags which
 677   # would make the python-related objects be compiled differently from the
 678   # rest of GDB (e.g., -O2 and -fPIC).
 679   if test "${GCC}" = yes; then
 680     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 681   fi
 682
 683   if test "x${tentative_python_cflags}" != x; then
 684     AC_MSG_CHECKING(compiler flags for python code)
 685     for flag in ${tentative_python_cflags}; do
 686       # Check that the compiler accepts it
 687       saved_CFLAGS="$CFLAGS"
 688       CFLAGS="$CFLAGS $flag"
 689       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 690       CFLAGS="$saved_CFLAGS"
 691     done
 692     AC_MSG_RESULT(${PYTHON_CFLAGS})
 693   fi
 694 else
 695   # Even if Python support is not compiled in, we need to have these files
 696   # included in order to recognize the GDB command "python".
 697   CONFIG_OBS="$CONFIG_OBS python.o python-value.o"
 698   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/python-value.c"
 699 fi
 700 AC_SUBST(PYTHON_CFLAGS)
 701
 702 # ------------------------- #
 703 # Checks for header files.  #
 704 # ------------------------- #
 705
 706 AC_HEADER_DIRENT
 707 AC_HEADER_STAT
 708 AC_HEADER_STDC
 709 # elf_hp.h is for HP/UX 64-bit shared library support.
 710 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 711 # unconditionally, so what's the point in checking these?
 712 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 713                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 714                   stdlib.h string.h memory.h strings.h sys/fault.h \
 715                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 716                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 717                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 718                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 719                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 720 AC_CHECK_HEADERS(link.h, [], [],
 721 [#if HAVE_SYS_TYPES_H
 722 # include <sys/types.h>
 723 #endif
 724 #if HAVE_NLIST_H
 725 # include <nlist.h>
 726 #endif
 727 ])
 728 AC_CHECK_HEADERS(sys/proc.h, [], [],
 729 [#if HAVE_SYS_PARAM_H
 730 # include <sys/param.h>
 731 #endif
 732 ])
 733 AC_CHECK_HEADERS(sys/user.h, [], [],
 734 [#if HAVE_SYS_PARAM_H
 735 # include <sys/param.h>
 736 #endif
 737 ])
 738
 739 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 740 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 741 # think that we don't have <curses.h> if we're using GCC.
 742 case $host_os in
 743   solaris2.[[789]])
 744     if test "$GCC" = yes; then
 745       AC_DEFINE(_MSE_INT_H, 1,
 746         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 747    Solaris 2.[789] when using GCC. ])
 748     fi ;;
 749 esac
 750 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 751 AC_CHECK_HEADERS(term.h, [], [],
 752 [#if HAVE_CURSES_H
 753 # include <curses.h>
 754 #endif
 755 ])
 756
 757 # ------------------------- #
 758 # Checks for declarations.  #
 759 # ------------------------- #
 760
 761 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 762                 snprintf, vsnprintf])
 763 AM_LC_MESSAGES
 764
 765 # ----------------------- #
 766 # Checks for structures.  #
 767 # ----------------------- #
 768
 769 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 770
 771 # ------------------ #
 772 # Checks for types.  #
 773 # ------------------ #
 774
 775 AC_TYPE_SIGNAL
 776 AC_CHECK_TYPES(socklen_t, [], [],
 777 [#include <sys/types.h>
 778 #include <sys/socket.h>
 779 ])
 780
 781 # ------------------------------------- #
 782 # Checks for compiler characteristics.  #
 783 # ------------------------------------- #
 784
 785 AC_C_CONST
 786 AC_C_INLINE
 787 AC_C_BIGENDIAN
 788
 789 # ------------------------------ #
 790 # Checks for library functions.  #
 791 # ------------------------------ #
 792
 793 AC_FUNC_ALLOCA
 794 AC_FUNC_MMAP
 795 AC_FUNC_VFORK
 796 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 797                 getgid poll pread64 sbrk setpgid setpgrp setsid \
 798                 sigaction sigprocmask sigsetmask socketpair syscall \
 799                 ttrace wborder setlocale iconvlist libiconvlist])
 800 AM_LANGINFO_CODESET
 801
 802 # Check the return and argument types of ptrace.  No canned test for
 803 # this, so roll our own.
 804 gdb_ptrace_headers='
 805 #if HAVE_SYS_TYPES_H
 806 # include <sys/types.h>
 807 #endif
 808 #if HAVE_SYS_PTRACE_H
 809 # include <sys/ptrace.h>
 810 #endif
 811 #if HAVE_UNISTD_H
 812 # include <unistd.h>
 813 #endif
 814 '
 815 # There is no point in checking if we don't have a prototype.
 816 AC_CHECK_DECLS(ptrace, [], [
 817   : ${gdb_cv_func_ptrace_ret='int'}
 818   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 819 ], $gdb_ptrace_headers)
 820 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 821 # empty argument list, so check for that explicitly.
 822 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 823   AC_TRY_COMPILE($gdb_ptrace_headers,
 824     [extern long ptrace (enum __ptrace_request, ...);],
 825     gdb_cv_func_ptrace_ret='long',
 826     AC_TRY_COMPILE($gdb_ptrace_headers,
 827       [extern int ptrace ();],
 828       gdb_cv_func_ptrace_ret='int',
 829       gdb_cv_func_ptrace_ret='long')))
 830 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 831   [Define as the return type of ptrace.])
 832 # Check argument types.
 833 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 834   AC_TRY_COMPILE($gdb_ptrace_headers,
 835     [extern long ptrace (enum __ptrace_request, ...);],
 836     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 837 for gdb_arg1 in 'int' 'long'; do
 838  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 839   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 840    for gdb_arg4 in 'int' 'long'; do
 841      AC_TRY_COMPILE($gdb_ptrace_headers, [
 842 extern $gdb_cv_func_ptrace_ret
 843   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 844 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 845     break 4;])
 846     for gdb_arg5 in 'int *' 'int' 'long'; do
 847      AC_TRY_COMPILE($gdb_ptrace_headers, [
 848 extern $gdb_cv_func_ptrace_ret
 849   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 850 ], [
 851 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 852     break 5;])
 853     done
 854    done
 855   done
 856  done
 857 done
 858 # Provide a safe default value.
 859 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 860 ])])
 861 ac_save_IFS=$IFS; IFS=','
 862 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 863 IFS=$ac_save_IFS
 864 shift
 865 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 866   [Define to the type of arg 3 for ptrace.])
 867 if test -n "$[5]"; then
 868   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 869     [Define to the type of arg 5 for ptrace.])
 870 fi
 871
 872 dnl AC_FUNC_SETPGRP does not work when cross compiling
 873 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 874 if test "$cross_compiling" = no; then
 875   AC_FUNC_SETPGRP
 876 else
 877   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 878     [AC_TRY_COMPILE([
 879 #include <unistd.h>
 880 ], [
 881   if (setpgrp(1,1) == -1)
 882     exit (0);
 883   else
 884     exit (1);
 885 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 886 if test $ac_cv_func_setpgrp_void = yes; then
 887   AC_DEFINE(SETPGRP_VOID, 1)
 888 fi
 889 fi
 890
 891 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 892 # since sigsetjmp might only be defined as a macro.
 893 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 894 [AC_TRY_COMPILE([
 895 #include <setjmp.h>
 896 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 897 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 898 if test $gdb_cv_func_sigsetjmp = yes; then
 899   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 900 fi
 901
 902 # Assume we'll default to using the included libiberty regex.
 903 gdb_use_included_regex=yes
 904
 905 # However, if the system regex is GNU regex, then default to *not*
 906 # using the included regex.
 907 AC_CACHE_CHECK(
 908   [for GNU regex],
 909   [gdb_cv_have_gnu_regex],
 910   [AC_TRY_COMPILE(
 911     [#include <gnu-versions.h>],
 912     [#define REGEX_INTERFACE_VERSION 1
 913 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 914 # error "Version mismatch"
 915 #endif],
 916     gdb_cv_have_gnu_regex=yes,
 917     gdb_cv_have_gnu_regex=no)])
 918 if test $gdb_cv_have_gnu_regex = yes; then
 919   gdb_use_included_regex=no
 920 fi
 921
 922 AC_ARG_WITH(included-regex,
 923   [  --without-included-regex don't use included regex; this is the default
 924                           on systems with version 2 of the GNU C library
 925                           (use with caution on other system)],
 926   gdb_with_regex=$withval,
 927   gdb_with_regex=$gdb_use_included_regex)
 928 if test "$gdb_with_regex" = yes; then
 929   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 930     [Define to 1 if the regex included in libiberty should be used.])
 931 fi
 932
 933 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 934 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 935 [#include <sys/param.h>
 936 #include <sys/proc.h>
 937 ])
 938
 939 # See if <sys/lwp.h> defines `struct lwp`.
 940 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 941 [AC_TRY_COMPILE([#include <sys/param.h>
 942 #include <sys/lwp.h>], [struct lwp l;],
 943 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 944 if test $gdb_cv_struct_lwp = yes; then
 945   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 946             [Define to 1 if your system has struct lwp.])
 947 fi
 948
 949 # See if <machine/reg.h> degines `struct reg'.
 950 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 951 [AC_TRY_COMPILE([#include <sys/types.h>
 952 #include <machine/reg.h>], [struct reg r;],
 953 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 954 if test $gdb_cv_struct_reg = yes; then
 955   AC_DEFINE(HAVE_STRUCT_REG, 1,
 956             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 957 fi
 958
 959 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 960 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 961 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 962                  [#include <machine/reg.h>])
 963
 964 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 965 AC_MSG_CHECKING(for PTRACE_GETREGS)
 966 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 967 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 968                 [PTRACE_GETREGS;],
 969                 [gdb_cv_have_ptrace_getregs=yes],
 970                 [gdb_cv_have_ptrace_getregs=no])])
 971 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 972 if test $gdb_cv_have_ptrace_getregs = yes; then
 973   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 974   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 975 fi
 976
 977 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 978 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 979 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 980 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 981                 [PTRACE_GETFPXREGS;],
 982                 [gdb_cv_have_ptrace_getfpxregs=yes],
 983                 [gdb_cv_have_ptrace_getfpxregs=no])])
 984 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 985 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 986   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 987   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 988 fi
 989
 990 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 991 AC_MSG_CHECKING(for PT_GETDBREGS)
 992 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 993 [AC_TRY_COMPILE([#include <sys/types.h>
 994 #include <sys/ptrace.h>],
 995                 [PT_GETDBREGS;],
 996                 [gdb_cv_have_pt_getdbregs=yes],
 997                 [gdb_cv_have_pt_getdbregs=no])])
 998 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 999 if test $gdb_cv_have_pt_getdbregs = yes; then
1000   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1001   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1002 fi
1003
1004 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1005 AC_MSG_CHECKING(for PT_GETXMMREGS)
1006 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1007 [AC_TRY_COMPILE([#include <sys/types.h>
1008 #include <sys/ptrace.h>],
1009                 [PT_GETXMMREGS;],
1010                 [gdb_cv_have_pt_getxmmregs=yes],
1011                 [gdb_cv_have_pt_getxmmregs=no])])
1012 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1013 if test $gdb_cv_have_pt_getxmmregs = yes; then
1014   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1015   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1016 fi
1017
1018 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1019
1020 if test "${target}" = "${host}"; then
1021   case "${host}" in
1022   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1023       AC_DEFINE(NEW_PROC_API, 1,
1024       [Define if you want to use new multi-fd /proc interface
1025        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1026       ;;
1027   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1028       AC_DEFINE(NEW_PROC_API, 1,
1029       [Define if you want to use new multi-fd /proc interface
1030        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1031       ;;
1032   mips-sgi-irix5*)
1033       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1034       AC_DEFINE([_KMEMUSER], 1,
1035       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1036        around a <sys/proc.h> problem on IRIX 5.])
1037       ;;
1038   esac
1039 fi
1040
1041 if test "$ac_cv_header_sys_procfs_h" = yes; then
1042   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1043   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1044   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1045   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1046   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1047   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1048   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1049   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1050   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1051   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1052   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1053   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1054   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1055   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1056
1057
1058   dnl Check for broken prfpregset_t type
1059
1060   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1061   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1062   dnl instead of the struct itself).  We detect this here, and work
1063   dnl around it in gdb_proc_service.h.
1064
1065   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1066     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1067     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1068       [AC_TRY_RUN([#include <sys/procfs.h>
1069        int main ()
1070        {
1071          if (sizeof (prfpregset_t) == sizeof (void *))
1072            return 1;
1073          return 0;
1074        }],
1075        gdb_cv_prfpregset_t_broken=no,
1076        gdb_cv_prfpregset_t_broken=yes,
1077        gdb_cv_prfpregset_t_broken=yes)])
1078     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1079     if test $gdb_cv_prfpregset_t_broken = yes; then
1080       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1081       [Define if the prfpregset_t type is broken.])
1082     fi
1083   fi
1084
1085   dnl Check for PIOCSET ioctl entry
1086
1087   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1088   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1089   [AC_TRY_COMPILE([#include <unistd.h>
1090 #include <sys/types.h>
1091 #include <sys/procfs.h>
1092 ], [
1093     int dummy;;
1094     dummy = ioctl(0, PIOCSET, &dummy);
1095   ],
1096   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1097   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1098   if test $gdb_cv_have_procfs_piocset = yes; then
1099     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1100     [Define if ioctl argument PIOCSET is available.])
1101   fi
1102 fi
1103
1104 dnl For native ports (host == target), check to see what kind of
1105 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1106 if test ${host} = ${target} ; then
1107   dnl Check for struct link_map with l_ members which are indicative
1108   dnl of SVR4-like shared libraries
1109
1110   AC_MSG_CHECKING(for member l_addr in struct link_map)
1111   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1112     [AC_TRY_COMPILE([#include <link.h>],
1113                     [struct link_map lm; (void) lm.l_addr;],
1114                     gdb_cv_have_struct_link_map_with_l_members=yes,
1115                     gdb_cv_have_struct_link_map_with_l_members=no)])
1116   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1117   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1118     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1119     [Define if <link.h> exists and defines struct link_map which has
1120      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1121      SVR4-like systems.)])
1122   fi
1123
1124   dnl Check for struct link_map with lm_ members which are indicative
1125   dnl of SunOS-like shared libraries
1126
1127   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1128   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1129     [AC_TRY_COMPILE([#include <sys/types.h>
1130 #include <link.h>],
1131                     [struct link_map lm; (void) lm.lm_addr;],
1132                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1133                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1134   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1135   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1136     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1137     [Define if <link.h> exists and defines struct link_map which has
1138      members with an ``lm_'' prefix.  (For SunOS.)])
1139   fi
1140
1141   dnl Check for struct so_map with som_ members which are found on
1142   dnl some *BSD systems.
1143
1144   AC_MSG_CHECKING(for member som_addr in struct so_map)
1145   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1146     [AC_TRY_COMPILE([#include <sys/types.h>
1147 #ifdef HAVE_NLIST_H
1148 #include <nlist.h>
1149 #endif
1150 #include <link.h>],
1151                     [struct so_map lm; (void) lm.som_addr;],
1152                     gdb_cv_have_struct_so_map_with_som_members=yes,
1153                     gdb_cv_have_struct_so_map_with_som_members=no)])
1154   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1155   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1156     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1157     [Define if <link.h> exists and defines a struct so_map which has
1158      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1159   fi
1160
1161   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1162   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1163
1164   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1165   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1166     [AC_TRY_COMPILE([#define _SYSCALL32
1167 #include <sys/link.h>], [struct link_map32 l;],
1168      gdb_cv_have_struct_link_map32=yes,
1169      gdb_cv_have_struct_link_map32=no)])
1170   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1171   if test $gdb_cv_have_struct_link_map32 = yes; then
1172     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1173     [Define if <sys/link.h> has struct link_map32])
1174     AC_DEFINE(_SYSCALL32, 1,
1175     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1176   fi
1177 fi
1178
1179 # Check if the compiler supports the `long long' type.
1180
1181 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1182                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1183 [[extern long long foo;]],
1184 [[switch (foo & 2) { case 0: return 1; }]])],
1185                                   gdb_cv_c_long_long=yes,
1186                                   gdb_cv_c_long_long=no)])
1187 if test $gdb_cv_c_long_long = yes; then
1188   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1189             [Define to 1 if the compiler supports long long.])
1190 fi
1191
1192 # Check if the compiler and runtime support printing long longs.
1193
1194 AC_CACHE_CHECK([for long long support in printf],
1195                gdb_cv_printf_has_long_long,
1196                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1197 [[char buf[32];
1198   long long l = 0;
1199   l = (l << 16) + 0x0123;
1200   l = (l << 16) + 0x4567;
1201   l = (l << 16) + 0x89ab;
1202   l = (l << 16) + 0xcdef;
1203   sprintf (buf, "0x%016llx", l);
1204   return (strcmp ("0x0123456789abcdef", buf));]])],
1205                               gdb_cv_printf_has_long_long=yes,
1206                               gdb_cv_printf_has_long_long=no,
1207                               gdb_cv_printf_has_long_long=no)])
1208 if test $gdb_cv_printf_has_long_long = yes; then
1209   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1210             [Define to 1 if the "%ll" format works to print long longs.])
1211 fi
1212
1213 # Check if the compiler and runtime support printing decfloats.
1214
1215 AC_CACHE_CHECK([for decfloat support in printf],
1216                gdb_cv_printf_has_decfloat,
1217                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1218 [[char buf[64];
1219   _Decimal32 d32 = 1.2345df;
1220   _Decimal64 d64 = 1.2345dd;
1221   _Decimal128 d128 = 1.2345dl;
1222   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1223   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1224                               gdb_cv_printf_has_decfloat=yes,
1225                               gdb_cv_printf_has_decfloat=no,
1226                               gdb_cv_printf_has_decfloat=no)])
1227 if test $gdb_cv_printf_has_decfloat = yes; then
1228   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1229             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1230 fi
1231
1232 # Check if the compiler supports the `long double' type.  We can't use
1233 # AC_C_LONG_DOUBLE because that one does additional checks on the
1234 # constants defined in <float.h> that fail on some systems,
1235 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1236
1237 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1238                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1239                                   gdb_cv_c_long_double=yes,
1240                                   gdb_cv_c_long_double=no)])
1241 if test $gdb_cv_c_long_double = yes; then
1242   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1243            [Define to 1 if the compiler supports long double.])
1244 fi
1245
1246 # Check if the compiler and runtime support printing long doubles.
1247
1248 AC_CACHE_CHECK([for long double support in printf],
1249                gdb_cv_printf_has_long_double,
1250                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1251 [[char buf[16];
1252   long double f = 3.141592653;
1253   sprintf (buf, "%Lg", f);
1254   return (strncmp ("3.14159", buf, 7));]])],
1255                               gdb_cv_printf_has_long_double=yes,
1256                               gdb_cv_printf_has_long_double=no,
1257                               gdb_cv_printf_has_long_double=no)])
1258 if test $gdb_cv_printf_has_long_double = yes; then
1259   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1260             [Define to 1 if the "%Lg" format works to print long doubles.])
1261 fi
1262
1263 # Check if the compiler and runtime support scanning long doubles.
1264
1265 AC_CACHE_CHECK([for long double support in scanf],
1266                gdb_cv_scanf_has_long_double,
1267                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1268 [[#include <stdio.h>]],
1269 [[char *buf = "3.141592653";
1270   long double f = 0;
1271   sscanf (buf, "%Lg", &f);
1272   return !(f > 3.14159 && f < 3.14160);]])],
1273                               gdb_cv_scanf_has_long_double=yes,
1274                               gdb_cv_scanf_has_long_double=no,
1275                               gdb_cv_scanf_has_long_double=no)])
1276 if test $gdb_cv_scanf_has_long_double = yes; then
1277   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1278             [Define to 1 if the "%Lg" format works to scan long doubles.])
1279 fi
1280
1281 case ${host_os} in
1282 aix*)
1283   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1284     SAVE_LDFLAGS=$LDFLAGS
1285
1286     case $GCC in
1287     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1288     *) gdb_cv_bigtoc=-bbigtoc ;;
1289     esac
1290
1291     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1292     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1293     LDFLAGS="${SAVE_LDFLAGS}"
1294   ])
1295   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1296   ;;
1297 esac
1298
1299
1300 dnl For certain native configurations, we need to check whether thread
1301 dnl support can be built in or not.
1302 dnl
1303 dnl Note that we only want this if we are both native (host == target),
1304 dnl and not doing a canadian cross build (build == host).
1305
1306 if test ${build} = ${host} -a ${host} = ${target} ; then
1307    case ${host_os} in
1308    hpux*)
1309       AC_MSG_CHECKING(for HPUX/OSF thread support)
1310       if test -f /usr/include/dce/cma_config.h ; then
1311          if test "$GCC" = "yes" ; then
1312             AC_MSG_RESULT(yes)
1313             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1314             [Define if you have HPUX threads])
1315             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1316             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1317          else
1318             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1319          fi
1320       else
1321          AC_MSG_RESULT(no)
1322       fi
1323       ;;
1324    solaris*)
1325       # See if thread_db library is around for Solaris thread debugging.
1326       # Note that we must explicitly test for version 1 of the library
1327       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1328       # the same API.
1329       AC_MSG_CHECKING(for Solaris thread debugging library)
1330       if test -f /usr/lib/libthread_db.so.1 ; then
1331          AC_MSG_RESULT(yes)
1332          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1333          [Define if using Solaris thread debugging.])
1334          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1335          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1336          AC_CHECK_LIB(dl, dlopen)
1337          if test "$GCC" = "yes" ; then
1338             # The GNU linker requires the -export-dynamic option to make
1339             # all symbols visible in the dynamic symbol table.
1340             hold_ldflags=$LDFLAGS
1341             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1342             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1343             AC_TRY_LINK(, [int i;], found=yes, found=no)
1344             LDFLAGS=$hold_ldflags
1345             AC_MSG_RESULT($found)
1346             if test $found = yes; then
1347                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1348             fi
1349          fi
1350          # Sun randomly tweaked the prototypes in <proc_service.h>
1351          # at one point.
1352          AC_MSG_CHECKING(if <proc_service.h> is old)
1353          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1354             AC_TRY_COMPILE([
1355                 #include <proc_service.h>
1356                 ps_err_e ps_pdwrite
1357                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1358             ],, gdb_cv_proc_service_is_old=no,
1359                 gdb_cv_proc_service_is_old=yes)
1360          ])
1361          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1362          if test $gdb_cv_proc_service_is_old = yes; then
1363             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1364             [Define if <proc_service.h> on solaris uses int instead of
1365              size_t, and assorted other type changes.])
1366          fi
1367       else
1368          AC_MSG_RESULT(no)
1369       fi
1370       ;;
1371    aix*)
1372       AC_MSG_CHECKING(for AiX thread debugging library)
1373       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1374                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1375                                    [#ifndef PTHDB_VERSION_3
1376                                     #error
1377                                     #endif],
1378                                    gdb_cv_have_aix_thread_debug=yes,
1379                                    gdb_cv_have_aix_thread_debug=no)])
1380       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1381       if test $gdb_cv_have_aix_thread_debug = yes; then
1382          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1383          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1384          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1385       fi
1386       ;;
1387    esac
1388    AC_SUBST(CONFIG_LDFLAGS)
1389 fi
1390
1391 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1392 dnl other error codes.
1393 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1394    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1395                   gdb_cv_thread_db_h_has_td_notalloc,
1396      AC_TRY_COMPILE(
1397        [#include <thread_db.h>],
1398        [int i = TD_NOTALLOC;],
1399        gdb_cv_thread_db_h_has_td_notalloc=yes,
1400        gdb_cv_thread_db_h_has_td_notalloc=no
1401      )
1402    )
1403    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1404                   gdb_cv_thread_db_h_has_td_version,
1405      AC_TRY_COMPILE(
1406        [#include <thread_db.h>],
1407        [int i = TD_VERSION;],
1408        gdb_cv_thread_db_h_has_td_version=yes,
1409        gdb_cv_thread_db_h_has_td_version=no
1410      )
1411    )
1412    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1413                   gdb_cv_thread_db_h_has_td_notls,
1414      AC_TRY_COMPILE(
1415        [#include <thread_db.h>],
1416        [int i = TD_NOTLS;],
1417        gdb_cv_thread_db_h_has_td_notls=yes,
1418        gdb_cv_thread_db_h_has_td_notls=no
1419      )
1420    )
1421 fi
1422 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1423   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1424             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1425 fi
1426 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1427   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1428             [Define if <thread_db.h> has the TD_VERSION error code.])
1429 fi
1430 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1431   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1432             [Define if <thread_db.h> has the TD_NOTLS error code.])
1433 fi
1434
1435 dnl See if we have a sys/syscall header file that has __NR_tkill.
1436 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1437    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1438                   gdb_cv_sys_syscall_h_has_tkill,
1439      AC_TRY_COMPILE(
1440        [#include <sys/syscall.h>],
1441        [int i = __NR_tkill;],
1442        gdb_cv_sys_syscall_h_has_tkill=yes,
1443        gdb_cv_sys_syscall_h_has_tkill=no
1444      )
1445    )
1446 fi
1447 dnl See if we can issue tkill syscall.
1448 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1449   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1450 fi
1451
1452 dnl Check if we can disable the virtual address space randomization.
1453 dnl The functionality of setarch -R.
1454 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1455 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1456 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1457 #       define ADDR_NO_RANDOMIZE 0x0040000
1458 #      endif
1459        /* Test the flag could be set and stays set.  */
1460        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1461        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1462            return 1])])
1463 AC_RUN_IFELSE([PERSONALITY_TEST],
1464               [have_personality=true],
1465               [have_personality=false],
1466               [AC_LINK_IFELSE([PERSONALITY_TEST],
1467                               [have_personality=true],
1468                               [have_personality=false])])
1469 if $have_personality
1470 then
1471     AC_DEFINE([HAVE_PERSONALITY], 1,
1472               [Define if you support the personality syscall.])
1473 fi
1474
1475 dnl Handle optional features that can be enabled.
1476
1477 AC_ARG_WITH(sysroot,
1478 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1479 [
1480  case ${with_sysroot} in
1481  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1482  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1483  esac
1484
1485  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1486
1487  if test "x$prefix" = xNONE; then
1488   test_prefix=/usr/local
1489  else
1490   test_prefix=$prefix
1491  fi
1492  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1493   test_exec_prefix=$test_prefix
1494  else
1495   test_exec_prefix=$exec_prefix
1496  fi
1497  case ${TARGET_SYSTEM_ROOT} in
1498  "${test_prefix}"|"${test_prefix}/"*|\
1499  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1500  '${prefix}'|'${prefix}/'*|\
1501  '${exec_prefix}'|'${exec_prefix}/'*)
1502    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1503    TARGET_SYSTEM_ROOT_DEFINE="$t"
1504    ;;
1505  esac
1506 ], [
1507  TARGET_SYSTEM_ROOT=
1508  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1509 ])
1510 AC_SUBST(TARGET_SYSTEM_ROOT)
1511 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1512
1513 system_gdbinit=
1514 AC_ARG_WITH(system-gdbinit,
1515 [  --with-system-gdbinit=file       Automatically load a system-wide gdbinit file],
1516 [system_gdbinit=${withval}])
1517
1518 AC_DEFINE_DIR(SYSTEM_GDBINIT, system_gdbinit,
1519               [System-wide gdbinit file.])
1520
1521 if test "x$prefix" = xNONE; then
1522   test_prefix=$ac_default_prefix
1523 else
1524   test_prefix=$prefix
1525 fi
1526 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1527   test_exec_prefix=$test_prefix
1528 else
1529   test_exec_prefix=$exec_prefix
1530 fi
1531 case ${system_gdbinit} in
1532  "${test_prefix}"|"${test_prefix}/"*|\
1533  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1534  '${prefix}'|'${prefix}/'*|\
1535  '${exec_prefix}'|'${exec_prefix}/'*)
1536   AC_DEFINE(SYSTEM_GDBINIT_RELOCATABLE, 1,
1537             [Define if the system-wide gdbinit file should be relocated when GDB is moved.])
1538    ;;
1539 esac
1540
1541 AC_ARG_ENABLE(werror,
1542   [  --enable-werror    treat compile warnings as errors],
1543   [case "${enableval}" in
1544      yes | y) ERROR_ON_WARNING="yes" ;;
1545      no | n)  ERROR_ON_WARNING="no" ;;
1546      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1547    esac])
1548
1549 # Enable -Werror by default when using gcc
1550 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1551     ERROR_ON_WARNING=yes
1552 fi
1553
1554 WERROR_CFLAGS=""
1555 if test "${ERROR_ON_WARNING}" = yes ; then
1556     WERROR_CFLAGS="-Werror"
1557 fi
1558
1559 # The entries after -Wno-pointer-sign are disabled warnings which may
1560 # be enabled in the future, which can not currently be used to build
1561 # GDB.
1562 # NOTE: If you change this list, remember to update
1563 # gdb/doc/gdbint.texinfo.
1564 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1565 -Wformat-nonliteral -Wno-pointer-sign \
1566 -Wno-unused -Wno-switch -Wno-char-subscripts"
1567
1568 # Enable -Wno-format by default when using gcc on mingw since many
1569 # GCC versions complain about %I64.
1570 case "${host}" in
1571   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1572 esac
1573
1574 AC_ARG_ENABLE(build-warnings,
1575 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1576 [case "${enableval}" in
1577   yes)  ;;
1578   no)   build_warnings="-w";;
1579   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1580         build_warnings="${build_warnings} ${t}";;
1581   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1582         build_warnings="${t} ${build_warnings}";;
1583   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1584 esac
1585 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1586   echo "Setting compiler warning flags = $build_warnings" 6>&1
1587 fi])dnl
1588 AC_ARG_ENABLE(gdb-build-warnings,
1589 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1590 [case "${enableval}" in
1591   yes)  ;;
1592   no)   build_warnings="-w";;
1593   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1594         build_warnings="${build_warnings} ${t}";;
1595   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1596         build_warnings="${t} ${build_warnings}";;
1597   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1598 esac
1599 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1600   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1601 fi])dnl
1602 WARN_CFLAGS=""
1603 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1604 then
1605     AC_MSG_CHECKING(compiler warning flags)
1606     # Separate out the -Werror flag as some files just cannot be
1607     # compiled with it enabled.
1608     for w in ${build_warnings}; do
1609         case $w in
1610         -Werr*) WERROR_CFLAGS=-Werror ;;
1611         *) # Check that GCC accepts it
1612             saved_CFLAGS="$CFLAGS"
1613             CFLAGS="$CFLAGS $w"
1614             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1615             CFLAGS="$saved_CFLAGS"
1616         esac
1617     done
1618     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1619 fi
1620 AC_SUBST(WARN_CFLAGS)
1621 AC_SUBST(WERROR_CFLAGS)
1622
1623 # In the Cygwin environment, we need some additional flags.
1624 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1625 [AC_EGREP_CPP(lose, [
1626 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1627 lose
1628 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1629
1630
1631 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1632 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1633 case ${host} in
1634   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1635   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1636   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1637 esac
1638 AC_SUBST(SER_HARDWIRE)
1639
1640 # libreadline needs libuser32.a in a cygwin environment
1641 WIN32LIBS=
1642 if test x$gdb_cv_os_cygwin = xyes; then
1643     WIN32LIBS="-luser32"
1644     case "${target}" in
1645         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1646         ;;
1647     esac
1648 fi
1649
1650 # The ser-tcp.c module requires sockets.
1651 case ${host} in
1652   *mingw32*)
1653     AC_DEFINE(USE_WIN32API, 1,
1654               [Define if we should use the Windows API, instead of the
1655                POSIX API.  On Windows, we use the Windows API when
1656                building for MinGW, but the POSIX API when building
1657                for Cygwin.])
1658     WIN32LIBS="$WIN32LIBS -lws2_32"
1659     ;;
1660 esac
1661 AC_SUBST(WIN32LIBS)
1662
1663 # Add ELF support to GDB, but only if BFD includes ELF support.
1664 OLD_CFLAGS=$CFLAGS
1665 OLD_LDFLAGS=$LDFLAGS
1666 OLD_LIBS=$LIBS
1667 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1668 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1669 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1670 LIBS="-lbfd -liberty $intl $LIBS"
1671 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1672 [AC_TRY_LINK(
1673 [#include <stdlib.h>
1674 #include "bfd.h"
1675 #include "elf-bfd.h"
1676 ],
1677 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1678 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1679 if test $gdb_cv_var_elf = yes; then
1680   CONFIG_OBS="$CONFIG_OBS elfread.o"
1681   AC_DEFINE(HAVE_ELF, 1,
1682             [Define if ELF support should be included.])
1683 fi
1684 CFLAGS=$OLD_CFLAGS
1685 LDFLAGS=$OLD_LDFLAGS
1686 LIBS=$OLD_LIBS
1687
1688 # Add any host-specific objects to GDB.
1689 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1690
1691 LIBGUI="../libgui/src/libgui.a"
1692 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1693 AC_SUBST(LIBGUI)
1694 AC_SUBST(GUI_CFLAGS_X)
1695
1696 WIN32LDAPP=
1697 AC_SUBST(WIN32LIBS)
1698 AC_SUBST(WIN32LDAPP)
1699
1700 case "${host}" in
1701 *-*-cygwin* | *-*-mingw* )
1702     configdir="win"
1703     ;;
1704 *)
1705     configdir="unix"
1706     ;;
1707 esac
1708
1709 GDBTKLIBS=
1710 if test "${enable_gdbtk}" = "yes"; then
1711
1712     # Gdbtk must have an absolute path to srcdir in order to run
1713     # properly when not installed.
1714     here=`pwd`
1715     cd ${srcdir}
1716     GDBTK_SRC_DIR=`pwd`
1717     cd $here
1718
1719     SC_PATH_TCLCONFIG
1720
1721     # If $no_tk is nonempty, then we can't do Tk, and there is no
1722     # point to doing Tcl.
1723     SC_PATH_TKCONFIG
1724
1725     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1726         SC_LOAD_TCLCONFIG
1727
1728         # Check for in-tree tcl
1729         here=`pwd`
1730         cd ${srcdir}/..
1731         topdir=`pwd`
1732         cd ${here}
1733
1734         intree="no"
1735         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1736           intree="yes"
1737         fi
1738
1739         # Find Tcl private headers
1740         if test x"${intree}" = xno; then
1741           CY_AC_TCL_PRIVATE_HEADERS
1742           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1743           TCL_LIBRARY="${TCL_LIB_SPEC}"
1744           TCL_DEPS=""
1745         else
1746           # If building tcl in the same src tree, private headers
1747           # are not needed, but we need to be sure to use the right
1748           # headers library
1749           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1750           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1751           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1752         fi
1753         AC_SUBST(TCL_INCLUDE)
1754         AC_SUBST(TCL_LIBRARY)
1755         AC_SUBST(TCL_DEPS)
1756
1757         SC_LOAD_TKCONFIG
1758
1759         # Check for in-tree Tk
1760         intree="no"
1761         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1762           intree="yes"
1763         fi
1764
1765         # Find Tk private headers
1766         if test x"${intree}" = xno; then
1767           CY_AC_TK_PRIVATE_HEADERS
1768           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1769           TK_LIBRARY=${TK_LIB_SPEC}
1770           TK_DEPS=""
1771         else
1772           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1773           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1774           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1775         fi
1776         AC_SUBST(TK_INCLUDE)
1777         AC_SUBST(TK_LIBRARY)
1778         AC_SUBST(TK_DEPS)
1779         AC_SUBST(TK_XINCLUDES)
1780
1781         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1782
1783         # Include some libraries that Tcl and Tk want.
1784         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1785         # Yes, the ordering seems wrong here.  But it isn't.
1786         # TK_LIBS is the list of libraries that need to be linked
1787         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1788         # were in LIBS then any link tests after this point would
1789         # try to include things like `$(LIBGUI)', which wouldn't work.
1790         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1791
1792         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1793         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1794         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1795         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1796         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1797         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1798         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1799
1800         if test x$gdb_cv_os_cygwin = xyes; then
1801           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1802           WIN32LDAPP="-Wl,--subsystem,console"
1803           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1804         fi
1805
1806         AC_CONFIG_SUBDIRS(gdbtk)
1807     fi
1808 fi
1809
1810 AC_SUBST(X_CFLAGS)
1811 AC_SUBST(X_LDFLAGS)
1812 AC_SUBST(X_LIBS)
1813 AC_SUBST(GDBTKLIBS)
1814 AC_SUBST(GDBTK_CFLAGS)
1815 AC_SUBST(GDBTK_SRC_DIR)
1816
1817 AC_PATH_X
1818
1819 # Unlike the sim directory, whether a simulator is linked is controlled by
1820 # presence of a gdb_sim definition in the target configure.tgt entry.
1821 # This code just checks for a few cases where we'd like to ignore those
1822 # definitions, even when they're present in the '.mt' file.  These cases
1823 # are when --disable-sim is specified, or if the simulator directory is
1824 # not part of the source tree.
1825 #
1826 AC_ARG_ENABLE(sim,
1827 [  --enable-sim            Link gdb with simulator],
1828 [echo "enable_sim = $enable_sim";
1829  echo "enableval = ${enableval}";
1830  case "${enableval}" in
1831   yes) ignore_sim=false ;;
1832   no)  ignore_sim=true ;;
1833   *)   ignore_sim=false ;;
1834  esac],
1835 [ignore_sim=false])
1836
1837 if test ! -d "${srcdir}/../sim"; then
1838   ignore_sim=true
1839 fi
1840
1841 SIM=
1842 SIM_OBS=
1843 if test "${ignore_sim}" = "false"; then
1844   if test x"${gdb_sim}" != x ; then
1845     SIM="${gdb_sim}"
1846     SIM_OBS="remote-sim.o"
1847     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1848   fi
1849 fi
1850 AC_SUBST(SIM)
1851 AC_SUBST(SIM_OBS)
1852
1853 AC_SUBST(ENABLE_CFLAGS)
1854 AC_SUBST(PROFILE_CFLAGS)
1855
1856 AC_SUBST(CONFIG_OBS)
1857 AC_SUBST(CONFIG_DEPS)
1858 AC_SUBST(CONFIG_SRCS)
1859 AC_SUBST(CONFIG_ALL)
1860 AC_SUBST(CONFIG_CLEAN)
1861 AC_SUBST(CONFIG_INSTALL)
1862 AC_SUBST(CONFIG_UNINSTALL)
1863
1864 # List of host floatformats.
1865 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1866 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1867 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1868
1869 # target_subdir is used by the testsuite to find the target libraries.
1870 target_subdir=
1871 if test "${host}" != "${target}"; then
1872     target_subdir="${target_alias}/"
1873 fi
1874 AC_SUBST(target_subdir)
1875
1876 frags=
1877 if test "${gdb_native}" = "yes"; then
1878   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1879   if test ! -f ${host_makefile_frag}; then
1880     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1881   fi
1882   frags="$frags $host_makefile_frag"
1883 else
1884   host_makefile_frag=/dev/null
1885 fi
1886
1887 AC_SUBST_FILE(host_makefile_frag)
1888 AC_SUBST(frags)
1889
1890 changequote(,)dnl
1891 if test "${gdb_native}" = "yes"; then
1892 # We pick this up from the host configuration file (.mh) because we
1893 # do not have a native configuration Makefile fragment.
1894 nativefile=`sed -n '
1895 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1896 ' ${host_makefile_frag}`
1897 fi
1898 changequote([,])
1899
1900 if test x"${gdb_osabi}" != x ; then
1901     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1902                        [Define to the default OS ABI for this configuration.])
1903 fi
1904
1905 # Enable multi-ice-gdb-server.
1906 AC_ARG_ENABLE(multi-ice,
1907 [  --enable-multi-ice      build the multi-ice-gdb-server],
1908   [case $enableval in
1909     yes | no)
1910       ;;
1911     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1912   esac])
1913 if test "x$enable_multi_ice" = xyes; then
1914    AC_CONFIG_SUBDIRS(multi-ice)
1915 fi
1916
1917 # We only build gdbserver automatically in a native configuration.
1918 if test "$gdb_native" = "yes"; then
1919   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1920   if test "x$build_gdbserver" = xyes; then
1921     AC_MSG_RESULT(yes)
1922     AC_CONFIG_SUBDIRS(gdbserver)
1923   else
1924     AC_MSG_RESULT(no)
1925   fi
1926 fi
1927
1928 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1929 # to an empty version.
1930
1931 files=
1932 links=
1933
1934 rm -f nm.h
1935 nm_h=""
1936 if test "${nativefile}" != ""; then
1937     nm_h=nm.h
1938     case "${nativefile}" in
1939       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1940       * ) GDB_NM_FILE="${nativefile}"
1941     esac
1942     files="${files} ${GDB_NM_FILE}"
1943     links="${links} nm.h"
1944     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1945 fi
1946 AC_SUBST(nm_h)
1947
1948 AC_LINK_FILES($files, $links)
1949
1950 dnl Check for exe extension set on certain hosts (e.g. Win32)
1951 AC_EXEEXT
1952
1953 dnl  Detect the character set used by this host.
1954 dnl  At the moment, we just assume it's UTF-8.
1955 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
1956           [Define to be a string naming the default host character set.])
1957
1958 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1959 [
1960 dnl Autoconf doesn't provide a mechanism for modifying definitions
1961 dnl provided by makefile fragments.
1962 dnl
1963
1964 changequote(,)dnl
1965 sed -e '/^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1966 mv -f Makefile.tmp Makefile
1967 changequote([,])dnl
1968
1969
1970 case x$CONFIG_HEADERS in
1971 xconfig.h:config.in)
1972 echo > stamp-h ;;
1973 esac
1974 ],
1975 [
1976 gdb_host_cpu=$gdb_host_cpu
1977 nativefile=$nativefile
1978 ])
1979
1980 exit 0