gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2014 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_SYS_LARGEFILE
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 AC_PROG_INSTALL
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_PROG_RANLIB
  37
  38 AC_ARG_PROGRAM
  39
  40 AC_HEADER_STDC
  41
  42 AC_FUNC_ALLOCA
  43
  44 # Set the 'development' global.
  45 . $srcdir/../../bfd/development.sh
  46
  47 # Enable -lmcheck by default (it provides cheap-enough memory
  48 # mangling), but turn it off for releases.
  49 if $development; then
  50   libmcheck_default=yes
  51 else
  52   libmcheck_default=no
  53 fi
  54 GDB_AC_LIBMCHECK(${libmcheck_default})
  55
  56 ACX_NONCANONICAL_TARGET
  57 ACX_NONCANONICAL_HOST
  58
  59 # Dependency checking.
  60 ZW_CREATE_DEPDIR
  61 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  62
  63 # Check for the 'make' the user wants to use.
  64 AC_CHECK_PROGS(MAKE, make)
  65 MAKE_IS_GNU=
  66 case "`$MAKE --version 2>&1 | sed 1q`" in
  67   *GNU*)
  68     MAKE_IS_GNU=yes
  69     ;;
  70 esac
  71 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  72 AC_PROG_MAKE_SET
  73
  74 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  75 # to find the the source subdir to be configured directly under
  76 # gdbserver/.  We need to build gnulib under some other directory not
  77 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  78 # build it in the same directory, when building in the source dir.
  79 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"])
  80
  81 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  82
  83 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  84                  proc_service.h sys/procfs.h linux/elf.h dnl
  85                  errno.h fcntl.h signal.h sys/file.h malloc.h dnl
  86                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  87                  netinet/tcp.h arpa/inet.h)
  88 AC_CHECK_FUNCS(pread pwrite pread64 readlink)
  89 AC_REPLACE_FUNCS(vasprintf vsnprintf)
  90
  91 GDB_AC_COMMON
  92
  93 # Check for UST
  94 ustlibs=""
  95 ustinc=""
  96
  97 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
  98                           Equivalent to --with-ust-include=PATH/include
  99                           plus --with-ust-lib=PATH/lib])
 100 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 101 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 102
 103 case $with_ust in
 104   no)
 105     ustlibs=
 106     ustinc=
 107     ;;
 108   "" | yes)
 109     ustlibs=" -lust "
 110     ustinc=""
 111     ;;
 112   *)
 113     ustlibs="-L$with_ust/lib -lust"
 114     ustinc="-I$with_ust/include "
 115     ;;
 116 esac
 117 if test "x$with_ust_include" != x; then
 118   ustinc="-I$with_ust_include "
 119 fi
 120 if test "x$with_ust_lib" != x; then
 121   ustlibs="-L$with_ust_lib -lust"
 122 fi
 123
 124 if test "x$with_ust" != "xno"; then
 125   saved_CFLAGS="$CFLAGS"
 126   CFLAGS="$CFLAGS $ustinc"
 127   AC_MSG_CHECKING([for ust])
 128   AC_TRY_COMPILE([
 129 #define CONFIG_UST_GDB_INTEGRATION
 130 #include <ust/ust.h>
 131   ],[],
 132   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 133   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 134   CFLAGS="$saved_CFLAGS"
 135 fi
 136
 137 # Flags needed for UST
 138 AC_SUBST(ustlibs)
 139 AC_SUBST(ustinc)
 140
 141 AC_ARG_ENABLE(werror,
 142   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
 143   [case "${enableval}" in
 144      yes | y) ERROR_ON_WARNING="yes" ;;
 145      no | n)  ERROR_ON_WARNING="no" ;;
 146      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
 147    esac])
 148
 149 # Enable -Werror by default when using gcc.  Turn it off for releases.
 150 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
 151     ERROR_ON_WARNING=yes
 152 fi
 153
 154 WERROR_CFLAGS=""
 155 if test "${ERROR_ON_WARNING}" = yes ; then
 156     WERROR_CFLAGS="-Werror"
 157 fi
 158
 159 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
 160 -Wformat-nonliteral -Wno-char-subscripts -Wempty-body"
 161
 162 WARN_CFLAGS=""
 163 if test "x$GCC" = xyes
 164 then
 165     AC_MSG_CHECKING(compiler warning flags)
 166     # Separate out the -Werror flag as some files just cannot be
 167     # compiled with it enabled.
 168     for w in ${build_warnings}; do
 169         case $w in
 170         -Werr*) WERROR_CFLAGS=-Werror ;;
 171         *) # Check that GCC accepts it
 172             saved_CFLAGS="$CFLAGS"
 173             CFLAGS="$CFLAGS $w"
 174             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 175             CFLAGS="$saved_CFLAGS"
 176         esac
 177     done
 178     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 179 fi
 180 AC_SUBST(WARN_CFLAGS)
 181 AC_SUBST(WERROR_CFLAGS)
 182
 183 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 184 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 185 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 186 dnl augment LIBS.
 187 old_LIBS="$LIBS"
 188 LIBS="$LIBS -ldl"
 189 AC_CHECK_FUNCS(dladdr)
 190 LIBS="$old_LIBS"
 191
 192 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 193
 194 AC_CHECK_TYPES(socklen_t, [], [],
 195 [#include <sys/types.h>
 196 #include <sys/socket.h>
 197 ])
 198
 199 AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 200 #include <elf.h>
 201 )
 202
 203 ACX_PKGVERSION([GDB])
 204 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 205 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 206 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 207
 208 # Check for various supplementary target information (beyond the
 209 # triplet) which might affect the choices in configure.srv.
 210 case "${target}" in
 211 changequote(,)dnl
 212   i[34567]86-*-linux*)
 213 changequote([,])dnl
 214     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 215                    [save_CPPFLAGS="$CPPFLAGS"
 216                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 217                     AC_EGREP_CPP([got it], [
 218 #if __x86_64__
 219 got it
 220 #endif
 221                  ], [gdb_cv_i386_is_x86_64=yes],
 222                     [gdb_cv_i386_is_x86_64=no])
 223                     CPPFLAGS="$save_CPPFLAGS"])
 224     ;;
 225   m68k-*-*)
 226     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 227                    [save_CPPFLAGS="$CPPFLAGS"
 228                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 229                     AC_EGREP_CPP([got it], [
 230 #ifdef __mcoldfire__
 231 got it
 232 #endif
 233                  ], [gdb_cv_m68k_is_coldfire=yes],
 234                     [gdb_cv_m68k_is_coldfire=no])
 235                     CPPFLAGS="$save_CPPFLAGS"])
 236     ;;
 237 esac
 238
 239 . ${srcdir}/configure.srv
 240
 241 if test "${srv_mingwce}" = "yes"; then
 242   LIBS="$LIBS -lws2"
 243 elif test "${srv_mingw}" = "yes"; then
 244   LIBS="$LIBS -lws2_32"
 245 elif test "${srv_qnx}" = "yes"; then
 246   LIBS="$LIBS -lsocket"
 247 elif test "${srv_lynxos}" = "yes"; then
 248   LIBS="$LIBS -lnetinet"
 249 fi
 250
 251 if test "${srv_mingw}" = "yes"; then
 252   AC_DEFINE(USE_WIN32API, 1,
 253             [Define if we should use the Windows API, instead of the
 254              POSIX API.  On Windows, we use the Windows API when
 255              building for MinGW, but the POSIX API when building
 256              for Cygwin.])
 257 fi
 258
 259 if test "${srv_linux_usrregs}" = "yes"; then
 260   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 261             [Define if the target supports PTRACE_PEEKUSR for register ]
 262             [access.])
 263 fi
 264
 265 if test "${srv_linux_regsets}" = "yes"; then
 266   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 267             [Define if the target supports register sets.])
 268
 269   AC_MSG_CHECKING(for PTRACE_GETREGS)
 270   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 271   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 272                   [PTRACE_GETREGS;],
 273                   [gdbsrv_cv_have_ptrace_getregs=yes],
 274                   [gdbsrv_cv_have_ptrace_getregs=no])])
 275   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 276   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 277     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 278               [Define if the target supports PTRACE_GETREGS for register ]
 279               [access.])
 280   fi
 281
 282   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 283   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 284   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 285                   [PTRACE_GETFPXREGS;],
 286                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 287                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 288   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 289   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 290     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 291               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 292               [register access.])
 293   fi
 294 fi
 295
 296 if test "${srv_linux_btrace}" = "yes"; then
 297   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 298             [Define if the target supports branch tracing.])
 299 fi
 300
 301 if test "$ac_cv_header_sys_procfs_h" = yes; then
 302   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 303   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 304   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 305   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 306 fi
 307
 308 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 309 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 310   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 311 fi
 312
 313 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 314 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 315   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 316 fi
 317
 318 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 319 dnl needs it (and gdbreplay doesn't).
 320 old_LIBS="$LIBS"
 321 AC_CHECK_LIB(dl, dlopen)
 322 LIBS="$old_LIBS"
 323
 324 srv_thread_depfiles=
 325 srv_libs=
 326
 327 if test "$srv_linux_thread_db" = "yes"; then
 328   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 329     srv_libs="-ldl"
 330     AC_MSG_CHECKING(for the dynamic export flag)
 331     old_LDFLAGS="$LDFLAGS"
 332     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 333     # supported there.
 334     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 335     LDFLAGS="$LDFLAGS $RDYNAMIC"
 336     AC_TRY_LINK([], [],
 337                 [found="-Wl,--dynamic-list"
 338                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 339                 [RDYNAMIC="-rdynamic"
 340                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 341                  AC_TRY_LINK([], [],
 342                              [found="-rdynamic"],
 343                              [found="no"
 344                               RDYNAMIC=""])])
 345     AC_SUBST(RDYNAMIC)
 346     LDFLAGS="$old_LDFLAGS"
 347     AC_MSG_RESULT($found)
 348   else
 349     srv_libs="-lthread_db"
 350   fi
 351
 352   srv_thread_depfiles="thread-db.o proc-service.o"
 353   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 354   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 355   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 356                   [gdbsrv_cv_have_td_version=yes],
 357                   [gdbsrv_cv_have_td_version=no])])
 358   if test $gdbsrv_cv_have_td_version = yes; then
 359     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 360   fi
 361 fi
 362
 363 AC_ARG_WITH(libthread-db,
 364 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 365 [srv_libthread_db_path="${withval}"
 366   srv_libs="$srv_libthread_db_path"
 367 ])
 368
 369 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 370   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 371 fi
 372
 373 if test "$srv_xmlfiles" != ""; then
 374   srv_xmlbuiltin="xml-builtin.o"
 375   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 376
 377   tmp_xmlfiles=$srv_xmlfiles
 378   srv_xmlfiles=""
 379   for f in $tmp_xmlfiles; do
 380     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 381   done
 382 fi
 383
 384 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
 385 GDBSERVER_LIBS="$srv_libs"
 386
 387 dnl Check whether the target supports __sync_*_compare_and_swap.
 388 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 389                 gdbsrv_cv_have_sync_builtins, [
 390 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 391                 gdbsrv_cv_have_sync_builtins=yes,
 392                 gdbsrv_cv_have_sync_builtins=no)])
 393 if test $gdbsrv_cv_have_sync_builtins = yes; then
 394   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 395     [Define to 1 if the target supports __sync_*_compare_and_swap])
 396 fi
 397
 398 dnl Check for -fvisibility=hidden support in the compiler.
 399 saved_cflags="$CFLAGS"
 400 CFLAGS="$CFLAGS -fvisibility=hidden"
 401 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 402                         [gdbsrv_cv_have_visibility_hidden=yes],
 403                         [gdbsrv_cv_have_visibility_hidden=no])
 404 CFLAGS="$saved_cflags"
 405
 406 dnl Check if we can disable the virtual address space randomization.
 407 dnl The functionality of setarch -R.
 408 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 409 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 410 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 411 #       define ADDR_NO_RANDOMIZE 0x0040000
 412 #      endif
 413        /* Test the flag could be set and stays set.  */
 414        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 415        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 416            return 1])])
 417 AC_RUN_IFELSE([PERSONALITY_TEST],
 418               [gdbsrv_cv_have_personality=true],
 419               [gdbsrv_cv_have_personality=false],
 420               [AC_LINK_IFELSE([PERSONALITY_TEST],
 421                               [gdbsrv_cv_have_personality=true],
 422                               [gdbsrv_cv_have_personality=false])])
 423 if $gdbsrv_cv_have_personality
 424 then
 425     AC_DEFINE([HAVE_PERSONALITY], 1,
 426               [Define if you support the personality syscall.])
 427 fi
 428
 429
 430 IPA_DEPFILES=""
 431 extra_libraries=""
 432
 433 # check whether to enable the inprocess agent
 434 if test "$ipa_obj" != "" \
 435    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 436    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 437    have_ipa=true
 438 else
 439    have_ipa=false
 440 fi
 441
 442 AC_ARG_ENABLE(inprocess-agent,
 443 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 444 [case "$enableval" in
 445   yes) want_ipa=true ;;
 446   no) want_ipa=false ;;
 447   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 448 esac],
 449 [want_ipa=$have_ipa])
 450
 451 if $want_ipa ; then
 452    if $have_ipa ; then
 453      IPA_DEPFILES="$ipa_obj"
 454      extra_libraries="$extra_libraries libinproctrace.so"
 455    else
 456      AC_MSG_ERROR([inprocess agent not supported for this target])
 457    fi
 458 fi
 459
 460 AC_SUBST(GDBSERVER_DEPFILES)
 461 AC_SUBST(GDBSERVER_LIBS)
 462 AC_SUBST(srv_xmlbuiltin)
 463 AC_SUBST(srv_xmlfiles)
 464 AC_SUBST(IPA_DEPFILES)
 465 AC_SUBST(extra_libraries)
 466
 467 GNULIB=build-gnulib-gdbserver/import
 468
 469 GNULIB_STDINT_H=
 470 if test x"$STDINT_H" != x; then
 471   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 472 fi
 473 AC_SUBST(GNULIB_STDINT_H)
 474
 475 AC_OUTPUT(Makefile,
 476 [case x$CONFIG_HEADERS in
 477 xconfig.h:config.in)
 478 echo > stamp-h ;;
 479 esac
 480 ])