gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl List of object files and targets accumulated by configure.
  46
  47 CONFIG_OBS=
  48 CONFIG_DEPS=
  49 CONFIG_SRCS=
  50 ENABLE_CFLAGS=
  51
  52 CONFIG_ALL=
  53 CONFIG_CLEAN=
  54 CONFIG_INSTALL=
  55 CONFIG_UNINSTALL=
  56
  57 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  58
  59 CY_GNU_GETTEXT
  60
  61 localedir='${datadir}/locale'
  62 AC_SUBST(localedir)
  63
  64 if test "x$POSUB" != x; then
  65
  66   dnl Lifted from GCC's config/gettext.m4.
  67   AC_MSG_CHECKING(for catalogs to be installed)
  68   # Look for .po and .gmo files in the source directory.
  69   CATALOGS=  AC_SUBST(CATALOGS)
  70   XLINGUAS=
  71   for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
  72     # If there aren't any .gmo files the shell will give us the
  73     # literal string "../path/to/srcdir/po/*.gmo" which has to be
  74     # weeded out.
  75     case "$cat" in *\**)
  76       continue;;
  77     esac
  78     # The quadruple backslash is collapsed to a double backslash
  79     # by the backticks, then collapsed again by the double quotes,
  80     # leaving us with one backslash in the sed expression (right
  81     # before the dot that mustn't act as a wildcard).
  82     cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
  83     lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
  84     # The user is allowed to set LINGUAS to a list of languages to
  85     # install catalogs for.  If it's empty that means "all of them."
  86     if test "x$LINGUAS" = x; then
  87       CATALOGS="$CATALOGS $cat"
  88       XLINGUAS="$XLINGUAS $lang"
  89     else
  90       case "$LINGUAS" in *$lang*)
  91         CATALOGS="$CATALOGS $cat"
  92         XLINGUAS="$XLINGUAS $lang"
  93         ;;
  94       esac
  95     fi
  96   done
  97   LINGUAS="$XLINGUAS"
  98   AC_MSG_RESULT($LINGUAS)
  99
 100    CONFIG_ALL="$CONFIG_ALL all-po"
 101    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
 102    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
 103    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
 104 fi
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 debugdir=${libdir}/debug
 111
 112 AC_ARG_WITH(separate-debug-dir,
 113 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
 114 [debugdir="${withval}"])
 115
 116 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 117               [Global directory for separate debug files. ])
 118 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 119
 120 AC_CONFIG_SUBDIRS(doc testsuite)
 121 configdirs=
 122
 123 . $srcdir/configure.host
 124
 125 . $srcdir/configure.tgt
 126
 127 # Fetch the default architecture and default target vector from BFD.
 128 targ=$target; . $srcdir/../bfd/config.bfd
 129
 130 # We only want the first architecture, so strip off the others if
 131 # there is more than one.
 132 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 133
 134 if test "x$targ_archs" != x; then
 135   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 136     [Define to BFD's default architecture. ])
 137 fi
 138 if test "x$targ_defvec" != x; then
 139   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 140     [Define to BFD's default target vector. ])
 141 fi
 142
 143 AC_ARG_PROGRAM
 144
 145 # The CLI cannot be disabled yet, but may be in the future.
 146
 147 # Enable CLI.
 148 AC_ARG_ENABLE(gdbcli,
 149 [  --disable-gdbcli        disable command-line interface (CLI)],
 150   [case $enableval in
 151     yes)
 152       ;;
 153     no)
 154       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 155     *)
 156       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 157   esac],
 158   [enable_gdbcli=yes])
 159 if test x"$enable_gdbcli" = xyes; then
 160   if test -d $srcdir/cli; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 164     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 165   fi
 166 fi
 167
 168 # Enable MI.
 169 AC_ARG_ENABLE(gdbmi,
 170 [  --disable-gdbmi         disable machine-interface (MI)],
 171   [case $enableval in
 172     yes | no)
 173       ;;
 174     *)
 175       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 176   esac],
 177   [enable_gdbmi=yes])
 178 if test x"$enable_gdbmi" = xyes; then
 179   if test -d $srcdir/mi; then
 180     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 181     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 182     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 183     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 184   fi
 185 fi
 186
 187 # Enable TUI.
 188 AC_ARG_ENABLE(tui,
 189 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 190   [case $enableval in
 191     yes | no)
 192       ;;
 193     *)
 194       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 195   esac],enable_tui=yes)
 196
 197 # Enable gdbtk.
 198 AC_ARG_ENABLE(gdbtk,
 199 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 200   [case $enableval in
 201     yes | no)
 202       ;;
 203     *)
 204       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 205   esac],
 206   [if test -d $srcdir/gdbtk; then
 207     enable_gdbtk=yes
 208   else
 209     enable_gdbtk=no
 210   fi])
 211 # We unconditionally disable gdbtk tests on selected platforms.
 212 case $host_os in
 213   go32* | windows*)
 214     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 215     enable_gdbtk=no ;;
 216 esac
 217
 218 # Libunwind support.
 219 AC_ARG_WITH(libunwind,
 220 [  --with-libunwind            Use libunwind frame unwinding support],
 221 [case "${withval}" in
 222   yes)  enable_libunwind=yes ;;
 223   no)   enable_libunwind=no ;;
 224   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 225 esac],[
 226   AC_CHECK_HEADERS(libunwind.h)
 227   AC_CHECK_HEADERS(libunwind-ia64.h)
 228   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 229     enable_libunwind=yes;
 230   fi
 231 ])
 232
 233 if test x"$enable_libunwind" = xyes; then
 234   AC_CHECK_HEADERS(libunwind.h)
 235   AC_CHECK_HEADERS(libunwind-ia64.h)
 236   AC_DEFINE(HAVE_LIBUNWIND, 1)
 237   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 238   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 239   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 240 fi
 241
 242 # Profiling support.
 243 AC_ARG_ENABLE(profiling,
 244 [  --enable-profiling      enable profiling of GDB],
 245   [case $enableval in
 246     yes | no)
 247       ;;
 248     *)
 249       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 250   esac],
 251  [enable_profiling=no])
 252
 253 AC_CHECK_FUNCS(monstartup _mcleanup)
 254 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 255 [AC_TRY_LINK(
 256 [#include <stdlib.h>
 257 extern char _etext;
 258 ],
 259 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 260 if test $ac_cv_var__etext = yes; then
 261   AC_DEFINE(HAVE__ETEXT, 1,
 262             [Define to 1 if your system has the _etext variable. ])
 263 fi
 264 if test "$enable_profiling" = yes ; then
 265   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 266     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 267   fi
 268   PROFILE_CFLAGS=-pg
 269   OLD_CFLAGS="$CFLAGS"
 270   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 271
 272   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 273     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 274      ac_cv_cc_supports_pg=no)])
 275
 276   if test $ac_cv_cc_supports_pg = no; then
 277     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 278   fi
 279
 280   CFLAGS="$OLD_CFLAGS"
 281 fi
 282
 283 # --------------------- #
 284 # Checks for programs.  #
 285 # --------------------- #
 286
 287 AC_PROG_AWK
 288 AC_PROG_INSTALL
 289 AC_PROG_LN_S
 290 AC_PROG_RANLIB
 291 AC_PROG_YACC
 292
 293 AC_CHECK_TOOL(AR, ar)
 294 AC_CHECK_TOOL(DLLTOOL, dlltool)
 295 AC_CHECK_TOOL(WINDRES, windres)
 296
 297 # Needed for GNU/Hurd.
 298 AC_CHECK_TOOL(MIG, mig)
 299
 300 # ---------------------- #
 301 # Checks for libraries.  #
 302 # ---------------------- #
 303
 304 # We might need to link with -lm; most simulators need it.
 305 AC_CHECK_LIB(m, main)
 306
 307 # We need to link with -lw to get `wctype' on Solaris before Solaris
 308 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 309 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 310 # is known to have this problem).  Therefore we avoid libw if we can.
 311 AC_CHECK_FUNC(wctype, [],
 312   [AC_CHECK_LIB(w, wctype)])
 313
 314 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 315 AC_SEARCH_LIBS(gethostbyname, nsl)
 316
 317 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 318 AC_SEARCH_LIBS(socketpair, socket)
 319
 320 # For the TUI, we need enhanced curses functionality.
 321 #
 322 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 323 # curses library because the latter might not provide all the
 324 # functionality we need.  However, this leads to problems on systems
 325 # where the linker searches /usr/local/lib, but the compiler doesn't
 326 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 327 # default installation of ncurses on alpha*-dec-osf* will lead to such
 328 # a situation.
 329 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 330
 331 # Since GDB uses Readline, we need termcap functionality.  In many
 332 # cases this will be provided by the curses library, but some systems
 333 # have a seperate termcap library, or no curses library at all.
 334
 335 case $host_os in
 336   cygwin*)
 337     if test -d $srcdir/libtermcap; then
 338       LIBS="../libtermcap/libtermcap.a $LIBS"
 339       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 340     fi ;;
 341   go32* | *djgpp*)
 342     ac_cv_search_tgetent="none required"
 343     ;;
 344 esac
 345
 346 # These are the libraries checked by Readline.
 347 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 348
 349 if test "$ac_cv_search_tgetent" = no; then
 350   AC_MSG_ERROR([no termcap library found])
 351 fi
 352
 353 # ------------------------- #
 354 # Checks for header files.  #
 355 # ------------------------- #
 356
 357 AC_HEADER_DIRENT
 358 AC_HEADER_STAT
 359 AC_HEADER_STDC
 360 AC_CHECK_HEADERS(link.h)
 361 AC_CHECK_HEADERS(machine/reg.h)
 362 AC_CHECK_HEADERS(nlist.h)
 363 AC_CHECK_HEADERS(poll.h sys/poll.h)
 364 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 365 AC_CHECK_HEADERS(stddef.h)
 366 AC_CHECK_HEADERS(stdlib.h)
 367 AC_CHECK_HEADERS(stdint.h)
 368 AC_CHECK_HEADERS(string.h memory.h strings.h)
 369 AC_CHECK_HEADERS(sys/fault.h)
 370 AC_CHECK_HEADERS(sys/file.h)
 371 AC_CHECK_HEADERS(sys/filio.h)
 372 AC_CHECK_HEADERS(sys/ioctl.h)
 373 AC_CHECK_HEADERS(sys/param.h)
 374 AC_CHECK_HEADERS(sys/proc.h)
 375 AC_CHECK_HEADERS(sys/procfs.h)
 376 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 377 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 378 AC_CHECK_HEADERS(sys/select.h)
 379 AC_CHECK_HEADERS(sys/syscall.h)
 380 AC_CHECK_HEADERS(sys/types.h)
 381 AC_CHECK_HEADERS(sys/user.h)
 382 AC_CHECK_HEADERS(sys/wait.h wait.h)
 383 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 384 AC_CHECK_HEADERS(unistd.h)
 385
 386 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 387 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 388 # think that we don't have <curses.h> if we're using GCC.
 389 case $host_os in
 390   solaris2.[[789]])
 391     if test "$GCC" = yes; then
 392       AC_DEFINE(_MSE_INT_H, 1,
 393         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 394    Solaris 2.[789] when using GCC. ]])
 395     fi ;;
 396 esac
 397 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 398 AC_CHECK_HEADERS(ncurses/term.h term.h)
 399
 400 # FIXME: kettenis/20030102: In most cases we include these
 401 # unconditionally, so what's the point in checking these?
 402 AC_CHECK_HEADERS(ctype.h time.h)
 403
 404 dnl Check for struct stat with an st_blocks member
 405 AC_MSG_CHECKING(for member st_blocks in struct stat)
 406 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
 407   [AC_TRY_COMPILE([#include <sys/types.h>
 408 #include <sys/stat.h>],
 409                   [struct stat st; (void) st.st_blocks;],
 410                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
 411                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
 412 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
 413 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
 414   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
 415 fi
 416
 417 # ------------------------- #
 418 # Checks for declarations.  #
 419 # ------------------------- #
 420
 421 gcc_AC_CHECK_DECLS(getopt)
 422
 423 # ------------------ #
 424 # Checks for types.  #
 425 # ------------------ #
 426
 427 AC_TYPE_SIGNAL
 428
 429 # ------------------------------------- #
 430 # Checks for compiler characteristics.  #
 431 # ------------------------------------- #
 432
 433 AC_C_CONST
 434 AC_C_INLINE
 435
 436 # ------------------------------ #
 437 # Checks for library functions.  #
 438 # ------------------------------ #
 439
 440 AC_FUNC_ALLOCA
 441 AC_FUNC_MMAP
 442 AC_FUNC_VFORK
 443 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 444 AC_CHECK_FUNCS(poll)
 445 AC_CHECK_FUNCS(pread64)
 446 AC_CHECK_FUNCS(sbrk)
 447 AC_CHECK_FUNCS(setpgid setpgrp)
 448 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 449 AC_CHECK_FUNCS(socketpair)
 450 AC_CHECK_FUNCS(syscall)
 451 AC_CHECK_FUNCS(ttrace)
 452 AC_CHECK_FUNCS(wborder)
 453
 454 # Check the return and argument types of ptrace.  No canned test for
 455 # this, so roll our own.
 456 gdb_ptrace_headers='
 457 #if HAVE_SYS_TYPES_H
 458 # include <sys/types.h>
 459 #endif
 460 #if HAVE_SYS_PTRACE_H
 461 # include <sys/ptrace.h>
 462 #endif
 463 #if HAVE_UNISTD_H
 464 # include <unistd.h>
 465 #endif
 466 '
 467 # There is no point in checking if we don't have a prototype.
 468 gcc_AC_CHECK_DECLS(ptrace, , [
 469   : ${gdb_cv_func_ptrace_ret='int'}
 470   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 471 ], $gdb_ptrace_headers)
 472 # Check return type.
 473 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 474   AC_TRY_COMPILE($gdb_ptrace_headers,
 475     [extern int ptrace ();],
 476     gdb_cv_func_ptrace_ret='int',
 477     gdb_cv_func_ptrace_ret='long'))
 478 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 479   [Define as the return type of ptrace.])
 480 # Check argument types.
 481 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 482 for gdb_arg1 in 'int' 'long'; do
 483  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 484   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 485    for gdb_arg4 in 'int' 'long'; do
 486      AC_TRY_COMPILE($gdb_ptrace_headers, [
 487 extern $gdb_cv_func_ptrace_ret
 488   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 489 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 490     break 4;])
 491     for gdb_arg5 in 'int *' 'int' 'long'; do
 492      AC_TRY_COMPILE($gdb_ptrace_headers, [
 493 extern $gdb_cv_func_ptrace_ret
 494   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 495 ], [
 496 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 497     break 5;])
 498     done
 499    done
 500   done
 501  done
 502 done
 503 # Provide a safe default value.
 504 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 505 ])
 506 ac_save_IFS=$IFS; IFS=','
 507 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 508 IFS=$ac_save_IFS
 509 shift
 510 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 511   [Define to the type of arg 3 for ptrace.])
 512 if test -n "$[5]"; then
 513   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 514     [Define to the type of arg 5 for ptrace.])
 515 fi
 516
 517 dnl AC_FUNC_SETPGRP does not work when cross compiling
 518 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 519 if test "$cross_compiling" = no; then
 520   AC_FUNC_SETPGRP
 521 else
 522   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 523     [AC_TRY_COMPILE([
 524 #include <unistd.h>
 525 ], [
 526   if (setpgrp(1,1) == -1)
 527     exit (0);
 528   else
 529     exit (1);
 530 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 531 if test $ac_cv_func_setpgrp_void = yes; then
 532   AC_DEFINE(SETPGRP_VOID, 1)
 533 fi
 534 fi
 535
 536 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 537 # since sigsetjmp might only be defined as a macro.
 538 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 539 [AC_TRY_COMPILE([
 540 #include <setjmp.h>
 541 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 542 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 543 if test $gdb_cv_func_sigsetjmp = yes; then
 544   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 545 fi
 546
 547 # Assume we'll default to using the included libiberty regex.
 548 gdb_use_included_regex=yes
 549
 550 # However, if the system regex is GNU regex, then default to *not*
 551 # using the included regex.
 552 AC_CACHE_CHECK(
 553   [for GNU regex],
 554   [gdb_cv_have_gnu_regex],
 555   [AC_TRY_COMPILE(
 556     [#include <gnu-versions.h>],
 557     [#define REGEX_INTERFACE_VERSION 1
 558 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 559 # error "Version mismatch"
 560 #endif],
 561     gdb_cv_have_gnu_regex=yes,
 562     gdb_cv_have_gnu_regex=no)])
 563 if test $gdb_cv_have_gnu_regex = yes; then
 564   gdb_use_included_regex=no
 565 fi
 566
 567 AC_ARG_WITH(included-regex,
 568   [  --without-included-regex don't use included regex; this is the default
 569                           on systems with version 2 of the GNU C library
 570                           (use with caution on other system)],
 571   gdb_with_regex=$withval,
 572   gdb_with_regex=$gdb_use_included_regex)
 573 if test "$gdb_with_regex" = yes; then
 574   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 575     [Define to 1 if the regex included in libiberty should be used.])
 576 fi
 577
 578 # See if <sys/proc.h> defines `struct thread' with a td_pcb member.
 579 AC_CACHE_CHECK([for td_pcb in struct thread], gdb_cv_struct_thread_td_pcb,
 580 [AC_TRY_COMPILE([#include <sys/param.h>
 581 #include <sys/proc.h>], [struct thread td; td.td_pcb;],
 582 gdb_cv_struct_thread_td_pcb=yes, gdb_cv_struct_thread_td_pcb=no)])
 583 if test $gdb_cv_struct_thread_td_pcb = yes; then
 584   AC_DEFINE(HAVE_STRUCT_THREAD_TD_PCB, 1,
 585             [Define to 1 if your system has td_pcb in struct thread.])
 586 fi
 587
 588 # See if <sys/lwp.h> defines `struct lwp`.
 589 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 590 [AC_TRY_COMPILE([#include <sys/param.h>
 591 #include <sys/lwp.h>], [struct lwp l;],
 592 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 593 if test $gdb_cv_struct_lwp = yes; then
 594   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 595             [Define to 1 if your system has struct lwp.])
 596 fi
 597
 598 # See if <machine/reg.h> degines `struct reg'.
 599 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 600 [AC_TRY_COMPILE([#include <sys/types.h>
 601 #include <machine/reg.h>], [struct reg r;],
 602 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 603 if test $gdb_cv_struct_reg = yes; then
 604   AC_DEFINE(HAVE_STRUCT_REG, 1,
 605             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 606 fi
 607
 608 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 609 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 610 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 611 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 612 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 613 if test $gdb_cv_struct_reg_r_fs = yes; then
 614   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 615 fi
 616 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 617 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 618 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 619 if test $gdb_cv_struct_reg_r_gs = yes; then
 620   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 621 fi
 622
 623 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 624 AC_MSG_CHECKING(for PTRACE_GETREGS)
 625 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 626 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 627                 [PTRACE_GETREGS;],
 628                 [gdb_cv_have_ptrace_getregs=yes],
 629                 [gdb_cv_have_ptrace_getregs=no])])
 630 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 631 if test $gdb_cv_have_ptrace_getregs = yes; then
 632   AC_DEFINE(HAVE_PTRACE_GETREGS)
 633 fi
 634
 635 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 636 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 637 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 638 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 639                 [PTRACE_GETFPXREGS;],
 640                 [gdb_cv_have_ptrace_getfpxregs=yes],
 641                 [gdb_cv_have_ptrace_getfpxregs=no])])
 642 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 643 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 644   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 645 fi
 646
 647 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 648 AC_MSG_CHECKING(for PT_GETDBREGS)
 649 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 650 [AC_TRY_COMPILE([#include <sys/types.h>
 651 #include <sys/ptrace.h>],
 652                 [PT_GETDBREGS;],
 653                 [gdb_cv_have_pt_getdbregs=yes],
 654                 [gdb_cv_have_pt_getdbregs=no])])
 655 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 656 if test $gdb_cv_have_pt_getdbregs = yes; then
 657   AC_DEFINE(HAVE_PT_GETDBREGS)
 658 fi
 659
 660 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 661 AC_MSG_CHECKING(for PT_GETXMMREGS)
 662 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 663 [AC_TRY_COMPILE([#include <sys/types.h>
 664 #include <sys/ptrace.h>],
 665                 [PT_GETXMMREGS;],
 666                 [gdb_cv_have_pt_getxmmregs=yes],
 667                 [gdb_cv_have_pt_getxmmregs=no])])
 668 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 669 if test $gdb_cv_have_pt_getxmmregs = yes; then
 670   AC_DEFINE(HAVE_PT_GETXMMREGS)
 671 fi
 672
 673 # See if stdint.h provides the uintptr_t type.
 674 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 675 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 676   [AC_TRY_COMPILE(
 677     [#include <stdint.h>],
 678     [uintptr_t foo = 0;],
 679     gdb_cv_have_uintptr_t=yes,
 680     gdb_cv_have_uintptr_t=no)])
 681 if test $gdb_cv_have_uintptr_t = yes; then
 682   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 683 fi
 684
 685 BFD_NEED_DECLARATION(malloc)
 686 BFD_NEED_DECLARATION(realloc)
 687 BFD_NEED_DECLARATION(free)
 688 BFD_NEED_DECLARATION(strerror)
 689 BFD_NEED_DECLARATION(strdup)
 690 BFD_NEED_DECLARATION(strstr)
 691 BFD_NEED_DECLARATION(canonicalize_file_name)
 692
 693 # The following save_state_t checkery is only necessary for HPUX
 694 # versions earlier than 10.20.  When those fade from memory, this
 695 # could be expunged. --jsm 1999-03-22
 696
 697 AC_MSG_CHECKING(for HPUX save_state structure)
 698 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 699                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 700 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 701                 gdb_cv_hpux_sswide=no)
 702 if test $gdb_cv_hpux_savestate = yes
 703 then
 704   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 705 fi
 706 if test $gdb_cv_hpux_sswide = yes
 707 then
 708   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 709 fi
 710 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 711
 712
 713 # If we are configured native on GNU/Linux, work around problems with
 714 # sys/procfs.h
 715 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 716
 717 if test "${target}" = "${host}"; then
 718   case "${host}" in
 719   i[[3456]]86-*-linux*)
 720         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 721         AC_DEFINE(sys_quotactl)
 722         ;;
 723   ia64-*-aix*)
 724       AC_DEFINE(NEW_PROC_API)
 725       ;;
 726   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 727       AC_DEFINE(NEW_PROC_API)
 728       ;;
 729   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 730       AC_DEFINE(NEW_PROC_API)
 731       ;;
 732   mips-sgi-irix5*)
 733       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 734       AC_DEFINE([_KMEMUSER], 1)
 735       ;;
 736   esac
 737 fi
 738
 739 if test "$ac_cv_header_sys_procfs_h" = yes; then
 740   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 741   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 742   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 743   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 744   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 745   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 746   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 747   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 748   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 749   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 750   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 751   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 752   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 753   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 754
 755
 756   dnl Check for broken prfpregset_t type
 757
 758   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 759   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 760   dnl instead of the struct itself).  We detect this here, and work
 761   dnl around it in gdb_proc_service.h.
 762
 763   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 764     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 765     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 766       [AC_TRY_RUN([#include <sys/procfs.h>
 767        int main ()
 768        {
 769          if (sizeof (prfpregset_t) == sizeof (void *))
 770            return 1;
 771          return 0;
 772        }],
 773        gdb_cv_prfpregset_t_broken=no,
 774        gdb_cv_prfpregset_t_broken=yes,
 775        gdb_cv_prfpregset_t_broken=yes)])
 776     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 777     if test $gdb_cv_prfpregset_t_broken = yes; then
 778       AC_DEFINE(PRFPREGSET_T_BROKEN)
 779     fi
 780   fi
 781
 782   dnl Check for PIOCSET ioctl entry
 783
 784   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 785   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 786   [AC_TRY_COMPILE([#include <unistd.h>
 787 #include <sys/types.h>
 788 #include <sys/procfs.h>
 789 ], [
 790     int dummy;;
 791     dummy = ioctl(0, PIOCSET, &dummy);
 792   ],
 793   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 794   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 795   if test $gdb_cv_have_procfs_piocset = yes; then
 796     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 797   fi
 798 fi
 799
 800 dnl For native ports (host == target), check to see what kind of
 801 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 802 if test ${host} = ${target} ; then
 803   dnl Check for struct link_map with l_ members which are indicative
 804   dnl of SVR4-like shared libraries
 805
 806   AC_MSG_CHECKING(for member l_addr in struct link_map)
 807   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 808     [AC_TRY_COMPILE([#include <link.h>],
 809                     [struct link_map lm; (void) lm.l_addr;],
 810                     gdb_cv_have_struct_link_map_with_l_members=yes,
 811                     gdb_cv_have_struct_link_map_with_l_members=no)])
 812   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 813   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 814     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 815   fi
 816
 817   dnl Check for struct link_map with lm_ members which are indicative
 818   dnl of SunOS-like shared libraries
 819
 820   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 821   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 822     [AC_TRY_COMPILE([#include <sys/types.h>
 823 #include <link.h>],
 824                     [struct link_map lm; (void) lm.lm_addr;],
 825                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 826                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 827   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 828   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 829     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 830   fi
 831
 832   dnl Check for struct so_map with som_ members which are found on
 833   dnl some *BSD systems.
 834
 835   AC_MSG_CHECKING(for member som_addr in struct so_map)
 836   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 837     [AC_TRY_COMPILE([#include <sys/types.h>
 838 #ifdef HAVE_NLIST_H
 839 #include <nlist.h>
 840 #endif
 841 #include <link.h>],
 842                     [struct so_map lm; (void) lm.som_addr;],
 843                     gdb_cv_have_struct_so_map_with_som_members=yes,
 844                     gdb_cv_have_struct_so_map_with_som_members=no)])
 845   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 846   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 847     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 848   fi
 849
 850   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 851   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 852
 853   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 854   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 855     [AC_TRY_COMPILE([#define _SYSCALL32
 856 #include <sys/link.h>], [struct link_map32 l;],
 857      gdb_cv_have_struct_link_map32=yes,
 858      gdb_cv_have_struct_link_map32=no)])
 859   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 860   if test $gdb_cv_have_struct_link_map32 = yes; then
 861     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 862     AC_DEFINE(_SYSCALL32)
 863   fi
 864 fi
 865
 866 dnl See if compiler supports "long long" type.
 867
 868 AC_MSG_CHECKING(for long long support in compiler)
 869 AC_CACHE_VAL(gdb_cv_c_long_long,
 870 [AC_TRY_COMPILE(, [
 871   extern long long foo;
 872   switch (foo & 2) { case 0: return 1; }
 873 ],
 874 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 875 AC_MSG_RESULT($gdb_cv_c_long_long)
 876 if test $gdb_cv_c_long_long = yes; then
 877   AC_DEFINE(CC_HAS_LONG_LONG)
 878 fi
 879
 880 dnl See if the compiler and runtime support printing long long
 881
 882 AC_MSG_CHECKING(for long long support in printf)
 883 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 884 [AC_TRY_RUN([
 885 int main () {
 886   char buf[32];
 887   long long l = 0;
 888   l = (l << 16) + 0x0123;
 889   l = (l << 16) + 0x4567;
 890   l = (l << 16) + 0x89ab;
 891   l = (l << 16) + 0xcdef;
 892   sprintf (buf, "0x%016llx", l);
 893   return (strcmp ("0x0123456789abcdef", buf));
 894 }],
 895 gdb_cv_printf_has_long_long=yes,
 896 gdb_cv_printf_has_long_long=no,
 897 gdb_cv_printf_has_long_long=no)])
 898 if test $gdb_cv_printf_has_long_long = yes; then
 899   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 900 fi
 901 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 902
 903 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 904 dnl because autoconf complains about cross-compilation issues.  However, this
 905 dnl code uses the same variables as the macro for compatibility.
 906
 907 AC_MSG_CHECKING(for long double support in compiler)
 908 AC_CACHE_VAL(ac_cv_c_long_double,
 909 [AC_TRY_COMPILE(, [long double foo;],
 910 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 911 AC_MSG_RESULT($ac_cv_c_long_double)
 912 if test $ac_cv_c_long_double = yes; then
 913   AC_DEFINE(HAVE_LONG_DOUBLE)
 914 fi
 915
 916 dnl See if the compiler and runtime support printing long doubles
 917
 918 AC_MSG_CHECKING(for long double support in printf)
 919 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 920 [AC_TRY_RUN([
 921 int main () {
 922   char buf[16];
 923   long double f = 3.141592653;
 924   sprintf (buf, "%Lg", f);
 925   return (strncmp ("3.14159", buf, 7));
 926 }],
 927 gdb_cv_printf_has_long_double=yes,
 928 gdb_cv_printf_has_long_double=no,
 929 gdb_cv_printf_has_long_double=no)])
 930 if test $gdb_cv_printf_has_long_double = yes; then
 931   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 932 fi
 933 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 934
 935 dnl See if the compiler and runtime support scanning long doubles
 936
 937 AC_MSG_CHECKING(for long double support in scanf)
 938 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 939 [AC_TRY_RUN([
 940 int main () {
 941   char *buf = "3.141592653";
 942   long double f = 0;
 943   sscanf (buf, "%Lg", &f);
 944   return !(f > 3.14159 && f < 3.14160);
 945 }],
 946 gdb_cv_scanf_has_long_double=yes,
 947 gdb_cv_scanf_has_long_double=no,
 948 gdb_cv_scanf_has_long_double=no)])
 949 if test $gdb_cv_scanf_has_long_double = yes; then
 950   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 951 fi
 952 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 953
 954 case ${host_os} in
 955 aix*)
 956   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 957     SAVE_LDFLAGS=$LDFLAGS
 958
 959     case $GCC in
 960     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 961     *) gdb_cv_bigtoc=-bbigtoc ;;
 962     esac
 963
 964     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 965     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 966     LDFLAGS="${SAVE_LDFLAGS}"
 967   ])
 968   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 969   ;;
 970 esac
 971
 972
 973 dnl For certain native configurations, we need to check whether thread
 974 dnl support can be built in or not.
 975 dnl
 976 dnl Note that we only want this if we are both native (host == target),
 977 dnl and not doing a canadian cross build (build == host).
 978
 979 if test ${build} = ${host} -a ${host} = ${target} ; then
 980    case ${host_os} in
 981    hpux*)
 982       AC_MSG_CHECKING(for HPUX/OSF thread support)
 983       if test -f /usr/include/dce/cma_config.h ; then
 984          if test "$GCC" = "yes" ; then
 985             AC_MSG_RESULT(yes)
 986             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 987             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 988             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 989          else
 990             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 991          fi
 992       else
 993          AC_MSG_RESULT(no)
 994       fi
 995       ;;
 996    solaris*)
 997       # See if thread_db library is around for Solaris thread debugging.
 998       # Note that we must explicitly test for version 1 of the library
 999       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1000       # the same API.
1001       AC_MSG_CHECKING(for Solaris thread debugging library)
1002       if test -f /usr/lib/libthread_db.so.1 ; then
1003          AC_MSG_RESULT(yes)
1004          AC_DEFINE(HAVE_THREAD_DB_LIB)
1005          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1006          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1007          AC_CHECK_LIB(dl, dlopen)
1008          if test "$GCC" = "yes" ; then
1009             # The GNU linker requires the -export-dynamic option to make
1010             # all symbols visible in the dynamic symbol table.
1011             hold_ldflags=$LDFLAGS
1012             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1013             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1014             AC_TRY_LINK(, [int i;], found=yes, found=no)
1015             LDFLAGS=$hold_ldflags
1016             AC_MSG_RESULT($found)
1017             if test $found = yes; then
1018                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1019             fi
1020          fi
1021          # Sun randomly tweaked the prototypes in <proc_service.h>
1022          # at one point.
1023          AC_MSG_CHECKING(if <proc_service.h> is old)
1024          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1025             AC_TRY_COMPILE([
1026                 #include <proc_service.h>
1027                 ps_err_e ps_pdwrite
1028                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1029             ],, gdb_cv_proc_service_is_old=no,
1030                 gdb_cv_proc_service_is_old=yes)
1031          ])
1032          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1033          if test $gdb_cv_proc_service_is_old = yes; then
1034             AC_DEFINE(PROC_SERVICE_IS_OLD)
1035          fi
1036       else
1037          AC_MSG_RESULT(no)
1038       fi
1039       ;;
1040    aix*)
1041       AC_MSG_CHECKING(for AiX thread debugging library)
1042       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1043                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1044                                    [#ifndef PTHDB_VERSION_3
1045                                     #error
1046                                     #endif],
1047                                    gdb_cv_have_aix_thread_debug=yes,
1048                                    gdb_cv_have_aix_thread_debug=no)])
1049       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1050       if test $gdb_cv_have_aix_thread_debug = yes; then
1051          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1052          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1053          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1054       fi
1055       ;;
1056    esac
1057    AC_SUBST(CONFIG_LDFLAGS)
1058 fi
1059
1060 dnl See if we have a thread_db header file that has TD_NOTALLOC.
1061 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1062    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1063                   gdb_cv_thread_db_h_has_td_notalloc,
1064      AC_TRY_COMPILE(
1065        [#include <thread_db.h>],
1066        [int i = TD_NOTALLOC;],
1067        gdb_cv_thread_db_h_has_td_notalloc=yes,
1068        gdb_cv_thread_db_h_has_td_notalloc=no
1069      )
1070    )
1071 fi
1072 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1073   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1074             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1075 fi
1076
1077 dnl See if we have a sys/syscall header file that has __NR_tkill.
1078 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1079    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1080                   gdb_cv_sys_syscall_h_has_tkill,
1081      AC_TRY_COMPILE(
1082        [#include <sys/syscall.h>],
1083        [int i = __NR_tkill;],
1084        gdb_cv_sys_syscall_h_has_tkill=yes,
1085        gdb_cv_sys_syscall_h_has_tkill=no
1086      )
1087    )
1088 fi
1089 dnl See if we can issue tkill syscall.
1090 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1091   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
1092             [Define if we can use the tkill syscall.])
1093 fi
1094
1095 dnl Handle optional features that can be enabled.
1096
1097 AC_ARG_WITH(sysroot,
1098 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1099 [
1100  case ${with_sysroot} in
1101  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1102  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1103  esac
1104
1105  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1106
1107  if test "x$exec_prefix" = xNONE; then
1108   if test "x$prefix" = xNONE; then
1109    test_prefix=/usr/local
1110   else
1111    test_prefix=$prefix
1112   fi
1113  else
1114   test_prefix=$exec_prefix
1115  fi
1116  case ${TARGET_SYSTEM_ROOT} in
1117  "${test_prefix}"|"${test_prefix}/"*|\
1118  '${exec_prefix}'|'${exec_prefix}/'*)
1119    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1120    TARGET_SYSTEM_ROOT_DEFINE="$t"
1121    ;;
1122  esac
1123 ], [
1124  TARGET_SYSTEM_ROOT=
1125  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1126 ])
1127 AC_SUBST(TARGET_SYSTEM_ROOT)
1128 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1129
1130 # NOTE: Don't add -Wall or -Wunused, they both include
1131 # -Wunused-parameter which reports bogus warnings.
1132 # NOTE: If you add to this list, remember to update
1133 # gdb/doc/gdbint.texinfo.
1134 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1135 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1136 -Wunused-label -Wunused-function"
1137 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1138 # -Wunused-function -Wunused-variable -Wunused-value
1139 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1140 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1141 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1142 # -Woverloaded-virtual -Winline -Werror"
1143 AC_ARG_ENABLE(build-warnings,
1144 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1145 [case "${enableval}" in
1146   yes)  ;;
1147   no)   build_warnings="-w";;
1148   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1149         build_warnings="${build_warnings} ${t}";;
1150   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1151         build_warnings="${t} ${build_warnings}";;
1152   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1153 esac
1154 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1155   echo "Setting compiler warning flags = $build_warnings" 6>&1
1156 fi])dnl
1157 AC_ARG_ENABLE(gdb-build-warnings,
1158 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1159 [case "${enableval}" in
1160   yes)  ;;
1161   no)   build_warnings="-w";;
1162   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1163         build_warnings="${build_warnings} ${t}";;
1164   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1165         build_warnings="${t} ${build_warnings}";;
1166   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1167 esac
1168 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1169   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1170 fi])dnl
1171 WARN_CFLAGS=""
1172 WERROR_CFLAGS=""
1173 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1174 then
1175     AC_MSG_CHECKING(compiler warning flags)
1176     # Separate out the -Werror flag as some files just cannot be
1177     # compiled with it enabled.
1178     for w in ${build_warnings}; do
1179         case $w in
1180         -Werr*) WERROR_CFLAGS=-Werror ;;
1181         *) # Check that GCC accepts it
1182             saved_CFLAGS="$CFLAGS"
1183             CFLAGS="$CFLAGS $w"
1184             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1185             CFLAGS="$saved_CFLAGS"
1186         esac
1187     done
1188     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1189 fi
1190 AC_SUBST(WARN_CFLAGS)
1191 AC_SUBST(WERROR_CFLAGS)
1192
1193 # In the Cygwin environment, we need some additional flags.
1194 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1195 [AC_EGREP_CPP(lose, [
1196 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1197 lose
1198 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1199
1200
1201 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1202 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1203 case ${host} in
1204   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1205   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1206 esac
1207 AC_SUBST(SER_HARDWIRE)
1208
1209 # libreadline needs libuser32.a in a cygwin environment
1210 WIN32LIBS=
1211 if test x$gdb_cv_os_cygwin = xyes; then
1212     WIN32LIBS="-luser32"
1213     case "${target}" in
1214         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1215         ;;
1216     esac
1217 fi
1218 AC_SUBST(WIN32LIBS)
1219
1220 LIBGUI="../libgui/src/libgui.a"
1221 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1222 AC_SUBST(LIBGUI)
1223 AC_SUBST(GUI_CFLAGS_X)
1224
1225 WIN32LDAPP=
1226 AC_SUBST(WIN32LIBS)
1227 AC_SUBST(WIN32LDAPP)
1228
1229 case "${host}" in
1230 *-*-cygwin*)
1231     configdir="win"
1232     ;;
1233 *)
1234     configdir="unix"
1235     ;;
1236 esac
1237
1238 GDBTKLIBS=
1239 if test "${enable_gdbtk}" = "yes"; then
1240
1241     # Gdbtk must have an absolute path to srcdir in order to run
1242     # properly when not installed.
1243     here=`pwd`
1244     cd ${srcdir}
1245     GDBTK_SRC_DIR=`pwd`
1246     cd $here
1247
1248     CY_AC_PATH_TCLCONFIG
1249     if test -z "${no_tcl}"; then
1250         CY_AC_LOAD_TCLCONFIG
1251         CY_AC_PATH_TKCONFIG
1252
1253         # now look for Tcl library stuff
1254
1255         tcldir="../tcl/${configdir}/"
1256
1257         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1258
1259         # If $no_tk is nonempty, then we can't do Tk, and there is no
1260         # point to doing Tcl.
1261         if test -z "${no_tk}"; then
1262            CY_AC_LOAD_TKCONFIG
1263            CY_AC_PATH_TCLH
1264            CY_AC_PATH_TKH
1265            CY_AC_PATH_ITCLH
1266            CY_AC_PATH_ITKH
1267
1268
1269            # now look for Tk library stuff
1270
1271            tkdir="../tk/${configdir}/"
1272
1273            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1274
1275            # now look for Itcl library stuff
1276
1277            CY_AC_PATH_ITCLCONFIG
1278            if test -z "${no_itcl}"; then
1279              CY_AC_LOAD_ITCLCONFIG
1280
1281              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1282              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1283            fi
1284
1285
1286            # now look for Itk library stuff
1287            CY_AC_PATH_ITKCONFIG
1288            if test -z "${no_itcl}"; then
1289              CY_AC_LOAD_ITKCONFIG
1290
1291              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1292              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1293            fi
1294
1295            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1296            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1297            # know whether 8.2 will or not, but I bet it will.
1298            # I don't have to worry about 7.x since we don't support it.
1299            GDBTK_CFLAGS=""
1300            if test "$GCC" = "yes"; then
1301                if test "$TCL_VERSION" != "8.0" ; then
1302                    GDBTK_CFLAGS="-fwritable-strings"
1303                fi
1304            fi
1305
1306            # Include some libraries that Tcl and Tk want.
1307            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1308            # Yes, the ordering seems wrong here.  But it isn't.
1309            # TK_LIBS is the list of libraries that need to be linked
1310            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1311            # were in LIBS then any link tests after this point would
1312            # try to include things like `$(LIBGUI)', which wouldn't work.
1313            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1314
1315            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1316            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1317            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1318            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1319            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1320            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1321            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1322
1323            if test x$gdb_cv_os_cygwin = xyes; then
1324               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1325               WIN32LDAPP="-Wl,--subsystem,console"
1326               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1327            fi
1328         fi
1329     fi
1330
1331     configdirs="${configdirs} gdbtk"
1332 fi
1333
1334 AC_SUBST(X_CFLAGS)
1335 AC_SUBST(X_LDFLAGS)
1336 AC_SUBST(X_LIBS)
1337 AC_SUBST(TCL_DEPS)
1338 AC_SUBST(TK_DEPS)
1339 AC_SUBST(ITCLLIB)
1340 AC_SUBST(ITCL_DEPS)
1341 AC_SUBST(ITKLIB)
1342 AC_SUBST(ITK_DEPS)
1343 AC_SUBST(GDBTKLIBS)
1344 AC_SUBST(GDBTK_CFLAGS)
1345 AC_SUBST(GDBTK_SRC_DIR)
1346
1347 AC_PATH_X
1348
1349 # Check whether we should enable the TUI, but only do so if we really
1350 # can.
1351 if test x"$enable_tui" = xyes; then
1352   if test -d $srcdir/tui; then
1353     if test "$ac_cv_search_waddstr" != no; then
1354       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1355       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1356       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1357       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1358       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1359       CONFIG_ALL="${CONFIG_ALL} all-tui"
1360       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1361       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1362       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1363     else
1364       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1365     fi
1366   fi
1367 fi
1368
1369 # Unlike the sim directory, whether a simulator is linked is controlled by
1370 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1371 # This code just checks for a few cases where we'd like to ignore those
1372 # definitions, even when they're present in the '.mt' file.  These cases
1373 # are when --disable-sim is specified, or if the simulator directory is
1374 # not part of the source tree.
1375 #
1376 AC_ARG_ENABLE(sim,
1377 [  --enable-sim            Link gdb with simulator],
1378 [echo "enable_sim = $enable_sim";
1379  echo "enableval = ${enableval}";
1380  case "${enableval}" in
1381   yes) ignore_sim=false ;;
1382   no)  ignore_sim=true ;;
1383   *)   ignore_sim=false ;;
1384  esac],
1385 [ignore_sim=false])
1386
1387 if test ! -d "${srcdir}/../sim"; then
1388   ignore_sim=true
1389 fi
1390
1391 if test "${ignore_sim}" = "true"; then
1392     IGNORE_SIM="SIM="
1393     IGNORE_SIM_OBS="SIM_OBS="
1394 else
1395     IGNORE_SIM=""
1396     IGNORE_SIM_OBS=""
1397     AC_DEFINE(WITH_SIM)
1398 fi
1399 AC_SUBST(IGNORE_SIM)
1400 AC_SUBST(IGNORE_SIM_OBS)
1401
1402 AC_SUBST(ENABLE_CFLAGS)
1403 AC_SUBST(PROFILE_CFLAGS)
1404
1405 AC_SUBST(CONFIG_OBS)
1406 AC_SUBST(CONFIG_DEPS)
1407 AC_SUBST(CONFIG_SRCS)
1408 AC_SUBST(CONFIG_ALL)
1409 AC_SUBST(CONFIG_CLEAN)
1410 AC_SUBST(CONFIG_INSTALL)
1411 AC_SUBST(CONFIG_UNINSTALL)
1412
1413 # List of host floatformats.
1414 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1415 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1416 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1417
1418 # target_subdir is used by the testsuite to find the target libraries.
1419 target_subdir=
1420 if test "${host}" != "${target}"; then
1421     target_subdir="${target_alias}/"
1422 fi
1423 AC_SUBST(target_subdir)
1424
1425 frags=
1426 if test "${target}" = "${host}"; then
1427   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1428   if test ! -f ${host_makefile_frag}; then
1429     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1430   fi
1431   frags="$frags $host_makefile_frag"
1432 else
1433   host_makefile_frag=/dev/null
1434 fi
1435
1436 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1437 if test ! -f ${target_makefile_frag}; then
1438   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1439 fi
1440 frags="$frags $target_makefile_frag"
1441
1442 AC_SUBST_FILE(host_makefile_frag)
1443 AC_SUBST_FILE(target_makefile_frag)
1444 AC_SUBST(frags)
1445
1446 changequote(,)dnl
1447 hostfile=`sed -n '
1448 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1449 ' ${host_makefile_frag}`
1450
1451 targetfile=`sed -n '
1452 s/DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1453 ' ${target_makefile_frag}`
1454
1455 if test "${target}" = "${host}"; then
1456 # We pick this up from the host configuration file (.mh) because we
1457 # do not have a native configuration Makefile fragment.
1458 nativefile=`sed -n '
1459 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1460 ' ${host_makefile_frag}`
1461 fi
1462 changequote([,])
1463
1464 if test x"${gdb_osabi}" != x ; then
1465     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1466                        [Define to the default OS ABI for this configuration.])
1467 fi
1468
1469 # Enable multi-ice-gdb-server.
1470 AC_ARG_ENABLE(multi-ice,
1471 [  --enable-multi-ice      build the multi-ice-gdb-server],
1472   [case $enableval in
1473     yes | no)
1474       ;;
1475     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1476   esac])
1477 if test "x$enable_multi_ice" = xyes; then
1478   configdirs="$configdirs multi-ice"
1479 fi
1480
1481 # We only build gdbserver automatically if host and target are the same.
1482 if test "x$target" = "x$host"; then
1483   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1484   if test "x$build_gdbserver" = xyes; then
1485     configdirs="$configdirs gdbserver"
1486     AC_MSG_RESULT(yes)
1487   else
1488     AC_MSG_RESULT(no)
1489   fi
1490 fi
1491
1492 AC_CONFIG_SUBDIRS($configdirs)
1493
1494 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1495 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1496 # to an empty version.
1497
1498 files=
1499 links=
1500
1501 rm -f xm.h
1502 xm_h=""
1503 if test "${hostfile}" != ""; then
1504     xm_h=xm.h
1505     case "${hostfile}" in
1506       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1507       * ) GDB_XM_FILE="${hostfile}"
1508     esac
1509     files="${files} ${GDB_XM_FILE}"
1510     links="${links} xm.h"
1511     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}")
1512 fi
1513 AC_SUBST(xm_h)
1514
1515 rm -f tm.h
1516 tm_h=""
1517 if test "${targetfile}" != ""; then
1518     tm_h=tm.h
1519     case "${targetfile}" in
1520       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1521       * ) GDB_TM_FILE="${targetfile}"
1522     esac
1523     files="${files} ${GDB_TM_FILE}"
1524     links="${links} tm.h"
1525     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}")
1526 fi
1527 AC_SUBST(tm_h)
1528
1529 rm -f nm.h
1530 nm_h=""
1531 if test "${nativefile}" != ""; then
1532     nm_h=nm.h
1533     case "${nativefile}" in
1534       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1535       * ) GDB_NM_FILE="${nativefile}"
1536     esac
1537     files="${files} ${GDB_NM_FILE}"
1538     links="${links} nm.h"
1539     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}")
1540 fi
1541 AC_SUBST(nm_h)
1542
1543 AC_LINK_FILES($files, $links)
1544
1545 dnl Check for exe extension set on certain hosts (e.g. Win32)
1546 AC_EXEEXT
1547
1548 dnl  Detect the character set used by this host.
1549
1550 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1551 dnl  superset of ASCII containing the characters needed for French,
1552 dnl  German, Spanish, Italian, and possibly others), but if were
1553 dnl  *were* to support any host character sets other than ISO-8859-1,
1554 dnl  here's where we'd detect it.
1555 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1556           [Define to be a string naming the default host character set.])
1557
1558 AM_ICONV
1559
1560 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1561 [
1562 dnl Autoconf doesn't provide a mechanism for modifying definitions
1563 dnl provided by makefile fragments.
1564 dnl
1565
1566 changequote(,)dnl
1567 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1568 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1569 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1570 mv -f Makefile.tmp Makefile
1571 changequote([,])dnl
1572
1573
1574 case x$CONFIG_HEADERS in
1575 xconfig.h:config.in)
1576 echo > stamp-h ;;
1577 esac
1578 ],
1579 [
1580 gdb_host_cpu=$gdb_host_cpu
1581 gdb_target_cpu=$gdb_target_cpu
1582 nativefile=$nativefile
1583 ])
1584
1585 exit 0