gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  38 dnl link with the correct libraries.
  39 ALL_LINGUAS=
  40 CY_GNU_GETTEXT
  41
  42 dnl List of object files added by configure.
  43
  44 CONFIG_OBS=
  45 CONFIG_DEPS=
  46 CONFIG_SRCS=
  47
  48 configdirs="doc testsuite"
  49
  50 dnl
  51 changequote(,)dnl
  52
  53 . ${srcdir}/configure.host
  54
  55 . ${srcdir}/configure.tgt
  56
  57 dnl
  58 changequote([,])dnl
  59
  60 AC_PROG_INSTALL
  61 AC_CHECK_TOOL(AR, ar)
  62 AC_CHECK_TOOL(RANLIB, ranlib, :)
  63 AC_PROG_YACC
  64 AC_PROG_AWK
  65
  66 AC_ARG_PROGRAM
  67
  68 AC_TYPE_SIGNAL
  69
  70 AC_HEADER_STDC
  71 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h libintl.h wctype.h wchar.h)
  72
  73 AC_HEADER_STAT
  74
  75 AC_C_CONST
  76
  77 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction isascii bzero bcopy memcpy btowc)
  78 AC_FUNC_ALLOCA
  79
  80 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  81 if test "${target}" = "${host}"; then
  82   case "${host}" in
  83   i[[3456]]86-*-linux*)
  84         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  85         AC_DEFINE(sys_quotactl)
  86         ;;
  87   esac
  88 fi
  89
  90 AC_MSG_CHECKING([for gregset_t type])
  91 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  92 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  93 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  94 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  95 if test $gdb_cv_have_gregset_t = yes; then
  96   AC_DEFINE(HAVE_GREGSET_T)
  97 fi
  98
  99 AC_MSG_CHECKING([for fpregset_t type])
 100 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 101 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 102 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 103 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 104 if test $gdb_cv_have_fpregset_t = yes; then
 105   AC_DEFINE(HAVE_FPREGSET_T)
 106 fi
 107
 108 dnl See if host has libm.  This is usually needed by simulators.
 109 AC_CHECK_LIB(m, main)
 110
 111 dnl See if compiler supports "long long" type.
 112
 113 AC_MSG_CHECKING(for long long support in compiler)
 114 AC_CACHE_VAL(gdb_cv_c_long_long,
 115 [AC_TRY_COMPILE(, [
 116   extern long long foo;
 117   switch (foo & 2) { case 0: return 1; }
 118 ],
 119 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 120 AC_MSG_RESULT($gdb_cv_c_long_long)
 121 if test $gdb_cv_c_long_long = yes; then
 122   AC_DEFINE(CC_HAS_LONG_LONG)
 123 fi
 124
 125 dnl See if the compiler and runtime support printing long long
 126
 127 AC_MSG_CHECKING(for long long support in printf)
 128 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 129 [AC_TRY_RUN([
 130 int main () {
 131   char buf[32];
 132   long long l = 0;
 133   l = (l << 16) + 0x0123;
 134   l = (l << 16) + 0x4567;
 135   l = (l << 16) + 0x89ab;
 136   l = (l << 16) + 0xcdef;
 137   sprintf (buf, "0x%016llx", l);
 138   return (strcmp ("0x0123456789abcdef", buf));
 139 }],
 140 gdb_cv_printf_has_long_long=yes,
 141 gdb_cv_printf_has_long_long=no,
 142 gdb_cv_printf_has_long_long=no)])
 143 if test $gdb_cv_printf_has_long_long = yes; then
 144   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 145 fi
 146 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 147
 148 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 149 dnl because autoconf complains about cross-compilation issues.  However, this
 150 dnl code uses the same variables as the macro for compatibility.
 151
 152 AC_MSG_CHECKING(for long double support in compiler)
 153 AC_CACHE_VAL(ac_cv_c_long_double,
 154 [AC_TRY_COMPILE(, [long double foo;],
 155 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 156 AC_MSG_RESULT($ac_cv_c_long_double)
 157 if test $ac_cv_c_long_double = yes; then
 158   AC_DEFINE(HAVE_LONG_DOUBLE)
 159 fi
 160
 161 dnl See if the compiler and runtime support printing long doubles
 162
 163 AC_MSG_CHECKING(for long double support in printf)
 164 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 165 [AC_TRY_RUN([
 166 int main () {
 167   char buf[16];
 168   long double f = 3.141592653;
 169   sprintf (buf, "%Lg", f);
 170   return (strncmp ("3.14159", buf, 7));
 171 }],
 172 gdb_cv_printf_has_long_double=yes,
 173 gdb_cv_printf_has_long_double=no,
 174 gdb_cv_printf_has_long_double=no)])
 175 if test $gdb_cv_printf_has_long_double = yes; then
 176   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 177 fi
 178 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 179
 180 dnl See if the compiler and runtime support scanning long doubles
 181
 182 AC_MSG_CHECKING(for long double support in scanf)
 183 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 184 [AC_TRY_RUN([
 185 int main () {
 186   char *buf = "3.141592653";
 187   long double f = 0;
 188   sscanf (buf, "%Lg", &f);
 189   return !(f > 3.14159 && f < 3.14160);
 190 }],
 191 gdb_cv_scanf_has_long_double=yes,
 192 gdb_cv_scanf_has_long_double=no,
 193 gdb_cv_scanf_has_long_double=no)])
 194 if test $gdb_cv_scanf_has_long_double = yes; then
 195   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 196 fi
 197 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 198
 199 AC_FUNC_MMAP
 200
 201 BFD_NEED_DECLARATION(malloc)
 202 BFD_NEED_DECLARATION(realloc)
 203 BFD_NEED_DECLARATION(free)
 204
 205 BFD_NEED_DECLARATION(strerror)
 206
 207 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 208 dnl we must explicitly test for version 1 of the library because version 0
 209 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 210
 211 dnl Note that we only want this if we are both native (host == target), and
 212 dnl not doing a canadian cross build (build == host).
 213
 214 if test ${build} = ${host} -a ${host} = ${target} ; then
 215    case ${host_os} in
 216    hpux*)
 217       AC_MSG_CHECKING(for HPUX/OSF thread support)
 218       if test -f /usr/include/dce/cma_config.h ; then
 219          if test "$GCC" = "yes" ; then
 220             AC_MSG_RESULT(yes)
 221             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 222             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 223             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 224          else
 225             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 226          fi
 227       else
 228          AC_MSG_RESULT(no)
 229       fi
 230       ;;
 231    solaris*)
 232       AC_MSG_CHECKING(for Solaris thread debugging library)
 233       if test -f /usr/lib/libthread_db.so.1 ; then
 234          AC_MSG_RESULT(yes)
 235          AC_DEFINE(HAVE_THREAD_DB_LIB)
 236          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 237          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 238          AC_CHECK_LIB(dl, dlopen)
 239          if test "$GCC" = "yes" ; then
 240             # The GNU linker requires the -export-dynamic option to make
 241             # all symbols visible in the dynamic symbol table.
 242             hold_ldflags=$LDFLAGS
 243             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 244             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 245             AC_TRY_LINK(, [int i;], found=yes, found=no)
 246             LDFLAGS=$hold_ldflags
 247             AC_MSG_RESULT($found)
 248             if test $found = yes; then
 249                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 250             fi
 251          fi
 252       else
 253          AC_MSG_RESULT(no)
 254       fi
 255       ;;
 256    esac
 257    AC_SUBST(CONFIG_LDFLAGS)
 258 fi
 259
 260 dnl Handle optional features that can be enabled.
 261 ENABLE_CFLAGS=
 262
 263 AC_ARG_ENABLE(netrom,
 264 [  --enable-netrom ],
 265 [case "${enableval}" in
 266 yes)    enable_netrom=yes ;;
 267 no)     enable_netrom=no ;;
 268 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 269 esac])
 270
 271 if test "${enable_netrom}" = "yes"; then
 272         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 273         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 274 fi
 275
 276 MMALLOC_CFLAGS=
 277 MMALLOC=
 278 AC_SUBST(MMALLOC_CFLAGS)
 279 AC_SUBST(MMALLOC)
 280
 281 AC_ARG_WITH(mmalloc,
 282 [  --with-mmalloc             use memory mapped malloc package],
 283 [case "${withval}" in
 284   yes)  want_mmalloc=true ;;
 285   no)   want_mmalloc=false;;
 286   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 287 esac],[want_mmalloc=false])dnl
 288
 289 if test x$want_mmalloc = xtrue; then
 290    AC_DEFINE(USE_MMALLOC)
 291    AC_DEFINE(MMCHECK_FORCE)
 292    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 293    MMALLOC='../mmalloc/libmmalloc.a'
 294 fi
 295
 296 # start-sanitize-gdbtk
 297 ENABLE_IDE=
 298 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 299 if test "$enable_ide" = yes; then
 300    enable_ide=yes
 301    ENABLE_IDE=1
 302 else
 303    enable_ide=no
 304 fi
 305 AC_SUBST(ENABLE_IDE)
 306
 307 ENABLE_GDBTK=
 308
 309 AC_ARG_ENABLE(gdbtk,
 310 [  --enable-gdbtk ],
 311 [case "${enableval}" in
 312     yes)
 313         case "$host" in
 314         *go32*)
 315             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 316             enable_gdbtk=no ;;
 317         *windows*)
 318             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 319             enable_gdbtk=no ;;
 320         *)
 321             enable_gdbtk=yes ;;
 322         esac ;;
 323     no)
 324         enable_gdbtk=no  ;;
 325     *)
 326         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 327 esac],
 328 [
 329 # Default is on for everything but go32 and cygwin32
 330 case "$host" in
 331     *go32* | *windows*)
 332         ;;
 333     *)
 334         enable_gdbtk=yes ;;
 335     esac
 336 ])
 337
 338 # In the cygwin32 environment, we need some additional flags.
 339 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 340 [AC_EGREP_CPP(lose, [
 341 #ifdef __CYGWIN32__
 342 lose
 343 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 344
 345 WIN32LIBS=
 346 WIN32LDAPP=
 347 AC_SUBST(WIN32LIBS)
 348 AC_SUBST(WIN32LDAPP)
 349
 350 WINDRES=${WINDRES-windres}
 351 AC_SUBST(WINDRES)
 352
 353 if test x$gdb_cv_os_cygwin32 = xyes; then
 354     if test x$enable_ide = xyes; then
 355         WIN32LIBS="-ladvapi32"
 356     fi
 357 fi
 358
 359 configdir="unix"
 360
 361 GDBTKLIBS=
 362 if test "${enable_gdbtk}" = "yes"; then
 363
 364     CY_AC_PATH_TCLCONFIG
 365     if test -z "${no_tcl}"; then
 366         CY_AC_LOAD_TCLCONFIG
 367         CY_AC_PATH_TKCONFIG
 368
 369         # If $no_tk is nonempty, then we can't do Tk, and there is no
 370         # point to doing Tcl.
 371         if test -z "${no_tk}"; then
 372            CY_AC_LOAD_TKCONFIG
 373            CY_AC_PATH_TCLH
 374            CY_AC_PATH_TKH
 375            CY_AC_PATH_ITCLH
 376            CY_AC_PATH_TIX
 377
 378            # now look for tix library stuff
 379            TIXVERSION=4.1.8.0
 380            . ${ac_cv_c_tclconfig}/tclConfig.sh
 381            case "${host}" in
 382            *-*-cygwin32*)
 383                 tixdir=../tix/win/tcl8.0
 384                 ;;
 385            *)
 386                 tixdir=../tix/unix/tk8.0
 387                 ;;
 388            esac
 389            if test "${TCL_SHARED_BUILD}" = "1"; then
 390                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 391
 392                 # Can't win them all: SunOS 4 (others?) appends a version
 393                 # number after the ".so"
 394                 case "${host}" in
 395                 *-*-sunos4*)
 396                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 397                 esac
 398
 399            else
 400                 TIX_LIB_EXT=".a"
 401            fi
 402
 403            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 404                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 405                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 406            else
 407                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 408                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 409            fi
 410
 411            ENABLE_GDBTK=1
 412
 413            # Include some libraries that Tcl and Tk want.
 414            if test "${enable_ide}" = "yes"; then
 415               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 416               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 417            else
 418               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 419               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 420            fi
 421            # Yes, the ordering seems wrong here.  But it isn't.
 422            # TK_LIBS is the list of libraries that need to be linked
 423            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 424            # were in LIBS then any link tests after this point would
 425            # try to include things like `$(LIBGUI)', which wouldn't work.
 426            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 427            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 428
 429            if test x$gdb_cv_os_cygwin32 = xyes; then
 430               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 431               WIN32LDAPP="-Wl,--subsystem,console"
 432               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 433            fi
 434         fi
 435     fi
 436 fi
 437
 438 AC_SUBST(ENABLE_GDBTK)
 439 AC_SUBST(X_CFLAGS)
 440 AC_SUBST(X_LDFLAGS)
 441 AC_SUBST(X_LIBS)
 442 AC_SUBST(TIXLIB)
 443 AC_SUBST(TIX_DEPS)
 444 AC_SUBST(GDBTKLIBS)
 445 # end-sanitize-gdbtk
 446
 447 AC_PATH_X
 448 # start-sanitize-sky
 449 # Enable GPU2 library for MIPS simulator
 450 AC_ARG_WITH(sim-gpu2,
 451 [  --with-sim-gpu2=path                 Use GPU2 library under given directory],
 452 [case "${target}" in
 453   mips*-sky-*)
 454     if test -d "${withval}"
 455     then
 456       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 lXext"
 457     else
 458       AC_MSG_WARN([Directory ${withval} does not exist.])
 459     fi ;;
 460   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 461 esac])dnl
 462
 463 # Enable target accurate FP library
 464 AC_ARG_WITH(sim-funit,
 465 [  --with-sim-funit=path                Use target FP lib under given directory],
 466 [case "${target}" in
 467   mips*-sky-*)
 468     if test -d "${withval}"
 469     then
 470       LIBS="${LIBS} -L${withval}/lib -lfunit"
 471     else
 472       AC_MSG_WARN([Directory ${withval} does not exist.])
 473     fi ;;
 474   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 475 esac])dnl
 476 # end-sanitize-sky
 477
 478 dnl Solaris puts wctype in /usr/lib/libw.a
 479 AC_CHECK_LIB(w, wctype, [LIBS="$LIBS -lw"])
 480
 481 AC_SUBST(ENABLE_CFLAGS)
 482
 483 AC_SUBST(CONFIG_OBS)
 484 AC_SUBST(CONFIG_DEPS)
 485 AC_SUBST(CONFIG_SRCS)
 486
 487 # Begin stuff to support --enable-shared
 488 AC_ARG_ENABLE(shared,
 489 [  --enable-shared         use shared libraries],
 490 [case "${enableval}" in
 491   yes) shared=true ;;
 492   no)  shared=false ;;
 493   *) shared=true ;;
 494 esac])dnl
 495
 496 HLDFLAGS=
 497 HLDENV=
 498 # If we have shared libraries, try to set rpath reasonably.
 499 if test "${shared}" = "true"; then
 500   case "${host}" in
 501   *-*-hpux*)
 502     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 503     ;;
 504   *-*-irix5* | *-*-irix6*)
 505     HLDFLAGS='-Wl,-rpath,$(libdir)'
 506     ;;
 507   *-*-linux*aout*)
 508     ;;
 509   *-*-linux* | *-pc-linux-gnu)
 510     HLDFLAGS='-Wl,-rpath,$(libdir)'
 511     ;;
 512   *-*-solaris*)
 513     HLDFLAGS='-R $(libdir)'
 514     ;;
 515   *-*-sysv4*)
 516     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 517     ;;
 518   esac
 519 fi
 520
 521 # On SunOS, if the linker supports the -rpath option, use it to
 522 # prevent ../bfd and ../opcodes from being included in the run time
 523 # search path.
 524 case "${host}" in
 525   *-*-sunos*)
 526     echo 'main () { }' > conftest.c
 527     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 528     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 529       :
 530     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 531       :
 532     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 533       :
 534     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 535       :
 536     elif test "${shared}" = "true"; then
 537       HLDFLAGS='-Wl,-rpath=$(libdir)'
 538     else
 539       HLDFLAGS='-Wl,-rpath='
 540     fi
 541     rm -f conftest.t conftest.c conftest
 542     ;;
 543 esac
 544 AC_SUBST(HLDFLAGS)
 545 AC_SUBST(HLDENV)
 546 # End stuff to support --enable-shared
 547
 548 # target_subdir is used by the testsuite to find the target libraries.
 549 target_subdir=
 550 if test "${host}" != "${target}"; then
 551     target_subdir="${target_alias}/"
 552 fi
 553 AC_SUBST(target_subdir)
 554
 555 frags=
 556 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 557 if test ! -f ${host_makefile_frag}; then
 558 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 559 fi
 560 frags="$frags $host_makefile_frag"
 561
 562 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 563 if test ! -f ${target_makefile_frag}; then
 564 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 565 fi
 566 frags="$frags $target_makefile_frag"
 567
 568 AC_SUBST_FILE(host_makefile_frag)
 569 AC_SUBST_FILE(target_makefile_frag)
 570 AC_SUBST(frags)
 571
 572 changequote(,)dnl
 573 hostfile=`sed -n '
 574 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 575 ' ${host_makefile_frag}`
 576
 577 targetfile=`sed -n '
 578 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 579 ' ${target_makefile_frag}`
 580
 581 # these really aren't orthogonal true/false values of the same condition,
 582 # but shells are slow enough that I like to reuse the test conditions
 583 # whenever possible
 584 if test "${target}" = "${host}"; then
 585 nativefile=`sed -n '
 586 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 587 ' ${host_makefile_frag}`
 588 # else
 589 # GDBserver is only useful in a "native" enviroment
 590 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 591 fi
 592 changequote([,])
 593
 594 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 595 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 596 # corresponding links.  But we have to remove the xm.h files and tm.h
 597 # files anyway, e.g. when switching from "configure host" to
 598 # "configure none".
 599
 600 files=
 601 links=
 602 rm -f xm.h
 603 if test "${hostfile}" != ""; then
 604 files="${files} config/${gdb_host_cpu}/${hostfile}"
 605 links="${links} xm.h"
 606 fi
 607 rm -f tm.h
 608 if test "${targetfile}" != ""; then
 609 files="${files} config/${gdb_target_cpu}/${targetfile}"
 610 links="${links} tm.h"
 611 fi
 612 rm -f nm.h
 613 if test "${nativefile}" != ""; then
 614 files="${files} config/${gdb_host_cpu}/${nativefile}"
 615 links="${links} nm.h"
 616 else
 617 # A cross-only configuration.
 618 files="${files} config/nm-empty.h"
 619 links="${links} nm.h"
 620 fi
 621 # start-sanitize-gdbtk
 622 AC_PROG_LN_S
 623 # Make it possible to use the GUI without doing a full install
 624 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 625   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 626   echo linking $srcdir/gdbtcl to gdbtcl
 627   $LN_S $srcdir/gdbtcl gdbtcl
 628   else
 629   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 630   echo "         " make install before you are able to run the GUI.
 631   fi
 632 fi
 633 # end-sanitize-gdbtk
 634
 635 AC_LINK_FILES($files, $links)
 636
 637 dnl Check for exe extension set on certain hosts (e.g. Win32)
 638 AM_EXEEXT
 639
 640 AC_CONFIG_SUBDIRS($configdirs)
 641 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 642 [
 643 dnl Autoconf doesn't provide a mechanism for modifying definitions
 644 dnl provided by makefile fragments.
 645 dnl
 646 if test "${nativefile}" = ""; then
 647 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 648         < Makefile > Makefile.tem
 649 mv -f Makefile.tem Makefile
 650 fi
 651
 652 changequote(,)dnl
 653 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 654 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 655 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 656 mv -f Makefile.tmp Makefile
 657 changequote([,])dnl
 658
 659 case x$CONFIG_HEADERS in
 660 xconfig.h:config.in)
 661 echo > stamp-h ;;
 662 esac
 663 ],
 664 [
 665 gdb_host_cpu=$gdb_host_cpu
 666 gdb_target_cpu=$gdb_target_cpu
 667 nativefile=$nativefile
 668 ])
 669
 670 exit 0
 671