gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_LIB_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 CONFIG_INITS=
  67 ENABLE_CFLAGS=
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 AC_CONFIG_SUBDIRS(doc testsuite)
  74 configdirs=
  75
  76 . $srcdir/configure.host
  77
  78 . $srcdir/configure.tgt
  79
  80 # Fetch the default architecture and default target vector from BFD.
  81 targ=$target; . $srcdir/../bfd/config.bfd
  82
  83 # We only want the first architecture, so strip off the others if
  84 # there is more than one.
  85 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  86
  87 if test "x$targ_archs" != x; then
  88   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  89     [Define to BFD's default architecture. ])
  90 fi
  91 if test "x$targ_defvec" != x; then
  92   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  93     [Define to BFD's default target vector. ])
  94 fi
  95
  96 AC_ARG_PROGRAM
  97
  98 # The CLI cannot be disabled yet, but may be in the future.
  99
 100 # Enable CLI.
 101 AC_ARG_ENABLE(gdbcli,
 102 [  --disable-gdbcli        disable command-line interface (CLI)],
 103   [case $enableval in
 104     yes)
 105       ;;
 106     no)
 107       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 108     *)
 109       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 110   esac],
 111   [enable_gdbcli=yes])
 112 if test x"$enable_gdbcli" = xyes; then
 113   if test -d $srcdir/cli; then
 114     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 115     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 116     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 117     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_CLI_INITS)"
 118     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 119     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_CLI_ALL)"
 120     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_CLI_CLEAN)"
 121     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_CLI_INSTALL)"
 122     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_CLI_UNINSTALL)"
 123   fi
 124 fi
 125
 126 # Enable MI.
 127 AC_ARG_ENABLE(gdbmi,
 128 [  --disable-gdbmi         disable machine-interface (MI)],
 129   [case $enableval in
 130     yes | no)
 131       ;;
 132     *)
 133       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 134   esac],
 135   [enable_gdbmi=yes])
 136 if test x"$enable_gdbmi" = xyes; then
 137   if test -d $srcdir/mi; then
 138     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 139     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 140     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 141     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_MI_INITS)"
 142     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 143     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_MI_ALL)"
 144     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_MI_CLEAN)"
 145     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_MI_INSTALL)"
 146     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_MI_UNINSTALL)"
 147   fi
 148 fi
 149
 150 # Enable TUI.
 151 AC_ARG_ENABLE(tui,
 152 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 153   [case $enableval in
 154     yes | no)
 155       ;;
 156     *)
 157       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 158   esac])
 159 if test x"$enable_tui" = xyes; then
 160   if test -d $srcdir/tui; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 164     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 165     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 166     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_TUI_ALL)"
 167     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_TUI_CLEAN)"
 168     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_TUI_INSTALL)"
 169     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_TUI_UNINSTALL)"
 170     need_curses=yes
 171   fi
 172 fi
 173
 174 # Enable gdbtk.
 175 AC_ARG_ENABLE(gdbtk,
 176 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 177   [case $enableval in
 178     yes | no)
 179       ;;
 180     *)
 181       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 182   esac],
 183   [if test -d $srcdir/gdbtk; then
 184     enable_gdbtk=yes
 185   else
 186     enable_gdbtk=no
 187   fi])
 188 # We unconditionally disable gdbtk tests on selected platforms.
 189 case $host_os in
 190   go32* | windows*)
 191     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 192     enable_gdbtk=no ;;
 193 esac
 194
 195 # Libunwind support.
 196 AC_ARG_WITH(libunwind,
 197 [  --with-libunwind            Use libunwind frame unwinding support],
 198 [case "${withval}" in
 199   yes)  enable_libunwind=yes ;;
 200   no)   enable_libunwind=no ;;
 201   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 202 esac],[
 203   AC_CHECK_HEADERS(libunwind.h)
 204   AC_CHECK_HEADERS(libunwind-ia64.h)
 205   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 206     enable_libunwind=yes;
 207   fi
 208 ])
 209
 210 if test x"$enable_libunwind" = xyes; then
 211   AC_CHECK_HEADERS(libunwind.h)
 212   AC_CHECK_HEADERS(libunwind-ia64.h)
 213   AC_DEFINE(HAVE_LIBUNWIND, 1)
 214   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 215   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 216   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 217 fi
 218
 219 # Profiling support.
 220 AC_ARG_ENABLE(profiling,
 221 [  --enable-profiling      enable profiling of GDB],
 222   [case $enableval in
 223     yes | no)
 224       ;;
 225     *)
 226       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 227   esac],
 228  [enable_profiling=no])
 229
 230 AC_CHECK_FUNCS(monstartup _mcleanup)
 231 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 232 [AC_TRY_LINK(
 233 [#include <stdlib.h>
 234 extern char _etext;
 235 ],
 236 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 237 if test $ac_cv_var__etext = yes; then
 238   AC_DEFINE(HAVE__ETEXT, 1,
 239             [Define to 1 if your system has the _etext variable. ])
 240 fi
 241 if test "$enable_profiling" = yes ; then
 242   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 243     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 244   fi
 245   PROFILE_CFLAGS=-pg
 246   OLD_CFLAGS="$CFLAGS"
 247   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 248
 249   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 250     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 251      ac_cv_cc_supports_pg=no)])
 252
 253   if test $ac_cv_cc_supports_pg = no; then
 254     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 255   fi
 256
 257   CFLAGS="$OLD_CFLAGS"
 258 fi
 259
 260 # --------------------- #
 261 # Checks for programs.  #
 262 # --------------------- #
 263
 264 AC_PROG_AWK
 265 AC_PROG_INSTALL
 266 AC_PROG_LN_S
 267 AC_PROG_RANLIB
 268 AC_PROG_YACC
 269
 270 AC_CHECK_TOOL(AR, ar)
 271 AC_CHECK_TOOL(DLLTOOL, dlltool)
 272 AC_CHECK_TOOL(WINDRES, windres)
 273
 274 # Needed for GNU/Hurd.
 275 AC_CHECK_TOOL(MIG, mig)
 276
 277 # ---------------------- #
 278 # Checks for libraries.  #
 279 # ---------------------- #
 280
 281 # We might need to link with -lm; most simulators need it.
 282 AC_CHECK_LIB(m, main)
 283
 284 # We need to link with -lw to get `wctype' on Solaris before Solaris
 285 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 286 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 287 # is known to have this problem).  Therefore we avoid libw if we can.
 288 AC_CHECK_FUNC(wctype, [],
 289   [AC_CHECK_LIB(w, wctype)])
 290
 291 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 292 AC_SEARCH_LIBS(gethostbyname, nsl)
 293
 294 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 295 AC_SEARCH_LIBS(socketpair, socket)
 296
 297 # Since GDB uses Readline, we need termcap functionality, so we need
 298 # to find a library that provides that.  When GDB is configured with
 299 # --enable-tui, we need full curses functionality.
 300 #
 301 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 302 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 303 # Makefile fragments.  That's why we need to have `Hcurses' before
 304 # `curses'.  I don't see why we should use HP curses if a more
 305 # standard curses is available, except that according to HP's
 306 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 307 # HP-UX 10.10 and 10.20.
 308
 309 if test "$need_curses" = yes; then
 310   AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses], [],
 311     [AC_MSG_ERROR([no curses library found])])
 312 fi
 313
 314 case $host_os in
 315   cygwin*)
 316     if test -d $srcdir/libtermcap; then
 317       LIBS="../libtermcap/libtermcap.a $LIBS"
 318       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 319     fi ;;
 320   go32*)
 321     # ??? Is this really true?
 322     ac_cv_search_tgetent="none required"
 323     ;;
 324   aix*)
 325     # Readline prefers curses over termcap on AIX.
 326     # ??? Why?
 327     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 328     ;;
 329 esac
 330
 331 # Note: We used to check for libtermlib and libterminfo too, but
 332 # Readline doesn't, so I think we're safe with leaving them out.
 333 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 334
 335 if test "$ac_cv_search_tgetent" = no; then
 336   AC_MSG_ERROR([no termcap library found])
 337 fi
 338
 339 # ------------------------- #
 340 # Checks for header files.  #
 341 # ------------------------- #
 342
 343 AC_HEADER_DIRENT
 344 AC_HEADER_STAT
 345 AC_HEADER_STDC
 346 AC_CHECK_HEADERS(link.h)
 347 AC_CHECK_HEADERS(nlist.h)
 348 AC_CHECK_HEADERS(poll.h sys/poll.h)
 349 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 350 AC_CHECK_HEADERS(stddef.h)
 351 AC_CHECK_HEADERS(stdlib.h)
 352 AC_CHECK_HEADERS(stdint.h)
 353 AC_CHECK_HEADERS(string.h memory.h strings.h)
 354 AC_CHECK_HEADERS(sys/fault.h)
 355 AC_CHECK_HEADERS(sys/file.h)
 356 AC_CHECK_HEADERS(sys/filio.h)
 357 AC_CHECK_HEADERS(sys/ioctl.h)
 358 AC_CHECK_HEADERS(sys/param.h)
 359 AC_CHECK_HEADERS(sys/proc.h)
 360 AC_CHECK_HEADERS(sys/procfs.h)
 361 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 362 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 363 AC_CHECK_HEADERS(sys/select.h)
 364 AC_CHECK_HEADERS(sys/syscall.h)
 365 AC_CHECK_HEADERS(sys/user.h)
 366 AC_CHECK_HEADERS(sys/wait.h wait.h)
 367 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 368 AC_CHECK_HEADERS(unistd.h)
 369
 370 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 371 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 372 # think that we don't have <curses.h> if we're using GCC.
 373 case $host_os in
 374   solaris2.[[78]])
 375     if test "$GCC" = yes; then
 376       AC_DEFINE(_MSE_INT_H, 1,
 377         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 378    Solaris 2.[78] when using GCC. ]])
 379     fi ;;
 380 esac
 381 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 382
 383 # FIXME: kettenis/20030102: In most cases we include these
 384 # unconditionally, so what's the point in checking these?
 385 AC_CHECK_HEADERS(ctype.h time.h)
 386
 387 # ------------------------- #
 388 # Checks for declarations.  #
 389 # ------------------------- #
 390
 391 gcc_AC_CHECK_DECLS(getopt)
 392
 393 # ------------------ #
 394 # Checks for types.  #
 395 # ------------------ #
 396
 397 AC_TYPE_SIGNAL
 398
 399 # ------------------------------------- #
 400 # Checks for compiler characteristics.  #
 401 # ------------------------------------- #
 402
 403 AC_C_CONST
 404 AC_C_INLINE
 405
 406 # ------------------------------ #
 407 # Checks for library functions.  #
 408 # ------------------------------ #
 409
 410 AC_FUNC_ALLOCA
 411 AC_FUNC_MMAP
 412 AC_FUNC_VFORK
 413 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 414 AC_CHECK_FUNCS(poll)
 415 AC_CHECK_FUNCS(pread64)
 416 AC_CHECK_FUNCS(sbrk)
 417 AC_CHECK_FUNCS(setpgid setpgrp)
 418 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 419 AC_CHECK_FUNCS(socketpair)
 420 AC_CHECK_FUNCS(syscall)
 421
 422 dnl AC_FUNC_SETPGRP does not work when cross compiling
 423 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 424 if test "$cross_compiling" = no; then
 425   AC_FUNC_SETPGRP
 426 else
 427   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 428     [AC_TRY_COMPILE([
 429 #include <unistd.h>
 430 ], [
 431   if (setpgrp(1,1) == -1)
 432     exit (0);
 433   else
 434     exit (1);
 435 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 436 if test $ac_cv_func_setpgrp_void = yes; then
 437   AC_DEFINE(SETPGRP_VOID, 1)
 438 fi
 439 fi
 440
 441 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 442 # since sigsetjmp might only be defined as a macro.
 443 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 444 [AC_TRY_COMPILE([
 445 #include <setjmp.h>
 446 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 447 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 448 if test $gdb_cv_func_sigsetjmp = yes; then
 449   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 450 fi
 451
 452 # Assume we'll default to using the included libiberty regex.
 453 gdb_use_included_regex=yes
 454
 455 # However, if the system regex is GNU regex, then default to *not*
 456 # using the included regex.
 457 AC_CACHE_CHECK(
 458   [for GNU regex],
 459   [gdb_cv_have_gnu_regex],
 460   [AC_TRY_COMPILE(
 461     [#include <gnu-versions.h>],
 462     [#define REGEX_INTERFACE_VERSION 1
 463 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 464 # error "Version mismatch"
 465 #endif],
 466     gdb_cv_have_gnu_regex=yes,
 467     gdb_cv_have_gnu_regex=no)])
 468 if test $gdb_cv_have_gnu_regex = yes; then
 469   gdb_use_included_regex=no
 470 fi
 471
 472 AC_ARG_WITH(included-regex,
 473   [  --without-included-regex don't use included regex; this is the default
 474                           on systems with version 2 of the GNU C library
 475                           (use with caution on other system)],
 476   gdb_with_regex=$withval,
 477   gdb_with_regex=$gdb_use_included_regex)
 478 if test "$gdb_with_regex" = yes; then
 479   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 480     [Define to 1 if the regex included in libiberty should be used.])
 481 fi
 482
 483 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 484 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 485 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 486 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 487 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 488 if test $gdb_cv_struct_reg_r_fs = yes; then
 489   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 490 fi
 491 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 492 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 493 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 494 if test $gdb_cv_struct_reg_r_gs = yes; then
 495   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 496 fi
 497
 498 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 499 AC_MSG_CHECKING(for PTRACE_GETREGS)
 500 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 501 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 502                 [PTRACE_GETREGS;],
 503                 [gdb_cv_have_ptrace_getregs=yes],
 504                 [gdb_cv_have_ptrace_getregs=no])])
 505 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 506 if test $gdb_cv_have_ptrace_getregs = yes; then
 507   AC_DEFINE(HAVE_PTRACE_GETREGS)
 508 fi
 509
 510 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 511 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 512 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 513 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 514                 [PTRACE_GETFPXREGS;],
 515                 [gdb_cv_have_ptrace_getfpxregs=yes],
 516                 [gdb_cv_have_ptrace_getfpxregs=no])])
 517 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 518 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 519   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 520 fi
 521
 522 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 523 AC_MSG_CHECKING(for PT_GETDBREGS)
 524 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 525 [AC_TRY_COMPILE([#include <sys/types.h>
 526 #include <sys/ptrace.h>],
 527                 [PT_GETDBREGS;],
 528                 [gdb_cv_have_pt_getdbregs=yes],
 529                 [gdb_cv_have_pt_getdbregs=no])])
 530 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 531 if test $gdb_cv_have_pt_getdbregs = yes; then
 532   AC_DEFINE(HAVE_PT_GETDBREGS)
 533 fi
 534
 535 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 536 AC_MSG_CHECKING(for PT_GETXMMREGS)
 537 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 538 [AC_TRY_COMPILE([#include <sys/types.h>
 539 #include <sys/ptrace.h>],
 540                 [PT_GETXMMREGS;],
 541                 [gdb_cv_have_pt_getxmmregs=yes],
 542                 [gdb_cv_have_pt_getxmmregs=no])])
 543 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 544 if test $gdb_cv_have_pt_getxmmregs = yes; then
 545   AC_DEFINE(HAVE_PT_GETXMMREGS)
 546 fi
 547
 548 # See if stdint.h provides the uintptr_t type.
 549 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 550 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 551   [AC_TRY_COMPILE(
 552     [#include <stdint.h>],
 553     [uintptr_t foo = 0;],
 554     gdb_cv_have_uintptr_t=yes,
 555     gdb_cv_have_uintptr_t=no)])
 556 if test $gdb_cv_have_uintptr_t = yes; then
 557   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 558 fi
 559
 560 BFD_NEED_DECLARATION(malloc)
 561 BFD_NEED_DECLARATION(realloc)
 562 BFD_NEED_DECLARATION(free)
 563 BFD_NEED_DECLARATION(strerror)
 564 BFD_NEED_DECLARATION(strdup)
 565 BFD_NEED_DECLARATION(strstr)
 566 BFD_NEED_DECLARATION(canonicalize_file_name)
 567
 568 # The following save_state_t checkery is only necessary for HPUX
 569 # versions earlier than 10.20.  When those fade from memory, this
 570 # could be expunged. --jsm 1999-03-22
 571
 572 AC_MSG_CHECKING(for HPUX save_state structure)
 573 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 574                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 575 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 576                 gdb_cv_hpux_sswide=no)
 577 if test $gdb_cv_hpux_savestate = yes
 578 then
 579   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 580 fi
 581 if test $gdb_cv_hpux_sswide = yes
 582 then
 583   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 584 fi
 585 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 586
 587
 588 # If we are configured native on GNU/Linux, work around problems with
 589 # sys/procfs.h
 590 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 591
 592 if test "${target}" = "${host}"; then
 593   case "${host}" in
 594   i[[3456]]86-*-linux*)
 595         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 596         AC_DEFINE(sys_quotactl)
 597         ;;
 598   ia64-*-aix*)
 599       AC_DEFINE(NEW_PROC_API)
 600       ;;
 601   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 602       AC_DEFINE(NEW_PROC_API)
 603       ;;
 604   *-*-solaris2.[[678]])
 605       AC_DEFINE(NEW_PROC_API)
 606       ;;
 607   esac
 608 fi
 609
 610 if test "$ac_cv_header_sys_procfs_h" = yes; then
 611   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 612   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 613   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 614   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 615   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 616   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 617   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 618   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 619   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 620   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 621   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 622   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 623   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 624   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 625
 626
 627   dnl Check for broken prfpregset_t type
 628
 629   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 630   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 631   dnl instead of the struct itself).  We detect this here, and work
 632   dnl around it in gdb_proc_service.h.
 633
 634   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 635     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 636     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 637       [AC_TRY_RUN([#include <sys/procfs.h>
 638        int main ()
 639        {
 640          if (sizeof (prfpregset_t) == sizeof (void *))
 641            return 1;
 642          return 0;
 643        }],
 644        gdb_cv_prfpregset_t_broken=no,
 645        gdb_cv_prfpregset_t_broken=yes,
 646        gdb_cv_prfpregset_t_broken=yes)])
 647     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 648     if test $gdb_cv_prfpregset_t_broken = yes; then
 649       AC_DEFINE(PRFPREGSET_T_BROKEN)
 650     fi
 651   fi
 652
 653   dnl Check for PIOCSET ioctl entry
 654
 655   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 656   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 657   [AC_TRY_COMPILE([#include <unistd.h>
 658 #include <sys/types.h>
 659 #include <sys/procfs.h>
 660 ], [
 661     int dummy;;
 662     dummy = ioctl(0, PIOCSET, &dummy);
 663   ],
 664   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 665   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 666   if test $gdb_cv_have_procfs_piocset = yes; then
 667     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 668   fi
 669 fi
 670
 671 dnl For native ports (host == target), check to see what kind of
 672 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 673 if test ${host} = ${target} ; then
 674   dnl Check for struct link_map with l_ members which are indicative
 675   dnl of SVR4-like shared libraries
 676
 677   AC_MSG_CHECKING(for member l_addr in struct link_map)
 678   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 679     [AC_TRY_COMPILE([#include <link.h>],
 680                     [struct link_map lm; (void) lm.l_addr;],
 681                     gdb_cv_have_struct_link_map_with_l_members=yes,
 682                     gdb_cv_have_struct_link_map_with_l_members=no)])
 683   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 684   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 685     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 686   fi
 687
 688   dnl Check for struct link_map with lm_ members which are indicative
 689   dnl of SunOS-like shared libraries
 690
 691   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 692   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 693     [AC_TRY_COMPILE([#include <sys/types.h>
 694 #include <link.h>],
 695                     [struct link_map lm; (void) lm.lm_addr;],
 696                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 697                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 698   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 699   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 700     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 701   fi
 702
 703   dnl Check for struct so_map with som_ members which are found on
 704   dnl some *BSD systems.
 705
 706   AC_MSG_CHECKING(for member som_addr in struct so_map)
 707   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 708     [AC_TRY_COMPILE([#include <sys/types.h>
 709 #ifdef HAVE_NLIST_H
 710 #include <nlist.h>
 711 #endif
 712 #include <link.h>],
 713                     [struct so_map lm; (void) lm.som_addr;],
 714                     gdb_cv_have_struct_so_map_with_som_members=yes,
 715                     gdb_cv_have_struct_so_map_with_som_members=no)])
 716   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 717   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 718     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 719   fi
 720
 721   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 722   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 723
 724   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 725   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 726     [AC_TRY_COMPILE([#define _SYSCALL32
 727 #include <sys/link.h>], [struct link_map32 l;],
 728      gdb_cv_have_struct_link_map32=yes,
 729      gdb_cv_have_struct_link_map32=no)])
 730   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 731   if test $gdb_cv_have_struct_link_map32 = yes; then
 732     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 733     AC_DEFINE(_SYSCALL32)
 734   fi
 735 fi
 736
 737 dnl See if compiler supports "long long" type.
 738
 739 AC_MSG_CHECKING(for long long support in compiler)
 740 AC_CACHE_VAL(gdb_cv_c_long_long,
 741 [AC_TRY_COMPILE(, [
 742   extern long long foo;
 743   switch (foo & 2) { case 0: return 1; }
 744 ],
 745 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 746 AC_MSG_RESULT($gdb_cv_c_long_long)
 747 if test $gdb_cv_c_long_long = yes; then
 748   AC_DEFINE(CC_HAS_LONG_LONG)
 749 fi
 750
 751 dnl See if the compiler and runtime support printing long long
 752
 753 AC_MSG_CHECKING(for long long support in printf)
 754 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 755 [AC_TRY_RUN([
 756 int main () {
 757   char buf[32];
 758   long long l = 0;
 759   l = (l << 16) + 0x0123;
 760   l = (l << 16) + 0x4567;
 761   l = (l << 16) + 0x89ab;
 762   l = (l << 16) + 0xcdef;
 763   sprintf (buf, "0x%016llx", l);
 764   return (strcmp ("0x0123456789abcdef", buf));
 765 }],
 766 gdb_cv_printf_has_long_long=yes,
 767 gdb_cv_printf_has_long_long=no,
 768 gdb_cv_printf_has_long_long=no)])
 769 if test $gdb_cv_printf_has_long_long = yes; then
 770   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 771 fi
 772 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 773
 774 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 775 dnl because autoconf complains about cross-compilation issues.  However, this
 776 dnl code uses the same variables as the macro for compatibility.
 777
 778 AC_MSG_CHECKING(for long double support in compiler)
 779 AC_CACHE_VAL(ac_cv_c_long_double,
 780 [AC_TRY_COMPILE(, [long double foo;],
 781 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 782 AC_MSG_RESULT($ac_cv_c_long_double)
 783 if test $ac_cv_c_long_double = yes; then
 784   AC_DEFINE(HAVE_LONG_DOUBLE)
 785 fi
 786
 787 dnl See if the compiler and runtime support printing long doubles
 788
 789 AC_MSG_CHECKING(for long double support in printf)
 790 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 791 [AC_TRY_RUN([
 792 int main () {
 793   char buf[16];
 794   long double f = 3.141592653;
 795   sprintf (buf, "%Lg", f);
 796   return (strncmp ("3.14159", buf, 7));
 797 }],
 798 gdb_cv_printf_has_long_double=yes,
 799 gdb_cv_printf_has_long_double=no,
 800 gdb_cv_printf_has_long_double=no)])
 801 if test $gdb_cv_printf_has_long_double = yes; then
 802   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 803 fi
 804 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 805
 806 dnl See if the compiler and runtime support scanning long doubles
 807
 808 AC_MSG_CHECKING(for long double support in scanf)
 809 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 810 [AC_TRY_RUN([
 811 int main () {
 812   char *buf = "3.141592653";
 813   long double f = 0;
 814   sscanf (buf, "%Lg", &f);
 815   return !(f > 3.14159 && f < 3.14160);
 816 }],
 817 gdb_cv_scanf_has_long_double=yes,
 818 gdb_cv_scanf_has_long_double=no,
 819 gdb_cv_scanf_has_long_double=no)])
 820 if test $gdb_cv_scanf_has_long_double = yes; then
 821   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 822 fi
 823 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 824
 825 case ${host_os} in
 826 aix*)
 827   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 828     SAVE_LDFLAGS=$LDFLAGS
 829
 830     case $GCC in
 831     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 832     *) gdb_cv_bigtoc=-bbigtoc ;;
 833     esac
 834
 835     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 836     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 837   ])
 838   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 839   ;;
 840 esac
 841
 842
 843 dnl For certain native configurations, we need to check whether thread
 844 dnl support can be built in or not.
 845 dnl
 846 dnl Note that we only want this if we are both native (host == target),
 847 dnl and not doing a canadian cross build (build == host).
 848
 849 if test ${build} = ${host} -a ${host} = ${target} ; then
 850    case ${host_os} in
 851    hpux*)
 852       AC_MSG_CHECKING(for HPUX/OSF thread support)
 853       if test -f /usr/include/dce/cma_config.h ; then
 854          if test "$GCC" = "yes" ; then
 855             AC_MSG_RESULT(yes)
 856             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 857             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 858             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 859          else
 860             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 861          fi
 862       else
 863          AC_MSG_RESULT(no)
 864       fi
 865       ;;
 866    solaris*)
 867       # See if thread_db library is around for Solaris thread debugging.
 868       # Note that we must explicitly test for version 1 of the library
 869       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 870       # the same API.
 871       AC_MSG_CHECKING(for Solaris thread debugging library)
 872       if test -f /usr/lib/libthread_db.so.1 ; then
 873          AC_MSG_RESULT(yes)
 874          AC_DEFINE(HAVE_THREAD_DB_LIB)
 875          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 876          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 877          AC_CHECK_LIB(dl, dlopen)
 878          if test "$GCC" = "yes" ; then
 879             # The GNU linker requires the -export-dynamic option to make
 880             # all symbols visible in the dynamic symbol table.
 881             hold_ldflags=$LDFLAGS
 882             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 883             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 884             AC_TRY_LINK(, [int i;], found=yes, found=no)
 885             LDFLAGS=$hold_ldflags
 886             AC_MSG_RESULT($found)
 887             if test $found = yes; then
 888                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 889             fi
 890          fi
 891          # Sun randomly tweaked the prototypes in <proc_service.h>
 892          # at one point.
 893          AC_MSG_CHECKING(if <proc_service.h> is old)
 894          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 895             AC_TRY_COMPILE([
 896                 #include <proc_service.h>
 897                 ps_err_e ps_pdwrite
 898                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 899             ],, gdb_cv_proc_service_is_old=no,
 900                 gdb_cv_proc_service_is_old=yes)
 901          ])
 902          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 903          if test $gdb_cv_proc_service_is_old = yes; then
 904             AC_DEFINE(PROC_SERVICE_IS_OLD)
 905          fi
 906       else
 907          AC_MSG_RESULT(no)
 908       fi
 909       ;;
 910    aix*)
 911       AC_MSG_CHECKING(for AiX thread debugging library)
 912       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 913                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 914                                    [#ifndef PTHDB_VERSION_3
 915                                     #error
 916                                     #endif],
 917                                    gdb_cv_have_aix_thread_debug=yes,
 918                                    gdb_cv_have_aix_thread_debug=no)])
 919       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 920       if test $gdb_cv_have_aix_thread_debug = yes; then
 921          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 922          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
 923          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 924       fi
 925       ;;
 926    esac
 927    AC_SUBST(CONFIG_LDFLAGS)
 928 fi
 929
 930 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 931 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 932    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 933                   gdb_cv_thread_db_h_has_td_notalloc,
 934      AC_TRY_COMPILE(
 935        [#include <thread_db.h>],
 936        [int i = TD_NOTALLOC;],
 937        gdb_cv_thread_db_h_has_td_notalloc=yes,
 938        gdb_cv_thread_db_h_has_td_notalloc=no
 939      )
 940    )
 941 fi
 942 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 943   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 944             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 945 fi
 946
 947 dnl See if we have a sys/syscall header file that has __NR_tkill.
 948 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 949    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 950                   gdb_cv_sys_syscall_h_has_tkill,
 951      AC_TRY_COMPILE(
 952        [#include <sys/syscall.h>],
 953        [int i = __NR_tkill;],
 954        gdb_cv_sys_syscall_h_has_tkill=yes,
 955        gdb_cv_sys_syscall_h_has_tkill=no
 956      )
 957    )
 958 fi
 959 dnl See if we can issue tkill syscall.
 960 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 961   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 962             [Define if we can use the tkill syscall.])
 963 fi
 964
 965 dnl Handle optional features that can be enabled.
 966
 967 AC_ARG_WITH(sysroot,
 968 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 969 [
 970  case ${with_sysroot} in
 971  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 972  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 973  esac
 974
 975  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 976
 977  if test "x$exec_prefix" = xNONE; then
 978   if test "x$prefix" = xNONE; then
 979    test_prefix=/usr/local
 980   else
 981    test_prefix=$prefix
 982   fi
 983  else
 984   test_prefix=$exec_prefix
 985  fi
 986  case ${TARGET_SYSTEM_ROOT} in
 987  "${test_prefix}"|"${test_prefix}/"*|\
 988  '${exec_prefix}'|'${exec_prefix}/'*)
 989    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 990    TARGET_SYSTEM_ROOT_DEFINE="$t"
 991    ;;
 992  esac
 993 ], [
 994  TARGET_SYSTEM_ROOT=
 995  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
 996 ])
 997 AC_SUBST(TARGET_SYSTEM_ROOT)
 998 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 999
1000 # NOTE: Don't add -Wall or -Wunused, they both include
1001 # -Wunused-parameter which reports bogus warnings.
1002 # NOTE: If you add to this list, remember to update
1003 # gdb/doc/gdbint.texinfo.
1004 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1005 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral"
1006 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1007 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
1008 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1009 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1010 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1011 # -Woverloaded-virtual -Winline -Werror"
1012 AC_ARG_ENABLE(build-warnings,
1013 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1014 [case "${enableval}" in
1015   yes)  ;;
1016   no)   build_warnings="-w";;
1017   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1018         build_warnings="${build_warnings} ${t}";;
1019   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1020         build_warnings="${t} ${build_warnings}";;
1021   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1022 esac
1023 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1024   echo "Setting compiler warning flags = $build_warnings" 6>&1
1025 fi])dnl
1026 AC_ARG_ENABLE(gdb-build-warnings,
1027 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1028 [case "${enableval}" in
1029   yes)  ;;
1030   no)   build_warnings="-w";;
1031   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1032         build_warnings="${build_warnings} ${t}";;
1033   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1034         build_warnings="${t} ${build_warnings}";;
1035   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1036 esac
1037 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1038   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1039 fi])dnl
1040 WARN_CFLAGS=""
1041 WERROR_CFLAGS=""
1042 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1043 then
1044     AC_MSG_CHECKING(compiler warning flags)
1045     # Separate out the -Werror flag as some files just cannot be
1046     # compiled with it enabled.
1047     for w in ${build_warnings}; do
1048         case $w in
1049         -Werr*) WERROR_CFLAGS=-Werror ;;
1050         *) # Check that GCC accepts it
1051             saved_CFLAGS="$CFLAGS"
1052             CFLAGS="$CFLAGS $w"
1053             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1054             CFLAGS="$saved_CFLAGS"
1055         esac
1056     done
1057     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1058 fi
1059 AC_SUBST(WARN_CFLAGS)
1060 AC_SUBST(WERROR_CFLAGS)
1061
1062 MMALLOC_CFLAGS=
1063 MMALLOC=
1064 AC_SUBST(MMALLOC_CFLAGS)
1065 AC_SUBST(MMALLOC)
1066
1067 AC_ARG_WITH(mmalloc,
1068 [  --with-mmalloc          Use memory mapped malloc package],
1069 [case "${withval}" in
1070   yes)  want_mmalloc=true ;;
1071   no)   want_mmalloc=false;;
1072   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
1073 esac],[want_mmalloc=false])dnl
1074
1075 if test x$want_mmalloc = xtrue; then
1076    AC_DEFINE(USE_MMALLOC)
1077    AC_DEFINE(MMCHECK_FORCE)
1078    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
1079    MMALLOC='../mmalloc/libmmalloc.a'
1080 fi
1081
1082 # In the Cygwin environment, we need some additional flags.
1083 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1084 [AC_EGREP_CPP(lose, [
1085 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1086 lose
1087 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1088
1089
1090 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1091 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1092 case ${host} in
1093   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1094   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1095 esac
1096 AC_SUBST(SER_HARDWIRE)
1097
1098 # libreadline needs libuser32.a in a cygwin environment
1099 WIN32LIBS=
1100 if test x$gdb_cv_os_cygwin = xyes; then
1101     WIN32LIBS="-luser32"
1102     case "${target}" in
1103         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1104         ;;
1105     esac
1106 fi
1107 AC_SUBST(WIN32LIBS)
1108
1109 LIBGUI="../libgui/src/libgui.a"
1110 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1111 AC_SUBST(LIBGUI)
1112 AC_SUBST(GUI_CFLAGS_X)
1113
1114 WIN32LDAPP=
1115 AC_SUBST(WIN32LIBS)
1116 AC_SUBST(WIN32LDAPP)
1117
1118 configdir="unix"
1119
1120 GDBTKLIBS=
1121 if test "${enable_gdbtk}" = "yes"; then
1122
1123     # Gdbtk must have an absolute path to srcdir in order to run
1124     # properly when not installed.
1125     here=`pwd`
1126     cd ${srcdir}
1127     GDBTK_SRC_DIR=`pwd`
1128     cd $here
1129
1130     CY_AC_PATH_TCLCONFIG
1131     if test -z "${no_tcl}"; then
1132         CY_AC_LOAD_TCLCONFIG
1133         CY_AC_PATH_TKCONFIG
1134
1135         # now look for Tcl library stuff
1136
1137         case "${host}" in
1138         *-*-cygwin*)
1139             tcldir=../tcl/win/
1140             ;;
1141         *)
1142             tcldir=../tcl/unix/
1143             ;;
1144         esac
1145
1146         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1147
1148         # If $no_tk is nonempty, then we can't do Tk, and there is no
1149         # point to doing Tcl.
1150         if test -z "${no_tk}"; then
1151            CY_AC_LOAD_TKCONFIG
1152            CY_AC_PATH_TCLH
1153            CY_AC_PATH_TKH
1154            CY_AC_PATH_ITCLH
1155            CY_AC_PATH_ITKH
1156
1157
1158            # now look for Tk library stuff
1159
1160            case "${host}" in
1161            *-*-cygwin*)
1162                tkdir=../tk/win/
1163                ;;
1164            *)
1165                tkdir=../tk/unix/
1166                ;;
1167            esac
1168
1169            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1170
1171            # now look for Itcl library stuff
1172
1173            CY_AC_PATH_ITCLCONFIG
1174            if test -z "${no_itcl}"; then
1175              CY_AC_LOAD_ITCLCONFIG
1176
1177              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1178              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1179            fi
1180
1181
1182            # now look for Itk library stuff
1183            CY_AC_PATH_ITKCONFIG
1184            if test -z "${no_itcl}"; then
1185              CY_AC_LOAD_ITKCONFIG
1186
1187              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1188              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1189            fi
1190
1191            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1192            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1193            # know whether 8.2 will or not, but I bet it will.
1194            # I don't have to worry about 7.x since we don't support it.
1195            GDBTK_CFLAGS=""
1196            if test "$GCC" = "yes"; then
1197                if test "$TCL_VERSION" != "8.0" ; then
1198                    GDBTK_CFLAGS="-fwritable-strings"
1199                fi
1200            fi
1201
1202            # Include some libraries that Tcl and Tk want.
1203            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1204            # Yes, the ordering seems wrong here.  But it isn't.
1205            # TK_LIBS is the list of libraries that need to be linked
1206            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1207            # were in LIBS then any link tests after this point would
1208            # try to include things like `$(LIBGUI)', which wouldn't work.
1209            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1210
1211            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1212            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1213            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1214            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
1215            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
1216            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
1217            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
1218            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
1219
1220            if test x$gdb_cv_os_cygwin = xyes; then
1221               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1222               WIN32LDAPP="-Wl,--subsystem,console"
1223               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1224            fi
1225         fi
1226     fi
1227
1228     configdirs="${configdirs} gdbtk"
1229 fi
1230
1231 AC_SUBST(X_CFLAGS)
1232 AC_SUBST(X_LDFLAGS)
1233 AC_SUBST(X_LIBS)
1234 AC_SUBST(TCL_DEPS)
1235 AC_SUBST(TK_DEPS)
1236 AC_SUBST(ITCLLIB)
1237 AC_SUBST(ITCL_DEPS)
1238 AC_SUBST(ITKLIB)
1239 AC_SUBST(ITK_DEPS)
1240 AC_SUBST(GDBTKLIBS)
1241 AC_SUBST(GDBTK_CFLAGS)
1242 AC_SUBST(GDBTK_SRC_DIR)
1243
1244 AC_PATH_X
1245
1246
1247 # Unlike the sim directory, whether a simulator is linked is controlled by
1248 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1249 # This code just checks for a few cases where we'd like to ignore those
1250 # definitions, even when they're present in the '.mt' file.  These cases
1251 # are when --disable-sim is specified, or if the simulator directory is
1252 # not part of the source tree.
1253 #
1254 AC_ARG_ENABLE(sim,
1255 [  --enable-sim            Link gdb with simulator],
1256 [echo "enable_sim = $enable_sim";
1257  echo "enableval = ${enableval}";
1258  case "${enableval}" in
1259   yes) ignore_sim=false ;;
1260   no)  ignore_sim=true ;;
1261   *)   ignore_sim=false ;;
1262  esac],
1263 [ignore_sim=false])
1264
1265 if test ! -d "${srcdir}/../sim"; then
1266   ignore_sim=true
1267 fi
1268
1269 if test "${ignore_sim}" = "true"; then
1270     IGNORE_SIM="SIM="
1271     IGNORE_SIM_OBS="SIM_OBS="
1272 else
1273     IGNORE_SIM=""
1274     IGNORE_SIM_OBS=""
1275     AC_DEFINE(WITH_SIM)
1276 fi
1277 AC_SUBST(IGNORE_SIM)
1278 AC_SUBST(IGNORE_SIM_OBS)
1279
1280 AC_SUBST(ENABLE_CFLAGS)
1281 AC_SUBST(PROFILE_CFLAGS)
1282
1283 AC_SUBST(CONFIG_OBS)
1284 AC_SUBST(CONFIG_LIB_OBS)
1285 AC_SUBST(CONFIG_DEPS)
1286 AC_SUBST(CONFIG_SRCS)
1287 AC_SUBST(CONFIG_INITS)
1288 AC_SUBST(CONFIG_ALL)
1289 AC_SUBST(CONFIG_CLEAN)
1290 AC_SUBST(CONFIG_INSTALL)
1291 AC_SUBST(CONFIG_UNINSTALL)
1292
1293 # target_subdir is used by the testsuite to find the target libraries.
1294 target_subdir=
1295 if test "${host}" != "${target}"; then
1296     target_subdir="${target_alias}/"
1297 fi
1298 AC_SUBST(target_subdir)
1299
1300 frags=
1301 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1302 if test ! -f ${host_makefile_frag}; then
1303     # When building a native debuger the .mh file containing things
1304     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1305     # since it no longer contains anything useful.
1306     if test "${target}" = "${host}"; then
1307         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1308     else
1309         host_makefile_frag=/dev/null
1310     fi
1311 fi
1312 frags="$frags $host_makefile_frag"
1313
1314 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1315 if test ! -f ${target_makefile_frag}; then
1316 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1317 fi
1318 frags="$frags $target_makefile_frag"
1319
1320 AC_SUBST_FILE(host_makefile_frag)
1321 AC_SUBST_FILE(target_makefile_frag)
1322 AC_SUBST(frags)
1323
1324 changequote(,)dnl
1325 hostfile=`sed -n '
1326 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1327 ' ${host_makefile_frag}`
1328
1329 targetfile=`sed -n '
1330 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1331 ' ${target_makefile_frag}`
1332
1333 if test "${target}" = "${host}"; then
1334 # We pick this up from the host configuration file (.mh) because we
1335 # do not have a native configuration Makefile fragment.
1336 nativefile=`sed -n '
1337 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1338 ' ${host_makefile_frag}`
1339 fi
1340 changequote([,])
1341
1342 if test x"${gdb_osabi}" != x ; then
1343     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1344                        [Define to the default OS ABI for this configuration.])
1345 fi
1346
1347 # Enable multi-ice-gdb-server.
1348 AC_ARG_ENABLE(multi-ice,
1349 [  --enable-multi-ice      build the multi-ice-gdb-server],
1350   [case $enableval in
1351     yes | no)
1352       ;;
1353     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1354   esac])
1355 if test "x$enable_multi_ice" = xyes; then
1356   configdirs="$configdirs multi-ice"
1357 fi
1358
1359 # We only build gdbserver automatically if host and target are the same.
1360 if test "x$target" = "x$host"; then
1361   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1362   if test "x$build_gdbserver" = xyes; then
1363     configdirs="$configdirs gdbserver"
1364     AC_MSG_RESULT(yes)
1365   else
1366     AC_MSG_RESULT(no)
1367   fi
1368 fi
1369
1370 AC_CONFIG_SUBDIRS($configdirs)
1371
1372 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1373 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1374 # version.
1375
1376 files=
1377 links=
1378
1379 rm -f xm.h
1380 xm_h=""
1381 if test "${hostfile}" != ""; then
1382     xm_h=xm.h
1383     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1384     files="${files} ${GDB_XM_FILE}"
1385     links="${links} xm.h"
1386     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1387 fi
1388 AC_SUBST(xm_h)
1389
1390 rm -f tm.h
1391 tm_h=""
1392 if test "${targetfile}" != ""; then
1393     tm_h=tm.h
1394     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1395     files="${files} ${GDB_TM_FILE}"
1396     links="${links} tm.h"
1397     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1398 fi
1399 AC_SUBST(tm_h)
1400
1401 rm -f nm.h
1402 nm_h=""
1403 if test "${nativefile}" != ""; then
1404     nm_h=nm.h
1405     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1406     files="${files} ${GDB_NM_FILE}"
1407     links="${links} nm.h"
1408     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1409 fi
1410 AC_SUBST(nm_h)
1411
1412 AC_LINK_FILES($files, $links)
1413
1414 dnl Check for exe extension set on certain hosts (e.g. Win32)
1415 AC_EXEEXT
1416
1417 dnl  Detect the character set used by this host.
1418
1419 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1420 dnl  superset of ASCII containing the characters needed for French,
1421 dnl  German, Spanish, Italian, and possibly others), but if were
1422 dnl  *were* to support any host character sets other than ISO-8859-1,
1423 dnl  here's where we'd detect it.
1424 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1425           [Define to be a string naming the default host character set.])
1426
1427 AM_ICONV
1428
1429 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1430 [
1431 dnl Autoconf doesn't provide a mechanism for modifying definitions
1432 dnl provided by makefile fragments.
1433 dnl
1434 if test "${nativefile}" = ""; then
1435         < Makefile \
1436         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1437             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1438         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1439         > Makefile.tem
1440 mv -f Makefile.tem Makefile
1441 fi
1442
1443 changequote(,)dnl
1444 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1445 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1446 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1447 mv -f Makefile.tmp Makefile
1448 changequote([,])dnl
1449
1450
1451 case x$CONFIG_HEADERS in
1452 xconfig.h:config.in)
1453 echo > stamp-h ;;
1454 esac
1455 ],
1456 [
1457 gdb_host_cpu=$gdb_host_cpu
1458 gdb_target_cpu=$gdb_target_cpu
1459 nativefile=$nativefile
1460 ])
1461
1462 exit 0