gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000,
   3 dnl 2001 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_AIX
  30 AC_ISC_POSIX
  31 AM_PROG_CC_STDC
  32
  33 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  34 AC_CANONICAL_SYSTEM
  35
  36 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  37 dnl link with the correct libraries.
  38 ALL_LINGUAS=
  39 CY_GNU_GETTEXT
  40
  41 dnl List of object files added by configure.
  42
  43 CONFIG_OBS=
  44 CONFIG_LIB_OBS=
  45 CONFIG_DEPS=
  46 CONFIG_SRCS=
  47 CONFIG_INITS=
  48 ENABLE_CFLAGS=
  49 CONFIG_ALL=
  50 CONFIG_CLEAN=
  51 CONFIG_INSTALL=
  52 CONFIG_UNINSTALL=
  53
  54 configdirs="doc testsuite"
  55
  56 AC_ARG_ENABLE(multi-ice,
  57 [  --enable-multi-ice            Build the multi-ice-gdb-server],
  58 [case "${enableval}" in
  59     yes ) enable_multi_ice="yes" ;;
  60     no)  enable_multi_ice="no" ;;
  61     *) AC_MSG_ERROR(Bad value for --enable-multi-ice: ${enableval}) ;;
  62   esac
  63 ])
  64
  65 if test "${enable_multi_ice}" = "yes"; then
  66   configdirs="${configdirs} multi-ice"
  67 fi
  68
  69 dnl
  70 changequote(,)dnl
  71
  72 . ${srcdir}/configure.host
  73
  74 . ${srcdir}/configure.tgt
  75
  76 targ=${target} ; . ${srcdir}/../bfd/config.bfd
  77
  78 dnl
  79 changequote([,])dnl
  80
  81 dnl use BFD to determine the default architecture and byte order
  82 dnl (bfd_vec->byteorder provides the latter).
  83 targ=${target}
  84 . ${srcdir}/../bfd/config.bfd
  85
  86 dnl We only want the first arch, if there is more than one.
  87 targ_archs=`echo ${targ_archs} | sed -e 's/ .*//;'`
  88
  89 if test x"${targ_archs}" != x ; then
  90     AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, ${targ_archs})
  91 fi
  92 if test x"${targ_defvec}" != x ; then
  93     AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, ${targ_defvec})
  94 fi
  95
  96 AC_PROG_AWK
  97 AC_PROG_INSTALL
  98 AC_CHECK_TOOL(AR, ar)
  99 AC_CHECK_TOOL(RANLIB, ranlib, :)
 100 AC_CHECK_TOOL(DLLTOOL, dlltool)
 101 AC_CHECK_TOOL(WINDRES, windres)
 102 AC_PROG_YACC
 103
 104 dnl MiG is needed for the Hurd.
 105 AC_CHECK_TOOL(MIG, mig)
 106
 107 AC_ARG_PROGRAM
 108
 109 AC_TYPE_SIGNAL
 110
 111 AC_HEADER_STDC
 112
 113 dnl Solaris 7 needs _MSE_INT_H defined to avoid a clash between <widec.h>
 114 dnl and <wchar.h> that causes AC_CHECK_HEADERS to think <curses.h> doesn't
 115 dnl exist.
 116
 117 case $host_os in solaris2.7 | solaris2.8) case "$GCC" in yes)
 118     AC_DEFINE(_MSE_INT_H)
 119 esac; esac
 120
 121 AC_CHECK_HEADERS(ctype.h endian.h link.h thread_db.h proc_service.h \
 122         memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
 123         string.h sys/procfs.h sys/ptrace.h sys/reg.h stdint.h \
 124         term.h termio.h termios.h unistd.h wait.h sys/wait.h \
 125         wchar.h wctype.h asm/debugreg.h sys/debugreg.h sys/select.h \
 126         time.h sys/file.h sys/ioctl.h sys/user.h \
 127         dirent.h sys/ndir.h sys/dir.h ndir.h \
 128         curses.h ncurses.h \
 129         poll.h sys/poll.h)
 130 AC_HEADER_STAT
 131
 132 AC_C_CONST
 133
 134 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc poll sigprocmask)
 135 AC_FUNC_VFORK
 136 AC_FUNC_ALLOCA
 137
 138 # See if machine/reg.h supports the %fs and %gs i386 segment registers.
 139 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 140 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 141 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 142 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 143 if test $gdb_cv_struct_reg_r_fs = yes; then
 144   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 145 fi
 146 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 147 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 148 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 149 if test $gdb_cv_struct_reg_r_gs = yes; then
 150   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 151 fi
 152
 153 dnl See if ptrace.h provides the PTRACE_GETREGS request.
 154 AC_MSG_CHECKING(for PTRACE_GETREGS)
 155 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 156 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 157                 [PTRACE_GETREGS;],
 158                 [gdb_cv_have_ptrace_getregs=yes],
 159                 [gdb_cv_have_ptrace_getregs=no])])
 160 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 161 if test $gdb_cv_have_ptrace_getregs = yes; then
 162   AC_DEFINE(HAVE_PTRACE_GETREGS)
 163 fi
 164
 165 dnl See if ptrace.h provides the PTRACE_GETFPXREGS request.
 166 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 167 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 168 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 169                 [PTRACE_GETFPXREGS;],
 170                 [gdb_cv_have_ptrace_getfpxregs=yes],
 171                 [gdb_cv_have_ptrace_getfpxregs=no])])
 172 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 173 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 174   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 175 fi
 176
 177 AC_CHECK_LIB(socket, socketpair)
 178 AC_CHECK_FUNCS(socketpair)
 179
 180
 181 BFD_NEED_DECLARATION(malloc)
 182 BFD_NEED_DECLARATION(realloc)
 183 BFD_NEED_DECLARATION(free)
 184 BFD_NEED_DECLARATION(strerror)
 185 BFD_NEED_DECLARATION(strdup)
 186 BFD_NEED_DECLARATION(strstr)
 187
 188
 189 # The following save_state_t checkery is only necessary for HPUX
 190 # versions earlier than 10.20.  When those fade from memory, this
 191 # could be expunged. --jsm 1999-03-22
 192
 193 AC_MSG_CHECKING(for HPUX save_state structure)
 194 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 195                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 196 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 197                 gdb_cv_hpux_sswide=no)
 198 if test $gdb_cv_hpux_savestate = yes
 199 then
 200   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 201 fi
 202 if test $gdb_cv_hpux_sswide = yes
 203 then
 204   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 205 fi
 206 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 207
 208
 209 # If we are configured native on GNU/Linux, work around problems with
 210 # sys/procfs.h
 211 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 212
 213 if test "${target}" = "${host}"; then
 214   case "${host}" in
 215   i[[3456]]86-*-linux*)
 216         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 217         AC_DEFINE(sys_quotactl)
 218         ;;
 219   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5*)
 220       AC_DEFINE(NEW_PROC_API)
 221       ;;
 222   *-*-solaris2.[[678]])
 223       AC_DEFINE(NEW_PROC_API)
 224       ;;
 225   esac
 226 fi
 227
 228 if test "$ac_cv_header_sys_procfs_h" = yes; then
 229   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 230   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 231   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 232   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 233   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 234   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 235   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 236   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 237   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 238   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 239
 240   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 241   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 242
 243   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 244   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 245     [AC_TRY_COMPILE([#define _SYSCALL32
 246 #include <sys/link.h>], [struct link_map32 l;],
 247      gdb_cv_have_struct_link_map32=yes,
 248      gdb_cv_have_struct_link_map32=no)])
 249   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 250   if test $gdb_cv_have_struct_link_map32 = yes; then
 251     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 252   fi
 253
 254   dnl Check for broken prfpregset_t type
 255
 256   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 257   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 258   dnl instead of the struct itself).  We detect this here, and work
 259   dnl around it in lin-thread.c.
 260
 261   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 262     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 263     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 264       [AC_TRY_RUN([#include <sys/procfs.h>
 265        int main ()
 266        {
 267          if (sizeof (prfpregset_t) == sizeof (void *))
 268            return 1;
 269          return 0;
 270        }],
 271        gdb_cv_prfpregset_t_broken=no,
 272        gdb_cv_prfpregset_t_broken=yes,
 273        gdb_cv_prfpregset_t_broken=yes)])
 274     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 275     if test $gdb_cv_prfpregset_t_broken = yes; then
 276       AC_DEFINE(PRFPREGSET_T_BROKEN)
 277     fi
 278   fi
 279
 280   dnl Check for PIOCSET ioctl entry
 281
 282   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 283   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 284   [AC_TRY_COMPILE([#include <unistd.h>
 285 #include <sys/types.h>
 286 #include <sys/procfs.h>
 287 ], [
 288     int dummy;;
 289     dummy = ioctl(0, PIOCSET, &dummy);
 290   ],
 291   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 292   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 293   if test $gdb_cv_have_procfs_piocset = yes; then
 294     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 295   fi
 296 fi
 297
 298 dnl See if host has libm.  This is usually needed by simulators.
 299 AC_CHECK_LIB(m, main)
 300
 301 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 302 dnl
 303 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 304 dnl under Solaris 2.6 because it is some funky empty library.
 305 dnl So only link in libw if we have to.
 306 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 307
 308 dnl See if compiler supports "long long" type.
 309
 310 AC_MSG_CHECKING(for long long support in compiler)
 311 AC_CACHE_VAL(gdb_cv_c_long_long,
 312 [AC_TRY_COMPILE(, [
 313   extern long long foo;
 314   switch (foo & 2) { case 0: return 1; }
 315 ],
 316 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 317 AC_MSG_RESULT($gdb_cv_c_long_long)
 318 if test $gdb_cv_c_long_long = yes; then
 319   AC_DEFINE(CC_HAS_LONG_LONG)
 320 fi
 321
 322 dnl See if the compiler and runtime support printing long long
 323
 324 AC_MSG_CHECKING(for long long support in printf)
 325 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 326 [AC_TRY_RUN([
 327 int main () {
 328   char buf[32];
 329   long long l = 0;
 330   l = (l << 16) + 0x0123;
 331   l = (l << 16) + 0x4567;
 332   l = (l << 16) + 0x89ab;
 333   l = (l << 16) + 0xcdef;
 334   sprintf (buf, "0x%016llx", l);
 335   return (strcmp ("0x0123456789abcdef", buf));
 336 }],
 337 gdb_cv_printf_has_long_long=yes,
 338 gdb_cv_printf_has_long_long=no,
 339 gdb_cv_printf_has_long_long=no)])
 340 if test $gdb_cv_printf_has_long_long = yes; then
 341   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 342 fi
 343 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 344
 345 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 346 dnl because autoconf complains about cross-compilation issues.  However, this
 347 dnl code uses the same variables as the macro for compatibility.
 348
 349 AC_MSG_CHECKING(for long double support in compiler)
 350 AC_CACHE_VAL(ac_cv_c_long_double,
 351 [AC_TRY_COMPILE(, [long double foo;],
 352 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 353 AC_MSG_RESULT($ac_cv_c_long_double)
 354 if test $ac_cv_c_long_double = yes; then
 355   AC_DEFINE(HAVE_LONG_DOUBLE)
 356 fi
 357
 358 dnl See if the compiler and runtime support printing long doubles
 359
 360 AC_MSG_CHECKING(for long double support in printf)
 361 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 362 [AC_TRY_RUN([
 363 int main () {
 364   char buf[16];
 365   long double f = 3.141592653;
 366   sprintf (buf, "%Lg", f);
 367   return (strncmp ("3.14159", buf, 7));
 368 }],
 369 gdb_cv_printf_has_long_double=yes,
 370 gdb_cv_printf_has_long_double=no,
 371 gdb_cv_printf_has_long_double=no)])
 372 if test $gdb_cv_printf_has_long_double = yes; then
 373   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 374 fi
 375 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 376
 377 dnl See if the compiler and runtime support scanning long doubles
 378
 379 AC_MSG_CHECKING(for long double support in scanf)
 380 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 381 [AC_TRY_RUN([
 382 int main () {
 383   char *buf = "3.141592653";
 384   long double f = 0;
 385   sscanf (buf, "%Lg", &f);
 386   return !(f > 3.14159 && f < 3.14160);
 387 }],
 388 gdb_cv_scanf_has_long_double=yes,
 389 gdb_cv_scanf_has_long_double=no,
 390 gdb_cv_scanf_has_long_double=no)])
 391 if test $gdb_cv_scanf_has_long_double = yes; then
 392   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 393 fi
 394 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 395
 396 AC_FUNC_MMAP
 397
 398 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 399 dnl we must explicitly test for version 1 of the library because version 0
 400 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 401
 402 dnl Note that we only want this if we are both native (host == target), and
 403 dnl not doing a canadian cross build (build == host).
 404
 405 if test ${build} = ${host} -a ${host} = ${target} ; then
 406    case ${host_os} in
 407    hpux*)
 408       AC_MSG_CHECKING(for HPUX/OSF thread support)
 409       if test -f /usr/include/dce/cma_config.h ; then
 410          if test "$GCC" = "yes" ; then
 411             AC_MSG_RESULT(yes)
 412             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 413             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 414             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 415          else
 416             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 417          fi
 418       else
 419          AC_MSG_RESULT(no)
 420       fi
 421       ;;
 422    solaris*)
 423       AC_MSG_CHECKING(for Solaris thread debugging library)
 424       if test -f /usr/lib/libthread_db.so.1 ; then
 425          AC_MSG_RESULT(yes)
 426          AC_DEFINE(HAVE_THREAD_DB_LIB)
 427          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 428          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 429          AC_CHECK_LIB(dl, dlopen)
 430          if test "$GCC" = "yes" ; then
 431             # The GNU linker requires the -export-dynamic option to make
 432             # all symbols visible in the dynamic symbol table.
 433             hold_ldflags=$LDFLAGS
 434             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 435             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 436             AC_TRY_LINK(, [int i;], found=yes, found=no)
 437             LDFLAGS=$hold_ldflags
 438             AC_MSG_RESULT($found)
 439             if test $found = yes; then
 440                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 441             fi
 442          fi
 443          # Sun randomly tweaked the prototypes in <proc_service.h>
 444          # at one point.
 445          AC_MSG_CHECKING(if <proc_service.h> is old)
 446          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 447             AC_TRY_COMPILE([
 448                 #include <proc_service.h>
 449                 ps_err_e ps_pdwrite
 450                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 451             ],, gdb_cv_proc_service_is_old=no,
 452                 gdb_cv_proc_service_is_old=yes)
 453          ])
 454          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 455          if test $gdb_cv_proc_service_is_old = yes; then
 456             AC_DEFINE(PROC_SERVICE_IS_OLD)
 457          fi
 458       else
 459          AC_MSG_RESULT(no)
 460       fi
 461       ;;
 462    esac
 463    AC_SUBST(CONFIG_LDFLAGS)
 464 fi
 465
 466 dnl The CLI cannot be disabled yet, but may be in the future
 467
 468 dnl Handle CLI sub-directory configury.
 469 AC_ARG_ENABLE(gdbcli,
 470 [  --enable-gdbcli            Enable GDB-CLI interface],
 471 [
 472   case "${enableval}" in
 473     yes) enable_gdbcli=yes ;;
 474     "") enable_gdbcli=yes ;;
 475     no)
 476       AC_MSG_ERROR(The CLI cannot be disabled yet)
 477     ;;
 478     *)
 479       AC_MSG_ERROR(Bad value for --enable-gdbcli: ${enableval})
 480     ;;
 481   esac
 482 ],
 483 [enable_gdbcli=yes])
 484 case ${enable_gdbcli} in
 485   "yes" )
 486     if test -d "${srcdir}/cli" ; then
 487       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_CLI_OBS)"
 488       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_CLI_DEPS)"
 489       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_CLI_SRCS)"
 490       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_CLI_INITS)"
 491       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_CLI_CFLAGS)"
 492       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_CLI_ALL)"
 493       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_CLI_CLEAN)"
 494       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_CLI_INSTALL)"
 495       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_CLI_UNINSTALL)"
 496     fi
 497     ;;
 498 esac
 499
 500 dnl Handle optional features that can be enabled.
 501
 502 dnl Handle MI sub-directory configury.
 503 AC_ARG_ENABLE(gdbmi,
 504 [  --enable-gdbmi            Enable GDB-MI interface],
 505 [
 506   case "${enable_gdbmi}" in
 507     yes | no) ;;
 508     "")  enable_gdbmi=yes ;;
 509     *)
 510       AC_MSG_ERROR(Bad value for --enable-gdbmi: ${enableval})
 511     ;;
 512   esac
 513 ])
 514 case ${enable_gdbmi} in
 515   "yes" )
 516     if test -d "${srcdir}/mi" ; then
 517       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_MI_OBS)"
 518       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_MI_DEPS)"
 519       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_MI_SRCS)"
 520       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_MI_INITS)"
 521       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_MI_CFLAGS)"
 522       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_MI_ALL)"
 523       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_MI_CLEAN)"
 524       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_MI_INSTALL)"
 525       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_MI_UNINSTALL)"
 526     fi
 527     ;;
 528 esac
 529
 530 # Configure UI_OUT by default (before 5.2 it can be disabled)
 531 # It must be configured if gdbmi is configured
 532
 533 UIOUT_CFLAGS=
 534 AC_SUBST(UIOUT_CFLAGS)
 535
 536 AC_ARG_WITH(uiout,
 537 [  --with-uiout          Use new uiout functions intead of *printf's],
 538 [case "${withval}" in
 539   yes)  want_uiout=true ;;
 540   no)   if test $enable_gdbmi = yes; then
 541           AC_MSG_ERROR(uiout is needed for MI and cannot be disabled)
 542         else
 543            want_uiout=false
 544         fi ;;
 545   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-uiout option) ;;
 546 esac],
 547 [want_uiout=true])dnl
 548
 549 if test $want_uiout = true; then
 550    UIOUT_CFLAGS="-DUI_OUT=1"
 551 fi
 552
 553 AC_ARG_ENABLE(tui,
 554 [  --enable-tui            Enable full-screen terminal user interface],
 555 [
 556   case "${enable_tui}" in
 557     yes | no) ;;
 558     "")  enable_tui=yes ;;
 559     *)
 560       AC_MSG_ERROR(Bad value for --enable-tui: ${enableval})
 561     ;;
 562   esac
 563 ])
 564 case ${enable_tui} in
 565   "yes" )
 566     if test -d "${srcdir}/tui" ; then
 567       CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_TUI_OBS)"
 568       CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_TUI_DEPS)"
 569       CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_TUI_SRCS)"
 570       CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_TUI_INITS)"
 571       ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_TUI_CFLAGS)"
 572       CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_TUI_ALL)"
 573       CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_TUI_CLEAN)"
 574       CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_TUI_INSTALL)"
 575       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_TUI_UNINSTALL)"
 576     fi
 577     ;;
 578 esac
 579
 580 AC_ARG_ENABLE(netrom,
 581 [  --enable-netrom         Enable NetROM support],
 582 [case "${enableval}" in
 583 yes)    enable_netrom=yes ;;
 584 no)     enable_netrom=no ;;
 585 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 586 esac])
 587
 588 if test "${enable_netrom}" = "yes"; then
 589         CONFIG_LIB_OBS="${CONFIG_LIB_OBS} remote-nrom.o"
 590         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 591 fi
 592
 593
 594 # NOTE: Don't add -Wall or -Wunused, they both include
 595 # -Wunused-parameter which reports bogus warnings.
 596 # NOTE: If you add to this list, remember to update
 597 # gdb/doc/gdbint.texinfo.
 598 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
 599 -Wformat -Wparentheses -Wpointer-arith"
 600 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
 601 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
 602 # -Wchar-subscripts -Wuninitialized -Wtraditional -Wshadow -Wcast-qual
 603 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
 604 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
 605 # -Woverloaded-virtual -Winline -Werror"
 606 AC_ARG_ENABLE(build-warnings,
 607 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 608 [case "${enableval}" in
 609   yes)  ;;
 610   no)   build_warnings="-w";;
 611   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 612         build_warnings="${build_warnings} ${t}";;
 613   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 614         build_warnings="${t} ${build_warnings}";;
 615   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 616 esac
 617 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 618   echo "Setting compiler warning flags = $build_warnings" 6>&1
 619 fi])dnl
 620 AC_ARG_ENABLE(gdb-build-warnings,
 621 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
 622 [case "${enableval}" in
 623   yes)  ;;
 624   no)   build_warnings="-w";;
 625   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 626         build_warnings="${build_warnings} ${t}";;
 627   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 628         build_warnings="${t} ${build_warnings}";;
 629   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 630 esac
 631 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 632   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
 633 fi])dnl
 634 WARN_CFLAGS=""
 635 WERROR_CFLAGS=""
 636 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 637 then
 638     AC_MSG_CHECKING(compiler warning flags)
 639     # Separate out the -Werror flag as some files just cannot be
 640     # compiled with it enabled.
 641     for w in ${build_warnings}; do
 642         case $w in
 643         -Werr*) WERROR_CFLAGS=-Werror ;;
 644         *) # Check that GCC accepts it
 645             if $CC $w 2>&1 | grep 'unrecognized option' > /dev/null; then
 646                 :
 647             else
 648                 WARN_CFLAGS="${WARN_CFLAGS} $w"
 649             fi
 650         esac
 651     done
 652     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
 653 fi
 654 AC_SUBST(WARN_CFLAGS)
 655 AC_SUBST(WERROR_CFLAGS)
 656
 657 MMALLOC_CFLAGS=
 658 MMALLOC=
 659 AC_SUBST(MMALLOC_CFLAGS)
 660 AC_SUBST(MMALLOC)
 661
 662 AC_ARG_WITH(mmalloc,
 663 [  --with-mmalloc          Use memory mapped malloc package],
 664 [case "${withval}" in
 665   yes)  want_mmalloc=true ;;
 666   no)   want_mmalloc=false;;
 667   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 668 esac],[want_mmalloc=false])dnl
 669
 670 if test x$want_mmalloc = xtrue; then
 671    AC_DEFINE(USE_MMALLOC)
 672    AC_DEFINE(MMCHECK_FORCE)
 673    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 674    MMALLOC='../mmalloc/libmmalloc.a'
 675 fi
 676
 677 AC_ARG_WITH(included-regex,
 678 [  --with-included-regex          Use included regex],
 679 [case "${withval}" in
 680   yes)  want_included_regex=true ;;
 681   no)   want_included_regex=false;;
 682   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-included-regex option) ;;
 683 esac],[want_included_regex=true])dnl
 684
 685 if test $want_included_regex = false; then
 686   AC_MSG_CHECKING(for GNU regex)
 687   AC_CACHE_VAL(gdb_cv_have_gnu_regex,
 688 [AC_TRY_COMPILE([#include <gnu-versions.h>
 689 #include <sys/types.h>
 690 #include <regex.h>],
 691 [#if !defined _GNU_REGEX_INTERFACE_VERSION || !defined __GLIBC__ || __GLIBC__ < 2
 692 #error No valid GNU regex.
 693 #endif
 694 ],
 695                 [gdb_cv_have_gnu_regex=yes],
 696                 [gdb_cv_have_gnu_regex=no])])
 697   AC_MSG_RESULT($gdb_cv_have_gnu_regex)
 698   if test $gdb_cv_have_gnu_regex = no; then
 699         want_included_regex=true
 700   fi
 701 fi
 702
 703 if test x${want_included_regex} = xtrue; then
 704     REGEX="gnu-regex.o"
 705     AC_DEFINE(USE_INCLUDED_REGEX)
 706 fi
 707 AC_SUBST(REGEX)
 708
 709 # In the Cygwin environment, we need some additional flags.
 710 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 711 [AC_EGREP_CPP(lose, [
 712 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
 713 lose
 714 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 715
 716
 717 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
 718 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
 719 case ${host} in
 720   *go32* ) SER_HARDWIRE=ser-go32.o ;;
 721   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
 722 esac
 723 AC_SUBST(SER_HARDWIRE)
 724
 725
 726 dnl Figure out which term library to use.
 727 if test x$gdb_host = xgo32; then
 728   TERM_LIB=
 729 else
 730 if test x$gdb_cv_os_cygwin = xyes; then
 731   TERM_LIB='`if test -r ../libtermcap/libtermcap.a; then echo ../libtermcap/libtermcap.a; else echo -ltermcap; fi`'
 732 else
 733   TERM_LIB=
 734   AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses,
 735     AC_CHECK_LIB(Hcurses, tgetent, TERM_LIB=-lHcurses,
 736       AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib,
 737         AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap,
 738           AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses,
 739             AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo))))))
 740
 741   if test "x$TERM_LIB" = x
 742   then
 743     AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!)
 744   fi
 745 fi
 746 fi
 747 AC_SUBST(TERM_LIB)
 748
 749 # libreadline needs libuser32.a in a cygwin environment
 750 WIN32LIBS=
 751 if test x$gdb_cv_os_cygwin = xyes; then
 752     WIN32LIBS="-luser32"
 753     case "${target}" in
 754         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
 755         ;;
 756     esac
 757 fi
 758 AC_SUBST(WIN32LIBS)
 759
 760 LIBGUI="../libgui/src/libgui.a"
 761 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 762 AC_SUBST(LIBGUI)
 763 AC_SUBST(GUI_CFLAGS_X)
 764
 765 AC_ARG_WITH(cpu,
 766 [  --with-cpu=CPU          Set the default CPU variant to debug],
 767 [case "${target}" in
 768   powerpc-* | powerpcle-* )
 769     ## It would be nice to keep this table in sync with the one in
 770     ## gcc/configure.
 771     case "${with_cpu}" in
 772       ppc-uisa | rs6000 | 403 | 403GC | 505 | 860 | 601 | 602 | 603 \
 773       | 604 | 750 )
 774         ## Those are all handled in variants in rs6000-tdep.c, so they're fine.
 775       ;;
 776       common | power | power2 | rios | rios1 | rios2 | rsc | rsc1 )
 777         ## These are all RS6000 variants, as far as GDB is concerned.
 778         with_cpu=rs6000
 779       ;;
 780       603e | ec603e )
 781         with_cpu=603
 782       ;;
 783       604e )
 784         with_cpu=604
 785       ;;
 786       * )
 787         AC_MSG_WARN(GDB: unknown --with-cpu value: \`${with_cpu}'; using \`ppc-uisa'.)
 788         with_cpu=ppc-uisa
 789       ;;
 790     esac
 791   ;;
 792   * )
 793     AC_MSG_WARN(GDB may ignore the --with-cpu flag for ${target} targets)
 794   ;;
 795 esac
 796 AC_DEFINE_UNQUOTED(TARGET_CPU_DEFAULT, "${with_cpu}")
 797 ],)
 798
 799
 800 AC_ARG_ENABLE(gdbtk,
 801 [  --enable-gdbtk          Enable GDBTK GUI front end],
 802 [case "${enableval}" in
 803     yes)
 804         case "$host" in
 805         *go32*)
 806             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 807             enable_gdbtk=no ;;
 808         *windows*)
 809             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 810             enable_gdbtk=no ;;
 811         *)
 812             enable_gdbtk=yes ;;
 813         esac ;;
 814     no)
 815         enable_gdbtk=no  ;;
 816     *)
 817         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 818 esac],
 819 [
 820 # Default is on for everything but go32 and Cygwin
 821 case "$host" in
 822     *go32* | *windows*)
 823         ;;
 824     *)
 825         if test -d "${srcdir}/gdbtk" ; then
 826             enable_gdbtk=yes
 827         fi
 828         ;;
 829 esac
 830 ])
 831
 832 WIN32LDAPP=
 833 AC_SUBST(WIN32LIBS)
 834 AC_SUBST(WIN32LDAPP)
 835
 836 configdir="unix"
 837
 838 GDBTKLIBS=
 839 if test "${enable_gdbtk}" = "yes"; then
 840
 841     CY_AC_PATH_TCLCONFIG
 842     if test -z "${no_tcl}"; then
 843         CY_AC_LOAD_TCLCONFIG
 844         CY_AC_PATH_TKCONFIG
 845
 846         # If $no_tk is nonempty, then we can't do Tk, and there is no
 847         # point to doing Tcl.
 848         if test -z "${no_tk}"; then
 849            CY_AC_LOAD_TKCONFIG
 850            CY_AC_PATH_TCLH
 851            CY_AC_PATH_TKH
 852            CY_AC_PATH_ITCLH
 853            CY_AC_PATH_ITKH
 854            CY_AC_PATH_TIXH
 855
 856            # now look for Itcl library stuff
 857
 858            CY_AC_PATH_ITCLCONFIG
 859            if test -z "${no_itcl}"; then
 860              CY_AC_LOAD_ITCLCONFIG
 861              case "${host}" in
 862              *-*-cygwin*)
 863                 itcldir=../itcl/itcl/win/
 864                 ;;
 865              *)
 866                 itcldir=../itcl/itcl/unix/
 867                 ;;
 868              esac
 869
 870
 871              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
 872              ITCL_DEPS="${itcldir}${ITCL_LIB_FILE}"
 873            fi
 874
 875
 876            # now look for Itk library stuff
 877            CY_AC_PATH_ITKCONFIG
 878            if test -z "${no_itcl}"; then
 879              CY_AC_LOAD_ITKCONFIG
 880
 881              case "${host}" in
 882                *-*-cygwin*)
 883                  itkdir=../itcl/itk/win/
 884                  ;;
 885                *)
 886                  itkdir=../itcl/itk/unix/
 887                  ;;
 888                esac
 889
 890              ITKLIB="${ITK_BUILD_LIB_SPEC}"
 891              ITK_DEPS="${itkdir}${ITK_LIB_FILE}"
 892            fi
 893
 894            # now look for Tix library stuff
 895            CY_AC_PATH_TIXCONFIG
 896            if test -z "${no_tix}"; then
 897              CY_AC_LOAD_TIXCONFIG
 898              TIXLIB="${TIX_BUILD_LIB_SPEC}"
 899              TIX_DEPS="${TIX_BUILD_LOCATION}/${TIX_LIB_FILE}"
 900            fi
 901
 902            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
 903            # Tcl/Tk 8.1 require -fwritable strings.  I don't
 904            # know whether 8.2 will or not, but I bet it will.
 905            # I don't have to worry about 7.x since we don't support it.
 906            GDBTK_CFLAGS=""
 907            if test "$GCC" = "yes"; then
 908                if test "$TCL_VERSION" != "8.0" ; then
 909                    GDBTK_CFLAGS="-fwritable-strings"
 910                fi
 911            fi
 912
 913            # Include some libraries that Tcl and Tk want.
 914            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 915            # Yes, the ordering seems wrong here.  But it isn't.
 916            # TK_LIBS is the list of libraries that need to be linked
 917            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 918            # were in LIBS then any link tests after this point would
 919            # try to include things like `$(LIBGUI)', which wouldn't work.
 920            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 921
 922            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
 923            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
 924            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
 925            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
 926            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
 927            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
 928            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
 929            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
 930
 931            if test x$gdb_cv_os_cygwin = xyes; then
 932               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
 933               WIN32LDAPP="-Wl,--subsystem,console"
 934               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 935            fi
 936         fi
 937     fi
 938 fi
 939
 940 AC_SUBST(X_CFLAGS)
 941 AC_SUBST(X_LDFLAGS)
 942 AC_SUBST(X_LIBS)
 943 AC_SUBST(ITCLLIB)
 944 AC_SUBST(ITCL_DEPS)
 945 AC_SUBST(ITKLIB)
 946 AC_SUBST(ITK_DEPS)
 947 AC_SUBST(TIXLIB)
 948 AC_SUBST(TIX_DEPS)
 949 AC_SUBST(GDBTKLIBS)
 950 AC_SUBST(GDBTK_CFLAGS)
 951
 952 AC_PATH_X
 953
 954
 955 # Unlike the sim directory, whether a simulator is linked is controlled by
 956 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
 957 # This code just checks for a few cases where we'd like to ignore those
 958 # definitions, even when they're present in the '.mt' file.  These cases
 959 # are when --disable-sim is specified, or if the simulator directory is
 960 # not part of the soruce tree.
 961 #
 962 AC_ARG_ENABLE(sim,
 963 [  --enable-sim            Link gdb with simulator],
 964 [echo "enable_sim = $enable_sim";
 965  echo "enableval = ${enableval}";
 966  case "${enableval}" in
 967   yes) ignore_sim=false ;;
 968   no)  ignore_sim=true ;;
 969   *)   ignore_sim=false ;;
 970  esac],
 971 [ignore_sim=false])
 972
 973 if test ! -d "${srcdir}/../sim"; then
 974   ignore_sim=true
 975 fi
 976
 977 if test "${ignore_sim}" = "true"; then
 978     IGNORE_SIM="SIM="
 979     IGNORE_SIM_OBS="SIM_OBS="
 980 else
 981     IGNORE_SIM=""
 982     IGNORE_SIM_OBS=""
 983     AC_DEFINE(WITH_SIM)
 984 fi
 985 AC_SUBST(IGNORE_SIM)
 986 AC_SUBST(IGNORE_SIM_OBS)
 987
 988 AC_SUBST(ENABLE_CFLAGS)
 989
 990 AC_SUBST(CONFIG_OBS)
 991 AC_SUBST(CONFIG_LIB_OBS)
 992 AC_SUBST(CONFIG_DEPS)
 993 AC_SUBST(CONFIG_SRCS)
 994 AC_SUBST(CONFIG_INITS)
 995 AC_SUBST(CONFIG_ALL)
 996 AC_SUBST(CONFIG_CLEAN)
 997 AC_SUBST(CONFIG_INSTALL)
 998 AC_SUBST(CONFIG_UNINSTALL)
 999
1000 # Begin stuff to support --enable-shared
1001 AC_ARG_ENABLE(shared,
1002 [  --enable-shared         Use shared libraries],
1003 [case "${enableval}" in
1004   yes) shared=true ;;
1005   no)  shared=false ;;
1006   *) shared=true ;;
1007 esac])dnl
1008
1009 HLDFLAGS=
1010 HLDENV=
1011 # If we have shared libraries, try to set rpath reasonably.
1012 if test "${shared}" = "true"; then
1013   case "${host}" in
1014   *-*-hpux*)
1015     HLDFLAGS='-Wl,+s,+b,$(libdir)'
1016     ;;
1017   *-*-irix5* | *-*-irix6*)
1018     HLDFLAGS='-Wl,-rpath,$(libdir)'
1019     ;;
1020   *-*-linux*aout*)
1021     ;;
1022   *-*-linux* | *-pc-linux-gnu*)
1023     HLDFLAGS='-Wl,-rpath,$(libdir)'
1024     ;;
1025   *-*-solaris*)
1026     HLDFLAGS='-R $(libdir)'
1027     ;;
1028   *-*-sysv4*)
1029     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
1030     ;;
1031   esac
1032 fi
1033
1034 # On SunOS, if the linker supports the -rpath option, use it to
1035 # prevent ../bfd and ../opcodes from being included in the run time
1036 # search path.
1037 case "${host}" in
1038   *-*-sunos*)
1039     echo 'main () { }' > conftest.c
1040     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
1041     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
1042       :
1043     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
1044       :
1045     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
1046       :
1047     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
1048       :
1049     elif test "${shared}" = "true"; then
1050       HLDFLAGS='-Wl,-rpath=$(libdir)'
1051     else
1052       HLDFLAGS='-Wl,-rpath='
1053     fi
1054     rm -f conftest.t conftest.c conftest
1055     ;;
1056 esac
1057 AC_SUBST(HLDFLAGS)
1058 AC_SUBST(HLDENV)
1059 # End stuff to support --enable-shared
1060
1061 # target_subdir is used by the testsuite to find the target libraries.
1062 target_subdir=
1063 if test "${host}" != "${target}"; then
1064     target_subdir="${target_alias}/"
1065 fi
1066 AC_SUBST(target_subdir)
1067
1068 frags=
1069 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1070 if test ! -f ${host_makefile_frag}; then
1071 AC_MSG_ERROR("*** Gdb does not support host ${host}")
1072 fi
1073 frags="$frags $host_makefile_frag"
1074
1075 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1076 if test ! -f ${target_makefile_frag}; then
1077 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1078 fi
1079 frags="$frags $target_makefile_frag"
1080
1081 AC_SUBST_FILE(host_makefile_frag)
1082 AC_SUBST_FILE(target_makefile_frag)
1083 AC_SUBST(frags)
1084
1085 changequote(,)dnl
1086 hostfile=`sed -n '
1087 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1088 ' ${host_makefile_frag}`
1089
1090 targetfile=`sed -n '
1091 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1092 ' ${target_makefile_frag}`
1093
1094 GDB_MULTI_ARCH=`sed -n '
1095 s/GDB_MULTI_ARCH[       ]*=[    ]*\([^  ]*\)[   ]*/\1/p
1096 ' ${target_makefile_frag}`
1097
1098 # these really aren't orthogonal true/false values of the same condition,
1099 # but shells are slow enough that I like to reuse the test conditions
1100 # whenever possible
1101 if test "${target}" = "${host}"; then
1102 nativefile=`sed -n '
1103 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1104 ' ${host_makefile_frag}`
1105 # else
1106 # GDBserver is only useful in a "native" enviroment
1107 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
1108 fi
1109 changequote([,])
1110
1111 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1112 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1113 # in the target specific makefile frag.  Eventually gdb_multi_arch=yes
1114 # will be the default.
1115 if test x"${GDB_MULTI_ARCH}" = x ; then
1116     case "${gdb_multi_arch}" in
1117     yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1118     no ) GDB_MULTI_ARCH=0 ;;
1119     0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1120     esac
1121 fi
1122 if test x"${GDB_MULTI_ARCH}" != x ; then
1123     AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1124 fi
1125 # Warn the user when they use an old pratice
1126 case "${GDB_MULTI_ARCH}" in
1127     "" ) ;;
1128     0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1129         AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1130     GDB_MULTI_ARCH_PURE )
1131         if test x"${targetfile}" != x ; then
1132             AC_MSG_WARN("GDB: Ingoring TM_FILE in ${target_makefile_frag}")
1133             targetfile=""
1134         fi ;;
1135     *)  AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1136 esac
1137
1138
1139 SUBDIRS="doc testsuite nlm"
1140 if test "${enable_multi_ice}" = "yes"; then
1141   SUBDIRS="${SUBDIRS} multi-ice"
1142 fi
1143
1144 AC_SUBST(SUBDIRS)
1145
1146 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1147 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1148 # version.
1149
1150 files=
1151 links=
1152
1153 rm -f xm.h
1154 xm_h=""
1155 if test "${hostfile}" != ""; then
1156     xm_h=xm.h
1157     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1158     files="${files} ${GDB_XM_FILE}"
1159     links="${links} xm.h"
1160     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1161 fi
1162 AC_SUBST(xm_h)
1163
1164 rm -f tm.h
1165 tm_h=""
1166 if test "${targetfile}" != ""; then
1167     tm_h=tm.h
1168     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1169     files="${files} ${GDB_TM_FILE}"
1170     links="${links} tm.h"
1171     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1172 fi
1173 AC_SUBST(tm_h)
1174
1175 rm -f nm.h
1176 nm_h=""
1177 if test "${nativefile}" != ""; then
1178     nm_h=nm.h
1179     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1180     files="${files} ${GDB_NM_FILE}"
1181     links="${links} nm.h"
1182     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1183 fi
1184 AC_SUBST(nm_h)
1185
1186 AC_PROG_LN_S
1187
1188 AC_LINK_FILES($files, $links)
1189
1190 dnl Check for exe extension set on certain hosts (e.g. Win32)
1191 AC_EXEEXT
1192
1193 AC_CONFIG_SUBDIRS($configdirs)
1194 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1195 [
1196 dnl Autoconf doesn't provide a mechanism for modifying definitions
1197 dnl provided by makefile fragments.
1198 dnl
1199 if test "${nativefile}" = ""; then
1200 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
1201         < Makefile > Makefile.tem
1202 mv -f Makefile.tem Makefile
1203 fi
1204
1205 changequote(,)dnl
1206 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1207 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1208 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1209 mv -f Makefile.tmp Makefile
1210 changequote([,])dnl
1211
1212
1213 case x$CONFIG_HEADERS in
1214 xconfig.h:config.in)
1215 echo > stamp-h ;;
1216 esac
1217 ],
1218 [
1219 gdb_host_cpu=$gdb_host_cpu
1220 gdb_target_cpu=$gdb_target_cpu
1221 nativefile=$nativefile
1222 ])
1223
1224 exit 0