gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_LIB_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 CONFIG_INITS=
  67 ENABLE_CFLAGS=
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 AC_CONFIG_SUBDIRS(doc testsuite)
  74 configdirs=
  75
  76 . $srcdir/configure.host
  77
  78 . $srcdir/configure.tgt
  79
  80 # Fetch the default architecture and default target vector from BFD.
  81 targ=$target; . $srcdir/../bfd/config.bfd
  82
  83 # We only want the first architecture, so strip off the others if
  84 # there is more than one.
  85 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  86
  87 if test "x$targ_archs" != x; then
  88   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  89     [Define to BFD's default architecture. ])
  90 fi
  91 if test "x$targ_defvec" != x; then
  92   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  93     [Define to BFD's default target vector. ])
  94 fi
  95
  96 AC_ARG_PROGRAM
  97
  98 # The CLI cannot be disabled yet, but may be in the future.
  99
 100 # Enable CLI.
 101 AC_ARG_ENABLE(gdbcli,
 102 [  --disable-gdbcli        disable command-line interface (CLI)],
 103   [case $enableval in
 104     yes)
 105       ;;
 106     no)
 107       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 108     *)
 109       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 110   esac],
 111   [enable_gdbcli=yes])
 112 if test x"$enable_gdbcli" = xyes; then
 113   if test -d $srcdir/cli; then
 114     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 115     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 116     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 117     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_CLI_INITS)"
 118     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 119     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_CLI_ALL)"
 120     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_CLI_CLEAN)"
 121     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_CLI_INSTALL)"
 122     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_CLI_UNINSTALL)"
 123   fi
 124 fi
 125
 126 # Enable MI.
 127 AC_ARG_ENABLE(gdbmi,
 128 [  --disable-gdbmi         disable machine-interface (MI)],
 129   [case $enableval in
 130     yes | no)
 131       ;;
 132     *)
 133       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 134   esac],
 135   [enable_gdbmi=yes])
 136 if test x"$enable_gdbmi" = xyes; then
 137   if test -d $srcdir/mi; then
 138     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 139     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 140     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 141     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_MI_INITS)"
 142     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 143     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_MI_ALL)"
 144     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_MI_CLEAN)"
 145     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_MI_INSTALL)"
 146     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_MI_UNINSTALL)"
 147   fi
 148 fi
 149
 150 # Enable TUI.
 151 AC_ARG_ENABLE(tui,
 152 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 153   [case $enableval in
 154     yes | no)
 155       ;;
 156     *)
 157       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 158   esac])
 159 if test x"$enable_tui" = xyes; then
 160   if test -d $srcdir/tui; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 164     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 165     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 166     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_TUI_ALL)"
 167     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_TUI_CLEAN)"
 168     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_TUI_INSTALL)"
 169     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_TUI_UNINSTALL)"
 170     need_curses=yes
 171   fi
 172 fi
 173
 174 # Enable gdbtk.
 175 AC_ARG_ENABLE(gdbtk,
 176 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 177   [case $enableval in
 178     yes | no)
 179       ;;
 180     *)
 181       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 182   esac],
 183   [if test -d $srcdir/gdbtk; then
 184     enable_gdbtk=yes
 185   else
 186     enable_gdbtk=no
 187   fi])
 188 # We unconditionally disable gdbtk tests on selected platforms.
 189 case $host_os in
 190   go32* | windows*)
 191     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 192     enable_gdbtk=no ;;
 193 esac
 194
 195 # Libunwind support.
 196 AC_ARG_WITH(libunwind,
 197 [  --with-libunwind            Use libunwind frame unwinding support],
 198 [case "${withval}" in
 199   yes)  enable_libunwind=yes ;;
 200   no)   enable_libunwind=no ;;
 201   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 202 esac],[
 203   AC_CHECK_HEADERS(libunwind.h)
 204   AC_CHECK_HEADERS(libunwind-ia64.h)
 205   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 206     enable_libunwind=yes;
 207   fi
 208 ])
 209
 210 if test x"$enable_libunwind" = xyes; then
 211   AC_CHECK_HEADERS(libunwind.h)
 212   AC_CHECK_HEADERS(libunwind-ia64.h)
 213   AC_DEFINE(HAVE_LIBUNWIND, 1)
 214   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 215   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 216   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 217 fi
 218
 219 # Profiling support.
 220 AC_ARG_ENABLE(profiling,
 221 [  --enable-profiling      enable profiling of GDB],
 222   [case $enableval in
 223     yes | no)
 224       ;;
 225     *)
 226       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 227   esac],
 228  [enable_profiling=no])
 229
 230 AC_CHECK_FUNCS(monstartup _mcleanup)
 231 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 232 [AC_TRY_LINK(
 233 [#include <stdlib.h>
 234 extern char _etext;
 235 ],
 236 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 237 if test $ac_cv_var__etext = yes; then
 238   AC_DEFINE(HAVE__ETEXT, 1,
 239             [Define to 1 if your system has the _etext variable. ])
 240 fi
 241 if test "$enable_profiling" = yes ; then
 242   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 243     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 244   fi
 245   PROFILE_CFLAGS=-pg
 246   OLD_CFLAGS="$CFLAGS"
 247   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 248
 249   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 250     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 251      ac_cv_cc_supports_pg=no)])
 252
 253   if test $ac_cv_cc_supports_pg = no; then
 254     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 255   fi
 256
 257   CFLAGS="$OLD_CFLAGS"
 258 fi
 259
 260 # --------------------- #
 261 # Checks for programs.  #
 262 # --------------------- #
 263
 264 AC_PROG_AWK
 265 AC_PROG_INSTALL
 266 AC_PROG_LN_S
 267 AC_PROG_RANLIB
 268 AC_PROG_YACC
 269
 270 AC_CHECK_TOOL(AR, ar)
 271 AC_CHECK_TOOL(DLLTOOL, dlltool)
 272 AC_CHECK_TOOL(WINDRES, windres)
 273
 274 # Needed for GNU/Hurd.
 275 AC_CHECK_TOOL(MIG, mig)
 276
 277 # ---------------------- #
 278 # Checks for libraries.  #
 279 # ---------------------- #
 280
 281 # We might need to link with -lm; most simulators need it.
 282 AC_CHECK_LIB(m, main)
 283
 284 # We need to link with -lw to get `wctype' on Solaris before Solaris
 285 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 286 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 287 # is known to have this problem).  Therefore we avoid libw if we can.
 288 AC_CHECK_FUNC(wctype, [],
 289   [AC_CHECK_LIB(w, wctype)])
 290
 291 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 292 AC_SEARCH_LIBS(gethostbyname, nsl)
 293
 294 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 295 AC_SEARCH_LIBS(socketpair, socket)
 296
 297 # Since GDB uses Readline, we need termcap functionality, so we need
 298 # to find a library that provides that.  When GDB is configured with
 299 # --enable-tui, we need full curses functionality.
 300 #
 301 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 302 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 303 # Makefile fragments.  That's why we need to have `Hcurses' before
 304 # `curses'.  I don't see why we should use HP curses if a more
 305 # standard curses is available, except that according to HP's
 306 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 307 # HP-UX 10.10 and 10.20.
 308
 309 if test "$need_curses" = yes; then
 310   AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses], [],
 311     [AC_MSG_ERROR([no curses library found])])
 312 fi
 313
 314 case $host_os in
 315   cygwin*)
 316     if test -d $srcdir/libtermcap; then
 317       LIBS="../libtermcap/libtermcap.a $LIBS"
 318       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 319     fi ;;
 320   go32* | *djgpp*)
 321     ac_cv_search_tgetent="none required"
 322     ;;
 323   aix*)
 324     # Readline prefers curses over termcap on AIX.
 325     # ??? Why?
 326     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 327     ;;
 328 esac
 329
 330 # Note: We used to check for libtermlib and libterminfo too, but
 331 # Readline doesn't, so I think we're safe with leaving them out.
 332 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 333
 334 if test "$ac_cv_search_tgetent" = no; then
 335   AC_MSG_ERROR([no termcap library found])
 336 fi
 337
 338 # ------------------------- #
 339 # Checks for header files.  #
 340 # ------------------------- #
 341
 342 AC_HEADER_DIRENT
 343 AC_HEADER_STAT
 344 AC_HEADER_STDC
 345 AC_CHECK_HEADERS(link.h)
 346 AC_CHECK_HEADERS(machine/reg.h)
 347 AC_CHECK_HEADERS(nlist.h)
 348 AC_CHECK_HEADERS(poll.h sys/poll.h)
 349 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 350 AC_CHECK_HEADERS(stddef.h)
 351 AC_CHECK_HEADERS(stdlib.h)
 352 AC_CHECK_HEADERS(stdint.h)
 353 AC_CHECK_HEADERS(string.h memory.h strings.h)
 354 AC_CHECK_HEADERS(sys/fault.h)
 355 AC_CHECK_HEADERS(sys/file.h)
 356 AC_CHECK_HEADERS(sys/filio.h)
 357 AC_CHECK_HEADERS(sys/ioctl.h)
 358 AC_CHECK_HEADERS(sys/param.h)
 359 AC_CHECK_HEADERS(sys/proc.h)
 360 AC_CHECK_HEADERS(sys/procfs.h)
 361 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 362 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 363 AC_CHECK_HEADERS(sys/select.h)
 364 AC_CHECK_HEADERS(sys/syscall.h)
 365 AC_CHECK_HEADERS(sys/user.h)
 366 AC_CHECK_HEADERS(sys/wait.h wait.h)
 367 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 368 AC_CHECK_HEADERS(unistd.h)
 369
 370 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 371 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 372 # think that we don't have <curses.h> if we're using GCC.
 373 case $host_os in
 374   solaris2.[[78]])
 375     if test "$GCC" = yes; then
 376       AC_DEFINE(_MSE_INT_H, 1,
 377         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 378    Solaris 2.[78] when using GCC. ]])
 379     fi ;;
 380 esac
 381 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 382
 383 # FIXME: kettenis/20030102: In most cases we include these
 384 # unconditionally, so what's the point in checking these?
 385 AC_CHECK_HEADERS(ctype.h time.h)
 386
 387 dnl Check for struct stat with an st_blocks member
 388 AC_MSG_CHECKING(for member st_blocks in struct stat)
 389 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
 390   [AC_TRY_COMPILE([#include <sys/types.h>
 391 #include <sys/stat.h>],
 392                   [struct stat st; (void) st.st_blocks;],
 393                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
 394                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
 395 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
 396 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
 397   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
 398 fi
 399 # ------------------------- #
 400 # Checks for declarations.  #
 401 # ------------------------- #
 402
 403 gcc_AC_CHECK_DECLS(getopt)
 404
 405 # ------------------ #
 406 # Checks for types.  #
 407 # ------------------ #
 408
 409 AC_TYPE_SIGNAL
 410
 411 # ------------------------------------- #
 412 # Checks for compiler characteristics.  #
 413 # ------------------------------------- #
 414
 415 AC_C_CONST
 416 AC_C_INLINE
 417
 418 # ------------------------------ #
 419 # Checks for library functions.  #
 420 # ------------------------------ #
 421
 422 AC_FUNC_ALLOCA
 423 AC_FUNC_MMAP
 424 AC_FUNC_VFORK
 425 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 426 AC_CHECK_FUNCS(poll)
 427 AC_CHECK_FUNCS(pread64)
 428 AC_CHECK_FUNCS(sbrk)
 429 AC_CHECK_FUNCS(setpgid setpgrp)
 430 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 431 AC_CHECK_FUNCS(socketpair)
 432 AC_CHECK_FUNCS(syscall)
 433
 434 dnl AC_FUNC_SETPGRP does not work when cross compiling
 435 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 436 if test "$cross_compiling" = no; then
 437   AC_FUNC_SETPGRP
 438 else
 439   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 440     [AC_TRY_COMPILE([
 441 #include <unistd.h>
 442 ], [
 443   if (setpgrp(1,1) == -1)
 444     exit (0);
 445   else
 446     exit (1);
 447 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 448 if test $ac_cv_func_setpgrp_void = yes; then
 449   AC_DEFINE(SETPGRP_VOID, 1)
 450 fi
 451 fi
 452
 453 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 454 # since sigsetjmp might only be defined as a macro.
 455 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 456 [AC_TRY_COMPILE([
 457 #include <setjmp.h>
 458 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 459 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 460 if test $gdb_cv_func_sigsetjmp = yes; then
 461   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 462 fi
 463
 464 # Assume we'll default to using the included libiberty regex.
 465 gdb_use_included_regex=yes
 466
 467 # However, if the system regex is GNU regex, then default to *not*
 468 # using the included regex.
 469 AC_CACHE_CHECK(
 470   [for GNU regex],
 471   [gdb_cv_have_gnu_regex],
 472   [AC_TRY_COMPILE(
 473     [#include <gnu-versions.h>],
 474     [#define REGEX_INTERFACE_VERSION 1
 475 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 476 # error "Version mismatch"
 477 #endif],
 478     gdb_cv_have_gnu_regex=yes,
 479     gdb_cv_have_gnu_regex=no)])
 480 if test $gdb_cv_have_gnu_regex = yes; then
 481   gdb_use_included_regex=no
 482 fi
 483
 484 AC_ARG_WITH(included-regex,
 485   [  --without-included-regex don't use included regex; this is the default
 486                           on systems with version 2 of the GNU C library
 487                           (use with caution on other system)],
 488   gdb_with_regex=$withval,
 489   gdb_with_regex=$gdb_use_included_regex)
 490 if test "$gdb_with_regex" = yes; then
 491   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 492     [Define to 1 if the regex included in libiberty should be used.])
 493 fi
 494
 495 # See if <machine/reg.h> degines `struct reg'.
 496 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 497 [AC_TRY_COMPILE([#include <sys/types.h>
 498 #include <machine/reg.h>], [struct reg r;],
 499 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 500 if test $gdb_cv_struct_reg = yes; then
 501   AC_DEFINE(HAVE_STRUCT_REG, 1,
 502             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 503 fi
 504
 505 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 506 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 507 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 508 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 509 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 510 if test $gdb_cv_struct_reg_r_fs = yes; then
 511   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 512 fi
 513 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 514 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 515 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 516 if test $gdb_cv_struct_reg_r_gs = yes; then
 517   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 518 fi
 519
 520 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 521 AC_MSG_CHECKING(for PTRACE_GETREGS)
 522 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 523 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 524                 [PTRACE_GETREGS;],
 525                 [gdb_cv_have_ptrace_getregs=yes],
 526                 [gdb_cv_have_ptrace_getregs=no])])
 527 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 528 if test $gdb_cv_have_ptrace_getregs = yes; then
 529   AC_DEFINE(HAVE_PTRACE_GETREGS)
 530 fi
 531
 532 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 533 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 534 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 535 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 536                 [PTRACE_GETFPXREGS;],
 537                 [gdb_cv_have_ptrace_getfpxregs=yes],
 538                 [gdb_cv_have_ptrace_getfpxregs=no])])
 539 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 540 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 541   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 542 fi
 543
 544 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 545 AC_MSG_CHECKING(for PT_GETDBREGS)
 546 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 547 [AC_TRY_COMPILE([#include <sys/types.h>
 548 #include <sys/ptrace.h>],
 549                 [PT_GETDBREGS;],
 550                 [gdb_cv_have_pt_getdbregs=yes],
 551                 [gdb_cv_have_pt_getdbregs=no])])
 552 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 553 if test $gdb_cv_have_pt_getdbregs = yes; then
 554   AC_DEFINE(HAVE_PT_GETDBREGS)
 555 fi
 556
 557 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 558 AC_MSG_CHECKING(for PT_GETXMMREGS)
 559 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 560 [AC_TRY_COMPILE([#include <sys/types.h>
 561 #include <sys/ptrace.h>],
 562                 [PT_GETXMMREGS;],
 563                 [gdb_cv_have_pt_getxmmregs=yes],
 564                 [gdb_cv_have_pt_getxmmregs=no])])
 565 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 566 if test $gdb_cv_have_pt_getxmmregs = yes; then
 567   AC_DEFINE(HAVE_PT_GETXMMREGS)
 568 fi
 569
 570 # See if stdint.h provides the uintptr_t type.
 571 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 572 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 573   [AC_TRY_COMPILE(
 574     [#include <stdint.h>],
 575     [uintptr_t foo = 0;],
 576     gdb_cv_have_uintptr_t=yes,
 577     gdb_cv_have_uintptr_t=no)])
 578 if test $gdb_cv_have_uintptr_t = yes; then
 579   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 580 fi
 581
 582 BFD_NEED_DECLARATION(malloc)
 583 BFD_NEED_DECLARATION(realloc)
 584 BFD_NEED_DECLARATION(free)
 585 BFD_NEED_DECLARATION(strerror)
 586 BFD_NEED_DECLARATION(strdup)
 587 BFD_NEED_DECLARATION(strstr)
 588 BFD_NEED_DECLARATION(canonicalize_file_name)
 589
 590 # The following save_state_t checkery is only necessary for HPUX
 591 # versions earlier than 10.20.  When those fade from memory, this
 592 # could be expunged. --jsm 1999-03-22
 593
 594 AC_MSG_CHECKING(for HPUX save_state structure)
 595 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 596                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 597 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 598                 gdb_cv_hpux_sswide=no)
 599 if test $gdb_cv_hpux_savestate = yes
 600 then
 601   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 602 fi
 603 if test $gdb_cv_hpux_sswide = yes
 604 then
 605   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 606 fi
 607 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 608
 609
 610 # If we are configured native on GNU/Linux, work around problems with
 611 # sys/procfs.h
 612 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 613
 614 if test "${target}" = "${host}"; then
 615   case "${host}" in
 616   i[[3456]]86-*-linux*)
 617         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 618         AC_DEFINE(sys_quotactl)
 619         ;;
 620   ia64-*-aix*)
 621       AC_DEFINE(NEW_PROC_API)
 622       ;;
 623   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 624       AC_DEFINE(NEW_PROC_API)
 625       ;;
 626   *-*-solaris2.[[678]])
 627       AC_DEFINE(NEW_PROC_API)
 628       ;;
 629   esac
 630 fi
 631
 632 if test "$ac_cv_header_sys_procfs_h" = yes; then
 633   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 634   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 635   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 636   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 637   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 638   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 639   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 640   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 641   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 642   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 643   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 644   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 645   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 646   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 647
 648
 649   dnl Check for broken prfpregset_t type
 650
 651   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 652   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 653   dnl instead of the struct itself).  We detect this here, and work
 654   dnl around it in gdb_proc_service.h.
 655
 656   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 657     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 658     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 659       [AC_TRY_RUN([#include <sys/procfs.h>
 660        int main ()
 661        {
 662          if (sizeof (prfpregset_t) == sizeof (void *))
 663            return 1;
 664          return 0;
 665        }],
 666        gdb_cv_prfpregset_t_broken=no,
 667        gdb_cv_prfpregset_t_broken=yes,
 668        gdb_cv_prfpregset_t_broken=yes)])
 669     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 670     if test $gdb_cv_prfpregset_t_broken = yes; then
 671       AC_DEFINE(PRFPREGSET_T_BROKEN)
 672     fi
 673   fi
 674
 675   dnl Check for PIOCSET ioctl entry
 676
 677   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 678   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 679   [AC_TRY_COMPILE([#include <unistd.h>
 680 #include <sys/types.h>
 681 #include <sys/procfs.h>
 682 ], [
 683     int dummy;;
 684     dummy = ioctl(0, PIOCSET, &dummy);
 685   ],
 686   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 687   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 688   if test $gdb_cv_have_procfs_piocset = yes; then
 689     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 690   fi
 691 fi
 692
 693 dnl For native ports (host == target), check to see what kind of
 694 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 695 if test ${host} = ${target} ; then
 696   dnl Check for struct link_map with l_ members which are indicative
 697   dnl of SVR4-like shared libraries
 698
 699   AC_MSG_CHECKING(for member l_addr in struct link_map)
 700   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 701     [AC_TRY_COMPILE([#include <link.h>],
 702                     [struct link_map lm; (void) lm.l_addr;],
 703                     gdb_cv_have_struct_link_map_with_l_members=yes,
 704                     gdb_cv_have_struct_link_map_with_l_members=no)])
 705   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 706   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 707     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 708   fi
 709
 710   dnl Check for struct link_map with lm_ members which are indicative
 711   dnl of SunOS-like shared libraries
 712
 713   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 714   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 715     [AC_TRY_COMPILE([#include <sys/types.h>
 716 #include <link.h>],
 717                     [struct link_map lm; (void) lm.lm_addr;],
 718                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 719                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 720   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 721   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 722     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 723   fi
 724
 725   dnl Check for struct so_map with som_ members which are found on
 726   dnl some *BSD systems.
 727
 728   AC_MSG_CHECKING(for member som_addr in struct so_map)
 729   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 730     [AC_TRY_COMPILE([#include <sys/types.h>
 731 #ifdef HAVE_NLIST_H
 732 #include <nlist.h>
 733 #endif
 734 #include <link.h>],
 735                     [struct so_map lm; (void) lm.som_addr;],
 736                     gdb_cv_have_struct_so_map_with_som_members=yes,
 737                     gdb_cv_have_struct_so_map_with_som_members=no)])
 738   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 739   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 740     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 741   fi
 742
 743   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 744   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 745
 746   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 747   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 748     [AC_TRY_COMPILE([#define _SYSCALL32
 749 #include <sys/link.h>], [struct link_map32 l;],
 750      gdb_cv_have_struct_link_map32=yes,
 751      gdb_cv_have_struct_link_map32=no)])
 752   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 753   if test $gdb_cv_have_struct_link_map32 = yes; then
 754     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 755     AC_DEFINE(_SYSCALL32)
 756   fi
 757 fi
 758
 759 dnl See if compiler supports "long long" type.
 760
 761 AC_MSG_CHECKING(for long long support in compiler)
 762 AC_CACHE_VAL(gdb_cv_c_long_long,
 763 [AC_TRY_COMPILE(, [
 764   extern long long foo;
 765   switch (foo & 2) { case 0: return 1; }
 766 ],
 767 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 768 AC_MSG_RESULT($gdb_cv_c_long_long)
 769 if test $gdb_cv_c_long_long = yes; then
 770   AC_DEFINE(CC_HAS_LONG_LONG)
 771 fi
 772
 773 dnl See if the compiler and runtime support printing long long
 774
 775 AC_MSG_CHECKING(for long long support in printf)
 776 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 777 [AC_TRY_RUN([
 778 int main () {
 779   char buf[32];
 780   long long l = 0;
 781   l = (l << 16) + 0x0123;
 782   l = (l << 16) + 0x4567;
 783   l = (l << 16) + 0x89ab;
 784   l = (l << 16) + 0xcdef;
 785   sprintf (buf, "0x%016llx", l);
 786   return (strcmp ("0x0123456789abcdef", buf));
 787 }],
 788 gdb_cv_printf_has_long_long=yes,
 789 gdb_cv_printf_has_long_long=no,
 790 gdb_cv_printf_has_long_long=no)])
 791 if test $gdb_cv_printf_has_long_long = yes; then
 792   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 793 fi
 794 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 795
 796 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 797 dnl because autoconf complains about cross-compilation issues.  However, this
 798 dnl code uses the same variables as the macro for compatibility.
 799
 800 AC_MSG_CHECKING(for long double support in compiler)
 801 AC_CACHE_VAL(ac_cv_c_long_double,
 802 [AC_TRY_COMPILE(, [long double foo;],
 803 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 804 AC_MSG_RESULT($ac_cv_c_long_double)
 805 if test $ac_cv_c_long_double = yes; then
 806   AC_DEFINE(HAVE_LONG_DOUBLE)
 807 fi
 808
 809 dnl See if the compiler and runtime support printing long doubles
 810
 811 AC_MSG_CHECKING(for long double support in printf)
 812 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 813 [AC_TRY_RUN([
 814 int main () {
 815   char buf[16];
 816   long double f = 3.141592653;
 817   sprintf (buf, "%Lg", f);
 818   return (strncmp ("3.14159", buf, 7));
 819 }],
 820 gdb_cv_printf_has_long_double=yes,
 821 gdb_cv_printf_has_long_double=no,
 822 gdb_cv_printf_has_long_double=no)])
 823 if test $gdb_cv_printf_has_long_double = yes; then
 824   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 825 fi
 826 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 827
 828 dnl See if the compiler and runtime support scanning long doubles
 829
 830 AC_MSG_CHECKING(for long double support in scanf)
 831 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 832 [AC_TRY_RUN([
 833 int main () {
 834   char *buf = "3.141592653";
 835   long double f = 0;
 836   sscanf (buf, "%Lg", &f);
 837   return !(f > 3.14159 && f < 3.14160);
 838 }],
 839 gdb_cv_scanf_has_long_double=yes,
 840 gdb_cv_scanf_has_long_double=no,
 841 gdb_cv_scanf_has_long_double=no)])
 842 if test $gdb_cv_scanf_has_long_double = yes; then
 843   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 844 fi
 845 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 846
 847 case ${host_os} in
 848 aix*)
 849   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 850     SAVE_LDFLAGS=$LDFLAGS
 851
 852     case $GCC in
 853     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 854     *) gdb_cv_bigtoc=-bbigtoc ;;
 855     esac
 856
 857     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 858     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 859   ])
 860   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 861   ;;
 862 esac
 863
 864
 865 dnl For certain native configurations, we need to check whether thread
 866 dnl support can be built in or not.
 867 dnl
 868 dnl Note that we only want this if we are both native (host == target),
 869 dnl and not doing a canadian cross build (build == host).
 870
 871 if test ${build} = ${host} -a ${host} = ${target} ; then
 872    case ${host_os} in
 873    hpux*)
 874       AC_MSG_CHECKING(for HPUX/OSF thread support)
 875       if test -f /usr/include/dce/cma_config.h ; then
 876          if test "$GCC" = "yes" ; then
 877             AC_MSG_RESULT(yes)
 878             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 879             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 880             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 881          else
 882             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 883          fi
 884       else
 885          AC_MSG_RESULT(no)
 886       fi
 887       ;;
 888    solaris*)
 889       # See if thread_db library is around for Solaris thread debugging.
 890       # Note that we must explicitly test for version 1 of the library
 891       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 892       # the same API.
 893       AC_MSG_CHECKING(for Solaris thread debugging library)
 894       if test -f /usr/lib/libthread_db.so.1 ; then
 895          AC_MSG_RESULT(yes)
 896          AC_DEFINE(HAVE_THREAD_DB_LIB)
 897          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 898          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 899          AC_CHECK_LIB(dl, dlopen)
 900          if test "$GCC" = "yes" ; then
 901             # The GNU linker requires the -export-dynamic option to make
 902             # all symbols visible in the dynamic symbol table.
 903             hold_ldflags=$LDFLAGS
 904             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 905             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 906             AC_TRY_LINK(, [int i;], found=yes, found=no)
 907             LDFLAGS=$hold_ldflags
 908             AC_MSG_RESULT($found)
 909             if test $found = yes; then
 910                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 911             fi
 912          fi
 913          # Sun randomly tweaked the prototypes in <proc_service.h>
 914          # at one point.
 915          AC_MSG_CHECKING(if <proc_service.h> is old)
 916          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 917             AC_TRY_COMPILE([
 918                 #include <proc_service.h>
 919                 ps_err_e ps_pdwrite
 920                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 921             ],, gdb_cv_proc_service_is_old=no,
 922                 gdb_cv_proc_service_is_old=yes)
 923          ])
 924          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 925          if test $gdb_cv_proc_service_is_old = yes; then
 926             AC_DEFINE(PROC_SERVICE_IS_OLD)
 927          fi
 928       else
 929          AC_MSG_RESULT(no)
 930       fi
 931       ;;
 932    aix*)
 933       AC_MSG_CHECKING(for AiX thread debugging library)
 934       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 935                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 936                                    [#ifndef PTHDB_VERSION_3
 937                                     #error
 938                                     #endif],
 939                                    gdb_cv_have_aix_thread_debug=yes,
 940                                    gdb_cv_have_aix_thread_debug=no)])
 941       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 942       if test $gdb_cv_have_aix_thread_debug = yes; then
 943          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 944          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
 945          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 946       fi
 947       ;;
 948    esac
 949    AC_SUBST(CONFIG_LDFLAGS)
 950 fi
 951
 952 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 953 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 954    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 955                   gdb_cv_thread_db_h_has_td_notalloc,
 956      AC_TRY_COMPILE(
 957        [#include <thread_db.h>],
 958        [int i = TD_NOTALLOC;],
 959        gdb_cv_thread_db_h_has_td_notalloc=yes,
 960        gdb_cv_thread_db_h_has_td_notalloc=no
 961      )
 962    )
 963 fi
 964 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 965   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 966             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 967 fi
 968
 969 dnl See if we have a sys/syscall header file that has __NR_tkill.
 970 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 971    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 972                   gdb_cv_sys_syscall_h_has_tkill,
 973      AC_TRY_COMPILE(
 974        [#include <sys/syscall.h>],
 975        [int i = __NR_tkill;],
 976        gdb_cv_sys_syscall_h_has_tkill=yes,
 977        gdb_cv_sys_syscall_h_has_tkill=no
 978      )
 979    )
 980 fi
 981 dnl See if we can issue tkill syscall.
 982 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 983   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 984             [Define if we can use the tkill syscall.])
 985 fi
 986
 987 dnl Handle optional features that can be enabled.
 988
 989 AC_ARG_WITH(sysroot,
 990 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 991 [
 992  case ${with_sysroot} in
 993  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 994  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 995  esac
 996
 997  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 998
 999  if test "x$exec_prefix" = xNONE; then
1000   if test "x$prefix" = xNONE; then
1001    test_prefix=/usr/local
1002   else
1003    test_prefix=$prefix
1004   fi
1005  else
1006   test_prefix=$exec_prefix
1007  fi
1008  case ${TARGET_SYSTEM_ROOT} in
1009  "${test_prefix}"|"${test_prefix}/"*|\
1010  '${exec_prefix}'|'${exec_prefix}/'*)
1011    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1012    TARGET_SYSTEM_ROOT_DEFINE="$t"
1013    ;;
1014  esac
1015 ], [
1016  TARGET_SYSTEM_ROOT=
1017  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1018 ])
1019 AC_SUBST(TARGET_SYSTEM_ROOT)
1020 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1021
1022 # NOTE: Don't add -Wall or -Wunused, they both include
1023 # -Wunused-parameter which reports bogus warnings.
1024 # NOTE: If you add to this list, remember to update
1025 # gdb/doc/gdbint.texinfo.
1026 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1027 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1028 -Wunused-label"
1029 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1030 # -Wunused-function -Wunused-variable -Wunused-value
1031 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1032 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1033 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1034 # -Woverloaded-virtual -Winline -Werror"
1035 AC_ARG_ENABLE(build-warnings,
1036 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1037 [case "${enableval}" in
1038   yes)  ;;
1039   no)   build_warnings="-w";;
1040   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1041         build_warnings="${build_warnings} ${t}";;
1042   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1043         build_warnings="${t} ${build_warnings}";;
1044   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1045 esac
1046 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1047   echo "Setting compiler warning flags = $build_warnings" 6>&1
1048 fi])dnl
1049 AC_ARG_ENABLE(gdb-build-warnings,
1050 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1051 [case "${enableval}" in
1052   yes)  ;;
1053   no)   build_warnings="-w";;
1054   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1055         build_warnings="${build_warnings} ${t}";;
1056   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1057         build_warnings="${t} ${build_warnings}";;
1058   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1059 esac
1060 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1061   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1062 fi])dnl
1063 WARN_CFLAGS=""
1064 WERROR_CFLAGS=""
1065 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1066 then
1067     AC_MSG_CHECKING(compiler warning flags)
1068     # Separate out the -Werror flag as some files just cannot be
1069     # compiled with it enabled.
1070     for w in ${build_warnings}; do
1071         case $w in
1072         -Werr*) WERROR_CFLAGS=-Werror ;;
1073         *) # Check that GCC accepts it
1074             saved_CFLAGS="$CFLAGS"
1075             CFLAGS="$CFLAGS $w"
1076             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1077             CFLAGS="$saved_CFLAGS"
1078         esac
1079     done
1080     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1081 fi
1082 AC_SUBST(WARN_CFLAGS)
1083 AC_SUBST(WERROR_CFLAGS)
1084
1085 MMALLOC_CFLAGS=
1086 MMALLOC=
1087 AC_SUBST(MMALLOC_CFLAGS)
1088 AC_SUBST(MMALLOC)
1089
1090 AC_ARG_WITH(mmalloc,
1091 [  --with-mmalloc          Use memory mapped malloc package],
1092 [case "${withval}" in
1093   yes)  want_mmalloc=true ;;
1094   no)   want_mmalloc=false;;
1095   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
1096 esac],[want_mmalloc=false])dnl
1097
1098 if test x$want_mmalloc = xtrue; then
1099    AC_DEFINE(USE_MMALLOC)
1100    AC_DEFINE(MMCHECK_FORCE)
1101    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
1102    MMALLOC='../mmalloc/libmmalloc.a'
1103 fi
1104
1105 # In the Cygwin environment, we need some additional flags.
1106 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1107 [AC_EGREP_CPP(lose, [
1108 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1109 lose
1110 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1111
1112
1113 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1114 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1115 case ${host} in
1116   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1117   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1118 esac
1119 AC_SUBST(SER_HARDWIRE)
1120
1121 # libreadline needs libuser32.a in a cygwin environment
1122 WIN32LIBS=
1123 if test x$gdb_cv_os_cygwin = xyes; then
1124     WIN32LIBS="-luser32"
1125     case "${target}" in
1126         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1127         ;;
1128     esac
1129 fi
1130 AC_SUBST(WIN32LIBS)
1131
1132 LIBGUI="../libgui/src/libgui.a"
1133 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1134 AC_SUBST(LIBGUI)
1135 AC_SUBST(GUI_CFLAGS_X)
1136
1137 WIN32LDAPP=
1138 AC_SUBST(WIN32LIBS)
1139 AC_SUBST(WIN32LDAPP)
1140
1141 configdir="unix"
1142
1143 GDBTKLIBS=
1144 if test "${enable_gdbtk}" = "yes"; then
1145
1146     # Gdbtk must have an absolute path to srcdir in order to run
1147     # properly when not installed.
1148     here=`pwd`
1149     cd ${srcdir}
1150     GDBTK_SRC_DIR=`pwd`
1151     cd $here
1152
1153     CY_AC_PATH_TCLCONFIG
1154     if test -z "${no_tcl}"; then
1155         CY_AC_LOAD_TCLCONFIG
1156         CY_AC_PATH_TKCONFIG
1157
1158         # now look for Tcl library stuff
1159
1160         case "${host}" in
1161         *-*-cygwin*)
1162             tcldir=../tcl/win/
1163             ;;
1164         *)
1165             tcldir=../tcl/unix/
1166             ;;
1167         esac
1168
1169         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1170
1171         # If $no_tk is nonempty, then we can't do Tk, and there is no
1172         # point to doing Tcl.
1173         if test -z "${no_tk}"; then
1174            CY_AC_LOAD_TKCONFIG
1175            CY_AC_PATH_TCLH
1176            CY_AC_PATH_TKH
1177            CY_AC_PATH_ITCLH
1178            CY_AC_PATH_ITKH
1179
1180
1181            # now look for Tk library stuff
1182
1183            case "${host}" in
1184            *-*-cygwin*)
1185                tkdir=../tk/win/
1186                ;;
1187            *)
1188                tkdir=../tk/unix/
1189                ;;
1190            esac
1191
1192            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1193
1194            # now look for Itcl library stuff
1195
1196            CY_AC_PATH_ITCLCONFIG
1197            if test -z "${no_itcl}"; then
1198              CY_AC_LOAD_ITCLCONFIG
1199
1200              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1201              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1202            fi
1203
1204
1205            # now look for Itk library stuff
1206            CY_AC_PATH_ITKCONFIG
1207            if test -z "${no_itcl}"; then
1208              CY_AC_LOAD_ITKCONFIG
1209
1210              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1211              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1212            fi
1213
1214            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1215            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1216            # know whether 8.2 will or not, but I bet it will.
1217            # I don't have to worry about 7.x since we don't support it.
1218            GDBTK_CFLAGS=""
1219            if test "$GCC" = "yes"; then
1220                if test "$TCL_VERSION" != "8.0" ; then
1221                    GDBTK_CFLAGS="-fwritable-strings"
1222                fi
1223            fi
1224
1225            # Include some libraries that Tcl and Tk want.
1226            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1227            # Yes, the ordering seems wrong here.  But it isn't.
1228            # TK_LIBS is the list of libraries that need to be linked
1229            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1230            # were in LIBS then any link tests after this point would
1231            # try to include things like `$(LIBGUI)', which wouldn't work.
1232            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1233
1234            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1235            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1236            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1237            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
1238            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
1239            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
1240            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
1241            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
1242
1243            if test x$gdb_cv_os_cygwin = xyes; then
1244               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1245               WIN32LDAPP="-Wl,--subsystem,console"
1246               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1247            fi
1248         fi
1249     fi
1250
1251     configdirs="${configdirs} gdbtk"
1252 fi
1253
1254 AC_SUBST(X_CFLAGS)
1255 AC_SUBST(X_LDFLAGS)
1256 AC_SUBST(X_LIBS)
1257 AC_SUBST(TCL_DEPS)
1258 AC_SUBST(TK_DEPS)
1259 AC_SUBST(ITCLLIB)
1260 AC_SUBST(ITCL_DEPS)
1261 AC_SUBST(ITKLIB)
1262 AC_SUBST(ITK_DEPS)
1263 AC_SUBST(GDBTKLIBS)
1264 AC_SUBST(GDBTK_CFLAGS)
1265 AC_SUBST(GDBTK_SRC_DIR)
1266
1267 AC_PATH_X
1268
1269
1270 # Unlike the sim directory, whether a simulator is linked is controlled by
1271 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1272 # This code just checks for a few cases where we'd like to ignore those
1273 # definitions, even when they're present in the '.mt' file.  These cases
1274 # are when --disable-sim is specified, or if the simulator directory is
1275 # not part of the source tree.
1276 #
1277 AC_ARG_ENABLE(sim,
1278 [  --enable-sim            Link gdb with simulator],
1279 [echo "enable_sim = $enable_sim";
1280  echo "enableval = ${enableval}";
1281  case "${enableval}" in
1282   yes) ignore_sim=false ;;
1283   no)  ignore_sim=true ;;
1284   *)   ignore_sim=false ;;
1285  esac],
1286 [ignore_sim=false])
1287
1288 if test ! -d "${srcdir}/../sim"; then
1289   ignore_sim=true
1290 fi
1291
1292 if test "${ignore_sim}" = "true"; then
1293     IGNORE_SIM="SIM="
1294     IGNORE_SIM_OBS="SIM_OBS="
1295 else
1296     IGNORE_SIM=""
1297     IGNORE_SIM_OBS=""
1298     AC_DEFINE(WITH_SIM)
1299 fi
1300 AC_SUBST(IGNORE_SIM)
1301 AC_SUBST(IGNORE_SIM_OBS)
1302
1303 AC_SUBST(ENABLE_CFLAGS)
1304 AC_SUBST(PROFILE_CFLAGS)
1305
1306 AC_SUBST(CONFIG_OBS)
1307 AC_SUBST(CONFIG_LIB_OBS)
1308 AC_SUBST(CONFIG_DEPS)
1309 AC_SUBST(CONFIG_SRCS)
1310 AC_SUBST(CONFIG_INITS)
1311 AC_SUBST(CONFIG_ALL)
1312 AC_SUBST(CONFIG_CLEAN)
1313 AC_SUBST(CONFIG_INSTALL)
1314 AC_SUBST(CONFIG_UNINSTALL)
1315
1316 # target_subdir is used by the testsuite to find the target libraries.
1317 target_subdir=
1318 if test "${host}" != "${target}"; then
1319     target_subdir="${target_alias}/"
1320 fi
1321 AC_SUBST(target_subdir)
1322
1323 frags=
1324 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1325 if test ! -f ${host_makefile_frag}; then
1326     # When building a native debuger the .mh file containing things
1327     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1328     # since it no longer contains anything useful.
1329     if test "${target}" = "${host}"; then
1330         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1331     else
1332         host_makefile_frag=/dev/null
1333     fi
1334 fi
1335 frags="$frags $host_makefile_frag"
1336
1337 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1338 if test ! -f ${target_makefile_frag}; then
1339 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1340 fi
1341 frags="$frags $target_makefile_frag"
1342
1343 AC_SUBST_FILE(host_makefile_frag)
1344 AC_SUBST_FILE(target_makefile_frag)
1345 AC_SUBST(frags)
1346
1347 changequote(,)dnl
1348 hostfile=`sed -n '
1349 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1350 ' ${host_makefile_frag}`
1351
1352 targetfile=`sed -n '
1353 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1354 ' ${target_makefile_frag}`
1355
1356 if test "${target}" = "${host}"; then
1357 # We pick this up from the host configuration file (.mh) because we
1358 # do not have a native configuration Makefile fragment.
1359 nativefile=`sed -n '
1360 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1361 ' ${host_makefile_frag}`
1362 fi
1363 changequote([,])
1364
1365 if test x"${gdb_osabi}" != x ; then
1366     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1367                        [Define to the default OS ABI for this configuration.])
1368 fi
1369
1370 # Enable multi-ice-gdb-server.
1371 AC_ARG_ENABLE(multi-ice,
1372 [  --enable-multi-ice      build the multi-ice-gdb-server],
1373   [case $enableval in
1374     yes | no)
1375       ;;
1376     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1377   esac])
1378 if test "x$enable_multi_ice" = xyes; then
1379   configdirs="$configdirs multi-ice"
1380 fi
1381
1382 # We only build gdbserver automatically if host and target are the same.
1383 if test "x$target" = "x$host"; then
1384   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1385   if test "x$build_gdbserver" = xyes; then
1386     configdirs="$configdirs gdbserver"
1387     AC_MSG_RESULT(yes)
1388   else
1389     AC_MSG_RESULT(no)
1390   fi
1391 fi
1392
1393 AC_CONFIG_SUBDIRS($configdirs)
1394
1395 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1396 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1397 # version.
1398
1399 files=
1400 links=
1401
1402 rm -f xm.h
1403 xm_h=""
1404 if test "${hostfile}" != ""; then
1405     xm_h=xm.h
1406     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1407     files="${files} ${GDB_XM_FILE}"
1408     links="${links} xm.h"
1409     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1410 fi
1411 AC_SUBST(xm_h)
1412
1413 rm -f tm.h
1414 tm_h=""
1415 if test "${targetfile}" != ""; then
1416     tm_h=tm.h
1417     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1418     files="${files} ${GDB_TM_FILE}"
1419     links="${links} tm.h"
1420     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1421 fi
1422 AC_SUBST(tm_h)
1423
1424 rm -f nm.h
1425 nm_h=""
1426 if test "${nativefile}" != ""; then
1427     nm_h=nm.h
1428     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1429     files="${files} ${GDB_NM_FILE}"
1430     links="${links} nm.h"
1431     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1432 fi
1433 AC_SUBST(nm_h)
1434
1435 AC_LINK_FILES($files, $links)
1436
1437 dnl Check for exe extension set on certain hosts (e.g. Win32)
1438 AC_EXEEXT
1439
1440 dnl  Detect the character set used by this host.
1441
1442 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1443 dnl  superset of ASCII containing the characters needed for French,
1444 dnl  German, Spanish, Italian, and possibly others), but if were
1445 dnl  *were* to support any host character sets other than ISO-8859-1,
1446 dnl  here's where we'd detect it.
1447 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1448           [Define to be a string naming the default host character set.])
1449
1450 AM_ICONV
1451
1452 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1453 [
1454 dnl Autoconf doesn't provide a mechanism for modifying definitions
1455 dnl provided by makefile fragments.
1456 dnl
1457 if test "${nativefile}" = ""; then
1458         < Makefile \
1459         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1460             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1461         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1462         > Makefile.tem
1463 mv -f Makefile.tem Makefile
1464 fi
1465
1466 changequote(,)dnl
1467 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1468 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1469 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1470 mv -f Makefile.tmp Makefile
1471 changequote([,])dnl
1472
1473
1474 case x$CONFIG_HEADERS in
1475 xconfig.h:config.in)
1476 echo > stamp-h ;;
1477 esac
1478 ],
1479 [
1480 gdb_host_cpu=$gdb_host_cpu
1481 gdb_target_cpu=$gdb_target_cpu
1482 nativefile=$nativefile
1483 ])
1484
1485 exit 0