gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2013 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_SYS_LARGEFILE
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 AC_PROG_INSTALL
  35 AC_PROG_RANLIB
  36
  37 AC_ARG_PROGRAM
  38
  39 AC_HEADER_STDC
  40
  41 AC_FUNC_ALLOCA
  42
  43 # Set the 'development' global.
  44 . $srcdir/../development.sh
  45
  46 # Enable -lmcheck by default (it provides cheap-enough memory
  47 # mangling), but turn it off for releases.
  48 if $development; then
  49   libmcheck_default=yes
  50 else
  51   libmcheck_default=no
  52 fi
  53 GDB_AC_LIBMCHECK(${libmcheck_default})
  54
  55 ACX_NONCANONICAL_TARGET
  56 ACX_NONCANONICAL_HOST
  57
  58 # Dependency checking.
  59 ZW_CREATE_DEPDIR
  60 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  61
  62 # Check for the 'make' the user wants to use.
  63 AC_CHECK_PROGS(MAKE, make)
  64 MAKE_IS_GNU=
  65 case "`$MAKE --version 2>&1 | sed 1q`" in
  66   *GNU*)
  67     MAKE_IS_GNU=yes
  68     ;;
  69 esac
  70 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  71 AC_PROG_MAKE_SET
  72
  73 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  74 # to find the the source subdir to be configured directly under
  75 # gdbserver/.  We need to build gnulib under some other directory not
  76 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  77 # build it in the same directory, when building in the source dir.
  78 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"])
  79
  80 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  81                  proc_service.h sys/procfs.h linux/elf.h dnl
  82                  stdlib.h dnl
  83                  errno.h fcntl.h signal.h sys/file.h malloc.h dnl
  84                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  85                  netinet/tcp.h arpa/inet.h)
  86 AC_CHECK_FUNCS(pread pwrite pread64 readlink)
  87 AC_REPLACE_FUNCS(vasprintf vsnprintf)
  88
  89 GDB_AC_COMMON
  90
  91 # Check for UST
  92 ustlibs=""
  93 ustinc=""
  94
  95 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
  96                           Equivalent to --with-ust-include=PATH/include
  97                           plus --with-ust-lib=PATH/lib])
  98 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
  99 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 100
 101 case $with_ust in
 102   no)
 103     ustlibs=
 104     ustinc=
 105     ;;
 106   "" | yes)
 107     ustlibs=" -lust "
 108     ustinc=""
 109     ;;
 110   *)
 111     ustlibs="-L$with_ust/lib -lust"
 112     ustinc="-I$with_ust/include "
 113     ;;
 114 esac
 115 if test "x$with_ust_include" != x; then
 116   ustinc="-I$with_ust_include "
 117 fi
 118 if test "x$with_ust_lib" != x; then
 119   ustlibs="-L$with_ust_lib -lust"
 120 fi
 121
 122 if test "x$with_ust" != "xno"; then
 123   saved_CFLAGS="$CFLAGS"
 124   CFLAGS="$CFLAGS $ustinc"
 125   AC_MSG_CHECKING([for ust])
 126   AC_TRY_COMPILE([
 127 #define CONFIG_UST_GDB_INTEGRATION
 128 #include <ust/ust.h>
 129   ],[],
 130   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 131   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 132   CFLAGS="$saved_CFLAGS"
 133 fi
 134
 135 # Flags needed for UST
 136 AC_SUBST(ustlibs)
 137 AC_SUBST(ustinc)
 138
 139 AC_ARG_ENABLE(werror,
 140   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
 141   [case "${enableval}" in
 142      yes | y) ERROR_ON_WARNING="yes" ;;
 143      no | n)  ERROR_ON_WARNING="no" ;;
 144      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
 145    esac])
 146
 147 # Enable -Werror by default when using gcc
 148 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
 149     ERROR_ON_WARNING=yes
 150 fi
 151
 152 WERROR_CFLAGS=""
 153 if test "${ERROR_ON_WARNING}" = yes ; then
 154     WERROR_CFLAGS="-Werror"
 155 fi
 156
 157 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
 158 -Wformat-nonliteral -Wno-char-subscripts -Wempty-body"
 159
 160 WARN_CFLAGS=""
 161 if test "x$GCC" = xyes
 162 then
 163     AC_MSG_CHECKING(compiler warning flags)
 164     # Separate out the -Werror flag as some files just cannot be
 165     # compiled with it enabled.
 166     for w in ${build_warnings}; do
 167         case $w in
 168         -Werr*) WERROR_CFLAGS=-Werror ;;
 169         *) # Check that GCC accepts it
 170             saved_CFLAGS="$CFLAGS"
 171             CFLAGS="$CFLAGS $w"
 172             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 173             CFLAGS="$saved_CFLAGS"
 174         esac
 175     done
 176     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 177 fi
 178 AC_SUBST(WARN_CFLAGS)
 179 AC_SUBST(WERROR_CFLAGS)
 180
 181 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 182 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 183 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 184 dnl augment LIBS.
 185 old_LIBS="$LIBS"
 186 LIBS="$LIBS -ldl"
 187 AC_CHECK_FUNCS(dladdr)
 188 LIBS="$old_LIBS"
 189
 190 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 191
 192 AC_CHECK_TYPES(socklen_t, [], [],
 193 [#include <sys/types.h>
 194 #include <sys/socket.h>
 195 ])
 196
 197 AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 198 #include <elf.h>
 199 )
 200
 201 ACX_PKGVERSION([GDB])
 202 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 203 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 204 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 205
 206 # Check for various supplementary target information (beyond the
 207 # triplet) which might affect the choices in configure.srv.
 208 case "${target}" in
 209 changequote(,)dnl
 210   i[34567]86-*-linux*)
 211 changequote([,])dnl
 212     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 213                    [save_CPPFLAGS="$CPPFLAGS"
 214                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 215                     AC_EGREP_CPP([got it], [
 216 #if __x86_64__
 217 got it
 218 #endif
 219                  ], [gdb_cv_i386_is_x86_64=yes],
 220                     [gdb_cv_i386_is_x86_64=no])
 221                     CPPFLAGS="$save_CPPFLAGS"])
 222     ;;
 223   m68k-*-*)
 224     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 225                    [save_CPPFLAGS="$CPPFLAGS"
 226                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 227                     AC_EGREP_CPP([got it], [
 228 #ifdef __mcoldfire__
 229 got it
 230 #endif
 231                  ], [gdb_cv_m68k_is_coldfire=yes],
 232                     [gdb_cv_m68k_is_coldfire=no])
 233                     CPPFLAGS="$save_CPPFLAGS"])
 234     ;;
 235 esac
 236
 237 . ${srcdir}/configure.srv
 238
 239 if test "${srv_mingwce}" = "yes"; then
 240   LIBS="$LIBS -lws2"
 241 elif test "${srv_mingw}" = "yes"; then
 242   LIBS="$LIBS -lws2_32"
 243 elif test "${srv_qnx}" = "yes"; then
 244   LIBS="$LIBS -lsocket"
 245 elif test "${srv_lynxos}" = "yes"; then
 246   LIBS="$LIBS -lnetinet"
 247 fi
 248
 249 if test "${srv_mingw}" = "yes"; then
 250   AC_DEFINE(USE_WIN32API, 1,
 251             [Define if we should use the Windows API, instead of the
 252              POSIX API.  On Windows, we use the Windows API when
 253              building for MinGW, but the POSIX API when building
 254              for Cygwin.])
 255 fi
 256
 257 if test "${srv_linux_usrregs}" = "yes"; then
 258   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 259             [Define if the target supports PTRACE_PEEKUSR for register ]
 260             [access.])
 261 fi
 262
 263 if test "${srv_linux_regsets}" = "yes"; then
 264   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 265             [Define if the target supports register sets.])
 266
 267   AC_MSG_CHECKING(for PTRACE_GETREGS)
 268   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 269   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 270                   [PTRACE_GETREGS;],
 271                   [gdbsrv_cv_have_ptrace_getregs=yes],
 272                   [gdbsrv_cv_have_ptrace_getregs=no])])
 273   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 274   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 275     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 276               [Define if the target supports PTRACE_GETREGS for register ]
 277               [access.])
 278   fi
 279
 280   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 281   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 282   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 283                   [PTRACE_GETFPXREGS;],
 284                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 285                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 286   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 287   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 288     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 289               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 290               [register access.])
 291   fi
 292 fi
 293
 294 if test "${srv_linux_btrace}" = "yes"; then
 295   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 296             [Define if the target supports branch tracing.])
 297 fi
 298
 299 if test "$ac_cv_header_sys_procfs_h" = yes; then
 300   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 301   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 302   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 303   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 304 fi
 305
 306 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 307 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 308   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 309 fi
 310
 311 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 312 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 313   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 314 fi
 315
 316 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 317 dnl needs it (and gdbreplay doesn't).
 318 old_LIBS="$LIBS"
 319 AC_CHECK_LIB(dl, dlopen)
 320 LIBS="$old_LIBS"
 321
 322 srv_thread_depfiles=
 323 srv_libs=
 324
 325 if test "$srv_linux_thread_db" = "yes"; then
 326   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 327     srv_libs="-ldl"
 328     AC_MSG_CHECKING(for the dynamic export flag)
 329     old_LDFLAGS="$LDFLAGS"
 330     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 331     # supported there.
 332     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 333     LDFLAGS="$LDFLAGS $RDYNAMIC"
 334     AC_TRY_LINK([], [],
 335                 [found="-Wl,--dynamic-list"
 336                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 337                 [RDYNAMIC="-rdynamic"
 338                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 339                  AC_TRY_LINK([], [],
 340                              [found="-rdynamic"],
 341                              [found="no"
 342                               RDYNAMIC=""])])
 343     AC_SUBST(RDYNAMIC)
 344     LDFLAGS="$old_LDFLAGS"
 345     AC_MSG_RESULT($found)
 346   else
 347     srv_libs="-lthread_db"
 348   fi
 349
 350   srv_thread_depfiles="thread-db.o proc-service.o"
 351   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 352   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 353   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 354                   [gdbsrv_cv_have_td_version=yes],
 355                   [gdbsrv_cv_have_td_version=no])])
 356   if test $gdbsrv_cv_have_td_version = yes; then
 357     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 358   fi
 359 fi
 360
 361 AC_ARG_WITH(libthread-db,
 362 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 363 [srv_libthread_db_path="${withval}"
 364   srv_libs="$srv_libthread_db_path"
 365 ])
 366
 367 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 368   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 369 fi
 370
 371 if test "$srv_xmlfiles" != ""; then
 372   srv_xmlbuiltin="xml-builtin.o"
 373   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 374
 375   tmp_xmlfiles=$srv_xmlfiles
 376   srv_xmlfiles=""
 377   for f in $tmp_xmlfiles; do
 378     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 379   done
 380 fi
 381
 382 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
 383 GDBSERVER_LIBS="$srv_libs"
 384
 385 dnl Check whether the target supports __sync_*_compare_and_swap.
 386 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 387                 gdbsrv_cv_have_sync_builtins, [
 388 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 389                 gdbsrv_cv_have_sync_builtins=yes,
 390                 gdbsrv_cv_have_sync_builtins=no)])
 391 if test $gdbsrv_cv_have_sync_builtins = yes; then
 392   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 393     [Define to 1 if the target supports __sync_*_compare_and_swap])
 394 fi
 395
 396 dnl Check for -fvisibility=hidden support in the compiler.
 397 saved_cflags="$CFLAGS"
 398 CFLAGS="$CFLAGS -fvisibility=hidden"
 399 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 400                         [gdbsrv_cv_have_visibility_hidden=yes],
 401                         [gdbsrv_cv_have_visibility_hidden=no])
 402 CFLAGS="$saved_cflags"
 403
 404 dnl Check if we can disable the virtual address space randomization.
 405 dnl The functionality of setarch -R.
 406 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 407 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 408 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 409 #       define ADDR_NO_RANDOMIZE 0x0040000
 410 #      endif
 411        /* Test the flag could be set and stays set.  */
 412        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 413        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 414            return 1])])
 415 AC_RUN_IFELSE([PERSONALITY_TEST],
 416               [gdbsrv_cv_have_personality=true],
 417               [gdbsrv_cv_have_personality=false],
 418               [AC_LINK_IFELSE([PERSONALITY_TEST],
 419                               [gdbsrv_cv_have_personality=true],
 420                               [gdbsrv_cv_have_personality=false])])
 421 if $gdbsrv_cv_have_personality
 422 then
 423     AC_DEFINE([HAVE_PERSONALITY], 1,
 424               [Define if you support the personality syscall.])
 425 fi
 426
 427
 428 IPA_DEPFILES=""
 429 extra_libraries=""
 430
 431 # check whether to enable the inprocess agent
 432 if test "$ipa_obj" != "" \
 433    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 434    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 435    have_ipa=true
 436 else
 437    have_ipa=false
 438 fi
 439
 440 AC_ARG_ENABLE(inprocess-agent,
 441 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 442 [case "$enableval" in
 443   yes) want_ipa=true ;;
 444   no) want_ipa=false ;;
 445   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 446 esac],
 447 [want_ipa=$have_ipa])
 448
 449 if $want_ipa ; then
 450    if $have_ipa ; then
 451      IPA_DEPFILES="$ipa_obj"
 452      extra_libraries="$extra_libraries libinproctrace.so"
 453    else
 454      AC_MSG_ERROR([inprocess agent not supported for this target])
 455    fi
 456 fi
 457
 458 AC_SUBST(GDBSERVER_DEPFILES)
 459 AC_SUBST(GDBSERVER_LIBS)
 460 AC_SUBST(srv_xmlbuiltin)
 461 AC_SUBST(srv_xmlfiles)
 462 AC_SUBST(IPA_DEPFILES)
 463 AC_SUBST(extra_libraries)
 464
 465 GNULIB=build-gnulib-gdbserver/import
 466
 467 GNULIB_STDINT_H=
 468 if test x"$STDINT_H" != x; then
 469   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 470 fi
 471 AC_SUBST(GNULIB_STDINT_H)
 472
 473 AC_OUTPUT(Makefile,
 474 [case x$CONFIG_HEADERS in
 475 xconfig.h:config.in)
 476 echo > stamp-h ;;
 477 esac
 478 ])