gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.13)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25 AM_MAINTAINER_MODE
  26
  27 AC_PROG_CC
  28 AC_AIX
  29 AC_ISC_POSIX
  30 AM_PROG_CC_STDC
  31
  32 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  33 AC_CANONICAL_SYSTEM
  34
  35 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  36 dnl link with the correct libraries.
  37 ALL_LINGUAS=
  38 CY_GNU_GETTEXT
  39
  40 dnl List of object files added by configure.
  41
  42 CONFIG_OBS=
  43 CONFIG_LOBS=
  44 CONFIG_DEPS=
  45 CONFIG_SRCS=
  46 CONFIG_INITS=
  47 ENABLE_CFLAGS=
  48 CONFIG_ALL=
  49 CONFIG_CLEAN=
  50 CONFIG_INSTALL=
  51 CONFIG_UNINSTALL=
  52
  53 configdirs="doc testsuite"
  54
  55 AC_ARG_ENABLE(multi-ice,
  56 [  --enable-multi-ice            Build the multi-ice-gdb-server],
  57 [case "${enableval}" in
  58     yes ) enable_multi_ice="yes" ;;
  59     no)  enable_multi_ice="no" ;;
  60     *) AC_MSG_ERROR(Bad value for --enable-multi-ice: ${enableval}) ;;
  61   esac
  62 ])
  63
  64 if test "${enable_multi_ice}" = "yes"; then
  65   configdirs="${configdirs} multi-ice"
  66 fi
  67
  68 dnl
  69 changequote(,)dnl
  70
  71 . ${srcdir}/configure.host
  72
  73 . ${srcdir}/configure.tgt
  74
  75 targ=${target} ; . ${srcdir}/../bfd/config.bfd
  76
  77 dnl
  78 changequote([,])dnl
  79
  80 dnl use BFD to determine the default architecture and byte order
  81 dnl (bfd_vec->byteorder provides the latter).
  82 targ=${target}
  83 . ${srcdir}/../bfd/config.bfd
  84
  85 dnl We only want the first arch, if there is more than one.
  86 targ_archs=`echo ${targ_archs} | sed -e 's/ .*//;'`
  87
  88 if test x"${targ_archs}" != x ; then
  89     AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, ${targ_archs})
  90 fi
  91 if test x"${targ_defvec}" != x ; then
  92     AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, ${targ_defvec})
  93 fi
  94
  95 AC_PROG_AWK
  96 AC_PROG_INSTALL
  97 AC_CHECK_TOOL(AR, ar)
  98 AC_CHECK_TOOL(RANLIB, ranlib, :)
  99 AC_CHECK_TOOL(DLLTOOL, dlltool)
 100 AC_CHECK_TOOL(WINDRES, windres)
 101 AC_PROG_YACC
 102
 103 dnl MiG is needed for the Hurd.
 104 AC_CHECK_TOOL(MIG, mig)
 105
 106 AC_ARG_PROGRAM
 107
 108 AC_TYPE_SIGNAL
 109
 110 AC_HEADER_STDC
 111
 112 dnl Solaris 7 needs _MSE_INT_H defined to avoid a clash between <widec.h>
 113 dnl and <wchar.h> that causes AC_CHECK_HEADERS to think <curses.h> doesn't
 114 dnl exist.
 115
 116 case $host_os in solaris2.7 | solaris2.8) case "$GCC" in yes)
 117     AC_DEFINE(_MSE_INT_H)
 118 esac; esac
 119
 120 AC_CHECK_HEADERS(ctype.h endian.h link.h thread_db.h proc_service.h \
 121         memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
 122         string.h sys/procfs.h sys/ptrace.h sys/reg.h stdint.h \
 123         term.h termio.h termios.h unistd.h wait.h sys/wait.h \
 124         wchar.h wctype.h asm/debugreg.h sys/debugreg.h sys/select.h \
 125         time.h sys/ioctl.h sys/user.h \
 126         dirent.h sys/ndir.h sys/dir.h ndir.h \
 127         curses.h ncurses.h \
 128         poll.h sys/poll.h)
 129 AC_HEADER_STAT
 130
 131 AC_C_CONST
 132
 133 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc poll sigprocmask vfork)
 134 AC_FUNC_ALLOCA
 135
 136 # See if machine/reg.h supports the %fs and %gs i386 segment registers.
 137 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 138 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 139 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 140 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 141 if test $gdb_cv_struct_reg_r_fs = yes; then
 142   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 143 fi
 144 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 145 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 146 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 147 if test $gdb_cv_struct_reg_r_gs = yes; then
 148   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 149 fi
 150
 151 dnl See if ptrace.h provides the PTRACE_GETREGS request.
 152 AC_MSG_CHECKING(for PTRACE_GETREGS)
 153 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 154 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 155                 [PTRACE_GETREGS;],
 156                 [gdb_cv_have_ptrace_getregs=yes],
 157                 [gdb_cv_have_ptrace_getregs=no])])
 158 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 159 if test $gdb_cv_have_ptrace_getregs = yes; then
 160   AC_DEFINE(HAVE_PTRACE_GETREGS)
 161 fi
 162
 163 dnl See if ptrace.h provides the PTRACE_GETFPXREGS request.
 164 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 165 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 166 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 167                 [PTRACE_GETFPXREGS;],
 168                 [gdb_cv_have_ptrace_getfpxregs=yes],
 169                 [gdb_cv_have_ptrace_getfpxregs=no])])
 170 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 171 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 172   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 173 fi
 174
 175 AC_CHECK_LIB(socket, socketpair)
 176 AC_CHECK_FUNCS(socketpair)
 177
 178
 179 BFD_NEED_DECLARATION(malloc)
 180 BFD_NEED_DECLARATION(realloc)
 181 BFD_NEED_DECLARATION(free)
 182 BFD_NEED_DECLARATION(strerror)
 183 BFD_NEED_DECLARATION(strdup)
 184 BFD_NEED_DECLARATION(strstr)
 185
 186
 187 # The following save_state_t checkery is only necessary for HPUX
 188 # versions earlier than 10.20.  When those fade from memory, this
 189 # could be expunged. --jsm 1999-03-22
 190
 191 AC_MSG_CHECKING(for HPUX save_state structure)
 192 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 193                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 194 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 195                 gdb_cv_hpux_sswide=no)
 196 if test $gdb_cv_hpux_savestate = yes
 197 then
 198   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 199 fi
 200 if test $gdb_cv_hpux_sswide = yes
 201 then
 202   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 203 fi
 204 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 205
 206
 207 # If we are configured native on GNU/Linux, work around problems with
 208 # sys/procfs.h
 209 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 210
 211 if test "${target}" = "${host}"; then
 212   case "${host}" in
 213   i[[3456]]86-*-linux*)
 214         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 215         AC_DEFINE(sys_quotactl)
 216         ;;
 217   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5*)
 218       AC_DEFINE(NEW_PROC_API)
 219       ;;
 220   *-*-solaris2.[[678]])
 221       AC_DEFINE(NEW_PROC_API)
 222       ;;
 223   esac
 224 fi
 225
 226 if test "$ac_cv_header_sys_procfs_h" = yes; then
 227   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 228   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 229   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 230   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 231   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 232   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 233   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 234   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 235   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 236   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 237
 238   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 239   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 240
 241   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 242   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 243     [AC_TRY_COMPILE([#define _SYSCALL32
 244 #include <sys/link.h>], [struct link_map32 l;],
 245      gdb_cv_have_struct_link_map32=yes,
 246      gdb_cv_have_struct_link_map32=no)])
 247   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 248   if test $gdb_cv_have_struct_link_map32 = yes; then
 249     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 250   fi
 251
 252   dnl Check for broken prfpregset_t type
 253
 254   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 255   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 256   dnl instead of the struct itself).  We detect this here, and work
 257   dnl around it in lin-thread.c.
 258
 259   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 260     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 261     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 262       [AC_TRY_RUN([#include <sys/procfs.h>
 263        int main ()
 264        {
 265          if (sizeof (prfpregset_t) == sizeof (void *))
 266            return 1;
 267          return 0;
 268        }],
 269        gdb_cv_prfpregset_t_broken=no,
 270        gdb_cv_prfpregset_t_broken=yes,
 271        gdb_cv_prfpregset_t_broken=yes)])
 272     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 273     if test $gdb_cv_prfpregset_t_broken = yes; then
 274       AC_DEFINE(PRFPREGSET_T_BROKEN)
 275     fi
 276   fi
 277
 278   dnl Check for PIOCSET ioctl entry
 279
 280   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 281   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 282   [AC_TRY_COMPILE([#include <unistd.h>
 283 #include <sys/types.h>
 284 #include <sys/procfs.h>
 285 ], [
 286     int dummy;;
 287     dummy = ioctl(0, PIOCSET, &dummy);
 288   ],
 289   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 290   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 291   if test $gdb_cv_have_procfs_piocset = yes; then
 292     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 293   fi
 294 fi
 295
 296 dnl See if host has libm.  This is usually needed by simulators.
 297 AC_CHECK_LIB(m, main)
 298
 299 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 300 dnl
 301 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 302 dnl under Solaris 2.6 because it is some funky empty library.
 303 dnl So only link in libw if we have to.
 304 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 305
 306 dnl See if compiler supports "long long" type.
 307
 308 AC_MSG_CHECKING(for long long support in compiler)
 309 AC_CACHE_VAL(gdb_cv_c_long_long,
 310 [AC_TRY_COMPILE(, [
 311   extern long long foo;
 312   switch (foo & 2) { case 0: return 1; }
 313 ],
 314 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 315 AC_MSG_RESULT($gdb_cv_c_long_long)
 316 if test $gdb_cv_c_long_long = yes; then
 317   AC_DEFINE(CC_HAS_LONG_LONG)
 318 fi
 319
 320 dnl See if the compiler and runtime support printing long long
 321
 322 AC_MSG_CHECKING(for long long support in printf)
 323 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 324 [AC_TRY_RUN([
 325 int main () {
 326   char buf[32];
 327   long long l = 0;
 328   l = (l << 16) + 0x0123;
 329   l = (l << 16) + 0x4567;
 330   l = (l << 16) + 0x89ab;
 331   l = (l << 16) + 0xcdef;
 332   sprintf (buf, "0x%016llx", l);
 333   return (strcmp ("0x0123456789abcdef", buf));
 334 }],
 335 gdb_cv_printf_has_long_long=yes,
 336 gdb_cv_printf_has_long_long=no,
 337 gdb_cv_printf_has_long_long=no)])
 338 if test $gdb_cv_printf_has_long_long = yes; then
 339   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 340 fi
 341 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 342
 343 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 344 dnl because autoconf complains about cross-compilation issues.  However, this
 345 dnl code uses the same variables as the macro for compatibility.
 346
 347 AC_MSG_CHECKING(for long double support in compiler)
 348 AC_CACHE_VAL(ac_cv_c_long_double,
 349 [AC_TRY_COMPILE(, [long double foo;],
 350 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 351 AC_MSG_RESULT($ac_cv_c_long_double)
 352 if test $ac_cv_c_long_double = yes; then
 353   AC_DEFINE(HAVE_LONG_DOUBLE)
 354 fi
 355
 356 dnl See if the compiler and runtime support printing long doubles
 357
 358 AC_MSG_CHECKING(for long double support in printf)
 359 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 360 [AC_TRY_RUN([
 361 int main () {
 362   char buf[16];
 363   long double f = 3.141592653;
 364   sprintf (buf, "%Lg", f);
 365   return (strncmp ("3.14159", buf, 7));
 366 }],
 367 gdb_cv_printf_has_long_double=yes,
 368 gdb_cv_printf_has_long_double=no,
 369 gdb_cv_printf_has_long_double=no)])
 370 if test $gdb_cv_printf_has_long_double = yes; then
 371   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 372 fi
 373 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 374
 375 dnl See if the compiler and runtime support scanning long doubles
 376
 377 AC_MSG_CHECKING(for long double support in scanf)
 378 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 379 [AC_TRY_RUN([
 380 int main () {
 381   char *buf = "3.141592653";
 382   long double f = 0;
 383   sscanf (buf, "%Lg", &f);
 384   return !(f > 3.14159 && f < 3.14160);
 385 }],
 386 gdb_cv_scanf_has_long_double=yes,
 387 gdb_cv_scanf_has_long_double=no,
 388 gdb_cv_scanf_has_long_double=no)])
 389 if test $gdb_cv_scanf_has_long_double = yes; then
 390   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 391 fi
 392 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 393
 394 AC_FUNC_MMAP
 395
 396 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 397 dnl we must explicitly test for version 1 of the library because version 0
 398 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 399
 400 dnl Note that we only want this if we are both native (host == target), and
 401 dnl not doing a canadian cross build (build == host).
 402
 403 if test ${build} = ${host} -a ${host} = ${target} ; then
 404    case ${host_os} in
 405    hpux*)
 406       AC_MSG_CHECKING(for HPUX/OSF thread support)
 407       if test -f /usr/include/dce/cma_config.h ; then
 408          if test "$GCC" = "yes" ; then
 409             AC_MSG_RESULT(yes)
 410             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 411             CONFIG_LOBS="${CONFIG_LOBS} hpux-thread.o"
 412             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 413          else
 414             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 415          fi
 416       else
 417          AC_MSG_RESULT(no)
 418       fi
 419       ;;
 420    solaris*)
 421       AC_MSG_CHECKING(for Solaris thread debugging library)
 422       if test -f /usr/lib/libthread_db.so.1 ; then
 423          AC_MSG_RESULT(yes)
 424          AC_DEFINE(HAVE_THREAD_DB_LIB)
 425          CONFIG_LOBS="${CONFIG_LOBS} sol-thread.o"
 426          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 427          AC_CHECK_LIB(dl, dlopen)
 428          if test "$GCC" = "yes" ; then
 429             # The GNU linker requires the -export-dynamic option to make
 430             # all symbols visible in the dynamic symbol table.
 431             hold_ldflags=$LDFLAGS
 432             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 433             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 434             AC_TRY_LINK(, [int i;], found=yes, found=no)
 435             LDFLAGS=$hold_ldflags
 436             AC_MSG_RESULT($found)
 437             if test $found = yes; then
 438                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 439             fi
 440          fi
 441          # Sun randomly tweaked the prototypes in <proc_service.h>
 442          # at one point.
 443          AC_MSG_CHECKING(if <proc_service.h> is old)
 444          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 445             AC_TRY_COMPILE([
 446                 #include <proc_service.h>
 447                 ps_err_e ps_pdwrite
 448                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 449             ],, gdb_cv_proc_service_is_old=no,
 450                 gdb_cv_proc_service_is_old=yes)
 451          ])
 452          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 453          if test $gdb_cv_proc_service_is_old = yes; then
 454             AC_DEFINE(PROC_SERVICE_IS_OLD)
 455          fi
 456       else
 457          AC_MSG_RESULT(no)
 458       fi
 459       ;;
 460    esac
 461    AC_SUBST(CONFIG_LDFLAGS)
 462 fi
 463
 464 dnl The CLI cannot be disabled yet, but may be in the future
 465
 466 dnl Handle CLI sub-directory configury.
 467 AC_ARG_ENABLE(gdbcli,
 468 [  --enable-gdbcli            Enable GDB-CLI interface],
 469 [
 470   case "${enableval}" in
 471     yes) enable_gdbcli=yes ;;
 472     "") enable_gdbcli=yes ;;
 473     no)
 474       AC_MSG_ERROR(The CLI cannot be disabled yet)
 475     ;;
 476     *)
 477       AC_MSG_ERROR(Bad value for --enable-gdbcli: ${enableval})
 478     ;;
 479   esac
 480 ],
 481 [enable_gdbcli=yes])
 482 case ${enable_gdbcli} in
 483   "yes" )
 484     if test -d "${srcdir}/cli" ; then
 485       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_CLI_OBS)"
 486       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_CLI_DEPS)"
 487       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_CLI_SRCS)"
 488       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_CLI_INITS)"
 489       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_CLI_CFLAGS)"
 490       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_CLI_ALL)"
 491       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_CLI_CLEAN)"
 492       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_CLI_INSTALL)"
 493       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_CLI_UNINSTALL)"
 494     fi
 495     ;;
 496 esac
 497
 498 dnl Handle optional features that can be enabled.
 499
 500 dnl Handle MI sub-directory configury.
 501 AC_ARG_ENABLE(gdbmi,
 502 [  --enable-gdbmi            Enable GDB-MI interface],
 503 [
 504   case "${enable_gdbmi}" in
 505     yes | no) ;;
 506     "")  enable_gdbmi=yes ;;
 507     *)
 508       AC_MSG_ERROR(Bad value for --enable-gdbmi: ${enableval})
 509     ;;
 510   esac
 511 ])
 512 case ${enable_gdbmi} in
 513   "yes" )
 514     if test -d "${srcdir}/mi" ; then
 515       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_MI_OBS)"
 516       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_MI_DEPS)"
 517       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_MI_SRCS)"
 518       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_MI_INITS)"
 519       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_MI_CFLAGS)"
 520       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_MI_ALL)"
 521       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_MI_CLEAN)"
 522       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_MI_INSTALL)"
 523       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_MI_UNINSTALL)"
 524     fi
 525     ;;
 526 esac
 527
 528 AC_ARG_ENABLE(tui,
 529 [  --enable-tui            Enable full-screen terminal user interface],
 530 [
 531   case "${enable_tui}" in
 532     yes | no) ;;
 533     "")  enable_tui=yes ;;
 534     *)
 535       AC_MSG_ERROR(Bad value for --enable-tui: ${enableval})
 536     ;;
 537   esac
 538 ])
 539 case ${enable_tui} in
 540   "yes" )
 541     if test -d "${srcdir}/tui" ; then
 542       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_TUI_OBS)"
 543       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_TUI_DEPS)"
 544       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_TUI_SRCS)"
 545       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_TUI_INITS)"
 546       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_TUI_CFLAGS)"
 547       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_TUI_ALL)"
 548       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_TUI_CLEAN)"
 549       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_TUI_INSTALL)"
 550       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_TUI_UNINSTALL)"
 551     fi
 552     ;;
 553 esac
 554
 555 AC_ARG_ENABLE(netrom,
 556 [  --enable-netrom         Enable NetROM support],
 557 [case "${enableval}" in
 558 yes)    enable_netrom=yes ;;
 559 no)     enable_netrom=no ;;
 560 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 561 esac])
 562
 563 if test "${enable_netrom}" = "yes"; then
 564         CONFIG_LOBS="${CONFIG_LOBS} remote-nrom.o"
 565         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 566 fi
 567
 568
 569 # NOTE: Don't add -Wall or -Wunused, they both include
 570 # -Wunused-parameter which reports bogus warnings.
 571 # NOTE: If you add to this list, remember to update
 572 # gdb/doc/gdbint.texinfo.
 573 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
 574 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized"
 575 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
 576 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
 577 # -Wchar-subscripts -Wuninitialized -Wtraditional -Wshadow -Wcast-qual
 578 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
 579 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
 580 # -Woverloaded-virtual -Winline -Werror"
 581 AC_ARG_ENABLE(build-warnings,
 582 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 583 [case "${enableval}" in
 584   yes)  ;;
 585   no)   build_warnings="-w";;
 586   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 587         build_warnings="${build_warnings} ${t}";;
 588   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 589         build_warnings="${t} ${build_warnings}";;
 590   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 591 esac
 592 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 593   echo "Setting compiler warning flags = $build_warnings" 6>&1
 594 fi])dnl
 595 AC_ARG_ENABLE(gdb-build-warnings,
 596 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
 597 [case "${enableval}" in
 598   yes)  ;;
 599   no)   build_warnings="-w";;
 600   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 601         build_warnings="${build_warnings} ${t}";;
 602   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 603         build_warnings="${t} ${build_warnings}";;
 604   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 605 esac
 606 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 607   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
 608 fi])dnl
 609 WARN_CFLAGS=""
 610 WERROR_CFLAGS=""
 611 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 612 then
 613     AC_MSG_CHECKING(compiler warning flags)
 614     # Separate out the -Werror flag as some files just cannot be
 615     # compiled with it enabled.
 616     for w in ${build_warnings}; do
 617         case $w in
 618         -Werr*) WERROR_CFLAGS=-Werror ;;
 619         *) # Check that GCC accepts it
 620             if $CC $w 2>&1 | grep 'unrecognized option' > /dev/null; then
 621                 :
 622             else
 623                 WARN_CFLAGS="${WARN_CFLAGS} $w"
 624             fi
 625         esac
 626     done
 627     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
 628 fi
 629 AC_SUBST(WARN_CFLAGS)
 630 AC_SUBST(WERROR_CFLAGS)
 631
 632 MMALLOC_CFLAGS=
 633 MMALLOC=
 634 AC_SUBST(MMALLOC_CFLAGS)
 635 AC_SUBST(MMALLOC)
 636
 637 AC_ARG_WITH(mmalloc,
 638 [  --with-mmalloc          Use memory mapped malloc package],
 639 [case "${withval}" in
 640   yes)  want_mmalloc=true ;;
 641   no)   want_mmalloc=false;;
 642   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 643 esac],[want_mmalloc=false])dnl
 644
 645 if test x$want_mmalloc = xtrue; then
 646    AC_DEFINE(USE_MMALLOC)
 647    AC_DEFINE(MMCHECK_FORCE)
 648    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 649    MMALLOC='../mmalloc/libmmalloc.a'
 650 fi
 651
 652 AC_ARG_WITH(included-regex,
 653 [  --with-included-regex          Use included regex],
 654 [case "${withval}" in
 655   yes)  want_included_regex=true ;;
 656   no)   want_included_regex=false;;
 657   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-included-regex option) ;;
 658 esac],[want_included_regex=true])dnl
 659
 660 if test $want_included_regex = false; then
 661   AC_MSG_CHECKING(for GNU regex)
 662   AC_CACHE_VAL(gdb_cv_have_gnu_regex,
 663 [AC_TRY_COMPILE([#include <gnu-versions.h>
 664 #include <sys/types.h>
 665 #include <regex.h>],
 666 [#if !defined _GNU_REGEX_INTERFACE_VERSION || !defined __GLIBC__ || __GLIBC__ < 2
 667 #error No valid GNU regex.
 668 #endif
 669 ],
 670                 [gdb_cv_have_gnu_regex=yes],
 671                 [gdb_cv_have_gnu_regex=no])])
 672   AC_MSG_RESULT($gdb_cv_have_gnu_regex)
 673   if test $gdb_cv_have_gnu_regex = no; then
 674         want_included_regex=true
 675   fi
 676 fi
 677
 678 if test x${want_included_regex} = xtrue; then
 679     REGEX="gnu-regex.o"
 680     AC_DEFINE(USE_INCLUDED_REGEX)
 681 fi
 682 AC_SUBST(REGEX)
 683
 684 # In the Cygwin environment, we need some additional flags.
 685 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 686 [AC_EGREP_CPP(lose, [
 687 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
 688 lose
 689 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 690
 691
 692 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
 693 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
 694 case ${host} in
 695   *go32* ) SER_HARDWIRE=ser-go32.o ;;
 696   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
 697 esac
 698 AC_SUBST(SER_HARDWIRE)
 699
 700
 701 dnl Figure out which term library to use.
 702 if test x$gdb_host = xgo32; then
 703   TERM_LIB=
 704 else
 705 if test x$gdb_cv_os_cygwin = xyes; then
 706   TERM_LIB='`if test -r ../libtermcap/libtermcap.a; then echo ../libtermcap/libtermcap.a; else echo -ltermcap; fi`'
 707 else
 708   TERM_LIB=
 709   AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses,
 710     AC_CHECK_LIB(Hcurses, tgetent, TERM_LIB=-lHcurses,
 711       AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib,
 712         AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap,
 713           AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses,
 714             AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo))))))
 715
 716   if test "x$TERM_LIB" = x
 717   then
 718     AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!)
 719   fi
 720 fi
 721 fi
 722 AC_SUBST(TERM_LIB)
 723
 724 # libreadline needs libuser32.a in a cygwin environment
 725 WIN32LIBS=
 726 if test x$gdb_cv_os_cygwin = xyes; then
 727     WIN32LIBS="-luser32"
 728     case "${target}" in
 729         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
 730         ;;
 731     esac
 732 fi
 733 AC_SUBST(WIN32LIBS)
 734
 735 LIBGUI="../libgui/src/libgui.a"
 736 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 737 AC_SUBST(LIBGUI)
 738 AC_SUBST(GUI_CFLAGS_X)
 739
 740 AC_ARG_WITH(cpu,
 741 [  --with-cpu=CPU          Set the default CPU variant to debug],
 742 [case "${target}" in
 743   powerpc-* | powerpcle-* )
 744     ## It would be nice to keep this table in sync with the one in
 745     ## gcc/configure.
 746     case "${with_cpu}" in
 747       ppc-uisa | rs6000 | 403 | 403GC | 505 | 860 | 601 | 602 | 603 \
 748       | 604 | 750 )
 749         ## Those are all handled in variants in rs6000-tdep.c, so they're fine.
 750       ;;
 751       common | power | power2 | rios | rios1 | rios2 | rsc | rsc1 )
 752         ## These are all RS6000 variants, as far as GDB is concerned.
 753         with_cpu=rs6000
 754       ;;
 755       603e | ec603e )
 756         with_cpu=603
 757       ;;
 758       604e )
 759         with_cpu=604
 760       ;;
 761       * )
 762         AC_MSG_WARN(GDB: unknown --with-cpu value: \`${with_cpu}'; using \`ppc-uisa'.)
 763         with_cpu=ppc-uisa
 764       ;;
 765     esac
 766   ;;
 767   * )
 768     AC_MSG_WARN(GDB may ignore the --with-cpu flag for ${target} targets)
 769   ;;
 770 esac
 771 AC_DEFINE_UNQUOTED(TARGET_CPU_DEFAULT, "${with_cpu}")
 772 ],)
 773
 774
 775 AC_ARG_ENABLE(gdbtk,
 776 [  --enable-gdbtk          Enable GDBTK GUI front end],
 777 [case "${enableval}" in
 778     yes)
 779         case "$host" in
 780         *go32*)
 781             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 782             enable_gdbtk=no ;;
 783         *windows*)
 784             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 785             enable_gdbtk=no ;;
 786         *)
 787             enable_gdbtk=yes ;;
 788         esac ;;
 789     no)
 790         enable_gdbtk=no  ;;
 791     *)
 792         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 793 esac],
 794 [
 795 # Default is on for everything but go32 and Cygwin
 796 case "$host" in
 797     *go32* | *windows*)
 798         ;;
 799     *)
 800         if test -d "${srcdir}/gdbtk" ; then
 801             enable_gdbtk=yes
 802         fi
 803         ;;
 804 esac
 805 ])
 806
 807 WIN32LDAPP=
 808 AC_SUBST(WIN32LIBS)
 809 AC_SUBST(WIN32LDAPP)
 810
 811 configdir="unix"
 812
 813 GDBTKLIBS=
 814 if test "${enable_gdbtk}" = "yes"; then
 815
 816     CY_AC_PATH_TCLCONFIG
 817     if test -z "${no_tcl}"; then
 818         CY_AC_LOAD_TCLCONFIG
 819         CY_AC_PATH_TKCONFIG
 820
 821         # If $no_tk is nonempty, then we can't do Tk, and there is no
 822         # point to doing Tcl.
 823         if test -z "${no_tk}"; then
 824            CY_AC_LOAD_TKCONFIG
 825            CY_AC_PATH_TCLH
 826            CY_AC_PATH_TKH
 827            CY_AC_PATH_ITCLH
 828            CY_AC_PATH_ITKH
 829            CY_AC_PATH_TIXH
 830
 831            # now look for Itcl library stuff
 832
 833            CY_AC_PATH_ITCLCONFIG
 834            if test -z "${no_itcl}"; then
 835              CY_AC_LOAD_ITCLCONFIG
 836              case "${host}" in
 837              *-*-cygwin*)
 838                 itcldir=../itcl/itcl/win/
 839                 ;;
 840              *)
 841                 itcldir=../itcl/itcl/unix/
 842                 ;;
 843              esac
 844
 845
 846              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
 847              ITCL_DEPS="${itcldir}${ITCL_LIB_FILE}"
 848            fi
 849
 850
 851            # now look for Itk library stuff
 852            CY_AC_PATH_ITKCONFIG
 853            if test -z "${no_itcl}"; then
 854              CY_AC_LOAD_ITKCONFIG
 855
 856              case "${host}" in
 857                *-*-cygwin*)
 858                  itkdir=../itcl/itk/win/
 859                  ;;
 860                *)
 861                  itkdir=../itcl/itk/unix/
 862                  ;;
 863                esac
 864
 865              ITKLIB="${ITK_BUILD_LIB_SPEC}"
 866              ITK_DEPS="${itkdir}${ITK_LIB_FILE}"
 867            fi
 868
 869            # now look for Tix library stuff
 870            CY_AC_PATH_TIXCONFIG
 871            if test -z "${no_tix}"; then
 872              CY_AC_LOAD_TIXCONFIG
 873              TIXLIB="${TIX_BUILD_LIB_SPEC}"
 874              TIX_DEPS="${TIX_BUILD_LOCATION}/${TIX_LIB_FILE}"
 875            fi
 876
 877            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
 878            # Tcl/Tk 8.1 require -fwritable strings.  I don't
 879            # know whether 8.2 will or not, but I bet it will.
 880            # I don't have to worry about 7.x since we don't support it.
 881            GDBTK_CFLAGS=""
 882            if test "$GCC" = "yes"; then
 883                if test "$TCL_VERSION" != "8.0" ; then
 884                    GDBTK_CFLAGS="-fwritable-strings"
 885                fi
 886            fi
 887
 888            # Include some libraries that Tcl and Tk want.
 889            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 890            # Yes, the ordering seems wrong here.  But it isn't.
 891            # TK_LIBS is the list of libraries that need to be linked
 892            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 893            # were in LIBS then any link tests after this point would
 894            # try to include things like `$(LIBGUI)', which wouldn't work.
 895            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 896
 897            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
 898            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
 899            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
 900            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
 901            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
 902            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
 903            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
 904            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
 905
 906            if test x$gdb_cv_os_cygwin = xyes; then
 907               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
 908               WIN32LDAPP="-Wl,--subsystem,console"
 909               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 910            fi
 911         fi
 912     fi
 913 fi
 914
 915 AC_SUBST(X_CFLAGS)
 916 AC_SUBST(X_LDFLAGS)
 917 AC_SUBST(X_LIBS)
 918 AC_SUBST(ITCLLIB)
 919 AC_SUBST(ITCL_DEPS)
 920 AC_SUBST(ITKLIB)
 921 AC_SUBST(ITK_DEPS)
 922 AC_SUBST(TIXLIB)
 923 AC_SUBST(TIX_DEPS)
 924 AC_SUBST(GDBTKLIBS)
 925 AC_SUBST(GDBTK_CFLAGS)
 926
 927 AC_PATH_X
 928
 929
 930 # Unlike the sim directory, whether a simulator is linked is controlled by
 931 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
 932 # This code just checks for a few cases where we'd like to ignore those
 933 # definitions, even when they're present in the '.mt' file.  These cases
 934 # are when --disable-sim is specified, or if the simulator directory is
 935 # not part of the soruce tree.
 936 #
 937 AC_ARG_ENABLE(sim,
 938 [  --enable-sim            Link gdb with simulator],
 939 [echo "enable_sim = $enable_sim";
 940  echo "enableval = ${enableval}";
 941  case "${enableval}" in
 942   yes) ignore_sim=false ;;
 943   no)  ignore_sim=true ;;
 944   *)   ignore_sim=false ;;
 945  esac],
 946 [ignore_sim=false])
 947
 948 if test ! -d "${srcdir}/../sim"; then
 949   ignore_sim=true
 950 fi
 951
 952 if test "${ignore_sim}" = "true"; then
 953     IGNORE_SIM="SIM="
 954     IGNORE_SIM_OBS="SIM_OBS="
 955 else
 956     IGNORE_SIM=""
 957     IGNORE_SIM_OBS=""
 958     AC_DEFINE(WITH_SIM)
 959 fi
 960 AC_SUBST(IGNORE_SIM)
 961 AC_SUBST(IGNORE_SIM_OBS)
 962
 963 AC_SUBST(ENABLE_CFLAGS)
 964
 965 AC_SUBST(CONFIG_OBS)
 966 AC_SUBST(CONFIG_LOBS)
 967 AC_SUBST(CONFIG_DEPS)
 968 AC_SUBST(CONFIG_SRCS)
 969 AC_SUBST(CONFIG_INITS)
 970 AC_SUBST(CONFIG_ALL)
 971 AC_SUBST(CONFIG_CLEAN)
 972 AC_SUBST(CONFIG_INSTALL)
 973 AC_SUBST(CONFIG_UNINSTALL)
 974
 975 # Begin stuff to support --enable-shared
 976 AC_ARG_ENABLE(shared,
 977 [  --enable-shared         Use shared libraries],
 978 [case "${enableval}" in
 979   yes) shared=true ;;
 980   no)  shared=false ;;
 981   *) shared=true ;;
 982 esac])dnl
 983
 984 HLDFLAGS=
 985 HLDENV=
 986 # If we have shared libraries, try to set rpath reasonably.
 987 if test "${shared}" = "true"; then
 988   case "${host}" in
 989   *-*-hpux*)
 990     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 991     ;;
 992   *-*-irix5* | *-*-irix6*)
 993     HLDFLAGS='-Wl,-rpath,$(libdir)'
 994     ;;
 995   *-*-linux*aout*)
 996     ;;
 997   *-*-linux* | *-pc-linux-gnu*)
 998     HLDFLAGS='-Wl,-rpath,$(libdir)'
 999     ;;
1000   *-*-solaris*)
1001     HLDFLAGS='-R $(libdir)'
1002     ;;
1003   *-*-sysv4*)
1004     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
1005     ;;
1006   esac
1007 fi
1008
1009 # On SunOS, if the linker supports the -rpath option, use it to
1010 # prevent ../bfd and ../opcodes from being included in the run time
1011 # search path.
1012 case "${host}" in
1013   *-*-sunos*)
1014     echo 'main () { }' > conftest.c
1015     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
1016     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
1017       :
1018     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
1019       :
1020     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
1021       :
1022     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
1023       :
1024     elif test "${shared}" = "true"; then
1025       HLDFLAGS='-Wl,-rpath=$(libdir)'
1026     else
1027       HLDFLAGS='-Wl,-rpath='
1028     fi
1029     rm -f conftest.t conftest.c conftest
1030     ;;
1031 esac
1032 AC_SUBST(HLDFLAGS)
1033 AC_SUBST(HLDENV)
1034 # End stuff to support --enable-shared
1035
1036 # target_subdir is used by the testsuite to find the target libraries.
1037 target_subdir=
1038 if test "${host}" != "${target}"; then
1039     target_subdir="${target_alias}/"
1040 fi
1041 AC_SUBST(target_subdir)
1042
1043 frags=
1044 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1045 if test ! -f ${host_makefile_frag}; then
1046 AC_MSG_ERROR("*** Gdb does not support host ${host}")
1047 fi
1048 frags="$frags $host_makefile_frag"
1049
1050 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1051 if test ! -f ${target_makefile_frag}; then
1052 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1053 fi
1054 frags="$frags $target_makefile_frag"
1055
1056 AC_SUBST_FILE(host_makefile_frag)
1057 AC_SUBST_FILE(target_makefile_frag)
1058 AC_SUBST(frags)
1059
1060 changequote(,)dnl
1061 hostfile=`sed -n '
1062 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1063 ' ${host_makefile_frag}`
1064
1065 targetfile=`sed -n '
1066 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1067 ' ${target_makefile_frag}`
1068
1069 GDB_MULTI_ARCH=`sed -n '
1070 s/GDB_MULTI_ARCH[       ]*=[    ]*\([^  ]*\)[   ]*/\1/p
1071 ' ${target_makefile_frag}`
1072
1073 # these really aren't orthogonal true/false values of the same condition,
1074 # but shells are slow enough that I like to reuse the test conditions
1075 # whenever possible
1076 if test "${target}" = "${host}"; then
1077 nativefile=`sed -n '
1078 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1079 ' ${host_makefile_frag}`
1080 # else
1081 # GDBserver is only useful in a "native" enviroment
1082 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
1083 fi
1084 changequote([,])
1085
1086 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1087 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1088 # in the target specific makefile frag.  Eventually gdb_multi_arch=yes
1089 # will be the default.
1090 if test x"${GDB_MULTI_ARCH}" = x ; then
1091     case "${gdb_multi_arch}" in
1092     yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1093     no ) GDB_MULTI_ARCH=0 ;;
1094     0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1095     esac
1096 fi
1097 if test x"${GDB_MULTI_ARCH}" != x ; then
1098     AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1099 fi
1100 # Warn the user when they use an old pratice
1101 case "${GDB_MULTI_ARCH}" in
1102     "" ) ;;
1103     0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1104         AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1105     GDB_MULTI_ARCH_PURE )
1106         if test x"${targetfile}" != x ; then
1107             AC_MSG_WARN("GDB: Ingoring TM_FILE in ${target_makefile_frag}")
1108             targetfile=""
1109         fi ;;
1110     *)  AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1111 esac
1112
1113
1114 SUBDIRS="doc testsuite nlm"
1115 if test "${enable_multi_ice}" = "yes"; then
1116   SUBDIRS="${SUBDIRS} multi-ice"
1117 fi
1118
1119 AC_SUBST(SUBDIRS)
1120
1121 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1122 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1123 # version.
1124
1125 files=
1126 links=
1127
1128 rm -f xm.h
1129 xm_h=""
1130 if test "${hostfile}" != ""; then
1131     xm_h=xm.h
1132     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1133     files="${files} ${GDB_XM_FILE}"
1134     links="${links} xm.h"
1135     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1136 fi
1137 AC_SUBST(xm_h)
1138
1139 rm -f tm.h
1140 tm_h=""
1141 if test "${targetfile}" != ""; then
1142     tm_h=tm.h
1143     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1144     files="${files} ${GDB_TM_FILE}"
1145     links="${links} tm.h"
1146     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1147 fi
1148 AC_SUBST(tm_h)
1149
1150 rm -f nm.h
1151 nm_h=""
1152 if test "${nativefile}" != ""; then
1153     nm_h=nm.h
1154     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1155     files="${files} ${GDB_NM_FILE}"
1156     links="${links} nm.h"
1157     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1158 fi
1159 AC_SUBST(nm_h)
1160
1161 AC_PROG_LN_S
1162
1163 AC_LINK_FILES($files, $links)
1164
1165 dnl Check for exe extension set on certain hosts (e.g. Win32)
1166 AC_EXEEXT
1167
1168 AC_CONFIG_SUBDIRS($configdirs)
1169 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1170 [
1171 dnl Autoconf doesn't provide a mechanism for modifying definitions
1172 dnl provided by makefile fragments.
1173 dnl
1174 if test "${nativefile}" = ""; then
1175 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
1176         < Makefile > Makefile.tem
1177 mv -f Makefile.tem Makefile
1178 fi
1179
1180 changequote(,)dnl
1181 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1182 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1183 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1184 mv -f Makefile.tmp Makefile
1185 changequote([,])dnl
1186
1187
1188 case x$CONFIG_HEADERS in
1189 xconfig.h:config.in)
1190 echo > stamp-h ;;
1191 esac
1192 ],
1193 [
1194 gdb_host_cpu=$gdb_host_cpu
1195 gdb_target_cpu=$gdb_target_cpu
1196 nativefile=$nativefile
1197 ])
1198
1199 exit 0