gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2016 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_GNU_SOURCE
  31 AC_SYS_LARGEFILE
  32
  33 AC_CANONICAL_SYSTEM
  34
  35 AC_PROG_INSTALL
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_PROG_RANLIB
  38
  39 AC_ARG_PROGRAM
  40
  41 AC_HEADER_STDC
  42
  43 # See if we are building with C++, and substitute COMPILER.
  44 GDB_AC_BUILD_WITH_CXX
  45
  46 # Set the 'development' global.
  47 . $srcdir/../../bfd/development.sh
  48
  49 # Enable -lmcheck by default (it provides cheap-enough memory
  50 # mangling), but turn it off for releases.
  51 if $development; then
  52   libmcheck_default=yes
  53 else
  54   libmcheck_default=no
  55 fi
  56 GDB_AC_LIBMCHECK(${libmcheck_default})
  57
  58 ACX_NONCANONICAL_TARGET
  59 ACX_NONCANONICAL_HOST
  60
  61 # Dependency checking.
  62 ZW_CREATE_DEPDIR
  63 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  64
  65 # Check for the 'make' the user wants to use.
  66 AC_CHECK_PROGS(MAKE, make)
  67 MAKE_IS_GNU=
  68 case "`$MAKE --version 2>&1 | sed 1q`" in
  69   *GNU*)
  70     MAKE_IS_GNU=yes
  71     ;;
  72 esac
  73 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  74 AC_PROG_MAKE_SET
  75
  76 gnulib_extra_configure_args=
  77 # If large-file support is disabled, make sure gnulib does the same.
  78 if test "$enable_largefile" = no; then
  79 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  80 fi
  81
  82 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  83 # to find the the source subdir to be configured directly under
  84 # gdbserver/.  We need to build gnulib under some other directory not
  85 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  86 # build it in the same directory, when building in the source dir.
  87 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  88                   ["$gnulib_extra_configure_args"])
  89
  90 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  91
  92 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  93                  proc_service.h sys/procfs.h linux/elf.h dnl
  94                  fcntl.h signal.h sys/file.h dnl
  95                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  96                  netinet/tcp.h arpa/inet.h)
  97 AC_FUNC_FORK
  98 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
  99
 100 GDB_AC_COMMON
 101
 102 # Check the return and argument types of ptrace.
 103 GDB_AC_PTRACE
 104
 105 # Check for UST
 106 ustlibs=""
 107 ustinc=""
 108
 109 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 110                           Equivalent to --with-ust-include=PATH/include
 111                           plus --with-ust-lib=PATH/lib])
 112 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 113 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 114
 115 case $with_ust in
 116   no)
 117     ustlibs=
 118     ustinc=
 119     ;;
 120   "" | yes)
 121     ustlibs=" -lust "
 122     ustinc=""
 123     ;;
 124   *)
 125     ustlibs="-L$with_ust/lib -lust"
 126     ustinc="-I$with_ust/include "
 127     ;;
 128 esac
 129 if test "x$with_ust_include" != x; then
 130   ustinc="-I$with_ust_include "
 131 fi
 132 if test "x$with_ust_lib" != x; then
 133   ustlibs="-L$with_ust_lib -lust"
 134 fi
 135
 136 if test "x$with_ust" != "xno"; then
 137   saved_CFLAGS="$CFLAGS"
 138   CFLAGS="$CFLAGS $ustinc"
 139   AC_MSG_CHECKING([for ust])
 140   AC_TRY_COMPILE([
 141 #define CONFIG_UST_GDB_INTEGRATION
 142 #include <ust/ust.h>
 143   ],[],
 144   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 145   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 146   CFLAGS="$saved_CFLAGS"
 147 fi
 148
 149 # Flags needed for UST
 150 AC_SUBST(ustlibs)
 151 AC_SUBST(ustinc)
 152
 153 AM_GDB_WARNINGS
 154 dnl The codebase isn't clean yet with this flag.
 155 case " $WARN_CFLAGS " in
 156 *" -Wmissing-prototypes "*)
 157   WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes"
 158   ;;
 159 esac
 160
 161 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 162 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 163 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 164 dnl augment LIBS.
 165 old_LIBS="$LIBS"
 166 LIBS="$LIBS -ldl"
 167 AC_CHECK_FUNCS(dladdr)
 168 LIBS="$old_LIBS"
 169
 170 libiberty_INIT
 171
 172 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 173
 174 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 175
 176 AC_CHECK_TYPES(socklen_t, [], [],
 177 [#include <sys/types.h>
 178 #include <sys/socket.h>
 179 ])
 180
 181 case "${target}" in
 182   *-android*)
 183     # Starting with NDK version 9, <elf.h> actually includes definitions
 184     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 185     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 186     # leading to conflicts with the defintions from <linux/elf.h>.
 187     # This makes it impossible for us to include both <elf.h> and
 188     # <linux/elf.h>, which means that, in practice, we do not have
 189     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 190     # Therefore, do not try to auto-detect availability, as it would
 191     # get it wrong on this platform.
 192     ;;
 193   *)
 194     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 195     #include <elf.h>
 196     )
 197 esac
 198
 199 ACX_PKGVERSION([GDB])
 200 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 201 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 202 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 203
 204 # Check for various supplementary target information (beyond the
 205 # triplet) which might affect the choices in configure.srv.
 206 case "${target}" in
 207 changequote(,)dnl
 208   i[34567]86-*-linux*)
 209 changequote([,])dnl
 210     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 211                    [save_CPPFLAGS="$CPPFLAGS"
 212                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 213                     AC_EGREP_CPP([got it], [
 214 #if __x86_64__
 215 got it
 216 #endif
 217                  ], [gdb_cv_i386_is_x86_64=yes],
 218                     [gdb_cv_i386_is_x86_64=no])
 219                     CPPFLAGS="$save_CPPFLAGS"])
 220     ;;
 221
 222   x86_64-*-linux*)
 223     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 224                    [save_CPPFLAGS="$CPPFLAGS"
 225                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 226                     AC_EGREP_CPP([got it], [
 227 #if __x86_64__ && __ILP32__
 228 got it
 229 #endif
 230                  ], [gdb_cv_x86_is_x32=yes],
 231                     [gdb_cv_x86_is_x32=no])
 232                     CPPFLAGS="$save_CPPFLAGS"])
 233     ;;
 234
 235   m68k-*-*)
 236     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 237                    [save_CPPFLAGS="$CPPFLAGS"
 238                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 239                     AC_EGREP_CPP([got it], [
 240 #ifdef __mcoldfire__
 241 got it
 242 #endif
 243                  ], [gdb_cv_m68k_is_coldfire=yes],
 244                     [gdb_cv_m68k_is_coldfire=no])
 245                     CPPFLAGS="$save_CPPFLAGS"])
 246     ;;
 247 esac
 248
 249 . ${srcdir}/configure.srv
 250
 251 # Add in the common host objects.
 252 . ${srcdir}/../common/common.host
 253 srv_host_obs="$common_host_obs"
 254
 255 if test "${srv_mingwce}" = "yes"; then
 256   LIBS="$LIBS -lws2"
 257 elif test "${srv_mingw}" = "yes"; then
 258   LIBS="$LIBS -lws2_32"
 259 elif test "${srv_qnx}" = "yes"; then
 260   LIBS="$LIBS -lsocket"
 261 elif test "${srv_lynxos}" = "yes"; then
 262   LIBS="$LIBS -lnetinet"
 263 fi
 264
 265 if test "${srv_mingw}" = "yes"; then
 266   AC_DEFINE(USE_WIN32API, 1,
 267             [Define if we should use the Windows API, instead of the
 268              POSIX API.  On Windows, we use the Windows API when
 269              building for MinGW, but the POSIX API when building
 270              for Cygwin.])
 271 fi
 272
 273 if test "${srv_linux_usrregs}" = "yes"; then
 274   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 275             [Define if the target supports PTRACE_PEEKUSR for register ]
 276             [access.])
 277 fi
 278
 279 if test "${srv_linux_regsets}" = "yes"; then
 280   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 281             [Define if the target supports register sets.])
 282
 283   AC_MSG_CHECKING(for PTRACE_GETREGS)
 284   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 285   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 286                   [PTRACE_GETREGS;],
 287                   [gdbsrv_cv_have_ptrace_getregs=yes],
 288                   [gdbsrv_cv_have_ptrace_getregs=no])])
 289   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 290   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 291     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 292               [Define if the target supports PTRACE_GETREGS for register ]
 293               [access.])
 294   fi
 295
 296   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 297   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 298   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 299                   [PTRACE_GETFPXREGS;],
 300                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 301                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 302   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 303   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 304     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 305               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 306               [register access.])
 307   fi
 308 fi
 309
 310 if test "${srv_linux_btrace}" = "yes"; then
 311   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 312             [Define if the target supports branch tracing.])
 313 fi
 314
 315 if test "$ac_cv_header_sys_procfs_h" = yes; then
 316   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 317   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 318   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 319   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 320   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 321 fi
 322
 323 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 324 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 325   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 326 fi
 327
 328 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 329 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 330   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 331 fi
 332
 333 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 334 dnl needs it (and gdbreplay doesn't).
 335 old_LIBS="$LIBS"
 336 AC_CHECK_LIB(dl, dlopen)
 337 LIBS="$old_LIBS"
 338
 339 srv_thread_depfiles=
 340 srv_libs=
 341
 342 if test "$srv_linux_thread_db" = "yes"; then
 343   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 344     srv_libs="-ldl"
 345     AC_MSG_CHECKING(for the dynamic export flag)
 346     old_LDFLAGS="$LDFLAGS"
 347     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 348     # supported there.
 349     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 350     LDFLAGS="$LDFLAGS $RDYNAMIC"
 351     AC_TRY_LINK([], [],
 352                 [found="-Wl,--dynamic-list"
 353                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 354                 [RDYNAMIC="-rdynamic"
 355                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 356                  AC_TRY_LINK([], [],
 357                              [found="-rdynamic"],
 358                              [found="no"
 359                               RDYNAMIC=""])])
 360     AC_SUBST(RDYNAMIC)
 361     LDFLAGS="$old_LDFLAGS"
 362     AC_MSG_RESULT($found)
 363   else
 364     srv_libs="-lthread_db"
 365   fi
 366
 367   srv_thread_depfiles="thread-db.o proc-service.o"
 368   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 369   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 370   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 371                   [gdbsrv_cv_have_td_version=yes],
 372                   [gdbsrv_cv_have_td_version=no])])
 373   if test $gdbsrv_cv_have_td_version = yes; then
 374     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 375   fi
 376 fi
 377
 378 AC_ARG_WITH(libthread-db,
 379 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 380 [srv_libthread_db_path="${withval}"
 381   srv_libs="$srv_libthread_db_path"
 382 ])
 383
 384 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 385   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 386 fi
 387
 388 if test "$srv_xmlfiles" != ""; then
 389   srv_xmlbuiltin="xml-builtin.o"
 390   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 391
 392   tmp_xmlfiles=$srv_xmlfiles
 393   srv_xmlfiles=""
 394   for f in $tmp_xmlfiles; do
 395     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 396   done
 397 fi
 398
 399 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs"
 400 GDBSERVER_LIBS="$srv_libs"
 401
 402 dnl Check whether the target supports __sync_*_compare_and_swap.
 403 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 404                 gdbsrv_cv_have_sync_builtins, [
 405 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 406                 gdbsrv_cv_have_sync_builtins=yes,
 407                 gdbsrv_cv_have_sync_builtins=no)])
 408 if test $gdbsrv_cv_have_sync_builtins = yes; then
 409   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 410     [Define to 1 if the target supports __sync_*_compare_and_swap])
 411 fi
 412
 413 dnl Check for -fvisibility=hidden support in the compiler.
 414 saved_cflags="$CFLAGS"
 415 CFLAGS="$CFLAGS -fvisibility=hidden"
 416 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 417                         [gdbsrv_cv_have_visibility_hidden=yes],
 418                         [gdbsrv_cv_have_visibility_hidden=no])
 419 CFLAGS="$saved_cflags"
 420
 421 dnl Check if we can disable the virtual address space randomization.
 422 dnl The functionality of setarch -R.
 423 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 424 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 425 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 426 #       define ADDR_NO_RANDOMIZE 0x0040000
 427 #      endif
 428        /* Test the flag could be set and stays set.  */
 429        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 430        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 431            return 1])])
 432 AC_RUN_IFELSE([PERSONALITY_TEST],
 433               [gdbsrv_cv_have_personality=true],
 434               [gdbsrv_cv_have_personality=false],
 435               [AC_LINK_IFELSE([PERSONALITY_TEST],
 436                               [gdbsrv_cv_have_personality=true],
 437                               [gdbsrv_cv_have_personality=false])])
 438 if $gdbsrv_cv_have_personality
 439 then
 440     AC_DEFINE([HAVE_PERSONALITY], 1,
 441               [Define if you support the personality syscall.])
 442 fi
 443
 444
 445 IPA_DEPFILES=""
 446 extra_libraries=""
 447
 448 # check whether to enable the inprocess agent
 449 if test "$ipa_obj" != "" \
 450    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 451    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 452    have_ipa=true
 453 else
 454    have_ipa=false
 455 fi
 456
 457 AC_ARG_ENABLE(inprocess-agent,
 458 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 459 [case "$enableval" in
 460   yes) want_ipa=true ;;
 461   no) want_ipa=false ;;
 462   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 463 esac],
 464 [want_ipa=$have_ipa])
 465
 466 if $want_ipa ; then
 467    if $have_ipa ; then
 468      IPA_DEPFILES="$ipa_obj"
 469      extra_libraries="$extra_libraries libinproctrace.so"
 470    else
 471      AC_MSG_ERROR([inprocess agent not supported for this target])
 472    fi
 473 fi
 474
 475 AC_SUBST(GDBSERVER_DEPFILES)
 476 AC_SUBST(GDBSERVER_LIBS)
 477 AC_SUBST(srv_xmlbuiltin)
 478 AC_SUBST(srv_xmlfiles)
 479 AC_SUBST(IPA_DEPFILES)
 480 AC_SUBST(extra_libraries)
 481
 482 GNULIB=build-gnulib-gdbserver/import
 483
 484 GNULIB_STDINT_H=
 485 if test x"$STDINT_H" != x; then
 486   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 487 fi
 488 AC_SUBST(GNULIB_STDINT_H)
 489
 490 AC_CONFIG_FILES([Makefile],
 491 [case x$CONFIG_HEADERS in
 492 xconfig.h:config.in)
 493 echo > stamp-h ;;
 494 esac
 495 ])
 496
 497 AC_OUTPUT