gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.13)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25 AM_MAINTAINER_MODE
  26
  27 AC_PROG_CC
  28 AC_AIX
  29 AC_ISC_POSIX
  30 AM_PROG_CC_STDC
  31
  32 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  33 AC_CANONICAL_SYSTEM
  34
  35 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  36 dnl link with the correct libraries.
  37 ALL_LINGUAS=
  38 CY_GNU_GETTEXT
  39
  40 dnl List of object files added by configure.
  41
  42 CONFIG_OBS=
  43 CONFIG_DEPS=
  44 CONFIG_SRCS=
  45 CONFIG_INITS=
  46 ENABLE_CFLAGS=
  47 CONFIG_ALL=
  48 CONFIG_CLEAN=
  49 CONFIG_INSTALL=
  50 CONFIG_UNINSTALL=
  51
  52 configdirs="doc testsuite"
  53
  54 AC_ARG_ENABLE(multi-ice,
  55 [  --enable-multi-ice            Build the multi-ice-gdb-server],
  56 [case "${enableval}" in
  57     yes ) enable_multi_ice="yes" ;;
  58     no)  enable_multi_ice="no" ;;
  59     *) AC_MSG_ERROR(Bad value for --enable-multi-ice: ${enableval}) ;;
  60   esac
  61 ])
  62
  63 if test "${enable_multi_ice}" = "yes"; then
  64   configdirs="${configdirs} multi-ice"
  65 fi
  66
  67 dnl
  68 changequote(,)dnl
  69
  70 . ${srcdir}/configure.host
  71
  72 . ${srcdir}/configure.tgt
  73
  74 targ=${target} ; . ${srcdir}/../bfd/config.bfd
  75
  76 dnl
  77 changequote([,])dnl
  78
  79 dnl use BFD to determine the default architecture and byte order
  80 dnl (bfd_vec->byteorder provides the latter).
  81 targ=${target}
  82 . ${srcdir}/../bfd/config.bfd
  83
  84 dnl We only want the first arch, if there is more than one.
  85 targ_archs=`echo ${targ_archs} | sed -e 's/ .*//;'`
  86
  87 if test x"${targ_archs}" != x ; then
  88     AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, ${targ_archs})
  89 fi
  90 if test x"${targ_defvec}" != x ; then
  91     AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, ${targ_defvec})
  92 fi
  93
  94 AC_PROG_AWK
  95 AC_PROG_INSTALL
  96 AC_CHECK_TOOL(AR, ar)
  97 AC_CHECK_TOOL(RANLIB, ranlib, :)
  98 AC_CHECK_TOOL(DLLTOOL, dlltool)
  99 AC_CHECK_TOOL(WINDRES, windres)
 100 AC_PROG_YACC
 101
 102 dnl MiG is needed for the Hurd.
 103 AC_CHECK_TOOL(MIG, mig)
 104
 105 AC_ARG_PROGRAM
 106
 107 AC_TYPE_SIGNAL
 108
 109 AC_HEADER_STDC
 110
 111 dnl Solaris 7 needs _MSE_INT_H defined to avoid a clash between <widec.h>
 112 dnl and <wchar.h> that causes AC_CHECK_HEADERS to think <curses.h> doesn't
 113 dnl exist.
 114
 115 case $host_os in solaris2.7 | solaris2.8) case "$GCC" in yes)
 116     AC_DEFINE(_MSE_INT_H)
 117 esac; esac
 118
 119 AC_CHECK_HEADERS(ctype.h endian.h link.h thread_db.h proc_service.h \
 120         memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
 121         string.h sys/procfs.h sys/ptrace.h sys/reg.h stdint.h \
 122         term.h termio.h termios.h unistd.h wait.h sys/wait.h \
 123         wchar.h wctype.h asm/debugreg.h sys/debugreg.h sys/select.h \
 124         time.h sys/ioctl.h sys/user.h \
 125         dirent.h sys/ndir.h sys/dir.h ndir.h \
 126         curses.h ncurses.h \
 127         poll.h sys/poll.h)
 128 AC_HEADER_STAT
 129
 130 AC_C_CONST
 131
 132 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc poll sigprocmask)
 133 AC_FUNC_ALLOCA
 134
 135 # See if machine/reg.h supports the %fs and %gs i386 segment registers.
 136 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 137 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 138 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 139 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 140 if test $gdb_cv_struct_reg_r_fs = yes; then
 141   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 142 fi
 143 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 144 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 145 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 146 if test $gdb_cv_struct_reg_r_gs = yes; then
 147   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 148 fi
 149
 150 dnl See if ptrace.h provides the PTRACE_GETREGS request.
 151 AC_MSG_CHECKING(for PTRACE_GETREGS)
 152 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 153 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 154                 [PTRACE_GETREGS;],
 155                 [gdb_cv_have_ptrace_getregs=yes],
 156                 [gdb_cv_have_ptrace_getregs=no])])
 157 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 158 if test $gdb_cv_have_ptrace_getregs = yes; then
 159   AC_DEFINE(HAVE_PTRACE_GETREGS)
 160 fi
 161
 162 dnl See if ptrace.h provides the PTRACE_GETFPXREGS request.
 163 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 164 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 165 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 166                 [PTRACE_GETFPXREGS;],
 167                 [gdb_cv_have_ptrace_getfpxregs=yes],
 168                 [gdb_cv_have_ptrace_getfpxregs=no])])
 169 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 170 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 171   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 172 fi
 173
 174 AC_CHECK_LIB(socket, socketpair)
 175 AC_CHECK_FUNCS(socketpair)
 176
 177
 178 BFD_NEED_DECLARATION(malloc)
 179 BFD_NEED_DECLARATION(realloc)
 180 BFD_NEED_DECLARATION(free)
 181 BFD_NEED_DECLARATION(strerror)
 182 BFD_NEED_DECLARATION(strdup)
 183 BFD_NEED_DECLARATION(strstr)
 184
 185
 186 # The following save_state_t checkery is only necessary for HPUX
 187 # versions earlier than 10.20.  When those fade from memory, this
 188 # could be expunged. --jsm 1999-03-22
 189
 190 AC_MSG_CHECKING(for HPUX save_state structure)
 191 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 192                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 193 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 194                 gdb_cv_hpux_sswide=no)
 195 if test $gdb_cv_hpux_savestate = yes
 196 then
 197   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 198 fi
 199 if test $gdb_cv_hpux_sswide = yes
 200 then
 201   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 202 fi
 203 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 204
 205
 206 # If we are configured native on GNU/Linux, work around problems with
 207 # sys/procfs.h
 208 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 209
 210 if test "${target}" = "${host}"; then
 211   case "${host}" in
 212   i[[3456]]86-*-linux*)
 213         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 214         AC_DEFINE(sys_quotactl)
 215         ;;
 216   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5*)
 217       AC_DEFINE(NEW_PROC_API)
 218       ;;
 219   *-*-solaris2.[[678]])
 220       AC_DEFINE(NEW_PROC_API)
 221       ;;
 222   esac
 223 fi
 224
 225 if test "$ac_cv_header_sys_procfs_h" = yes; then
 226   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 227   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 228   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 229   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 230   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 231   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 232   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 233   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 234   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 235   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 236
 237   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 238   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 239
 240   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 241   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 242     [AC_TRY_COMPILE([#define _SYSCALL32
 243 #include <sys/link.h>], [struct link_map32 l;],
 244      gdb_cv_have_struct_link_map32=yes,
 245      gdb_cv_have_struct_link_map32=no)])
 246   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 247   if test $gdb_cv_have_struct_link_map32 = yes; then
 248     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 249   fi
 250
 251   dnl Check for broken prfpregset_t type
 252
 253   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 254   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 255   dnl instead of the struct itself).  We detect this here, and work
 256   dnl around it in lin-thread.c.
 257
 258   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 259     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 260     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 261       [AC_TRY_RUN([#include <sys/procfs.h>
 262        int main ()
 263        {
 264          if (sizeof (prfpregset_t) == sizeof (void *))
 265            return 1;
 266          return 0;
 267        }],
 268        gdb_cv_prfpregset_t_broken=no,
 269        gdb_cv_prfpregset_t_broken=yes,
 270        gdb_cv_prfpregset_t_broken=yes)])
 271     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 272     if test $gdb_cv_prfpregset_t_broken = yes; then
 273       AC_DEFINE(PRFPREGSET_T_BROKEN)
 274     fi
 275   fi
 276
 277   dnl Check for PIOCSET ioctl entry
 278
 279   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 280   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 281   [AC_TRY_COMPILE([#include <unistd.h>
 282 #include <sys/types.h>
 283 #include <sys/procfs.h>
 284 ], [
 285     int dummy;;
 286     dummy = ioctl(0, PIOCSET, &dummy);
 287   ],
 288   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 289   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 290   if test $gdb_cv_have_procfs_piocset = yes; then
 291     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 292   fi
 293 fi
 294
 295 dnl See if host has libm.  This is usually needed by simulators.
 296 AC_CHECK_LIB(m, main)
 297
 298 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 299 dnl
 300 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 301 dnl under Solaris 2.6 because it is some funky empty library.
 302 dnl So only link in libw if we have to.
 303 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 304
 305 dnl See if compiler supports "long long" type.
 306
 307 AC_MSG_CHECKING(for long long support in compiler)
 308 AC_CACHE_VAL(gdb_cv_c_long_long,
 309 [AC_TRY_COMPILE(, [
 310   extern long long foo;
 311   switch (foo & 2) { case 0: return 1; }
 312 ],
 313 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 314 AC_MSG_RESULT($gdb_cv_c_long_long)
 315 if test $gdb_cv_c_long_long = yes; then
 316   AC_DEFINE(CC_HAS_LONG_LONG)
 317 fi
 318
 319 dnl See if the compiler and runtime support printing long long
 320
 321 AC_MSG_CHECKING(for long long support in printf)
 322 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 323 [AC_TRY_RUN([
 324 int main () {
 325   char buf[32];
 326   long long l = 0;
 327   l = (l << 16) + 0x0123;
 328   l = (l << 16) + 0x4567;
 329   l = (l << 16) + 0x89ab;
 330   l = (l << 16) + 0xcdef;
 331   sprintf (buf, "0x%016llx", l);
 332   return (strcmp ("0x0123456789abcdef", buf));
 333 }],
 334 gdb_cv_printf_has_long_long=yes,
 335 gdb_cv_printf_has_long_long=no,
 336 gdb_cv_printf_has_long_long=no)])
 337 if test $gdb_cv_printf_has_long_long = yes; then
 338   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 339 fi
 340 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 341
 342 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 343 dnl because autoconf complains about cross-compilation issues.  However, this
 344 dnl code uses the same variables as the macro for compatibility.
 345
 346 AC_MSG_CHECKING(for long double support in compiler)
 347 AC_CACHE_VAL(ac_cv_c_long_double,
 348 [AC_TRY_COMPILE(, [long double foo;],
 349 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 350 AC_MSG_RESULT($ac_cv_c_long_double)
 351 if test $ac_cv_c_long_double = yes; then
 352   AC_DEFINE(HAVE_LONG_DOUBLE)
 353 fi
 354
 355 dnl See if the compiler and runtime support printing long doubles
 356
 357 AC_MSG_CHECKING(for long double support in printf)
 358 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 359 [AC_TRY_RUN([
 360 int main () {
 361   char buf[16];
 362   long double f = 3.141592653;
 363   sprintf (buf, "%Lg", f);
 364   return (strncmp ("3.14159", buf, 7));
 365 }],
 366 gdb_cv_printf_has_long_double=yes,
 367 gdb_cv_printf_has_long_double=no,
 368 gdb_cv_printf_has_long_double=no)])
 369 if test $gdb_cv_printf_has_long_double = yes; then
 370   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 371 fi
 372 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 373
 374 dnl See if the compiler and runtime support scanning long doubles
 375
 376 AC_MSG_CHECKING(for long double support in scanf)
 377 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 378 [AC_TRY_RUN([
 379 int main () {
 380   char *buf = "3.141592653";
 381   long double f = 0;
 382   sscanf (buf, "%Lg", &f);
 383   return !(f > 3.14159 && f < 3.14160);
 384 }],
 385 gdb_cv_scanf_has_long_double=yes,
 386 gdb_cv_scanf_has_long_double=no,
 387 gdb_cv_scanf_has_long_double=no)])
 388 if test $gdb_cv_scanf_has_long_double = yes; then
 389   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 390 fi
 391 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 392
 393 AC_FUNC_MMAP
 394
 395 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 396 dnl we must explicitly test for version 1 of the library because version 0
 397 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 398
 399 dnl Note that we only want this if we are both native (host == target), and
 400 dnl not doing a canadian cross build (build == host).
 401
 402 if test ${build} = ${host} -a ${host} = ${target} ; then
 403    case ${host_os} in
 404    hpux*)
 405       AC_MSG_CHECKING(for HPUX/OSF thread support)
 406       if test -f /usr/include/dce/cma_config.h ; then
 407          if test "$GCC" = "yes" ; then
 408             AC_MSG_RESULT(yes)
 409             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 410             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 411             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 412          else
 413             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 414          fi
 415       else
 416          AC_MSG_RESULT(no)
 417       fi
 418       ;;
 419    solaris*)
 420       AC_MSG_CHECKING(for Solaris thread debugging library)
 421       if test -f /usr/lib/libthread_db.so.1 ; then
 422          AC_MSG_RESULT(yes)
 423          AC_DEFINE(HAVE_THREAD_DB_LIB)
 424          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 425          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 426          AC_CHECK_LIB(dl, dlopen)
 427          if test "$GCC" = "yes" ; then
 428             # The GNU linker requires the -export-dynamic option to make
 429             # all symbols visible in the dynamic symbol table.
 430             hold_ldflags=$LDFLAGS
 431             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 432             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 433             AC_TRY_LINK(, [int i;], found=yes, found=no)
 434             LDFLAGS=$hold_ldflags
 435             AC_MSG_RESULT($found)
 436             if test $found = yes; then
 437                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 438             fi
 439          fi
 440          # Sun randomly tweaked the prototypes in <proc_service.h>
 441          # at one point.
 442          AC_MSG_CHECKING(if <proc_service.h> is old)
 443          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 444             AC_TRY_COMPILE([
 445                 #include <proc_service.h>
 446                 ps_err_e ps_pdwrite
 447                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 448             ],, gdb_cv_proc_service_is_old=no,
 449                 gdb_cv_proc_service_is_old=yes)
 450          ])
 451          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 452          if test $gdb_cv_proc_service_is_old = yes; then
 453             AC_DEFINE(PROC_SERVICE_IS_OLD)
 454          fi
 455       else
 456          AC_MSG_RESULT(no)
 457       fi
 458       ;;
 459    esac
 460    AC_SUBST(CONFIG_LDFLAGS)
 461 fi
 462
 463 dnl Handle optional features that can be enabled.
 464
 465 dnl Handle MI sub-directory configury.
 466 AC_ARG_ENABLE(gdbmi,
 467 [  --enable-gdbmi            Enable GDB-MI interface],
 468 [
 469   case "${enable_gdbmi}" in
 470     yes | no) ;;
 471     "")  enable_gdbmi=yes ;;
 472     *)
 473       AC_MSG_ERROR(Bad value for --enable-gdbmi: ${enableval})
 474     ;;
 475   esac
 476 ])
 477 case ${enable_gdbmi} in
 478   "yes" )
 479     if test -d "${srcdir}/mi" ; then
 480       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_MI_OBS)"
 481       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_MI_DEPS)"
 482       CONFIG_SRCS="${CONFIG_SRS} \$(SUBDIR_MI_SRCS)"
 483       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_MI_INITS)"
 484       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_MI_CFLAGS)"
 485       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_MI_ALL)"
 486       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_MI_CLEAN)"
 487       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_MI_INSTALL)"
 488       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_MI_UNINSTALL)"
 489     fi
 490     ;;
 491 esac
 492
 493 AC_ARG_ENABLE(tui,
 494 [  --enable-tui            Enable full-screen terminal user interface],
 495 [
 496   case "${enable_tui}" in
 497     yes | no) ;;
 498     "")  enable_tui=yes ;;
 499     *)
 500       AC_MSG_ERROR(Bad value for --enable-tui: ${enableval})
 501     ;;
 502   esac
 503 ])
 504 case ${enable_tui} in
 505   "yes" )
 506     if test -d "${srcdir}/tui" ; then
 507       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_TUI_OBS)"
 508       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_TUI_DEPS)"
 509       CONFIG_SRCS="${CONFIG_SRS} \$(SUBDIR_TUI_SRCS)"
 510       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_TUI_INITS)"
 511       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_TUI_CFLAGS)"
 512       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_TUI_ALL)"
 513       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_TUI_CLEAN)"
 514       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_TUI_INSTALL)"
 515       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_TUI_UNINSTALL)"
 516     fi
 517     ;;
 518 esac
 519
 520 AC_ARG_ENABLE(netrom,
 521 [  --enable-netrom         Enable NetROM support],
 522 [case "${enableval}" in
 523 yes)    enable_netrom=yes ;;
 524 no)     enable_netrom=no ;;
 525 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 526 esac])
 527
 528 if test "${enable_netrom}" = "yes"; then
 529         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 530         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 531 fi
 532
 533
 534 # NOTE: Don't add -Wall or -Wunused, they both include
 535 # -Wunused-parameter which reports bogus warnings.
 536 # NOTE: If you add to this list, remember to update
 537 # gdb/doc/gdbint.texinfo.
 538 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
 539 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized"
 540 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
 541 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
 542 # -Wchar-subscripts -Wuninitialized -Wtraditional -Wshadow -Wcast-qual
 543 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
 544 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
 545 # -Woverloaded-virtual -Winline -Werror"
 546 AC_ARG_ENABLE(build-warnings,
 547 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 548 [case "${enableval}" in
 549   yes)  ;;
 550   no)   build_warnings="-w";;
 551   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 552         build_warnings="${build_warnings} ${t}";;
 553   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 554         build_warnings="${t} ${build_warnings}";;
 555   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 556 esac
 557 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 558   echo "Setting compiler warning flags = $build_warnings" 6>&1
 559 fi])dnl
 560 AC_ARG_ENABLE(gdb-build-warnings,
 561 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
 562 [case "${enableval}" in
 563   yes)  ;;
 564   no)   build_warnings="-w";;
 565   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 566         build_warnings="${build_warnings} ${t}";;
 567   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 568         build_warnings="${t} ${build_warnings}";;
 569   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 570 esac
 571 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 572   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
 573 fi])dnl
 574 WARN_CFLAGS=""
 575 WERROR_CFLAGS=""
 576 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 577 then
 578     AC_MSG_CHECKING(compiler warning flags)
 579     # Separate out the -Werror flag as some files just cannot be
 580     # compiled with it enabled.
 581     for w in ${build_warnings}; do
 582         case $w in
 583         -Werr*) WERROR_CFLAGS=-Werror ;;
 584         *) # Check that GCC accepts it
 585             if $CC $w 2>&1 | grep 'unrecognized option' > /dev/null; then
 586                 :
 587             else
 588                 WARN_CFLAGS="${WARN_CFLAGS} $w"
 589             fi
 590         esac
 591     done
 592     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
 593 fi
 594 AC_SUBST(WARN_CFLAGS)
 595 AC_SUBST(WERROR_CFLAGS)
 596
 597 MMALLOC_CFLAGS=
 598 MMALLOC=
 599 AC_SUBST(MMALLOC_CFLAGS)
 600 AC_SUBST(MMALLOC)
 601
 602 AC_ARG_WITH(mmalloc,
 603 [  --with-mmalloc          Use memory mapped malloc package],
 604 [case "${withval}" in
 605   yes)  want_mmalloc=true ;;
 606   no)   want_mmalloc=false;;
 607   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 608 esac],[want_mmalloc=false])dnl
 609
 610 if test x$want_mmalloc = xtrue; then
 611    AC_DEFINE(USE_MMALLOC)
 612    AC_DEFINE(MMCHECK_FORCE)
 613    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 614    MMALLOC='../mmalloc/libmmalloc.a'
 615 fi
 616
 617 AC_ARG_WITH(included-regex,
 618 [  --with-included-regex          Use included regex],
 619 [case "${withval}" in
 620   yes)  want_included_regex=true ;;
 621   no)   want_included_regex=false;;
 622   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-included-regex option) ;;
 623 esac],[want_included_regex=true])dnl
 624
 625 if test $want_included_regex = false; then
 626   AC_MSG_CHECKING(for GNU regex)
 627   AC_CACHE_VAL(gdb_cv_have_gnu_regex,
 628 [AC_TRY_COMPILE([#include <gnu-versions.h>
 629 #include <sys/types.h>
 630 #include <regex.h>],
 631 [#if !defined _GNU_REGEX_INTERFACE_VERSION || !defined __GLIBC__ || __GLIBC__ < 2
 632 #error No valid GNU regex.
 633 #endif
 634 ],
 635                 [gdb_cv_have_gnu_regex=yes],
 636                 [gdb_cv_have_gnu_regex=no])])
 637   AC_MSG_RESULT($gdb_cv_have_gnu_regex)
 638   if test $gdb_cv_have_gnu_regex = no; then
 639         want_included_regex=true
 640   fi
 641 fi
 642
 643 if test x${want_included_regex} = xtrue; then
 644     REGEX="gnu-regex.o"
 645     AC_DEFINE(USE_INCLUDED_REGEX)
 646 fi
 647 AC_SUBST(REGEX)
 648
 649 # In the Cygwin environment, we need some additional flags.
 650 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 651 [AC_EGREP_CPP(lose, [
 652 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
 653 lose
 654 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 655
 656
 657 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
 658 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
 659 case ${host} in
 660   *go32* ) SER_HARDWIRE=ser-go32.o ;;
 661   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
 662 esac
 663 AC_SUBST(SER_HARDWIRE)
 664
 665
 666 dnl Figure out which term library to use.
 667 if test x$gdb_host = xgo32; then
 668   TERM_LIB=
 669 else
 670 if test x$gdb_cv_os_cygwin = xyes; then
 671   TERM_LIB='`if test -r ../libtermcap/libtermcap.a; then echo ../libtermcap/libtermcap.a; else echo -ltermcap; fi`'
 672 else
 673   TERM_LIB=
 674   AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses,
 675     AC_CHECK_LIB(Hcurses, tgetent, TERM_LIB=-lHcurses,
 676       AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib,
 677         AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap,
 678           AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses,
 679             AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo))))))
 680
 681   if test "x$TERM_LIB" = x
 682   then
 683     AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!)
 684   fi
 685 fi
 686 fi
 687 AC_SUBST(TERM_LIB)
 688
 689 # libreadline needs libuser32.a in a cygwin environment
 690 WIN32LIBS=
 691 if test x$gdb_cv_os_cygwin = xyes; then
 692     WIN32LIBS="-luser32"
 693     case "${target}" in
 694         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
 695         ;;
 696     esac
 697 fi
 698 AC_SUBST(WIN32LIBS)
 699
 700 LIBGUI="../libgui/src/libgui.a"
 701 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 702 AC_SUBST(LIBGUI)
 703 AC_SUBST(GUI_CFLAGS_X)
 704
 705 AC_ARG_WITH(cpu,
 706 [  --with-cpu=CPU          Set the default CPU variant to debug],
 707 [case "${target}" in
 708   powerpc-* | powerpcle-* )
 709     ## It would be nice to keep this table in sync with the one in
 710     ## gcc/configure.
 711     case "${with_cpu}" in
 712       ppc-uisa | rs6000 | 403 | 403GC | 505 | 860 | 601 | 602 | 603 \
 713       | 604 | 750 )
 714         ## Those are all handled in variants in rs6000-tdep.c, so they're fine.
 715       ;;
 716       common | power | power2 | rios | rios1 | rios2 | rsc | rsc1 )
 717         ## These are all RS6000 variants, as far as GDB is concerned.
 718         with_cpu=rs6000
 719       ;;
 720       603e | ec603e )
 721         with_cpu=603
 722       ;;
 723       604e )
 724         with_cpu=604
 725       ;;
 726       * )
 727         AC_MSG_WARN(GDB: unknown --with-cpu value: \`${with_cpu}'; using \`ppc-uisa'.)
 728         with_cpu=ppc-uisa
 729       ;;
 730     esac
 731   ;;
 732   * )
 733     AC_MSG_WARN(GDB may ignore the --with-cpu flag for ${target} targets)
 734   ;;
 735 esac
 736 AC_DEFINE_UNQUOTED(TARGET_CPU_DEFAULT, "${with_cpu}")
 737 ],)
 738
 739
 740 AC_ARG_ENABLE(gdbtk,
 741 [  --enable-gdbtk          Enable GDBTK GUI front end],
 742 [case "${enableval}" in
 743     yes)
 744         case "$host" in
 745         *go32*)
 746             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 747             enable_gdbtk=no ;;
 748         *windows*)
 749             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 750             enable_gdbtk=no ;;
 751         *)
 752             enable_gdbtk=yes ;;
 753         esac ;;
 754     no)
 755         enable_gdbtk=no  ;;
 756     *)
 757         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 758 esac],
 759 [
 760 # Default is on for everything but go32 and Cygwin
 761 case "$host" in
 762     *go32* | *windows*)
 763         ;;
 764     *)
 765         if test -d "${srcdir}/gdbtk" ; then
 766             enable_gdbtk=yes
 767         fi
 768         ;;
 769 esac
 770 ])
 771
 772 WIN32LDAPP=
 773 AC_SUBST(WIN32LIBS)
 774 AC_SUBST(WIN32LDAPP)
 775
 776 configdir="unix"
 777
 778 GDBTKLIBS=
 779 if test "${enable_gdbtk}" = "yes"; then
 780
 781     CY_AC_PATH_TCLCONFIG
 782     if test -z "${no_tcl}"; then
 783         CY_AC_LOAD_TCLCONFIG
 784         CY_AC_PATH_TKCONFIG
 785
 786         # If $no_tk is nonempty, then we can't do Tk, and there is no
 787         # point to doing Tcl.
 788         if test -z "${no_tk}"; then
 789            CY_AC_LOAD_TKCONFIG
 790            CY_AC_PATH_TCLH
 791            CY_AC_PATH_TKH
 792            CY_AC_PATH_ITCLH
 793            CY_AC_PATH_ITKH
 794            CY_AC_PATH_TIXH
 795
 796            # now look for Itcl library stuff
 797
 798            CY_AC_PATH_ITCLCONFIG
 799            if test -z "${no_itcl}"; then
 800              CY_AC_LOAD_ITCLCONFIG
 801              case "${host}" in
 802              *-*-cygwin*)
 803                 itcldir=../itcl/itcl/win/
 804                 ;;
 805              *)
 806                 itcldir=../itcl/itcl/unix/
 807                 ;;
 808              esac
 809
 810
 811              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
 812              ITCL_DEPS="${itcldir}${ITCL_LIB_FILE}"
 813            fi
 814
 815
 816            # now look for Itk library stuff
 817            CY_AC_PATH_ITKCONFIG
 818            if test -z "${no_itcl}"; then
 819              CY_AC_LOAD_ITKCONFIG
 820
 821              case "${host}" in
 822                *-*-cygwin*)
 823                  itkdir=../itcl/itk/win/
 824                  ;;
 825                *)
 826                  itkdir=../itcl/itk/unix/
 827                  ;;
 828                esac
 829
 830              ITKLIB="${ITK_BUILD_LIB_SPEC}"
 831              ITK_DEPS="${itkdir}${ITK_LIB_FILE}"
 832            fi
 833
 834            # now look for Tix library stuff
 835            CY_AC_PATH_TIXCONFIG
 836            if test -z "${no_tix}"; then
 837              CY_AC_LOAD_TIXCONFIG
 838              TIXLIB="${TIX_BUILD_LIB_SPEC}"
 839              TIX_DEPS="${TIX_BUILD_LOCATION}/${TIX_LIB_FILE}"
 840            fi
 841
 842            ENABLE_CFLAGS="$ENABLE_CFLAGS -DGDBTK"
 843            # Tcl/Tk 8.1 require -fwritable strings.  I don't
 844            # know whether 8.2 will or not, but I bet it will.
 845            # I don't have to worry about 7.x since we don't support it.
 846            GDBTK_CFLAGS=""
 847            if test "$GCC" = "yes"; then
 848                if test "$TCL_VERSION" != "8.0" ; then
 849                    GDBTK_CFLAGS="-fwritable-strings"
 850                fi
 851            fi
 852
 853            # Include some libraries that Tcl and Tk want.
 854            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 855            CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(ITK_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 856            # Yes, the ordering seems wrong here.  But it isn't.
 857            # TK_LIBS is the list of libraries that need to be linked
 858            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 859            # were in LIBS then any link tests after this point would
 860            # try to include things like `$(LIBGUI)', which wouldn't work.
 861            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 862            CONFIG_SRCS="${CONFIG_SRCS} gdbtk/generic/gdbtk.c gdbtk/generic/gdbtk-cmds.c gdbtk/generic/gdbtk-hooks.c gdbtk/generic/gdbtk-varobj.c gdbtk/generic/gdbtk-wrapper.c"
 863            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o gdbtk-varobj.o gdbtk-wrapper.o"
 864            CONFIG_INITS="${CONFIG_INITS} gdbtk/generic/gdbtk.c gdbtk/generic/gdbtk-cmds.c gdbtk/generic/gdbtk-hooks.c gdbtk/generic/gdbtk-varobj.c gdbtk/generic/gdbtk-wrapper.c"
 865            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
 866            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
 867            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
 868            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
 869
 870            if test x$gdb_cv_os_cygwin = xyes; then
 871               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
 872               WIN32LDAPP="-Wl,--subsystem,console"
 873               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 874            fi
 875         fi
 876     fi
 877 fi
 878
 879 AC_SUBST(X_CFLAGS)
 880 AC_SUBST(X_LDFLAGS)
 881 AC_SUBST(X_LIBS)
 882 AC_SUBST(ITCLLIB)
 883 AC_SUBST(ITCL_DEPS)
 884 AC_SUBST(ITKLIB)
 885 AC_SUBST(ITK_DEPS)
 886 AC_SUBST(TIXLIB)
 887 AC_SUBST(TIX_DEPS)
 888 AC_SUBST(GDBTKLIBS)
 889 AC_SUBST(GDBTK_CFLAGS)
 890
 891 AC_PATH_X
 892
 893
 894 # Unlike the sim directory, whether a simulator is linked is controlled by
 895 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
 896 # This code just checks for a few cases where we'd like to ignore those
 897 # definitions, even when they're present in the '.mt' file.  These cases
 898 # are when --disable-sim is specified, or if the simulator directory is
 899 # not part of the soruce tree.
 900 #
 901 AC_ARG_ENABLE(sim,
 902 [  --enable-sim            Link gdb with simulator],
 903 [echo "enable_sim = $enable_sim";
 904  echo "enableval = ${enableval}";
 905  case "${enableval}" in
 906   yes) ignore_sim=false ;;
 907   no)  ignore_sim=true ;;
 908   *)   ignore_sim=false ;;
 909  esac],
 910 [ignore_sim=false])
 911
 912 if test ! -d "${srcdir}/../sim"; then
 913   ignore_sim=true
 914 fi
 915
 916 if test "${ignore_sim}" = "true"; then
 917     IGNORE_SIM="SIM="
 918     IGNORE_SIM_OBS="SIM_OBS="
 919 else
 920     IGNORE_SIM=""
 921     IGNORE_SIM_OBS=""
 922     AC_DEFINE(WITH_SIM)
 923 fi
 924 AC_SUBST(IGNORE_SIM)
 925 AC_SUBST(IGNORE_SIM_OBS)
 926
 927 AC_SUBST(ENABLE_CFLAGS)
 928
 929 AC_SUBST(CONFIG_OBS)
 930 AC_SUBST(CONFIG_DEPS)
 931 AC_SUBST(CONFIG_SRCS)
 932 AC_SUBST(CONFIG_INITS)
 933 AC_SUBST(CONFIG_ALL)
 934 AC_SUBST(CONFIG_CLEAN)
 935 AC_SUBST(CONFIG_INSTALL)
 936 AC_SUBST(CONFIG_UNINSTALL)
 937
 938 # Begin stuff to support --enable-shared
 939 AC_ARG_ENABLE(shared,
 940 [  --enable-shared         Use shared libraries],
 941 [case "${enableval}" in
 942   yes) shared=true ;;
 943   no)  shared=false ;;
 944   *) shared=true ;;
 945 esac])dnl
 946
 947 HLDFLAGS=
 948 HLDENV=
 949 # If we have shared libraries, try to set rpath reasonably.
 950 if test "${shared}" = "true"; then
 951   case "${host}" in
 952   *-*-hpux*)
 953     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 954     ;;
 955   *-*-irix5* | *-*-irix6*)
 956     HLDFLAGS='-Wl,-rpath,$(libdir)'
 957     ;;
 958   *-*-linux*aout*)
 959     ;;
 960   *-*-linux* | *-pc-linux-gnu*)
 961     HLDFLAGS='-Wl,-rpath,$(libdir)'
 962     ;;
 963   *-*-solaris*)
 964     HLDFLAGS='-R $(libdir)'
 965     ;;
 966   *-*-sysv4*)
 967     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 968     ;;
 969   esac
 970 fi
 971
 972 # On SunOS, if the linker supports the -rpath option, use it to
 973 # prevent ../bfd and ../opcodes from being included in the run time
 974 # search path.
 975 case "${host}" in
 976   *-*-sunos*)
 977     echo 'main () { }' > conftest.c
 978     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 979     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 980       :
 981     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 982       :
 983     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 984       :
 985     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 986       :
 987     elif test "${shared}" = "true"; then
 988       HLDFLAGS='-Wl,-rpath=$(libdir)'
 989     else
 990       HLDFLAGS='-Wl,-rpath='
 991     fi
 992     rm -f conftest.t conftest.c conftest
 993     ;;
 994 esac
 995 AC_SUBST(HLDFLAGS)
 996 AC_SUBST(HLDENV)
 997 # End stuff to support --enable-shared
 998
 999 # target_subdir is used by the testsuite to find the target libraries.
1000 target_subdir=
1001 if test "${host}" != "${target}"; then
1002     target_subdir="${target_alias}/"
1003 fi
1004 AC_SUBST(target_subdir)
1005
1006 frags=
1007 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1008 if test ! -f ${host_makefile_frag}; then
1009 AC_MSG_ERROR("*** Gdb does not support host ${host}")
1010 fi
1011 frags="$frags $host_makefile_frag"
1012
1013 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1014 if test ! -f ${target_makefile_frag}; then
1015 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1016 fi
1017 frags="$frags $target_makefile_frag"
1018
1019 AC_SUBST_FILE(host_makefile_frag)
1020 AC_SUBST_FILE(target_makefile_frag)
1021 AC_SUBST(frags)
1022
1023 changequote(,)dnl
1024 hostfile=`sed -n '
1025 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1026 ' ${host_makefile_frag}`
1027
1028 targetfile=`sed -n '
1029 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1030 ' ${target_makefile_frag}`
1031
1032 GDB_MULTI_ARCH=`sed -n '
1033 s/GDB_MULTI_ARCH[       ]*=[    ]*\([^  ]*\)[   ]*/\1/p
1034 ' ${target_makefile_frag}`
1035
1036 # these really aren't orthogonal true/false values of the same condition,
1037 # but shells are slow enough that I like to reuse the test conditions
1038 # whenever possible
1039 if test "${target}" = "${host}"; then
1040 nativefile=`sed -n '
1041 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1042 ' ${host_makefile_frag}`
1043 # else
1044 # GDBserver is only useful in a "native" enviroment
1045 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
1046 fi
1047 changequote([,])
1048
1049 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1050 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1051 # in the target specific makefile frag.  Eventually gdb_multi_arch=yes
1052 # will be the default.
1053 if test x"${GDB_MULTI_ARCH}" = x ; then
1054     case "${gdb_multi_arch}" in
1055     yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1056     no ) GDB_MULTI_ARCH=0 ;;
1057     0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1058     esac
1059 fi
1060 if test x"${GDB_MULTI_ARCH}" != x ; then
1061     AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1062 fi
1063 # Warn the user when they use an old pratice
1064 case "${GDB_MULTI_ARCH}" in
1065     "" ) ;;
1066     0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1067         AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1068     GDB_MULTI_ARCH_PURE )
1069         if test x"${targetfile}" != x ; then
1070             AC_MSG_WARN("GDB: Ingoring TM_FILE in ${target_makefile_frag}")
1071             targetfile=""
1072         fi ;;
1073     *)  AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1074 esac
1075
1076
1077 SUBDIRS="doc testsuite nlm"
1078 if test "${enable_multi_ice}" = "yes"; then
1079   SUBDIRS="${SUBDIRS} multi-ice"
1080 fi
1081
1082 AC_SUBST(SUBDIRS)
1083
1084 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1085 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1086 # version.
1087
1088 files=
1089 links=
1090
1091 rm -f xm.h
1092 xm_h=""
1093 if test "${hostfile}" != ""; then
1094     xm_h=xm.h
1095     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1096     files="${files} ${GDB_XM_FILE}"
1097     links="${links} xm.h"
1098     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1099 fi
1100 AC_SUBST(xm_h)
1101
1102 rm -f tm.h
1103 tm_h=""
1104 if test "${targetfile}" != ""; then
1105     tm_h=tm.h
1106     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1107     files="${files} ${GDB_TM_FILE}"
1108     links="${links} tm.h"
1109     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1110 fi
1111 AC_SUBST(tm_h)
1112
1113 rm -f nm.h
1114 nm_h=""
1115 if test "${nativefile}" != ""; then
1116     nm_h=nm.h
1117     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1118     files="${files} ${GDB_NM_FILE}"
1119     links="${links} nm.h"
1120     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1121 fi
1122 AC_SUBST(nm_h)
1123
1124 AC_PROG_LN_S
1125
1126 AC_LINK_FILES($files, $links)
1127
1128 dnl Check for exe extension set on certain hosts (e.g. Win32)
1129 AC_EXEEXT
1130
1131 AC_CONFIG_SUBDIRS($configdirs)
1132 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1133 [
1134 dnl Autoconf doesn't provide a mechanism for modifying definitions
1135 dnl provided by makefile fragments.
1136 dnl
1137 if test "${nativefile}" = ""; then
1138 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
1139         < Makefile > Makefile.tem
1140 mv -f Makefile.tem Makefile
1141 fi
1142
1143 changequote(,)dnl
1144 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1145 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1146 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1147 mv -f Makefile.tmp Makefile
1148 changequote([,])dnl
1149
1150
1151 case x$CONFIG_HEADERS in
1152 xconfig.h:config.in)
1153 echo > stamp-h ;;
1154 esac
1155 ],
1156 [
1157 gdb_host_cpu=$gdb_host_cpu
1158 gdb_target_cpu=$gdb_target_cpu
1159 nativefile=$nativefile
1160 ])
1161
1162 exit 0